gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 AC_PREREQ(1.118)dnl
   8 AC_INIT(as.h)dnl
   9 dnl
  10 bfd_gas=no
  11 user_bfd_gas=
  12 AC_ARG_ENABLE(bfd-assembler,
  13 [    bfd-assembler      use BFD back end for writing object files],
  14 [case "${enableval}" in
  15   yes) need_bfd=yes user_bfd_gas=yes ;;
  16   no)  user_bfd_gas=no ;;
  17   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  18 esac])dnl
  19
  20 # Generate a header file -- gets more post-processing by Makefile later.
  21 AC_CONFIG_HEADER(conf)
  22
  23 dnl For recursion to work right, this must be an absolute pathname.
  24 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  25 AC_CANONICAL_SYSTEM
  26 AC_ARG_PROGRAM
  27
  28 emulation=generic
  29
  30 # assign cpu type
  31
  32 # check for architecture variants
  33 case ${target_cpu} in
  34   hppa*)        cpu_type=hppa ;;
  35 changequote(,)dnl
  36   i[45]86)      cpu_type=i386 ;;
  37   m680[012346]0) cpu_type=m68k ;;
  38   m68008)       cpu_type=m68k ;;
  39   m683??)       cpu_type=m68k ;;
  40 changequote([,])dnl
  41   m8*)          cpu_type=m88k ;;
  42   mips*el)      cpu_type=mips endian=little;;
  43   mips*)        cpu_type=mips endian=big ;;
  44   powerpc*)     cpu_type=ppc ;;
  45   rs6000*)      cpu_type=ppc ;;
  46   sparc64)      cpu_type=sparc obj_format=elf
  47                 AC_DEFINE(sparcv9) ;;
  48   sparclite*)   cpu_type=sparc ;;
  49   *)            cpu_type=${target_cpu} ;;
  50 esac
  51
  52 # do we need the opcodes library?
  53 case ${cpu_type} in
  54   alpha | vax)
  55     ;;
  56   *)
  57     OPCODES_LIB="../opcodes/libopcodes.a"
  58     ;;
  59 esac
  60 AC_SUBST(OPCODES_LIB)
  61
  62 gas_target=${cpu_type}
  63 generic_target=${cpu_type}-${target_vendor}-${target_os}
  64 dev=no
  65
  66 # assign object format
  67 case ${generic_target} in
  68   a29k-amd-udi)         obj_format=coff gas_target=ebmon29k ;;
  69   a29k-amd-ebmon)       obj_format=coff gas_target=ebmon29k ;;
  70
  71   alpha-*-netware*)     obj_format=ecoff ;;
  72   alpha-*-osf*)         obj_format=ecoff ;;
  73
  74   arm-*-riscix*)        obj_format=aout ;;
  75
  76   hppa-*-*elf*)         obj_format=elf emulation=hppa ;;
  77   hppa-*-osf*)          obj_format=som emulation=hppa ;;
  78   hppa-*-hpux*)         obj_format=som emulation=hppa ;;
  79   hppa-*-bsd*)          obj_format=som emulation=hppa ;;
  80   hppa-*-hiux*)         obj_format=som emulation=hppa ;;
  81
  82   h8300-*-coff)         obj_format=coff ;;
  83
  84   i386-ibm-aix*)        obj_format=coff gas_target=i386coff
  85                          emulation=i386aix ;;
  86   i386-*-bsd*)          obj_format=aout emulation=386bsd ;;
  87   i386-*-netbsd0.8)     obj_format=aout emulation=386bsd ;;
  88   i386-*-netbsd*)       obj_format=aout emulation=netbsd ;;
  89   i386-*-linux*elf*)    obj_format=elf  emulation=linux ;;
  90   i386-*-linux*coff*)   obj_format=coff emulation=linux
  91                          gas_target=i386coff ;;
  92   i386-*-linux*)        obj_format=aout emulation=linux ;;
  93   i386-*-lynxos*)       obj_format=coff gas_target=i386coff
  94                          emulation=lynx ;;
  95   i386-*-sysv4* | i386-*-solaris* | i386-*-elf)
  96                         obj_format=elf ;;
  97   i386-*-coff | i386-*-sysv* | i386-*-sco* | i386-*-isc*)
  98                         obj_format=coff gas_target=i386coff ;;
  99   i386-*-vsta)          obj_format=aout ;;
 100   i386-*-go32)          obj_format=coff gas_target=i386coff ;;
 101   i386-*-mach* | i386-*-gnu*)
 102                         obj_format=aout emulation=mach bfd_gas=yes ;;
 103
 104   i960-*-bout)          obj_format=bout ;;
 105   i960-*-coff)          obj_format=coff emulation=ic960 gas_target=ic960coff ;;
 106   i960-*-nindy*)        obj_format=bout ;;
 107   i960-*-vxworks4*)     obj_format=bout ;;
 108   i960-*-vxworks5.0)    obj_format=bout ;;
 109   i960-*-vxworks5.*)    obj_format=coff emulation=ic960 gas_target=ic960coff ;;
 110   i960-*-vxworks*)      obj_format=bout ;;
 111
 112   m68k-wrs-vxworks | m68k-ericsson-ose | m68k-*-sunos*)
 113                         obj_format=aout emulation=sun3 ;;
 114   m68k-motorola-sysv)   obj_format=coff gas_target=m68kcoff emulation=delta ;;
 115   m68k-bull-sysv3*)     obj_format=coff gas_target=m68kcoff emulation=dpx2 ;;
 116   m68k-apollo-*)        obj_format=coff gas_target=apollo emulation=apollo ;;
 117   m68k-*-coff | m68k-*-sysv*)
 118                         obj_format=coff gas_target=m68kcoff ;;
 119   m68k-*-hpux*)         obj_format=hp300 emulation=hp300 ;;
 120   m68k-*-lynxos*)       obj_format=coff gas_target=m68kcoff
 121                          emulation=lynx ;;
 122
 123   m88k-*-coff*)         obj_format=coff gas_target=m88kcoff ;;
 124
 125   # don't change emulation like *-*-bsd does
 126   mips-*-bsd*)          obj_format=aout gas_target=mips-lit ;;
 127   mips-*-ultrix*)       obj_format=ecoff gas_target=mips-lit ;;
 128   mips-*-ecoff*)        obj_format=ecoff
 129                         case "$endian" in
 130                         big) gas_target=mips-big ;;
 131                         *)   gas_target=mips-lit ;;
 132                         esac
 133                         ;;
 134   mips-*-ecoff*)        obj_format=ecoff gas_target=mips-big ;;
 135   mips-*-irix5*)        obj_format=elf gas_target=mips-big ;;
 136   mips-*-irix*)         obj_format=ecoff gas_target=mips-big ;;
 137   mips-*-riscos*)       obj_format=ecoff gas_target=mips-big ;;
 138   mips-*-sysv*)         obj_format=ecoff gas_target=mips-big ;;
 139   mips-*-elf*)          obj_format=elf
 140                         case "$endian" in
 141                         big) gas_target=mips-big ;;
 142                         *)   gas_target=mips-lit ;;
 143                         esac
 144                         ;;
 145   ppc-*-aix*)           obj_format=coff ;;
 146   ppc-*-elf*)           obj_format=elf ;;
 147   ppc-*-netware*)       obj_format=elf emulation=ppcnw ;;
 148   ppc-*-sysv4*)         obj_format=elf ;;
 149
 150   sh-*-coff)            obj_format=coff ;;
 151
 152   ns32k-pc532-mach*)    obj_format=aout emulation=pc532 ;;
 153   ns32k-pc532-netbsd*)  obj_format=aout emulation=nbsd532 ;;
 154
 155   sparc*-*-sunos4*)     obj_format=aout emulation=sun3 ;;
 156   sparc*-*-aout | sparc*-*-vxworks)
 157                         obj_format=aout ;;
 158   sparc*-*-coff)        obj_format=coff ;;
 159   sparc*-*-lynxos*)     obj_format=coff emulation=lynx ;;
 160   sparc*-fujitsu-none)  obj_format=aout ;;
 161   sparc*-*-elf | sparc*-*-solaris*)
 162                         obj_format=elf ;;
 163
 164   vax-*-bsd* | vax-*-ultrix*)
 165                         obj_format=aout ;;
 166   vax-*-vms)            obj_format=vms ;;
 167
 168   z8k-*-coff | z8k-*-sim)
 169                         obj_format=coff ;;
 170
 171   *-*-aout | *-*-scout)
 172                         obj_format=aout ;;
 173   *-*-nindy*)
 174                         obj_format=bout ;;
 175   *-*-bsd*)
 176                         obj_format=aout emulation=sun3 ;;
 177   *-*-generic)          obj_format=generic ;;
 178   *-*-xray | *-*-hms)   obj_format=coff ;;
 179   *-*-sim)              obj_format=coff ;;
 180   *-*-elf | *-*-sysv4* | *-*-solaris*)
 181                         AC_MSG_WARN(GAS support for ELF format is incomplete)
 182                         obj_format=elf dev=yes ;;
 183   *-*-vxworks)          obj_format=aout ;;
 184   *-*-netware)          obj_format=elf ;;
 185 esac
 186
 187 # Assign floating point type.  Most processors with FP support
 188 # IEEE FP.  On those that don't support FP at all, usually IEEE
 189 # is emulated.
 190 case ${target_cpu} in
 191   vax | tahoe ) atof=${target_cpu} ;;
 192   *)                    atof=ieee ;;
 193 esac
 194
 195 case "${obj_format}" in
 196   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 197 esac
 198
 199 dnl
 200 dnl Make sure the desired support files exist.
 201 dnl
 202
 203 if test ! -r ${srcdir}/config/tc-${cpu_type}.c; then
 204   AC_MSG_ERROR(GAS does not support target CPU ${cpu_type})
 205 fi
 206
 207 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 208   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 209 fi
 210
 211 # and target makefile frag
 212
 213 target_frag=${srcdir}/config/${gas_target}.mt
 214 if test ! -r ${target_frag}; then
 215   target_frag=/dev/null # ick! but subst_file can't be conditionalized
 216 fi
 217 AC_SUBST_FILE(target_frag)
 218
 219 case ${cpu_type}-${obj_format} in
 220   arm-*)        bfd_gas=yes ;;
 221 # not yet
 222 # i386-aout)    bfd_gas=preferred ;;
 223   mips-*)       bfd_gas=yes ;;
 224   ns32k-*)      bfd_gas=yes ;;
 225   ppc-*)        bfd_gas=yes ;;
 226   sparc*-*)     bfd_gas=yes ;;
 227   *-elf)        bfd_gas=yes ;;
 228   *-ecoff)      bfd_gas=yes ;;
 229   *-som)        bfd_gas=yes ;;
 230   *)            ;;
 231 esac
 232
 233 case ${user_bfd_gas}-${bfd_gas} in
 234   yes-yes | no-no)
 235     # We didn't override user's choice.
 236     ;;
 237   no-yes)
 238     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 239     ;;
 240   no-preferred)
 241     bfd_gas=no
 242     ;;
 243   *-preferred)
 244     bfd_gas=yes
 245     ;;
 246   yes-*)
 247     bfd_gas=yes
 248     ;;
 249   -*)
 250     # User specified nothing.
 251     ;;
 252 esac
 253
 254 case ${bfd_gas}-${cpu_type}-${obj_format} in
 255   yes-*-coff)   need_bfd=yes ;;
 256   no-*-coff)    need_bfd=yes
 257                 AC_DEFINE(MANY_SEGMENTS) ;;
 258 esac
 259
 260 reject_dev_configs=yes
 261
 262 case ${reject_dev_configs}-${dev} in
 263   yes-yes) # Oops.
 264     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 265     ;;
 266 esac
 267
 268 AC_LINK_FILES(config/tc-${cpu_type}.c   config/tc-${cpu_type}.h \
 269         config/obj-${obj_format}.h config/obj-${obj_format}.c \
 270         config/te-${emulation}.h config/atof-${atof}.c,
 271         targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c)
 272
 273 case "${bfd_gas}" in
 274   yes)  AC_DEFINE(BFD_ASSEMBLER)
 275         need_bfd=yes ;;
 276 esac
 277
 278 case "${need_bfd}" in
 279   yes)  BFDLIB=../bfd/libbfd.a
 280         ALL_OBJ_DEPS="$ALL_OBJ_DEPS ../bfd/bfd.h"
 281         ;;
 282 esac
 283 AC_SUBST(BFDLIB)
 284 AC_SUBST(ALL_OBJ_DEPS)
 285
 286 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}")
 287 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}")
 288 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}")
 289 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}")
 290 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}")
 291
 292 AC_PROG_CC
 293 AC_PROG_INSTALL
 294
 295 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 296
 297 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 298 # people who are not cross-compiling but are compiling cross-assemblers.
 299 AC_MSG_CHECKING(whether compiling a cross-assembler)
 300 if test "${host}" = "${target}"; then
 301   cross_gas=no
 302 else
 303   cross_gas=yes
 304   AC_DEFINE(CROSS_COMPILE)
 305 fi
 306 AC_MSG_RESULT($cross_gas)
 307
 308 dnl ansidecl.h will deal with const
 309 dnl AC_CONST
 310 AC_FUNC_ALLOCA
 311 AC_C_INLINE
 312
 313 # VMS doesn't have unlink.
 314 AC_CHECK_FUNCS(unlink remove, break)
 315
 316 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 317 # enough, but on some of those systems, the assert macro relies on requoting
 318 # working properly!
 319 GAS_WORKING_ASSERT
 320
 321 # On some systems, the system header files may not declare malloc, realloc,
 322 # and free.  There are places where gas needs these functions to have been
 323 # declared -- such as when taking their addresses.
 324 gas_test_headers="
 325 #ifdef HAVE_MEMORY_H
 326 #include <memory.h>
 327 #endif
 328 #ifdef HAVE_STRING_H
 329 #include <string.h>
 330 #endif
 331 #ifdef HAVE_STDLIB_H
 332 #include <stdlib.h>
 333 #endif
 334 #ifdef HAVE_UNISTD_H
 335 #include <unistd.h>
 336 #endif
 337 "
 338 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 339 GAS_CHECK_DECL_NEEDED(free, f, int f, $gas_test_headers)
 340
 341 # Does errno.h declare errno, or do we have to add a separate declaration
 342 # for it?
 343 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 344 #ifdef HAVE_ERRNO_H
 345 #include <errno.h>
 346 #endif
 347 ])
 348
 349 AC_CONFIG_SUBDIRS(testsuite)
 350
 351 dnl This must come last.
 352 AC_OUTPUT(Makefile doc/Makefile .gdbinit:gdbinit.in)