gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 dnl v2.5 needed for --bindir et al
   8 AC_PREREQ(2.57)
   9 AC_INIT(as.h)
  10
  11 dnl Autoconf 2.57 will find the aux dir without this.  However, unless
  12 dnl we specify this explicitly, automake-1.7 will assume that ylwrap is in
  13 dnl gas/ instead of gas/../.
  14 AC_CONFIG_AUX_DIR(..)
  15 AC_CANONICAL_SYSTEM
  16 AC_ISC_POSIX
  17
  18 changequote(,)dnl
  19 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  20 changequote([,])dnl
  21 AM_INIT_AUTOMAKE(gas, ${BFD_VERSION})
  22
  23 AM_PROG_LIBTOOL
  24
  25 user_bfd_gas=
  26 AC_ARG_ENABLE(bfd-assembler,
  27 [  --enable-bfd-assembler  use BFD back end for writing object files],
  28 [case "${enableval}" in
  29   yes) need_bfd=yes user_bfd_gas=yes ;;
  30   no)  user_bfd_gas=no ;;
  31   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  32 esac])dnl
  33 AC_ARG_ENABLE(targets,
  34 [    targets            alternative target configurations besides the primary],
  35 [case "${enableval}" in
  36   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  37             ;;
  38   no)       enable_targets= ;;
  39   *)        enable_targets=$enableval ;;
  40 esac])dnl
  41 AC_ARG_ENABLE(commonbfdlib,
  42 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  43 [case "${enableval}" in
  44   yes) commonbfdlib=true ;;
  45   no)  commonbfdlib=false ;;
  46   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  47 esac])dnl
  48
  49 using_cgen=no
  50
  51 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  52 AC_ARG_ENABLE(build-warnings,
  53 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  54 [case "${enableval}" in
  55   yes)  ;;
  56   no)   build_warnings="-w";;
  57   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  58         build_warnings="${build_warnings} ${t}";;
  59   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  60         build_warnings="${t} ${build_warnings}";;
  61   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  62 esac
  63 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  64   echo "Setting warning flags = $build_warnings" 6>&1
  65 fi])dnl
  66 WARN_CFLAGS=""
  67 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  68     WARN_CFLAGS="${build_warnings}"
  69 fi
  70 AC_SUBST(WARN_CFLAGS)
  71
  72 # Generate a header file
  73 AM_CONFIG_HEADER(config.h:config.in)
  74
  75 # If we are on a DOS filesystem, we must use gdb.ini rather than
  76 # .gdbinit.
  77 case "${host}" in
  78   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-windows*)
  79     GDBINIT="gdb.ini"
  80     AC_CONFIG_FILES(gdb.ini:gdbinit.in)
  81     ;;
  82   *)
  83     GDBINIT=".gdbinit"
  84     AC_CONFIG_FILES(.gdbinit:gdbinit.in)
  85     ;;
  86 esac
  87 AC_SUBST(GDBINIT)
  88
  89 te_file=generic
  90
  91 # Makefile target for installing gas in $(tooldir)/bin.
  92 install_tooldir=install-exec-tooldir
  93
  94 canon_targets=""
  95 all_targets=no
  96 if test -n "$enable_targets" ; then
  97   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  98     if test $t = "all"; then
  99       all_targets=yes
 100       continue
 101     fi
 102     result=`$ac_config_sub $t 2>/dev/null`
 103     if test -n "$result" ; then
 104       canon_targets="$canon_targets $result"
 105 #    else
 106 #      # Permit "all", etc.  We don't support it yet though.
 107 #      canon_targets="$canon_targets $t"
 108     fi
 109   done
 110   GAS_UNIQ(canon_targets)
 111 fi
 112
 113 emulations=""
 114
 115 for this_target in $target $canon_targets ; do
 116
 117 changequote(,)dnl
 118     eval `echo $this_target | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
 119 changequote([,])dnl
 120
 121     # check for architecture variants
 122     arch=
 123     endian=
 124     case ${cpu} in
 125       am33_2.0)         cpu_type=mn10300 endian=little ;;
 126       alpha*)           cpu_type=alpha ;;
 127       arm*be|xscale*be|strongarm*be | \
 128       arm*b|xscale*b|strongarm*b) cpu_type=arm endian=big ;;
 129       arm*|xscale*|strongarm*)    cpu_type=arm endian=little ;;
 130       c4x*)             cpu_type=tic4x ;;
 131       hppa*)            cpu_type=hppa ;;
 132 changequote(,)dnl
 133       i[3-7]86)         cpu_type=i386 arch=i386;;
 134       x86_64)           cpu_type=i386 arch=x86_64;;
 135       ia64)             cpu_type=ia64 ;;
 136       ip2k)             cpu_type=ip2k endian=big ;;
 137       iq2000)           cpu_type=iq2000 endian=big ;;
 138       m6811|m6812|m68hc12) cpu_type=m68hc11 ;;
 139       m680[012346]0)    cpu_type=m68k ;;
 140 changequote([,])dnl
 141       m68008)           cpu_type=m68k ;;
 142       m683??)           cpu_type=m68k ;;
 143       m5200)            cpu_type=m68k ;;
 144       m8*)              cpu_type=m88k ;;
 145       mips*el)          cpu_type=mips endian=little ;;
 146       mips*)            cpu_type=mips endian=big ;;
 147       or32*)            cpu_type=or32 endian=big ;;
 148       pjl*)             cpu_type=pj endian=little ;;
 149       pj*)              cpu_type=pj endian=big ;;
 150       powerpc*le*)      cpu_type=ppc endian=little ;;
 151       powerpc*)         cpu_type=ppc endian=big ;;
 152       rs6000*)          cpu_type=ppc ;;
 153       s390x*)           cpu_type=s390 arch=s390x ;;
 154       s390*)            cpu_type=s390 arch=s390 ;;
 155       sh5*)             cpu_type=sh64 endian=big ;;
 156       sh5le*)           cpu_type=sh64 endian=little ;;
 157       sh64*)            cpu_type=sh64 endian=big ;;
 158       sh64le*)          cpu_type=sh64 endian=little ;;
 159       sh*le)            cpu_type=sh endian=little ;;
 160       sh*)              cpu_type=sh endian=big ;;
 161       sparclite*)       cpu_type=sparc arch=sparclite ;;
 162       sparclet*)        cpu_type=sparc arch=sparclet ;;
 163       sparc64*)         cpu_type=sparc arch=v9-64 ;;
 164       sparc86x*)        cpu_type=sparc arch=sparc86x  ;;
 165       sparc*)           cpu_type=sparc arch=sparclite ;; # ??? See tc-sparc.c.
 166       v850*)            cpu_type=v850 ;;
 167       crx*)             cpu_type=crx endian=little ;;
 168       xtensa*)          cpu_type=xtensa arch=xtensa ;;
 169       m32r)             cpu_type=m32r target_cpu=m32r endian=big ;;
 170       m32rle)           cpu_type=m32r target_cpu=m32r endian=little ;;
 171       *)                cpu_type=${cpu} ;;
 172     esac
 173
 174     if test ${this_target} = $target ; then
 175       target_cpu_type=${cpu_type}
 176     elif test ${target_cpu_type} != ${cpu_type} ; then
 177       continue
 178     fi
 179
 180     generic_target=${cpu_type}-$vendor-$os
 181     dev=no
 182     bfd_gas=no
 183     em=generic
 184
 185     # assign object format
 186     case ${generic_target} in
 187       a29k-*-coff)                      fmt=coff ;;
 188       a29k-amd-udi)                     fmt=coff ;;
 189       a29k-amd-ebmon)                   fmt=coff ;;
 190       a29k-nyu-sym1)                    fmt=coff ;;
 191       a29k-*-rtems*)                    fmt=coff ;;
 192       a29k-*-vxworks*)                  fmt=coff ;;
 193
 194       alpha*-*-*vms*)                   fmt=evax ;;
 195       alpha*-*-osf*)                    fmt=ecoff ;;
 196       alpha*-*-linuxecoff*)             fmt=ecoff ;;
 197       alpha*-*-linux-gnu*)              fmt=elf em=linux ;;
 198       alpha*-*-netbsd*)                 fmt=elf em=nbsd ;;
 199       alpha*-*-openbsd*)                fmt=elf em=obsd ;;
 200
 201       # cpu_type for am33_2.0 is set to mn10300
 202       mn10300-*-linux*)                 fmt=elf bfd_gas=yes em=linux ;;
 203
 204       arc-*-elf*)                       fmt=elf ;;
 205
 206       arm-*-aout)                       fmt=aout ;;
 207       arm-*-coff | thumb-*-coff)        fmt=coff ;;
 208       arm-*-rtems* | thumb-*-rtems*)    fmt=elf ;;
 209       arm-*-elf | thumb-*-elf)          fmt=elf ;;
 210       arm-*-kaos*)                      fmt=elf ;;
 211       arm*-*-conix*)                    fmt=elf ;;
 212       arm-*-linux*aout*)                fmt=aout em=linux ;;
 213       arm*-*-linux-gnu*)                fmt=elf  em=linux ;;
 214       arm*-*-uclinux*)                  fmt=elf  em=linux ;;
 215       arm-*-netbsdelf*)                 fmt=elf  em=nbsd ;;
 216       arm-*-*n*bsd*)                    fmt=aout em=nbsd ;;
 217       arm-**-nto*)                      fmt=elf ;;
 218       arm-*-oabi | thumb-*-oabi)        fmt=elf ;;
 219       arm-epoc-pe | thumb-epoc-pe)      fmt=coff em=epoc-pe ;;
 220       arm-wince-pe | arm-*-wince)       fmt=coff em=wince-pe ;;
 221       arm-*-pe | thumb-*-pe)            fmt=coff em=pe ;;
 222       arm-*-riscix*)                    fmt=aout em=riscix ;;
 223
 224       avr-*-*)                          fmt=elf ;;
 225
 226       cris-*-linux-gnu*)                fmt=multi bfd_gas=yes em=linux ;;
 227       cris-*-*)                         fmt=multi bfd_gas=yes ;;
 228
 229       crx-*-elf*)                       fmt=elf ;;
 230
 231       d10v-*-*)                         fmt=elf ;;
 232       d30v-*-*)                         fmt=elf ;;
 233       dlx-*-*)                          fmt=elf ;;
 234
 235       fr30-*-*)                         fmt=elf ;;
 236       frv-*-*linux*)                    fmt=elf em=linux;;
 237       frv-*-*)                          fmt=elf ;;
 238
 239       hppa-*-linux*)    case ${cpu} in
 240                             hppa*64*)   fmt=elf em=hppalinux64;;
 241                             hppa*)      fmt=elf em=linux;;
 242                         esac ;;
 243       hppa-*-*elf*)                     fmt=elf em=hppa ;;
 244       hppa-*-lites*)                    fmt=elf em=hppa ;;
 245       hppa-*-netbsd*)                   fmt=elf em=nbsd ;;
 246       hppa-*-openbsd*)                  fmt=elf em=hppa ;;
 247       hppa-*-osf*)                      fmt=som em=hppa ;;
 248       hppa-*-rtems*)                    fmt=elf em=hppa ;;
 249       hppa-*-hpux11*)   case ${cpu} in
 250                             hppa*64*)   fmt=elf em=hppa64 ;;
 251                             hppa*)      fmt=som em=hppa ;;
 252                         esac ;;
 253       hppa-*-hpux*)                     fmt=som em=hppa ;;
 254       hppa-*-mpeix*)                    fmt=som em=hppa ;;
 255       hppa-*-bsd*)                      fmt=som em=hppa ;;
 256       hppa-*-hiux*)                     fmt=som em=hppa ;;
 257
 258       h8300-*-rtems*)                   fmt=coff ;;
 259       h8300-*-coff)                     fmt=coff ;;
 260       h8300-*-elf)                      fmt=elf ;;
 261       h8500-*-rtems*)                   fmt=coff ;;
 262       h8500-*-coff)                     fmt=coff ;;
 263
 264       i370-*-elf* | i370-*-linux*)      fmt=elf ;;
 265       i386-ibm-aix*)                    fmt=coff em=i386aix ;;
 266       i386-sequent-bsd*)                fmt=aout em=dynix ;;
 267       i386-*-beospe*)                   fmt=coff em=pe ;;
 268       i386-*-beos*)                     fmt=elf ;;
 269       i386-*-coff)                      fmt=coff ;;
 270       i386-*-elf)                       fmt=elf ;;
 271       i386-*-kaos*)                     fmt=elf ;;
 272       i386-*-bsd*)                      fmt=aout em=386bsd ;;
 273       i386-*-netbsd0.8)                 fmt=aout em=386bsd ;;
 274       i386-*-netbsdpe*)                 fmt=coff em=pe ;;
 275       i386-*-netbsd*-gnu* | \
 276       i386-*-knetbsd*-gnu | \
 277       i386-*-netbsdelf*)                fmt=elf em=nbsd ;;
 278       i386-*-*n*bsd*)   case ${cpu} in
 279                             x86_64)     fmt=elf em=nbsd ;;
 280                             *)          fmt=aout em=nbsd ;;
 281                         esac ;;
 282       i386-*-linux*aout*)               fmt=aout em=linux ;;
 283       i386-*-linux*oldld)               fmt=aout em=linux ;;
 284       i386-*-linux*coff*)               fmt=coff em=linux ;;
 285       i386-*-linux-gnu*)                fmt=elf em=linux ;;
 286       x86_64-*-linux-gnu*)              fmt=elf em=linux ;;
 287       i386-*-lynxos*)                   fmt=elf em=lynx bfd_gas=yes ;;
 288 changequote(,)dnl
 289       i386-*-sysv[45]*)                 fmt=elf ;;
 290       i386-*-solaris*)                  fmt=elf ;;
 291       i386-*-freebsdaout*)              fmt=aout em=386bsd ;;
 292       i386-*-freebsd[12].*)             fmt=aout em=386bsd ;;
 293       i386-*-freebsd[12])               fmt=aout em=386bsd ;;
 294 changequote([,])dnl
 295       i386-*-freebsd* | i386-*-kfreebsd*-gnu)
 296                                         fmt=elf em=freebsd ;;
 297       i386-*-sysv*)                     fmt=coff ;;
 298       i386-*-sco3.2v5*coff)             fmt=coff ;;
 299       i386-*-isc*)                      fmt=coff ;;
 300       i386-*-sco3.2v5*)                 fmt=elf
 301           if test ${this_target} = $target; then
 302             AC_DEFINE(SCO_ELF, 1, [Define if defaulting to ELF on SCO 5.])
 303           fi ;;
 304       i386-*-sco3.2*)                   fmt=coff ;;
 305       i386-*-vsta)                      fmt=aout ;;
 306       i386-*-msdosdjgpp* \
 307       | i386-*-go32* \
 308       | i386-go32-rtems*)               fmt=coff em=go32
 309             AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?]) ;;
 310       i386-*-rtemself*)                 fmt=elf ;;
 311       i386-*-rtemscoff*)                fmt=coff ;;
 312       i386-*-rtems*)                    fmt=elf ;;
 313       i386-*-gnu*)                      fmt=elf ;;
 314       i386-*-mach*)                     fmt=aout em=mach ;;
 315       i386-*-msdos*)                    fmt=aout ;;
 316       i386-*-moss*)                     fmt=elf ;;
 317       i386-*-pe)                        fmt=coff em=pe ;;
 318       i386-*-cygwin*)                   fmt=coff em=pe ;;
 319       i386-*-interix*)                  fmt=coff em=interix ;;
 320       i386-*-mingw32*)                  fmt=coff em=pe ;;
 321       i386-*-nto-qnx*)                  fmt=elf ;;
 322       i386-*-*nt*)                      fmt=coff em=pe ;;
 323       i386-*-chaos)                     fmt=elf ;;
 324
 325       i860-*-*)                         fmt=elf endian=little
 326                 AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress) ;;
 327       i960-*-bout)                      fmt=bout ;;
 328       i960-*-coff)                      fmt=coff em=ic960 ;;
 329       i960-*-rtems*)                    fmt=coff em=ic960 ;;
 330       i960-*-nindy*)                    fmt=bout ;;
 331       i960-*-vxworks5.0)                fmt=bout ;;
 332       i960-*-vxworks5.*)                fmt=coff em=ic960 ;;
 333       i960-*-vxworks*)                  fmt=bout ;;
 334       i960-*-elf*)                      fmt=elf ;;
 335
 336       ia64-*-elf*)                      fmt=elf ;;
 337       ia64-*-aix*)                      fmt=elf em=ia64aix ;;
 338       ia64-*-linux-gnu*)                fmt=elf em=linux ;;
 339       ia64-*-hpux*)                     fmt=elf em=hpux ;;
 340       ia64-*-netbsd*)                   fmt=elf em=nbsd ;;
 341
 342       ip2k-*-*)                         fmt=elf ;;
 343
 344       iq2000-*-elf)                     fmt=elf bfd_gas=yes ;;
 345
 346       m32r-*-elf*)                      fmt=elf ;;
 347       m32r-*-linux*)                    fmt=elf em=linux;;
 348
 349       m68hc11-*-* | m6811-*-*)          fmt=elf ;;
 350       m68hc12-*-* | m6812-*-*)          fmt=elf ;;
 351
 352       m68k-*-vxworks*)                  fmt=aout em=sun3 ;;
 353       m68k-ericsson-ose)                fmt=aout em=sun3 ;;
 354       m68k-*-sunos*)                    fmt=aout em=sun3 ;;
 355       m68k-motorola-sysv*)              fmt=coff em=delta ;;
 356       m68k-bull-sysv3*)                 fmt=coff em=dpx2 ;;
 357       m68k-apollo-*)                    fmt=coff em=apollo ;;
 358       m68k-*-elf*)                      fmt=elf ;;
 359       m68k-*-sysv4*)                    fmt=elf em=svr4 ;;
 360       m68k-*-sysv*)                     fmt=coff ;;
 361       m68k-*-coff | m68k-*-rtemscoff*)  fmt=coff ;;
 362       m68k-*-rtems*)                    fmt=elf ;;
 363       m68k-*-hpux*)                     fmt=hp300 em=hp300 ;;
 364       m68k-*-linux*aout*)               fmt=aout em=linux ;;
 365       m68k-*-linux-gnu*)                fmt=elf em=linux ;;
 366       m68k-*-uclinux*)                  fmt=elf ;;
 367       m68k-*-gnu*)                      fmt=elf ;;
 368       m68k-*-lynxos*)                   fmt=coff em=lynx ;;
 369       m68k-*-netbsdelf*)                fmt=elf em=nbsd ;;
 370       m68k-*-netbsd*)                   fmt=aout em=nbsd bfd_gas=yes ;;
 371       m68k-*-openbsd*)                  fmt=aout em=nbsd bfd_gas=yes ;;
 372       m68k-apple-aux*)                  fmt=coff em=aux ;;
 373       m68k-*-psos*)                     fmt=elf em=psos;;
 374
 375       m88k-motorola-sysv3*)             fmt=coff em=delt88 ;;
 376       m88k-*-coff*)                     fmt=coff ;;
 377
 378       mcore-*-elf)                      fmt=elf ;;
 379       mcore-*-pe)                       fmt=coff em=pe bfd_gas=yes ;;
 380
 381       # don't change em like *-*-bsd does
 382       mips-dec-openbsd*)                fmt=elf endian=little ;;
 383       mips-sony-bsd*)                   fmt=ecoff ;;
 384       mips-*-bsd*)
 385             AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 386       mips-*-ultrix*)                   fmt=ecoff endian=little ;;
 387       mips-*-osf*)                      fmt=ecoff endian=little ;;
 388       mips-*-ecoff*)                    fmt=ecoff ;;
 389       mips-*-pe*)                       fmt=coff endian=little em=pe ;;
 390       mips-*-irix6*)                    fmt=elf em=irix ;;
 391       mips-*-irix5*)                    fmt=elf em=irix ;;
 392       mips-*-irix*)                     fmt=ecoff em=irix ;;
 393       mips-*-lnews*)                    fmt=ecoff em=lnews ;;
 394       mips-*-riscos*)                   fmt=ecoff ;;
 395       mips*-*-linux*)                   fmt=elf em=tmips ;;
 396       mips-*-sysv4*MP* | mips-*-gnu*)   fmt=elf em=tmips ;;
 397       mips-*-sysv*)                     fmt=ecoff ;;
 398       mips-*-elf* | mips-*-rtems*)      fmt=elf ;;
 399       mips-*-netbsd*)                   fmt=elf ;;
 400       mips-*-openbsd*)                  fmt=elf ;;
 401
 402       mmix-*-*)                         fmt=elf ;;
 403       mn10200-*-*)                      fmt=elf ;;
 404       mn10300-*-*)                      fmt=elf ;;
 405       msp430-*-*)                       fmt=elf ;;
 406       openrisc-*-*)                     fmt=elf ;;
 407       or32-*-rtems*)                    fmt=elf ;;
 408       or32-*-coff)                      fmt=coff ;;
 409       or32-*-elf)                       fmt=elf ;;
 410       pj*)                              fmt=elf ;;
 411
 412       ppc-*-pe | ppc-*-cygwin*)         fmt=coff em=pe ;;
 413       ppc-*-winnt*)                     fmt=coff em=pe ;;
 414 changequote(,)dnl
 415       ppc-*-aix5.[01])                  fmt=coff em=aix5 ;;
 416 changequote([,])dnl
 417       ppc-*-aix5.*)                     fmt=coff em=aix5
 418         AC_DEFINE(AIX_WEAK_SUPPORT, 1,
 419                   [Define if using AIX 5.2 value for C_WEAKEXT.])
 420       ;;
 421       ppc-*-aix*)                       fmt=coff ;;
 422       ppc-*-beos*)                      fmt=coff ;;
 423       ppc-*-*n*bsd* | ppc-*-elf*)       fmt=elf ;;
 424       ppc-*-eabi* | ppc-*-sysv4*)       fmt=elf ;;
 425       ppc-*-linux-gnu*)                 fmt=elf em=linux
 426             case "$endian" in
 427                 big)  ;;
 428                 *)    AC_MSG_ERROR(GNU/Linux must be configured big endian) ;;
 429             esac ;;
 430       ppc-*-solaris*)                   fmt=elf
 431             if test ${this_target} = $target; then
 432                 AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 433                           [Define if default target is PowerPC Solaris.])
 434             fi
 435             if test x${endian} = xbig; then
 436                 AC_MSG_ERROR(Solaris must be configured little endian)
 437             fi ;;
 438       ppc-*-rtems*)                     fmt=elf ;;
 439       ppc-*-macos*)                     fmt=coff em=macos ;;
 440       ppc-*-nto*)                       fmt=elf ;;
 441       ppc-*-kaos*)                      fmt=elf ;;
 442       ppc-*-lynxos*)                    fmt=elf em=lynx bfd_gas=yes ;;
 443
 444       s390x-*-linux-gnu*)               fmt=elf em=linux ;;
 445       s390-*-linux-gnu*)                fmt=elf em=linux ;;
 446
 447       sh*-*-linux*)                     fmt=elf em=linux
 448             case ${cpu} in
 449                 sh*eb)  endian=big ;;
 450                 *)      endian=little ;;
 451             esac ;;
 452       sh5*-*-netbsd*)                   fmt=elf em=nbsd ;;
 453       sh64*-*-netbsd*)                  fmt=elf em=nbsd ;;
 454       sh*-*-netbsdelf*)                 fmt=elf em=nbsd ;;
 455       sh*-*-symbianelf*)                fmt=elf endian=little
 456                 AC_DEFINE(TARGET_SYMBIAN, 1, [Define if target is Symbian OS.])
 457                 ;;
 458       sh-*-elf*)                        fmt=elf ;;
 459       sh-*-coff*)                       fmt=coff ;;
 460       sh-*-nto*)                        fmt=elf ;;
 461       sh-*-pe*)                         fmt=coff em=pe bfd_gas=yes endian=little ;;
 462       sh-*-rtemscoff*)                  fmt=coff ;;
 463       sh-*-rtems*)                      fmt=elf ;;
 464       sh-*-kaos*)                       fmt=elf ;;
 465       shle*-*-kaos*)                    fmt=elf ;;
 466       sh64-*-elf*)                      fmt=elf ;;
 467
 468       ns32k-pc532-mach*)                fmt=aout em=pc532mach ;;
 469       ns32k-pc532-ux*)                  fmt=aout em=pc532mach ;;
 470       ns32k-pc532-lites*)               fmt=aout em=nbsd532 ;;
 471       ns32k-*-*n*bsd*)                  fmt=aout em=nbsd532 ;;
 472
 473       sparc-*-rtemsaout*)               fmt=aout ;;
 474       sparc-*-rtemself*)                fmt=elf ;;
 475       sparc-*-rtems*)                   fmt=elf ;;
 476       sparc-*-sunos4*)                  fmt=aout em=sun3 ;;
 477       sparc-*-aout | sparc*-*-vxworks*) fmt=aout em=sparcaout ;;
 478       sparc-*-coff)                     fmt=coff ;;
 479       sparc-*-linux*aout*)              fmt=aout em=linux ;;
 480       sparc-*-linux-gnu*)               fmt=elf em=linux ;;
 481       sparc-*-lynxos*)                  fmt=coff em=lynx ;;
 482       sparc-fujitsu-none)               fmt=aout ;;
 483       sparc-*-elf)                      fmt=elf ;;
 484       sparc-*-sysv4*)                   fmt=elf ;;
 485       sparc-*-solaris*)                 fmt=elf ;;
 486       sparc-*-netbsdelf*)               fmt=elf em=nbsd ;;
 487       sparc-*-*n*bsd*)  case ${cpu} in
 488                             sparc64)    fmt=elf em=nbsd ;;
 489                             *)          fmt=aout em=nbsd ;;
 490                         esac ;;
 491       strongarm-*-coff)                 fmt=coff ;;
 492       strongarm-*-elf)                  fmt=elf ;;
 493       strongarm-*-kaos*)                fmt=elf ;;
 494       xscale-*-coff)                    fmt=coff ;;
 495       xscale-*-elf)                     fmt=elf ;;
 496
 497       tic30-*-*aout*)                   fmt=aout bfd_gas=yes ;;
 498       tic30-*-*coff*)                   fmt=coff bfd_gas=yes ;;
 499       tic4x-*-* | c4x-*-*)              fmt=coff bfd_gas=yes ;;
 500       tic54x-*-* | c54x*-*-*)           fmt=coff bfd_gas=yes need_libm=yes;;
 501       tic80-*-*)                        fmt=coff ;;
 502
 503       v850-*-*)                         fmt=elf ;;
 504       v850e-*-*)                        fmt=elf ;;
 505       v850ea-*-*)                       fmt=elf ;;
 506
 507       vax-*-netbsdelf*)                 fmt=elf em=nbsd ;;
 508       vax-*-netbsd*)                    fmt=aout em=nbsd ;;
 509       vax-*-bsd* | vax-*-ultrix*)       fmt=aout ;;
 510       vax-*-linux-gnu*)                 fmt=elf em=linux bfd_gas=yes ;;
 511       vax-*-vms)                        fmt=vms ;;
 512
 513       w65-*-*)                          fmt=coff ;;
 514
 515       xstormy16-*-*)                    fmt=elf ;;
 516
 517       xtensa-*-*)                       fmt=elf ;;
 518
 519       z8k-*-coff | z8k-*-sim)           fmt=coff ;;
 520
 521       *-*-aout | *-*-scout)             fmt=aout ;;
 522       *-*-freebsd* | *-*-kfreebsd*-gnu) fmt=elf em=freebsd ;;
 523       *-*-nindy*)                       fmt=bout ;;
 524       *-*-bsd*)                         fmt=aout em=sun3 ;;
 525       *-*-generic)                      fmt=generic ;;
 526       *-*-xray | *-*-hms)               fmt=coff ;;
 527       *-*-sim)                          fmt=coff ;;
 528       *-*-elf | *-*-sysv4* | *-*-solaris*) fmt=elf dev=yes ;;
 529       *-*-aros*)                        fmt=elf em=linux bfd_gas=yes ;;
 530       *-*-vxworks | *-*-windiss)        fmt=elf ;;
 531       *-*-netware)                      fmt=elf em=netware ;;
 532     esac
 533
 534     if test ${this_target} = $target ; then
 535       endian_def=
 536       if test x${endian} = xbig; then
 537         endian_def=1
 538       elif test x${endian} = xlittle; then
 539         endian_def=0
 540       fi
 541       if test x${endian_def} != x; then
 542         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 543                            [Define as 1 if big endian.])
 544       fi
 545     fi
 546
 547     case ${cpu_type}-${fmt} in
 548         alpha*-* | arm-* | i386-* | ia64*-* | mips-* | ns32k-* \
 549                 | pdp11-* | ppc-* | sparc-* | strongarm-* | xscale-* \
 550                 | *-elf | *-ecoff | *-som)
 551             bfd_gas=yes ;;
 552     esac
 553
 554 # Other random stuff.
 555
 556     case ${cpu_type} in
 557       mips)
 558         # Set mips_cpu to the name of the default CPU.
 559         case ${target_cpu} in
 560           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 561             mips_cpu=from-abi
 562             ;;
 563           mipsisa32 | mipsisa32el)
 564             mips_cpu=mips32
 565             ;;
 566           mipsisa32r2 | mipsisa32r2el)
 567             mips_cpu=mips32r2
 568             ;;
 569           mipsisa64 | mipsisa64el)
 570             mips_cpu=mips64
 571             ;;
 572           mipsisa64r2 | mipsisa64r2el)
 573             mips_cpu=mips64r2
 574             ;;
 575           mipstx39 | mipstx39el)
 576             mips_cpu=r3900
 577             ;;
 578           mips64vr | mips64vrel)
 579             mips_cpu=vr4100
 580             ;;
 581           mipsisa32r2* | mipsisa64r2*)
 582 changequote(,)dnl
 583             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r2//' -e 's/el$//'`
 584 changequote([,])dnl
 585             ;;
 586           mips64* | mipsisa64* | mipsisa32*)
 587 changequote(,)dnl
 588             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 589 changequote([,])dnl
 590             ;;
 591           *)
 592             AC_ERROR($target_cpu isn't a supported MIPS CPU name)
 593             ;;
 594         esac
 595         # See whether it's appropriate to set E_MIPS_ABI_O32 for o32
 596         # binaries.  It's a GNU extension that some OSes don't understand.
 597         # The value only matters on ELF targets.
 598         case ${target} in
 599           *-*-irix*)
 600             use_e_mips_abi_o32=0
 601             ;;
 602           *)
 603             use_e_mips_abi_o32=1
 604             ;;
 605         esac
 606         # Decide whether to generate 32-bit or 64-bit code by default.
 607         # Used to resolve -march=from-abi when an embedded ABI is selected.
 608         case ${target} in
 609           mips64*-*-* | mipsisa64*-*-*)
 610             mips_default_64bit=1
 611             ;;
 612           *)
 613             mips_default_64bit=0
 614             ;;
 615         esac
 616         # Decide which ABI to target by default.
 617         case ${target} in
 618           mips64*-linux* | mips-sgi-irix6*)
 619             mips_default_abi=N32_ABI
 620             ;;
 621           mips*-linux*)
 622             mips_default_abi=O32_ABI
 623             ;;
 624           *)
 625             mips_default_abi=NO_ABI
 626             ;;
 627         esac
 628         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 629                            [Default CPU for MIPS targets. ])
 630         AC_DEFINE_UNQUOTED(USE_E_MIPS_ABI_O32, $use_e_mips_abi_o32,
 631                            [Allow use of E_MIPS_ABI_O32 on MIPS targets. ])
 632         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 633                            [Generate 64-bit code by default on MIPS targets. ])
 634         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_ABI, $mips_default_abi,
 635                            [Choose a default ABI for MIPS targets. ])
 636         ;;
 637     esac
 638
 639     # Do we need the opcodes library?
 640     case ${cpu_type} in
 641       vax | i386 | tic30)
 642         ;;
 643
 644       *)
 645         need_opcodes=yes
 646
 647         case "${enable_shared}" in
 648         yes) shared_opcodes=true ;;
 649         *opcodes*) shared_opcodes=true ;;
 650         *) shared_opcodes=false ;;
 651         esac
 652         if test "${shared_opcodes}" = "true"; then
 653           # A shared libopcodes must be linked against libbfd.
 654           need_bfd=yes
 655         fi
 656         ;;
 657     esac
 658
 659     # Any other special object files needed ?
 660     case ${cpu_type} in
 661       fr30 | ip2k | iq2000 | m32r | openrisc)
 662         using_cgen=yes
 663         ;;
 664
 665       frv)
 666         using_cgen=yes
 667         ;;
 668       m68k)
 669         case ${extra_objects} in
 670         *m68k-parse.o*) ;;
 671         *) extra_objects="$extra_objects m68k-parse.o" ;;
 672         esac
 673         ;;
 674
 675       mips)
 676         echo ${extra_objects} | grep -s "itbl-parse.o"
 677         if test $? -ne 0 ; then
 678           extra_objects="$extra_objects itbl-parse.o"
 679         fi
 680
 681         echo ${extra_objects} | grep -s "itbl-lex.o"
 682         if test $? -ne 0 ; then
 683           extra_objects="$extra_objects itbl-lex.o"
 684         fi
 685
 686         echo ${extra_objects} | grep -s "itbl-ops.o"
 687         if test $? -ne 0 ; then
 688           extra_objects="$extra_objects itbl-ops.o"
 689         fi
 690         ;;
 691
 692       i386 | s390 | sparc)
 693         if test $this_target = $target ; then
 694           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 695         fi
 696         ;;
 697
 698       xstormy16)
 699         using_cgen=yes
 700         ;;
 701
 702       xtensa)
 703         echo ${extra_objects} | grep -s "xtensa-relax.o"
 704         if test $? -ne 0 ; then
 705           extra_objects="$extra_objects xtensa-relax.o"
 706         fi
 707         ;;
 708
 709       *)
 710         ;;
 711     esac
 712
 713     if test $using_cgen = yes ; then
 714         case "x${extra_objects}" in
 715         *cgen.o*) ;;
 716         *) extra_objects="$extra_objects cgen.o" ;;
 717         esac
 718     fi
 719
 720 # See if we really can support this configuration with the emulation code.
 721
 722     if test $this_target = $target ; then
 723       primary_bfd_gas=$bfd_gas
 724       obj_format=$fmt
 725       te_file=$em
 726
 727       if test $bfd_gas = no ; then
 728         # Can't support other configurations this way.
 729         break
 730       fi
 731     elif test $bfd_gas = no ; then
 732       # Can't support this configuration.
 733       break
 734     fi
 735
 736 # From target name and format, produce a list of supported emulations.
 737
 738     case ${generic_target}-${fmt} in
 739       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 740       mips*-*-linux*-*) case "$endian" in
 741                         big)    emulation="mipsbelf mipslelf mipself" ;;
 742                         *)      emulation="mipslelf mipsbelf mipself" ;;
 743                         esac ;;
 744       mips-*-lnews*-ecoff) ;;
 745       mips-*-*-ecoff)   case "$endian" in
 746                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 747                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 748                         esac ;;
 749       mips-*-*-elf)     case "$endian" in
 750                         big)    emulation="mipsbelf mipslelf mipself" ;;
 751                         *)      emulation="mipslelf mipsbelf mipself" ;;
 752                         esac ;;
 753       mips-*-sysv4*MP*-*) emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 754       # i386-pc-pe-coff != i386-pc-coff.
 755       i386-*-pe-coff)   ;;
 756       # Uncommenting the next line will turn on support for i386 AOUT
 757       # for the default linux configuration
 758       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 759       #
 760       i386-*-aout)      emulation="i386aout" ;;
 761       i386-*-coff)      emulation="i386coff" ;;
 762       i386-*-elf)       emulation="i386elf" ;;
 763
 764       # Always all formats.  The first stated emulation becomes the default.
 765       cris-*-*aout*)    emulation="crisaout criself" ;;
 766       cris-*-*)         emulation="criself crisaout" ;;
 767     esac
 768
 769     emulations="$emulations $emulation"
 770
 771 done
 772
 773 # Turn on all targets if possible
 774 if test ${all_targets} = "yes"; then
 775   case ${target_cpu_type} in
 776   i386)
 777     case ${obj_format} in
 778     aout)
 779       emulations="$emulations i386coff i386elf"
 780       ;;
 781     coff)
 782       emulations="$emulations i386aout i386elf"
 783     ;;
 784     elf)
 785       emulations="$emulations i386aout i386coff"
 786       ;;
 787     esac
 788   ;;
 789   esac
 790 fi
 791
 792 # Assign floating point type.  Most processors with FP support
 793 # IEEE FP.  On those that don't support FP at all, usually IEEE
 794 # is emulated.
 795 case ${target_cpu} in
 796   vax | tahoe ) atof=${target_cpu} ;;
 797   pdp11)        atof=vax ;;
 798   *)            atof=ieee ;;
 799 esac
 800
 801 case "${obj_format}" in
 802   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 803 esac
 804
 805 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 806 cgen_cpu_prefix=""
 807 if test $using_cgen = yes ; then
 808   case ${target_cpu} in
 809     *) cgen_cpu_prefix=${target_cpu} ;;
 810   esac
 811   AC_SUBST(cgen_cpu_prefix)
 812   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 813 fi
 814
 815 dnl
 816 dnl Make sure the desired support files exist.
 817 dnl
 818
 819 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 820   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 821 fi
 822
 823 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 824   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 825 fi
 826
 827 case ${user_bfd_gas}-${primary_bfd_gas} in
 828   yes-yes | no-no)
 829     # We didn't override user's choice.
 830     ;;
 831   no-yes)
 832     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 833     ;;
 834   no-preferred)
 835     primary_bfd_gas=no
 836     ;;
 837   *-preferred)
 838     primary_bfd_gas=yes
 839     ;;
 840   yes-*)
 841     primary_bfd_gas=yes
 842     ;;
 843   -*)
 844     # User specified nothing.
 845     ;;
 846 esac
 847
 848 # Some COFF configurations want these random other flags set.
 849 case ${obj_format} in
 850   coff)
 851     case ${target_cpu_type} in
 852       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 853       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 854       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 855     esac
 856     ;;
 857 esac
 858
 859 # Getting this done right is going to be a bitch.  Each configuration specified
 860 # with --enable-targets=... should be checked for environment, format, cpu, and
 861 # bfd_gas setting.
 862 #
 863 # For each configuration, the necessary object file support code must be linked
 864 # in.  This might be only one, it might be up to four.  The necessary emulation
 865 # code needs to be provided, too.
 866 #
 867 # And then there's "--enable-targets=all"....
 868 #
 869 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 870
 871 formats="${obj_format}"
 872 emfiles=""
 873 EMULATIONS=""
 874 GAS_UNIQ(emulations)
 875 for em in . $emulations ; do
 876   case $em in
 877     .)  continue ;;
 878     mipsbelf | mipslelf | mipself)
 879         fmt=elf   file=mipself ;;
 880     mipsbecoff | mipslecoff | mipsecoff)
 881         fmt=ecoff file=mipsecoff ;;
 882     *coff)
 883         fmt=coff  file=$em ;;
 884     *aout)
 885         fmt=aout file=$em ;;
 886     *elf)
 887         fmt=elf file=$em ;;
 888   esac
 889   formats="$formats $fmt"
 890   emfiles="$emfiles e-$file.o"
 891   EMULATIONS="$EMULATIONS &$em,"
 892 done
 893 GAS_UNIQ(formats)
 894 GAS_UNIQ(emfiles)
 895 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 896   for fmt in $formats ; do
 897     case $fmt in
 898       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 899       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 900       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 901       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 902       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 903       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 904       hp300)    AC_DEFINE(OBJ_MAYBE_HP300, 1,   [HP300 support?])   ;;
 905       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE, 1,    [IEEE support?])    ;;
 906       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 907       vms)      AC_DEFINE(OBJ_MAYBE_VMS, 1,     [VMS support?])     ;;
 908     esac
 909     extra_objects="$extra_objects obj-$fmt.o"
 910   done
 911   obj_format=multi
 912 fi
 913 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 914   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 915   # e-mips* has more than one emulation per file, e-i386* has just one at the
 916   # moment.  If only one emulation is specified, then don't define
 917   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 918   case "${obj_format}${emfiles}" in
 919     multi* | *mips*)
 920       extra_objects="$extra_objects $emfiles"
 921       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 922   esac
 923 fi
 924 AC_SUBST(extra_objects)
 925 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 926 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 927                    [Default emulation.])
 928
 929 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 930   yes-*-coff)   need_bfd=yes ;;
 931   no-*-coff)    need_bfd=yes
 932                 AC_DEFINE(MANY_SEGMENTS, 1, [old COFF support?]) ;;
 933 esac
 934
 935 reject_dev_configs=yes
 936
 937 case ${reject_dev_configs}-${dev} in
 938   yes-yes) # Oops.
 939     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 940     ;;
 941 esac
 942
 943 AC_SUBST(target_cpu_type)
 944 AC_SUBST(obj_format)
 945 AC_SUBST(te_file)
 946 AC_SUBST(install_tooldir)
 947 AC_SUBST(atof)
 948 dnl AC_SUBST(emulation)
 949
 950 case "${primary_bfd_gas}" in
 951   yes)  AC_DEFINE(BFD_ASSEMBLER, 1, [Use BFD interface?])
 952         need_bfd=yes ;;
 953 esac
 954
 955 # do we need the opcodes library?
 956 case "${need_opcodes}" in
 957 yes)
 958   OPCODES_LIB=../opcodes/libopcodes.la
 959   ;;
 960 esac
 961
 962 case "${need_bfd}" in
 963 yes)
 964   BFDLIB=../bfd/libbfd.la
 965   BFDVER_H=../bfd/bfdver.h
 966   ALL_OBJ_DEPS="$ALL_OBJ_DEPS"' ../bfd/bfd.h $(INCDIR)/symcat.h'
 967   ;;
 968 esac
 969
 970 AC_SUBST(BFDLIB)
 971 AC_SUBST(OPCODES_LIB)
 972
 973 AC_SUBST(BFDVER_H)
 974 AC_SUBST(ALL_OBJ_DEPS)
 975
 976 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 977 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 978 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 979 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 980 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 981
 982 AC_PROG_CC
 983
 984 AC_PROG_YACC
 985 AM_PROG_LEX
 986
 987 ALL_LINGUAS="fr tr es"
 988 CY_GNU_GETTEXT
 989
 990 AM_MAINTAINER_MODE
 991 AC_EXEEXT
 992
 993 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 994
 995 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 996 # people who are not cross-compiling but are compiling cross-assemblers.
 997 AC_MSG_CHECKING(whether compiling a cross-assembler)
 998 if test "${host}" = "${target}"; then
 999   cross_gas=no
1000 else
1001   cross_gas=yes
1002   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
1003 fi
1004 AC_MSG_RESULT($cross_gas)
1005
1006 dnl ansidecl.h will deal with const
1007 dnl AC_CONST
1008 AC_FUNC_ALLOCA
1009 AC_C_INLINE
1010
1011 # VMS doesn't have unlink.
1012 AC_CHECK_FUNCS(unlink remove, break)
1013
1014 # Some systems don't have sbrk().
1015 AC_CHECK_FUNCS(sbrk)
1016
1017 # do we need the math library?
1018 case "${need_libm}" in
1019 yes)
1020   AC_CHECK_LIBM
1021   AC_SUBST(LIBM)
1022   ;;
1023 esac
1024
1025 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
1026 # enough, but on some of those systems, the assert macro relies on requoting
1027 # working properly!
1028 GAS_WORKING_ASSERT
1029
1030 # On some systems, the system header files may not declare malloc, realloc,
1031 # and free.  There are places where gas needs these functions to have been
1032 # declared -- such as when taking their addresses.
1033 gas_test_headers="
1034 #ifdef HAVE_MEMORY_H
1035 #include <memory.h>
1036 #endif
1037 #ifdef HAVE_STRING_H
1038 #include <string.h>
1039 #else
1040 #ifdef HAVE_STRINGS_H
1041 #include <strings.h>
1042 #endif
1043 #endif
1044 #ifdef HAVE_STDLIB_H
1045 #include <stdlib.h>
1046 #endif
1047 #ifdef HAVE_UNISTD_H
1048 #include <unistd.h>
1049 #endif
1050 "
1051 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
1052 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
1053 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
1054 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
1055 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
1056
1057 # Does errno.h declare errno, or do we have to add a separate declaration
1058 # for it?
1059 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
1060 #ifdef HAVE_ERRNO_H
1061 #include <errno.h>
1062 #endif
1063 ])
1064
1065 dnl This must come last.
1066
1067 dnl We used to make symlinks to files in the source directory, but now
1068 dnl we just use the right name for .c files, and create .h files in
1069 dnl the build directory which include the right .h file.  Make sure
1070 dnl the old symlinks don't exist, so that a reconfigure in an existing
1071 dnl directory behaves reasonably.
1072
1073 AC_CONFIG_FILES(Makefile doc/Makefile po/Makefile.in:po/Make-in)
1074 AC_CONFIG_COMMANDS([default],
1075 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
1076  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
1077  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
1078  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
1079  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
1080  if test "x$cgen_cpu_prefix" != x ; then
1081    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
1082  fi
1083
1084  sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile],
1085 [target_cpu_type=${target_cpu_type}
1086  cgen_cpu_prefix=${cgen_cpu_prefix}
1087  obj_format=${obj_format}
1088  te_file=${te_file}])
1089
1090 AC_OUTPUT