gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 dnl v2.5 needed for --bindir et al
   8 AC_PREREQ(2.57)
   9 AC_INIT(as.h)
  10
  11 dnl Autoconf 2.57 will find the aux dir without this.  However, unless
  12 dnl we specify this explicitly, automake-1.7 will assume that ylwrap is in
  13 dnl gas/ instead of gas/../.
  14 AC_CONFIG_AUX_DIR(..)
  15 AC_CANONICAL_SYSTEM
  16 AC_ISC_POSIX
  17
  18 changequote(,)dnl
  19 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  20 changequote([,])dnl
  21 AM_INIT_AUTOMAKE(gas, ${BFD_VERSION})
  22
  23 AC_PROG_CC
  24 AC_GNU_SOURCE
  25 AC_USE_SYSTEM_EXTENSIONS
  26
  27 AM_PROG_LIBTOOL
  28
  29 AC_ARG_ENABLE(targets,
  30 [  --enable-targets        alternative target configurations besides the primary],
  31 [case "${enableval}" in
  32   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  33             ;;
  34   no)       enable_targets= ;;
  35   *)        enable_targets=$enableval ;;
  36 esac])dnl
  37
  38 AC_ARG_ENABLE(commonbfdlib,
  39 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  40 [case "${enableval}" in
  41   yes) commonbfdlib=true ;;
  42   no)  commonbfdlib=false ;;
  43   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  44 esac])dnl
  45
  46 ac_checking=yes
  47 if grep '^RELEASE=y' ${srcdir}/../bfd/Makefile.am >/dev/null 2>/dev/null ; then
  48   ac_checking=
  49 fi
  50 AC_ARG_ENABLE(checking,
  51 [  --enable-checking       enable run-time checks],
  52 [case "${enableval}" in
  53   no|none)  ac_checking= ;;
  54   *)        ac_checking=yes ;;
  55 esac])dnl
  56 if test x$ac_checking != x ; then
  57   AC_DEFINE(ENABLE_CHECKING, 1, [Define if you want run-time sanity checks.])
  58 fi
  59
  60 using_cgen=no
  61
  62 AM_BINUTILS_WARNINGS
  63
  64 # Generate a header file
  65 AM_CONFIG_HEADER(config.h:config.in)
  66
  67 # If we are on a DOS filesystem, we must use gdb.ini rather than
  68 # .gdbinit.
  69 case "${host}" in
  70   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-windows*)
  71     GDBINIT="gdb.ini"
  72     AC_CONFIG_FILES(gdb.ini:gdbinit.in)
  73     ;;
  74   *)
  75     GDBINIT=".gdbinit"
  76     AC_CONFIG_FILES(.gdbinit:gdbinit.in)
  77     ;;
  78 esac
  79 AC_SUBST(GDBINIT)
  80
  81 #We need this for the host.  BOUT header is in host order.
  82 AC_C_BIGENDIAN
  83
  84 te_file=generic
  85
  86 # Makefile target for installing gas in $(tooldir)/bin.
  87 install_tooldir=install-exec-tooldir
  88
  89 canon_targets=""
  90 all_targets=no
  91 if test -n "$enable_targets" ; then
  92   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  93     if test $t = "all"; then
  94       all_targets=yes
  95       continue
  96     fi
  97     result=`$ac_config_sub $t 2>/dev/null`
  98     if test -n "$result" ; then
  99       canon_targets="$canon_targets $result"
 100 #    else
 101 #      # Permit "all", etc.  We don't support it yet though.
 102 #      canon_targets="$canon_targets $t"
 103     fi
 104   done
 105   GAS_UNIQ(canon_targets)
 106 fi
 107
 108 emulations=""
 109
 110 for this_target in $target $canon_targets ; do
 111
 112     targ=${this_target}
 113     . ${srcdir}/configure.tgt
 114
 115     case ${target_cpu} in
 116       crisv32)
 117         AC_DEFINE_UNQUOTED(DEFAULT_CRIS_ARCH, $arch,
 118                            [Default CRIS architecture.])
 119         ;;
 120     esac
 121
 122     if test ${this_target} = $target ; then
 123       target_cpu_type=${cpu_type}
 124     elif test ${target_cpu_type} != ${cpu_type} ; then
 125       continue
 126     fi
 127
 128     generic_target=${cpu_type}-${target_vendor}-${target_os}
 129     case ${generic_target} in
 130       i386-*-sco3.2v5*)
 131         if test ${this_target} = $target; then
 132           AC_DEFINE(SCO_ELF, 1, [Define if defaulting to ELF on SCO 5.])
 133         fi
 134         ;;
 135
 136       i386-*-msdosdjgpp* \
 137       | i386-*-go32* \
 138       | i386-go32-rtems*)
 139         AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?])
 140         ;;
 141
 142       i860-*-*)
 143         AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress)
 144         ;;
 145
 146       mips-sony-bsd*)
 147         ;;
 148       mips-*-bsd*)
 149         AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.)
 150         ;;
 151
 152       ppc-*-aix5.*)
 153         AC_DEFINE(AIX_WEAK_SUPPORT, 1,
 154                   [Define if using AIX 5.2 value for C_WEAKEXT.])
 155         ;;
 156       ppc-*-linux-*)
 157         case "$endian" in
 158           big)  ;;
 159           *)    AC_MSG_ERROR(GNU/Linux must be configured big endian) ;;
 160         esac
 161         ;;
 162       ppc-*-solaris*)
 163         if test ${this_target} = $target; then
 164           AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 165                     [Define if default target is PowerPC Solaris.])
 166         fi
 167         if test x${endian} = xbig; then
 168           AC_MSG_ERROR(Solaris must be configured little endian)
 169         fi
 170         ;;
 171
 172       sh*-*-symbianelf*)
 173         AC_DEFINE(TARGET_SYMBIAN, 1, [Define if target is Symbian OS.])
 174         ;;
 175     esac
 176
 177     if test ${this_target} = $target ; then
 178       endian_def=
 179       if test x${endian} = xbig; then
 180         endian_def=1
 181       elif test x${endian} = xlittle; then
 182         endian_def=0
 183       fi
 184       if test x${endian_def} != x; then
 185         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 186                            [Define as 1 if big endian.])
 187       fi
 188     fi
 189
 190 # Other random stuff.
 191
 192     case ${cpu_type} in
 193       mips)
 194         # Set mips_cpu to the name of the default CPU.
 195         case ${target_cpu} in
 196           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 197             mips_cpu=from-abi
 198             ;;
 199           mipsisa32 | mipsisa32el)
 200             mips_cpu=mips32
 201             ;;
 202           mipsisa32r2 | mipsisa32r2el)
 203             mips_cpu=mips32r2
 204             ;;
 205           mipsisa64 | mipsisa64el)
 206             mips_cpu=mips64
 207             ;;
 208           mipsisa64r2 | mipsisa64r2el)
 209             mips_cpu=mips64r2
 210             ;;
 211           mipstx39 | mipstx39el)
 212             mips_cpu=r3900
 213             ;;
 214           mips64vr | mips64vrel)
 215             mips_cpu=vr4100
 216             ;;
 217           mipsisa32r2* | mipsisa64r2*)
 218 changequote(,)dnl
 219             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r2//' -e 's/el$//'`
 220 changequote([,])dnl
 221             ;;
 222           mips64* | mipsisa64* | mipsisa32*)
 223 changequote(,)dnl
 224             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 225 changequote([,])dnl
 226             ;;
 227           *)
 228             AC_ERROR($target_cpu isn't a supported MIPS CPU name)
 229             ;;
 230         esac
 231         # See whether it's appropriate to set E_MIPS_ABI_O32 for o32
 232         # binaries.  It's a GNU extension that some OSes don't understand.
 233         # The value only matters on ELF targets.
 234         case ${target} in
 235           *-*-irix*)
 236             use_e_mips_abi_o32=0
 237             ;;
 238           *)
 239             use_e_mips_abi_o32=1
 240             ;;
 241         esac
 242         # Decide whether to generate 32-bit or 64-bit code by default.
 243         # Used to resolve -march=from-abi when an embedded ABI is selected.
 244         case ${target} in
 245           mips64*-*-* | mipsisa64*-*-*)
 246             mips_default_64bit=1
 247             ;;
 248           *)
 249             mips_default_64bit=0
 250             ;;
 251         esac
 252         # Decide which ABI to target by default.
 253         case ${target} in
 254           mips64*-linux* | mips-sgi-irix6*)
 255             mips_default_abi=N32_ABI
 256             ;;
 257           mips*-linux*)
 258             mips_default_abi=O32_ABI
 259             ;;
 260           mips64*-openbsd*)
 261             mips_default_abi=N64_ABI
 262             ;;
 263           *)
 264             mips_default_abi=NO_ABI
 265             ;;
 266         esac
 267         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 268                            [Default CPU for MIPS targets. ])
 269         AC_DEFINE_UNQUOTED(USE_E_MIPS_ABI_O32, $use_e_mips_abi_o32,
 270                            [Allow use of E_MIPS_ABI_O32 on MIPS targets. ])
 271         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 272                            [Generate 64-bit code by default on MIPS targets. ])
 273         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_ABI, $mips_default_abi,
 274                            [Choose a default ABI for MIPS targets. ])
 275         ;;
 276     esac
 277
 278     # Do we need the opcodes library?
 279     case ${cpu_type} in
 280       vax | tic30)
 281         ;;
 282
 283       *)
 284         need_opcodes=yes
 285
 286         case "${enable_shared}" in
 287         yes) shared_opcodes=true ;;
 288         *opcodes*) shared_opcodes=true ;;
 289         *) shared_opcodes=false ;;
 290         esac
 291         ;;
 292     esac
 293
 294     # Any other special object files needed ?
 295     case ${cpu_type} in
 296
 297       bfin)
 298         echo ${extra_objects} | grep -s "bfin-parse.o"
 299         if test $? -ne 0 ; then
 300           extra_objects="$extra_objects bfin-parse.o"
 301         fi
 302
 303         echo ${extra_objects} | grep -s "bfin-lex.o"
 304         if test $? -ne 0 ; then
 305           extra_objects="$extra_objects bfin-lex.o"
 306         fi
 307         ;;
 308
 309       fr30 | ip2k | iq2000 | m32r | openrisc)
 310         using_cgen=yes
 311         ;;
 312
 313       m32c)
 314         using_cgen=yes
 315         ;;
 316       frv)
 317         using_cgen=yes
 318         ;;
 319       m68k)
 320         case ${extra_objects} in
 321         *m68k-parse.o*) ;;
 322         *) extra_objects="$extra_objects m68k-parse.o" ;;
 323         esac
 324         ;;
 325
 326       mep)
 327         using_cgen=yes
 328         ;;
 329
 330       mips)
 331         echo ${extra_objects} | grep -s "itbl-parse.o"
 332         if test $? -ne 0 ; then
 333           extra_objects="$extra_objects itbl-parse.o"
 334         fi
 335
 336         echo ${extra_objects} | grep -s "itbl-lex.o"
 337         if test $? -ne 0 ; then
 338           extra_objects="$extra_objects itbl-lex.o"
 339         fi
 340
 341         echo ${extra_objects} | grep -s "itbl-ops.o"
 342         if test $? -ne 0 ; then
 343           extra_objects="$extra_objects itbl-ops.o"
 344         fi
 345         ;;
 346
 347       mt)
 348         using_cgen=yes
 349         ;;
 350
 351       i386 | s390 | sparc)
 352         if test $this_target = $target ; then
 353           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 354         fi
 355         ;;
 356
 357       xstormy16)
 358         using_cgen=yes
 359         ;;
 360
 361       xc16x)
 362         using_cgen=yes
 363         ;;
 364
 365       xtensa)
 366         echo ${extra_objects} | grep -s "xtensa-relax.o"
 367         if test $? -ne 0 ; then
 368           extra_objects="$extra_objects xtensa-relax.o"
 369         fi
 370         ;;
 371
 372       *)
 373         ;;
 374     esac
 375
 376     if test $using_cgen = yes ; then
 377         case "x${extra_objects}" in
 378         *cgen.o*) ;;
 379         *) extra_objects="$extra_objects cgen.o" ;;
 380         esac
 381     fi
 382
 383 # See if we really can support this configuration with the emulation code.
 384
 385     if test $this_target = $target ; then
 386       obj_format=$fmt
 387       te_file=$em
 388     fi
 389
 390 # From target name and format, produce a list of supported emulations.
 391
 392     case ${generic_target}-${fmt} in
 393       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 394       mips*-*-linux*-*) case "$endian" in
 395                         big)    emulation="mipsbelf mipslelf mipself" ;;
 396                         *)      emulation="mipslelf mipsbelf mipself" ;;
 397                         esac ;;
 398       mips-*-lnews*-ecoff) ;;
 399       mips-*-*-ecoff)   case "$endian" in
 400                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 401                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 402                         esac ;;
 403       mips-*-*-elf)     case "$endian" in
 404                         big)    emulation="mipsbelf mipslelf mipself" ;;
 405                         *)      emulation="mipslelf mipsbelf mipself" ;;
 406                         esac ;;
 407       mips-*-sysv4*MP*-*) emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 408       # i386-pc-pe-coff != i386-pc-coff.
 409       i386-*-pe-coff)   ;;
 410       # Uncommenting the next line will turn on support for i386 AOUT
 411       # for the default linux configuration
 412       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 413       #
 414       i386-*-aout)      emulation="i386aout" ;;
 415       i386-*-coff)      emulation="i386coff" ;;
 416       i386-*-elf)       emulation="i386elf" ;;
 417
 418       # Always all formats.  The first stated emulation becomes the default.
 419       cris-*-*aout*)    emulation="crisaout criself" ;;
 420       cris-*-*)         emulation="criself crisaout" ;;
 421     esac
 422
 423     emulations="$emulations $emulation"
 424
 425 done
 426
 427 # Turn on all targets if possible
 428 if test ${all_targets} = "yes"; then
 429   case ${target_cpu_type} in
 430   i386)
 431     case ${obj_format} in
 432     aout)
 433       emulations="$emulations i386coff i386elf"
 434       ;;
 435     coff)
 436       emulations="$emulations i386aout i386elf"
 437     ;;
 438     elf)
 439       emulations="$emulations i386aout i386coff"
 440       ;;
 441     esac
 442   ;;
 443   x86_64)
 444     case ${obj_format} in
 445     aout)
 446       emulations="$emulations i386coff i386elf"
 447       ;;
 448     coff)
 449       emulations="$emulations i386aout i386elf"
 450     ;;
 451     elf)
 452       emulations="$emulations i386aout i386coff"
 453       ;;
 454     esac
 455   ;;
 456   esac
 457 fi
 458
 459 # Assign floating point type.  Most processors with FP support
 460 # IEEE FP.  On those that don't support FP at all, usually IEEE
 461 # is emulated.
 462 case ${target_cpu} in
 463   vax | pdp11 ) atof=vax ;;
 464   *)            atof=ieee ;;
 465 esac
 466
 467 case "${obj_format}" in
 468   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 469 esac
 470
 471 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 472 cgen_cpu_prefix=""
 473 if test $using_cgen = yes ; then
 474   case ${target_cpu} in
 475     *) cgen_cpu_prefix=${target_cpu} ;;
 476   esac
 477   AC_SUBST(cgen_cpu_prefix)
 478   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 479 fi
 480
 481 dnl
 482 dnl Make sure the desired support files exist.
 483 dnl
 484
 485 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 486   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 487 fi
 488
 489 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 490   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 491 fi
 492
 493 # Some COFF configurations want these random other flags set.
 494 case ${obj_format} in
 495   coff)
 496     case ${target_cpu_type} in
 497       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 498       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 499       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 500       x86_64) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 501     esac
 502     ;;
 503 esac
 504
 505 # Getting this done right is going to be a bitch.  Each configuration specified
 506 # with --enable-targets=... should be checked for environment, format, cpu
 507 # setting.
 508 #
 509 # For each configuration, the necessary object file support code must be linked
 510 # in.  This might be only one, it might be up to four.  The necessary emulation
 511 # code needs to be provided, too.
 512 #
 513 # And then there's "--enable-targets=all"....
 514 #
 515 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 516
 517 formats="${obj_format}"
 518 emfiles=""
 519 EMULATIONS=""
 520 GAS_UNIQ(emulations)
 521 for em in . $emulations ; do
 522   case $em in
 523     .)  continue ;;
 524     mipsbelf | mipslelf | mipself)
 525         fmt=elf   file=mipself ;;
 526     mipsbecoff | mipslecoff | mipsecoff)
 527         fmt=ecoff file=mipsecoff ;;
 528     *coff)
 529         fmt=coff  file=$em ;;
 530     *aout)
 531         fmt=aout file=$em ;;
 532     *elf)
 533         fmt=elf file=$em ;;
 534   esac
 535   formats="$formats $fmt"
 536   emfiles="$emfiles e-$file.o"
 537   EMULATIONS="$EMULATIONS &$em,"
 538 done
 539 GAS_UNIQ(formats)
 540 GAS_UNIQ(emfiles)
 541 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 542   for fmt in $formats ; do
 543     case $fmt in
 544       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 545       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 546       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 547       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 548       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 549       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 550       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 551     esac
 552     extra_objects="$extra_objects obj-$fmt.o"
 553   done
 554   obj_format=multi
 555 fi
 556 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 557   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 558   # e-mips* has more than one emulation per file, e-i386* has just one at the
 559   # moment.  If only one emulation is specified, then don't define
 560   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 561   case "${obj_format}${emfiles}" in
 562     multi* | *mips*)
 563       extra_objects="$extra_objects $emfiles"
 564       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 565   esac
 566 fi
 567 AC_SUBST(extra_objects)
 568 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 569 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 570                    [Default emulation.])
 571
 572 reject_dev_configs=yes
 573
 574 case ${reject_dev_configs}-${dev} in
 575   yes-yes) # Oops.
 576     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 577     ;;
 578 esac
 579
 580 AC_SUBST(target_cpu_type)
 581 AC_SUBST(obj_format)
 582 AC_SUBST(te_file)
 583 AC_SUBST(install_tooldir)
 584 AC_SUBST(atof)
 585 dnl AC_SUBST(emulation)
 586
 587 # do we need the opcodes library?
 588 case "${need_opcodes}" in
 589 yes)
 590   OPCODES_LIB=../opcodes/libopcodes.la
 591   ;;
 592 esac
 593
 594 AC_SUBST(OPCODES_LIB)
 595
 596 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 597 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 598 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 599 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 600 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 601
 602 AC_PROG_YACC
 603 AM_PROG_LEX
 604
 605 ALL_LINGUAS="fr tr es rw"
 606 ZW_GNU_GETTEXT_SISTER_DIR
 607 AM_PO_SUBDIRS
 608
 609 AM_MAINTAINER_MODE
 610 AM_CONDITIONAL(GENINSRC_NEVER, false)
 611 AC_EXEEXT
 612
 613 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h limits.h)
 614
 615 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 616 # people who are not cross-compiling but are compiling cross-assemblers.
 617 AC_MSG_CHECKING(whether compiling a cross-assembler)
 618 if test "${host}" = "${target}"; then
 619   cross_gas=no
 620 else
 621   cross_gas=yes
 622   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 623 fi
 624 AC_MSG_RESULT($cross_gas)
 625
 626 dnl ansidecl.h will deal with const
 627 dnl AC_CONST
 628 AC_FUNC_ALLOCA
 629 AC_C_INLINE
 630
 631 # VMS doesn't have unlink.
 632 AC_CHECK_FUNCS(unlink remove, break)
 633
 634 # Some systems don't have sbrk().
 635 AC_CHECK_FUNCS(sbrk)
 636
 637 # do we need the math library?
 638 case "${need_libm}" in
 639 yes)
 640   AC_CHECK_LIBM
 641   AC_SUBST(LIBM)
 642   ;;
 643 esac
 644
 645 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 646 # enough, but on some of those systems, the assert macro relies on requoting
 647 # working properly!
 648 GAS_WORKING_ASSERT
 649
 650 # On some systems, the system header files may not declare malloc, realloc,
 651 # and free.  There are places where gas needs these functions to have been
 652 # declared -- such as when taking their addresses.
 653 gas_test_headers="
 654 #ifdef HAVE_MEMORY_H
 655 #include <memory.h>
 656 #endif
 657 #ifdef HAVE_STRING_H
 658 #include <string.h>
 659 #else
 660 #ifdef HAVE_STRINGS_H
 661 #include <strings.h>
 662 #endif
 663 #endif
 664 #ifdef HAVE_STDLIB_H
 665 #include <stdlib.h>
 666 #endif
 667 #ifdef HAVE_UNISTD_H
 668 #include <unistd.h>
 669 #endif
 670 "
 671
 672 # Does errno.h declare errno, or do we have to add a separate declaration
 673 # for it?
 674 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 675 #ifdef HAVE_ERRNO_H
 676 #include <errno.h>
 677 #endif
 678 ])
 679
 680 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 681 AC_CACHE_VAL(gas_cv_decl_getopt_unistd_h,
 682 [AC_TRY_COMPILE([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);],
 683 gas_cv_decl_getopt_unistd_h=yes, gas_cv_decl_getopt_unistd_h=no)])
 684 AC_MSG_RESULT($gas_cv_decl_getopt_unistd_h)
 685 if test $gas_cv_decl_getopt_unistd_h = yes; then
 686   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 687             [Is the prototype for getopt in <unistd.h> in the expected format?])
 688 fi
 689
 690 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
 691 GAS_CHECK_DECL_NEEDED(ffs, f, int (*f)(int), $gas_test_headers)
 692 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 693 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 694 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 695 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 696
 697 AC_CHECK_DECLS([vsnprintf])
 698
 699 BFD_BINARY_FOPEN
 700
 701 dnl Required for html and install-html targets.
 702 AC_SUBST(datarootdir)
 703 AC_SUBST(docdir)
 704 AC_SUBST(htmldir)
 705
 706 dnl This must come last.
 707
 708 dnl We used to make symlinks to files in the source directory, but now
 709 dnl we just use the right name for .c files, and create .h files in
 710 dnl the build directory which include the right .h file.  Make sure
 711 dnl the old symlinks don't exist, so that a reconfigure in an existing
 712 dnl directory behaves reasonably.
 713
 714 AC_CONFIG_FILES(Makefile doc/Makefile po/Makefile.in:po/Make-in)
 715 AC_CONFIG_COMMANDS([default],
 716 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
 717  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
 718  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
 719  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
 720  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
 721  if test "x$cgen_cpu_prefix" != x ; then
 722    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
 723  fi],
 724 [target_cpu_type=${target_cpu_type}
 725  cgen_cpu_prefix=${cgen_cpu_prefix}
 726  obj_format=${obj_format}
 727  te_file=${te_file}])
 728
 729 AC_OUTPUT