gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 dnl v2.5 needed for --bindir et al
   8 AC_PREREQ(2.57)
   9 AC_INIT(as.h)
  10
  11 dnl Autoconf 2.57 will find the aux dir without this.  However, unless
  12 dnl we specify this explicitly, automake-1.7 will assume that ylwrap is in
  13 dnl gas/ instead of gas/../.
  14 AC_CONFIG_AUX_DIR(..)
  15 AC_CANONICAL_SYSTEM
  16 AC_ISC_POSIX
  17
  18 changequote(,)dnl
  19 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  20 changequote([,])dnl
  21 AM_INIT_AUTOMAKE(gas, ${BFD_VERSION})
  22
  23 AM_PROG_LIBTOOL
  24
  25 user_bfd_gas=
  26 AC_ARG_ENABLE(bfd-assembler,
  27 [  --enable-bfd-assembler  use BFD back end for writing object files],
  28 [case "${enableval}" in
  29   yes) need_bfd=yes user_bfd_gas=yes ;;
  30   no)  user_bfd_gas=no ;;
  31   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  32 esac])dnl
  33 AC_ARG_ENABLE(targets,
  34 [    targets            alternative target configurations besides the primary],
  35 [case "${enableval}" in
  36   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  37             ;;
  38   no)       enable_targets= ;;
  39   *)        enable_targets=$enableval ;;
  40 esac])dnl
  41 AC_ARG_ENABLE(commonbfdlib,
  42 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  43 [case "${enableval}" in
  44   yes) commonbfdlib=true ;;
  45   no)  commonbfdlib=false ;;
  46   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  47 esac])dnl
  48
  49 using_cgen=no
  50
  51 AM_BINUTILS_WARNINGS
  52
  53 # Generate a header file
  54 AM_CONFIG_HEADER(config.h:config.in)
  55
  56 # If we are on a DOS filesystem, we must use gdb.ini rather than
  57 # .gdbinit.
  58 case "${host}" in
  59   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-windows*)
  60     GDBINIT="gdb.ini"
  61     AC_CONFIG_FILES(gdb.ini:gdbinit.in)
  62     ;;
  63   *)
  64     GDBINIT=".gdbinit"
  65     AC_CONFIG_FILES(.gdbinit:gdbinit.in)
  66     ;;
  67 esac
  68 AC_SUBST(GDBINIT)
  69
  70 #We need this for the host.  BOUT header is in host order.
  71 AC_C_BIGENDIAN
  72
  73 te_file=generic
  74
  75 # Makefile target for installing gas in $(tooldir)/bin.
  76 install_tooldir=install-exec-tooldir
  77
  78 canon_targets=""
  79 all_targets=no
  80 if test -n "$enable_targets" ; then
  81   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  82     if test $t = "all"; then
  83       all_targets=yes
  84       continue
  85     fi
  86     result=`$ac_config_sub $t 2>/dev/null`
  87     if test -n "$result" ; then
  88       canon_targets="$canon_targets $result"
  89 #    else
  90 #      # Permit "all", etc.  We don't support it yet though.
  91 #      canon_targets="$canon_targets $t"
  92     fi
  93   done
  94   GAS_UNIQ(canon_targets)
  95 fi
  96
  97 emulations=""
  98
  99 for this_target in $target $canon_targets ; do
 100
 101     targ=${this_target}
 102     . ${srcdir}/configure.tgt
 103
 104     case ${target_cpu} in
 105       crisv32)
 106         AC_DEFINE_UNQUOTED(DEFAULT_CRIS_ARCH, $arch,
 107                            [Default CRIS architecture.])
 108         ;;
 109     esac
 110
 111     if test ${this_target} = $target ; then
 112       target_cpu_type=${cpu_type}
 113     elif test ${target_cpu_type} != ${cpu_type} ; then
 114       continue
 115     fi
 116
 117     generic_target=${cpu_type}-${target_vendor}-${target_os}
 118     case ${generic_target} in
 119       i386-*-sco3.2v5*)
 120         if test ${this_target} = $target; then
 121           AC_DEFINE(SCO_ELF, 1, [Define if defaulting to ELF on SCO 5.])
 122         fi
 123         ;;
 124
 125       i386-*-msdosdjgpp* \
 126       | i386-*-go32* \
 127       | i386-go32-rtems*)
 128         AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?])
 129         ;;
 130
 131       i860-*-*)
 132         AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress)
 133         ;;
 134
 135       mips-sony-bsd*)
 136         ;;
 137       mips-*-bsd*)
 138         AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.)
 139         ;;
 140
 141       ppc-*-aix5.*)
 142         AC_DEFINE(AIX_WEAK_SUPPORT, 1,
 143                   [Define if using AIX 5.2 value for C_WEAKEXT.])
 144         ;;
 145       ppc-*-linux-*)
 146         case "$endian" in
 147           big)  ;;
 148           *)    AC_MSG_ERROR(GNU/Linux must be configured big endian) ;;
 149         esac
 150         ;;
 151       ppc-*-solaris*)
 152         if test ${this_target} = $target; then
 153           AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 154                     [Define if default target is PowerPC Solaris.])
 155         fi
 156         if test x${endian} = xbig; then
 157           AC_MSG_ERROR(Solaris must be configured little endian)
 158         fi
 159         ;;
 160
 161       sh*-*-symbianelf*)
 162         AC_DEFINE(TARGET_SYMBIAN, 1, [Define if target is Symbian OS.])
 163         ;;
 164     esac
 165
 166     if test ${this_target} = $target ; then
 167       endian_def=
 168       if test x${endian} = xbig; then
 169         endian_def=1
 170       elif test x${endian} = xlittle; then
 171         endian_def=0
 172       fi
 173       if test x${endian_def} != x; then
 174         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 175                            [Define as 1 if big endian.])
 176       fi
 177     fi
 178
 179 # Other random stuff.
 180
 181     case ${cpu_type} in
 182       mips)
 183         # Set mips_cpu to the name of the default CPU.
 184         case ${target_cpu} in
 185           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 186             mips_cpu=from-abi
 187             ;;
 188           mipsisa32 | mipsisa32el)
 189             mips_cpu=mips32
 190             ;;
 191           mipsisa32r2 | mipsisa32r2el)
 192             mips_cpu=mips32r2
 193             ;;
 194           mipsisa64 | mipsisa64el)
 195             mips_cpu=mips64
 196             ;;
 197           mipsisa64r2 | mipsisa64r2el)
 198             mips_cpu=mips64r2
 199             ;;
 200           mipstx39 | mipstx39el)
 201             mips_cpu=r3900
 202             ;;
 203           mips64vr | mips64vrel)
 204             mips_cpu=vr4100
 205             ;;
 206           mipsisa32r2* | mipsisa64r2*)
 207 changequote(,)dnl
 208             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r2//' -e 's/el$//'`
 209 changequote([,])dnl
 210             ;;
 211           mips64* | mipsisa64* | mipsisa32*)
 212 changequote(,)dnl
 213             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 214 changequote([,])dnl
 215             ;;
 216           *)
 217             AC_ERROR($target_cpu isn't a supported MIPS CPU name)
 218             ;;
 219         esac
 220         # See whether it's appropriate to set E_MIPS_ABI_O32 for o32
 221         # binaries.  It's a GNU extension that some OSes don't understand.
 222         # The value only matters on ELF targets.
 223         case ${target} in
 224           *-*-irix*)
 225             use_e_mips_abi_o32=0
 226             ;;
 227           *)
 228             use_e_mips_abi_o32=1
 229             ;;
 230         esac
 231         # Decide whether to generate 32-bit or 64-bit code by default.
 232         # Used to resolve -march=from-abi when an embedded ABI is selected.
 233         case ${target} in
 234           mips64*-*-* | mipsisa64*-*-*)
 235             mips_default_64bit=1
 236             ;;
 237           *)
 238             mips_default_64bit=0
 239             ;;
 240         esac
 241         # Decide which ABI to target by default.
 242         case ${target} in
 243           mips64*-linux* | mips-sgi-irix6*)
 244             mips_default_abi=N32_ABI
 245             ;;
 246           mips*-linux*)
 247             mips_default_abi=O32_ABI
 248             ;;
 249           *)
 250             mips_default_abi=NO_ABI
 251             ;;
 252         esac
 253         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 254                            [Default CPU for MIPS targets. ])
 255         AC_DEFINE_UNQUOTED(USE_E_MIPS_ABI_O32, $use_e_mips_abi_o32,
 256                            [Allow use of E_MIPS_ABI_O32 on MIPS targets. ])
 257         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 258                            [Generate 64-bit code by default on MIPS targets. ])
 259         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_ABI, $mips_default_abi,
 260                            [Choose a default ABI for MIPS targets. ])
 261         ;;
 262     esac
 263
 264     # Do we need the opcodes library?
 265     case ${cpu_type} in
 266       vax | i386 | tic30)
 267         ;;
 268
 269       *)
 270         need_opcodes=yes
 271
 272         case "${enable_shared}" in
 273         yes) shared_opcodes=true ;;
 274         *opcodes*) shared_opcodes=true ;;
 275         *) shared_opcodes=false ;;
 276         esac
 277         if test "${shared_opcodes}" = "true"; then
 278           # A shared libopcodes must be linked against libbfd.
 279           need_bfd=yes
 280         fi
 281         ;;
 282     esac
 283
 284     # Any other special object files needed ?
 285     case ${cpu_type} in
 286       fr30 | ip2k | iq2000 | m32r | openrisc)
 287         using_cgen=yes
 288         ;;
 289
 290       frv)
 291         using_cgen=yes
 292         ;;
 293       m68k)
 294         case ${extra_objects} in
 295         *m68k-parse.o*) ;;
 296         *) extra_objects="$extra_objects m68k-parse.o" ;;
 297         esac
 298         ;;
 299
 300       mips)
 301         echo ${extra_objects} | grep -s "itbl-parse.o"
 302         if test $? -ne 0 ; then
 303           extra_objects="$extra_objects itbl-parse.o"
 304         fi
 305
 306         echo ${extra_objects} | grep -s "itbl-lex.o"
 307         if test $? -ne 0 ; then
 308           extra_objects="$extra_objects itbl-lex.o"
 309         fi
 310
 311         echo ${extra_objects} | grep -s "itbl-ops.o"
 312         if test $? -ne 0 ; then
 313           extra_objects="$extra_objects itbl-ops.o"
 314         fi
 315         ;;
 316
 317       i386 | s390 | sparc)
 318         if test $this_target = $target ; then
 319           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 320         fi
 321         ;;
 322
 323       xstormy16)
 324         using_cgen=yes
 325         ;;
 326
 327       xtensa)
 328         echo ${extra_objects} | grep -s "xtensa-relax.o"
 329         if test $? -ne 0 ; then
 330           extra_objects="$extra_objects xtensa-relax.o"
 331         fi
 332         ;;
 333
 334       *)
 335         ;;
 336     esac
 337
 338     if test $using_cgen = yes ; then
 339         case "x${extra_objects}" in
 340         *cgen.o*) ;;
 341         *) extra_objects="$extra_objects cgen.o" ;;
 342         esac
 343     fi
 344
 345 # See if we really can support this configuration with the emulation code.
 346
 347     if test $this_target = $target ; then
 348       primary_bfd_gas=$bfd_gas
 349       obj_format=$fmt
 350       te_file=$em
 351
 352       if test $bfd_gas = no ; then
 353         # Can't support other configurations this way.
 354         break
 355       fi
 356     elif test $bfd_gas = no ; then
 357       # Can't support this configuration.
 358       break
 359     fi
 360
 361 # From target name and format, produce a list of supported emulations.
 362
 363     case ${generic_target}-${fmt} in
 364       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 365       mips*-*-linux*-*) case "$endian" in
 366                         big)    emulation="mipsbelf mipslelf mipself" ;;
 367                         *)      emulation="mipslelf mipsbelf mipself" ;;
 368                         esac ;;
 369       mips-*-lnews*-ecoff) ;;
 370       mips-*-*-ecoff)   case "$endian" in
 371                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 372                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 373                         esac ;;
 374       mips-*-*-elf)     case "$endian" in
 375                         big)    emulation="mipsbelf mipslelf mipself" ;;
 376                         *)      emulation="mipslelf mipsbelf mipself" ;;
 377                         esac ;;
 378       mips-*-sysv4*MP*-*) emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 379       # i386-pc-pe-coff != i386-pc-coff.
 380       i386-*-pe-coff)   ;;
 381       # Uncommenting the next line will turn on support for i386 AOUT
 382       # for the default linux configuration
 383       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 384       #
 385       i386-*-aout)      emulation="i386aout" ;;
 386       i386-*-coff)      emulation="i386coff" ;;
 387       i386-*-elf)       emulation="i386elf" ;;
 388
 389       # Always all formats.  The first stated emulation becomes the default.
 390       cris-*-*aout*)    emulation="crisaout criself" ;;
 391       cris-*-*)         emulation="criself crisaout" ;;
 392     esac
 393
 394     emulations="$emulations $emulation"
 395
 396 done
 397
 398 # Turn on all targets if possible
 399 if test ${all_targets} = "yes"; then
 400   case ${target_cpu_type} in
 401   i386)
 402     case ${obj_format} in
 403     aout)
 404       emulations="$emulations i386coff i386elf"
 405       ;;
 406     coff)
 407       emulations="$emulations i386aout i386elf"
 408     ;;
 409     elf)
 410       emulations="$emulations i386aout i386coff"
 411       ;;
 412     esac
 413   ;;
 414   esac
 415 fi
 416
 417 # Assign floating point type.  Most processors with FP support
 418 # IEEE FP.  On those that don't support FP at all, usually IEEE
 419 # is emulated.
 420 case ${target_cpu} in
 421   vax | tahoe ) atof=${target_cpu} ;;
 422   pdp11)        atof=vax ;;
 423   *)            atof=ieee ;;
 424 esac
 425
 426 case "${obj_format}" in
 427   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 428 esac
 429
 430 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 431 cgen_cpu_prefix=""
 432 if test $using_cgen = yes ; then
 433   case ${target_cpu} in
 434     *) cgen_cpu_prefix=${target_cpu} ;;
 435   esac
 436   AC_SUBST(cgen_cpu_prefix)
 437   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 438 fi
 439
 440 dnl
 441 dnl Make sure the desired support files exist.
 442 dnl
 443
 444 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 445   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 446 fi
 447
 448 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 449   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 450 fi
 451
 452 case ${user_bfd_gas}-${primary_bfd_gas} in
 453   yes-yes | no-no)
 454     # We didn't override user's choice.
 455     ;;
 456   no-yes)
 457     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 458     ;;
 459   no-preferred)
 460     primary_bfd_gas=no
 461     ;;
 462   *-preferred)
 463     primary_bfd_gas=yes
 464     ;;
 465   yes-*)
 466     primary_bfd_gas=yes
 467     ;;
 468   -*)
 469     # User specified nothing.
 470     ;;
 471 esac
 472
 473 # Some COFF configurations want these random other flags set.
 474 case ${obj_format} in
 475   coff)
 476     case ${target_cpu_type} in
 477       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 478       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 479       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 480     esac
 481     ;;
 482 esac
 483
 484 # Getting this done right is going to be a bitch.  Each configuration specified
 485 # with --enable-targets=... should be checked for environment, format, cpu, and
 486 # bfd_gas setting.
 487 #
 488 # For each configuration, the necessary object file support code must be linked
 489 # in.  This might be only one, it might be up to four.  The necessary emulation
 490 # code needs to be provided, too.
 491 #
 492 # And then there's "--enable-targets=all"....
 493 #
 494 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 495
 496 formats="${obj_format}"
 497 emfiles=""
 498 EMULATIONS=""
 499 GAS_UNIQ(emulations)
 500 for em in . $emulations ; do
 501   case $em in
 502     .)  continue ;;
 503     mipsbelf | mipslelf | mipself)
 504         fmt=elf   file=mipself ;;
 505     mipsbecoff | mipslecoff | mipsecoff)
 506         fmt=ecoff file=mipsecoff ;;
 507     *coff)
 508         fmt=coff  file=$em ;;
 509     *aout)
 510         fmt=aout file=$em ;;
 511     *elf)
 512         fmt=elf file=$em ;;
 513   esac
 514   formats="$formats $fmt"
 515   emfiles="$emfiles e-$file.o"
 516   EMULATIONS="$EMULATIONS &$em,"
 517 done
 518 GAS_UNIQ(formats)
 519 GAS_UNIQ(emfiles)
 520 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 521   for fmt in $formats ; do
 522     case $fmt in
 523       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 524       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 525       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 526       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 527       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 528       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 529       hp300)    AC_DEFINE(OBJ_MAYBE_HP300, 1,   [HP300 support?])   ;;
 530       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE, 1,    [IEEE support?])    ;;
 531       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 532     esac
 533     extra_objects="$extra_objects obj-$fmt.o"
 534   done
 535   obj_format=multi
 536 fi
 537 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 538   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 539   # e-mips* has more than one emulation per file, e-i386* has just one at the
 540   # moment.  If only one emulation is specified, then don't define
 541   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 542   case "${obj_format}${emfiles}" in
 543     multi* | *mips*)
 544       extra_objects="$extra_objects $emfiles"
 545       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 546   esac
 547 fi
 548 AC_SUBST(extra_objects)
 549 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 550 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 551                    [Default emulation.])
 552
 553 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 554   yes-*-coff)   need_bfd=yes ;;
 555   no-*-coff)    need_bfd=yes
 556                 AC_DEFINE(MANY_SEGMENTS, 1, [old COFF support?]) ;;
 557 esac
 558
 559 reject_dev_configs=yes
 560
 561 case ${reject_dev_configs}-${dev} in
 562   yes-yes) # Oops.
 563     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 564     ;;
 565 esac
 566
 567 AC_SUBST(target_cpu_type)
 568 AC_SUBST(obj_format)
 569 AC_SUBST(te_file)
 570 AC_SUBST(install_tooldir)
 571 AC_SUBST(atof)
 572 dnl AC_SUBST(emulation)
 573
 574 case "${primary_bfd_gas}" in
 575   yes)  AC_DEFINE(BFD_ASSEMBLER, 1, [Use BFD interface?])
 576         need_bfd=yes ;;
 577 esac
 578
 579 # do we need the opcodes library?
 580 case "${need_opcodes}" in
 581 yes)
 582   OPCODES_LIB=../opcodes/libopcodes.la
 583   ;;
 584 esac
 585
 586 case "${need_bfd}" in
 587 yes)
 588   BFDLIB=../bfd/libbfd.la
 589   BFDVER_H=../bfd/bfdver.h
 590   ALL_OBJ_DEPS="$ALL_OBJ_DEPS"' ../bfd/bfd.h $(INCDIR)/symcat.h'
 591   ;;
 592 esac
 593
 594 AC_SUBST(BFDLIB)
 595 AC_SUBST(OPCODES_LIB)
 596
 597 AC_SUBST(BFDVER_H)
 598 AC_SUBST(ALL_OBJ_DEPS)
 599
 600 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 601 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 602 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 603 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 604 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 605
 606 AC_PROG_CC
 607
 608 AC_PROG_YACC
 609 AM_PROG_LEX
 610
 611 ALL_LINGUAS="fr tr es rw"
 612 CY_GNU_GETTEXT
 613
 614 AM_MAINTAINER_MODE
 615 AC_EXEEXT
 616
 617 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 618
 619 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 620 # people who are not cross-compiling but are compiling cross-assemblers.
 621 AC_MSG_CHECKING(whether compiling a cross-assembler)
 622 if test "${host}" = "${target}"; then
 623   cross_gas=no
 624 else
 625   cross_gas=yes
 626   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 627 fi
 628 AC_MSG_RESULT($cross_gas)
 629
 630 dnl ansidecl.h will deal with const
 631 dnl AC_CONST
 632 AC_FUNC_ALLOCA
 633 AC_C_INLINE
 634
 635 # VMS doesn't have unlink.
 636 AC_CHECK_FUNCS(unlink remove, break)
 637
 638 # Some systems don't have sbrk().
 639 AC_CHECK_FUNCS(sbrk)
 640
 641 # do we need the math library?
 642 case "${need_libm}" in
 643 yes)
 644   AC_CHECK_LIBM
 645   AC_SUBST(LIBM)
 646   ;;
 647 esac
 648
 649 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 650 # enough, but on some of those systems, the assert macro relies on requoting
 651 # working properly!
 652 GAS_WORKING_ASSERT
 653
 654 # On some systems, the system header files may not declare malloc, realloc,
 655 # and free.  There are places where gas needs these functions to have been
 656 # declared -- such as when taking their addresses.
 657 gas_test_headers="
 658 #ifdef HAVE_MEMORY_H
 659 #include <memory.h>
 660 #endif
 661 #ifdef HAVE_STRING_H
 662 #include <string.h>
 663 #else
 664 #ifdef HAVE_STRINGS_H
 665 #include <strings.h>
 666 #endif
 667 #endif
 668 #ifdef HAVE_STDLIB_H
 669 #include <stdlib.h>
 670 #endif
 671 #ifdef HAVE_UNISTD_H
 672 #include <unistd.h>
 673 #endif
 674 "
 675
 676 # Does errno.h declare errno, or do we have to add a separate declaration
 677 # for it?
 678 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 679 #ifdef HAVE_ERRNO_H
 680 #include <errno.h>
 681 #endif
 682 ])
 683
 684 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 685 AC_CACHE_VAL(gas_cv_decl_getopt_unistd_h,
 686 [AC_TRY_COMPILE([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);],
 687 gas_cv_decl_getopt_unistd_h=yes, gas_cv_decl_getopt_unistd_h=no)])
 688 AC_MSG_RESULT($gas_cv_decl_getopt_unistd_h)
 689 if test $gas_cv_decl_getopt_unistd_h = yes; then
 690   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 691             [Is the prototype for getopt in <unistd.h> in the expected format?])
 692 fi
 693
 694 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
 695 GAS_CHECK_DECL_NEEDED(ffs, f, int (*f)(int), $gas_test_headers)
 696 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 697 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 698 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 699 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 700
 701 dnl This must come last.
 702
 703 dnl We used to make symlinks to files in the source directory, but now
 704 dnl we just use the right name for .c files, and create .h files in
 705 dnl the build directory which include the right .h file.  Make sure
 706 dnl the old symlinks don't exist, so that a reconfigure in an existing
 707 dnl directory behaves reasonably.
 708
 709 AC_CONFIG_FILES(Makefile doc/Makefile po/Makefile.in:po/Make-in)
 710 AC_CONFIG_COMMANDS([default],
 711 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
 712  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
 713  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
 714  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
 715  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
 716  if test "x$cgen_cpu_prefix" != x ; then
 717    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
 718  fi
 719
 720  sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile],
 721 [target_cpu_type=${target_cpu_type}
 722  cgen_cpu_prefix=${cgen_cpu_prefix}
 723  obj_format=${obj_format}
 724  te_file=${te_file}])
 725
 726 AC_OUTPUT