gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 dnl v2.5 needed for --bindir et al
   8 AC_PREREQ(2.13)
   9 AC_INIT(as.h)
  10
  11 AC_CANONICAL_SYSTEM
  12 AC_ISC_POSIX
  13
  14 changequote(,)dnl
  15 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  16 changequote([,])dnl
  17 AM_INIT_AUTOMAKE(gas, ${BFD_VERSION})
  18
  19 AM_PROG_LIBTOOL
  20
  21 user_bfd_gas=
  22 AC_ARG_ENABLE(bfd-assembler,
  23 [  --enable-bfd-assembler  use BFD back end for writing object files],
  24 [case "${enableval}" in
  25   yes) need_bfd=yes user_bfd_gas=yes ;;
  26   no)  user_bfd_gas=no ;;
  27   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  28 esac])dnl
  29 AC_ARG_ENABLE(targets,
  30 [    targets            alternative target configurations besides the primary],
  31 [case "${enableval}" in
  32   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  33             ;;
  34   no)       enable_targets= ;;
  35   *)        enable_targets=$enableval ;;
  36 esac])dnl
  37 AC_ARG_ENABLE(commonbfdlib,
  38 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  39 [case "${enableval}" in
  40   yes) commonbfdlib=true ;;
  41   no)  commonbfdlib=false ;;
  42   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  43 esac])dnl
  44
  45 using_cgen=no
  46
  47 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  48 AC_ARG_ENABLE(build-warnings,
  49 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  50 [case "${enableval}" in
  51   yes)  ;;
  52   no)   build_warnings="-w";;
  53   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  54         build_warnings="${build_warnings} ${t}";;
  55   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  56         build_warnings="${t} ${build_warnings}";;
  57   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  58 esac
  59 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  60   echo "Setting warning flags = $build_warnings" 6>&1
  61 fi])dnl
  62 WARN_CFLAGS=""
  63 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  64     WARN_CFLAGS="${build_warnings}"
  65 fi
  66 AC_SUBST(WARN_CFLAGS)
  67
  68 # Generate a header file
  69 AM_CONFIG_HEADER(config.h:config.in)
  70
  71 # If we are on a DOS filesystem, we must use gdb.ini rather than
  72 # .gdbinit.
  73 GDBINIT=".gdbinit"
  74 case "${host}" in
  75   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-windows*)
  76     GDBINIT="gdb.ini"
  77     ;;
  78 esac
  79 AC_SUBST(GDBINIT)
  80
  81 te_file=generic
  82
  83 # Makefile target for installing gas in $(tooldir)/bin.
  84 install_tooldir=install-exec-tooldir
  85
  86 canon_targets=""
  87 all_targets=no
  88 if test -n "$enable_targets" ; then
  89   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  90     if test $t = "all"; then
  91       all_targets=yes
  92       continue
  93     fi
  94     result=`$ac_config_sub $t 2>/dev/null`
  95     if test -n "$result" ; then
  96       canon_targets="$canon_targets $result"
  97 #    else
  98 #      # Permit "all", etc.  We don't support it yet though.
  99 #      canon_targets="$canon_targets $t"
 100     fi
 101   done
 102   GAS_UNIQ(canon_targets)
 103 fi
 104
 105 emulations=""
 106
 107 for this_target in $target $canon_targets ; do
 108
 109 changequote(,)dnl
 110     eval `echo $this_target | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
 111 changequote([,])dnl
 112
 113     # check for architecture variants
 114     arch=
 115     endian=
 116     case ${cpu} in
 117       alpha*)           cpu_type=alpha ;;
 118       arm*b|xscale*b|strongarm*b) cpu_type=arm endian=big ;;
 119       arm*|xscale*|strongarm*)    cpu_type=arm endian=little ;;
 120       hppa*)            cpu_type=hppa ;;
 121 changequote(,)dnl
 122       i[3-7]86)         cpu_type=i386 arch=i386;;
 123       x86_64)           cpu_type=i386 arch=x86_64;;
 124       ia64)             cpu_type=ia64 ;;
 125       ip2k)             cpu_type=ip2k endian=big ;;
 126       iq2000)           cpu_type=iq2000 endian=big ;;
 127       m6811|m6812|m68hc12) cpu_type=m68hc11 ;;
 128       m680[012346]0)    cpu_type=m68k ;;
 129 changequote([,])dnl
 130       m68008)           cpu_type=m68k ;;
 131       m683??)           cpu_type=m68k ;;
 132       m5200)            cpu_type=m68k ;;
 133       m8*)              cpu_type=m88k ;;
 134       mips*el)          cpu_type=mips endian=little ;;
 135       mips*)            cpu_type=mips endian=big ;;
 136       or32*)            cpu_type=or32 endian=big ;;
 137       pjl*)             cpu_type=pj endian=little ;;
 138       pj*)              cpu_type=pj endian=big ;;
 139       powerpc*le*)      cpu_type=ppc endian=little ;;
 140       powerpc*)         cpu_type=ppc endian=big ;;
 141       rs6000*)          cpu_type=ppc ;;
 142       s390x*)           cpu_type=s390 arch=s390x ;;
 143       s390*)            cpu_type=s390 arch=s390 ;;
 144       sh5*)             cpu_type=sh64 endian=big ;;
 145       sh5le*)           cpu_type=sh64 endian=little ;;
 146       sh64*)            cpu_type=sh64 endian=big ;;
 147       sh64le*)          cpu_type=sh64 endian=little ;;
 148       sh*le)            cpu_type=sh endian=little ;;
 149       sh*)              cpu_type=sh endian=big ;;
 150       sparclite*)       cpu_type=sparc arch=sparclite ;;
 151       sparclet*)        cpu_type=sparc arch=sparclet ;;
 152       sparc64*)         cpu_type=sparc arch=v9-64 ;;
 153       sparc86x*)        cpu_type=sparc arch=sparc86x  ;;
 154       sparc*)           cpu_type=sparc arch=sparclite ;; # ??? See tc-sparc.c.
 155       v850*)            cpu_type=v850 ;;
 156       xtensa*)          cpu_type=xtensa arch=xtensa ;;
 157       *)                cpu_type=${cpu} ;;
 158     esac
 159
 160     if test ${this_target} = $target ; then
 161       target_cpu_type=${cpu_type}
 162     elif test ${target_cpu_type} != ${cpu_type} ; then
 163       continue
 164     fi
 165
 166     generic_target=${cpu_type}-$vendor-$os
 167     dev=no
 168     bfd_gas=no
 169     em=generic
 170
 171     # assign object format
 172     case ${generic_target} in
 173       a29k-*-coff)                      fmt=coff ;;
 174       a29k-amd-udi)                     fmt=coff ;;
 175       a29k-amd-ebmon)                   fmt=coff ;;
 176       a29k-nyu-sym1)                    fmt=coff ;;
 177       a29k-*-rtems*)                    fmt=coff ;;
 178       a29k-*-vxworks*)                  fmt=coff ;;
 179
 180       alpha*-*-*vms*)                   fmt=evax ;;
 181       alpha*-*-netware*)                fmt=ecoff ;;
 182       alpha*-*-osf*)                    fmt=ecoff ;;
 183       alpha*-*-linuxecoff*)             fmt=ecoff ;;
 184       alpha*-*-linux-gnu*)              fmt=elf em=linux ;;
 185       alpha*-*-netbsd*)                 fmt=elf em=nbsd ;;
 186       alpha*-*-openbsd*)                fmt=elf em=obsd ;;
 187
 188       arc-*-elf*)                       fmt=elf ;;
 189
 190       arm-*-aout)                       fmt=aout ;;
 191       arm-*-coff | thumb-*-coff)        fmt=coff ;;
 192       arm-*-rtems | thumb-*-rtems)      fmt=elf ;;
 193       arm-*-elf | thumb-*-elf)          fmt=elf ;;
 194       arm-*-kaos*)                      fmt=elf ;;
 195       arm*-*-conix*)                    fmt=elf ;;
 196       arm-*-linux*aout*)                fmt=aout em=linux ;;
 197       arm*-*-linux-gnu*)                fmt=elf  em=linux ;;
 198       arm*-*-uclinux*)                  fmt=elf  em=linux ;;
 199       arm-*-netbsdelf*)                 fmt=elf  em=nbsd ;;
 200       arm-*-*n*bsd*)                    fmt=aout em=nbsd ;;
 201       arm-**-nto*)                      fmt=elf ;;
 202       arm-*-oabi | thumb-*-oabi)        fmt=elf ;;
 203       arm-epoc-pe | thumb-epoc-pe)      fmt=coff em=epoc-pe ;;
 204       arm-*-wince)                      fmt=coff em=wince-pe ;;
 205       arm-*-pe | thumb-*-pe)            fmt=coff em=pe ;;
 206       arm-*-riscix*)                    fmt=aout em=riscix ;;
 207       arm-*-vxworks)                    fmt=coff ;;
 208
 209       avr-*-*)                          fmt=elf ;;
 210
 211       cris-*-*)                         fmt=multi bfd_gas=yes ;;
 212
 213       d10v-*-*)                         fmt=elf ;;
 214       d30v-*-*)                         fmt=elf ;;
 215       dlx-*-*)                          fmt=elf ;;
 216
 217       fr30-*-*)                         fmt=elf ;;
 218       frv-*-*)                          fmt=elf ;;
 219
 220       hppa-*-linux*)    case ${cpu} in
 221                             hppa*64*)   fmt=elf em=hppalinux64;;
 222                             hppa*)      fmt=elf em=linux;;
 223                         esac ;;
 224       hppa-*-*elf*)                     fmt=elf em=hppa ;;
 225       hppa-*-lites*)                    fmt=elf em=hppa ;;
 226       hppa-*-netbsd*)                   fmt=elf em=nbsd ;;
 227       hppa-*-openbsd*)                  fmt=elf em=hppa ;;
 228       hppa-*-osf*)                      fmt=som em=hppa ;;
 229       hppa-*-rtems*)                    fmt=elf em=hppa ;;
 230       hppa-*-hpux11*)   case ${cpu} in
 231                             hppa*64*)   fmt=elf em=hppa64 ;;
 232                             hppa*)      fmt=som em=hppa ;;
 233                         esac ;;
 234       hppa-*-hpux*)                     fmt=som em=hppa ;;
 235       hppa-*-mpeix*)                    fmt=som em=hppa ;;
 236       hppa-*-bsd*)                      fmt=som em=hppa ;;
 237       hppa-*-hiux*)                     fmt=som em=hppa ;;
 238
 239       h8300-*-rtems*)                   fmt=coff ;;
 240       h8300-*-coff)                     fmt=coff ;;
 241       h8300-*-elf)                      fmt=elf ;;
 242       h8500-*-rtems*)                   fmt=coff ;;
 243       h8500-*-coff)                     fmt=coff ;;
 244
 245       i370-*-elf* | i370-*-linux*)      fmt=elf ;;
 246       i386-ibm-aix*)                    fmt=coff em=i386aix ;;
 247       i386-sequent-bsd*)                fmt=aout em=dynix ;;
 248       i386-*-beospe*)                   fmt=coff em=pe ;;
 249       i386-*-beos*)                     fmt=elf ;;
 250       i386-*-coff)                      fmt=coff ;;
 251       i386-*-elf)                       fmt=elf ;;
 252       i386-*-kaos*)                     fmt=elf ;;
 253       i386-*-bsd*)                      fmt=aout em=386bsd ;;
 254       i386-*-netbsd0.8)                 fmt=aout em=386bsd ;;
 255       i386-*-netbsdpe*)                 fmt=coff em=pe ;;
 256       i386-*-netbsd*-gnu*)              fmt=elf em=nbsd ;;
 257       i386-*-netbsdelf*)                fmt=elf em=nbsd ;;
 258       i386-*-*n*bsd*)   case ${cpu} in
 259                             x86_64)     fmt=elf em=nbsd ;;
 260                             *)          fmt=aout em=nbsd ;;
 261                         esac ;;
 262       i386-*-linux*aout*)               fmt=aout em=linux ;;
 263       i386-*-linux*oldld)               fmt=aout em=linux ;;
 264       i386-*-linux*coff*)               fmt=coff em=linux ;;
 265       i386-*-linux-gnu*)                fmt=elf em=linux ;;
 266       x86_64-*-linux-gnu*)              fmt=elf em=linux ;;
 267       i386-*-lynxos*)                   fmt=coff em=lynx ;;
 268 changequote(,)dnl
 269       i386-*-sysv[45]*)                 fmt=elf ;;
 270       i386-*-solaris*)                  fmt=elf ;;
 271       i386-*-freebsdaout*)              fmt=aout em=386bsd ;;
 272       i386-*-freebsd[12].*)             fmt=aout em=386bsd ;;
 273       i386-*-freebsd[12])               fmt=aout em=386bsd ;;
 274 changequote([,])dnl
 275       i386-*-freebsd*)                  fmt=elf em=freebsd ;;
 276       i386-*-sysv*)                     fmt=coff ;;
 277       i386-*-sco3.2v5*coff)             fmt=coff ;;
 278       i386-*-isc*)                      fmt=coff ;;
 279       i386-*-sco3.2v5*)                 fmt=elf
 280           if test ${this_target} = $target; then
 281             AC_DEFINE(SCO_ELF, 1, [Define if defaulting to ELF on SCO 5.])
 282           fi ;;
 283       i386-*-sco3.2*)                   fmt=coff ;;
 284       i386-*-vsta)                      fmt=aout ;;
 285       i386-*-msdosdjgpp* \
 286       | i386-*-go32* \
 287       | i386-go32-rtems*)               fmt=coff em=go32
 288             AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?]) ;;
 289       i386-*-rtemself*)                 fmt=elf ;;
 290       i386-*-rtemscoff*)                fmt=coff ;;
 291       i386-*-rtems*)                    fmt=elf ;;
 292       i386-*-gnu*)                      fmt=elf ;;
 293       i386-*-mach*)                     fmt=aout em=mach ;;
 294       i386-*-msdos*)                    fmt=aout ;;
 295       i386-*-moss*)                     fmt=elf ;;
 296       i386-*-pe)                        fmt=coff em=pe ;;
 297       i386-*-cygwin*)                   fmt=coff em=pe ;;
 298       i386-*-interix*)                  fmt=coff em=interix ;;
 299       i386-*-mingw32*)                  fmt=coff em=pe ;;
 300       i386-*-nto-qnx*)                  fmt=elf ;;
 301       i386-*-*nt*)                      fmt=coff em=pe ;;
 302       i386-*-vxworks*)                  fmt=aout ;;
 303       i386-*-chaos)                     fmt=elf ;;
 304
 305       i860-*-*)                         fmt=elf endian=little
 306                 AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress) ;;
 307       i960-*-bout)                      fmt=bout ;;
 308       i960-*-coff)                      fmt=coff em=ic960 ;;
 309       i960-*-rtems*)                    fmt=coff em=ic960 ;;
 310       i960-*-nindy*)                    fmt=bout ;;
 311       i960-*-vxworks5.0)                fmt=bout ;;
 312       i960-*-vxworks5.*)                fmt=coff em=ic960 ;;
 313       i960-*-vxworks*)                  fmt=bout ;;
 314       i960-*-elf*)                      fmt=elf ;;
 315
 316       ia64-*-elf*)                      fmt=elf ;;
 317       ia64-*-aix*)                      fmt=elf em=ia64aix ;;
 318       ia64-*-linux-gnu*)                fmt=elf em=linux ;;
 319       ia64-*-hpux*)                     fmt=elf em=hpux ;;
 320       ia64-*-netbsd*)                   fmt=elf em=nbsd ;;
 321
 322       ip2k-*-*)                         fmt=elf ;;
 323
 324       iq2000-*-elf)                     fmt=elf bfd_gas=yes ;;
 325
 326       m32r-*-*)                         fmt=elf ;;
 327
 328       m68hc11-*-* | m6811-*-*)          fmt=elf ;;
 329       m68hc12-*-* | m6812-*-*)          fmt=elf ;;
 330
 331       m68k-*-vxworks*)                  fmt=aout em=sun3 ;;
 332       m68k-ericsson-ose)                fmt=aout em=sun3 ;;
 333       m68k-*-sunos*)                    fmt=aout em=sun3 ;;
 334       m68k-motorola-sysv*)              fmt=coff em=delta ;;
 335       m68k-bull-sysv3*)                 fmt=coff em=dpx2 ;;
 336       m68k-apollo-*)                    fmt=coff em=apollo ;;
 337       m68k-*-elf*)                      fmt=elf ;;
 338       m68k-*-sysv4*)                    fmt=elf em=svr4 ;;
 339       m68k-*-sysv*)                     fmt=coff ;;
 340       m68k-*-coff | m68k-*-rtemscoff*)  fmt=coff ;;
 341       m68k-*-rtems*)                    fmt=elf ;;
 342       m68k-*-hpux*)                     fmt=hp300 em=hp300 ;;
 343       m68k-*-linux*aout*)               fmt=aout em=linux ;;
 344       m68k-*-linux-gnu*)                fmt=elf em=linux ;;
 345       m68k-*-gnu*)                      fmt=elf ;;
 346       m68k-*-lynxos*)                   fmt=coff em=lynx ;;
 347       m68k-*-netbsdelf*)                fmt=elf em=nbsd ;;
 348       m68k-*-netbsd*)                   fmt=aout em=nbsd bfd_gas=yes ;;
 349       m68k-*-openbsd*)                  fmt=aout em=nbsd bfd_gas=yes ;;
 350       m68k-apple-aux*)                  fmt=coff em=aux ;;
 351       m68k-*-psos*)                     fmt=elf em=psos;;
 352
 353       m88k-motorola-sysv3*)             fmt=coff em=delt88 ;;
 354       m88k-*-coff*)                     fmt=coff ;;
 355
 356       mcore-*-elf)                      fmt=elf ;;
 357       mcore-*-pe)                       fmt=coff em=pe bfd_gas=yes ;;
 358
 359       # don't change em like *-*-bsd does
 360       mips-dec-openbsd*)                fmt=elf endian=little ;;
 361       mips-dec-bsd*)                    fmt=aout endian=little ;;
 362       mips-sony-bsd*)                   fmt=ecoff ;;
 363       mips-*-bsd*)
 364             AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 365       mips-*-ultrix*)                   fmt=ecoff endian=little ;;
 366       mips-*-osf*)                      fmt=ecoff endian=little ;;
 367       mips-*-ecoff*)                    fmt=ecoff ;;
 368       mips-*-pe*)                       fmt=coff endian=little em=pe ;;
 369       mips-*-irix6*)                    fmt=elf em=irix ;;
 370       mips-*-irix5*)                    fmt=elf em=irix ;;
 371       mips-*-irix*)                     fmt=ecoff em=irix ;;
 372       mips-*-lnews*)                    fmt=ecoff em=lnews ;;
 373       mips-*-riscos*)                   fmt=ecoff ;;
 374       mips*-*-linux*)                   fmt=elf em=tmips ;;
 375       mips-*-sysv4*MP* | mips-*-gnu*)   fmt=elf em=tmips ;;
 376       mips-*-sysv*)                     fmt=ecoff ;;
 377       mips-*-elf* | mips-*-rtems*)      fmt=elf ;;
 378       mips-*-netbsd*)                   fmt=elf ;;
 379       mips-*-openbsd*)                  fmt=elf ;;
 380       mips-*-vxworks*)                  fmt=elf ;;
 381
 382       mmix-*-*)                         fmt=elf ;;
 383       mn10200-*-*)                      fmt=elf ;;
 384       mn10300-*-*)                      fmt=elf ;;
 385       msp430-*-*)                       fmt=elf ;;
 386       openrisc-*-*)                     fmt=elf ;;
 387       or32-*-rtems*)                    fmt=coff ;;
 388       or32-*-coff)                      fmt=coff ;;
 389       or32-*-elf)                       fmt=elf ;;
 390       pj*)                              fmt=elf ;;
 391
 392       ppc-*-pe | ppc-*-cygwin*)         fmt=coff em=pe ;;
 393       ppc-*-winnt*)                     fmt=coff em=pe ;;
 394       ppc-*-aix5*)                      fmt=coff em=aix5 ;;
 395       ppc-*-aix*)                       fmt=coff ;;
 396       ppc-*-beos*)                      fmt=coff ;;
 397       ppc-*-*n*bsd* | ppc-*-elf*)       fmt=elf ;;
 398       ppc-*-eabi* | ppc-*-sysv4*)       fmt=elf ;;
 399       ppc-*-linux-gnu*)                 fmt=elf
 400             case "$endian" in
 401                 big)  ;;
 402                 *)    AC_MSG_ERROR(GNU/Linux must be configured big endian) ;;
 403             esac ;;
 404       ppc-*-solaris*)                   fmt=elf
 405             if test ${this_target} = $target; then
 406                 AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 407                           [Define if default target is PowerPC Solaris.])
 408             fi
 409             if test x${endian} = xbig; then
 410                 AC_MSG_ERROR(Solaris must be configured little endian)
 411             fi ;;
 412       ppc-*-rtems*)                     fmt=elf ;;
 413       ppc-*-macos* | ppc-*-mpw*)        fmt=coff em=macos ;;
 414       ppc-*-netware*)                   fmt=elf em=ppcnw ;;
 415       ppc-**-nto*)                      fmt=elf ;;
 416       ppc-*-vxworks*)                   fmt=elf ;;
 417       ppc-*-windiss*)                   fmt=elf ;;
 418       ppc-*-kaos*)                      fmt=elf ;;
 419
 420       s390x-*-linux-gnu*)               fmt=elf em=linux ;;
 421       s390-*-linux-gnu*)                fmt=elf em=linux ;;
 422
 423       sh*-*-linux*)                     fmt=elf em=linux
 424             case ${cpu} in
 425                 sh*eb)  endian=big ;;
 426                 *)      endian=little ;;
 427             esac ;;
 428       sh5*-*-netbsd*)                   fmt=elf em=nbsd ;;
 429       sh64*-*-netbsd*)                  fmt=elf em=nbsd ;;
 430       sh*-*-netbsdelf*)                 fmt=elf em=nbsd ;;
 431       sh-*-elf*)                        fmt=elf ;;
 432       sh-*-coff*)                       fmt=coff ;;
 433       sh-*-nto*)                        fmt=elf ;;
 434       sh-*-pe*)                         fmt=coff em=pe bfd_gas=yes endian=little ;;
 435       sh-*-rtemself*)                   fmt=elf ;;
 436       sh-*-rtems*)                      fmt=coff ;;
 437       sh-*-kaos*)                       fmt=elf ;;
 438       shle*-*-kaos*)                    fmt=elf ;;
 439       sh64-*-elf*)                      fmt=elf ;;
 440
 441       ns32k-pc532-mach*)                fmt=aout em=pc532mach ;;
 442       ns32k-pc532-ux*)                  fmt=aout em=pc532mach ;;
 443       ns32k-pc532-lites*)               fmt=aout em=nbsd532 ;;
 444       ns32k-*-*n*bsd*)                  fmt=aout em=nbsd532 ;;
 445
 446       sparc-*-rtemsaout*)               fmt=aout ;;
 447       sparc-*-rtemself*)                fmt=elf ;;
 448       sparc-*-rtems*)                   fmt=elf ;;
 449       sparc-*-sunos4*)                  fmt=aout em=sun3 ;;
 450       sparc-*-aout | sparc*-*-vxworks*) fmt=aout em=sparcaout ;;
 451       sparc-*-coff)                     fmt=coff ;;
 452       sparc-*-linux*aout*)              fmt=aout em=linux ;;
 453       sparc-*-linux-gnu*)               fmt=elf em=linux ;;
 454       sparc-*-lynxos*)                  fmt=coff em=lynx ;;
 455       sparc-fujitsu-none)               fmt=aout ;;
 456       sparc-*-elf)                      fmt=elf ;;
 457       sparc-*-sysv4*)                   fmt=elf ;;
 458       sparc-*-solaris*)                 fmt=elf ;;
 459       sparc-*-netbsdelf*)               fmt=elf em=nbsd ;;
 460       sparc-*-*n*bsd*)  case ${cpu} in
 461                             sparc64)    fmt=elf em=nbsd ;;
 462                             *)          fmt=aout em=nbsd ;;
 463                         esac ;;
 464       strongarm-*-coff)                 fmt=coff ;;
 465       strongarm-*-elf)                  fmt=elf ;;
 466       strongarm-*-kaos*)                fmt=elf ;;
 467       xscale-*-coff)                    fmt=coff ;;
 468       xscale-*-elf)                     fmt=elf ;;
 469
 470       tic30-*-*aout*)                   fmt=aout bfd_gas=yes ;;
 471       tic30-*-*coff*)                   fmt=coff bfd_gas=yes ;;
 472       tic4x-*-* | c4x-*-*)              fmt=coff bfd_gas=yes ;;
 473       tic54x-*-* | c54x*-*-*)           fmt=coff bfd_gas=yes need_libm=yes;;
 474       tic80-*-*)                        fmt=coff ;;
 475
 476       v850-*-*)                         fmt=elf ;;
 477       v850e-*-*)                        fmt=elf ;;
 478       v850ea-*-*)                       fmt=elf ;;
 479
 480       vax-*-netbsdelf*)                 fmt=elf em=nbsd ;;
 481       vax-*-netbsd*)                    fmt=aout em=nbsd ;;
 482       vax-*-bsd* | vax-*-ultrix*)       fmt=aout ;;
 483       vax-*-vms)                        fmt=vms ;;
 484
 485       w65-*-*)                          fmt=coff ;;
 486
 487       xstormy16-*-*)                    fmt=elf ;;
 488
 489       xtensa-*-*)                       fmt=elf ;;
 490
 491       z8k-*-coff | z8k-*-sim)           fmt=coff ;;
 492
 493       *-*-aout | *-*-scout)             fmt=aout ;;
 494       *-*-freebsd*)                     fmt=elf em=freebsd ;;
 495       *-*-nindy*)                       fmt=bout ;;
 496       *-*-bsd*)                         fmt=aout em=sun3 ;;
 497       *-*-generic)                      fmt=generic ;;
 498       *-*-xray | *-*-hms)               fmt=coff ;;
 499       *-*-sim)                          fmt=coff ;;
 500       *-*-elf | *-*-sysv4* | *-*-solaris*) fmt=elf dev=yes ;;
 501       *-*-aros*)                                fmt=elf em=linux bfd_gas=yes ;;
 502       *-*-vxworks)                      fmt=aout ;;
 503       *-*-netware)                      fmt=elf ;;
 504     esac
 505
 506     if test ${this_target} = $target ; then
 507       endian_def=
 508       if test x${endian} = xbig; then
 509         endian_def=1
 510       elif test x${endian} = xlittle; then
 511         endian_def=0
 512       fi
 513       if test x${endian_def} != x; then
 514         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 515                            [Define as 1 if big endian.])
 516       fi
 517     fi
 518
 519     case ${cpu_type}-${fmt} in
 520         alpha*-* | arm-* | i386-* | ia64*-* | mips-* | ns32k-* \
 521                 | pdp11-* | ppc-* | sparc-* | strongarm-* | xscale-* \
 522                 | *-elf | *-ecoff | *-som)
 523             bfd_gas=yes ;;
 524     esac
 525
 526 # Other random stuff.
 527
 528     case ${cpu_type} in
 529       mips)
 530         # Set mips_cpu to the name of the default CPU.
 531         case ${target_cpu} in
 532           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 533             mips_cpu=from-abi
 534             ;;
 535           mipsisa32 | mipsisa32el)
 536             mips_cpu=mips32
 537             ;;
 538           mipsisa32r2 | mipsisa32r2el)
 539             mips_cpu=mips32r2
 540             ;;
 541           mipsisa64 | mipsisa64el)
 542             mips_cpu=mips64
 543             ;;
 544           mipstx39 | mipstx39el)
 545             mips_cpu=r3900
 546             ;;
 547           mips64vr | mips64vrel)
 548             mips_cpu=vr4100
 549             ;;
 550           mipsisa32r2*)
 551 changequote(,)dnl
 552             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r2//' -e 's/el$//'`
 553 changequote([,])dnl
 554             ;;
 555           mips64* | mipsisa64* | mipsisa32*)
 556 changequote(,)dnl
 557             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 558 changequote([,])dnl
 559             ;;
 560           *)
 561             AC_ERROR($target_cpu isn't a supported MIPS CPU name)
 562             ;;
 563         esac
 564         # See whether it's appropriate to set E_MIPS_ABI_O32 for o32
 565         # binaries.  It's a GNU extension that some OSes don't understand.
 566         # The value only matters on ELF targets.
 567         case ${target} in
 568           *-*-irix*)
 569             use_e_mips_abi_o32=0
 570             ;;
 571           *)
 572             use_e_mips_abi_o32=1
 573             ;;
 574         esac
 575         # Decide whether to generate 32-bit or 64-bit code by default.
 576         # Used to resolve -march=from-abi when an embedded ABI is selected.
 577         case ${target} in
 578           mips64*-*-* | mipsisa64*-*-*)
 579             mips_default_64bit=1
 580             ;;
 581           *)
 582             mips_default_64bit=0
 583             ;;
 584         esac
 585         # Decide which ABI to target by default.
 586         case ${target} in
 587           mips64*-linux* | mips-sgi-irix6*)
 588             mips_default_abi=N32_ABI
 589             ;;
 590           mips*-linux*)
 591             mips_default_abi=O32_ABI
 592             ;;
 593           *)
 594             mips_default_abi=NO_ABI
 595             ;;
 596         esac
 597         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 598                            [Default CPU for MIPS targets. ])
 599         AC_DEFINE_UNQUOTED(USE_E_MIPS_ABI_O32, $use_e_mips_abi_o32,
 600                            [Allow use of E_MIPS_ABI_O32 on MIPS targets. ])
 601         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 602                            [Generate 64-bit code by default on MIPS targets. ])
 603         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_ABI, $mips_default_abi,
 604                            [Choose a default ABI for MIPS targets. ])
 605         ;;
 606     esac
 607
 608     # Do we need the opcodes library?
 609     case ${cpu_type} in
 610       vax | i386 | tic30)
 611         ;;
 612
 613       *)
 614         need_opcodes=yes
 615
 616         case "${enable_shared}" in
 617         yes) shared_opcodes=true ;;
 618         *opcodes*) shared_opcodes=true ;;
 619         *) shared_opcodes=false ;;
 620         esac
 621         if test "${shared_opcodes}" = "true"; then
 622           # A shared libopcodes must be linked against libbfd.
 623           need_bfd=yes
 624         fi
 625         ;;
 626     esac
 627
 628     # Any other special object files needed ?
 629     case ${cpu_type} in
 630       fr30 | ip2k | iq2000 | m32r | openrisc)
 631         using_cgen=yes
 632         ;;
 633
 634       frv)
 635         using_cgen=yes
 636         ;;
 637       m68k)
 638         case ${extra_objects} in
 639         *m68k-parse.o*) ;;
 640         *) extra_objects="$extra_objects m68k-parse.o" ;;
 641         esac
 642         ;;
 643
 644       mips)
 645         echo ${extra_objects} | grep -s "itbl-parse.o"
 646         if test $? -ne 0 ; then
 647           extra_objects="$extra_objects itbl-parse.o"
 648         fi
 649
 650         echo ${extra_objects} | grep -s "itbl-lex.o"
 651         if test $? -ne 0 ; then
 652           extra_objects="$extra_objects itbl-lex.o"
 653         fi
 654
 655         echo ${extra_objects} | grep -s "itbl-ops.o"
 656         if test $? -ne 0 ; then
 657           extra_objects="$extra_objects itbl-ops.o"
 658         fi
 659         ;;
 660
 661       i386 | s390 | sparc)
 662         if test $this_target = $target ; then
 663           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 664         fi
 665         ;;
 666
 667       xstormy16)
 668         using_cgen=yes
 669         ;;
 670
 671       xtensa)
 672         echo ${extra_objects} | grep -s "xtensa-relax.o"
 673         if test $? -ne 0 ; then
 674           extra_objects="$extra_objects xtensa-relax.o"
 675         fi
 676         ;;
 677
 678       *)
 679         ;;
 680     esac
 681
 682     if test $using_cgen = yes ; then
 683         case "x${extra_objects}" in
 684         *cgen.o*) ;;
 685         *) extra_objects="$extra_objects cgen.o" ;;
 686         esac
 687     fi
 688
 689 # See if we really can support this configuration with the emulation code.
 690
 691     if test $this_target = $target ; then
 692       primary_bfd_gas=$bfd_gas
 693       obj_format=$fmt
 694       te_file=$em
 695
 696       if test $bfd_gas = no ; then
 697         # Can't support other configurations this way.
 698         break
 699       fi
 700     elif test $bfd_gas = no ; then
 701       # Can't support this configuration.
 702       break
 703     fi
 704
 705 # From target name and format, produce a list of supported emulations.
 706
 707     case ${generic_target}-${fmt} in
 708       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 709       mips*-*-linux*-*) case "$endian" in
 710                         big)    emulation="mipsbelf mipslelf mipself" ;;
 711                         *)      emulation="mipslelf mipsbelf mipself" ;;
 712                         esac ;;
 713       mips-*-lnews*-ecoff) ;;
 714       mips-*-*-ecoff)   case "$endian" in
 715                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 716                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 717                         esac ;;
 718       mips-*-*-elf)     case "$endian" in
 719                         big)    emulation="mipsbelf mipslelf mipself" ;;
 720                         *)      emulation="mipslelf mipsbelf mipself" ;;
 721                         esac ;;
 722       mips-*-sysv4*MP*-*) emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 723       # i386-pc-pe-coff != i386-pc-coff.
 724       i386-*-pe-coff)   ;;
 725       # Uncommenting the next line will turn on support for i386 AOUT
 726       # for the default linux configuration
 727       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 728       #
 729       i386-*-aout)      emulation="i386aout" ;;
 730       i386-*-coff)      emulation="i386coff" ;;
 731       i386-*-elf)       emulation="i386elf" ;;
 732
 733       # Always all formats.  The first stated emulation becomes the default.
 734       cris-*-*aout*)    emulation="crisaout criself" ;;
 735       cris-*-*)         emulation="criself crisaout" ;;
 736     esac
 737
 738     emulations="$emulations $emulation"
 739
 740 done
 741
 742 # Turn on all targets if possible
 743 if test ${all_targets} = "yes"; then
 744   case ${target_cpu_type} in
 745   i386)
 746     case ${obj_format} in
 747     aout)
 748       emulations="$emulations i386coff i386elf"
 749       ;;
 750     coff)
 751       emulations="$emulations i386aout i386elf"
 752     ;;
 753     elf)
 754       emulations="$emulations i386aout i386coff"
 755       ;;
 756     esac
 757   ;;
 758   esac
 759 fi
 760
 761 # Assign floating point type.  Most processors with FP support
 762 # IEEE FP.  On those that don't support FP at all, usually IEEE
 763 # is emulated.
 764 case ${target_cpu} in
 765   vax | tahoe ) atof=${target_cpu} ;;
 766   pdp11)        atof=vax ;;
 767   *)            atof=ieee ;;
 768 esac
 769
 770 case "${obj_format}" in
 771   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 772 esac
 773
 774 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 775 cgen_cpu_prefix=""
 776 if test $using_cgen = yes ; then
 777   case ${target_cpu} in
 778     *) cgen_cpu_prefix=${target_cpu} ;;
 779   esac
 780   AC_SUBST(cgen_cpu_prefix)
 781   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 782 fi
 783
 784 dnl
 785 dnl Make sure the desired support files exist.
 786 dnl
 787
 788 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 789   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 790 fi
 791
 792 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 793   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 794 fi
 795
 796 case ${user_bfd_gas}-${primary_bfd_gas} in
 797   yes-yes | no-no)
 798     # We didn't override user's choice.
 799     ;;
 800   no-yes)
 801     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 802     ;;
 803   no-preferred)
 804     primary_bfd_gas=no
 805     ;;
 806   *-preferred)
 807     primary_bfd_gas=yes
 808     ;;
 809   yes-*)
 810     primary_bfd_gas=yes
 811     ;;
 812   -*)
 813     # User specified nothing.
 814     ;;
 815 esac
 816
 817 # Some COFF configurations want these random other flags set.
 818 case ${obj_format} in
 819   coff)
 820     case ${target_cpu_type} in
 821       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 822       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 823       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 824     esac
 825     ;;
 826 esac
 827
 828 # Getting this done right is going to be a bitch.  Each configuration specified
 829 # with --enable-targets=... should be checked for environment, format, cpu, and
 830 # bfd_gas setting.
 831 #
 832 # For each configuration, the necessary object file support code must be linked
 833 # in.  This might be only one, it might be up to four.  The necessary emulation
 834 # code needs to be provided, too.
 835 #
 836 # And then there's "--enable-targets=all"....
 837 #
 838 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 839
 840 formats="${obj_format}"
 841 emfiles=""
 842 EMULATIONS=""
 843 GAS_UNIQ(emulations)
 844 for em in . $emulations ; do
 845   case $em in
 846     .)  continue ;;
 847     mipsbelf | mipslelf | mipself)
 848         fmt=elf   file=mipself ;;
 849     mipsbecoff | mipslecoff | mipsecoff)
 850         fmt=ecoff file=mipsecoff ;;
 851     *coff)
 852         fmt=coff  file=$em ;;
 853     *aout)
 854         fmt=aout file=$em ;;
 855     *elf)
 856         fmt=elf file=$em ;;
 857   esac
 858   formats="$formats $fmt"
 859   emfiles="$emfiles e-$file.o"
 860   EMULATIONS="$EMULATIONS &$em,"
 861 done
 862 GAS_UNIQ(formats)
 863 GAS_UNIQ(emfiles)
 864 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 865   for fmt in $formats ; do
 866     case $fmt in
 867       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 868       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 869       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 870       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 871       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 872       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 873       hp300)    AC_DEFINE(OBJ_MAYBE_HP300, 1,   [HP300 support?])   ;;
 874       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE, 1,    [IEEE support?])    ;;
 875       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 876       vms)      AC_DEFINE(OBJ_MAYBE_VMS, 1,     [VMS support?])     ;;
 877     esac
 878     extra_objects="$extra_objects obj-$fmt.o"
 879   done
 880   obj_format=multi
 881 fi
 882 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 883   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 884   # e-mips* has more than one emulation per file, e-i386* has just one at the
 885   # moment.  If only one emulation is specified, then don't define
 886   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 887   case "${obj_format}${emfiles}" in
 888     multi* | *mips*)
 889       extra_objects="$extra_objects $emfiles"
 890       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 891   esac
 892 fi
 893 AC_SUBST(extra_objects)
 894 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 895 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 896                    [Default emulation.])
 897
 898 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 899   yes-*-coff)   need_bfd=yes ;;
 900   no-*-coff)    need_bfd=yes
 901                 AC_DEFINE(MANY_SEGMENTS, 1, [old COFF support?]) ;;
 902 esac
 903
 904 reject_dev_configs=yes
 905
 906 case ${reject_dev_configs}-${dev} in
 907   yes-yes) # Oops.
 908     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 909     ;;
 910 esac
 911
 912 AC_SUBST(target_cpu_type)
 913 AC_SUBST(obj_format)
 914 AC_SUBST(te_file)
 915 AC_SUBST(install_tooldir)
 916 AC_SUBST(atof)
 917 dnl AC_SUBST(emulation)
 918
 919 case "${primary_bfd_gas}" in
 920   yes)  AC_DEFINE(BFD_ASSEMBLER, 1, [Use BFD interface?])
 921         need_bfd=yes ;;
 922 esac
 923
 924 # do we need the opcodes library?
 925 case "${need_opcodes}" in
 926 yes)
 927   OPCODES_LIB=../opcodes/libopcodes.la
 928   ;;
 929 esac
 930
 931 case "${need_bfd}" in
 932 yes)
 933   BFDLIB=../bfd/libbfd.la
 934   BFDVER_H=../bfd/bfdver.h
 935   ALL_OBJ_DEPS="$ALL_OBJ_DEPS"' ../bfd/bfd.h $(INCDIR)/symcat.h'
 936   ;;
 937 esac
 938
 939 AC_SUBST(BFDLIB)
 940 AC_SUBST(OPCODES_LIB)
 941
 942 AC_SUBST(BFDVER_H)
 943 AC_SUBST(ALL_OBJ_DEPS)
 944
 945 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 946 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 947 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 948 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 949 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 950
 951 AC_PROG_CC
 952
 953 AC_PROG_YACC
 954 AM_PROG_LEX
 955
 956 ALL_LINGUAS="fr tr es"
 957 CY_GNU_GETTEXT
 958
 959 AM_MAINTAINER_MODE
 960 AC_EXEEXT
 961
 962 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 963
 964 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 965 # people who are not cross-compiling but are compiling cross-assemblers.
 966 AC_MSG_CHECKING(whether compiling a cross-assembler)
 967 if test "${host}" = "${target}"; then
 968   cross_gas=no
 969 else
 970   cross_gas=yes
 971   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 972 fi
 973 AC_MSG_RESULT($cross_gas)
 974
 975 dnl ansidecl.h will deal with const
 976 dnl AC_CONST
 977 AC_FUNC_ALLOCA
 978 AC_C_INLINE
 979
 980 # VMS doesn't have unlink.
 981 AC_CHECK_FUNCS(unlink remove, break)
 982
 983 # Some systems don't have sbrk().
 984 AC_CHECK_FUNCS(sbrk)
 985
 986 # do we need the math library?
 987 case "${need_libm}" in
 988 yes)
 989   AC_CHECK_LIBM
 990   AC_SUBST(LIBM)
 991   ;;
 992 esac
 993
 994 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 995 # enough, but on some of those systems, the assert macro relies on requoting
 996 # working properly!
 997 GAS_WORKING_ASSERT
 998
 999 # On some systems, the system header files may not declare malloc, realloc,
1000 # and free.  There are places where gas needs these functions to have been
1001 # declared -- such as when taking their addresses.
1002 gas_test_headers="
1003 #ifdef HAVE_MEMORY_H
1004 #include <memory.h>
1005 #endif
1006 #ifdef HAVE_STRING_H
1007 #include <string.h>
1008 #else
1009 #ifdef HAVE_STRINGS_H
1010 #include <strings.h>
1011 #endif
1012 #endif
1013 #ifdef HAVE_STDLIB_H
1014 #include <stdlib.h>
1015 #endif
1016 #ifdef HAVE_UNISTD_H
1017 #include <unistd.h>
1018 #endif
1019 "
1020 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
1021 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
1022 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
1023 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
1024 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
1025
1026 # Does errno.h declare errno, or do we have to add a separate declaration
1027 # for it?
1028 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
1029 #ifdef HAVE_ERRNO_H
1030 #include <errno.h>
1031 #endif
1032 ])
1033
1034 dnl This must come last.
1035
1036 dnl We used to make symlinks to files in the source directory, but now
1037 dnl we just use the right name for .c files, and create .h files in
1038 dnl the build directory which include the right .h file.  Make sure
1039 dnl the old symlinks don't exist, so that a reconfigure in an existing
1040 dnl directory behaves reasonably.
1041
1042 AC_OUTPUT(Makefile doc/Makefile ${GDBINIT}:gdbinit.in po/Makefile.in:po/Make-in,
1043 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
1044  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
1045  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
1046  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
1047  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
1048  if test "x$cgen_cpu_prefix" != x ; then
1049    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
1050  fi
1051
1052  sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile],
1053 [target_cpu_type=${target_cpu_type}
1054  cgen_cpu_prefix=${cgen_cpu_prefix}
1055  obj_format=${obj_format}
1056  te_file=${te_file}])