gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 dnl v2.5 needed for --bindir et al
   8 AC_PREREQ(2.13)
   9 AC_INIT(as.h)
  10
  11 AC_CANONICAL_SYSTEM
  12 AC_ISC_POSIX
  13
  14 changequote(,)dnl
  15 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  16 changequote([,])dnl
  17 AM_INIT_AUTOMAKE(gas, ${BFD_VERSION})
  18
  19 AM_PROG_LIBTOOL
  20
  21 user_bfd_gas=
  22 AC_ARG_ENABLE(bfd-assembler,
  23 [  --enable-bfd-assembler  use BFD back end for writing object files],
  24 [case "${enableval}" in
  25   yes) need_bfd=yes user_bfd_gas=yes ;;
  26   no)  user_bfd_gas=no ;;
  27   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  28 esac])dnl
  29 AC_ARG_ENABLE(targets,
  30 [    targets            alternative target configurations besides the primary],
  31 [case "${enableval}" in
  32   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  33             ;;
  34   no)       enable_targets= ;;
  35   *)        enable_targets=$enableval ;;
  36 esac])dnl
  37 AC_ARG_ENABLE(commonbfdlib,
  38 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  39 [case "${enableval}" in
  40   yes) commonbfdlib=true ;;
  41   no)  commonbfdlib=false ;;
  42   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  43 esac])dnl
  44
  45 using_cgen=no
  46
  47 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  48 AC_ARG_ENABLE(build-warnings,
  49 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  50 [case "${enableval}" in
  51   yes)  ;;
  52   no)   build_warnings="-w";;
  53   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  54         build_warnings="${build_warnings} ${t}";;
  55   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  56         build_warnings="${t} ${build_warnings}";;
  57   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  58 esac
  59 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  60   echo "Setting warning flags = $build_warnings" 6>&1
  61 fi])dnl
  62 WARN_CFLAGS=""
  63 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  64     WARN_CFLAGS="${build_warnings}"
  65 fi
  66 AC_SUBST(WARN_CFLAGS)
  67
  68 # Generate a header file
  69 AM_CONFIG_HEADER(config.h:config.in)
  70
  71 # If we are on a DOS filesystem, we must use gdb.ini rather than
  72 # .gdbinit.
  73 GDBINIT=".gdbinit"
  74 case "${host}" in
  75   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-windows*)
  76     GDBINIT="gdb.ini"
  77     ;;
  78 esac
  79 AC_SUBST(GDBINIT)
  80
  81 te_file=generic
  82
  83 # Makefile target for installing gas in $(tooldir)/bin.
  84 install_tooldir=install-exec-tooldir
  85
  86 canon_targets=""
  87 all_targets=no
  88 if test -n "$enable_targets" ; then
  89   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  90     if test $t = "all"; then
  91       all_targets=yes
  92       continue
  93     fi
  94     result=`$ac_config_sub $t 2>/dev/null`
  95     if test -n "$result" ; then
  96       canon_targets="$canon_targets $result"
  97 #    else
  98 #      # Permit "all", etc.  We don't support it yet though.
  99 #      canon_targets="$canon_targets $t"
 100     fi
 101   done
 102   GAS_UNIQ(canon_targets)
 103 fi
 104
 105 emulations=""
 106
 107 for this_target in $target $canon_targets ; do
 108
 109 changequote(,)dnl
 110     eval `echo $this_target | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
 111 changequote([,])dnl
 112
 113     # check for architecture variants
 114     arch=
 115     endian=
 116     case ${cpu} in
 117       alpha*)           cpu_type=alpha ;;
 118       arm*b|xscale*b|strongarm*b) cpu_type=arm endian=big ;;
 119       arm*|xscale*|strongarm*)    cpu_type=arm endian=little ;;
 120       hppa*)            cpu_type=hppa ;;
 121 changequote(,)dnl
 122       i[3456]86)        cpu_type=i386 arch=i386;;
 123       x86_64)           cpu_type=i386 arch=x86_64;;
 124       ia64)             cpu_type=ia64 ;;
 125       ip2k)             cpu_type=ip2k endian=big ;;
 126       iq2000)           cpu_type=iq2000 endian=big ;;
 127       m6811|m6812|m68hc12) cpu_type=m68hc11 ;;
 128       m680[012346]0)    cpu_type=m68k ;;
 129 changequote([,])dnl
 130       m68008)           cpu_type=m68k ;;
 131       m683??)           cpu_type=m68k ;;
 132       m5200)            cpu_type=m68k ;;
 133       m8*)              cpu_type=m88k ;;
 134       mips*el)          cpu_type=mips endian=little ;;
 135       mips*)            cpu_type=mips endian=big ;;
 136       or32*)            cpu_type=or32 endian=big ;;
 137       pjl*)             cpu_type=pj endian=little ;;
 138       pj*)              cpu_type=pj endian=big ;;
 139       powerpc*le*)      cpu_type=ppc endian=little ;;
 140       powerpc*)         cpu_type=ppc endian=big ;;
 141       rs6000*)          cpu_type=ppc ;;
 142       s390x*)           cpu_type=s390 arch=s390x ;;
 143       s390*)            cpu_type=s390 arch=s390 ;;
 144       sh5*)             cpu_type=sh64 endian=big ;;
 145       sh5le*)           cpu_type=sh64 endian=little ;;
 146       sh64*)            cpu_type=sh64 endian=big ;;
 147       sh64le*)          cpu_type=sh64 endian=little ;;
 148       sh*le)            cpu_type=sh endian=little ;;
 149       sh*)              cpu_type=sh endian=big ;;
 150       sparclite*)       cpu_type=sparc arch=sparclite ;;
 151       sparclet*)        cpu_type=sparc arch=sparclet ;;
 152       sparc64*)         cpu_type=sparc arch=v9-64 ;;
 153       sparc86x*)        cpu_type=sparc arch=sparc86x  ;;
 154       sparc*)           cpu_type=sparc arch=sparclite ;; # ??? See tc-sparc.c.
 155       v850*)            cpu_type=v850 ;;
 156       xtensa*)          cpu_type=xtensa arch=xtensa ;;
 157       *)                cpu_type=${cpu} ;;
 158     esac
 159
 160     if test ${this_target} = $target ; then
 161       target_cpu_type=${cpu_type}
 162     elif test ${target_cpu_type} != ${cpu_type} ; then
 163       continue
 164     fi
 165
 166     generic_target=${cpu_type}-$vendor-$os
 167     dev=no
 168     bfd_gas=no
 169     em=generic
 170
 171     # assign object format
 172     case ${generic_target} in
 173       a29k-*-coff)                      fmt=coff ;;
 174       a29k-amd-udi)                     fmt=coff ;;
 175       a29k-amd-ebmon)                   fmt=coff ;;
 176       a29k-nyu-sym1)                    fmt=coff ;;
 177       a29k-*-rtems*)                    fmt=coff ;;
 178       a29k-*-vxworks*)                  fmt=coff ;;
 179
 180       alpha*-*-*vms*)                   fmt=evax ;;
 181       alpha*-*-netware*)                fmt=ecoff ;;
 182       alpha*-*-osf*)                    fmt=ecoff ;;
 183       alpha*-*-linuxecoff*)             fmt=ecoff ;;
 184       alpha*-*-linux-gnu*)              fmt=elf em=linux ;;
 185       alpha*-*-netbsd*)                 fmt=elf em=nbsd ;;
 186       alpha*-*-openbsd*)                fmt=elf em=obsd ;;
 187
 188       arc-*-elf*)                       fmt=elf ;;
 189
 190       arm-*-aout)                       fmt=aout ;;
 191       arm-*-coff | thumb-*-coff)        fmt=coff ;;
 192       arm-*-rtems | thumb-*-rtems)      fmt=elf ;;
 193       arm-*-elf | thumb-*-elf)          fmt=elf ;;
 194       arm-*-kaos*)                      fmt=elf ;;
 195       arm*-*-conix*)                    fmt=elf ;;
 196       arm-*-linux*aout*)                fmt=aout em=linux ;;
 197       arm*-*-linux-gnu*)                fmt=elf  em=linux ;;
 198       arm*-*-uclinux*)                  fmt=elf  em=linux ;;
 199       arm-*-netbsdelf*)                 fmt=elf  em=nbsd ;;
 200       arm-*-*n*bsd*)                    fmt=aout em=nbsd ;;
 201       arm-**-nto*)                      fmt=elf ;;
 202       arm-*-oabi | thumb-*-oabi)        fmt=elf ;;
 203       arm-epoc-pe | thumb-epoc-pe)      fmt=coff em=epoc-pe ;;
 204       arm-*-wince)                      fmt=coff em=wince-pe ;;
 205       arm-*-pe | thumb-*-pe)            fmt=coff em=pe ;;
 206       arm-*-riscix*)                    fmt=aout em=riscix ;;
 207       arm-*-vxworks)                    fmt=coff ;;
 208
 209       avr-*-*)                          fmt=elf ;;
 210
 211       cris-*-*)                         fmt=multi bfd_gas=yes ;;
 212
 213       d10v-*-*)                         fmt=elf ;;
 214       d30v-*-*)                         fmt=elf ;;
 215       dlx-*-*)                          fmt=elf ;;
 216
 217       fr30-*-*)                         fmt=elf ;;
 218       frv-*-*)                          fmt=elf ;;
 219
 220       hppa-*-linux*)    case ${cpu} in
 221                             hppa*64*)   fmt=elf em=hppalinux64;;
 222                             hppa*)      fmt=elf em=linux;;
 223                         esac ;;
 224       hppa-*-*elf*)                     fmt=elf em=hppa ;;
 225       hppa-*-lites*)                    fmt=elf em=hppa ;;
 226       hppa-*-netbsd*)                   fmt=elf em=nbsd ;;
 227       hppa-*-openbsd*)                  fmt=elf em=hppa ;;
 228       hppa-*-osf*)                      fmt=som em=hppa ;;
 229       hppa-*-rtems*)                    fmt=elf em=hppa ;;
 230       hppa-*-hpux11*)   case ${cpu} in
 231                             hppa*64*)   fmt=elf em=hppa64 ;;
 232                             hppa*)      fmt=som em=hppa ;;
 233                         esac ;;
 234       hppa-*-hpux*)                     fmt=som em=hppa ;;
 235       hppa-*-mpeix*)                    fmt=som em=hppa ;;
 236       hppa-*-bsd*)                      fmt=som em=hppa ;;
 237       hppa-*-hiux*)                     fmt=som em=hppa ;;
 238
 239       h8300-*-rtems*)                   fmt=coff ;;
 240       h8300-*-coff)                     fmt=coff ;;
 241       h8300-*-elf)                      fmt=elf ;;
 242       h8500-*-rtems*)                   fmt=coff ;;
 243       h8500-*-coff)                     fmt=coff ;;
 244
 245       i370-*-elf* | i370-*-linux*)      fmt=elf ;;
 246       i386-ibm-aix*)                    fmt=coff em=i386aix ;;
 247       i386-sequent-bsd*)                fmt=aout em=dynix ;;
 248       i386-*-beospe*)                   fmt=coff em=pe ;;
 249       i386-*-beos*)                     fmt=elf ;;
 250       i386-*-coff)                      fmt=coff ;;
 251       i386-*-elf)                       fmt=elf ;;
 252       i386-*-kaos*)                     fmt=elf ;;
 253       i386-*-bsd*)                      fmt=aout em=386bsd ;;
 254       i386-*-netbsd0.8)                 fmt=aout em=386bsd ;;
 255       i386-*-netbsdpe*)                 fmt=coff em=pe ;;
 256       i386-*-netbsdelf*)                fmt=elf em=nbsd ;;
 257       i386-*-*n*bsd*)   case ${cpu} in
 258                             x86_64)     fmt=elf em=nbsd ;;
 259                             *)          fmt=aout em=nbsd ;;
 260                         esac ;;
 261       i386-*-linux*aout*)               fmt=aout em=linux ;;
 262       i386-*-linux*oldld)               fmt=aout em=linux ;;
 263       i386-*-linux*coff*)               fmt=coff em=linux ;;
 264       i386-*-linux-gnu*)                fmt=elf em=linux ;;
 265       x86_64-*-linux-gnu*)              fmt=elf em=linux ;;
 266       i386-*-lynxos*)                   fmt=coff em=lynx ;;
 267 changequote(,)dnl
 268       i386-*-sysv[45]*)                 fmt=elf ;;
 269       i386-*-solaris*)                  fmt=elf ;;
 270       i386-*-freebsdaout*)              fmt=aout em=386bsd ;;
 271       i386-*-freebsd[12].*)             fmt=aout em=386bsd ;;
 272       i386-*-freebsd[12])               fmt=aout em=386bsd ;;
 273 changequote([,])dnl
 274       i386-*-sysv*)                     fmt=coff ;;
 275       i386-*-sco3.2v5*coff)             fmt=coff ;;
 276       i386-*-isc*)                      fmt=coff ;;
 277       i386-*-sco3.2v5*)                 fmt=elf
 278           if test ${this_target} = $target; then
 279             AC_DEFINE(SCO_ELF, 1, [Define if defaulting to ELF on SCO 5.])
 280           fi ;;
 281       i386-*-sco3.2*)                   fmt=coff ;;
 282       i386-*-vsta)                      fmt=aout ;;
 283       i386-*-msdosdjgpp* \
 284       | i386-*-go32* \
 285       | i386-go32-rtems*)               fmt=coff em=go32
 286             AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?]) ;;
 287       i386-*-rtemself*)                 fmt=elf ;;
 288       i386-*-rtemscoff*)                fmt=coff ;;
 289       i386-*-rtems*)                    fmt=elf ;;
 290       i386-*-gnu*)                      fmt=elf ;;
 291       i386-*-mach*)                     fmt=aout em=mach ;;
 292       i386-*-msdos*)                    fmt=aout ;;
 293       i386-*-moss*)                     fmt=elf ;;
 294       i386-*-pe)                        fmt=coff em=pe ;;
 295       i386-*-cygwin*)                   fmt=coff em=pe ;;
 296       i386-*-interix*)                  fmt=coff em=interix ;;
 297       i386-*-mingw32*)                  fmt=coff em=pe ;;
 298       i386-*-nto-qnx*)                  fmt=elf ;;
 299       i386-*-*nt*)                      fmt=coff em=pe ;;
 300       i386-*-vxworks*)                  fmt=aout ;;
 301       i386-*-chaos)                     fmt=elf ;;
 302
 303       i860-*-*)                         fmt=elf endian=little
 304                 AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress) ;;
 305       i960-*-bout)                      fmt=bout ;;
 306       i960-*-coff)                      fmt=coff em=ic960 ;;
 307       i960-*-rtems*)                    fmt=coff em=ic960 ;;
 308       i960-*-nindy*)                    fmt=bout ;;
 309       i960-*-vxworks5.0)                fmt=bout ;;
 310       i960-*-vxworks5.*)                fmt=coff em=ic960 ;;
 311       i960-*-vxworks*)                  fmt=bout ;;
 312       i960-*-elf*)                      fmt=elf ;;
 313
 314       ia64-*-elf*)                      fmt=elf ;;
 315       ia64-*-aix*)                      fmt=elf em=ia64aix ;;
 316       ia64-*-linux-gnu*)                fmt=elf em=linux ;;
 317       ia64-*-hpux*)                     fmt=elf em=hpux ;;
 318       ia64-*-netbsd*)                   fmt=elf em=nbsd ;;
 319
 320       ip2k-*-*)                         fmt=elf ;;
 321
 322       iq2000-*-elf)                     fmt=elf bfd_gas=yes ;;
 323
 324       m32r-*-*)                         fmt=elf ;;
 325
 326       m68hc11-*-* | m6811-*-*)          fmt=elf ;;
 327       m68hc12-*-* | m6812-*-*)          fmt=elf ;;
 328
 329       m68k-*-vxworks*)                  fmt=aout em=sun3 ;;
 330       m68k-ericsson-ose)                fmt=aout em=sun3 ;;
 331       m68k-*-sunos*)                    fmt=aout em=sun3 ;;
 332       m68k-motorola-sysv*)              fmt=coff em=delta ;;
 333       m68k-bull-sysv3*)                 fmt=coff em=dpx2 ;;
 334       m68k-apollo-*)                    fmt=coff em=apollo ;;
 335       m68k-*-elf*)                      fmt=elf ;;
 336       m68k-*-sysv4*)                    fmt=elf em=svr4 ;;
 337       m68k-*-sysv*)                     fmt=coff ;;
 338       m68k-*-coff | m68k-*-rtemscoff*)  fmt=coff ;;
 339       m68k-*-rtems*)                    fmt=elf ;;
 340       m68k-*-hpux*)                     fmt=hp300 em=hp300 ;;
 341       m68k-*-linux*aout*)               fmt=aout em=linux ;;
 342       m68k-*-linux-gnu*)                fmt=elf em=linux ;;
 343       m68k-*-gnu*)                      fmt=elf ;;
 344       m68k-*-lynxos*)                   fmt=coff em=lynx ;;
 345       m68k-*-netbsdelf*)                fmt=elf em=nbsd ;;
 346       m68k-*-netbsd*)                   fmt=aout em=nbsd bfd_gas=yes ;;
 347       m68k-*-openbsd*)                  fmt=aout em=nbsd bfd_gas=yes ;;
 348       m68k-apple-aux*)                  fmt=coff em=aux ;;
 349       m68k-*-psos*)                     fmt=elf em=psos;;
 350
 351       m88k-motorola-sysv3*)             fmt=coff em=delt88 ;;
 352       m88k-*-coff*)                     fmt=coff ;;
 353
 354       mcore-*-elf)                      fmt=elf ;;
 355       mcore-*-pe)                       fmt=coff em=pe bfd_gas=yes ;;
 356
 357       # don't change em like *-*-bsd does
 358       mips-dec-openbsd*)                fmt=elf endian=little ;;
 359       mips-dec-bsd*)                    fmt=aout endian=little ;;
 360       mips-sony-bsd*)                   fmt=ecoff ;;
 361       mips-*-bsd*)
 362             AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 363       mips-*-ultrix*)                   fmt=ecoff endian=little ;;
 364       mips-*-osf*)                      fmt=ecoff endian=little ;;
 365       mips-*-ecoff*)                    fmt=ecoff ;;
 366       mips-*-pe*)                       fmt=coff endian=little em=pe ;;
 367       mips-*-irix6*)                    fmt=elf em=irix ;;
 368       mips-*-irix5*)                    fmt=elf em=irix ;;
 369       mips-*-irix*)                     fmt=ecoff em=irix ;;
 370       mips-*-lnews*)                    fmt=ecoff em=lnews ;;
 371       mips-*-riscos*)                   fmt=ecoff ;;
 372       mips*-*-linux*)                   fmt=elf em=tmips ;;
 373       mips-*-sysv4*MP* | mips-*-gnu*)   fmt=elf em=tmips ;;
 374       mips-*-sysv*)                     fmt=ecoff ;;
 375       mips-*-elf* | mips-*-rtems*)      fmt=elf ;;
 376       mips-*-*n*bsd*)                   fmt=elf ;;
 377       mips-*-vxworks*)                  fmt=elf ;;
 378
 379       mmix-*-*)                         fmt=elf ;;
 380       mn10200-*-*)                      fmt=elf ;;
 381       mn10300-*-*)                      fmt=elf ;;
 382       msp430-*-*)                       fmt=elf ;;
 383       openrisc-*-*)                     fmt=elf ;;
 384       or32-*-rtems*)                    fmt=coff ;;
 385       or32-*-coff)                      fmt=coff ;;
 386       or32-*-elf)                       fmt=elf ;;
 387       pj*)                              fmt=elf ;;
 388
 389       ppc-*-pe | ppc-*-cygwin*)         fmt=coff em=pe ;;
 390       ppc-*-winnt*)                     fmt=coff em=pe ;;
 391       ppc-*-aix5*)                      fmt=coff em=aix5 ;;
 392       ppc-*-aix*)                       fmt=coff ;;
 393       ppc-*-beos*)                      fmt=coff ;;
 394       ppc-*-*n*bsd* | ppc-*-elf*)       fmt=elf ;;
 395       ppc-*-eabi* | ppc-*-sysv4*)       fmt=elf ;;
 396       ppc-*-linux-gnu*)                 fmt=elf
 397             case "$endian" in
 398                 big)  ;;
 399                 *)    AC_MSG_ERROR(GNU/Linux must be configured big endian) ;;
 400             esac ;;
 401       ppc-*-solaris*)                   fmt=elf
 402             if test ${this_target} = $target; then
 403                 AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 404                           [Define if default target is PowerPC Solaris.])
 405             fi
 406             if test x${endian} = xbig; then
 407                 AC_MSG_ERROR(Solaris must be configured little endian)
 408             fi ;;
 409       ppc-*-rtems*)                     fmt=elf ;;
 410       ppc-*-macos* | ppc-*-mpw*)        fmt=coff em=macos ;;
 411       ppc-*-netware*)                   fmt=elf em=ppcnw ;;
 412       ppc-**-nto*)                      fmt=elf ;;
 413       ppc-*-vxworks*)                   fmt=elf ;;
 414       ppc-*-windiss*)                   fmt=elf ;;
 415       ppc-*-kaos*)                      fmt=elf ;;
 416
 417       s390x-*-linux-gnu*)               fmt=elf em=linux ;;
 418       s390-*-linux-gnu*)                fmt=elf em=linux ;;
 419
 420       sh*-*-linux*)                     fmt=elf em=linux
 421             case ${cpu} in
 422                 sh*eb)  endian=big ;;
 423                 *)      endian=little ;;
 424             esac ;;
 425       sh5*-*-netbsd*)                   fmt=elf em=nbsd ;;
 426       sh64*-*-netbsd*)                  fmt=elf em=nbsd ;;
 427       sh*-*-netbsdelf*)                 fmt=elf em=nbsd ;;
 428       sh-*-elf*)                        fmt=elf ;;
 429       sh-*-coff*)                       fmt=coff ;;
 430       sh-*-nto*)                        fmt=elf ;;
 431       sh-*-pe*)                         fmt=coff em=pe bfd_gas=yes endian=little ;;
 432       sh-*-rtemself*)                   fmt=elf ;;
 433       sh-*-rtems*)                      fmt=coff ;;
 434       sh-*-kaos*)                       fmt=elf ;;
 435       shle*-*-kaos*)                    fmt=elf ;;
 436       sh64-*-elf*)                      fmt=elf ;;
 437
 438       ns32k-pc532-mach*)                fmt=aout em=pc532mach ;;
 439       ns32k-pc532-ux*)                  fmt=aout em=pc532mach ;;
 440       ns32k-pc532-lites*)               fmt=aout em=nbsd532 ;;
 441       ns32k-*-*n*bsd*)                  fmt=aout em=nbsd532 ;;
 442
 443       sparc-*-rtemsaout*)               fmt=aout ;;
 444       sparc-*-rtemself*)                fmt=elf ;;
 445       sparc-*-rtems*)                   fmt=elf ;;
 446       sparc-*-sunos4*)                  fmt=aout em=sun3 ;;
 447       sparc-*-aout | sparc*-*-vxworks*) fmt=aout em=sparcaout ;;
 448       sparc-*-coff)                     fmt=coff ;;
 449       sparc-*-linux*aout*)              fmt=aout em=linux ;;
 450       sparc-*-linux-gnu*)               fmt=elf em=linux ;;
 451       sparc-*-lynxos*)                  fmt=coff em=lynx ;;
 452       sparc-fujitsu-none)               fmt=aout ;;
 453       sparc-*-elf)                      fmt=elf ;;
 454       sparc-*-sysv4*)                   fmt=elf ;;
 455       sparc-*-solaris*)                 fmt=elf ;;
 456       sparc-*-netbsdelf*)               fmt=elf em=nbsd ;;
 457       sparc-*-*n*bsd*)  case ${cpu} in
 458                             sparc64)    fmt=elf em=nbsd ;;
 459                             *)          fmt=aout em=nbsd ;;
 460                         esac ;;
 461       strongarm-*-coff)                 fmt=coff ;;
 462       strongarm-*-elf)                  fmt=elf ;;
 463       strongarm-*-kaos*)                fmt=elf ;;
 464       xscale-*-coff)                    fmt=coff ;;
 465       xscale-*-elf)                     fmt=elf ;;
 466
 467       tic30-*-*aout*)                   fmt=aout bfd_gas=yes ;;
 468       tic30-*-*coff*)                   fmt=coff bfd_gas=yes ;;
 469       tic4x-*-* | c4x-*-*)              fmt=coff bfd_gas=yes ;;
 470       tic54x-*-* | c54x*-*-*)           fmt=coff bfd_gas=yes need_libm=yes;;
 471       tic80-*-*)                        fmt=coff ;;
 472
 473       v850-*-*)                         fmt=elf ;;
 474       v850e-*-*)                        fmt=elf ;;
 475       v850ea-*-*)                       fmt=elf ;;
 476
 477       vax-*-netbsdelf*)                 fmt=elf em=nbsd ;;
 478       vax-*-netbsd*)                    fmt=aout em=nbsd ;;
 479       vax-*-bsd* | vax-*-ultrix*)       fmt=aout ;;
 480       vax-*-vms)                        fmt=vms ;;
 481
 482       w65-*-*)                          fmt=coff ;;
 483
 484       xstormy16-*-*)                    fmt=elf ;;
 485
 486       xtensa-*-*)                       fmt=elf ;;
 487
 488       z8k-*-coff | z8k-*-sim)           fmt=coff ;;
 489
 490       *-*-aout | *-*-scout)             fmt=aout ;;
 491       *-*-freebsd*)                     fmt=elf em=freebsd ;;
 492       *-*-nindy*)                       fmt=bout ;;
 493       *-*-bsd*)                         fmt=aout em=sun3 ;;
 494       *-*-generic)                      fmt=generic ;;
 495       *-*-xray | *-*-hms)               fmt=coff ;;
 496       *-*-sim)                          fmt=coff ;;
 497       *-*-elf | *-*-sysv4* | *-*-solaris*) fmt=elf dev=yes ;;
 498       *-*-aros*)                                fmt=elf em=linux bfd_gas=yes ;;
 499       *-*-vxworks)                      fmt=aout ;;
 500       *-*-netware)                      fmt=elf ;;
 501     esac
 502
 503     if test ${this_target} = $target ; then
 504       endian_def=
 505       if test x${endian} = xbig; then
 506         endian_def=1
 507       elif test x${endian} = xlittle; then
 508         endian_def=0
 509       fi
 510       if test x${endian_def} != x; then
 511         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 512                            [Define as 1 if big endian.])
 513       fi
 514     fi
 515
 516     case ${cpu_type}-${fmt} in
 517         alpha*-* | arm-* | i386-* | ia64*-* | mips-* | ns32k-* \
 518                 | pdp11-* | ppc-* | sparc-* | strongarm-* | xscale-* \
 519                 | *-elf | *-ecoff | *-som)
 520             bfd_gas=yes ;;
 521     esac
 522
 523 # Other random stuff.
 524
 525     case ${cpu_type} in
 526       mips)
 527         # Set mips_cpu to the name of the default CPU.
 528         case ${target_cpu} in
 529           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 530             mips_cpu=from-abi
 531             ;;
 532           mipsisa32 | mipsisa32el)
 533             mips_cpu=mips32
 534             ;;
 535           mipsisa32r2 | mipsisa32r2el)
 536             mips_cpu=mips32r2
 537             ;;
 538           mipsisa64 | mipsisa64el)
 539             mips_cpu=mips64
 540             ;;
 541           mipstx39 | mipstx39el)
 542             mips_cpu=r3900
 543             ;;
 544           mips64vr | mips64vrel)
 545             mips_cpu=vr4100
 546             ;;
 547           mipsisa32r2*)
 548 changequote(,)dnl
 549             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r2//' -e 's/el$//'`
 550 changequote([,])dnl
 551             ;;
 552           mips64* | mipsisa64* | mipsisa32*)
 553 changequote(,)dnl
 554             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 555 changequote([,])dnl
 556             ;;
 557           *)
 558             AC_ERROR($target_cpu isn't a supported MIPS CPU name)
 559             ;;
 560         esac
 561         # See whether it's appropriate to set E_MIPS_ABI_O32 for o32
 562         # binaries.  It's a GNU extension that some OSes don't understand.
 563         # The value only matters on ELF targets.
 564         case ${target} in
 565           *-*-irix*)
 566             use_e_mips_abi_o32=0
 567             ;;
 568           *)
 569             use_e_mips_abi_o32=1
 570             ;;
 571         esac
 572         # Decide whether to generate 32-bit or 64-bit code by default.
 573         # Used to resolve -march=from-abi when an embedded ABI is selected.
 574         case ${target} in
 575           mips64*-*-* | mipsisa64*-*-*)
 576             mips_default_64bit=1
 577             ;;
 578           *)
 579             mips_default_64bit=0
 580             ;;
 581         esac
 582         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 583                            [Default CPU for MIPS targets. ])
 584         AC_DEFINE_UNQUOTED(USE_E_MIPS_ABI_O32, $use_e_mips_abi_o32,
 585                            [Allow use of E_MIPS_ABI_O32 on MIPS targets. ])
 586         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 587                            [Generate 64-bit code by default on MIPS targets. ])
 588         ;;
 589     esac
 590
 591     # Do we need the opcodes library?
 592     case ${cpu_type} in
 593       vax | i386 | tic30)
 594         ;;
 595
 596       *)
 597         need_opcodes=yes
 598
 599         case "${enable_shared}" in
 600         yes) shared_opcodes=true ;;
 601         *opcodes*) shared_opcodes=true ;;
 602         *) shared_opcodes=false ;;
 603         esac
 604         if test "${shared_opcodes}" = "true"; then
 605           # A shared libopcodes must be linked against libbfd.
 606           need_bfd=yes
 607         fi
 608         ;;
 609     esac
 610
 611     # Any other special object files needed ?
 612     case ${cpu_type} in
 613       fr30 | ip2k | iq2000 | m32r | openrisc)
 614         using_cgen=yes
 615         ;;
 616
 617       frv)
 618         using_cgen=yes
 619         ;;
 620       m68k)
 621         case ${extra_objects} in
 622         *m68k-parse.o*) ;;
 623         *) extra_objects="$extra_objects m68k-parse.o" ;;
 624         esac
 625         ;;
 626
 627       mips)
 628         echo ${extra_objects} | grep -s "itbl-parse.o"
 629         if test $? -ne 0 ; then
 630           extra_objects="$extra_objects itbl-parse.o"
 631         fi
 632
 633         echo ${extra_objects} | grep -s "itbl-lex.o"
 634         if test $? -ne 0 ; then
 635           extra_objects="$extra_objects itbl-lex.o"
 636         fi
 637
 638         echo ${extra_objects} | grep -s "itbl-ops.o"
 639         if test $? -ne 0 ; then
 640           extra_objects="$extra_objects itbl-ops.o"
 641         fi
 642         ;;
 643
 644       i386 | s390 | sparc)
 645         if test $this_target = $target ; then
 646           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 647         fi
 648         ;;
 649
 650       xstormy16)
 651         using_cgen=yes
 652         ;;
 653
 654       xtensa)
 655         echo ${extra_objects} | grep -s "xtensa-relax.o"
 656         if test $? -ne 0 ; then
 657           extra_objects="$extra_objects xtensa-relax.o"
 658         fi
 659         ;;
 660
 661       *)
 662         ;;
 663     esac
 664
 665     if test $using_cgen = yes ; then
 666         case "x${extra_objects}" in
 667         *cgen.o*) ;;
 668         *) extra_objects="$extra_objects cgen.o" ;;
 669         esac
 670     fi
 671
 672 # See if we really can support this configuration with the emulation code.
 673
 674     if test $this_target = $target ; then
 675       primary_bfd_gas=$bfd_gas
 676       obj_format=$fmt
 677       te_file=$em
 678
 679       if test $bfd_gas = no ; then
 680         # Can't support other configurations this way.
 681         break
 682       fi
 683     elif test $bfd_gas = no ; then
 684       # Can't support this configuration.
 685       break
 686     fi
 687
 688 # From target name and format, produce a list of supported emulations.
 689
 690     case ${generic_target}-${fmt} in
 691       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 692       mips*-*-linux*-*) case "$endian" in
 693                         big)    emulation="mipsbelf mipslelf mipself" ;;
 694                         *)      emulation="mipslelf mipsbelf mipself" ;;
 695                         esac ;;
 696       mips-*-lnews*-ecoff) ;;
 697       mips-*-*-ecoff)   case "$endian" in
 698                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 699                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 700                         esac ;;
 701       mips-*-*-elf)     case "$endian" in
 702                         big)    emulation="mipsbelf mipslelf mipself" ;;
 703                         *)      emulation="mipslelf mipsbelf mipself" ;;
 704                         esac ;;
 705       mips-*-sysv4*MP*-*) emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 706       # i386-pc-pe-coff != i386-pc-coff.
 707       i386-*-pe-coff)   ;;
 708       # Uncommenting the next line will turn on support for i386 AOUT
 709       # for the default linux configuration
 710       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 711       #
 712       i386-*-aout)      emulation="i386aout" ;;
 713       i386-*-coff)      emulation="i386coff" ;;
 714       i386-*-elf)       emulation="i386elf" ;;
 715
 716       # Always all formats.  The first stated emulation becomes the default.
 717       cris-*-*aout*)    emulation="crisaout criself" ;;
 718       cris-*-*)         emulation="criself crisaout" ;;
 719     esac
 720
 721     emulations="$emulations $emulation"
 722
 723 done
 724
 725 # Turn on all targets if possible
 726 if test ${all_targets} = "yes"; then
 727   case ${target_cpu_type} in
 728   i386)
 729     case ${obj_format} in
 730     aout)
 731       emulations="$emulations i386coff i386elf"
 732       ;;
 733     coff)
 734       emulations="$emulations i386aout i386elf"
 735     ;;
 736     elf)
 737       emulations="$emulations i386aout i386coff"
 738       ;;
 739     esac
 740   ;;
 741   esac
 742 fi
 743
 744 # Assign floating point type.  Most processors with FP support
 745 # IEEE FP.  On those that don't support FP at all, usually IEEE
 746 # is emulated.
 747 case ${target_cpu} in
 748   vax | tahoe ) atof=${target_cpu} ;;
 749   pdp11)        atof=vax ;;
 750   *)            atof=ieee ;;
 751 esac
 752
 753 case "${obj_format}" in
 754   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 755 esac
 756
 757 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 758 cgen_cpu_prefix=""
 759 if test $using_cgen = yes ; then
 760   case ${target_cpu} in
 761     *) cgen_cpu_prefix=${target_cpu} ;;
 762   esac
 763   AC_SUBST(cgen_cpu_prefix)
 764   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 765 fi
 766
 767 dnl
 768 dnl Make sure the desired support files exist.
 769 dnl
 770
 771 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 772   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 773 fi
 774
 775 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 776   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 777 fi
 778
 779 case ${user_bfd_gas}-${primary_bfd_gas} in
 780   yes-yes | no-no)
 781     # We didn't override user's choice.
 782     ;;
 783   no-yes)
 784     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 785     ;;
 786   no-preferred)
 787     primary_bfd_gas=no
 788     ;;
 789   *-preferred)
 790     primary_bfd_gas=yes
 791     ;;
 792   yes-*)
 793     primary_bfd_gas=yes
 794     ;;
 795   -*)
 796     # User specified nothing.
 797     ;;
 798 esac
 799
 800 # Some COFF configurations want these random other flags set.
 801 case ${obj_format} in
 802   coff)
 803     case ${target_cpu_type} in
 804       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 805       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 806       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 807     esac
 808     ;;
 809 esac
 810
 811 # Getting this done right is going to be a bitch.  Each configuration specified
 812 # with --enable-targets=... should be checked for environment, format, cpu, and
 813 # bfd_gas setting.
 814 #
 815 # For each configuration, the necessary object file support code must be linked
 816 # in.  This might be only one, it might be up to four.  The necessary emulation
 817 # code needs to be provided, too.
 818 #
 819 # And then there's "--enable-targets=all"....
 820 #
 821 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 822
 823 formats="${obj_format}"
 824 emfiles=""
 825 EMULATIONS=""
 826 GAS_UNIQ(emulations)
 827 for em in . $emulations ; do
 828   case $em in
 829     .)  continue ;;
 830     mipsbelf | mipslelf | mipself)
 831         fmt=elf   file=mipself ;;
 832     mipsbecoff | mipslecoff | mipsecoff)
 833         fmt=ecoff file=mipsecoff ;;
 834     *coff)
 835         fmt=coff  file=$em ;;
 836     *aout)
 837         fmt=aout file=$em ;;
 838     *elf)
 839         fmt=elf file=$em ;;
 840   esac
 841   formats="$formats $fmt"
 842   emfiles="$emfiles e-$file.o"
 843   EMULATIONS="$EMULATIONS &$em,"
 844 done
 845 GAS_UNIQ(formats)
 846 GAS_UNIQ(emfiles)
 847 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 848   for fmt in $formats ; do
 849     case $fmt in
 850       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 851       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 852       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 853       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 854       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 855       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 856       hp300)    AC_DEFINE(OBJ_MAYBE_HP300, 1,   [HP300 support?])   ;;
 857       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE, 1,    [IEEE support?])    ;;
 858       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 859       vms)      AC_DEFINE(OBJ_MAYBE_VMS, 1,     [VMS support?])     ;;
 860     esac
 861     extra_objects="$extra_objects obj-$fmt.o"
 862   done
 863   obj_format=multi
 864 fi
 865 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 866   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 867   # e-mips* has more than one emulation per file, e-i386* has just one at the
 868   # moment.  If only one emulation is specified, then don't define
 869   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 870   case "${obj_format}${emfiles}" in
 871     multi* | *mips*)
 872       extra_objects="$extra_objects $emfiles"
 873       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 874   esac
 875 fi
 876 AC_SUBST(extra_objects)
 877 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 878 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 879                    [Default emulation.])
 880
 881 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 882   yes-*-coff)   need_bfd=yes ;;
 883   no-*-coff)    need_bfd=yes
 884                 AC_DEFINE(MANY_SEGMENTS, 1, [old COFF support?]) ;;
 885 esac
 886
 887 reject_dev_configs=yes
 888
 889 case ${reject_dev_configs}-${dev} in
 890   yes-yes) # Oops.
 891     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 892     ;;
 893 esac
 894
 895 AC_SUBST(target_cpu_type)
 896 AC_SUBST(obj_format)
 897 AC_SUBST(te_file)
 898 AC_SUBST(install_tooldir)
 899 AC_SUBST(atof)
 900 dnl AC_SUBST(emulation)
 901
 902 case "${primary_bfd_gas}" in
 903   yes)  AC_DEFINE(BFD_ASSEMBLER, 1, [Use BFD interface?])
 904         need_bfd=yes ;;
 905 esac
 906
 907 # do we need the opcodes library?
 908 case "${need_opcodes}" in
 909 yes)
 910   OPCODES_LIB=../opcodes/libopcodes.la
 911   ;;
 912 esac
 913
 914 case "${need_bfd}" in
 915 yes)
 916   BFDLIB=../bfd/libbfd.la
 917   BFDVER_H=../bfd/bfdver.h
 918   ALL_OBJ_DEPS="$ALL_OBJ_DEPS"' ../bfd/bfd.h $(INCDIR)/symcat.h'
 919   ;;
 920 esac
 921
 922 AC_SUBST(BFDLIB)
 923 AC_SUBST(OPCODES_LIB)
 924
 925 AC_SUBST(BFDVER_H)
 926 AC_SUBST(ALL_OBJ_DEPS)
 927
 928 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 929 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 930 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 931 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 932 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 933
 934 AC_PROG_CC
 935
 936 AC_PROG_YACC
 937 AM_PROG_LEX
 938
 939 ALL_LINGUAS="fr tr es"
 940 CY_GNU_GETTEXT
 941
 942 AM_MAINTAINER_MODE
 943 AC_EXEEXT
 944
 945 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 946
 947 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 948 # people who are not cross-compiling but are compiling cross-assemblers.
 949 AC_MSG_CHECKING(whether compiling a cross-assembler)
 950 if test "${host}" = "${target}"; then
 951   cross_gas=no
 952 else
 953   cross_gas=yes
 954   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 955 fi
 956 AC_MSG_RESULT($cross_gas)
 957
 958 dnl ansidecl.h will deal with const
 959 dnl AC_CONST
 960 AC_FUNC_ALLOCA
 961 AC_C_INLINE
 962
 963 # VMS doesn't have unlink.
 964 AC_CHECK_FUNCS(unlink remove, break)
 965
 966 # Some systems don't have sbrk().
 967 AC_CHECK_FUNCS(sbrk)
 968
 969 # do we need the math library?
 970 case "${need_libm}" in
 971 yes)
 972   AC_CHECK_LIBM
 973   AC_SUBST(LIBM)
 974   ;;
 975 esac
 976
 977 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 978 # enough, but on some of those systems, the assert macro relies on requoting
 979 # working properly!
 980 GAS_WORKING_ASSERT
 981
 982 # On some systems, the system header files may not declare malloc, realloc,
 983 # and free.  There are places where gas needs these functions to have been
 984 # declared -- such as when taking their addresses.
 985 gas_test_headers="
 986 #ifdef HAVE_MEMORY_H
 987 #include <memory.h>
 988 #endif
 989 #ifdef HAVE_STRING_H
 990 #include <string.h>
 991 #else
 992 #ifdef HAVE_STRINGS_H
 993 #include <strings.h>
 994 #endif
 995 #endif
 996 #ifdef HAVE_STDLIB_H
 997 #include <stdlib.h>
 998 #endif
 999 #ifdef HAVE_UNISTD_H
1000 #include <unistd.h>
1001 #endif
1002 "
1003 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
1004 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
1005 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
1006 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
1007 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
1008
1009 # Does errno.h declare errno, or do we have to add a separate declaration
1010 # for it?
1011 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
1012 #ifdef HAVE_ERRNO_H
1013 #include <errno.h>
1014 #endif
1015 ])
1016
1017 dnl This must come last.
1018
1019 dnl We used to make symlinks to files in the source directory, but now
1020 dnl we just use the right name for .c files, and create .h files in
1021 dnl the build directory which include the right .h file.  Make sure
1022 dnl the old symlinks don't exist, so that a reconfigure in an existing
1023 dnl directory behaves reasonably.
1024
1025 AC_OUTPUT(Makefile doc/Makefile ${GDBINIT}:gdbinit.in po/Makefile.in:po/Make-in,
1026 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
1027  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
1028  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
1029  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
1030  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
1031  if test "x$cgen_cpu_prefix" != x ; then
1032    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
1033  fi
1034
1035  sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile],
1036 [target_cpu_type=${target_cpu_type}
1037  cgen_cpu_prefix=${cgen_cpu_prefix}
1038  obj_format=${obj_format}
1039  te_file=${te_file}])