gas/testsuite/gas/mips/mips.exp

   1 #
   2 # Some generic MIPS tests
   3 #
   4
   5 # When adding a new test to this file, try to do the following things:
   6 #
   7 # * If testing assembly and disassembly of code, don't forget to test
   8 # the actual bit encodings of the instructions (using the
   9 # --show-raw-insn flag to objdump).
  10 #
  11 # * Try to run the test for as many architectures as appropriate,
  12 # using the "run_dump_test_arches" or "run_list_test_arches" functions,
  13 # along with the output from a call to "mips_arch_list_matching."
  14 #
  15 # * Be sure to compare the test output before and after your testsuite
  16 # changes, to verify that existing and new tests were run as expected.
  17 # Look for expect ERROR messages in the testsuite .log file to make sure
  18 # the new expect code did not contain errors.
  19
  20 # To add support for a new CPU to this file, add an appropriate entry
  21 # to the sequence of "mips_arch_create" function calls below, and test
  22 # the result.  The new CPU should automatically be used when running
  23 # various tests.  If the new CPU is the default CPU for any tool
  24 # targets, make sure the call to "mips_arch_create" reflects that fact.
  25
  26
  27 # "LOSE" marks information about tests which fail at a particular point
  28 # in time, but which are not XFAILed.  Either they used to pass
  29 # and indicate either regressions or the need to tweak the tests to keep
  30 # up the with code, or they are new tests and it is unknown whether or not
  31 # they should pass as-is for the given object formats.
  32
  33
  34 # The functions below create and manipulate an "architecture data
  35 # array" which contains entries for each MIPS architecture (or CPU)
  36 # known to these tests.  The array contains the following information
  37 # for each architecture, indexed by the name of the architecture
  38 # described by the entry:
  39 #
  40 # displayname: The name of the entry to be used for pretty-printing.
  41 #
  42 # gprsize: The size in bits of General Purpose Registers provided by
  43 # the architecture (must be 32 or 64).
  44 #
  45 # props: A list of text strings which are associated with the
  46 # architecture.  These include the architecture name as well as
  47 # information about what instructions the CPU supports.  When matching
  48 # based on properties, an additional property is added to the normal
  49 # property list, "gpr<gprsize>" so that tests can match CPUs which
  50 # have GPRs of a specific size.  The following properties are most
  51 # useful when matching properties for generic (i.e., not CPU-specific)
  52 # tests:
  53 #
  54 #       mips1, mips2, mips3, mips4, mips5, mips32, mips64
  55 #               The architecture includes the instructions defined
  56 #               by that MIPS ISA.
  57 #
  58 #       gpr_ilocks
  59 #               The architecture interlocks GPRs accesses.  (That is,
  60 #               there are no load delay slots.)
  61 #
  62 #       mips3d  The architecture includes the MIPS-3D ASE.
  63 #
  64 #       ror     The architecture includes hardware rotate instructions.
  65 #
  66 #       gpr32, gpr64
  67 #               The architecture provides 32- or 64-bit General Purpose
  68 #               Registers.
  69 #
  70 # as_flags: The assembler flags used when assembling tests for this
  71 # architecture.
  72 #
  73 # objdump_flags: The objdump flags used when disassembling tests for
  74 # this architecture.
  75 #
  76 # Most entries in the architecture array will have values in all of
  77 # the fields above.  One entry, "default" represents the default CPU
  78 # based on the target of the assembler being built.  If always has
  79 # empty "as_flags" and "objdump_flags."
  80
  81 # mips_arch_init
  82 #
  83 # This function initializes the architecture data array ("mips_arches")
  84 # to be empty.
  85 proc mips_arch_init {} {
  86     global mips_arches
  87
  88     # Catch because the variable won't be set the first time through.
  89     catch {unset mips_arches}
  90 }
  91
  92 # mips_arch_create ARCH GPRSIZE EXTENDS PROPS AS_FLAGS OBJDUMP_FLAGS \
  93 #                  (optional:) DEFAULT_FOR_TARGETS
  94 #
  95 # This function creates a new entry in the architecture data array,
  96 # for the architecture or CPU named ARCH, and fills in the entry
  97 # according to the rest of the arguments.
  98 #
  99 # The new entry's property list is initialized to contain ARCH, any
 100 # properties specified by PROPS, and the properties associated with
 101 # the entry specified by EXTENDS.  (The new architecture is considered
 102 # to extend the capabilities provided by that architecture.)
 103 #
 104 # If DEFAULT_FOR_TARGETS is specified, it is a list of targets for which
 105 # this architecture is the default architecture.  If "istarget" returns
 106 # true for any of the targets in the list, a "default" entry will be
 107 # added to the architecture array which indicates that ARCH is the default
 108 # architecture.
 109 proc mips_arch_create {arch gprsize extends props as_flags objdump_flags
 110                        {default_for_targets {}}} {
 111     global mips_arches
 112
 113     if { [info exists mips_arches($arch)] } {
 114              error "mips_arch_create: arch \"$arch\" already exists"
 115     }
 116     if { $gprsize != 32 && $gprsize != 64 } {
 117         error "mips_arch_create: invalid GPR size $gprsize"
 118     }
 119
 120     set archdata(displayname) $arch
 121     set archdata(gprsize) $gprsize
 122     set archdata(as_flags) $as_flags
 123     set archdata(objdump_flags) $objdump_flags
 124     set archdata(props) $arch
 125     eval lappend archdata(props) $props
 126     if { [string length $extends] != 0 } {
 127         eval lappend archdata(props) [mips_arch_properties $extends 0]
 128     }
 129
 130     set mips_arches($arch) [array get archdata]
 131
 132     # Set as default if appropriate.
 133     foreach target $default_for_targets {
 134         if { [istarget $target] } {
 135             if { [info exists mips_arches(default)] } {
 136                 error "mips_arch_create: default arch already exists"
 137             }
 138
 139             set archdata(displayname) "default = $arch"
 140             set archdata(as_flags) ""
 141             set archdata(objdump_flags) ""
 142
 143             set mips_arches(default) [array get archdata]
 144             break
 145         }
 146     }
 147 }
 148
 149 # mips_arch_destroy ARCH
 150 #
 151 # The opposite of the above.  This function removes an entry from
 152 # the architecture data array, for the architecture or CPU named ARCH.
 153
 154 proc mips_arch_destroy {arch} {
 155     global mips_arches
 156
 157     if { [info exists mips_arches($arch)] } {
 158         unset mips_arches($arch)
 159     }
 160 }
 161
 162 # mips_arch_list_all
 163 #
 164 # This function returns the list of all names of entries in the
 165 # architecture data array (including the default entry, if a default
 166 # is known).
 167 proc mips_arch_list_all {} {
 168     global mips_arches
 169     return [lsort -dictionary [array names mips_arches]]
 170 }
 171
 172 # mips_arch_data ARCH
 173 #
 174 # This function returns the information associated with ARCH
 175 # in the architecture data array, in "array get" form.
 176 proc mips_arch_data {arch} {
 177     global mips_arches
 178
 179     if { ! [info exists mips_arches($arch)] } {
 180         error "mips_arch_data: unknown arch \"$arch\""
 181     }
 182     return $mips_arches($arch)
 183 }
 184
 185 # mips_arch_displayname ARCH
 186 #
 187 # This function returns the printable name associated with ARCH in
 188 # the architecture data array.
 189 proc mips_arch_displayname {arch} {
 190     array set archdata [mips_arch_data $arch]
 191     return $archdata(displayname)
 192 }
 193
 194 # mips_arch_properties ARCH (optional:) INCLUDE_GPRSIZE
 195 #
 196 # This function returns the property list associated with ARCH in the
 197 # architecture data array, including the "canonical" target name as the
 198 # first element.
 199 #
 200 # If INCLUDE_GPRSIZE is non-zero, an additional "gpr32" or "gpr64"
 201 # property will be returned as part of the list based on the
 202 # architecture's GPR size.
 203 proc mips_arch_properties {arch {include_gprsize 1}} {
 204     array set archdata [mips_arch_data $arch]
 205     set props $archdata(props)
 206     if { $include_gprsize } {
 207         lappend props gpr$archdata(gprsize)
 208     }
 209     return $props
 210 }
 211
 212 # mips_arch_as_flags ARCH
 213 #
 214 # This function returns the assembler flags associated with ARCH in
 215 # the architecture data array.
 216 proc mips_arch_as_flags {arch} {
 217     array set archdata [mips_arch_data $arch]
 218     return $archdata(as_flags)
 219 }
 220
 221 # mips_arch_objdump_flags ARCH
 222 #
 223 # This function returns the objdump disassembly flags associated with
 224 # ARCH in the architecture data array.
 225 proc mips_arch_objdump_flags {arch} {
 226     array set archdata [mips_arch_data $arch]
 227     return $archdata(objdump_flags)
 228 }
 229
 230 # mips_arch_matches ARCH PROPMATCHLIST
 231 #
 232 # This function returns non-zero if ARCH matches the set of properties
 233 # described by PROPMATCHLIST.  Each entry in PROPMATCHLIST can either
 234 # be the name of a property which must be matched, or "!" followed by
 235 # the name of a property which must not be matched.  ARCH matches
 236 # PROPMATCHLIST if and only if all of the conditions specified by
 237 # PROPMATCHLIST are satisfied.
 238 proc mips_arch_matches {arch propmatchlist} {
 239     foreach pm $propmatchlist {
 240         if { [string match {!*} $pm] } {
 241             # fail if present.
 242             set inverted 1
 243             set p [string range $pm 1 end]
 244         } {
 245             # fail if not present.
 246             set inverted 0
 247             set p $pm
 248         }
 249
 250         set loc [lsearch -exact [mips_arch_properties $arch] $p]
 251
 252         # required-absent and found, or required-present and not found: fail.
 253         if { ($inverted && $loc != -1) || (! $inverted && $loc == -1) } {
 254             return 0
 255         }
 256     }
 257     return 1
 258 }
 259
 260 # mips_arch_list_matching ARGS
 261 #
 262 # This function returns a list of all architectures which match
 263 # the conditions described by its arguments.  Its arguments are
 264 # taken as a list and used as the PROPMATCHLIST in a call to
 265 # "mips_arch_matches" for each known architecture.
 266 proc mips_arch_list_matching {args} {
 267     set l ""
 268     foreach arch [mips_arch_list_all] {
 269         # For now, don't match default arch until we know what its
 270         # properties actually are.
 271         if { [string compare $arch default] == 0
 272              && [string length [mips_arch_properties default]] == 0} {
 273             continue
 274         }
 275         if { [mips_arch_matches $arch $args] } {
 276             lappend l $arch
 277         }
 278     }
 279     return $l
 280 }
 281
 282
 283 # The functions below facilitate running various types of tests.
 284
 285 # run_dump_test_arch NAME ARCH
 286 #
 287 # Invoke "run_dump_test" for test NAME, with extra assembler and
 288 # disassembler flags to test architecture ARCH.
 289 #
 290 # You can override the expected output for particular architectures
 291 # and file formats.  The possible test names are, in order of preference:
 292 #
 293 # 1. CARCH@FORMAT@NAME.d
 294 # 2. CARCH@NAME.d
 295 # 3. FORMAT@NAME.d
 296 # 4. NAME.d
 297 #
 298 # where CARCH is the "canonical" name of architecture ARCH as recorded
 299 # in its associated property list, and where FORMAT is the target's
 300 # file format (one of "elf", "ecoff" or "aout").
 301 proc run_dump_test_arch { name arch } {
 302     upvar elf elf ecoff ecoff aout aout
 303     global subdir srcdir
 304
 305     set format [expr { $elf ? "elf" : $ecoff ? "ecoff" : "aout" }]
 306     set proparch [lindex [mips_arch_properties $arch 0] 0]
 307     foreach prefix [list ${proparch}@${format}@ ${proparch}@ ${format}@] {
 308         set archname ${prefix}${name}
 309         if { [file exists "$srcdir/$subdir/${archname}.d"] } {
 310             set name $archname
 311             break
 312         }
 313     }
 314
 315     if [catch {run_dump_test $name \
 316                              "{name    {([mips_arch_displayname $arch])}}
 317                               {objdump {[mips_arch_objdump_flags $arch]}}
 318                               {as      {[mips_arch_as_flags $arch]}}"} rv] {
 319         perror "$rv"
 320         untested "$subdir/$name ($arch)"
 321     }
 322 }
 323
 324 # run_dump_test_arches NAME ARCH_LIST
 325 #
 326 # Invoke "run_dump_test_arch" for test NAME, for each architecture
 327 # listed in ARCH_LIST.
 328 proc run_dump_test_arches { name arch_list } {
 329     upvar elf elf ecoff ecoff aout aout
 330     foreach arch $arch_list {
 331         run_dump_test_arch "$name" "$arch"
 332     }
 333 }
 334
 335 # run_list_test_arch NAME OPTS ARCH
 336 #
 337 # Invoke "run_list_test" for test NAME with options OPTS, with extra
 338 # assembler flags to test architecture ARCH.
 339 proc run_list_test_arch { name opts arch } {
 340     global subdir
 341
 342     set testname "MIPS $name ([mips_arch_displayname $arch])"
 343     if [catch {run_list_test "$name" "$opts [mips_arch_as_flags $arch]" \
 344                              "$testname"} rv] {
 345         perror "$rv"
 346         untested "$testname"
 347     }
 348 }
 349
 350 # run_list_test_arches NAME OPTS ARCH_LIST
 351 #
 352 # Invoke "run_list_test_arch" for test NAME with options OPTS, for each
 353 # architecture listed in ARCH_LIST.
 354 proc run_list_test_arches { name opts arch_list } {
 355     foreach arch $arch_list {
 356         run_list_test_arch "$name" "$opts" "$arch"
 357     }
 358 }
 359
 360
 361 # Create the architecture data array by providing data for all
 362 # known architectures.
 363 #
 364 # Note that several targets pick default CPU based on ABI.  We
 365 # can't easily handle that; do NOT list those targets as defaulting
 366 # to any architecture.
 367 mips_arch_init
 368 mips_arch_create mips1  32      {}      {} \
 369                         { -march=mips1 -mtune=mips1 } { -mmips:3000 }
 370 mips_arch_create mips2  32      mips1   { gpr_ilocks } \
 371                         { -march=mips2 -mtune=mips2 } { -mmips:6000 }
 372 mips_arch_create mips3  64      mips2   {} \
 373                         { -march=mips3 -mtune=mips3 } { -mmips:4000 }
 374 mips_arch_create mips4  64      mips3   {} \
 375                         { -march=mips4 -mtune=mips4 } { -mmips:8000 }
 376 mips_arch_create mips5  64      mips4   {} \
 377                         { -march=mips5 -mtune=mips5 } { -mmips:mips5 }
 378 mips_arch_create mips32 32      mips2   {} \
 379                         { -march=mips32 -mtune=mips32 } { -mmips:isa32 } \
 380                         { mipsisa32-*-* mipsisa32el-*-* }
 381 mips_arch_create mips32r2 32    mips32  { ror } \
 382                         { -march=mips32r2 -mtune=mips32r2 } \
 383                         { -mmips:isa32r2 } \
 384                         { mipsisa32r2-*-* mipsisa32r2el-*-* }
 385 mips_arch_create mips64 64      mips5   { mips32 } \
 386                         { -march=mips64 -mtune=mips64 } { -mmips:isa64 } \
 387                         { mipsisa64-*-* mipsisa64el-*-* }
 388 mips_arch_create mips64r2 64    mips64  { mips32r2 ror } \
 389                         { -march=mips64r2 -mtune=mips64r2 } \
 390                         { -mmips:isa64r2 } \
 391                         { mipsisa64r2-*-* mipsisa64r2el-*-* }
 392 mips_arch_create mips16 32      {}      {} \
 393                         { -march=mips1 -mips16 } { -mmips:16 }
 394 mips_arch_create r3000  32      mips1   {} \
 395                         { -march=r3000 -mtune=r3000 } { -mmips:3000 }
 396 mips_arch_create r3900  32      mips1   { gpr_ilocks } \
 397                         { -march=r3900 -mtune=r3900 } { -mmips:3900 } \
 398                         { mipstx39-*-* mipstx39el-*-* }
 399 mips_arch_create r4000  64      mips3   {} \
 400                         { -march=r4000 -mtune=r4000 } { -mmips:4000 }
 401 mips_arch_create vr5400 64      mips4   { ror } \
 402                         { -march=vr5400 -mtune=vr5400 } { -mmips:5400 }
 403 mips_arch_create sb1    64      mips64  { mips3d } \
 404                         { -march=sb1 -mtune=sb1 } { -mmips:sb1 } \
 405                         { mipsisa64sb1-*-* mipsisa64sb1el-*-* }
 406 mips_arch_create octeon 64      mips64r2 {} \
 407                         { -march=octeon -mtune=octeon } { -mmips:octeon } \
 408                         { mips64octeon*-*-* }
 409 mips_arch_create xlr    64      mips64  {} \
 410                         { -march=xlr -mtune=xlr } { -mmips:xlr }
 411
 412 #
 413 # And now begin the actual tests!  VxWorks uses RELA rather than REL
 414 # relocations, so most of the generic dump tests will not work there.
 415 #
 416 if { [istarget mips*-*-vxworks*] } {
 417     run_dump_test "vxworks1"
 418     run_dump_test "vxworks1-xgot"
 419     run_dump_test "vxworks1-el"
 420     run_dump_test "vxworks1-xgot-el"
 421 } elseif { [istarget mips*-*-*] } {
 422     set no_mips16 0
 423     set elf [expr [istarget *-*-elf*] || [istarget *-*-irix5*] || [istarget *-*-irix6* ] || [istarget *-*-linux*] || [istarget *-*-netbsd*] ]
 424     set ecoff [expr [istarget *-*-ecoff*] || [istarget *-*-ultrix*] || [istarget *-*-irix\[1-4\]*] ]
 425     set aout [expr [istarget *-*-bsd*] || [istarget *-*-openbsd*] ]
 426     set addr32 [expr [istarget mipstx39*-*-*] || [istarget mips-*-linux*] || [istarget mipsel-*-linux*] || [istarget mips*-*-ecoff]]
 427     set has_newabi [expr [istarget *-*-irix6*] || [istarget mips64*-*-linux*]]
 428
 429     if { [istarget "mips*-*-*linux*"] || [istarget "mips*-sde-elf*"] } then {
 430         set tmips "t"
 431     } else {
 432         set tmips ""
 433     }
 434     if [istarget mips*el-*-*] {
 435         set el "el"
 436     } {
 437         set el ""
 438     }
 439     if { $ecoff } {
 440         set no_mips16 1
 441     }
 442     if { $no_mips16 } {
 443         mips_arch_destroy mips16
 444     }
 445
 446     run_dump_test_arches "abs"          [mips_arch_list_matching mips1]
 447     run_dump_test_arches "add"          [mips_arch_list_matching mips1]
 448     run_dump_test_arches "and"          [mips_arch_list_matching mips1]
 449     run_dump_test_arches "mips1-fp"     [mips_arch_list_matching mips1]
 450     run_list_test_arches "mips1-fp" "-32 -msoft-float" \
 451                                         [mips_arch_list_matching mips1]
 452     run_dump_test "break20"
 453     run_dump_test "trap20"
 454
 455     # LOSE: As of 2002-02-08, "beq" through "bltu" fail for target mips-ecoff.
 456     # See http://sources.redhat.com/ml/binutils/2001-10/msg00418.html for
 457     # more information.  Not sure if the fixes there are correct; should
 458     # branches to external labels be allowed for ECOFF?
 459     run_dump_test_arches "beq"          [mips_arch_list_matching mips1]
 460     run_dump_test_arches "bge"          [mips_arch_list_matching mips1]
 461     run_dump_test_arches "bgeu"         [mips_arch_list_matching mips1]
 462     run_dump_test_arches "blt"          [mips_arch_list_matching mips1]
 463     run_dump_test_arches "bltu"         [mips_arch_list_matching mips1]
 464     run_dump_test_arches "branch-likely" [mips_arch_list_matching mips2]
 465     run_dump_test_arches "branch-misc-1" [mips_arch_list_matching mips1]
 466     run_dump_test_arches "branch-misc-2" [mips_arch_list_matching mips1]
 467     run_dump_test_arches "branch-misc-2pic" [mips_arch_list_matching mips1]
 468     run_dump_test_arches "branch-misc-2-64" [mips_arch_list_matching mips3]
 469     run_dump_test_arches "branch-misc-2pic-64" [mips_arch_list_matching mips3]
 470     run_dump_test "branch-misc-3"
 471     run_dump_test "branch-swap"
 472     run_dump_test "div"
 473
 474     if { !$addr32 } {
 475         run_dump_test_arches "dli"              [mips_arch_list_matching mips3]
 476     }
 477     if $elf {
 478         run_dump_test_arches "elf-jal"  [mips_arch_list_matching mips1]
 479     } else {
 480         run_dump_test "jal"
 481     }
 482     run_dump_test "eret-1"
 483     run_dump_test "eret-2"
 484     run_dump_test "eret-3"
 485
 486     if $elf {
 487         run_dump_test_arches "jal-svr4pic" \
 488                                         [mips_arch_list_matching mips1]
 489         run_dump_test_arches "jal-svr4pic-noreorder" \
 490                                         [mips_arch_list_matching mips1]
 491     }
 492     if $elf { run_dump_test "jal-xgot" }
 493     run_list_test_arches "jal-range" "-32" [mips_arch_list_matching mips1]
 494     if $has_newabi { run_dump_test "jal-newabi" }
 495     if !$aout { run_dump_test "la" }
 496     if $elf { run_dump_test "la-svr4pic" }
 497     if $elf { run_dump_test "la-xgot" }
 498     if $elf { run_dump_test "lca-svr4pic" }
 499     if $elf { run_dump_test "lca-xgot" }
 500     if !$aout {
 501         # XXX FIXME: Has mips2 and later insns with mips1 disassemblies.
 502         # (Should split and then use appropriate arch lists.)
 503         run_dump_test_arches "lb"       [mips_arch_list_matching mips1 !mips2]
 504     }
 505     if $elf {
 506         run_dump_test_arches "lb-svr4pic" \
 507                                 [mips_arch_list_matching mips1 !gpr_ilocks]
 508         run_dump_test_arches "lb-svr4pic-ilocks" [mips_arch_list_matching gpr_ilocks]
 509     }
 510     if $elf {
 511         # Both versions specify the cpu, so we can run both regardless of
 512         # the interlocking in the configured default cpu.
 513         run_dump_test "lb-xgot"
 514         run_dump_test "lb-xgot-ilocks"
 515     }
 516     if !$aout {
 517         run_dump_test_arches "ld"       [mips_arch_list_matching mips1]
 518         run_dump_test_arches "ld-forward" \
 519                                         [mips_arch_list_matching mips1]
 520         run_dump_test_arches "sd"       [mips_arch_list_matching mips1]
 521         run_dump_test_arches "sd-forward" \
 522                                         [mips_arch_list_matching mips1]
 523         run_dump_test_arches "l_d"      [mips_arch_list_matching mips1]
 524         run_dump_test_arches "l_d-forward" \
 525                                         [mips_arch_list_matching mips1]
 526         run_dump_test_arches "s_d"      [mips_arch_list_matching mips1]
 527         run_dump_test_arches "s_d-forward" \
 528                                         [mips_arch_list_matching mips1]
 529         run_dump_test_arches "ldc1"     [mips_arch_list_matching mips2]
 530         run_dump_test_arches "ldc1-forward" \
 531                                         [mips_arch_list_matching mips2]
 532         run_dump_test_arches "sdc1"     [mips_arch_list_matching mips2]
 533         run_dump_test_arches "sdc1-forward" \
 534                                         [mips_arch_list_matching mips2]
 535         if $has_newabi {
 536             run_dump_test_arches "ld-n32" \
 537                                         [mips_arch_list_matching mips3]
 538             run_dump_test_arches "ld-forward-n32" \
 539                                         [mips_arch_list_matching mips3]
 540             run_dump_test_arches "sd-n32" \
 541                                         [mips_arch_list_matching mips3]
 542             run_dump_test_arches "sd-forward-n32" \
 543                                         [mips_arch_list_matching mips3]
 544             run_dump_test_arches "l_d-n32" \
 545                                         [mips_arch_list_matching mips3]
 546             run_dump_test_arches "l_d-forward-n32" \
 547                                         [mips_arch_list_matching mips3]
 548             run_dump_test_arches "s_d-n32" \
 549                                         [mips_arch_list_matching mips3]
 550             run_dump_test_arches "s_d-forward-n32" \
 551                                         [mips_arch_list_matching mips3]
 552             run_dump_test_arches "ldc1-n32" \
 553                                         [mips_arch_list_matching mips3]
 554             run_dump_test_arches "ldc1-forward-n32" \
 555                                         [mips_arch_list_matching mips3]
 556             run_dump_test_arches "sdc1-n32" \
 557                                         [mips_arch_list_matching mips3]
 558             run_dump_test_arches "sdc1-forward-n32" \
 559                                         [mips_arch_list_matching mips3]
 560             run_dump_test_arches "ld-n64" \
 561                                         [mips_arch_list_matching mips3]
 562             run_dump_test_arches "ld-forward-n64" \
 563                                         [mips_arch_list_matching mips3]
 564             run_dump_test_arches "sd-n64" \
 565                                         [mips_arch_list_matching mips3]
 566             run_dump_test_arches "sd-forward-n64" \
 567                                         [mips_arch_list_matching mips3]
 568             run_dump_test_arches "l_d-n64" \
 569                                         [mips_arch_list_matching mips3]
 570             run_dump_test_arches "l_d-forward-n64" \
 571                                         [mips_arch_list_matching mips3]
 572             run_dump_test_arches "s_d-n64" \
 573                                         [mips_arch_list_matching mips3]
 574             run_dump_test_arches "s_d-forward-n64" \
 575                                         [mips_arch_list_matching mips3]
 576             run_dump_test_arches "ldc1-n64" \
 577                                         [mips_arch_list_matching mips3]
 578             run_dump_test_arches "ldc1-forward-n64" \
 579                                         [mips_arch_list_matching mips3]
 580             run_dump_test_arches "sdc1-n64" \
 581                                         [mips_arch_list_matching mips3]
 582             run_dump_test_arches "sdc1-forward-n64" \
 583                                         [mips_arch_list_matching mips3]
 584         }
 585     }
 586     if $elf { run_dump_test "ld-svr4pic" }
 587     if $elf { run_dump_test "ld-xgot" }
 588     run_dump_test_arches "li"           [mips_arch_list_matching mips1]
 589     if !$aout { run_dump_test "lifloat" }
 590     if $elf { run_dump_test "lif-svr4pic" }
 591     if $elf { run_dump_test "lif-xgot" }
 592     run_dump_test_arches "mips4"        [mips_arch_list_matching mips4]
 593     run_dump_test_arches "mips4-fp"     [mips_arch_list_matching mips4]
 594     run_list_test_arches "mips4-fp" "-32 -msoft-float" \
 595                                         [mips_arch_list_matching mips4]
 596     run_dump_test_arches "mips4-branch-likely" \
 597                                         [mips_arch_list_matching mips4]
 598     run_list_test_arches "mips4-branch-likely" "-32 -msoft-float" \
 599                                         [mips_arch_list_matching mips4]
 600     run_dump_test_arches "mips5"        [mips_arch_list_matching mips5]
 601     run_dump_test "mul"
 602
 603     run_dump_test_arches "rol"          [mips_arch_list_matching mips1 !ror]
 604     run_dump_test_arches "rol-hw"       [mips_arch_list_matching ror]
 605
 606     run_dump_test_arches "rol64"        [mips_arch_list_matching gpr64 !ror]
 607     run_dump_test_arches "rol64-hw"     [mips_arch_list_matching gpr64 ror]
 608
 609     if !$aout { run_dump_test "sb" }
 610     run_dump_test "trunc"
 611     if !$aout { run_dump_test "ulh" }
 612     run_dump_test_arches "ulh2-eb"      [mips_arch_list_matching mips1]
 613     run_dump_test_arches "ulh2-el"      [mips_arch_list_matching mips1]
 614     if $elf { run_dump_test "ulh-svr4pic" }
 615     if $elf { run_dump_test "ulh-xgot" }
 616     if !$aout {
 617         run_dump_test "ulw"
 618         run_dump_test "uld"
 619         run_dump_test "ush"
 620         run_dump_test "usw"
 621         run_dump_test "usd"
 622     }
 623     run_dump_test_arches "ulw2-eb" \
 624                                 [mips_arch_list_matching mips1 !gpr_ilocks]
 625     run_dump_test_arches "ulw2-eb-ilocks" [mips_arch_list_matching gpr_ilocks]
 626     run_dump_test_arches "ulw2-el" \
 627                                 [mips_arch_list_matching mips1 !gpr_ilocks]
 628     run_dump_test_arches "ulw2-el-ilocks" [mips_arch_list_matching gpr_ilocks]
 629
 630     run_dump_test_arches "uld2-eb" [mips_arch_list_matching mips3]
 631     run_dump_test_arches "uld2-el" [mips_arch_list_matching mips3]
 632
 633     # The mips16 test can only be run on ELF, because only ELF
 634     # supports the necessary mips16 reloc.
 635     if { $elf && !$no_mips16 } {
 636         run_dump_test "mips16"
 637         run_dump_test "mips16-64"
 638         # Check MIPS16e extensions
 639         run_dump_test_arches "mips16e"  [mips_arch_list_matching mips32]
 640         # Check jalx handling
 641         run_dump_test "mips16-jalx"
 642         run_dump_test "mips-jalx"
 643         run_dump_test "mips-jalx-2"
 644         # Check MIPS16 HI16/LO16 relocations
 645         run_dump_test "mips16-hilo"
 646         if $has_newabi {
 647             run_dump_test "mips16-hilo-n32"
 648         }
 649         run_dump_test "mips16-hilo-match"
 650     }
 651     run_dump_test "delay"
 652     run_dump_test "nodelay"
 653     run_dump_test "mips4010"
 654     run_dump_test "mips4650"
 655     run_dump_test "mips4100"
 656     run_dump_test "vr4111"
 657     run_dump_test "vr4120"
 658     run_dump_test "vr4120-2"
 659     run_dump_test "vr4130"
 660     run_dump_test "vr5400"
 661     run_dump_test "vr5500"
 662     run_dump_test "rm7000"
 663     run_dump_test "perfcount"
 664     run_dump_test "lineno"
 665     run_dump_test "sync"
 666
 667     run_dump_test_arches "mips32"       [mips_arch_list_matching mips32]
 668
 669     run_dump_test_arches "mips32-sf32"  [mips_arch_list_matching mips32]
 670     run_list_test_arches "mips32-sf32" "-32 -msoft-float" \
 671                                         [mips_arch_list_matching mips32]
 672     run_dump_test_arches "mips32-cp2"   [mips_arch_list_matching mips32 \
 673                                             !octeon]
 674
 675     run_dump_test_arches "mips32r2"     [mips_arch_list_matching mips32r2]
 676     run_dump_test_arches "mips32r2-cp2" [mips_arch_list_matching mips32r2 \
 677                                             !octeon]
 678     run_dump_test_arches "mips32r2-fp32" \
 679                                         [mips_arch_list_matching mips32r2]
 680     run_list_test_arches "mips32r2-fp32" "-32 -msoft-float" \
 681                                         [mips_arch_list_matching mips32r2]
 682     run_list_test_arches "mips32r2-ill" "-32" \
 683                         [mips_arch_list_matching mips32r2 gpr32]
 684     run_list_test_arches "mips32r2-ill-fp64" "-mabi=o64" \
 685                         [mips_arch_list_matching mips32r2 gpr64]
 686     run_list_test_arches "mips32r2-ill-nofp" "-32 -msoft-float" \
 687                         [mips_arch_list_matching mips32r2]
 688
 689     run_dump_test_arches "mips64"       [mips_arch_list_matching mips64]
 690     run_dump_test_arches "mips64-cp2"   [mips_arch_list_matching mips64 \
 691                                             !octeon]
 692
 693     run_dump_test_arches "mips64r2"     [mips_arch_list_matching mips64r2]
 694     run_list_test_arches "mips64r2-ill" "" [mips_arch_list_matching mips64r2]
 695
 696     run_dump_test "set-arch"
 697
 698     if { !$addr32 } {
 699         run_dump_test "mips64-mips3d"
 700         run_dump_test_arches "mips64-mips3d-incl" [mips_arch_list_matching mips3d]
 701
 702         run_dump_test "mips64-mdmx"
 703         run_dump_test "sb1-ext-mdmx"
 704         run_dump_test "sb1-ext-ps"
 705         run_dump_test "xlr-ext"
 706     }
 707
 708     run_dump_test "relax"
 709     run_dump_test "relax-swap1-mips1"
 710     run_dump_test "relax-swap1-mips2"
 711     run_dump_test "relax-swap2"
 712
 713     run_list_test "illegal" "-32"
 714     run_list_test "baddata1" "-32"
 715     run_list_test "jalr" ""
 716
 717     # LOSE: As of 2002-02-08, the next 4 tests fail for target mips-ecoff.
 718     # It's unknown whether they _should_ pass as-is, or whether different
 719     # variants are needed for ELF and ECOFF.
 720     run_dump_test "mips-gp32-fp32"
 721     run_dump_test "mips-gp32-fp64"
 722     run_dump_test "mips-gp64-fp32"
 723     run_dump_test "mips-gp64-fp64"
 724
 725     if $elf {
 726         # Make sure that -mcpu=FOO and -mFOO are equivalent.  Assemble a file
 727         # containing 4650-specific instructions with -m4650 and -mcpu=4650,
 728         # and verify that they're the same.  Specifically, we're checking
 729         # that the EF_MIPS_MACH field is set, and that the 4650 'mul'
 730         # instruction does get used.  In previous versions of GAS,
 731         # only -mcpu=4650 would set the EF_MIPS_MACH field; -m4650 wouldn't.
 732         run_dump_test "elf_e_flags1"
 733         run_dump_test "elf_e_flags2"
 734         run_dump_test "elf_e_flags3"
 735         run_dump_test "elf_e_flags4"
 736
 737         # Check EF_MIPS_ARCH markings for each supported architecture.
 738         run_dump_test "elf_arch_mips1"
 739         run_dump_test "elf_arch_mips2"
 740         run_dump_test "elf_arch_mips3"
 741         run_dump_test "elf_arch_mips4"
 742         run_dump_test "elf_arch_mips5"
 743         run_dump_test "elf_arch_mips32"
 744         run_dump_test "elf_arch_mips32r2"
 745         run_dump_test "elf_arch_mips64"
 746         run_dump_test "elf_arch_mips64r2"
 747
 748         # Verify that ASE markings are handled properly.
 749         if { !$no_mips16 } { run_dump_test "elf_ase_mips16" }
 750
 751         run_dump_test "mips-gp32-fp32-pic"
 752         run_dump_test "mips-gp32-fp64-pic"
 753         run_dump_test "mips-gp64-fp32-pic"
 754         run_dump_test "mips-gp64-fp64-pic"
 755
 756         run_dump_test "mips-abi32"
 757         run_dump_test "mips-abi32-pic"
 758         run_dump_test "mips-abi32-pic2"
 759
 760         run_dump_test "elf${el}-rel"
 761         run_dump_test_arches "elf${el}-rel2" [mips_arch_list_matching gpr64]
 762         run_dump_test "e32${el}-rel2"
 763         run_dump_test "elf${el}-rel3"
 764         run_dump_test_arches "elf-rel4" [mips_arch_list_matching gpr64]
 765         run_dump_test "e32-rel4"
 766         run_dump_test "elf-rel5"
 767         run_dump_test "elf-rel6"
 768         if $has_newabi {
 769             run_dump_test "elf-rel6-n32"
 770             run_dump_test "elf-rel6-n64"
 771         }
 772         run_dump_test "elf-rel7"
 773         run_dump_test "elf-rel8"
 774         run_dump_test "elf-rel8-mips16"
 775         run_dump_test "elf-rel9"
 776         run_dump_test "elf-rel9-mips16"
 777         if $has_newabi {
 778             run_dump_test "elf-rel10"
 779             run_dump_test "elf-rel11"
 780         }
 781         run_dump_test "elf-rel12"
 782         run_dump_test "elf-rel13"
 783         run_dump_test "elf-rel13-mips16"
 784         run_dump_test "elf-rel14"
 785
 786         if $has_newabi {
 787             run_dump_test "elf-rel15"
 788             run_dump_test "elf-rel16"
 789
 790             run_dump_test "elf-rel-got-n32"
 791             run_dump_test "elf-rel-xgot-n32"
 792             run_dump_test "elf-rel-got-n64"
 793             run_dump_test "elf-rel-xgot-n64"
 794         }
 795         run_dump_test "elf-rel17"
 796         if $has_newabi {
 797             run_dump_test "elf-rel18"
 798         }
 799         run_dump_test "elf-rel19"
 800         run_dump_test "elf-rel20"
 801         if $has_newabi {
 802             run_dump_test "elf-rel21"
 803             run_dump_test "elf-rel22"
 804             run_dump_test "elf-rel23"
 805             run_dump_test "elf-rel23a"
 806             run_dump_test "elf-rel23b"
 807             run_dump_test "elf-rel24"
 808         }
 809
 810         run_dump_test "elf-rel25"
 811         run_dump_test "elf-rel25a"
 812         run_dump_test "elf-rel26"
 813
 814         run_dump_test_arches "elf-rel27" [mips_arch_list_all]
 815
 816         if { !$no_mips16 } {
 817             run_dump_test "${tmips}mips${el}16-e"
 818             run_dump_test "${tmips}mips${el}16-f"
 819         }
 820         run_dump_test "elf-consthilo"
 821         run_dump_test "expr1"
 822
 823         run_list_test "tls-ill" "-32"
 824         run_dump_test "tls-o32"
 825         run_dump_test "jalr2"
 826     }
 827
 828     if $has_newabi {
 829         run_dump_test "n32-consec"
 830     }
 831
 832     # tests of objdump's ability to disassemble using different
 833     # register names.
 834     run_dump_test "gpr-names-numeric"
 835     run_dump_test "gpr-names-32"
 836     run_dump_test "gpr-names-n32"
 837     run_dump_test "gpr-names-64"
 838
 839     run_dump_test "fpr-names-numeric"
 840     run_dump_test "fpr-names-32"
 841     run_dump_test "fpr-names-n32"
 842     run_dump_test "fpr-names-64"
 843
 844     run_dump_test "cp0-names-numeric"
 845     run_dump_test "cp0-names-r3000"
 846     run_dump_test "cp0-names-r4000" \
 847                   { { {name} {(r4000)} } { {objdump} {-M cp0-names=r4000} } }
 848     run_dump_test "cp0-names-r4000" \
 849                   { { {name} {(r4400)} } { {objdump} {-M cp0-names=r4400} } }
 850     run_dump_test "cp0-names-mips32"
 851     run_dump_test "cp0-names-mips32r2"
 852     run_dump_test "cp0-names-mips64"
 853     run_dump_test "cp0-names-mips64r2"
 854     run_dump_test "cp0-names-sb1"
 855
 856     run_dump_test "cp0sel-names-numeric"
 857     run_dump_test "cp0sel-names-mips32"
 858     run_dump_test "cp0sel-names-mips32r2"
 859     run_dump_test "cp0sel-names-mips64"
 860     run_dump_test "cp0sel-names-mips64r2"
 861     run_dump_test "cp0sel-names-sb1"
 862
 863     run_dump_test "hwr-names-numeric"
 864     run_dump_test "hwr-names-mips32r2"
 865     run_dump_test "hwr-names-mips64r2"
 866
 867     run_dump_test "ldstla-32"
 868     run_dump_test "ldstla-32-mips3"
 869     run_dump_test "ldstla-32-shared"
 870     run_dump_test "ldstla-32-mips3-shared"
 871     run_list_test "ldstla-32-1" "-mabi=32" \
 872         "MIPS ld-st-la bad constants (ABI o32)"
 873     run_list_test "ldstla-32-mips3-1" "-mabi=32" \
 874         "MIPS ld-st-la bad constants (ABI o32, mips3)"
 875     run_list_test "ldstla-32-1" "-KPIC -mabi=32" \
 876         "MIPS ld-st-la bad constants (ABI o32, shared)"
 877     run_list_test "ldstla-32-mips3-1" "-KPIC -mabi=32" \
 878         "MIPS ld-st-la bad constants (ABI o32, mips3, shared)"
 879     run_dump_test "ldstla-eabi64"
 880     if $has_newabi {
 881         run_dump_test "ldstla-n64"
 882         run_dump_test "ldstla-n64-shared"
 883         run_dump_test "ldstla-n64-sym32"
 884     }
 885
 886     run_dump_test "macro-warn-1"
 887     run_dump_test "macro-warn-2"
 888     run_dump_test "macro-warn-3"
 889     run_dump_test "macro-warn-4"
 890     if $has_newabi {
 891         run_dump_test "macro-warn-1-n32"
 892         run_dump_test "macro-warn-2-n32"
 893     }
 894
 895     run_dump_test "noat-1"
 896     run_list_test "noat-2" ""
 897     run_list_test "noat-3" ""
 898     run_list_test "noat-4" ""
 899     run_list_test "noat-5" ""
 900     run_list_test "noat-6" ""
 901     run_list_test "noat-7" ""
 902
 903     run_dump_test "at-1"
 904     run_list_test "at-2" "-32 -mips1" "MIPS at-2"
 905
 906     run_dump_test "loongson-2e"
 907     run_dump_test "loongson-2f"
 908     run_dump_test "loongson-2f-2"
 909     run_dump_test "loongson-2f-3"
 910
 911     run_dump_test_arches "octeon"       [mips_arch_list_matching octeon]
 912     run_list_test_arches "octeon-ill" "" \
 913                                         [mips_arch_list_matching octeon]
 914     run_dump_test_arches "octeon-pref"  [mips_arch_list_matching octeon]
 915
 916     run_dump_test "smartmips"
 917     run_dump_test "mips32-dsp"
 918     run_dump_test "mips32-dspr2"
 919     run_dump_test "mips64-dsp"
 920     run_dump_test "mips32-mt"
 921
 922     if { $elf && !$no_mips16 } {
 923         run_dump_test "mips16-dwarf2"
 924         if $has_newabi {
 925             run_dump_test "mips16-dwarf2-n32"
 926         }
 927     }
 928     if { !$no_mips16 } {
 929         run_dump_test "mips16e-jrc"
 930         run_dump_test "mips16e-save"
 931         run_dump_test "mips16e-64"
 932         run_list_test "mips16e-64" "-march=mips32 -32"
 933         run_dump_test "mips16-intermix"
 934     }
 935     run_dump_test "vxworks1"
 936     run_dump_test "vxworks1-xgot"
 937     run_dump_test "vxworks1-el"
 938     run_dump_test "vxworks1-xgot-el"
 939
 940     run_dump_test "noreorder"
 941     run_dump_test "align"
 942     run_dump_test "align2"
 943     run_dump_test "align2-el"
 944     run_dump_test "odd-float"
 945
 946     run_list_test_arches "mips-macro-ill-sfp" "-32 -msingle-float" \
 947                                         [mips_arch_list_matching mips2]
 948     run_list_test_arches "mips-macro-ill-nofp" "-32 -msoft-float" \
 949                                         [mips_arch_list_matching mips2]
 950
 951     run_list_test_arches "mips-hard-float-flag" \
 952         "-32 -msoft-float -mhard-float" \
 953                                         [mips_arch_list_matching mips1]
 954     run_list_test_arches "mips-double-float-flag" \
 955         "-32 -msingle-float -mdouble-float" \
 956                                         [mips_arch_list_matching mips1]
 957
 958     run_dump_test "mips16-vis-1"
 959     run_dump_test "call-nonpic-1"
 960     run_dump_test "mips32-sync"
 961     run_dump_test_arches "mips32r2-sync" \
 962                                         [mips_arch_list_matching mips32r2]
 963
 964     if $has_newabi { run_dump_test "cfi-n64-1" }
 965
 966     run_dump_test_arches "aent"         [mips_arch_list_matching mips1]
 967 }