gcc/aclocal.m4

   1 dnl See if stdbool.h properly defines bool and true/false.
   2 AC_DEFUN(gcc_AC_HEADER_STDBOOL,
   3 [AC_CACHE_CHECK([for working stdbool.h],
   4   ac_cv_header_stdbool_h,
   5 [AC_TRY_COMPILE([#include <stdbool.h>],
   6 [bool foo = false;],
   7 ac_cv_header_stdbool_h=yes, ac_cv_header_stdbool_h=no)])
   8 if test $ac_cv_header_stdbool_h = yes; then
   9   AC_DEFINE(HAVE_STDBOOL_H, 1,
  10   [Define if you have a working <stdbool.h> header file.])
  11 fi
  12 ])
  13
  14 dnl See whether we can include both string.h and strings.h.
  15 AC_DEFUN(gcc_AC_HEADER_STRING,
  16 [AC_CACHE_CHECK([whether string.h and strings.h may both be included],
  17   gcc_cv_header_string,
  18 [AC_TRY_COMPILE([#include <string.h>
  19 #include <strings.h>], , gcc_cv_header_string=yes, gcc_cv_header_string=no)])
  20 if test $gcc_cv_header_string = yes; then
  21   AC_DEFINE(STRING_WITH_STRINGS, 1, [Define if you can safely include both <string.h> and <strings.h>.])
  22 fi
  23 ])
  24
  25 dnl See whether we need a declaration for a function.
  26 dnl The result is highly dependent on the INCLUDES passed in, so make sure
  27 dnl to use a different cache variable name in this macro if it is invoked
  28 dnl in a different context somewhere else.
  29 dnl gcc_AC_CHECK_DECL(SYMBOL,
  30 dnl     [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND [, INCLUDES]]])
  31 AC_DEFUN(gcc_AC_CHECK_DECL,
  32 [AC_MSG_CHECKING([whether $1 is declared])
  33 AC_CACHE_VAL(gcc_cv_have_decl_$1,
  34 [AC_TRY_COMPILE([$4],
  35 [#ifndef $1
  36 char *(*pfn) = (char *(*)) $1 ;
  37 #endif], eval "gcc_cv_have_decl_$1=yes", eval "gcc_cv_have_decl_$1=no")])
  38 if eval "test \"`echo '$gcc_cv_have_decl_'$1`\" = yes"; then
  39   AC_MSG_RESULT(yes) ; ifelse([$2], , :, [$2])
  40 else
  41   AC_MSG_RESULT(no) ; ifelse([$3], , :, [$3])
  42 fi
  43 ])dnl
  44
  45 dnl Check multiple functions to see whether each needs a declaration.
  46 dnl Arrange to define HAVE_DECL_<FUNCTION> to 0 or 1 as appropriate.
  47 dnl gcc_AC_CHECK_DECLS(SYMBOLS,
  48 dnl     [ACTION-IF-NEEDED [, ACTION-IF-NOT-NEEDED [, INCLUDES]]])
  49 AC_DEFUN(gcc_AC_CHECK_DECLS,
  50 [for ac_func in $1
  51 do
  52 changequote(, )dnl
  53   ac_tr_decl=HAVE_DECL_`echo $ac_func | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
  54 changequote([, ])dnl
  55 gcc_AC_CHECK_DECL($ac_func,
  56   [AC_DEFINE_UNQUOTED($ac_tr_decl, 1) $2],
  57   [AC_DEFINE_UNQUOTED($ac_tr_decl, 0) $3],
  58 dnl It is possible that the include files passed in here are local headers
  59 dnl which supply a backup declaration for the relevant prototype based on
  60 dnl the definition of (or lack of) the HAVE_DECL_ macro.  If so, this test
  61 dnl will always return success.  E.g. see libiberty.h's handling of
  62 dnl `basename'.  To avoid this, we define the relevant HAVE_DECL_ macro to
  63 dnl 1 so that any local headers used do not provide their own prototype
  64 dnl during this test.
  65 #undef $ac_tr_decl
  66 #define $ac_tr_decl 1
  67   $4
  68 )
  69 done
  70 dnl Automatically generate config.h entries via autoheader.
  71 if test x = y ; then
  72   patsubst(translit([$1], [a-z], [A-Z]), [\w+],
  73     [AC_DEFINE([HAVE_DECL_\&], 1,
  74       [Define to 1 if we found this declaration otherwise define to 0.])])dnl
  75 fi
  76 ])
  77
  78 dnl See if the printf functions in libc support %p in format strings.
  79 AC_DEFUN(gcc_AC_FUNC_PRINTF_PTR,
  80 [AC_CACHE_CHECK(whether the printf functions support %p,
  81   gcc_cv_func_printf_ptr,
  82 [AC_TRY_RUN([#include <stdio.h>
  83
  84 int main()
  85 {
  86   char buf[64];
  87   char *p = buf, *q = NULL;
  88   sprintf(buf, "%p", p);
  89   sscanf(buf, "%p", &q);
  90   return (p != q);
  91 }], gcc_cv_func_printf_ptr=yes, gcc_cv_func_printf_ptr=no,
  92         gcc_cv_func_printf_ptr=no)
  93 rm -f core core.* *.core])
  94 if test $gcc_cv_func_printf_ptr = yes ; then
  95   AC_DEFINE(HAVE_PRINTF_PTR, 1, [Define if printf supports "%p".])
  96 fi
  97 ])
  98
  99 dnl See if symbolic links work and if not, try to substitute either hard links or simple copy.
 100 AC_DEFUN(gcc_AC_PROG_LN_S,
 101 [AC_MSG_CHECKING(whether ln -s works)
 102 AC_CACHE_VAL(gcc_cv_prog_LN_S,
 103 [rm -f conftestdata_t
 104 echo >conftestdata_f
 105 if ln -s conftestdata_f conftestdata_t 2>/dev/null
 106 then
 107   gcc_cv_prog_LN_S="ln -s"
 108 else
 109   if ln conftestdata_f conftestdata_t 2>/dev/null
 110   then
 111     gcc_cv_prog_LN_S=ln
 112   else
 113     gcc_cv_prog_LN_S=cp
 114   fi
 115 fi
 116 rm -f conftestdata_f conftestdata_t
 117 ])dnl
 118 LN_S="$gcc_cv_prog_LN_S"
 119 if test "$gcc_cv_prog_LN_S" = "ln -s"; then
 120   AC_MSG_RESULT(yes)
 121 else
 122   if test "$gcc_cv_prog_LN_S" = "ln"; then
 123     AC_MSG_RESULT([no, using ln])
 124   else
 125     AC_MSG_RESULT([no, and neither does ln, so using cp])
 126   fi
 127 fi
 128 AC_SUBST(LN_S)dnl
 129 ])
 130
 131 dnl See if hard links work and if not, try to substitute either symbolic links or simple copy.
 132 AC_DEFUN(gcc_AC_PROG_LN,
 133 [AC_MSG_CHECKING(whether ln works)
 134 AC_CACHE_VAL(gcc_cv_prog_LN,
 135 [rm -f conftestdata_t
 136 echo >conftestdata_f
 137 if ln conftestdata_f conftestdata_t 2>/dev/null
 138 then
 139   gcc_cv_prog_LN="ln"
 140 else
 141   if ln -s conftestdata_f conftestdata_t 2>/dev/null
 142   then
 143     gcc_cv_prog_LN="ln -s"
 144   else
 145     gcc_cv_prog_LN=cp
 146   fi
 147 fi
 148 rm -f conftestdata_f conftestdata_t
 149 ])dnl
 150 LN="$gcc_cv_prog_LN"
 151 if test "$gcc_cv_prog_LN" = "ln"; then
 152   AC_MSG_RESULT(yes)
 153 else
 154   if test "$gcc_cv_prog_LN" = "ln -s"; then
 155     AC_MSG_RESULT([no, using ln -s])
 156   else
 157     AC_MSG_RESULT([no, and neither does ln -s, so using cp])
 158   fi
 159 fi
 160 AC_SUBST(LN)dnl
 161 ])
 162
 163 dnl See whether the stage1 host compiler accepts the volatile keyword.
 164 AC_DEFUN(gcc_AC_C_VOLATILE,
 165 [AC_CACHE_CHECK([for volatile], gcc_cv_c_volatile,
 166 [AC_TRY_COMPILE(, [volatile int foo;],
 167         gcc_cv_c_volatile=yes, gcc_cv_c_volatile=no)])
 168 if test $gcc_cv_c_volatile = yes ; then
 169   AC_DEFINE(HAVE_VOLATILE, 1, [Define if your compiler understands volatile.])
 170 fi
 171 ])
 172
 173 dnl Check whether long double is supported.  This differs from the
 174 dnl built-in autoconf test in that it works for cross compiles.
 175 AC_DEFUN(gcc_AC_C_LONG_DOUBLE,
 176 [AC_CACHE_CHECK(for long double, gcc_cv_c_long_double,
 177 [if test "$GCC" = yes; then
 178   gcc_cv_c_long_double=yes
 179 else
 180 AC_TRY_COMPILE(,
 181 [/* The Stardent Vistra knows sizeof(long double), but does not support it.  */
 182 long double foo = 0.0;
 183 /* On Ultrix 4.3 cc, long double is 4 and double is 8.  */
 184 switch (0) case 0: case (sizeof(long double) >= sizeof(double)):;],
 185 gcc_cv_c_long_double=yes, gcc_cv_c_long_double=no)
 186 fi])
 187 if test $gcc_cv_c_long_double = yes; then
 188   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
 189       [Define if your compiler supports the \`long double' type.])
 190 fi
 191 ])
 192
 193 dnl Check whether _Bool is built-in.
 194 AC_DEFUN(gcc_AC_C__BOOL,
 195 [AC_CACHE_CHECK(for built-in _Bool, gcc_cv_c__bool,
 196 [AC_TRY_COMPILE(,
 197 [_Bool foo;],
 198 gcc_cv_c__bool=yes, gcc_cv_c__bool=no)
 199 ])
 200 if test $gcc_cv_c__bool = yes; then
 201   AC_DEFINE(HAVE__BOOL, 1, [Define if the \`_Bool' type is built-in.])
 202 fi
 203 ])
 204
 205 dnl Define MKDIR_TAKES_ONE_ARG if mkdir accepts only one argument instead
 206 dnl of the usual 2.
 207 AC_DEFUN(gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG,
 208 [AC_CACHE_CHECK([if mkdir takes one argument], gcc_cv_mkdir_takes_one_arg,
 209 [AC_TRY_COMPILE([
 210 #include <sys/types.h>
 211 #ifdef HAVE_SYS_STAT_H
 212 # include <sys/stat.h>
 213 #endif
 214 #ifdef HAVE_UNISTD_H
 215 # include <unistd.h>
 216 #endif
 217 #ifdef HAVE_DIRECT_H
 218 # include <direct.h>
 219 #endif], [mkdir ("foo", 0);],
 220         gcc_cv_mkdir_takes_one_arg=no, gcc_cv_mkdir_takes_one_arg=yes)])
 221 if test $gcc_cv_mkdir_takes_one_arg = yes ; then
 222   AC_DEFINE(MKDIR_TAKES_ONE_ARG, 1, [Define if host mkdir takes a single argument.])
 223 fi
 224 ])
 225
 226 AC_DEFUN(gcc_AC_PROG_INSTALL,
 227 [AC_REQUIRE([AC_CONFIG_AUX_DIR_DEFAULT])dnl
 228 # Find a good install program.  We prefer a C program (faster),
 229 # so one script is as good as another.  But avoid the broken or
 230 # incompatible versions:
 231 # SysV /etc/install, /usr/sbin/install
 232 # SunOS /usr/etc/install
 233 # IRIX /sbin/install
 234 # AIX /bin/install
 235 # AFS /usr/afsws/bin/install, which mishandles nonexistent args
 236 # SVR4 /usr/ucb/install, which tries to use the nonexistent group "staff"
 237 # ./install, which can be erroneously created by make from ./install.sh.
 238 AC_MSG_CHECKING(for a BSD compatible install)
 239 if test -z "$INSTALL"; then
 240 AC_CACHE_VAL(ac_cv_path_install,
 241 [  IFS="${IFS=  }"; ac_save_IFS="$IFS"; IFS="${IFS}:"
 242   for ac_dir in $PATH; do
 243     # Account for people who put trailing slashes in PATH elements.
 244     case "$ac_dir/" in
 245     /|./|.//|/etc/*|/usr/sbin/*|/usr/etc/*|/sbin/*|/usr/afsws/bin/*|/usr/ucb/*) ;;
 246     *)
 247       # OSF1 and SCO ODT 3.0 have their own names for install.
 248       for ac_prog in ginstall scoinst install; do
 249         if test -f $ac_dir/$ac_prog; then
 250           if test $ac_prog = install &&
 251             grep dspmsg $ac_dir/$ac_prog >/dev/null 2>&1; then
 252             # AIX install.  It has an incompatible calling convention.
 253             # OSF/1 installbsd also uses dspmsg, but is usable.
 254             :
 255           else
 256             ac_cv_path_install="$ac_dir/$ac_prog -c"
 257             break 2
 258           fi
 259         fi
 260       done
 261       ;;
 262     esac
 263   done
 264   IFS="$ac_save_IFS"
 265 ])dnl
 266   if test "${ac_cv_path_install+set}" = set; then
 267     INSTALL="$ac_cv_path_install"
 268   else
 269     # As a last resort, use the slow shell script.  We don't cache a
 270     # path for INSTALL within a source directory, because that will
 271     # break other packages using the cache if that directory is
 272     # removed, or if the path is relative.
 273     INSTALL="$ac_install_sh"
 274   fi
 275 fi
 276 dnl We do special magic for INSTALL instead of AC_SUBST, to get
 277 dnl relative paths right.
 278 AC_MSG_RESULT($INSTALL)
 279 AC_SUBST(INSTALL)dnl
 280
 281 # Use test -z because SunOS4 sh mishandles braces in ${var-val}.
 282 # It thinks the first close brace ends the variable substitution.
 283 test -z "$INSTALL_PROGRAM" && INSTALL_PROGRAM='${INSTALL}'
 284 AC_SUBST(INSTALL_PROGRAM)dnl
 285
 286 test -z "$INSTALL_DATA" && INSTALL_DATA='${INSTALL} -m 644'
 287 AC_SUBST(INSTALL_DATA)dnl
 288 ])
 289
 290 dnl Test for GNAT.
 291 dnl We require the gnatbind program, and a compiler driver that
 292 dnl understands Ada.  The user may set the driver name explicitly
 293 dnl with ADAC; also, the user's CC setting is tried.  Failing that,
 294 dnl we try gcc and cc, then a sampling of names known to be used for
 295 dnl the Ada driver on various systems.
 296 dnl
 297 dnl Sets the shell variable have_gnat to yes or no as appropriate, and
 298 dnl substitutes GNATBIND and ADAC.
 299 AC_DEFUN([gcc_AC_PROG_GNAT],
 300 [AC_REQUIRE([AC_CHECK_TOOL_PREFIX])
 301 AC_CHECK_TOOL(GNATBIND, gnatbind, no)
 302 AC_CACHE_CHECK([for compiler driver that understands Ada],
 303                  gcc_cv_prog_adac,
 304 [cat >conftest.adb <<EOF
 305 procedure conftest is begin null; end conftest;
 306 EOF
 307 gcc_cv_prog_adac=no
 308 # Have to do ac_tool_prefix and user overrides by hand.
 309 user_adac=$ADAC
 310 user_cc=$CC
 311 for cand in ${ac_tool_prefix}$user_adac $user_adac      \
 312             ${ac_tool_prefix}$user_cc   $user_cc        \
 313             ${ac_tool_prefix}gcc        gcc             \
 314             ${ac_tool_prefix}cc         cc              \
 315             ${ac_tool_prefix}gnatgcc    gnatgcc         \
 316             ${ac_tool_prefix}gnatcc     gnatcc          \
 317             ${ac_tool_prefix}adagcc     adagcc          \
 318             ${ac_tool_prefix}adacc      adacc           ; do
 319   # There is a bug in all released versions of GCC which causes the
 320   # driver to exit successfully when the appropriate language module
 321   # has not been installed.  This is fixed in 2.95.4, 3.0.2, and 3.1.
 322   # Therefore we must check for the error message as well as an
 323   # unsuccessful exit.
 324   errors=`($cand -c conftest.adb) 2>&1 || echo failure`
 325   if test x"$errors" = x; then
 326     gcc_cv_prog_adac=$cand
 327     break
 328   fi
 329 done
 330 rm -f conftest.*])
 331 ADAC=$gcc_cv_prog_adac
 332 AC_SUBST(ADAC)
 333
 334 if test x$GNATBIND != xno && test x$ADAC != xno; then
 335   have_gnat=yes
 336 else
 337   have_gnat=no
 338 fi
 339 ])
 340
 341 #serial 1
 342 dnl This test replaces the one in autoconf.
 343 dnl Currently this macro should have the same name as the autoconf macro
 344 dnl because gettext's gettext.m4 (distributed in the automake package)
 345 dnl still uses it.  Otherwise, the use in gettext.m4 makes autoheader
 346 dnl give these diagnostics:
 347 dnl   configure.in:556: AC_TRY_COMPILE was called before AC_ISC_POSIX
 348 dnl   configure.in:556: AC_TRY_RUN was called before AC_ISC_POSIX
 349
 350 undefine([AC_ISC_POSIX])
 351 AC_DEFUN(AC_ISC_POSIX,
 352   [
 353     dnl This test replaces the obsolescent AC_ISC_POSIX kludge.
 354     AC_CHECK_LIB(cposix, strerror, [LIBS="$LIBS -lcposix"])
 355   ]
 356 )
 357
 358
 359 dnl GCC_PATH_PROG(VARIABLE, PROG-TO-CHECK-FOR [, VALUE-IF-NOT-FOUND [, PATH]])
 360 dnl like AC_PATH_PROG but use other cache variables
 361 AC_DEFUN(GCC_PATH_PROG,
 362 [# Extract the first word of "$2", so it can be a program name with args.
 363 set dummy $2; ac_word=[$]2
 364 AC_MSG_CHECKING([for $ac_word])
 365 AC_CACHE_VAL(gcc_cv_path_$1,
 366 [case "[$]$1" in
 367   /*)
 368   gcc_cv_path_$1="[$]$1" # Let the user override the test with a path.
 369   ;;
 370   ?:/*)
 371   gcc_cv_path_$1="[$]$1" # Let the user override the test with a dos path.
 372   ;;
 373   *)
 374   IFS="${IFS=   }"; ac_save_ifs="$IFS"; IFS=":"
 375 dnl $ac_dummy forces splitting on constant user-supplied paths.
 376 dnl POSIX.2 word splitting is done only on the output of word expansions,
 377 dnl not every word.  This closes a longstanding sh security hole.
 378   ac_dummy="ifelse([$4], , $PATH, [$4])"
 379   for ac_dir in $ac_dummy; do
 380     test -z "$ac_dir" && ac_dir=.
 381     if test -f $ac_dir/$ac_word; then
 382       gcc_cv_path_$1="$ac_dir/$ac_word"
 383       break
 384     fi
 385   done
 386   IFS="$ac_save_ifs"
 387 dnl If no 3rd arg is given, leave the cache variable unset,
 388 dnl so GCC_PATH_PROGS will keep looking.
 389 ifelse([$3], , , [  test -z "[$]gcc_cv_path_$1" && gcc_cv_path_$1="$3"
 390 ])dnl
 391   ;;
 392 esac])dnl
 393 $1="$gcc_cv_path_$1"
 394 if test -n "[$]$1"; then
 395   AC_MSG_RESULT([$]$1)
 396 else
 397   AC_MSG_RESULT(no)
 398 fi
 399 AC_SUBST($1)dnl
 400 ])
 401
 402 # Check whether mmap can map an arbitrary page from /dev/zero or with
 403 # MAP_ANONYMOUS, without MAP_FIXED.
 404 AC_DEFUN([AC_FUNC_MMAP_ANYWHERE],
 405 [AC_CHECK_FUNCS(getpagesize)
 406 # The test program for the next two tests is the same except for one
 407 # set of ifdefs.
 408 changequote({{{,}}})dnl
 409 {{{cat >ct-mmap.inc <<'EOF'
 410 #include <sys/types.h>
 411 #include <sys/mman.h>
 412 #include <fcntl.h>
 413 #include <signal.h>
 414 #include <setjmp.h>
 415 #include <stdio.h>
 416
 417 #if !defined (MAP_ANONYMOUS) && defined (MAP_ANON)
 418 # define MAP_ANONYMOUS MAP_ANON
 419 #endif
 420
 421 /* This mess was copied from the GNU getpagesize.h.  */
 422 #ifndef HAVE_GETPAGESIZE
 423 # ifdef HAVE_UNISTD_H
 424 #  include <unistd.h>
 425 # endif
 426
 427 /* Assume that all systems that can run configure have sys/param.h.  */
 428 # ifndef HAVE_SYS_PARAM_H
 429 #  define HAVE_SYS_PARAM_H 1
 430 # endif
 431
 432 # ifdef _SC_PAGESIZE
 433 #  define getpagesize() sysconf(_SC_PAGESIZE)
 434 # else /* no _SC_PAGESIZE */
 435 #  ifdef HAVE_SYS_PARAM_H
 436 #   include <sys/param.h>
 437 #   ifdef EXEC_PAGESIZE
 438 #    define getpagesize() EXEC_PAGESIZE
 439 #   else /* no EXEC_PAGESIZE */
 440 #    ifdef NBPG
 441 #     define getpagesize() NBPG * CLSIZE
 442 #     ifndef CLSIZE
 443 #      define CLSIZE 1
 444 #     endif /* no CLSIZE */
 445 #    else /* no NBPG */
 446 #     ifdef NBPC
 447 #      define getpagesize() NBPC
 448 #     else /* no NBPC */
 449 #      ifdef PAGESIZE
 450 #       define getpagesize() PAGESIZE
 451 #      endif /* PAGESIZE */
 452 #     endif /* no NBPC */
 453 #    endif /* no NBPG */
 454 #   endif /* no EXEC_PAGESIZE */
 455 #  else /* no HAVE_SYS_PARAM_H */
 456 #   define getpagesize() 8192   /* punt totally */
 457 #  endif /* no HAVE_SYS_PARAM_H */
 458 # endif /* no _SC_PAGESIZE */
 459
 460 #endif /* no HAVE_GETPAGESIZE */
 461
 462 #ifndef MAP_FAILED
 463 # define MAP_FAILED -1
 464 #endif
 465
 466 #undef perror_exit
 467 #define perror_exit(str, val) \
 468   do { perror(str); exit(val); } while (0)
 469
 470 /* Some versions of cygwin mmap require that munmap is called with the
 471    same parameters as mmap.  GCC expects that this is not the case.
 472    Test for various forms of this problem.  Warning - icky signal games.  */
 473
 474 static sigset_t unblock_sigsegv;
 475 static jmp_buf r;
 476 static size_t pg;
 477 static int devzero;
 478
 479 static char *
 480 anonmap (size)
 481      size_t size;
 482 {
 483 #ifdef USE_MAP_ANON
 484   return (char *) mmap (0, size, PROT_READ|PROT_WRITE,
 485                         MAP_PRIVATE|MAP_ANONYMOUS, -1, 0);
 486 #else
 487   return (char *) mmap (0, size, PROT_READ|PROT_WRITE,
 488                         MAP_PRIVATE, devzero, 0);
 489 #endif
 490 }
 491
 492 static void
 493 sigsegv (unused)
 494      int unused;
 495 {
 496   sigprocmask (SIG_UNBLOCK, &unblock_sigsegv, 0);
 497   longjmp (r, 1);
 498 }
 499
 500 /* Basic functionality test.  */
 501 void
 502 test_0 ()
 503 {
 504   char *x = anonmap (pg);
 505   if (x == (char *) MAP_FAILED)
 506     perror_exit("test 0 mmap", 2);
 507
 508   *(int *)x += 1;
 509
 510   if (munmap(x, pg) < 0)
 511     perror_exit("test 0 munmap", 3);
 512 }
 513
 514 /* 1. If we map a 2-page region and unmap its second page, the first page
 515    must remain.  */
 516 static void
 517 test_1 ()
 518 {
 519   char *x = anonmap (pg * 2);
 520   if (x == (char *)MAP_FAILED)
 521     perror_exit ("test 1 mmap", 4);
 522
 523   signal (SIGSEGV, sigsegv);
 524   if (setjmp (r))
 525     perror_exit ("test 1 fault", 5);
 526
 527   x[0] = 1;
 528   x[pg] = 1;
 529
 530   if (munmap (x + pg, pg) < 0)
 531     perror_exit ("test 1 munmap 1", 6);
 532   x[0] = 2;
 533
 534   if (setjmp (r) == 0)
 535     {
 536       x[pg] = 1;
 537       perror_exit ("test 1 no fault", 7);
 538     }
 539   if (munmap (x, pg) < 0)
 540     perror_exit ("test 1 munmap 2", 8);
 541 }
 542
 543 /* 2. If we map a 2-page region and unmap its first page, the second
 544    page must remain.  */
 545 static void
 546 test_2 ()
 547 {
 548   char *x = anonmap (pg * 2);
 549   if (x == (char *)MAP_FAILED)
 550     perror_exit ("test 2 mmap", 9);
 551
 552   signal (SIGSEGV, sigsegv);
 553   if (setjmp (r))
 554     perror_exit ("test 2 fault", 10);
 555
 556   x[0] = 1;
 557   x[pg] = 1;
 558
 559   if (munmap (x, pg) < 0)
 560     perror_exit ("test 2 munmap 1", 11);
 561
 562   x[pg] = 2;
 563
 564   if (setjmp (r) == 0)
 565     {
 566       x[0] = 1;
 567       perror_exit ("test 2 no fault", 12);
 568     }
 569
 570   if (munmap (x+pg, pg) < 0)
 571     perror_exit ("test 2 munmap 2", 13);
 572 }
 573
 574 /* 3. If we map two adjacent 1-page regions and unmap them both with
 575    one munmap, both must go away.
 576
 577    Getting two adjacent 1-page regions with two mmap calls is slightly
 578    tricky.  All OS's tested skip over already-allocated blocks; therefore
 579    we have been careful to unmap all allocated regions in previous tests.
 580    HP/UX allocates pages backward in memory.  No OS has yet been observed
 581    to be so perverse as to leave unmapped space between consecutive calls
 582    to mmap.  */
 583
 584 static void
 585 test_3 ()
 586 {
 587   char *x, *y, *z;
 588
 589   x = anonmap (pg);
 590   if (x == (char *)MAP_FAILED)
 591     perror_exit ("test 3 mmap 1", 14);
 592   y = anonmap (pg);
 593   if (y == (char *)MAP_FAILED)
 594     perror_exit ("test 3 mmap 2", 15);
 595
 596   if (y != x + pg)
 597     {
 598       if (y == x - pg)
 599         z = y, y = x, x = z;
 600       else
 601         {
 602           fprintf (stderr, "test 3 nonconsecutive pages - %lx, %lx\n",
 603                    (unsigned long)x, (unsigned long)y);
 604           exit (16);
 605         }
 606     }
 607
 608   signal (SIGSEGV, sigsegv);
 609   if (setjmp (r))
 610     perror_exit ("test 3 fault", 17);
 611
 612   x[0] = 1;
 613   y[0] = 1;
 614
 615   if (munmap (x, pg*2) < 0)
 616     perror_exit ("test 3 munmap", 18);
 617
 618   if (setjmp (r) == 0)
 619     {
 620       x[0] = 1;
 621       perror_exit ("test 3 no fault 1", 19);
 622     }
 623
 624   signal (SIGSEGV, sigsegv);
 625   if (setjmp (r) == 0)
 626     {
 627       y[0] = 1;
 628       perror_exit ("test 3 no fault 2", 20);
 629     }
 630 }
 631
 632 int
 633 main ()
 634 {
 635   sigemptyset (&unblock_sigsegv);
 636   sigaddset (&unblock_sigsegv, SIGSEGV);
 637   pg = getpagesize ();
 638 #ifndef USE_MAP_ANON
 639   devzero = open ("/dev/zero", O_RDWR);
 640   if (devzero < 0)
 641     perror_exit ("open /dev/zero", 1);
 642 #endif
 643
 644   test_0();
 645   test_1();
 646   test_2();
 647   test_3();
 648
 649   exit(0);
 650 }
 651 EOF}}}
 652 changequote([,])dnl
 653
 654 AC_CACHE_CHECK(for working mmap from /dev/zero,
 655   ac_cv_func_mmap_dev_zero,
 656 [AC_TRY_RUN(
 657  [#include "ct-mmap.inc"],
 658  ac_cv_func_mmap_dev_zero=yes,
 659  [if test $? -lt 4
 660  then ac_cv_func_mmap_dev_zero=no
 661  else ac_cv_func_mmap_dev_zero=buggy
 662  fi],
 663  # If this is not cygwin, and /dev/zero is a character device, it's probably
 664  # safe to assume it works.
 665  [case "$host_os" in
 666    cygwin* | win32 | pe | mingw* ) ac_cv_func_mmap_dev_zero=buggy ;;
 667    * ) if test -c /dev/zero
 668        then ac_cv_func_mmap_dev_zero=yes
 669        else ac_cv_func_mmap_dev_zero=no
 670        fi ;;
 671   esac])
 672 ])
 673 if test $ac_cv_func_mmap_dev_zero = yes; then
 674   AC_DEFINE(HAVE_MMAP_DEV_ZERO, 1,
 675             [Define if mmap can get us zeroed pages from /dev/zero.])
 676 fi
 677
 678 AC_CACHE_CHECK([for working mmap with MAP_ANON(YMOUS)],
 679   ac_cv_func_mmap_anon,
 680 [AC_TRY_RUN(
 681  [#define USE_MAP_ANON
 682 #include "ct-mmap.inc"],
 683  ac_cv_func_mmap_anon=yes,
 684  [if test $? -lt 4
 685  then ac_cv_func_mmap_anon=no
 686  else ac_cv_func_mmap_anon=buggy
 687  fi],
 688  # Unlike /dev/zero, it is not safe to assume MAP_ANON(YMOUS) works
 689  # just because it's there. Some SCO Un*xen define it but don't implement it.
 690  ac_cv_func_mmap_anon=no)
 691 ])
 692 if test $ac_cv_func_mmap_anon = yes; then
 693   AC_DEFINE(HAVE_MMAP_ANON, 1,
 694             [Define if mmap can get us zeroed pages using MAP_ANON(YMOUS).])
 695 fi
 696 rm -f ct-mmap.inc
 697 ])
 698
 699 # Check whether mmap can map a plain file, without MAP_FIXED.
 700 AC_DEFUN([AC_FUNC_MMAP_FILE],
 701 [AC_CACHE_CHECK(for working mmap of a file, ac_cv_func_mmap_file,
 702 [# Create a file one thousand bytes long.
 703 for i in 1 2 3 4 5 6 7 8 9 0
 704 do for j in 1 2 3 4 5 6 7 8 9 0
 705 do echo $i $j xxxxx
 706 done
 707 done > conftestdata$$
 708
 709 AC_TRY_RUN([
 710 /* Test by Zack Weinberg.  Modified from MMAP_ANYWHERE test by
 711    Richard Henderson and Alexandre Oliva.
 712    Check whether read-only mmap of a plain file works. */
 713 #include <sys/types.h>
 714 #include <sys/stat.h>
 715 #include <fcntl.h>
 716 #include <sys/mman.h>
 717
 718 int main()
 719 {
 720   char *x;
 721   int fd;
 722   struct stat st;
 723
 724   fd = open("conftestdata$$", O_RDONLY);
 725   if (fd < 0)
 726     exit(1);
 727
 728   if (fstat (fd, &st))
 729     exit(2);
 730
 731   x = (char*)mmap(0, st.st_size, PROT_READ, MAP_PRIVATE, fd, 0);
 732   if (x == (char *) -1)
 733     exit(3);
 734
 735   if (x[0] != '1' || x[1] != ' ' || x[2] != '1' || x[3] != ' ')
 736     exit(4);
 737
 738   if (munmap(x, st.st_size) < 0)
 739     exit(5);
 740
 741   exit(0);
 742 }], ac_cv_func_mmap_file=yes, ac_cv_func_mmap_file=no,
 743 ac_cv_func_mmap_file=no)])
 744 if test $ac_cv_func_mmap_file = yes; then
 745   AC_DEFINE(HAVE_MMAP_FILE, 1,
 746             [Define if read-only mmap of a plain file works.])
 747 fi
 748 ])
 749
 750 dnl Locate a program and check that its version is acceptable.
 751 dnl AC_PROG_CHECK_VER(var, name, version-switch,
 752 dnl                  version-extract-regexp, version-glob)
 753 AC_DEFUN(gcc_AC_CHECK_PROG_VER,
 754 [AC_CHECK_PROG([$1], [$2], [$2])
 755 if test -n "[$]$1"; then
 756   # Found it, now check the version.
 757   AC_CACHE_CHECK(for modern $2, gcc_cv_prog_$2_modern,
 758 [changequote(<<,>>)dnl
 759   ac_prog_version=`<<$>>$1 $3 2>&1 |
 760                    sed -n 's/^.*patsubst(<<$4>>,/,\/).*$/\1/p'`
 761 changequote([,])dnl
 762   echo "configure:__oline__: version of $2 is $ac_prog_version" >&AC_FD_CC
 763 changequote(<<,>>)dnl
 764   case $ac_prog_version in
 765     '')     gcc_cv_prog_$2_modern=no;;
 766     <<$5>>)
 767             gcc_cv_prog_$2_modern=yes;;
 768     *)      gcc_cv_prog_$2_modern=no;;
 769   esac
 770 changequote([,])dnl
 771 ])
 772 else
 773   gcc_cv_prog_$2_modern=no
 774 fi
 775 ])
 776
 777 dnl Determine if enumerated bitfields are unsigned.   ISO C says they can
 778 dnl be either signed or unsigned.
 779 dnl
 780 AC_DEFUN(gcc_AC_C_ENUM_BF_UNSIGNED,
 781 [AC_CACHE_CHECK(for unsigned enumerated bitfields, gcc_cv_enum_bf_unsigned,
 782 [AC_TRY_RUN(#include <stdlib.h>
 783 enum t { BLAH = 128 } ;
 784 struct s_t { enum t member : 8; } s ;
 785 int main(void)
 786 {
 787         s.member = BLAH;
 788         if (s.member < 0) exit(1);
 789         exit(0);
 790
 791 }, gcc_cv_enum_bf_unsigned=yes, gcc_cv_enum_bf_unsigned=no, gcc_cv_enum_bf_unsigned=yes)])
 792 if test $gcc_cv_enum_bf_unsigned = yes; then
 793   AC_DEFINE(ENUM_BITFIELDS_ARE_UNSIGNED, 1,
 794     [Define if enumerated bitfields are treated as unsigned values.])
 795 fi])
 796
 797 dnl Host type sizes probe.
 798 dnl By Kaveh R. Ghazi.  One typo fixed since.
 799 dnl
 800 AC_DEFUN([gcc_AC_COMPILE_CHECK_SIZEOF],
 801 [changequote(<<, >>)dnl
 802 dnl The name to #define.
 803 define(<<AC_TYPE_NAME>>, translit(sizeof_$1, [a-z *], [A-Z_P]))dnl
 804 dnl The cache variable name.
 805 define(<<AC_CV_NAME>>, translit(ac_cv_sizeof_$1, [ *], [_p]))dnl
 806 changequote([, ])dnl
 807 AC_MSG_CHECKING(size of $1)
 808 AC_CACHE_VAL(AC_CV_NAME,
 809 [for ac_size in 4 8 1 2 16 $3 ; do # List sizes in rough order of prevalence.
 810   AC_TRY_COMPILE([#include "confdefs.h"
 811 #include <sys/types.h>
 812 $2
 813 ], [switch (0) case 0: case (sizeof ($1) == $ac_size):;], AC_CV_NAME=$ac_size)
 814   if test x$AC_CV_NAME != x ; then break; fi
 815 done
 816 ])
 817 if test x$AC_CV_NAME = x ; then
 818   AC_MSG_ERROR([cannot determine a size for $1])
 819 fi
 820 AC_MSG_RESULT($AC_CV_NAME)
 821 AC_DEFINE_UNQUOTED(AC_TYPE_NAME, $AC_CV_NAME, [The number of bytes in type $1])
 822 undefine([AC_TYPE_NAME])dnl
 823 undefine([AC_CV_NAME])dnl
 824 ])
 825
 826 dnl Probe number of bits in a byte.
 827 dnl Note C89 requires CHAR_BIT >= 8.
 828 dnl
 829 AC_DEFUN(gcc_AC_C_CHAR_BIT,
 830 [AC_CACHE_CHECK(for CHAR_BIT, gcc_cv_decl_char_bit,
 831 [AC_EGREP_CPP(found,
 832 [#ifdef HAVE_LIMITS_H
 833 #include <limits.h>
 834 #endif
 835 #ifdef CHAR_BIT
 836 found
 837 #endif], gcc_cv_decl_char_bit=yes, gcc_cv_decl_char_bit=no)
 838 ])
 839 if test $gcc_cv_decl_char_bit = no; then
 840   AC_CACHE_CHECK(number of bits in a byte, gcc_cv_c_nbby,
 841 [i=8
 842  gcc_cv_c_nbby=
 843  while test $i -lt 65; do
 844    AC_TRY_COMPILE(,
 845      [switch(0) {
 846   case (unsigned char)((unsigned long)1 << $i) == ((unsigned long)1 << $i):
 847   case (unsigned char)((unsigned long)1<<($i-1)) == ((unsigned long)1<<($i-1)):
 848   ; }],
 849      [gcc_cv_c_nbby=$i; break])
 850    i=`expr $i + 1`
 851  done
 852  test -z "$gcc_cv_c_nbby" && gcc_cv_c_nbby=failed
 853 ])
 854 if test $gcc_cv_c_nbby = failed; then
 855   AC_MSG_ERROR(cannot determine number of bits in a byte)
 856 else
 857   AC_DEFINE_UNQUOTED(CHAR_BIT, $gcc_cv_c_nbby,
 858   [Define as the number of bits in a byte, if \`limits.h' doesn't.])
 859 fi
 860 fi])
 861
 862 dnl Checking for long long.
 863 dnl By Caolan McNamara <caolan@skynet.ie>
 864 dnl Added check for __int64, Zack Weinberg <zackw@stanford.edu>
 865 dnl
 866 AC_DEFUN([gcc_AC_C_LONG_LONG],
 867 [AC_CACHE_CHECK(for long long int, ac_cv_c_long_long,
 868   [AC_TRY_COMPILE(,[long long int i;],
 869          ac_cv_c_long_long=yes,
 870          ac_cv_c_long_long=no)])
 871   if test $ac_cv_c_long_long = yes; then
 872     AC_DEFINE(HAVE_LONG_LONG, 1,
 873       [Define if your compiler supports the \`long long' type.])
 874   fi
 875 AC_CACHE_CHECK(for __int64, ac_cv_c___int64,
 876   [AC_TRY_COMPILE(,[__int64 i;],
 877         ac_cv_c___int64=yes,
 878         ac_cv_c___int64=no)])
 879   if test $ac_cv_c___int64 = yes; then
 880     AC_DEFINE(HAVE___INT64, 1,
 881       [Define if your compiler supports the \`__int64' type.])
 882   fi
 883 ])
 884
 885 dnl Host character set probe.
 886 dnl The EBCDIC values match the table in config/i370/i370.c;
 887 dnl there are other versions of EBCDIC but GCC won't work with them.
 888 dnl
 889 AC_DEFUN([gcc_AC_C_CHARSET],
 890 [AC_CACHE_CHECK(execution character set, ac_cv_c_charset,
 891   [AC_EGREP_CPP(ASCII,
 892 [#if '\n' == 0x0A && ' ' == 0x20 && '0' == 0x30 \
 893    && 'A' == 0x41 && 'a' == 0x61 && '!' == 0x21
 894 ASCII
 895 #endif], ac_cv_c_charset=ASCII)
 896   if test x${ac_cv_c_charset+set} != xset; then
 897     AC_EGREP_CPP(EBCDIC,
 898 [#if '\n' == 0x15 && ' ' == 0x40 && '0' == 0xF0 \
 899    && 'A' == 0xC1 && 'a' == 0x81 && '!' == 0x5A
 900 EBCDIC
 901 #endif], ac_cv_c_charset=EBCDIC)
 902   fi
 903   if test x${ac_cv_c_charset+set} != xset; then
 904     ac_cv_c_charset=unknown
 905   fi])
 906 if test $ac_cv_c_charset = unknown; then
 907   AC_MSG_ERROR([*** Cannot determine host character set.])
 908 elif test $ac_cv_c_charset = EBCDIC; then
 909   AC_DEFINE(HOST_EBCDIC, 1,
 910   [Define if the host execution character set is EBCDIC.])
 911 fi])
 912
 913 dnl Utility macro used by next two tests.
 914 dnl AC_EXAMINE_OBJECT(C source code,
 915 dnl     commands examining object file,
 916 dnl     [commands to run if compile failed]):
 917 dnl
 918 dnl Compile the source code to an object file; then convert it into a
 919 dnl printable representation.  All unprintable characters and
 920 dnl asterisks (*) are replaced by dots (.).  All white space is
 921 dnl deleted.  Newlines (ASCII 0x10) in the input are preserved in the
 922 dnl output, but runs of newlines are compressed to a single newline.
 923 dnl Finally, line breaks are forcibly inserted so that no line is
 924 dnl longer than 80 columns and the file ends with a newline.  The
 925 dnl result of all this processing is in the file conftest.dmp, which
 926 dnl may be examined by the commands in the second argument.
 927 dnl
 928 AC_DEFUN([gcc_AC_EXAMINE_OBJECT],
 929 [AC_LANG_SAVE
 930 AC_LANG_C
 931 dnl Next bit cribbed from AC_TRY_COMPILE.
 932 cat > conftest.$ac_ext <<EOF
 933 [#line __oline__ "configure"
 934 #include "confdefs.h"
 935 $1
 936 ]EOF
 937 if AC_TRY_EVAL(ac_compile); then
 938   od -c conftest.o |
 939     sed ['s/^[0-7]*[    ]*/ /
 940           s/\*/./g
 941           s/ \\n/*/g
 942           s/ [0-9][0-9][0-9]/./g
 943           s/  \\[^ ]/./g'] |
 944     tr -d '
 945  ' | tr -s '*' '
 946 ' | fold | sed '$a\
 947 ' > conftest.dmp
 948   $2
 949 ifelse($3, , , else
 950   $3
 951 )dnl
 952 fi
 953 rm -rf conftest*
 954 AC_LANG_RESTORE])
 955
 956 dnl Host endianness probe.
 957 dnl This tests byte-within-word endianness.  GCC actually needs
 958 dnl to know word-within-larger-object endianness.  They are the
 959 dnl same on all presently supported hosts.
 960 dnl Differs from AC_C_BIGENDIAN in that it does not require
 961 dnl running a program on the host, and it defines the macro we
 962 dnl want to see.
 963 dnl
 964 AC_DEFUN([gcc_AC_C_COMPILE_ENDIAN],
 965 [AC_CACHE_CHECK(byte ordering, ac_cv_c_compile_endian,
 966 [ac_cv_c_compile_endian=unknown
 967 gcc_AC_EXAMINE_OBJECT([
 968 #ifdef HAVE_LIMITS_H
 969 # include <limits.h>
 970 #endif
 971 /* This structure must have no internal padding.  */
 972   struct {
 973     char prefix[sizeof "\nendian:" - 1];
 974     short word;
 975     char postfix[2];
 976  } tester = {
 977     "\nendian:",
 978 #if SIZEOF_SHORT == 4
 979     ('A' << (CHAR_BIT * 3)) | ('B' << (CHAR_BIT * 2)) |
 980 #endif
 981     ('A' << CHAR_BIT) | 'B',
 982     'X', '\n'
 983 };],
 984  [if   grep 'endian:AB' conftest.dmp >/dev/null 2>&1; then
 985     ac_cv_c_compile_endian=big-endian
 986   elif grep 'endian:BA' conftest.dmp >/dev/null 2>&1; then
 987     ac_cv_c_compile_endian=little-endian
 988   fi])
 989 ])
 990 if test $ac_cv_c_compile_endian = unknown; then
 991   AC_MSG_ERROR([*** unable to determine endianness])
 992 elif test $ac_cv_c_compile_endian = big-endian; then
 993   AC_DEFINE(HOST_WORDS_BIG_ENDIAN, 1,
 994   [Define if the host machine stores words of multi-word integers in
 995    big-endian order.])
 996 fi
 997 ])
 998
 999 dnl Floating point format probe.
1000 dnl The basic concept is the same as the above: grep the object
1001 dnl file for an interesting string.  We have to watch out for
1002 dnl rounding changing the values in the object, however; this is
1003 dnl handled by ignoring the least significant byte of the float.
1004 dnl
1005 dnl Does not know about VAX G-float or C4x idiosyncratic format.
1006 dnl It does know about PDP-10 idiosyncratic format, but this is
1007 dnl not presently supported by GCC.  S/390 "binary floating point"
1008 dnl is in fact IEEE (but maybe we should have that in EBCDIC as well
1009 dnl as ASCII?)
1010 dnl
1011 AC_DEFUN([gcc_AC_C_FLOAT_FORMAT],
1012 [AC_CACHE_CHECK(floating point format, ac_cv_c_float_format,
1013 [gcc_AC_EXAMINE_OBJECT(
1014 [/* This will not work unless sizeof(double) == 8.  */
1015 extern char sizeof_double_must_be_8 [sizeof(double) == 8 ? 1 : -1];
1016
1017 /* This structure must have no internal padding.  */
1018 struct possibility {
1019   char prefix[8];
1020   double candidate;
1021   char postfix[8];
1022 };
1023
1024 #define C(cand) { "\nformat:", cand, ":tamrof\n" }
1025 struct possibility table [] =
1026 {
1027   C( 3.25724264705901305206e+01), /* @@IEEEFP - IEEE 754 */
1028   C( 3.53802595280598432000e+18), /* D__float - VAX */
1029   C( 5.32201830133125317057e-19), /* D.PDP-10 - PDP-10 - the dot is 0x13a */
1030   C( 1.77977764695171661377e+10), /* IBMHEXFP - s/390 format, ascii */
1031   C(-5.22995989424860458374e+10)  /* IBMHEXFP - s/390 format, EBCDIC */
1032 };],
1033  [if   grep 'format:.@IEEEF.:tamrof' conftest.dmp >/dev/null 2>&1; then
1034     ac_cv_c_float_format='IEEE (big-endian)'
1035   elif grep 'format:.I@@PFE.:tamrof' conftest.dmp >/dev/null 2>&1; then
1036     ac_cv_c_float_format='IEEE (big-endian)'
1037   elif grep 'format:.FEEEI@.:tamrof' conftest.dmp >/dev/null 2>&1; then
1038     ac_cv_c_float_format='IEEE (little-endian)'
1039   elif grep 'format:.EFP@@I.:tamrof' conftest.dmp >/dev/null 2>&1; then
1040     ac_cv_c_float_format='IEEE (little-endian)'
1041   elif grep 'format:.__floa.:tamrof' conftest.dmp >/dev/null 2>&1; then
1042     ac_cv_c_float_format='VAX D-float'
1043   elif grep 'format:..PDP-1.:tamrof' conftest.dmp >/dev/null 2>&1; then
1044     ac_cv_c_float_format='PDP-10'
1045   elif grep 'format:.BMHEXF.:tamrof' conftest.dmp >/dev/null 2>&1; then
1046     ac_cv_c_float_format='IBM 370 hex'
1047   else
1048     AC_MSG_ERROR(Unknown floating point format)
1049   fi],
1050   [AC_MSG_ERROR(compile failed)])
1051 ])
1052 # IEEE is the default format.  If the float endianness isn't the same
1053 # as the integer endianness, we have to set FLOAT_WORDS_BIG_ENDIAN
1054 # (which is a tristate: yes, no, default).  This is only an issue with
1055 # IEEE; the other formats are only supported by a few machines each,
1056 # all with the same endianness.
1057 format=
1058 fbigend=
1059 case $ac_cv_c_float_format in
1060     'IEEE (big-endian)' )
1061         if test $ac_cv_c_compile_endian = little-endian; then
1062             fbigend=1
1063         fi
1064         ;;
1065     'IEEE (little-endian)' )
1066         if test $ac_cv_c_compile_endian = big-endian; then
1067             fbigend=0
1068         fi
1069         ;;
1070     'VAX D-float' )
1071         format=VAX_FLOAT_FORMAT
1072         ;;
1073     'PDP-10' )
1074         format=PDP10_FLOAT_FORMAT
1075         ;;
1076     'IBM 370 hex' )
1077         format=IBM_FLOAT_FORMAT
1078         ;;
1079 esac
1080 if test -n "$format"; then
1081         AC_DEFINE_UNQUOTED(HOST_FLOAT_FORMAT, $format,
1082   [Define to the floating point format of the host machine, if not IEEE.])
1083 fi
1084 if test -n "$fbigend"; then
1085         AC_DEFINE_UNQUOTED(HOST_FLOAT_WORDS_BIG_ENDIAN, $fbigend,
1086   [Define to 1 if the host machine stores floating point numbers in
1087    memory with the word containing the sign bit at the lowest address,
1088    or to 0 if it does it the other way around.
1089
1090    This macro should not be defined if the ordering is the same as for
1091    multi-word integers.])
1092 fi
1093 ])
1094
1095 #serial AM2
1096
1097 dnl From Bruno Haible.
1098
1099 AC_DEFUN([AM_ICONV],
1100 [
1101   dnl Some systems have iconv in libc, some have it in libiconv (OSF/1 and
1102   dnl those with the standalone portable GNU libiconv installed).
1103
1104   AC_ARG_WITH([libiconv-prefix],
1105 [  --with-libiconv-prefix=DIR  search for libiconv in DIR/include and DIR/lib], [
1106     for dir in `echo "$withval" | tr : ' '`; do
1107       if test -d $dir/include; then CPPFLAGS="$CPPFLAGS -I$dir/include"; fi
1108       if test -d $dir/lib; then LDFLAGS="$LDFLAGS -L$dir/lib"; fi
1109     done
1110    ])
1111
1112   AC_CACHE_CHECK(for iconv, am_cv_func_iconv, [
1113     am_cv_func_iconv="no, consider installing GNU libiconv"
1114     am_cv_lib_iconv=no
1115     AC_TRY_LINK([#include <stdlib.h>
1116 #include <iconv.h>],
1117       [iconv_t cd = iconv_open("","");
1118        iconv(cd,NULL,NULL,NULL,NULL);
1119        iconv_close(cd);],
1120       am_cv_func_iconv=yes)
1121     if test "$am_cv_func_iconv" != yes; then
1122       am_save_LIBS="$LIBS"
1123       LIBS="$LIBS -liconv"
1124       AC_TRY_LINK([#include <stdlib.h>
1125 #include <iconv.h>],
1126         [iconv_t cd = iconv_open("","");
1127          iconv(cd,NULL,NULL,NULL,NULL);
1128          iconv_close(cd);],
1129         am_cv_lib_iconv=yes
1130         am_cv_func_iconv=yes)
1131       LIBS="$am_save_LIBS"
1132     fi
1133   ])
1134   if test "$am_cv_func_iconv" = yes; then
1135     AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
1136     AC_MSG_CHECKING([for iconv declaration])
1137     AC_CACHE_VAL(am_cv_proto_iconv, [
1138       AC_TRY_COMPILE([
1139 #include <stdlib.h>
1140 #include <iconv.h>
1141 extern
1142 #ifdef __cplusplus
1143 "C"
1144 #endif
1145 #if defined(__STDC__) || defined(__cplusplus)
1146 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
1147 #else
1148 size_t iconv();
1149 #endif
1150 ], [], am_cv_proto_iconv_arg1="", am_cv_proto_iconv_arg1="const")
1151       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
1152     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed -e 's/( /(/'`
1153     AC_MSG_RESULT([$]{ac_t:-
1154          }[$]am_cv_proto_iconv)
1155     AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
1156       [Define as const if the declaration of iconv() needs const.])
1157   fi
1158   LIBICONV=
1159   if test "$am_cv_lib_iconv" = yes; then
1160     LIBICONV="-liconv"
1161   fi
1162   AC_SUBST(LIBICONV)
1163 ])
1164
1165 ### Gettext macros begin here.
1166 ### Changes for GCC marked by 'dnl GCC LOCAL'.
1167 ### Note iconv.m4 appears above, as it's used for other reasons.
1168
1169 #serial AM1
1170
1171 dnl From Bruno Haible.
1172
1173 AC_DEFUN([AM_LANGINFO_CODESET],
1174 [
1175   AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
1176     [AC_TRY_LINK([#include <langinfo.h>],
1177       [char* cs = nl_langinfo(CODESET);],
1178       am_cv_langinfo_codeset=yes,
1179       am_cv_langinfo_codeset=no)
1180     ])
1181   if test $am_cv_langinfo_codeset = yes; then
1182     AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
1183       [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
1184   fi
1185 ])
1186
1187 #serial 1
1188 # This test replaces the one in autoconf.
1189 # Currently this macro should have the same name as the autoconf macro
1190 # because gettext's gettext.m4 (distributed in the automake package)
1191 # still uses it.  Otherwise, the use in gettext.m4 makes autoheader
1192 # give these diagnostics:
1193 #   configure.in:556: AC_TRY_COMPILE was called before AC_ISC_POSIX
1194 #   configure.in:556: AC_TRY_RUN was called before AC_ISC_POSIX
1195
1196 undefine([AC_ISC_POSIX])
1197
1198 AC_DEFUN([AC_ISC_POSIX],
1199   [
1200     dnl This test replaces the obsolescent AC_ISC_POSIX kludge.
1201     dnl GCC LOCAL: Use AC_SEARCH_LIBS.
1202     AC_SEARCH_LIBS(strerror, cposix)
1203   ]
1204 )
1205
1206 #serial 2
1207
1208 # Test for the GNU C Library, version 2.1 or newer.
1209 # From Bruno Haible.
1210
1211 AC_DEFUN([jm_GLIBC21],
1212   [
1213     AC_CACHE_CHECK(whether we are using the GNU C Library 2.1 or newer,
1214       ac_cv_gnu_library_2_1,
1215       [AC_EGREP_CPP([Lucky GNU user],
1216         [
1217 #include <features.h>
1218 #ifdef __GNU_LIBRARY__
1219  #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 1) || (__GLIBC__ > 2)
1220   Lucky GNU user
1221  #endif
1222 #endif
1223         ],
1224         ac_cv_gnu_library_2_1=yes,
1225         ac_cv_gnu_library_2_1=no)
1226       ]
1227     )
1228     AC_SUBST(GLIBC21)
1229     GLIBC21="$ac_cv_gnu_library_2_1"
1230   ]
1231 )
1232
1233 # Check whether LC_MESSAGES is available in <locale.h>.
1234 # Ulrich Drepper <drepper@cygnus.com>, 1995.
1235 #
1236 # This file can be copied and used freely without restrictions.  It can
1237 # be used in projects which are not available under the GNU General Public
1238 # License or the GNU Library General Public License but which still want
1239 # to provide support for the GNU gettext functionality.
1240 # Please note that the actual code of the GNU gettext library is covered
1241 # by the GNU Library General Public License, and the rest of the GNU
1242 # gettext package package is covered by the GNU General Public License.
1243 # They are *not* in the public domain.
1244
1245 # serial 2
1246
1247 AC_DEFUN([AM_LC_MESSAGES],
1248   [if test $ac_cv_header_locale_h = yes; then
1249     AC_CACHE_CHECK([for LC_MESSAGES], am_cv_val_LC_MESSAGES,
1250       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
1251        am_cv_val_LC_MESSAGES=yes, am_cv_val_LC_MESSAGES=no)])
1252     if test $am_cv_val_LC_MESSAGES = yes; then
1253       AC_DEFINE(HAVE_LC_MESSAGES, 1,
1254         [Define if your <locale.h> file defines LC_MESSAGES.])
1255     fi
1256   fi])
1257
1258 # Search path for a program which passes the given test.
1259 # Ulrich Drepper <drepper@cygnus.com>, 1996.
1260 #
1261 # This file can be copied and used freely without restrictions.  It can
1262 # be used in projects which are not available under the GNU General Public
1263 # License or the GNU Library General Public License but which still want
1264 # to provide support for the GNU gettext functionality.
1265 # Please note that the actual code of the GNU gettext library is covered
1266 # by the GNU Library General Public License, and the rest of the GNU
1267 # gettext package package is covered by the GNU General Public License.
1268 # They are *not* in the public domain.
1269
1270 # serial 2
1271
1272 dnl AM_PATH_PROG_WITH_TEST(VARIABLE, PROG-TO-CHECK-FOR,
1273 dnl   TEST-PERFORMED-ON-FOUND_PROGRAM [, VALUE-IF-NOT-FOUND [, PATH]])
1274 AC_DEFUN([AM_PATH_PROG_WITH_TEST],
1275 [# Extract the first word of "$2", so it can be a program name with args.
1276 set dummy $2; ac_word=[$]2
1277 AC_MSG_CHECKING([for $ac_word])
1278 AC_CACHE_VAL(ac_cv_path_$1,
1279 [case "[$]$1" in
1280   /*)
1281   ac_cv_path_$1="[$]$1" # Let the user override the test with a path.
1282   ;;
1283   *)
1284   IFS="${IFS=   }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
1285   for ac_dir in ifelse([$5], , $PATH, [$5]); do
1286     test -z "$ac_dir" && ac_dir=.
1287     if test -f $ac_dir/$ac_word; then
1288       if [$3]; then
1289         ac_cv_path_$1="$ac_dir/$ac_word"
1290         break
1291       fi
1292     fi
1293   done
1294   IFS="$ac_save_ifs"
1295 dnl If no 4th arg is given, leave the cache variable unset,
1296 dnl so AC_PATH_PROGS will keep looking.
1297 ifelse([$4], , , [  test -z "[$]ac_cv_path_$1" && ac_cv_path_$1="$4"
1298 ])dnl
1299   ;;
1300 esac])dnl
1301 $1="$ac_cv_path_$1"
1302 if test ifelse([$4], , [-n "[$]$1"], ["[$]$1" != "$4"]); then
1303   AC_MSG_RESULT([$]$1)
1304 else
1305   AC_MSG_RESULT(no)
1306 fi
1307 AC_SUBST($1)dnl
1308 ])
1309
1310 # Macro to add for using GNU gettext.
1311 # Ulrich Drepper <drepper@cygnus.com>, 1995.
1312 #
1313 # This file can be copied and used freely without restrictions.  It can
1314 # be used in projects which are not available under the GNU General Public
1315 # License or the GNU Library General Public License but which still want
1316 # to provide support for the GNU gettext functionality.
1317 # Please note that the actual code of the GNU gettext library is covered
1318 # by the GNU Library General Public License, and the rest of the GNU
1319 # gettext package package is covered by the GNU General Public License.
1320 # They are *not* in the public domain.
1321
1322 # serial 10
1323
1324 dnl Usage: AM_WITH_NLS([TOOLSYMBOL], [NEEDSYMBOL], [LIBDIR]).
1325 dnl If TOOLSYMBOL is specified and is 'use-libtool', then a libtool library
1326 dnl    $(top_builddir)/intl/libintl.la will be created (shared and/or static,
1327 dnl    depending on --{enable,disable}-{shared,static} and on the presence of
1328 dnl    AM-DISABLE-SHARED). Otherwise, a static library
1329 dnl    $(top_builddir)/intl/libintl.a will be created.
1330 dnl If NEEDSYMBOL is specified and is 'need-ngettext', then GNU gettext
1331 dnl    implementations (in libc or libintl) without the ngettext() function
1332 dnl    will be ignored.
1333 dnl LIBDIR is used to find the intl libraries.  If empty,
1334 dnl    the value `$(top_builddir)/intl/' is used.
1335 dnl
1336 dnl The result of the configuration is one of three cases:
1337 dnl 1) GNU gettext, as included in the intl subdirectory, will be compiled
1338 dnl    and used.
1339 dnl    Catalog format: GNU --> install in $(datadir)
1340 dnl    Catalog extension: .mo after installation, .gmo in source tree
1341 dnl 2) GNU gettext has been found in the system's C library.
1342 dnl    Catalog format: GNU --> install in $(datadir)
1343 dnl    Catalog extension: .mo after installation, .gmo in source tree
1344 dnl 3) No internationalization, always use English msgid.
1345 dnl    Catalog format: none
1346 dnl    Catalog extension: none
1347 dnl The use of .gmo is historical (it was needed to avoid overwriting the
1348 dnl GNU format catalogs when building on a platform with an X/Open gettext),
1349 dnl but we keep it in order not to force irrelevant filename changes on the
1350 dnl maintainers.
1351 dnl
1352 AC_DEFUN([AM_WITH_NLS],
1353   [AC_MSG_CHECKING([whether NLS is requested])
1354     dnl Default is enabled NLS
1355     AC_ARG_ENABLE(nls,
1356       [  --disable-nls           do not use Native Language Support],
1357       USE_NLS=$enableval, USE_NLS=yes)
1358     AC_MSG_RESULT($USE_NLS)
1359     AC_SUBST(USE_NLS)
1360
1361     BUILD_INCLUDED_LIBINTL=no
1362     USE_INCLUDED_LIBINTL=no
1363 dnl GCC LOCAL: Separate concept of link command line from dependencies.
1364     INTLLIBS=
1365     INTLDEPS=
1366
1367     dnl If we use NLS figure out what method
1368     if test "$USE_NLS" = "yes"; then
1369       AC_DEFINE(ENABLE_NLS, 1,
1370         [Define to 1 if translation of program messages to the user's native language
1371    is requested.])
1372       AC_MSG_CHECKING([whether included gettext is requested])
1373       AC_ARG_WITH(included-gettext,
1374         [  --with-included-gettext use the GNU gettext library included here],
1375         nls_cv_force_use_gnu_gettext=$withval,
1376         nls_cv_force_use_gnu_gettext=no)
1377       AC_MSG_RESULT($nls_cv_force_use_gnu_gettext)
1378
1379       nls_cv_use_gnu_gettext="$nls_cv_force_use_gnu_gettext"
1380       if test "$nls_cv_force_use_gnu_gettext" != "yes"; then
1381         dnl User does not insist on using GNU NLS library.  Figure out what
1382         dnl to use.  If GNU gettext is available we use this.  Else we have
1383         dnl to fall back to GNU NLS library.
1384         CATOBJEXT=NONE
1385
1386         dnl Add a version number to the cache macros.
1387         define(gt_cv_func_gnugettext_libc, [gt_cv_func_gnugettext]ifelse([$2], need-ngettext, 2, 1)[_libc])
1388         define(gt_cv_func_gnugettext_libintl, [gt_cv_func_gnugettext]ifelse([$2], need-ngettext, 2, 1)[_libintl])
1389
1390 dnl GCC LOCAL: Expose presence of libintl.h to C code.
1391         AC_CHECK_HEADER(libintl.h,
1392           [AC_DEFINE([HAVE_LIBINTL_H], 1,
1393                 [Define if you have the <libintl.h> header file.])
1394            AC_CACHE_CHECK([for GNU gettext in libc], gt_cv_func_gnugettext_libc,
1395             [AC_TRY_LINK([#include <libintl.h>
1396 extern int _nl_msg_cat_cntr;],
1397                [bindtextdomain ("", "");
1398 return (int) gettext ("")]ifelse([$2], need-ngettext, [ + (int) ngettext ("", "", 0)], [])[ + _nl_msg_cat_cntr],
1399                gt_cv_func_gnugettext_libc=yes,
1400                gt_cv_func_gnugettext_libc=no)])
1401
1402            if test "$gt_cv_func_gnugettext_libc" != "yes"; then
1403              AC_CACHE_CHECK([for GNU gettext in libintl],
1404                gt_cv_func_gnugettext_libintl,
1405                [gt_save_LIBS="$LIBS"
1406                 LIBS="$LIBS -lintl $LIBICONV"
1407                 AC_TRY_LINK([#include <libintl.h>
1408 extern int _nl_msg_cat_cntr;],
1409                   [bindtextdomain ("", "");
1410 return (int) gettext ("")]ifelse([$2], need-ngettext, [ + (int) ngettext ("", "", 0)], [])[ + _nl_msg_cat_cntr],
1411                   gt_cv_func_gnugettext_libintl=yes,
1412                   gt_cv_func_gnugettext_libintl=no)
1413                 LIBS="$gt_save_LIBS"])
1414            fi
1415
1416            dnl If an already present or preinstalled GNU gettext() is found,
1417            dnl use it.  But if this macro is used in GNU gettext, and GNU
1418            dnl gettext is already preinstalled in libintl, we update this
1419            dnl libintl.  (Cf. the install rule in intl/Makefile.in.)
1420            if test "$gt_cv_func_gnugettext_libc" = "yes" \
1421               || { test "$gt_cv_func_gnugettext_libintl" = "yes" \
1422                    && test "$PACKAGE" != gettext; }; then
1423              AC_DEFINE(HAVE_GETTEXT, 1,
1424                [Define if the GNU gettext() function is already present or preinstalled.])
1425
1426              if test "$gt_cv_func_gnugettext_libintl" = "yes"; then
1427                dnl If iconv() is in a separate libiconv library, then anyone
1428                dnl linking with libintl{.a,.so} also needs to link with
1429                dnl libiconv.
1430                INTLLIBS="-lintl $LIBICONV"
1431              fi
1432
1433              gt_save_LIBS="$LIBS"
1434              LIBS="$LIBS $INTLLIBS"
1435              AC_CHECK_FUNCS(dcgettext)
1436              LIBS="$gt_save_LIBS"
1437
1438              dnl Search for GNU msgfmt in the PATH.
1439              AM_PATH_PROG_WITH_TEST(MSGFMT, msgfmt,
1440                [$ac_dir/$ac_word --statistics /dev/null >/dev/null 2>&1], :)
1441              AC_PATH_PROG(GMSGFMT, gmsgfmt, $MSGFMT)
1442
1443              dnl Search for GNU xgettext in the PATH.
1444              AM_PATH_PROG_WITH_TEST(XGETTEXT, xgettext,
1445                [$ac_dir/$ac_word --omit-header /dev/null >/dev/null 2>&1], :)
1446
1447              CATOBJEXT=.gmo
1448            fi
1449         ])
1450
1451         if test "$CATOBJEXT" = "NONE"; then
1452           dnl GNU gettext is not found in the C library.
1453           dnl Fall back on GNU gettext library.
1454           nls_cv_use_gnu_gettext=yes
1455         fi
1456       fi
1457
1458       if test "$nls_cv_use_gnu_gettext" = "yes"; then
1459         dnl Mark actions used to generate GNU NLS library.
1460         INTLOBJS="\$(GETTOBJS)"
1461         AM_PATH_PROG_WITH_TEST(MSGFMT, msgfmt,
1462           [$ac_dir/$ac_word --statistics /dev/null >/dev/null 2>&1], :)
1463         AC_PATH_PROG(GMSGFMT, gmsgfmt, $MSGFMT)
1464         AM_PATH_PROG_WITH_TEST(XGETTEXT, xgettext,
1465           [$ac_dir/$ac_word --omit-header /dev/null >/dev/null 2>&1], :)
1466         AC_SUBST(MSGFMT)
1467         BUILD_INCLUDED_LIBINTL=yes
1468         USE_INCLUDED_LIBINTL=yes
1469         CATOBJEXT=.gmo
1470         INTLLIBS="ifelse([$3],[],\$(top_builddir)/intl,[$3])/libintl.ifelse([$1], use-libtool, [l], [])a $LIBICONV"
1471         INTLDEPS="ifelse([$3],[],\$(top_builddir)/intl,[$3])/libintl.ifelse([$1], use-libtool, [l], [])a"
1472         LIBS=`echo " $LIBS " | sed -e 's/ -lintl / /' -e 's/^ //' -e 's/ $//'`
1473       fi
1474
1475       dnl This could go away some day; the PATH_PROG_WITH_TEST already does it.
1476       dnl Test whether we really found GNU msgfmt.
1477       if test "$GMSGFMT" != ":"; then
1478         dnl If it is no GNU msgfmt we define it as : so that the
1479         dnl Makefiles still can work.
1480         if $GMSGFMT --statistics /dev/null >/dev/null 2>&1; then
1481           : ;
1482         else
1483           AC_MSG_RESULT(
1484             [found msgfmt program is not GNU msgfmt; ignore it])
1485           GMSGFMT=":"
1486         fi
1487       fi
1488
1489       dnl This could go away some day; the PATH_PROG_WITH_TEST already does it.
1490       dnl Test whether we really found GNU xgettext.
1491       if test "$XGETTEXT" != ":"; then
1492         dnl If it is no GNU xgettext we define it as : so that the
1493         dnl Makefiles still can work.
1494         if $XGETTEXT --omit-header /dev/null >/dev/null 2>&1; then
1495           : ;
1496         else
1497           AC_MSG_RESULT(
1498             [found xgettext program is not GNU xgettext; ignore it])
1499           XGETTEXT=":"
1500         fi
1501       fi
1502
1503       dnl We need to process the po/ directory.
1504       POSUB=po
1505     fi
1506     AC_OUTPUT_COMMANDS(
1507      [for ac_file in $CONFIG_FILES; do
1508         # Support "outfile[:infile[:infile...]]"
1509         case "$ac_file" in
1510           *:*) ac_file=`echo "$ac_file"|sed 's%:.*%%'` ;;
1511         esac
1512         # PO directories have a Makefile.in generated from Makefile.in.in.
1513         case "$ac_file" in */Makefile.in)
1514           # Adjust a relative srcdir.
1515           ac_dir=`echo "$ac_file"|sed 's%/[^/][^/]*$%%'`
1516           ac_dir_suffix="/`echo "$ac_dir"|sed 's%^\./%%'`"
1517           ac_dots=`echo "$ac_dir_suffix"|sed 's%/[^/]*%../%g'`
1518           # In autoconf-2.13 it is called $ac_given_srcdir.
1519           # In autoconf-2.50 it is called $srcdir.
1520           test -n "$ac_given_srcdir" || ac_given_srcdir="$srcdir"
1521           case "$ac_given_srcdir" in
1522             .)  top_srcdir=`echo $ac_dots|sed 's%/$%%'` ;;
1523             /*) top_srcdir="$ac_given_srcdir" ;;
1524             *)  top_srcdir="$ac_dots$ac_given_srcdir" ;;
1525           esac
1526           if test -f "$ac_given_srcdir/$ac_dir/POTFILES.in"; then
1527             rm -f "$ac_dir/POTFILES"
1528             test -n "$as_me" && echo "$as_me: creating $ac_dir/POTFILES" || echo "creating $ac_dir/POTFILES"
1529             sed -e "/^#/d" -e "/^[      ]*\$/d" -e "s,.*,     $top_srcdir/& \\\\," -e "\$s/\(.*\) \\\\/\1/" < "$ac_given_srcdir/$ac_dir/POTFILES.in" > "$ac_dir/POTFILES"
1530             test -n "$as_me" && echo "$as_me: creating $ac_dir/Makefile" || echo "creating $ac_dir/Makefile"
1531             sed -e "/POTFILES =/r $ac_dir/POTFILES" "$ac_dir/Makefile.in" > "$ac_dir/Makefile"
1532           fi
1533           ;;
1534         esac
1535       done])
1536
1537
1538     dnl If this is used in GNU gettext we have to set BUILD_INCLUDED_LIBINTL
1539     dnl to 'yes' because some of the testsuite requires it.
1540     if test "$PACKAGE" = gettext; then
1541       BUILD_INCLUDED_LIBINTL=yes
1542     fi
1543
1544     dnl intl/plural.c is generated from intl/plural.y. It requires bison,
1545     dnl because plural.y uses bison specific features. It requires at least
1546     dnl bison-1.26 because earlier versions generate a plural.c that doesn't
1547     dnl compile.
1548     dnl bison is only needed for the maintainer (who touches plural.y). But in
1549     dnl order to avoid separate Makefiles or --enable-maintainer-mode, we put
1550     dnl the rule in general Makefile. Now, some people carelessly touch the
1551     dnl files or have a broken "make" program, hence the plural.c rule will
1552     dnl sometimes fire. To avoid an error, defines BISON to ":" if it is not
1553     dnl present or too old.
1554     AC_CHECK_PROGS([INTLBISON], [bison])
1555     if test -z "$INTLBISON"; then
1556       ac_verc_fail=yes
1557     else
1558       dnl Found it, now check the version.
1559       AC_MSG_CHECKING([version of bison])
1560 changequote(<<,>>)dnl
1561       ac_prog_version=`$INTLBISON --version 2>&1 | sed -n 's/^.*GNU Bison.* \([0-9]*\.[0-9.]*\).*$/\1/p'`
1562       case $ac_prog_version in
1563         '') ac_prog_version="v. ?.??, bad"; ac_verc_fail=yes;;
1564         1.2[6-9]* | 1.[3-9][0-9]* | [2-9].*)
1565 changequote([,])dnl
1566            ac_prog_version="$ac_prog_version, ok"; ac_verc_fail=no;;
1567         *) ac_prog_version="$ac_prog_version, bad"; ac_verc_fail=yes;;
1568       esac
1569       AC_MSG_RESULT([$ac_prog_version])
1570     fi
1571     if test $ac_verc_fail = yes; then
1572       INTLBISON=:
1573     fi
1574
1575     dnl GCC LOCAL: GMOFILES/POFILES removed as unnecessary.
1576
1577     dnl Make all variables we use known to autoconf.
1578     AC_SUBST(BUILD_INCLUDED_LIBINTL)
1579     AC_SUBST(USE_INCLUDED_LIBINTL)
1580     AC_SUBST(CATALOGS)
1581     AC_SUBST(CATOBJEXT)
1582     AC_SUBST(INTLLIBS)
1583     AC_SUBST(INTLDEPS)
1584     AC_SUBST(INTLOBJS)
1585     AC_SUBST(POSUB)
1586 dnl GCC LOCAL: Make USE_INCLUDED_LIBINTL visible to C code.
1587     if test $USE_INCLUDED_LIBINTL = yes; then
1588       AC_DEFINE([USE_INCLUDED_LIBINTL], 1,
1589   [Define to use the libintl included with this package instead of any
1590    version in the system libraries.])
1591     fi
1592
1593     dnl For backward compatibility. Some configure.ins may be using this.
1594     nls_cv_header_intl=
1595     nls_cv_header_libgt=
1596
1597     dnl For backward compatibility. Some Makefiles may be using this.
1598     DATADIRNAME=share
1599     AC_SUBST(DATADIRNAME)
1600
1601     dnl For backward compatibility. Some Makefiles may be using this.
1602     INSTOBJEXT=.mo
1603     AC_SUBST(INSTOBJEXT)
1604
1605     dnl For backward compatibility. Some Makefiles may be using this.
1606     GENCAT=gencat
1607     AC_SUBST(GENCAT)
1608   ])
1609
1610 dnl Usage: Just like AM_WITH_NLS, which see.
1611 AC_DEFUN([AM_GNU_GETTEXT],
1612   [AC_REQUIRE([AC_PROG_MAKE_SET])dnl
1613    AC_REQUIRE([AC_PROG_CC])dnl
1614    AC_REQUIRE([AC_CANONICAL_HOST])dnl
1615    AC_REQUIRE([AC_PROG_RANLIB])dnl
1616    AC_REQUIRE([AC_ISC_POSIX])dnl
1617    AC_REQUIRE([AC_HEADER_STDC])dnl
1618    AC_REQUIRE([AC_C_CONST])dnl
1619    AC_REQUIRE([AC_C_INLINE])dnl
1620    AC_REQUIRE([AC_TYPE_OFF_T])dnl
1621    AC_REQUIRE([AC_TYPE_SIZE_T])dnl
1622    AC_REQUIRE([AC_FUNC_ALLOCA])dnl
1623 dnl GCC LOCAL: Do not refer to AC_FUNC_MMAP, we have special needs.
1624 dnl   AC_REQUIRE([AC_FUNC_MMAP])dnl
1625    AC_REQUIRE([jm_GLIBC21])dnl
1626
1627    AC_CHECK_HEADERS([argz.h limits.h locale.h nl_types.h malloc.h stddef.h \
1628 stdlib.h string.h unistd.h sys/param.h])
1629    AC_CHECK_FUNCS([feof_unlocked fgets_unlocked getcwd getegid geteuid \
1630 getgid getuid mempcpy munmap putenv setenv setlocale stpcpy strchr strcasecmp \
1631 strdup strtoul tsearch __argz_count __argz_stringify __argz_next])
1632
1633    AM_ICONV
1634    AM_LANGINFO_CODESET
1635    AM_LC_MESSAGES
1636    AM_WITH_NLS([$1],[$2],[$3])
1637
1638    dnl GCC LOCAL: The LINGUAS/ALL_LINGUAS/CATALOGS mess that was here
1639    dnl has been torn out and replaced with this more sensible scheme.
1640    if test "x$CATOBJEXT" != x; then
1641      AC_MSG_CHECKING(for catalogs to be installed)
1642      # Look for .po and .gmo files in the source directory.
1643      CATALOGS=
1644      XLINGUAS=
1645      for cat in $srcdir/po/*$CATOBJEXT $srcdir/po/*.po; do
1646         # If there aren't any .gmo files the shell will give us the
1647         # literal string "../path/to/srcdir/po/*.gmo" which has to be
1648         # weeded out.
1649         case "$cat" in *\**)
1650             continue;;
1651         esac
1652         # The quadruple backslash is collapsed to a double backslash
1653         # by the backticks, then collapsed again by the double quotes,
1654         # leaving us with one backslash in the sed expression (right
1655         # before the dot that mustn't act as a wildcard).  The dot to
1656         # be escaped in the second expression is hiding inside CATOBJEXT.
1657         cat=`echo $cat | sed -e "s!$srcdir/!!" -e "s!\\\\.po!$CATOBJEXT!"`
1658         lang=`echo $cat | sed -e 's!po/!!' -e "s!\\\\$CATOBJEXT!!"`
1659         # The user is allowed to set LINGUAS to a list of languages to
1660         # install catalogs for.  If it's empty that means "all of them."
1661         if test "x$LINGUAS" = x; then
1662             CATALOGS="$CATALOGS $cat"
1663             XLINGUAS="$XLINGUAS $lang"
1664         else
1665           case "$LINGUAS" in *$lang*)
1666             CATALOGS="$CATALOGS $cat"
1667             XLINGUAS="$XLINGUAS $lang"
1668             ;;
1669           esac
1670         fi
1671      done
1672      LINGUAS="$XLINGUAS"
1673      AC_MSG_RESULT($LINGUAS)
1674    fi
1675
1676    dnl If the AC_CONFIG_AUX_DIR macro for autoconf is used we possibly
1677    dnl find the mkinstalldirs script in another subdir but $(top_srcdir).
1678    dnl Try to locate is.
1679    MKINSTALLDIRS=
1680    if test -n "$ac_aux_dir"; then
1681      MKINSTALLDIRS="$ac_aux_dir/mkinstalldirs"
1682    fi
1683    if test -z "$MKINSTALLDIRS"; then
1684      MKINSTALLDIRS="\$(top_srcdir)/mkinstalldirs"
1685    fi
1686    AC_SUBST(MKINSTALLDIRS)
1687
1688    dnl Enable libtool support if the surrounding package wishes it.
1689    INTL_LIBTOOL_SUFFIX_PREFIX=ifelse([$1], use-libtool, [l], [])
1690    AC_SUBST(INTL_LIBTOOL_SUFFIX_PREFIX)
1691   ])