gcc/ada/a-cuprqu.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --                 ADA.CONTAINERS.UNBOUNDED_PRIORITY_QUEUES                 --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --            Copyright (C) 2011, Free Software Foundation, Inc.            --
  10 --                                                                          --
  11 -- This specification is derived from the Ada Reference Manual for use with --
  12 -- GNAT. The copyright notice above, and the license provisions that follow --
  13 -- apply solely to the  contents of the part following the private keyword. --
  14 --                                                                          --
  15 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  16 -- terms of the  GNU General Public License as published  by the Free Soft- --
  17 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  18 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  19 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  20 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  21 --                                                                          --
  22 -- As a special exception under Section 7 of GPL version 3, you are granted --
  23 -- additional permissions described in the GCC Runtime Library Exception,   --
  24 -- version 3.1, as published by the Free Software Foundation.               --
  25 --                                                                          --
  26 -- You should have received a copy of the GNU General Public License and    --
  27 -- a copy of the GCC Runtime Library Exception along with this program;     --
  28 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  29 -- <http://www.gnu.org/licenses/>.                                          --
  30 --                                                                          --
  31 -- This unit was originally developed by Matthew J Heaney.                  --
  32 ------------------------------------------------------------------------------
  33
  34 with System;
  35 with Ada.Containers.Synchronized_Queue_Interfaces;
  36 with Ada.Finalization;
  37
  38 generic
  39    with package Queue_Interfaces is
  40      new Ada.Containers.Synchronized_Queue_Interfaces (<>);
  41
  42    type Queue_Priority is private;
  43
  44    with function Get_Priority
  45      (Element : Queue_Interfaces.Element_Type) return Queue_Priority is <>;
  46
  47    with function Before
  48      (Left, Right : Queue_Priority) return Boolean is <>;
  49
  50    Default_Ceiling : System.Any_Priority := System.Priority'Last;
  51
  52 package Ada.Containers.Unbounded_Priority_Queues is
  53    pragma Preelaborate;
  54
  55    --  All identifiers in this unit are implementation defined
  56
  57    pragma Implementation_Defined;
  58
  59    package Implementation is
  60
  61       type List_Type is tagged limited private;
  62
  63       procedure Enqueue
  64         (List     : in out List_Type;
  65          New_Item : Queue_Interfaces.Element_Type);
  66
  67       procedure Dequeue
  68         (List    : in out List_Type;
  69          Element : out Queue_Interfaces.Element_Type);
  70
  71       function Length (List : List_Type) return Count_Type;
  72
  73       function Max_Length (List : List_Type) return Count_Type;
  74
  75    private
  76
  77       type Node_Type;
  78       type Node_Access is access Node_Type;
  79
  80       type Node_Type is limited record
  81          Element : Queue_Interfaces.Element_Type;
  82          Next    : Node_Access;
  83       end record;
  84
  85       type List_Type is new Ada.Finalization.Limited_Controlled with record
  86          First, Last : Node_Access;
  87          Length      : Count_Type := 0;
  88          Max_Length  : Count_Type := 0;
  89       end record;
  90
  91       overriding
  92       procedure Finalize (List : in out List_Type);
  93
  94       --  ???
  95       --  not overriding
  96       --  function Have_High_Priority
  97       --    (List         : List_Type;
  98       --     Low_Priority : Queue_Priority) return Boolean;
  99
 100    end Implementation;
 101
 102    protected type Queue (Ceiling : System.Any_Priority := Default_Ceiling)
 103      --  ???
 104      --  with Priority => Ceiling is new Queue_Interfaces.Queue with
 105      is new Queue_Interfaces.Queue with
 106
 107      overriding
 108      entry Enqueue (New_Item : Queue_Interfaces.Element_Type);
 109
 110      overriding
 111      entry Dequeue (Element : out Queue_Interfaces.Element_Type);
 112
 113      --  ???
 114      --  not overriding
 115      --  entry Dequeue_Only_High_Priority
 116      --    (Low_Priority : Queue_Priority;
 117      --     Element      : out Queue_Interfaces.Element_Type);
 118
 119      overriding
 120      function Current_Use return Count_Type;
 121
 122      overriding
 123      function Peak_Use return Count_Type;
 124
 125    private
 126
 127       List : Implementation.List_Type;
 128
 129    end Queue;
 130
 131 end Ada.Containers.Unbounded_Priority_Queues;