gcc/ada/exp_spark.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                            E X P _ S P A R K                             --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2020, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Checks;   use Checks;
  28 with Einfo;    use Einfo;
  29 with Exp_Attr;
  30 with Exp_Ch4;
  31 with Exp_Ch5;  use Exp_Ch5;
  32 with Exp_Dbug; use Exp_Dbug;
  33 with Exp_Util; use Exp_Util;
  34 with Namet;    use Namet;
  35 with Nlists;   use Nlists;
  36 with Nmake;    use Nmake;
  37 with Rtsfind;  use Rtsfind;
  38 with Sem;      use Sem;
  39 with Sem_Prag; use Sem_Prag;
  40 with Sem_Res;  use Sem_Res;
  41 with Sem_Util; use Sem_Util;
  42 with Sinfo;    use Sinfo;
  43 with Snames;   use Snames;
  44 with Stand;    use Stand;
  45 with Tbuild;   use Tbuild;
  46 with Uintp;    use Uintp;
  47
  48 package body Exp_SPARK is
  49
  50    -----------------------
  51    -- Local Subprograms --
  52    -----------------------
  53
  54    procedure Expand_SPARK_N_Attribute_Reference (N : Node_Id);
  55    --  Perform attribute-reference-specific expansion
  56
  57    procedure Expand_SPARK_N_Freeze_Type (E : Entity_Id);
  58    --  Build the DIC procedure of a type when needed, if not already done
  59
  60    procedure Expand_SPARK_N_Loop_Statement (N : Node_Id);
  61    --  Perform loop-statement-specific expansion
  62
  63    procedure Expand_SPARK_N_Object_Declaration (N : Node_Id);
  64    --  Perform object-declaration-specific expansion
  65
  66    procedure Expand_SPARK_N_Object_Renaming_Declaration (N : Node_Id);
  67    --  Perform name evaluation for a renamed object
  68
  69    procedure Expand_SPARK_N_Op_Ne (N : Node_Id);
  70    --  Rewrite operator /= based on operator = when defined explicitly
  71
  72    ------------------
  73    -- Expand_SPARK --
  74    ------------------
  75
  76    procedure Expand_SPARK (N : Node_Id) is
  77    begin
  78       case Nkind (N) is
  79
  80          --  Qualification of entity names in formal verification mode
  81          --  is limited to the addition of a suffix for homonyms (see
  82          --  Exp_Dbug.Qualify_Entity_Name). We used to qualify entity names
  83          --  as full expansion does, but this was removed as this prevents the
  84          --  verification back-end from using a short name for debugging and
  85          --  user interaction. The verification back-end already takes care
  86          --  of qualifying names when needed.
  87
  88          when N_Block_Statement
  89             | N_Entry_Declaration
  90             | N_Package_Body
  91             | N_Package_Declaration
  92             | N_Protected_Type_Declaration
  93             | N_Subprogram_Body
  94             | N_Task_Type_Declaration
  95          =>
  96             Qualify_Entity_Names (N);
  97
  98          --  Replace occurrences of System'To_Address by calls to
  99          --  System.Storage_Elements.To_Address.
 100
 101          when N_Attribute_Reference =>
 102             Expand_SPARK_N_Attribute_Reference (N);
 103
 104          when N_Expanded_Name
 105             | N_Identifier
 106          =>
 107             Expand_SPARK_Potential_Renaming (N);
 108
 109          --  Loop iterations over arrays need to be expanded, to avoid getting
 110          --  two names referring to the same object in memory (the array and
 111          --  the iterator) in GNATprove, especially since both can be written
 112          --  (thus possibly leading to interferences due to aliasing). No such
 113          --  problem arises with quantified expressions over arrays, which are
 114          --  dealt with specially in GNATprove.
 115
 116          when N_Loop_Statement =>
 117             Expand_SPARK_N_Loop_Statement (N);
 118
 119          when N_Object_Declaration =>
 120             Expand_SPARK_N_Object_Declaration (N);
 121
 122          when N_Object_Renaming_Declaration =>
 123             Expand_SPARK_N_Object_Renaming_Declaration (N);
 124
 125          when N_Op_Ne =>
 126             Expand_SPARK_N_Op_Ne (N);
 127
 128          when N_Freeze_Entity =>
 129             if Is_Type (Entity (N)) then
 130                Expand_SPARK_N_Freeze_Type (Entity (N));
 131             end if;
 132
 133          --  In SPARK mode, no other constructs require expansion
 134
 135          when others =>
 136             null;
 137       end case;
 138    end Expand_SPARK;
 139
 140    --------------------------------
 141    -- Expand_SPARK_N_Freeze_Type --
 142    --------------------------------
 143
 144    procedure Expand_SPARK_N_Freeze_Type (E : Entity_Id) is
 145    begin
 146       --  When a DIC is inherited by a tagged type, it may need to be
 147       --  specialized to the descendant type, hence build a separate DIC
 148       --  procedure for it as done during regular expansion for compilation.
 149
 150       if Has_DIC (E) and then Is_Tagged_Type (E) then
 151          Build_DIC_Procedure_Body (E, For_Freeze => True);
 152       end if;
 153    end Expand_SPARK_N_Freeze_Type;
 154
 155    ----------------------------------------
 156    -- Expand_SPARK_N_Attribute_Reference --
 157    ----------------------------------------
 158
 159    procedure Expand_SPARK_N_Attribute_Reference (N : Node_Id) is
 160       Aname   : constant Name_Id      := Attribute_Name (N);
 161       Attr_Id : constant Attribute_Id := Get_Attribute_Id (Aname);
 162       Loc     : constant Source_Ptr   := Sloc (N);
 163       Pref    : constant Node_Id      := Prefix (N);
 164       Typ     : constant Entity_Id    := Etype (N);
 165       Expr    : Node_Id;
 166
 167    begin
 168       if Attr_Id = Attribute_To_Address then
 169
 170          --  Extract and convert argument to expected type for call
 171
 172          Expr :=
 173            Make_Type_Conversion (Loc,
 174              Subtype_Mark =>
 175                New_Occurrence_Of (RTE (RE_Integer_Address), Loc),
 176              Expression   => Relocate_Node (First (Expressions (N))));
 177
 178          --  Replace attribute reference with call
 179
 180          Rewrite (N,
 181            Make_Function_Call (Loc,
 182              Name                   =>
 183                New_Occurrence_Of (RTE (RE_To_Address), Loc),
 184              Parameter_Associations => New_List (Expr)));
 185          Analyze_And_Resolve (N, Typ);
 186
 187       elsif Attr_Id = Attribute_Object_Size
 188         or else Attr_Id = Attribute_Size
 189         or else Attr_Id = Attribute_Value_Size
 190         or else Attr_Id = Attribute_VADS_Size
 191       then
 192          Exp_Attr.Expand_Size_Attribute (N);
 193
 194       --  For attributes which return Universal_Integer, introduce a conversion
 195       --  to the expected type with the appropriate check flags set.
 196
 197       elsif Attr_Id = Attribute_Alignment
 198         or else Attr_Id = Attribute_Bit
 199         or else Attr_Id = Attribute_Bit_Position
 200         or else Attr_Id = Attribute_Descriptor_Size
 201         or else Attr_Id = Attribute_First_Bit
 202         or else Attr_Id = Attribute_Last_Bit
 203         or else Attr_Id = Attribute_Length
 204         or else Attr_Id = Attribute_Max_Size_In_Storage_Elements
 205         or else Attr_Id = Attribute_Pos
 206         or else Attr_Id = Attribute_Position
 207         or else Attr_Id = Attribute_Range_Length
 208         or else Attr_Id = Attribute_Aft
 209         or else Attr_Id = Attribute_Max_Alignment_For_Allocation
 210       then
 211          --  If the expected type is Long_Long_Integer, there will be no check
 212          --  flag as the compiler assumes attributes always fit in this type.
 213          --  Since in SPARK_Mode we do not take Storage_Error into account, we
 214          --  cannot make this assumption and need to produce a check.
 215          --  ??? It should be enough to add this check for attributes 'Length
 216          --  and 'Range_Length when the type is as big as Long_Long_Integer.
 217
 218          declare
 219             Typ : Entity_Id;
 220          begin
 221             if Attr_Id = Attribute_Range_Length then
 222                Typ := Etype (Prefix (N));
 223
 224             elsif Attr_Id = Attribute_Length then
 225                Typ := Get_Index_Subtype (N);
 226
 227             else
 228                Typ := Empty;
 229             end if;
 230
 231             Apply_Universal_Integer_Attribute_Checks (N);
 232
 233             if Present (Typ)
 234               and then RM_Size (Typ) = RM_Size (Standard_Long_Long_Integer)
 235             then
 236                Set_Do_Overflow_Check (N);
 237             end if;
 238          end;
 239
 240       elsif Attr_Id = Attribute_Constrained then
 241
 242          --  If the prefix is an access to object, the attribute applies to
 243          --  the designated object, so rewrite with an explicit dereference.
 244
 245          if Is_Access_Type (Etype (Pref))
 246            and then
 247              (not Is_Entity_Name (Pref) or else Is_Object (Entity (Pref)))
 248          then
 249             Rewrite (Pref,
 250                      Make_Explicit_Dereference (Loc, Relocate_Node (Pref)));
 251             Analyze_And_Resolve (N, Standard_Boolean);
 252          end if;
 253
 254       elsif Attr_Id = Attribute_Update then
 255          declare
 256             Aggr : constant Node_Id := First (Expressions (N));
 257             --  The aggregate expression
 258
 259             Assoc     : Node_Id;
 260             Comp      : Node_Id;
 261             Comp_Type : Node_Id;
 262             Expr      : Node_Id;
 263
 264          begin
 265             --  Apply scalar range checks on the updated components, if needed
 266
 267             if Is_Array_Type (Typ) then
 268                Assoc := First (Component_Associations (Aggr));
 269
 270                while Present (Assoc) loop
 271                   Expr      := Expression (Assoc);
 272                   Comp_Type := Component_Type (Typ);
 273
 274                   if Is_Scalar_Type (Comp_Type) then
 275                      Apply_Scalar_Range_Check (Expr, Comp_Type);
 276                   end if;
 277
 278                   Next (Assoc);
 279                end loop;
 280
 281             else pragma Assert (Is_Record_Type (Typ));
 282
 283                Assoc := First (Component_Associations (Aggr));
 284                while Present (Assoc) loop
 285                   Expr      := Expression (Assoc);
 286                   Comp      := First (Choices (Assoc));
 287                   Comp_Type := Etype (Entity (Comp));
 288
 289                   --  Use the type of the first component from the Choices
 290                   --  list, as multiple components can only appear there if
 291                   --  they have exactly the same type.
 292
 293                   if Is_Scalar_Type (Comp_Type) then
 294                      Apply_Scalar_Range_Check (Expr, Comp_Type);
 295                   end if;
 296
 297                   Next (Assoc);
 298                end loop;
 299             end if;
 300          end;
 301       end if;
 302    end Expand_SPARK_N_Attribute_Reference;
 303
 304    -----------------------------------
 305    -- Expand_SPARK_N_Loop_Statement --
 306    -----------------------------------
 307
 308    procedure Expand_SPARK_N_Loop_Statement (N : Node_Id) is
 309       Scheme : constant Node_Id := Iteration_Scheme (N);
 310
 311    begin
 312       --  Loop iterations over arrays need to be expanded, to avoid getting
 313       --  two names referring to the same object in memory (the array and the
 314       --  iterator) in GNATprove, especially since both can be written (thus
 315       --  possibly leading to interferences due to aliasing). No such problem
 316       --  arises with quantified expressions over arrays, which are dealt with
 317       --  specially in GNATprove.
 318
 319       if Present (Scheme)
 320         and then Present (Iterator_Specification (Scheme))
 321         and then Is_Iterator_Over_Array (Iterator_Specification (Scheme))
 322       then
 323          Expand_Iterator_Loop_Over_Array (N);
 324       end if;
 325    end Expand_SPARK_N_Loop_Statement;
 326
 327    ---------------------------------------
 328    -- Expand_SPARK_N_Object_Declaration --
 329    ---------------------------------------
 330
 331    procedure Expand_SPARK_N_Object_Declaration (N : Node_Id) is
 332       Loc    : constant Source_Ptr := Sloc (N);
 333       Obj_Id : constant Entity_Id  := Defining_Identifier (N);
 334       Typ    : constant Entity_Id  := Etype (Obj_Id);
 335
 336       Call : Node_Id;
 337
 338    begin
 339       --  If the object declaration denotes a variable without initialization
 340       --  whose type is subject to pragma Default_Initial_Condition, create
 341       --  and analyze a dummy call to the DIC procedure of the type in order
 342       --  to detect potential elaboration issues.
 343
 344       if Comes_From_Source (Obj_Id)
 345         and then Ekind (Obj_Id) = E_Variable
 346         and then Has_DIC (Typ)
 347         and then Present (DIC_Procedure (Typ))
 348         and then not Has_Init_Expression (N)
 349       then
 350          Call := Build_DIC_Call (Loc, Obj_Id, Typ);
 351
 352          --  Partially insert the call into the tree by setting its parent
 353          --  pointer.
 354
 355          Set_Parent (Call, N);
 356          Analyze (Call);
 357       end if;
 358    end Expand_SPARK_N_Object_Declaration;
 359
 360    ------------------------------------------------
 361    -- Expand_SPARK_N_Object_Renaming_Declaration --
 362    ------------------------------------------------
 363
 364    procedure Expand_SPARK_N_Object_Renaming_Declaration (N : Node_Id) is
 365       CFS    : constant Boolean    := Comes_From_Source (N);
 366       Loc    : constant Source_Ptr := Sloc (N);
 367       Obj_Id : constant Entity_Id  := Defining_Entity (N);
 368       Nam    : constant Node_Id    := Name (N);
 369       Typ    : constant Entity_Id  := Etype (Obj_Id);
 370
 371    begin
 372       --  Transform a renaming of the form
 373
 374       --    Obj_Id : <subtype mark> renames <function call>;
 375
 376       --  into
 377
 378       --    Obj_Id : constant <subtype mark> := <function call>;
 379
 380       --  Invoking Evaluate_Name and ultimately Remove_Side_Effects introduces
 381       --  a temporary to capture the function result. Once potential renamings
 382       --  are rewritten for SPARK, the temporary may be leaked out into source
 383       --  constructs and lead to confusing error diagnostics. Using an object
 384       --  declaration prevents this unwanted side effect.
 385
 386       if Nkind (Nam) = N_Function_Call then
 387          Rewrite (N,
 388            Make_Object_Declaration (Loc,
 389              Defining_Identifier => Obj_Id,
 390              Constant_Present    => True,
 391              Object_Definition   => New_Occurrence_Of (Typ, Loc),
 392              Expression          => Nam));
 393
 394          --  Inherit the original Comes_From_Source status of the renaming
 395
 396          Set_Comes_From_Source (N, CFS);
 397
 398          --  Sever the link to the renamed function result because the entity
 399          --  will no longer alias anything.
 400
 401          Set_Renamed_Object (Obj_Id, Empty);
 402
 403          --  Remove the entity of the renaming declaration from visibility as
 404          --  the analysis of the object declaration will reintroduce it again.
 405
 406          Remove_Entity_And_Homonym (Obj_Id);
 407          Analyze (N);
 408
 409       --  Otherwise unconditionally remove all side effects from the name
 410
 411       else
 412          Evaluate_Name (Nam);
 413       end if;
 414    end Expand_SPARK_N_Object_Renaming_Declaration;
 415
 416    --------------------------
 417    -- Expand_SPARK_N_Op_Ne --
 418    --------------------------
 419
 420    procedure Expand_SPARK_N_Op_Ne (N : Node_Id) is
 421       Typ : constant Entity_Id := Etype (Left_Opnd (N));
 422
 423    begin
 424       --  Case of elementary type with standard operator
 425
 426       if Is_Elementary_Type (Typ)
 427         and then Sloc (Entity (N)) = Standard_Location
 428       then
 429          null;
 430
 431       else
 432          Exp_Ch4.Expand_N_Op_Ne (N);
 433       end if;
 434    end Expand_SPARK_N_Op_Ne;
 435
 436    -------------------------------------
 437    -- Expand_SPARK_Potential_Renaming --
 438    -------------------------------------
 439
 440    procedure Expand_SPARK_Potential_Renaming (N : Node_Id) is
 441       function In_Insignificant_Pragma (Nod : Node_Id) return Boolean;
 442       --  Determine whether arbitrary node Nod appears within a significant
 443       --  pragma for SPARK.
 444
 445       -----------------------------
 446       -- In_Insignificant_Pragma --
 447       -----------------------------
 448
 449       function In_Insignificant_Pragma (Nod : Node_Id) return Boolean is
 450          Par : Node_Id;
 451
 452       begin
 453          --  Climb the parent chain looking for an enclosing pragma
 454
 455          Par := Nod;
 456          while Present (Par) loop
 457             if Nkind (Par) = N_Pragma then
 458                return not Pragma_Significant_In_SPARK (Get_Pragma_Id (Par));
 459
 460             --  Prevent the search from going too far
 461
 462             elsif Is_Body_Or_Package_Declaration (Par) then
 463                exit;
 464             end if;
 465
 466             Par := Parent (Par);
 467          end loop;
 468
 469          return False;
 470       end In_Insignificant_Pragma;
 471
 472       --  Local variables
 473
 474       Loc    : constant Source_Ptr := Sloc (N);
 475       Obj_Id : constant Entity_Id  := Entity (N);
 476       Typ    : constant Entity_Id  := Etype (N);
 477       Ren    : Node_Id;
 478
 479    --  Start of processing for Expand_SPARK_Potential_Renaming
 480
 481    begin
 482       --  Replace a reference to a renaming with the actual renamed object
 483
 484       if Is_Object (Obj_Id) then
 485          Ren := Renamed_Object (Obj_Id);
 486
 487          if Present (Ren) then
 488
 489             --  Do not process a reference when it appears within a pragma of
 490             --  no significance to SPARK. It is assumed that the replacement
 491             --  will violate the semantics of the pragma and cause a spurious
 492             --  error.
 493
 494             if In_Insignificant_Pragma (N) then
 495                return;
 496
 497             --  Instantiations and inlining of subprograms employ "prologues"
 498             --  which map actual to formal parameters by means of renamings.
 499             --  Replace a reference to a formal by the corresponding actual
 500             --  parameter.
 501
 502             elsif Nkind (Ren) in N_Entity then
 503                Rewrite (N, New_Occurrence_Of (Ren, Loc));
 504
 505             --  Otherwise the renamed object denotes a name
 506
 507             else
 508                Rewrite (N, New_Copy_Tree (Ren, New_Sloc => Loc));
 509                Reset_Analyzed_Flags (N);
 510             end if;
 511
 512             Analyze_And_Resolve (N, Typ);
 513          end if;
 514       end if;
 515    end Expand_SPARK_Potential_Renaming;
 516
 517 end Exp_SPARK;