gcc/ada/exp_spark.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                            E X P _ S P A R K                             --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2017, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Checks;   use Checks;
  28 with Einfo;    use Einfo;
  29 with Exp_Ch4;
  30 with Exp_Ch5;  use Exp_Ch5;
  31 with Exp_Dbug; use Exp_Dbug;
  32 with Exp_Util; use Exp_Util;
  33 with Namet;    use Namet;
  34 with Nlists;   use Nlists;
  35 with Nmake;    use Nmake;
  36 with Rtsfind;  use Rtsfind;
  37 with Sem;      use Sem;
  38 with Sem_Eval; use Sem_Eval;
  39 with Sem_Prag; use Sem_Prag;
  40 with Sem_Res;  use Sem_Res;
  41 with Sem_Util; use Sem_Util;
  42 with Sinfo;    use Sinfo;
  43 with Snames;   use Snames;
  44 with Stand;    use Stand;
  45 with Tbuild;   use Tbuild;
  46 with Uintp;    use Uintp;
  47
  48 package body Exp_SPARK is
  49
  50    -----------------------
  51    -- Local Subprograms --
  52    -----------------------
  53
  54    procedure Expand_SPARK_N_Attribute_Reference (N : Node_Id);
  55    --  Replace occurrences of System'To_Address by calls to
  56    --  System.Storage_Elements.To_Address
  57
  58    procedure Expand_SPARK_Freeze_Type (E : Entity_Id);
  59    --  Build the DIC procedure of a type when needed, if not already done
  60
  61    procedure Expand_SPARK_Indexed_Component (N : Node_Id);
  62    --  Insert explicit dereference if required
  63
  64    procedure Expand_SPARK_N_Loop_Statement (N : Node_Id);
  65    --  Perform loop statement-specific expansion
  66
  67    procedure Expand_SPARK_N_Object_Declaration (N : Node_Id);
  68    --  Perform object-declaration-specific expansion
  69
  70    procedure Expand_SPARK_N_Object_Renaming_Declaration (N : Node_Id);
  71    --  Perform name evaluation for a renamed object
  72
  73    procedure Expand_SPARK_N_Op_Ne (N : Node_Id);
  74    --  Rewrite operator /= based on operator = when defined explicitly
  75
  76    procedure Expand_SPARK_Selected_Component (N : Node_Id);
  77    --  Insert explicit dereference if required
  78
  79    ------------------
  80    -- Expand_SPARK --
  81    ------------------
  82
  83    procedure Expand_SPARK (N : Node_Id) is
  84    begin
  85       case Nkind (N) is
  86
  87          --  Qualification of entity names in formal verification mode
  88          --  is limited to the addition of a suffix for homonyms (see
  89          --  Exp_Dbug.Qualify_Entity_Name). We used to qualify entity names
  90          --  as full expansion does, but this was removed as this prevents the
  91          --  verification back-end from using a short name for debugging and
  92          --  user interaction. The verification back-end already takes care
  93          --  of qualifying names when needed.
  94
  95          when N_Block_Statement
  96             | N_Entry_Declaration
  97             | N_Package_Body
  98             | N_Package_Declaration
  99             | N_Protected_Type_Declaration
 100             | N_Subprogram_Body
 101             | N_Task_Type_Declaration
 102          =>
 103             Qualify_Entity_Names (N);
 104
 105          --  Replace occurrences of System'To_Address by calls to
 106          --  System.Storage_Elements.To_Address.
 107
 108          when N_Attribute_Reference =>
 109             Expand_SPARK_N_Attribute_Reference (N);
 110
 111          when N_Expanded_Name
 112             | N_Identifier
 113          =>
 114             Expand_SPARK_Potential_Renaming (N);
 115
 116          --  Loop iterations over arrays need to be expanded, to avoid getting
 117          --  two names referring to the same object in memory (the array and
 118          --  the iterator) in GNATprove, especially since both can be written
 119          --  (thus possibly leading to interferences due to aliasing). No such
 120          --  problem arises with quantified expressions over arrays, which are
 121          --  dealt with specially in GNATprove.
 122
 123          when N_Loop_Statement =>
 124             Expand_SPARK_N_Loop_Statement (N);
 125
 126          when N_Object_Declaration =>
 127             Expand_SPARK_N_Object_Declaration (N);
 128
 129          when N_Object_Renaming_Declaration =>
 130             Expand_SPARK_N_Object_Renaming_Declaration (N);
 131
 132          when N_Op_Ne =>
 133             Expand_SPARK_N_Op_Ne (N);
 134
 135          when N_Freeze_Entity =>
 136             if Is_Type (Entity (N)) then
 137                Expand_SPARK_Freeze_Type (Entity (N));
 138             end if;
 139
 140          when N_Indexed_Component =>
 141             Expand_SPARK_Indexed_Component (N);
 142
 143          when N_Selected_Component =>
 144             Expand_SPARK_Selected_Component (N);
 145
 146          --  In SPARK mode, no other constructs require expansion
 147
 148          when others =>
 149             null;
 150       end case;
 151    end Expand_SPARK;
 152
 153    ------------------------------
 154    -- Expand_SPARK_Freeze_Type --
 155    ------------------------------
 156
 157    procedure Expand_SPARK_Freeze_Type (E : Entity_Id) is
 158    begin
 159       --  When a DIC is inherited by a tagged type, it may need to be
 160       --  specialized to the descendant type, hence build a separate DIC
 161       --  procedure for it as done during regular expansion for compilation.
 162
 163       if Has_DIC (E) and then Is_Tagged_Type (E) then
 164          Build_DIC_Procedure_Body (E, For_Freeze => True);
 165       end if;
 166    end Expand_SPARK_Freeze_Type;
 167
 168    ----------------------------------------
 169    -- Expand_SPARK_N_Attribute_Reference --
 170    ----------------------------------------
 171
 172    procedure Expand_SPARK_N_Attribute_Reference (N : Node_Id) is
 173       Aname   : constant Name_Id      := Attribute_Name (N);
 174       Attr_Id : constant Attribute_Id := Get_Attribute_Id (Aname);
 175       Loc     : constant Source_Ptr   := Sloc (N);
 176       Typ     : constant Entity_Id    := Etype (N);
 177       Expr    : Node_Id;
 178
 179    begin
 180       if Attr_Id = Attribute_To_Address then
 181
 182          --  Extract and convert argument to expected type for call
 183
 184          Expr :=
 185            Make_Type_Conversion (Loc,
 186              Subtype_Mark =>
 187                New_Occurrence_Of (RTE (RE_Integer_Address), Loc),
 188              Expression   => Relocate_Node (First (Expressions (N))));
 189
 190          --  Replace attribute reference with call
 191
 192          Rewrite (N,
 193            Make_Function_Call (Loc,
 194              Name                   =>
 195                New_Occurrence_Of (RTE (RE_To_Address), Loc),
 196              Parameter_Associations => New_List (Expr)));
 197          Analyze_And_Resolve (N, Typ);
 198
 199       --  For attributes which return Universal_Integer, introduce a conversion
 200       --  to the expected type with the appropriate check flags set.
 201
 202       elsif Attr_Id = Attribute_Alignment
 203         or else Attr_Id = Attribute_Bit
 204         or else Attr_Id = Attribute_Bit_Position
 205         or else Attr_Id = Attribute_Descriptor_Size
 206         or else Attr_Id = Attribute_First_Bit
 207         or else Attr_Id = Attribute_Last_Bit
 208         or else Attr_Id = Attribute_Length
 209         or else Attr_Id = Attribute_Max_Size_In_Storage_Elements
 210         or else Attr_Id = Attribute_Pos
 211         or else Attr_Id = Attribute_Position
 212         or else Attr_Id = Attribute_Range_Length
 213         or else Attr_Id = Attribute_Object_Size
 214         or else Attr_Id = Attribute_Size
 215         or else Attr_Id = Attribute_Value_Size
 216         or else Attr_Id = Attribute_VADS_Size
 217         or else Attr_Id = Attribute_Aft
 218         or else Attr_Id = Attribute_Max_Alignment_For_Allocation
 219       then
 220          --  If the expected type is Long_Long_Integer, there will be no check
 221          --  flag as the compiler assumes attributes always fit in this type.
 222          --  Since in SPARK_Mode we do not take Storage_Error into account, we
 223          --  cannot make this assumption and need to produce a check.
 224          --  ??? It should be enough to add this check for attributes 'Length
 225          --  and 'Range_Length when the type is as big as Long_Long_Integer.
 226
 227          declare
 228             Typ : Entity_Id := Empty;
 229          begin
 230             if Attr_Id = Attribute_Range_Length then
 231                Typ := Etype (Prefix (N));
 232
 233             elsif Attr_Id = Attribute_Length then
 234                Typ := Etype (Prefix (N));
 235
 236                declare
 237                   Indx : Node_Id;
 238                   J    : Int;
 239
 240                begin
 241                   if Is_Access_Type (Typ) then
 242                      Typ := Designated_Type (Typ);
 243                   end if;
 244
 245                   if No (Expressions (N)) then
 246                      J := 1;
 247                   else
 248                      J := UI_To_Int (Expr_Value (First (Expressions (N))));
 249                   end if;
 250
 251                   Indx := First_Index (Typ);
 252                   while J > 1 loop
 253                      Next_Index (Indx);
 254                      J := J - 1;
 255                   end loop;
 256
 257                   Typ := Etype (Indx);
 258                end;
 259             end if;
 260
 261             Apply_Universal_Integer_Attribute_Checks (N);
 262
 263             if Present (Typ)
 264               and then RM_Size (Typ) = RM_Size (Standard_Long_Long_Integer)
 265             then
 266                Set_Do_Overflow_Check (N);
 267             end if;
 268          end;
 269       end if;
 270    end Expand_SPARK_N_Attribute_Reference;
 271
 272    -----------------------------------
 273    -- Expand_SPARK_N_Loop_Statement --
 274    -----------------------------------
 275
 276    procedure Expand_SPARK_N_Loop_Statement (N : Node_Id) is
 277       Scheme : constant Node_Id := Iteration_Scheme (N);
 278
 279    begin
 280       --  Loop iterations over arrays need to be expanded, to avoid getting
 281       --  two names referring to the same object in memory (the array and the
 282       --  iterator) in GNATprove, especially since both can be written (thus
 283       --  possibly leading to interferences due to aliasing). No such problem
 284       --  arises with quantified expressions over arrays, which are dealt with
 285       --  specially in GNATprove.
 286
 287       if Present (Scheme)
 288         and then Present (Iterator_Specification (Scheme))
 289         and then Is_Iterator_Over_Array (Iterator_Specification (Scheme))
 290       then
 291          Expand_Iterator_Loop_Over_Array (N);
 292       end if;
 293    end Expand_SPARK_N_Loop_Statement;
 294
 295    ------------------------------------
 296    -- Expand_SPARK_Indexed_Component --
 297    ------------------------------------
 298
 299    procedure Expand_SPARK_Indexed_Component (N : Node_Id) is
 300       P   : constant Node_Id    := Prefix (N);
 301       T   : constant Entity_Id  := Etype (P);
 302    begin
 303       if Is_Access_Type (T) then
 304          Insert_Explicit_Dereference (P);
 305          Analyze_And_Resolve (P, Designated_Type (T));
 306       end if;
 307    end Expand_SPARK_Indexed_Component;
 308
 309    ---------------------------------------
 310    -- Expand_SPARK_N_Object_Declaration --
 311    ---------------------------------------
 312
 313    procedure Expand_SPARK_N_Object_Declaration (N : Node_Id) is
 314       Loc    : constant Source_Ptr := Sloc (N);
 315       Obj_Id : constant Entity_Id  := Defining_Identifier (N);
 316       Typ    : constant Entity_Id  := Etype (Obj_Id);
 317
 318       Call : Node_Id;
 319
 320    begin
 321       --  If the object declaration denotes a variable without initialization
 322       --  whose type is subject to pragma Default_Initial_Condition, create
 323       --  and analyze a dummy call to the DIC procedure of the type in order
 324       --  to detect potential elaboration issues.
 325
 326       if Comes_From_Source (Obj_Id)
 327         and then Ekind (Obj_Id) = E_Variable
 328         and then Has_DIC (Typ)
 329         and then Present (DIC_Procedure (Typ))
 330         and then not Has_Init_Expression (N)
 331       then
 332          Call := Build_DIC_Call (Loc, Obj_Id, Typ);
 333
 334          --  Partially insert the call into the tree by setting its parent
 335          --  pointer.
 336
 337          Set_Parent (Call, N);
 338          Analyze (Call);
 339       end if;
 340    end Expand_SPARK_N_Object_Declaration;
 341
 342    ------------------------------------------------
 343    -- Expand_SPARK_N_Object_Renaming_Declaration --
 344    ------------------------------------------------
 345
 346    procedure Expand_SPARK_N_Object_Renaming_Declaration (N : Node_Id) is
 347       CFS    : constant Boolean    := Comes_From_Source (N);
 348       Loc    : constant Source_Ptr := Sloc (N);
 349       Obj_Id : constant Entity_Id  := Defining_Entity (N);
 350       Nam    : constant Node_Id    := Name (N);
 351       Typ    : constant Entity_Id  := Etype (Subtype_Mark (N));
 352
 353    begin
 354       --  Transform a renaming of the form
 355
 356       --    Obj_Id : <subtype mark> renames <function call>;
 357
 358       --  into
 359
 360       --    Obj_Id : constant <subtype mark> := <function call>;
 361
 362       --  Invoking Evaluate_Name and ultimately Remove_Side_Effects introduces
 363       --  a temporary to capture the function result. Once potential renamings
 364       --  are rewritten for SPARK, the temporary may be leaked out into source
 365       --  constructs and lead to confusing error diagnostics. Using an object
 366       --  declaration prevents this unwanted side effect.
 367
 368       if Nkind (Nam) = N_Function_Call then
 369          Rewrite (N,
 370            Make_Object_Declaration (Loc,
 371              Defining_Identifier => Obj_Id,
 372              Constant_Present    => True,
 373              Object_Definition   => New_Occurrence_Of (Typ, Loc),
 374              Expression          => Nam));
 375
 376          --  Inherit the original Comes_From_Source status of the renaming
 377
 378          Set_Comes_From_Source (N, CFS);
 379
 380          --  Sever the link to the renamed function result because the entity
 381          --  will no longer alias anything.
 382
 383          Set_Renamed_Object (Obj_Id, Empty);
 384
 385          --  Remove the entity of the renaming declaration from visibility as
 386          --  the analysis of the object declaration will reintroduce it again.
 387
 388          Remove_Entity (Obj_Id);
 389          Analyze (N);
 390
 391       --  Otherwise unconditionally remove all side effects from the name
 392
 393       else
 394          Evaluate_Name (Nam);
 395       end if;
 396    end Expand_SPARK_N_Object_Renaming_Declaration;
 397
 398    --------------------------
 399    -- Expand_SPARK_N_Op_Ne --
 400    --------------------------
 401
 402    procedure Expand_SPARK_N_Op_Ne (N : Node_Id) is
 403       Typ : constant Entity_Id := Etype (Left_Opnd (N));
 404
 405    begin
 406       --  Case of elementary type with standard operator
 407
 408       if Is_Elementary_Type (Typ)
 409         and then Sloc (Entity (N)) = Standard_Location
 410       then
 411          null;
 412
 413       else
 414          Exp_Ch4.Expand_N_Op_Ne (N);
 415       end if;
 416    end Expand_SPARK_N_Op_Ne;
 417
 418    -------------------------------------
 419    -- Expand_SPARK_Potential_Renaming --
 420    -------------------------------------
 421
 422    procedure Expand_SPARK_Potential_Renaming (N : Node_Id) is
 423       function In_Insignificant_Pragma (Nod : Node_Id) return Boolean;
 424       --  Determine whether arbitrary node Nod appears within a significant
 425       --  pragma for SPARK.
 426
 427       -----------------------------
 428       -- In_Insignificant_Pragma --
 429       -----------------------------
 430
 431       function In_Insignificant_Pragma (Nod : Node_Id) return Boolean is
 432          Par : Node_Id;
 433
 434       begin
 435          --  Climb the parent chain looking for an enclosing pragma
 436
 437          Par := Nod;
 438          while Present (Par) loop
 439             if Nkind (Par) = N_Pragma then
 440                return not Pragma_Significant_In_SPARK (Get_Pragma_Id (Par));
 441
 442             --  Prevent the search from going too far
 443
 444             elsif Is_Body_Or_Package_Declaration (Par) then
 445                exit;
 446             end if;
 447
 448             Par := Parent (Par);
 449          end loop;
 450
 451          return False;
 452       end In_Insignificant_Pragma;
 453
 454       --  Local variables
 455
 456       Loc    : constant Source_Ptr := Sloc (N);
 457       Obj_Id : constant Entity_Id  := Entity (N);
 458       Typ    : constant Entity_Id  := Etype (N);
 459       Ren    : Node_Id;
 460
 461    --  Start of processing for Expand_SPARK_Potential_Renaming
 462
 463    begin
 464       --  Replace a reference to a renaming with the actual renamed object
 465
 466       if Ekind (Obj_Id) in Object_Kind then
 467          Ren := Renamed_Object (Obj_Id);
 468
 469          if Present (Ren) then
 470
 471             --  Do not process a reference when it appears within a pragma of
 472             --  no significance to SPARK. It is assumed that the replacement
 473             --  will violate the semantics of the pragma and cause a spurious
 474             --  error.
 475
 476             if In_Insignificant_Pragma (N) then
 477                return;
 478
 479             --  Instantiations and inlining of subprograms employ "prologues"
 480             --  which map actual to formal parameters by means of renamings.
 481             --  Replace a reference to a formal by the corresponding actual
 482             --  parameter.
 483
 484             elsif Nkind (Ren) in N_Entity then
 485                Rewrite (N, New_Occurrence_Of (Ren, Loc));
 486
 487             --  Otherwise the renamed object denotes a name
 488
 489             else
 490                Rewrite (N, New_Copy_Tree (Ren, New_Sloc => Loc));
 491                Reset_Analyzed_Flags (N);
 492             end if;
 493
 494             Analyze_And_Resolve (N, Typ);
 495          end if;
 496       end if;
 497    end Expand_SPARK_Potential_Renaming;
 498
 499    -------------------------------------
 500    -- Expand_SPARK_Selected_Component --
 501    -------------------------------------
 502
 503    procedure Expand_SPARK_Selected_Component (N : Node_Id) is
 504       P    : constant Node_Id   := Prefix (N);
 505       Ptyp : constant Entity_Id := Underlying_Type (Etype (P));
 506    begin
 507       if Present (Ptyp)
 508         and then Is_Access_Type (Ptyp)
 509       then
 510          --  First set prefix type to proper access type, in case it currently
 511          --  has a private (non-access) view of this type.
 512
 513          Set_Etype (P, Ptyp);
 514
 515          Insert_Explicit_Dereference (P);
 516          Analyze_And_Resolve (P, Designated_Type (Ptyp));
 517
 518          if Ekind (Etype (P)) = E_Private_Subtype
 519            and then Is_For_Access_Subtype (Etype (P))
 520          then
 521             Set_Etype (P, Base_Type (Etype (P)));
 522          end if;
 523       end if;
 524    end Expand_SPARK_Selected_Component;
 525
 526 end Exp_SPARK;