projects / gcc.git / blob
? search:
summary | shortlog | log | commit | commitdiff | tree
history | raw | HEAD
[Ada] Cleanup SPARK expansion of aggregates with iterated_component_assoc
[gcc.git] / gcc / ada / exp_spark.adb
1 ------------------------------------------------------------------------------
2 -- --
3 -- GNAT COMPILER COMPONENTS --
4 -- --
5 -- E X P _ S P A R K --
6 -- --
7 -- B o d y --
8 -- --
9 -- Copyright (C) 1992-2020, Free Software Foundation, Inc. --
10 -- --
11 -- GNAT is free software; you can redistribute it and/or modify it under --
12 -- terms of the GNU General Public License as published by the Free Soft- --
13 -- ware Foundation; either version 3, or (at your option) any later ver- --
14 -- sion. GNAT is distributed in the hope that it will be useful, but WITH- --
15 -- OUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY --
16 -- or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License --
17 -- for more details. You should have received a copy of the GNU General --
18 -- Public License distributed with GNAT; see file COPYING3. If not, go to --
19 -- http://www.gnu.org/licenses for a complete copy of the license. --
20 -- --
21 -- GNAT was originally developed by the GNAT team at New York University. --
22 -- Extensive contributions were provided by Ada Core Technologies Inc. --
23 -- --
24 ------------------------------------------------------------------------------
25
26 with Atree; use Atree;
27 with Checks; use Checks;
28 with Einfo; use Einfo;
29 with Exp_Attr;
30 with Exp_Ch4;
31 with Exp_Ch5; use Exp_Ch5;
32 with Exp_Dbug; use Exp_Dbug;
33 with Exp_Util; use Exp_Util;
34 with Namet; use Namet;
35 with Nlists; use Nlists;
36 with Nmake; use Nmake;
37 with Rtsfind; use Rtsfind;
38 with Sem; use Sem;
39 with Sem_Ch8; use Sem_Ch8;
40 with Sem_Prag; use Sem_Prag;
41 with Sem_Res; use Sem_Res;
42 with Sem_Util; use Sem_Util;
43 with Sinfo; use Sinfo;
44 with Snames; use Snames;
45 with Stand; use Stand;
46 with Tbuild; use Tbuild;
47 with Uintp; use Uintp;
48
49 package body Exp_SPARK is
50
51 -----------------------
52 -- Local Subprograms --
53 -----------------------
54
55 procedure Expand_SPARK_N_Aggregate (N : Node_Id);
56 -- Perform aggregate-specific expansion
57
58 procedure Expand_SPARK_N_Attribute_Reference (N : Node_Id);
59 -- Perform attribute-reference-specific expansion
60
61 procedure Expand_SPARK_N_Delta_Aggregate (N : Node_Id);
62 -- Perform delta-aggregate-specific expansion
63
64 procedure Expand_SPARK_N_Freeze_Type (E : Entity_Id);
65 -- Build the DIC procedure of a type when needed, if not already done
66
67 procedure Expand_SPARK_N_Loop_Statement (N : Node_Id);
68 -- Perform loop-statement-specific expansion
69
70 procedure Expand_SPARK_N_Object_Declaration (N : Node_Id);
71 -- Perform object-declaration-specific expansion
72
73 procedure Expand_SPARK_N_Object_Renaming_Declaration (N : Node_Id);
74 -- Perform name evaluation for a renamed object
75
76 procedure Expand_SPARK_N_Op_Ne (N : Node_Id);
77 -- Rewrite operator /= based on operator = when defined explicitly
78
79 procedure Expand_SPARK_Delta_Or_Update (Typ : Entity_Id; Aggr : Node_Id);
80 -- Common expansion for attribute Update and delta aggregates
81
82 ------------------
83 -- Expand_SPARK --
84 ------------------
85
86 procedure Expand_SPARK (N : Node_Id) is
87 begin
88 case Nkind (N) is
89
90 -- Qualification of entity names in formal verification mode
91 -- is limited to the addition of a suffix for homonyms (see
92 -- Exp_Dbug.Qualify_Entity_Name). We used to qualify entity names
93 -- as full expansion does, but this was removed as this prevents the
94 -- verification back-end from using a short name for debugging and
95 -- user interaction. The verification back-end already takes care
96 -- of qualifying names when needed.
97
98 when N_Block_Statement
99 | N_Entry_Declaration
100 | N_Package_Body
101 | N_Package_Declaration
102 | N_Protected_Type_Declaration
103 | N_Subprogram_Body
104 | N_Task_Type_Declaration
105 =>
106 Qualify_Entity_Names (N);
107
108 when N_Aggregate =>
109 Expand_SPARK_N_Aggregate (N);
110
111 -- Replace occurrences of System'To_Address by calls to
112 -- System.Storage_Elements.To_Address.
113
114 when N_Attribute_Reference =>
115 Expand_SPARK_N_Attribute_Reference (N);
116
117 when N_Delta_Aggregate =>
118 Expand_SPARK_N_Delta_Aggregate (N);
119
120 when N_Expanded_Name
121 | N_Identifier
122 =>
123 Expand_SPARK_Potential_Renaming (N);
124
125 -- Loop iterations over arrays need to be expanded, to avoid getting
126 -- two names referring to the same object in memory (the array and
127 -- the iterator) in GNATprove, especially since both can be written
128 -- (thus possibly leading to interferences due to aliasing). No such
129 -- problem arises with quantified expressions over arrays, which are
130 -- dealt with specially in GNATprove.
131
132 when N_Loop_Statement =>
133 Expand_SPARK_N_Loop_Statement (N);
134
135 when N_Object_Declaration =>
136 Expand_SPARK_N_Object_Declaration (N);
137
138 when N_Object_Renaming_Declaration =>
139 Expand_SPARK_N_Object_Renaming_Declaration (N);
140
141 when N_Op_Ne =>
142 Expand_SPARK_N_Op_Ne (N);
143
144 when N_Freeze_Entity =>
145 if Is_Type (Entity (N)) then
146 Expand_SPARK_N_Freeze_Type (Entity (N));
147 end if;
148
149 -- In SPARK mode, no other constructs require expansion
150
151 when others =>
152 null;
153 end case;
154 end Expand_SPARK;
155
156 ----------------------------------
157 -- Expand_SPARK_Delta_Or_Update --
158 ----------------------------------
159
160 procedure Expand_SPARK_Delta_Or_Update
161 (Typ : Entity_Id;
162 Aggr : Node_Id)
163 is
164 Assoc : Node_Id;
165 Comp : Node_Id;
166 Comp_Id : Entity_Id;
167 Comp_Type : Entity_Id;
168 Expr : Node_Id;
169 Index : Node_Id;
170 Index_Typ : Entity_Id;
171 New_Assoc : Node_Id;
172
173 begin
174 -- Apply scalar range checks on the updated components, if needed
175
176 if Is_Array_Type (Typ) then
177
178 -- Multidimensional arrays
179
180 if Present (Next_Index (First_Index (Typ))) then
181 Assoc := First (Component_Associations (Aggr));
182
183 while Present (Assoc) loop
184 Expr := Expression (Assoc);
185 Comp_Type := Component_Type (Typ);
186
187 if Is_Scalar_Type (Comp_Type) then
188 Apply_Scalar_Range_Check (Expr, Comp_Type);
189 end if;
190
191 -- The current association contains a sequence of indexes
192 -- denoting an element of a multidimensional array:
193 --
194 -- (Index_1, ..., Index_N)
195
196 Expr := First (Choices (Assoc));
197
198 pragma Assert (Nkind (Aggr) = N_Aggregate);
199
200 while Present (Expr) loop
201 Index := First (Expressions (Expr));
202 Index_Typ := First_Index (Typ);
203
204 while Present (Index_Typ) loop
205 Apply_Scalar_Range_Check (Index, Etype (Index_Typ));
206 Next (Index);
207 Next_Index (Index_Typ);
208 end loop;
209
210 Next (Expr);
211 end loop;
212
213 Next (Assoc);
214 end loop;
215
216 -- One-dimensional arrays
217
218 else
219 Assoc := First (Component_Associations (Aggr));
220
221 while Present (Assoc) loop
222 Expr := Expression (Assoc);
223 Comp_Type := Component_Type (Typ);
224
225 -- Analyze expression of the iterated_component_association
226 -- with its index parameter in scope.
227
228 if Nkind (Assoc) = N_Iterated_Component_Association then
229 Push_Scope (Scope (Defining_Identifier (Assoc)));
230 Analyze_And_Resolve (Expr, Comp_Type);
231 end if;
232
233 if Is_Scalar_Type (Comp_Type) then
234 Apply_Scalar_Range_Check (Expr, Comp_Type);
235 end if;
236
237 -- Restore scope of the iterated_component_association
238
239 if Nkind (Assoc) = N_Iterated_Component_Association then
240 End_Scope;
241 end if;
242
243 Index := First (Choice_List (Assoc));
244 Index_Typ := First_Index (Typ);
245
246 while Present (Index) loop
247 -- If the index denotes a range of elements or a constrained
248 -- subtype indication, then their low and high bounds
249 -- already have range checks applied.
250
251 if Nkind (Index) in N_Range | N_Subtype_Indication then
252 null;
253
254 -- Otherwise the index denotes a single expression where
255 -- range checks need to be applied or a subtype name
256 -- (without range constraints) where applying checks is
257 -- harmless.
258 --
259 -- In delta_aggregate and Update attribute on array the
260 -- others_choice is not allowed.
261
262 else pragma Assert (Nkind (Index) in N_Subexpr);
263 Apply_Scalar_Range_Check (Index, Etype (Index_Typ));
264 end if;
265
266 Next (Index);
267 end loop;
268
269 Next (Assoc);
270 end loop;
271 end if;
272
273 else pragma Assert (Is_Record_Type (Typ));
274
275 -- If the aggregate has multiple component choices, e.g.:
276 --
277 -- X'Update (A | B | C => 123)
278 --
279 -- then each component might be of a different type and might or
280 -- might not require a range check. We first rewrite associations
281 -- into single-component choices, e.g.:
282 --
283 -- X'Update (A => 123, B => 123, C => 123)
284 --
285 -- and then apply range checks to individual copies of the
286 -- expressions. We do the same for delta aggregates, accordingly.
287
288 -- Iterate over associations of the original aggregate
289
290 Assoc := First (Component_Associations (Aggr));
291
292 -- Rewrite into a new aggregate and decorate
293
294 case Nkind (Aggr) is
295 when N_Aggregate =>
296 Rewrite
297 (Aggr,
298 Make_Aggregate
299 (Sloc => Sloc (Aggr),
300 Component_Associations => New_List));
301
302 when N_Delta_Aggregate =>
303 Rewrite
304 (Aggr,
305 Make_Delta_Aggregate
306 (Sloc => Sloc (Aggr),
307 Expression => Expression (Aggr),
308 Component_Associations => New_List));
309
310 when others =>
311 raise Program_Error;
312 end case;
313
314 Set_Etype (Aggr, Typ);
315
316 -- Populate the new aggregate with component associations
317
318 while Present (Assoc) loop
319 Expr := Expression (Assoc);
320 Comp := First (Choices (Assoc));
321
322 while Present (Comp) loop
323 Comp_Id := Entity (Comp);
324 Comp_Type := Etype (Comp_Id);
325
326 New_Assoc :=
327 Make_Component_Association
328 (Sloc => Sloc (Assoc),
329 Choices =>
330 New_List
331 (New_Occurrence_Of (Comp_Id, Sloc (Comp))),
332 Expression => New_Copy_Tree (Expr));
333
334 -- New association must be attached to the aggregate before we
335 -- analyze it.
336
337 Append (New_Assoc, Component_Associations (Aggr));
338
339 Analyze_And_Resolve (Expression (New_Assoc), Comp_Type);
340
341 if Is_Scalar_Type (Comp_Type) then
342 Apply_Scalar_Range_Check
343 (Expression (New_Assoc), Comp_Type);
344 end if;
345
346 Next (Comp);
347 end loop;
348
349 Next (Assoc);
350 end loop;
351 end if;
352 end Expand_SPARK_Delta_Or_Update;
353
354 --------------------------------
355 -- Expand_SPARK_N_Freeze_Type --
356 --------------------------------
357
358 procedure Expand_SPARK_N_Freeze_Type (E : Entity_Id) is
359 begin
360 -- When a DIC is inherited by a tagged type, it may need to be
361 -- specialized to the descendant type, hence build a separate DIC
362 -- procedure for it as done during regular expansion for compilation.
363
364 if Has_DIC (E) and then Is_Tagged_Type (E) then
365 Build_DIC_Procedure_Body (E, For_Freeze => True);
366 end if;
367 end Expand_SPARK_N_Freeze_Type;
368
369 ------------------------------
370 -- Expand_SPARK_N_Aggregate --
371 ------------------------------
372
373 procedure Expand_SPARK_N_Aggregate (N : Node_Id) is
374 Assoc : Node_Id := First (Component_Associations (N));
375 begin
376 -- For compilation, frontend analyses a copy of the
377 -- iterated_component_association's expression for legality checking;
378 -- (then the expression is copied again when expanding association into
379 -- assignments for the individual choices). For SPARK we analyze the
380 -- original expression and apply range checks, if required.
381
382 while Present (Assoc) loop
383 if Nkind (Assoc) = N_Iterated_Component_Association then
384 declare
385 Typ : constant Entity_Id := Etype (N);
386
387 Comp_Type : constant Entity_Id := Component_Type (Typ);
388 Expr : constant Node_Id := Expression (Assoc);
389 Index_Typ : constant Entity_Id := First_Index (Typ);
390
391 Index : Node_Id;
392
393 begin
394 -- Analyze expression with index parameter in scope
395
396 Push_Scope (Scope (Defining_Identifier (Assoc)));
397 Enter_Name (Defining_Identifier (Assoc));
398 Analyze_And_Resolve (Expr, Comp_Type);
399
400 if Is_Scalar_Type (Comp_Type) then
401 Apply_Scalar_Range_Check (Expr, Comp_Type);
402 end if;
403
404 End_Scope;
405
406 -- Analyze discrete choices
407
408 Index := First (Discrete_Choices (Assoc));
409
410 while Present (Index) loop
411
412 -- The index denotes a range of elements where range checks
413 -- have been already applied.
414
415 if Nkind (Index) in N_Others_Choice
416 | N_Range
417 | N_Subtype_Indication
418 then
419 null;
420
421 -- Otherwise the index denotes a single element (or a
422 -- subtype name which doesn't require range checks).
423
424 else pragma Assert (Nkind (Index) in N_Subexpr);
425 Apply_Scalar_Range_Check (Index, Etype (Index_Typ));
426 end if;
427
428 Next (Index);
429 end loop;
430 end;
431 end if;
432
433 Next (Assoc);
434 end loop;
435 end Expand_SPARK_N_Aggregate;
436
437 ----------------------------------------
438 -- Expand_SPARK_N_Attribute_Reference --
439 ----------------------------------------
440
441 procedure Expand_SPARK_N_Attribute_Reference (N : Node_Id) is
442 Aname : constant Name_Id := Attribute_Name (N);
443 Attr_Id : constant Attribute_Id := Get_Attribute_Id (Aname);
444 Loc : constant Source_Ptr := Sloc (N);
445 Pref : constant Node_Id := Prefix (N);
446 Typ : constant Entity_Id := Etype (N);
447 Expr : Node_Id;
448
449 begin
450 if Attr_Id = Attribute_To_Address then
451
452 -- Extract and convert argument to expected type for call
453
454 Expr :=
455 Make_Type_Conversion (Loc,
456 Subtype_Mark =>
457 New_Occurrence_Of (RTE (RE_Integer_Address), Loc),
458 Expression => Relocate_Node (First (Expressions (N))));
459
460 -- Replace attribute reference with call
461
462 Rewrite (N,
463 Make_Function_Call (Loc,
464 Name =>
465 New_Occurrence_Of (RTE (RE_To_Address), Loc),
466 Parameter_Associations => New_List (Expr)));
467 Analyze_And_Resolve (N, Typ);
468
469 elsif Attr_Id = Attribute_Object_Size
470 or else Attr_Id = Attribute_Size
471 or else Attr_Id = Attribute_Value_Size
472 or else Attr_Id = Attribute_VADS_Size
473 then
474 Exp_Attr.Expand_Size_Attribute (N);
475
476 -- For attributes which return Universal_Integer, introduce a conversion
477 -- to the expected type with the appropriate check flags set.
478
479 elsif Attr_Id = Attribute_Alignment
480 or else Attr_Id = Attribute_Bit
481 or else Attr_Id = Attribute_Bit_Position
482 or else Attr_Id = Attribute_Descriptor_Size
483 or else Attr_Id = Attribute_First_Bit
484 or else Attr_Id = Attribute_Last_Bit
485 or else Attr_Id = Attribute_Length
486 or else Attr_Id = Attribute_Max_Size_In_Storage_Elements
487 or else Attr_Id = Attribute_Pos
488 or else Attr_Id = Attribute_Position
489 or else Attr_Id = Attribute_Range_Length
490 or else Attr_Id = Attribute_Aft
491 or else Attr_Id = Attribute_Max_Alignment_For_Allocation
492 then
493 -- If the expected type is Long_Long_Integer, there will be no check
494 -- flag as the compiler assumes attributes always fit in this type.
495 -- Since in SPARK_Mode we do not take Storage_Error into account, we
496 -- cannot make this assumption and need to produce a check.
497 -- ??? It should be enough to add this check for attributes
498 -- 'Length, 'Range_Length and 'Pos when the type is as big
499 -- as Long_Long_Integer.
500
501 declare
502 Typ : Entity_Id;
503 begin
504 if Attr_Id = Attribute_Range_Length
505 or else Attr_Id = Attribute_Pos
506 then
507 Typ := Etype (Prefix (N));
508
509 elsif Attr_Id = Attribute_Length then
510 Typ := Get_Index_Subtype (N);
511
512 else
513 Typ := Empty;
514 end if;
515
516 Apply_Universal_Integer_Attribute_Checks (N);
517
518 if Present (Typ)
519 and then RM_Size (Typ) = RM_Size (Standard_Long_Long_Integer)
520 then
521 -- ??? This should rather be a range check, but this would
522 -- crash GNATprove which somehow recovers the proper kind
523 -- of check anyway.
524 Set_Do_Overflow_Check (N);
525 end if;
526 end;
527
528 elsif Attr_Id = Attribute_Constrained then
529
530 -- If the prefix is an access to object, the attribute applies to
531 -- the designated object, so rewrite with an explicit dereference.
532
533 if Is_Access_Type (Etype (Pref))
534 and then
535 (not Is_Entity_Name (Pref) or else Is_Object (Entity (Pref)))
536 then
537 Rewrite (Pref,
538 Make_Explicit_Dereference (Loc, Relocate_Node (Pref)));
539 Analyze_And_Resolve (N, Standard_Boolean);
540 end if;
541
542 elsif Attr_Id = Attribute_Update then
543 Expand_SPARK_Delta_Or_Update (Typ, First (Expressions (N)));
544 end if;
545 end Expand_SPARK_N_Attribute_Reference;
546
547 ------------------------------------
548 -- Expand_SPARK_N_Delta_Aggregate --
549 ------------------------------------
550
551 procedure Expand_SPARK_N_Delta_Aggregate (N : Node_Id) is
552 begin
553 Expand_SPARK_Delta_Or_Update (Etype (N), N);
554 end Expand_SPARK_N_Delta_Aggregate;
555
556 -----------------------------------
557 -- Expand_SPARK_N_Loop_Statement --
558 -----------------------------------
559
560 procedure Expand_SPARK_N_Loop_Statement (N : Node_Id) is
561 Scheme : constant Node_Id := Iteration_Scheme (N);
562
563 begin
564 -- Loop iterations over arrays need to be expanded, to avoid getting
565 -- two names referring to the same object in memory (the array and the
566 -- iterator) in GNATprove, especially since both can be written (thus
567 -- possibly leading to interferences due to aliasing). No such problem
568 -- arises with quantified expressions over arrays, which are dealt with
569 -- specially in GNATprove.
570
571 if Present (Scheme)
572 and then Present (Iterator_Specification (Scheme))
573 and then Is_Iterator_Over_Array (Iterator_Specification (Scheme))
574 then
575 Expand_Iterator_Loop_Over_Array (N);
576 end if;
577 end Expand_SPARK_N_Loop_Statement;
578
579 ---------------------------------------
580 -- Expand_SPARK_N_Object_Declaration --
581 ---------------------------------------
582
583 procedure Expand_SPARK_N_Object_Declaration (N : Node_Id) is
584 Loc : constant Source_Ptr := Sloc (N);
585 Obj_Id : constant Entity_Id := Defining_Identifier (N);
586 Typ : constant Entity_Id := Etype (Obj_Id);
587
588 Call : Node_Id;
589
590 begin
591 -- If the object declaration denotes a variable without initialization
592 -- whose type is subject to pragma Default_Initial_Condition, create
593 -- and analyze a dummy call to the DIC procedure of the type in order
594 -- to detect potential elaboration issues.
595
596 if Comes_From_Source (Obj_Id)
597 and then Ekind (Obj_Id) = E_Variable
598 and then Has_DIC (Typ)
599 and then Present (DIC_Procedure (Typ))
600 and then not Has_Init_Expression (N)
601 then
602 Call := Build_DIC_Call (Loc, Obj_Id, Typ);
603
604 -- Partially insert the call into the tree by setting its parent
605 -- pointer.
606
607 Set_Parent (Call, N);
608 Analyze (Call);
609 end if;
610 end Expand_SPARK_N_Object_Declaration;
611
612 ------------------------------------------------
613 -- Expand_SPARK_N_Object_Renaming_Declaration --
614 ------------------------------------------------
615
616 procedure Expand_SPARK_N_Object_Renaming_Declaration (N : Node_Id) is
617 CFS : constant Boolean := Comes_From_Source (N);
618 Loc : constant Source_Ptr := Sloc (N);
619 Obj_Id : constant Entity_Id := Defining_Entity (N);
620 Nam : constant Node_Id := Name (N);
621 Typ : constant Entity_Id := Etype (Obj_Id);
622
623 begin
624 -- Transform a renaming of the form
625
626 -- Obj_Id : <subtype mark> renames <function call>;
627
628 -- into
629
630 -- Obj_Id : constant <subtype mark> := <function call>;
631
632 -- Invoking Evaluate_Name and ultimately Remove_Side_Effects introduces
633 -- a temporary to capture the function result. Once potential renamings
634 -- are rewritten for SPARK, the temporary may be leaked out into source
635 -- constructs and lead to confusing error diagnostics. Using an object
636 -- declaration prevents this unwanted side effect.
637
638 if Nkind (Nam) = N_Function_Call then
639 Rewrite (N,
640 Make_Object_Declaration (Loc,
641 Defining_Identifier => Obj_Id,
642 Constant_Present => True,
643 Object_Definition => New_Occurrence_Of (Typ, Loc),
644 Expression => Nam));
645
646 -- Inherit the original Comes_From_Source status of the renaming
647
648 Set_Comes_From_Source (N, CFS);
649
650 -- Sever the link to the renamed function result because the entity
651 -- will no longer alias anything.
652
653 Set_Renamed_Object (Obj_Id, Empty);
654
655 -- Remove the entity of the renaming declaration from visibility as
656 -- the analysis of the object declaration will reintroduce it again.
657
658 Remove_Entity_And_Homonym (Obj_Id);
659 Analyze (N);
660
661 -- Otherwise unconditionally remove all side effects from the name
662
663 else
664 Evaluate_Name (Nam);
665 end if;
666 end Expand_SPARK_N_Object_Renaming_Declaration;
667
668 --------------------------
669 -- Expand_SPARK_N_Op_Ne --
670 --------------------------
671
672 procedure Expand_SPARK_N_Op_Ne (N : Node_Id) is
673 Typ : constant Entity_Id := Etype (Left_Opnd (N));
674
675 begin
676 -- Case of elementary type with standard operator
677
678 if Is_Elementary_Type (Typ)
679 and then Sloc (Entity (N)) = Standard_Location
680 then
681 null;
682
683 else
684 Exp_Ch4.Expand_N_Op_Ne (N);
685 end if;
686 end Expand_SPARK_N_Op_Ne;
687
688 -------------------------------------
689 -- Expand_SPARK_Potential_Renaming --
690 -------------------------------------
691
692 procedure Expand_SPARK_Potential_Renaming (N : Node_Id) is
693 function In_Insignificant_Pragma (Nod : Node_Id) return Boolean;
694 -- Determine whether arbitrary node Nod appears within a significant
695 -- pragma for SPARK.
696
697 -----------------------------
698 -- In_Insignificant_Pragma --
699 -----------------------------
700
701 function In_Insignificant_Pragma (Nod : Node_Id) return Boolean is
702 Par : Node_Id;
703
704 begin
705 -- Climb the parent chain looking for an enclosing pragma
706
707 Par := Nod;
708 while Present (Par) loop
709 if Nkind (Par) = N_Pragma then
710 return not Pragma_Significant_In_SPARK (Get_Pragma_Id (Par));
711
712 -- Prevent the search from going too far
713
714 elsif Is_Body_Or_Package_Declaration (Par) then
715 exit;
716 end if;
717
718 Par := Parent (Par);
719 end loop;
720
721 return False;
722 end In_Insignificant_Pragma;
723
724 -- Local variables
725
726 Loc : constant Source_Ptr := Sloc (N);
727 Obj_Id : constant Entity_Id := Entity (N);
728 Typ : constant Entity_Id := Etype (N);
729 Ren : Node_Id;
730
731 -- Start of processing for Expand_SPARK_Potential_Renaming
732
733 begin
734 -- Replace a reference to a renaming with the actual renamed object
735
736 if Is_Object (Obj_Id) then
737 Ren := Renamed_Object (Obj_Id);
738
739 if Present (Ren) then
740
741 -- Do not process a reference when it appears within a pragma of
742 -- no significance to SPARK. It is assumed that the replacement
743 -- will violate the semantics of the pragma and cause a spurious
744 -- error.
745
746 if In_Insignificant_Pragma (N) then
747 return;
748
749 -- Instantiations and inlining of subprograms employ "prologues"
750 -- which map actual to formal parameters by means of renamings.
751 -- Replace a reference to a formal by the corresponding actual
752 -- parameter.
753
754 elsif Nkind (Ren) in N_Entity then
755 Rewrite (N, New_Occurrence_Of (Ren, Loc));
756
757 -- Otherwise the renamed object denotes a name
758
759 else
760 Rewrite (N, New_Copy_Tree (Ren, New_Sloc => Loc));
761 Reset_Analyzed_Flags (N);
762 end if;
763
764 Analyze_And_Resolve (N, Typ);
765 end if;
766 end if;
767 end Expand_SPARK_Potential_Renaming;
768
769 end Exp_SPARK;