gcc/ada/exp_spark.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                            E X P _ S P A R K                             --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2020, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Checks;   use Checks;
  28 with Einfo;    use Einfo;
  29 with Exp_Attr;
  30 with Exp_Ch4;
  31 with Exp_Ch5;  use Exp_Ch5;
  32 with Exp_Dbug; use Exp_Dbug;
  33 with Exp_Util; use Exp_Util;
  34 with Namet;    use Namet;
  35 with Nlists;   use Nlists;
  36 with Nmake;    use Nmake;
  37 with Rtsfind;  use Rtsfind;
  38 with Sem;      use Sem;
  39 with Sem_Prag; use Sem_Prag;
  40 with Sem_Res;  use Sem_Res;
  41 with Sem_Util; use Sem_Util;
  42 with Sinfo;    use Sinfo;
  43 with Snames;   use Snames;
  44 with Stand;    use Stand;
  45 with Tbuild;   use Tbuild;
  46 with Uintp;    use Uintp;
  47
  48 package body Exp_SPARK is
  49
  50    -----------------------
  51    -- Local Subprograms --
  52    -----------------------
  53
  54    procedure Expand_SPARK_N_Attribute_Reference (N : Node_Id);
  55    --  Perform attribute-reference-specific expansion
  56
  57    procedure Expand_SPARK_N_Freeze_Type (E : Entity_Id);
  58    --  Build the DIC procedure of a type when needed, if not already done
  59
  60    procedure Expand_SPARK_N_Loop_Statement (N : Node_Id);
  61    --  Perform loop-statement-specific expansion
  62
  63    procedure Expand_SPARK_N_Object_Declaration (N : Node_Id);
  64    --  Perform object-declaration-specific expansion
  65
  66    procedure Expand_SPARK_N_Object_Renaming_Declaration (N : Node_Id);
  67    --  Perform name evaluation for a renamed object
  68
  69    procedure Expand_SPARK_N_Op_Ne (N : Node_Id);
  70    --  Rewrite operator /= based on operator = when defined explicitly
  71
  72    ------------------
  73    -- Expand_SPARK --
  74    ------------------
  75
  76    procedure Expand_SPARK (N : Node_Id) is
  77    begin
  78       case Nkind (N) is
  79
  80          --  Qualification of entity names in formal verification mode
  81          --  is limited to the addition of a suffix for homonyms (see
  82          --  Exp_Dbug.Qualify_Entity_Name). We used to qualify entity names
  83          --  as full expansion does, but this was removed as this prevents the
  84          --  verification back-end from using a short name for debugging and
  85          --  user interaction. The verification back-end already takes care
  86          --  of qualifying names when needed.
  87
  88          when N_Block_Statement
  89             | N_Entry_Declaration
  90             | N_Package_Body
  91             | N_Package_Declaration
  92             | N_Protected_Type_Declaration
  93             | N_Subprogram_Body
  94             | N_Task_Type_Declaration
  95          =>
  96             Qualify_Entity_Names (N);
  97
  98          --  Replace occurrences of System'To_Address by calls to
  99          --  System.Storage_Elements.To_Address.
 100
 101          when N_Attribute_Reference =>
 102             Expand_SPARK_N_Attribute_Reference (N);
 103
 104          when N_Expanded_Name
 105             | N_Identifier
 106          =>
 107             Expand_SPARK_Potential_Renaming (N);
 108
 109          --  Loop iterations over arrays need to be expanded, to avoid getting
 110          --  two names referring to the same object in memory (the array and
 111          --  the iterator) in GNATprove, especially since both can be written
 112          --  (thus possibly leading to interferences due to aliasing). No such
 113          --  problem arises with quantified expressions over arrays, which are
 114          --  dealt with specially in GNATprove.
 115
 116          when N_Loop_Statement =>
 117             Expand_SPARK_N_Loop_Statement (N);
 118
 119          when N_Object_Declaration =>
 120             Expand_SPARK_N_Object_Declaration (N);
 121
 122          when N_Object_Renaming_Declaration =>
 123             Expand_SPARK_N_Object_Renaming_Declaration (N);
 124
 125          when N_Op_Ne =>
 126             Expand_SPARK_N_Op_Ne (N);
 127
 128          when N_Freeze_Entity =>
 129             if Is_Type (Entity (N)) then
 130                Expand_SPARK_N_Freeze_Type (Entity (N));
 131             end if;
 132
 133          --  In SPARK mode, no other constructs require expansion
 134
 135          when others =>
 136             null;
 137       end case;
 138    end Expand_SPARK;
 139
 140    --------------------------------
 141    -- Expand_SPARK_N_Freeze_Type --
 142    --------------------------------
 143
 144    procedure Expand_SPARK_N_Freeze_Type (E : Entity_Id) is
 145    begin
 146       --  When a DIC is inherited by a tagged type, it may need to be
 147       --  specialized to the descendant type, hence build a separate DIC
 148       --  procedure for it as done during regular expansion for compilation.
 149
 150       if Has_DIC (E) and then Is_Tagged_Type (E) then
 151          Build_DIC_Procedure_Body (E, For_Freeze => True);
 152       end if;
 153    end Expand_SPARK_N_Freeze_Type;
 154
 155    ----------------------------------------
 156    -- Expand_SPARK_N_Attribute_Reference --
 157    ----------------------------------------
 158
 159    procedure Expand_SPARK_N_Attribute_Reference (N : Node_Id) is
 160       Aname   : constant Name_Id      := Attribute_Name (N);
 161       Attr_Id : constant Attribute_Id := Get_Attribute_Id (Aname);
 162       Loc     : constant Source_Ptr   := Sloc (N);
 163       Pref    : constant Node_Id      := Prefix (N);
 164       Typ     : constant Entity_Id    := Etype (N);
 165       Expr    : Node_Id;
 166
 167    begin
 168       if Attr_Id = Attribute_To_Address then
 169
 170          --  Extract and convert argument to expected type for call
 171
 172          Expr :=
 173            Make_Type_Conversion (Loc,
 174              Subtype_Mark =>
 175                New_Occurrence_Of (RTE (RE_Integer_Address), Loc),
 176              Expression   => Relocate_Node (First (Expressions (N))));
 177
 178          --  Replace attribute reference with call
 179
 180          Rewrite (N,
 181            Make_Function_Call (Loc,
 182              Name                   =>
 183                New_Occurrence_Of (RTE (RE_To_Address), Loc),
 184              Parameter_Associations => New_List (Expr)));
 185          Analyze_And_Resolve (N, Typ);
 186
 187       elsif Attr_Id = Attribute_Object_Size
 188         or else Attr_Id = Attribute_Size
 189         or else Attr_Id = Attribute_Value_Size
 190         or else Attr_Id = Attribute_VADS_Size
 191       then
 192          Exp_Attr.Expand_Size_Attribute (N);
 193
 194       --  For attributes which return Universal_Integer, introduce a conversion
 195       --  to the expected type with the appropriate check flags set.
 196
 197       elsif Attr_Id = Attribute_Alignment
 198         or else Attr_Id = Attribute_Bit
 199         or else Attr_Id = Attribute_Bit_Position
 200         or else Attr_Id = Attribute_Descriptor_Size
 201         or else Attr_Id = Attribute_First_Bit
 202         or else Attr_Id = Attribute_Last_Bit
 203         or else Attr_Id = Attribute_Length
 204         or else Attr_Id = Attribute_Max_Size_In_Storage_Elements
 205         or else Attr_Id = Attribute_Pos
 206         or else Attr_Id = Attribute_Position
 207         or else Attr_Id = Attribute_Range_Length
 208         or else Attr_Id = Attribute_Aft
 209         or else Attr_Id = Attribute_Max_Alignment_For_Allocation
 210       then
 211          --  If the expected type is Long_Long_Integer, there will be no check
 212          --  flag as the compiler assumes attributes always fit in this type.
 213          --  Since in SPARK_Mode we do not take Storage_Error into account, we
 214          --  cannot make this assumption and need to produce a check.
 215          --  ??? It should be enough to add this check for attributes 'Length
 216          --  and 'Range_Length when the type is as big as Long_Long_Integer.
 217
 218          declare
 219             Typ : Entity_Id;
 220          begin
 221             if Attr_Id = Attribute_Range_Length then
 222                Typ := Etype (Prefix (N));
 223
 224             elsif Attr_Id = Attribute_Length then
 225                Typ := Get_Index_Subtype (N);
 226
 227             else
 228                Typ := Empty;
 229             end if;
 230
 231             Apply_Universal_Integer_Attribute_Checks (N);
 232
 233             if Present (Typ)
 234               and then RM_Size (Typ) = RM_Size (Standard_Long_Long_Integer)
 235             then
 236                Set_Do_Overflow_Check (N);
 237             end if;
 238          end;
 239
 240       elsif Attr_Id = Attribute_Constrained then
 241
 242          --  If the prefix is an access to object, the attribute applies to
 243          --  the designated object, so rewrite with an explicit dereference.
 244
 245          if Is_Access_Type (Etype (Pref))
 246            and then
 247              (not Is_Entity_Name (Pref) or else Is_Object (Entity (Pref)))
 248          then
 249             Rewrite (Pref,
 250                      Make_Explicit_Dereference (Loc, Relocate_Node (Pref)));
 251             Analyze_And_Resolve (N, Standard_Boolean);
 252          end if;
 253
 254       end if;
 255    end Expand_SPARK_N_Attribute_Reference;
 256
 257    -----------------------------------
 258    -- Expand_SPARK_N_Loop_Statement --
 259    -----------------------------------
 260
 261    procedure Expand_SPARK_N_Loop_Statement (N : Node_Id) is
 262       Scheme : constant Node_Id := Iteration_Scheme (N);
 263
 264    begin
 265       --  Loop iterations over arrays need to be expanded, to avoid getting
 266       --  two names referring to the same object in memory (the array and the
 267       --  iterator) in GNATprove, especially since both can be written (thus
 268       --  possibly leading to interferences due to aliasing). No such problem
 269       --  arises with quantified expressions over arrays, which are dealt with
 270       --  specially in GNATprove.
 271
 272       if Present (Scheme)
 273         and then Present (Iterator_Specification (Scheme))
 274         and then Is_Iterator_Over_Array (Iterator_Specification (Scheme))
 275       then
 276          Expand_Iterator_Loop_Over_Array (N);
 277       end if;
 278    end Expand_SPARK_N_Loop_Statement;
 279
 280    ---------------------------------------
 281    -- Expand_SPARK_N_Object_Declaration --
 282    ---------------------------------------
 283
 284    procedure Expand_SPARK_N_Object_Declaration (N : Node_Id) is
 285       Loc    : constant Source_Ptr := Sloc (N);
 286       Obj_Id : constant Entity_Id  := Defining_Identifier (N);
 287       Typ    : constant Entity_Id  := Etype (Obj_Id);
 288
 289       Call : Node_Id;
 290
 291    begin
 292       --  If the object declaration denotes a variable without initialization
 293       --  whose type is subject to pragma Default_Initial_Condition, create
 294       --  and analyze a dummy call to the DIC procedure of the type in order
 295       --  to detect potential elaboration issues.
 296
 297       if Comes_From_Source (Obj_Id)
 298         and then Ekind (Obj_Id) = E_Variable
 299         and then Has_DIC (Typ)
 300         and then Present (DIC_Procedure (Typ))
 301         and then not Has_Init_Expression (N)
 302       then
 303          Call := Build_DIC_Call (Loc, Obj_Id, Typ);
 304
 305          --  Partially insert the call into the tree by setting its parent
 306          --  pointer.
 307
 308          Set_Parent (Call, N);
 309          Analyze (Call);
 310       end if;
 311    end Expand_SPARK_N_Object_Declaration;
 312
 313    ------------------------------------------------
 314    -- Expand_SPARK_N_Object_Renaming_Declaration --
 315    ------------------------------------------------
 316
 317    procedure Expand_SPARK_N_Object_Renaming_Declaration (N : Node_Id) is
 318       CFS    : constant Boolean    := Comes_From_Source (N);
 319       Loc    : constant Source_Ptr := Sloc (N);
 320       Obj_Id : constant Entity_Id  := Defining_Entity (N);
 321       Nam    : constant Node_Id    := Name (N);
 322       Typ    : constant Entity_Id  := Etype (Obj_Id);
 323
 324    begin
 325       --  Transform a renaming of the form
 326
 327       --    Obj_Id : <subtype mark> renames <function call>;
 328
 329       --  into
 330
 331       --    Obj_Id : constant <subtype mark> := <function call>;
 332
 333       --  Invoking Evaluate_Name and ultimately Remove_Side_Effects introduces
 334       --  a temporary to capture the function result. Once potential renamings
 335       --  are rewritten for SPARK, the temporary may be leaked out into source
 336       --  constructs and lead to confusing error diagnostics. Using an object
 337       --  declaration prevents this unwanted side effect.
 338
 339       if Nkind (Nam) = N_Function_Call then
 340          Rewrite (N,
 341            Make_Object_Declaration (Loc,
 342              Defining_Identifier => Obj_Id,
 343              Constant_Present    => True,
 344              Object_Definition   => New_Occurrence_Of (Typ, Loc),
 345              Expression          => Nam));
 346
 347          --  Inherit the original Comes_From_Source status of the renaming
 348
 349          Set_Comes_From_Source (N, CFS);
 350
 351          --  Sever the link to the renamed function result because the entity
 352          --  will no longer alias anything.
 353
 354          Set_Renamed_Object (Obj_Id, Empty);
 355
 356          --  Remove the entity of the renaming declaration from visibility as
 357          --  the analysis of the object declaration will reintroduce it again.
 358
 359          Remove_Entity_And_Homonym (Obj_Id);
 360          Analyze (N);
 361
 362       --  Otherwise unconditionally remove all side effects from the name
 363
 364       else
 365          Evaluate_Name (Nam);
 366       end if;
 367    end Expand_SPARK_N_Object_Renaming_Declaration;
 368
 369    --------------------------
 370    -- Expand_SPARK_N_Op_Ne --
 371    --------------------------
 372
 373    procedure Expand_SPARK_N_Op_Ne (N : Node_Id) is
 374       Typ : constant Entity_Id := Etype (Left_Opnd (N));
 375
 376    begin
 377       --  Case of elementary type with standard operator
 378
 379       if Is_Elementary_Type (Typ)
 380         and then Sloc (Entity (N)) = Standard_Location
 381       then
 382          null;
 383
 384       else
 385          Exp_Ch4.Expand_N_Op_Ne (N);
 386       end if;
 387    end Expand_SPARK_N_Op_Ne;
 388
 389    -------------------------------------
 390    -- Expand_SPARK_Potential_Renaming --
 391    -------------------------------------
 392
 393    procedure Expand_SPARK_Potential_Renaming (N : Node_Id) is
 394       function In_Insignificant_Pragma (Nod : Node_Id) return Boolean;
 395       --  Determine whether arbitrary node Nod appears within a significant
 396       --  pragma for SPARK.
 397
 398       -----------------------------
 399       -- In_Insignificant_Pragma --
 400       -----------------------------
 401
 402       function In_Insignificant_Pragma (Nod : Node_Id) return Boolean is
 403          Par : Node_Id;
 404
 405       begin
 406          --  Climb the parent chain looking for an enclosing pragma
 407
 408          Par := Nod;
 409          while Present (Par) loop
 410             if Nkind (Par) = N_Pragma then
 411                return not Pragma_Significant_In_SPARK (Get_Pragma_Id (Par));
 412
 413             --  Prevent the search from going too far
 414
 415             elsif Is_Body_Or_Package_Declaration (Par) then
 416                exit;
 417             end if;
 418
 419             Par := Parent (Par);
 420          end loop;
 421
 422          return False;
 423       end In_Insignificant_Pragma;
 424
 425       --  Local variables
 426
 427       Loc    : constant Source_Ptr := Sloc (N);
 428       Obj_Id : constant Entity_Id  := Entity (N);
 429       Typ    : constant Entity_Id  := Etype (N);
 430       Ren    : Node_Id;
 431
 432    --  Start of processing for Expand_SPARK_Potential_Renaming
 433
 434    begin
 435       --  Replace a reference to a renaming with the actual renamed object
 436
 437       if Ekind (Obj_Id) in Object_Kind then
 438          Ren := Renamed_Object (Obj_Id);
 439
 440          if Present (Ren) then
 441
 442             --  Do not process a reference when it appears within a pragma of
 443             --  no significance to SPARK. It is assumed that the replacement
 444             --  will violate the semantics of the pragma and cause a spurious
 445             --  error.
 446
 447             if In_Insignificant_Pragma (N) then
 448                return;
 449
 450             --  Instantiations and inlining of subprograms employ "prologues"
 451             --  which map actual to formal parameters by means of renamings.
 452             --  Replace a reference to a formal by the corresponding actual
 453             --  parameter.
 454
 455             elsif Nkind (Ren) in N_Entity then
 456                Rewrite (N, New_Occurrence_Of (Ren, Loc));
 457
 458             --  Otherwise the renamed object denotes a name
 459
 460             else
 461                Rewrite (N, New_Copy_Tree (Ren, New_Sloc => Loc));
 462                Reset_Analyzed_Flags (N);
 463             end if;
 464
 465             Analyze_And_Resolve (N, Typ);
 466          end if;
 467       end if;
 468    end Expand_SPARK_Potential_Renaming;
 469
 470 end Exp_SPARK;