gcc/ada/g-dyntab.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                   G N A T . D Y N A M I C _ T A B L E S                  --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --                            $Revision: 1.11 $
  10 --                                                                          --
  11 --            Copyright (C) 2000-2001 Ada Core Technologies, Inc.           --
  12 --                                                                          --
  13 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  14 -- terms of the  GNU General Public License as published  by the Free Soft- --
  15 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  16 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  17 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  18 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  19 -- for  more details.  You should have  received  a copy of the GNU General --
  20 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  21 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  22 -- MA 02111-1307, USA.                                                      --
  23 --                                                                          --
  24 -- As a special exception,  if other files  instantiate  generics from this --
  25 -- unit, or you link  this unit with other files  to produce an executable, --
  26 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  27 -- covered  by the  GNU  General  Public  License.  This exception does not --
  28 -- however invalidate  any other reasons why  the executable file  might be --
  29 -- covered by the  GNU Public License.                                      --
  30 --                                                                          --
  31 -- GNAT is maintained by Ada Core Technologies Inc (http://www.gnat.com).   --
  32 --                                                                          --
  33 ------------------------------------------------------------------------------
  34
  35 --  Resizable one dimensional array support
  36
  37 --  This package provides an implementation of dynamically resizable one
  38 --  dimensional arrays. The idea is to mimic the normal Ada semantics for
  39 --  arrays as closely as possible with the one additional capability of
  40 --  dynamically modifying the value of the Last attribute.
  41
  42 --  This package provides a facility similar to that of GNAT.Table, except
  43 --  that this package declares a type that can be used to define dynamic
  44 --  instances of the table, while an instantiation of GNAT.Table creates a
  45 --  single instance of the table type.
  46
  47 --  Note that this interface should remain synchronized with those in
  48 --  GNAT.Table and the GNAT compiler source unit Table to keep as much
  49 --  coherency as possible between these three related units.
  50
  51 generic
  52    type Table_Component_Type is private;
  53    type Table_Index_Type     is range <>;
  54
  55    Table_Low_Bound : Table_Index_Type;
  56    Table_Initial   : Positive;
  57    Table_Increment : Natural;
  58
  59 package GNAT.Dynamic_Tables is
  60
  61    --  Table_Component_Type and Table_Index_Type specify the type of the
  62    --  array, Table_Low_Bound is the lower bound. Index_type must be an
  63    --  integer type. The effect is roughly to declare:
  64
  65    --    Table : array (Table_Low_Bound .. <>) of Table_Component_Type;
  66
  67    --  Table_Component_Type may be any Ada type, except that controlled
  68    --  types are not supported. Note however that default initialization
  69    --  will NOT occur for array components.
  70
  71    --  The Table_Initial values controls the allocation of the table when
  72    --  it is first allocated, either by default, or by an explicit Init
  73    --  call.
  74
  75    --  The Table_Increment value controls the amount of increase, if the
  76    --  table has to be increased in size. The value given is a percentage
  77    --  value (e.g. 100 = increase table size by 100%, i.e. double it).
  78
  79    --  The Last and Set_Last subprograms provide control over the current
  80    --  logical allocation. They are quite efficient, so they can be used
  81    --  freely (expensive reallocation occurs only at major granularity
  82    --  chunks controlled by the allocation parameters).
  83
  84    --  Note: we do not make the table components aliased, since this would
  85    --  restrict the use of table for discriminated types. If it is necessary
  86    --  to take the access of a table element, use Unrestricted_Access.
  87
  88    type Table_Type is
  89      array (Table_Index_Type range <>) of Table_Component_Type;
  90
  91    subtype Big_Table_Type is
  92      Table_Type (Table_Low_Bound .. Table_Index_Type'Last);
  93    --  We work with pointers to a bogus array type that is constrained
  94    --  with the maximum possible range bound. This means that the pointer
  95    --  is a thin pointer, which is more efficient. Since subscript checks
  96    --  in any case must be on the logical, rather than physical bounds,
  97    --  safety is not compromised by this approach.
  98
  99    type Table_Ptr is access all Big_Table_Type;
 100    --  The table is actually represented as a pointer to allow
 101    --  reallocation.
 102
 103    type Table_Private is private;
 104    --  table private data that is not exported in Instance.
 105
 106    type Instance is record
 107       Table : aliased Table_Ptr := null;
 108    --  The table itself. The lower bound is the value of Low_Bound.
 109    --  Logically the upper bound is the current value of Last (although
 110    --  the actual size of the allocated table may be larger than this).
 111    --  The program may only access and modify Table entries in the
 112    --  range First .. Last.
 113
 114       P : Table_Private;
 115    end record;
 116
 117    procedure Init (T : in out Instance);
 118    --  This procedure allocates a new table of size Initial (freeing any
 119    --  previously allocated larger table). Init must be called before using
 120    --  the table. Init is convenient in reestablishing a table for new use.
 121
 122    function Last (T : in Instance) return Table_Index_Type;
 123    pragma Inline (Last);
 124    --  Returns the current value of the last used entry in the table,
 125    --  which can then be used as a subscript for Table. Note that the
 126    --  only way to modify Last is to call the Set_Last procedure. Last
 127    --  must always be used to determine the logically last entry.
 128
 129    procedure Release (T : in out Instance);
 130    --  Storage is allocated in chunks according to the values given in the
 131    --  Initial and Increment parameters. A call to Release releases all
 132    --  storage that is allocated, but is not logically part of the current
 133    --  array value. Current array values are not affected by this call.
 134
 135    procedure Free (T : in out Instance);
 136    --  Free all allocated memory for the table. A call to init is required
 137    --  before any use of this table after calling Free.
 138
 139    First : constant Table_Index_Type := Table_Low_Bound;
 140    --  Export First as synonym for Low_Bound (parallel with use of Last)
 141
 142    procedure Set_Last (T : in out Instance; New_Val : Table_Index_Type);
 143    pragma Inline (Set_Last);
 144    --  This procedure sets Last to the indicated value. If necessary the
 145    --  table is reallocated to accomodate the new value (i.e. on return
 146    --  the allocated table has an upper bound of at least Last). If
 147    --  Set_Last reduces the size of the table, then logically entries are
 148    --  removed from the table. If Set_Last increases the size of the
 149    --  table, then new entries are logically added to the table.
 150
 151    procedure Increment_Last (T : in out Instance);
 152    pragma Inline (Increment_Last);
 153    --  Adds 1 to Last (same as Set_Last (Last + 1).
 154
 155    procedure Decrement_Last (T : in out Instance);
 156    pragma Inline (Decrement_Last);
 157    --  Subtracts 1 from Last (same as Set_Last (Last - 1).
 158
 159    procedure Append (T : in out Instance; New_Val : Table_Component_Type);
 160    pragma Inline (Append);
 161    --  Equivalent to:
 162    --    Increment_Last (T);
 163    --    T.Table (T.Last) := New_Val;
 164    --  i.e. the table size is increased by one, and the given new item
 165    --  stored in the newly created table element.
 166
 167    procedure Set_Item
 168      (T     : in out Instance;
 169       Index : Table_Index_Type;
 170       Item  : Table_Component_Type);
 171    pragma Inline (Set_Item);
 172    --  Put Item in the table at position Index. The table is expanded if
 173    --  current table length is less than Index and in that case Last is set to
 174    --  Index. Item will replace any value already present in the table at this
 175    --  position.
 176
 177    procedure Allocate (T : in out Instance; Num : Integer := 1);
 178    pragma Inline (Allocate);
 179    --  Adds Num to Last.
 180
 181 private
 182
 183    type Table_Private is record
 184       Max : Integer;
 185       --  Subscript of the maximum entry in the currently allocated table
 186
 187       Length : Integer := 0;
 188       --  Number of entries in currently allocated table. The value of zero
 189       --  ensures that we initially allocate the table.
 190
 191       Last_Val : Integer;
 192       --  Current value of Last.
 193    end record;
 194
 195 end GNAT.Dynamic_Tables;