[multiple changes]
[gcc.git] / gcc / ada / g-socket.ads
1 ------------------------------------------------------------------------------
2 -- --
3 -- GNAT COMPILER COMPONENTS --
4 -- --
5 -- G N A T . S O C K E T S --
6 -- --
7 -- S p e c --
8 -- --
9 -- Copyright (C) 2001-2008, AdaCore --
10 -- --
11 -- GNAT is free software; you can redistribute it and/or modify it under --
12 -- terms of the GNU General Public License as published by the Free Soft- --
13 -- ware Foundation; either version 2, or (at your option) any later ver- --
14 -- sion. GNAT is distributed in the hope that it will be useful, but WITH- --
15 -- OUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY --
16 -- or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License --
17 -- for more details. You should have received a copy of the GNU General --
18 -- Public License distributed with GNAT; see file COPYING. If not, write --
19 -- to the Free Software Foundation, 51 Franklin Street, Fifth Floor, --
20 -- Boston, MA 02110-1301, USA. --
21 -- --
22 -- As a special exception, if other files instantiate generics from this --
23 -- unit, or you link this unit with other files to produce an executable, --
24 -- this unit does not by itself cause the resulting executable to be --
25 -- covered by the GNU General Public License. This exception does not --
26 -- however invalidate any other reasons why the executable file might be --
27 -- covered by the GNU Public License. --
28 -- --
29 -- GNAT was originally developed by the GNAT team at New York University. --
30 -- Extensive contributions were provided by Ada Core Technologies Inc. --
31 -- --
32 ------------------------------------------------------------------------------
33
34 -- This package provides an interface to the sockets communication facility
35 -- provided on many operating systems. This is implemented on the following
36 -- platforms:
37
38 -- All native ports, with restrictions as follows
39
40 -- Multicast is available only on systems which provide support for this
41 -- feature, so it is not available if Multicast is not supported, or not
42 -- installed.
43
44 -- The VMS implementation was implemented using the DECC RTL Socket API,
45 -- and is thus subject to limitations in the implementation of this API.
46
47 -- VxWorks cross ports fully implement this package
48
49 -- This package is not yet implemented on LynxOS or other cross ports
50
51 with Ada.Exceptions;
52 with Ada.Streams;
53 with Ada.Unchecked_Deallocation;
54
55 with Interfaces.C;
56
57 with System.OS_Constants;
58 with System.Storage_Elements;
59
60 package GNAT.Sockets is
61
62 -- Sockets are designed to provide a consistent communication facility
63 -- between applications. This package provides an Ada binding to the
64 -- the de-facto standard BSD sockets API. The documentation below covers
65 -- only the specific binding provided by this package. It assumes that
66 -- the reader is already familiar with general network programming and
67 -- sockets usage. A useful reference on this matter is W. Richard Stevens'
68 -- "UNIX Network Programming: The Sockets Networking API"
69 -- (ISBN: 0131411551).
70
71 -- GNAT.Sockets has been designed with several ideas in mind
72
73 -- This is a system independent interface. Therefore, we try as much as
74 -- possible to mask system incompatibilities. Some functionalities are not
75 -- available because there are not fully supported on some systems.
76
77 -- This is a thick binding. For instance, a major effort has been done to
78 -- avoid using memory addresses or untyped ints. We preferred to define
79 -- streams and enumeration types. Errors are not returned as returned
80 -- values but as exceptions.
81
82 -- This package provides a POSIX-compliant interface (between two
83 -- different implementations of the same routine, we adopt the one closest
84 -- to the POSIX specification). For instance, using select(), the
85 -- notification of an asynchronous connect failure is delivered in the
86 -- write socket set (POSIX) instead of the exception socket set (NT).
87
88 -- The example below demonstrates various features of GNAT.Sockets:
89
90 -- with GNAT.Sockets; use GNAT.Sockets;
91
92 -- with Ada.Text_IO;
93 -- with Ada.Exceptions; use Ada.Exceptions;
94
95 -- procedure PingPong is
96
97 -- Group : constant String := "239.255.128.128";
98 -- -- Multicast group: administratively scoped IP address
99
100 -- task Pong is
101 -- entry Start;
102 -- entry Stop;
103 -- end Pong;
104
105 -- task body Pong is
106 -- Address : Sock_Addr_Type;
107 -- Server : Socket_Type;
108 -- Socket : Socket_Type;
109 -- Channel : Stream_Access;
110
111 -- begin
112 -- accept Start;
113 --
114 -- -- Get an Internet address of a host (here the local host name).
115 -- -- Note that a host can have several addresses. Here we get
116 -- -- the first one which is supposed to be the official one.
117
118 -- Address.Addr := Addresses (Get_Host_By_Name (Host_Name), 1);
119
120 -- -- Get a socket address that is an Internet address and a port
121
122 -- Address.Port := 5876;
123
124 -- -- The first step is to create a socket. Once created, this
125 -- -- socket must be associated to with an address. Usually only a
126 -- -- server (Pong here) needs to bind an address explicitly. Most
127 -- -- of the time clients can skip this step because the socket
128 -- -- routines will bind an arbitrary address to an unbound socket.
129
130 -- Create_Socket (Server);
131
132 -- -- Allow reuse of local addresses
133
134 -- Set_Socket_Option
135 -- (Server,
136 -- Socket_Level,
137 -- (Reuse_Address, True));
138
139 -- Bind_Socket (Server, Address);
140
141 -- -- A server marks a socket as willing to receive connect events
142
143 -- Listen_Socket (Server);
144
145 -- -- Once a server calls Listen_Socket, incoming connects events
146 -- -- can be accepted. The returned Socket is a new socket that
147 -- -- represents the server side of the connection. Server remains
148 -- -- available to receive further connections.
149
150 -- Accept_Socket (Server, Socket, Address);
151
152 -- -- Return a stream associated to the connected socket
153
154 -- Channel := Stream (Socket);
155
156 -- -- Force Pong to block
157
158 -- delay 0.2;
159
160 -- -- Receive and print message from client Ping
161
162 -- declare
163 -- Message : String := String'Input (Channel);
164
165 -- begin
166 -- Ada.Text_IO.Put_Line (Message);
167
168 -- -- Send same message back to client Ping
169
170 -- String'Output (Channel, Message);
171 -- end;
172
173 -- Close_Socket (Server);
174 -- Close_Socket (Socket);
175
176 -- -- Part of the multicast example
177
178 -- -- Create a datagram socket to send connectionless, unreliable
179 -- -- messages of a fixed maximum length.
180
181 -- Create_Socket (Socket, Family_Inet, Socket_Datagram);
182
183 -- -- Allow reuse of local addresses
184
185 -- Set_Socket_Option
186 -- (Socket,
187 -- Socket_Level,
188 -- (Reuse_Address, True));
189
190 -- -- Controls the live time of the datagram to avoid it being
191 -- -- looped forever due to routing errors. Routers decrement
192 -- -- the TTL of every datagram as it traverses from one network
193 -- -- to another and when its value reaches 0 the packet is
194 -- -- dropped. Default is 1.
195
196 -- Set_Socket_Option
197 -- (Socket,
198 -- IP_Protocol_For_IP_Level,
199 -- (Multicast_TTL, 1));
200
201 -- -- Want the data you send to be looped back to your host
202
203 -- Set_Socket_Option
204 -- (Socket,
205 -- IP_Protocol_For_IP_Level,
206 -- (Multicast_Loop, True));
207
208 -- -- If this socket is intended to receive messages, bind it
209 -- -- to a given socket address.
210
211 -- Address.Addr := Any_Inet_Addr;
212 -- Address.Port := 55505;
213
214 -- Bind_Socket (Socket, Address);
215
216 -- -- Join a multicast group
217
218 -- -- Portability note: On Windows, this option may be set only
219 -- -- on a bound socket.
220
221 -- Set_Socket_Option
222 -- (Socket,
223 -- IP_Protocol_For_IP_Level,
224 -- (Add_Membership, Inet_Addr (Group), Any_Inet_Addr));
225
226 -- -- If this socket is intended to send messages, provide the
227 -- -- receiver socket address.
228
229 -- Address.Addr := Inet_Addr (Group);
230 -- Address.Port := 55506;
231
232 -- Channel := Stream (Socket, Address);
233
234 -- -- Receive and print message from client Ping
235
236 -- declare
237 -- Message : String := String'Input (Channel);
238
239 -- begin
240 -- -- Get the address of the sender
241
242 -- Address := Get_Address (Channel);
243 -- Ada.Text_IO.Put_Line (Message & " from " & Image (Address));
244
245 -- -- Send same message back to client Ping
246
247 -- String'Output (Channel, Message);
248 -- end;
249
250 -- Close_Socket (Socket);
251
252 -- accept Stop;
253
254 -- exception when E : others =>
255 -- Ada.Text_IO.Put_Line
256 -- (Exception_Name (E) & ": " & Exception_Message (E));
257 -- end Pong;
258
259 -- task Ping is
260 -- entry Start;
261 -- entry Stop;
262 -- end Ping;
263
264 -- task body Ping is
265 -- Address : Sock_Addr_Type;
266 -- Socket : Socket_Type;
267 -- Channel : Stream_Access;
268
269 -- begin
270 -- accept Start;
271
272 -- -- See comments in Ping section for the first steps
273
274 -- Address.Addr := Addresses (Get_Host_By_Name (Host_Name), 1);
275 -- Address.Port := 5876;
276 -- Create_Socket (Socket);
277
278 -- Set_Socket_Option
279 -- (Socket,
280 -- Socket_Level,
281 -- (Reuse_Address, True));
282
283 -- -- Force Pong to block
284
285 -- delay 0.2;
286
287 -- -- If the client's socket is not bound, Connect_Socket will
288 -- -- bind to an unused address. The client uses Connect_Socket to
289 -- -- create a logical connection between the client's socket and
290 -- -- a server's socket returned by Accept_Socket.
291
292 -- Connect_Socket (Socket, Address);
293
294 -- Channel := Stream (Socket);
295
296 -- -- Send message to server Pong
297
298 -- String'Output (Channel, "Hello world");
299
300 -- -- Force Ping to block
301
302 -- delay 0.2;
303
304 -- -- Receive and print message from server Pong
305
306 -- Ada.Text_IO.Put_Line (String'Input (Channel));
307 -- Close_Socket (Socket);
308
309 -- -- Part of multicast example. Code similar to Pong's one
310
311 -- Create_Socket (Socket, Family_Inet, Socket_Datagram);
312
313 -- Set_Socket_Option
314 -- (Socket,
315 -- Socket_Level,
316 -- (Reuse_Address, True));
317
318 -- Set_Socket_Option
319 -- (Socket,
320 -- IP_Protocol_For_IP_Level,
321 -- (Multicast_TTL, 1));
322
323 -- Set_Socket_Option
324 -- (Socket,
325 -- IP_Protocol_For_IP_Level,
326 -- (Multicast_Loop, True));
327
328 -- Address.Addr := Any_Inet_Addr;
329 -- Address.Port := 55506;
330
331 -- Bind_Socket (Socket, Address);
332
333 -- Set_Socket_Option
334 -- (Socket,
335 -- IP_Protocol_For_IP_Level,
336 -- (Add_Membership, Inet_Addr (Group), Any_Inet_Addr));
337
338 -- Address.Addr := Inet_Addr (Group);
339 -- Address.Port := 55505;
340
341 -- Channel := Stream (Socket, Address);
342
343 -- -- Send message to server Pong
344
345 -- String'Output (Channel, "Hello world");
346
347 -- -- Receive and print message from server Pong
348
349 -- declare
350 -- Message : String := String'Input (Channel);
351
352 -- begin
353 -- Address := Get_Address (Channel);
354 -- Ada.Text_IO.Put_Line (Message & " from " & Image (Address));
355 -- end;
356
357 -- Close_Socket (Socket);
358
359 -- accept Stop;
360
361 -- exception when E : others =>
362 -- Ada.Text_IO.Put_Line
363 -- (Exception_Name (E) & ": " & Exception_Message (E));
364 -- end Ping;
365
366 -- begin
367 -- Initialize;
368 -- Ping.Start;
369 -- Pong.Start;
370 -- Ping.Stop;
371 -- Pong.Stop;
372 -- Finalize;
373 -- end PingPong;
374
375 package SOSC renames System.OS_Constants;
376 -- Renaming used to provide short-hand notations throughout the sockets
377 -- binding. Note that System.OS_Constants is an internal unit, and the
378 -- entities declared therein are not meant for direct access by users,
379 -- including through this renaming.
380
381 procedure Initialize;
382 -- Initialize must be called before using any other socket routines.
383 -- Note that this operation is a no-op on UNIX platforms, but applications
384 -- should make sure to call it if portability is expected: some platforms
385 -- (such as Windows) require initialization before any socket operation.
386
387 procedure Initialize (Process_Blocking_IO : Boolean);
388 pragma Obsolescent
389 (Entity => Initialize,
390 Message => "passing a parameter to Initialize is not supported anymore");
391 -- Previous versions of GNAT.Sockets used to require the user to indicate
392 -- whether socket I/O was process- or thread-blocking on the platform.
393 -- This property is now determined automatically when the run-time library
394 -- is built. The old version of Initialize, taking a parameter, is kept
395 -- for compatibility reasons, but this interface is obsolete (and if the
396 -- value given is wrong, an exception will be raised at run time).
397
398 procedure Finalize;
399 -- After Finalize is called it is not possible to use any routines
400 -- exported in by this package. This procedure is idempotent.
401
402 type Socket_Type is private;
403 -- Sockets are used to implement a reliable bi-directional point-to-point,
404 -- stream-based connections between hosts. No_Socket provides a special
405 -- value to denote uninitialized sockets.
406
407 No_Socket : constant Socket_Type;
408
409 type Selector_Type is limited private;
410 type Selector_Access is access all Selector_Type;
411 -- Selector objects are used to wait for i/o events to occur on sockets
412
413 -- Timeval_Duration is a subtype of Standard.Duration because the full
414 -- range of Standard.Duration cannot be represented in the equivalent C
415 -- structure. Moreover, negative values are not allowed to avoid system
416 -- incompatibilities.
417
418 Immediate : constant Duration := 0.0;
419
420 Timeval_Forever : constant := 2.0 ** (SOSC.SIZEOF_tv_sec * 8 - 1) - 1.0;
421 Forever : constant Duration :=
422 Duration'Min (Duration'Last, Timeval_Forever);
423
424 subtype Timeval_Duration is Duration range Immediate .. Forever;
425
426 subtype Selector_Duration is Timeval_Duration;
427 -- Timeout value for selector operations
428
429 type Selector_Status is (Completed, Expired, Aborted);
430 -- Completion status of a selector operation, indicated as follows:
431 -- Complete: one of the expected events occurred
432 -- Expired: no event occurred before the expiration of the timeout
433 -- Aborted: an external action cancelled the wait operation before
434 -- any event occurred.
435
436 Socket_Error : exception;
437 -- There is only one exception in this package to deal with an error during
438 -- a socket routine. Once raised, its message contains a string describing
439 -- the error code.
440
441 function Image (Socket : Socket_Type) return String;
442 -- Return a printable string for Socket
443
444 function To_C (Socket : Socket_Type) return Integer;
445 -- Return a file descriptor to be used by external subprograms. This is
446 -- useful for C functions that are not yet interfaced in this package.
447
448 type Family_Type is (Family_Inet, Family_Inet6);
449 -- Address family (or protocol family) identifies the communication domain
450 -- and groups protocols with similar address formats. IPv6 will soon be
451 -- supported.
452
453 type Mode_Type is (Socket_Stream, Socket_Datagram);
454 -- Stream sockets provide connection-oriented byte streams. Datagram
455 -- sockets support unreliable connectionless message based communication.
456
457 type Shutmode_Type is (Shut_Read, Shut_Write, Shut_Read_Write);
458 -- When a process closes a socket, the policy is to retain any data queued
459 -- until either a delivery or a timeout expiration (in this case, the data
460 -- are discarded). A finer control is available through shutdown. With
461 -- Shut_Read, no more data can be received from the socket. With_Write, no
462 -- more data can be transmitted. Neither transmission nor reception can be
463 -- performed with Shut_Read_Write.
464
465 type Port_Type is new Natural;
466 -- Classical port definition. No_Port provides a special value to
467 -- denote uninitialized port. Any_Port provides a special value
468 -- enabling all ports.
469
470 Any_Port : constant Port_Type;
471 No_Port : constant Port_Type;
472
473 type Inet_Addr_Type (Family : Family_Type := Family_Inet) is private;
474 -- An Internet address depends on an address family (IPv4 contains 4 octets
475 -- and IPv6 contains 16 octets). Any_Inet_Addr is a special value treated
476 -- like a wildcard enabling all addresses. No_Inet_Addr provides a special
477 -- value to denote uninitialized inet addresses.
478
479 Any_Inet_Addr : constant Inet_Addr_Type;
480 No_Inet_Addr : constant Inet_Addr_Type;
481 Broadcast_Inet_Addr : constant Inet_Addr_Type;
482
483 type Sock_Addr_Type (Family : Family_Type := Family_Inet) is record
484 Addr : Inet_Addr_Type (Family);
485 Port : Port_Type;
486 end record;
487 -- Socket addresses fully define a socket connection with protocol family,
488 -- an Internet address and a port. No_Sock_Addr provides a special value
489 -- for uninitialized socket addresses.
490
491 No_Sock_Addr : constant Sock_Addr_Type;
492
493 function Image (Value : Inet_Addr_Type) return String;
494 -- Return an image of an Internet address. IPv4 notation consists in 4
495 -- octets in decimal format separated by dots. IPv6 notation consists in
496 -- 16 octets in hexadecimal format separated by colons (and possibly
497 -- dots).
498
499 function Image (Value : Sock_Addr_Type) return String;
500 -- Return inet address image and port image separated by a colon
501
502 function Inet_Addr (Image : String) return Inet_Addr_Type;
503 -- Convert address image from numbers-and-dots notation into an
504 -- inet address.
505
506 -- Host entries provide complete information on a given host: the official
507 -- name, an array of alternative names or aliases and array of network
508 -- addresses.
509
510 type Host_Entry_Type
511 (Aliases_Length, Addresses_Length : Natural) is private;
512
513 function Official_Name (E : Host_Entry_Type) return String;
514 -- Return official name in host entry
515
516 function Aliases_Length (E : Host_Entry_Type) return Natural;
517 -- Return number of aliases in host entry
518
519 function Addresses_Length (E : Host_Entry_Type) return Natural;
520 -- Return number of addresses in host entry
521
522 function Aliases
523 (E : Host_Entry_Type;
524 N : Positive := 1) return String;
525 -- Return N'th aliases in host entry. The first index is 1
526
527 function Addresses
528 (E : Host_Entry_Type;
529 N : Positive := 1) return Inet_Addr_Type;
530 -- Return N'th addresses in host entry. The first index is 1
531
532 Host_Error : exception;
533 -- Exception raised by the two following procedures. Once raised, its
534 -- message contains a string describing the error code. This exception is
535 -- raised when an host entry cannot be retrieved.
536
537 function Get_Host_By_Address
538 (Address : Inet_Addr_Type;
539 Family : Family_Type := Family_Inet) return Host_Entry_Type;
540 -- Return host entry structure for the given Inet address. Note that no
541 -- result will be returned if there is no mapping of this IP address to a
542 -- host name in the system tables (host database, DNS or otherwise).
543
544 function Get_Host_By_Name
545 (Name : String) return Host_Entry_Type;
546 -- Return host entry structure for the given host name. Here name is
547 -- either a host name, or an IP address. If Name is an IP address, this
548 -- is equivalent to Get_Host_By_Address (Inet_Addr (Name)).
549
550 function Host_Name return String;
551 -- Return the name of the current host
552
553 type Service_Entry_Type (Aliases_Length : Natural) is private;
554 -- Service entries provide complete information on a given service: the
555 -- official name, an array of alternative names or aliases and the port
556 -- number.
557
558 function Official_Name (S : Service_Entry_Type) return String;
559 -- Return official name in service entry
560
561 function Port_Number (S : Service_Entry_Type) return Port_Type;
562 -- Return port number in service entry
563
564 function Protocol_Name (S : Service_Entry_Type) return String;
565 -- Return Protocol in service entry (usually UDP or TCP)
566
567 function Aliases_Length (S : Service_Entry_Type) return Natural;
568 -- Return number of aliases in service entry
569
570 function Aliases
571 (S : Service_Entry_Type;
572 N : Positive := 1) return String;
573 -- Return N'th aliases in service entry (the first index is 1)
574
575 function Get_Service_By_Name
576 (Name : String;
577 Protocol : String) return Service_Entry_Type;
578 -- Return service entry structure for the given service name
579
580 function Get_Service_By_Port
581 (Port : Port_Type;
582 Protocol : String) return Service_Entry_Type;
583 -- Return service entry structure for the given service port number
584
585 Service_Error : exception;
586 -- Comment required ???
587
588 -- Errors are described by an enumeration type. There is only one exception
589 -- Socket_Error in this package to deal with an error during a socket
590 -- routine. Once raised, its message contains the error code between
591 -- brackets and a string describing the error code.
592
593 -- The name of the enumeration constant documents the error condition
594
595 type Error_Type is
596 (Success,
597 Permission_Denied,
598 Address_Already_In_Use,
599 Cannot_Assign_Requested_Address,
600 Address_Family_Not_Supported_By_Protocol,
601 Operation_Already_In_Progress,
602 Bad_File_Descriptor,
603 Software_Caused_Connection_Abort,
604 Connection_Refused,
605 Connection_Reset_By_Peer,
606 Destination_Address_Required,
607 Bad_Address,
608 Host_Is_Down,
609 No_Route_To_Host,
610 Operation_Now_In_Progress,
611 Interrupted_System_Call,
612 Invalid_Argument,
613 Input_Output_Error,
614 Transport_Endpoint_Already_Connected,
615 Too_Many_Symbolic_Links,
616 Too_Many_Open_Files,
617 Message_Too_Long,
618 File_Name_Too_Long,
619 Network_Is_Down,
620 Network_Dropped_Connection_Because_Of_Reset,
621 Network_Is_Unreachable,
622 No_Buffer_Space_Available,
623 Protocol_Not_Available,
624 Transport_Endpoint_Not_Connected,
625 Socket_Operation_On_Non_Socket,
626 Operation_Not_Supported,
627 Protocol_Family_Not_Supported,
628 Protocol_Not_Supported,
629 Protocol_Wrong_Type_For_Socket,
630 Cannot_Send_After_Transport_Endpoint_Shutdown,
631 Socket_Type_Not_Supported,
632 Connection_Timed_Out,
633 Too_Many_References,
634 Resource_Temporarily_Unavailable,
635 Unknown_Host,
636 Host_Name_Lookup_Failure,
637 Non_Recoverable_Error,
638 Unknown_Server_Error,
639 Cannot_Resolve_Error);
640
641 -- Get_Socket_Options and Set_Socket_Options manipulate options associated
642 -- with a socket. Options may exist at multiple protocol levels in the
643 -- communication stack. Socket_Level is the uppermost socket level.
644
645 type Level_Type is (
646 Socket_Level,
647 IP_Protocol_For_IP_Level,
648 IP_Protocol_For_UDP_Level,
649 IP_Protocol_For_TCP_Level);
650
651 -- There are several options available to manipulate sockets. Each option
652 -- has a name and several values available. Most of the time, the value is
653 -- a boolean to enable or disable this option.
654
655 type Option_Name is (
656 Keep_Alive, -- Enable sending of keep-alive messages
657 Reuse_Address, -- Allow bind to reuse local address
658 Broadcast, -- Enable datagram sockets to recv/send broadcasts
659 Send_Buffer, -- Set/get the maximum socket send buffer in bytes
660 Receive_Buffer, -- Set/get the maximum socket recv buffer in bytes
661 Linger, -- Shutdown wait for msg to be sent or timeout occur
662 Error, -- Get and clear the pending socket error
663 No_Delay, -- Do not delay send to coalesce data (TCP_NODELAY)
664 Add_Membership, -- Join a multicast group
665 Drop_Membership, -- Leave a multicast group
666 Multicast_If, -- Set default out interface for multicast packets
667 Multicast_TTL, -- Set the time-to-live of sent multicast packets
668 Multicast_Loop, -- Sent multicast packets are looped to local socket
669 Receive_Packet_Info, -- Receive low level packet info as ancillary data
670 Send_Timeout, -- Set timeout value for output
671 Receive_Timeout); -- Set timeout value for input
672
673 type Option_Type (Name : Option_Name := Keep_Alive) is record
674 case Name is
675 when Keep_Alive |
676 Reuse_Address |
677 Broadcast |
678 Linger |
679 No_Delay |
680 Receive_Packet_Info |
681 Multicast_Loop =>
682 Enabled : Boolean;
683
684 case Name is
685 when Linger =>
686 Seconds : Natural;
687 when others =>
688 null;
689 end case;
690
691 when Send_Buffer |
692 Receive_Buffer =>
693 Size : Natural;
694
695 when Error =>
696 Error : Error_Type;
697
698 when Add_Membership |
699 Drop_Membership =>
700 Multicast_Address : Inet_Addr_Type;
701 Local_Interface : Inet_Addr_Type;
702
703 when Multicast_If =>
704 Outgoing_If : Inet_Addr_Type;
705
706 when Multicast_TTL =>
707 Time_To_Live : Natural;
708
709 when Send_Timeout |
710 Receive_Timeout =>
711 Timeout : Timeval_Duration;
712
713 end case;
714 end record;
715
716 -- There are several controls available to manipulate sockets. Each option
717 -- has a name and several values available. These controls differ from the
718 -- socket options in that they are not specific to sockets but are
719 -- available for any device.
720
721 type Request_Name is (
722 Non_Blocking_IO, -- Cause a caller not to wait on blocking operations.
723 N_Bytes_To_Read); -- Return the number of bytes available to read
724
725 type Request_Type (Name : Request_Name := Non_Blocking_IO) is record
726 case Name is
727 when Non_Blocking_IO =>
728 Enabled : Boolean;
729
730 when N_Bytes_To_Read =>
731 Size : Natural;
732
733 end case;
734 end record;
735
736 -- A request flag allows to specify the type of message transmissions or
737 -- receptions. A request flag can be combination of zero or more
738 -- predefined request flags.
739
740 type Request_Flag_Type is private;
741
742 No_Request_Flag : constant Request_Flag_Type;
743 -- This flag corresponds to the normal execution of an operation
744
745 Process_Out_Of_Band_Data : constant Request_Flag_Type;
746 -- This flag requests that the receive or send function operates on
747 -- out-of-band data when the socket supports this notion (e.g.
748 -- Socket_Stream).
749
750 Peek_At_Incoming_Data : constant Request_Flag_Type;
751 -- This flag causes the receive operation to return data from the beginning
752 -- of the receive queue without removing that data from the queue. A
753 -- subsequent receive call will return the same data.
754
755 Wait_For_A_Full_Reception : constant Request_Flag_Type;
756 -- This flag requests that the operation block until the full request is
757 -- satisfied. However, the call may still return less data than requested
758 -- if a signal is caught, an error or disconnect occurs, or the next data
759 -- to be received is of a different type than that returned. Note that
760 -- this flag depends on support in the underlying sockets implementation,
761 -- and is not supported under Windows.
762
763 Send_End_Of_Record : constant Request_Flag_Type;
764 -- This flag indicates that the entire message has been sent and so this
765 -- terminates the record.
766
767 function "+" (L, R : Request_Flag_Type) return Request_Flag_Type;
768 -- Combine flag L with flag R
769
770 type Stream_Element_Reference is access all Ada.Streams.Stream_Element;
771
772 type Vector_Element is record
773 Base : Stream_Element_Reference;
774 Length : Ada.Streams.Stream_Element_Count;
775 end record;
776
777 type Vector_Type is array (Integer range <>) of Vector_Element;
778
779 procedure Create_Socket
780 (Socket : out Socket_Type;
781 Family : Family_Type := Family_Inet;
782 Mode : Mode_Type := Socket_Stream);
783 -- Create an endpoint for communication. Raises Socket_Error on error
784
785 procedure Accept_Socket
786 (Server : Socket_Type;
787 Socket : out Socket_Type;
788 Address : out Sock_Addr_Type);
789 -- Extracts the first connection request on the queue of pending
790 -- connections, creates a new connected socket with mostly the same
791 -- properties as Server, and allocates a new socket. The returned Address
792 -- is filled in with the address of the connection. Raises Socket_Error on
793 -- error.
794
795 procedure Accept_Socket
796 (Server : Socket_Type;
797 Socket : out Socket_Type;
798 Address : out Sock_Addr_Type;
799 Timeout : Selector_Duration;
800 Selector : access Selector_Type := null;
801 Status : out Selector_Status);
802 -- Accept a new connection on Server using Accept_Socket, waiting no longer
803 -- than the given timeout duration. Status is set to indicate whether the
804 -- operation completed successfully, timed out, or was aborted. If Selector
805 -- is not null, the designated selector is used to wait for the socket to
806 -- become available, else a private selector object is created by this
807 -- procedure and destroyed before it returns.
808
809 procedure Bind_Socket
810 (Socket : Socket_Type;
811 Address : Sock_Addr_Type);
812 -- Once a socket is created, assign a local address to it. Raise
813 -- Socket_Error on error.
814
815 procedure Close_Socket (Socket : Socket_Type);
816 -- Close a socket and more specifically a non-connected socket
817
818 procedure Connect_Socket
819 (Socket : Socket_Type;
820 Server : Sock_Addr_Type);
821 -- Make a connection to another socket which has the address of Server.
822 -- Raises Socket_Error on error.
823
824 procedure Connect_Socket
825 (Socket : Socket_Type;
826 Server : Sock_Addr_Type;
827 Timeout : Selector_Duration;
828 Selector : access Selector_Type := null;
829 Status : out Selector_Status);
830 -- Connect Socket to the given Server address using Connect_Socket, waiting
831 -- no longer than the given timeout duration. Status is set to indicate
832 -- whether the operation completed successfully, timed out, or was aborted.
833 -- If Selector is not null, the designated selector is used to wait for the
834 -- socket to become available, else a private selector object is created
835 -- by this procedure and destroyed before it returns.
836
837 procedure Control_Socket
838 (Socket : Socket_Type;
839 Request : in out Request_Type);
840 -- Obtain or set parameter values that control the socket. This control
841 -- differs from the socket options in that they are not specific to sockets
842 -- but are available for any device.
843
844 function Get_Peer_Name (Socket : Socket_Type) return Sock_Addr_Type;
845 -- Return the peer or remote socket address of a socket. Raise
846 -- Socket_Error on error.
847
848 function Get_Socket_Name (Socket : Socket_Type) return Sock_Addr_Type;
849 -- Return the local or current socket address of a socket. Return
850 -- No_Sock_Addr on error (e.g. socket closed or not locally bound).
851
852 function Get_Socket_Option
853 (Socket : Socket_Type;
854 Level : Level_Type := Socket_Level;
855 Name : Option_Name) return Option_Type;
856 -- Get the options associated with a socket. Raises Socket_Error on error
857
858 procedure Listen_Socket
859 (Socket : Socket_Type;
860 Length : Natural := 15);
861 -- To accept connections, a socket is first created with Create_Socket,
862 -- a willingness to accept incoming connections and a queue Length for
863 -- incoming connections are specified. Raise Socket_Error on error.
864 -- The queue length of 15 is an example value that should be appropriate
865 -- in usual cases. It can be adjusted according to each application's
866 -- particular requirements.
867
868 procedure Receive_Socket
869 (Socket : Socket_Type;
870 Item : out Ada.Streams.Stream_Element_Array;
871 Last : out Ada.Streams.Stream_Element_Offset;
872 Flags : Request_Flag_Type := No_Request_Flag);
873 -- Receive message from Socket. Last is the index value such that Item
874 -- (Last) is the last character assigned. Note that Last is set to
875 -- Item'First - 1 when the socket has been closed by peer. This is not an
876 -- error and no exception is raised. Flags allows to control the
877 -- reception. Raise Socket_Error on error.
878
879 procedure Receive_Socket
880 (Socket : Socket_Type;
881 Item : out Ada.Streams.Stream_Element_Array;
882 Last : out Ada.Streams.Stream_Element_Offset;
883 From : out Sock_Addr_Type;
884 Flags : Request_Flag_Type := No_Request_Flag);
885 -- Receive message from Socket. If Socket is not connection-oriented, the
886 -- source address From of the message is filled in. Last is the index
887 -- value such that Item (Last) is the last character assigned. Flags
888 -- allows to control the reception. Raises Socket_Error on error.
889
890 procedure Receive_Vector
891 (Socket : Socket_Type;
892 Vector : Vector_Type;
893 Count : out Ada.Streams.Stream_Element_Count);
894 -- Receive data from a socket and scatter it into the set of vector
895 -- elements Vector. Count is set to the count of received stream elements.
896
897 function Resolve_Exception
898 (Occurrence : Ada.Exceptions.Exception_Occurrence) return Error_Type;
899 -- When Socket_Error or Host_Error are raised, the exception message
900 -- contains the error code between brackets and a string describing the
901 -- error code. Resolve_Error extracts the error code from an exception
902 -- message and translate it into an enumeration value.
903
904 procedure Send_Socket
905 (Socket : Socket_Type;
906 Item : Ada.Streams.Stream_Element_Array;
907 Last : out Ada.Streams.Stream_Element_Offset;
908 Flags : Request_Flag_Type := No_Request_Flag);
909 -- Transmit a message to another socket. Note that Last is set to
910 -- Item'First-1 when socket has been closed by peer. This is not
911 -- considered an error and no exception is raised. Flags allows to control
912 -- the transmission. Raises Socket_Error on any other error condition.
913
914 procedure Send_Socket
915 (Socket : Socket_Type;
916 Item : Ada.Streams.Stream_Element_Array;
917 Last : out Ada.Streams.Stream_Element_Offset;
918 To : Sock_Addr_Type;
919 Flags : Request_Flag_Type := No_Request_Flag);
920 -- Transmit a message to another socket. The address is given by To. Flags
921 -- allows to control the transmission. Raises Socket_Error on error.
922
923 procedure Send_Vector
924 (Socket : Socket_Type;
925 Vector : Vector_Type;
926 Count : out Ada.Streams.Stream_Element_Count);
927 -- Transmit data gathered from the set of vector elements Vector to a
928 -- socket. Count is set to the count of transmitted stream elements.
929
930 procedure Set_Socket_Option
931 (Socket : Socket_Type;
932 Level : Level_Type := Socket_Level;
933 Option : Option_Type);
934 -- Manipulate socket options. Raises Socket_Error on error
935
936 procedure Shutdown_Socket
937 (Socket : Socket_Type;
938 How : Shutmode_Type := Shut_Read_Write);
939 -- Shutdown a connected socket. If How is Shut_Read, further receives will
940 -- be disallowed. If How is Shut_Write, further sends will be disallowed.
941 -- If how is Shut_Read_Write, further sends and receives will be
942 -- disallowed.
943
944 type Stream_Access is access all Ada.Streams.Root_Stream_Type'Class;
945 -- Same interface as Ada.Streams.Stream_IO
946
947 function Stream (Socket : Socket_Type) return Stream_Access;
948 -- Create a stream associated with a stream-based socket that is
949 -- already connected.
950
951 function Stream
952 (Socket : Socket_Type;
953 Send_To : Sock_Addr_Type) return Stream_Access;
954 -- Create a stream associated with a datagram-based socket that is already
955 -- bound. Send_To is the socket address to which messages are being sent.
956
957 function Get_Address
958 (Stream : not null Stream_Access) return Sock_Addr_Type;
959 -- Return the socket address from which the last message was received
960
961 procedure Free is new Ada.Unchecked_Deallocation
962 (Ada.Streams.Root_Stream_Type'Class, Stream_Access);
963 -- Destroy a stream created by one of the Stream functions above,
964 -- releasing the corresponding resources. The user is responsible for
965 -- calling this subprogram when the stream is not needed anymore.
966
967 type Socket_Set_Type is limited private;
968 -- This type allows to manipulate sets of sockets. It allows to wait for
969 -- events on multiple endpoints at one time. This type used to contain
970 -- a pointer to dynamically allocated storage, but this is not the case
971 -- anymore, and no special precautions are required to avoid memory leaks.
972
973 procedure Clear (Item : in out Socket_Set_Type; Socket : Socket_Type);
974 -- Remove Socket from Item
975
976 procedure Copy (Source : Socket_Set_Type; Target : in out Socket_Set_Type);
977 -- Copy Source into Target as Socket_Set_Type is limited private
978
979 procedure Empty (Item : in out Socket_Set_Type);
980 -- Remove all Sockets from Item
981
982 procedure Get (Item : in out Socket_Set_Type; Socket : out Socket_Type);
983 -- Extract a Socket from socket set Item. Socket is set to
984 -- No_Socket when the set is empty.
985
986 function Is_Empty (Item : Socket_Set_Type) return Boolean;
987 -- Return True iff Item is empty
988
989 function Is_Set
990 (Item : Socket_Set_Type;
991 Socket : Socket_Type) return Boolean;
992 -- Return True iff Socket is present in Item
993
994 procedure Set (Item : in out Socket_Set_Type; Socket : Socket_Type);
995 -- Insert Socket into Item
996
997 function Image (Item : Socket_Set_Type) return String;
998 -- Return a printable image of Item, for debugging purposes
999
1000 -- The select(2) system call waits for events to occur on any of a set of
1001 -- file descriptors. Usually, three independent sets of descriptors are
1002 -- watched (read, write and exception). A timeout gives an upper bound
1003 -- on the amount of time elapsed before select returns. This function
1004 -- blocks until an event occurs. On some platforms, the select(2) system
1005 -- can block the full process (not just the calling thread).
1006 --
1007 -- Check_Selector provides the very same behaviour. The only difference is
1008 -- that it does not watch for exception events. Note that on some
1009 -- platforms it is kept process blocking on purpose. The timeout parameter
1010 -- allows the user to have the behaviour he wants. Abort_Selector allows
1011 -- to abort safely a Check_Selector that is blocked forever. A special
1012 -- file descriptor is opened by Create_Selector and included in each call
1013 -- to Check_Selector. Abort_Selector causes an event to occur on this
1014 -- descriptor in order to unblock Check_Selector. The user must call
1015 -- Close_Selector to discard this special file. A reason to abort a select
1016 -- operation is typically to add a socket in one of the socket sets when
1017 -- the timeout is set to forever.
1018
1019 procedure Create_Selector (Selector : out Selector_Type);
1020 -- Create a new selector
1021
1022 procedure Close_Selector (Selector : in out Selector_Type);
1023 -- Close Selector and all internal descriptors associated; deallocate any
1024 -- associated resources. This subprogram may be called only when there is
1025 -- no other task still using Selector (i.e. still executing Check_Selector
1026 -- or Abort_Selector on this Selector).
1027
1028 procedure Check_Selector
1029 (Selector : in out Selector_Type;
1030 R_Socket_Set : in out Socket_Set_Type;
1031 W_Socket_Set : in out Socket_Set_Type;
1032 Status : out Selector_Status;
1033 Timeout : Selector_Duration := Forever);
1034 -- Return when one Socket in R_Socket_Set has some data to be read or if
1035 -- one Socket in W_Socket_Set is ready to transmit some data. In these
1036 -- cases Status is set to Completed and sockets that are ready are set in
1037 -- R_Socket_Set or W_Socket_Set. Status is set to Expired if no socket was
1038 -- ready after a Timeout expiration. Status is set to Aborted if an abort
1039 -- signal has been received while checking socket status.
1040 -- Note that two different Socket_Set_Type objects must be passed as
1041 -- R_Socket_Set and W_Socket_Set (even if they denote the same set of
1042 -- Sockets), or some event may be lost.
1043 -- Socket_Error is raised when the select(2) system call returns an
1044 -- error condition, or when a read error occurs on the signalling socket
1045 -- used for the implementation of Abort_Selector.
1046
1047 procedure Check_Selector
1048 (Selector : in out Selector_Type;
1049 R_Socket_Set : in out Socket_Set_Type;
1050 W_Socket_Set : in out Socket_Set_Type;
1051 E_Socket_Set : in out Socket_Set_Type;
1052 Status : out Selector_Status;
1053 Timeout : Selector_Duration := Forever);
1054 -- This refined version of Check_Selector allows to watch for exception
1055 -- events (that is notifications of out-of-band transmission and
1056 -- reception). As above, all of R_Socket_Set, W_Socket_Set and
1057 -- E_Socket_Set must be different objects.
1058
1059 procedure Abort_Selector (Selector : Selector_Type);
1060 -- Send an abort signal to the selector
1061
1062 type Fd_Set is private;
1063 -- ??? This type must not be used directly, it needs to be visible because
1064 -- it is used in the visible part of GNAT.Sockets.Thin_Common. This is
1065 -- really an inversion of abstraction. The private part of GNAT.Sockets
1066 -- needs to have visibility on this type, but since Thin_Common is a child
1067 -- of Sockets, the type can't be declared there. The correct fix would
1068 -- be to move the thin sockets binding outside of GNAT.Sockets altogether,
1069 -- e.g. by renaming it to GNAT.Sockets_Thin.
1070
1071 private
1072
1073 type Socket_Type is new Integer;
1074 No_Socket : constant Socket_Type := -1;
1075
1076 type Selector_Type is limited record
1077 R_Sig_Socket : Socket_Type := No_Socket;
1078 W_Sig_Socket : Socket_Type := No_Socket;
1079 -- Signalling sockets used to abort a select operation
1080 end record;
1081
1082 pragma Volatile (Selector_Type);
1083
1084 type Fd_Set is
1085 new System.Storage_Elements.Storage_Array (1 .. SOSC.SIZEOF_fd_set);
1086 for Fd_Set'Alignment use Interfaces.C.int'Alignment;
1087
1088 type Fd_Set_Access is access all Fd_Set;
1089 pragma Convention (C, Fd_Set_Access);
1090 No_Fd_Set_Access : constant Fd_Set_Access := null;
1091
1092 type Socket_Set_Type is record
1093 Last : Socket_Type := No_Socket;
1094 Set : aliased Fd_Set;
1095 end record;
1096
1097 subtype Inet_Addr_Comp_Type is Natural range 0 .. 255;
1098 -- Octet for Internet address
1099
1100 type Inet_Addr_VN_Type is array (Natural range <>) of Inet_Addr_Comp_Type;
1101
1102 subtype Inet_Addr_V4_Type is Inet_Addr_VN_Type (1 .. 4);
1103 subtype Inet_Addr_V6_Type is Inet_Addr_VN_Type (1 .. 16);
1104
1105 type Inet_Addr_Type (Family : Family_Type := Family_Inet) is record
1106 case Family is
1107 when Family_Inet =>
1108 Sin_V4 : Inet_Addr_V4_Type := (others => 0);
1109
1110 when Family_Inet6 =>
1111 Sin_V6 : Inet_Addr_V6_Type := (others => 0);
1112 end case;
1113 end record;
1114
1115 Any_Port : constant Port_Type := 0;
1116 No_Port : constant Port_Type := 0;
1117
1118 Any_Inet_Addr : constant Inet_Addr_Type :=
1119 (Family_Inet, (others => 0));
1120 No_Inet_Addr : constant Inet_Addr_Type :=
1121 (Family_Inet, (others => 0));
1122 Broadcast_Inet_Addr : constant Inet_Addr_Type :=
1123 (Family_Inet, (others => 255));
1124
1125 No_Sock_Addr : constant Sock_Addr_Type := (Family_Inet, No_Inet_Addr, 0);
1126
1127 Max_Name_Length : constant := 64;
1128 -- The constant MAXHOSTNAMELEN is usually set to 64
1129
1130 subtype Name_Index is Natural range 1 .. Max_Name_Length;
1131
1132 type Name_Type
1133 (Length : Name_Index := Max_Name_Length)
1134 is record
1135 Name : String (1 .. Length);
1136 end record;
1137 -- We need fixed strings to avoid access types in host entry type
1138
1139 type Name_Array is array (Natural range <>) of Name_Type;
1140 type Inet_Addr_Array is array (Natural range <>) of Inet_Addr_Type;
1141
1142 type Host_Entry_Type (Aliases_Length, Addresses_Length : Natural) is record
1143 Official : Name_Type;
1144 Aliases : Name_Array (1 .. Aliases_Length);
1145 Addresses : Inet_Addr_Array (1 .. Addresses_Length);
1146 end record;
1147
1148 type Service_Entry_Type (Aliases_Length : Natural) is record
1149 Official : Name_Type;
1150 Aliases : Name_Array (1 .. Aliases_Length);
1151 Port : Port_Type;
1152 Protocol : Name_Type;
1153 end record;
1154
1155 type Request_Flag_Type is mod 2 ** 8;
1156 No_Request_Flag : constant Request_Flag_Type := 0;
1157 Process_Out_Of_Band_Data : constant Request_Flag_Type := 1;
1158 Peek_At_Incoming_Data : constant Request_Flag_Type := 2;
1159 Wait_For_A_Full_Reception : constant Request_Flag_Type := 4;
1160 Send_End_Of_Record : constant Request_Flag_Type := 8;
1161
1162 end GNAT.Sockets;