gcc/ada/lib-xref.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             L I B . X R E F                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1998-2011, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Csets;    use Csets;
  28 with Elists;   use Elists;
  29 with Errout;   use Errout;
  30 with Nlists;   use Nlists;
  31 with Opt;      use Opt;
  32 with Restrict; use Restrict;
  33 with Rident;   use Rident;
  34 with Sem;      use Sem;
  35 with Sem_Aux;  use Sem_Aux;
  36 with Sem_Prag; use Sem_Prag;
  37 with Sem_Util; use Sem_Util;
  38 with Sem_Warn; use Sem_Warn;
  39 with Sinfo;    use Sinfo;
  40 with Sinput;   use Sinput;
  41 with Snames;   use Snames;
  42 with Stringt;  use Stringt;
  43 with Stand;    use Stand;
  44 with Table;    use Table;
  45
  46 with GNAT.Heap_Sort_G;
  47 with GNAT.HTable;
  48
  49 package body Lib.Xref is
  50
  51    ------------------
  52    -- Declarations --
  53    ------------------
  54
  55    --  The Xref table is used to record references. The Loc field is set
  56    --  to No_Location for a definition entry.
  57
  58    subtype Xref_Entry_Number is Int;
  59
  60    type Xref_Key is record
  61       --  These are the components of Xref_Entry that participate in hash
  62       --  lookups.
  63
  64       Ent : Entity_Id;
  65       --  Entity referenced (E parameter to Generate_Reference)
  66
  67       Loc : Source_Ptr;
  68       --  Location of reference (Original_Location (Sloc field of N parameter
  69       --  to Generate_Reference). Set to No_Location for the case of a
  70       --  defining occurrence.
  71
  72       Typ : Character;
  73       --  Reference type (Typ param to Generate_Reference)
  74
  75       Eun : Unit_Number_Type;
  76       --  Unit number corresponding to Ent
  77
  78       Lun : Unit_Number_Type;
  79       --  Unit number corresponding to Loc. Value is undefined and not
  80       --  referenced if Loc is set to No_Location.
  81
  82       --  The following components are only used for Alfa cross-references
  83
  84       Ref_Scope : Entity_Id;
  85       --  Entity of the closest subprogram or package enclosing the reference
  86
  87       Ent_Scope : Entity_Id;
  88       --  Entity of the closest subprogram or package enclosing the definition,
  89       --  which should be located in the same file as the definition itself.
  90    end record;
  91
  92    type Xref_Entry is record
  93       Key : Xref_Key;
  94
  95       Ent_Scope_File : Unit_Number_Type;
  96       --  File for entity Ent_Scope
  97
  98       Def : Source_Ptr;
  99       --  Original source location for entity being referenced. Note that these
 100       --  values are used only during the output process, they are not set when
 101       --  the entries are originally built. This is because private entities
 102       --  can be swapped when the initial call is made.
 103
 104       HTable_Next : Xref_Entry_Number;
 105       --  For use only by Static_HTable
 106    end record;
 107
 108    package Xrefs is new Table.Table (
 109      Table_Component_Type => Xref_Entry,
 110      Table_Index_Type     => Xref_Entry_Number,
 111      Table_Low_Bound      => 1,
 112      Table_Initial        => Alloc.Xrefs_Initial,
 113      Table_Increment      => Alloc.Xrefs_Increment,
 114      Table_Name           => "Xrefs");
 115
 116    --------------
 117    -- Xref_Set --
 118    --------------
 119
 120    --  We keep a set of xref entries, in order to avoid inserting duplicate
 121    --  entries into the above Xrefs table. An entry is in Xref_Set if and only
 122    --  if it is in Xrefs.
 123
 124    Num_Buckets : constant := 2**16;
 125
 126    subtype Header_Num is Integer range 0 .. Num_Buckets - 1;
 127    type Null_Type is null record;
 128    pragma Unreferenced (Null_Type);
 129
 130    function Hash (F : Xref_Entry_Number) return Header_Num;
 131
 132    function Equal (F1, F2 : Xref_Entry_Number) return Boolean;
 133
 134    procedure HT_Set_Next (E : Xref_Entry_Number; Next : Xref_Entry_Number);
 135
 136    function  HT_Next (E : Xref_Entry_Number) return Xref_Entry_Number;
 137
 138    function Get_Key (E : Xref_Entry_Number) return Xref_Entry_Number;
 139
 140    pragma Inline (Hash, Equal, HT_Set_Next, HT_Next, Get_Key);
 141
 142    package Xref_Set is new GNAT.HTable.Static_HTable (
 143      Header_Num,
 144      Element    => Xref_Entry,
 145      Elmt_Ptr   => Xref_Entry_Number,
 146      Null_Ptr   => 0,
 147      Set_Next   => HT_Set_Next,
 148      Next       => HT_Next,
 149      Key        => Xref_Entry_Number,
 150      Get_Key    => Get_Key,
 151      Hash       => Hash,
 152      Equal      => Equal);
 153
 154    ----------------------
 155    -- Alfa Information --
 156    ----------------------
 157
 158    package body Alfa is separate;
 159
 160    ------------------------
 161    --  Local Subprograms --
 162    ------------------------
 163
 164    procedure Generate_Prim_Op_References (Typ : Entity_Id);
 165    --  For a tagged type, generate implicit references to its primitive
 166    --  operations, for source navigation. This is done right before emitting
 167    --  cross-reference information rather than at the freeze point of the type
 168    --  in order to handle late bodies that are primitive operations.
 169
 170    function Lt (T1, T2 : Xref_Entry) return Boolean;
 171    --  Order cross-references
 172
 173    procedure Add_Entry (Key : Xref_Key; Ent_Scope_File : Unit_Number_Type);
 174    --  Add an entry to the tables of Xref_Entries, avoiding duplicates
 175
 176    ---------------
 177    -- Add_Entry --
 178    ---------------
 179
 180    procedure Add_Entry (Key : Xref_Key; Ent_Scope_File : Unit_Number_Type) is
 181    begin
 182       Xrefs.Increment_Last; -- tentative
 183       Xrefs.Table (Xrefs.Last).Key := Key;
 184
 185       --  Set the entry in Xref_Set, and if newly set, keep the above
 186       --  tentative increment.
 187
 188       if Xref_Set.Set_If_Not_Present (Xrefs.Last) then
 189          Xrefs.Table (Xrefs.Last).Ent_Scope_File := Ent_Scope_File;
 190          --  Leave Def and HTable_Next uninitialized
 191
 192          Set_Has_Xref_Entry (Key.Ent);
 193
 194       --  It was already in Xref_Set, so throw away the tentatively-added
 195       --  entry
 196
 197       else
 198          Xrefs.Decrement_Last;
 199       end if;
 200    end Add_Entry;
 201
 202    -----------
 203    -- Equal --
 204    -----------
 205
 206    function Equal (F1, F2 : Xref_Entry_Number) return Boolean is
 207       Result : constant Boolean :=
 208                  Xrefs.Table (F1).Key = Xrefs.Table (F2).Key;
 209    begin
 210       return Result;
 211    end Equal;
 212
 213    -------------------------
 214    -- Generate_Definition --
 215    -------------------------
 216
 217    procedure Generate_Definition (E : Entity_Id) is
 218    begin
 219       pragma Assert (Nkind (E) in N_Entity);
 220
 221       --  Note that we do not test Xref_Entity_Letters here. It is too early
 222       --  to do so, since we are often called before the entity is fully
 223       --  constructed, so that the Ekind is still E_Void.
 224
 225       if Opt.Xref_Active
 226
 227          --  Definition must come from source
 228
 229          --  We make an exception for subprogram child units that have no spec.
 230          --  For these we generate a subprogram declaration for library use,
 231          --  and the corresponding entity does not come from source.
 232          --  Nevertheless, all references will be attached to it and we have
 233          --  to treat is as coming from user code.
 234
 235          and then (Comes_From_Source (E) or else Is_Child_Unit (E))
 236
 237          --  And must have a reasonable source location that is not
 238          --  within an instance (all entities in instances are ignored)
 239
 240          and then Sloc (E) > No_Location
 241          and then Instantiation_Location (Sloc (E)) = No_Location
 242
 243          --  And must be a non-internal name from the main source unit
 244
 245          and then In_Extended_Main_Source_Unit (E)
 246          and then not Is_Internal_Name (Chars (E))
 247       then
 248          Add_Entry
 249            ((Ent => E,
 250              Loc => No_Location,
 251              Typ => ' ',
 252              Eun => Get_Source_Unit (Original_Location (Sloc (E))),
 253              Lun => No_Unit,
 254              Ref_Scope => Empty,
 255              Ent_Scope => Empty),
 256             Ent_Scope_File => No_Unit);
 257
 258          if In_Inlined_Body then
 259             Set_Referenced (E);
 260          end if;
 261       end if;
 262    end Generate_Definition;
 263
 264    ---------------------------------
 265    -- Generate_Operator_Reference --
 266    ---------------------------------
 267
 268    procedure Generate_Operator_Reference
 269      (N : Node_Id;
 270       T : Entity_Id)
 271    is
 272    begin
 273       if not In_Extended_Main_Source_Unit (N) then
 274          return;
 275       end if;
 276
 277       --  If the operator is not a Standard operator, then we generate a real
 278       --  reference to the user defined operator.
 279
 280       if Sloc (Entity (N)) /= Standard_Location then
 281          Generate_Reference (Entity (N), N);
 282
 283          --  A reference to an implicit inequality operator is also a reference
 284          --  to the user-defined equality.
 285
 286          if Nkind (N) = N_Op_Ne
 287            and then not Comes_From_Source (Entity (N))
 288            and then Present (Corresponding_Equality (Entity (N)))
 289          then
 290             Generate_Reference (Corresponding_Equality (Entity (N)), N);
 291          end if;
 292
 293       --  For the case of Standard operators, we mark the result type as
 294       --  referenced. This ensures that in the case where we are using a
 295       --  derived operator, we mark an entity of the unit that implicitly
 296       --  defines this operator as used. Otherwise we may think that no entity
 297       --  of the unit is used. The actual entity marked as referenced is the
 298       --  first subtype, which is the relevant user defined entity.
 299
 300       --  Note: we only do this for operators that come from source. The
 301       --  generated code sometimes reaches for entities that do not need to be
 302       --  explicitly visible (for example, when we expand the code for
 303       --  comparing two record objects, the fields of the record may not be
 304       --  visible).
 305
 306       elsif Comes_From_Source (N) then
 307          Set_Referenced (First_Subtype (T));
 308       end if;
 309    end Generate_Operator_Reference;
 310
 311    ---------------------------------
 312    -- Generate_Prim_Op_References --
 313    ---------------------------------
 314
 315    procedure Generate_Prim_Op_References (Typ : Entity_Id) is
 316       Base_T    : Entity_Id;
 317       Prim      : Elmt_Id;
 318       Prim_List : Elist_Id;
 319
 320    begin
 321       --  Handle subtypes of synchronized types
 322
 323       if Ekind (Typ) = E_Protected_Subtype
 324         or else Ekind (Typ) = E_Task_Subtype
 325       then
 326          Base_T := Etype (Typ);
 327       else
 328          Base_T := Typ;
 329       end if;
 330
 331       --  References to primitive operations are only relevant for tagged types
 332
 333       if not Is_Tagged_Type (Base_T)
 334         or else Is_Class_Wide_Type (Base_T)
 335       then
 336          return;
 337       end if;
 338
 339       --  Ada 2005 (AI-345): For synchronized types generate reference to the
 340       --  wrapper that allow us to dispatch calls through their implemented
 341       --  abstract interface types.
 342
 343       --  The check for Present here is to protect against previously reported
 344       --  critical errors.
 345
 346       Prim_List := Primitive_Operations (Base_T);
 347
 348       if No (Prim_List) then
 349          return;
 350       end if;
 351
 352       Prim := First_Elmt (Prim_List);
 353       while Present (Prim) loop
 354
 355          --  If the operation is derived, get the original for cross-reference
 356          --  reference purposes (it is the original for which we want the xref
 357          --  and for which the comes_from_source test must be performed).
 358
 359          Generate_Reference
 360            (Typ, Ultimate_Alias (Node (Prim)), 'p', Set_Ref => False);
 361          Next_Elmt (Prim);
 362       end loop;
 363    end Generate_Prim_Op_References;
 364
 365    ------------------------
 366    -- Generate_Reference --
 367    ------------------------
 368
 369    procedure Generate_Reference
 370      (E       : Entity_Id;
 371       N       : Node_Id;
 372       Typ     : Character := 'r';
 373       Set_Ref : Boolean   := True;
 374       Force   : Boolean   := False)
 375    is
 376       Nod : Node_Id;
 377       Ref : Source_Ptr;
 378       Def : Source_Ptr;
 379       Ent : Entity_Id;
 380
 381       Actual_Typ : Character := Typ;
 382
 383       Ref_Scope      : Entity_Id;
 384       Ent_Scope      : Entity_Id;
 385       Ent_Scope_File : Unit_Number_Type;
 386
 387       Call   : Node_Id;
 388       Formal : Entity_Id;
 389       --  Used for call to Find_Actual
 390
 391       Kind : Entity_Kind;
 392       --  If Formal is non-Empty, then its Ekind, otherwise E_Void
 393
 394       function Is_On_LHS (Node : Node_Id) return Boolean;
 395       --  Used to check if a node is on the left hand side of an assignment.
 396       --  The following cases are handled:
 397       --
 398       --   Variable    Node is a direct descendant of left hand side of an
 399       --               assignment statement.
 400       --
 401       --   Prefix      Of an indexed or selected component that is present in
 402       --               a subtree rooted by an assignment statement. There is
 403       --               no restriction of nesting of components, thus cases
 404       --               such as A.B (C).D are handled properly. However a prefix
 405       --               of a dereference (either implicit or explicit) is never
 406       --               considered as on a LHS.
 407       --
 408       --   Out param   Same as above cases, but OUT parameter
 409
 410       function OK_To_Set_Referenced return Boolean;
 411       --  Returns True if the Referenced flag can be set. There are a few
 412       --  exceptions where we do not want to set this flag, see body for
 413       --  details of these exceptional cases.
 414
 415       ---------------
 416       -- Is_On_LHS --
 417       ---------------
 418
 419       --  ??? There are several routines here and there that perform a similar
 420       --      (but subtly different) computation, which should be factored:
 421
 422       --      Sem_Util.May_Be_Lvalue
 423       --      Sem_Util.Known_To_Be_Assigned
 424       --      Exp_Ch2.Expand_Entry_Parameter.In_Assignment_Context
 425       --      Exp_Smem.Is_Out_Actual
 426
 427       function Is_On_LHS (Node : Node_Id) return Boolean is
 428          N : Node_Id;
 429          P : Node_Id;
 430          K : Node_Kind;
 431
 432       begin
 433          --  Only identifiers are considered, is this necessary???
 434
 435          if Nkind (Node) /= N_Identifier then
 436             return False;
 437          end if;
 438
 439          --  Immediate return if appeared as OUT parameter
 440
 441          if Kind = E_Out_Parameter then
 442             return True;
 443          end if;
 444
 445          --  Search for assignment statement subtree root
 446
 447          N := Node;
 448          loop
 449             P := Parent (N);
 450             K := Nkind (P);
 451
 452             if K = N_Assignment_Statement then
 453                return Name (P) = N;
 454
 455             --  Check whether the parent is a component and the current node is
 456             --  its prefix, but return False if the current node has an access
 457             --  type, as in that case the selected or indexed component is an
 458             --  implicit dereference, and the LHS is the designated object, not
 459             --  the access object.
 460
 461             --  ??? case of a slice assignment?
 462
 463             --  ??? Note that in some cases this is called too early
 464             --  (see comments in Sem_Ch8.Find_Direct_Name), at a point where
 465             --  the tree is not fully typed yet. In that case we may lack
 466             --  an Etype for N, and we must disable the check for an implicit
 467             --  dereference. If the dereference is on an LHS, this causes a
 468             --  false positive.
 469
 470             elsif (K = N_Selected_Component or else K = N_Indexed_Component)
 471               and then Prefix (P) = N
 472               and then not (Present (Etype (N))
 473                               and then
 474                             Is_Access_Type (Etype (N)))
 475             then
 476                N := P;
 477
 478             --  All other cases, definitely not on left side
 479
 480             else
 481                return False;
 482             end if;
 483          end loop;
 484       end Is_On_LHS;
 485
 486       ---------------------------
 487       -- OK_To_Set_Referenced --
 488       ---------------------------
 489
 490       function OK_To_Set_Referenced return Boolean is
 491          P : Node_Id;
 492
 493       begin
 494          --  A reference from a pragma Unreferenced or pragma Unmodified or
 495          --  pragma Warnings does not cause the Referenced flag to be set.
 496          --  This avoids silly warnings about things being referenced and
 497          --  not assigned when the only reference is from the pragma.
 498
 499          if Nkind (N) = N_Identifier then
 500             P := Parent (N);
 501
 502             if Nkind (P) = N_Pragma_Argument_Association then
 503                P := Parent (P);
 504
 505                if Nkind (P) = N_Pragma then
 506                   if Pragma_Name (P) = Name_Warnings
 507                        or else
 508                      Pragma_Name (P) = Name_Unmodified
 509                        or else
 510                      Pragma_Name (P) = Name_Unreferenced
 511                   then
 512                      return False;
 513                   end if;
 514                end if;
 515             end if;
 516          end if;
 517
 518          return True;
 519       end OK_To_Set_Referenced;
 520
 521    --  Start of processing for Generate_Reference
 522
 523    begin
 524       pragma Assert (Nkind (E) in N_Entity);
 525       Find_Actual (N, Formal, Call);
 526
 527       if Present (Formal) then
 528          Kind := Ekind (Formal);
 529       else
 530          Kind := E_Void;
 531       end if;
 532
 533       --  Check for obsolescent reference to package ASCII. GNAT treats this
 534       --  element of annex J specially since in practice, programs make a lot
 535       --  of use of this feature, so we don't include it in the set of features
 536       --  diagnosed when Warn_On_Obsolescent_Features mode is set. However we
 537       --  are required to note it as a violation of the RM defined restriction.
 538
 539       if E = Standard_ASCII then
 540          Check_Restriction (No_Obsolescent_Features, N);
 541       end if;
 542
 543       --  Check for reference to entity marked with Is_Obsolescent
 544
 545       --  Note that we always allow obsolescent references in the compiler
 546       --  itself and the run time, since we assume that we know what we are
 547       --  doing in such cases. For example the calls in Ada.Characters.Handling
 548       --  to its own obsolescent subprograms are just fine.
 549
 550       --  In any case we do not generate warnings within the extended source
 551       --  unit of the entity in question, since we assume the source unit
 552       --  itself knows what is going on (and for sure we do not want silly
 553       --  warnings, e.g. on the end line of an obsolescent procedure body).
 554
 555       if Is_Obsolescent (E)
 556         and then not GNAT_Mode
 557         and then not In_Extended_Main_Source_Unit (E)
 558       then
 559          Check_Restriction (No_Obsolescent_Features, N);
 560
 561          if Warn_On_Obsolescent_Feature then
 562             Output_Obsolescent_Entity_Warnings (N, E);
 563          end if;
 564       end if;
 565
 566       --  Warn if reference to Ada 2005 entity not in Ada 2005 mode. We only
 567       --  detect real explicit references (modifications and references).
 568
 569       if Comes_From_Source (N)
 570         and then Is_Ada_2005_Only (E)
 571         and then Ada_Version < Ada_2005
 572         and then Warn_On_Ada_2005_Compatibility
 573         and then (Typ = 'm' or else Typ = 'r' or else Typ = 's')
 574       then
 575          Error_Msg_NE ("& is only defined in Ada 2005?", N, E);
 576       end if;
 577
 578       --  Warn if reference to Ada 2012 entity not in Ada 2012 mode. We only
 579       --  detect real explicit references (modifications and references).
 580
 581       if Comes_From_Source (N)
 582         and then Is_Ada_2012_Only (E)
 583         and then Ada_Version < Ada_2012
 584         and then Warn_On_Ada_2012_Compatibility
 585         and then (Typ = 'm' or else Typ = 'r')
 586       then
 587          Error_Msg_NE ("& is only defined in Ada 2012?", N, E);
 588       end if;
 589
 590       --  Never collect references if not in main source unit. However, we omit
 591       --  this test if Typ is 'e' or 'k', since these entries are structural,
 592       --  and it is useful to have them in units that reference packages as
 593       --  well as units that define packages. We also omit the test for the
 594       --  case of 'p' since we want to include inherited primitive operations
 595       --  from other packages.
 596
 597       --  We also omit this test is this is a body reference for a subprogram
 598       --  instantiation. In this case the reference is to the generic body,
 599       --  which clearly need not be in the main unit containing the instance.
 600       --  For the same reason we accept an implicit reference generated for
 601       --  a default in an instance.
 602
 603       if not In_Extended_Main_Source_Unit (N) then
 604          if Typ = 'e'
 605            or else Typ = 'I'
 606            or else Typ = 'p'
 607            or else Typ = 'i'
 608            or else Typ = 'k'
 609            or else (Typ = 'b' and then Is_Generic_Instance (E))
 610          then
 611             null;
 612          else
 613             return;
 614          end if;
 615       end if;
 616
 617       --  For reference type p, the entity must be in main source unit
 618
 619       if Typ = 'p' and then not In_Extended_Main_Source_Unit (E) then
 620          return;
 621       end if;
 622
 623       --  Unless the reference is forced, we ignore references where the
 624       --  reference itself does not come from source.
 625
 626       if not Force and then not Comes_From_Source (N) then
 627          return;
 628       end if;
 629
 630       --  Deal with setting entity as referenced, unless suppressed. Note that
 631       --  we still do Set_Referenced on entities that do not come from source.
 632       --  This situation arises when we have a source reference to a derived
 633       --  operation, where the derived operation itself does not come from
 634       --  source, but we still want to mark it as referenced, since we really
 635       --  are referencing an entity in the corresponding package (this avoids
 636       --  wrong complaints that the package contains no referenced entities).
 637
 638       if Set_Ref then
 639
 640          --  Assignable object appearing on left side of assignment or as
 641          --  an out parameter.
 642
 643          if Is_Assignable (E)
 644            and then Is_On_LHS (N)
 645            and then Ekind (E) /= E_In_Out_Parameter
 646          then
 647             --  For objects that are renamings, just set as simply referenced
 648             --  we do not try to do assignment type tracking in this case.
 649
 650             if Present (Renamed_Object (E)) then
 651                Set_Referenced (E);
 652
 653             --  Out parameter case
 654
 655             elsif Kind = E_Out_Parameter then
 656
 657                --  If warning mode for all out parameters is set, or this is
 658                --  the only warning parameter, then we want to mark this for
 659                --  later warning logic by setting Referenced_As_Out_Parameter
 660
 661                if Warn_On_Modified_As_Out_Parameter (Formal) then
 662                   Set_Referenced_As_Out_Parameter (E, True);
 663                   Set_Referenced_As_LHS (E, False);
 664
 665                --  For OUT parameter not covered by the above cases, we simply
 666                --  regard it as a normal reference (in this case we do not
 667                --  want any of the warning machinery for out parameters).
 668
 669                else
 670                   Set_Referenced (E);
 671                end if;
 672
 673             --  For the left hand of an assignment case, we do nothing here.
 674             --  The processing for Analyze_Assignment_Statement will set the
 675             --  Referenced_As_LHS flag.
 676
 677             else
 678                null;
 679             end if;
 680
 681          --  Check for a reference in a pragma that should not count as a
 682          --  making the variable referenced for warning purposes.
 683
 684          elsif Is_Non_Significant_Pragma_Reference (N) then
 685             null;
 686
 687          --  A reference in an attribute definition clause does not count as a
 688          --  reference except for the case of Address. The reason that 'Address
 689          --  is an exception is that it creates an alias through which the
 690          --  variable may be referenced.
 691
 692          elsif Nkind (Parent (N)) = N_Attribute_Definition_Clause
 693            and then Chars (Parent (N)) /= Name_Address
 694            and then N = Name (Parent (N))
 695          then
 696             null;
 697
 698          --  Constant completion does not count as a reference
 699
 700          elsif Typ = 'c'
 701            and then Ekind (E) = E_Constant
 702          then
 703             null;
 704
 705          --  Record representation clause does not count as a reference
 706
 707          elsif Nkind (N) = N_Identifier
 708            and then Nkind (Parent (N)) = N_Record_Representation_Clause
 709          then
 710             null;
 711
 712          --  Discriminants do not need to produce a reference to record type
 713
 714          elsif Typ = 'd'
 715            and then Nkind (Parent (N)) = N_Discriminant_Specification
 716          then
 717             null;
 718
 719          --  All other cases
 720
 721          else
 722             --  Special processing for IN OUT parameters, where we have an
 723             --  implicit assignment to a simple variable.
 724
 725             if Kind = E_In_Out_Parameter
 726               and then Is_Assignable (E)
 727             then
 728                --  For sure this counts as a normal read reference
 729
 730                Set_Referenced (E);
 731                Set_Last_Assignment (E, Empty);
 732
 733                --  We count it as being referenced as an out parameter if the
 734                --  option is set to warn on all out parameters, except that we
 735                --  have a special exclusion for an intrinsic subprogram, which
 736                --  is most likely an instantiation of Unchecked_Deallocation
 737                --  which we do not want to consider as an assignment since it
 738                --  generates false positives. We also exclude the case of an
 739                --  IN OUT parameter if the name of the procedure is Free,
 740                --  since we suspect similar semantics.
 741
 742                if Warn_On_All_Unread_Out_Parameters
 743                  and then Is_Entity_Name (Name (Call))
 744                  and then not Is_Intrinsic_Subprogram (Entity (Name (Call)))
 745                  and then Chars (Name (Call)) /= Name_Free
 746                then
 747                   Set_Referenced_As_Out_Parameter (E, True);
 748                   Set_Referenced_As_LHS (E, False);
 749                end if;
 750
 751             --  Don't count a recursive reference within a subprogram as a
 752             --  reference (that allows detection of a recursive subprogram
 753             --  whose only references are recursive calls as unreferenced).
 754
 755             elsif Is_Subprogram (E)
 756               and then E = Nearest_Dynamic_Scope (Current_Scope)
 757             then
 758                null;
 759
 760             --  Any other occurrence counts as referencing the entity
 761
 762             elsif OK_To_Set_Referenced then
 763                Set_Referenced (E);
 764
 765                --  If variable, this is an OK reference after an assignment
 766                --  so we can clear the Last_Assignment indication.
 767
 768                if Is_Assignable (E) then
 769                   Set_Last_Assignment (E, Empty);
 770                end if;
 771             end if;
 772          end if;
 773
 774          --  Check for pragma Unreferenced given and reference is within
 775          --  this source unit (occasion for possible warning to be issued).
 776
 777          if Has_Unreferenced (E)
 778            and then In_Same_Extended_Unit (E, N)
 779          then
 780             --  A reference as a named parameter in a call does not count
 781             --  as a violation of pragma Unreferenced for this purpose...
 782
 783             if Nkind (N) = N_Identifier
 784               and then Nkind (Parent (N)) = N_Parameter_Association
 785               and then Selector_Name (Parent (N)) = N
 786             then
 787                null;
 788
 789             --  ... Neither does a reference to a variable on the left side
 790             --  of an assignment.
 791
 792             elsif Is_On_LHS (N) then
 793                null;
 794
 795             --  For entry formals, we want to place the warning message on the
 796             --  corresponding entity in the accept statement. The current scope
 797             --  is the body of the accept, so we find the formal whose name
 798             --  matches that of the entry formal (there is no link between the
 799             --  two entities, and the one in the accept statement is only used
 800             --  for conformance checking).
 801
 802             elsif Ekind (Scope (E)) = E_Entry then
 803                declare
 804                   BE : Entity_Id;
 805
 806                begin
 807                   BE := First_Entity (Current_Scope);
 808                   while Present (BE) loop
 809                      if Chars (BE) = Chars (E) then
 810                         Error_Msg_NE -- CODEFIX
 811                           ("?pragma Unreferenced given for&!", N, BE);
 812                         exit;
 813                      end if;
 814
 815                      Next_Entity (BE);
 816                   end loop;
 817                end;
 818
 819             --  Here we issue the warning, since this is a real reference
 820
 821             else
 822                Error_Msg_NE -- CODEFIX
 823                  ("?pragma Unreferenced given for&!", N, E);
 824             end if;
 825          end if;
 826
 827          --  If this is a subprogram instance, mark as well the internal
 828          --  subprogram in the wrapper package, which may be a visible
 829          --  compilation unit.
 830
 831          if Is_Overloadable (E)
 832            and then Is_Generic_Instance (E)
 833            and then Present (Alias (E))
 834          then
 835             Set_Referenced (Alias (E));
 836          end if;
 837       end if;
 838
 839       --  Generate reference if all conditions are met:
 840
 841       if
 842          --  Cross referencing must be active
 843
 844          Opt.Xref_Active
 845
 846          --  The entity must be one for which we collect references
 847
 848          and then Xref_Entity_Letters (Ekind (E)) /= ' '
 849
 850          --  Both Sloc values must be set to something sensible
 851
 852          and then Sloc (E) > No_Location
 853          and then Sloc (N) > No_Location
 854
 855          --  We ignore references from within an instance, except for default
 856          --  subprograms, for which we generate an implicit reference.
 857
 858          and then
 859            (Instantiation_Location (Sloc (N)) = No_Location or else Typ = 'i')
 860
 861          --  Ignore dummy references
 862
 863         and then Typ /= ' '
 864       then
 865          if Nkind (N) = N_Identifier
 866               or else
 867             Nkind (N) = N_Defining_Identifier
 868               or else
 869             Nkind (N) in N_Op
 870               or else
 871             Nkind (N) = N_Defining_Operator_Symbol
 872               or else
 873             Nkind (N) = N_Operator_Symbol
 874               or else
 875             (Nkind (N) = N_Character_Literal
 876               and then Sloc (Entity (N)) /= Standard_Location)
 877               or else
 878             Nkind (N) = N_Defining_Character_Literal
 879          then
 880             Nod := N;
 881
 882          elsif Nkind (N) = N_Expanded_Name
 883                  or else
 884                Nkind (N) = N_Selected_Component
 885          then
 886             Nod := Selector_Name (N);
 887
 888          else
 889             return;
 890          end if;
 891
 892          --  Normal case of source entity comes from source
 893
 894          if Comes_From_Source (E) then
 895             Ent := E;
 896
 897          --  Entity does not come from source, but is a derived subprogram and
 898          --  the derived subprogram comes from source (after one or more
 899          --  derivations) in which case the reference is to parent subprogram.
 900
 901          elsif Is_Overloadable (E)
 902            and then Present (Alias (E))
 903          then
 904             Ent := Alias (E);
 905             while not Comes_From_Source (Ent) loop
 906                if No (Alias (Ent)) then
 907                   return;
 908                end if;
 909
 910                Ent := Alias (Ent);
 911             end loop;
 912
 913          --  The internally created defining entity for a child subprogram
 914          --  that has no previous spec has valid references.
 915
 916          elsif Is_Overloadable (E)
 917            and then Is_Child_Unit (E)
 918          then
 919             Ent := E;
 920
 921          --  Record components of discriminated subtypes or derived types must
 922          --  be treated as references to the original component.
 923
 924          elsif Ekind (E) = E_Component
 925            and then Comes_From_Source (Original_Record_Component (E))
 926          then
 927             Ent := Original_Record_Component (E);
 928
 929          --  If this is an expanded reference to a discriminant, recover the
 930          --  original discriminant, which gets the reference.
 931
 932          elsif Ekind (E) = E_In_Parameter
 933            and then  Present (Discriminal_Link (E))
 934          then
 935             Ent := Discriminal_Link (E);
 936             Set_Referenced (Ent);
 937
 938          --  Ignore reference to any other entity that is not from source
 939
 940          else
 941             return;
 942          end if;
 943
 944          --  Record reference to entity
 945
 946          Ref := Original_Location (Sloc (Nod));
 947          Def := Original_Location (Sloc (Ent));
 948
 949          if Actual_Typ = 'p'
 950            and then Is_Subprogram (N)
 951            and then Present (Overridden_Operation (N))
 952          then
 953             Actual_Typ := 'P';
 954          end if;
 955
 956          if Alfa_Mode then
 957             Ref_Scope := Alfa.Enclosing_Subprogram_Or_Package (N);
 958             Ent_Scope := Alfa.Enclosing_Subprogram_Or_Package (Ent);
 959             Ent_Scope_File := Get_Source_Unit (Ent_Scope);
 960
 961          else
 962             Ref_Scope := Empty;
 963             Ent_Scope := Empty;
 964             Ent_Scope_File := No_Unit;
 965          end if;
 966
 967          Add_Entry
 968            ((Ent => Ent,
 969              Loc => Ref,
 970              Typ => Actual_Typ,
 971              Eun => Get_Source_Unit (Def),
 972              Lun => Get_Source_Unit (Ref),
 973              Ref_Scope => Ref_Scope,
 974              Ent_Scope => Ent_Scope),
 975             Ent_Scope_File => Ent_Scope_File);
 976       end if;
 977    end Generate_Reference;
 978
 979    -----------------------------------
 980    -- Generate_Reference_To_Formals --
 981    -----------------------------------
 982
 983    procedure Generate_Reference_To_Formals (E : Entity_Id) is
 984       Formal : Entity_Id;
 985
 986    begin
 987       if Is_Generic_Subprogram (E) then
 988          Formal := First_Entity (E);
 989
 990          while Present (Formal)
 991            and then not Is_Formal (Formal)
 992          loop
 993             Next_Entity (Formal);
 994          end loop;
 995
 996       else
 997          Formal := First_Formal (E);
 998       end if;
 999
1000       while Present (Formal) loop
1001          if Ekind (Formal) = E_In_Parameter then
1002
1003             if Nkind (Parameter_Type (Parent (Formal)))
1004               = N_Access_Definition
1005             then
1006                Generate_Reference (E, Formal, '^', False);
1007             else
1008                Generate_Reference (E, Formal, '>', False);
1009             end if;
1010
1011          elsif Ekind (Formal) = E_In_Out_Parameter then
1012             Generate_Reference (E, Formal, '=', False);
1013
1014          else
1015             Generate_Reference (E, Formal, '<', False);
1016          end if;
1017
1018          Next_Formal (Formal);
1019       end loop;
1020    end Generate_Reference_To_Formals;
1021
1022    -------------------------------------------
1023    -- Generate_Reference_To_Generic_Formals --
1024    -------------------------------------------
1025
1026    procedure Generate_Reference_To_Generic_Formals (E : Entity_Id) is
1027       Formal : Entity_Id;
1028
1029    begin
1030       Formal := First_Entity (E);
1031       while Present (Formal) loop
1032          if Comes_From_Source (Formal) then
1033             Generate_Reference (E, Formal, 'z', False);
1034          end if;
1035
1036          Next_Entity (Formal);
1037       end loop;
1038    end Generate_Reference_To_Generic_Formals;
1039
1040    -------------
1041    -- Get_Key --
1042    -------------
1043
1044    function Get_Key (E : Xref_Entry_Number) return Xref_Entry_Number is
1045    begin
1046       return E;
1047    end Get_Key;
1048
1049    ----------
1050    -- Hash --
1051    ----------
1052
1053    function Hash (F : Xref_Entry_Number) return Header_Num is
1054       --  It is unlikely to have two references to the same entity at the same
1055       --  source location, so the hash function depends only on the Ent and Loc
1056       --  fields.
1057
1058       XE : Xref_Entry renames Xrefs.Table (F);
1059       type M is mod 2**32;
1060       H : constant M := M'Mod (XE.Key.Ent) + 2**7 * M'Mod (XE.Key.Loc);
1061    begin
1062       return Header_Num (H mod Num_Buckets);
1063    end Hash;
1064
1065    -----------------
1066    -- HT_Set_Next --
1067    -----------------
1068
1069    procedure HT_Set_Next (E : Xref_Entry_Number; Next : Xref_Entry_Number) is
1070    begin
1071       Xrefs.Table (E).HTable_Next := Next;
1072    end HT_Set_Next;
1073
1074    -------------
1075    -- HT_Next --
1076    -------------
1077
1078    function HT_Next (E : Xref_Entry_Number) return Xref_Entry_Number is
1079    begin
1080       return Xrefs.Table (E).HTable_Next;
1081    end HT_Next;
1082
1083    ----------------
1084    -- Initialize --
1085    ----------------
1086
1087    procedure Initialize is
1088    begin
1089       Xrefs.Init;
1090    end Initialize;
1091
1092    --------
1093    -- Lt --
1094    --------
1095
1096    function Lt (T1, T2 : Xref_Entry) return Boolean is
1097    begin
1098       --  First test: if entity is in different unit, sort by unit
1099
1100       if T1.Key.Eun /= T2.Key.Eun then
1101          return Dependency_Num (T1.Key.Eun) < Dependency_Num (T2.Key.Eun);
1102
1103       --  Second test: within same unit, sort by entity Sloc
1104
1105       elsif T1.Def /= T2.Def then
1106          return T1.Def < T2.Def;
1107
1108       --  Third test: sort definitions ahead of references
1109
1110       elsif T1.Key.Loc = No_Location then
1111          return True;
1112
1113       elsif T2.Key.Loc = No_Location then
1114          return False;
1115
1116       --  Fourth test: for same entity, sort by reference location unit
1117
1118       elsif T1.Key.Lun /= T2.Key.Lun then
1119          return Dependency_Num (T1.Key.Lun) < Dependency_Num (T2.Key.Lun);
1120
1121       --  Fifth test: order of location within referencing unit
1122
1123       elsif T1.Key.Loc /= T2.Key.Loc then
1124          return T1.Key.Loc < T2.Key.Loc;
1125
1126       --  Finally, for two locations at the same address, we prefer
1127       --  the one that does NOT have the type 'r' so that a modification
1128       --  or extension takes preference, when there are more than one
1129       --  reference at the same location. As a result, in the case of
1130       --  entities that are in-out actuals, the read reference follows
1131       --  the modify reference.
1132
1133       else
1134          return T2.Key.Typ = 'r';
1135       end if;
1136    end Lt;
1137
1138    -----------------------
1139    -- Output_References --
1140    -----------------------
1141
1142    procedure Output_References is
1143
1144       procedure Get_Type_Reference
1145         (Ent   : Entity_Id;
1146          Tref  : out Entity_Id;
1147          Left  : out Character;
1148          Right : out Character);
1149       --  Given an Entity_Id Ent, determines whether a type reference is
1150       --  required. If so, Tref is set to the entity for the type reference
1151       --  and Left and Right are set to the left/right brackets to be output
1152       --  for the reference. If no type reference is required, then Tref is
1153       --  set to Empty, and Left/Right are set to space.
1154
1155       procedure Output_Import_Export_Info (Ent : Entity_Id);
1156       --  Output language and external name information for an interfaced
1157       --  entity, using the format <language, external_name>,
1158
1159       ------------------------
1160       -- Get_Type_Reference --
1161       ------------------------
1162
1163       procedure Get_Type_Reference
1164         (Ent   : Entity_Id;
1165          Tref  : out Entity_Id;
1166          Left  : out Character;
1167          Right : out Character)
1168       is
1169          Sav : Entity_Id;
1170
1171       begin
1172          --  See if we have a type reference
1173
1174          Tref := Ent;
1175          Left := '{';
1176          Right := '}';
1177
1178          loop
1179             Sav := Tref;
1180
1181             --  Processing for types
1182
1183             if Is_Type (Tref) then
1184
1185                --  Case of base type
1186
1187                if Base_Type (Tref) = Tref then
1188
1189                   --  If derived, then get first subtype
1190
1191                   if Tref /= Etype (Tref) then
1192                      Tref := First_Subtype (Etype (Tref));
1193
1194                      --  Set brackets for derived type, but don't override
1195                      --  pointer case since the fact that something is a
1196                      --  pointer is more important.
1197
1198                      if Left /= '(' then
1199                         Left := '<';
1200                         Right := '>';
1201                      end if;
1202
1203                   --  If non-derived ptr, get directly designated type.
1204                   --  If the type has a full view, all references are on the
1205                   --  partial view, that is seen first.
1206
1207                   elsif Is_Access_Type (Tref) then
1208                      Tref := Directly_Designated_Type (Tref);
1209                      Left := '(';
1210                      Right := ')';
1211
1212                   elsif Is_Private_Type (Tref)
1213                     and then Present (Full_View (Tref))
1214                   then
1215                      if Is_Access_Type (Full_View (Tref)) then
1216                         Tref := Directly_Designated_Type (Full_View (Tref));
1217                         Left := '(';
1218                         Right := ')';
1219
1220                      --  If the full view is an array type, we also retrieve
1221                      --  the corresponding component type, because the ali
1222                      --  entry already indicates that this is an array.
1223
1224                      elsif Is_Array_Type (Full_View (Tref)) then
1225                         Tref := Component_Type (Full_View (Tref));
1226                         Left := '(';
1227                         Right := ')';
1228                      end if;
1229
1230                   --  If non-derived array, get component type. Skip component
1231                   --  type for case of String or Wide_String, saves worthwhile
1232                   --  space.
1233
1234                   elsif Is_Array_Type (Tref)
1235                     and then Tref /= Standard_String
1236                     and then Tref /= Standard_Wide_String
1237                   then
1238                      Tref := Component_Type (Tref);
1239                      Left := '(';
1240                      Right := ')';
1241
1242                   --  For other non-derived base types, nothing
1243
1244                   else
1245                      exit;
1246                   end if;
1247
1248                --  For a subtype, go to ancestor subtype
1249
1250                else
1251                   Tref := Ancestor_Subtype (Tref);
1252
1253                   --  If no ancestor subtype, go to base type
1254
1255                   if No (Tref) then
1256                      Tref := Base_Type (Sav);
1257                   end if;
1258                end if;
1259
1260             --  For objects, functions, enum literals, just get type from
1261             --  Etype field.
1262
1263             elsif Is_Object (Tref)
1264               or else Ekind (Tref) = E_Enumeration_Literal
1265               or else Ekind (Tref) = E_Function
1266               or else Ekind (Tref) = E_Operator
1267             then
1268                Tref := Etype (Tref);
1269
1270             --  For anything else, exit
1271
1272             else
1273                exit;
1274             end if;
1275
1276             --  Exit if no type reference, or we are stuck in some loop trying
1277             --  to find the type reference, or if the type is standard void
1278             --  type (the latter is an implementation artifact that should not
1279             --  show up in the generated cross-references).
1280
1281             exit when No (Tref)
1282               or else Tref = Sav
1283               or else Tref = Standard_Void_Type;
1284
1285             --  If we have a usable type reference, return, otherwise keep
1286             --  looking for something useful (we are looking for something
1287             --  that either comes from source or standard)
1288
1289             if Sloc (Tref) = Standard_Location
1290               or else Comes_From_Source (Tref)
1291             then
1292                --  If the reference is a subtype created for a generic actual,
1293                --  go actual directly, the inner subtype is not user visible.
1294
1295                if Nkind (Parent (Tref)) = N_Subtype_Declaration
1296                  and then not Comes_From_Source (Parent (Tref))
1297                  and then
1298                   (Is_Wrapper_Package (Scope (Tref))
1299                      or else Is_Generic_Instance (Scope (Tref)))
1300                then
1301                   Tref := First_Subtype (Base_Type (Tref));
1302                end if;
1303
1304                return;
1305             end if;
1306          end loop;
1307
1308          --  If we fall through the loop, no type reference
1309
1310          Tref := Empty;
1311          Left := ' ';
1312          Right := ' ';
1313       end Get_Type_Reference;
1314
1315       -------------------------------
1316       -- Output_Import_Export_Info --
1317       -------------------------------
1318
1319       procedure Output_Import_Export_Info (Ent : Entity_Id) is
1320          Language_Name : Name_Id;
1321          Conv          : constant Convention_Id := Convention (Ent);
1322
1323       begin
1324          --  Generate language name from convention
1325
1326          if Conv  = Convention_C then
1327             Language_Name := Name_C;
1328
1329          elsif Conv = Convention_CPP then
1330             Language_Name := Name_CPP;
1331
1332          elsif Conv = Convention_Ada then
1333             Language_Name := Name_Ada;
1334
1335          else
1336             --  For the moment we ignore all other cases ???
1337
1338             return;
1339          end if;
1340
1341          Write_Info_Char ('<');
1342          Get_Unqualified_Name_String (Language_Name);
1343
1344          for J in 1 .. Name_Len loop
1345             Write_Info_Char (Name_Buffer (J));
1346          end loop;
1347
1348          if Present (Interface_Name (Ent)) then
1349             Write_Info_Char (',');
1350             String_To_Name_Buffer (Strval (Interface_Name (Ent)));
1351
1352             for J in 1 .. Name_Len loop
1353                Write_Info_Char (Name_Buffer (J));
1354             end loop;
1355          end if;
1356
1357          Write_Info_Char ('>');
1358       end Output_Import_Export_Info;
1359
1360    --  Start of processing for Output_References
1361
1362    begin
1363       --  First we add references to the primitive operations of tagged types
1364       --  declared in the main unit.
1365
1366       Handle_Prim_Ops : declare
1367          Ent  : Entity_Id;
1368
1369       begin
1370          for J in 1 .. Xrefs.Last loop
1371             Ent := Xrefs.Table (J).Key.Ent;
1372
1373             if Is_Type (Ent)
1374               and then Is_Tagged_Type (Ent)
1375               and then Is_Base_Type (Ent)
1376               and then In_Extended_Main_Source_Unit (Ent)
1377             then
1378                Generate_Prim_Op_References (Ent);
1379             end if;
1380          end loop;
1381       end Handle_Prim_Ops;
1382
1383       --  Before we go ahead and output the references we have a problem
1384       --  that needs dealing with. So far we have captured things that are
1385       --  definitely referenced by the main unit, or defined in the main
1386       --  unit. That's because we don't want to clutter up the ali file
1387       --  for this unit with definition lines for entities in other units
1388       --  that are not referenced.
1389
1390       --  But there is a glitch. We may reference an entity in another unit,
1391       --  and it may have a type reference to an entity that is not directly
1392       --  referenced in the main unit, which may mean that there is no xref
1393       --  entry for this entity yet in the list of references.
1394
1395       --  If we don't do something about this, we will end with an orphan type
1396       --  reference, i.e. it will point to an entity that does not appear
1397       --  within the generated references in the ali file. That is not good for
1398       --  tools using the xref information.
1399
1400       --  To fix this, we go through the references adding definition entries
1401       --  for any unreferenced entities that can be referenced in a type
1402       --  reference. There is a recursion problem here, and that is dealt with
1403       --  by making sure that this traversal also traverses any entries that
1404       --  get added by the traversal.
1405
1406       Handle_Orphan_Type_References : declare
1407          J    : Nat;
1408          Tref : Entity_Id;
1409          Ent  : Entity_Id;
1410
1411          L, R : Character;
1412          pragma Warnings (Off, L);
1413          pragma Warnings (Off, R);
1414
1415          procedure New_Entry (E : Entity_Id);
1416          --  Make an additional entry into the Xref table for a type entity
1417          --  that is related to the current entity (parent, type ancestor,
1418          --  progenitor, etc.).
1419
1420          ----------------
1421          -- New_Entry --
1422          ----------------
1423
1424          procedure New_Entry (E : Entity_Id) is
1425          begin
1426             pragma Assert (Present (E));
1427
1428             if not Has_Xref_Entry (Implementation_Base_Type (E))
1429               and then Sloc (E) > No_Location
1430             then
1431                Add_Entry
1432                  ((Ent => E,
1433                    Loc => No_Location,
1434                    Typ => Character'First,
1435                    Eun => Get_Source_Unit (Original_Location (Sloc (E))),
1436                    Lun => No_Unit,
1437                    Ref_Scope => Empty,
1438                    Ent_Scope => Empty),
1439                   Ent_Scope_File => No_Unit);
1440             end if;
1441          end New_Entry;
1442
1443       --  Start of processing for Handle_Orphan_Type_References
1444
1445       begin
1446          --  Note that this is not a for loop for a very good reason. The
1447          --  processing of items in the table can add new items to the table,
1448          --  and they must be processed as well.
1449
1450          J := 1;
1451          while J <= Xrefs.Last loop
1452             Ent := Xrefs.Table (J).Key.Ent;
1453             Get_Type_Reference (Ent, Tref, L, R);
1454
1455             if Present (Tref)
1456               and then not Has_Xref_Entry (Tref)
1457               and then Sloc (Tref) > No_Location
1458             then
1459                New_Entry (Tref);
1460
1461                if Is_Record_Type (Ent)
1462                  and then Present (Interfaces (Ent))
1463                then
1464                   --  Add an entry for each one of the given interfaces
1465                   --  implemented by type Ent.
1466
1467                   declare
1468                      Elmt : Elmt_Id := First_Elmt (Interfaces (Ent));
1469                   begin
1470                      while Present (Elmt) loop
1471                         New_Entry (Node (Elmt));
1472                         Next_Elmt (Elmt);
1473                      end loop;
1474                   end;
1475                end if;
1476             end if;
1477
1478             --  Collect inherited primitive operations that may be declared in
1479             --  another unit and have no visible reference in the current one.
1480
1481             if Is_Type (Ent)
1482               and then Is_Tagged_Type (Ent)
1483               and then Is_Derived_Type (Ent)
1484               and then Is_Base_Type (Ent)
1485               and then In_Extended_Main_Source_Unit (Ent)
1486             then
1487                declare
1488                   Op_List : constant Elist_Id := Primitive_Operations (Ent);
1489                   Op      : Elmt_Id;
1490                   Prim    : Entity_Id;
1491
1492                   function Parent_Op (E : Entity_Id) return Entity_Id;
1493                   --  Find original operation, which may be inherited through
1494                   --  several derivations.
1495
1496                   function Parent_Op (E : Entity_Id) return Entity_Id is
1497                      Orig_Op : constant Entity_Id := Alias (E);
1498
1499                   begin
1500                      if No (Orig_Op) then
1501                         return Empty;
1502
1503                      elsif not Comes_From_Source (E)
1504                        and then not Has_Xref_Entry (Orig_Op)
1505                        and then Comes_From_Source (Orig_Op)
1506                      then
1507                         return Orig_Op;
1508                      else
1509                         return Parent_Op (Orig_Op);
1510                      end if;
1511                   end Parent_Op;
1512
1513                begin
1514                   Op := First_Elmt (Op_List);
1515                   while Present (Op) loop
1516                      Prim := Parent_Op (Node (Op));
1517
1518                      if Present (Prim) then
1519                         Add_Entry
1520                           ((Ent => Prim,
1521                             Loc => No_Location,
1522                             Typ => Character'First,
1523                             Eun => Get_Source_Unit (Sloc (Prim)),
1524                             Lun => No_Unit,
1525                             Ref_Scope => Empty,
1526                             Ent_Scope => Empty),
1527                            Ent_Scope_File => No_Unit);
1528                      end if;
1529
1530                      Next_Elmt (Op);
1531                   end loop;
1532                end;
1533             end if;
1534
1535             J := J + 1;
1536          end loop;
1537       end Handle_Orphan_Type_References;
1538
1539       --  Now we have all the references, including those for any embedded
1540       --  type references, so we can sort them, and output them.
1541
1542       Output_Refs : declare
1543
1544          Nrefs : constant Nat := Xrefs.Last;
1545          --  Number of references in table
1546
1547          Rnums : array (0 .. Nrefs) of Nat;
1548          --  This array contains numbers of references in the Xrefs table.
1549          --  This list is sorted in output order. The extra 0'th entry is
1550          --  convenient for the call to sort. When we sort the table, we
1551          --  move the entries in Rnums around, but we do not move the
1552          --  original table entries.
1553
1554          Curxu : Unit_Number_Type;
1555          --  Current xref unit
1556
1557          Curru : Unit_Number_Type;
1558          --  Current reference unit for one entity
1559
1560          Curent : Entity_Id;
1561          --  Current entity
1562
1563          Curnam : String (1 .. Name_Buffer'Length);
1564          Curlen : Natural;
1565          --  Simple name and length of current entity
1566
1567          Curdef : Source_Ptr;
1568          --  Original source location for current entity
1569
1570          Crloc : Source_Ptr;
1571          --  Current reference location
1572
1573          Ctyp : Character;
1574          --  Entity type character
1575
1576          Prevt : Character;
1577          --  reference kind of previous reference
1578
1579          Tref : Entity_Id;
1580          --  Type reference
1581
1582          Rref : Node_Id;
1583          --  Renaming reference
1584
1585          Trunit : Unit_Number_Type;
1586          --  Unit number for type reference
1587
1588          function Lt (Op1, Op2 : Natural) return Boolean;
1589          --  Comparison function for Sort call
1590
1591          function Name_Change (X : Entity_Id) return Boolean;
1592          --  Determines if entity X has a different simple name from Curent
1593
1594          procedure Move (From : Natural; To : Natural);
1595          --  Move procedure for Sort call
1596
1597          package Sorting is new GNAT.Heap_Sort_G (Move, Lt);
1598
1599          --------
1600          -- Lt --
1601          --------
1602
1603          function Lt (Op1, Op2 : Natural) return Boolean is
1604             T1 : Xref_Entry renames Xrefs.Table (Rnums (Nat (Op1)));
1605             T2 : Xref_Entry renames Xrefs.Table (Rnums (Nat (Op2)));
1606
1607          begin
1608             return Lt (T1, T2);
1609          end Lt;
1610
1611          ----------
1612          -- Move --
1613          ----------
1614
1615          procedure Move (From : Natural; To : Natural) is
1616          begin
1617             Rnums (Nat (To)) := Rnums (Nat (From));
1618          end Move;
1619
1620          -----------------
1621          -- Name_Change --
1622          -----------------
1623
1624          --  Why a string comparison here??? Why not compare Name_Id values???
1625
1626          function Name_Change (X : Entity_Id) return Boolean is
1627          begin
1628             Get_Unqualified_Name_String (Chars (X));
1629
1630             if Name_Len /= Curlen then
1631                return True;
1632             else
1633                return Name_Buffer (1 .. Curlen) /= Curnam (1 .. Curlen);
1634             end if;
1635          end Name_Change;
1636
1637       --  Start of processing for Output_Refs
1638
1639       begin
1640          --  Capture the definition Sloc values. We delay doing this till now,
1641          --  since at the time the reference or definition is made, private
1642          --  types may be swapped, and the Sloc value may be incorrect. We
1643          --  also set up the pointer vector for the sort.
1644
1645          for J in 1 .. Nrefs loop
1646             Rnums (J) := J;
1647             Xrefs.Table (J).Def :=
1648               Original_Location (Sloc (Xrefs.Table (J).Key.Ent));
1649          end loop;
1650
1651          --  Sort the references
1652
1653          Sorting.Sort (Integer (Nrefs));
1654
1655          --  Initialize loop through references
1656
1657          Curxu  := No_Unit;
1658          Curent := Empty;
1659          Curdef := No_Location;
1660          Curru  := No_Unit;
1661          Crloc  := No_Location;
1662          Prevt  := 'm';
1663
1664          --  Loop to output references
1665
1666          for Refno in 1 .. Nrefs loop
1667             Output_One_Ref : declare
1668                Ent : Entity_Id;
1669
1670                XE : Xref_Entry renames Xrefs.Table (Rnums (Refno));
1671                --  The current entry to be accessed
1672
1673                Left  : Character;
1674                Right : Character;
1675                --  Used for {} or <> or () for type reference
1676
1677                procedure Check_Type_Reference
1678                  (Ent            : Entity_Id;
1679                   List_Interface : Boolean);
1680                --  Find whether there is a meaningful type reference for
1681                --  Ent, and display it accordingly. If List_Interface is
1682                --  true, then Ent is a progenitor interface of the current
1683                --  type entity being listed. In that case list it as is,
1684                --  without looking for a type reference for it.
1685
1686                procedure Output_Instantiation_Refs (Loc : Source_Ptr);
1687                --  Recursive procedure to output instantiation references for
1688                --  the given source ptr in [file|line[...]] form. No output
1689                --  if the given location is not a generic template reference.
1690
1691                procedure Output_Overridden_Op (Old_E : Entity_Id);
1692                --  For a subprogram that is overriding, display information
1693                --  about the inherited operation that it overrides.
1694
1695                --------------------------
1696                -- Check_Type_Reference --
1697                --------------------------
1698
1699                procedure Check_Type_Reference
1700                  (Ent            : Entity_Id;
1701                   List_Interface : Boolean)
1702                is
1703                begin
1704                   if List_Interface then
1705
1706                      --  This is a progenitor interface of the type for which
1707                      --  xref information is being generated.
1708
1709                      Tref  := Ent;
1710                      Left  := '<';
1711                      Right := '>';
1712
1713                   else
1714                      Get_Type_Reference (Ent, Tref, Left, Right);
1715                   end if;
1716
1717                   if Present (Tref) then
1718
1719                      --  Case of standard entity, output name
1720
1721                      if Sloc (Tref) = Standard_Location then
1722                         Write_Info_Char (Left);
1723                         Write_Info_Name (Chars (Tref));
1724                         Write_Info_Char (Right);
1725
1726                      --  Case of source entity, output location
1727
1728                      else
1729                         Write_Info_Char (Left);
1730                         Trunit := Get_Source_Unit (Sloc (Tref));
1731
1732                         if Trunit /= Curxu then
1733                            Write_Info_Nat (Dependency_Num (Trunit));
1734                            Write_Info_Char ('|');
1735                         end if;
1736
1737                         Write_Info_Nat
1738                           (Int (Get_Logical_Line_Number (Sloc (Tref))));
1739
1740                         declare
1741                            Ent  : Entity_Id;
1742                            Ctyp : Character;
1743
1744                         begin
1745                            Ent := Tref;
1746                            Ctyp := Xref_Entity_Letters (Ekind (Ent));
1747
1748                            if Ctyp = '+'
1749                              and then Present (Full_View (Ent))
1750                            then
1751                               Ent := Underlying_Type (Ent);
1752
1753                               if Present (Ent) then
1754                                  Ctyp := Xref_Entity_Letters (Ekind (Ent));
1755                               end if;
1756                            end if;
1757
1758                            Write_Info_Char (Ctyp);
1759                         end;
1760
1761                         Write_Info_Nat
1762                           (Int (Get_Column_Number (Sloc (Tref))));
1763
1764                         --  If the type comes from an instantiation, add the
1765                         --  corresponding info.
1766
1767                         Output_Instantiation_Refs (Sloc (Tref));
1768                         Write_Info_Char (Right);
1769                      end if;
1770                   end if;
1771                end Check_Type_Reference;
1772
1773                -------------------------------
1774                -- Output_Instantiation_Refs --
1775                -------------------------------
1776
1777                procedure Output_Instantiation_Refs (Loc : Source_Ptr) is
1778                   Iloc : constant Source_Ptr := Instantiation_Location (Loc);
1779                   Lun  : Unit_Number_Type;
1780                   Cu   : constant Unit_Number_Type := Curru;
1781
1782                begin
1783                   --  Nothing to do if this is not an instantiation
1784
1785                   if Iloc = No_Location then
1786                      return;
1787                   end if;
1788
1789                   --  Output instantiation reference
1790
1791                   Write_Info_Char ('[');
1792                   Lun := Get_Source_Unit (Iloc);
1793
1794                   if Lun /= Curru then
1795                      Curru := Lun;
1796                      Write_Info_Nat (Dependency_Num (Curru));
1797                      Write_Info_Char ('|');
1798                   end if;
1799
1800                   Write_Info_Nat (Int (Get_Logical_Line_Number (Iloc)));
1801
1802                   --  Recursive call to get nested instantiations
1803
1804                   Output_Instantiation_Refs (Iloc);
1805
1806                   --  Output final ] after call to get proper nesting
1807
1808                   Write_Info_Char (']');
1809                   Curru := Cu;
1810                   return;
1811                end Output_Instantiation_Refs;
1812
1813                --------------------------
1814                -- Output_Overridden_Op --
1815                --------------------------
1816
1817                procedure Output_Overridden_Op (Old_E : Entity_Id) is
1818                   Op : Entity_Id;
1819
1820                begin
1821                   --  The overridden operation has an implicit declaration
1822                   --  at the point of derivation. What we want to display
1823                   --  is the original operation, which has the actual body
1824                   --  (or abstract declaration) that is being overridden.
1825                   --  The overridden operation is not always set, e.g. when
1826                   --  it is a predefined operator.
1827
1828                   if No (Old_E) then
1829                      return;
1830
1831                   --  Follow alias chain if one is present
1832
1833                   elsif Present (Alias (Old_E)) then
1834
1835                      --  The subprogram may have been implicitly inherited
1836                      --  through several levels of derivation, so find the
1837                      --  ultimate (source) ancestor.
1838
1839                      Op := Ultimate_Alias (Old_E);
1840
1841                   --  Normal case of no alias present
1842
1843                   else
1844                      Op := Old_E;
1845                   end if;
1846
1847                   if Present (Op)
1848                     and then Sloc (Op) /= Standard_Location
1849                   then
1850                      declare
1851                         Loc      : constant Source_Ptr := Sloc (Op);
1852                         Par_Unit : constant Unit_Number_Type :=
1853                                      Get_Source_Unit (Loc);
1854
1855                      begin
1856                         Write_Info_Char ('<');
1857
1858                         if Par_Unit /= Curxu then
1859                            Write_Info_Nat (Dependency_Num (Par_Unit));
1860                            Write_Info_Char ('|');
1861                         end if;
1862
1863                         Write_Info_Nat (Int (Get_Logical_Line_Number (Loc)));
1864                         Write_Info_Char ('p');
1865                         Write_Info_Nat (Int (Get_Column_Number (Loc)));
1866                         Write_Info_Char ('>');
1867                      end;
1868                   end if;
1869                end Output_Overridden_Op;
1870
1871             --  Start of processing for Output_One_Ref
1872
1873             begin
1874                Ent := XE.Key.Ent;
1875                Ctyp := Xref_Entity_Letters (Ekind (Ent));
1876
1877                --  Skip reference if it is the only reference to an entity,
1878                --  and it is an END line reference, and the entity is not in
1879                --  the current extended source. This prevents junk entries
1880                --  consisting only of packages with END lines, where no
1881                --  entity from the package is actually referenced.
1882
1883                if XE.Key.Typ = 'e'
1884                  and then Ent /= Curent
1885                  and then (Refno = Nrefs
1886                             or else
1887                               Ent /= Xrefs.Table (Rnums (Refno + 1)).Key.Ent)
1888                  and then not In_Extended_Main_Source_Unit (Ent)
1889                then
1890                   goto Continue;
1891                end if;
1892
1893                --  For private type, get full view type
1894
1895                if Ctyp = '+'
1896                  and then Present (Full_View (XE.Key.Ent))
1897                then
1898                   Ent := Underlying_Type (Ent);
1899
1900                   if Present (Ent) then
1901                      Ctyp := Xref_Entity_Letters (Ekind (Ent));
1902                   end if;
1903                end if;
1904
1905                --  Special exception for Boolean
1906
1907                if Ctyp = 'E' and then Is_Boolean_Type (Ent) then
1908                   Ctyp := 'B';
1909                end if;
1910
1911                --  For variable reference, get corresponding type
1912
1913                if Ctyp = '*' then
1914                   Ent := Etype (XE.Key.Ent);
1915                   Ctyp := Fold_Lower (Xref_Entity_Letters (Ekind (Ent)));
1916
1917                   --  If variable is private type, get full view type
1918
1919                   if Ctyp = '+'
1920                     and then Present (Full_View (Etype (XE.Key.Ent)))
1921                   then
1922                      Ent := Underlying_Type (Etype (XE.Key.Ent));
1923
1924                      if Present (Ent) then
1925                         Ctyp := Fold_Lower (Xref_Entity_Letters (Ekind (Ent)));
1926                      end if;
1927
1928                   elsif Is_Generic_Type (Ent) then
1929
1930                      --  If the type of the entity is a generic private type,
1931                      --  there is no usable full view, so retain the indication
1932                      --  that this is an object.
1933
1934                      Ctyp := '*';
1935                   end if;
1936
1937                   --  Special handling for access parameters and objects of
1938                   --  an anonymous access type.
1939
1940                   if Ekind_In (Etype (XE.Key.Ent),
1941                                E_Anonymous_Access_Type,
1942                                E_Anonymous_Access_Subprogram_Type,
1943                                E_Anonymous_Access_Protected_Subprogram_Type)
1944                   then
1945                      if Is_Formal (XE.Key.Ent)
1946                        or else Ekind_In (XE.Key.Ent, E_Variable, E_Constant)
1947                      then
1948                         Ctyp := 'p';
1949                      end if;
1950
1951                      --  Special handling for Boolean
1952
1953                   elsif Ctyp = 'e' and then Is_Boolean_Type (Ent) then
1954                      Ctyp := 'b';
1955                   end if;
1956                end if;
1957
1958                --  Special handling for abstract types and operations
1959
1960                if Is_Overloadable (XE.Key.Ent)
1961                  and then Is_Abstract_Subprogram (XE.Key.Ent)
1962                then
1963                   if Ctyp = 'U' then
1964                      Ctyp := 'x';            --  Abstract procedure
1965
1966                   elsif Ctyp = 'V' then
1967                      Ctyp := 'y';            --  Abstract function
1968                   end if;
1969
1970                elsif Is_Type (XE.Key.Ent)
1971                  and then Is_Abstract_Type (XE.Key.Ent)
1972                then
1973                   if Is_Interface (XE.Key.Ent) then
1974                      Ctyp := 'h';
1975
1976                   elsif Ctyp = 'R' then
1977                      Ctyp := 'H';            --  Abstract type
1978                   end if;
1979                end if;
1980
1981                --  Only output reference if interesting type of entity
1982
1983                if Ctyp = ' '
1984
1985                --  Suppress references to object definitions, used for local
1986                --  references.
1987
1988                  or else XE.Key.Typ = 'D'
1989                  or else XE.Key.Typ = 'I'
1990
1991                --  Suppress self references, except for bodies that act as
1992                --  specs.
1993
1994                  or else (XE.Key.Loc = XE.Def
1995                            and then
1996                              (XE.Key.Typ /= 'b'
1997                                or else not Is_Subprogram (XE.Key.Ent)))
1998
1999                --  Also suppress definitions of body formals (we only
2000                --  treat these as references, and the references were
2001                --  separately recorded).
2002
2003                  or else (Is_Formal (XE.Key.Ent)
2004                            and then Present (Spec_Entity (XE.Key.Ent)))
2005                then
2006                   null;
2007
2008                else
2009                   --  Start new Xref section if new xref unit
2010
2011                   if XE.Key.Eun /= Curxu then
2012                      if Write_Info_Col > 1 then
2013                         Write_Info_EOL;
2014                      end if;
2015
2016                      Curxu := XE.Key.Eun;
2017
2018                      Write_Info_Initiate ('X');
2019                      Write_Info_Char (' ');
2020                      Write_Info_Nat (Dependency_Num (XE.Key.Eun));
2021                      Write_Info_Char (' ');
2022                      Write_Info_Name
2023                        (Reference_Name (Source_Index (XE.Key.Eun)));
2024                   end if;
2025
2026                   --  Start new Entity line if new entity. Note that we
2027                   --  consider two entities the same if they have the same
2028                   --  name and source location. This causes entities in
2029                   --  instantiations to be treated as though they referred
2030                   --  to the template.
2031
2032                   if No (Curent)
2033                     or else
2034                       (XE.Key.Ent /= Curent
2035                          and then
2036                            (Name_Change (XE.Key.Ent) or else XE.Def /= Curdef))
2037                   then
2038                      Curent := XE.Key.Ent;
2039                      Curdef := XE.Def;
2040
2041                      Get_Unqualified_Name_String (Chars (XE.Key.Ent));
2042                      Curlen := Name_Len;
2043                      Curnam (1 .. Curlen) := Name_Buffer (1 .. Curlen);
2044
2045                      if Write_Info_Col > 1 then
2046                         Write_Info_EOL;
2047                      end if;
2048
2049                      --  Write column number information
2050
2051                      Write_Info_Nat (Int (Get_Logical_Line_Number (XE.Def)));
2052                      Write_Info_Char (Ctyp);
2053                      Write_Info_Nat (Int (Get_Column_Number (XE.Def)));
2054
2055                      --  Write level information
2056
2057                      Write_Level_Info : declare
2058                         function Is_Visible_Generic_Entity
2059                           (E : Entity_Id) return Boolean;
2060                         --  Check whether E is declared in the visible part
2061                         --  of a generic package. For source navigation
2062                         --  purposes, treat this as a visible entity.
2063
2064                         function Is_Private_Record_Component
2065                           (E : Entity_Id) return Boolean;
2066                         --  Check whether E is a non-inherited component of a
2067                         --  private extension. Even if the enclosing record is
2068                         --  public, we want to treat the component as private
2069                         --  for navigation purposes.
2070
2071                         ---------------------------------
2072                         -- Is_Private_Record_Component --
2073                         ---------------------------------
2074
2075                         function Is_Private_Record_Component
2076                           (E : Entity_Id) return Boolean
2077                         is
2078                            S : constant Entity_Id := Scope (E);
2079                         begin
2080                            return
2081                              Ekind (E) = E_Component
2082                                and then Nkind (Declaration_Node (S)) =
2083                                  N_Private_Extension_Declaration
2084                                and then Original_Record_Component (E) = E;
2085                         end Is_Private_Record_Component;
2086
2087                         -------------------------------
2088                         -- Is_Visible_Generic_Entity --
2089                         -------------------------------
2090
2091                         function Is_Visible_Generic_Entity
2092                           (E : Entity_Id) return Boolean
2093                         is
2094                            Par : Node_Id;
2095
2096                         begin
2097                            --  The Present check here is an error defense
2098
2099                            if Present (Scope (E))
2100                              and then Ekind (Scope (E)) /= E_Generic_Package
2101                            then
2102                               return False;
2103                            end if;
2104
2105                            Par := Parent (E);
2106                            while Present (Par) loop
2107                               if
2108                                 Nkind (Par) = N_Generic_Package_Declaration
2109                               then
2110                                  --  Entity is a generic formal
2111
2112                                  return False;
2113
2114                               elsif
2115                                 Nkind (Parent (Par)) = N_Package_Specification
2116                               then
2117                                  return
2118                                    Is_List_Member (Par)
2119                                      and then List_Containing (Par) =
2120                                        Visible_Declarations (Parent (Par));
2121                               else
2122                                  Par := Parent (Par);
2123                               end if;
2124                            end loop;
2125
2126                            return False;
2127                         end Is_Visible_Generic_Entity;
2128
2129                      --  Start of processing for Write_Level_Info
2130
2131                      begin
2132                         if Is_Hidden (Curent)
2133                           or else Is_Private_Record_Component (Curent)
2134                         then
2135                            Write_Info_Char (' ');
2136
2137                         elsif
2138                            Is_Public (Curent)
2139                              or else Is_Visible_Generic_Entity (Curent)
2140                         then
2141                            Write_Info_Char ('*');
2142
2143                         else
2144                            Write_Info_Char (' ');
2145                         end if;
2146                      end Write_Level_Info;
2147
2148                      --  Output entity name. We use the occurrence from the
2149                      --  actual source program at the definition point.
2150
2151                      declare
2152                         Ent_Name : constant String :=
2153                                      Exact_Source_Name (Sloc (XE.Key.Ent));
2154                      begin
2155                         for C in Ent_Name'Range loop
2156                            Write_Info_Char (Ent_Name (C));
2157                         end loop;
2158                      end;
2159
2160                      --  See if we have a renaming reference
2161
2162                      if Is_Object (XE.Key.Ent)
2163                        and then Present (Renamed_Object (XE.Key.Ent))
2164                      then
2165                         Rref := Renamed_Object (XE.Key.Ent);
2166
2167                      elsif Is_Overloadable (XE.Key.Ent)
2168                        and then Nkind (Parent (Declaration_Node (XE.Key.Ent)))
2169                                            = N_Subprogram_Renaming_Declaration
2170                      then
2171                         Rref := Name (Parent (Declaration_Node (XE.Key.Ent)));
2172
2173                      elsif Ekind (XE.Key.Ent) = E_Package
2174                        and then Nkind (Declaration_Node (XE.Key.Ent)) =
2175                                          N_Package_Renaming_Declaration
2176                      then
2177                         Rref := Name (Declaration_Node (XE.Key.Ent));
2178
2179                      else
2180                         Rref := Empty;
2181                      end if;
2182
2183                      if Present (Rref) then
2184                         if Nkind (Rref) = N_Expanded_Name then
2185                            Rref := Selector_Name (Rref);
2186                         end if;
2187
2188                         if Nkind (Rref) = N_Identifier
2189                           or else Nkind (Rref) = N_Operator_Symbol
2190                         then
2191                            null;
2192
2193                         --  For renamed array components, use the array name
2194                         --  for the renamed entity, which reflect the fact that
2195                         --  in general the whole array is aliased.
2196
2197                         elsif Nkind (Rref) = N_Indexed_Component then
2198                            if Nkind (Prefix (Rref)) = N_Identifier then
2199                               Rref := Prefix (Rref);
2200                            elsif Nkind (Prefix (Rref)) = N_Expanded_Name then
2201                               Rref := Selector_Name (Prefix (Rref));
2202                            else
2203                               Rref := Empty;
2204                            end if;
2205
2206                         else
2207                            Rref := Empty;
2208                         end if;
2209                      end if;
2210
2211                      --  Write out renaming reference if we have one
2212
2213                      if Present (Rref) then
2214                         Write_Info_Char ('=');
2215                         Write_Info_Nat
2216                           (Int (Get_Logical_Line_Number (Sloc (Rref))));
2217                         Write_Info_Char (':');
2218                         Write_Info_Nat
2219                           (Int (Get_Column_Number (Sloc (Rref))));
2220                      end if;
2221
2222                      --  Indicate that the entity is in the unit of the current
2223                      --  xref section.
2224
2225                      Curru := Curxu;
2226
2227                      --  Write out information about generic parent, if entity
2228                      --  is an instance.
2229
2230                      if  Is_Generic_Instance (XE.Key.Ent) then
2231                         declare
2232                            Gen_Par : constant Entity_Id :=
2233                                        Generic_Parent
2234                                          (Specification
2235                                             (Unit_Declaration_Node
2236                                                (XE.Key.Ent)));
2237                            Loc     : constant Source_Ptr := Sloc (Gen_Par);
2238                            Gen_U   : constant Unit_Number_Type :=
2239                                        Get_Source_Unit (Loc);
2240
2241                         begin
2242                            Write_Info_Char ('[');
2243
2244                            if Curru /= Gen_U then
2245                               Write_Info_Nat (Dependency_Num (Gen_U));
2246                               Write_Info_Char ('|');
2247                            end if;
2248
2249                            Write_Info_Nat
2250                              (Int (Get_Logical_Line_Number (Loc)));
2251                            Write_Info_Char (']');
2252                         end;
2253                      end if;
2254
2255                      --  See if we have a type reference and if so output
2256
2257                      Check_Type_Reference (XE.Key.Ent, False);
2258
2259                      --  Additional information for types with progenitors
2260
2261                      if Is_Record_Type (XE.Key.Ent)
2262                        and then Present (Interfaces (XE.Key.Ent))
2263                      then
2264                         declare
2265                            Elmt : Elmt_Id :=
2266                                     First_Elmt (Interfaces (XE.Key.Ent));
2267                         begin
2268                            while Present (Elmt) loop
2269                               Check_Type_Reference (Node (Elmt), True);
2270                               Next_Elmt (Elmt);
2271                            end loop;
2272                         end;
2273
2274                      --  For array types, list index types as well. (This is
2275                      --  not C, indexes have distinct types).
2276
2277                      elsif Is_Array_Type (XE.Key.Ent) then
2278                         declare
2279                            Indx : Node_Id;
2280                         begin
2281                            Indx := First_Index (XE.Key.Ent);
2282                            while Present (Indx) loop
2283                               Check_Type_Reference
2284                                 (First_Subtype (Etype (Indx)), True);
2285                               Next_Index (Indx);
2286                            end loop;
2287                         end;
2288                      end if;
2289
2290                      --  If the entity is an overriding operation, write info
2291                      --  on operation that was overridden.
2292
2293                      if Is_Subprogram (XE.Key.Ent)
2294                        and then Present (Overridden_Operation (XE.Key.Ent))
2295                      then
2296                         Output_Overridden_Op
2297                           (Overridden_Operation (XE.Key.Ent));
2298                      end if;
2299
2300                      --  End of processing for entity output
2301
2302                      Crloc := No_Location;
2303                   end if;
2304
2305                   --  Output the reference if it is not as the same location
2306                   --  as the previous one, or it is a read-reference that
2307                   --  indicates that the entity is an in-out actual in a call.
2308
2309                   if XE.Key.Loc /= No_Location
2310                     and then
2311                       (XE.Key.Loc /= Crloc
2312                         or else (Prevt = 'm' and then  XE.Key.Typ = 'r'))
2313                   then
2314                      Crloc := XE.Key.Loc;
2315                      Prevt := XE.Key.Typ;
2316
2317                      --  Start continuation if line full, else blank
2318
2319                      if Write_Info_Col > 72 then
2320                         Write_Info_EOL;
2321                         Write_Info_Initiate ('.');
2322                      end if;
2323
2324                      Write_Info_Char (' ');
2325
2326                      --  Output file number if changed
2327
2328                      if XE.Key.Lun /= Curru then
2329                         Curru := XE.Key.Lun;
2330                         Write_Info_Nat (Dependency_Num (Curru));
2331                         Write_Info_Char ('|');
2332                      end if;
2333
2334                      Write_Info_Nat
2335                        (Int (Get_Logical_Line_Number (XE.Key.Loc)));
2336                      Write_Info_Char (XE.Key.Typ);
2337
2338                      if Is_Overloadable (XE.Key.Ent)
2339                        and then Is_Imported (XE.Key.Ent)
2340                        and then XE.Key.Typ = 'b'
2341                      then
2342                         Output_Import_Export_Info (XE.Key.Ent);
2343                      end if;
2344
2345                      Write_Info_Nat (Int (Get_Column_Number (XE.Key.Loc)));
2346
2347                      Output_Instantiation_Refs (Sloc (XE.Key.Ent));
2348                   end if;
2349                end if;
2350             end Output_One_Ref;
2351
2352          <<Continue>>
2353             null;
2354          end loop;
2355
2356          Write_Info_EOL;
2357       end Output_Refs;
2358    end Output_References;
2359
2360 begin
2361    --  Reset is necessary because Elmt_Ptr does not default to Null_Ptr,
2362    --  because it's not an access type.
2363
2364    Xref_Set.Reset;
2365 end Lib.Xref;