gcc/ada/lib-xref.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             L I B . X R E F                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1998-2012, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Csets;    use Csets;
  28 with Elists;   use Elists;
  29 with Errout;   use Errout;
  30 with Nlists;   use Nlists;
  31 with Opt;      use Opt;
  32 with Restrict; use Restrict;
  33 with Rident;   use Rident;
  34 with Sem;      use Sem;
  35 with Sem_Aux;  use Sem_Aux;
  36 with Sem_Prag; use Sem_Prag;
  37 with Sem_Util; use Sem_Util;
  38 with Sem_Warn; use Sem_Warn;
  39 with Sinfo;    use Sinfo;
  40 with Sinput;   use Sinput;
  41 with Snames;   use Snames;
  42 with Stringt;  use Stringt;
  43 with Stand;    use Stand;
  44 with Table;    use Table;
  45
  46 with GNAT.Heap_Sort_G;
  47 with GNAT.HTable;
  48
  49 package body Lib.Xref is
  50
  51    ------------------
  52    -- Declarations --
  53    ------------------
  54
  55    --  The Xref table is used to record references. The Loc field is set
  56    --  to No_Location for a definition entry.
  57
  58    subtype Xref_Entry_Number is Int;
  59
  60    type Xref_Key is record
  61       --  These are the components of Xref_Entry that participate in hash
  62       --  lookups.
  63
  64       Ent : Entity_Id;
  65       --  Entity referenced (E parameter to Generate_Reference)
  66
  67       Loc : Source_Ptr;
  68       --  Location of reference (Original_Location (Sloc field of N parameter
  69       --  to Generate_Reference). Set to No_Location for the case of a
  70       --  defining occurrence.
  71
  72       Typ : Character;
  73       --  Reference type (Typ param to Generate_Reference)
  74
  75       Eun : Unit_Number_Type;
  76       --  Unit number corresponding to Ent
  77
  78       Lun : Unit_Number_Type;
  79       --  Unit number corresponding to Loc. Value is undefined and not
  80       --  referenced if Loc is set to No_Location.
  81
  82       --  The following components are only used for Alfa cross-references
  83
  84       Ref_Scope : Entity_Id;
  85       --  Entity of the closest subprogram or package enclosing the reference
  86
  87       Ent_Scope : Entity_Id;
  88       --  Entity of the closest subprogram or package enclosing the definition,
  89       --  which should be located in the same file as the definition itself.
  90    end record;
  91
  92    type Xref_Entry is record
  93       Key : Xref_Key;
  94
  95       Ent_Scope_File : Unit_Number_Type;
  96       --  File for entity Ent_Scope
  97
  98       Def : Source_Ptr;
  99       --  Original source location for entity being referenced. Note that these
 100       --  values are used only during the output process, they are not set when
 101       --  the entries are originally built. This is because private entities
 102       --  can be swapped when the initial call is made.
 103
 104       HTable_Next : Xref_Entry_Number;
 105       --  For use only by Static_HTable
 106    end record;
 107
 108    package Xrefs is new Table.Table (
 109      Table_Component_Type => Xref_Entry,
 110      Table_Index_Type     => Xref_Entry_Number,
 111      Table_Low_Bound      => 1,
 112      Table_Initial        => Alloc.Xrefs_Initial,
 113      Table_Increment      => Alloc.Xrefs_Increment,
 114      Table_Name           => "Xrefs");
 115
 116    --------------
 117    -- Xref_Set --
 118    --------------
 119
 120    --  We keep a set of xref entries, in order to avoid inserting duplicate
 121    --  entries into the above Xrefs table. An entry is in Xref_Set if and only
 122    --  if it is in Xrefs.
 123
 124    Num_Buckets : constant := 2**16;
 125
 126    subtype Header_Num is Integer range 0 .. Num_Buckets - 1;
 127    type Null_Type is null record;
 128    pragma Unreferenced (Null_Type);
 129
 130    function Hash (F : Xref_Entry_Number) return Header_Num;
 131
 132    function Equal (F1, F2 : Xref_Entry_Number) return Boolean;
 133
 134    procedure HT_Set_Next (E : Xref_Entry_Number; Next : Xref_Entry_Number);
 135
 136    function  HT_Next (E : Xref_Entry_Number) return Xref_Entry_Number;
 137
 138    function Get_Key (E : Xref_Entry_Number) return Xref_Entry_Number;
 139
 140    pragma Inline (Hash, Equal, HT_Set_Next, HT_Next, Get_Key);
 141
 142    package Xref_Set is new GNAT.HTable.Static_HTable (
 143      Header_Num,
 144      Element    => Xref_Entry,
 145      Elmt_Ptr   => Xref_Entry_Number,
 146      Null_Ptr   => 0,
 147      Set_Next   => HT_Set_Next,
 148      Next       => HT_Next,
 149      Key        => Xref_Entry_Number,
 150      Get_Key    => Get_Key,
 151      Hash       => Hash,
 152      Equal      => Equal);
 153
 154    ----------------------
 155    -- Alfa Information --
 156    ----------------------
 157
 158    package body Alfa is separate;
 159
 160    ------------------------
 161    --  Local Subprograms --
 162    ------------------------
 163
 164    procedure Add_Entry (Key : Xref_Key; Ent_Scope_File : Unit_Number_Type);
 165    --  Add an entry to the tables of Xref_Entries, avoiding duplicates
 166
 167    procedure Generate_Prim_Op_References (Typ : Entity_Id);
 168    --  For a tagged type, generate implicit references to its primitive
 169    --  operations, for source navigation. This is done right before emitting
 170    --  cross-reference information rather than at the freeze point of the type
 171    --  in order to handle late bodies that are primitive operations.
 172
 173    function Lt (T1, T2 : Xref_Entry) return Boolean;
 174    --  Order cross-references
 175
 176    ---------------
 177    -- Add_Entry --
 178    ---------------
 179
 180    procedure Add_Entry (Key : Xref_Key; Ent_Scope_File : Unit_Number_Type) is
 181    begin
 182       Xrefs.Increment_Last; -- tentative
 183       Xrefs.Table (Xrefs.Last).Key := Key;
 184
 185       --  Set the entry in Xref_Set, and if newly set, keep the above
 186       --  tentative increment.
 187
 188       if Xref_Set.Set_If_Not_Present (Xrefs.Last) then
 189          Xrefs.Table (Xrefs.Last).Ent_Scope_File := Ent_Scope_File;
 190          --  Leave Def and HTable_Next uninitialized
 191
 192          Set_Has_Xref_Entry (Key.Ent);
 193
 194       --  It was already in Xref_Set, so throw away the tentatively-added
 195       --  entry
 196
 197       else
 198          Xrefs.Decrement_Last;
 199       end if;
 200    end Add_Entry;
 201
 202    -----------
 203    -- Equal --
 204    -----------
 205
 206    function Equal (F1, F2 : Xref_Entry_Number) return Boolean is
 207       Result : constant Boolean :=
 208                  Xrefs.Table (F1).Key = Xrefs.Table (F2).Key;
 209    begin
 210       return Result;
 211    end Equal;
 212
 213    -------------------------
 214    -- Generate_Definition --
 215    -------------------------
 216
 217    procedure Generate_Definition (E : Entity_Id) is
 218    begin
 219       pragma Assert (Nkind (E) in N_Entity);
 220
 221       --  Note that we do not test Xref_Entity_Letters here. It is too early
 222       --  to do so, since we are often called before the entity is fully
 223       --  constructed, so that the Ekind is still E_Void.
 224
 225       if Opt.Xref_Active
 226
 227          --  Definition must come from source
 228
 229          --  We make an exception for subprogram child units that have no spec.
 230          --  For these we generate a subprogram declaration for library use,
 231          --  and the corresponding entity does not come from source.
 232          --  Nevertheless, all references will be attached to it and we have
 233          --  to treat is as coming from user code.
 234
 235          and then (Comes_From_Source (E) or else Is_Child_Unit (E))
 236
 237          --  And must have a reasonable source location that is not
 238          --  within an instance (all entities in instances are ignored)
 239
 240          and then Sloc (E) > No_Location
 241          and then Instantiation_Location (Sloc (E)) = No_Location
 242
 243          --  And must be a non-internal name from the main source unit
 244
 245          and then In_Extended_Main_Source_Unit (E)
 246          and then not Is_Internal_Name (Chars (E))
 247       then
 248          Add_Entry
 249            ((Ent => E,
 250              Loc => No_Location,
 251              Typ => ' ',
 252              Eun => Get_Source_Unit (Original_Location (Sloc (E))),
 253              Lun => No_Unit,
 254              Ref_Scope => Empty,
 255              Ent_Scope => Empty),
 256             Ent_Scope_File => No_Unit);
 257
 258          if In_Inlined_Body then
 259             Set_Referenced (E);
 260          end if;
 261       end if;
 262    end Generate_Definition;
 263
 264    ---------------------------------
 265    -- Generate_Operator_Reference --
 266    ---------------------------------
 267
 268    procedure Generate_Operator_Reference
 269      (N : Node_Id;
 270       T : Entity_Id)
 271    is
 272    begin
 273       if not In_Extended_Main_Source_Unit (N) then
 274          return;
 275       end if;
 276
 277       --  If the operator is not a Standard operator, then we generate a real
 278       --  reference to the user defined operator.
 279
 280       if Sloc (Entity (N)) /= Standard_Location then
 281          Generate_Reference (Entity (N), N);
 282
 283          --  A reference to an implicit inequality operator is also a reference
 284          --  to the user-defined equality.
 285
 286          if Nkind (N) = N_Op_Ne
 287            and then not Comes_From_Source (Entity (N))
 288            and then Present (Corresponding_Equality (Entity (N)))
 289          then
 290             Generate_Reference (Corresponding_Equality (Entity (N)), N);
 291          end if;
 292
 293       --  For the case of Standard operators, we mark the result type as
 294       --  referenced. This ensures that in the case where we are using a
 295       --  derived operator, we mark an entity of the unit that implicitly
 296       --  defines this operator as used. Otherwise we may think that no entity
 297       --  of the unit is used. The actual entity marked as referenced is the
 298       --  first subtype, which is the relevant user defined entity.
 299
 300       --  Note: we only do this for operators that come from source. The
 301       --  generated code sometimes reaches for entities that do not need to be
 302       --  explicitly visible (for example, when we expand the code for
 303       --  comparing two record objects, the fields of the record may not be
 304       --  visible).
 305
 306       elsif Comes_From_Source (N) then
 307          Set_Referenced (First_Subtype (T));
 308       end if;
 309    end Generate_Operator_Reference;
 310
 311    ---------------------------------
 312    -- Generate_Prim_Op_References --
 313    ---------------------------------
 314
 315    procedure Generate_Prim_Op_References (Typ : Entity_Id) is
 316       Base_T    : Entity_Id;
 317       Prim      : Elmt_Id;
 318       Prim_List : Elist_Id;
 319
 320    begin
 321       --  Handle subtypes of synchronized types
 322
 323       if Ekind (Typ) = E_Protected_Subtype
 324         or else Ekind (Typ) = E_Task_Subtype
 325       then
 326          Base_T := Etype (Typ);
 327       else
 328          Base_T := Typ;
 329       end if;
 330
 331       --  References to primitive operations are only relevant for tagged types
 332
 333       if not Is_Tagged_Type (Base_T)
 334         or else Is_Class_Wide_Type (Base_T)
 335       then
 336          return;
 337       end if;
 338
 339       --  Ada 2005 (AI-345): For synchronized types generate reference to the
 340       --  wrapper that allow us to dispatch calls through their implemented
 341       --  abstract interface types.
 342
 343       --  The check for Present here is to protect against previously reported
 344       --  critical errors.
 345
 346       Prim_List := Primitive_Operations (Base_T);
 347
 348       if No (Prim_List) then
 349          return;
 350       end if;
 351
 352       Prim := First_Elmt (Prim_List);
 353       while Present (Prim) loop
 354
 355          --  If the operation is derived, get the original for cross-reference
 356          --  reference purposes (it is the original for which we want the xref
 357          --  and for which the comes_from_source test must be performed).
 358
 359          Generate_Reference
 360            (Typ, Ultimate_Alias (Node (Prim)), 'p', Set_Ref => False);
 361          Next_Elmt (Prim);
 362       end loop;
 363    end Generate_Prim_Op_References;
 364
 365    ------------------------
 366    -- Generate_Reference --
 367    ------------------------
 368
 369    procedure Generate_Reference
 370      (E       : Entity_Id;
 371       N       : Node_Id;
 372       Typ     : Character := 'r';
 373       Set_Ref : Boolean   := True;
 374       Force   : Boolean   := False)
 375    is
 376       Actual_Typ     : Character := Typ;
 377       Call           : Node_Id;
 378       Def            : Source_Ptr;
 379       Ent            : Entity_Id;
 380       Ent_Scope      : Entity_Id;
 381       Formal         : Entity_Id;
 382       Kind           : Entity_Kind;
 383       Nod            : Node_Id;
 384       Ref            : Source_Ptr;
 385       Ref_Scope      : Entity_Id;
 386
 387       function Get_Through_Renamings (E : Entity_Id) return Entity_Id;
 388       --  Get the enclosing entity through renamings, which may come from
 389       --  source or from the translation of generic instantiations.
 390
 391       function Is_On_LHS (Node : Node_Id) return Boolean;
 392       --  Used to check if a node is on the left hand side of an assignment.
 393       --  The following cases are handled:
 394       --
 395       --   Variable    Node is a direct descendant of left hand side of an
 396       --               assignment statement.
 397       --
 398       --   Prefix      Of an indexed or selected component that is present in
 399       --               a subtree rooted by an assignment statement. There is
 400       --               no restriction of nesting of components, thus cases
 401       --               such as A.B (C).D are handled properly. However a prefix
 402       --               of a dereference (either implicit or explicit) is never
 403       --               considered as on a LHS.
 404       --
 405       --   Out param   Same as above cases, but OUT parameter
 406
 407       function OK_To_Set_Referenced return Boolean;
 408       --  Returns True if the Referenced flag can be set. There are a few
 409       --  exceptions where we do not want to set this flag, see body for
 410       --  details of these exceptional cases.
 411
 412       ---------------------------
 413       -- Get_Through_Renamings --
 414       ---------------------------
 415
 416       function Get_Through_Renamings (E : Entity_Id) return Entity_Id is
 417          Result : Entity_Id := E;
 418       begin
 419          while Present (Result)
 420            and then Is_Object (Result)
 421            and then Present (Renamed_Object (Result))
 422          loop
 423             Result := Get_Enclosing_Object (Renamed_Object (Result));
 424          end loop;
 425          return Result;
 426       end Get_Through_Renamings;
 427
 428       ---------------
 429       -- Is_On_LHS --
 430       ---------------
 431
 432       --  ??? There are several routines here and there that perform a similar
 433       --      (but subtly different) computation, which should be factored:
 434
 435       --      Sem_Util.May_Be_Lvalue
 436       --      Sem_Util.Known_To_Be_Assigned
 437       --      Exp_Ch2.Expand_Entry_Parameter.In_Assignment_Context
 438       --      Exp_Smem.Is_Out_Actual
 439
 440       function Is_On_LHS (Node : Node_Id) return Boolean is
 441          N : Node_Id;
 442          P : Node_Id;
 443          K : Node_Kind;
 444
 445       begin
 446          --  Only identifiers are considered, is this necessary???
 447
 448          if Nkind (Node) /= N_Identifier then
 449             return False;
 450          end if;
 451
 452          --  Immediate return if appeared as OUT parameter
 453
 454          if Kind = E_Out_Parameter then
 455             return True;
 456          end if;
 457
 458          --  Search for assignment statement subtree root
 459
 460          N := Node;
 461          loop
 462             P := Parent (N);
 463             K := Nkind (P);
 464
 465             if K = N_Assignment_Statement then
 466                return Name (P) = N;
 467
 468             --  Check whether the parent is a component and the current node is
 469             --  its prefix, but return False if the current node has an access
 470             --  type, as in that case the selected or indexed component is an
 471             --  implicit dereference, and the LHS is the designated object, not
 472             --  the access object.
 473
 474             --  ??? case of a slice assignment?
 475
 476             --  ??? Note that in some cases this is called too early
 477             --  (see comments in Sem_Ch8.Find_Direct_Name), at a point where
 478             --  the tree is not fully typed yet. In that case we may lack
 479             --  an Etype for N, and we must disable the check for an implicit
 480             --  dereference. If the dereference is on an LHS, this causes a
 481             --  false positive.
 482
 483             elsif (K = N_Selected_Component or else K = N_Indexed_Component)
 484               and then Prefix (P) = N
 485               and then not (Present (Etype (N))
 486                               and then
 487                             Is_Access_Type (Etype (N)))
 488             then
 489                N := P;
 490
 491             --  All other cases, definitely not on left side
 492
 493             else
 494                return False;
 495             end if;
 496          end loop;
 497       end Is_On_LHS;
 498
 499       ---------------------------
 500       -- OK_To_Set_Referenced --
 501       ---------------------------
 502
 503       function OK_To_Set_Referenced return Boolean is
 504          P : Node_Id;
 505
 506       begin
 507          --  A reference from a pragma Unreferenced or pragma Unmodified or
 508          --  pragma Warnings does not cause the Referenced flag to be set.
 509          --  This avoids silly warnings about things being referenced and
 510          --  not assigned when the only reference is from the pragma.
 511
 512          if Nkind (N) = N_Identifier then
 513             P := Parent (N);
 514
 515             if Nkind (P) = N_Pragma_Argument_Association then
 516                P := Parent (P);
 517
 518                if Nkind (P) = N_Pragma then
 519                   if Pragma_Name (P) = Name_Warnings
 520                        or else
 521                      Pragma_Name (P) = Name_Unmodified
 522                        or else
 523                      Pragma_Name (P) = Name_Unreferenced
 524                   then
 525                      return False;
 526                   end if;
 527                end if;
 528
 529             --  A reference to a formal in a named parameter association does
 530             --  not make the formal referenced. Formals that are unused in the
 531             --  subprogram body are properly flagged as such, even if calls
 532             --  elsewhere use named notation.
 533
 534             elsif Nkind (P) = N_Parameter_Association
 535               and then N = Selector_Name (P)
 536             then
 537                return False;
 538             end if;
 539          end if;
 540
 541          return True;
 542       end OK_To_Set_Referenced;
 543
 544    --  Start of processing for Generate_Reference
 545
 546    begin
 547       pragma Assert (Nkind (E) in N_Entity);
 548       Find_Actual (N, Formal, Call);
 549
 550       if Present (Formal) then
 551          Kind := Ekind (Formal);
 552       else
 553          Kind := E_Void;
 554       end if;
 555
 556       --  Check for obsolescent reference to package ASCII. GNAT treats this
 557       --  element of annex J specially since in practice, programs make a lot
 558       --  of use of this feature, so we don't include it in the set of features
 559       --  diagnosed when Warn_On_Obsolescent_Features mode is set. However we
 560       --  are required to note it as a violation of the RM defined restriction.
 561
 562       if E = Standard_ASCII then
 563          Check_Restriction (No_Obsolescent_Features, N);
 564       end if;
 565
 566       --  Check for reference to entity marked with Is_Obsolescent
 567
 568       --  Note that we always allow obsolescent references in the compiler
 569       --  itself and the run time, since we assume that we know what we are
 570       --  doing in such cases. For example the calls in Ada.Characters.Handling
 571       --  to its own obsolescent subprograms are just fine.
 572
 573       --  In any case we only generate warnings if we are in the extended main
 574       --  source unit, and the entity itself is not in the extended main source
 575       --  unit, since we assume the source unit itself knows what is going on
 576       --  (and for sure we do not want silly warnings, e.g. on the end line of
 577       --  an obsolescent procedure body).
 578
 579       if Is_Obsolescent (E)
 580         and then not GNAT_Mode
 581         and then not In_Extended_Main_Source_Unit (E)
 582         and then In_Extended_Main_Source_Unit (N)
 583       then
 584          Check_Restriction (No_Obsolescent_Features, N);
 585
 586          if Warn_On_Obsolescent_Feature then
 587             Output_Obsolescent_Entity_Warnings (N, E);
 588          end if;
 589       end if;
 590
 591       --  Warn if reference to Ada 2005 entity not in Ada 2005 mode. We only
 592       --  detect real explicit references (modifications and references).
 593
 594       if Comes_From_Source (N)
 595         and then Is_Ada_2005_Only (E)
 596         and then Ada_Version < Ada_2005
 597         and then Warn_On_Ada_2005_Compatibility
 598         and then (Typ = 'm' or else Typ = 'r' or else Typ = 's')
 599       then
 600          Error_Msg_NE ("& is only defined in Ada 2005?", N, E);
 601       end if;
 602
 603       --  Warn if reference to Ada 2012 entity not in Ada 2012 mode. We only
 604       --  detect real explicit references (modifications and references).
 605
 606       if Comes_From_Source (N)
 607         and then Is_Ada_2012_Only (E)
 608         and then Ada_Version < Ada_2012
 609         and then Warn_On_Ada_2012_Compatibility
 610         and then (Typ = 'm' or else Typ = 'r')
 611       then
 612          Error_Msg_NE ("& is only defined in Ada 2012?", N, E);
 613       end if;
 614
 615       --  Never collect references if not in main source unit. However, we omit
 616       --  this test if Typ is 'e' or 'k', since these entries are structural,
 617       --  and it is useful to have them in units that reference packages as
 618       --  well as units that define packages. We also omit the test for the
 619       --  case of 'p' since we want to include inherited primitive operations
 620       --  from other packages.
 621
 622       --  We also omit this test is this is a body reference for a subprogram
 623       --  instantiation. In this case the reference is to the generic body,
 624       --  which clearly need not be in the main unit containing the instance.
 625       --  For the same reason we accept an implicit reference generated for
 626       --  a default in an instance.
 627
 628       if not In_Extended_Main_Source_Unit (N) then
 629          if Typ = 'e'
 630            or else Typ = 'I'
 631            or else Typ = 'p'
 632            or else Typ = 'i'
 633            or else Typ = 'k'
 634            or else (Typ = 'b' and then Is_Generic_Instance (E))
 635
 636             --  Allow the generation of references to reads, writes and calls
 637             --  in Alfa mode when the related context comes from an instance.
 638
 639            or else
 640              (Alfa_Mode
 641                 and then In_Extended_Main_Code_Unit (N)
 642                 and then (Typ = 'm' or else Typ = 'r' or else Typ = 's'))
 643          then
 644             null;
 645          else
 646             return;
 647          end if;
 648       end if;
 649
 650       --  For reference type p, the entity must be in main source unit
 651
 652       if Typ = 'p' and then not In_Extended_Main_Source_Unit (E) then
 653          return;
 654       end if;
 655
 656       --  Unless the reference is forced, we ignore references where the
 657       --  reference itself does not come from source.
 658
 659       if not Force and then not Comes_From_Source (N) then
 660          return;
 661       end if;
 662
 663       --  Deal with setting entity as referenced, unless suppressed. Note that
 664       --  we still do Set_Referenced on entities that do not come from source.
 665       --  This situation arises when we have a source reference to a derived
 666       --  operation, where the derived operation itself does not come from
 667       --  source, but we still want to mark it as referenced, since we really
 668       --  are referencing an entity in the corresponding package (this avoids
 669       --  wrong complaints that the package contains no referenced entities).
 670
 671       if Set_Ref then
 672
 673          --  Assignable object appearing on left side of assignment or as
 674          --  an out parameter.
 675
 676          if Is_Assignable (E)
 677            and then Is_On_LHS (N)
 678            and then Ekind (E) /= E_In_Out_Parameter
 679          then
 680             --  For objects that are renamings, just set as simply referenced
 681             --  we do not try to do assignment type tracking in this case.
 682
 683             if Present (Renamed_Object (E)) then
 684                Set_Referenced (E);
 685
 686             --  Out parameter case
 687
 688             elsif Kind = E_Out_Parameter then
 689
 690                --  If warning mode for all out parameters is set, or this is
 691                --  the only warning parameter, then we want to mark this for
 692                --  later warning logic by setting Referenced_As_Out_Parameter
 693
 694                if Warn_On_Modified_As_Out_Parameter (Formal) then
 695                   Set_Referenced_As_Out_Parameter (E, True);
 696                   Set_Referenced_As_LHS (E, False);
 697
 698                --  For OUT parameter not covered by the above cases, we simply
 699                --  regard it as a normal reference (in this case we do not
 700                --  want any of the warning machinery for out parameters).
 701
 702                else
 703                   Set_Referenced (E);
 704                end if;
 705
 706             --  For the left hand of an assignment case, we do nothing here.
 707             --  The processing for Analyze_Assignment_Statement will set the
 708             --  Referenced_As_LHS flag.
 709
 710             else
 711                null;
 712             end if;
 713
 714          --  Check for a reference in a pragma that should not count as a
 715          --  making the variable referenced for warning purposes.
 716
 717          elsif Is_Non_Significant_Pragma_Reference (N) then
 718             null;
 719
 720          --  A reference in an attribute definition clause does not count as a
 721          --  reference except for the case of Address. The reason that 'Address
 722          --  is an exception is that it creates an alias through which the
 723          --  variable may be referenced.
 724
 725          elsif Nkind (Parent (N)) = N_Attribute_Definition_Clause
 726            and then Chars (Parent (N)) /= Name_Address
 727            and then N = Name (Parent (N))
 728          then
 729             null;
 730
 731          --  Constant completion does not count as a reference
 732
 733          elsif Typ = 'c'
 734            and then Ekind (E) = E_Constant
 735          then
 736             null;
 737
 738          --  Record representation clause does not count as a reference
 739
 740          elsif Nkind (N) = N_Identifier
 741            and then Nkind (Parent (N)) = N_Record_Representation_Clause
 742          then
 743             null;
 744
 745          --  Discriminants do not need to produce a reference to record type
 746
 747          elsif Typ = 'd'
 748            and then Nkind (Parent (N)) = N_Discriminant_Specification
 749          then
 750             null;
 751
 752          --  All other cases
 753
 754          else
 755             --  Special processing for IN OUT parameters, where we have an
 756             --  implicit assignment to a simple variable.
 757
 758             if Kind = E_In_Out_Parameter
 759               and then Is_Assignable (E)
 760             then
 761                --  For sure this counts as a normal read reference
 762
 763                Set_Referenced (E);
 764                Set_Last_Assignment (E, Empty);
 765
 766                --  We count it as being referenced as an out parameter if the
 767                --  option is set to warn on all out parameters, except that we
 768                --  have a special exclusion for an intrinsic subprogram, which
 769                --  is most likely an instantiation of Unchecked_Deallocation
 770                --  which we do not want to consider as an assignment since it
 771                --  generates false positives. We also exclude the case of an
 772                --  IN OUT parameter if the name of the procedure is Free,
 773                --  since we suspect similar semantics.
 774
 775                if Warn_On_All_Unread_Out_Parameters
 776                  and then Is_Entity_Name (Name (Call))
 777                  and then not Is_Intrinsic_Subprogram (Entity (Name (Call)))
 778                  and then Chars (Name (Call)) /= Name_Free
 779                then
 780                   Set_Referenced_As_Out_Parameter (E, True);
 781                   Set_Referenced_As_LHS (E, False);
 782                end if;
 783
 784             --  Don't count a recursive reference within a subprogram as a
 785             --  reference (that allows detection of a recursive subprogram
 786             --  whose only references are recursive calls as unreferenced).
 787
 788             elsif Is_Subprogram (E)
 789               and then E = Nearest_Dynamic_Scope (Current_Scope)
 790             then
 791                null;
 792
 793             --  Any other occurrence counts as referencing the entity
 794
 795             elsif OK_To_Set_Referenced then
 796                Set_Referenced (E);
 797
 798                --  If variable, this is an OK reference after an assignment
 799                --  so we can clear the Last_Assignment indication.
 800
 801                if Is_Assignable (E) then
 802                   Set_Last_Assignment (E, Empty);
 803                end if;
 804             end if;
 805          end if;
 806
 807          --  Check for pragma Unreferenced given and reference is within
 808          --  this source unit (occasion for possible warning to be issued).
 809
 810          if Has_Unreferenced (E)
 811            and then In_Same_Extended_Unit (E, N)
 812          then
 813             --  A reference as a named parameter in a call does not count
 814             --  as a violation of pragma Unreferenced for this purpose...
 815
 816             if Nkind (N) = N_Identifier
 817               and then Nkind (Parent (N)) = N_Parameter_Association
 818               and then Selector_Name (Parent (N)) = N
 819             then
 820                null;
 821
 822             --  ... Neither does a reference to a variable on the left side
 823             --  of an assignment.
 824
 825             elsif Is_On_LHS (N) then
 826                null;
 827
 828             --  For entry formals, we want to place the warning message on the
 829             --  corresponding entity in the accept statement. The current scope
 830             --  is the body of the accept, so we find the formal whose name
 831             --  matches that of the entry formal (there is no link between the
 832             --  two entities, and the one in the accept statement is only used
 833             --  for conformance checking).
 834
 835             elsif Ekind (Scope (E)) = E_Entry then
 836                declare
 837                   BE : Entity_Id;
 838
 839                begin
 840                   BE := First_Entity (Current_Scope);
 841                   while Present (BE) loop
 842                      if Chars (BE) = Chars (E) then
 843                         Error_Msg_NE -- CODEFIX
 844                           ("?pragma Unreferenced given for&!", N, BE);
 845                         exit;
 846                      end if;
 847
 848                      Next_Entity (BE);
 849                   end loop;
 850                end;
 851
 852             --  Here we issue the warning, since this is a real reference
 853
 854             else
 855                Error_Msg_NE -- CODEFIX
 856                  ("?pragma Unreferenced given for&!", N, E);
 857             end if;
 858          end if;
 859
 860          --  If this is a subprogram instance, mark as well the internal
 861          --  subprogram in the wrapper package, which may be a visible
 862          --  compilation unit.
 863
 864          if Is_Overloadable (E)
 865            and then Is_Generic_Instance (E)
 866            and then Present (Alias (E))
 867          then
 868             Set_Referenced (Alias (E));
 869          end if;
 870       end if;
 871
 872       --  Generate reference if all conditions are met:
 873
 874       if
 875          --  Cross referencing must be active
 876
 877          Opt.Xref_Active
 878
 879          --  The entity must be one for which we collect references
 880
 881          and then Xref_Entity_Letters (Ekind (E)) /= ' '
 882
 883          --  Both Sloc values must be set to something sensible
 884
 885          and then Sloc (E) > No_Location
 886          and then Sloc (N) > No_Location
 887
 888          --  Ignore references from within an instance. The only exceptions to
 889          --  this are default subprograms, for which we generate an implicit
 890          --  reference and compilations in Alfa_Mode.
 891
 892          and then
 893            (Instantiation_Location (Sloc (N)) = No_Location
 894              or else Typ = 'i'
 895              or else Alfa_Mode)
 896
 897         --  Ignore dummy references
 898
 899         and then Typ /= ' '
 900       then
 901          if Nkind_In (N, N_Identifier,
 902                          N_Defining_Identifier,
 903                          N_Defining_Operator_Symbol,
 904                          N_Operator_Symbol,
 905                          N_Defining_Character_Literal)
 906            or else Nkind (N) in N_Op
 907            or else (Nkind (N) = N_Character_Literal
 908                      and then Sloc (Entity (N)) /= Standard_Location)
 909          then
 910             Nod := N;
 911
 912          elsif Nkind_In (N, N_Expanded_Name, N_Selected_Component) then
 913             Nod := Selector_Name (N);
 914
 915          else
 916             return;
 917          end if;
 918
 919          --  Normal case of source entity comes from source
 920
 921          if Comes_From_Source (E) then
 922             Ent := E;
 923
 924          --  Entity does not come from source, but is a derived subprogram and
 925          --  the derived subprogram comes from source (after one or more
 926          --  derivations) in which case the reference is to parent subprogram.
 927
 928          elsif Is_Overloadable (E)
 929            and then Present (Alias (E))
 930          then
 931             Ent := Alias (E);
 932             while not Comes_From_Source (Ent) loop
 933                if No (Alias (Ent)) then
 934                   return;
 935                end if;
 936
 937                Ent := Alias (Ent);
 938             end loop;
 939
 940          --  The internally created defining entity for a child subprogram
 941          --  that has no previous spec has valid references.
 942
 943          elsif Is_Overloadable (E)
 944            and then Is_Child_Unit (E)
 945          then
 946             Ent := E;
 947
 948          --  Record components of discriminated subtypes or derived types must
 949          --  be treated as references to the original component.
 950
 951          elsif Ekind (E) = E_Component
 952            and then Comes_From_Source (Original_Record_Component (E))
 953          then
 954             Ent := Original_Record_Component (E);
 955
 956          --  If this is an expanded reference to a discriminant, recover the
 957          --  original discriminant, which gets the reference.
 958
 959          elsif Ekind (E) = E_In_Parameter
 960            and then  Present (Discriminal_Link (E))
 961          then
 962             Ent := Discriminal_Link (E);
 963             Set_Referenced (Ent);
 964
 965          --  Ignore reference to any other entity that is not from source
 966
 967          else
 968             return;
 969          end if;
 970
 971          --  In Alfa mode, consider the underlying entity renamed instead of
 972          --  the renaming, which is needed to compute a valid set of effects
 973          --  (reads, writes) for the enclosing subprogram.
 974
 975          if Alfa_Mode then
 976             Ent := Get_Through_Renamings (Ent);
 977
 978             --  If no enclosing object, then it could be a reference to any
 979             --  location not tracked individually, like heap-allocated data.
 980             --  Conservatively approximate this possibility by generating a
 981             --  dereference, and return.
 982
 983             if No (Ent) then
 984                if Actual_Typ = 'w' then
 985                   Alfa.Generate_Dereference (Nod, 'r');
 986                   Alfa.Generate_Dereference (Nod, 'w');
 987                else
 988                   Alfa.Generate_Dereference (Nod, 'r');
 989                end if;
 990
 991                return;
 992             end if;
 993          end if;
 994
 995          --  Record reference to entity
 996
 997          if Actual_Typ = 'p'
 998            and then Is_Subprogram (Nod)
 999            and then Present (Overridden_Operation (Nod))
1000          then
1001             Actual_Typ := 'P';
1002          end if;
1003
1004          if Alfa_Mode then
1005             Ref := Sloc (Nod);
1006             Def := Sloc (Ent);
1007
1008             Ref_Scope := Alfa.Enclosing_Subprogram_Or_Package (Nod);
1009             Ent_Scope := Alfa.Enclosing_Subprogram_Or_Package (Ent);
1010
1011             --  Since we are reaching through renamings in Alfa mode, we may
1012             --  end up with standard constants. Ignore those.
1013
1014             if Sloc (Ent_Scope) <= Standard_Location
1015               or else Def <= Standard_Location
1016             then
1017                return;
1018             end if;
1019
1020             Add_Entry
1021               ((Ent      => Ent,
1022                 Loc       => Ref,
1023                 Typ       => Actual_Typ,
1024                 Eun       => Get_Code_Unit (Def),
1025                 Lun       => Get_Code_Unit (Ref),
1026                 Ref_Scope => Ref_Scope,
1027                 Ent_Scope => Ent_Scope),
1028                Ent_Scope_File => Get_Code_Unit (Ent));
1029
1030          else
1031             Ref := Original_Location (Sloc (Nod));
1032             Def := Original_Location (Sloc (Ent));
1033
1034             --  If this is an operator symbol, skip the initial
1035             --  quote, for navigation purposes.
1036
1037             if Nkind (N) = N_Defining_Operator_Symbol
1038               or else Nkind (Nod) = N_Operator_Symbol
1039             then
1040                Ref := Ref + 1;
1041             end if;
1042
1043             Add_Entry
1044               ((Ent      => Ent,
1045                 Loc       => Ref,
1046                 Typ       => Actual_Typ,
1047                 Eun       => Get_Source_Unit (Def),
1048                 Lun       => Get_Source_Unit (Ref),
1049                 Ref_Scope => Empty,
1050                 Ent_Scope => Empty),
1051                Ent_Scope_File => No_Unit);
1052          end if;
1053       end if;
1054    end Generate_Reference;
1055
1056    -----------------------------------
1057    -- Generate_Reference_To_Formals --
1058    -----------------------------------
1059
1060    procedure Generate_Reference_To_Formals (E : Entity_Id) is
1061       Formal : Entity_Id;
1062
1063    begin
1064       if Is_Generic_Subprogram (E) then
1065          Formal := First_Entity (E);
1066
1067          while Present (Formal)
1068            and then not Is_Formal (Formal)
1069          loop
1070             Next_Entity (Formal);
1071          end loop;
1072
1073       else
1074          Formal := First_Formal (E);
1075       end if;
1076
1077       while Present (Formal) loop
1078          if Ekind (Formal) = E_In_Parameter then
1079
1080             if Nkind (Parameter_Type (Parent (Formal)))
1081               = N_Access_Definition
1082             then
1083                Generate_Reference (E, Formal, '^', False);
1084             else
1085                Generate_Reference (E, Formal, '>', False);
1086             end if;
1087
1088          elsif Ekind (Formal) = E_In_Out_Parameter then
1089             Generate_Reference (E, Formal, '=', False);
1090
1091          else
1092             Generate_Reference (E, Formal, '<', False);
1093          end if;
1094
1095          Next_Formal (Formal);
1096       end loop;
1097    end Generate_Reference_To_Formals;
1098
1099    -------------------------------------------
1100    -- Generate_Reference_To_Generic_Formals --
1101    -------------------------------------------
1102
1103    procedure Generate_Reference_To_Generic_Formals (E : Entity_Id) is
1104       Formal : Entity_Id;
1105
1106    begin
1107       Formal := First_Entity (E);
1108       while Present (Formal) loop
1109          if Comes_From_Source (Formal) then
1110             Generate_Reference (E, Formal, 'z', False);
1111          end if;
1112
1113          Next_Entity (Formal);
1114       end loop;
1115    end Generate_Reference_To_Generic_Formals;
1116
1117    -------------
1118    -- Get_Key --
1119    -------------
1120
1121    function Get_Key (E : Xref_Entry_Number) return Xref_Entry_Number is
1122    begin
1123       return E;
1124    end Get_Key;
1125
1126    ----------
1127    -- Hash --
1128    ----------
1129
1130    function Hash (F : Xref_Entry_Number) return Header_Num is
1131       --  It is unlikely to have two references to the same entity at the same
1132       --  source location, so the hash function depends only on the Ent and Loc
1133       --  fields.
1134
1135       XE : Xref_Entry renames Xrefs.Table (F);
1136       type M is mod 2**32;
1137
1138       H : constant M := M (XE.Key.Ent) + 2 ** 7 * M (abs XE.Key.Loc);
1139       --  It would be more natural to write:
1140       --
1141       --    H : constant M := M'Mod (XE.Key.Ent) + 2**7 * M'Mod (XE.Key.Loc);
1142       --
1143       --  But we can't use M'Mod, because it prevents bootstrapping with older
1144       --  compilers. Loc can be negative, so we do "abs" before converting.
1145       --  One day this can be cleaned up ???
1146
1147    begin
1148       return Header_Num (H mod Num_Buckets);
1149    end Hash;
1150
1151    -----------------
1152    -- HT_Set_Next --
1153    -----------------
1154
1155    procedure HT_Set_Next (E : Xref_Entry_Number; Next : Xref_Entry_Number) is
1156    begin
1157       Xrefs.Table (E).HTable_Next := Next;
1158    end HT_Set_Next;
1159
1160    -------------
1161    -- HT_Next --
1162    -------------
1163
1164    function HT_Next (E : Xref_Entry_Number) return Xref_Entry_Number is
1165    begin
1166       return Xrefs.Table (E).HTable_Next;
1167    end HT_Next;
1168
1169    ----------------
1170    -- Initialize --
1171    ----------------
1172
1173    procedure Initialize is
1174    begin
1175       Xrefs.Init;
1176    end Initialize;
1177
1178    --------
1179    -- Lt --
1180    --------
1181
1182    function Lt (T1, T2 : Xref_Entry) return Boolean is
1183    begin
1184       --  First test: if entity is in different unit, sort by unit
1185
1186       if T1.Key.Eun /= T2.Key.Eun then
1187          return Dependency_Num (T1.Key.Eun) < Dependency_Num (T2.Key.Eun);
1188
1189       --  Second test: within same unit, sort by entity Sloc
1190
1191       elsif T1.Def /= T2.Def then
1192          return T1.Def < T2.Def;
1193
1194       --  Third test: sort definitions ahead of references
1195
1196       elsif T1.Key.Loc = No_Location then
1197          return True;
1198
1199       elsif T2.Key.Loc = No_Location then
1200          return False;
1201
1202       --  Fourth test: for same entity, sort by reference location unit
1203
1204       elsif T1.Key.Lun /= T2.Key.Lun then
1205          return Dependency_Num (T1.Key.Lun) < Dependency_Num (T2.Key.Lun);
1206
1207       --  Fifth test: order of location within referencing unit
1208
1209       elsif T1.Key.Loc /= T2.Key.Loc then
1210          return T1.Key.Loc < T2.Key.Loc;
1211
1212       --  Finally, for two locations at the same address, we prefer
1213       --  the one that does NOT have the type 'r' so that a modification
1214       --  or extension takes preference, when there are more than one
1215       --  reference at the same location. As a result, in the case of
1216       --  entities that are in-out actuals, the read reference follows
1217       --  the modify reference.
1218
1219       else
1220          return T2.Key.Typ = 'r';
1221       end if;
1222    end Lt;
1223
1224    -----------------------
1225    -- Output_References --
1226    -----------------------
1227
1228    procedure Output_References is
1229
1230       procedure Get_Type_Reference
1231         (Ent   : Entity_Id;
1232          Tref  : out Entity_Id;
1233          Left  : out Character;
1234          Right : out Character);
1235       --  Given an Entity_Id Ent, determines whether a type reference is
1236       --  required. If so, Tref is set to the entity for the type reference
1237       --  and Left and Right are set to the left/right brackets to be output
1238       --  for the reference. If no type reference is required, then Tref is
1239       --  set to Empty, and Left/Right are set to space.
1240
1241       procedure Output_Import_Export_Info (Ent : Entity_Id);
1242       --  Output language and external name information for an interfaced
1243       --  entity, using the format <language, external_name>.
1244
1245       ------------------------
1246       -- Get_Type_Reference --
1247       ------------------------
1248
1249       procedure Get_Type_Reference
1250         (Ent   : Entity_Id;
1251          Tref  : out Entity_Id;
1252          Left  : out Character;
1253          Right : out Character)
1254       is
1255          Sav : Entity_Id;
1256
1257       begin
1258          --  See if we have a type reference
1259
1260          Tref := Ent;
1261          Left := '{';
1262          Right := '}';
1263
1264          loop
1265             Sav := Tref;
1266
1267             --  Processing for types
1268
1269             if Is_Type (Tref) then
1270
1271                --  Case of base type
1272
1273                if Base_Type (Tref) = Tref then
1274
1275                   --  If derived, then get first subtype
1276
1277                   if Tref /= Etype (Tref) then
1278                      Tref := First_Subtype (Etype (Tref));
1279
1280                      --  Set brackets for derived type, but don't override
1281                      --  pointer case since the fact that something is a
1282                      --  pointer is more important.
1283
1284                      if Left /= '(' then
1285                         Left := '<';
1286                         Right := '>';
1287                      end if;
1288
1289                   --  If non-derived ptr, get directly designated type.
1290                   --  If the type has a full view, all references are on the
1291                   --  partial view, that is seen first.
1292
1293                   elsif Is_Access_Type (Tref) then
1294                      Tref := Directly_Designated_Type (Tref);
1295                      Left := '(';
1296                      Right := ')';
1297
1298                   elsif Is_Private_Type (Tref)
1299                     and then Present (Full_View (Tref))
1300                   then
1301                      if Is_Access_Type (Full_View (Tref)) then
1302                         Tref := Directly_Designated_Type (Full_View (Tref));
1303                         Left := '(';
1304                         Right := ')';
1305
1306                      --  If the full view is an array type, we also retrieve
1307                      --  the corresponding component type, because the ali
1308                      --  entry already indicates that this is an array.
1309
1310                      elsif Is_Array_Type (Full_View (Tref)) then
1311                         Tref := Component_Type (Full_View (Tref));
1312                         Left := '(';
1313                         Right := ')';
1314                      end if;
1315
1316                   --  If non-derived array, get component type. Skip component
1317                   --  type for case of String or Wide_String, saves worthwhile
1318                   --  space.
1319
1320                   elsif Is_Array_Type (Tref)
1321                     and then Tref /= Standard_String
1322                     and then Tref /= Standard_Wide_String
1323                   then
1324                      Tref := Component_Type (Tref);
1325                      Left := '(';
1326                      Right := ')';
1327
1328                   --  For other non-derived base types, nothing
1329
1330                   else
1331                      exit;
1332                   end if;
1333
1334                --  For a subtype, go to ancestor subtype
1335
1336                else
1337                   Tref := Ancestor_Subtype (Tref);
1338
1339                   --  If no ancestor subtype, go to base type
1340
1341                   if No (Tref) then
1342                      Tref := Base_Type (Sav);
1343                   end if;
1344                end if;
1345
1346             --  For objects, functions, enum literals, just get type from
1347             --  Etype field.
1348
1349             elsif Is_Object (Tref)
1350               or else Ekind (Tref) = E_Enumeration_Literal
1351               or else Ekind (Tref) = E_Function
1352               or else Ekind (Tref) = E_Operator
1353             then
1354                Tref := Etype (Tref);
1355
1356             --  For anything else, exit
1357
1358             else
1359                exit;
1360             end if;
1361
1362             --  Exit if no type reference, or we are stuck in some loop trying
1363             --  to find the type reference, or if the type is standard void
1364             --  type (the latter is an implementation artifact that should not
1365             --  show up in the generated cross-references).
1366
1367             exit when No (Tref)
1368               or else Tref = Sav
1369               or else Tref = Standard_Void_Type;
1370
1371             --  If we have a usable type reference, return, otherwise keep
1372             --  looking for something useful (we are looking for something
1373             --  that either comes from source or standard)
1374
1375             if Sloc (Tref) = Standard_Location
1376               or else Comes_From_Source (Tref)
1377             then
1378                --  If the reference is a subtype created for a generic actual,
1379                --  go actual directly, the inner subtype is not user visible.
1380
1381                if Nkind (Parent (Tref)) = N_Subtype_Declaration
1382                  and then not Comes_From_Source (Parent (Tref))
1383                  and then
1384                   (Is_Wrapper_Package (Scope (Tref))
1385                      or else Is_Generic_Instance (Scope (Tref)))
1386                then
1387                   Tref := First_Subtype (Base_Type (Tref));
1388                end if;
1389
1390                return;
1391             end if;
1392          end loop;
1393
1394          --  If we fall through the loop, no type reference
1395
1396          Tref := Empty;
1397          Left := ' ';
1398          Right := ' ';
1399       end Get_Type_Reference;
1400
1401       -------------------------------
1402       -- Output_Import_Export_Info --
1403       -------------------------------
1404
1405       procedure Output_Import_Export_Info (Ent : Entity_Id) is
1406          Language_Name : Name_Id;
1407          Conv          : constant Convention_Id := Convention (Ent);
1408
1409       begin
1410          --  Generate language name from convention
1411
1412          if Conv  = Convention_C then
1413             Language_Name := Name_C;
1414
1415          elsif Conv = Convention_CPP then
1416             Language_Name := Name_CPP;
1417
1418          elsif Conv = Convention_Ada then
1419             Language_Name := Name_Ada;
1420
1421          else
1422             --  For the moment we ignore all other cases ???
1423
1424             return;
1425          end if;
1426
1427          Write_Info_Char ('<');
1428          Get_Unqualified_Name_String (Language_Name);
1429
1430          for J in 1 .. Name_Len loop
1431             Write_Info_Char (Name_Buffer (J));
1432          end loop;
1433
1434          if Present (Interface_Name (Ent)) then
1435             Write_Info_Char (',');
1436             String_To_Name_Buffer (Strval (Interface_Name (Ent)));
1437
1438             for J in 1 .. Name_Len loop
1439                Write_Info_Char (Name_Buffer (J));
1440             end loop;
1441          end if;
1442
1443          Write_Info_Char ('>');
1444       end Output_Import_Export_Info;
1445
1446    --  Start of processing for Output_References
1447
1448    begin
1449       --  First we add references to the primitive operations of tagged types
1450       --  declared in the main unit.
1451
1452       Handle_Prim_Ops : declare
1453          Ent  : Entity_Id;
1454
1455       begin
1456          for J in 1 .. Xrefs.Last loop
1457             Ent := Xrefs.Table (J).Key.Ent;
1458
1459             if Is_Type (Ent)
1460               and then Is_Tagged_Type (Ent)
1461               and then Is_Base_Type (Ent)
1462               and then In_Extended_Main_Source_Unit (Ent)
1463             then
1464                Generate_Prim_Op_References (Ent);
1465             end if;
1466          end loop;
1467       end Handle_Prim_Ops;
1468
1469       --  Before we go ahead and output the references we have a problem
1470       --  that needs dealing with. So far we have captured things that are
1471       --  definitely referenced by the main unit, or defined in the main
1472       --  unit. That's because we don't want to clutter up the ali file
1473       --  for this unit with definition lines for entities in other units
1474       --  that are not referenced.
1475
1476       --  But there is a glitch. We may reference an entity in another unit,
1477       --  and it may have a type reference to an entity that is not directly
1478       --  referenced in the main unit, which may mean that there is no xref
1479       --  entry for this entity yet in the list of references.
1480
1481       --  If we don't do something about this, we will end with an orphan type
1482       --  reference, i.e. it will point to an entity that does not appear
1483       --  within the generated references in the ali file. That is not good for
1484       --  tools using the xref information.
1485
1486       --  To fix this, we go through the references adding definition entries
1487       --  for any unreferenced entities that can be referenced in a type
1488       --  reference. There is a recursion problem here, and that is dealt with
1489       --  by making sure that this traversal also traverses any entries that
1490       --  get added by the traversal.
1491
1492       Handle_Orphan_Type_References : declare
1493          J    : Nat;
1494          Tref : Entity_Id;
1495          Ent  : Entity_Id;
1496
1497          L, R : Character;
1498          pragma Warnings (Off, L);
1499          pragma Warnings (Off, R);
1500
1501          procedure New_Entry (E : Entity_Id);
1502          --  Make an additional entry into the Xref table for a type entity
1503          --  that is related to the current entity (parent, type ancestor,
1504          --  progenitor, etc.).
1505
1506          ----------------
1507          -- New_Entry --
1508          ----------------
1509
1510          procedure New_Entry (E : Entity_Id) is
1511          begin
1512             pragma Assert (Present (E));
1513
1514             if not Has_Xref_Entry (Implementation_Base_Type (E))
1515               and then Sloc (E) > No_Location
1516             then
1517                Add_Entry
1518                  ((Ent => E,
1519                    Loc => No_Location,
1520                    Typ => Character'First,
1521                    Eun => Get_Source_Unit (Original_Location (Sloc (E))),
1522                    Lun => No_Unit,
1523                    Ref_Scope => Empty,
1524                    Ent_Scope => Empty),
1525                   Ent_Scope_File => No_Unit);
1526             end if;
1527          end New_Entry;
1528
1529       --  Start of processing for Handle_Orphan_Type_References
1530
1531       begin
1532          --  Note that this is not a for loop for a very good reason. The
1533          --  processing of items in the table can add new items to the table,
1534          --  and they must be processed as well.
1535
1536          J := 1;
1537          while J <= Xrefs.Last loop
1538             Ent := Xrefs.Table (J).Key.Ent;
1539             Get_Type_Reference (Ent, Tref, L, R);
1540
1541             if Present (Tref)
1542               and then not Has_Xref_Entry (Tref)
1543               and then Sloc (Tref) > No_Location
1544             then
1545                New_Entry (Tref);
1546
1547                if Is_Record_Type (Ent)
1548                  and then Present (Interfaces (Ent))
1549                then
1550                   --  Add an entry for each one of the given interfaces
1551                   --  implemented by type Ent.
1552
1553                   declare
1554                      Elmt : Elmt_Id := First_Elmt (Interfaces (Ent));
1555                   begin
1556                      while Present (Elmt) loop
1557                         New_Entry (Node (Elmt));
1558                         Next_Elmt (Elmt);
1559                      end loop;
1560                   end;
1561                end if;
1562             end if;
1563
1564             --  Collect inherited primitive operations that may be declared in
1565             --  another unit and have no visible reference in the current one.
1566
1567             if Is_Type (Ent)
1568               and then Is_Tagged_Type (Ent)
1569               and then Is_Derived_Type (Ent)
1570               and then Is_Base_Type (Ent)
1571               and then In_Extended_Main_Source_Unit (Ent)
1572             then
1573                declare
1574                   Op_List : constant Elist_Id := Primitive_Operations (Ent);
1575                   Op      : Elmt_Id;
1576                   Prim    : Entity_Id;
1577
1578                   function Parent_Op (E : Entity_Id) return Entity_Id;
1579                   --  Find original operation, which may be inherited through
1580                   --  several derivations.
1581
1582                   function Parent_Op (E : Entity_Id) return Entity_Id is
1583                      Orig_Op : constant Entity_Id := Alias (E);
1584
1585                   begin
1586                      if No (Orig_Op) then
1587                         return Empty;
1588
1589                      elsif not Comes_From_Source (E)
1590                        and then not Has_Xref_Entry (Orig_Op)
1591                        and then Comes_From_Source (Orig_Op)
1592                      then
1593                         return Orig_Op;
1594                      else
1595                         return Parent_Op (Orig_Op);
1596                      end if;
1597                   end Parent_Op;
1598
1599                begin
1600                   Op := First_Elmt (Op_List);
1601                   while Present (Op) loop
1602                      Prim := Parent_Op (Node (Op));
1603
1604                      if Present (Prim) then
1605                         Add_Entry
1606                           ((Ent => Prim,
1607                             Loc => No_Location,
1608                             Typ => Character'First,
1609                             Eun => Get_Source_Unit (Sloc (Prim)),
1610                             Lun => No_Unit,
1611                             Ref_Scope => Empty,
1612                             Ent_Scope => Empty),
1613                            Ent_Scope_File => No_Unit);
1614                      end if;
1615
1616                      Next_Elmt (Op);
1617                   end loop;
1618                end;
1619             end if;
1620
1621             J := J + 1;
1622          end loop;
1623       end Handle_Orphan_Type_References;
1624
1625       --  Now we have all the references, including those for any embedded
1626       --  type references, so we can sort them, and output them.
1627
1628       Output_Refs : declare
1629
1630          Nrefs : constant Nat := Xrefs.Last;
1631          --  Number of references in table
1632
1633          Rnums : array (0 .. Nrefs) of Nat;
1634          --  This array contains numbers of references in the Xrefs table.
1635          --  This list is sorted in output order. The extra 0'th entry is
1636          --  convenient for the call to sort. When we sort the table, we
1637          --  move the entries in Rnums around, but we do not move the
1638          --  original table entries.
1639
1640          Curxu : Unit_Number_Type;
1641          --  Current xref unit
1642
1643          Curru : Unit_Number_Type;
1644          --  Current reference unit for one entity
1645
1646          Curent : Entity_Id;
1647          --  Current entity
1648
1649          Curnam : String (1 .. Name_Buffer'Length);
1650          Curlen : Natural;
1651          --  Simple name and length of current entity
1652
1653          Curdef : Source_Ptr;
1654          --  Original source location for current entity
1655
1656          Crloc : Source_Ptr;
1657          --  Current reference location
1658
1659          Ctyp : Character;
1660          --  Entity type character
1661
1662          Prevt : Character;
1663          --  reference kind of previous reference
1664
1665          Tref : Entity_Id;
1666          --  Type reference
1667
1668          Rref : Node_Id;
1669          --  Renaming reference
1670
1671          Trunit : Unit_Number_Type;
1672          --  Unit number for type reference
1673
1674          function Lt (Op1, Op2 : Natural) return Boolean;
1675          --  Comparison function for Sort call
1676
1677          function Name_Change (X : Entity_Id) return Boolean;
1678          --  Determines if entity X has a different simple name from Curent
1679
1680          procedure Move (From : Natural; To : Natural);
1681          --  Move procedure for Sort call
1682
1683          package Sorting is new GNAT.Heap_Sort_G (Move, Lt);
1684
1685          --------
1686          -- Lt --
1687          --------
1688
1689          function Lt (Op1, Op2 : Natural) return Boolean is
1690             T1 : Xref_Entry renames Xrefs.Table (Rnums (Nat (Op1)));
1691             T2 : Xref_Entry renames Xrefs.Table (Rnums (Nat (Op2)));
1692
1693          begin
1694             return Lt (T1, T2);
1695          end Lt;
1696
1697          ----------
1698          -- Move --
1699          ----------
1700
1701          procedure Move (From : Natural; To : Natural) is
1702          begin
1703             Rnums (Nat (To)) := Rnums (Nat (From));
1704          end Move;
1705
1706          -----------------
1707          -- Name_Change --
1708          -----------------
1709
1710          --  Why a string comparison here??? Why not compare Name_Id values???
1711
1712          function Name_Change (X : Entity_Id) return Boolean is
1713          begin
1714             Get_Unqualified_Name_String (Chars (X));
1715
1716             if Name_Len /= Curlen then
1717                return True;
1718             else
1719                return Name_Buffer (1 .. Curlen) /= Curnam (1 .. Curlen);
1720             end if;
1721          end Name_Change;
1722
1723       --  Start of processing for Output_Refs
1724
1725       begin
1726          --  Capture the definition Sloc values. We delay doing this till now,
1727          --  since at the time the reference or definition is made, private
1728          --  types may be swapped, and the Sloc value may be incorrect. We
1729          --  also set up the pointer vector for the sort.
1730          --  For user-defined operators we need to skip the initial
1731          --  quote and point to the first character of the name, for
1732          --  navigation purposes.
1733
1734          for J in 1 .. Nrefs loop
1735             declare
1736                E   : constant Entity_Id  := Xrefs.Table (J).Key.Ent;
1737                Loc : constant Source_Ptr := Original_Location (Sloc (E));
1738
1739             begin
1740                Rnums (J) := J;
1741
1742                if Nkind (E) = N_Defining_Operator_Symbol then
1743                   Xrefs.Table (J).Def := Loc + 1;
1744                else
1745                   Xrefs.Table (J).Def := Loc;
1746                end if;
1747             end;
1748          end loop;
1749
1750          --  Sort the references
1751
1752          Sorting.Sort (Integer (Nrefs));
1753
1754          --  Initialize loop through references
1755
1756          Curxu  := No_Unit;
1757          Curent := Empty;
1758          Curdef := No_Location;
1759          Curru  := No_Unit;
1760          Crloc  := No_Location;
1761          Prevt  := 'm';
1762
1763          --  Loop to output references
1764
1765          for Refno in 1 .. Nrefs loop
1766             Output_One_Ref : declare
1767                Ent : Entity_Id;
1768
1769                XE : Xref_Entry renames Xrefs.Table (Rnums (Refno));
1770                --  The current entry to be accessed
1771
1772                Left  : Character;
1773                Right : Character;
1774                --  Used for {} or <> or () for type reference
1775
1776                procedure Check_Type_Reference
1777                  (Ent            : Entity_Id;
1778                   List_Interface : Boolean);
1779                --  Find whether there is a meaningful type reference for
1780                --  Ent, and display it accordingly. If List_Interface is
1781                --  true, then Ent is a progenitor interface of the current
1782                --  type entity being listed. In that case list it as is,
1783                --  without looking for a type reference for it.
1784
1785                procedure Output_Instantiation_Refs (Loc : Source_Ptr);
1786                --  Recursive procedure to output instantiation references for
1787                --  the given source ptr in [file|line[...]] form. No output
1788                --  if the given location is not a generic template reference.
1789
1790                procedure Output_Overridden_Op (Old_E : Entity_Id);
1791                --  For a subprogram that is overriding, display information
1792                --  about the inherited operation that it overrides.
1793
1794                --------------------------
1795                -- Check_Type_Reference --
1796                --------------------------
1797
1798                procedure Check_Type_Reference
1799                  (Ent            : Entity_Id;
1800                   List_Interface : Boolean)
1801                is
1802                begin
1803                   if List_Interface then
1804
1805                      --  This is a progenitor interface of the type for which
1806                      --  xref information is being generated.
1807
1808                      Tref  := Ent;
1809                      Left  := '<';
1810                      Right := '>';
1811
1812                   else
1813                      Get_Type_Reference (Ent, Tref, Left, Right);
1814                   end if;
1815
1816                   if Present (Tref) then
1817
1818                      --  Case of standard entity, output name
1819
1820                      if Sloc (Tref) = Standard_Location then
1821                         Write_Info_Char (Left);
1822                         Write_Info_Name (Chars (Tref));
1823                         Write_Info_Char (Right);
1824
1825                      --  Case of source entity, output location
1826
1827                      else
1828                         Write_Info_Char (Left);
1829                         Trunit := Get_Source_Unit (Sloc (Tref));
1830
1831                         if Trunit /= Curxu then
1832                            Write_Info_Nat (Dependency_Num (Trunit));
1833                            Write_Info_Char ('|');
1834                         end if;
1835
1836                         Write_Info_Nat
1837                           (Int (Get_Logical_Line_Number (Sloc (Tref))));
1838
1839                         declare
1840                            Ent  : Entity_Id;
1841                            Ctyp : Character;
1842
1843                         begin
1844                            Ent := Tref;
1845                            Ctyp := Xref_Entity_Letters (Ekind (Ent));
1846
1847                            if Ctyp = '+'
1848                              and then Present (Full_View (Ent))
1849                            then
1850                               Ent := Underlying_Type (Ent);
1851
1852                               if Present (Ent) then
1853                                  Ctyp := Xref_Entity_Letters (Ekind (Ent));
1854                               end if;
1855                            end if;
1856
1857                            Write_Info_Char (Ctyp);
1858                         end;
1859
1860                         Write_Info_Nat
1861                           (Int (Get_Column_Number (Sloc (Tref))));
1862
1863                         --  If the type comes from an instantiation, add the
1864                         --  corresponding info.
1865
1866                         Output_Instantiation_Refs (Sloc (Tref));
1867                         Write_Info_Char (Right);
1868                      end if;
1869                   end if;
1870                end Check_Type_Reference;
1871
1872                -------------------------------
1873                -- Output_Instantiation_Refs --
1874                -------------------------------
1875
1876                procedure Output_Instantiation_Refs (Loc : Source_Ptr) is
1877                   Iloc : constant Source_Ptr := Instantiation_Location (Loc);
1878                   Lun  : Unit_Number_Type;
1879                   Cu   : constant Unit_Number_Type := Curru;
1880
1881                begin
1882                   --  Nothing to do if this is not an instantiation
1883
1884                   if Iloc = No_Location then
1885                      return;
1886                   end if;
1887
1888                   --  Output instantiation reference
1889
1890                   Write_Info_Char ('[');
1891                   Lun := Get_Source_Unit (Iloc);
1892
1893                   if Lun /= Curru then
1894                      Curru := Lun;
1895                      Write_Info_Nat (Dependency_Num (Curru));
1896                      Write_Info_Char ('|');
1897                   end if;
1898
1899                   Write_Info_Nat (Int (Get_Logical_Line_Number (Iloc)));
1900
1901                   --  Recursive call to get nested instantiations
1902
1903                   Output_Instantiation_Refs (Iloc);
1904
1905                   --  Output final ] after call to get proper nesting
1906
1907                   Write_Info_Char (']');
1908                   Curru := Cu;
1909                   return;
1910                end Output_Instantiation_Refs;
1911
1912                --------------------------
1913                -- Output_Overridden_Op --
1914                --------------------------
1915
1916                procedure Output_Overridden_Op (Old_E : Entity_Id) is
1917                   Op : Entity_Id;
1918
1919                begin
1920                   --  The overridden operation has an implicit declaration
1921                   --  at the point of derivation. What we want to display
1922                   --  is the original operation, which has the actual body
1923                   --  (or abstract declaration) that is being overridden.
1924                   --  The overridden operation is not always set, e.g. when
1925                   --  it is a predefined operator.
1926
1927                   if No (Old_E) then
1928                      return;
1929
1930                   --  Follow alias chain if one is present
1931
1932                   elsif Present (Alias (Old_E)) then
1933
1934                      --  The subprogram may have been implicitly inherited
1935                      --  through several levels of derivation, so find the
1936                      --  ultimate (source) ancestor.
1937
1938                      Op := Ultimate_Alias (Old_E);
1939
1940                   --  Normal case of no alias present. We omit generated
1941                   --  primitives like tagged equality, that have no source
1942                   --  representation.
1943
1944                   else
1945                      Op := Old_E;
1946                   end if;
1947
1948                   if Present (Op)
1949                     and then Sloc (Op) /= Standard_Location
1950                     and then Comes_From_Source (Op)
1951                   then
1952                      declare
1953                         Loc      : constant Source_Ptr := Sloc (Op);
1954                         Par_Unit : constant Unit_Number_Type :=
1955                                      Get_Source_Unit (Loc);
1956
1957                      begin
1958                         Write_Info_Char ('<');
1959
1960                         if Par_Unit /= Curxu then
1961                            Write_Info_Nat (Dependency_Num (Par_Unit));
1962                            Write_Info_Char ('|');
1963                         end if;
1964
1965                         Write_Info_Nat (Int (Get_Logical_Line_Number (Loc)));
1966                         Write_Info_Char ('p');
1967                         Write_Info_Nat (Int (Get_Column_Number (Loc)));
1968                         Write_Info_Char ('>');
1969                      end;
1970                   end if;
1971                end Output_Overridden_Op;
1972
1973             --  Start of processing for Output_One_Ref
1974
1975             begin
1976                Ent := XE.Key.Ent;
1977                Ctyp := Xref_Entity_Letters (Ekind (Ent));
1978
1979                --  Skip reference if it is the only reference to an entity,
1980                --  and it is an END line reference, and the entity is not in
1981                --  the current extended source. This prevents junk entries
1982                --  consisting only of packages with END lines, where no
1983                --  entity from the package is actually referenced.
1984
1985                if XE.Key.Typ = 'e'
1986                  and then Ent /= Curent
1987                  and then (Refno = Nrefs
1988                             or else
1989                               Ent /= Xrefs.Table (Rnums (Refno + 1)).Key.Ent)
1990                  and then not In_Extended_Main_Source_Unit (Ent)
1991                then
1992                   goto Continue;
1993                end if;
1994
1995                --  For private type, get full view type
1996
1997                if Ctyp = '+'
1998                  and then Present (Full_View (XE.Key.Ent))
1999                then
2000                   Ent := Underlying_Type (Ent);
2001
2002                   if Present (Ent) then
2003                      Ctyp := Xref_Entity_Letters (Ekind (Ent));
2004                   end if;
2005                end if;
2006
2007                --  Special exception for Boolean
2008
2009                if Ctyp = 'E' and then Is_Boolean_Type (Ent) then
2010                   Ctyp := 'B';
2011                end if;
2012
2013                --  For variable reference, get corresponding type
2014
2015                if Ctyp = '*' then
2016                   Ent := Etype (XE.Key.Ent);
2017                   Ctyp := Fold_Lower (Xref_Entity_Letters (Ekind (Ent)));
2018
2019                   --  If variable is private type, get full view type
2020
2021                   if Ctyp = '+'
2022                     and then Present (Full_View (Etype (XE.Key.Ent)))
2023                   then
2024                      Ent := Underlying_Type (Etype (XE.Key.Ent));
2025
2026                      if Present (Ent) then
2027                         Ctyp := Fold_Lower (Xref_Entity_Letters (Ekind (Ent)));
2028                      end if;
2029
2030                   elsif Is_Generic_Type (Ent) then
2031
2032                      --  If the type of the entity is a generic private type,
2033                      --  there is no usable full view, so retain the indication
2034                      --  that this is an object.
2035
2036                      Ctyp := '*';
2037                   end if;
2038
2039                   --  Special handling for access parameters and objects of
2040                   --  an anonymous access type.
2041
2042                   if Ekind_In (Etype (XE.Key.Ent),
2043                                E_Anonymous_Access_Type,
2044                                E_Anonymous_Access_Subprogram_Type,
2045                                E_Anonymous_Access_Protected_Subprogram_Type)
2046                   then
2047                      if Is_Formal (XE.Key.Ent)
2048                        or else Ekind_In (XE.Key.Ent, E_Variable, E_Constant)
2049                      then
2050                         Ctyp := 'p';
2051                      end if;
2052
2053                      --  Special handling for Boolean
2054
2055                   elsif Ctyp = 'e' and then Is_Boolean_Type (Ent) then
2056                      Ctyp := 'b';
2057                   end if;
2058                end if;
2059
2060                --  Special handling for abstract types and operations
2061
2062                if Is_Overloadable (XE.Key.Ent)
2063                  and then Is_Abstract_Subprogram (XE.Key.Ent)
2064                then
2065                   if Ctyp = 'U' then
2066                      Ctyp := 'x';            --  Abstract procedure
2067
2068                   elsif Ctyp = 'V' then
2069                      Ctyp := 'y';            --  Abstract function
2070                   end if;
2071
2072                elsif Is_Type (XE.Key.Ent)
2073                  and then Is_Abstract_Type (XE.Key.Ent)
2074                then
2075                   if Is_Interface (XE.Key.Ent) then
2076                      Ctyp := 'h';
2077
2078                   elsif Ctyp = 'R' then
2079                      Ctyp := 'H';            --  Abstract type
2080                   end if;
2081                end if;
2082
2083                --  Only output reference if interesting type of entity
2084
2085                if Ctyp = ' '
2086
2087                --  Suppress references to object definitions, used for local
2088                --  references.
2089
2090                  or else XE.Key.Typ = 'D'
2091                  or else XE.Key.Typ = 'I'
2092
2093                --  Suppress self references, except for bodies that act as
2094                --  specs.
2095
2096                  or else (XE.Key.Loc = XE.Def
2097                            and then
2098                              (XE.Key.Typ /= 'b'
2099                                or else not Is_Subprogram (XE.Key.Ent)))
2100
2101                --  Also suppress definitions of body formals (we only
2102                --  treat these as references, and the references were
2103                --  separately recorded).
2104
2105                  or else (Is_Formal (XE.Key.Ent)
2106                            and then Present (Spec_Entity (XE.Key.Ent)))
2107                then
2108                   null;
2109
2110                else
2111                   --  Start new Xref section if new xref unit
2112
2113                   if XE.Key.Eun /= Curxu then
2114                      if Write_Info_Col > 1 then
2115                         Write_Info_EOL;
2116                      end if;
2117
2118                      Curxu := XE.Key.Eun;
2119
2120                      Write_Info_Initiate ('X');
2121                      Write_Info_Char (' ');
2122                      Write_Info_Nat (Dependency_Num (XE.Key.Eun));
2123                      Write_Info_Char (' ');
2124                      Write_Info_Name
2125                        (Reference_Name (Source_Index (XE.Key.Eun)));
2126                   end if;
2127
2128                   --  Start new Entity line if new entity. Note that we
2129                   --  consider two entities the same if they have the same
2130                   --  name and source location. This causes entities in
2131                   --  instantiations to be treated as though they referred
2132                   --  to the template.
2133
2134                   if No (Curent)
2135                     or else
2136                       (XE.Key.Ent /= Curent
2137                          and then
2138                            (Name_Change (XE.Key.Ent) or else XE.Def /= Curdef))
2139                   then
2140                      Curent := XE.Key.Ent;
2141                      Curdef := XE.Def;
2142
2143                      Get_Unqualified_Name_String (Chars (XE.Key.Ent));
2144                      Curlen := Name_Len;
2145                      Curnam (1 .. Curlen) := Name_Buffer (1 .. Curlen);
2146
2147                      if Write_Info_Col > 1 then
2148                         Write_Info_EOL;
2149                      end if;
2150
2151                      --  Write column number information
2152
2153                      Write_Info_Nat (Int (Get_Logical_Line_Number (XE.Def)));
2154                      Write_Info_Char (Ctyp);
2155                      Write_Info_Nat (Int (Get_Column_Number (XE.Def)));
2156
2157                      --  Write level information
2158
2159                      Write_Level_Info : declare
2160                         function Is_Visible_Generic_Entity
2161                           (E : Entity_Id) return Boolean;
2162                         --  Check whether E is declared in the visible part
2163                         --  of a generic package. For source navigation
2164                         --  purposes, treat this as a visible entity.
2165
2166                         function Is_Private_Record_Component
2167                           (E : Entity_Id) return Boolean;
2168                         --  Check whether E is a non-inherited component of a
2169                         --  private extension. Even if the enclosing record is
2170                         --  public, we want to treat the component as private
2171                         --  for navigation purposes.
2172
2173                         ---------------------------------
2174                         -- Is_Private_Record_Component --
2175                         ---------------------------------
2176
2177                         function Is_Private_Record_Component
2178                           (E : Entity_Id) return Boolean
2179                         is
2180                            S : constant Entity_Id := Scope (E);
2181                         begin
2182                            return
2183                              Ekind (E) = E_Component
2184                                and then Nkind (Declaration_Node (S)) =
2185                                  N_Private_Extension_Declaration
2186                                and then Original_Record_Component (E) = E;
2187                         end Is_Private_Record_Component;
2188
2189                         -------------------------------
2190                         -- Is_Visible_Generic_Entity --
2191                         -------------------------------
2192
2193                         function Is_Visible_Generic_Entity
2194                           (E : Entity_Id) return Boolean
2195                         is
2196                            Par : Node_Id;
2197
2198                         begin
2199                            --  The Present check here is an error defense
2200
2201                            if Present (Scope (E))
2202                              and then Ekind (Scope (E)) /= E_Generic_Package
2203                            then
2204                               return False;
2205                            end if;
2206
2207                            Par := Parent (E);
2208                            while Present (Par) loop
2209                               if
2210                                 Nkind (Par) = N_Generic_Package_Declaration
2211                               then
2212                                  --  Entity is a generic formal
2213
2214                                  return False;
2215
2216                               elsif
2217                                 Nkind (Parent (Par)) = N_Package_Specification
2218                               then
2219                                  return
2220                                    Is_List_Member (Par)
2221                                      and then List_Containing (Par) =
2222                                        Visible_Declarations (Parent (Par));
2223                               else
2224                                  Par := Parent (Par);
2225                               end if;
2226                            end loop;
2227
2228                            return False;
2229                         end Is_Visible_Generic_Entity;
2230
2231                      --  Start of processing for Write_Level_Info
2232
2233                      begin
2234                         if Is_Hidden (Curent)
2235                           or else Is_Private_Record_Component (Curent)
2236                         then
2237                            Write_Info_Char (' ');
2238
2239                         elsif
2240                            Is_Public (Curent)
2241                              or else Is_Visible_Generic_Entity (Curent)
2242                         then
2243                            Write_Info_Char ('*');
2244
2245                         else
2246                            Write_Info_Char (' ');
2247                         end if;
2248                      end Write_Level_Info;
2249
2250                      --  Output entity name. We use the occurrence from the
2251                      --  actual source program at the definition point.
2252
2253                      declare
2254                         Ent_Name : constant String :=
2255                                      Exact_Source_Name (Sloc (XE.Key.Ent));
2256                      begin
2257                         for C in Ent_Name'Range loop
2258                            Write_Info_Char (Ent_Name (C));
2259                         end loop;
2260                      end;
2261
2262                      --  See if we have a renaming reference
2263
2264                      if Is_Object (XE.Key.Ent)
2265                        and then Present (Renamed_Object (XE.Key.Ent))
2266                      then
2267                         Rref := Renamed_Object (XE.Key.Ent);
2268
2269                      elsif Is_Overloadable (XE.Key.Ent)
2270                        and then Nkind (Parent (Declaration_Node (XE.Key.Ent)))
2271                                            = N_Subprogram_Renaming_Declaration
2272                      then
2273                         Rref := Name (Parent (Declaration_Node (XE.Key.Ent)));
2274
2275                      elsif Ekind (XE.Key.Ent) = E_Package
2276                        and then Nkind (Declaration_Node (XE.Key.Ent)) =
2277                                          N_Package_Renaming_Declaration
2278                      then
2279                         Rref := Name (Declaration_Node (XE.Key.Ent));
2280
2281                      else
2282                         Rref := Empty;
2283                      end if;
2284
2285                      if Present (Rref) then
2286                         if Nkind (Rref) = N_Expanded_Name then
2287                            Rref := Selector_Name (Rref);
2288                         end if;
2289
2290                         if Nkind (Rref) = N_Identifier
2291                           or else Nkind (Rref) = N_Operator_Symbol
2292                         then
2293                            null;
2294
2295                         --  For renamed array components, use the array name
2296                         --  for the renamed entity, which reflect the fact that
2297                         --  in general the whole array is aliased.
2298
2299                         elsif Nkind (Rref) = N_Indexed_Component then
2300                            if Nkind (Prefix (Rref)) = N_Identifier then
2301                               Rref := Prefix (Rref);
2302                            elsif Nkind (Prefix (Rref)) = N_Expanded_Name then
2303                               Rref := Selector_Name (Prefix (Rref));
2304                            else
2305                               Rref := Empty;
2306                            end if;
2307
2308                         else
2309                            Rref := Empty;
2310                         end if;
2311                      end if;
2312
2313                      --  Write out renaming reference if we have one
2314
2315                      if Present (Rref) then
2316                         Write_Info_Char ('=');
2317                         Write_Info_Nat
2318                           (Int (Get_Logical_Line_Number (Sloc (Rref))));
2319                         Write_Info_Char (':');
2320                         Write_Info_Nat
2321                           (Int (Get_Column_Number (Sloc (Rref))));
2322                      end if;
2323
2324                      --  Indicate that the entity is in the unit of the current
2325                      --  xref section.
2326
2327                      Curru := Curxu;
2328
2329                      --  Write out information about generic parent, if entity
2330                      --  is an instance.
2331
2332                      if  Is_Generic_Instance (XE.Key.Ent) then
2333                         declare
2334                            Gen_Par : constant Entity_Id :=
2335                                        Generic_Parent
2336                                          (Specification
2337                                             (Unit_Declaration_Node
2338                                                (XE.Key.Ent)));
2339                            Loc     : constant Source_Ptr := Sloc (Gen_Par);
2340                            Gen_U   : constant Unit_Number_Type :=
2341                                        Get_Source_Unit (Loc);
2342
2343                         begin
2344                            Write_Info_Char ('[');
2345
2346                            if Curru /= Gen_U then
2347                               Write_Info_Nat (Dependency_Num (Gen_U));
2348                               Write_Info_Char ('|');
2349                            end if;
2350
2351                            Write_Info_Nat
2352                              (Int (Get_Logical_Line_Number (Loc)));
2353                            Write_Info_Char (']');
2354                         end;
2355                      end if;
2356
2357                      --  See if we have a type reference and if so output
2358
2359                      Check_Type_Reference (XE.Key.Ent, False);
2360
2361                      --  Additional information for types with progenitors
2362
2363                      if Is_Record_Type (XE.Key.Ent)
2364                        and then Present (Interfaces (XE.Key.Ent))
2365                      then
2366                         declare
2367                            Elmt : Elmt_Id :=
2368                                     First_Elmt (Interfaces (XE.Key.Ent));
2369                         begin
2370                            while Present (Elmt) loop
2371                               Check_Type_Reference (Node (Elmt), True);
2372                               Next_Elmt (Elmt);
2373                            end loop;
2374                         end;
2375
2376                      --  For array types, list index types as well. (This is
2377                      --  not C, indexes have distinct types).
2378
2379                      elsif Is_Array_Type (XE.Key.Ent) then
2380                         declare
2381                            Indx : Node_Id;
2382                         begin
2383                            Indx := First_Index (XE.Key.Ent);
2384                            while Present (Indx) loop
2385                               Check_Type_Reference
2386                                 (First_Subtype (Etype (Indx)), True);
2387                               Next_Index (Indx);
2388                            end loop;
2389                         end;
2390                      end if;
2391
2392                      --  If the entity is an overriding operation, write info
2393                      --  on operation that was overridden.
2394
2395                      if Is_Subprogram (XE.Key.Ent)
2396                        and then Present (Overridden_Operation (XE.Key.Ent))
2397                      then
2398                         Output_Overridden_Op
2399                           (Overridden_Operation (XE.Key.Ent));
2400                      end if;
2401
2402                      --  End of processing for entity output
2403
2404                      Crloc := No_Location;
2405                   end if;
2406
2407                   --  Output the reference if it is not as the same location
2408                   --  as the previous one, or it is a read-reference that
2409                   --  indicates that the entity is an in-out actual in a call.
2410
2411                   if XE.Key.Loc /= No_Location
2412                     and then
2413                       (XE.Key.Loc /= Crloc
2414                         or else (Prevt = 'm' and then  XE.Key.Typ = 'r'))
2415                   then
2416                      Crloc := XE.Key.Loc;
2417                      Prevt := XE.Key.Typ;
2418
2419                      --  Start continuation if line full, else blank
2420
2421                      if Write_Info_Col > 72 then
2422                         Write_Info_EOL;
2423                         Write_Info_Initiate ('.');
2424                      end if;
2425
2426                      Write_Info_Char (' ');
2427
2428                      --  Output file number if changed
2429
2430                      if XE.Key.Lun /= Curru then
2431                         Curru := XE.Key.Lun;
2432                         Write_Info_Nat (Dependency_Num (Curru));
2433                         Write_Info_Char ('|');
2434                      end if;
2435
2436                      Write_Info_Nat
2437                        (Int (Get_Logical_Line_Number (XE.Key.Loc)));
2438                      Write_Info_Char (XE.Key.Typ);
2439
2440                      if Is_Overloadable (XE.Key.Ent)
2441                        and then Is_Imported (XE.Key.Ent)
2442                        and then XE.Key.Typ = 'b'
2443                      then
2444                         Output_Import_Export_Info (XE.Key.Ent);
2445                      end if;
2446
2447                      Write_Info_Nat (Int (Get_Column_Number (XE.Key.Loc)));
2448
2449                      Output_Instantiation_Refs (Sloc (XE.Key.Ent));
2450                   end if;
2451                end if;
2452             end Output_One_Ref;
2453
2454          <<Continue>>
2455             null;
2456          end loop;
2457
2458          Write_Info_EOL;
2459       end Output_Refs;
2460    end Output_References;
2461
2462 --  Start of elaboration for Lib.Xref
2463
2464 begin
2465    --  Reset is necessary because Elmt_Ptr does not default to Null_Ptr,
2466    --  because it's not an access type.
2467
2468    Xref_Set.Reset;
2469 end Lib.Xref;