gcc/ada/lib-xref.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             L I B . X R E F                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1998-2011, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Csets;    use Csets;
  28 with Elists;   use Elists;
  29 with Errout;   use Errout;
  30 with Nlists;   use Nlists;
  31 with Opt;      use Opt;
  32 with Restrict; use Restrict;
  33 with Rident;   use Rident;
  34 with Sem;      use Sem;
  35 with Sem_Aux;  use Sem_Aux;
  36 with Sem_Prag; use Sem_Prag;
  37 with Sem_Util; use Sem_Util;
  38 with Sem_Warn; use Sem_Warn;
  39 with Sinfo;    use Sinfo;
  40 with Sinput;   use Sinput;
  41 with Snames;   use Snames;
  42 with Stringt;  use Stringt;
  43 with Stand;    use Stand;
  44 with Table;    use Table;
  45
  46 with GNAT.Heap_Sort_G;
  47 with GNAT.HTable;
  48
  49 package body Lib.Xref is
  50
  51    ------------------
  52    -- Declarations --
  53    ------------------
  54
  55    --  The Xref table is used to record references. The Loc field is set
  56    --  to No_Location for a definition entry.
  57
  58    subtype Xref_Entry_Number is Int;
  59
  60    type Xref_Key is record
  61       --  These are the components of Xref_Entry that participate in hash
  62       --  lookups.
  63
  64       Ent : Entity_Id;
  65       --  Entity referenced (E parameter to Generate_Reference)
  66
  67       Loc : Source_Ptr;
  68       --  Location of reference (Original_Location (Sloc field of N parameter
  69       --  to Generate_Reference). Set to No_Location for the case of a
  70       --  defining occurrence.
  71
  72       Typ : Character;
  73       --  Reference type (Typ param to Generate_Reference)
  74
  75       Eun : Unit_Number_Type;
  76       --  Unit number corresponding to Ent
  77
  78       Lun : Unit_Number_Type;
  79       --  Unit number corresponding to Loc. Value is undefined and not
  80       --  referenced if Loc is set to No_Location.
  81
  82       --  The following components are only used for Alfa cross-references
  83
  84       Ref_Scope : Entity_Id;
  85       --  Entity of the closest subprogram or package enclosing the reference
  86
  87       Ent_Scope : Entity_Id;
  88       --  Entity of the closest subprogram or package enclosing the definition,
  89       --  which should be located in the same file as the definition itself.
  90    end record;
  91
  92    type Xref_Entry is record
  93       Key : Xref_Key;
  94
  95       Ent_Scope_File : Unit_Number_Type;
  96       --  File for entity Ent_Scope
  97
  98       Def : Source_Ptr;
  99       --  Original source location for entity being referenced. Note that these
 100       --  values are used only during the output process, they are not set when
 101       --  the entries are originally built. This is because private entities
 102       --  can be swapped when the initial call is made.
 103
 104       HTable_Next : Xref_Entry_Number;
 105       --  For use only by Static_HTable
 106    end record;
 107
 108    package Xrefs is new Table.Table (
 109      Table_Component_Type => Xref_Entry,
 110      Table_Index_Type     => Xref_Entry_Number,
 111      Table_Low_Bound      => 1,
 112      Table_Initial        => Alloc.Xrefs_Initial,
 113      Table_Increment      => Alloc.Xrefs_Increment,
 114      Table_Name           => "Xrefs");
 115
 116    --------------
 117    -- Xref_Set --
 118    --------------
 119
 120    --  We keep a set of xref entries, in order to avoid inserting duplicate
 121    --  entries into the above Xrefs table. An entry is in Xref_Set if and only
 122    --  if it is in Xrefs.
 123
 124    Num_Buckets : constant := 2**16;
 125
 126    subtype Header_Num is Integer range 0 .. Num_Buckets - 1;
 127    type Null_Type is null record;
 128    pragma Unreferenced (Null_Type);
 129
 130    function Hash (F : Xref_Entry_Number) return Header_Num;
 131
 132    function Equal (F1, F2 : Xref_Entry_Number) return Boolean;
 133
 134    procedure HT_Set_Next (E : Xref_Entry_Number; Next : Xref_Entry_Number);
 135
 136    function  HT_Next (E : Xref_Entry_Number) return Xref_Entry_Number;
 137
 138    function Get_Key (E : Xref_Entry_Number) return Xref_Entry_Number;
 139
 140    pragma Inline (Hash, Equal, HT_Set_Next, HT_Next, Get_Key);
 141
 142    package Xref_Set is new GNAT.HTable.Static_HTable (
 143      Header_Num,
 144      Element    => Xref_Entry,
 145      Elmt_Ptr   => Xref_Entry_Number,
 146      Null_Ptr   => 0,
 147      Set_Next   => HT_Set_Next,
 148      Next       => HT_Next,
 149      Key        => Xref_Entry_Number,
 150      Get_Key    => Get_Key,
 151      Hash       => Hash,
 152      Equal      => Equal);
 153
 154    ----------------------
 155    -- Alfa Information --
 156    ----------------------
 157
 158    package body Alfa is separate;
 159
 160    ------------------------
 161    --  Local Subprograms --
 162    ------------------------
 163
 164    procedure Generate_Prim_Op_References (Typ : Entity_Id);
 165    --  For a tagged type, generate implicit references to its primitive
 166    --  operations, for source navigation. This is done right before emitting
 167    --  cross-reference information rather than at the freeze point of the type
 168    --  in order to handle late bodies that are primitive operations.
 169
 170    function Lt (T1, T2 : Xref_Entry) return Boolean;
 171    --  Order cross-references
 172
 173    procedure Add_Entry (Key : Xref_Key; Ent_Scope_File : Unit_Number_Type);
 174    --  Add an entry to the tables of Xref_Entries, avoiding duplicates
 175
 176    ---------------
 177    -- Add_Entry --
 178    ---------------
 179
 180    procedure Add_Entry (Key : Xref_Key; Ent_Scope_File : Unit_Number_Type) is
 181    begin
 182       Xrefs.Increment_Last; -- tentative
 183       Xrefs.Table (Xrefs.Last).Key := Key;
 184
 185       --  Set the entry in Xref_Set, and if newly set, keep the above
 186       --  tentative increment.
 187
 188       if Xref_Set.Set_If_Not_Present (Xrefs.Last) then
 189          Xrefs.Table (Xrefs.Last).Ent_Scope_File := Ent_Scope_File;
 190          --  Leave Def and HTable_Next uninitialized
 191
 192          Set_Has_Xref_Entry (Key.Ent);
 193
 194       --  It was already in Xref_Set, so throw away the tentatively-added
 195       --  entry
 196
 197       else
 198          Xrefs.Decrement_Last;
 199       end if;
 200    end Add_Entry;
 201
 202    -----------
 203    -- Equal --
 204    -----------
 205
 206    function Equal (F1, F2 : Xref_Entry_Number) return Boolean is
 207       Result : constant Boolean :=
 208                  Xrefs.Table (F1).Key = Xrefs.Table (F2).Key;
 209    begin
 210       return Result;
 211    end Equal;
 212
 213    -------------------------
 214    -- Generate_Definition --
 215    -------------------------
 216
 217    procedure Generate_Definition (E : Entity_Id) is
 218    begin
 219       pragma Assert (Nkind (E) in N_Entity);
 220
 221       --  Note that we do not test Xref_Entity_Letters here. It is too early
 222       --  to do so, since we are often called before the entity is fully
 223       --  constructed, so that the Ekind is still E_Void.
 224
 225       if Opt.Xref_Active
 226
 227          --  Definition must come from source
 228
 229          --  We make an exception for subprogram child units that have no spec.
 230          --  For these we generate a subprogram declaration for library use,
 231          --  and the corresponding entity does not come from source.
 232          --  Nevertheless, all references will be attached to it and we have
 233          --  to treat is as coming from user code.
 234
 235          and then (Comes_From_Source (E) or else Is_Child_Unit (E))
 236
 237          --  And must have a reasonable source location that is not
 238          --  within an instance (all entities in instances are ignored)
 239
 240          and then Sloc (E) > No_Location
 241          and then Instantiation_Location (Sloc (E)) = No_Location
 242
 243          --  And must be a non-internal name from the main source unit
 244
 245          and then In_Extended_Main_Source_Unit (E)
 246          and then not Is_Internal_Name (Chars (E))
 247       then
 248          Add_Entry
 249            ((Ent => E,
 250              Loc => No_Location,
 251              Typ => ' ',
 252              Eun => Get_Source_Unit (Original_Location (Sloc (E))),
 253              Lun => No_Unit,
 254              Ref_Scope => Empty,
 255              Ent_Scope => Empty),
 256             Ent_Scope_File => No_Unit);
 257
 258          if In_Inlined_Body then
 259             Set_Referenced (E);
 260          end if;
 261       end if;
 262    end Generate_Definition;
 263
 264    ---------------------------------
 265    -- Generate_Operator_Reference --
 266    ---------------------------------
 267
 268    procedure Generate_Operator_Reference
 269      (N : Node_Id;
 270       T : Entity_Id)
 271    is
 272    begin
 273       if not In_Extended_Main_Source_Unit (N) then
 274          return;
 275       end if;
 276
 277       --  If the operator is not a Standard operator, then we generate a real
 278       --  reference to the user defined operator.
 279
 280       if Sloc (Entity (N)) /= Standard_Location then
 281          Generate_Reference (Entity (N), N);
 282
 283          --  A reference to an implicit inequality operator is also a reference
 284          --  to the user-defined equality.
 285
 286          if Nkind (N) = N_Op_Ne
 287            and then not Comes_From_Source (Entity (N))
 288            and then Present (Corresponding_Equality (Entity (N)))
 289          then
 290             Generate_Reference (Corresponding_Equality (Entity (N)), N);
 291          end if;
 292
 293       --  For the case of Standard operators, we mark the result type as
 294       --  referenced. This ensures that in the case where we are using a
 295       --  derived operator, we mark an entity of the unit that implicitly
 296       --  defines this operator as used. Otherwise we may think that no entity
 297       --  of the unit is used. The actual entity marked as referenced is the
 298       --  first subtype, which is the relevant user defined entity.
 299
 300       --  Note: we only do this for operators that come from source. The
 301       --  generated code sometimes reaches for entities that do not need to be
 302       --  explicitly visible (for example, when we expand the code for
 303       --  comparing two record objects, the fields of the record may not be
 304       --  visible).
 305
 306       elsif Comes_From_Source (N) then
 307          Set_Referenced (First_Subtype (T));
 308       end if;
 309    end Generate_Operator_Reference;
 310
 311    ---------------------------------
 312    -- Generate_Prim_Op_References --
 313    ---------------------------------
 314
 315    procedure Generate_Prim_Op_References (Typ : Entity_Id) is
 316       Base_T    : Entity_Id;
 317       Prim      : Elmt_Id;
 318       Prim_List : Elist_Id;
 319
 320    begin
 321       --  Handle subtypes of synchronized types
 322
 323       if Ekind (Typ) = E_Protected_Subtype
 324         or else Ekind (Typ) = E_Task_Subtype
 325       then
 326          Base_T := Etype (Typ);
 327       else
 328          Base_T := Typ;
 329       end if;
 330
 331       --  References to primitive operations are only relevant for tagged types
 332
 333       if not Is_Tagged_Type (Base_T)
 334         or else Is_Class_Wide_Type (Base_T)
 335       then
 336          return;
 337       end if;
 338
 339       --  Ada 2005 (AI-345): For synchronized types generate reference to the
 340       --  wrapper that allow us to dispatch calls through their implemented
 341       --  abstract interface types.
 342
 343       --  The check for Present here is to protect against previously reported
 344       --  critical errors.
 345
 346       Prim_List := Primitive_Operations (Base_T);
 347
 348       if No (Prim_List) then
 349          return;
 350       end if;
 351
 352       Prim := First_Elmt (Prim_List);
 353       while Present (Prim) loop
 354
 355          --  If the operation is derived, get the original for cross-reference
 356          --  reference purposes (it is the original for which we want the xref
 357          --  and for which the comes_from_source test must be performed).
 358
 359          Generate_Reference
 360            (Typ, Ultimate_Alias (Node (Prim)), 'p', Set_Ref => False);
 361          Next_Elmt (Prim);
 362       end loop;
 363    end Generate_Prim_Op_References;
 364
 365    ------------------------
 366    -- Generate_Reference --
 367    ------------------------
 368
 369    procedure Generate_Reference
 370      (E       : Entity_Id;
 371       N       : Node_Id;
 372       Typ     : Character := 'r';
 373       Set_Ref : Boolean   := True;
 374       Force   : Boolean   := False)
 375    is
 376       Nod : Node_Id;
 377       Ref : Source_Ptr;
 378       Def : Source_Ptr;
 379       Ent : Entity_Id;
 380
 381       Actual_Typ : Character := Typ;
 382
 383       Ref_Scope      : Entity_Id;
 384       Ent_Scope      : Entity_Id;
 385       Ent_Scope_File : Unit_Number_Type;
 386
 387       Call   : Node_Id;
 388       Formal : Entity_Id;
 389       --  Used for call to Find_Actual
 390
 391       Kind : Entity_Kind;
 392       --  If Formal is non-Empty, then its Ekind, otherwise E_Void
 393
 394       function Is_On_LHS (Node : Node_Id) return Boolean;
 395       --  Used to check if a node is on the left hand side of an assignment.
 396       --  The following cases are handled:
 397       --
 398       --   Variable    Node is a direct descendant of left hand side of an
 399       --               assignment statement.
 400       --
 401       --   Prefix      Of an indexed or selected component that is present in
 402       --               a subtree rooted by an assignment statement. There is
 403       --               no restriction of nesting of components, thus cases
 404       --               such as A.B (C).D are handled properly. However a prefix
 405       --               of a dereference (either implicit or explicit) is never
 406       --               considered as on a LHS.
 407       --
 408       --   Out param   Same as above cases, but OUT parameter
 409
 410       function OK_To_Set_Referenced return Boolean;
 411       --  Returns True if the Referenced flag can be set. There are a few
 412       --  exceptions where we do not want to set this flag, see body for
 413       --  details of these exceptional cases.
 414
 415       ---------------
 416       -- Is_On_LHS --
 417       ---------------
 418
 419       --  ??? There are several routines here and there that perform a similar
 420       --      (but subtly different) computation, which should be factored:
 421
 422       --      Sem_Util.May_Be_Lvalue
 423       --      Sem_Util.Known_To_Be_Assigned
 424       --      Exp_Ch2.Expand_Entry_Parameter.In_Assignment_Context
 425       --      Exp_Smem.Is_Out_Actual
 426
 427       function Is_On_LHS (Node : Node_Id) return Boolean is
 428          N : Node_Id;
 429          P : Node_Id;
 430          K : Node_Kind;
 431
 432       begin
 433          --  Only identifiers are considered, is this necessary???
 434
 435          if Nkind (Node) /= N_Identifier then
 436             return False;
 437          end if;
 438
 439          --  Immediate return if appeared as OUT parameter
 440
 441          if Kind = E_Out_Parameter then
 442             return True;
 443          end if;
 444
 445          --  Search for assignment statement subtree root
 446
 447          N := Node;
 448          loop
 449             P := Parent (N);
 450             K := Nkind (P);
 451
 452             if K = N_Assignment_Statement then
 453                return Name (P) = N;
 454
 455             --  Check whether the parent is a component and the current node is
 456             --  its prefix, but return False if the current node has an access
 457             --  type, as in that case the selected or indexed component is an
 458             --  implicit dereference, and the LHS is the designated object, not
 459             --  the access object.
 460
 461             --  ??? case of a slice assignment?
 462
 463             --  ??? Note that in some cases this is called too early
 464             --  (see comments in Sem_Ch8.Find_Direct_Name), at a point where
 465             --  the tree is not fully typed yet. In that case we may lack
 466             --  an Etype for N, and we must disable the check for an implicit
 467             --  dereference. If the dereference is on an LHS, this causes a
 468             --  false positive.
 469
 470             elsif (K = N_Selected_Component or else K = N_Indexed_Component)
 471               and then Prefix (P) = N
 472               and then not (Present (Etype (N))
 473                               and then
 474                             Is_Access_Type (Etype (N)))
 475             then
 476                N := P;
 477
 478             --  All other cases, definitely not on left side
 479
 480             else
 481                return False;
 482             end if;
 483          end loop;
 484       end Is_On_LHS;
 485
 486       ---------------------------
 487       -- OK_To_Set_Referenced --
 488       ---------------------------
 489
 490       function OK_To_Set_Referenced return Boolean is
 491          P : Node_Id;
 492
 493       begin
 494          --  A reference from a pragma Unreferenced or pragma Unmodified or
 495          --  pragma Warnings does not cause the Referenced flag to be set.
 496          --  This avoids silly warnings about things being referenced and
 497          --  not assigned when the only reference is from the pragma.
 498
 499          if Nkind (N) = N_Identifier then
 500             P := Parent (N);
 501
 502             if Nkind (P) = N_Pragma_Argument_Association then
 503                P := Parent (P);
 504
 505                if Nkind (P) = N_Pragma then
 506                   if Pragma_Name (P) = Name_Warnings
 507                        or else
 508                      Pragma_Name (P) = Name_Unmodified
 509                        or else
 510                      Pragma_Name (P) = Name_Unreferenced
 511                   then
 512                      return False;
 513                   end if;
 514                end if;
 515             end if;
 516          end if;
 517
 518          return True;
 519       end OK_To_Set_Referenced;
 520
 521    --  Start of processing for Generate_Reference
 522
 523    begin
 524       pragma Assert (Nkind (E) in N_Entity);
 525       Find_Actual (N, Formal, Call);
 526
 527       if Present (Formal) then
 528          Kind := Ekind (Formal);
 529       else
 530          Kind := E_Void;
 531       end if;
 532
 533       --  Check for obsolescent reference to package ASCII. GNAT treats this
 534       --  element of annex J specially since in practice, programs make a lot
 535       --  of use of this feature, so we don't include it in the set of features
 536       --  diagnosed when Warn_On_Obsolescent_Features mode is set. However we
 537       --  are required to note it as a violation of the RM defined restriction.
 538
 539       if E = Standard_ASCII then
 540          Check_Restriction (No_Obsolescent_Features, N);
 541       end if;
 542
 543       --  Check for reference to entity marked with Is_Obsolescent
 544
 545       --  Note that we always allow obsolescent references in the compiler
 546       --  itself and the run time, since we assume that we know what we are
 547       --  doing in such cases. For example the calls in Ada.Characters.Handling
 548       --  to its own obsolescent subprograms are just fine.
 549
 550       --  In any case we do not generate warnings within the extended source
 551       --  unit of the entity in question, since we assume the source unit
 552       --  itself knows what is going on (and for sure we do not want silly
 553       --  warnings, e.g. on the end line of an obsolescent procedure body).
 554
 555       if Is_Obsolescent (E)
 556         and then not GNAT_Mode
 557         and then not In_Extended_Main_Source_Unit (E)
 558       then
 559          Check_Restriction (No_Obsolescent_Features, N);
 560
 561          if Warn_On_Obsolescent_Feature then
 562             Output_Obsolescent_Entity_Warnings (N, E);
 563          end if;
 564       end if;
 565
 566       --  Warn if reference to Ada 2005 entity not in Ada 2005 mode. We only
 567       --  detect real explicit references (modifications and references).
 568
 569       if Comes_From_Source (N)
 570         and then Is_Ada_2005_Only (E)
 571         and then Ada_Version < Ada_2005
 572         and then Warn_On_Ada_2005_Compatibility
 573         and then (Typ = 'm' or else Typ = 'r' or else Typ = 's')
 574       then
 575          Error_Msg_NE ("& is only defined in Ada 2005?", N, E);
 576       end if;
 577
 578       --  Warn if reference to Ada 2012 entity not in Ada 2012 mode. We only
 579       --  detect real explicit references (modifications and references).
 580
 581       if Comes_From_Source (N)
 582         and then Is_Ada_2012_Only (E)
 583         and then Ada_Version < Ada_2012
 584         and then Warn_On_Ada_2012_Compatibility
 585         and then (Typ = 'm' or else Typ = 'r')
 586       then
 587          Error_Msg_NE ("& is only defined in Ada 2012?", N, E);
 588       end if;
 589
 590       --  Never collect references if not in main source unit. However, we omit
 591       --  this test if Typ is 'e' or 'k', since these entries are structural,
 592       --  and it is useful to have them in units that reference packages as
 593       --  well as units that define packages. We also omit the test for the
 594       --  case of 'p' since we want to include inherited primitive operations
 595       --  from other packages.
 596
 597       --  We also omit this test is this is a body reference for a subprogram
 598       --  instantiation. In this case the reference is to the generic body,
 599       --  which clearly need not be in the main unit containing the instance.
 600       --  For the same reason we accept an implicit reference generated for
 601       --  a default in an instance.
 602
 603       if not In_Extended_Main_Source_Unit (N) then
 604          if Typ = 'e'
 605            or else Typ = 'I'
 606            or else Typ = 'p'
 607            or else Typ = 'i'
 608            or else Typ = 'k'
 609            or else (Typ = 'b' and then Is_Generic_Instance (E))
 610          then
 611             null;
 612          else
 613             return;
 614          end if;
 615       end if;
 616
 617       --  For reference type p, the entity must be in main source unit
 618
 619       if Typ = 'p' and then not In_Extended_Main_Source_Unit (E) then
 620          return;
 621       end if;
 622
 623       --  Unless the reference is forced, we ignore references where the
 624       --  reference itself does not come from source.
 625
 626       if not Force and then not Comes_From_Source (N) then
 627          return;
 628       end if;
 629
 630       --  Deal with setting entity as referenced, unless suppressed. Note that
 631       --  we still do Set_Referenced on entities that do not come from source.
 632       --  This situation arises when we have a source reference to a derived
 633       --  operation, where the derived operation itself does not come from
 634       --  source, but we still want to mark it as referenced, since we really
 635       --  are referencing an entity in the corresponding package (this avoids
 636       --  wrong complaints that the package contains no referenced entities).
 637
 638       if Set_Ref then
 639
 640          --  Assignable object appearing on left side of assignment or as
 641          --  an out parameter.
 642
 643          if Is_Assignable (E)
 644            and then Is_On_LHS (N)
 645            and then Ekind (E) /= E_In_Out_Parameter
 646          then
 647             --  For objects that are renamings, just set as simply referenced
 648             --  we do not try to do assignment type tracking in this case.
 649
 650             if Present (Renamed_Object (E)) then
 651                Set_Referenced (E);
 652
 653             --  Out parameter case
 654
 655             elsif Kind = E_Out_Parameter then
 656
 657                --  If warning mode for all out parameters is set, or this is
 658                --  the only warning parameter, then we want to mark this for
 659                --  later warning logic by setting Referenced_As_Out_Parameter
 660
 661                if Warn_On_Modified_As_Out_Parameter (Formal) then
 662                   Set_Referenced_As_Out_Parameter (E, True);
 663                   Set_Referenced_As_LHS (E, False);
 664
 665                --  For OUT parameter not covered by the above cases, we simply
 666                --  regard it as a normal reference (in this case we do not
 667                --  want any of the warning machinery for out parameters).
 668
 669                else
 670                   Set_Referenced (E);
 671                end if;
 672
 673             --  For the left hand of an assignment case, we do nothing here.
 674             --  The processing for Analyze_Assignment_Statement will set the
 675             --  Referenced_As_LHS flag.
 676
 677             else
 678                null;
 679             end if;
 680
 681          --  Check for a reference in a pragma that should not count as a
 682          --  making the variable referenced for warning purposes.
 683
 684          elsif Is_Non_Significant_Pragma_Reference (N) then
 685             null;
 686
 687          --  A reference in an attribute definition clause does not count as a
 688          --  reference except for the case of Address. The reason that 'Address
 689          --  is an exception is that it creates an alias through which the
 690          --  variable may be referenced.
 691
 692          elsif Nkind (Parent (N)) = N_Attribute_Definition_Clause
 693            and then Chars (Parent (N)) /= Name_Address
 694            and then N = Name (Parent (N))
 695          then
 696             null;
 697
 698          --  Constant completion does not count as a reference
 699
 700          elsif Typ = 'c'
 701            and then Ekind (E) = E_Constant
 702          then
 703             null;
 704
 705          --  Record representation clause does not count as a reference
 706
 707          elsif Nkind (N) = N_Identifier
 708            and then Nkind (Parent (N)) = N_Record_Representation_Clause
 709          then
 710             null;
 711
 712          --  Discriminants do not need to produce a reference to record type
 713
 714          elsif Typ = 'd'
 715            and then Nkind (Parent (N)) = N_Discriminant_Specification
 716          then
 717             null;
 718
 719          --  All other cases
 720
 721          else
 722             --  Special processing for IN OUT parameters, where we have an
 723             --  implicit assignment to a simple variable.
 724
 725             if Kind = E_In_Out_Parameter
 726               and then Is_Assignable (E)
 727             then
 728                --  For sure this counts as a normal read reference
 729
 730                Set_Referenced (E);
 731                Set_Last_Assignment (E, Empty);
 732
 733                --  We count it as being referenced as an out parameter if the
 734                --  option is set to warn on all out parameters, except that we
 735                --  have a special exclusion for an intrinsic subprogram, which
 736                --  is most likely an instantiation of Unchecked_Deallocation
 737                --  which we do not want to consider as an assignment since it
 738                --  generates false positives. We also exclude the case of an
 739                --  IN OUT parameter if the name of the procedure is Free,
 740                --  since we suspect similar semantics.
 741
 742                if Warn_On_All_Unread_Out_Parameters
 743                  and then Is_Entity_Name (Name (Call))
 744                  and then not Is_Intrinsic_Subprogram (Entity (Name (Call)))
 745                  and then Chars (Name (Call)) /= Name_Free
 746                then
 747                   Set_Referenced_As_Out_Parameter (E, True);
 748                   Set_Referenced_As_LHS (E, False);
 749                end if;
 750
 751             --  Don't count a recursive reference within a subprogram as a
 752             --  reference (that allows detection of a recursive subprogram
 753             --  whose only references are recursive calls as unreferenced).
 754
 755             elsif Is_Subprogram (E)
 756               and then E = Nearest_Dynamic_Scope (Current_Scope)
 757             then
 758                null;
 759
 760             --  Any other occurrence counts as referencing the entity
 761
 762             elsif OK_To_Set_Referenced then
 763                Set_Referenced (E);
 764
 765                --  If variable, this is an OK reference after an assignment
 766                --  so we can clear the Last_Assignment indication.
 767
 768                if Is_Assignable (E) then
 769                   Set_Last_Assignment (E, Empty);
 770                end if;
 771             end if;
 772          end if;
 773
 774          --  Check for pragma Unreferenced given and reference is within
 775          --  this source unit (occasion for possible warning to be issued).
 776
 777          if Has_Unreferenced (E)
 778            and then In_Same_Extended_Unit (E, N)
 779          then
 780             --  A reference as a named parameter in a call does not count
 781             --  as a violation of pragma Unreferenced for this purpose...
 782
 783             if Nkind (N) = N_Identifier
 784               and then Nkind (Parent (N)) = N_Parameter_Association
 785               and then Selector_Name (Parent (N)) = N
 786             then
 787                null;
 788
 789             --  ... Neither does a reference to a variable on the left side
 790             --  of an assignment.
 791
 792             elsif Is_On_LHS (N) then
 793                null;
 794
 795             --  For entry formals, we want to place the warning message on the
 796             --  corresponding entity in the accept statement. The current scope
 797             --  is the body of the accept, so we find the formal whose name
 798             --  matches that of the entry formal (there is no link between the
 799             --  two entities, and the one in the accept statement is only used
 800             --  for conformance checking).
 801
 802             elsif Ekind (Scope (E)) = E_Entry then
 803                declare
 804                   BE : Entity_Id;
 805
 806                begin
 807                   BE := First_Entity (Current_Scope);
 808                   while Present (BE) loop
 809                      if Chars (BE) = Chars (E) then
 810                         Error_Msg_NE -- CODEFIX
 811                           ("?pragma Unreferenced given for&!", N, BE);
 812                         exit;
 813                      end if;
 814
 815                      Next_Entity (BE);
 816                   end loop;
 817                end;
 818
 819             --  Here we issue the warning, since this is a real reference
 820
 821             else
 822                Error_Msg_NE -- CODEFIX
 823                  ("?pragma Unreferenced given for&!", N, E);
 824             end if;
 825          end if;
 826
 827          --  If this is a subprogram instance, mark as well the internal
 828          --  subprogram in the wrapper package, which may be a visible
 829          --  compilation unit.
 830
 831          if Is_Overloadable (E)
 832            and then Is_Generic_Instance (E)
 833            and then Present (Alias (E))
 834          then
 835             Set_Referenced (Alias (E));
 836          end if;
 837       end if;
 838
 839       --  Generate reference if all conditions are met:
 840
 841       if
 842          --  Cross referencing must be active
 843
 844          Opt.Xref_Active
 845
 846          --  The entity must be one for which we collect references
 847
 848          and then Xref_Entity_Letters (Ekind (E)) /= ' '
 849
 850          --  Both Sloc values must be set to something sensible
 851
 852          and then Sloc (E) > No_Location
 853          and then Sloc (N) > No_Location
 854
 855          --  We ignore references from within an instance, except for default
 856          --  subprograms, for which we generate an implicit reference.
 857
 858          and then
 859            (Instantiation_Location (Sloc (N)) = No_Location or else Typ = 'i')
 860
 861          --  Ignore dummy references
 862
 863         and then Typ /= ' '
 864       then
 865          if Nkind (N) = N_Identifier
 866               or else
 867             Nkind (N) = N_Defining_Identifier
 868               or else
 869             Nkind (N) in N_Op
 870               or else
 871             Nkind (N) = N_Defining_Operator_Symbol
 872               or else
 873             Nkind (N) = N_Operator_Symbol
 874               or else
 875             (Nkind (N) = N_Character_Literal
 876               and then Sloc (Entity (N)) /= Standard_Location)
 877               or else
 878             Nkind (N) = N_Defining_Character_Literal
 879          then
 880             Nod := N;
 881
 882          elsif Nkind (N) = N_Expanded_Name
 883                  or else
 884                Nkind (N) = N_Selected_Component
 885          then
 886             Nod := Selector_Name (N);
 887
 888          else
 889             return;
 890          end if;
 891
 892          --  Normal case of source entity comes from source
 893
 894          if Comes_From_Source (E) then
 895             Ent := E;
 896
 897          --  Entity does not come from source, but is a derived subprogram and
 898          --  the derived subprogram comes from source (after one or more
 899          --  derivations) in which case the reference is to parent subprogram.
 900
 901          elsif Is_Overloadable (E)
 902            and then Present (Alias (E))
 903          then
 904             Ent := Alias (E);
 905             while not Comes_From_Source (Ent) loop
 906                if No (Alias (Ent)) then
 907                   return;
 908                end if;
 909
 910                Ent := Alias (Ent);
 911             end loop;
 912
 913          --  The internally created defining entity for a child subprogram
 914          --  that has no previous spec has valid references.
 915
 916          elsif Is_Overloadable (E)
 917            and then Is_Child_Unit (E)
 918          then
 919             Ent := E;
 920
 921          --  Record components of discriminated subtypes or derived types must
 922          --  be treated as references to the original component.
 923
 924          elsif Ekind (E) = E_Component
 925            and then Comes_From_Source (Original_Record_Component (E))
 926          then
 927             Ent := Original_Record_Component (E);
 928
 929          --  If this is an expanded reference to a discriminant, recover the
 930          --  original discriminant, which gets the reference.
 931
 932          elsif Ekind (E) = E_In_Parameter
 933            and then  Present (Discriminal_Link (E))
 934          then
 935             Ent := Discriminal_Link (E);
 936             Set_Referenced (Ent);
 937
 938          --  Ignore reference to any other entity that is not from source
 939
 940          else
 941             return;
 942          end if;
 943
 944          --  Record reference to entity
 945
 946          Ref := Original_Location (Sloc (Nod));
 947          Def := Original_Location (Sloc (Ent));
 948
 949          if Actual_Typ = 'p'
 950            and then Is_Subprogram (N)
 951            and then Present (Overridden_Operation (N))
 952          then
 953             Actual_Typ := 'P';
 954          end if;
 955
 956          if Alfa_Mode then
 957             Ref_Scope := Alfa.Enclosing_Subprogram_Or_Package (N);
 958             Ent_Scope := Alfa.Enclosing_Subprogram_Or_Package (Ent);
 959             Ent_Scope_File := Get_Source_Unit (Ent_Scope);
 960
 961          else
 962             Ref_Scope := Empty;
 963             Ent_Scope := Empty;
 964             Ent_Scope_File := No_Unit;
 965          end if;
 966
 967          Add_Entry
 968            ((Ent => Ent,
 969              Loc => Ref,
 970              Typ => Actual_Typ,
 971              Eun => Get_Source_Unit (Def),
 972              Lun => Get_Source_Unit (Ref),
 973              Ref_Scope => Ref_Scope,
 974              Ent_Scope => Ent_Scope),
 975             Ent_Scope_File => Ent_Scope_File);
 976       end if;
 977    end Generate_Reference;
 978
 979    -----------------------------------
 980    -- Generate_Reference_To_Formals --
 981    -----------------------------------
 982
 983    procedure Generate_Reference_To_Formals (E : Entity_Id) is
 984       Formal : Entity_Id;
 985
 986    begin
 987       if Is_Generic_Subprogram (E) then
 988          Formal := First_Entity (E);
 989
 990          while Present (Formal)
 991            and then not Is_Formal (Formal)
 992          loop
 993             Next_Entity (Formal);
 994          end loop;
 995
 996       else
 997          Formal := First_Formal (E);
 998       end if;
 999
1000       while Present (Formal) loop
1001          if Ekind (Formal) = E_In_Parameter then
1002
1003             if Nkind (Parameter_Type (Parent (Formal)))
1004               = N_Access_Definition
1005             then
1006                Generate_Reference (E, Formal, '^', False);
1007             else
1008                Generate_Reference (E, Formal, '>', False);
1009             end if;
1010
1011          elsif Ekind (Formal) = E_In_Out_Parameter then
1012             Generate_Reference (E, Formal, '=', False);
1013
1014          else
1015             Generate_Reference (E, Formal, '<', False);
1016          end if;
1017
1018          Next_Formal (Formal);
1019       end loop;
1020    end Generate_Reference_To_Formals;
1021
1022    -------------------------------------------
1023    -- Generate_Reference_To_Generic_Formals --
1024    -------------------------------------------
1025
1026    procedure Generate_Reference_To_Generic_Formals (E : Entity_Id) is
1027       Formal : Entity_Id;
1028
1029    begin
1030       Formal := First_Entity (E);
1031       while Present (Formal) loop
1032          if Comes_From_Source (Formal) then
1033             Generate_Reference (E, Formal, 'z', False);
1034          end if;
1035
1036          Next_Entity (Formal);
1037       end loop;
1038    end Generate_Reference_To_Generic_Formals;
1039
1040    -------------
1041    -- Get_Key --
1042    -------------
1043
1044    function Get_Key (E : Xref_Entry_Number) return Xref_Entry_Number is
1045    begin
1046       return E;
1047    end Get_Key;
1048
1049    ----------
1050    -- Hash --
1051    ----------
1052
1053    function Hash (F : Xref_Entry_Number) return Header_Num is
1054       --  It is unlikely to have two references to the same entity at the same
1055       --  source location, so the hash function depends only on the Ent and Loc
1056       --  fields.
1057
1058       XE : Xref_Entry renames Xrefs.Table (F);
1059       type M is mod 2**32;
1060
1061       H : constant M := M (XE.Key.Ent) + 2**7 * M (abs XE.Key.Loc);
1062       --  We can't use M'Mod above, because it prevents bootstrapping with
1063       --  older compilers. Loc can be negative, so we do "abs" before
1064       --  converting.
1065    begin
1066       return Header_Num (H mod Num_Buckets);
1067    end Hash;
1068
1069    -----------------
1070    -- HT_Set_Next --
1071    -----------------
1072
1073    procedure HT_Set_Next (E : Xref_Entry_Number; Next : Xref_Entry_Number) is
1074    begin
1075       Xrefs.Table (E).HTable_Next := Next;
1076    end HT_Set_Next;
1077
1078    -------------
1079    -- HT_Next --
1080    -------------
1081
1082    function HT_Next (E : Xref_Entry_Number) return Xref_Entry_Number is
1083    begin
1084       return Xrefs.Table (E).HTable_Next;
1085    end HT_Next;
1086
1087    ----------------
1088    -- Initialize --
1089    ----------------
1090
1091    procedure Initialize is
1092    begin
1093       Xrefs.Init;
1094    end Initialize;
1095
1096    --------
1097    -- Lt --
1098    --------
1099
1100    function Lt (T1, T2 : Xref_Entry) return Boolean is
1101    begin
1102       --  First test: if entity is in different unit, sort by unit
1103
1104       if T1.Key.Eun /= T2.Key.Eun then
1105          return Dependency_Num (T1.Key.Eun) < Dependency_Num (T2.Key.Eun);
1106
1107       --  Second test: within same unit, sort by entity Sloc
1108
1109       elsif T1.Def /= T2.Def then
1110          return T1.Def < T2.Def;
1111
1112       --  Third test: sort definitions ahead of references
1113
1114       elsif T1.Key.Loc = No_Location then
1115          return True;
1116
1117       elsif T2.Key.Loc = No_Location then
1118          return False;
1119
1120       --  Fourth test: for same entity, sort by reference location unit
1121
1122       elsif T1.Key.Lun /= T2.Key.Lun then
1123          return Dependency_Num (T1.Key.Lun) < Dependency_Num (T2.Key.Lun);
1124
1125       --  Fifth test: order of location within referencing unit
1126
1127       elsif T1.Key.Loc /= T2.Key.Loc then
1128          return T1.Key.Loc < T2.Key.Loc;
1129
1130       --  Finally, for two locations at the same address, we prefer
1131       --  the one that does NOT have the type 'r' so that a modification
1132       --  or extension takes preference, when there are more than one
1133       --  reference at the same location. As a result, in the case of
1134       --  entities that are in-out actuals, the read reference follows
1135       --  the modify reference.
1136
1137       else
1138          return T2.Key.Typ = 'r';
1139       end if;
1140    end Lt;
1141
1142    -----------------------
1143    -- Output_References --
1144    -----------------------
1145
1146    procedure Output_References is
1147
1148       procedure Get_Type_Reference
1149         (Ent   : Entity_Id;
1150          Tref  : out Entity_Id;
1151          Left  : out Character;
1152          Right : out Character);
1153       --  Given an Entity_Id Ent, determines whether a type reference is
1154       --  required. If so, Tref is set to the entity for the type reference
1155       --  and Left and Right are set to the left/right brackets to be output
1156       --  for the reference. If no type reference is required, then Tref is
1157       --  set to Empty, and Left/Right are set to space.
1158
1159       procedure Output_Import_Export_Info (Ent : Entity_Id);
1160       --  Output language and external name information for an interfaced
1161       --  entity, using the format <language, external_name>,
1162
1163       ------------------------
1164       -- Get_Type_Reference --
1165       ------------------------
1166
1167       procedure Get_Type_Reference
1168         (Ent   : Entity_Id;
1169          Tref  : out Entity_Id;
1170          Left  : out Character;
1171          Right : out Character)
1172       is
1173          Sav : Entity_Id;
1174
1175       begin
1176          --  See if we have a type reference
1177
1178          Tref := Ent;
1179          Left := '{';
1180          Right := '}';
1181
1182          loop
1183             Sav := Tref;
1184
1185             --  Processing for types
1186
1187             if Is_Type (Tref) then
1188
1189                --  Case of base type
1190
1191                if Base_Type (Tref) = Tref then
1192
1193                   --  If derived, then get first subtype
1194
1195                   if Tref /= Etype (Tref) then
1196                      Tref := First_Subtype (Etype (Tref));
1197
1198                      --  Set brackets for derived type, but don't override
1199                      --  pointer case since the fact that something is a
1200                      --  pointer is more important.
1201
1202                      if Left /= '(' then
1203                         Left := '<';
1204                         Right := '>';
1205                      end if;
1206
1207                   --  If non-derived ptr, get directly designated type.
1208                   --  If the type has a full view, all references are on the
1209                   --  partial view, that is seen first.
1210
1211                   elsif Is_Access_Type (Tref) then
1212                      Tref := Directly_Designated_Type (Tref);
1213                      Left := '(';
1214                      Right := ')';
1215
1216                   elsif Is_Private_Type (Tref)
1217                     and then Present (Full_View (Tref))
1218                   then
1219                      if Is_Access_Type (Full_View (Tref)) then
1220                         Tref := Directly_Designated_Type (Full_View (Tref));
1221                         Left := '(';
1222                         Right := ')';
1223
1224                      --  If the full view is an array type, we also retrieve
1225                      --  the corresponding component type, because the ali
1226                      --  entry already indicates that this is an array.
1227
1228                      elsif Is_Array_Type (Full_View (Tref)) then
1229                         Tref := Component_Type (Full_View (Tref));
1230                         Left := '(';
1231                         Right := ')';
1232                      end if;
1233
1234                   --  If non-derived array, get component type. Skip component
1235                   --  type for case of String or Wide_String, saves worthwhile
1236                   --  space.
1237
1238                   elsif Is_Array_Type (Tref)
1239                     and then Tref /= Standard_String
1240                     and then Tref /= Standard_Wide_String
1241                   then
1242                      Tref := Component_Type (Tref);
1243                      Left := '(';
1244                      Right := ')';
1245
1246                   --  For other non-derived base types, nothing
1247
1248                   else
1249                      exit;
1250                   end if;
1251
1252                --  For a subtype, go to ancestor subtype
1253
1254                else
1255                   Tref := Ancestor_Subtype (Tref);
1256
1257                   --  If no ancestor subtype, go to base type
1258
1259                   if No (Tref) then
1260                      Tref := Base_Type (Sav);
1261                   end if;
1262                end if;
1263
1264             --  For objects, functions, enum literals, just get type from
1265             --  Etype field.
1266
1267             elsif Is_Object (Tref)
1268               or else Ekind (Tref) = E_Enumeration_Literal
1269               or else Ekind (Tref) = E_Function
1270               or else Ekind (Tref) = E_Operator
1271             then
1272                Tref := Etype (Tref);
1273
1274             --  For anything else, exit
1275
1276             else
1277                exit;
1278             end if;
1279
1280             --  Exit if no type reference, or we are stuck in some loop trying
1281             --  to find the type reference, or if the type is standard void
1282             --  type (the latter is an implementation artifact that should not
1283             --  show up in the generated cross-references).
1284
1285             exit when No (Tref)
1286               or else Tref = Sav
1287               or else Tref = Standard_Void_Type;
1288
1289             --  If we have a usable type reference, return, otherwise keep
1290             --  looking for something useful (we are looking for something
1291             --  that either comes from source or standard)
1292
1293             if Sloc (Tref) = Standard_Location
1294               or else Comes_From_Source (Tref)
1295             then
1296                --  If the reference is a subtype created for a generic actual,
1297                --  go actual directly, the inner subtype is not user visible.
1298
1299                if Nkind (Parent (Tref)) = N_Subtype_Declaration
1300                  and then not Comes_From_Source (Parent (Tref))
1301                  and then
1302                   (Is_Wrapper_Package (Scope (Tref))
1303                      or else Is_Generic_Instance (Scope (Tref)))
1304                then
1305                   Tref := First_Subtype (Base_Type (Tref));
1306                end if;
1307
1308                return;
1309             end if;
1310          end loop;
1311
1312          --  If we fall through the loop, no type reference
1313
1314          Tref := Empty;
1315          Left := ' ';
1316          Right := ' ';
1317       end Get_Type_Reference;
1318
1319       -------------------------------
1320       -- Output_Import_Export_Info --
1321       -------------------------------
1322
1323       procedure Output_Import_Export_Info (Ent : Entity_Id) is
1324          Language_Name : Name_Id;
1325          Conv          : constant Convention_Id := Convention (Ent);
1326
1327       begin
1328          --  Generate language name from convention
1329
1330          if Conv  = Convention_C then
1331             Language_Name := Name_C;
1332
1333          elsif Conv = Convention_CPP then
1334             Language_Name := Name_CPP;
1335
1336          elsif Conv = Convention_Ada then
1337             Language_Name := Name_Ada;
1338
1339          else
1340             --  For the moment we ignore all other cases ???
1341
1342             return;
1343          end if;
1344
1345          Write_Info_Char ('<');
1346          Get_Unqualified_Name_String (Language_Name);
1347
1348          for J in 1 .. Name_Len loop
1349             Write_Info_Char (Name_Buffer (J));
1350          end loop;
1351
1352          if Present (Interface_Name (Ent)) then
1353             Write_Info_Char (',');
1354             String_To_Name_Buffer (Strval (Interface_Name (Ent)));
1355
1356             for J in 1 .. Name_Len loop
1357                Write_Info_Char (Name_Buffer (J));
1358             end loop;
1359          end if;
1360
1361          Write_Info_Char ('>');
1362       end Output_Import_Export_Info;
1363
1364    --  Start of processing for Output_References
1365
1366    begin
1367       --  First we add references to the primitive operations of tagged types
1368       --  declared in the main unit.
1369
1370       Handle_Prim_Ops : declare
1371          Ent  : Entity_Id;
1372
1373       begin
1374          for J in 1 .. Xrefs.Last loop
1375             Ent := Xrefs.Table (J).Key.Ent;
1376
1377             if Is_Type (Ent)
1378               and then Is_Tagged_Type (Ent)
1379               and then Is_Base_Type (Ent)
1380               and then In_Extended_Main_Source_Unit (Ent)
1381             then
1382                Generate_Prim_Op_References (Ent);
1383             end if;
1384          end loop;
1385       end Handle_Prim_Ops;
1386
1387       --  Before we go ahead and output the references we have a problem
1388       --  that needs dealing with. So far we have captured things that are
1389       --  definitely referenced by the main unit, or defined in the main
1390       --  unit. That's because we don't want to clutter up the ali file
1391       --  for this unit with definition lines for entities in other units
1392       --  that are not referenced.
1393
1394       --  But there is a glitch. We may reference an entity in another unit,
1395       --  and it may have a type reference to an entity that is not directly
1396       --  referenced in the main unit, which may mean that there is no xref
1397       --  entry for this entity yet in the list of references.
1398
1399       --  If we don't do something about this, we will end with an orphan type
1400       --  reference, i.e. it will point to an entity that does not appear
1401       --  within the generated references in the ali file. That is not good for
1402       --  tools using the xref information.
1403
1404       --  To fix this, we go through the references adding definition entries
1405       --  for any unreferenced entities that can be referenced in a type
1406       --  reference. There is a recursion problem here, and that is dealt with
1407       --  by making sure that this traversal also traverses any entries that
1408       --  get added by the traversal.
1409
1410       Handle_Orphan_Type_References : declare
1411          J    : Nat;
1412          Tref : Entity_Id;
1413          Ent  : Entity_Id;
1414
1415          L, R : Character;
1416          pragma Warnings (Off, L);
1417          pragma Warnings (Off, R);
1418
1419          procedure New_Entry (E : Entity_Id);
1420          --  Make an additional entry into the Xref table for a type entity
1421          --  that is related to the current entity (parent, type ancestor,
1422          --  progenitor, etc.).
1423
1424          ----------------
1425          -- New_Entry --
1426          ----------------
1427
1428          procedure New_Entry (E : Entity_Id) is
1429          begin
1430             pragma Assert (Present (E));
1431
1432             if not Has_Xref_Entry (Implementation_Base_Type (E))
1433               and then Sloc (E) > No_Location
1434             then
1435                Add_Entry
1436                  ((Ent => E,
1437                    Loc => No_Location,
1438                    Typ => Character'First,
1439                    Eun => Get_Source_Unit (Original_Location (Sloc (E))),
1440                    Lun => No_Unit,
1441                    Ref_Scope => Empty,
1442                    Ent_Scope => Empty),
1443                   Ent_Scope_File => No_Unit);
1444             end if;
1445          end New_Entry;
1446
1447       --  Start of processing for Handle_Orphan_Type_References
1448
1449       begin
1450          --  Note that this is not a for loop for a very good reason. The
1451          --  processing of items in the table can add new items to the table,
1452          --  and they must be processed as well.
1453
1454          J := 1;
1455          while J <= Xrefs.Last loop
1456             Ent := Xrefs.Table (J).Key.Ent;
1457             Get_Type_Reference (Ent, Tref, L, R);
1458
1459             if Present (Tref)
1460               and then not Has_Xref_Entry (Tref)
1461               and then Sloc (Tref) > No_Location
1462             then
1463                New_Entry (Tref);
1464
1465                if Is_Record_Type (Ent)
1466                  and then Present (Interfaces (Ent))
1467                then
1468                   --  Add an entry for each one of the given interfaces
1469                   --  implemented by type Ent.
1470
1471                   declare
1472                      Elmt : Elmt_Id := First_Elmt (Interfaces (Ent));
1473                   begin
1474                      while Present (Elmt) loop
1475                         New_Entry (Node (Elmt));
1476                         Next_Elmt (Elmt);
1477                      end loop;
1478                   end;
1479                end if;
1480             end if;
1481
1482             --  Collect inherited primitive operations that may be declared in
1483             --  another unit and have no visible reference in the current one.
1484
1485             if Is_Type (Ent)
1486               and then Is_Tagged_Type (Ent)
1487               and then Is_Derived_Type (Ent)
1488               and then Is_Base_Type (Ent)
1489               and then In_Extended_Main_Source_Unit (Ent)
1490             then
1491                declare
1492                   Op_List : constant Elist_Id := Primitive_Operations (Ent);
1493                   Op      : Elmt_Id;
1494                   Prim    : Entity_Id;
1495
1496                   function Parent_Op (E : Entity_Id) return Entity_Id;
1497                   --  Find original operation, which may be inherited through
1498                   --  several derivations.
1499
1500                   function Parent_Op (E : Entity_Id) return Entity_Id is
1501                      Orig_Op : constant Entity_Id := Alias (E);
1502
1503                   begin
1504                      if No (Orig_Op) then
1505                         return Empty;
1506
1507                      elsif not Comes_From_Source (E)
1508                        and then not Has_Xref_Entry (Orig_Op)
1509                        and then Comes_From_Source (Orig_Op)
1510                      then
1511                         return Orig_Op;
1512                      else
1513                         return Parent_Op (Orig_Op);
1514                      end if;
1515                   end Parent_Op;
1516
1517                begin
1518                   Op := First_Elmt (Op_List);
1519                   while Present (Op) loop
1520                      Prim := Parent_Op (Node (Op));
1521
1522                      if Present (Prim) then
1523                         Add_Entry
1524                           ((Ent => Prim,
1525                             Loc => No_Location,
1526                             Typ => Character'First,
1527                             Eun => Get_Source_Unit (Sloc (Prim)),
1528                             Lun => No_Unit,
1529                             Ref_Scope => Empty,
1530                             Ent_Scope => Empty),
1531                            Ent_Scope_File => No_Unit);
1532                      end if;
1533
1534                      Next_Elmt (Op);
1535                   end loop;
1536                end;
1537             end if;
1538
1539             J := J + 1;
1540          end loop;
1541       end Handle_Orphan_Type_References;
1542
1543       --  Now we have all the references, including those for any embedded
1544       --  type references, so we can sort them, and output them.
1545
1546       Output_Refs : declare
1547
1548          Nrefs : constant Nat := Xrefs.Last;
1549          --  Number of references in table
1550
1551          Rnums : array (0 .. Nrefs) of Nat;
1552          --  This array contains numbers of references in the Xrefs table.
1553          --  This list is sorted in output order. The extra 0'th entry is
1554          --  convenient for the call to sort. When we sort the table, we
1555          --  move the entries in Rnums around, but we do not move the
1556          --  original table entries.
1557
1558          Curxu : Unit_Number_Type;
1559          --  Current xref unit
1560
1561          Curru : Unit_Number_Type;
1562          --  Current reference unit for one entity
1563
1564          Curent : Entity_Id;
1565          --  Current entity
1566
1567          Curnam : String (1 .. Name_Buffer'Length);
1568          Curlen : Natural;
1569          --  Simple name and length of current entity
1570
1571          Curdef : Source_Ptr;
1572          --  Original source location for current entity
1573
1574          Crloc : Source_Ptr;
1575          --  Current reference location
1576
1577          Ctyp : Character;
1578          --  Entity type character
1579
1580          Prevt : Character;
1581          --  reference kind of previous reference
1582
1583          Tref : Entity_Id;
1584          --  Type reference
1585
1586          Rref : Node_Id;
1587          --  Renaming reference
1588
1589          Trunit : Unit_Number_Type;
1590          --  Unit number for type reference
1591
1592          function Lt (Op1, Op2 : Natural) return Boolean;
1593          --  Comparison function for Sort call
1594
1595          function Name_Change (X : Entity_Id) return Boolean;
1596          --  Determines if entity X has a different simple name from Curent
1597
1598          procedure Move (From : Natural; To : Natural);
1599          --  Move procedure for Sort call
1600
1601          package Sorting is new GNAT.Heap_Sort_G (Move, Lt);
1602
1603          --------
1604          -- Lt --
1605          --------
1606
1607          function Lt (Op1, Op2 : Natural) return Boolean is
1608             T1 : Xref_Entry renames Xrefs.Table (Rnums (Nat (Op1)));
1609             T2 : Xref_Entry renames Xrefs.Table (Rnums (Nat (Op2)));
1610
1611          begin
1612             return Lt (T1, T2);
1613          end Lt;
1614
1615          ----------
1616          -- Move --
1617          ----------
1618
1619          procedure Move (From : Natural; To : Natural) is
1620          begin
1621             Rnums (Nat (To)) := Rnums (Nat (From));
1622          end Move;
1623
1624          -----------------
1625          -- Name_Change --
1626          -----------------
1627
1628          --  Why a string comparison here??? Why not compare Name_Id values???
1629
1630          function Name_Change (X : Entity_Id) return Boolean is
1631          begin
1632             Get_Unqualified_Name_String (Chars (X));
1633
1634             if Name_Len /= Curlen then
1635                return True;
1636             else
1637                return Name_Buffer (1 .. Curlen) /= Curnam (1 .. Curlen);
1638             end if;
1639          end Name_Change;
1640
1641       --  Start of processing for Output_Refs
1642
1643       begin
1644          --  Capture the definition Sloc values. We delay doing this till now,
1645          --  since at the time the reference or definition is made, private
1646          --  types may be swapped, and the Sloc value may be incorrect. We
1647          --  also set up the pointer vector for the sort.
1648
1649          for J in 1 .. Nrefs loop
1650             Rnums (J) := J;
1651             Xrefs.Table (J).Def :=
1652               Original_Location (Sloc (Xrefs.Table (J).Key.Ent));
1653          end loop;
1654
1655          --  Sort the references
1656
1657          Sorting.Sort (Integer (Nrefs));
1658
1659          --  Initialize loop through references
1660
1661          Curxu  := No_Unit;
1662          Curent := Empty;
1663          Curdef := No_Location;
1664          Curru  := No_Unit;
1665          Crloc  := No_Location;
1666          Prevt  := 'm';
1667
1668          --  Loop to output references
1669
1670          for Refno in 1 .. Nrefs loop
1671             Output_One_Ref : declare
1672                Ent : Entity_Id;
1673
1674                XE : Xref_Entry renames Xrefs.Table (Rnums (Refno));
1675                --  The current entry to be accessed
1676
1677                Left  : Character;
1678                Right : Character;
1679                --  Used for {} or <> or () for type reference
1680
1681                procedure Check_Type_Reference
1682                  (Ent            : Entity_Id;
1683                   List_Interface : Boolean);
1684                --  Find whether there is a meaningful type reference for
1685                --  Ent, and display it accordingly. If List_Interface is
1686                --  true, then Ent is a progenitor interface of the current
1687                --  type entity being listed. In that case list it as is,
1688                --  without looking for a type reference for it.
1689
1690                procedure Output_Instantiation_Refs (Loc : Source_Ptr);
1691                --  Recursive procedure to output instantiation references for
1692                --  the given source ptr in [file|line[...]] form. No output
1693                --  if the given location is not a generic template reference.
1694
1695                procedure Output_Overridden_Op (Old_E : Entity_Id);
1696                --  For a subprogram that is overriding, display information
1697                --  about the inherited operation that it overrides.
1698
1699                --------------------------
1700                -- Check_Type_Reference --
1701                --------------------------
1702
1703                procedure Check_Type_Reference
1704                  (Ent            : Entity_Id;
1705                   List_Interface : Boolean)
1706                is
1707                begin
1708                   if List_Interface then
1709
1710                      --  This is a progenitor interface of the type for which
1711                      --  xref information is being generated.
1712
1713                      Tref  := Ent;
1714                      Left  := '<';
1715                      Right := '>';
1716
1717                   else
1718                      Get_Type_Reference (Ent, Tref, Left, Right);
1719                   end if;
1720
1721                   if Present (Tref) then
1722
1723                      --  Case of standard entity, output name
1724
1725                      if Sloc (Tref) = Standard_Location then
1726                         Write_Info_Char (Left);
1727                         Write_Info_Name (Chars (Tref));
1728                         Write_Info_Char (Right);
1729
1730                      --  Case of source entity, output location
1731
1732                      else
1733                         Write_Info_Char (Left);
1734                         Trunit := Get_Source_Unit (Sloc (Tref));
1735
1736                         if Trunit /= Curxu then
1737                            Write_Info_Nat (Dependency_Num (Trunit));
1738                            Write_Info_Char ('|');
1739                         end if;
1740
1741                         Write_Info_Nat
1742                           (Int (Get_Logical_Line_Number (Sloc (Tref))));
1743
1744                         declare
1745                            Ent  : Entity_Id;
1746                            Ctyp : Character;
1747
1748                         begin
1749                            Ent := Tref;
1750                            Ctyp := Xref_Entity_Letters (Ekind (Ent));
1751
1752                            if Ctyp = '+'
1753                              and then Present (Full_View (Ent))
1754                            then
1755                               Ent := Underlying_Type (Ent);
1756
1757                               if Present (Ent) then
1758                                  Ctyp := Xref_Entity_Letters (Ekind (Ent));
1759                               end if;
1760                            end if;
1761
1762                            Write_Info_Char (Ctyp);
1763                         end;
1764
1765                         Write_Info_Nat
1766                           (Int (Get_Column_Number (Sloc (Tref))));
1767
1768                         --  If the type comes from an instantiation, add the
1769                         --  corresponding info.
1770
1771                         Output_Instantiation_Refs (Sloc (Tref));
1772                         Write_Info_Char (Right);
1773                      end if;
1774                   end if;
1775                end Check_Type_Reference;
1776
1777                -------------------------------
1778                -- Output_Instantiation_Refs --
1779                -------------------------------
1780
1781                procedure Output_Instantiation_Refs (Loc : Source_Ptr) is
1782                   Iloc : constant Source_Ptr := Instantiation_Location (Loc);
1783                   Lun  : Unit_Number_Type;
1784                   Cu   : constant Unit_Number_Type := Curru;
1785
1786                begin
1787                   --  Nothing to do if this is not an instantiation
1788
1789                   if Iloc = No_Location then
1790                      return;
1791                   end if;
1792
1793                   --  Output instantiation reference
1794
1795                   Write_Info_Char ('[');
1796                   Lun := Get_Source_Unit (Iloc);
1797
1798                   if Lun /= Curru then
1799                      Curru := Lun;
1800                      Write_Info_Nat (Dependency_Num (Curru));
1801                      Write_Info_Char ('|');
1802                   end if;
1803
1804                   Write_Info_Nat (Int (Get_Logical_Line_Number (Iloc)));
1805
1806                   --  Recursive call to get nested instantiations
1807
1808                   Output_Instantiation_Refs (Iloc);
1809
1810                   --  Output final ] after call to get proper nesting
1811
1812                   Write_Info_Char (']');
1813                   Curru := Cu;
1814                   return;
1815                end Output_Instantiation_Refs;
1816
1817                --------------------------
1818                -- Output_Overridden_Op --
1819                --------------------------
1820
1821                procedure Output_Overridden_Op (Old_E : Entity_Id) is
1822                   Op : Entity_Id;
1823
1824                begin
1825                   --  The overridden operation has an implicit declaration
1826                   --  at the point of derivation. What we want to display
1827                   --  is the original operation, which has the actual body
1828                   --  (or abstract declaration) that is being overridden.
1829                   --  The overridden operation is not always set, e.g. when
1830                   --  it is a predefined operator.
1831
1832                   if No (Old_E) then
1833                      return;
1834
1835                   --  Follow alias chain if one is present
1836
1837                   elsif Present (Alias (Old_E)) then
1838
1839                      --  The subprogram may have been implicitly inherited
1840                      --  through several levels of derivation, so find the
1841                      --  ultimate (source) ancestor.
1842
1843                      Op := Ultimate_Alias (Old_E);
1844
1845                   --  Normal case of no alias present
1846
1847                   else
1848                      Op := Old_E;
1849                   end if;
1850
1851                   if Present (Op)
1852                     and then Sloc (Op) /= Standard_Location
1853                   then
1854                      declare
1855                         Loc      : constant Source_Ptr := Sloc (Op);
1856                         Par_Unit : constant Unit_Number_Type :=
1857                                      Get_Source_Unit (Loc);
1858
1859                      begin
1860                         Write_Info_Char ('<');
1861
1862                         if Par_Unit /= Curxu then
1863                            Write_Info_Nat (Dependency_Num (Par_Unit));
1864                            Write_Info_Char ('|');
1865                         end if;
1866
1867                         Write_Info_Nat (Int (Get_Logical_Line_Number (Loc)));
1868                         Write_Info_Char ('p');
1869                         Write_Info_Nat (Int (Get_Column_Number (Loc)));
1870                         Write_Info_Char ('>');
1871                      end;
1872                   end if;
1873                end Output_Overridden_Op;
1874
1875             --  Start of processing for Output_One_Ref
1876
1877             begin
1878                Ent := XE.Key.Ent;
1879                Ctyp := Xref_Entity_Letters (Ekind (Ent));
1880
1881                --  Skip reference if it is the only reference to an entity,
1882                --  and it is an END line reference, and the entity is not in
1883                --  the current extended source. This prevents junk entries
1884                --  consisting only of packages with END lines, where no
1885                --  entity from the package is actually referenced.
1886
1887                if XE.Key.Typ = 'e'
1888                  and then Ent /= Curent
1889                  and then (Refno = Nrefs
1890                             or else
1891                               Ent /= Xrefs.Table (Rnums (Refno + 1)).Key.Ent)
1892                  and then not In_Extended_Main_Source_Unit (Ent)
1893                then
1894                   goto Continue;
1895                end if;
1896
1897                --  For private type, get full view type
1898
1899                if Ctyp = '+'
1900                  and then Present (Full_View (XE.Key.Ent))
1901                then
1902                   Ent := Underlying_Type (Ent);
1903
1904                   if Present (Ent) then
1905                      Ctyp := Xref_Entity_Letters (Ekind (Ent));
1906                   end if;
1907                end if;
1908
1909                --  Special exception for Boolean
1910
1911                if Ctyp = 'E' and then Is_Boolean_Type (Ent) then
1912                   Ctyp := 'B';
1913                end if;
1914
1915                --  For variable reference, get corresponding type
1916
1917                if Ctyp = '*' then
1918                   Ent := Etype (XE.Key.Ent);
1919                   Ctyp := Fold_Lower (Xref_Entity_Letters (Ekind (Ent)));
1920
1921                   --  If variable is private type, get full view type
1922
1923                   if Ctyp = '+'
1924                     and then Present (Full_View (Etype (XE.Key.Ent)))
1925                   then
1926                      Ent := Underlying_Type (Etype (XE.Key.Ent));
1927
1928                      if Present (Ent) then
1929                         Ctyp := Fold_Lower (Xref_Entity_Letters (Ekind (Ent)));
1930                      end if;
1931
1932                   elsif Is_Generic_Type (Ent) then
1933
1934                      --  If the type of the entity is a generic private type,
1935                      --  there is no usable full view, so retain the indication
1936                      --  that this is an object.
1937
1938                      Ctyp := '*';
1939                   end if;
1940
1941                   --  Special handling for access parameters and objects of
1942                   --  an anonymous access type.
1943
1944                   if Ekind_In (Etype (XE.Key.Ent),
1945                                E_Anonymous_Access_Type,
1946                                E_Anonymous_Access_Subprogram_Type,
1947                                E_Anonymous_Access_Protected_Subprogram_Type)
1948                   then
1949                      if Is_Formal (XE.Key.Ent)
1950                        or else Ekind_In (XE.Key.Ent, E_Variable, E_Constant)
1951                      then
1952                         Ctyp := 'p';
1953                      end if;
1954
1955                      --  Special handling for Boolean
1956
1957                   elsif Ctyp = 'e' and then Is_Boolean_Type (Ent) then
1958                      Ctyp := 'b';
1959                   end if;
1960                end if;
1961
1962                --  Special handling for abstract types and operations
1963
1964                if Is_Overloadable (XE.Key.Ent)
1965                  and then Is_Abstract_Subprogram (XE.Key.Ent)
1966                then
1967                   if Ctyp = 'U' then
1968                      Ctyp := 'x';            --  Abstract procedure
1969
1970                   elsif Ctyp = 'V' then
1971                      Ctyp := 'y';            --  Abstract function
1972                   end if;
1973
1974                elsif Is_Type (XE.Key.Ent)
1975                  and then Is_Abstract_Type (XE.Key.Ent)
1976                then
1977                   if Is_Interface (XE.Key.Ent) then
1978                      Ctyp := 'h';
1979
1980                   elsif Ctyp = 'R' then
1981                      Ctyp := 'H';            --  Abstract type
1982                   end if;
1983                end if;
1984
1985                --  Only output reference if interesting type of entity
1986
1987                if Ctyp = ' '
1988
1989                --  Suppress references to object definitions, used for local
1990                --  references.
1991
1992                  or else XE.Key.Typ = 'D'
1993                  or else XE.Key.Typ = 'I'
1994
1995                --  Suppress self references, except for bodies that act as
1996                --  specs.
1997
1998                  or else (XE.Key.Loc = XE.Def
1999                            and then
2000                              (XE.Key.Typ /= 'b'
2001                                or else not Is_Subprogram (XE.Key.Ent)))
2002
2003                --  Also suppress definitions of body formals (we only
2004                --  treat these as references, and the references were
2005                --  separately recorded).
2006
2007                  or else (Is_Formal (XE.Key.Ent)
2008                            and then Present (Spec_Entity (XE.Key.Ent)))
2009                then
2010                   null;
2011
2012                else
2013                   --  Start new Xref section if new xref unit
2014
2015                   if XE.Key.Eun /= Curxu then
2016                      if Write_Info_Col > 1 then
2017                         Write_Info_EOL;
2018                      end if;
2019
2020                      Curxu := XE.Key.Eun;
2021
2022                      Write_Info_Initiate ('X');
2023                      Write_Info_Char (' ');
2024                      Write_Info_Nat (Dependency_Num (XE.Key.Eun));
2025                      Write_Info_Char (' ');
2026                      Write_Info_Name
2027                        (Reference_Name (Source_Index (XE.Key.Eun)));
2028                   end if;
2029
2030                   --  Start new Entity line if new entity. Note that we
2031                   --  consider two entities the same if they have the same
2032                   --  name and source location. This causes entities in
2033                   --  instantiations to be treated as though they referred
2034                   --  to the template.
2035
2036                   if No (Curent)
2037                     or else
2038                       (XE.Key.Ent /= Curent
2039                          and then
2040                            (Name_Change (XE.Key.Ent) or else XE.Def /= Curdef))
2041                   then
2042                      Curent := XE.Key.Ent;
2043                      Curdef := XE.Def;
2044
2045                      Get_Unqualified_Name_String (Chars (XE.Key.Ent));
2046                      Curlen := Name_Len;
2047                      Curnam (1 .. Curlen) := Name_Buffer (1 .. Curlen);
2048
2049                      if Write_Info_Col > 1 then
2050                         Write_Info_EOL;
2051                      end if;
2052
2053                      --  Write column number information
2054
2055                      Write_Info_Nat (Int (Get_Logical_Line_Number (XE.Def)));
2056                      Write_Info_Char (Ctyp);
2057                      Write_Info_Nat (Int (Get_Column_Number (XE.Def)));
2058
2059                      --  Write level information
2060
2061                      Write_Level_Info : declare
2062                         function Is_Visible_Generic_Entity
2063                           (E : Entity_Id) return Boolean;
2064                         --  Check whether E is declared in the visible part
2065                         --  of a generic package. For source navigation
2066                         --  purposes, treat this as a visible entity.
2067
2068                         function Is_Private_Record_Component
2069                           (E : Entity_Id) return Boolean;
2070                         --  Check whether E is a non-inherited component of a
2071                         --  private extension. Even if the enclosing record is
2072                         --  public, we want to treat the component as private
2073                         --  for navigation purposes.
2074
2075                         ---------------------------------
2076                         -- Is_Private_Record_Component --
2077                         ---------------------------------
2078
2079                         function Is_Private_Record_Component
2080                           (E : Entity_Id) return Boolean
2081                         is
2082                            S : constant Entity_Id := Scope (E);
2083                         begin
2084                            return
2085                              Ekind (E) = E_Component
2086                                and then Nkind (Declaration_Node (S)) =
2087                                  N_Private_Extension_Declaration
2088                                and then Original_Record_Component (E) = E;
2089                         end Is_Private_Record_Component;
2090
2091                         -------------------------------
2092                         -- Is_Visible_Generic_Entity --
2093                         -------------------------------
2094
2095                         function Is_Visible_Generic_Entity
2096                           (E : Entity_Id) return Boolean
2097                         is
2098                            Par : Node_Id;
2099
2100                         begin
2101                            --  The Present check here is an error defense
2102
2103                            if Present (Scope (E))
2104                              and then Ekind (Scope (E)) /= E_Generic_Package
2105                            then
2106                               return False;
2107                            end if;
2108
2109                            Par := Parent (E);
2110                            while Present (Par) loop
2111                               if
2112                                 Nkind (Par) = N_Generic_Package_Declaration
2113                               then
2114                                  --  Entity is a generic formal
2115
2116                                  return False;
2117
2118                               elsif
2119                                 Nkind (Parent (Par)) = N_Package_Specification
2120                               then
2121                                  return
2122                                    Is_List_Member (Par)
2123                                      and then List_Containing (Par) =
2124                                        Visible_Declarations (Parent (Par));
2125                               else
2126                                  Par := Parent (Par);
2127                               end if;
2128                            end loop;
2129
2130                            return False;
2131                         end Is_Visible_Generic_Entity;
2132
2133                      --  Start of processing for Write_Level_Info
2134
2135                      begin
2136                         if Is_Hidden (Curent)
2137                           or else Is_Private_Record_Component (Curent)
2138                         then
2139                            Write_Info_Char (' ');
2140
2141                         elsif
2142                            Is_Public (Curent)
2143                              or else Is_Visible_Generic_Entity (Curent)
2144                         then
2145                            Write_Info_Char ('*');
2146
2147                         else
2148                            Write_Info_Char (' ');
2149                         end if;
2150                      end Write_Level_Info;
2151
2152                      --  Output entity name. We use the occurrence from the
2153                      --  actual source program at the definition point.
2154
2155                      declare
2156                         Ent_Name : constant String :=
2157                                      Exact_Source_Name (Sloc (XE.Key.Ent));
2158                      begin
2159                         for C in Ent_Name'Range loop
2160                            Write_Info_Char (Ent_Name (C));
2161                         end loop;
2162                      end;
2163
2164                      --  See if we have a renaming reference
2165
2166                      if Is_Object (XE.Key.Ent)
2167                        and then Present (Renamed_Object (XE.Key.Ent))
2168                      then
2169                         Rref := Renamed_Object (XE.Key.Ent);
2170
2171                      elsif Is_Overloadable (XE.Key.Ent)
2172                        and then Nkind (Parent (Declaration_Node (XE.Key.Ent)))
2173                                            = N_Subprogram_Renaming_Declaration
2174                      then
2175                         Rref := Name (Parent (Declaration_Node (XE.Key.Ent)));
2176
2177                      elsif Ekind (XE.Key.Ent) = E_Package
2178                        and then Nkind (Declaration_Node (XE.Key.Ent)) =
2179                                          N_Package_Renaming_Declaration
2180                      then
2181                         Rref := Name (Declaration_Node (XE.Key.Ent));
2182
2183                      else
2184                         Rref := Empty;
2185                      end if;
2186
2187                      if Present (Rref) then
2188                         if Nkind (Rref) = N_Expanded_Name then
2189                            Rref := Selector_Name (Rref);
2190                         end if;
2191
2192                         if Nkind (Rref) = N_Identifier
2193                           or else Nkind (Rref) = N_Operator_Symbol
2194                         then
2195                            null;
2196
2197                         --  For renamed array components, use the array name
2198                         --  for the renamed entity, which reflect the fact that
2199                         --  in general the whole array is aliased.
2200
2201                         elsif Nkind (Rref) = N_Indexed_Component then
2202                            if Nkind (Prefix (Rref)) = N_Identifier then
2203                               Rref := Prefix (Rref);
2204                            elsif Nkind (Prefix (Rref)) = N_Expanded_Name then
2205                               Rref := Selector_Name (Prefix (Rref));
2206                            else
2207                               Rref := Empty;
2208                            end if;
2209
2210                         else
2211                            Rref := Empty;
2212                         end if;
2213                      end if;
2214
2215                      --  Write out renaming reference if we have one
2216
2217                      if Present (Rref) then
2218                         Write_Info_Char ('=');
2219                         Write_Info_Nat
2220                           (Int (Get_Logical_Line_Number (Sloc (Rref))));
2221                         Write_Info_Char (':');
2222                         Write_Info_Nat
2223                           (Int (Get_Column_Number (Sloc (Rref))));
2224                      end if;
2225
2226                      --  Indicate that the entity is in the unit of the current
2227                      --  xref section.
2228
2229                      Curru := Curxu;
2230
2231                      --  Write out information about generic parent, if entity
2232                      --  is an instance.
2233
2234                      if  Is_Generic_Instance (XE.Key.Ent) then
2235                         declare
2236                            Gen_Par : constant Entity_Id :=
2237                                        Generic_Parent
2238                                          (Specification
2239                                             (Unit_Declaration_Node
2240                                                (XE.Key.Ent)));
2241                            Loc     : constant Source_Ptr := Sloc (Gen_Par);
2242                            Gen_U   : constant Unit_Number_Type :=
2243                                        Get_Source_Unit (Loc);
2244
2245                         begin
2246                            Write_Info_Char ('[');
2247
2248                            if Curru /= Gen_U then
2249                               Write_Info_Nat (Dependency_Num (Gen_U));
2250                               Write_Info_Char ('|');
2251                            end if;
2252
2253                            Write_Info_Nat
2254                              (Int (Get_Logical_Line_Number (Loc)));
2255                            Write_Info_Char (']');
2256                         end;
2257                      end if;
2258
2259                      --  See if we have a type reference and if so output
2260
2261                      Check_Type_Reference (XE.Key.Ent, False);
2262
2263                      --  Additional information for types with progenitors
2264
2265                      if Is_Record_Type (XE.Key.Ent)
2266                        and then Present (Interfaces (XE.Key.Ent))
2267                      then
2268                         declare
2269                            Elmt : Elmt_Id :=
2270                                     First_Elmt (Interfaces (XE.Key.Ent));
2271                         begin
2272                            while Present (Elmt) loop
2273                               Check_Type_Reference (Node (Elmt), True);
2274                               Next_Elmt (Elmt);
2275                            end loop;
2276                         end;
2277
2278                      --  For array types, list index types as well. (This is
2279                      --  not C, indexes have distinct types).
2280
2281                      elsif Is_Array_Type (XE.Key.Ent) then
2282                         declare
2283                            Indx : Node_Id;
2284                         begin
2285                            Indx := First_Index (XE.Key.Ent);
2286                            while Present (Indx) loop
2287                               Check_Type_Reference
2288                                 (First_Subtype (Etype (Indx)), True);
2289                               Next_Index (Indx);
2290                            end loop;
2291                         end;
2292                      end if;
2293
2294                      --  If the entity is an overriding operation, write info
2295                      --  on operation that was overridden.
2296
2297                      if Is_Subprogram (XE.Key.Ent)
2298                        and then Present (Overridden_Operation (XE.Key.Ent))
2299                      then
2300                         Output_Overridden_Op
2301                           (Overridden_Operation (XE.Key.Ent));
2302                      end if;
2303
2304                      --  End of processing for entity output
2305
2306                      Crloc := No_Location;
2307                   end if;
2308
2309                   --  Output the reference if it is not as the same location
2310                   --  as the previous one, or it is a read-reference that
2311                   --  indicates that the entity is an in-out actual in a call.
2312
2313                   if XE.Key.Loc /= No_Location
2314                     and then
2315                       (XE.Key.Loc /= Crloc
2316                         or else (Prevt = 'm' and then  XE.Key.Typ = 'r'))
2317                   then
2318                      Crloc := XE.Key.Loc;
2319                      Prevt := XE.Key.Typ;
2320
2321                      --  Start continuation if line full, else blank
2322
2323                      if Write_Info_Col > 72 then
2324                         Write_Info_EOL;
2325                         Write_Info_Initiate ('.');
2326                      end if;
2327
2328                      Write_Info_Char (' ');
2329
2330                      --  Output file number if changed
2331
2332                      if XE.Key.Lun /= Curru then
2333                         Curru := XE.Key.Lun;
2334                         Write_Info_Nat (Dependency_Num (Curru));
2335                         Write_Info_Char ('|');
2336                      end if;
2337
2338                      Write_Info_Nat
2339                        (Int (Get_Logical_Line_Number (XE.Key.Loc)));
2340                      Write_Info_Char (XE.Key.Typ);
2341
2342                      if Is_Overloadable (XE.Key.Ent)
2343                        and then Is_Imported (XE.Key.Ent)
2344                        and then XE.Key.Typ = 'b'
2345                      then
2346                         Output_Import_Export_Info (XE.Key.Ent);
2347                      end if;
2348
2349                      Write_Info_Nat (Int (Get_Column_Number (XE.Key.Loc)));
2350
2351                      Output_Instantiation_Refs (Sloc (XE.Key.Ent));
2352                   end if;
2353                end if;
2354             end Output_One_Ref;
2355
2356          <<Continue>>
2357             null;
2358          end loop;
2359
2360          Write_Info_EOL;
2361       end Output_Refs;
2362    end Output_References;
2363
2364 begin
2365    --  Reset is necessary because Elmt_Ptr does not default to Null_Ptr,
2366    --  because it's not an access type.
2367
2368    Xref_Set.Reset;
2369 end Lib.Xref;