gcc/ada/lib-xref.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             L I B . X R E F                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1998-2011, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Csets;    use Csets;
  28 with Elists;   use Elists;
  29 with Errout;   use Errout;
  30 with Nlists;   use Nlists;
  31 with Opt;      use Opt;
  32 with Restrict; use Restrict;
  33 with Rident;   use Rident;
  34 with Sem;      use Sem;
  35 with Sem_Aux;  use Sem_Aux;
  36 with Sem_Prag; use Sem_Prag;
  37 with Sem_Util; use Sem_Util;
  38 with Sem_Warn; use Sem_Warn;
  39 with Sinfo;    use Sinfo;
  40 with Sinput;   use Sinput;
  41 with Snames;   use Snames;
  42 with Stringt;  use Stringt;
  43 with Stand;    use Stand;
  44 with Table;    use Table;
  45
  46 with GNAT.Heap_Sort_G;
  47 with GNAT.HTable;
  48
  49 package body Lib.Xref is
  50
  51    ------------------
  52    -- Declarations --
  53    ------------------
  54
  55    --  The Xref table is used to record references. The Loc field is set
  56    --  to No_Location for a definition entry.
  57
  58    subtype Xref_Entry_Number is Int;
  59
  60    type Xref_Key is record
  61       --  These are the components of Xref_Entry that participate in hash
  62       --  lookups.
  63
  64       Ent : Entity_Id;
  65       --  Entity referenced (E parameter to Generate_Reference)
  66
  67       Loc : Source_Ptr;
  68       --  Location of reference (Original_Location (Sloc field of N parameter
  69       --  to Generate_Reference). Set to No_Location for the case of a
  70       --  defining occurrence.
  71
  72       Typ : Character;
  73       --  Reference type (Typ param to Generate_Reference)
  74
  75       Eun : Unit_Number_Type;
  76       --  Unit number corresponding to Ent
  77
  78       Lun : Unit_Number_Type;
  79       --  Unit number corresponding to Loc. Value is undefined and not
  80       --  referenced if Loc is set to No_Location.
  81
  82       --  The following components are only used for Alfa cross-references
  83
  84       Ref_Scope : Entity_Id;
  85       --  Entity of the closest subprogram or package enclosing the reference
  86
  87       Ent_Scope : Entity_Id;
  88       --  Entity of the closest subprogram or package enclosing the definition,
  89       --  which should be located in the same file as the definition itself.
  90    end record;
  91
  92    type Xref_Entry is record
  93       Key : Xref_Key;
  94
  95       Ent_Scope_File : Unit_Number_Type;
  96       --  File for entity Ent_Scope
  97
  98       Def : Source_Ptr;
  99       --  Original source location for entity being referenced. Note that these
 100       --  values are used only during the output process, they are not set when
 101       --  the entries are originally built. This is because private entities
 102       --  can be swapped when the initial call is made.
 103
 104       HTable_Next : Xref_Entry_Number;
 105       --  For use only by Static_HTable
 106    end record;
 107
 108    package Xrefs is new Table.Table (
 109      Table_Component_Type => Xref_Entry,
 110      Table_Index_Type     => Xref_Entry_Number,
 111      Table_Low_Bound      => 1,
 112      Table_Initial        => Alloc.Xrefs_Initial,
 113      Table_Increment      => Alloc.Xrefs_Increment,
 114      Table_Name           => "Xrefs");
 115
 116    --------------
 117    -- Xref_Set --
 118    --------------
 119
 120    --  We keep a set of xref entries, in order to avoid inserting duplicate
 121    --  entries into the above Xrefs table. An entry is in Xref_Set if and only
 122    --  if it is in Xrefs.
 123
 124    Num_Buckets : constant := 2**16;
 125
 126    subtype Header_Num is Integer range 0 .. Num_Buckets - 1;
 127    type Null_Type is null record;
 128    pragma Unreferenced (Null_Type);
 129
 130    function Hash (F : Xref_Entry_Number) return Header_Num;
 131
 132    function Equal (F1, F2 : Xref_Entry_Number) return Boolean;
 133
 134    procedure HT_Set_Next (E : Xref_Entry_Number; Next : Xref_Entry_Number);
 135
 136    function  HT_Next (E : Xref_Entry_Number) return Xref_Entry_Number;
 137
 138    function Get_Key (E : Xref_Entry_Number) return Xref_Entry_Number;
 139
 140    pragma Inline (Hash, Equal, HT_Set_Next, HT_Next, Get_Key);
 141
 142    package Xref_Set is new GNAT.HTable.Static_HTable (
 143      Header_Num,
 144      Element    => Xref_Entry,
 145      Elmt_Ptr   => Xref_Entry_Number,
 146      Null_Ptr   => 0,
 147      Set_Next   => HT_Set_Next,
 148      Next       => HT_Next,
 149      Key        => Xref_Entry_Number,
 150      Get_Key    => Get_Key,
 151      Hash       => Hash,
 152      Equal      => Equal);
 153
 154    ----------------------
 155    -- Alfa Information --
 156    ----------------------
 157
 158    package body Alfa is separate;
 159
 160    ------------------------
 161    --  Local Subprograms --
 162    ------------------------
 163
 164    procedure Generate_Prim_Op_References (Typ : Entity_Id);
 165    --  For a tagged type, generate implicit references to its primitive
 166    --  operations, for source navigation. This is done right before emitting
 167    --  cross-reference information rather than at the freeze point of the type
 168    --  in order to handle late bodies that are primitive operations.
 169
 170    function Lt (T1, T2 : Xref_Entry) return Boolean;
 171    --  Order cross-references
 172
 173    procedure Add_Entry (Key : Xref_Key; Ent_Scope_File : Unit_Number_Type);
 174    --  Add an entry to the tables of Xref_Entries, avoiding duplicates
 175
 176    ---------------
 177    -- Add_Entry --
 178    ---------------
 179
 180    procedure Add_Entry (Key : Xref_Key; Ent_Scope_File : Unit_Number_Type) is
 181    begin
 182       Xrefs.Increment_Last; -- tentative
 183       Xrefs.Table (Xrefs.Last).Key := Key;
 184
 185       --  Set the entry in Xref_Set, and if newly set, keep the above
 186       --  tentative increment.
 187
 188       if Xref_Set.Set_If_Not_Present (Xrefs.Last) then
 189          Xrefs.Table (Xrefs.Last).Ent_Scope_File := Ent_Scope_File;
 190          --  Leave Def and HTable_Next uninitialized
 191
 192          Set_Has_Xref_Entry (Key.Ent);
 193
 194       --  It was already in Xref_Set, so throw away the tentatively-added
 195       --  entry
 196
 197       else
 198          Xrefs.Decrement_Last;
 199       end if;
 200    end Add_Entry;
 201
 202    -----------
 203    -- Equal --
 204    -----------
 205
 206    function Equal (F1, F2 : Xref_Entry_Number) return Boolean is
 207       Result : constant Boolean :=
 208                  Xrefs.Table (F1).Key = Xrefs.Table (F2).Key;
 209    begin
 210       return Result;
 211    end Equal;
 212
 213    -------------------------
 214    -- Generate_Definition --
 215    -------------------------
 216
 217    procedure Generate_Definition (E : Entity_Id) is
 218    begin
 219       pragma Assert (Nkind (E) in N_Entity);
 220
 221       --  Note that we do not test Xref_Entity_Letters here. It is too early
 222       --  to do so, since we are often called before the entity is fully
 223       --  constructed, so that the Ekind is still E_Void.
 224
 225       if Opt.Xref_Active
 226
 227          --  Definition must come from source
 228
 229          --  We make an exception for subprogram child units that have no spec.
 230          --  For these we generate a subprogram declaration for library use,
 231          --  and the corresponding entity does not come from source.
 232          --  Nevertheless, all references will be attached to it and we have
 233          --  to treat is as coming from user code.
 234
 235          and then (Comes_From_Source (E) or else Is_Child_Unit (E))
 236
 237          --  And must have a reasonable source location that is not
 238          --  within an instance (all entities in instances are ignored)
 239
 240          and then Sloc (E) > No_Location
 241          and then Instantiation_Location (Sloc (E)) = No_Location
 242
 243          --  And must be a non-internal name from the main source unit
 244
 245          and then In_Extended_Main_Source_Unit (E)
 246          and then not Is_Internal_Name (Chars (E))
 247       then
 248          Add_Entry
 249            ((Ent => E,
 250              Loc => No_Location,
 251              Typ => ' ',
 252              Eun => Get_Source_Unit (Original_Location (Sloc (E))),
 253              Lun => No_Unit,
 254              Ref_Scope => Empty,
 255              Ent_Scope => Empty),
 256             Ent_Scope_File => No_Unit);
 257
 258          if In_Inlined_Body then
 259             Set_Referenced (E);
 260          end if;
 261       end if;
 262    end Generate_Definition;
 263
 264    ---------------------------------
 265    -- Generate_Operator_Reference --
 266    ---------------------------------
 267
 268    procedure Generate_Operator_Reference
 269      (N : Node_Id;
 270       T : Entity_Id)
 271    is
 272    begin
 273       if not In_Extended_Main_Source_Unit (N) then
 274          return;
 275       end if;
 276
 277       --  If the operator is not a Standard operator, then we generate a real
 278       --  reference to the user defined operator.
 279
 280       if Sloc (Entity (N)) /= Standard_Location then
 281          Generate_Reference (Entity (N), N);
 282
 283          --  A reference to an implicit inequality operator is also a reference
 284          --  to the user-defined equality.
 285
 286          if Nkind (N) = N_Op_Ne
 287            and then not Comes_From_Source (Entity (N))
 288            and then Present (Corresponding_Equality (Entity (N)))
 289          then
 290             Generate_Reference (Corresponding_Equality (Entity (N)), N);
 291          end if;
 292
 293       --  For the case of Standard operators, we mark the result type as
 294       --  referenced. This ensures that in the case where we are using a
 295       --  derived operator, we mark an entity of the unit that implicitly
 296       --  defines this operator as used. Otherwise we may think that no entity
 297       --  of the unit is used. The actual entity marked as referenced is the
 298       --  first subtype, which is the relevant user defined entity.
 299
 300       --  Note: we only do this for operators that come from source. The
 301       --  generated code sometimes reaches for entities that do not need to be
 302       --  explicitly visible (for example, when we expand the code for
 303       --  comparing two record objects, the fields of the record may not be
 304       --  visible).
 305
 306       elsif Comes_From_Source (N) then
 307          Set_Referenced (First_Subtype (T));
 308       end if;
 309    end Generate_Operator_Reference;
 310
 311    ---------------------------------
 312    -- Generate_Prim_Op_References --
 313    ---------------------------------
 314
 315    procedure Generate_Prim_Op_References (Typ : Entity_Id) is
 316       Base_T    : Entity_Id;
 317       Prim      : Elmt_Id;
 318       Prim_List : Elist_Id;
 319
 320    begin
 321       --  Handle subtypes of synchronized types
 322
 323       if Ekind (Typ) = E_Protected_Subtype
 324         or else Ekind (Typ) = E_Task_Subtype
 325       then
 326          Base_T := Etype (Typ);
 327       else
 328          Base_T := Typ;
 329       end if;
 330
 331       --  References to primitive operations are only relevant for tagged types
 332
 333       if not Is_Tagged_Type (Base_T)
 334         or else Is_Class_Wide_Type (Base_T)
 335       then
 336          return;
 337       end if;
 338
 339       --  Ada 2005 (AI-345): For synchronized types generate reference to the
 340       --  wrapper that allow us to dispatch calls through their implemented
 341       --  abstract interface types.
 342
 343       --  The check for Present here is to protect against previously reported
 344       --  critical errors.
 345
 346       Prim_List := Primitive_Operations (Base_T);
 347
 348       if No (Prim_List) then
 349          return;
 350       end if;
 351
 352       Prim := First_Elmt (Prim_List);
 353       while Present (Prim) loop
 354
 355          --  If the operation is derived, get the original for cross-reference
 356          --  reference purposes (it is the original for which we want the xref
 357          --  and for which the comes_from_source test must be performed).
 358
 359          Generate_Reference
 360            (Typ, Ultimate_Alias (Node (Prim)), 'p', Set_Ref => False);
 361          Next_Elmt (Prim);
 362       end loop;
 363    end Generate_Prim_Op_References;
 364
 365    ------------------------
 366    -- Generate_Reference --
 367    ------------------------
 368
 369    procedure Generate_Reference
 370      (E       : Entity_Id;
 371       N       : Node_Id;
 372       Typ     : Character := 'r';
 373       Set_Ref : Boolean   := True;
 374       Force   : Boolean   := False)
 375    is
 376       Nod : Node_Id;
 377       Ref : Source_Ptr;
 378       Def : Source_Ptr;
 379       Ent : Entity_Id;
 380
 381       Actual_Typ : Character := Typ;
 382
 383       Ref_Scope      : Entity_Id;
 384       Ent_Scope      : Entity_Id;
 385       Ent_Scope_File : Unit_Number_Type;
 386
 387       Call   : Node_Id;
 388       Formal : Entity_Id;
 389       --  Used for call to Find_Actual
 390
 391       Kind : Entity_Kind;
 392       --  If Formal is non-Empty, then its Ekind, otherwise E_Void
 393
 394       function Is_On_LHS (Node : Node_Id) return Boolean;
 395       --  Used to check if a node is on the left hand side of an assignment.
 396       --  The following cases are handled:
 397       --
 398       --   Variable    Node is a direct descendant of left hand side of an
 399       --               assignment statement.
 400       --
 401       --   Prefix      Of an indexed or selected component that is present in
 402       --               a subtree rooted by an assignment statement. There is
 403       --               no restriction of nesting of components, thus cases
 404       --               such as A.B (C).D are handled properly. However a prefix
 405       --               of a dereference (either implicit or explicit) is never
 406       --               considered as on a LHS.
 407       --
 408       --   Out param   Same as above cases, but OUT parameter
 409
 410       function OK_To_Set_Referenced return Boolean;
 411       --  Returns True if the Referenced flag can be set. There are a few
 412       --  exceptions where we do not want to set this flag, see body for
 413       --  details of these exceptional cases.
 414
 415       ---------------
 416       -- Is_On_LHS --
 417       ---------------
 418
 419       --  ??? There are several routines here and there that perform a similar
 420       --      (but subtly different) computation, which should be factored:
 421
 422       --      Sem_Util.May_Be_Lvalue
 423       --      Sem_Util.Known_To_Be_Assigned
 424       --      Exp_Ch2.Expand_Entry_Parameter.In_Assignment_Context
 425       --      Exp_Smem.Is_Out_Actual
 426
 427       function Is_On_LHS (Node : Node_Id) return Boolean is
 428          N : Node_Id;
 429          P : Node_Id;
 430          K : Node_Kind;
 431
 432       begin
 433          --  Only identifiers are considered, is this necessary???
 434
 435          if Nkind (Node) /= N_Identifier then
 436             return False;
 437          end if;
 438
 439          --  Immediate return if appeared as OUT parameter
 440
 441          if Kind = E_Out_Parameter then
 442             return True;
 443          end if;
 444
 445          --  Search for assignment statement subtree root
 446
 447          N := Node;
 448          loop
 449             P := Parent (N);
 450             K := Nkind (P);
 451
 452             if K = N_Assignment_Statement then
 453                return Name (P) = N;
 454
 455             --  Check whether the parent is a component and the current node is
 456             --  its prefix, but return False if the current node has an access
 457             --  type, as in that case the selected or indexed component is an
 458             --  implicit dereference, and the LHS is the designated object, not
 459             --  the access object.
 460
 461             --  ??? case of a slice assignment?
 462
 463             --  ??? Note that in some cases this is called too early
 464             --  (see comments in Sem_Ch8.Find_Direct_Name), at a point where
 465             --  the tree is not fully typed yet. In that case we may lack
 466             --  an Etype for N, and we must disable the check for an implicit
 467             --  dereference. If the dereference is on an LHS, this causes a
 468             --  false positive.
 469
 470             elsif (K = N_Selected_Component or else K = N_Indexed_Component)
 471               and then Prefix (P) = N
 472               and then not (Present (Etype (N))
 473                               and then
 474                             Is_Access_Type (Etype (N)))
 475             then
 476                N := P;
 477
 478             --  All other cases, definitely not on left side
 479
 480             else
 481                return False;
 482             end if;
 483          end loop;
 484       end Is_On_LHS;
 485
 486       ---------------------------
 487       -- OK_To_Set_Referenced --
 488       ---------------------------
 489
 490       function OK_To_Set_Referenced return Boolean is
 491          P : Node_Id;
 492
 493       begin
 494          --  A reference from a pragma Unreferenced or pragma Unmodified or
 495          --  pragma Warnings does not cause the Referenced flag to be set.
 496          --  This avoids silly warnings about things being referenced and
 497          --  not assigned when the only reference is from the pragma.
 498
 499          if Nkind (N) = N_Identifier then
 500             P := Parent (N);
 501
 502             if Nkind (P) = N_Pragma_Argument_Association then
 503                P := Parent (P);
 504
 505                if Nkind (P) = N_Pragma then
 506                   if Pragma_Name (P) = Name_Warnings
 507                        or else
 508                      Pragma_Name (P) = Name_Unmodified
 509                        or else
 510                      Pragma_Name (P) = Name_Unreferenced
 511                   then
 512                      return False;
 513                   end if;
 514                end if;
 515
 516             --  A reference to a formal in a named parameter association does
 517             --  not make the formal referenced. Formals that are unused in the
 518             --  subprogram body are properly flagged as such, even if calls
 519             --  elsewhere use named notation.
 520
 521             elsif Nkind (P) = N_Parameter_Association
 522               and then N = Selector_Name (P)
 523             then
 524                return False;
 525             end if;
 526          end if;
 527
 528          return True;
 529       end OK_To_Set_Referenced;
 530
 531    --  Start of processing for Generate_Reference
 532
 533    begin
 534       pragma Assert (Nkind (E) in N_Entity);
 535       Find_Actual (N, Formal, Call);
 536
 537       if Present (Formal) then
 538          Kind := Ekind (Formal);
 539       else
 540          Kind := E_Void;
 541       end if;
 542
 543       --  Check for obsolescent reference to package ASCII. GNAT treats this
 544       --  element of annex J specially since in practice, programs make a lot
 545       --  of use of this feature, so we don't include it in the set of features
 546       --  diagnosed when Warn_On_Obsolescent_Features mode is set. However we
 547       --  are required to note it as a violation of the RM defined restriction.
 548
 549       if E = Standard_ASCII then
 550          Check_Restriction (No_Obsolescent_Features, N);
 551       end if;
 552
 553       --  Check for reference to entity marked with Is_Obsolescent
 554
 555       --  Note that we always allow obsolescent references in the compiler
 556       --  itself and the run time, since we assume that we know what we are
 557       --  doing in such cases. For example the calls in Ada.Characters.Handling
 558       --  to its own obsolescent subprograms are just fine.
 559
 560       --  In any case we do not generate warnings within the extended source
 561       --  unit of the entity in question, since we assume the source unit
 562       --  itself knows what is going on (and for sure we do not want silly
 563       --  warnings, e.g. on the end line of an obsolescent procedure body).
 564
 565       if Is_Obsolescent (E)
 566         and then not GNAT_Mode
 567         and then not In_Extended_Main_Source_Unit (E)
 568       then
 569          Check_Restriction (No_Obsolescent_Features, N);
 570
 571          if Warn_On_Obsolescent_Feature then
 572             Output_Obsolescent_Entity_Warnings (N, E);
 573          end if;
 574       end if;
 575
 576       --  Warn if reference to Ada 2005 entity not in Ada 2005 mode. We only
 577       --  detect real explicit references (modifications and references).
 578
 579       if Comes_From_Source (N)
 580         and then Is_Ada_2005_Only (E)
 581         and then Ada_Version < Ada_2005
 582         and then Warn_On_Ada_2005_Compatibility
 583         and then (Typ = 'm' or else Typ = 'r' or else Typ = 's')
 584       then
 585          Error_Msg_NE ("& is only defined in Ada 2005?", N, E);
 586       end if;
 587
 588       --  Warn if reference to Ada 2012 entity not in Ada 2012 mode. We only
 589       --  detect real explicit references (modifications and references).
 590
 591       if Comes_From_Source (N)
 592         and then Is_Ada_2012_Only (E)
 593         and then Ada_Version < Ada_2012
 594         and then Warn_On_Ada_2012_Compatibility
 595         and then (Typ = 'm' or else Typ = 'r')
 596       then
 597          Error_Msg_NE ("& is only defined in Ada 2012?", N, E);
 598       end if;
 599
 600       --  Never collect references if not in main source unit. However, we omit
 601       --  this test if Typ is 'e' or 'k', since these entries are structural,
 602       --  and it is useful to have them in units that reference packages as
 603       --  well as units that define packages. We also omit the test for the
 604       --  case of 'p' since we want to include inherited primitive operations
 605       --  from other packages.
 606
 607       --  We also omit this test is this is a body reference for a subprogram
 608       --  instantiation. In this case the reference is to the generic body,
 609       --  which clearly need not be in the main unit containing the instance.
 610       --  For the same reason we accept an implicit reference generated for
 611       --  a default in an instance.
 612
 613       if not In_Extended_Main_Source_Unit (N) then
 614          if Typ = 'e'
 615            or else Typ = 'I'
 616            or else Typ = 'p'
 617            or else Typ = 'i'
 618            or else Typ = 'k'
 619            or else (Typ = 'b' and then Is_Generic_Instance (E))
 620          then
 621             null;
 622          else
 623             return;
 624          end if;
 625       end if;
 626
 627       --  For reference type p, the entity must be in main source unit
 628
 629       if Typ = 'p' and then not In_Extended_Main_Source_Unit (E) then
 630          return;
 631       end if;
 632
 633       --  Unless the reference is forced, we ignore references where the
 634       --  reference itself does not come from source.
 635
 636       if not Force and then not Comes_From_Source (N) then
 637          return;
 638       end if;
 639
 640       --  Deal with setting entity as referenced, unless suppressed. Note that
 641       --  we still do Set_Referenced on entities that do not come from source.
 642       --  This situation arises when we have a source reference to a derived
 643       --  operation, where the derived operation itself does not come from
 644       --  source, but we still want to mark it as referenced, since we really
 645       --  are referencing an entity in the corresponding package (this avoids
 646       --  wrong complaints that the package contains no referenced entities).
 647
 648       if Set_Ref then
 649
 650          --  Assignable object appearing on left side of assignment or as
 651          --  an out parameter.
 652
 653          if Is_Assignable (E)
 654            and then Is_On_LHS (N)
 655            and then Ekind (E) /= E_In_Out_Parameter
 656          then
 657             --  For objects that are renamings, just set as simply referenced
 658             --  we do not try to do assignment type tracking in this case.
 659
 660             if Present (Renamed_Object (E)) then
 661                Set_Referenced (E);
 662
 663             --  Out parameter case
 664
 665             elsif Kind = E_Out_Parameter then
 666
 667                --  If warning mode for all out parameters is set, or this is
 668                --  the only warning parameter, then we want to mark this for
 669                --  later warning logic by setting Referenced_As_Out_Parameter
 670
 671                if Warn_On_Modified_As_Out_Parameter (Formal) then
 672                   Set_Referenced_As_Out_Parameter (E, True);
 673                   Set_Referenced_As_LHS (E, False);
 674
 675                --  For OUT parameter not covered by the above cases, we simply
 676                --  regard it as a normal reference (in this case we do not
 677                --  want any of the warning machinery for out parameters).
 678
 679                else
 680                   Set_Referenced (E);
 681                end if;
 682
 683             --  For the left hand of an assignment case, we do nothing here.
 684             --  The processing for Analyze_Assignment_Statement will set the
 685             --  Referenced_As_LHS flag.
 686
 687             else
 688                null;
 689             end if;
 690
 691          --  Check for a reference in a pragma that should not count as a
 692          --  making the variable referenced for warning purposes.
 693
 694          elsif Is_Non_Significant_Pragma_Reference (N) then
 695             null;
 696
 697          --  A reference in an attribute definition clause does not count as a
 698          --  reference except for the case of Address. The reason that 'Address
 699          --  is an exception is that it creates an alias through which the
 700          --  variable may be referenced.
 701
 702          elsif Nkind (Parent (N)) = N_Attribute_Definition_Clause
 703            and then Chars (Parent (N)) /= Name_Address
 704            and then N = Name (Parent (N))
 705          then
 706             null;
 707
 708          --  Constant completion does not count as a reference
 709
 710          elsif Typ = 'c'
 711            and then Ekind (E) = E_Constant
 712          then
 713             null;
 714
 715          --  Record representation clause does not count as a reference
 716
 717          elsif Nkind (N) = N_Identifier
 718            and then Nkind (Parent (N)) = N_Record_Representation_Clause
 719          then
 720             null;
 721
 722          --  Discriminants do not need to produce a reference to record type
 723
 724          elsif Typ = 'd'
 725            and then Nkind (Parent (N)) = N_Discriminant_Specification
 726          then
 727             null;
 728
 729          --  All other cases
 730
 731          else
 732             --  Special processing for IN OUT parameters, where we have an
 733             --  implicit assignment to a simple variable.
 734
 735             if Kind = E_In_Out_Parameter
 736               and then Is_Assignable (E)
 737             then
 738                --  For sure this counts as a normal read reference
 739
 740                Set_Referenced (E);
 741                Set_Last_Assignment (E, Empty);
 742
 743                --  We count it as being referenced as an out parameter if the
 744                --  option is set to warn on all out parameters, except that we
 745                --  have a special exclusion for an intrinsic subprogram, which
 746                --  is most likely an instantiation of Unchecked_Deallocation
 747                --  which we do not want to consider as an assignment since it
 748                --  generates false positives. We also exclude the case of an
 749                --  IN OUT parameter if the name of the procedure is Free,
 750                --  since we suspect similar semantics.
 751
 752                if Warn_On_All_Unread_Out_Parameters
 753                  and then Is_Entity_Name (Name (Call))
 754                  and then not Is_Intrinsic_Subprogram (Entity (Name (Call)))
 755                  and then Chars (Name (Call)) /= Name_Free
 756                then
 757                   Set_Referenced_As_Out_Parameter (E, True);
 758                   Set_Referenced_As_LHS (E, False);
 759                end if;
 760
 761             --  Don't count a recursive reference within a subprogram as a
 762             --  reference (that allows detection of a recursive subprogram
 763             --  whose only references are recursive calls as unreferenced).
 764
 765             elsif Is_Subprogram (E)
 766               and then E = Nearest_Dynamic_Scope (Current_Scope)
 767             then
 768                null;
 769
 770             --  Any other occurrence counts as referencing the entity
 771
 772             elsif OK_To_Set_Referenced then
 773                Set_Referenced (E);
 774
 775                --  If variable, this is an OK reference after an assignment
 776                --  so we can clear the Last_Assignment indication.
 777
 778                if Is_Assignable (E) then
 779                   Set_Last_Assignment (E, Empty);
 780                end if;
 781             end if;
 782          end if;
 783
 784          --  Check for pragma Unreferenced given and reference is within
 785          --  this source unit (occasion for possible warning to be issued).
 786
 787          if Has_Unreferenced (E)
 788            and then In_Same_Extended_Unit (E, N)
 789          then
 790             --  A reference as a named parameter in a call does not count
 791             --  as a violation of pragma Unreferenced for this purpose...
 792
 793             if Nkind (N) = N_Identifier
 794               and then Nkind (Parent (N)) = N_Parameter_Association
 795               and then Selector_Name (Parent (N)) = N
 796             then
 797                null;
 798
 799             --  ... Neither does a reference to a variable on the left side
 800             --  of an assignment.
 801
 802             elsif Is_On_LHS (N) then
 803                null;
 804
 805             --  For entry formals, we want to place the warning message on the
 806             --  corresponding entity in the accept statement. The current scope
 807             --  is the body of the accept, so we find the formal whose name
 808             --  matches that of the entry formal (there is no link between the
 809             --  two entities, and the one in the accept statement is only used
 810             --  for conformance checking).
 811
 812             elsif Ekind (Scope (E)) = E_Entry then
 813                declare
 814                   BE : Entity_Id;
 815
 816                begin
 817                   BE := First_Entity (Current_Scope);
 818                   while Present (BE) loop
 819                      if Chars (BE) = Chars (E) then
 820                         Error_Msg_NE -- CODEFIX
 821                           ("?pragma Unreferenced given for&!", N, BE);
 822                         exit;
 823                      end if;
 824
 825                      Next_Entity (BE);
 826                   end loop;
 827                end;
 828
 829             --  Here we issue the warning, since this is a real reference
 830
 831             else
 832                Error_Msg_NE -- CODEFIX
 833                  ("?pragma Unreferenced given for&!", N, E);
 834             end if;
 835          end if;
 836
 837          --  If this is a subprogram instance, mark as well the internal
 838          --  subprogram in the wrapper package, which may be a visible
 839          --  compilation unit.
 840
 841          if Is_Overloadable (E)
 842            and then Is_Generic_Instance (E)
 843            and then Present (Alias (E))
 844          then
 845             Set_Referenced (Alias (E));
 846          end if;
 847       end if;
 848
 849       --  Generate reference if all conditions are met:
 850
 851       if
 852          --  Cross referencing must be active
 853
 854          Opt.Xref_Active
 855
 856          --  The entity must be one for which we collect references
 857
 858          and then Xref_Entity_Letters (Ekind (E)) /= ' '
 859
 860          --  Both Sloc values must be set to something sensible
 861
 862          and then Sloc (E) > No_Location
 863          and then Sloc (N) > No_Location
 864
 865          --  We ignore references from within an instance, except for default
 866          --  subprograms, for which we generate an implicit reference.
 867
 868          and then
 869            (Instantiation_Location (Sloc (N)) = No_Location or else Typ = 'i')
 870
 871          --  Ignore dummy references
 872
 873         and then Typ /= ' '
 874       then
 875          if Nkind (N) = N_Identifier
 876               or else
 877             Nkind (N) = N_Defining_Identifier
 878               or else
 879             Nkind (N) in N_Op
 880               or else
 881             Nkind (N) = N_Defining_Operator_Symbol
 882               or else
 883             Nkind (N) = N_Operator_Symbol
 884               or else
 885             (Nkind (N) = N_Character_Literal
 886               and then Sloc (Entity (N)) /= Standard_Location)
 887               or else
 888             Nkind (N) = N_Defining_Character_Literal
 889          then
 890             Nod := N;
 891
 892          elsif Nkind (N) = N_Expanded_Name
 893                  or else
 894                Nkind (N) = N_Selected_Component
 895          then
 896             Nod := Selector_Name (N);
 897
 898          else
 899             return;
 900          end if;
 901
 902          --  Normal case of source entity comes from source
 903
 904          if Comes_From_Source (E) then
 905             Ent := E;
 906
 907          --  Entity does not come from source, but is a derived subprogram and
 908          --  the derived subprogram comes from source (after one or more
 909          --  derivations) in which case the reference is to parent subprogram.
 910
 911          elsif Is_Overloadable (E)
 912            and then Present (Alias (E))
 913          then
 914             Ent := Alias (E);
 915             while not Comes_From_Source (Ent) loop
 916                if No (Alias (Ent)) then
 917                   return;
 918                end if;
 919
 920                Ent := Alias (Ent);
 921             end loop;
 922
 923          --  The internally created defining entity for a child subprogram
 924          --  that has no previous spec has valid references.
 925
 926          elsif Is_Overloadable (E)
 927            and then Is_Child_Unit (E)
 928          then
 929             Ent := E;
 930
 931          --  Record components of discriminated subtypes or derived types must
 932          --  be treated as references to the original component.
 933
 934          elsif Ekind (E) = E_Component
 935            and then Comes_From_Source (Original_Record_Component (E))
 936          then
 937             Ent := Original_Record_Component (E);
 938
 939          --  If this is an expanded reference to a discriminant, recover the
 940          --  original discriminant, which gets the reference.
 941
 942          elsif Ekind (E) = E_In_Parameter
 943            and then  Present (Discriminal_Link (E))
 944          then
 945             Ent := Discriminal_Link (E);
 946             Set_Referenced (Ent);
 947
 948          --  Ignore reference to any other entity that is not from source
 949
 950          else
 951             return;
 952          end if;
 953
 954          --  Record reference to entity
 955
 956          Ref := Original_Location (Sloc (Nod));
 957          Def := Original_Location (Sloc (Ent));
 958
 959          if Actual_Typ = 'p'
 960            and then Is_Subprogram (N)
 961            and then Present (Overridden_Operation (N))
 962          then
 963             Actual_Typ := 'P';
 964          end if;
 965
 966          if Alfa_Mode then
 967             Ref_Scope := Alfa.Enclosing_Subprogram_Or_Package (N);
 968             Ent_Scope := Alfa.Enclosing_Subprogram_Or_Package (Ent);
 969             Ent_Scope_File := Get_Source_Unit (Ent_Scope);
 970
 971          else
 972             Ref_Scope := Empty;
 973             Ent_Scope := Empty;
 974             Ent_Scope_File := No_Unit;
 975          end if;
 976
 977          Add_Entry
 978            ((Ent => Ent,
 979              Loc => Ref,
 980              Typ => Actual_Typ,
 981              Eun => Get_Source_Unit (Def),
 982              Lun => Get_Source_Unit (Ref),
 983              Ref_Scope => Ref_Scope,
 984              Ent_Scope => Ent_Scope),
 985             Ent_Scope_File => Ent_Scope_File);
 986       end if;
 987    end Generate_Reference;
 988
 989    -----------------------------------
 990    -- Generate_Reference_To_Formals --
 991    -----------------------------------
 992
 993    procedure Generate_Reference_To_Formals (E : Entity_Id) is
 994       Formal : Entity_Id;
 995
 996    begin
 997       if Is_Generic_Subprogram (E) then
 998          Formal := First_Entity (E);
 999
1000          while Present (Formal)
1001            and then not Is_Formal (Formal)
1002          loop
1003             Next_Entity (Formal);
1004          end loop;
1005
1006       else
1007          Formal := First_Formal (E);
1008       end if;
1009
1010       while Present (Formal) loop
1011          if Ekind (Formal) = E_In_Parameter then
1012
1013             if Nkind (Parameter_Type (Parent (Formal)))
1014               = N_Access_Definition
1015             then
1016                Generate_Reference (E, Formal, '^', False);
1017             else
1018                Generate_Reference (E, Formal, '>', False);
1019             end if;
1020
1021          elsif Ekind (Formal) = E_In_Out_Parameter then
1022             Generate_Reference (E, Formal, '=', False);
1023
1024          else
1025             Generate_Reference (E, Formal, '<', False);
1026          end if;
1027
1028          Next_Formal (Formal);
1029       end loop;
1030    end Generate_Reference_To_Formals;
1031
1032    -------------------------------------------
1033    -- Generate_Reference_To_Generic_Formals --
1034    -------------------------------------------
1035
1036    procedure Generate_Reference_To_Generic_Formals (E : Entity_Id) is
1037       Formal : Entity_Id;
1038
1039    begin
1040       Formal := First_Entity (E);
1041       while Present (Formal) loop
1042          if Comes_From_Source (Formal) then
1043             Generate_Reference (E, Formal, 'z', False);
1044          end if;
1045
1046          Next_Entity (Formal);
1047       end loop;
1048    end Generate_Reference_To_Generic_Formals;
1049
1050    -------------
1051    -- Get_Key --
1052    -------------
1053
1054    function Get_Key (E : Xref_Entry_Number) return Xref_Entry_Number is
1055    begin
1056       return E;
1057    end Get_Key;
1058
1059    ----------
1060    -- Hash --
1061    ----------
1062
1063    function Hash (F : Xref_Entry_Number) return Header_Num is
1064       --  It is unlikely to have two references to the same entity at the same
1065       --  source location, so the hash function depends only on the Ent and Loc
1066       --  fields.
1067
1068       XE : Xref_Entry renames Xrefs.Table (F);
1069       type M is mod 2**32;
1070
1071       H : constant M := M (XE.Key.Ent) + 2 ** 7 * M (abs XE.Key.Loc);
1072       --  It would be more natural to write:
1073       --
1074       --    H : constant M := M'Mod (XE.Key.Ent) + 2**7 * M'Mod (XE.Key.Loc);
1075       --
1076       --  But we can't use M'Mod, because it prevents bootstrapping with older
1077       --  compilers. Loc can be negative, so we do "abs" before converting.
1078       --  One day this can be cleaned up ???
1079
1080    begin
1081       return Header_Num (H mod Num_Buckets);
1082    end Hash;
1083
1084    -----------------
1085    -- HT_Set_Next --
1086    -----------------
1087
1088    procedure HT_Set_Next (E : Xref_Entry_Number; Next : Xref_Entry_Number) is
1089    begin
1090       Xrefs.Table (E).HTable_Next := Next;
1091    end HT_Set_Next;
1092
1093    -------------
1094    -- HT_Next --
1095    -------------
1096
1097    function HT_Next (E : Xref_Entry_Number) return Xref_Entry_Number is
1098    begin
1099       return Xrefs.Table (E).HTable_Next;
1100    end HT_Next;
1101
1102    ----------------
1103    -- Initialize --
1104    ----------------
1105
1106    procedure Initialize is
1107    begin
1108       Xrefs.Init;
1109    end Initialize;
1110
1111    --------
1112    -- Lt --
1113    --------
1114
1115    function Lt (T1, T2 : Xref_Entry) return Boolean is
1116    begin
1117       --  First test: if entity is in different unit, sort by unit
1118
1119       if T1.Key.Eun /= T2.Key.Eun then
1120          return Dependency_Num (T1.Key.Eun) < Dependency_Num (T2.Key.Eun);
1121
1122       --  Second test: within same unit, sort by entity Sloc
1123
1124       elsif T1.Def /= T2.Def then
1125          return T1.Def < T2.Def;
1126
1127       --  Third test: sort definitions ahead of references
1128
1129       elsif T1.Key.Loc = No_Location then
1130          return True;
1131
1132       elsif T2.Key.Loc = No_Location then
1133          return False;
1134
1135       --  Fourth test: for same entity, sort by reference location unit
1136
1137       elsif T1.Key.Lun /= T2.Key.Lun then
1138          return Dependency_Num (T1.Key.Lun) < Dependency_Num (T2.Key.Lun);
1139
1140       --  Fifth test: order of location within referencing unit
1141
1142       elsif T1.Key.Loc /= T2.Key.Loc then
1143          return T1.Key.Loc < T2.Key.Loc;
1144
1145       --  Finally, for two locations at the same address, we prefer
1146       --  the one that does NOT have the type 'r' so that a modification
1147       --  or extension takes preference, when there are more than one
1148       --  reference at the same location. As a result, in the case of
1149       --  entities that are in-out actuals, the read reference follows
1150       --  the modify reference.
1151
1152       else
1153          return T2.Key.Typ = 'r';
1154       end if;
1155    end Lt;
1156
1157    -----------------------
1158    -- Output_References --
1159    -----------------------
1160
1161    procedure Output_References is
1162
1163       procedure Get_Type_Reference
1164         (Ent   : Entity_Id;
1165          Tref  : out Entity_Id;
1166          Left  : out Character;
1167          Right : out Character);
1168       --  Given an Entity_Id Ent, determines whether a type reference is
1169       --  required. If so, Tref is set to the entity for the type reference
1170       --  and Left and Right are set to the left/right brackets to be output
1171       --  for the reference. If no type reference is required, then Tref is
1172       --  set to Empty, and Left/Right are set to space.
1173
1174       procedure Output_Import_Export_Info (Ent : Entity_Id);
1175       --  Output language and external name information for an interfaced
1176       --  entity, using the format <language, external_name>.
1177
1178       ------------------------
1179       -- Get_Type_Reference --
1180       ------------------------
1181
1182       procedure Get_Type_Reference
1183         (Ent   : Entity_Id;
1184          Tref  : out Entity_Id;
1185          Left  : out Character;
1186          Right : out Character)
1187       is
1188          Sav : Entity_Id;
1189
1190       begin
1191          --  See if we have a type reference
1192
1193          Tref := Ent;
1194          Left := '{';
1195          Right := '}';
1196
1197          loop
1198             Sav := Tref;
1199
1200             --  Processing for types
1201
1202             if Is_Type (Tref) then
1203
1204                --  Case of base type
1205
1206                if Base_Type (Tref) = Tref then
1207
1208                   --  If derived, then get first subtype
1209
1210                   if Tref /= Etype (Tref) then
1211                      Tref := First_Subtype (Etype (Tref));
1212
1213                      --  Set brackets for derived type, but don't override
1214                      --  pointer case since the fact that something is a
1215                      --  pointer is more important.
1216
1217                      if Left /= '(' then
1218                         Left := '<';
1219                         Right := '>';
1220                      end if;
1221
1222                   --  If non-derived ptr, get directly designated type.
1223                   --  If the type has a full view, all references are on the
1224                   --  partial view, that is seen first.
1225
1226                   elsif Is_Access_Type (Tref) then
1227                      Tref := Directly_Designated_Type (Tref);
1228                      Left := '(';
1229                      Right := ')';
1230
1231                   elsif Is_Private_Type (Tref)
1232                     and then Present (Full_View (Tref))
1233                   then
1234                      if Is_Access_Type (Full_View (Tref)) then
1235                         Tref := Directly_Designated_Type (Full_View (Tref));
1236                         Left := '(';
1237                         Right := ')';
1238
1239                      --  If the full view is an array type, we also retrieve
1240                      --  the corresponding component type, because the ali
1241                      --  entry already indicates that this is an array.
1242
1243                      elsif Is_Array_Type (Full_View (Tref)) then
1244                         Tref := Component_Type (Full_View (Tref));
1245                         Left := '(';
1246                         Right := ')';
1247                      end if;
1248
1249                   --  If non-derived array, get component type. Skip component
1250                   --  type for case of String or Wide_String, saves worthwhile
1251                   --  space.
1252
1253                   elsif Is_Array_Type (Tref)
1254                     and then Tref /= Standard_String
1255                     and then Tref /= Standard_Wide_String
1256                   then
1257                      Tref := Component_Type (Tref);
1258                      Left := '(';
1259                      Right := ')';
1260
1261                   --  For other non-derived base types, nothing
1262
1263                   else
1264                      exit;
1265                   end if;
1266
1267                --  For a subtype, go to ancestor subtype
1268
1269                else
1270                   Tref := Ancestor_Subtype (Tref);
1271
1272                   --  If no ancestor subtype, go to base type
1273
1274                   if No (Tref) then
1275                      Tref := Base_Type (Sav);
1276                   end if;
1277                end if;
1278
1279             --  For objects, functions, enum literals, just get type from
1280             --  Etype field.
1281
1282             elsif Is_Object (Tref)
1283               or else Ekind (Tref) = E_Enumeration_Literal
1284               or else Ekind (Tref) = E_Function
1285               or else Ekind (Tref) = E_Operator
1286             then
1287                Tref := Etype (Tref);
1288
1289             --  For anything else, exit
1290
1291             else
1292                exit;
1293             end if;
1294
1295             --  Exit if no type reference, or we are stuck in some loop trying
1296             --  to find the type reference, or if the type is standard void
1297             --  type (the latter is an implementation artifact that should not
1298             --  show up in the generated cross-references).
1299
1300             exit when No (Tref)
1301               or else Tref = Sav
1302               or else Tref = Standard_Void_Type;
1303
1304             --  If we have a usable type reference, return, otherwise keep
1305             --  looking for something useful (we are looking for something
1306             --  that either comes from source or standard)
1307
1308             if Sloc (Tref) = Standard_Location
1309               or else Comes_From_Source (Tref)
1310             then
1311                --  If the reference is a subtype created for a generic actual,
1312                --  go actual directly, the inner subtype is not user visible.
1313
1314                if Nkind (Parent (Tref)) = N_Subtype_Declaration
1315                  and then not Comes_From_Source (Parent (Tref))
1316                  and then
1317                   (Is_Wrapper_Package (Scope (Tref))
1318                      or else Is_Generic_Instance (Scope (Tref)))
1319                then
1320                   Tref := First_Subtype (Base_Type (Tref));
1321                end if;
1322
1323                return;
1324             end if;
1325          end loop;
1326
1327          --  If we fall through the loop, no type reference
1328
1329          Tref := Empty;
1330          Left := ' ';
1331          Right := ' ';
1332       end Get_Type_Reference;
1333
1334       -------------------------------
1335       -- Output_Import_Export_Info --
1336       -------------------------------
1337
1338       procedure Output_Import_Export_Info (Ent : Entity_Id) is
1339          Language_Name : Name_Id;
1340          Conv          : constant Convention_Id := Convention (Ent);
1341
1342       begin
1343          --  Generate language name from convention
1344
1345          if Conv  = Convention_C then
1346             Language_Name := Name_C;
1347
1348          elsif Conv = Convention_CPP then
1349             Language_Name := Name_CPP;
1350
1351          elsif Conv = Convention_Ada then
1352             Language_Name := Name_Ada;
1353
1354          else
1355             --  For the moment we ignore all other cases ???
1356
1357             return;
1358          end if;
1359
1360          Write_Info_Char ('<');
1361          Get_Unqualified_Name_String (Language_Name);
1362
1363          for J in 1 .. Name_Len loop
1364             Write_Info_Char (Name_Buffer (J));
1365          end loop;
1366
1367          if Present (Interface_Name (Ent)) then
1368             Write_Info_Char (',');
1369             String_To_Name_Buffer (Strval (Interface_Name (Ent)));
1370
1371             for J in 1 .. Name_Len loop
1372                Write_Info_Char (Name_Buffer (J));
1373             end loop;
1374          end if;
1375
1376          Write_Info_Char ('>');
1377       end Output_Import_Export_Info;
1378
1379    --  Start of processing for Output_References
1380
1381    begin
1382       --  First we add references to the primitive operations of tagged types
1383       --  declared in the main unit.
1384
1385       Handle_Prim_Ops : declare
1386          Ent  : Entity_Id;
1387
1388       begin
1389          for J in 1 .. Xrefs.Last loop
1390             Ent := Xrefs.Table (J).Key.Ent;
1391
1392             if Is_Type (Ent)
1393               and then Is_Tagged_Type (Ent)
1394               and then Is_Base_Type (Ent)
1395               and then In_Extended_Main_Source_Unit (Ent)
1396             then
1397                Generate_Prim_Op_References (Ent);
1398             end if;
1399          end loop;
1400       end Handle_Prim_Ops;
1401
1402       --  Before we go ahead and output the references we have a problem
1403       --  that needs dealing with. So far we have captured things that are
1404       --  definitely referenced by the main unit, or defined in the main
1405       --  unit. That's because we don't want to clutter up the ali file
1406       --  for this unit with definition lines for entities in other units
1407       --  that are not referenced.
1408
1409       --  But there is a glitch. We may reference an entity in another unit,
1410       --  and it may have a type reference to an entity that is not directly
1411       --  referenced in the main unit, which may mean that there is no xref
1412       --  entry for this entity yet in the list of references.
1413
1414       --  If we don't do something about this, we will end with an orphan type
1415       --  reference, i.e. it will point to an entity that does not appear
1416       --  within the generated references in the ali file. That is not good for
1417       --  tools using the xref information.
1418
1419       --  To fix this, we go through the references adding definition entries
1420       --  for any unreferenced entities that can be referenced in a type
1421       --  reference. There is a recursion problem here, and that is dealt with
1422       --  by making sure that this traversal also traverses any entries that
1423       --  get added by the traversal.
1424
1425       Handle_Orphan_Type_References : declare
1426          J    : Nat;
1427          Tref : Entity_Id;
1428          Ent  : Entity_Id;
1429
1430          L, R : Character;
1431          pragma Warnings (Off, L);
1432          pragma Warnings (Off, R);
1433
1434          procedure New_Entry (E : Entity_Id);
1435          --  Make an additional entry into the Xref table for a type entity
1436          --  that is related to the current entity (parent, type ancestor,
1437          --  progenitor, etc.).
1438
1439          ----------------
1440          -- New_Entry --
1441          ----------------
1442
1443          procedure New_Entry (E : Entity_Id) is
1444          begin
1445             pragma Assert (Present (E));
1446
1447             if not Has_Xref_Entry (Implementation_Base_Type (E))
1448               and then Sloc (E) > No_Location
1449             then
1450                Add_Entry
1451                  ((Ent => E,
1452                    Loc => No_Location,
1453                    Typ => Character'First,
1454                    Eun => Get_Source_Unit (Original_Location (Sloc (E))),
1455                    Lun => No_Unit,
1456                    Ref_Scope => Empty,
1457                    Ent_Scope => Empty),
1458                   Ent_Scope_File => No_Unit);
1459             end if;
1460          end New_Entry;
1461
1462       --  Start of processing for Handle_Orphan_Type_References
1463
1464       begin
1465          --  Note that this is not a for loop for a very good reason. The
1466          --  processing of items in the table can add new items to the table,
1467          --  and they must be processed as well.
1468
1469          J := 1;
1470          while J <= Xrefs.Last loop
1471             Ent := Xrefs.Table (J).Key.Ent;
1472             Get_Type_Reference (Ent, Tref, L, R);
1473
1474             if Present (Tref)
1475               and then not Has_Xref_Entry (Tref)
1476               and then Sloc (Tref) > No_Location
1477             then
1478                New_Entry (Tref);
1479
1480                if Is_Record_Type (Ent)
1481                  and then Present (Interfaces (Ent))
1482                then
1483                   --  Add an entry for each one of the given interfaces
1484                   --  implemented by type Ent.
1485
1486                   declare
1487                      Elmt : Elmt_Id := First_Elmt (Interfaces (Ent));
1488                   begin
1489                      while Present (Elmt) loop
1490                         New_Entry (Node (Elmt));
1491                         Next_Elmt (Elmt);
1492                      end loop;
1493                   end;
1494                end if;
1495             end if;
1496
1497             --  Collect inherited primitive operations that may be declared in
1498             --  another unit and have no visible reference in the current one.
1499
1500             if Is_Type (Ent)
1501               and then Is_Tagged_Type (Ent)
1502               and then Is_Derived_Type (Ent)
1503               and then Is_Base_Type (Ent)
1504               and then In_Extended_Main_Source_Unit (Ent)
1505             then
1506                declare
1507                   Op_List : constant Elist_Id := Primitive_Operations (Ent);
1508                   Op      : Elmt_Id;
1509                   Prim    : Entity_Id;
1510
1511                   function Parent_Op (E : Entity_Id) return Entity_Id;
1512                   --  Find original operation, which may be inherited through
1513                   --  several derivations.
1514
1515                   function Parent_Op (E : Entity_Id) return Entity_Id is
1516                      Orig_Op : constant Entity_Id := Alias (E);
1517
1518                   begin
1519                      if No (Orig_Op) then
1520                         return Empty;
1521
1522                      elsif not Comes_From_Source (E)
1523                        and then not Has_Xref_Entry (Orig_Op)
1524                        and then Comes_From_Source (Orig_Op)
1525                      then
1526                         return Orig_Op;
1527                      else
1528                         return Parent_Op (Orig_Op);
1529                      end if;
1530                   end Parent_Op;
1531
1532                begin
1533                   Op := First_Elmt (Op_List);
1534                   while Present (Op) loop
1535                      Prim := Parent_Op (Node (Op));
1536
1537                      if Present (Prim) then
1538                         Add_Entry
1539                           ((Ent => Prim,
1540                             Loc => No_Location,
1541                             Typ => Character'First,
1542                             Eun => Get_Source_Unit (Sloc (Prim)),
1543                             Lun => No_Unit,
1544                             Ref_Scope => Empty,
1545                             Ent_Scope => Empty),
1546                            Ent_Scope_File => No_Unit);
1547                      end if;
1548
1549                      Next_Elmt (Op);
1550                   end loop;
1551                end;
1552             end if;
1553
1554             J := J + 1;
1555          end loop;
1556       end Handle_Orphan_Type_References;
1557
1558       --  Now we have all the references, including those for any embedded
1559       --  type references, so we can sort them, and output them.
1560
1561       Output_Refs : declare
1562
1563          Nrefs : constant Nat := Xrefs.Last;
1564          --  Number of references in table
1565
1566          Rnums : array (0 .. Nrefs) of Nat;
1567          --  This array contains numbers of references in the Xrefs table.
1568          --  This list is sorted in output order. The extra 0'th entry is
1569          --  convenient for the call to sort. When we sort the table, we
1570          --  move the entries in Rnums around, but we do not move the
1571          --  original table entries.
1572
1573          Curxu : Unit_Number_Type;
1574          --  Current xref unit
1575
1576          Curru : Unit_Number_Type;
1577          --  Current reference unit for one entity
1578
1579          Curent : Entity_Id;
1580          --  Current entity
1581
1582          Curnam : String (1 .. Name_Buffer'Length);
1583          Curlen : Natural;
1584          --  Simple name and length of current entity
1585
1586          Curdef : Source_Ptr;
1587          --  Original source location for current entity
1588
1589          Crloc : Source_Ptr;
1590          --  Current reference location
1591
1592          Ctyp : Character;
1593          --  Entity type character
1594
1595          Prevt : Character;
1596          --  reference kind of previous reference
1597
1598          Tref : Entity_Id;
1599          --  Type reference
1600
1601          Rref : Node_Id;
1602          --  Renaming reference
1603
1604          Trunit : Unit_Number_Type;
1605          --  Unit number for type reference
1606
1607          function Lt (Op1, Op2 : Natural) return Boolean;
1608          --  Comparison function for Sort call
1609
1610          function Name_Change (X : Entity_Id) return Boolean;
1611          --  Determines if entity X has a different simple name from Curent
1612
1613          procedure Move (From : Natural; To : Natural);
1614          --  Move procedure for Sort call
1615
1616          package Sorting is new GNAT.Heap_Sort_G (Move, Lt);
1617
1618          --------
1619          -- Lt --
1620          --------
1621
1622          function Lt (Op1, Op2 : Natural) return Boolean is
1623             T1 : Xref_Entry renames Xrefs.Table (Rnums (Nat (Op1)));
1624             T2 : Xref_Entry renames Xrefs.Table (Rnums (Nat (Op2)));
1625
1626          begin
1627             return Lt (T1, T2);
1628          end Lt;
1629
1630          ----------
1631          -- Move --
1632          ----------
1633
1634          procedure Move (From : Natural; To : Natural) is
1635          begin
1636             Rnums (Nat (To)) := Rnums (Nat (From));
1637          end Move;
1638
1639          -----------------
1640          -- Name_Change --
1641          -----------------
1642
1643          --  Why a string comparison here??? Why not compare Name_Id values???
1644
1645          function Name_Change (X : Entity_Id) return Boolean is
1646          begin
1647             Get_Unqualified_Name_String (Chars (X));
1648
1649             if Name_Len /= Curlen then
1650                return True;
1651             else
1652                return Name_Buffer (1 .. Curlen) /= Curnam (1 .. Curlen);
1653             end if;
1654          end Name_Change;
1655
1656       --  Start of processing for Output_Refs
1657
1658       begin
1659          --  Capture the definition Sloc values. We delay doing this till now,
1660          --  since at the time the reference or definition is made, private
1661          --  types may be swapped, and the Sloc value may be incorrect. We
1662          --  also set up the pointer vector for the sort.
1663
1664          for J in 1 .. Nrefs loop
1665             Rnums (J) := J;
1666             Xrefs.Table (J).Def :=
1667               Original_Location (Sloc (Xrefs.Table (J).Key.Ent));
1668          end loop;
1669
1670          --  Sort the references
1671
1672          Sorting.Sort (Integer (Nrefs));
1673
1674          --  Initialize loop through references
1675
1676          Curxu  := No_Unit;
1677          Curent := Empty;
1678          Curdef := No_Location;
1679          Curru  := No_Unit;
1680          Crloc  := No_Location;
1681          Prevt  := 'm';
1682
1683          --  Loop to output references
1684
1685          for Refno in 1 .. Nrefs loop
1686             Output_One_Ref : declare
1687                Ent : Entity_Id;
1688
1689                XE : Xref_Entry renames Xrefs.Table (Rnums (Refno));
1690                --  The current entry to be accessed
1691
1692                Left  : Character;
1693                Right : Character;
1694                --  Used for {} or <> or () for type reference
1695
1696                procedure Check_Type_Reference
1697                  (Ent            : Entity_Id;
1698                   List_Interface : Boolean);
1699                --  Find whether there is a meaningful type reference for
1700                --  Ent, and display it accordingly. If List_Interface is
1701                --  true, then Ent is a progenitor interface of the current
1702                --  type entity being listed. In that case list it as is,
1703                --  without looking for a type reference for it.
1704
1705                procedure Output_Instantiation_Refs (Loc : Source_Ptr);
1706                --  Recursive procedure to output instantiation references for
1707                --  the given source ptr in [file|line[...]] form. No output
1708                --  if the given location is not a generic template reference.
1709
1710                procedure Output_Overridden_Op (Old_E : Entity_Id);
1711                --  For a subprogram that is overriding, display information
1712                --  about the inherited operation that it overrides.
1713
1714                --------------------------
1715                -- Check_Type_Reference --
1716                --------------------------
1717
1718                procedure Check_Type_Reference
1719                  (Ent            : Entity_Id;
1720                   List_Interface : Boolean)
1721                is
1722                begin
1723                   if List_Interface then
1724
1725                      --  This is a progenitor interface of the type for which
1726                      --  xref information is being generated.
1727
1728                      Tref  := Ent;
1729                      Left  := '<';
1730                      Right := '>';
1731
1732                   else
1733                      Get_Type_Reference (Ent, Tref, Left, Right);
1734                   end if;
1735
1736                   if Present (Tref) then
1737
1738                      --  Case of standard entity, output name
1739
1740                      if Sloc (Tref) = Standard_Location then
1741                         Write_Info_Char (Left);
1742                         Write_Info_Name (Chars (Tref));
1743                         Write_Info_Char (Right);
1744
1745                      --  Case of source entity, output location
1746
1747                      else
1748                         Write_Info_Char (Left);
1749                         Trunit := Get_Source_Unit (Sloc (Tref));
1750
1751                         if Trunit /= Curxu then
1752                            Write_Info_Nat (Dependency_Num (Trunit));
1753                            Write_Info_Char ('|');
1754                         end if;
1755
1756                         Write_Info_Nat
1757                           (Int (Get_Logical_Line_Number (Sloc (Tref))));
1758
1759                         declare
1760                            Ent  : Entity_Id;
1761                            Ctyp : Character;
1762
1763                         begin
1764                            Ent := Tref;
1765                            Ctyp := Xref_Entity_Letters (Ekind (Ent));
1766
1767                            if Ctyp = '+'
1768                              and then Present (Full_View (Ent))
1769                            then
1770                               Ent := Underlying_Type (Ent);
1771
1772                               if Present (Ent) then
1773                                  Ctyp := Xref_Entity_Letters (Ekind (Ent));
1774                               end if;
1775                            end if;
1776
1777                            Write_Info_Char (Ctyp);
1778                         end;
1779
1780                         Write_Info_Nat
1781                           (Int (Get_Column_Number (Sloc (Tref))));
1782
1783                         --  If the type comes from an instantiation, add the
1784                         --  corresponding info.
1785
1786                         Output_Instantiation_Refs (Sloc (Tref));
1787                         Write_Info_Char (Right);
1788                      end if;
1789                   end if;
1790                end Check_Type_Reference;
1791
1792                -------------------------------
1793                -- Output_Instantiation_Refs --
1794                -------------------------------
1795
1796                procedure Output_Instantiation_Refs (Loc : Source_Ptr) is
1797                   Iloc : constant Source_Ptr := Instantiation_Location (Loc);
1798                   Lun  : Unit_Number_Type;
1799                   Cu   : constant Unit_Number_Type := Curru;
1800
1801                begin
1802                   --  Nothing to do if this is not an instantiation
1803
1804                   if Iloc = No_Location then
1805                      return;
1806                   end if;
1807
1808                   --  Output instantiation reference
1809
1810                   Write_Info_Char ('[');
1811                   Lun := Get_Source_Unit (Iloc);
1812
1813                   if Lun /= Curru then
1814                      Curru := Lun;
1815                      Write_Info_Nat (Dependency_Num (Curru));
1816                      Write_Info_Char ('|');
1817                   end if;
1818
1819                   Write_Info_Nat (Int (Get_Logical_Line_Number (Iloc)));
1820
1821                   --  Recursive call to get nested instantiations
1822
1823                   Output_Instantiation_Refs (Iloc);
1824
1825                   --  Output final ] after call to get proper nesting
1826
1827                   Write_Info_Char (']');
1828                   Curru := Cu;
1829                   return;
1830                end Output_Instantiation_Refs;
1831
1832                --------------------------
1833                -- Output_Overridden_Op --
1834                --------------------------
1835
1836                procedure Output_Overridden_Op (Old_E : Entity_Id) is
1837                   Op : Entity_Id;
1838
1839                begin
1840                   --  The overridden operation has an implicit declaration
1841                   --  at the point of derivation. What we want to display
1842                   --  is the original operation, which has the actual body
1843                   --  (or abstract declaration) that is being overridden.
1844                   --  The overridden operation is not always set, e.g. when
1845                   --  it is a predefined operator.
1846
1847                   if No (Old_E) then
1848                      return;
1849
1850                   --  Follow alias chain if one is present
1851
1852                   elsif Present (Alias (Old_E)) then
1853
1854                      --  The subprogram may have been implicitly inherited
1855                      --  through several levels of derivation, so find the
1856                      --  ultimate (source) ancestor.
1857
1858                      Op := Ultimate_Alias (Old_E);
1859
1860                   --  Normal case of no alias present
1861
1862                   else
1863                      Op := Old_E;
1864                   end if;
1865
1866                   if Present (Op)
1867                     and then Sloc (Op) /= Standard_Location
1868                   then
1869                      declare
1870                         Loc      : constant Source_Ptr := Sloc (Op);
1871                         Par_Unit : constant Unit_Number_Type :=
1872                                      Get_Source_Unit (Loc);
1873
1874                      begin
1875                         Write_Info_Char ('<');
1876
1877                         if Par_Unit /= Curxu then
1878                            Write_Info_Nat (Dependency_Num (Par_Unit));
1879                            Write_Info_Char ('|');
1880                         end if;
1881
1882                         Write_Info_Nat (Int (Get_Logical_Line_Number (Loc)));
1883                         Write_Info_Char ('p');
1884                         Write_Info_Nat (Int (Get_Column_Number (Loc)));
1885                         Write_Info_Char ('>');
1886                      end;
1887                   end if;
1888                end Output_Overridden_Op;
1889
1890             --  Start of processing for Output_One_Ref
1891
1892             begin
1893                Ent := XE.Key.Ent;
1894                Ctyp := Xref_Entity_Letters (Ekind (Ent));
1895
1896                --  Skip reference if it is the only reference to an entity,
1897                --  and it is an END line reference, and the entity is not in
1898                --  the current extended source. This prevents junk entries
1899                --  consisting only of packages with END lines, where no
1900                --  entity from the package is actually referenced.
1901
1902                if XE.Key.Typ = 'e'
1903                  and then Ent /= Curent
1904                  and then (Refno = Nrefs
1905                             or else
1906                               Ent /= Xrefs.Table (Rnums (Refno + 1)).Key.Ent)
1907                  and then not In_Extended_Main_Source_Unit (Ent)
1908                then
1909                   goto Continue;
1910                end if;
1911
1912                --  For private type, get full view type
1913
1914                if Ctyp = '+'
1915                  and then Present (Full_View (XE.Key.Ent))
1916                then
1917                   Ent := Underlying_Type (Ent);
1918
1919                   if Present (Ent) then
1920                      Ctyp := Xref_Entity_Letters (Ekind (Ent));
1921                   end if;
1922                end if;
1923
1924                --  Special exception for Boolean
1925
1926                if Ctyp = 'E' and then Is_Boolean_Type (Ent) then
1927                   Ctyp := 'B';
1928                end if;
1929
1930                --  For variable reference, get corresponding type
1931
1932                if Ctyp = '*' then
1933                   Ent := Etype (XE.Key.Ent);
1934                   Ctyp := Fold_Lower (Xref_Entity_Letters (Ekind (Ent)));
1935
1936                   --  If variable is private type, get full view type
1937
1938                   if Ctyp = '+'
1939                     and then Present (Full_View (Etype (XE.Key.Ent)))
1940                   then
1941                      Ent := Underlying_Type (Etype (XE.Key.Ent));
1942
1943                      if Present (Ent) then
1944                         Ctyp := Fold_Lower (Xref_Entity_Letters (Ekind (Ent)));
1945                      end if;
1946
1947                   elsif Is_Generic_Type (Ent) then
1948
1949                      --  If the type of the entity is a generic private type,
1950                      --  there is no usable full view, so retain the indication
1951                      --  that this is an object.
1952
1953                      Ctyp := '*';
1954                   end if;
1955
1956                   --  Special handling for access parameters and objects of
1957                   --  an anonymous access type.
1958
1959                   if Ekind_In (Etype (XE.Key.Ent),
1960                                E_Anonymous_Access_Type,
1961                                E_Anonymous_Access_Subprogram_Type,
1962                                E_Anonymous_Access_Protected_Subprogram_Type)
1963                   then
1964                      if Is_Formal (XE.Key.Ent)
1965                        or else Ekind_In (XE.Key.Ent, E_Variable, E_Constant)
1966                      then
1967                         Ctyp := 'p';
1968                      end if;
1969
1970                      --  Special handling for Boolean
1971
1972                   elsif Ctyp = 'e' and then Is_Boolean_Type (Ent) then
1973                      Ctyp := 'b';
1974                   end if;
1975                end if;
1976
1977                --  Special handling for abstract types and operations
1978
1979                if Is_Overloadable (XE.Key.Ent)
1980                  and then Is_Abstract_Subprogram (XE.Key.Ent)
1981                then
1982                   if Ctyp = 'U' then
1983                      Ctyp := 'x';            --  Abstract procedure
1984
1985                   elsif Ctyp = 'V' then
1986                      Ctyp := 'y';            --  Abstract function
1987                   end if;
1988
1989                elsif Is_Type (XE.Key.Ent)
1990                  and then Is_Abstract_Type (XE.Key.Ent)
1991                then
1992                   if Is_Interface (XE.Key.Ent) then
1993                      Ctyp := 'h';
1994
1995                   elsif Ctyp = 'R' then
1996                      Ctyp := 'H';            --  Abstract type
1997                   end if;
1998                end if;
1999
2000                --  Only output reference if interesting type of entity
2001
2002                if Ctyp = ' '
2003
2004                --  Suppress references to object definitions, used for local
2005                --  references.
2006
2007                  or else XE.Key.Typ = 'D'
2008                  or else XE.Key.Typ = 'I'
2009
2010                --  Suppress self references, except for bodies that act as
2011                --  specs.
2012
2013                  or else (XE.Key.Loc = XE.Def
2014                            and then
2015                              (XE.Key.Typ /= 'b'
2016                                or else not Is_Subprogram (XE.Key.Ent)))
2017
2018                --  Also suppress definitions of body formals (we only
2019                --  treat these as references, and the references were
2020                --  separately recorded).
2021
2022                  or else (Is_Formal (XE.Key.Ent)
2023                            and then Present (Spec_Entity (XE.Key.Ent)))
2024                then
2025                   null;
2026
2027                else
2028                   --  Start new Xref section if new xref unit
2029
2030                   if XE.Key.Eun /= Curxu then
2031                      if Write_Info_Col > 1 then
2032                         Write_Info_EOL;
2033                      end if;
2034
2035                      Curxu := XE.Key.Eun;
2036
2037                      Write_Info_Initiate ('X');
2038                      Write_Info_Char (' ');
2039                      Write_Info_Nat (Dependency_Num (XE.Key.Eun));
2040                      Write_Info_Char (' ');
2041                      Write_Info_Name
2042                        (Reference_Name (Source_Index (XE.Key.Eun)));
2043                   end if;
2044
2045                   --  Start new Entity line if new entity. Note that we
2046                   --  consider two entities the same if they have the same
2047                   --  name and source location. This causes entities in
2048                   --  instantiations to be treated as though they referred
2049                   --  to the template.
2050
2051                   if No (Curent)
2052                     or else
2053                       (XE.Key.Ent /= Curent
2054                          and then
2055                            (Name_Change (XE.Key.Ent) or else XE.Def /= Curdef))
2056                   then
2057                      Curent := XE.Key.Ent;
2058                      Curdef := XE.Def;
2059
2060                      Get_Unqualified_Name_String (Chars (XE.Key.Ent));
2061                      Curlen := Name_Len;
2062                      Curnam (1 .. Curlen) := Name_Buffer (1 .. Curlen);
2063
2064                      if Write_Info_Col > 1 then
2065                         Write_Info_EOL;
2066                      end if;
2067
2068                      --  Write column number information
2069
2070                      Write_Info_Nat (Int (Get_Logical_Line_Number (XE.Def)));
2071                      Write_Info_Char (Ctyp);
2072                      Write_Info_Nat (Int (Get_Column_Number (XE.Def)));
2073
2074                      --  Write level information
2075
2076                      Write_Level_Info : declare
2077                         function Is_Visible_Generic_Entity
2078                           (E : Entity_Id) return Boolean;
2079                         --  Check whether E is declared in the visible part
2080                         --  of a generic package. For source navigation
2081                         --  purposes, treat this as a visible entity.
2082
2083                         function Is_Private_Record_Component
2084                           (E : Entity_Id) return Boolean;
2085                         --  Check whether E is a non-inherited component of a
2086                         --  private extension. Even if the enclosing record is
2087                         --  public, we want to treat the component as private
2088                         --  for navigation purposes.
2089
2090                         ---------------------------------
2091                         -- Is_Private_Record_Component --
2092                         ---------------------------------
2093
2094                         function Is_Private_Record_Component
2095                           (E : Entity_Id) return Boolean
2096                         is
2097                            S : constant Entity_Id := Scope (E);
2098                         begin
2099                            return
2100                              Ekind (E) = E_Component
2101                                and then Nkind (Declaration_Node (S)) =
2102                                  N_Private_Extension_Declaration
2103                                and then Original_Record_Component (E) = E;
2104                         end Is_Private_Record_Component;
2105
2106                         -------------------------------
2107                         -- Is_Visible_Generic_Entity --
2108                         -------------------------------
2109
2110                         function Is_Visible_Generic_Entity
2111                           (E : Entity_Id) return Boolean
2112                         is
2113                            Par : Node_Id;
2114
2115                         begin
2116                            --  The Present check here is an error defense
2117
2118                            if Present (Scope (E))
2119                              and then Ekind (Scope (E)) /= E_Generic_Package
2120                            then
2121                               return False;
2122                            end if;
2123
2124                            Par := Parent (E);
2125                            while Present (Par) loop
2126                               if
2127                                 Nkind (Par) = N_Generic_Package_Declaration
2128                               then
2129                                  --  Entity is a generic formal
2130
2131                                  return False;
2132
2133                               elsif
2134                                 Nkind (Parent (Par)) = N_Package_Specification
2135                               then
2136                                  return
2137                                    Is_List_Member (Par)
2138                                      and then List_Containing (Par) =
2139                                        Visible_Declarations (Parent (Par));
2140                               else
2141                                  Par := Parent (Par);
2142                               end if;
2143                            end loop;
2144
2145                            return False;
2146                         end Is_Visible_Generic_Entity;
2147
2148                      --  Start of processing for Write_Level_Info
2149
2150                      begin
2151                         if Is_Hidden (Curent)
2152                           or else Is_Private_Record_Component (Curent)
2153                         then
2154                            Write_Info_Char (' ');
2155
2156                         elsif
2157                            Is_Public (Curent)
2158                              or else Is_Visible_Generic_Entity (Curent)
2159                         then
2160                            Write_Info_Char ('*');
2161
2162                         else
2163                            Write_Info_Char (' ');
2164                         end if;
2165                      end Write_Level_Info;
2166
2167                      --  Output entity name. We use the occurrence from the
2168                      --  actual source program at the definition point.
2169
2170                      declare
2171                         Ent_Name : constant String :=
2172                                      Exact_Source_Name (Sloc (XE.Key.Ent));
2173                      begin
2174                         for C in Ent_Name'Range loop
2175                            Write_Info_Char (Ent_Name (C));
2176                         end loop;
2177                      end;
2178
2179                      --  See if we have a renaming reference
2180
2181                      if Is_Object (XE.Key.Ent)
2182                        and then Present (Renamed_Object (XE.Key.Ent))
2183                      then
2184                         Rref := Renamed_Object (XE.Key.Ent);
2185
2186                      elsif Is_Overloadable (XE.Key.Ent)
2187                        and then Nkind (Parent (Declaration_Node (XE.Key.Ent)))
2188                                            = N_Subprogram_Renaming_Declaration
2189                      then
2190                         Rref := Name (Parent (Declaration_Node (XE.Key.Ent)));
2191
2192                      elsif Ekind (XE.Key.Ent) = E_Package
2193                        and then Nkind (Declaration_Node (XE.Key.Ent)) =
2194                                          N_Package_Renaming_Declaration
2195                      then
2196                         Rref := Name (Declaration_Node (XE.Key.Ent));
2197
2198                      else
2199                         Rref := Empty;
2200                      end if;
2201
2202                      if Present (Rref) then
2203                         if Nkind (Rref) = N_Expanded_Name then
2204                            Rref := Selector_Name (Rref);
2205                         end if;
2206
2207                         if Nkind (Rref) = N_Identifier
2208                           or else Nkind (Rref) = N_Operator_Symbol
2209                         then
2210                            null;
2211
2212                         --  For renamed array components, use the array name
2213                         --  for the renamed entity, which reflect the fact that
2214                         --  in general the whole array is aliased.
2215
2216                         elsif Nkind (Rref) = N_Indexed_Component then
2217                            if Nkind (Prefix (Rref)) = N_Identifier then
2218                               Rref := Prefix (Rref);
2219                            elsif Nkind (Prefix (Rref)) = N_Expanded_Name then
2220                               Rref := Selector_Name (Prefix (Rref));
2221                            else
2222                               Rref := Empty;
2223                            end if;
2224
2225                         else
2226                            Rref := Empty;
2227                         end if;
2228                      end if;
2229
2230                      --  Write out renaming reference if we have one
2231
2232                      if Present (Rref) then
2233                         Write_Info_Char ('=');
2234                         Write_Info_Nat
2235                           (Int (Get_Logical_Line_Number (Sloc (Rref))));
2236                         Write_Info_Char (':');
2237                         Write_Info_Nat
2238                           (Int (Get_Column_Number (Sloc (Rref))));
2239                      end if;
2240
2241                      --  Indicate that the entity is in the unit of the current
2242                      --  xref section.
2243
2244                      Curru := Curxu;
2245
2246                      --  Write out information about generic parent, if entity
2247                      --  is an instance.
2248
2249                      if  Is_Generic_Instance (XE.Key.Ent) then
2250                         declare
2251                            Gen_Par : constant Entity_Id :=
2252                                        Generic_Parent
2253                                          (Specification
2254                                             (Unit_Declaration_Node
2255                                                (XE.Key.Ent)));
2256                            Loc     : constant Source_Ptr := Sloc (Gen_Par);
2257                            Gen_U   : constant Unit_Number_Type :=
2258                                        Get_Source_Unit (Loc);
2259
2260                         begin
2261                            Write_Info_Char ('[');
2262
2263                            if Curru /= Gen_U then
2264                               Write_Info_Nat (Dependency_Num (Gen_U));
2265                               Write_Info_Char ('|');
2266                            end if;
2267
2268                            Write_Info_Nat
2269                              (Int (Get_Logical_Line_Number (Loc)));
2270                            Write_Info_Char (']');
2271                         end;
2272                      end if;
2273
2274                      --  See if we have a type reference and if so output
2275
2276                      Check_Type_Reference (XE.Key.Ent, False);
2277
2278                      --  Additional information for types with progenitors
2279
2280                      if Is_Record_Type (XE.Key.Ent)
2281                        and then Present (Interfaces (XE.Key.Ent))
2282                      then
2283                         declare
2284                            Elmt : Elmt_Id :=
2285                                     First_Elmt (Interfaces (XE.Key.Ent));
2286                         begin
2287                            while Present (Elmt) loop
2288                               Check_Type_Reference (Node (Elmt), True);
2289                               Next_Elmt (Elmt);
2290                            end loop;
2291                         end;
2292
2293                      --  For array types, list index types as well. (This is
2294                      --  not C, indexes have distinct types).
2295
2296                      elsif Is_Array_Type (XE.Key.Ent) then
2297                         declare
2298                            Indx : Node_Id;
2299                         begin
2300                            Indx := First_Index (XE.Key.Ent);
2301                            while Present (Indx) loop
2302                               Check_Type_Reference
2303                                 (First_Subtype (Etype (Indx)), True);
2304                               Next_Index (Indx);
2305                            end loop;
2306                         end;
2307                      end if;
2308
2309                      --  If the entity is an overriding operation, write info
2310                      --  on operation that was overridden.
2311
2312                      if Is_Subprogram (XE.Key.Ent)
2313                        and then Present (Overridden_Operation (XE.Key.Ent))
2314                      then
2315                         Output_Overridden_Op
2316                           (Overridden_Operation (XE.Key.Ent));
2317                      end if;
2318
2319                      --  End of processing for entity output
2320
2321                      Crloc := No_Location;
2322                   end if;
2323
2324                   --  Output the reference if it is not as the same location
2325                   --  as the previous one, or it is a read-reference that
2326                   --  indicates that the entity is an in-out actual in a call.
2327
2328                   if XE.Key.Loc /= No_Location
2329                     and then
2330                       (XE.Key.Loc /= Crloc
2331                         or else (Prevt = 'm' and then  XE.Key.Typ = 'r'))
2332                   then
2333                      Crloc := XE.Key.Loc;
2334                      Prevt := XE.Key.Typ;
2335
2336                      --  Start continuation if line full, else blank
2337
2338                      if Write_Info_Col > 72 then
2339                         Write_Info_EOL;
2340                         Write_Info_Initiate ('.');
2341                      end if;
2342
2343                      Write_Info_Char (' ');
2344
2345                      --  Output file number if changed
2346
2347                      if XE.Key.Lun /= Curru then
2348                         Curru := XE.Key.Lun;
2349                         Write_Info_Nat (Dependency_Num (Curru));
2350                         Write_Info_Char ('|');
2351                      end if;
2352
2353                      Write_Info_Nat
2354                        (Int (Get_Logical_Line_Number (XE.Key.Loc)));
2355                      Write_Info_Char (XE.Key.Typ);
2356
2357                      if Is_Overloadable (XE.Key.Ent)
2358                        and then Is_Imported (XE.Key.Ent)
2359                        and then XE.Key.Typ = 'b'
2360                      then
2361                         Output_Import_Export_Info (XE.Key.Ent);
2362                      end if;
2363
2364                      Write_Info_Nat (Int (Get_Column_Number (XE.Key.Loc)));
2365
2366                      Output_Instantiation_Refs (Sloc (XE.Key.Ent));
2367                   end if;
2368                end if;
2369             end Output_One_Ref;
2370
2371          <<Continue>>
2372             null;
2373          end loop;
2374
2375          Write_Info_EOL;
2376       end Output_Refs;
2377    end Output_References;
2378
2379 begin
2380    --  Reset is necessary because Elmt_Ptr does not default to Null_Ptr,
2381    --  because it's not an access type.
2382
2383    Xref_Set.Reset;
2384 end Lib.Xref;