gcc/ada/prj-util.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              P R J . U T I L                             --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --             Copyright (C) 2001-2004 Free Software Foundation, Inc.       --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 --  Utilities for use in processing project files
  28
  29 with Types; use Types;
  30
  31 with GNAT.OS_Lib; use GNAT.OS_Lib;
  32
  33 package Prj.Util is
  34
  35    function Executable_Of
  36      (Project  : Project_Id;
  37       Main     : Name_Id;
  38       Index    : Int;
  39       Ada_Main : Boolean := True) return Name_Id;
  40    --  Return the value of the attribute Builder'Executable for file Main in
  41    --  the project Project, if it exists. If there is no attribute Executable
  42    --  for Main, remove the suffix from Main; then, if the attribute
  43    --  Executable_Suffix is specified, add this suffix, otherwise add the
  44    --  standard executable suffix for the platform.
  45
  46    function Value_Of
  47      (Variable : Variable_Value;
  48       Default  : String) return String;
  49    --  Get the value of a single string variable. If Variable is
  50    --  Nil_Variable_Value, is a string list or is defaulted, return Default.
  51
  52    function Value_Of
  53      (Index    : Name_Id;
  54       In_Array : Array_Element_Id) return Name_Id;
  55    --  Get a single string array component. Returns No_Name if there is no
  56    --  component Index, if In_Array is null, or if the component is a String
  57    --  list. Depending on the attribute (only attributes may be associative
  58    --  arrays) the index may or may not be case sensitive. If the index is not
  59    --  case sensitive, it is first set to lower case before the search in the
  60    --  associative array.
  61
  62    function Value_Of
  63      (Index     : Name_Id;
  64       Src_Index : Int := 0;
  65       In_Array  : Array_Element_Id) return Variable_Value;
  66    --  Get a string array component (single String or String list).
  67    --  Returns Nil_Variable_Value if there is no component Index
  68    --  or if In_Array is null.
  69    --
  70    --  Depending on the attribute (only attributes may be associative arrays)
  71    --  the index may or may not be case sensitive. If the index is not
  72    --  case sensitive, it is first set to lower case before the search
  73    --  in the associative array.
  74
  75    function Value_Of
  76      (Name                    : Name_Id;
  77       Index                   : Int := 0;
  78       Attribute_Or_Array_Name : Name_Id;
  79       In_Package              : Package_Id) return Variable_Value;
  80    --  In a specific package,
  81    --   - if there exists an array Attribute_Or_Array_Name with an index
  82    --     Name, returns the corresponding component (depending on the
  83    --     attribute, the index may or may not be case sensitive, see previous
  84    --     function),
  85    --   - otherwise if there is a single attribute Attribute_Or_Array_Name,
  86    --     returns this attribute,
  87    --   - otherwise, returns Nil_Variable_Value.
  88    --  If In_Package is null, returns Nil_Variable_Value.
  89
  90    function Value_Of
  91      (Index     : Name_Id;
  92       In_Array  : Name_Id;
  93       In_Arrays : Array_Id) return Name_Id;
  94    --  Get a string array component in an array of an array list.
  95    --  Returns No_Name if there is no component Index, if In_Arrays is null, if
  96    --  In_Array is not found in In_Arrays or if the component is a String list.
  97
  98    function Value_Of
  99      (Name      : Name_Id;
 100       In_Arrays : Array_Id) return Array_Element_Id;
 101    --  Returns a specified array in an array list. Returns No_Array_Element
 102    --  if In_Arrays is null or if Name is not the name of an array in
 103    --  In_Arrays. The caller must ensure that Name is in lower case.
 104
 105    function Value_Of
 106      (Name        : Name_Id;
 107       In_Packages : Package_Id) return Package_Id;
 108    --  Returns a specified package in a package list. Returns No_Package
 109    --  if In_Packages is null or if Name is not the name of a package in
 110    --  Package_List. The caller must ensure that Name is in lower case.
 111
 112    function Value_Of
 113      (Variable_Name : Name_Id;
 114       In_Variables  : Variable_Id) return Variable_Value;
 115    --  Returns a specified variable in a variable list. Returns null if
 116    --  In_Variables is null or if Variable_Name is not the name of a
 117    --  variable in In_Variables. Caller must ensure that Name is lower case.
 118
 119    procedure Write_Str
 120      (S          : String;
 121       Max_Length : Positive;
 122       Separator  : Character);
 123    --  Output string S using Output.Write_Str. If S is too long to fit in
 124    --  one line of Max_Length, cut it in several lines, using Separator as
 125    --  the last character of each line, if possible.
 126
 127    type Text_File is limited private;
 128    --  Represents a text file. Default is invalid text file.
 129
 130    function Is_Valid (File : Text_File) return Boolean;
 131    --  Returns True if File designates an open text file that
 132    --  has not yet been closed.
 133
 134    procedure Open (File : out Text_File; Name : String);
 135    --  Open a text file. If this procedure fails, File is invalid.
 136
 137    function End_Of_File (File : Text_File) return Boolean;
 138    --  Returns True if the end of the text file File has been
 139    --  reached. Fails if File is invalid.
 140
 141    procedure Get_Line
 142      (File : Text_File;
 143       Line : out String;
 144       Last : out Natural);
 145    --  Reads a line from an open text file. Fails if File is invalid.
 146
 147    procedure Close (File : in out Text_File);
 148    --  Close an open text file. File becomes invalid.
 149    --  Fails if File is already invalid.
 150
 151 private
 152
 153    type Text_File_Data is record
 154       FD                  : File_Descriptor := Invalid_FD;
 155       Buffer              : String (1 .. 1_000);
 156       Buffer_Len          : Natural;
 157       Cursor              : Natural := 0;
 158       End_Of_File_Reached : Boolean := False;
 159    end record;
 160
 161    type Text_File is access Text_File_Data;
 162
 163 end Prj.Util;