gcc/ada/prj.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                                  P R J                                   --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2001-2008, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Ada.Characters.Handling; use Ada.Characters.Handling;
  27
  28 with Debug;
  29 with Output;   use Output;
  30 with Osint;    use Osint;
  31 with Prj.Attr;
  32 with Prj.Env;
  33 with Prj.Err;  use Prj.Err;
  34 with Snames;   use Snames;
  35 with Table;
  36 with Uintp;    use Uintp;
  37
  38 with System.Case_Util; use System.Case_Util;
  39 with System.HTable;
  40
  41 package body Prj is
  42
  43    Object_Suffix : constant String := Get_Target_Object_Suffix.all;
  44    --  File suffix for object files
  45
  46    Initial_Buffer_Size : constant := 100;
  47    --  Initial size for extensible buffer used in Add_To_Buffer
  48
  49    Current_Mode : Mode := Ada_Only;
  50
  51    Configuration_Mode : Boolean := False;
  52
  53    The_Empty_String : Name_Id;
  54
  55    Default_Ada_Spec_Suffix_Id : File_Name_Type;
  56    Default_Ada_Body_Suffix_Id : File_Name_Type;
  57    Slash_Id                   : Path_Name_Type;
  58    --  Initialized in Prj.Initialize, then never modified
  59
  60    subtype Known_Casing is Casing_Type range All_Upper_Case .. Mixed_Case;
  61
  62    The_Casing_Images : constant array (Known_Casing) of String_Access :=
  63      (All_Lower_Case => new String'("lowercase"),
  64       All_Upper_Case => new String'("UPPERCASE"),
  65       Mixed_Case     => new String'("MixedCase"));
  66
  67    Initialized : Boolean := False;
  68
  69    Standard_Dot_Replacement : constant File_Name_Type :=
  70                                 File_Name_Type
  71                                   (First_Name_Id + Character'Pos ('-'));
  72
  73    Std_Naming_Data : constant Naming_Data :=
  74                        (Dot_Replacement           => Standard_Dot_Replacement,
  75                         Dot_Repl_Loc              => No_Location,
  76                         Casing                    => All_Lower_Case,
  77                         Spec_Suffix               => No_Array_Element,
  78                         Ada_Spec_Suffix_Loc       => No_Location,
  79                         Body_Suffix               => No_Array_Element,
  80                         Ada_Body_Suffix_Loc       => No_Location,
  81                         Separate_Suffix           => No_File,
  82                         Sep_Suffix_Loc            => No_Location,
  83                         Specs                     => No_Array_Element,
  84                         Bodies                    => No_Array_Element,
  85                         Specification_Exceptions  => No_Array_Element,
  86                         Implementation_Exceptions => No_Array_Element);
  87
  88    Project_Empty : constant Project_Data :=
  89                      (Qualifier                      => Unspecified,
  90                       Externally_Built               => False,
  91                       Config                         => Default_Project_Config,
  92                       Languages                      => No_Name_List,
  93                       First_Referred_By              => No_Project,
  94                       Name                           => No_Name,
  95                       Display_Name                   => No_Name,
  96                       Path                           => No_Path_Information,
  97                       Virtual                        => False,
  98                       Location                       => No_Location,
  99                       Mains                          => Nil_String,
 100                       Directory                      => No_Path_Information,
 101                       Dir_Path                       => null,
 102                       Library                        => False,
 103                       Library_Dir                    => No_Path_Information,
 104                       Library_Src_Dir                => No_Path_Information,
 105                       Library_ALI_Dir                => No_Path_Information,
 106                       Library_Name                   => No_Name,
 107                       Library_Kind                   => Static,
 108                       Lib_Internal_Name              => No_Name,
 109                       Standalone_Library             => False,
 110                       Lib_Interface_ALIs             => Nil_String,
 111                       Lib_Auto_Init                  => False,
 112                       Libgnarl_Needed                => Unknown,
 113                       Symbol_Data                    => No_Symbols,
 114                       Ada_Sources_Present            => True,
 115                       Other_Sources_Present          => True,
 116                       Ada_Sources                    => Nil_String,
 117                       Sources                        => Nil_String,
 118                       First_Source                   => No_Source,
 119                       Last_Source                    => No_Source,
 120                       Interfaces_Defined             => False,
 121                       Unit_Based_Language_Name       => No_Name,
 122                       Unit_Based_Language_Index      => No_Language_Index,
 123                       Imported_Directories_Switches  => null,
 124                       Include_Path                   => null,
 125                       Include_Data_Set               => False,
 126                       Include_Language               => No_Language_Index,
 127                       Source_Dirs                    => Nil_String,
 128                       Known_Order_Of_Source_Dirs     => True,
 129                       Object_Directory               => No_Path_Information,
 130                       Library_TS                     => Empty_Time_Stamp,
 131                       Exec_Directory                 => No_Path_Information,
 132                       Extends                        => No_Project,
 133                       Extended_By                    => No_Project,
 134                       Naming                         => Std_Naming_Data,
 135                       First_Language_Processing      => No_Language_Index,
 136                       Decl                           => No_Declarations,
 137                       Imported_Projects              => Empty_Project_List,
 138                       All_Imported_Projects          => Empty_Project_List,
 139                       Ada_Include_Path               => null,
 140                       Ada_Objects_Path               => null,
 141                       Objects_Path                   => null,
 142                       Include_Path_File              => No_Path,
 143                       Objects_Path_File_With_Libs    => No_Path,
 144                       Objects_Path_File_Without_Libs => No_Path,
 145                       Config_File_Name               => No_Path,
 146                       Config_File_Temp               => False,
 147                       Linker_Name                    => No_File,
 148                       Linker_Path                    => No_Path,
 149                       Minimum_Linker_Options         => No_Name_List,
 150                       Config_Checked                 => False,
 151                       Checked                        => False,
 152                       Seen                           => False,
 153                       Need_To_Build_Lib              => False,
 154                       Depth                          => 0,
 155                       Unkept_Comments                => False);
 156
 157    package Temp_Files is new Table.Table
 158      (Table_Component_Type => Path_Name_Type,
 159       Table_Index_Type     => Integer,
 160       Table_Low_Bound      => 1,
 161       Table_Initial        => 20,
 162       Table_Increment      => 100,
 163       Table_Name           => "Makegpr.Temp_Files");
 164    --  Table to store the path name of all the created temporary files, so that
 165    --  they can be deleted at the end, or when the program is interrupted.
 166
 167    -------------------
 168    -- Add_To_Buffer --
 169    -------------------
 170
 171    procedure Add_To_Buffer
 172      (S    : String;
 173       To   : in out String_Access;
 174       Last : in out Natural)
 175    is
 176    begin
 177       if To = null then
 178          To := new String (1 .. Initial_Buffer_Size);
 179          Last := 0;
 180       end if;
 181
 182       --  If Buffer is too small, double its size
 183
 184       while Last + S'Length > To'Last loop
 185          declare
 186             New_Buffer : constant  String_Access :=
 187                            new String (1 .. 2 * Last);
 188
 189          begin
 190             New_Buffer (1 .. Last) := To (1 .. Last);
 191             Free (To);
 192             To := New_Buffer;
 193          end;
 194       end loop;
 195
 196       To (Last + 1 .. Last + S'Length) := S;
 197       Last := Last + S'Length;
 198    end Add_To_Buffer;
 199
 200    -----------------------
 201    -- Body_Suffix_Id_Of --
 202    -----------------------
 203
 204    function Body_Suffix_Id_Of
 205      (In_Tree  : Project_Tree_Ref;
 206       Language : String;
 207       Naming   : Naming_Data) return File_Name_Type
 208    is
 209       Language_Id : Name_Id;
 210
 211    begin
 212       Name_Len := 0;
 213       Add_Str_To_Name_Buffer (Language);
 214       To_Lower (Name_Buffer (1 .. Name_Len));
 215       Language_Id := Name_Find;
 216
 217       return
 218         Body_Suffix_Id_Of
 219           (In_Tree     => In_Tree,
 220            Language_Id => Language_Id,
 221            Naming      => Naming);
 222    end Body_Suffix_Id_Of;
 223
 224    -----------------------
 225    -- Body_Suffix_Id_Of --
 226    -----------------------
 227
 228    function Body_Suffix_Id_Of
 229      (In_Tree     : Project_Tree_Ref;
 230       Language_Id : Name_Id;
 231       Naming      : Naming_Data) return File_Name_Type
 232    is
 233       Element_Id : Array_Element_Id;
 234       Element    : Array_Element;
 235       Suffix     : File_Name_Type := No_File;
 236       Lang       : Language_Index;
 237
 238    begin
 239       --  ??? This seems to be only for Ada_Only mode...
 240       Element_Id := Naming.Body_Suffix;
 241       while Element_Id /= No_Array_Element loop
 242          Element := In_Tree.Array_Elements.Table (Element_Id);
 243
 244          if Element.Index = Language_Id then
 245             return File_Name_Type (Element.Value.Value);
 246          end if;
 247
 248          Element_Id := Element.Next;
 249       end loop;
 250
 251       if Current_Mode = Multi_Language then
 252          Lang := In_Tree.First_Language;
 253          while Lang /= No_Language_Index loop
 254             if In_Tree.Languages_Data.Table (Lang).Name = Language_Id then
 255                Suffix :=
 256                  In_Tree.Languages_Data.Table
 257                    (Lang).Config.Naming_Data.Body_Suffix;
 258                exit;
 259             end if;
 260
 261             Lang := In_Tree.Languages_Data.Table (Lang).Next;
 262          end loop;
 263       end if;
 264
 265       return Suffix;
 266    end Body_Suffix_Id_Of;
 267
 268    --------------------
 269    -- Body_Suffix_Of --
 270    --------------------
 271
 272    function Body_Suffix_Of
 273      (In_Tree  : Project_Tree_Ref;
 274       Language : String;
 275       Naming   : Naming_Data) return String
 276    is
 277       Language_Id : Name_Id;
 278       Element_Id  : Array_Element_Id;
 279       Element     : Array_Element;
 280       Suffix      : File_Name_Type := No_File;
 281       Lang        : Language_Index;
 282
 283    begin
 284       Name_Len := 0;
 285       Add_Str_To_Name_Buffer (Language);
 286       To_Lower (Name_Buffer (1 .. Name_Len));
 287       Language_Id := Name_Find;
 288
 289       Element_Id := Naming.Body_Suffix;
 290       while Element_Id /= No_Array_Element loop
 291          Element := In_Tree.Array_Elements.Table (Element_Id);
 292
 293          if Element.Index = Language_Id then
 294             return Get_Name_String (Element.Value.Value);
 295          end if;
 296
 297          Element_Id := Element.Next;
 298       end loop;
 299
 300       if Current_Mode = Multi_Language then
 301          Lang := In_Tree.First_Language;
 302          while Lang /= No_Language_Index loop
 303             if In_Tree.Languages_Data.Table (Lang).Name = Language_Id then
 304                Suffix :=
 305                  File_Name_Type
 306                    (In_Tree.Languages_Data.Table
 307                         (Lang).Config.Naming_Data.Body_Suffix);
 308                exit;
 309             end if;
 310
 311             Lang := In_Tree.Languages_Data.Table (Lang).Next;
 312          end loop;
 313
 314          if Suffix /= No_File then
 315             return Get_Name_String (Suffix);
 316          end if;
 317       end if;
 318
 319       return "";
 320    end Body_Suffix_Of;
 321
 322    -----------------------------
 323    -- Default_Ada_Body_Suffix --
 324    -----------------------------
 325
 326    function Default_Ada_Body_Suffix return File_Name_Type is
 327    begin
 328       return Default_Ada_Body_Suffix_Id;
 329    end Default_Ada_Body_Suffix;
 330
 331    -----------------------------
 332    -- Default_Ada_Spec_Suffix --
 333    -----------------------------
 334
 335    function Default_Ada_Spec_Suffix return File_Name_Type is
 336    begin
 337       return Default_Ada_Spec_Suffix_Id;
 338    end Default_Ada_Spec_Suffix;
 339
 340    ---------------------------
 341    -- Delete_All_Temp_Files --
 342    ---------------------------
 343
 344    procedure Delete_All_Temp_Files is
 345       Dont_Care : Boolean;
 346       pragma Warnings (Off, Dont_Care);
 347    begin
 348       if not Debug.Debug_Flag_N then
 349          for Index in 1 .. Temp_Files.Last loop
 350             Delete_File
 351               (Get_Name_String (Temp_Files.Table (Index)), Dont_Care);
 352          end loop;
 353       end if;
 354    end Delete_All_Temp_Files;
 355
 356    ---------------------
 357    -- Dependency_Name --
 358    ---------------------
 359
 360    function Dependency_Name
 361      (Source_File_Name : File_Name_Type;
 362       Dependency       : Dependency_File_Kind) return File_Name_Type
 363    is
 364    begin
 365       case Dependency is
 366          when None =>
 367             return No_File;
 368
 369          when Makefile =>
 370             return
 371               File_Name_Type
 372                 (Extend_Name
 373                    (Source_File_Name, Makefile_Dependency_Suffix));
 374
 375          when ALI_File =>
 376             return
 377               File_Name_Type
 378                 (Extend_Name
 379                    (Source_File_Name, ALI_Dependency_Suffix));
 380       end case;
 381    end Dependency_Name;
 382
 383    ---------------------------
 384    -- Display_Language_Name --
 385    ---------------------------
 386
 387    procedure Display_Language_Name
 388      (In_Tree  : Project_Tree_Ref;
 389       Language : Language_Index)
 390    is
 391    begin
 392       Get_Name_String (In_Tree.Languages_Data.Table (Language).Display_Name);
 393       Write_Str (Name_Buffer (1 .. Name_Len));
 394    end Display_Language_Name;
 395
 396    ----------------
 397    -- Empty_File --
 398    ----------------
 399
 400    function Empty_File return File_Name_Type is
 401    begin
 402       return File_Name_Type (The_Empty_String);
 403    end Empty_File;
 404
 405    -------------------
 406    -- Empty_Project --
 407    -------------------
 408
 409    function Empty_Project (Tree : Project_Tree_Ref) return Project_Data is
 410       Value : Project_Data;
 411
 412    begin
 413       Prj.Initialize (Tree => No_Project_Tree);
 414       Value := Project_Empty;
 415       Value.Naming := Tree.Private_Part.Default_Naming;
 416
 417       return Value;
 418    end Empty_Project;
 419
 420    ------------------
 421    -- Empty_String --
 422    ------------------
 423
 424    function Empty_String return Name_Id is
 425    begin
 426       return The_Empty_String;
 427    end Empty_String;
 428
 429    ------------
 430    -- Expect --
 431    ------------
 432
 433    procedure Expect (The_Token : Token_Type; Token_Image : String) is
 434    begin
 435       if Token /= The_Token then
 436          Error_Msg (Token_Image & " expected", Token_Ptr);
 437       end if;
 438    end Expect;
 439
 440    -----------------
 441    -- Extend_Name --
 442    -----------------
 443
 444    function Extend_Name
 445      (File        : File_Name_Type;
 446       With_Suffix : String) return File_Name_Type
 447    is
 448       Last : Positive;
 449
 450    begin
 451       Get_Name_String (File);
 452       Last := Name_Len + 1;
 453
 454       while Name_Len /= 0 and then Name_Buffer (Name_Len) /= '.' loop
 455          Name_Len := Name_Len - 1;
 456       end loop;
 457
 458       if Name_Len <= 1 then
 459          Name_Len := Last;
 460       end if;
 461
 462       for J in With_Suffix'Range loop
 463          Name_Buffer (Name_Len) := With_Suffix (J);
 464          Name_Len := Name_Len + 1;
 465       end loop;
 466
 467       Name_Len := Name_Len - 1;
 468       return Name_Find;
 469
 470    end Extend_Name;
 471
 472    --------------------------------
 473    -- For_Every_Project_Imported --
 474    --------------------------------
 475
 476    procedure For_Every_Project_Imported
 477      (By         : Project_Id;
 478       In_Tree    : Project_Tree_Ref;
 479       With_State : in out State)
 480    is
 481
 482       procedure Recursive_Check (Project : Project_Id);
 483       --  Check if a project has already been seen. If not seen, mark it as
 484       --  Seen, Call Action, and check all its imported projects.
 485
 486       ---------------------
 487       -- Recursive_Check --
 488       ---------------------
 489
 490       procedure Recursive_Check (Project : Project_Id) is
 491          List : Project_List;
 492       begin
 493          if not In_Tree.Projects.Table (Project).Seen then
 494             In_Tree.Projects.Table (Project).Seen := True;
 495             Action (Project, With_State);
 496
 497             List := In_Tree.Projects.Table (Project).Imported_Projects;
 498             while List /= Empty_Project_List loop
 499                Recursive_Check (In_Tree.Project_Lists.Table (List).Project);
 500                List := In_Tree.Project_Lists.Table (List).Next;
 501             end loop;
 502          end if;
 503       end Recursive_Check;
 504
 505    --  Start of processing for For_Every_Project_Imported
 506
 507    begin
 508       for Project in Project_Table.First ..
 509                      Project_Table.Last (In_Tree.Projects)
 510       loop
 511          In_Tree.Projects.Table (Project).Seen := False;
 512       end loop;
 513
 514       Recursive_Check (Project => By);
 515    end For_Every_Project_Imported;
 516
 517    --------------
 518    -- Get_Mode --
 519    --------------
 520
 521    function Get_Mode return Mode is
 522    begin
 523       return Current_Mode;
 524    end Get_Mode;
 525
 526    ----------
 527    -- Hash --
 528    ----------
 529
 530    function Hash is new System.HTable.Hash (Header_Num => Header_Num);
 531    --  Used in implementation of other functions Hash below
 532
 533    function Hash (Name : File_Name_Type) return Header_Num is
 534    begin
 535       return Hash (Get_Name_String (Name));
 536    end Hash;
 537
 538    function Hash (Name : Name_Id) return Header_Num is
 539    begin
 540       return Hash (Get_Name_String (Name));
 541    end Hash;
 542
 543    function Hash (Name : Path_Name_Type) return Header_Num is
 544    begin
 545       return Hash (Get_Name_String (Name));
 546    end Hash;
 547
 548    function Hash (Project : Project_Id) return Header_Num is
 549    begin
 550       return Header_Num (Project mod Max_Header_Num);
 551    end Hash;
 552
 553    -----------
 554    -- Image --
 555    -----------
 556
 557    function Image (Casing : Casing_Type) return String is
 558    begin
 559       return The_Casing_Images (Casing).all;
 560    end Image;
 561
 562    ----------------------
 563    -- In_Configuration --
 564    ----------------------
 565
 566    function In_Configuration return Boolean is
 567    begin
 568       return Configuration_Mode;
 569    end In_Configuration;
 570
 571    ----------------
 572    -- Initialize --
 573    ----------------
 574
 575    procedure Initialize (Tree : Project_Tree_Ref) is
 576    begin
 577       if not Initialized then
 578          Initialized := True;
 579          Uintp.Initialize;
 580          Name_Len := 0;
 581          The_Empty_String := Name_Find;
 582          Empty_Name := The_Empty_String;
 583          Empty_File_Name := File_Name_Type (The_Empty_String);
 584          Name_Len := 4;
 585          Name_Buffer (1 .. 4) := ".ads";
 586          Default_Ada_Spec_Suffix_Id := Name_Find;
 587          Name_Len := 4;
 588          Name_Buffer (1 .. 4) := ".adb";
 589          Default_Ada_Body_Suffix_Id := Name_Find;
 590          Name_Len := 1;
 591          Name_Buffer (1) := '/';
 592          Slash_Id := Name_Find;
 593
 594          Prj.Env.Initialize;
 595          Prj.Attr.Initialize;
 596          Set_Name_Table_Byte (Name_Project,  Token_Type'Pos (Tok_Project));
 597          Set_Name_Table_Byte (Name_Extends,  Token_Type'Pos (Tok_Extends));
 598          Set_Name_Table_Byte (Name_External, Token_Type'Pos (Tok_External));
 599       end if;
 600
 601       if Tree /= No_Project_Tree then
 602          Reset (Tree);
 603       end if;
 604    end Initialize;
 605
 606    -------------------
 607    -- Is_A_Language --
 608    -------------------
 609
 610    function Is_A_Language
 611      (Tree          : Project_Tree_Ref;
 612       Data          : Project_Data;
 613       Language_Name : Name_Id) return Boolean
 614    is
 615    begin
 616       if Get_Mode = Ada_Only then
 617          declare
 618             List : Name_List_Index := Data.Languages;
 619          begin
 620             while List /= No_Name_List loop
 621                if Tree.Name_Lists.Table (List).Name = Language_Name then
 622                   return True;
 623                else
 624                   List := Tree.Name_Lists.Table (List).Next;
 625                end if;
 626             end loop;
 627          end;
 628
 629       else
 630          declare
 631             Lang_Ind  : Language_Index := Data.First_Language_Processing;
 632             Lang_Data : Language_Data;
 633
 634          begin
 635             while Lang_Ind /= No_Language_Index loop
 636                Lang_Data := Tree.Languages_Data.Table (Lang_Ind);
 637
 638                if Lang_Data.Name = Language_Name then
 639                   return True;
 640                end if;
 641
 642                Lang_Ind := Lang_Data.Next;
 643             end loop;
 644          end;
 645       end if;
 646
 647       return False;
 648    end Is_A_Language;
 649
 650    ------------------
 651    -- Is_Extending --
 652    ------------------
 653
 654    function Is_Extending
 655      (Extending : Project_Id;
 656       Extended  : Project_Id;
 657       In_Tree   : Project_Tree_Ref) return Boolean
 658    is
 659       Proj : Project_Id;
 660
 661    begin
 662       Proj := Extending;
 663       while Proj /= No_Project loop
 664          if Proj = Extended then
 665             return True;
 666          end if;
 667
 668          Proj := In_Tree.Projects.Table (Proj).Extends;
 669       end loop;
 670
 671       return False;
 672    end Is_Extending;
 673
 674    -----------------------
 675    -- Objects_Exist_For --
 676    -----------------------
 677
 678    function Objects_Exist_For
 679      (Language : String;
 680       In_Tree  : Project_Tree_Ref) return Boolean
 681    is
 682       Language_Id : Name_Id;
 683       Lang        : Language_Index;
 684
 685    begin
 686       if Current_Mode = Multi_Language then
 687          Name_Len := 0;
 688          Add_Str_To_Name_Buffer (Language);
 689          To_Lower (Name_Buffer (1 .. Name_Len));
 690          Language_Id := Name_Find;
 691
 692          Lang := In_Tree.First_Language;
 693          while Lang /= No_Language_Index loop
 694             if In_Tree.Languages_Data.Table (Lang).Name = Language_Id then
 695                return
 696                  In_Tree.Languages_Data.Table
 697                    (Lang).Config.Objects_Generated;
 698             end if;
 699
 700             Lang := In_Tree.Languages_Data.Table (Lang).Next;
 701          end loop;
 702       end if;
 703
 704       return True;
 705    end Objects_Exist_For;
 706
 707    -----------------
 708    -- Object_Name --
 709    -----------------
 710
 711    function Object_Name
 712      (Source_File_Name : File_Name_Type)
 713       return File_Name_Type
 714    is
 715    begin
 716       return Extend_Name (Source_File_Name, Object_Suffix);
 717    end Object_Name;
 718
 719    ----------------------
 720    -- Record_Temp_File --
 721    ----------------------
 722
 723    procedure Record_Temp_File (Path : Path_Name_Type) is
 724    begin
 725       Temp_Files.Increment_Last;
 726       Temp_Files.Table (Temp_Files.Last) := Path;
 727    end Record_Temp_File;
 728
 729    ------------------------------------
 730    -- Register_Default_Naming_Scheme --
 731    ------------------------------------
 732
 733    procedure Register_Default_Naming_Scheme
 734      (Language            : Name_Id;
 735       Default_Spec_Suffix : File_Name_Type;
 736       Default_Body_Suffix : File_Name_Type;
 737       In_Tree             : Project_Tree_Ref)
 738    is
 739       Lang : Name_Id;
 740       Suffix : Array_Element_Id;
 741       Found : Boolean := False;
 742       Element : Array_Element;
 743
 744    begin
 745       --  Get the language name in small letters
 746
 747       Get_Name_String (Language);
 748       Name_Buffer (1 .. Name_Len) := To_Lower (Name_Buffer (1 .. Name_Len));
 749       Lang := Name_Find;
 750
 751       --  Look for an element of the spec suffix array indexed by the language
 752       --  name. If one is found, put the default value.
 753
 754       Suffix := In_Tree.Private_Part.Default_Naming.Spec_Suffix;
 755       Found := False;
 756       while Suffix /= No_Array_Element and then not Found loop
 757          Element := In_Tree.Array_Elements.Table (Suffix);
 758
 759          if Element.Index = Lang then
 760             Found := True;
 761             Element.Value.Value := Name_Id (Default_Spec_Suffix);
 762             In_Tree.Array_Elements.Table (Suffix) := Element;
 763
 764          else
 765             Suffix := Element.Next;
 766          end if;
 767       end loop;
 768
 769       --  If none can be found, create a new one
 770
 771       if not Found then
 772          Element :=
 773            (Index     => Lang,
 774             Src_Index => 0,
 775             Index_Case_Sensitive => False,
 776             Value => (Project  => No_Project,
 777                       Kind     => Single,
 778                       Location => No_Location,
 779                       Default  => False,
 780                       Value    => Name_Id (Default_Spec_Suffix),
 781                       Index    => 0),
 782             Next  => In_Tree.Private_Part.Default_Naming.Spec_Suffix);
 783          Array_Element_Table.Increment_Last (In_Tree.Array_Elements);
 784          In_Tree.Array_Elements.Table
 785            (Array_Element_Table.Last (In_Tree.Array_Elements)) :=
 786             Element;
 787          In_Tree.Private_Part.Default_Naming.Spec_Suffix :=
 788            Array_Element_Table.Last (In_Tree.Array_Elements);
 789       end if;
 790
 791       --  Look for an element of the body suffix array indexed by the language
 792       --  name. If one is found, put the default value.
 793
 794       Suffix := In_Tree.Private_Part.Default_Naming.Body_Suffix;
 795       Found := False;
 796       while Suffix /= No_Array_Element and then not Found loop
 797          Element := In_Tree.Array_Elements.Table (Suffix);
 798
 799          if Element.Index = Lang then
 800             Found := True;
 801             Element.Value.Value := Name_Id (Default_Body_Suffix);
 802             In_Tree.Array_Elements.Table (Suffix) := Element;
 803
 804          else
 805             Suffix := Element.Next;
 806          end if;
 807       end loop;
 808
 809       --  If none can be found, create a new one
 810
 811       if not Found then
 812          Element :=
 813            (Index     => Lang,
 814             Src_Index => 0,
 815             Index_Case_Sensitive => False,
 816             Value => (Project  => No_Project,
 817                       Kind     => Single,
 818                       Location => No_Location,
 819                       Default  => False,
 820                       Value    => Name_Id (Default_Body_Suffix),
 821                       Index    => 0),
 822             Next  => In_Tree.Private_Part.Default_Naming.Body_Suffix);
 823          Array_Element_Table.Increment_Last
 824            (In_Tree.Array_Elements);
 825          In_Tree.Array_Elements.Table
 826            (Array_Element_Table.Last (In_Tree.Array_Elements))
 827              := Element;
 828          In_Tree.Private_Part.Default_Naming.Body_Suffix :=
 829            Array_Element_Table.Last (In_Tree.Array_Elements);
 830       end if;
 831    end Register_Default_Naming_Scheme;
 832
 833    -----------
 834    -- Reset --
 835    -----------
 836
 837    procedure Reset (Tree : Project_Tree_Ref) is
 838
 839       --  Def_Lang : constant Name_Node :=
 840       --             (Name => Name_Ada,
 841       --              Next => No_Name_List);
 842       --  Why is the above commented out ???
 843
 844    begin
 845       Prj.Env.Initialize;
 846
 847       --  Visible tables
 848
 849       Language_Data_Table.Init      (Tree.Languages_Data);
 850       Name_List_Table.Init          (Tree.Name_Lists);
 851       String_Element_Table.Init     (Tree.String_Elements);
 852       Variable_Element_Table.Init   (Tree.Variable_Elements);
 853       Array_Element_Table.Init      (Tree.Array_Elements);
 854       Array_Table.Init              (Tree.Arrays);
 855       Package_Table.Init            (Tree.Packages);
 856       Project_List_Table.Init       (Tree.Project_Lists);
 857       Project_Table.Init            (Tree.Projects);
 858       Source_Data_Table.Init        (Tree.Sources);
 859       Alternate_Language_Table.Init (Tree.Alt_Langs);
 860       Unit_Table.Init               (Tree.Units);
 861       Units_Htable.Reset            (Tree.Units_HT);
 862       Files_Htable.Reset            (Tree.Files_HT);
 863       Source_Paths_Htable.Reset     (Tree.Source_Paths_HT);
 864
 865       --  Private part table
 866
 867       Naming_Table.Init             (Tree.Private_Part.Namings);
 868       Naming_Table.Increment_Last   (Tree.Private_Part.Namings);
 869       Tree.Private_Part.Namings.Table
 870         (Naming_Table.Last (Tree.Private_Part.Namings)) := Std_Naming_Data;
 871       Path_File_Table.Init        (Tree.Private_Part.Path_Files);
 872       Source_Path_Table.Init      (Tree.Private_Part.Source_Paths);
 873       Object_Path_Table.Init      (Tree.Private_Part.Object_Paths);
 874       Tree.Private_Part.Default_Naming := Std_Naming_Data;
 875
 876       if Current_Mode = Ada_Only then
 877          Register_Default_Naming_Scheme
 878            (Language            => Name_Ada,
 879             Default_Spec_Suffix => Default_Ada_Spec_Suffix,
 880             Default_Body_Suffix => Default_Ada_Body_Suffix,
 881             In_Tree             => Tree);
 882          Tree.Private_Part.Default_Naming.Separate_Suffix :=
 883            Default_Ada_Body_Suffix;
 884       end if;
 885    end Reset;
 886
 887    ------------------------
 888    -- Same_Naming_Scheme --
 889    ------------------------
 890
 891    function Same_Naming_Scheme
 892      (Left, Right : Naming_Data) return Boolean
 893    is
 894    begin
 895       return Left.Dot_Replacement = Right.Dot_Replacement
 896         and then Left.Casing = Right.Casing
 897         and then Left.Separate_Suffix = Right.Separate_Suffix;
 898    end Same_Naming_Scheme;
 899
 900    ---------------------
 901    -- Set_Body_Suffix --
 902    ---------------------
 903
 904    procedure Set_Body_Suffix
 905      (In_Tree  : Project_Tree_Ref;
 906       Language : String;
 907       Naming   : in out Naming_Data;
 908       Suffix   : File_Name_Type)
 909    is
 910       Language_Id : Name_Id;
 911       Element     : Array_Element;
 912
 913    begin
 914       Name_Len := 0;
 915       Add_Str_To_Name_Buffer (Language);
 916       To_Lower (Name_Buffer (1 .. Name_Len));
 917       Language_Id := Name_Find;
 918
 919       Element :=
 920         (Index                => Language_Id,
 921          Src_Index            => 0,
 922          Index_Case_Sensitive => False,
 923          Value                =>
 924            (Kind     => Single,
 925             Project  => No_Project,
 926             Location => No_Location,
 927             Default  => False,
 928             Value    => Name_Id (Suffix),
 929             Index    => 0),
 930          Next                 => Naming.Body_Suffix);
 931
 932       Array_Element_Table.Increment_Last (In_Tree.Array_Elements);
 933       Naming.Body_Suffix :=
 934          Array_Element_Table.Last (In_Tree.Array_Elements);
 935       In_Tree.Array_Elements.Table (Naming.Body_Suffix) := Element;
 936    end Set_Body_Suffix;
 937
 938    --------------------------
 939    -- Set_In_Configuration --
 940    --------------------------
 941
 942    procedure Set_In_Configuration (Value : Boolean) is
 943    begin
 944       Configuration_Mode := Value;
 945    end Set_In_Configuration;
 946
 947    --------------
 948    -- Set_Mode --
 949    --------------
 950
 951    procedure Set_Mode (New_Mode : Mode) is
 952    begin
 953       Current_Mode := New_Mode;
 954       case New_Mode is
 955          when Ada_Only =>
 956             Default_Language_Is_Ada := True;
 957             Must_Check_Configuration := False;
 958          when Multi_Language =>
 959             Default_Language_Is_Ada := False;
 960             Must_Check_Configuration := True;
 961       end case;
 962    end Set_Mode;
 963
 964    ---------------------
 965    -- Set_Spec_Suffix --
 966    ---------------------
 967
 968    procedure Set_Spec_Suffix
 969      (In_Tree  : Project_Tree_Ref;
 970       Language : String;
 971       Naming   : in out Naming_Data;
 972       Suffix   : File_Name_Type)
 973    is
 974       Language_Id : Name_Id;
 975       Element     : Array_Element;
 976
 977    begin
 978       Name_Len := 0;
 979       Add_Str_To_Name_Buffer (Language);
 980       To_Lower (Name_Buffer (1 .. Name_Len));
 981       Language_Id := Name_Find;
 982
 983       Element :=
 984         (Index                => Language_Id,
 985          Src_Index            => 0,
 986          Index_Case_Sensitive => False,
 987          Value                =>
 988            (Kind     => Single,
 989             Project  => No_Project,
 990             Location => No_Location,
 991             Default  => False,
 992             Value    => Name_Id (Suffix),
 993             Index    => 0),
 994          Next                 => Naming.Spec_Suffix);
 995
 996       Array_Element_Table.Increment_Last (In_Tree.Array_Elements);
 997       Naming.Spec_Suffix :=
 998         Array_Element_Table.Last (In_Tree.Array_Elements);
 999       In_Tree.Array_Elements.Table (Naming.Spec_Suffix) := Element;
1000    end Set_Spec_Suffix;
1001
1002    -----------
1003    -- Slash --
1004    -----------
1005
1006    function Slash return Path_Name_Type is
1007    begin
1008       return Slash_Id;
1009    end Slash;
1010
1011    -----------------------
1012    -- Spec_Suffix_Id_Of --
1013    -----------------------
1014
1015    function Spec_Suffix_Id_Of
1016      (In_Tree  : Project_Tree_Ref;
1017       Language : String;
1018       Naming   : Naming_Data) return File_Name_Type
1019    is
1020       Language_Id : Name_Id;
1021
1022    begin
1023       Name_Len := 0;
1024       Add_Str_To_Name_Buffer (Language);
1025       To_Lower (Name_Buffer (1 .. Name_Len));
1026       Language_Id := Name_Find;
1027
1028       return
1029         Spec_Suffix_Id_Of
1030           (In_Tree     => In_Tree,
1031            Language_Id => Language_Id,
1032            Naming      => Naming);
1033    end Spec_Suffix_Id_Of;
1034
1035    -----------------------
1036    -- Spec_Suffix_Id_Of --
1037    -----------------------
1038
1039    function Spec_Suffix_Id_Of
1040      (In_Tree     : Project_Tree_Ref;
1041       Language_Id : Name_Id;
1042       Naming      : Naming_Data) return File_Name_Type
1043    is
1044       Element_Id : Array_Element_Id;
1045       Element    : Array_Element;
1046       Suffix     : File_Name_Type := No_File;
1047       Lang       : Language_Index;
1048
1049    begin
1050       Element_Id := Naming.Spec_Suffix;
1051       while Element_Id /= No_Array_Element loop
1052          Element := In_Tree.Array_Elements.Table (Element_Id);
1053
1054          if Element.Index = Language_Id then
1055             return File_Name_Type (Element.Value.Value);
1056          end if;
1057
1058          Element_Id := Element.Next;
1059       end loop;
1060
1061       if Current_Mode = Multi_Language then
1062          Lang := In_Tree.First_Language;
1063          while Lang /= No_Language_Index loop
1064             if In_Tree.Languages_Data.Table (Lang).Name = Language_Id then
1065                Suffix :=
1066                  In_Tree.Languages_Data.Table
1067                    (Lang).Config.Naming_Data.Spec_Suffix;
1068                exit;
1069             end if;
1070
1071             Lang := In_Tree.Languages_Data.Table (Lang).Next;
1072          end loop;
1073       end if;
1074
1075       return Suffix;
1076    end Spec_Suffix_Id_Of;
1077
1078    --------------------
1079    -- Spec_Suffix_Of --
1080    --------------------
1081
1082    function Spec_Suffix_Of
1083      (In_Tree  : Project_Tree_Ref;
1084       Language : String;
1085       Naming   : Naming_Data) return String
1086    is
1087       Language_Id : Name_Id;
1088       Element_Id  : Array_Element_Id;
1089       Element     : Array_Element;
1090       Suffix      : File_Name_Type := No_File;
1091       Lang        : Language_Index;
1092
1093    begin
1094       Name_Len := 0;
1095       Add_Str_To_Name_Buffer (Language);
1096       To_Lower (Name_Buffer (1 .. Name_Len));
1097       Language_Id := Name_Find;
1098
1099       Element_Id := Naming.Spec_Suffix;
1100       while Element_Id /= No_Array_Element loop
1101          Element := In_Tree.Array_Elements.Table (Element_Id);
1102
1103          if Element.Index = Language_Id then
1104             return Get_Name_String (Element.Value.Value);
1105          end if;
1106
1107          Element_Id := Element.Next;
1108       end loop;
1109
1110       if Current_Mode = Multi_Language then
1111          Lang := In_Tree.First_Language;
1112          while Lang /= No_Language_Index loop
1113             if In_Tree.Languages_Data.Table (Lang).Name = Language_Id then
1114                Suffix :=
1115                  File_Name_Type
1116                    (In_Tree.Languages_Data.Table
1117                       (Lang).Config.Naming_Data.Spec_Suffix);
1118                exit;
1119             end if;
1120
1121             Lang := In_Tree.Languages_Data.Table (Lang).Next;
1122          end loop;
1123
1124          if Suffix /= No_File then
1125             return Get_Name_String (Suffix);
1126          end if;
1127       end if;
1128
1129       return "";
1130    end Spec_Suffix_Of;
1131
1132    --------------------------
1133    -- Standard_Naming_Data --
1134    --------------------------
1135
1136    function Standard_Naming_Data
1137      (Tree : Project_Tree_Ref := No_Project_Tree) return Naming_Data
1138    is
1139    begin
1140       if Tree = No_Project_Tree then
1141          Prj.Initialize (Tree => No_Project_Tree);
1142          return Std_Naming_Data;
1143       else
1144          return Tree.Private_Part.Default_Naming;
1145       end if;
1146    end Standard_Naming_Data;
1147
1148    -------------------
1149    -- Switches_Name --
1150    -------------------
1151
1152    function Switches_Name
1153      (Source_File_Name : File_Name_Type) return File_Name_Type
1154    is
1155    begin
1156       return Extend_Name (Source_File_Name, Switches_Dependency_Suffix);
1157    end Switches_Name;
1158
1159    ---------------------------
1160    -- There_Are_Ada_Sources --
1161    ---------------------------
1162
1163    function There_Are_Ada_Sources
1164      (In_Tree : Project_Tree_Ref;
1165       Project : Project_Id) return Boolean
1166    is
1167       Prj : Project_Id;
1168
1169    begin
1170       Prj := Project;
1171       while Prj /= No_Project loop
1172          if In_Tree.Projects.Table (Prj).Ada_Sources /= Nil_String then
1173             return True;
1174          end if;
1175
1176          Prj := In_Tree.Projects.Table (Prj).Extends;
1177       end loop;
1178
1179       return False;
1180    end There_Are_Ada_Sources;
1181
1182    -----------
1183    -- Value --
1184    -----------
1185
1186    function Value (Image : String) return Casing_Type is
1187    begin
1188       for Casing in The_Casing_Images'Range loop
1189          if To_Lower (Image) = To_Lower (The_Casing_Images (Casing).all) then
1190             return Casing;
1191          end if;
1192       end loop;
1193
1194       raise Constraint_Error;
1195    end Value;
1196
1197 begin
1198    --  Make sure that the standard config and user project file extensions are
1199    --  compatible with canonical case file naming.
1200
1201    Canonical_Case_File_Name (Config_Project_File_Extension);
1202    Canonical_Case_File_Name (Project_File_Extension);
1203 end Prj;