gcc/ada/s-imgwiu.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUNTIME COMPONENTS                          --
   4 --                                                                          --
   5 --                       S Y S T E M . I M G _ W I U                        --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --                            $Revision: 1.4 $                              --
  10 --                                                                          --
  11 --     Copyright (C) 1992,1993,1994,1995 Free Software Foundation, Inc.     --
  12 --                                                                          --
  13 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  14 -- terms of the  GNU General Public License as published  by the Free Soft- --
  15 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  16 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  17 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  18 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  19 -- for  more details.  You should have  received  a copy of the GNU General --
  20 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  21 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  22 -- MA 02111-1307, USA.                                                      --
  23 --                                                                          --
  24 -- As a special exception,  if other files  instantiate  generics from this --
  25 -- unit, or you link  this unit with other files  to produce an executable, --
  26 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  27 -- covered  by the  GNU  General  Public  License.  This exception does not --
  28 -- however invalidate  any other reasons why  the executable file  might be --
  29 -- covered by the  GNU Public License.                                      --
  30 --                                                                          --
  31 -- GNAT was originally developed  by the GNAT team at  New York University. --
  32 -- It is now maintained by Ada Core Technologies Inc (http://www.gnat.com). --
  33 --                                                                          --
  34 ------------------------------------------------------------------------------
  35
  36 with System.Unsigned_Types; use System.Unsigned_Types;
  37
  38 package body System.Img_WIU is
  39
  40    -----------------------------
  41    -- Set_Image_Width_Integer --
  42    -----------------------------
  43
  44    procedure Set_Image_Width_Integer
  45      (V : Integer;
  46       W : Integer;
  47       S : out String;
  48       P : in out Natural)
  49    is
  50       Start : Natural;
  51
  52    begin
  53       --  Positive case can just use the unsigned circuit directly
  54
  55       if V >= 0 then
  56          Set_Image_Width_Unsigned (Unsigned (V), W, S, P);
  57
  58       --  Negative case has to set a minus sign. Note also that we have to be
  59       --  careful not to generate overflow with the largest negative number.
  60
  61       else
  62          P := P + 1;
  63          S (P) := ' ';
  64          Start := P;
  65
  66          declare
  67             pragma Suppress (Overflow_Check);
  68             pragma Suppress (Range_Check);
  69          begin
  70             Set_Image_Width_Unsigned (Unsigned (-V), W - 1, S, P);
  71          end;
  72
  73          --  Set minus sign in last leading blank location. Because of the
  74          --  code above, there must be at least one such location.
  75
  76          while S (Start + 1) = ' ' loop
  77             Start := Start + 1;
  78          end loop;
  79
  80          S (Start) := '-';
  81       end if;
  82
  83    end Set_Image_Width_Integer;
  84
  85    ------------------------------
  86    -- Set_Image_Width_Unsigned --
  87    ------------------------------
  88
  89    procedure Set_Image_Width_Unsigned
  90      (V : Unsigned;
  91       W : Integer;
  92       S : out String;
  93       P : in out Natural)
  94    is
  95       Start : constant Natural := P;
  96       F, T  : Natural;
  97
  98       procedure Set_Digits (T : Unsigned);
  99       --  Set digits of absolute value of T
 100
 101       procedure Set_Digits (T : Unsigned) is
 102       begin
 103          if T >= 10 then
 104             Set_Digits (T / 10);
 105             P := P + 1;
 106             S (P) := Character'Val (T mod 10 + Character'Pos ('0'));
 107          else
 108             P := P + 1;
 109             S (P) := Character'Val (T + Character'Pos ('0'));
 110          end if;
 111       end Set_Digits;
 112
 113    --  Start of processing for Set_Image_Width_Unsigned
 114
 115    begin
 116       Set_Digits (V);
 117
 118       --  Add leading spaces if required by width parameter
 119
 120       if P - Start < W then
 121          F := P;
 122          P := P + (W - (P - Start));
 123          T := P;
 124
 125          while F > Start loop
 126             S (T) := S (F);
 127             T := T - 1;
 128             F := F - 1;
 129          end loop;
 130
 131          for J in Start + 1 .. T loop
 132             S (J) := ' ';
 133          end loop;
 134       end if;
 135
 136    end Set_Image_Width_Unsigned;
 137
 138 end System.Img_WIU;