gcc/ada/s-osinte-freebsd.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                  GNAT RUN-TIME LIBRARY (GNARL) COMPONENTS                --
   4 --                                                                          --
   5 --                   S Y S T E M . O S _ I N T E R F A C E                  --
   6 --                                                                          --
   7 --                                   S p e c                                --
   8 --                                                                          --
   9 --             Copyright (C) 1991-1994, Florida State University            --
  10 --          Copyright (C) 1995-2011, Free Software Foundation, Inc.         --
  11 --                                                                          --
  12 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  15 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  18 --                                                                          --
  19 -- As a special exception under Section 7 of GPL version 3, you are granted --
  20 -- additional permissions described in the GCC Runtime Library Exception,   --
  21 -- version 3.1, as published by the Free Software Foundation.               --
  22 --                                                                          --
  23 -- You should have received a copy of the GNU General Public License and    --
  24 -- a copy of the GCC Runtime Library Exception along with this program;     --
  25 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  26 -- <http://www.gnu.org/licenses/>.                                          --
  27 --                                                                          --
  28 -- GNARL was developed by the GNARL team at Florida State University. It is --
  29 -- now maintained by Ada Core Technologies Inc. in cooperation with Florida --
  30 -- State University (http://www.gnat.com).                                  --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 --  This is the FreeBSD PTHREADS version of this package
  35
  36 --  This package encapsulates all direct interfaces to OS services
  37 --  that are needed by the tasking run-time (libgnarl).
  38
  39 --  PLEASE DO NOT add any with-clauses to this package or remove the pragma
  40 --  Preelaborate. This package is designed to be a bottom-level (leaf) package.
  41
  42 with Ada.Unchecked_Conversion;
  43
  44 with Interfaces.C;
  45
  46 package System.OS_Interface is
  47    pragma Preelaborate;
  48
  49    pragma Linker_Options ("-pthread");
  50
  51    subtype int            is Interfaces.C.int;
  52    subtype short          is Interfaces.C.short;
  53    subtype long           is Interfaces.C.long;
  54    subtype unsigned       is Interfaces.C.unsigned;
  55    subtype unsigned_short is Interfaces.C.unsigned_short;
  56    subtype unsigned_long  is Interfaces.C.unsigned_long;
  57    subtype unsigned_char  is Interfaces.C.unsigned_char;
  58    subtype plain_char     is Interfaces.C.plain_char;
  59    subtype size_t         is Interfaces.C.size_t;
  60
  61    -----------
  62    -- Errno --
  63    -----------
  64
  65    function Errno return int;
  66    pragma Inline (Errno);
  67
  68    EAGAIN    : constant := 35;
  69    EINTR     : constant := 4;
  70    EINVAL    : constant := 22;
  71    ENOMEM    : constant := 12;
  72    ETIMEDOUT : constant := 60;
  73
  74    -------------
  75    -- Signals --
  76    -------------
  77
  78    Max_Interrupt : constant := 31;
  79    type Signal is new int range 0 .. Max_Interrupt;
  80    for Signal'Size use int'Size;
  81
  82    SIGHUP     : constant := 1; --  hangup
  83    SIGINT     : constant := 2; --  interrupt (rubout)
  84    SIGQUIT    : constant := 3; --  quit (ASCD FS)
  85    SIGILL     : constant := 4; --  illegal instruction (not reset)
  86    SIGTRAP    : constant := 5; --  trace trap (not reset)
  87    SIGIOT     : constant := 6; --  IOT instruction
  88    SIGABRT    : constant := 6; --  used by abort, replace SIGIOT in the  future
  89    SIGEMT     : constant := 7; --  EMT instruction
  90    SIGFPE     : constant := 8; --  floating point exception
  91    SIGKILL    : constant := 9; --  kill (cannot be caught or ignored)
  92    SIGBUS     : constant := 10; --  bus error
  93    SIGSEGV    : constant := 11; --  segmentation violation
  94    SIGSYS     : constant := 12; --  bad argument to system call
  95    SIGPIPE    : constant := 13; --  write on a pipe with no one to read it
  96    SIGALRM    : constant := 14; --  alarm clock
  97    SIGTERM    : constant := 15; --  software termination signal from kill
  98    SIGURG     : constant := 16; --  urgent condition on IO channel
  99    SIGSTOP    : constant := 17; --  stop (cannot be caught or ignored)
 100    SIGTSTP    : constant := 18; --  user stop requested from tty
 101    SIGCONT    : constant := 19; --  stopped process has been continued
 102    SIGCLD     : constant := 20; --  alias for SIGCHLD
 103    SIGCHLD    : constant := 20; --  child status change
 104    SIGTTIN    : constant := 21; --  background tty read attempted
 105    SIGTTOU    : constant := 22; --  background tty write attempted
 106    SIGIO      : constant := 23; --  I/O possible (Solaris SIGPOLL alias)
 107    SIGXCPU    : constant := 24; --  CPU time limit exceeded
 108    SIGXFSZ    : constant := 25; --  filesize limit exceeded
 109    SIGVTALRM  : constant := 26; --  virtual timer expired
 110    SIGPROF    : constant := 27; --  profiling timer expired
 111    SIGWINCH   : constant := 28; --  window size change
 112    SIGINFO    : constant := 29; --  information request (NetBSD/FreeBSD)
 113    SIGUSR1    : constant := 30; --  user defined signal 1
 114    SIGUSR2    : constant := 31; --  user defined signal 2
 115
 116    SIGADAABORT : constant := SIGABRT;
 117    --  Change this if you want to use another signal for task abort.
 118    --  SIGTERM might be a good one.
 119
 120    type Signal_Set is array (Natural range <>) of Signal;
 121
 122    --  Interrupts that must be unmasked at all times.  FreeBSD
 123    --  pthreads will not allow an application to mask out any
 124    --  interrupt needed by the threads library.
 125    Unmasked : constant Signal_Set :=
 126      (SIGTRAP, SIGBUS, SIGTTIN, SIGTTOU, SIGTSTP);
 127
 128    --  FreeBSD will uses SIGPROF for timing.  Do not allow a
 129    --  handler to attach to this signal.
 130    Reserved : constant Signal_Set := (0 .. 0 => SIGPROF);
 131
 132    type sigset_t is private;
 133
 134    function sigaddset
 135      (set : access sigset_t;
 136       sig : Signal) return int;
 137    pragma Import (C, sigaddset, "sigaddset");
 138
 139    function sigdelset
 140      (set : access sigset_t;
 141       sig : Signal) return int;
 142    pragma Import (C, sigdelset, "sigdelset");
 143
 144    function sigfillset (set : access sigset_t) return int;
 145    pragma Import (C, sigfillset, "sigfillset");
 146
 147    function sigismember
 148      (set : access sigset_t;
 149       sig : Signal) return int;
 150    pragma Import (C, sigismember, "sigismember");
 151
 152    function sigemptyset (set : access sigset_t) return int;
 153    pragma Import (C, sigemptyset, "sigemptyset");
 154
 155    --  sigcontext is architecture dependent, so define it private
 156    type struct_sigcontext is private;
 157
 158    type old_struct_sigaction is record
 159       sa_handler : System.Address;
 160       sa_mask    : sigset_t;
 161       sa_flags   : int;
 162    end record;
 163    pragma Convention (C, old_struct_sigaction);
 164
 165    type new_struct_sigaction is record
 166       sa_handler : System.Address;
 167       sa_flags   : int;
 168       sa_mask    : sigset_t;
 169    end record;
 170    pragma Convention (C, new_struct_sigaction);
 171
 172    subtype struct_sigaction is new_struct_sigaction;
 173    type struct_sigaction_ptr is access all struct_sigaction;
 174
 175    SIG_BLOCK   : constant := 1;
 176    SIG_UNBLOCK : constant := 2;
 177    SIG_SETMASK : constant := 3;
 178
 179    SIG_DFL : constant := 0;
 180    SIG_IGN : constant := 1;
 181
 182    SA_SIGINFO : constant := 16#0040#;
 183    SA_ONSTACK : constant := 16#0001#;
 184
 185    function sigaction
 186      (sig  : Signal;
 187       act  : struct_sigaction_ptr;
 188       oact : struct_sigaction_ptr) return int;
 189    pragma Import (C, sigaction, "sigaction");
 190
 191    ----------
 192    -- Time --
 193    ----------
 194
 195    Time_Slice_Supported : constant Boolean := True;
 196    --  Indicates whether time slicing is supported (i.e SCHED_RR is supported)
 197
 198    type timespec is private;
 199
 200    function nanosleep (rqtp, rmtp : access timespec)  return int;
 201    pragma Import (C, nanosleep, "nanosleep");
 202
 203    type clockid_t is private;
 204
 205    CLOCK_REALTIME  : constant clockid_t;
 206    CLOCK_MONOTONIC : constant clockid_t;
 207
 208    function clock_gettime
 209      (clock_id : clockid_t;
 210       tp       : access timespec)
 211       return int;
 212    pragma Import (C, clock_gettime, "clock_gettime");
 213
 214    function To_Duration (TS : timespec) return Duration;
 215    pragma Inline (To_Duration);
 216
 217    function To_Timespec (D : Duration) return timespec;
 218    pragma Inline (To_Timespec);
 219
 220    type struct_timezone is record
 221       tz_minuteswest : int;
 222       tz_dsttime     : int;
 223    end record;
 224    pragma Convention (C, struct_timezone);
 225
 226    procedure usleep (useconds : unsigned_long);
 227    pragma Import (C, usleep, "usleep");
 228
 229    -------------------------
 230    -- Priority Scheduling --
 231    -------------------------
 232
 233    SCHED_FIFO  : constant := 1;
 234    SCHED_OTHER : constant := 2;
 235    SCHED_RR    : constant := 3;
 236
 237    function To_Target_Priority
 238      (Prio : System.Any_Priority) return Interfaces.C.int;
 239    --  Maps System.Any_Priority to a POSIX priority
 240
 241    -------------
 242    -- Process --
 243    -------------
 244
 245    type pid_t is private;
 246
 247    Self_PID : constant pid_t;
 248
 249    function kill (pid : pid_t; sig : Signal) return int;
 250    pragma Import (C, kill, "kill");
 251
 252    function getpid return pid_t;
 253    pragma Import (C, getpid, "getpid");
 254
 255    ---------
 256    -- LWP --
 257    ---------
 258
 259    function lwp_self return System.Address;
 260    --  lwp_self does not exist on this thread library, revert to pthread_self
 261    --  which is the closest approximation (with getpid). This function is
 262    --  needed to share 7staprop.adb across POSIX-like targets.
 263    pragma Import (C, lwp_self, "pthread_self");
 264
 265    -------------
 266    -- Threads --
 267    -------------
 268
 269    type Thread_Body is access
 270      function (arg : System.Address) return System.Address;
 271    pragma Convention (C, Thread_Body);
 272
 273    function Thread_Body_Access is new
 274      Ada.Unchecked_Conversion (System.Address, Thread_Body);
 275
 276    type pthread_t           is private;
 277    subtype Thread_Id        is pthread_t;
 278
 279    type pthread_mutex_t     is limited private;
 280    type pthread_cond_t      is limited private;
 281    type pthread_attr_t      is limited private;
 282    type pthread_mutexattr_t is limited private;
 283    type pthread_condattr_t  is limited private;
 284    type pthread_key_t       is private;
 285
 286    PTHREAD_CREATE_DETACHED : constant := 1;
 287    PTHREAD_CREATE_JOINABLE : constant := 0;
 288
 289    PTHREAD_SCOPE_PROCESS : constant := 0;
 290    PTHREAD_SCOPE_SYSTEM  : constant := 2;
 291
 292    -----------
 293    -- Stack --
 294    -----------
 295
 296    type stack_t is record
 297       ss_sp    : System.Address;
 298       ss_size  : size_t;
 299       ss_flags : int;
 300    end record;
 301    pragma Convention (C, stack_t);
 302
 303    function sigaltstack
 304      (ss  : not null access stack_t;
 305       oss : access stack_t) return int;
 306    pragma Import (C, sigaltstack, "sigaltstack");
 307
 308    Alternate_Stack : aliased System.Address;
 309    --  This is a dummy definition, never used (Alternate_Stack_Size is null)
 310
 311    Alternate_Stack_Size : constant := 0;
 312    --  No alternate signal stack is used on this platform
 313
 314    Stack_Base_Available : constant Boolean := False;
 315    --  Indicates whether the stack base is available on this target. This
 316    --  allows us to share s-osinte.adb between all the FSU run time. Note that
 317    --  this value can only be true if pthread_t has a complete definition that
 318    --  corresponds exactly to the C header files.
 319
 320    function Get_Stack_Base (thread : pthread_t) return Address;
 321    pragma Inline (Get_Stack_Base);
 322    --  returns the stack base of the specified thread. Only call this function
 323    --  when Stack_Base_Available is True.
 324
 325    function Get_Page_Size return size_t;
 326    function Get_Page_Size return Address;
 327    pragma Import (C, Get_Page_Size, "getpagesize");
 328    --  Returns the size of a page
 329
 330    PROT_NONE  : constant := 0;
 331    PROT_READ  : constant := 1;
 332    PROT_WRITE : constant := 2;
 333    PROT_EXEC  : constant := 4;
 334    PROT_ALL   : constant := PROT_READ + PROT_WRITE + PROT_EXEC;
 335    PROT_ON    : constant := PROT_NONE;
 336    PROT_OFF   : constant := PROT_ALL;
 337
 338    function mprotect (addr : Address; len : size_t; prot : int) return int;
 339    pragma Import (C, mprotect);
 340
 341    ---------------------------------------
 342    -- Nonstandard Thread Initialization --
 343    ---------------------------------------
 344
 345    --  FSU_THREADS requires pthread_init, which is nonstandard and this should
 346    --  be invoked during the elaboration of s-taprop.adb.
 347
 348    --  FreeBSD does not require this so we provide an empty Ada body
 349
 350    procedure pthread_init;
 351
 352    -------------------------
 353    -- POSIX.1c  Section 3 --
 354    -------------------------
 355
 356    function sigwait
 357      (set : access sigset_t;
 358       sig : access Signal) return int;
 359    pragma Import (C, sigwait, "sigwait");
 360
 361    function pthread_kill
 362      (thread : pthread_t;
 363       sig    : Signal) return int;
 364    pragma Import (C, pthread_kill, "pthread_kill");
 365
 366    function pthread_sigmask
 367      (how  : int;
 368       set  : access sigset_t;
 369       oset : access sigset_t) return int;
 370    pragma Import (C, pthread_sigmask, "pthread_sigmask");
 371
 372    --------------------------
 373    -- POSIX.1c  Section 11 --
 374    --------------------------
 375
 376    function pthread_mutexattr_init
 377      (attr : access pthread_mutexattr_t) return int;
 378    pragma Import (C, pthread_mutexattr_init, "pthread_mutexattr_init");
 379
 380    function pthread_mutexattr_destroy
 381      (attr : access pthread_mutexattr_t) return int;
 382    pragma Import (C, pthread_mutexattr_destroy, "pthread_mutexattr_destroy");
 383
 384    function pthread_mutex_init
 385      (mutex : access pthread_mutex_t;
 386       attr  : access pthread_mutexattr_t) return int;
 387    pragma Import (C, pthread_mutex_init, "pthread_mutex_init");
 388
 389    function pthread_mutex_destroy (mutex : access pthread_mutex_t) return int;
 390    pragma Import (C, pthread_mutex_destroy, "pthread_mutex_destroy");
 391
 392    function pthread_mutex_lock (mutex : access pthread_mutex_t) return int;
 393    pragma Import (C, pthread_mutex_lock, "pthread_mutex_lock");
 394
 395    function pthread_mutex_unlock (mutex : access pthread_mutex_t) return int;
 396    pragma Import (C, pthread_mutex_unlock, "pthread_mutex_unlock");
 397
 398    function pthread_condattr_init
 399      (attr : access pthread_condattr_t) return int;
 400    pragma Import (C, pthread_condattr_init, "pthread_condattr_init");
 401
 402    function pthread_condattr_destroy
 403      (attr : access pthread_condattr_t) return int;
 404    pragma Import (C, pthread_condattr_destroy, "pthread_condattr_destroy");
 405
 406    function pthread_cond_init
 407      (cond : access pthread_cond_t;
 408       attr : access pthread_condattr_t) return int;
 409    pragma Import (C, pthread_cond_init, "pthread_cond_init");
 410
 411    function pthread_cond_destroy (cond : access pthread_cond_t) return int;
 412    pragma Import (C, pthread_cond_destroy, "pthread_cond_destroy");
 413
 414    function pthread_cond_signal (cond : access pthread_cond_t) return int;
 415    pragma Import (C, pthread_cond_signal, "pthread_cond_signal");
 416
 417    function pthread_cond_wait
 418      (cond  : access pthread_cond_t;
 419       mutex : access pthread_mutex_t) return int;
 420    pragma Import (C, pthread_cond_wait, "pthread_cond_wait");
 421
 422    function pthread_cond_timedwait
 423      (cond    : access pthread_cond_t;
 424       mutex   : access pthread_mutex_t;
 425       abstime : access timespec) return int;
 426    pragma Import (C, pthread_cond_timedwait, "pthread_cond_timedwait");
 427
 428    Relative_Timed_Wait : constant Boolean := False;
 429    --  pthread_cond_timedwait requires an absolute delay time
 430
 431    --------------------------
 432    -- POSIX.1c  Section 13 --
 433    --------------------------
 434
 435    PTHREAD_PRIO_NONE    : constant := 0;
 436    PTHREAD_PRIO_PROTECT : constant := 2;
 437    PTHREAD_PRIO_INHERIT : constant := 1;
 438
 439    function pthread_mutexattr_setprotocol
 440      (attr     : access pthread_mutexattr_t;
 441       protocol : int) return int;
 442    pragma Import
 443       (C, pthread_mutexattr_setprotocol, "pthread_mutexattr_setprotocol");
 444
 445    function pthread_mutexattr_getprotocol
 446      (attr     : access pthread_mutexattr_t;
 447       protocol : access int) return int;
 448    pragma Import
 449      (C, pthread_mutexattr_getprotocol, "pthread_mutexattr_getprotocol");
 450
 451    function pthread_mutexattr_setprioceiling
 452      (attr     : access pthread_mutexattr_t;
 453       prioceiling : int) return int;
 454    pragma Import
 455      (C, pthread_mutexattr_setprioceiling,
 456       "pthread_mutexattr_setprioceiling");
 457
 458    function pthread_mutexattr_getprioceiling
 459      (attr     : access pthread_mutexattr_t;
 460       prioceiling : access int) return int;
 461    pragma Import
 462      (C, pthread_mutexattr_getprioceiling,
 463       "pthread_mutexattr_getprioceiling");
 464
 465    type struct_sched_param is record
 466       sched_priority : int;
 467    end record;
 468    pragma Convention (C, struct_sched_param);
 469
 470    function pthread_getschedparam
 471      (thread : pthread_t;
 472       policy : access int;
 473       param  : access struct_sched_param) return int;
 474    pragma Import (C, pthread_getschedparam, "pthread_getschedparam");
 475
 476    function pthread_setschedparam
 477      (thread : pthread_t;
 478       policy : int;
 479       param  : access struct_sched_param) return int;
 480    pragma Import (C, pthread_setschedparam, "pthread_setschedparam");
 481
 482    function pthread_attr_setscope
 483      (attr            : access pthread_attr_t;
 484       contentionscope : int) return int;
 485    pragma Import (C, pthread_attr_setscope, "pthread_attr_setscope");
 486
 487    function pthread_attr_getscope
 488      (attr            : access pthread_attr_t;
 489       contentionscope : access int) return int;
 490    pragma Import (C, pthread_attr_getscope, "pthread_attr_getscope");
 491
 492    function pthread_attr_setinheritsched
 493      (attr            : access pthread_attr_t;
 494       inheritsched : int) return int;
 495    pragma Import
 496      (C, pthread_attr_setinheritsched, "pthread_attr_setinheritsched");
 497
 498    function pthread_attr_getinheritsched
 499      (attr         : access pthread_attr_t;
 500       inheritsched : access int) return int;
 501    pragma Import
 502      (C, pthread_attr_getinheritsched, "pthread_attr_getinheritsched");
 503
 504    function pthread_attr_setschedpolicy
 505      (attr   : access pthread_attr_t;
 506       policy : int) return int;
 507    pragma Import (C, pthread_attr_setschedpolicy,
 508      "pthread_attr_setschedpolicy");
 509
 510    function pthread_attr_getschedpolicy
 511      (attr   : access pthread_attr_t;
 512       policy : access int) return int;
 513    pragma Import (C, pthread_attr_getschedpolicy,
 514      "pthread_attr_getschedpolicy");
 515
 516    function pthread_attr_setschedparam
 517      (attr        : access pthread_attr_t;
 518       sched_param : int) return int;
 519    pragma Import (C, pthread_attr_setschedparam, "pthread_attr_setschedparam");
 520
 521    function pthread_attr_getschedparam
 522      (attr        : access pthread_attr_t;
 523       sched_param : access int) return int;
 524    pragma Import (C, pthread_attr_getschedparam, "pthread_attr_getschedparam");
 525
 526    function sched_yield return int;
 527    pragma Import (C, sched_yield, "pthread_yield");
 528
 529    --------------------------
 530    -- P1003.1c  Section 16 --
 531    --------------------------
 532
 533    function pthread_attr_init (attributes : access pthread_attr_t) return int;
 534    pragma Import (C, pthread_attr_init, "pthread_attr_init");
 535
 536    function pthread_attr_destroy
 537      (attributes : access pthread_attr_t) return int;
 538    pragma Import (C, pthread_attr_destroy, "pthread_attr_destroy");
 539
 540    function pthread_attr_setdetachstate
 541      (attr        : access pthread_attr_t;
 542       detachstate : int) return int;
 543    pragma Import
 544      (C, pthread_attr_setdetachstate, "pthread_attr_setdetachstate");
 545
 546    function pthread_attr_getdetachstate
 547      (attr        : access pthread_attr_t;
 548       detachstate : access int) return int;
 549    pragma Import
 550      (C, pthread_attr_getdetachstate, "pthread_attr_getdetachstate");
 551
 552    function pthread_attr_getstacksize
 553      (attr      : access pthread_attr_t;
 554       stacksize : access size_t) return int;
 555    pragma Import
 556      (C, pthread_attr_getstacksize, "pthread_attr_getstacksize");
 557
 558    function pthread_attr_setstacksize
 559      (attr      : access pthread_attr_t;
 560       stacksize : size_t) return int;
 561    pragma Import
 562      (C, pthread_attr_setstacksize, "pthread_attr_setstacksize");
 563
 564    function pthread_create
 565      (thread        : access pthread_t;
 566       attributes    : access pthread_attr_t;
 567       start_routine : Thread_Body;
 568       arg           : System.Address) return int;
 569    pragma Import (C, pthread_create, "pthread_create");
 570
 571    function pthread_detach (thread : pthread_t) return int;
 572    pragma Import (C, pthread_detach, "pthread_detach");
 573
 574    procedure pthread_exit (status : System.Address);
 575    pragma Import (C, pthread_exit, "pthread_exit");
 576
 577    function pthread_self return pthread_t;
 578    pragma Import (C, pthread_self, "pthread_self");
 579
 580    --------------------------
 581    -- POSIX.1c  Section 17 --
 582    --------------------------
 583
 584    function pthread_setspecific
 585      (key   : pthread_key_t;
 586       value : System.Address) return  int;
 587    pragma Import (C, pthread_setspecific, "pthread_setspecific");
 588
 589    function pthread_getspecific (key : pthread_key_t) return System.Address;
 590    pragma Import (C, pthread_getspecific, "pthread_getspecific");
 591
 592    type destructor_pointer is access procedure (arg : System.Address);
 593    pragma Convention (C, destructor_pointer);
 594
 595    function pthread_key_create
 596      (key        : access pthread_key_t;
 597       destructor : destructor_pointer) return int;
 598    pragma Import (C, pthread_key_create, "pthread_key_create");
 599
 600    ------------------------------------
 601    -- Non-portable Pthread Functions --
 602    ------------------------------------
 603
 604    function pthread_set_name_np
 605      (thread : pthread_t;
 606       name   : System.Address) return int;
 607    pragma Import (C, pthread_set_name_np, "pthread_set_name_np");
 608
 609 private
 610
 611    type sigset_t is array (1 .. 4) of unsigned;
 612
 613    --  In FreeBSD the component sa_handler turns out to
 614    --  be one a union type, and the selector is a macro:
 615    --  #define sa_handler __sigaction_u._handler
 616    --  #define sa_sigaction __sigaction_u._sigaction
 617
 618    --  Should we add a signal_context type here ???
 619    --  How could it be done independent of the CPU architecture ???
 620    --  sigcontext type is opaque, so it is architecturally neutral.
 621    --  It is always passed as an access type, so define it as an empty record
 622    --  since the contents are not used anywhere.
 623
 624    type struct_sigcontext is null record;
 625    pragma Convention (C, struct_sigcontext);
 626
 627    type pid_t is new int;
 628    Self_PID : constant pid_t := 0;
 629
 630    type time_t is new long;
 631
 632    type timespec is record
 633       ts_sec  : time_t;
 634       ts_nsec : long;
 635    end record;
 636    pragma Convention (C, timespec);
 637
 638    type clockid_t is new int;
 639    CLOCK_REALTIME  : constant clockid_t := 0;
 640    CLOCK_MONOTONIC : constant clockid_t := 4;
 641
 642    type pthread_t           is new System.Address;
 643    type pthread_attr_t      is new System.Address;
 644    type pthread_mutex_t     is new System.Address;
 645    type pthread_mutexattr_t is new System.Address;
 646    type pthread_cond_t      is new System.Address;
 647    type pthread_condattr_t  is new System.Address;
 648    type pthread_key_t       is new int;
 649
 650 end System.OS_Interface;