gcc/ada/s-taskin.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                 GNAT RUN-TIME LIBRARY (GNARL) COMPONENTS                 --
   4 --                                                                          --
   5 --                        S Y S T E M . T A S K I N G                       --
   6 --                                                                          --
   7 --                                  B o d y                                 --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2014, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNARL is free software; you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- As a special exception under Section 7 of GPL version 3, you are granted --
  19 -- additional permissions described in the GCC Runtime Library Exception,   --
  20 -- version 3.1, as published by the Free Software Foundation.               --
  21 --                                                                          --
  22 -- You should have received a copy of the GNU General Public License and    --
  23 -- a copy of the GCC Runtime Library Exception along with this program;     --
  24 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  25 -- <http://www.gnu.org/licenses/>.                                          --
  26 --                                                                          --
  27 -- GNARL was developed by the GNARL team at Florida State University.       --
  28 -- Extensive contributions were provided by Ada Core Technologies, Inc.     --
  29 --                                                                          --
  30 ------------------------------------------------------------------------------
  31
  32 pragma Polling (Off);
  33 --  Turn off polling, we do not want ATC polling to take place during tasking
  34 --  operations. It causes infinite loops and other problems.
  35
  36 with System.Task_Primitives.Operations;
  37 with System.Storage_Elements;
  38
  39 package body System.Tasking is
  40
  41    package STPO renames System.Task_Primitives.Operations;
  42
  43    ---------------------
  44    -- Detect_Blocking --
  45    ---------------------
  46
  47    function Detect_Blocking return Boolean is
  48       GL_Detect_Blocking : Integer;
  49       pragma Import (C, GL_Detect_Blocking, "__gl_detect_blocking");
  50       --  Global variable exported by the binder generated file. A value equal
  51       --  to 1 indicates that pragma Detect_Blocking is active, while 0 is used
  52       --  for the pragma not being present.
  53
  54    begin
  55       return GL_Detect_Blocking = 1;
  56    end Detect_Blocking;
  57
  58    -----------------------
  59    -- Number_Of_Entries --
  60    -----------------------
  61
  62    function Number_Of_Entries (Self_Id : Task_Id) return Entry_Index is
  63    begin
  64       return Entry_Index (Self_Id.Entry_Num);
  65    end Number_Of_Entries;
  66
  67    ----------
  68    -- Self --
  69    ----------
  70
  71    function Self return Task_Id renames STPO.Self;
  72
  73    ------------------
  74    -- Storage_Size --
  75    ------------------
  76
  77    function Storage_Size (T : Task_Id) return System.Parameters.Size_Type is
  78    begin
  79       return
  80          System.Parameters.Size_Type
  81            (T.Common.Compiler_Data.Pri_Stack_Info.Size);
  82    end Storage_Size;
  83
  84    ---------------------
  85    -- Initialize_ATCB --
  86    ---------------------
  87
  88    procedure Initialize_ATCB
  89      (Self_ID          : Task_Id;
  90       Task_Entry_Point : Task_Procedure_Access;
  91       Task_Arg         : System.Address;
  92       Parent           : Task_Id;
  93       Elaborated       : Access_Boolean;
  94       Base_Priority    : System.Any_Priority;
  95       Base_CPU         : System.Multiprocessors.CPU_Range;
  96       Domain           : Dispatching_Domain_Access;
  97       Task_Info        : System.Task_Info.Task_Info_Type;
  98       Stack_Size       : System.Parameters.Size_Type;
  99       T                : Task_Id;
 100       Success          : out Boolean)
 101    is
 102    begin
 103       T.Common.State := Unactivated;
 104
 105       --  Initialize T.Common.LL
 106
 107       STPO.Initialize_TCB (T, Success);
 108
 109       if not Success then
 110          return;
 111       end if;
 112
 113       T.Common.Parent                   := Parent;
 114       T.Common.Base_Priority            := Base_Priority;
 115       T.Common.Base_CPU                 := Base_CPU;
 116
 117       --  The Domain defaults to that of the activator
 118
 119       T.Common.Domain                   :=
 120         (if Domain = null then Self_ID.Common.Domain else Domain);
 121       pragma Assert (T.Common.Domain /= null);
 122
 123       T.Common.Current_Priority         := 0;
 124       T.Common.Protected_Action_Nesting := 0;
 125       T.Common.Call                     := null;
 126       T.Common.Task_Arg                 := Task_Arg;
 127       T.Common.Task_Entry_Point         := Task_Entry_Point;
 128       T.Common.Activator                := Self_ID;
 129       T.Common.Wait_Count               := 0;
 130       T.Common.Elaborated               := Elaborated;
 131       T.Common.Activation_Failed        := False;
 132       T.Common.Task_Info                := Task_Info;
 133       T.Common.Global_Task_Lock_Nesting := 0;
 134       T.Common.Fall_Back_Handler        := null;
 135       T.Common.Specific_Handler         := null;
 136       T.Common.Debug_Events             := (others => False);
 137       T.Common.Task_Image_Len           := 0;
 138
 139       if T.Common.Parent = null then
 140
 141          --  For the environment task, the adjusted stack size is meaningless.
 142          --  For example, an unspecified Stack_Size means that the stack size
 143          --  is determined by the environment, or can grow dynamically. The
 144          --  Stack_Checking algorithm therefore needs to use the requested
 145          --  size, or 0 in case of an unknown size.
 146
 147          T.Common.Compiler_Data.Pri_Stack_Info.Size :=
 148             Storage_Elements.Storage_Offset (Stack_Size);
 149
 150       else
 151          T.Common.Compiler_Data.Pri_Stack_Info.Size :=
 152            Storage_Elements.Storage_Offset
 153              (Parameters.Adjust_Storage_Size (Stack_Size));
 154       end if;
 155
 156       --  Link the task into the list of all tasks
 157
 158       T.Common.All_Tasks_Link := All_Tasks_List;
 159       All_Tasks_List := T;
 160    end Initialize_ATCB;
 161
 162    ----------------
 163    -- Initialize --
 164    ----------------
 165
 166    Main_Task_Image : constant String := "main_task";
 167    --  Image of environment task
 168
 169    Main_Priority : Integer;
 170    pragma Import (C, Main_Priority, "__gl_main_priority");
 171    --  Priority for main task. Note that this is of type Integer, not Priority,
 172    --  because we use the value -1 to indicate the default main priority, and
 173    --  that is of course not in Priority'range.
 174
 175    Main_CPU : Integer;
 176    pragma Import (C, Main_CPU, "__gl_main_cpu");
 177    --  Affinity for main task. Note that this is of type Integer, not
 178    --  CPU_Range, because we use the value -1 to indicate the unassigned
 179    --  affinity, and that is of course not in CPU_Range'Range.
 180
 181    Initialized : Boolean := False;
 182    --  Used to prevent multiple calls to Initialize
 183
 184    procedure Initialize is
 185       T             : Task_Id;
 186       Base_Priority : Any_Priority;
 187       Base_CPU      : System.Multiprocessors.CPU_Range;
 188       Success       : Boolean;
 189
 190       use type System.Multiprocessors.CPU_Range;
 191
 192    begin
 193       if Initialized then
 194          return;
 195       end if;
 196
 197       Initialized := True;
 198
 199       --  Initialize Environment Task
 200
 201       Base_Priority :=
 202         (if Main_Priority = Unspecified_Priority
 203          then Default_Priority
 204          else Priority (Main_Priority));
 205
 206       Base_CPU :=
 207         (if Main_CPU = Unspecified_CPU
 208          then System.Multiprocessors.Not_A_Specific_CPU
 209          else System.Multiprocessors.CPU_Range (Main_CPU));
 210
 211       --  At program start-up the environment task is allocated to the default
 212       --  system dispatching domain.
 213       --  Make sure that the processors which are not available are not taken
 214       --  into account. Use Number_Of_CPUs to know the exact number of
 215       --  processors in the system at execution time.
 216
 217       System_Domain :=
 218         new Dispatching_Domain'
 219           (Multiprocessors.CPU'First .. Multiprocessors.Number_Of_CPUs =>
 220              True);
 221
 222       T := STPO.New_ATCB (0);
 223       Initialize_ATCB
 224         (Self_ID          => null,
 225          Task_Entry_Point => null,
 226          Task_Arg         => Null_Address,
 227          Parent           => Null_Task,
 228          Elaborated       => null,
 229          Base_Priority    => Base_Priority,
 230          Base_CPU         => Base_CPU,
 231          Domain           => System_Domain,
 232          Task_Info        => Task_Info.Unspecified_Task_Info,
 233          Stack_Size       => 0,
 234          T                => T,
 235          Success          => Success);
 236       pragma Assert (Success);
 237
 238       STPO.Initialize (T);
 239       STPO.Set_Priority (T, T.Common.Base_Priority);
 240       T.Common.State := Runnable;
 241       T.Common.Task_Image_Len := Main_Task_Image'Length;
 242       T.Common.Task_Image (Main_Task_Image'Range) := Main_Task_Image;
 243
 244       Dispatching_Domain_Tasks :=
 245         new Array_Allocated_Tasks'
 246           (Multiprocessors.CPU'First .. Multiprocessors.Number_Of_CPUs => 0);
 247
 248       --  Signal that this task is being allocated to a processor
 249
 250       if Base_CPU /= System.Multiprocessors.Not_A_Specific_CPU then
 251
 252          --  Increase the number of tasks attached to the CPU to which this
 253          --  task is allocated.
 254
 255          Dispatching_Domain_Tasks (Base_CPU) :=
 256            Dispatching_Domain_Tasks (Base_CPU) + 1;
 257       end if;
 258
 259       --  Only initialize the first element since others are not relevant
 260       --  in ravenscar mode. Rest of the initialization is done in Init_RTS.
 261
 262       T.Entry_Calls (1).Self := T;
 263    end Initialize;
 264
 265    ---------------------
 266    -- Set_Entry_Names --
 267    ---------------------
 268
 269    procedure Set_Entry_Names
 270      (Self_Id : Task_Id;
 271       Names   : Task_Entry_Names_Access)
 272    is
 273    begin
 274       Self_Id.Entry_Names := Names;
 275    end Set_Entry_Names;
 276
 277 end System.Tasking;