gcc/ada/sem_ch13.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             S E M _ C H 1 3                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2004, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 with Atree;    use Atree;
  28 with Checks;   use Checks;
  29 with Einfo;    use Einfo;
  30 with Errout;   use Errout;
  31 with Exp_Tss;  use Exp_Tss;
  32 with Exp_Util; use Exp_Util;
  33 with Lib;      use Lib;
  34 with Nlists;   use Nlists;
  35 with Nmake;    use Nmake;
  36 with Opt;      use Opt;
  37 with Rtsfind;  use Rtsfind;
  38 with Sem;      use Sem;
  39 with Sem_Ch8;  use Sem_Ch8;
  40 with Sem_Eval; use Sem_Eval;
  41 with Sem_Res;  use Sem_Res;
  42 with Sem_Type; use Sem_Type;
  43 with Sem_Util; use Sem_Util;
  44 with Snames;   use Snames;
  45 with Stand;    use Stand;
  46 with Sinfo;    use Sinfo;
  47 with Table;
  48 with Targparm; use Targparm;
  49 with Ttypes;   use Ttypes;
  50 with Tbuild;   use Tbuild;
  51 with Urealp;   use Urealp;
  52
  53 with GNAT.Heap_Sort_A; use GNAT.Heap_Sort_A;
  54
  55 package body Sem_Ch13 is
  56
  57    SSU : constant Pos := System_Storage_Unit;
  58    --  Convenient short hand for commonly used constant
  59
  60    -----------------------
  61    -- Local Subprograms --
  62    -----------------------
  63
  64    procedure Alignment_Check_For_Esize_Change (Typ : Entity_Id);
  65    --  This routine is called after setting the Esize of type entity Typ.
  66    --  The purpose is to deal with the situation where an aligment has been
  67    --  inherited from a derived type that is no longer appropriate for the
  68    --  new Esize value. In this case, we reset the Alignment to unknown.
  69
  70    procedure Check_Component_Overlap (C1_Ent, C2_Ent : Entity_Id);
  71    --  Given two entities for record components or discriminants, checks
  72    --  if they hav overlapping component clauses and issues errors if so.
  73
  74    function Get_Alignment_Value (Expr : Node_Id) return Uint;
  75    --  Given the expression for an alignment value, returns the corresponding
  76    --  Uint value. If the value is inappropriate, then error messages are
  77    --  posted as required, and a value of No_Uint is returned.
  78
  79    function Is_Operational_Item (N : Node_Id) return Boolean;
  80    --  A specification for a stream attribute is allowed before the full
  81    --  type is declared, as explained in AI-00137 and the corrigendum.
  82    --  Attributes that do not specify a representation characteristic are
  83    --  operational attributes.
  84
  85    function Address_Aliased_Entity (N : Node_Id) return Entity_Id;
  86    --  If expression N is of the form E'Address, return E.
  87
  88    procedure Mark_Aliased_Address_As_Volatile (N : Node_Id);
  89    --  This is used for processing of an address representation clause. If
  90    --  the expression N is of the form of K'Address, then the entity that
  91    --  is associated with K is marked as volatile.
  92
  93    procedure New_Stream_Function
  94      (N    : Node_Id;
  95       Ent  : Entity_Id;
  96       Subp : Entity_Id;
  97       Nam  : TSS_Name_Type);
  98    --  Create a function renaming of a given stream attribute to the
  99    --  designated subprogram and then in the tagged case, provide this as
 100    --  a primitive operation, or in the non-tagged case make an appropriate
 101    --  TSS entry. Used for Input. This is more properly an expansion activity
 102    --  than just semantics, but the presence of user-defined stream functions
 103    --  for limited types is a legality check, which is why this takes place
 104    --  here rather than in exp_ch13, where it was previously. Nam indicates
 105    --  the name of the TSS function to be generated.
 106    --
 107    --  To avoid elaboration anomalies with freeze nodes, for untagged types
 108    --  we generate both a subprogram declaration and a subprogram renaming
 109    --  declaration, so that the attribute specification is handled as a
 110    --  renaming_as_body. For tagged types, the specification is one of the
 111    --  primitive specs.
 112
 113    procedure New_Stream_Procedure
 114      (N     : Node_Id;
 115       Ent   : Entity_Id;
 116       Subp  : Entity_Id;
 117       Nam   : TSS_Name_Type;
 118       Out_P : Boolean := False);
 119    --  Create a procedure renaming of a given stream attribute to the
 120    --  designated subprogram and then in the tagged case, provide this as
 121    --  a primitive operation, or in the non-tagged case make an appropriate
 122    --  TSS entry. Used for Read, Output, Write. Nam indicates the name of
 123    --  the TSS procedure to be generated.
 124
 125    ----------------------------------------------
 126    -- Table for Validate_Unchecked_Conversions --
 127    ----------------------------------------------
 128
 129    --  The following table collects unchecked conversions for validation.
 130    --  Entries are made by Validate_Unchecked_Conversion and then the
 131    --  call to Validate_Unchecked_Conversions does the actual error
 132    --  checking and posting of warnings. The reason for this delayed
 133    --  processing is to take advantage of back-annotations of size and
 134    --  alignment values peformed by the back end.
 135
 136    type UC_Entry is record
 137       Enode  : Node_Id;   -- node used for posting warnings
 138       Source : Entity_Id; -- source type for unchecked conversion
 139       Target : Entity_Id; -- target type for unchecked conversion
 140    end record;
 141
 142    package Unchecked_Conversions is new Table.Table (
 143      Table_Component_Type => UC_Entry,
 144      Table_Index_Type     => Int,
 145      Table_Low_Bound      => 1,
 146      Table_Initial        => 50,
 147      Table_Increment      => 200,
 148      Table_Name           => "Unchecked_Conversions");
 149
 150    ----------------------------
 151    -- Address_Aliased_Entity --
 152    ----------------------------
 153
 154    function Address_Aliased_Entity (N : Node_Id) return Entity_Id is
 155    begin
 156       if Nkind (N) = N_Attribute_Reference
 157         and then Attribute_Name (N) = Name_Address
 158       then
 159          declare
 160             Nam : Node_Id := Prefix (N);
 161          begin
 162             while False
 163               or else Nkind (Nam) = N_Selected_Component
 164               or else Nkind (Nam) = N_Indexed_Component
 165             loop
 166                Nam := Prefix (Nam);
 167             end loop;
 168
 169             if Is_Entity_Name (Nam) then
 170                return Entity (Nam);
 171             end if;
 172          end;
 173       end if;
 174
 175       return Empty;
 176    end Address_Aliased_Entity;
 177
 178    --------------------------------------
 179    -- Alignment_Check_For_Esize_Change --
 180    --------------------------------------
 181
 182    procedure Alignment_Check_For_Esize_Change (Typ : Entity_Id) is
 183    begin
 184       --  If the alignment is known, and not set by a rep clause, and is
 185       --  inconsistent with the size being set, then reset it to unknown,
 186       --  we assume in this case that the size overrides the inherited
 187       --  alignment, and that the alignment must be recomputed.
 188
 189       if Known_Alignment (Typ)
 190         and then not Has_Alignment_Clause (Typ)
 191         and then Esize (Typ) mod (Alignment (Typ) * SSU) /= 0
 192       then
 193          Init_Alignment (Typ);
 194       end if;
 195    end Alignment_Check_For_Esize_Change;
 196
 197    -----------------------
 198    -- Analyze_At_Clause --
 199    -----------------------
 200
 201    --  An at clause is replaced by the corresponding Address attribute
 202    --  definition clause that is the preferred approach in Ada 95.
 203
 204    procedure Analyze_At_Clause (N : Node_Id) is
 205    begin
 206       if Warn_On_Obsolescent_Feature then
 207          Error_Msg_N
 208            ("at clause is an obsolescent feature ('R'M 'J.7(2))?", N);
 209          Error_Msg_N
 210            ("|use address attribute definition clause instead?", N);
 211       end if;
 212
 213       Rewrite (N,
 214         Make_Attribute_Definition_Clause (Sloc (N),
 215           Name  => Identifier (N),
 216           Chars => Name_Address,
 217           Expression => Expression (N)));
 218       Analyze_Attribute_Definition_Clause (N);
 219    end Analyze_At_Clause;
 220
 221    -----------------------------------------
 222    -- Analyze_Attribute_Definition_Clause --
 223    -----------------------------------------
 224
 225    procedure Analyze_Attribute_Definition_Clause (N : Node_Id) is
 226       Loc   : constant Source_Ptr   := Sloc (N);
 227       Nam   : constant Node_Id      := Name (N);
 228       Attr  : constant Name_Id      := Chars (N);
 229       Expr  : constant Node_Id      := Expression (N);
 230       Id    : constant Attribute_Id := Get_Attribute_Id (Attr);
 231       Ent   : Entity_Id;
 232       U_Ent : Entity_Id;
 233
 234       FOnly : Boolean := False;
 235       --  Reset to True for subtype specific attribute (Alignment, Size)
 236       --  and for stream attributes, i.e. those cases where in the call
 237       --  to Rep_Item_Too_Late, FOnly is set True so that only the freezing
 238       --  rules are checked. Note that the case of stream attributes is not
 239       --  clear from the RM, but see AI95-00137. Also, the RM seems to
 240       --  disallow Storage_Size for derived task types, but that is also
 241       --  clearly unintentional.
 242
 243    begin
 244       Analyze (Nam);
 245       Ent := Entity (Nam);
 246
 247       if Rep_Item_Too_Early (Ent, N) then
 248          return;
 249       end if;
 250
 251       --  Rep clause applies to full view of incomplete type or private type
 252       --  if we have one (if not, this is a premature use of the type).
 253       --  However, certain semantic checks need to be done on the specified
 254       --  entity (i.e. the private view), so we save it in Ent.
 255
 256       if Is_Private_Type (Ent)
 257         and then Is_Derived_Type (Ent)
 258         and then not Is_Tagged_Type (Ent)
 259         and then No (Full_View (Ent))
 260       then
 261          --  If this is a private type whose completion is a derivation
 262          --  from another private type, there is no full view, and the
 263          --  attribute belongs to the type itself, not its underlying parent.
 264
 265          U_Ent := Ent;
 266
 267       elsif Ekind (Ent) = E_Incomplete_Type then
 268
 269          --  The attribute applies to the full view, set the entity
 270          --  of the attribute definition accordingly.
 271
 272          Ent := Underlying_Type (Ent);
 273          U_Ent := Ent;
 274          Set_Entity (Nam, Ent);
 275
 276       else
 277          U_Ent := Underlying_Type (Ent);
 278       end if;
 279
 280       --  Complete other routine error checks
 281
 282       if Etype (Nam) = Any_Type then
 283          return;
 284
 285       elsif Scope (Ent) /= Current_Scope then
 286          Error_Msg_N ("entity must be declared in this scope", Nam);
 287          return;
 288
 289       elsif No (U_Ent) then
 290          U_Ent := Ent;
 291
 292       elsif Is_Type (U_Ent)
 293         and then not Is_First_Subtype (U_Ent)
 294         and then Id /= Attribute_Object_Size
 295         and then Id /= Attribute_Value_Size
 296         and then not From_At_Mod (N)
 297       then
 298          Error_Msg_N ("cannot specify attribute for subtype", Nam);
 299          return;
 300
 301       end if;
 302
 303       --  Switch on particular attribute
 304
 305       case Id is
 306
 307          -------------
 308          -- Address --
 309          -------------
 310
 311          --  Address attribute definition clause
 312
 313          when Attribute_Address => Address : begin
 314             Analyze_And_Resolve (Expr, RTE (RE_Address));
 315
 316             if Present (Address_Clause (U_Ent)) then
 317                Error_Msg_N ("address already given for &", Nam);
 318
 319             --  Case of address clause for subprogram
 320
 321             elsif Is_Subprogram (U_Ent) then
 322                if Has_Homonym (U_Ent) then
 323                   Error_Msg_N
 324                     ("address clause cannot be given " &
 325                      "for overloaded subprogram",
 326                      Nam);
 327                end if;
 328
 329                --  For subprograms, all address clauses are permitted,
 330                --  and we mark the subprogram as having a deferred freeze
 331                --  so that Gigi will not elaborate it too soon.
 332
 333                --  Above needs more comments, what is too soon about???
 334
 335                Set_Has_Delayed_Freeze (U_Ent);
 336
 337             --  Case of address clause for entry
 338
 339             elsif Ekind (U_Ent) = E_Entry then
 340                if Nkind (Parent (N)) = N_Task_Body then
 341                   Error_Msg_N
 342                     ("entry address must be specified in task spec", Nam);
 343                end if;
 344
 345                --  For entries, we require a constant address
 346
 347                Check_Constant_Address_Clause (Expr, U_Ent);
 348
 349                if Is_Task_Type (Scope (U_Ent))
 350                  and then Comes_From_Source (Scope (U_Ent))
 351                then
 352                   Error_Msg_N
 353                     ("?entry address declared for entry in task type", N);
 354                   Error_Msg_N
 355                     ("\?only one task can be declared of this type", N);
 356                end if;
 357
 358                if Warn_On_Obsolescent_Feature then
 359                   Error_Msg_N
 360                     ("attaching interrupt to task entry is an " &
 361                      "obsolescent feature ('R'M 'J.7.1)?", N);
 362                   Error_Msg_N
 363                     ("|use interrupt procedure instead?", N);
 364                end if;
 365
 366             --  Case of an address clause for a controlled object:
 367             --  erroneous execution.
 368
 369             elsif Is_Controlled (Etype (U_Ent)) then
 370                Error_Msg_NE
 371                  ("?controlled object& must not be overlaid", Nam, U_Ent);
 372                Error_Msg_N
 373                  ("\?Program_Error will be raised at run time", Nam);
 374                Insert_Action (Declaration_Node (U_Ent),
 375                  Make_Raise_Program_Error (Loc,
 376                    Reason => PE_Overlaid_Controlled_Object));
 377
 378             --  Case of address clause for a (non-controlled) object
 379
 380             elsif
 381               Ekind (U_Ent) = E_Variable
 382                 or else
 383               Ekind (U_Ent) = E_Constant
 384             then
 385                declare
 386                   Expr : constant Node_Id   := Expression (N);
 387                   Aent : constant Entity_Id := Address_Aliased_Entity (Expr);
 388
 389                begin
 390                   --  Exported variables cannot have an address clause,
 391                   --  because this cancels the effect of the pragma Export
 392
 393                   if Is_Exported (U_Ent) then
 394                      Error_Msg_N
 395                        ("cannot export object with address clause", Nam);
 396
 397                   --  Overlaying controlled objects is erroneous
 398
 399                   elsif Present (Aent)
 400                     and then Is_Controlled (Etype (Aent))
 401                   then
 402                      Error_Msg_N
 403                        ("?controlled object must not be overlaid", Expr);
 404                      Error_Msg_N
 405                        ("\?Program_Error will be raised at run time", Expr);
 406                      Insert_Action (Declaration_Node (U_Ent),
 407                        Make_Raise_Program_Error (Loc,
 408                          Reason => PE_Overlaid_Controlled_Object));
 409
 410                   elsif Present (Aent)
 411                     and then Ekind (U_Ent) = E_Constant
 412                     and then Ekind (Aent) /= E_Constant
 413                   then
 414                      Error_Msg_N ("constant overlays a variable?", Expr);
 415
 416                   elsif Present (Renamed_Object (U_Ent)) then
 417                      Error_Msg_N
 418                        ("address clause not allowed"
 419                           & " for a renaming declaration ('R'M 13.1(6))", Nam);
 420
 421                   --  Imported variables can have an address clause, but then
 422                   --  the import is pretty meaningless except to suppress
 423                   --  initializations, so we do not need such variables to
 424                   --  be statically allocated (and in fact it causes trouble
 425                   --  if the address clause is a local value).
 426
 427                   elsif Is_Imported (U_Ent) then
 428                      Set_Is_Statically_Allocated (U_Ent, False);
 429                   end if;
 430
 431                   --  We mark a possible modification of a variable with an
 432                   --  address clause, since it is likely aliasing is occurring.
 433
 434                   Note_Possible_Modification (Nam);
 435
 436                   --  Here we are checking for explicit overlap of one
 437                   --  variable by another, and if we find this, then we
 438                   --  mark the overlapped variable as also being aliased.
 439
 440                   --  First case is where we have an explicit
 441
 442                   --    for J'Address use K'Address;
 443
 444                   --  In this case, we mark K as volatile
 445
 446                   Mark_Aliased_Address_As_Volatile (Expr);
 447
 448                   --  Second case is where we have a constant whose
 449                   --  definition is of the form of an adress as in:
 450
 451                   --     A : constant Address := K'Address;
 452                   --     ...
 453                   --     for B'Address use A;
 454
 455                   --  In this case we also mark K as volatile
 456
 457                   if Is_Entity_Name (Expr) then
 458                      declare
 459                         Ent  : constant Entity_Id := Entity (Expr);
 460                         Decl : constant Node_Id   := Declaration_Node (Ent);
 461
 462                      begin
 463                         if Ekind (Ent) = E_Constant
 464                           and then Nkind (Decl) = N_Object_Declaration
 465                           and then Present (Expression (Decl))
 466                         then
 467                            Mark_Aliased_Address_As_Volatile
 468                              (Expression (Decl));
 469                         end if;
 470                      end;
 471                   end if;
 472
 473                   --  Legality checks on the address clause for initialized
 474                   --  objects is deferred until the freeze point, because
 475                   --  a subsequent pragma might indicate that the object is
 476                   --  imported and thus not initialized.
 477
 478                   Set_Has_Delayed_Freeze (U_Ent);
 479
 480                   if Is_Exported (U_Ent) then
 481                      Error_Msg_N
 482                        ("& cannot be exported if an address clause is given",
 483                         Nam);
 484                      Error_Msg_N
 485                        ("\define and export a variable " &
 486                         "that holds its address instead",
 487                         Nam);
 488                   end if;
 489
 490                   --  Entity has delayed freeze, so we will generate
 491                   --  an alignment check at the freeze point.
 492
 493                   Set_Check_Address_Alignment
 494                     (N, not Range_Checks_Suppressed (U_Ent));
 495
 496                   --  Kill the size check code, since we are not allocating
 497                   --  the variable, it is somewhere else.
 498
 499                   Kill_Size_Check_Code (U_Ent);
 500                end;
 501
 502             --  Not a valid entity for an address clause
 503
 504             else
 505                Error_Msg_N ("address cannot be given for &", Nam);
 506             end if;
 507          end Address;
 508
 509          ---------------
 510          -- Alignment --
 511          ---------------
 512
 513          --  Alignment attribute definition clause
 514
 515          when Attribute_Alignment => Alignment_Block : declare
 516             Align : constant Uint := Get_Alignment_Value (Expr);
 517
 518          begin
 519             FOnly := True;
 520
 521             if not Is_Type (U_Ent)
 522               and then Ekind (U_Ent) /= E_Variable
 523               and then Ekind (U_Ent) /= E_Constant
 524             then
 525                Error_Msg_N ("alignment cannot be given for &", Nam);
 526
 527             elsif Has_Alignment_Clause (U_Ent) then
 528                Error_Msg_Sloc := Sloc (Alignment_Clause (U_Ent));
 529                Error_Msg_N ("alignment clause previously given#", N);
 530
 531             elsif Align /= No_Uint then
 532                Set_Has_Alignment_Clause (U_Ent);
 533                Set_Alignment            (U_Ent, Align);
 534             end if;
 535          end Alignment_Block;
 536
 537          ---------------
 538          -- Bit_Order --
 539          ---------------
 540
 541          --  Bit_Order attribute definition clause
 542
 543          when Attribute_Bit_Order => Bit_Order : declare
 544          begin
 545             if not Is_Record_Type (U_Ent) then
 546                Error_Msg_N
 547                  ("Bit_Order can only be defined for record type", Nam);
 548
 549             else
 550                Analyze_And_Resolve (Expr, RTE (RE_Bit_Order));
 551
 552                if Etype (Expr) = Any_Type then
 553                   return;
 554
 555                elsif not Is_Static_Expression (Expr) then
 556                   Flag_Non_Static_Expr
 557                     ("Bit_Order requires static expression!", Expr);
 558
 559                else
 560                   if (Expr_Value (Expr) = 0) /= Bytes_Big_Endian then
 561                      Set_Reverse_Bit_Order (U_Ent, True);
 562                   end if;
 563                end if;
 564             end if;
 565          end Bit_Order;
 566
 567          --------------------
 568          -- Component_Size --
 569          --------------------
 570
 571          --  Component_Size attribute definition clause
 572
 573          when Attribute_Component_Size => Component_Size_Case : declare
 574             Csize    : constant Uint := Static_Integer (Expr);
 575             Btype    : Entity_Id;
 576             Biased   : Boolean;
 577             New_Ctyp : Entity_Id;
 578             Decl     : Node_Id;
 579
 580          begin
 581             if not Is_Array_Type (U_Ent) then
 582                Error_Msg_N ("component size requires array type", Nam);
 583                return;
 584             end if;
 585
 586             Btype := Base_Type (U_Ent);
 587
 588             if Has_Component_Size_Clause (Btype) then
 589                Error_Msg_N
 590                  ("component size clase for& previously given", Nam);
 591
 592             elsif Csize /= No_Uint then
 593                Check_Size (Expr, Component_Type (Btype), Csize, Biased);
 594
 595                if Has_Aliased_Components (Btype)
 596                  and then Csize < 32
 597                  and then Csize /= 8
 598                  and then Csize /= 16
 599                then
 600                   Error_Msg_N
 601                     ("component size incorrect for aliased components", N);
 602                   return;
 603                end if;
 604
 605                --  For the biased case, build a declaration for a subtype
 606                --  that will be used to represent the biased subtype that
 607                --  reflects the biased representation of components. We need
 608                --  this subtype to get proper conversions on referencing
 609                --  elements of the array.
 610
 611                if Biased then
 612                   New_Ctyp :=
 613                     Make_Defining_Identifier (Loc,
 614                       Chars => New_External_Name (Chars (U_Ent), 'C', 0, 'T'));
 615
 616                   Decl :=
 617                     Make_Subtype_Declaration (Loc,
 618                       Defining_Identifier => New_Ctyp,
 619                       Subtype_Indication  =>
 620                         New_Occurrence_Of (Component_Type (Btype), Loc));
 621
 622                   Set_Parent (Decl, N);
 623                   Analyze (Decl, Suppress => All_Checks);
 624
 625                   Set_Has_Delayed_Freeze        (New_Ctyp, False);
 626                   Set_Esize                     (New_Ctyp, Csize);
 627                   Set_RM_Size                   (New_Ctyp, Csize);
 628                   Init_Alignment                (New_Ctyp);
 629                   Set_Has_Biased_Representation (New_Ctyp, True);
 630                   Set_Is_Itype                  (New_Ctyp, True);
 631                   Set_Associated_Node_For_Itype (New_Ctyp, U_Ent);
 632
 633                   Set_Component_Type (Btype, New_Ctyp);
 634                end if;
 635
 636                Set_Component_Size            (Btype, Csize);
 637                Set_Has_Component_Size_Clause (Btype, True);
 638                Set_Has_Non_Standard_Rep      (Btype, True);
 639             end if;
 640          end Component_Size_Case;
 641
 642          ------------------
 643          -- External_Tag --
 644          ------------------
 645
 646          when Attribute_External_Tag => External_Tag :
 647          begin
 648             if not Is_Tagged_Type (U_Ent) then
 649                Error_Msg_N ("should be a tagged type", Nam);
 650             end if;
 651
 652             Analyze_And_Resolve (Expr, Standard_String);
 653
 654             if not Is_Static_Expression (Expr) then
 655                Flag_Non_Static_Expr
 656                  ("static string required for tag name!", Nam);
 657             end if;
 658
 659             Set_Has_External_Tag_Rep_Clause (U_Ent);
 660          end External_Tag;
 661
 662          -----------
 663          -- Input --
 664          -----------
 665
 666          when Attribute_Input => Input : declare
 667             Subp : Entity_Id := Empty;
 668             I    : Interp_Index;
 669             It   : Interp;
 670             Pnam : Entity_Id;
 671
 672             function Has_Good_Profile (Subp : Entity_Id) return Boolean;
 673             --  Return true if the entity is a function with an appropriate
 674             --  profile for the Input attribute.
 675
 676             ----------------------
 677             -- Has_Good_Profile --
 678             ----------------------
 679
 680             function Has_Good_Profile (Subp : Entity_Id) return Boolean is
 681                F  : Entity_Id;
 682                Ok : Boolean := False;
 683
 684             begin
 685                if Ekind (Subp) = E_Function then
 686                   F := First_Formal (Subp);
 687
 688                   if Present (F) and then No (Next_Formal (F)) then
 689                      if Ekind (Etype (F)) = E_Anonymous_Access_Type
 690                        and then
 691                          Designated_Type (Etype (F)) =
 692                            Class_Wide_Type (RTE (RE_Root_Stream_Type))
 693                      then
 694                         Ok := Base_Type (Etype (Subp)) = Base_Type (Ent);
 695                      end if;
 696                   end if;
 697                end if;
 698
 699                return Ok;
 700             end Has_Good_Profile;
 701
 702          --  Start of processing for Input attribute definition
 703
 704          begin
 705             FOnly := True;
 706
 707             if not Is_Type (U_Ent) then
 708                Error_Msg_N ("local name must be a subtype", Nam);
 709                return;
 710
 711             else
 712                Pnam := TSS (Base_Type (U_Ent), TSS_Stream_Input);
 713
 714                if Present (Pnam)
 715                  and then Base_Type (Etype (Pnam)) = Base_Type (U_Ent)
 716                then
 717                   Error_Msg_Sloc := Sloc (Pnam);
 718                   Error_Msg_N ("input attribute already defined #", Nam);
 719                   return;
 720                end if;
 721             end if;
 722
 723             Analyze (Expr);
 724
 725             if Is_Entity_Name (Expr) then
 726                if not Is_Overloaded (Expr) then
 727                   if Has_Good_Profile (Entity (Expr)) then
 728                      Subp := Entity (Expr);
 729                   end if;
 730
 731                else
 732                   Get_First_Interp (Expr, I, It);
 733
 734                   while Present (It.Nam) loop
 735                      if Has_Good_Profile (It.Nam) then
 736                         Subp := It.Nam;
 737                         exit;
 738                      end if;
 739
 740                      Get_Next_Interp (I, It);
 741                   end loop;
 742                end if;
 743             end if;
 744
 745             if Present (Subp) then
 746                Set_Entity (Expr, Subp);
 747                Set_Etype (Expr, Etype (Subp));
 748                New_Stream_Function (N, U_Ent, Subp,  TSS_Stream_Input);
 749             else
 750                Error_Msg_N ("incorrect expression for input attribute", Expr);
 751                return;
 752             end if;
 753          end Input;
 754
 755          -------------------
 756          -- Machine_Radix --
 757          -------------------
 758
 759          --  Machine radix attribute definition clause
 760
 761          when Attribute_Machine_Radix => Machine_Radix : declare
 762             Radix : constant Uint := Static_Integer (Expr);
 763
 764          begin
 765             if not Is_Decimal_Fixed_Point_Type (U_Ent) then
 766                Error_Msg_N ("decimal fixed-point type expected for &", Nam);
 767
 768             elsif Has_Machine_Radix_Clause (U_Ent) then
 769                Error_Msg_Sloc := Sloc (Alignment_Clause (U_Ent));
 770                Error_Msg_N ("machine radix clause previously given#", N);
 771
 772             elsif Radix /= No_Uint then
 773                Set_Has_Machine_Radix_Clause (U_Ent);
 774                Set_Has_Non_Standard_Rep (Base_Type (U_Ent));
 775
 776                if Radix = 2 then
 777                   null;
 778                elsif Radix = 10 then
 779                   Set_Machine_Radix_10 (U_Ent);
 780                else
 781                   Error_Msg_N ("machine radix value must be 2 or 10", Expr);
 782                end if;
 783             end if;
 784          end Machine_Radix;
 785
 786          -----------------
 787          -- Object_Size --
 788          -----------------
 789
 790          --  Object_Size attribute definition clause
 791
 792          when Attribute_Object_Size => Object_Size : declare
 793             Size   : constant Uint := Static_Integer (Expr);
 794             Biased : Boolean;
 795
 796          begin
 797             if not Is_Type (U_Ent) then
 798                Error_Msg_N ("Object_Size cannot be given for &", Nam);
 799
 800             elsif Has_Object_Size_Clause (U_Ent) then
 801                Error_Msg_N ("Object_Size already given for &", Nam);
 802
 803             else
 804                Check_Size (Expr, U_Ent, Size, Biased);
 805
 806                if Size /= 8
 807                     and then
 808                   Size /= 16
 809                     and then
 810                   Size /= 32
 811                     and then
 812                   UI_Mod (Size, 64) /= 0
 813                then
 814                   Error_Msg_N
 815                     ("Object_Size must be 8, 16, 32, or multiple of 64",
 816                      Expr);
 817                end if;
 818
 819                Set_Esize (U_Ent, Size);
 820                Set_Has_Object_Size_Clause (U_Ent);
 821                Alignment_Check_For_Esize_Change (U_Ent);
 822             end if;
 823          end Object_Size;
 824
 825          ------------
 826          -- Output --
 827          ------------
 828
 829          when Attribute_Output => Output : declare
 830             Subp : Entity_Id := Empty;
 831             I    : Interp_Index;
 832             It   : Interp;
 833             Pnam : Entity_Id;
 834
 835             function Has_Good_Profile (Subp : Entity_Id) return Boolean;
 836             --  Return true if the entity is a procedure with an
 837             --  appropriate profile for the output attribute.
 838
 839             ----------------------
 840             -- Has_Good_Profile --
 841             ----------------------
 842
 843             function Has_Good_Profile (Subp : Entity_Id) return Boolean is
 844                F  : Entity_Id;
 845                Ok : Boolean := False;
 846
 847             begin
 848                if Ekind (Subp) = E_Procedure then
 849                   F := First_Formal (Subp);
 850
 851                   if Present (F) then
 852                      if Ekind (Etype (F)) = E_Anonymous_Access_Type
 853                        and then
 854                          Designated_Type (Etype (F)) =
 855                            Class_Wide_Type (RTE (RE_Root_Stream_Type))
 856                      then
 857                         Next_Formal (F);
 858                         Ok :=  Present (F)
 859                           and then Parameter_Mode (F) = E_In_Parameter
 860                           and then Base_Type (Etype (F)) = Base_Type (Ent)
 861                           and then No (Next_Formal (F));
 862                      end if;
 863                   end if;
 864                end if;
 865
 866                return Ok;
 867             end Has_Good_Profile;
 868
 869          --  Start of processing for Output attribute definition
 870
 871          begin
 872             FOnly := True;
 873
 874             if not Is_Type (U_Ent) then
 875                Error_Msg_N ("local name must be a subtype", Nam);
 876                return;
 877
 878             else
 879                Pnam := TSS (Base_Type (U_Ent), TSS_Stream_Output);
 880
 881                if Present (Pnam)
 882                  and then
 883                    Base_Type (Etype (Next_Formal (First_Formal (Pnam))))
 884                                                         = Base_Type (U_Ent)
 885                then
 886                   Error_Msg_Sloc := Sloc (Pnam);
 887                   Error_Msg_N ("output attribute already defined #", Nam);
 888                   return;
 889                end if;
 890             end if;
 891
 892             Analyze (Expr);
 893
 894             if Is_Entity_Name (Expr) then
 895                if not Is_Overloaded (Expr) then
 896                   if Has_Good_Profile (Entity (Expr)) then
 897                      Subp := Entity (Expr);
 898                   end if;
 899
 900                else
 901                   Get_First_Interp (Expr, I, It);
 902
 903                   while Present (It.Nam) loop
 904                      if Has_Good_Profile (It.Nam) then
 905                         Subp := It.Nam;
 906                         exit;
 907                      end if;
 908
 909                      Get_Next_Interp (I, It);
 910                   end loop;
 911                end if;
 912             end if;
 913
 914             if Present (Subp) then
 915                Set_Entity (Expr, Subp);
 916                Set_Etype (Expr, Etype (Subp));
 917                New_Stream_Procedure (N, U_Ent, Subp, TSS_Stream_Output);
 918             else
 919                Error_Msg_N ("incorrect expression for output attribute", Expr);
 920                return;
 921             end if;
 922          end Output;
 923
 924          ----------
 925          -- Read --
 926          ----------
 927
 928          when Attribute_Read => Read : declare
 929             Subp : Entity_Id := Empty;
 930             I    : Interp_Index;
 931             It   : Interp;
 932             Pnam : Entity_Id;
 933
 934             function Has_Good_Profile (Subp : Entity_Id) return Boolean;
 935             --  Return true if the entity is a procedure with an appropriate
 936             --  profile for the Read attribute.
 937
 938             ----------------------
 939             -- Has_Good_Profile --
 940             ----------------------
 941
 942             function Has_Good_Profile (Subp : Entity_Id) return Boolean is
 943                F     : Entity_Id;
 944                Ok    : Boolean := False;
 945
 946             begin
 947                if Ekind (Subp) = E_Procedure then
 948                   F := First_Formal (Subp);
 949
 950                   if Present (F) then
 951                      if Ekind (Etype (F)) = E_Anonymous_Access_Type
 952                        and then
 953                          Designated_Type (Etype (F)) =
 954                            Class_Wide_Type (RTE (RE_Root_Stream_Type))
 955                      then
 956                         Next_Formal (F);
 957                         Ok :=  Present (F)
 958                           and then Parameter_Mode (F) = E_Out_Parameter
 959                           and then Base_Type (Etype (F)) = Base_Type (Ent)
 960                           and then No (Next_Formal (F));
 961                      end if;
 962                   end if;
 963                end if;
 964
 965                return Ok;
 966             end Has_Good_Profile;
 967
 968          --  Start of processing for Read attribute definition
 969
 970          begin
 971             FOnly := True;
 972
 973             if not Is_Type (U_Ent) then
 974                Error_Msg_N ("local name must be a subtype", Nam);
 975                return;
 976
 977             else
 978                Pnam := TSS (Base_Type (U_Ent), TSS_Stream_Read);
 979
 980                if Present (Pnam)
 981                  and then Base_Type (Etype (Next_Formal (First_Formal (Pnam))))
 982                    = Base_Type (U_Ent)
 983                then
 984                   Error_Msg_Sloc := Sloc (Pnam);
 985                   Error_Msg_N ("read attribute already defined #", Nam);
 986                   return;
 987                end if;
 988             end if;
 989
 990             Analyze (Expr);
 991
 992             if Is_Entity_Name (Expr) then
 993                if not Is_Overloaded (Expr) then
 994                   if Has_Good_Profile (Entity (Expr)) then
 995                      Subp := Entity (Expr);
 996                   end if;
 997
 998                else
 999                   Get_First_Interp (Expr, I, It);
1000
1001                   while Present (It.Nam) loop
1002                      if Has_Good_Profile (It.Nam) then
1003                         Subp := It.Nam;
1004                         exit;
1005                      end if;
1006
1007                      Get_Next_Interp (I, It);
1008                   end loop;
1009                end if;
1010             end if;
1011
1012             if Present (Subp) then
1013                Set_Entity (Expr, Subp);
1014                Set_Etype (Expr, Etype (Subp));
1015                New_Stream_Procedure (N, U_Ent, Subp, TSS_Stream_Read, True);
1016             else
1017                Error_Msg_N ("incorrect expression for read attribute", Expr);
1018                return;
1019             end if;
1020          end Read;
1021
1022          ----------
1023          -- Size --
1024          ----------
1025
1026          --  Size attribute definition clause
1027
1028          when Attribute_Size => Size : declare
1029             Size   : constant Uint := Static_Integer (Expr);
1030             Etyp   : Entity_Id;
1031             Biased : Boolean;
1032
1033          begin
1034             FOnly := True;
1035
1036             if Has_Size_Clause (U_Ent) then
1037                Error_Msg_N ("size already given for &", Nam);
1038
1039             elsif not Is_Type (U_Ent)
1040               and then Ekind (U_Ent) /= E_Variable
1041               and then Ekind (U_Ent) /= E_Constant
1042             then
1043                Error_Msg_N ("size cannot be given for &", Nam);
1044
1045             elsif Is_Array_Type (U_Ent)
1046               and then not Is_Constrained (U_Ent)
1047             then
1048                Error_Msg_N
1049                  ("size cannot be given for unconstrained array", Nam);
1050
1051             elsif Size /= No_Uint then
1052                if Is_Type (U_Ent) then
1053                   Etyp := U_Ent;
1054                else
1055                   Etyp := Etype (U_Ent);
1056                end if;
1057
1058                --  Check size, note that Gigi is in charge of checking
1059                --  that the size of an array or record type is OK. Also
1060                --  we do not check the size in the ordinary fixed-point
1061                --  case, since it is too early to do so (there may be a
1062                --  subsequent small clause that affects the size). We can
1063                --  check the size if a small clause has already been given.
1064
1065                if not Is_Ordinary_Fixed_Point_Type (U_Ent)
1066                  or else Has_Small_Clause (U_Ent)
1067                then
1068                   Check_Size (Expr, Etyp, Size, Biased);
1069                   Set_Has_Biased_Representation (U_Ent, Biased);
1070                end if;
1071
1072                --  For types set RM_Size and Esize if possible
1073
1074                if Is_Type (U_Ent) then
1075                   Set_RM_Size (U_Ent, Size);
1076
1077                   --  For scalar types, increase Object_Size to power of 2,
1078                   --  but not less than a storage unit in any case (i.e.,
1079                   --  normally this means it will be byte addressable).
1080
1081                   if Is_Scalar_Type (U_Ent) then
1082                      if Size <= System_Storage_Unit then
1083                         Init_Esize (U_Ent, System_Storage_Unit);
1084                      elsif Size <= 16 then
1085                         Init_Esize (U_Ent, 16);
1086                      elsif Size <= 32 then
1087                         Init_Esize (U_Ent, 32);
1088                      else
1089                         Set_Esize  (U_Ent, (Size + 63) / 64 * 64);
1090                      end if;
1091
1092                   --  For all other types, object size = value size. The
1093                   --  backend will adjust as needed.
1094
1095                   else
1096                      Set_Esize (U_Ent, Size);
1097                   end if;
1098
1099                   Alignment_Check_For_Esize_Change (U_Ent);
1100
1101                --  For objects, set Esize only
1102
1103                else
1104                   if Is_Elementary_Type (Etyp) then
1105                      if Size /= System_Storage_Unit
1106                           and then
1107                         Size /= System_Storage_Unit * 2
1108                           and then
1109                         Size /= System_Storage_Unit * 4
1110                            and then
1111                         Size /= System_Storage_Unit * 8
1112                      then
1113                         Error_Msg_N
1114                           ("size for primitive object must be power of 2", N);
1115                      end if;
1116                   end if;
1117
1118                   Set_Esize (U_Ent, Size);
1119                end if;
1120
1121                Set_Has_Size_Clause (U_Ent);
1122             end if;
1123          end Size;
1124
1125          -----------
1126          -- Small --
1127          -----------
1128
1129          --  Small attribute definition clause
1130
1131          when Attribute_Small => Small : declare
1132             Implicit_Base : constant Entity_Id := Base_Type (U_Ent);
1133             Small         : Ureal;
1134
1135          begin
1136             Analyze_And_Resolve (Expr, Any_Real);
1137
1138             if Etype (Expr) = Any_Type then
1139                return;
1140
1141             elsif not Is_Static_Expression (Expr) then
1142                Flag_Non_Static_Expr
1143                  ("small requires static expression!", Expr);
1144                return;
1145
1146             else
1147                Small := Expr_Value_R (Expr);
1148
1149                if Small <= Ureal_0 then
1150                   Error_Msg_N ("small value must be greater than zero", Expr);
1151                   return;
1152                end if;
1153
1154             end if;
1155
1156             if not Is_Ordinary_Fixed_Point_Type (U_Ent) then
1157                Error_Msg_N
1158                  ("small requires an ordinary fixed point type", Nam);
1159
1160             elsif Has_Small_Clause (U_Ent) then
1161                Error_Msg_N ("small already given for &", Nam);
1162
1163             elsif Small > Delta_Value (U_Ent) then
1164                Error_Msg_N
1165                  ("small value must not be greater then delta value", Nam);
1166
1167             else
1168                Set_Small_Value (U_Ent, Small);
1169                Set_Small_Value (Implicit_Base, Small);
1170                Set_Has_Small_Clause (U_Ent);
1171                Set_Has_Small_Clause (Implicit_Base);
1172                Set_Has_Non_Standard_Rep (Implicit_Base);
1173             end if;
1174          end Small;
1175
1176          ------------------
1177          -- Storage_Size --
1178          ------------------
1179
1180          --  Storage_Size attribute definition clause
1181
1182          when Attribute_Storage_Size => Storage_Size : declare
1183             Btype : constant Entity_Id := Base_Type (U_Ent);
1184             Sprag : Node_Id;
1185
1186          begin
1187             if Is_Task_Type (U_Ent) then
1188                if Warn_On_Obsolescent_Feature then
1189                   Error_Msg_N
1190                     ("storage size clause for task is an " &
1191                      "obsolescent feature ('R'M 'J.9)?", N);
1192                   Error_Msg_N
1193                     ("|use Storage_Size pragma instead?", N);
1194                end if;
1195
1196                FOnly := True;
1197             end if;
1198
1199             if not Is_Access_Type (U_Ent)
1200               and then Ekind (U_Ent) /= E_Task_Type
1201             then
1202                Error_Msg_N ("storage size cannot be given for &", Nam);
1203
1204             elsif Is_Access_Type (U_Ent) and Is_Derived_Type (U_Ent) then
1205                Error_Msg_N
1206                  ("storage size cannot be given for a derived access type",
1207                   Nam);
1208
1209             elsif Has_Storage_Size_Clause (Btype) then
1210                Error_Msg_N ("storage size already given for &", Nam);
1211
1212             else
1213                Analyze_And_Resolve (Expr, Any_Integer);
1214
1215                if Is_Access_Type (U_Ent) then
1216
1217                   if Present (Associated_Storage_Pool (U_Ent)) then
1218                      Error_Msg_N ("storage pool already given for &", Nam);
1219                      return;
1220                   end if;
1221
1222                   if Compile_Time_Known_Value (Expr)
1223                     and then Expr_Value (Expr) = 0
1224                   then
1225                      Set_No_Pool_Assigned (Btype);
1226                   end if;
1227
1228                else -- Is_Task_Type (U_Ent)
1229                   Sprag := Get_Rep_Pragma (Btype, Name_Storage_Size);
1230
1231                   if Present (Sprag) then
1232                      Error_Msg_Sloc := Sloc (Sprag);
1233                      Error_Msg_N
1234                        ("Storage_Size already specified#", Nam);
1235                      return;
1236                   end if;
1237                end if;
1238
1239                Set_Has_Storage_Size_Clause (Btype);
1240             end if;
1241          end Storage_Size;
1242
1243          ------------------
1244          -- Storage_Pool --
1245          ------------------
1246
1247          --  Storage_Pool attribute definition clause
1248
1249          when Attribute_Storage_Pool => Storage_Pool : declare
1250             Pool : Entity_Id;
1251
1252          begin
1253             if Ekind (U_Ent) /= E_Access_Type
1254               and then Ekind (U_Ent) /= E_General_Access_Type
1255             then
1256                Error_Msg_N (
1257                  "storage pool can only be given for access types", Nam);
1258                return;
1259
1260             elsif Is_Derived_Type (U_Ent) then
1261                Error_Msg_N
1262                  ("storage pool cannot be given for a derived access type",
1263                   Nam);
1264
1265             elsif Has_Storage_Size_Clause (U_Ent) then
1266                Error_Msg_N ("storage size already given for &", Nam);
1267                return;
1268
1269             elsif Present (Associated_Storage_Pool (U_Ent)) then
1270                Error_Msg_N ("storage pool already given for &", Nam);
1271                return;
1272             end if;
1273
1274             Analyze_And_Resolve
1275               (Expr, Class_Wide_Type (RTE (RE_Root_Storage_Pool)));
1276
1277             --  If the argument is a name that is not an entity name, then
1278             --  we construct a renaming operation to define an entity of
1279             --  type storage pool.
1280
1281             if not Is_Entity_Name (Expr)
1282               and then Is_Object_Reference (Expr)
1283             then
1284                Pool :=
1285                  Make_Defining_Identifier (Loc,
1286                    Chars => New_Internal_Name ('P'));
1287
1288                declare
1289                   Rnode : constant Node_Id :=
1290                             Make_Object_Renaming_Declaration (Loc,
1291                               Defining_Identifier => Pool,
1292                               Subtype_Mark        =>
1293                                 New_Occurrence_Of (Etype (Expr), Loc),
1294                               Name => Expr);
1295
1296                begin
1297                   Insert_Before (N, Rnode);
1298                   Analyze (Rnode);
1299                   Set_Associated_Storage_Pool (U_Ent, Pool);
1300                end;
1301
1302             elsif Is_Entity_Name (Expr) then
1303                Pool := Entity (Expr);
1304
1305                --  If pool is a renamed object, get original one. This can
1306                --  happen with an explicit renaming, and within instances.
1307
1308                while Present (Renamed_Object (Pool))
1309                  and then Is_Entity_Name (Renamed_Object (Pool))
1310                loop
1311                   Pool := Entity (Renamed_Object (Pool));
1312                end loop;
1313
1314                if Present (Renamed_Object (Pool))
1315                  and then Nkind (Renamed_Object (Pool)) = N_Type_Conversion
1316                  and then Is_Entity_Name (Expression (Renamed_Object (Pool)))
1317                then
1318                   Pool := Entity (Expression (Renamed_Object (Pool)));
1319                end if;
1320
1321                if Present (Etype (Pool))
1322                  and then Etype (Pool) /= RTE (RE_Stack_Bounded_Pool)
1323                  and then Etype (Pool) /= RTE (RE_Unbounded_Reclaim_Pool)
1324                then
1325                   Set_Associated_Storage_Pool (U_Ent, Pool);
1326                else
1327                   Error_Msg_N ("Non sharable GNAT Pool", Expr);
1328                end if;
1329
1330             --  The pool may be specified as the Storage_Pool of some other
1331             --  type. It is rewritten as a class_wide conversion of the
1332             --  corresponding pool entity.
1333
1334             elsif Nkind (Expr) = N_Type_Conversion
1335               and then Is_Entity_Name (Expression (Expr))
1336               and then Nkind (Original_Node (Expr)) = N_Attribute_Reference
1337             then
1338                Pool := Entity (Expression (Expr));
1339
1340                if Present (Etype (Pool))
1341                  and then Etype (Pool) /= RTE (RE_Stack_Bounded_Pool)
1342                  and then Etype (Pool) /= RTE (RE_Unbounded_Reclaim_Pool)
1343                then
1344                   Set_Associated_Storage_Pool (U_Ent, Pool);
1345                else
1346                   Error_Msg_N ("Non sharable GNAT Pool", Expr);
1347                end if;
1348
1349             else
1350                Error_Msg_N ("incorrect reference to a Storage Pool", Expr);
1351                return;
1352             end if;
1353          end Storage_Pool;
1354
1355          ----------------
1356          -- Value_Size --
1357          ----------------
1358
1359          --  Value_Size attribute definition clause
1360
1361          when Attribute_Value_Size => Value_Size : declare
1362             Size   : constant Uint := Static_Integer (Expr);
1363             Biased : Boolean;
1364
1365          begin
1366             if not Is_Type (U_Ent) then
1367                Error_Msg_N ("Value_Size cannot be given for &", Nam);
1368
1369             elsif Present
1370                    (Get_Attribute_Definition_Clause
1371                      (U_Ent, Attribute_Value_Size))
1372             then
1373                Error_Msg_N ("Value_Size already given for &", Nam);
1374
1375             else
1376                if Is_Elementary_Type (U_Ent) then
1377                   Check_Size (Expr, U_Ent, Size, Biased);
1378                   Set_Has_Biased_Representation (U_Ent, Biased);
1379                end if;
1380
1381                Set_RM_Size (U_Ent, Size);
1382             end if;
1383          end Value_Size;
1384
1385          -----------
1386          -- Write --
1387          -----------
1388
1389          --  Write attribute definition clause
1390          --  check for class-wide case will be performed later
1391
1392          when Attribute_Write => Write : declare
1393             Subp : Entity_Id := Empty;
1394             I    : Interp_Index;
1395             It   : Interp;
1396             Pnam : Entity_Id;
1397
1398             function Has_Good_Profile (Subp : Entity_Id) return Boolean;
1399             --  Return true if the entity is a procedure with an
1400             --  appropriate profile for the write attribute.
1401
1402             function Has_Good_Profile (Subp : Entity_Id) return Boolean is
1403                F     : Entity_Id;
1404                Ok    : Boolean := False;
1405
1406             begin
1407                if Ekind (Subp) = E_Procedure then
1408                   F := First_Formal (Subp);
1409
1410                   if Present (F) then
1411                      if Ekind (Etype (F)) = E_Anonymous_Access_Type
1412                        and then
1413                          Designated_Type (Etype (F)) =
1414                            Class_Wide_Type (RTE (RE_Root_Stream_Type))
1415                      then
1416                         Next_Formal (F);
1417                         Ok :=  Present (F)
1418                           and then Parameter_Mode (F) = E_In_Parameter
1419                           and then Base_Type (Etype (F)) = Base_Type (Ent)
1420                           and then No (Next_Formal (F));
1421                      end if;
1422                   end if;
1423                end if;
1424
1425                return Ok;
1426             end Has_Good_Profile;
1427
1428          --  Start of processing for Write attribute definition
1429
1430          begin
1431             FOnly := True;
1432
1433             if not Is_Type (U_Ent) then
1434                Error_Msg_N ("local name must be a subtype", Nam);
1435                return;
1436             end if;
1437
1438             Pnam := TSS (Base_Type (U_Ent), TSS_Stream_Write);
1439
1440             if Present (Pnam)
1441               and then Base_Type (Etype (Next_Formal (First_Formal (Pnam))))
1442                 = Base_Type (U_Ent)
1443             then
1444                Error_Msg_Sloc := Sloc (Pnam);
1445                Error_Msg_N ("write attribute already defined #", Nam);
1446                return;
1447             end if;
1448
1449             Analyze (Expr);
1450
1451             if Is_Entity_Name (Expr) then
1452                if not Is_Overloaded (Expr) then
1453                   if Has_Good_Profile (Entity (Expr)) then
1454                      Subp := Entity (Expr);
1455                   end if;
1456
1457                else
1458                   Get_First_Interp (Expr, I, It);
1459
1460                   while Present (It.Nam) loop
1461                      if Has_Good_Profile (It.Nam) then
1462                         Subp := It.Nam;
1463                         exit;
1464                      end if;
1465
1466                      Get_Next_Interp (I, It);
1467                   end loop;
1468                end if;
1469             end if;
1470
1471             if Present (Subp) then
1472                Set_Entity (Expr, Subp);
1473                Set_Etype (Expr, Etype (Subp));
1474                New_Stream_Procedure (N, U_Ent, Subp, TSS_Stream_Write);
1475             else
1476                Error_Msg_N ("incorrect expression for write attribute", Expr);
1477                return;
1478             end if;
1479          end Write;
1480
1481          --  All other attributes cannot be set
1482
1483          when others =>
1484             Error_Msg_N
1485               ("attribute& cannot be set with definition clause", N);
1486
1487       end case;
1488
1489       --  The test for the type being frozen must be performed after
1490       --  any expression the clause has been analyzed since the expression
1491       --  itself might cause freezing that makes the clause illegal.
1492
1493       if Rep_Item_Too_Late (U_Ent, N, FOnly) then
1494          return;
1495       end if;
1496    end Analyze_Attribute_Definition_Clause;
1497
1498    ----------------------------
1499    -- Analyze_Code_Statement --
1500    ----------------------------
1501
1502    procedure Analyze_Code_Statement (N : Node_Id) is
1503       HSS   : constant Node_Id   := Parent (N);
1504       SBody : constant Node_Id   := Parent (HSS);
1505       Subp  : constant Entity_Id := Current_Scope;
1506       Stmt  : Node_Id;
1507       Decl  : Node_Id;
1508       StmtO : Node_Id;
1509       DeclO : Node_Id;
1510
1511    begin
1512       --  Analyze and check we get right type, note that this implements the
1513       --  requirement (RM 13.8(1)) that Machine_Code be with'ed, since that
1514       --  is the only way that Asm_Insn could possibly be visible.
1515
1516       Analyze_And_Resolve (Expression (N));
1517
1518       if Etype (Expression (N)) = Any_Type then
1519          return;
1520       elsif Etype (Expression (N)) /= RTE (RE_Asm_Insn) then
1521          Error_Msg_N ("incorrect type for code statement", N);
1522          return;
1523       end if;
1524
1525       --  Make sure we appear in the handled statement sequence of a
1526       --  subprogram (RM 13.8(3)).
1527
1528       if Nkind (HSS) /= N_Handled_Sequence_Of_Statements
1529         or else Nkind (SBody) /= N_Subprogram_Body
1530       then
1531          Error_Msg_N
1532            ("code statement can only appear in body of subprogram", N);
1533          return;
1534       end if;
1535
1536       --  Do remaining checks (RM 13.8(3)) if not already done
1537
1538       if not Is_Machine_Code_Subprogram (Subp) then
1539          Set_Is_Machine_Code_Subprogram (Subp);
1540
1541          --  No exception handlers allowed
1542
1543          if Present (Exception_Handlers (HSS)) then
1544             Error_Msg_N
1545               ("exception handlers not permitted in machine code subprogram",
1546                First (Exception_Handlers (HSS)));
1547          end if;
1548
1549          --  No declarations other than use clauses and pragmas (we allow
1550          --  certain internally generated declarations as well).
1551
1552          Decl := First (Declarations (SBody));
1553          while Present (Decl) loop
1554             DeclO := Original_Node (Decl);
1555             if Comes_From_Source (DeclO)
1556               and then Nkind (DeclO) /= N_Pragma
1557               and then Nkind (DeclO) /= N_Use_Package_Clause
1558               and then Nkind (DeclO) /= N_Use_Type_Clause
1559               and then Nkind (DeclO) /= N_Implicit_Label_Declaration
1560             then
1561                Error_Msg_N
1562                  ("this declaration not allowed in machine code subprogram",
1563                   DeclO);
1564             end if;
1565
1566             Next (Decl);
1567          end loop;
1568
1569          --  No statements other than code statements, pragmas, and labels.
1570          --  Again we allow certain internally generated statements.
1571
1572          Stmt := First (Statements (HSS));
1573          while Present (Stmt) loop
1574             StmtO := Original_Node (Stmt);
1575             if Comes_From_Source (StmtO)
1576               and then Nkind (StmtO) /= N_Pragma
1577               and then Nkind (StmtO) /= N_Label
1578               and then Nkind (StmtO) /= N_Code_Statement
1579             then
1580                Error_Msg_N
1581                  ("this statement is not allowed in machine code subprogram",
1582                   StmtO);
1583             end if;
1584
1585             Next (Stmt);
1586          end loop;
1587       end if;
1588    end Analyze_Code_Statement;
1589
1590    -----------------------------------------------
1591    -- Analyze_Enumeration_Representation_Clause --
1592    -----------------------------------------------
1593
1594    procedure Analyze_Enumeration_Representation_Clause (N : Node_Id) is
1595       Ident    : constant Node_Id    := Identifier (N);
1596       Aggr     : constant Node_Id    := Array_Aggregate (N);
1597       Enumtype : Entity_Id;
1598       Elit     : Entity_Id;
1599       Expr     : Node_Id;
1600       Assoc    : Node_Id;
1601       Choice   : Node_Id;
1602       Val      : Uint;
1603       Err      : Boolean := False;
1604
1605       Lo  : constant Uint := Expr_Value (Type_Low_Bound (Universal_Integer));
1606       Hi  : constant Uint := Expr_Value (Type_High_Bound (Universal_Integer));
1607       Min : Uint;
1608       Max : Uint;
1609
1610    begin
1611       --  First some basic error checks
1612
1613       Find_Type (Ident);
1614       Enumtype := Entity (Ident);
1615
1616       if Enumtype = Any_Type
1617         or else Rep_Item_Too_Early (Enumtype, N)
1618       then
1619          return;
1620       else
1621          Enumtype := Underlying_Type (Enumtype);
1622       end if;
1623
1624       if not Is_Enumeration_Type (Enumtype) then
1625          Error_Msg_NE
1626            ("enumeration type required, found}",
1627             Ident, First_Subtype (Enumtype));
1628          return;
1629       end if;
1630
1631       --  Ignore rep clause on generic actual type. This will already have
1632       --  been flagged on the template as an error, and this is the safest
1633       --  way to ensure we don't get a junk cascaded message in the instance.
1634
1635       if Is_Generic_Actual_Type (Enumtype) then
1636          return;
1637
1638       --  Type must be in current scope
1639
1640       elsif Scope (Enumtype) /= Current_Scope then
1641          Error_Msg_N ("type must be declared in this scope", Ident);
1642          return;
1643
1644       --  Type must be a first subtype
1645
1646       elsif not Is_First_Subtype (Enumtype) then
1647          Error_Msg_N ("cannot give enumeration rep clause for subtype", N);
1648          return;
1649
1650       --  Ignore duplicate rep clause
1651
1652       elsif Has_Enumeration_Rep_Clause (Enumtype) then
1653          Error_Msg_N ("duplicate enumeration rep clause ignored", N);
1654          return;
1655
1656       --  Don't allow rep clause if root type is standard [wide_]character
1657
1658       elsif Root_Type (Enumtype) = Standard_Character
1659         or else Root_Type (Enumtype) = Standard_Wide_Character
1660       then
1661          Error_Msg_N ("enumeration rep clause not allowed for this type", N);
1662          return;
1663
1664       --  All tests passed, so set rep clause in place
1665
1666       else
1667          Set_Has_Enumeration_Rep_Clause (Enumtype);
1668          Set_Has_Enumeration_Rep_Clause (Base_Type (Enumtype));
1669       end if;
1670
1671       --  Now we process the aggregate. Note that we don't use the normal
1672       --  aggregate code for this purpose, because we don't want any of the
1673       --  normal expansion activities, and a number of special semantic
1674       --  rules apply (including the component type being any integer type)
1675
1676       --  Badent signals that we found some incorrect entries processing
1677       --  the list. The final checks for completeness and ordering are
1678       --  skipped in this case.
1679
1680       Elit := First_Literal (Enumtype);
1681
1682       --  First the positional entries if any
1683
1684       if Present (Expressions (Aggr)) then
1685          Expr := First (Expressions (Aggr));
1686          while Present (Expr) loop
1687             if No (Elit) then
1688                Error_Msg_N ("too many entries in aggregate", Expr);
1689                return;
1690             end if;
1691
1692             Val := Static_Integer (Expr);
1693
1694             if Val = No_Uint then
1695                Err := True;
1696
1697             elsif Val < Lo or else Hi < Val then
1698                Error_Msg_N ("value outside permitted range", Expr);
1699                Err := True;
1700             end if;
1701
1702             Set_Enumeration_Rep (Elit, Val);
1703             Set_Enumeration_Rep_Expr (Elit, Expr);
1704             Next (Expr);
1705             Next (Elit);
1706          end loop;
1707       end if;
1708
1709       --  Now process the named entries if present
1710
1711       if Present (Component_Associations (Aggr)) then
1712          Assoc := First (Component_Associations (Aggr));
1713          while Present (Assoc) loop
1714             Choice := First (Choices (Assoc));
1715
1716             if Present (Next (Choice)) then
1717                Error_Msg_N
1718                  ("multiple choice not allowed here", Next (Choice));
1719                Err := True;
1720             end if;
1721
1722             if Nkind (Choice) = N_Others_Choice then
1723                Error_Msg_N ("others choice not allowed here", Choice);
1724                Err := True;
1725
1726             elsif Nkind (Choice) = N_Range then
1727                --  ??? should allow zero/one element range here
1728                Error_Msg_N ("range not allowed here", Choice);
1729                Err := True;
1730
1731             else
1732                Analyze_And_Resolve (Choice, Enumtype);
1733
1734                if Is_Entity_Name (Choice)
1735                  and then Is_Type (Entity (Choice))
1736                then
1737                   Error_Msg_N ("subtype name not allowed here", Choice);
1738                   Err := True;
1739                   --  ??? should allow static subtype with zero/one entry
1740
1741                elsif Etype (Choice) = Base_Type (Enumtype) then
1742                   if not Is_Static_Expression (Choice) then
1743                      Flag_Non_Static_Expr
1744                        ("non-static expression used for choice!", Choice);
1745                      Err := True;
1746
1747                   else
1748                      Elit := Expr_Value_E (Choice);
1749
1750                      if Present (Enumeration_Rep_Expr (Elit)) then
1751                         Error_Msg_Sloc := Sloc (Enumeration_Rep_Expr (Elit));
1752                         Error_Msg_NE
1753                           ("representation for& previously given#",
1754                            Choice, Elit);
1755                         Err := True;
1756                      end if;
1757
1758                      Set_Enumeration_Rep_Expr (Elit, Choice);
1759
1760                      Expr := Expression (Assoc);
1761                      Val := Static_Integer (Expr);
1762
1763                      if Val = No_Uint then
1764                         Err := True;
1765
1766                      elsif Val < Lo or else Hi < Val then
1767                         Error_Msg_N ("value outside permitted range", Expr);
1768                         Err := True;
1769                      end if;
1770
1771                      Set_Enumeration_Rep (Elit, Val);
1772                   end if;
1773                end if;
1774             end if;
1775
1776             Next (Assoc);
1777          end loop;
1778       end if;
1779
1780       --  Aggregate is fully processed. Now we check that a full set of
1781       --  representations was given, and that they are in range and in order.
1782       --  These checks are only done if no other errors occurred.
1783
1784       if not Err then
1785          Min  := No_Uint;
1786          Max  := No_Uint;
1787
1788          Elit := First_Literal (Enumtype);
1789          while Present (Elit) loop
1790             if No (Enumeration_Rep_Expr (Elit)) then
1791                Error_Msg_NE ("missing representation for&!", N, Elit);
1792
1793             else
1794                Val := Enumeration_Rep (Elit);
1795
1796                if Min = No_Uint then
1797                   Min := Val;
1798                end if;
1799
1800                if Val /= No_Uint then
1801                   if Max /= No_Uint and then Val <= Max then
1802                      Error_Msg_NE
1803                        ("enumeration value for& not ordered!",
1804                                        Enumeration_Rep_Expr (Elit), Elit);
1805                   end if;
1806
1807                   Max := Val;
1808                end if;
1809
1810                --  If there is at least one literal whose representation
1811                --  is not equal to the Pos value, then note that this
1812                --  enumeration type has a non-standard representation.
1813
1814                if Val /= Enumeration_Pos (Elit) then
1815                   Set_Has_Non_Standard_Rep (Base_Type (Enumtype));
1816                end if;
1817             end if;
1818
1819             Next (Elit);
1820          end loop;
1821
1822          --  Now set proper size information
1823
1824          declare
1825             Minsize : Uint := UI_From_Int (Minimum_Size (Enumtype));
1826
1827          begin
1828             if Has_Size_Clause (Enumtype) then
1829                if Esize (Enumtype) >= Minsize then
1830                   null;
1831
1832                else
1833                   Minsize :=
1834                     UI_From_Int (Minimum_Size (Enumtype, Biased => True));
1835
1836                   if Esize (Enumtype) < Minsize then
1837                      Error_Msg_N ("previously given size is too small", N);
1838
1839                   else
1840                      Set_Has_Biased_Representation (Enumtype);
1841                   end if;
1842                end if;
1843
1844             else
1845                Set_RM_Size    (Enumtype, Minsize);
1846                Set_Enum_Esize (Enumtype);
1847             end if;
1848
1849             Set_RM_Size   (Base_Type (Enumtype), RM_Size   (Enumtype));
1850             Set_Esize     (Base_Type (Enumtype), Esize     (Enumtype));
1851             Set_Alignment (Base_Type (Enumtype), Alignment (Enumtype));
1852          end;
1853       end if;
1854
1855       --  We repeat the too late test in case it froze itself!
1856
1857       if Rep_Item_Too_Late (Enumtype, N) then
1858          null;
1859       end if;
1860    end Analyze_Enumeration_Representation_Clause;
1861
1862    ----------------------------
1863    -- Analyze_Free_Statement --
1864    ----------------------------
1865
1866    procedure Analyze_Free_Statement (N : Node_Id) is
1867    begin
1868       Analyze (Expression (N));
1869    end Analyze_Free_Statement;
1870
1871    ------------------------------------------
1872    -- Analyze_Record_Representation_Clause --
1873    ------------------------------------------
1874
1875    procedure Analyze_Record_Representation_Clause (N : Node_Id) is
1876       Loc     : constant Source_Ptr := Sloc (N);
1877       Ident   : constant Node_Id    := Identifier (N);
1878       Rectype : Entity_Id;
1879       Fent    : Entity_Id;
1880       CC      : Node_Id;
1881       Posit   : Uint;
1882       Fbit    : Uint;
1883       Lbit    : Uint;
1884       Hbit    : Uint := Uint_0;
1885       Comp    : Entity_Id;
1886       Ocomp   : Entity_Id;
1887       Biased  : Boolean;
1888
1889       Max_Bit_So_Far : Uint;
1890       --  Records the maximum bit position so far. If all field positions
1891       --  are monotonically increasing, then we can skip the circuit for
1892       --  checking for overlap, since no overlap is possible.
1893
1894       Overlap_Check_Required : Boolean;
1895       --  Used to keep track of whether or not an overlap check is required
1896
1897       Ccount : Natural := 0;
1898       --  Number of component clauses in record rep clause
1899
1900    begin
1901       Find_Type (Ident);
1902       Rectype := Entity (Ident);
1903
1904       if Rectype = Any_Type
1905         or else Rep_Item_Too_Early (Rectype, N)
1906       then
1907          return;
1908       else
1909          Rectype := Underlying_Type (Rectype);
1910       end if;
1911
1912       --  First some basic error checks
1913
1914       if not Is_Record_Type (Rectype) then
1915          Error_Msg_NE
1916            ("record type required, found}", Ident, First_Subtype (Rectype));
1917          return;
1918
1919       elsif Is_Unchecked_Union (Rectype) then
1920          Error_Msg_N
1921            ("record rep clause not allowed for Unchecked_Union", N);
1922
1923       elsif Scope (Rectype) /= Current_Scope then
1924          Error_Msg_N ("type must be declared in this scope", N);
1925          return;
1926
1927       elsif not Is_First_Subtype (Rectype) then
1928          Error_Msg_N ("cannot give record rep clause for subtype", N);
1929          return;
1930
1931       elsif Has_Record_Rep_Clause (Rectype) then
1932          Error_Msg_N ("duplicate record rep clause ignored", N);
1933          return;
1934
1935       elsif Rep_Item_Too_Late (Rectype, N) then
1936          return;
1937       end if;
1938
1939       if Present (Mod_Clause (N)) then
1940          declare
1941             Loc     : constant Source_Ptr := Sloc (N);
1942             M       : constant Node_Id := Mod_Clause (N);
1943             P       : constant List_Id := Pragmas_Before (M);
1944             AtM_Nod : Node_Id;
1945
1946             Mod_Val : Uint;
1947             pragma Warnings (Off, Mod_Val);
1948
1949          begin
1950             if Warn_On_Obsolescent_Feature then
1951                Error_Msg_N
1952                  ("mod clause is an obsolescent feature ('R'M 'J.8)?", N);
1953                Error_Msg_N
1954                  ("|use alignment attribute definition clause instead?", N);
1955             end if;
1956
1957             if Present (P) then
1958                Analyze_List (P);
1959             end if;
1960
1961             --  In ASIS_Mode mode, expansion is disabled, but we must
1962             --  convert the Mod clause into an alignment clause anyway, so
1963             --  that the back-end can compute and back-annotate properly the
1964             --  size and alignment of types that may include this record.
1965
1966             if Operating_Mode = Check_Semantics
1967               and then ASIS_Mode
1968             then
1969                AtM_Nod :=
1970                  Make_Attribute_Definition_Clause (Loc,
1971                    Name       => New_Reference_To (Base_Type (Rectype), Loc),
1972                    Chars      => Name_Alignment,
1973                    Expression => Relocate_Node (Expression (M)));
1974
1975                Set_From_At_Mod (AtM_Nod);
1976                Insert_After (N, AtM_Nod);
1977                Mod_Val := Get_Alignment_Value (Expression (AtM_Nod));
1978                Set_Mod_Clause (N, Empty);
1979
1980             else
1981                --  Get the alignment value to perform error checking
1982
1983                Mod_Val := Get_Alignment_Value (Expression (M));
1984
1985             end if;
1986          end;
1987       end if;
1988
1989       --  Clear any existing component clauses for the type (this happens
1990       --  with derived types, where we are now overriding the original)
1991
1992       Fent := First_Entity (Rectype);
1993
1994       Comp := Fent;
1995       while Present (Comp) loop
1996          if Ekind (Comp) = E_Component
1997            or else Ekind (Comp) = E_Discriminant
1998          then
1999             Set_Component_Clause (Comp, Empty);
2000          end if;
2001
2002          Next_Entity (Comp);
2003       end loop;
2004
2005       --  All done if no component clauses
2006
2007       CC := First (Component_Clauses (N));
2008
2009       if No (CC) then
2010          return;
2011       end if;
2012
2013       --  If a tag is present, then create a component clause that places
2014       --  it at the start of the record (otherwise gigi may place it after
2015       --  other fields that have rep clauses).
2016
2017       if Nkind (Fent) = N_Defining_Identifier
2018         and then Chars (Fent) = Name_uTag
2019       then
2020          Set_Component_Bit_Offset    (Fent, Uint_0);
2021          Set_Normalized_Position     (Fent, Uint_0);
2022          Set_Normalized_First_Bit    (Fent, Uint_0);
2023          Set_Normalized_Position_Max (Fent, Uint_0);
2024          Init_Esize                  (Fent, System_Address_Size);
2025
2026          Set_Component_Clause    (Fent,
2027            Make_Component_Clause (Loc,
2028              Component_Name =>
2029                Make_Identifier (Loc,
2030                  Chars => Name_uTag),
2031
2032              Position  =>
2033                Make_Integer_Literal (Loc,
2034                  Intval => Uint_0),
2035
2036              First_Bit =>
2037                Make_Integer_Literal (Loc,
2038                  Intval => Uint_0),
2039
2040              Last_Bit  =>
2041                Make_Integer_Literal (Loc,
2042                  UI_From_Int (System_Address_Size))));
2043
2044          Ccount := Ccount + 1;
2045       end if;
2046
2047       --  A representation like this applies to the base type
2048
2049       Set_Has_Record_Rep_Clause (Base_Type (Rectype));
2050       Set_Has_Non_Standard_Rep  (Base_Type (Rectype));
2051       Set_Has_Specified_Layout  (Base_Type (Rectype));
2052
2053       Max_Bit_So_Far := Uint_Minus_1;
2054       Overlap_Check_Required := False;
2055
2056       --  Process the component clauses
2057
2058       while Present (CC) loop
2059
2060          --  If pragma, just analyze it
2061
2062          if Nkind (CC) = N_Pragma then
2063             Analyze (CC);
2064
2065          --  Processing for real component clause
2066
2067          else
2068             Ccount := Ccount + 1;
2069             Posit := Static_Integer (Position  (CC));
2070             Fbit  := Static_Integer (First_Bit (CC));
2071             Lbit  := Static_Integer (Last_Bit  (CC));
2072
2073             if Posit /= No_Uint
2074               and then Fbit /= No_Uint
2075               and then Lbit /= No_Uint
2076             then
2077                if Posit < 0 then
2078                   Error_Msg_N
2079                     ("position cannot be negative", Position (CC));
2080
2081                elsif Fbit < 0 then
2082                   Error_Msg_N
2083                     ("first bit cannot be negative", First_Bit (CC));
2084
2085                --  Values look OK, so find the corresponding record component
2086                --  Even though the syntax allows an attribute reference for
2087                --  implementation-defined components, GNAT does not allow the
2088                --  tag to get an explicit position.
2089
2090                elsif Nkind (Component_Name (CC)) = N_Attribute_Reference then
2091
2092                   if Attribute_Name (Component_Name (CC)) = Name_Tag then
2093                      Error_Msg_N ("position of tag cannot be specified", CC);
2094                   else
2095                      Error_Msg_N ("illegal component name", CC);
2096                   end if;
2097
2098                else
2099                   Comp := First_Entity (Rectype);
2100                   while Present (Comp) loop
2101                      exit when Chars (Comp) = Chars (Component_Name (CC));
2102                      Next_Entity (Comp);
2103                   end loop;
2104
2105                   if No (Comp) then
2106
2107                      --  Maybe component of base type that is absent from
2108                      --  statically constrained first subtype.
2109
2110                      Comp := First_Entity (Base_Type (Rectype));
2111                      while Present (Comp) loop
2112                         exit when Chars (Comp) = Chars (Component_Name (CC));
2113                         Next_Entity (Comp);
2114                      end loop;
2115                   end if;
2116
2117                   if No (Comp) then
2118                      Error_Msg_N
2119                        ("component clause is for non-existent field", CC);
2120
2121                   elsif Present (Component_Clause (Comp)) then
2122                      Error_Msg_Sloc := Sloc (Component_Clause (Comp));
2123                      Error_Msg_N
2124                        ("component clause previously given#", CC);
2125
2126                   else
2127                      --  Update Fbit and Lbit to the actual bit number.
2128
2129                      Fbit := Fbit + UI_From_Int (SSU) * Posit;
2130                      Lbit := Lbit + UI_From_Int (SSU) * Posit;
2131
2132                      if Fbit <= Max_Bit_So_Far then
2133                         Overlap_Check_Required := True;
2134                      else
2135                         Max_Bit_So_Far := Lbit;
2136                      end if;
2137
2138                      if Has_Size_Clause (Rectype)
2139                        and then Esize (Rectype) <= Lbit
2140                      then
2141                         Error_Msg_N
2142                           ("bit number out of range of specified size",
2143                            Last_Bit (CC));
2144                      else
2145                         Set_Component_Clause     (Comp, CC);
2146                         Set_Component_Bit_Offset (Comp, Fbit);
2147                         Set_Esize                (Comp, 1 + (Lbit - Fbit));
2148                         Set_Normalized_First_Bit (Comp, Fbit mod SSU);
2149                         Set_Normalized_Position  (Comp, Fbit / SSU);
2150
2151                         Set_Normalized_Position_Max
2152                           (Fent, Normalized_Position (Fent));
2153
2154                         if Is_Tagged_Type (Rectype)
2155                           and then Fbit < System_Address_Size
2156                         then
2157                            Error_Msg_NE
2158                              ("component overlaps tag field of&",
2159                               CC, Rectype);
2160                         end if;
2161
2162                         --  This information is also set in the corresponding
2163                         --  component of the base type, found by accessing the
2164                         --  Original_Record_Component link if it is present.
2165
2166                         Ocomp := Original_Record_Component (Comp);
2167
2168                         if Hbit < Lbit then
2169                            Hbit := Lbit;
2170                         end if;
2171
2172                         Check_Size
2173                           (Component_Name (CC),
2174                            Etype (Comp),
2175                            Esize (Comp),
2176                            Biased);
2177
2178                         Set_Has_Biased_Representation (Comp, Biased);
2179
2180                         if Present (Ocomp) then
2181                            Set_Component_Clause     (Ocomp, CC);
2182                            Set_Component_Bit_Offset (Ocomp, Fbit);
2183                            Set_Normalized_First_Bit (Ocomp, Fbit mod SSU);
2184                            Set_Normalized_Position  (Ocomp, Fbit / SSU);
2185                            Set_Esize                (Ocomp, 1 + (Lbit - Fbit));
2186
2187                            Set_Normalized_Position_Max
2188                              (Ocomp, Normalized_Position (Ocomp));
2189
2190                            Set_Has_Biased_Representation
2191                              (Ocomp, Has_Biased_Representation (Comp));
2192                         end if;
2193
2194                         if Esize (Comp) < 0 then
2195                            Error_Msg_N ("component size is negative", CC);
2196                         end if;
2197                      end if;
2198                   end if;
2199                end if;
2200             end if;
2201          end if;
2202
2203          Next (CC);
2204       end loop;
2205
2206       --  Now that we have processed all the component clauses, check for
2207       --  overlap. We have to leave this till last, since the components
2208       --  can appear in any arbitrary order in the representation clause.
2209
2210       --  We do not need this check if all specified ranges were monotonic,
2211       --  as recorded by Overlap_Check_Required being False at this stage.
2212
2213       --  This first section checks if there are any overlapping entries
2214       --  at all. It does this by sorting all entries and then seeing if
2215       --  there are any overlaps. If there are none, then that is decisive,
2216       --  but if there are overlaps, they may still be OK (they may result
2217       --  from fields in different variants).
2218
2219       if Overlap_Check_Required then
2220          Overlap_Check1 : declare
2221
2222             OC_Fbit : array (0 .. Ccount) of Uint;
2223             --  First-bit values for component clauses, the value is the
2224             --  offset of the first bit of the field from start of record.
2225             --  The zero entry is for use in sorting.
2226
2227             OC_Lbit : array (0 .. Ccount) of Uint;
2228             --  Last-bit values for component clauses, the value is the
2229             --  offset of the last bit of the field from start of record.
2230             --  The zero entry is for use in sorting.
2231
2232             OC_Count : Natural := 0;
2233             --  Count of entries in OC_Fbit and OC_Lbit
2234
2235             function OC_Lt (Op1, Op2 : Natural) return Boolean;
2236             --  Compare routine for Sort (See GNAT.Heap_Sort_A)
2237
2238             procedure OC_Move (From : Natural; To : Natural);
2239             --  Move routine for Sort (see GNAT.Heap_Sort_A)
2240
2241             function OC_Lt (Op1, Op2 : Natural) return Boolean is
2242             begin
2243                return OC_Fbit (Op1) < OC_Fbit (Op2);
2244             end OC_Lt;
2245
2246             procedure OC_Move (From : Natural; To : Natural) is
2247             begin
2248                OC_Fbit (To) := OC_Fbit (From);
2249                OC_Lbit (To) := OC_Lbit (From);
2250             end OC_Move;
2251
2252          begin
2253             CC := First (Component_Clauses (N));
2254             while Present (CC) loop
2255                if Nkind (CC) /= N_Pragma then
2256                   Posit := Static_Integer (Position  (CC));
2257                   Fbit  := Static_Integer (First_Bit (CC));
2258                   Lbit  := Static_Integer (Last_Bit  (CC));
2259
2260                   if Posit /= No_Uint
2261                     and then Fbit /= No_Uint
2262                     and then Lbit /= No_Uint
2263                   then
2264                      OC_Count := OC_Count + 1;
2265                      Posit := Posit * SSU;
2266                      OC_Fbit (OC_Count) := Fbit + Posit;
2267                      OC_Lbit (OC_Count) := Lbit + Posit;
2268                   end if;
2269                end if;
2270
2271                Next (CC);
2272             end loop;
2273
2274             Sort
2275               (OC_Count,
2276                OC_Move'Unrestricted_Access,
2277                OC_Lt'Unrestricted_Access);
2278
2279             Overlap_Check_Required := False;
2280             for J in 1 .. OC_Count - 1 loop
2281                if OC_Lbit (J) >= OC_Fbit (J + 1) then
2282                   Overlap_Check_Required := True;
2283                   exit;
2284                end if;
2285             end loop;
2286          end Overlap_Check1;
2287       end if;
2288
2289       --  If Overlap_Check_Required is still True, then we have to do
2290       --  the full scale overlap check, since we have at least two fields
2291       --  that do overlap, and we need to know if that is OK since they
2292       --  are in the same variant, or whether we have a definite problem
2293
2294       if Overlap_Check_Required then
2295          Overlap_Check2 : declare
2296             C1_Ent, C2_Ent : Entity_Id;
2297             --  Entities of components being checked for overlap
2298
2299             Clist : Node_Id;
2300             --  Component_List node whose Component_Items are being checked
2301
2302             Citem : Node_Id;
2303             --  Component declaration for component being checked
2304
2305          begin
2306             C1_Ent := First_Entity (Base_Type (Rectype));
2307
2308             --  Loop through all components in record. For each component check
2309             --  for overlap with any of the preceding elements on the component
2310             --  list containing the component, and also, if the component is in
2311             --  a variant, check against components outside the case structure.
2312             --  This latter test is repeated recursively up the variant tree.
2313
2314             Main_Component_Loop : while Present (C1_Ent) loop
2315                if Ekind (C1_Ent) /= E_Component
2316                  and then Ekind (C1_Ent) /= E_Discriminant
2317                then
2318                   goto Continue_Main_Component_Loop;
2319                end if;
2320
2321                --  Skip overlap check if entity has no declaration node. This
2322                --  happens with discriminants in constrained derived types.
2323                --  Probably we are missing some checks as a result, but that
2324                --  does not seem terribly serious ???
2325
2326                if No (Declaration_Node (C1_Ent)) then
2327                   goto Continue_Main_Component_Loop;
2328                end if;
2329
2330                Clist := Parent (List_Containing (Declaration_Node (C1_Ent)));
2331
2332                --  Loop through component lists that need checking. Check the
2333                --  current component list and all lists in variants above us.
2334
2335                Component_List_Loop : loop
2336
2337                   --  If derived type definition, go to full declaration
2338                   --  If at outer level, check discriminants if there are any
2339
2340                   if Nkind (Clist) = N_Derived_Type_Definition then
2341                      Clist := Parent (Clist);
2342                   end if;
2343
2344                   --  Outer level of record definition, check discriminants
2345
2346                   if Nkind (Clist) = N_Full_Type_Declaration
2347                     or else Nkind (Clist) = N_Private_Type_Declaration
2348                   then
2349                      if Has_Discriminants (Defining_Identifier (Clist)) then
2350                         C2_Ent :=
2351                           First_Discriminant (Defining_Identifier (Clist));
2352
2353                         while Present (C2_Ent) loop
2354                            exit when C1_Ent = C2_Ent;
2355                            Check_Component_Overlap (C1_Ent, C2_Ent);
2356                            Next_Discriminant (C2_Ent);
2357                         end loop;
2358                      end if;
2359
2360                   --  Record extension case
2361
2362                   elsif Nkind (Clist) = N_Derived_Type_Definition then
2363                      Clist := Empty;
2364
2365                   --  Otherwise check one component list
2366
2367                   else
2368                      Citem := First (Component_Items (Clist));
2369
2370                      while Present (Citem) loop
2371                         if Nkind (Citem) = N_Component_Declaration then
2372                            C2_Ent := Defining_Identifier (Citem);
2373                            exit when C1_Ent = C2_Ent;
2374                            Check_Component_Overlap (C1_Ent, C2_Ent);
2375                         end if;
2376
2377                         Next (Citem);
2378                      end loop;
2379                   end if;
2380
2381                   --  Check for variants above us (the parent of the Clist can
2382                   --  be a variant, in which case its parent is a variant part,
2383                   --  and the parent of the variant part is a component list
2384                   --  whose components must all be checked against the current
2385                   --  component for overlap.
2386
2387                   if Nkind (Parent (Clist)) = N_Variant then
2388                      Clist := Parent (Parent (Parent (Clist)));
2389
2390                   --  Check for possible discriminant part in record, this is
2391                   --  treated essentially as another level in the recursion.
2392                   --  For this case we have the parent of the component list
2393                   --  is the record definition, and its parent is the full
2394                   --  type declaration which contains the discriminant
2395                   --  specifications.
2396
2397                   elsif Nkind (Parent (Clist)) = N_Record_Definition then
2398                      Clist := Parent (Parent ((Clist)));
2399
2400                   --  If neither of these two cases, we are at the top of
2401                   --  the tree
2402
2403                   else
2404                      exit Component_List_Loop;
2405                   end if;
2406                end loop Component_List_Loop;
2407
2408                <<Continue_Main_Component_Loop>>
2409                   Next_Entity (C1_Ent);
2410
2411             end loop Main_Component_Loop;
2412          end Overlap_Check2;
2413       end if;
2414
2415       --  For records that have component clauses for all components, and
2416       --  whose size is less than or equal to 32, we need to know the size
2417       --  in the front end to activate possible packed array processing
2418       --  where the component type is a record.
2419
2420       --  At this stage Hbit + 1 represents the first unused bit from all
2421       --  the component clauses processed, so if the component clauses are
2422       --  complete, then this is the length of the record.
2423
2424       --  For records longer than System.Storage_Unit, and for those where
2425       --  not all components have component clauses, the back end determines
2426       --  the length (it may for example be appopriate to round up the size
2427       --  to some convenient boundary, based on alignment considerations etc).
2428
2429       if Unknown_RM_Size (Rectype)
2430         and then Hbit + 1 <= 32
2431       then
2432          --  Nothing to do if at least one component with no component clause
2433
2434          Comp := First_Entity (Rectype);
2435          while Present (Comp) loop
2436             if Ekind (Comp) = E_Component
2437               or else Ekind (Comp) = E_Discriminant
2438             then
2439                if No (Component_Clause (Comp)) then
2440                   return;
2441                end if;
2442             end if;
2443
2444             Next_Entity (Comp);
2445          end loop;
2446
2447          --  If we fall out of loop, all components have component clauses
2448          --  and so we can set the size to the maximum value.
2449
2450          Set_RM_Size (Rectype, Hbit + 1);
2451       end if;
2452    end Analyze_Record_Representation_Clause;
2453
2454    -----------------------------
2455    -- Check_Component_Overlap --
2456    -----------------------------
2457
2458    procedure Check_Component_Overlap (C1_Ent, C2_Ent : Entity_Id) is
2459    begin
2460       if Present (Component_Clause (C1_Ent))
2461         and then Present (Component_Clause (C2_Ent))
2462       then
2463          --  Exclude odd case where we have two tag fields in the same
2464          --  record, both at location zero. This seems a bit strange,
2465          --  but it seems to happen in some circumstances ???
2466
2467          if Chars (C1_Ent) = Name_uTag
2468            and then Chars (C2_Ent) = Name_uTag
2469          then
2470             return;
2471          end if;
2472
2473          --  Here we check if the two fields overlap
2474
2475          declare
2476             S1 : constant Uint := Component_Bit_Offset (C1_Ent);
2477             S2 : constant Uint := Component_Bit_Offset (C2_Ent);
2478             E1 : constant Uint := S1 + Esize (C1_Ent);
2479             E2 : constant Uint := S2 + Esize (C2_Ent);
2480
2481          begin
2482             if E2 <= S1 or else E1 <= S2 then
2483                null;
2484             else
2485                Error_Msg_Node_2 :=
2486                  Component_Name (Component_Clause (C2_Ent));
2487                Error_Msg_Sloc := Sloc (Error_Msg_Node_2);
2488                Error_Msg_Node_1 :=
2489                  Component_Name (Component_Clause (C1_Ent));
2490                Error_Msg_N
2491                  ("component& overlaps & #",
2492                   Component_Name (Component_Clause (C1_Ent)));
2493             end if;
2494          end;
2495       end if;
2496    end Check_Component_Overlap;
2497
2498    -----------------------------------
2499    -- Check_Constant_Address_Clause --
2500    -----------------------------------
2501
2502    procedure Check_Constant_Address_Clause
2503      (Expr  : Node_Id;
2504       U_Ent : Entity_Id)
2505    is
2506       procedure Check_At_Constant_Address (Nod : Node_Id);
2507       --  Checks that the given node N represents a name whose 'Address
2508       --  is constant (in the same sense as OK_Constant_Address_Clause,
2509       --  i.e. the address value is the same at the point of declaration
2510       --  of U_Ent and at the time of elaboration of the address clause.
2511
2512       procedure Check_Expr_Constants (Nod : Node_Id);
2513       --  Checks that Nod meets the requirements for a constant address
2514       --  clause in the sense of the enclosing procedure.
2515
2516       procedure Check_List_Constants (Lst : List_Id);
2517       --  Check that all elements of list Lst meet the requirements for a
2518       --  constant address clause in the sense of the enclosing procedure.
2519
2520       -------------------------------
2521       -- Check_At_Constant_Address --
2522       -------------------------------
2523
2524       procedure Check_At_Constant_Address (Nod : Node_Id) is
2525       begin
2526          if Is_Entity_Name (Nod) then
2527             if Present (Address_Clause (Entity ((Nod)))) then
2528                Error_Msg_NE
2529                  ("invalid address clause for initialized object &!",
2530                            Nod, U_Ent);
2531                Error_Msg_NE
2532                  ("address for& cannot" &
2533                     " depend on another address clause! ('R'M 13.1(22))!",
2534                   Nod, U_Ent);
2535
2536             elsif In_Same_Source_Unit (Entity (Nod), U_Ent)
2537               and then Sloc (U_Ent) < Sloc (Entity (Nod))
2538             then
2539                Error_Msg_NE
2540                  ("invalid address clause for initialized object &!",
2541                   Nod, U_Ent);
2542                Error_Msg_Name_1 := Chars (Entity (Nod));
2543                Error_Msg_Name_2 := Chars (U_Ent);
2544                Error_Msg_N
2545                  ("\% must be defined before % ('R'M 13.1(22))!",
2546                   Nod);
2547             end if;
2548
2549          elsif Nkind (Nod) = N_Selected_Component then
2550             declare
2551                T : constant Entity_Id := Etype (Prefix (Nod));
2552
2553             begin
2554                if (Is_Record_Type (T)
2555                     and then Has_Discriminants (T))
2556                  or else
2557                   (Is_Access_Type (T)
2558                      and then Is_Record_Type (Designated_Type (T))
2559                      and then Has_Discriminants (Designated_Type (T)))
2560                then
2561                   Error_Msg_NE
2562                     ("invalid address clause for initialized object &!",
2563                      Nod, U_Ent);
2564                   Error_Msg_N
2565                     ("\address cannot depend on component" &
2566                      " of discriminated record ('R'M 13.1(22))!",
2567                      Nod);
2568                else
2569                   Check_At_Constant_Address (Prefix (Nod));
2570                end if;
2571             end;
2572
2573          elsif Nkind (Nod) = N_Indexed_Component then
2574             Check_At_Constant_Address (Prefix (Nod));
2575             Check_List_Constants (Expressions (Nod));
2576
2577          else
2578             Check_Expr_Constants (Nod);
2579          end if;
2580       end Check_At_Constant_Address;
2581
2582       --------------------------
2583       -- Check_Expr_Constants --
2584       --------------------------
2585
2586       procedure Check_Expr_Constants (Nod : Node_Id) is
2587          Loc_U_Ent : constant Source_Ptr := Sloc (U_Ent);
2588          Ent       : Entity_Id           := Empty;
2589
2590       begin
2591          if Nkind (Nod) in N_Has_Etype
2592            and then Etype (Nod) = Any_Type
2593          then
2594             return;
2595          end if;
2596
2597          case Nkind (Nod) is
2598             when N_Empty | N_Error =>
2599                return;
2600
2601             when N_Identifier | N_Expanded_Name =>
2602                Ent := Entity (Nod);
2603
2604                --  We need to look at the original node if it is different
2605                --  from the node, since we may have rewritten things and
2606                --  substituted an identifier representing the rewrite.
2607
2608                if Original_Node (Nod) /= Nod then
2609                   Check_Expr_Constants (Original_Node (Nod));
2610
2611                   --  If the node is an object declaration without initial
2612                   --  value, some code has been expanded, and the expression
2613                   --  is not constant, even if the constituents might be
2614                   --  acceptable, as in  A'Address + offset.
2615
2616                   if Ekind (Ent) = E_Variable
2617                     and then Nkind (Declaration_Node (Ent))
2618                       = N_Object_Declaration
2619                     and then
2620                       No (Expression (Declaration_Node (Ent)))
2621                   then
2622                      Error_Msg_NE
2623                        ("invalid address clause for initialized object &!",
2624                         Nod, U_Ent);
2625
2626                   --  If entity is constant, it may be the result of expanding
2627                   --  a check. We must verify that its declaration appears
2628                   --  before the object in question, else we also reject the
2629                   --  address clause.
2630
2631                   elsif Ekind (Ent) = E_Constant
2632                     and then In_Same_Source_Unit (Ent, U_Ent)
2633                     and then Sloc (Ent) > Loc_U_Ent
2634                   then
2635                      Error_Msg_NE
2636                        ("invalid address clause for initialized object &!",
2637                         Nod, U_Ent);
2638                   end if;
2639
2640                   return;
2641                end if;
2642
2643                --  Otherwise look at the identifier and see if it is OK.
2644
2645                if Ekind (Ent) = E_Named_Integer
2646                     or else
2647                   Ekind (Ent) = E_Named_Real
2648                     or else
2649                   Is_Type (Ent)
2650                then
2651                   return;
2652
2653                elsif
2654                   Ekind (Ent) = E_Constant
2655                     or else
2656                   Ekind (Ent) = E_In_Parameter
2657                then
2658                   --  This is the case where we must have Ent defined
2659                   --  before U_Ent. Clearly if they are in different
2660                   --  units this requirement is met since the unit
2661                   --  containing Ent is already processed.
2662
2663                   if not In_Same_Source_Unit (Ent, U_Ent) then
2664                      return;
2665
2666                   --  Otherwise location of Ent must be before the
2667                   --  location of U_Ent, that's what prior defined means.
2668
2669                   elsif Sloc (Ent) < Loc_U_Ent then
2670                      return;
2671
2672                   else
2673                      Error_Msg_NE
2674                        ("invalid address clause for initialized object &!",
2675                         Nod, U_Ent);
2676                      Error_Msg_Name_1 := Chars (Ent);
2677                      Error_Msg_Name_2 := Chars (U_Ent);
2678                      Error_Msg_N
2679                        ("\% must be defined before % ('R'M 13.1(22))!",
2680                         Nod);
2681                   end if;
2682
2683                elsif Nkind (Original_Node (Nod)) = N_Function_Call then
2684                   Check_Expr_Constants (Original_Node (Nod));
2685
2686                else
2687                   Error_Msg_NE
2688                     ("invalid address clause for initialized object &!",
2689                      Nod, U_Ent);
2690
2691                   if Comes_From_Source (Ent) then
2692                      Error_Msg_Name_1 := Chars (Ent);
2693                      Error_Msg_N
2694                        ("\reference to variable% not allowed"
2695                           & " ('R'M 13.1(22))!", Nod);
2696                   else
2697                      Error_Msg_N
2698                        ("non-static expression not allowed"
2699                           & " ('R'M 13.1(22))!", Nod);
2700                   end if;
2701                end if;
2702
2703             when N_Integer_Literal   =>
2704
2705                --  If this is a rewritten unchecked conversion, in a system
2706                --  where Address is an integer type, always use the base type
2707                --  for a literal value. This is user-friendly and prevents
2708                --  order-of-elaboration issues with instances of unchecked
2709                --  conversion.
2710
2711                if Nkind (Original_Node (Nod)) = N_Function_Call then
2712                   Set_Etype (Nod, Base_Type (Etype (Nod)));
2713                end if;
2714
2715             when N_Real_Literal      |
2716                  N_String_Literal    |
2717                  N_Character_Literal =>
2718                return;
2719
2720             when N_Range =>
2721                Check_Expr_Constants (Low_Bound (Nod));
2722                Check_Expr_Constants (High_Bound (Nod));
2723
2724             when N_Explicit_Dereference =>
2725                Check_Expr_Constants (Prefix (Nod));
2726
2727             when N_Indexed_Component =>
2728                Check_Expr_Constants (Prefix (Nod));
2729                Check_List_Constants (Expressions (Nod));
2730
2731             when N_Slice =>
2732                Check_Expr_Constants (Prefix (Nod));
2733                Check_Expr_Constants (Discrete_Range (Nod));
2734
2735             when N_Selected_Component =>
2736                Check_Expr_Constants (Prefix (Nod));
2737
2738             when N_Attribute_Reference =>
2739
2740                if Attribute_Name (Nod) = Name_Address
2741                    or else
2742                   Attribute_Name (Nod) = Name_Access
2743                     or else
2744                   Attribute_Name (Nod) = Name_Unchecked_Access
2745                     or else
2746                   Attribute_Name (Nod) = Name_Unrestricted_Access
2747                then
2748                   Check_At_Constant_Address (Prefix (Nod));
2749
2750                else
2751                   Check_Expr_Constants (Prefix (Nod));
2752                   Check_List_Constants (Expressions (Nod));
2753                end if;
2754
2755             when N_Aggregate =>
2756                Check_List_Constants (Component_Associations (Nod));
2757                Check_List_Constants (Expressions (Nod));
2758
2759             when N_Component_Association =>
2760                Check_Expr_Constants (Expression (Nod));
2761
2762             when N_Extension_Aggregate =>
2763                Check_Expr_Constants (Ancestor_Part (Nod));
2764                Check_List_Constants (Component_Associations (Nod));
2765                Check_List_Constants (Expressions (Nod));
2766
2767             when N_Null =>
2768                return;
2769
2770             when N_Binary_Op | N_And_Then | N_Or_Else | N_In | N_Not_In =>
2771                Check_Expr_Constants (Left_Opnd (Nod));
2772                Check_Expr_Constants (Right_Opnd (Nod));
2773
2774             when N_Unary_Op =>
2775                Check_Expr_Constants (Right_Opnd (Nod));
2776
2777             when N_Type_Conversion           |
2778                  N_Qualified_Expression      |
2779                  N_Allocator                 =>
2780                Check_Expr_Constants (Expression (Nod));
2781
2782             when N_Unchecked_Type_Conversion =>
2783                Check_Expr_Constants (Expression (Nod));
2784
2785                --  If this is a rewritten unchecked conversion, subtypes
2786                --  in this node are those created within the instance.
2787                --  To avoid order of elaboration issues, replace them
2788                --  with their base types. Note that address clauses can
2789                --  cause order of elaboration problems because they are
2790                --  elaborated by the back-end at the point of definition,
2791                --  and may mention entities declared in between (as long
2792                --  as everything is static). It is user-friendly to allow
2793                --  unchecked conversions in this context.
2794
2795                if Nkind (Original_Node (Nod)) = N_Function_Call then
2796                   Set_Etype (Expression (Nod),
2797                     Base_Type (Etype (Expression (Nod))));
2798                   Set_Etype (Nod, Base_Type (Etype (Nod)));
2799                end if;
2800
2801             when N_Function_Call =>
2802                if not Is_Pure (Entity (Name (Nod))) then
2803                   Error_Msg_NE
2804                     ("invalid address clause for initialized object &!",
2805                      Nod, U_Ent);
2806
2807                   Error_Msg_NE
2808                     ("\function & is not pure ('R'M 13.1(22))!",
2809                      Nod, Entity (Name (Nod)));
2810
2811                else
2812                   Check_List_Constants (Parameter_Associations (Nod));
2813                end if;
2814
2815             when N_Parameter_Association =>
2816                Check_Expr_Constants (Explicit_Actual_Parameter (Nod));
2817
2818             when others =>
2819                Error_Msg_NE
2820                  ("invalid address clause for initialized object &!",
2821                   Nod, U_Ent);
2822                Error_Msg_NE
2823                  ("\must be constant defined before& ('R'M 13.1(22))!",
2824                   Nod, U_Ent);
2825          end case;
2826       end Check_Expr_Constants;
2827
2828       --------------------------
2829       -- Check_List_Constants --
2830       --------------------------
2831
2832       procedure Check_List_Constants (Lst : List_Id) is
2833          Nod1 : Node_Id;
2834
2835       begin
2836          if Present (Lst) then
2837             Nod1 := First (Lst);
2838             while Present (Nod1) loop
2839                Check_Expr_Constants (Nod1);
2840                Next (Nod1);
2841             end loop;
2842          end if;
2843       end Check_List_Constants;
2844
2845    --  Start of processing for Check_Constant_Address_Clause
2846
2847    begin
2848       Check_Expr_Constants (Expr);
2849    end Check_Constant_Address_Clause;
2850
2851    ----------------
2852    -- Check_Size --
2853    ----------------
2854
2855    procedure Check_Size
2856      (N      : Node_Id;
2857       T      : Entity_Id;
2858       Siz    : Uint;
2859       Biased : out Boolean)
2860    is
2861       UT : constant Entity_Id := Underlying_Type (T);
2862       M  : Uint;
2863
2864    begin
2865       Biased := False;
2866
2867       --  Dismiss cases for generic types or types with previous errors
2868
2869       if No (UT)
2870         or else UT = Any_Type
2871         or else Is_Generic_Type (UT)
2872         or else Is_Generic_Type (Root_Type (UT))
2873       then
2874          return;
2875
2876       --  Check case of bit packed array
2877
2878       elsif Is_Array_Type (UT)
2879         and then Known_Static_Component_Size (UT)
2880         and then Is_Bit_Packed_Array (UT)
2881       then
2882          declare
2883             Asiz : Uint;
2884             Indx : Node_Id;
2885             Ityp : Entity_Id;
2886
2887          begin
2888             Asiz := Component_Size (UT);
2889             Indx := First_Index (UT);
2890             loop
2891                Ityp := Etype (Indx);
2892
2893                --  If non-static bound, then we are not in the business of
2894                --  trying to check the length, and indeed an error will be
2895                --  issued elsewhere, since sizes of non-static array types
2896                --  cannot be set implicitly or explicitly.
2897
2898                if not Is_Static_Subtype (Ityp) then
2899                   return;
2900                end if;
2901
2902                --  Otherwise accumulate next dimension
2903
2904                Asiz := Asiz * (Expr_Value (Type_High_Bound (Ityp)) -
2905                                Expr_Value (Type_Low_Bound  (Ityp)) +
2906                                Uint_1);
2907
2908                Next_Index (Indx);
2909                exit when No (Indx);
2910             end loop;
2911
2912             if Asiz <= Siz then
2913                return;
2914             else
2915                Error_Msg_Uint_1 := Asiz;
2916                Error_Msg_NE
2917                  ("size for& too small, minimum allowed is ^", N, T);
2918                Set_Esize   (T, Asiz);
2919                Set_RM_Size (T, Asiz);
2920             end if;
2921          end;
2922
2923       --  All other composite types are ignored
2924
2925       elsif Is_Composite_Type (UT) then
2926          return;
2927
2928       --  For fixed-point types, don't check minimum if type is not frozen,
2929       --  since we don't know all the characteristics of the type that can
2930       --  affect the size (e.g. a specified small) till freeze time.
2931
2932       elsif Is_Fixed_Point_Type (UT)
2933         and then not Is_Frozen (UT)
2934       then
2935          null;
2936
2937       --  Cases for which a minimum check is required
2938
2939       else
2940          --  Ignore if specified size is correct for the type
2941
2942          if Known_Esize (UT) and then Siz = Esize (UT) then
2943             return;
2944          end if;
2945
2946          --  Otherwise get minimum size
2947
2948          M := UI_From_Int (Minimum_Size (UT));
2949
2950          if Siz < M then
2951
2952             --  Size is less than minimum size, but one possibility remains
2953             --  that we can manage with the new size if we bias the type
2954
2955             M := UI_From_Int (Minimum_Size (UT, Biased => True));
2956
2957             if Siz < M then
2958                Error_Msg_Uint_1 := M;
2959                Error_Msg_NE
2960                  ("size for& too small, minimum allowed is ^", N, T);
2961                Set_Esize (T, M);
2962                Set_RM_Size (T, M);
2963             else
2964                Biased := True;
2965             end if;
2966          end if;
2967       end if;
2968    end Check_Size;
2969
2970    -------------------------
2971    -- Get_Alignment_Value --
2972    -------------------------
2973
2974    function Get_Alignment_Value (Expr : Node_Id) return Uint is
2975       Align : constant Uint := Static_Integer (Expr);
2976
2977    begin
2978       if Align = No_Uint then
2979          return No_Uint;
2980
2981       elsif Align <= 0 then
2982          Error_Msg_N ("alignment value must be positive", Expr);
2983          return No_Uint;
2984
2985       else
2986          for J in Int range 0 .. 64 loop
2987             declare
2988                M : constant Uint := Uint_2 ** J;
2989
2990             begin
2991                exit when M = Align;
2992
2993                if M > Align then
2994                   Error_Msg_N
2995                     ("alignment value must be power of 2", Expr);
2996                   return No_Uint;
2997                end if;
2998             end;
2999          end loop;
3000
3001          return Align;
3002       end if;
3003    end Get_Alignment_Value;
3004
3005    ----------------
3006    -- Initialize --
3007    ----------------
3008
3009    procedure Initialize is
3010    begin
3011       Unchecked_Conversions.Init;
3012    end Initialize;
3013
3014    -------------------------
3015    -- Is_Operational_Item --
3016    -------------------------
3017
3018    function Is_Operational_Item (N : Node_Id) return Boolean is
3019    begin
3020       if Nkind (N) /= N_Attribute_Definition_Clause then
3021          return False;
3022       else
3023          declare
3024             Id    : constant Attribute_Id := Get_Attribute_Id (Chars (N));
3025
3026          begin
3027             return Id = Attribute_Input
3028               or else Id = Attribute_Output
3029               or else Id = Attribute_Read
3030               or else Id = Attribute_Write
3031               or else Id = Attribute_External_Tag;
3032          end;
3033       end if;
3034    end Is_Operational_Item;
3035
3036    --------------------------------------
3037    -- Mark_Aliased_Address_As_Volatile --
3038    --------------------------------------
3039
3040    procedure Mark_Aliased_Address_As_Volatile (N : Node_Id) is
3041       Ent : constant Entity_Id := Address_Aliased_Entity (N);
3042
3043    begin
3044       if Present (Ent) then
3045          Set_Treat_As_Volatile (Ent);
3046       end if;
3047    end Mark_Aliased_Address_As_Volatile;
3048
3049    ------------------
3050    -- Minimum_Size --
3051    ------------------
3052
3053    function Minimum_Size
3054      (T      : Entity_Id;
3055       Biased : Boolean := False) return Nat
3056    is
3057       Lo     : Uint    := No_Uint;
3058       Hi     : Uint    := No_Uint;
3059       LoR    : Ureal   := No_Ureal;
3060       HiR    : Ureal   := No_Ureal;
3061       LoSet  : Boolean := False;
3062       HiSet  : Boolean := False;
3063       B      : Uint;
3064       S      : Nat;
3065       Ancest : Entity_Id;
3066       R_Typ  : constant Entity_Id := Root_Type (T);
3067
3068    begin
3069       --  If bad type, return 0
3070
3071       if T = Any_Type then
3072          return 0;
3073
3074       --  For generic types, just return zero. There cannot be any legitimate
3075       --  need to know such a size, but this routine may be called with a
3076       --  generic type as part of normal processing.
3077
3078       elsif Is_Generic_Type (R_Typ)
3079         or else R_Typ = Any_Type
3080       then
3081          return 0;
3082
3083          --  Access types. Normally an access type cannot have a size smaller
3084          --  than the size of System.Address. The exception is on VMS, where
3085          --  we have short and long addresses, and it is possible for an access
3086          --  type to have a short address size (and thus be less than the size
3087          --  of System.Address itself). We simply skip the check for VMS, and
3088          --  leave the back end to do the check.
3089
3090       elsif Is_Access_Type (T) then
3091          if OpenVMS_On_Target then
3092             return 0;
3093          else
3094             return System_Address_Size;
3095          end if;
3096
3097       --  Floating-point types
3098
3099       elsif Is_Floating_Point_Type (T) then
3100          return UI_To_Int (Esize (R_Typ));
3101
3102       --  Discrete types
3103
3104       elsif Is_Discrete_Type (T) then
3105
3106          --  The following loop is looking for the nearest compile time
3107          --  known bounds following the ancestor subtype chain. The idea
3108          --  is to find the most restrictive known bounds information.
3109
3110          Ancest := T;
3111          loop
3112             if Ancest = Any_Type or else Etype (Ancest) = Any_Type then
3113                return 0;
3114             end if;
3115
3116             if not LoSet then
3117                if Compile_Time_Known_Value (Type_Low_Bound (Ancest)) then
3118                   Lo := Expr_Rep_Value (Type_Low_Bound (Ancest));
3119                   LoSet := True;
3120                   exit when HiSet;
3121                end if;
3122             end if;
3123
3124             if not HiSet then
3125                if Compile_Time_Known_Value (Type_High_Bound (Ancest)) then
3126                   Hi := Expr_Rep_Value (Type_High_Bound (Ancest));
3127                   HiSet := True;
3128                   exit when LoSet;
3129                end if;
3130             end if;
3131
3132             Ancest := Ancestor_Subtype (Ancest);
3133
3134             if No (Ancest) then
3135                Ancest := Base_Type (T);
3136
3137                if Is_Generic_Type (Ancest) then
3138                   return 0;
3139                end if;
3140             end if;
3141          end loop;
3142
3143       --  Fixed-point types. We can't simply use Expr_Value to get the
3144       --  Corresponding_Integer_Value values of the bounds, since these
3145       --  do not get set till the type is frozen, and this routine can
3146       --  be called before the type is frozen. Similarly the test for
3147       --  bounds being static needs to include the case where we have
3148       --  unanalyzed real literals for the same reason.
3149
3150       elsif Is_Fixed_Point_Type (T) then
3151
3152          --  The following loop is looking for the nearest compile time
3153          --  known bounds following the ancestor subtype chain. The idea
3154          --  is to find the most restrictive known bounds information.
3155
3156          Ancest := T;
3157          loop
3158             if Ancest = Any_Type or else Etype (Ancest) = Any_Type then
3159                return 0;
3160             end if;
3161
3162             if not LoSet then
3163                if Nkind (Type_Low_Bound (Ancest)) = N_Real_Literal
3164                  or else Compile_Time_Known_Value (Type_Low_Bound (Ancest))
3165                then
3166                   LoR := Expr_Value_R (Type_Low_Bound (Ancest));
3167                   LoSet := True;
3168                   exit when HiSet;
3169                end if;
3170             end if;
3171
3172             if not HiSet then
3173                if Nkind (Type_High_Bound (Ancest)) = N_Real_Literal
3174                  or else Compile_Time_Known_Value (Type_High_Bound (Ancest))
3175                then
3176                   HiR := Expr_Value_R (Type_High_Bound (Ancest));
3177                   HiSet := True;
3178                   exit when LoSet;
3179                end if;
3180             end if;
3181
3182             Ancest := Ancestor_Subtype (Ancest);
3183
3184             if No (Ancest) then
3185                Ancest := Base_Type (T);
3186
3187                if Is_Generic_Type (Ancest) then
3188                   return 0;
3189                end if;
3190             end if;
3191          end loop;
3192
3193          Lo := UR_To_Uint (LoR / Small_Value (T));
3194          Hi := UR_To_Uint (HiR / Small_Value (T));
3195
3196       --  No other types allowed
3197
3198       else
3199          raise Program_Error;
3200       end if;
3201
3202       --  Fall through with Hi and Lo set. Deal with biased case.
3203
3204       if (Biased and then not Is_Fixed_Point_Type (T))
3205         or else Has_Biased_Representation (T)
3206       then
3207          Hi := Hi - Lo;
3208          Lo := Uint_0;
3209       end if;
3210
3211       --  Signed case. Note that we consider types like range 1 .. -1 to be
3212       --  signed for the purpose of computing the size, since the bounds
3213       --  have to be accomodated in the base type.
3214
3215       if Lo < 0 or else Hi < 0 then
3216          S := 1;
3217          B := Uint_1;
3218
3219          --  S = size, B = 2 ** (size - 1) (can accommodate -B .. +(B - 1))
3220          --  Note that we accommodate the case where the bounds cross. This
3221          --  can happen either because of the way the bounds are declared
3222          --  or because of the algorithm in Freeze_Fixed_Point_Type.
3223
3224          while Lo < -B
3225            or else Hi < -B
3226            or else Lo >= B
3227            or else Hi >= B
3228          loop
3229             B := Uint_2 ** S;
3230             S := S + 1;
3231          end loop;
3232
3233       --  Unsigned case
3234
3235       else
3236          --  If both bounds are positive, make sure that both are represen-
3237          --  table in the case where the bounds are crossed. This can happen
3238          --  either because of the way the bounds are declared, or because of
3239          --  the algorithm in Freeze_Fixed_Point_Type.
3240
3241          if Lo > Hi then
3242             Hi := Lo;
3243          end if;
3244
3245          --  S = size, (can accommodate 0 .. (2**size - 1))
3246
3247          S := 0;
3248          while Hi >= Uint_2 ** S loop
3249             S := S + 1;
3250          end loop;
3251       end if;
3252
3253       return S;
3254    end Minimum_Size;
3255
3256    -------------------------
3257    -- New_Stream_Function --
3258    -------------------------
3259
3260    procedure New_Stream_Function
3261      (N    : Node_Id;
3262       Ent  : Entity_Id;
3263       Subp : Entity_Id;
3264       Nam  : TSS_Name_Type)
3265    is
3266       Loc       : constant Source_Ptr := Sloc (N);
3267       Sname     : constant Name_Id    := Make_TSS_Name (Base_Type (Ent), Nam);
3268       Subp_Id   : Entity_Id;
3269       Subp_Decl : Node_Id;
3270       F         : Entity_Id;
3271       Etyp      : Entity_Id;
3272
3273       function Build_Spec return Node_Id;
3274       --  Used for declaration and renaming declaration, so that this is
3275       --  treated as a renaming_as_body.
3276
3277       ----------------
3278       -- Build_Spec --
3279       ----------------
3280
3281       function Build_Spec return Node_Id is
3282       begin
3283          Subp_Id := Make_Defining_Identifier (Loc, Sname);
3284
3285          return
3286            Make_Function_Specification (Loc,
3287              Defining_Unit_Name => Subp_Id,
3288              Parameter_Specifications =>
3289                New_List (
3290                  Make_Parameter_Specification (Loc,
3291                    Defining_Identifier =>
3292                      Make_Defining_Identifier (Loc, Name_S),
3293                    Parameter_Type =>
3294                      Make_Access_Definition (Loc,
3295                        Subtype_Mark =>
3296                          New_Reference_To (
3297                            Designated_Type (Etype (F)), Loc)))),
3298
3299              Subtype_Mark =>
3300                New_Reference_To (Etyp, Loc));
3301       end Build_Spec;
3302
3303    --  Start of processing for New_Stream_Function
3304
3305    begin
3306       F    := First_Formal (Subp);
3307       Etyp := Etype (Subp);
3308
3309       if not Is_Tagged_Type (Ent) then
3310          Subp_Decl :=
3311            Make_Subprogram_Declaration (Loc,
3312              Specification => Build_Spec);
3313          Insert_Action (N, Subp_Decl);
3314       end if;
3315
3316       Subp_Decl :=
3317         Make_Subprogram_Renaming_Declaration (Loc,
3318           Specification => Build_Spec,
3319           Name => New_Reference_To (Subp, Loc));
3320
3321       if Is_Tagged_Type (Ent) and then not Is_Limited_Type (Ent) then
3322          Set_TSS (Base_Type (Ent), Subp_Id);
3323       else
3324          Insert_Action (N, Subp_Decl);
3325          Copy_TSS (Subp_Id, Base_Type (Ent));
3326       end if;
3327    end New_Stream_Function;
3328
3329    --------------------------
3330    -- New_Stream_Procedure --
3331    --------------------------
3332
3333    procedure New_Stream_Procedure
3334      (N     : Node_Id;
3335       Ent   : Entity_Id;
3336       Subp  : Entity_Id;
3337       Nam   : TSS_Name_Type;
3338       Out_P : Boolean := False)
3339    is
3340       Loc       : constant Source_Ptr := Sloc (N);
3341       Sname     : constant Name_Id    := Make_TSS_Name (Base_Type (Ent), Nam);
3342       Subp_Id   : Entity_Id;
3343       Subp_Decl : Node_Id;
3344       F         : Entity_Id;
3345       Etyp      : Entity_Id;
3346
3347       function Build_Spec return Node_Id;
3348       --  Used for declaration and renaming declaration, so that this is
3349       --  treated as a renaming_as_body.
3350
3351       ----------------
3352       -- Build_Spec --
3353       ----------------
3354
3355       function Build_Spec return Node_Id is
3356       begin
3357          Subp_Id := Make_Defining_Identifier (Loc, Sname);
3358
3359          return
3360            Make_Procedure_Specification (Loc,
3361              Defining_Unit_Name => Subp_Id,
3362              Parameter_Specifications =>
3363                New_List (
3364                  Make_Parameter_Specification (Loc,
3365                    Defining_Identifier =>
3366                      Make_Defining_Identifier (Loc, Name_S),
3367                    Parameter_Type =>
3368                      Make_Access_Definition (Loc,
3369                        Subtype_Mark =>
3370                          New_Reference_To (
3371                            Designated_Type (Etype (F)), Loc))),
3372
3373                  Make_Parameter_Specification (Loc,
3374                    Defining_Identifier =>
3375                      Make_Defining_Identifier (Loc, Name_V),
3376                    Out_Present => Out_P,
3377                    Parameter_Type =>
3378                      New_Reference_To (Etyp, Loc))));
3379       end Build_Spec;
3380
3381       --  Start of processing for New_Stream_Procedure
3382
3383    begin
3384       F        := First_Formal (Subp);
3385       Etyp     := Etype (Next_Formal (F));
3386
3387       if not Is_Tagged_Type (Ent) then
3388          Subp_Decl :=
3389            Make_Subprogram_Declaration (Loc,
3390              Specification => Build_Spec);
3391          Insert_Action (N, Subp_Decl);
3392       end if;
3393
3394       Subp_Decl :=
3395         Make_Subprogram_Renaming_Declaration (Loc,
3396           Specification => Build_Spec,
3397           Name => New_Reference_To (Subp, Loc));
3398
3399       if Is_Tagged_Type (Ent) and then not Is_Limited_Type (Ent) then
3400          Set_TSS (Base_Type (Ent), Subp_Id);
3401       else
3402          Insert_Action (N, Subp_Decl);
3403          Copy_TSS (Subp_Id, Base_Type (Ent));
3404       end if;
3405    end New_Stream_Procedure;
3406
3407    ---------------------
3408    -- Record_Rep_Item --
3409    ---------------------
3410
3411    procedure Record_Rep_Item (T : Entity_Id; N : Node_Id) is
3412    begin
3413       Set_Next_Rep_Item (N, First_Rep_Item (T));
3414       Set_First_Rep_Item (T, N);
3415    end Record_Rep_Item;
3416
3417    ------------------------
3418    -- Rep_Item_Too_Early --
3419    ------------------------
3420
3421    function Rep_Item_Too_Early
3422      (T : Entity_Id;
3423       N : Node_Id) return Boolean
3424    is
3425    begin
3426       --  Cannot apply rep items that are not operational items
3427       --  to generic types
3428
3429       if Is_Operational_Item (N) then
3430          return False;
3431
3432       elsif Is_Type (T)
3433         and then Is_Generic_Type (Root_Type (T))
3434       then
3435          Error_Msg_N
3436            ("representation item not allowed for generic type", N);
3437          return True;
3438       end if;
3439
3440       --  Otherwise check for incompleted type
3441
3442       if Is_Incomplete_Or_Private_Type (T)
3443         and then No (Underlying_Type (T))
3444       then
3445          Error_Msg_N
3446            ("representation item must be after full type declaration", N);
3447          return True;
3448
3449       --  If the type has incompleted components, a representation clause is
3450       --  illegal but stream attributes and Convention pragmas are correct.
3451
3452       elsif Has_Private_Component (T) then
3453          if Nkind (N) = N_Pragma then
3454             return False;
3455          else
3456             Error_Msg_N
3457               ("representation item must appear after type is fully defined",
3458                 N);
3459             return True;
3460          end if;
3461       else
3462          return False;
3463       end if;
3464    end Rep_Item_Too_Early;
3465
3466    -----------------------
3467    -- Rep_Item_Too_Late --
3468    -----------------------
3469
3470    function Rep_Item_Too_Late
3471      (T     : Entity_Id;
3472       N     : Node_Id;
3473       FOnly : Boolean := False) return Boolean
3474    is
3475       S           : Entity_Id;
3476       Parent_Type : Entity_Id;
3477
3478       procedure Too_Late;
3479       --  Output the too late message
3480
3481       procedure Too_Late is
3482       begin
3483          Error_Msg_N ("representation item appears too late!", N);
3484       end Too_Late;
3485
3486    --  Start of processing for Rep_Item_Too_Late
3487
3488    begin
3489       --  First make sure entity is not frozen (RM 13.1(9)). Exclude imported
3490       --  types, which may be frozen if they appear in a representation clause
3491       --  for a local type.
3492
3493       if Is_Frozen (T)
3494         and then not From_With_Type (T)
3495       then
3496          Too_Late;
3497          S := First_Subtype (T);
3498
3499          if Present (Freeze_Node (S)) then
3500             Error_Msg_NE
3501               ("?no more representation items for }!", Freeze_Node (S), S);
3502          end if;
3503
3504          return True;
3505
3506       --  Check for case of non-tagged derived type whose parent either has
3507       --  primitive operations, or is a by reference type (RM 13.1(10)).
3508
3509       elsif Is_Type (T)
3510         and then not FOnly
3511         and then Is_Derived_Type (T)
3512         and then not Is_Tagged_Type (T)
3513       then
3514          Parent_Type := Etype (Base_Type (T));
3515
3516          if Has_Primitive_Operations (Parent_Type) then
3517             Too_Late;
3518             Error_Msg_NE
3519               ("primitive operations already defined for&!", N, Parent_Type);
3520             return True;
3521
3522          elsif Is_By_Reference_Type (Parent_Type) then
3523             Too_Late;
3524             Error_Msg_NE
3525               ("parent type & is a by reference type!", N, Parent_Type);
3526             return True;
3527          end if;
3528       end if;
3529
3530       --  No error, link item into head of chain of rep items for the entity
3531
3532       Record_Rep_Item (T, N);
3533       return False;
3534    end Rep_Item_Too_Late;
3535
3536    -------------------------
3537    -- Same_Representation --
3538    -------------------------
3539
3540    function Same_Representation (Typ1, Typ2 : Entity_Id) return Boolean is
3541       T1 : constant Entity_Id := Underlying_Type (Typ1);
3542       T2 : constant Entity_Id := Underlying_Type (Typ2);
3543
3544    begin
3545       --  A quick check, if base types are the same, then we definitely have
3546       --  the same representation, because the subtype specific representation
3547       --  attributes (Size and Alignment) do not affect representation from
3548       --  the point of view of this test.
3549
3550       if Base_Type (T1) = Base_Type (T2) then
3551          return True;
3552
3553       elsif Is_Private_Type (Base_Type (T2))
3554         and then Base_Type (T1) = Full_View (Base_Type (T2))
3555       then
3556          return True;
3557       end if;
3558
3559       --  Tagged types never have differing representations
3560
3561       if Is_Tagged_Type (T1) then
3562          return True;
3563       end if;
3564
3565       --  Representations are definitely different if conventions differ
3566
3567       if Convention (T1) /= Convention (T2) then
3568          return False;
3569       end if;
3570
3571       --  Representations are different if component alignments differ
3572
3573       if (Is_Record_Type (T1) or else Is_Array_Type (T1))
3574         and then
3575          (Is_Record_Type (T2) or else Is_Array_Type (T2))
3576         and then Component_Alignment (T1) /= Component_Alignment (T2)
3577       then
3578          return False;
3579       end if;
3580
3581       --  For arrays, the only real issue is component size. If we know the
3582       --  component size for both arrays, and it is the same, then that's
3583       --  good enough to know we don't have a change of representation.
3584
3585       if Is_Array_Type (T1) then
3586          if Known_Component_Size (T1)
3587            and then Known_Component_Size (T2)
3588            and then Component_Size (T1) = Component_Size (T2)
3589          then
3590             return True;
3591          end if;
3592       end if;
3593
3594       --  Types definitely have same representation if neither has non-standard
3595       --  representation since default representations are always consistent.
3596       --  If only one has non-standard representation, and the other does not,
3597       --  then we consider that they do not have the same representation. They
3598       --  might, but there is no way of telling early enough.
3599
3600       if Has_Non_Standard_Rep (T1) then
3601          if not Has_Non_Standard_Rep (T2) then
3602             return False;
3603          end if;
3604       else
3605          return not Has_Non_Standard_Rep (T2);
3606       end if;
3607
3608       --  Here the two types both have non-standard representation, and we
3609       --  need to determine if they have the same non-standard representation
3610
3611       --  For arrays, we simply need to test if the component sizes are the
3612       --  same. Pragma Pack is reflected in modified component sizes, so this
3613       --  check also deals with pragma Pack.
3614
3615       if Is_Array_Type (T1) then
3616          return Component_Size (T1) = Component_Size (T2);
3617
3618       --  Tagged types always have the same representation, because it is not
3619       --  possible to specify different representations for common fields.
3620
3621       elsif Is_Tagged_Type (T1) then
3622          return True;
3623
3624       --  Case of record types
3625
3626       elsif Is_Record_Type (T1) then
3627
3628          --  Packed status must conform
3629
3630          if Is_Packed (T1) /= Is_Packed (T2) then
3631             return False;
3632
3633          --  Otherwise we must check components. Typ2 maybe a constrained
3634          --  subtype with fewer components, so we compare the components
3635          --  of the base types.
3636
3637          else
3638             Record_Case : declare
3639                CD1, CD2 : Entity_Id;
3640
3641                function Same_Rep return Boolean;
3642                --  CD1 and CD2 are either components or discriminants. This
3643                --  function tests whether the two have the same representation
3644
3645                function Same_Rep return Boolean is
3646                begin
3647                   if No (Component_Clause (CD1)) then
3648                      return No (Component_Clause (CD2));
3649
3650                   else
3651                      return
3652                         Present (Component_Clause (CD2))
3653                           and then
3654                         Component_Bit_Offset (CD1) = Component_Bit_Offset (CD2)
3655                           and then
3656                         Esize (CD1) = Esize (CD2);
3657                   end if;
3658                end Same_Rep;
3659
3660             --  Start processing for Record_Case
3661
3662             begin
3663                if Has_Discriminants (T1) then
3664                   CD1 := First_Discriminant (T1);
3665                   CD2 := First_Discriminant (T2);
3666
3667                   --  The number of discriminants may be different if the
3668                   --  derived type has fewer (constrained by values). The
3669                   --  invisible discriminants retain the representation of
3670                   --  the original, so the discrepancy does not per se
3671                   --  indicate a different representation.
3672
3673                   while Present (CD1)
3674                     and then Present (CD2)
3675                   loop
3676                      if not Same_Rep then
3677                         return False;
3678                      else
3679                         Next_Discriminant (CD1);
3680                         Next_Discriminant (CD2);
3681                      end if;
3682                   end loop;
3683                end if;
3684
3685                CD1 := First_Component (Underlying_Type (Base_Type (T1)));
3686                CD2 := First_Component (Underlying_Type (Base_Type (T2)));
3687
3688                while Present (CD1) loop
3689                   if not Same_Rep then
3690                      return False;
3691                   else
3692                      Next_Component (CD1);
3693                      Next_Component (CD2);
3694                   end if;
3695                end loop;
3696
3697                return True;
3698             end Record_Case;
3699          end if;
3700
3701       --  For enumeration types, we must check each literal to see if the
3702       --  representation is the same. Note that we do not permit enumeration
3703       --  reprsentation clauses for Character and Wide_Character, so these
3704       --  cases were already dealt with.
3705
3706       elsif Is_Enumeration_Type (T1) then
3707
3708          Enumeration_Case : declare
3709             L1, L2 : Entity_Id;
3710
3711          begin
3712             L1 := First_Literal (T1);
3713             L2 := First_Literal (T2);
3714
3715             while Present (L1) loop
3716                if Enumeration_Rep (L1) /= Enumeration_Rep (L2) then
3717                   return False;
3718                else
3719                   Next_Literal (L1);
3720                   Next_Literal (L2);
3721                end if;
3722             end loop;
3723
3724             return True;
3725
3726          end Enumeration_Case;
3727
3728       --  Any other types have the same representation for these purposes
3729
3730       else
3731          return True;
3732       end if;
3733    end Same_Representation;
3734
3735    --------------------
3736    -- Set_Enum_Esize --
3737    --------------------
3738
3739    procedure Set_Enum_Esize (T : Entity_Id) is
3740       Lo : Uint;
3741       Hi : Uint;
3742       Sz : Nat;
3743
3744    begin
3745       Init_Alignment (T);
3746
3747       --  Find the minimum standard size (8,16,32,64) that fits
3748
3749       Lo := Enumeration_Rep (Entity (Type_Low_Bound (T)));
3750       Hi := Enumeration_Rep (Entity (Type_High_Bound (T)));
3751
3752       if Lo < 0 then
3753          if Lo >= -Uint_2**07 and then Hi < Uint_2**07 then
3754             Sz := Standard_Character_Size;  -- May be > 8 on some targets
3755
3756          elsif Lo >= -Uint_2**15 and then Hi < Uint_2**15 then
3757             Sz := 16;
3758
3759          elsif Lo >= -Uint_2**31 and then Hi < Uint_2**31 then
3760             Sz := 32;
3761
3762          else pragma Assert (Lo >= -Uint_2**63 and then Hi < Uint_2**63);
3763             Sz := 64;
3764          end if;
3765
3766       else
3767          if Hi < Uint_2**08 then
3768             Sz := Standard_Character_Size;  -- May be > 8 on some targets
3769
3770          elsif Hi < Uint_2**16 then
3771             Sz := 16;
3772
3773          elsif Hi < Uint_2**32 then
3774             Sz := 32;
3775
3776          else pragma Assert (Hi < Uint_2**63);
3777             Sz := 64;
3778          end if;
3779       end if;
3780
3781       --  That minimum is the proper size unless we have a foreign convention
3782       --  and the size required is 32 or less, in which case we bump the size
3783       --  up to 32. This is required for C and C++ and seems reasonable for
3784       --  all other foreign conventions.
3785
3786       if Has_Foreign_Convention (T)
3787         and then Esize (T) < Standard_Integer_Size
3788       then
3789          Init_Esize (T, Standard_Integer_Size);
3790
3791       else
3792          Init_Esize (T, Sz);
3793       end if;
3794    end Set_Enum_Esize;
3795
3796    -----------------------------------
3797    -- Validate_Unchecked_Conversion --
3798    -----------------------------------
3799
3800    procedure Validate_Unchecked_Conversion
3801      (N        : Node_Id;
3802       Act_Unit : Entity_Id)
3803    is
3804       Source : Entity_Id;
3805       Target : Entity_Id;
3806       Vnode  : Node_Id;
3807
3808    begin
3809       --  Obtain source and target types. Note that we call Ancestor_Subtype
3810       --  here because the processing for generic instantiation always makes
3811       --  subtypes, and we want the original frozen actual types.
3812
3813       --  If we are dealing with private types, then do the check on their
3814       --  fully declared counterparts if the full declarations have been
3815       --  encountered (they don't have to be visible, but they must exist!)
3816
3817       Source := Ancestor_Subtype (Etype (First_Formal (Act_Unit)));
3818
3819       if Is_Private_Type (Source)
3820         and then Present (Underlying_Type (Source))
3821       then
3822          Source := Underlying_Type (Source);
3823       end if;
3824
3825       Target := Ancestor_Subtype (Etype (Act_Unit));
3826
3827       --  If either type is generic, the instantiation happens within a
3828       --  generic unit, and there is nothing to check. The proper check
3829       --  will happen when the enclosing generic is instantiated.
3830
3831       if Is_Generic_Type (Source) or else Is_Generic_Type (Target) then
3832          return;
3833       end if;
3834
3835       if Is_Private_Type (Target)
3836         and then Present (Underlying_Type (Target))
3837       then
3838          Target := Underlying_Type (Target);
3839       end if;
3840
3841       --  Source may be unconstrained array, but not target
3842
3843       if Is_Array_Type (Target)
3844         and then not Is_Constrained (Target)
3845       then
3846          Error_Msg_N
3847            ("unchecked conversion to unconstrained array not allowed", N);
3848          return;
3849       end if;
3850
3851       --  Make entry in unchecked conversion table for later processing
3852       --  by Validate_Unchecked_Conversions, which will check sizes and
3853       --  alignments (using values set by the back-end where possible).
3854       --  This is only done if the appropriate warning is active
3855
3856       if Warn_On_Unchecked_Conversion then
3857          Unchecked_Conversions.Append
3858            (New_Val => UC_Entry'
3859               (Enode  => N,
3860                Source => Source,
3861                Target => Target));
3862
3863          --  If both sizes are known statically now, then back end annotation
3864          --  is not required to do a proper check but if either size is not
3865          --  known statically, then we need the annotation.
3866
3867          if Known_Static_RM_Size (Source)
3868            and then Known_Static_RM_Size (Target)
3869          then
3870             null;
3871          else
3872             Back_Annotate_Rep_Info := True;
3873          end if;
3874       end if;
3875
3876       --  If unchecked conversion to access type, and access type is
3877       --  declared in the same unit as the unchecked conversion, then
3878       --  set the No_Strict_Aliasing flag (no strict aliasing is
3879       --  implicit in this situation).
3880
3881       if Is_Access_Type (Target) and then
3882         In_Same_Source_Unit (Target, N)
3883       then
3884          Set_No_Strict_Aliasing (Implementation_Base_Type (Target));
3885       end if;
3886
3887       --  Generate N_Validate_Unchecked_Conversion node for back end in
3888       --  case the back end needs to perform special validation checks.
3889
3890       --  Shouldn't this be in exp_ch13, since the check only gets done
3891       --  if we have full expansion and the back end is called ???
3892
3893       Vnode :=
3894         Make_Validate_Unchecked_Conversion (Sloc (N));
3895       Set_Source_Type (Vnode, Source);
3896       Set_Target_Type (Vnode, Target);
3897
3898       --  If the unchecked conversion node is in a list, just insert before
3899       --  it. If not we have some strange case, not worth bothering about.
3900
3901       if Is_List_Member (N) then
3902          Insert_After (N, Vnode);
3903       end if;
3904    end Validate_Unchecked_Conversion;
3905
3906    ------------------------------------
3907    -- Validate_Unchecked_Conversions --
3908    ------------------------------------
3909
3910    procedure Validate_Unchecked_Conversions is
3911    begin
3912       for N in Unchecked_Conversions.First .. Unchecked_Conversions.Last loop
3913          declare
3914             T : UC_Entry renames Unchecked_Conversions.Table (N);
3915
3916             Enode  : constant Node_Id   := T.Enode;
3917             Source : constant Entity_Id := T.Source;
3918             Target : constant Entity_Id := T.Target;
3919
3920             Source_Siz    : Uint;
3921             Target_Siz    : Uint;
3922
3923          begin
3924             --  This validation check, which warns if we have unequal sizes
3925             --  for unchecked conversion, and thus potentially implementation
3926             --  dependent semantics, is one of the few occasions on which we
3927             --  use the official RM size instead of Esize. See description
3928             --  in Einfo "Handling of Type'Size Values" for details.
3929
3930             if Serious_Errors_Detected = 0
3931               and then Known_Static_RM_Size (Source)
3932               and then Known_Static_RM_Size (Target)
3933             then
3934                Source_Siz := RM_Size (Source);
3935                Target_Siz := RM_Size (Target);
3936
3937                if Source_Siz /= Target_Siz then
3938                   Error_Msg_N
3939                     ("types for unchecked conversion have different sizes?",
3940                      Enode);
3941
3942                   if All_Errors_Mode then
3943                      Error_Msg_Name_1 := Chars (Source);
3944                      Error_Msg_Uint_1 := Source_Siz;
3945                      Error_Msg_Name_2 := Chars (Target);
3946                      Error_Msg_Uint_2 := Target_Siz;
3947                      Error_Msg_N
3948                        ("\size of % is ^, size of % is ^?", Enode);
3949
3950                      Error_Msg_Uint_1 := UI_Abs (Source_Siz - Target_Siz);
3951
3952                      if Is_Discrete_Type (Source)
3953                        and then Is_Discrete_Type (Target)
3954                      then
3955                         if Source_Siz > Target_Siz then
3956                            Error_Msg_N
3957                              ("\^ high order bits of source will be ignored?",
3958                               Enode);
3959
3960                         elsif Is_Unsigned_Type (Source) then
3961                            Error_Msg_N
3962                              ("\source will be extended with ^ high order " &
3963                               "zero bits?", Enode);
3964
3965                         else
3966                            Error_Msg_N
3967                              ("\source will be extended with ^ high order " &
3968                               "sign bits?",
3969                               Enode);
3970                         end if;
3971
3972                      elsif Source_Siz < Target_Siz then
3973                         if Is_Discrete_Type (Target) then
3974                            if Bytes_Big_Endian then
3975                               Error_Msg_N
3976                                 ("\target value will include ^ undefined " &
3977                                  "low order bits?",
3978                                  Enode);
3979                            else
3980                               Error_Msg_N
3981                                 ("\target value will include ^ undefined " &
3982                                  "high order bits?",
3983                                  Enode);
3984                            end if;
3985
3986                         else
3987                            Error_Msg_N
3988                              ("\^ trailing bits of target value will be " &
3989                               "undefined?", Enode);
3990                         end if;
3991
3992                      else pragma Assert (Source_Siz > Target_Siz);
3993                         Error_Msg_N
3994                           ("\^ trailing bits of source will be ignored?",
3995                            Enode);
3996                      end if;
3997                   end if;
3998                end if;
3999             end if;
4000
4001             --  If both types are access types, we need to check the alignment.
4002             --  If the alignment of both is specified, we can do it here.
4003
4004             if Serious_Errors_Detected = 0
4005               and then Ekind (Source) in Access_Kind
4006               and then Ekind (Target) in Access_Kind
4007               and then Target_Strict_Alignment
4008               and then Present (Designated_Type (Source))
4009               and then Present (Designated_Type (Target))
4010             then
4011                declare
4012                   D_Source : constant Entity_Id := Designated_Type (Source);
4013                   D_Target : constant Entity_Id := Designated_Type (Target);
4014
4015                begin
4016                   if Known_Alignment (D_Source)
4017                     and then Known_Alignment (D_Target)
4018                   then
4019                      declare
4020                         Source_Align : constant Uint := Alignment (D_Source);
4021                         Target_Align : constant Uint := Alignment (D_Target);
4022
4023                      begin
4024                         if Source_Align < Target_Align
4025                           and then not Is_Tagged_Type (D_Source)
4026                         then
4027                            Error_Msg_Uint_1 := Target_Align;
4028                            Error_Msg_Uint_2 := Source_Align;
4029                            Error_Msg_Node_2 := D_Source;
4030                            Error_Msg_NE
4031                              ("alignment of & (^) is stricter than " &
4032                               "alignment of & (^)?", Enode, D_Target);
4033
4034                            if All_Errors_Mode then
4035                               Error_Msg_N
4036                                 ("\resulting access value may have invalid " &
4037                                  "alignment?", Enode);
4038                            end if;
4039                         end if;
4040                      end;
4041                   end if;
4042                end;
4043             end if;
4044          end;
4045       end loop;
4046    end Validate_Unchecked_Conversions;
4047
4048 end Sem_Ch13;