gcc/ada/xr_tabls.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             X R  _ T A B L S                             --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1998-2012, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 --  We need comment here saying what this package is???
  27
  28 with GNAT.OS_Lib;
  29
  30 package Xr_Tabls is
  31
  32    -------------------
  33    -- Project files --
  34    -------------------
  35
  36    function ALI_File_Name (Ada_File_Name : String) return String;
  37    --  Returns the ali file name corresponding to Ada_File_Name
  38
  39    procedure Create_Project_File (Name : String);
  40    --  Open and parse a new project file. If the file Name could not be
  41    --  opened or is not a valid project file, then a project file associated
  42    --  with the standard default directories is returned
  43
  44    function Next_Obj_Dir return String;
  45    --  Returns the next directory to visit to find related ali files
  46    --  If there are no more such directories, returns a null string.
  47
  48    function Current_Obj_Dir return String;
  49    --  Returns the obj_dir which was returned by the last Next_Obj_Dir call
  50
  51    procedure Reset_Obj_Dir;
  52    --  Reset the iterator for Obj_Dir
  53
  54    ------------
  55    -- Tables --
  56    ------------
  57
  58    type Declaration_Reference is private;
  59    Empty_Declaration : constant Declaration_Reference;
  60
  61    type Declaration_Array is array (Natural range <>) of Declaration_Reference;
  62    type Declaration_Array_Access is access Declaration_Array;
  63
  64    type File_Reference is private;
  65    Empty_File : constant File_Reference;
  66
  67    type Reference is private;
  68    Empty_Reference : constant Reference;
  69
  70    type Reference_Array is array (Natural range <>) of Reference;
  71    type Reference_Array_Access is access Reference_Array;
  72
  73    procedure Free (Arr : in out Reference_Array_Access);
  74
  75    function Add_Declaration
  76      (File_Ref     : File_Reference;
  77       Symbol       : String;
  78       Line         : Natural;
  79       Column       : Natural;
  80       Decl_Type    : Character;
  81       Is_Parameter : Boolean := False;
  82       Remove_Only  : Boolean := False;
  83       Symbol_Match : Boolean := True)
  84       return         Declaration_Reference;
  85    --  Add a new declaration in the table and return the index to it. Decl_Type
  86    --  is the type of the entity Any previous instance of this entity in the
  87    --  htable is removed. If Remove_Only is True, then any previous instance is
  88    --  removed, but the new entity is never inserted. Symbol_Match should be
  89    --  set to False if the name of the symbol doesn't match the pattern from
  90    --  the command line. In that case, the entity will not be output by
  91    --  gnatfind. If Symbol_Match is True, the entity will only be output if the
  92    --  file name itself matches.
  93    --  Is_Parameter should be set to True if the entity is known to be a
  94    --  subprogram parameter.
  95
  96    procedure Add_Parent
  97      (Declaration : in out Declaration_Reference;
  98       Symbol      : String;
  99       Line        : Natural;
 100       Column      : Natural;
 101       File_Ref    : File_Reference);
 102    --  The parent declaration (Symbol in file File_Ref at position Line and
 103    --  Column) information is added to Declaration.
 104
 105    function Add_To_Xref_File
 106      (File_Name       : String;
 107       Visited         : Boolean := True;
 108       Emit_Warning    : Boolean := False;
 109       Gnatchop_File   : String  := "";
 110       Gnatchop_Offset : Integer := 0)
 111       return            File_Reference;
 112    --  Add a new reference to a file in the table. Ref is used to return the
 113    --  index in the table where this file is stored. Visited is the value which
 114    --  will be used in the table (if True, the file will not be returned by
 115    --  Next_Unvisited_File). If Emit_Warning is True and the ali file does
 116    --  not exist or does not have cross-referencing information, then a
 117    --  warning will be emitted. Gnatchop_File is the name of the file that
 118    --  File_Name was extracted from through a call to "gnatchop -r" (using
 119    --  pragma Source_Reference). Gnatchop_Offset should be the index of the
 120    --  first line of File_Name within the Gnatchop_File.
 121
 122    procedure Add_Line
 123      (File   : File_Reference;
 124       Line   : Natural;
 125       Column : Natural);
 126    --  Add a new reference in a file, which the user has provided on the
 127    --  command line. This is used for an optimized matching algorithm.
 128
 129    procedure Add_Reference
 130      (Declaration   : Declaration_Reference;
 131       File_Ref      : File_Reference;
 132       Line          : Natural;
 133       Column        : Natural;
 134       Ref_Type      : Character;
 135       Labels_As_Ref : Boolean);
 136    --  Add a new reference (Ref_Type = 'r'), body (Ref_Type = 'b') or
 137    --  modification (Ref_Type = 'm') to an entity. If Labels_As_Ref is True,
 138    --  then the references to the entity after the end statements ("end Foo")
 139    --  are counted as actual references. This means that the entity will never
 140    --  be reported as unreferenced (for instance in the case of gnatxref -u).
 141
 142    function Get_Declarations
 143      (Sorted : Boolean := True)
 144       return   Declaration_Array_Access;
 145    --  Return a sorted list of all the declarations in the application.
 146    --  Freeing this array is the responsibility of the caller, however it
 147    --  shouldn't free the actual contents of the array, which are pointers
 148    --  to internal data
 149
 150    function References_Count
 151      (Decl       : Declaration_Reference;
 152       Get_Reads  : Boolean := False;
 153       Get_Writes : Boolean := False;
 154       Get_Bodies : Boolean := False)
 155       return       Natural;
 156    --  Return the number of references in Decl for the categories specified
 157    --  by the Get_* parameters (read-only accesses, write accesses and bodies)
 158
 159    function Get_References
 160      (Decl : Declaration_Reference;
 161       Get_Reads  : Boolean := False;
 162       Get_Writes : Boolean := False;
 163       Get_Bodies : Boolean := False)
 164       return       Reference_Array_Access;
 165    --  Return a sorted list of all references to the entity in decl. The
 166    --  parameters Get_* are used to specify what kind of references should be
 167    --  merged and returned (read-only accesses, write accesses and bodies).
 168
 169    function Get_Column (Decl : Declaration_Reference) return String;
 170    function Get_Column (Ref : Reference) return String;
 171
 172    function Get_Declaration
 173      (File_Ref : File_Reference;
 174       Line     : Natural;
 175       Column   : Natural)
 176       return     Declaration_Reference;
 177    --  Returns reference to the declaration found in file File_Ref at the
 178    --  given Line and Column
 179
 180    function Get_Parent
 181      (Decl : Declaration_Reference)
 182       return Declaration_Reference;
 183    --  Returns reference to Decl's parent declaration
 184
 185    function Get_Emit_Warning (File : File_Reference) return Boolean;
 186    --  Returns the Emit_Warning field of the structure
 187
 188    function Get_Gnatchop_File
 189      (File     : File_Reference;
 190       With_Dir : Boolean := False)
 191       return     String;
 192    function Get_Gnatchop_File
 193      (Ref      : Reference;
 194       With_Dir : Boolean := False)
 195       return     String;
 196    function Get_Gnatchop_File
 197      (Decl     : Declaration_Reference;
 198       With_Dir : Boolean := False)
 199       return     String;
 200    --  Return the name of the file that File was extracted from through a
 201    --  call to "gnatchop -r". The file name for File is returned if File
 202    --  was not extracted from such a file. The directory will be given only
 203    --  if With_Dir is True.
 204
 205    function Get_File
 206      (Decl     : Declaration_Reference;
 207       With_Dir : Boolean := False) return String;
 208    pragma Inline (Get_File);
 209    --  Extract column number or file name from reference
 210
 211    function Get_File
 212      (Ref      : Reference;
 213       With_Dir : Boolean := False) return String;
 214    pragma Inline (Get_File);
 215
 216    function Get_File
 217      (File     : File_Reference;
 218       With_Dir : Boolean := False;
 219       Strip    : Natural := 0) return String;
 220    --  Returns the file name (and its directory if With_Dir is True or the user
 221    --  has used the -f switch on the command line. If Strip is not 0, then the
 222    --  last Strip-th "-..." substrings are removed first. For instance, with
 223    --  Strip=2, a file name "parent-child1-child2-child3.ali" would be returned
 224    --  as "parent-child1.ali". This is used when looking for the ALI file to
 225    --  use for a package, since for separates with have to use the parent's
 226    --  ALI. The null string is returned if there is no such parent unit.
 227    --
 228    --  Note that this version of Get_File is not inlined
 229
 230    function Get_File_Ref (Ref : Reference)              return File_Reference;
 231    function Get_Line     (Decl : Declaration_Reference) return String;
 232    function Get_Line     (Ref : Reference)              return String;
 233    function Get_Symbol   (Decl : Declaration_Reference) return String;
 234    function Get_Type     (Decl : Declaration_Reference) return Character;
 235    function Is_Parameter (Decl : Declaration_Reference) return Boolean;
 236    --  Functions that return the contents of a declaration
 237
 238    function Get_Source_Line (Ref : Reference)              return String;
 239    function Get_Source_Line (Decl : Declaration_Reference) return String;
 240    --  Return the source line associated with the reference
 241
 242    procedure Grep_Source_Files;
 243    --  Parse all the source files which have at least one reference, and grep
 244    --  the appropriate source lines so that we'll be able to display them. This
 245    --  function should be called once all the .ali files have been parsed, and
 246    --  only if the appropriate user switch
 247    --  has been used (gnatfind -s).
 248    --
 249    --  Note: To save memory, the strings for the source lines are shared. Thus
 250    --  it is no longer possible to free the references, or we would free the
 251    --  same chunk multiple times. It doesn't matter, though, since this is only
 252    --  called once, prior to exiting gnatfind.
 253
 254    function Longest_File_Name return Natural;
 255    --  Returns the longest file name found
 256
 257    function Match (Decl : Declaration_Reference) return Boolean;
 258    --  Return True if the declaration matches
 259
 260    function Match
 261      (File   : File_Reference;
 262       Line   : Natural;
 263       Column : Natural)
 264       return   Boolean;
 265    --  Returns True if File:Line:Column was given on the command line
 266    --  by the user
 267
 268    function Next_Unvisited_File return File_Reference;
 269    --  Returns the next unvisited library file in the list If there is no more
 270    --  unvisited file, return Empty_File. Two calls to this subprogram will
 271    --  return different files.
 272
 273    procedure Set_Default_Match (Value : Boolean);
 274    --  Set the default value for match in declarations.
 275    --  This is used so that if no file was provided in the
 276    --  command line, then every file match
 277
 278    procedure Reset_Directory (File : File_Reference);
 279    --  Reset the cached directory for file. Next time Get_File is called, the
 280    --  directory will be recomputed.
 281
 282    procedure Set_Unvisited (File_Ref : File_Reference);
 283    --  Set File_Ref as unvisited. So Next_Unvisited_File will return it
 284
 285    procedure Read_File
 286      (File_Name : String;
 287       Contents  : out GNAT.OS_Lib.String_Access);
 288    --  Reads File_Name into the newly allocated string Contents. Types.EOF
 289    --  character will be added to the returned Contents to simplify parsing.
 290    --  Name_Error is raised if the file was not found. End_Error is raised if
 291    --  the file could not be read correctly. For most systems correct reading
 292    --  means that the number of bytes read is equal to the file size. The
 293    --  exception is OpenVMS where correct reading means that the number of
 294    --  bytes read is less than or equal to the file size.
 295
 296 private
 297    type Project_File (Src_Dir_Length, Obj_Dir_Length : Natural) is record
 298       Src_Dir : String (1 .. Src_Dir_Length);
 299       Src_Dir_Index : Integer;
 300
 301       Obj_Dir            : String (1 .. Obj_Dir_Length);
 302       Obj_Dir_Index      : Integer;
 303       Last_Obj_Dir_Start : Natural;
 304    end record;
 305
 306    type Project_File_Ptr is access all Project_File;
 307    --  This is actually a list of all the directories to be searched,
 308    --  either for source files or for library files
 309
 310    type Ref_In_File;
 311    type Ref_In_File_Ptr is access all Ref_In_File;
 312
 313    type Ref_In_File is record
 314       Line   : Natural;
 315       Column : Natural;
 316       Next   : Ref_In_File_Ptr := null;
 317    end record;
 318
 319    type File_Record;
 320    type File_Reference is access all File_Record;
 321
 322    Empty_File : constant File_Reference := null;
 323    type Cst_String_Access is access constant String;
 324
 325    procedure Free (Str : in out Cst_String_Access);
 326
 327    type File_Record is record
 328       File            : Cst_String_Access;
 329       Dir             : GNAT.OS_Lib.String_Access;
 330       Lines           : Ref_In_File_Ptr := null;
 331       Visited         : Boolean         := False;
 332       Emit_Warning    : Boolean         := False;
 333       Gnatchop_File   : GNAT.OS_Lib.String_Access   := null;
 334       Gnatchop_Offset : Integer         := 0;
 335       Next            : File_Reference  := null;
 336    end record;
 337    --  Holds a reference to a source file, that was referenced in at least one
 338    --  ALI file. Gnatchop_File will contain the name of the file that File was
 339    --  extracted From. Gnatchop_Offset contains the index of the first line of
 340    --  File within Gnatchop_File. These two fields are used to properly support
 341    --  gnatchop files and pragma Source_Reference.
 342    --
 343    --  Lines is used for files that were given on the command line, to
 344    --  memorize the lines and columns that the user specified.
 345
 346    type Reference_Record;
 347    type Reference is access all Reference_Record;
 348
 349    Empty_Reference : constant Reference := null;
 350
 351    type Reference_Record is record
 352       File        : File_Reference;
 353       Line        : Natural;
 354       Column      : Natural;
 355       Source_Line : Cst_String_Access;
 356       Next        : Reference := null;
 357    end record;
 358    --  File is a reference to the Ada source file
 359    --  Source_Line is the Line as it appears in the source file. This
 360    --  field is only used when the switch is set on the command line of
 361    --  gnatfind.
 362
 363    type Declaration_Record;
 364    type Declaration_Reference is access all Declaration_Record;
 365
 366    Empty_Declaration : constant Declaration_Reference := null;
 367
 368    type Declaration_Record (Symbol_Length : Natural) is record
 369       Key          : Cst_String_Access;
 370       Symbol       : String (1 .. Symbol_Length);
 371       Decl         : Reference;
 372       Is_Parameter : Boolean := False; -- True if entity is subprog param
 373       Decl_Type    : Character;
 374       Body_Ref     : Reference := null;
 375       Ref_Ref      : Reference := null;
 376       Modif_Ref    : Reference := null;
 377       Match        : Boolean := False;
 378       Par_Symbol   : Declaration_Reference := null;
 379       Next         : Declaration_Reference := null;
 380    end record;
 381    --  The lists of referenced (Body_Ref, Ref_Ref and Modif_Ref) are
 382    --  kept unsorted until the results needs to be printed. This saves
 383    --  lots of time while the internal tables are created.
 384
 385    pragma Inline (Get_Column);
 386    pragma Inline (Get_Emit_Warning);
 387    pragma Inline (Get_File_Ref);
 388    pragma Inline (Get_Line);
 389    pragma Inline (Get_Symbol);
 390    pragma Inline (Get_Type);
 391    pragma Inline (Longest_File_Name);
 392 end Xr_Tabls;