projects / gcc.git / blob
? search:
summary | shortlog | log | commit | commitdiff | tree
history | raw | HEAD
re PR c/10675 (Compile time increases quadratically with struct size)
[gcc.git] / gcc / c-parse.in
1 /* YACC parser for C syntax and for Objective C. -*-c-*-
2 Copyright (C) 1987, 1988, 1989, 1992, 1993, 1994, 1995, 1996,
3 1997, 1998, 1999, 2000, 2001, 2002, 2003 Free Software Foundation, Inc.
4
5 This file is part of GCC.
6
7 GCC is free software; you can redistribute it and/or modify it under
8 the terms of the GNU General Public License as published by the Free
9 Software Foundation; either version 2, or (at your option) any later
10 version.
11
12 GCC is distributed in the hope that it will be useful, but WITHOUT ANY
13 WARRANTY; without even the implied warranty of MERCHANTABILITY or
14 FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
15 for more details.
16
17 You should have received a copy of the GNU General Public License
18 along with GCC; see the file COPYING. If not, write to the Free
19 Software Foundation, 59 Temple Place - Suite 330, Boston, MA
20 02111-1307, USA. */
21
22 /* This file defines the grammar of C and that of Objective C.
23 ifobjc ... end ifobjc conditionals contain code for Objective C only.
24 ifc ... end ifc conditionals contain code for C only.
25 Sed commands in Makefile.in are used to convert this file into
26 c-parse.y and into objc-parse.y. */
27
28 /* To whomever it may concern: I have heard that such a thing was once
29 written by AT&T, but I have never seen it. */
30
31 ifc
32 %expect 10 /* shift/reduce conflicts, and no reduce/reduce conflicts. */
33 end ifc
34
35 %{
36 #include "config.h"
37 #include "system.h"
38 #include "coretypes.h"
39 #include "tm.h"
40 #include "tree.h"
41 #include "input.h"
42 #include "cpplib.h"
43 #include "intl.h"
44 #include "timevar.h"
45 #include "c-pragma.h" /* For YYDEBUG definition, and parse_in. */
46 #include "c-tree.h"
47 #include "flags.h"
48 #include "varray.h"
49 #include "output.h"
50 #include "toplev.h"
51 #include "ggc.h"
52
53 #ifdef MULTIBYTE_CHARS
54 #include <locale.h>
55 #endif
56
57 ifobjc
58 #include "objc-act.h"
59 end ifobjc
60
61 /* Like YYERROR but do call yyerror. */
62 #define YYERROR1 { yyerror ("syntax error"); YYERROR; }
63
64 /* Like the default stack expander, except (1) use realloc when possible,
65 (2) impose no hard maxiumum on stack size, (3) REALLY do not use alloca.
66
67 Irritatingly, YYSTYPE is defined after this %{ %} block, so we cannot
68 give malloced_yyvs its proper type. This is ok since all we need from
69 it is to be able to free it. */
70
71 static short *malloced_yyss;
72 static void *malloced_yyvs;
73
74 #define yyoverflow(MSG, SS, SSSIZE, VS, VSSIZE, YYSSZ) \
75 do { \
76 size_t newsize; \
77 short *newss; \
78 YYSTYPE *newvs; \
79 newsize = *(YYSSZ) *= 2; \
80 if (malloced_yyss) \
81 { \
82 newss = (short *) \
83 really_call_realloc (*(SS), newsize * sizeof (short)); \
84 newvs = (YYSTYPE *) \
85 really_call_realloc (*(VS), newsize * sizeof (YYSTYPE)); \
86 } \
87 else \
88 { \
89 newss = (short *) really_call_malloc (newsize * sizeof (short)); \
90 newvs = (YYSTYPE *) really_call_malloc (newsize * sizeof (YYSTYPE)); \
91 if (newss) \
92 memcpy (newss, *(SS), (SSSIZE)); \
93 if (newvs) \
94 memcpy (newvs, *(VS), (VSSIZE)); \
95 } \
96 if (!newss || !newvs) \
97 { \
98 yyerror (MSG); \
99 return 2; \
100 } \
101 *(SS) = newss; \
102 *(VS) = newvs; \
103 malloced_yyss = newss; \
104 malloced_yyvs = (void *) newvs; \
105 } while (0)
106 %}
107
108 %start program
109
110 %union {long itype; tree ttype; enum tree_code code;
111 const char *filename; int lineno; }
112
113 /* All identifiers that are not reserved words
114 and are not declared typedefs in the current block */
115 %token IDENTIFIER
116
117 /* All identifiers that are declared typedefs in the current block.
118 In some contexts, they are treated just like IDENTIFIER,
119 but they can also serve as typespecs in declarations. */
120 %token TYPENAME
121
122 /* Reserved words that specify storage class.
123 yylval contains an IDENTIFIER_NODE which indicates which one. */
124 %token SCSPEC /* Storage class other than static. */
125 %token STATIC /* Static storage class. */
126
127 /* Reserved words that specify type.
128 yylval contains an IDENTIFIER_NODE which indicates which one. */
129 %token TYPESPEC
130
131 /* Reserved words that qualify type: "const", "volatile", or "restrict".
132 yylval contains an IDENTIFIER_NODE which indicates which one. */
133 %token TYPE_QUAL
134
135 /* Character or numeric constants.
136 yylval is the node for the constant. */
137 %token CONSTANT
138
139 /* String constants in raw form.
140 yylval is a STRING_CST node. */
141
142 %token STRING
143
144 /* "...", used for functions with variable arglists. */
145 %token ELLIPSIS
146
147 /* the reserved words */
148 /* SCO include files test "ASM", so use something else. */
149 %token SIZEOF ENUM STRUCT UNION IF ELSE WHILE DO FOR SWITCH CASE DEFAULT
150 %token BREAK CONTINUE RETURN GOTO ASM_KEYWORD TYPEOF ALIGNOF
151 %token ATTRIBUTE EXTENSION LABEL
152 %token REALPART IMAGPART VA_ARG CHOOSE_EXPR TYPES_COMPATIBLE_P
153 %token PTR_VALUE PTR_BASE PTR_EXTENT
154
155 /* function name can be a string const or a var decl. */
156 %token STRING_FUNC_NAME VAR_FUNC_NAME
157
158 /* Add precedence rules to solve dangling else s/r conflict */
159 %nonassoc IF
160 %nonassoc ELSE
161
162 /* Define the operator tokens and their precedences.
163 The value is an integer because, if used, it is the tree code
164 to use in the expression made from the operator. */
165
166 %right <code> ASSIGN '='
167 %right <code> '?' ':'
168 %left <code> OROR
169 %left <code> ANDAND
170 %left <code> '|'
171 %left <code> '^'
172 %left <code> '&'
173 %left <code> EQCOMPARE
174 %left <code> ARITHCOMPARE
175 %left <code> LSHIFT RSHIFT
176 %left <code> '+' '-'
177 %left <code> '*' '/' '%'
178 %right <code> UNARY PLUSPLUS MINUSMINUS
179 %left HYPERUNARY
180 %left <code> POINTSAT '.' '(' '['
181
182 /* The Objective-C keywords. These are included in C and in
183 Objective C, so that the token codes are the same in both. */
184 %token INTERFACE IMPLEMENTATION END SELECTOR DEFS ENCODE
185 %token CLASSNAME PUBLIC PRIVATE PROTECTED PROTOCOL OBJECTNAME CLASS ALIAS
186
187 %type <code> unop
188 %type <ttype> ENUM STRUCT UNION IF ELSE WHILE DO FOR SWITCH CASE DEFAULT
189 %type <ttype> BREAK CONTINUE RETURN GOTO ASM_KEYWORD SIZEOF TYPEOF ALIGNOF
190
191 %type <ttype> identifier IDENTIFIER TYPENAME CONSTANT expr nonnull_exprlist exprlist
192 %type <ttype> expr_no_commas cast_expr unary_expr primary STRING
193 %type <ttype> declspecs_nosc_nots_nosa_noea declspecs_nosc_nots_nosa_ea
194 %type <ttype> declspecs_nosc_nots_sa_noea declspecs_nosc_nots_sa_ea
195 %type <ttype> declspecs_nosc_ts_nosa_noea declspecs_nosc_ts_nosa_ea
196 %type <ttype> declspecs_nosc_ts_sa_noea declspecs_nosc_ts_sa_ea
197 %type <ttype> declspecs_sc_nots_nosa_noea declspecs_sc_nots_nosa_ea
198 %type <ttype> declspecs_sc_nots_sa_noea declspecs_sc_nots_sa_ea
199 %type <ttype> declspecs_sc_ts_nosa_noea declspecs_sc_ts_nosa_ea
200 %type <ttype> declspecs_sc_ts_sa_noea declspecs_sc_ts_sa_ea
201 %type <ttype> declspecs_ts declspecs_nots
202 %type <ttype> declspecs_ts_nosa declspecs_nots_nosa
203 %type <ttype> declspecs_nosc_ts declspecs_nosc_nots declspecs_nosc declspecs
204 %type <ttype> maybe_type_quals_attrs typespec_nonattr typespec_attr
205 %type <ttype> typespec_reserved_nonattr typespec_reserved_attr
206 %type <ttype> typespec_nonreserved_nonattr
207
208 %type <ttype> scspec SCSPEC STATIC TYPESPEC TYPE_QUAL maybe_type_qual
209 %type <ttype> initdecls notype_initdecls initdcl notype_initdcl
210 %type <ttype> init maybeasm
211 %type <ttype> asm_operands nonnull_asm_operands asm_operand asm_clobbers
212 %type <ttype> maybe_attribute attributes attribute attribute_list attrib
213 %type <ttype> any_word extension
214
215 %type <ttype> compstmt compstmt_start compstmt_nostart compstmt_primary_start
216 %type <ttype> do_stmt_start poplevel stmt label
217
218 %type <ttype> c99_block_start c99_block_end
219 %type <ttype> declarator
220 %type <ttype> notype_declarator after_type_declarator
221 %type <ttype> parm_declarator
222 %type <ttype> parm_declarator_starttypename parm_declarator_nostarttypename
223 %type <ttype> array_declarator
224
225 %type <ttype> structsp_attr structsp_nonattr
226 %type <ttype> component_decl_list component_decl_list2
227 %type <ttype> component_decl components components_notype component_declarator
228 %type <ttype> component_notype_declarator
229 %type <ttype> enumlist enumerator
230 %type <ttype> struct_head union_head enum_head
231 %type <ttype> typename absdcl absdcl1 absdcl1_ea absdcl1_noea
232 %type <ttype> direct_absdcl1 absdcl_maybe_attribute
233 %type <ttype> xexpr parms parm firstparm identifiers
234
235 %type <ttype> parmlist parmlist_1 parmlist_2
236 %type <ttype> parmlist_or_identifiers parmlist_or_identifiers_1
237 %type <ttype> identifiers_or_typenames
238
239 %type <itype> setspecs setspecs_fp
240
241 %type <filename> save_filename
242 %type <lineno> save_lineno
243 \f
244 ifobjc
245 /* the Objective-C nonterminals */
246
247 %type <ttype> ivar_decl_list ivar_decls ivar_decl ivars ivar_declarator
248 %type <ttype> methoddecl unaryselector keywordselector selector
249 %type <ttype> keyworddecl receiver objcmessageexpr messageargs
250 %type <ttype> keywordexpr keywordarglist keywordarg
251 %type <ttype> myparms myparm optparmlist reservedwords objcselectorexpr
252 %type <ttype> selectorarg keywordnamelist keywordname objcencodeexpr
253 %type <ttype> objc_string non_empty_protocolrefs protocolrefs identifier_list objcprotocolexpr
254
255 %type <ttype> CLASSNAME OBJECTNAME
256 end ifobjc
257 \f
258 %{
259 /* Number of statements (loosely speaking) and compound statements
260 seen so far. */
261 static int stmt_count;
262 static int compstmt_count;
263
264 /* Input location of the end of the body of last simple_if;
265 used by the stmt-rule immediately after simple_if returns. */
266 static location_t if_stmt_locus;
267
268
269 /* List of types and structure classes of the current declaration. */
270 static GTY(()) tree current_declspecs;
271 static GTY(()) tree prefix_attributes;
272
273 /* List of all the attributes applying to the identifier currently being
274 declared; includes prefix_attributes and possibly some more attributes
275 just after a comma. */
276 static GTY(()) tree all_prefix_attributes;
277
278 /* Stack of saved values of current_declspecs, prefix_attributes and
279 all_prefix_attributes. */
280 static GTY(()) tree declspec_stack;
281
282 /* PUSH_DECLSPEC_STACK is called from setspecs; POP_DECLSPEC_STACK
283 should be called from the productions making use of setspecs. */
284 #define PUSH_DECLSPEC_STACK \
285 do { \
286 declspec_stack = tree_cons (build_tree_list (prefix_attributes, \
287 all_prefix_attributes), \
288 current_declspecs, \
289 declspec_stack); \
290 } while (0)
291
292 #define POP_DECLSPEC_STACK \
293 do { \
294 current_declspecs = TREE_VALUE (declspec_stack); \
295 prefix_attributes = TREE_PURPOSE (TREE_PURPOSE (declspec_stack)); \
296 all_prefix_attributes = TREE_VALUE (TREE_PURPOSE (declspec_stack)); \
297 declspec_stack = TREE_CHAIN (declspec_stack); \
298 } while (0)
299
300 /* For __extension__, save/restore the warning flags which are
301 controlled by __extension__. */
302 #define SAVE_EXT_FLAGS() \
303 size_int (pedantic \
304 | (warn_pointer_arith << 1) \
305 | (warn_traditional << 2) \
306 | (flag_iso << 3))
307
308 #define RESTORE_EXT_FLAGS(tval) \
309 do { \
310 int val = tree_low_cst (tval, 0); \
311 pedantic = val & 1; \
312 warn_pointer_arith = (val >> 1) & 1; \
313 warn_traditional = (val >> 2) & 1; \
314 flag_iso = (val >> 3) & 1; \
315 } while (0)
316
317 ifobjc
318 /* Objective-C specific parser/lexer information */
319
320 static enum tree_code objc_inherit_code;
321 static int objc_pq_context = 0, objc_public_flag = 0;
322
323 /* The following flag is needed to contextualize ObjC lexical analysis.
324 In some cases (e.g., 'int NSObject;'), it is undesirable to bind
325 an identifier to an ObjC class, even if a class with that name
326 exists. */
327 static int objc_need_raw_identifier;
328 #define OBJC_NEED_RAW_IDENTIFIER(VAL) objc_need_raw_identifier = VAL
329 end ifobjc
330
331 ifc
332 #define OBJC_NEED_RAW_IDENTIFIER(VAL) /* nothing */
333 end ifc
334
335 static bool parsing_iso_function_signature;
336
337 /* Tell yyparse how to print a token's value, if yydebug is set. */
338
339 #define YYPRINT(FILE,YYCHAR,YYLVAL) yyprint(FILE,YYCHAR,YYLVAL)
340
341 static void yyprint PARAMS ((FILE *, int, YYSTYPE));
342 static void yyerror PARAMS ((const char *));
343 static int yylexname PARAMS ((void));
344 static int yylexstring PARAMS ((void));
345 static inline int _yylex PARAMS ((void));
346 static int yylex PARAMS ((void));
347 static void init_reswords PARAMS ((void));
348
349 /* Initialisation routine for this file. */
350 void
351 c_parse_init ()
352 {
353 init_reswords ();
354 }
355
356 %}
357 \f
358 %%
359 program: /* empty */
360 { if (pedantic)
361 pedwarn ("ISO C forbids an empty source file");
362 finish_file ();
363 }
364 | extdefs
365 {
366 /* In case there were missing closebraces,
367 get us back to the global binding level. */
368 while (! global_bindings_p ())
369 poplevel (0, 0, 0);
370 /* __FUNCTION__ is defined at file scope (""). This
371 call may not be necessary as my tests indicate it
372 still works without it. */
373 finish_fname_decls ();
374 finish_file ();
375 }
376 ;
377
378 /* the reason for the strange actions in this rule
379 is so that notype_initdecls when reached via datadef
380 can find a valid list of type and sc specs in $0. */
381
382 extdefs:
383 {$<ttype>$ = NULL_TREE; } extdef
384 | extdefs {$<ttype>$ = NULL_TREE; ggc_collect(); } extdef
385 ;
386
387 extdef:
388 extdef_1
389 { parsing_iso_function_signature = false; } /* Reset after any external definition. */
390 ;
391
392 extdef_1:
393 fndef
394 | datadef
395 ifobjc
396 | objcdef
397 end ifobjc
398 | ASM_KEYWORD '(' expr ')' ';'
399 { STRIP_NOPS ($3);
400 if ((TREE_CODE ($3) == ADDR_EXPR
401 && TREE_CODE (TREE_OPERAND ($3, 0)) == STRING_CST)
402 || TREE_CODE ($3) == STRING_CST)
403 assemble_asm ($3);
404 else
405 error ("argument of `asm' is not a constant string"); }
406 | extension extdef
407 { RESTORE_EXT_FLAGS ($1); }
408 ;
409
410 datadef:
411 setspecs notype_initdecls ';'
412 { if (pedantic)
413 error ("ISO C forbids data definition with no type or storage class");
414 else
415 warning ("data definition has no type or storage class");
416
417 POP_DECLSPEC_STACK; }
418 | declspecs_nots setspecs notype_initdecls ';'
419 { POP_DECLSPEC_STACK; }
420 | declspecs_ts setspecs initdecls ';'
421 { POP_DECLSPEC_STACK; }
422 | declspecs ';'
423 { shadow_tag ($1); }
424 | error ';'
425 | error '}'
426 | ';'
427 { if (pedantic)
428 pedwarn ("ISO C does not allow extra `;' outside of a function"); }
429 ;
430 \f
431 fndef:
432 declspecs_ts setspecs declarator
433 { if (! start_function (current_declspecs, $3,
434 all_prefix_attributes))
435 YYERROR1;
436 }
437 old_style_parm_decls
438 { store_parm_decls (); }
439 save_filename save_lineno compstmt_or_error
440 { DECL_SOURCE_FILE (current_function_decl) = $7;
441 DECL_SOURCE_LINE (current_function_decl) = $8;
442 finish_function (0, 1);
443 POP_DECLSPEC_STACK; }
444 | declspecs_ts setspecs declarator error
445 { POP_DECLSPEC_STACK; }
446 | declspecs_nots setspecs notype_declarator
447 { if (! start_function (current_declspecs, $3,
448 all_prefix_attributes))
449 YYERROR1;
450 }
451 old_style_parm_decls
452 { store_parm_decls (); }
453 save_filename save_lineno compstmt_or_error
454 { DECL_SOURCE_FILE (current_function_decl) = $7;
455 DECL_SOURCE_LINE (current_function_decl) = $8;
456 finish_function (0, 1);
457 POP_DECLSPEC_STACK; }
458 | declspecs_nots setspecs notype_declarator error
459 { POP_DECLSPEC_STACK; }
460 | setspecs notype_declarator
461 { if (! start_function (NULL_TREE, $2,
462 all_prefix_attributes))
463 YYERROR1;
464 }
465 old_style_parm_decls
466 { store_parm_decls (); }
467 save_filename save_lineno compstmt_or_error
468 { DECL_SOURCE_FILE (current_function_decl) = $6;
469 DECL_SOURCE_LINE (current_function_decl) = $7;
470 finish_function (0, 1);
471 POP_DECLSPEC_STACK; }
472 | setspecs notype_declarator error
473 { POP_DECLSPEC_STACK; }
474 ;
475
476 identifier:
477 IDENTIFIER
478 | TYPENAME
479 ifobjc
480 | OBJECTNAME
481 | CLASSNAME
482 end ifobjc
483 ;
484
485 unop: '&'
486 { $$ = ADDR_EXPR; }
487 | '-'
488 { $$ = NEGATE_EXPR; }
489 | '+'
490 { $$ = CONVERT_EXPR;
491 ifc
492 if (warn_traditional && !in_system_header)
493 warning ("traditional C rejects the unary plus operator");
494 end ifc
495 }
496 | PLUSPLUS
497 { $$ = PREINCREMENT_EXPR; }
498 | MINUSMINUS
499 { $$ = PREDECREMENT_EXPR; }
500 | '~'
501 { $$ = BIT_NOT_EXPR; }
502 | '!'
503 { $$ = TRUTH_NOT_EXPR; }
504 ;
505
506 expr: nonnull_exprlist
507 { $$ = build_compound_expr ($1); }
508 ;
509
510 exprlist:
511 /* empty */
512 { $$ = NULL_TREE; }
513 | nonnull_exprlist
514 ;
515
516 nonnull_exprlist:
517 expr_no_commas
518 { $$ = build_tree_list (NULL_TREE, $1); }
519 | nonnull_exprlist ',' expr_no_commas
520 { chainon ($1, build_tree_list (NULL_TREE, $3)); }
521 ;
522
523 unary_expr:
524 primary
525 | '*' cast_expr %prec UNARY
526 { $$ = build_indirect_ref ($2, "unary *"); }
527 /* __extension__ turns off -pedantic for following primary. */
528 | extension cast_expr %prec UNARY
529 { $$ = $2;
530 RESTORE_EXT_FLAGS ($1); }
531 | unop cast_expr %prec UNARY
532 { $$ = build_unary_op ($1, $2, 0);
533 overflow_warning ($$); }
534 /* Refer to the address of a label as a pointer. */
535 | ANDAND identifier
536 { $$ = finish_label_address_expr ($2); }
537 | sizeof unary_expr %prec UNARY
538 { skip_evaluation--;
539 if (TREE_CODE ($2) == COMPONENT_REF
540 && DECL_C_BIT_FIELD (TREE_OPERAND ($2, 1)))
541 error ("`sizeof' applied to a bit-field");
542 $$ = c_sizeof (TREE_TYPE ($2)); }
543 | sizeof '(' typename ')' %prec HYPERUNARY
544 { skip_evaluation--;
545 $$ = c_sizeof (groktypename ($3)); }
546 | alignof unary_expr %prec UNARY
547 { skip_evaluation--;
548 $$ = c_alignof_expr ($2); }
549 | alignof '(' typename ')' %prec HYPERUNARY
550 { skip_evaluation--;
551 $$ = c_alignof (groktypename ($3)); }
552 | REALPART cast_expr %prec UNARY
553 { $$ = build_unary_op (REALPART_EXPR, $2, 0); }
554 | IMAGPART cast_expr %prec UNARY
555 { $$ = build_unary_op (IMAGPART_EXPR, $2, 0); }
556 ;
557
558 sizeof:
559 SIZEOF { skip_evaluation++; }
560 ;
561
562 alignof:
563 ALIGNOF { skip_evaluation++; }
564 ;
565
566 typeof:
567 TYPEOF { skip_evaluation++; }
568 ;
569
570 cast_expr:
571 unary_expr
572 | '(' typename ')' cast_expr %prec UNARY
573 { $$ = c_cast_expr ($2, $4); }
574 ;
575
576 expr_no_commas:
577 cast_expr
578 | expr_no_commas '+' expr_no_commas
579 { $$ = parser_build_binary_op ($2, $1, $3); }
580 | expr_no_commas '-' expr_no_commas
581 { $$ = parser_build_binary_op ($2, $1, $3); }
582 | expr_no_commas '*' expr_no_commas
583 { $$ = parser_build_binary_op ($2, $1, $3); }
584 | expr_no_commas '/' expr_no_commas
585 { $$ = parser_build_binary_op ($2, $1, $3); }
586 | expr_no_commas '%' expr_no_commas
587 { $$ = parser_build_binary_op ($2, $1, $3); }
588 | expr_no_commas LSHIFT expr_no_commas
589 { $$ = parser_build_binary_op ($2, $1, $3); }
590 | expr_no_commas RSHIFT expr_no_commas
591 { $$ = parser_build_binary_op ($2, $1, $3); }
592 | expr_no_commas ARITHCOMPARE expr_no_commas
593 { $$ = parser_build_binary_op ($2, $1, $3); }
594 | expr_no_commas EQCOMPARE expr_no_commas
595 { $$ = parser_build_binary_op ($2, $1, $3); }
596 | expr_no_commas '&' expr_no_commas
597 { $$ = parser_build_binary_op ($2, $1, $3); }
598 | expr_no_commas '|' expr_no_commas
599 { $$ = parser_build_binary_op ($2, $1, $3); }
600 | expr_no_commas '^' expr_no_commas
601 { $$ = parser_build_binary_op ($2, $1, $3); }
602 | expr_no_commas ANDAND
603 { $1 = c_common_truthvalue_conversion
604 (default_conversion ($1));
605 skip_evaluation += $1 == boolean_false_node; }
606 expr_no_commas
607 { skip_evaluation -= $1 == boolean_false_node;
608 $$ = parser_build_binary_op (TRUTH_ANDIF_EXPR, $1, $4); }
609 | expr_no_commas OROR
610 { $1 = c_common_truthvalue_conversion
611 (default_conversion ($1));
612 skip_evaluation += $1 == boolean_true_node; }
613 expr_no_commas
614 { skip_evaluation -= $1 == boolean_true_node;
615 $$ = parser_build_binary_op (TRUTH_ORIF_EXPR, $1, $4); }
616 | expr_no_commas '?'
617 { $1 = c_common_truthvalue_conversion
618 (default_conversion ($1));
619 skip_evaluation += $1 == boolean_false_node; }
620 expr ':'
621 { skip_evaluation += (($1 == boolean_true_node)
622 - ($1 == boolean_false_node)); }
623 expr_no_commas
624 { skip_evaluation -= $1 == boolean_true_node;
625 $$ = build_conditional_expr ($1, $4, $7); }
626 | expr_no_commas '?'
627 { if (pedantic)
628 pedwarn ("ISO C forbids omitting the middle term of a ?: expression");
629 /* Make sure first operand is calculated only once. */
630 $<ttype>2 = save_expr ($1);
631 $1 = c_common_truthvalue_conversion
632 (default_conversion ($<ttype>2));
633 skip_evaluation += $1 == boolean_true_node; }
634 ':' expr_no_commas
635 { skip_evaluation -= $1 == boolean_true_node;
636 $$ = build_conditional_expr ($1, $<ttype>2, $5); }
637 | expr_no_commas '=' expr_no_commas
638 { char class;
639 $$ = build_modify_expr ($1, NOP_EXPR, $3);
640 class = TREE_CODE_CLASS (TREE_CODE ($$));
641 if (IS_EXPR_CODE_CLASS (class))
642 C_SET_EXP_ORIGINAL_CODE ($$, MODIFY_EXPR);
643 }
644 | expr_no_commas ASSIGN expr_no_commas
645 { char class;
646 $$ = build_modify_expr ($1, $2, $3);
647 /* This inhibits warnings in
648 c_common_truthvalue_conversion. */
649 class = TREE_CODE_CLASS (TREE_CODE ($$));
650 if (IS_EXPR_CODE_CLASS (class))
651 C_SET_EXP_ORIGINAL_CODE ($$, ERROR_MARK);
652 }
653 ;
654
655 primary:
656 IDENTIFIER
657 {
658 if (yychar == YYEMPTY)
659 yychar = YYLEX;
660 $$ = build_external_ref ($1, yychar == '(');
661 }
662 | CONSTANT
663 | STRING
664 { $$ = fix_string_type ($$); }
665 | VAR_FUNC_NAME
666 { $$ = fname_decl (C_RID_CODE ($$), $$); }
667 | '(' typename ')' '{'
668 { start_init (NULL_TREE, NULL, 0);
669 $2 = groktypename ($2);
670 really_start_incremental_init ($2); }
671 initlist_maybe_comma '}' %prec UNARY
672 { tree constructor = pop_init_level (0);
673 tree type = $2;
674 finish_init ();
675
676 if (pedantic && ! flag_isoc99)
677 pedwarn ("ISO C89 forbids compound literals");
678 $$ = build_compound_literal (type, constructor);
679 }
680 | '(' expr ')'
681 { char class = TREE_CODE_CLASS (TREE_CODE ($2));
682 if (IS_EXPR_CODE_CLASS (class))
683 C_SET_EXP_ORIGINAL_CODE ($2, ERROR_MARK);
684 $$ = $2; }
685 | '(' error ')'
686 { $$ = error_mark_node; }
687 | compstmt_primary_start compstmt_nostart ')'
688 { tree saved_last_tree;
689
690 if (pedantic)
691 pedwarn ("ISO C forbids braced-groups within expressions");
692 pop_label_level ();
693
694 saved_last_tree = COMPOUND_BODY ($1);
695 RECHAIN_STMTS ($1, COMPOUND_BODY ($1));
696 last_tree = saved_last_tree;
697 TREE_CHAIN (last_tree) = NULL_TREE;
698 if (!last_expr_type)
699 last_expr_type = void_type_node;
700 $$ = build1 (STMT_EXPR, last_expr_type, $1);
701 TREE_SIDE_EFFECTS ($$) = 1;
702 }
703 | compstmt_primary_start error ')'
704 {
705 pop_label_level ();
706 last_tree = COMPOUND_BODY ($1);
707 TREE_CHAIN (last_tree) = NULL_TREE;
708 $$ = error_mark_node;
709 }
710 | primary '(' exprlist ')' %prec '.'
711 { $$ = build_function_call ($1, $3); }
712 | VA_ARG '(' expr_no_commas ',' typename ')'
713 { $$ = build_va_arg ($3, groktypename ($5)); }
714
715 | CHOOSE_EXPR '(' expr_no_commas ',' expr_no_commas ',' expr_no_commas ')'
716 {
717 tree c;
718
719 c = fold ($3);
720 STRIP_NOPS (c);
721 if (TREE_CODE (c) != INTEGER_CST)
722 error ("first argument to __builtin_choose_expr not a constant");
723 $$ = integer_zerop (c) ? $7 : $5;
724 }
725 | TYPES_COMPATIBLE_P '(' typename ',' typename ')'
726 {
727 tree e1, e2;
728
729 e1 = TYPE_MAIN_VARIANT (groktypename ($3));
730 e2 = TYPE_MAIN_VARIANT (groktypename ($5));
731
732 $$ = comptypes (e1, e2)
733 ? build_int_2 (1, 0) : build_int_2 (0, 0);
734 }
735 | primary '[' expr ']' %prec '.'
736 { $$ = build_array_ref ($1, $3); }
737 | primary '.' identifier
738 {
739 ifobjc
740 if (!is_public ($1, $3))
741 $$ = error_mark_node;
742 else
743 end ifobjc
744 $$ = build_component_ref ($1, $3);
745 }
746 | primary POINTSAT identifier
747 {
748 tree expr = build_indirect_ref ($1, "->");
749
750 ifobjc
751 if (!is_public (expr, $3))
752 $$ = error_mark_node;
753 else
754 end ifobjc
755 $$ = build_component_ref (expr, $3);
756 }
757 | primary PLUSPLUS
758 { $$ = build_unary_op (POSTINCREMENT_EXPR, $1, 0); }
759 | primary MINUSMINUS
760 { $$ = build_unary_op (POSTDECREMENT_EXPR, $1, 0); }
761 ifobjc
762 | objcmessageexpr
763 { $$ = build_message_expr ($1); }
764 | objcselectorexpr
765 { $$ = build_selector_expr ($1); }
766 | objcprotocolexpr
767 { $$ = build_protocol_expr ($1); }
768 | objcencodeexpr
769 { $$ = build_encode_expr ($1); }
770 | objc_string
771 { $$ = build_objc_string_object ($1); }
772 end ifobjc
773 ;
774
775 ifobjc
776 /* Produces an STRING_CST with perhaps more STRING_CSTs chained
777 onto it, which is to be read as an ObjC string object. */
778 objc_string:
779 '@' STRING
780 { $$ = $2; }
781 | objc_string '@' STRING
782 { $$ = chainon ($1, $3); }
783 ;
784 end ifobjc
785
786 old_style_parm_decls:
787 old_style_parm_decls_1
788 {
789 parsing_iso_function_signature = false; /* Reset after decls. */
790 }
791 ;
792
793 old_style_parm_decls_1:
794 /* empty */
795 {
796 if (warn_traditional && !in_system_header
797 && parsing_iso_function_signature)
798 warning ("traditional C rejects ISO C style function definitions");
799 parsing_iso_function_signature = false; /* Reset after warning. */
800 }
801 | datadecls
802 ;
803
804 /* The following are analogous to lineno_decl, decls and decl
805 except that they do not allow nested functions.
806 They are used for old-style parm decls. */
807 lineno_datadecl:
808 save_filename save_lineno datadecl
809 { }
810 ;
811
812 datadecls:
813 lineno_datadecl
814 | errstmt
815 | datadecls lineno_datadecl
816 | lineno_datadecl errstmt
817 ;
818
819 /* We don't allow prefix attributes here because they cause reduce/reduce
820 conflicts: we can't know whether we're parsing a function decl with
821 attribute suffix, or function defn with attribute prefix on first old
822 style parm. */
823 datadecl:
824 declspecs_ts_nosa setspecs initdecls ';'
825 { POP_DECLSPEC_STACK; }
826 | declspecs_nots_nosa setspecs notype_initdecls ';'
827 { POP_DECLSPEC_STACK; }
828 | declspecs_ts_nosa ';'
829 { shadow_tag_warned ($1, 1);
830 pedwarn ("empty declaration"); }
831 | declspecs_nots_nosa ';'
832 { pedwarn ("empty declaration"); }
833 ;
834
835 /* This combination which saves a lineno before a decl
836 is the normal thing to use, rather than decl itself.
837 This is to avoid shift/reduce conflicts in contexts
838 where statement labels are allowed. */
839 lineno_decl:
840 save_filename save_lineno decl
841 { }
842 ;
843
844 /* records the type and storage class specs to use for processing
845 the declarators that follow.
846 Maintains a stack of outer-level values of current_declspecs,
847 for the sake of parm declarations nested in function declarators. */
848 setspecs: /* empty */
849 { pending_xref_error ();
850 PUSH_DECLSPEC_STACK;
851 split_specs_attrs ($<ttype>0,
852 &current_declspecs, &prefix_attributes);
853 all_prefix_attributes = prefix_attributes; }
854 ;
855
856 /* Possibly attributes after a comma, which should reset all_prefix_attributes
857 to prefix_attributes with these ones chained on the front. */
858 maybe_resetattrs:
859 maybe_attribute
860 { all_prefix_attributes = chainon ($1, prefix_attributes); }
861 ;
862
863 decl:
864 declspecs_ts setspecs initdecls ';'
865 { POP_DECLSPEC_STACK; }
866 | declspecs_nots setspecs notype_initdecls ';'
867 { POP_DECLSPEC_STACK; }
868 | declspecs_ts setspecs nested_function
869 { POP_DECLSPEC_STACK; }
870 | declspecs_nots setspecs notype_nested_function
871 { POP_DECLSPEC_STACK; }
872 | declspecs ';'
873 { shadow_tag ($1); }
874 | extension decl
875 { RESTORE_EXT_FLAGS ($1); }
876 ;
877
878 /* A list of declaration specifiers. These are:
879
880 - Storage class specifiers (scspec), which for GCC currently includes
881 function specifiers ("inline").
882
883 - Type specifiers (typespec_*).
884
885 - Type qualifiers (TYPE_QUAL).
886
887 - Attribute specifier lists (attributes).
888
889 These are stored as a TREE_LIST; the head of the list is the last
890 item in the specifier list. Each entry in the list has either a
891 TREE_PURPOSE that is an attribute specifier list, or a TREE_VALUE that
892 is a single other specifier or qualifier; and a TREE_CHAIN that is the
893 rest of the list. TREE_STATIC is set on the list if something other
894 than a storage class specifier or attribute has been seen; this is used
895 to warn for the obsolescent usage of storage class specifiers other than
896 at the start of the list. (Doing this properly would require function
897 specifiers to be handled separately from storage class specifiers.)
898
899 The various cases below are classified according to:
900
901 (a) Whether a storage class specifier is included or not; some
902 places in the grammar disallow storage class specifiers (_sc or _nosc).
903
904 (b) Whether a type specifier has been seen; after a type specifier,
905 a typedef name is an identifier to redeclare (_ts or _nots).
906
907 (c) Whether the list starts with an attribute; in certain places,
908 the grammar requires specifiers that don't start with an attribute
909 (_sa or _nosa).
910
911 (d) Whether the list ends with an attribute (or a specifier such that
912 any following attribute would have been parsed as part of that specifier);
913 this avoids shift-reduce conflicts in the parsing of attributes
914 (_ea or _noea).
915
916 TODO:
917
918 (i) Distinguish between function specifiers and storage class specifiers,
919 at least for the purpose of warnings about obsolescent usage.
920
921 (ii) Halve the number of productions here by eliminating the _sc/_nosc
922 distinction and instead checking where required that storage class
923 specifiers aren't present. */
924
925 /* Declspecs which contain at least one type specifier or typedef name.
926 (Just `const' or `volatile' is not enough.)
927 A typedef'd name following these is taken as a name to be declared.
928 Declspecs have a non-NULL TREE_VALUE, attributes do not. */
929
930 declspecs_nosc_nots_nosa_noea:
931 TYPE_QUAL
932 { $$ = tree_cons (NULL_TREE, $1, NULL_TREE);
933 TREE_STATIC ($$) = 1; }
934 | declspecs_nosc_nots_nosa_noea TYPE_QUAL
935 { $$ = tree_cons (NULL_TREE, $2, $1);
936 TREE_STATIC ($$) = 1; }
937 | declspecs_nosc_nots_nosa_ea TYPE_QUAL
938 { $$ = tree_cons (NULL_TREE, $2, $1);
939 TREE_STATIC ($$) = 1; }
940 ;
941
942 declspecs_nosc_nots_nosa_ea:
943 declspecs_nosc_nots_nosa_noea attributes
944 { $$ = tree_cons ($2, NULL_TREE, $1);
945 TREE_STATIC ($$) = TREE_STATIC ($1); }
946 ;
947
948 declspecs_nosc_nots_sa_noea:
949 declspecs_nosc_nots_sa_noea TYPE_QUAL
950 { $$ = tree_cons (NULL_TREE, $2, $1);
951 TREE_STATIC ($$) = 1; }
952 | declspecs_nosc_nots_sa_ea TYPE_QUAL
953 { $$ = tree_cons (NULL_TREE, $2, $1);
954 TREE_STATIC ($$) = 1; }
955 ;
956
957 declspecs_nosc_nots_sa_ea:
958 attributes
959 { $$ = tree_cons ($1, NULL_TREE, NULL_TREE);
960 TREE_STATIC ($$) = 0; }
961 | declspecs_nosc_nots_sa_noea attributes
962 { $$ = tree_cons ($2, NULL_TREE, $1);
963 TREE_STATIC ($$) = TREE_STATIC ($1); }
964 ;
965
966 declspecs_nosc_ts_nosa_noea:
967 typespec_nonattr
968 { $$ = tree_cons (NULL_TREE, $1, NULL_TREE);
969 TREE_STATIC ($$) = 1; }
970 | declspecs_nosc_ts_nosa_noea TYPE_QUAL
971 { $$ = tree_cons (NULL_TREE, $2, $1);
972 TREE_STATIC ($$) = 1; }
973 | declspecs_nosc_ts_nosa_ea TYPE_QUAL
974 { $$ = tree_cons (NULL_TREE, $2, $1);
975 TREE_STATIC ($$) = 1; }
976 | declspecs_nosc_ts_nosa_noea typespec_reserved_nonattr
977 { $$ = tree_cons (NULL_TREE, $2, $1);
978 TREE_STATIC ($$) = 1; }
979 | declspecs_nosc_ts_nosa_ea typespec_reserved_nonattr
980 { $$ = tree_cons (NULL_TREE, $2, $1);
981 TREE_STATIC ($$) = 1; }
982 | declspecs_nosc_nots_nosa_noea typespec_nonattr
983 { $$ = tree_cons (NULL_TREE, $2, $1);
984 TREE_STATIC ($$) = 1; }
985 | declspecs_nosc_nots_nosa_ea typespec_nonattr
986 { $$ = tree_cons (NULL_TREE, $2, $1);
987 TREE_STATIC ($$) = 1; }
988 ;
989
990 declspecs_nosc_ts_nosa_ea:
991 typespec_attr
992 { $$ = tree_cons (NULL_TREE, $1, NULL_TREE);
993 TREE_STATIC ($$) = 1; }
994 | declspecs_nosc_ts_nosa_noea attributes
995 { $$ = tree_cons ($2, NULL_TREE, $1);
996 TREE_STATIC ($$) = TREE_STATIC ($1); }
997 | declspecs_nosc_ts_nosa_noea typespec_reserved_attr
998 { $$ = tree_cons (NULL_TREE, $2, $1);
999 TREE_STATIC ($$) = 1; }
1000 | declspecs_nosc_ts_nosa_ea typespec_reserved_attr
1001 { $$ = tree_cons (NULL_TREE, $2, $1);
1002 TREE_STATIC ($$) = 1; }
1003 | declspecs_nosc_nots_nosa_noea typespec_attr
1004 { $$ = tree_cons (NULL_TREE, $2, $1);
1005 TREE_STATIC ($$) = 1; }
1006 | declspecs_nosc_nots_nosa_ea typespec_attr
1007 { $$ = tree_cons (NULL_TREE, $2, $1);
1008 TREE_STATIC ($$) = 1; }
1009 ;
1010
1011 declspecs_nosc_ts_sa_noea:
1012 declspecs_nosc_ts_sa_noea TYPE_QUAL
1013 { $$ = tree_cons (NULL_TREE, $2, $1);
1014 TREE_STATIC ($$) = 1; }
1015 | declspecs_nosc_ts_sa_ea TYPE_QUAL
1016 { $$ = tree_cons (NULL_TREE, $2, $1);
1017 TREE_STATIC ($$) = 1; }
1018 | declspecs_nosc_ts_sa_noea typespec_reserved_nonattr
1019 { $$ = tree_cons (NULL_TREE, $2, $1);
1020 TREE_STATIC ($$) = 1; }
1021 | declspecs_nosc_ts_sa_ea typespec_reserved_nonattr
1022 { $$ = tree_cons (NULL_TREE, $2, $1);
1023 TREE_STATIC ($$) = 1; }
1024 | declspecs_nosc_nots_sa_noea typespec_nonattr
1025 { $$ = tree_cons (NULL_TREE, $2, $1);
1026 TREE_STATIC ($$) = 1; }
1027 | declspecs_nosc_nots_sa_ea typespec_nonattr
1028 { $$ = tree_cons (NULL_TREE, $2, $1);
1029 TREE_STATIC ($$) = 1; }
1030 ;
1031
1032 declspecs_nosc_ts_sa_ea:
1033 declspecs_nosc_ts_sa_noea attributes
1034 { $$ = tree_cons ($2, NULL_TREE, $1);
1035 TREE_STATIC ($$) = TREE_STATIC ($1); }
1036 | declspecs_nosc_ts_sa_noea typespec_reserved_attr
1037 { $$ = tree_cons (NULL_TREE, $2, $1);
1038 TREE_STATIC ($$) = 1; }
1039 | declspecs_nosc_ts_sa_ea typespec_reserved_attr
1040 { $$ = tree_cons (NULL_TREE, $2, $1);
1041 TREE_STATIC ($$) = 1; }
1042 | declspecs_nosc_nots_sa_noea typespec_attr
1043 { $$ = tree_cons (NULL_TREE, $2, $1);
1044 TREE_STATIC ($$) = 1; }
1045 | declspecs_nosc_nots_sa_ea typespec_attr
1046 { $$ = tree_cons (NULL_TREE, $2, $1);
1047 TREE_STATIC ($$) = 1; }
1048 ;
1049
1050 declspecs_sc_nots_nosa_noea:
1051 scspec
1052 { $$ = tree_cons (NULL_TREE, $1, NULL_TREE);
1053 TREE_STATIC ($$) = 0; }
1054 | declspecs_sc_nots_nosa_noea TYPE_QUAL
1055 { $$ = tree_cons (NULL_TREE, $2, $1);
1056 TREE_STATIC ($$) = 1; }
1057 | declspecs_sc_nots_nosa_ea TYPE_QUAL
1058 { $$ = tree_cons (NULL_TREE, $2, $1);
1059 TREE_STATIC ($$) = 1; }
1060 | declspecs_nosc_nots_nosa_noea scspec
1061 { if (extra_warnings && TREE_STATIC ($1))
1062 warning ("`%s' is not at beginning of declaration",
1063 IDENTIFIER_POINTER ($2));
1064 $$ = tree_cons (NULL_TREE, $2, $1);
1065 TREE_STATIC ($$) = TREE_STATIC ($1); }
1066 | declspecs_nosc_nots_nosa_ea scspec
1067 { if (extra_warnings && TREE_STATIC ($1))
1068 warning ("`%s' is not at beginning of declaration",
1069 IDENTIFIER_POINTER ($2));
1070 $$ = tree_cons (NULL_TREE, $2, $1);
1071 TREE_STATIC ($$) = TREE_STATIC ($1); }
1072 | declspecs_sc_nots_nosa_noea scspec
1073 { if (extra_warnings && TREE_STATIC ($1))
1074 warning ("`%s' is not at beginning of declaration",
1075 IDENTIFIER_POINTER ($2));
1076 $$ = tree_cons (NULL_TREE, $2, $1);
1077 TREE_STATIC ($$) = TREE_STATIC ($1); }
1078 | declspecs_sc_nots_nosa_ea scspec
1079 { if (extra_warnings && TREE_STATIC ($1))
1080 warning ("`%s' is not at beginning of declaration",
1081 IDENTIFIER_POINTER ($2));
1082 $$ = tree_cons (NULL_TREE, $2, $1);
1083 TREE_STATIC ($$) = TREE_STATIC ($1); }
1084 ;
1085
1086 declspecs_sc_nots_nosa_ea:
1087 declspecs_sc_nots_nosa_noea attributes
1088 { $$ = tree_cons ($2, NULL_TREE, $1);
1089 TREE_STATIC ($$) = TREE_STATIC ($1); }
1090 ;
1091
1092 declspecs_sc_nots_sa_noea:
1093 declspecs_sc_nots_sa_noea TYPE_QUAL
1094 { $$ = tree_cons (NULL_TREE, $2, $1);
1095 TREE_STATIC ($$) = 1; }
1096 | declspecs_sc_nots_sa_ea TYPE_QUAL
1097 { $$ = tree_cons (NULL_TREE, $2, $1);
1098 TREE_STATIC ($$) = 1; }
1099 | declspecs_nosc_nots_sa_noea scspec
1100 { if (extra_warnings && TREE_STATIC ($1))
1101 warning ("`%s' is not at beginning of declaration",
1102 IDENTIFIER_POINTER ($2));
1103 $$ = tree_cons (NULL_TREE, $2, $1);
1104 TREE_STATIC ($$) = TREE_STATIC ($1); }
1105 | declspecs_nosc_nots_sa_ea scspec
1106 { if (extra_warnings && TREE_STATIC ($1))
1107 warning ("`%s' is not at beginning of declaration",
1108 IDENTIFIER_POINTER ($2));
1109 $$ = tree_cons (NULL_TREE, $2, $1);
1110 TREE_STATIC ($$) = TREE_STATIC ($1); }
1111 | declspecs_sc_nots_sa_noea scspec
1112 { if (extra_warnings && TREE_STATIC ($1))
1113 warning ("`%s' is not at beginning of declaration",
1114 IDENTIFIER_POINTER ($2));
1115 $$ = tree_cons (NULL_TREE, $2, $1);
1116 TREE_STATIC ($$) = TREE_STATIC ($1); }
1117 | declspecs_sc_nots_sa_ea scspec
1118 { if (extra_warnings && TREE_STATIC ($1))
1119 warning ("`%s' is not at beginning of declaration",
1120 IDENTIFIER_POINTER ($2));
1121 $$ = tree_cons (NULL_TREE, $2, $1);
1122 TREE_STATIC ($$) = TREE_STATIC ($1); }
1123 ;
1124
1125 declspecs_sc_nots_sa_ea:
1126 declspecs_sc_nots_sa_noea attributes
1127 { $$ = tree_cons ($2, NULL_TREE, $1);
1128 TREE_STATIC ($$) = TREE_STATIC ($1); }
1129 ;
1130
1131 declspecs_sc_ts_nosa_noea:
1132 declspecs_sc_ts_nosa_noea TYPE_QUAL
1133 { $$ = tree_cons (NULL_TREE, $2, $1);
1134 TREE_STATIC ($$) = 1; }
1135 | declspecs_sc_ts_nosa_ea TYPE_QUAL
1136 { $$ = tree_cons (NULL_TREE, $2, $1);
1137 TREE_STATIC ($$) = 1; }
1138 | declspecs_sc_ts_nosa_noea typespec_reserved_nonattr
1139 { $$ = tree_cons (NULL_TREE, $2, $1);
1140 TREE_STATIC ($$) = 1; }
1141 | declspecs_sc_ts_nosa_ea typespec_reserved_nonattr
1142 { $$ = tree_cons (NULL_TREE, $2, $1);
1143 TREE_STATIC ($$) = 1; }
1144 | declspecs_sc_nots_nosa_noea typespec_nonattr
1145 { $$ = tree_cons (NULL_TREE, $2, $1);
1146 TREE_STATIC ($$) = 1; }
1147 | declspecs_sc_nots_nosa_ea typespec_nonattr
1148 { $$ = tree_cons (NULL_TREE, $2, $1);
1149 TREE_STATIC ($$) = 1; }
1150 | declspecs_nosc_ts_nosa_noea scspec
1151 { if (extra_warnings && TREE_STATIC ($1))
1152 warning ("`%s' is not at beginning of declaration",
1153 IDENTIFIER_POINTER ($2));
1154 $$ = tree_cons (NULL_TREE, $2, $1);
1155 TREE_STATIC ($$) = TREE_STATIC ($1); }
1156 | declspecs_nosc_ts_nosa_ea scspec
1157 { if (extra_warnings && TREE_STATIC ($1))
1158 warning ("`%s' is not at beginning of declaration",
1159 IDENTIFIER_POINTER ($2));
1160 $$ = tree_cons (NULL_TREE, $2, $1);
1161 TREE_STATIC ($$) = TREE_STATIC ($1); }
1162 | declspecs_sc_ts_nosa_noea scspec
1163 { if (extra_warnings && TREE_STATIC ($1))
1164 warning ("`%s' is not at beginning of declaration",
1165 IDENTIFIER_POINTER ($2));
1166 $$ = tree_cons (NULL_TREE, $2, $1);
1167 TREE_STATIC ($$) = TREE_STATIC ($1); }
1168 | declspecs_sc_ts_nosa_ea scspec
1169 { if (extra_warnings && TREE_STATIC ($1))
1170 warning ("`%s' is not at beginning of declaration",
1171 IDENTIFIER_POINTER ($2));
1172 $$ = tree_cons (NULL_TREE, $2, $1);
1173 TREE_STATIC ($$) = TREE_STATIC ($1); }
1174 ;
1175
1176 declspecs_sc_ts_nosa_ea:
1177 declspecs_sc_ts_nosa_noea attributes
1178 { $$ = tree_cons ($2, NULL_TREE, $1);
1179 TREE_STATIC ($$) = TREE_STATIC ($1); }
1180 | declspecs_sc_ts_nosa_noea typespec_reserved_attr
1181 { $$ = tree_cons (NULL_TREE, $2, $1);
1182 TREE_STATIC ($$) = 1; }
1183 | declspecs_sc_ts_nosa_ea typespec_reserved_attr
1184 { $$ = tree_cons (NULL_TREE, $2, $1);
1185 TREE_STATIC ($$) = 1; }
1186 | declspecs_sc_nots_nosa_noea typespec_attr
1187 { $$ = tree_cons (NULL_TREE, $2, $1);
1188 TREE_STATIC ($$) = 1; }
1189 | declspecs_sc_nots_nosa_ea typespec_attr
1190 { $$ = tree_cons (NULL_TREE, $2, $1);
1191 TREE_STATIC ($$) = 1; }
1192 ;
1193
1194 declspecs_sc_ts_sa_noea:
1195 declspecs_sc_ts_sa_noea TYPE_QUAL
1196 { $$ = tree_cons (NULL_TREE, $2, $1);
1197 TREE_STATIC ($$) = 1; }
1198 | declspecs_sc_ts_sa_ea TYPE_QUAL
1199 { $$ = tree_cons (NULL_TREE, $2, $1);
1200 TREE_STATIC ($$) = 1; }
1201 | declspecs_sc_ts_sa_noea typespec_reserved_nonattr
1202 { $$ = tree_cons (NULL_TREE, $2, $1);
1203 TREE_STATIC ($$) = 1; }
1204 | declspecs_sc_ts_sa_ea typespec_reserved_nonattr
1205 { $$ = tree_cons (NULL_TREE, $2, $1);
1206 TREE_STATIC ($$) = 1; }
1207 | declspecs_sc_nots_sa_noea typespec_nonattr
1208 { $$ = tree_cons (NULL_TREE, $2, $1);
1209 TREE_STATIC ($$) = 1; }
1210 | declspecs_sc_nots_sa_ea typespec_nonattr
1211 { $$ = tree_cons (NULL_TREE, $2, $1);
1212 TREE_STATIC ($$) = 1; }
1213 | declspecs_nosc_ts_sa_noea scspec
1214 { if (extra_warnings && TREE_STATIC ($1))
1215 warning ("`%s' is not at beginning of declaration",
1216 IDENTIFIER_POINTER ($2));
1217 $$ = tree_cons (NULL_TREE, $2, $1);
1218 TREE_STATIC ($$) = TREE_STATIC ($1); }
1219 | declspecs_nosc_ts_sa_ea scspec
1220 { if (extra_warnings && TREE_STATIC ($1))
1221 warning ("`%s' is not at beginning of declaration",
1222 IDENTIFIER_POINTER ($2));
1223 $$ = tree_cons (NULL_TREE, $2, $1);
1224 TREE_STATIC ($$) = TREE_STATIC ($1); }
1225 | declspecs_sc_ts_sa_noea scspec
1226 { if (extra_warnings && TREE_STATIC ($1))
1227 warning ("`%s' is not at beginning of declaration",
1228 IDENTIFIER_POINTER ($2));
1229 $$ = tree_cons (NULL_TREE, $2, $1);
1230 TREE_STATIC ($$) = TREE_STATIC ($1); }
1231 | declspecs_sc_ts_sa_ea scspec
1232 { if (extra_warnings && TREE_STATIC ($1))
1233 warning ("`%s' is not at beginning of declaration",
1234 IDENTIFIER_POINTER ($2));
1235 $$ = tree_cons (NULL_TREE, $2, $1);
1236 TREE_STATIC ($$) = TREE_STATIC ($1); }
1237 ;
1238
1239 declspecs_sc_ts_sa_ea:
1240 declspecs_sc_ts_sa_noea attributes
1241 { $$ = tree_cons ($2, NULL_TREE, $1);
1242 TREE_STATIC ($$) = TREE_STATIC ($1); }
1243 | declspecs_sc_ts_sa_noea typespec_reserved_attr
1244 { $$ = tree_cons (NULL_TREE, $2, $1);
1245 TREE_STATIC ($$) = 1; }
1246 | declspecs_sc_ts_sa_ea typespec_reserved_attr
1247 { $$ = tree_cons (NULL_TREE, $2, $1);
1248 TREE_STATIC ($$) = 1; }
1249 | declspecs_sc_nots_sa_noea typespec_attr
1250 { $$ = tree_cons (NULL_TREE, $2, $1);
1251 TREE_STATIC ($$) = 1; }
1252 | declspecs_sc_nots_sa_ea typespec_attr
1253 { $$ = tree_cons (NULL_TREE, $2, $1);
1254 TREE_STATIC ($$) = 1; }
1255 ;
1256
1257 /* Particular useful classes of declspecs. */
1258 declspecs_ts:
1259 declspecs_nosc_ts_nosa_noea
1260 | declspecs_nosc_ts_nosa_ea
1261 | declspecs_nosc_ts_sa_noea
1262 | declspecs_nosc_ts_sa_ea
1263 | declspecs_sc_ts_nosa_noea
1264 | declspecs_sc_ts_nosa_ea
1265 | declspecs_sc_ts_sa_noea
1266 | declspecs_sc_ts_sa_ea
1267 ;
1268
1269 declspecs_nots:
1270 declspecs_nosc_nots_nosa_noea
1271 | declspecs_nosc_nots_nosa_ea
1272 | declspecs_nosc_nots_sa_noea
1273 | declspecs_nosc_nots_sa_ea
1274 | declspecs_sc_nots_nosa_noea
1275 | declspecs_sc_nots_nosa_ea
1276 | declspecs_sc_nots_sa_noea
1277 | declspecs_sc_nots_sa_ea
1278 ;
1279
1280 declspecs_ts_nosa:
1281 declspecs_nosc_ts_nosa_noea
1282 | declspecs_nosc_ts_nosa_ea
1283 | declspecs_sc_ts_nosa_noea
1284 | declspecs_sc_ts_nosa_ea
1285 ;
1286
1287 declspecs_nots_nosa:
1288 declspecs_nosc_nots_nosa_noea
1289 | declspecs_nosc_nots_nosa_ea
1290 | declspecs_sc_nots_nosa_noea
1291 | declspecs_sc_nots_nosa_ea
1292 ;
1293
1294 declspecs_nosc_ts:
1295 declspecs_nosc_ts_nosa_noea
1296 | declspecs_nosc_ts_nosa_ea
1297 | declspecs_nosc_ts_sa_noea
1298 | declspecs_nosc_ts_sa_ea
1299 ;
1300
1301 declspecs_nosc_nots:
1302 declspecs_nosc_nots_nosa_noea
1303 | declspecs_nosc_nots_nosa_ea
1304 | declspecs_nosc_nots_sa_noea
1305 | declspecs_nosc_nots_sa_ea
1306 ;
1307
1308 declspecs_nosc:
1309 declspecs_nosc_ts_nosa_noea
1310 | declspecs_nosc_ts_nosa_ea
1311 | declspecs_nosc_ts_sa_noea
1312 | declspecs_nosc_ts_sa_ea
1313 | declspecs_nosc_nots_nosa_noea
1314 | declspecs_nosc_nots_nosa_ea
1315 | declspecs_nosc_nots_sa_noea
1316 | declspecs_nosc_nots_sa_ea
1317 ;
1318
1319 declspecs:
1320 declspecs_nosc_nots_nosa_noea
1321 | declspecs_nosc_nots_nosa_ea
1322 | declspecs_nosc_nots_sa_noea
1323 | declspecs_nosc_nots_sa_ea
1324 | declspecs_nosc_ts_nosa_noea
1325 | declspecs_nosc_ts_nosa_ea
1326 | declspecs_nosc_ts_sa_noea
1327 | declspecs_nosc_ts_sa_ea
1328 | declspecs_sc_nots_nosa_noea
1329 | declspecs_sc_nots_nosa_ea
1330 | declspecs_sc_nots_sa_noea
1331 | declspecs_sc_nots_sa_ea
1332 | declspecs_sc_ts_nosa_noea
1333 | declspecs_sc_ts_nosa_ea
1334 | declspecs_sc_ts_sa_noea
1335 | declspecs_sc_ts_sa_ea
1336 ;
1337
1338 /* A (possibly empty) sequence of type qualifiers and attributes. */
1339 maybe_type_quals_attrs:
1340 /* empty */
1341 { $$ = NULL_TREE; }
1342 | declspecs_nosc_nots
1343 { $$ = $1; }
1344 ;
1345
1346 /* A type specifier (but not a type qualifier).
1347 Once we have seen one of these in a declaration,
1348 if a typedef name appears then it is being redeclared.
1349
1350 The _reserved versions start with a reserved word and may appear anywhere
1351 in the declaration specifiers; the _nonreserved versions may only
1352 appear before any other type specifiers, and after that are (if names)
1353 being redeclared.
1354
1355 FIXME: should the _nonreserved version be restricted to names being
1356 redeclared only? The other entries there relate only the GNU extensions
1357 and Objective C, and are historically parsed thus, and don't make sense
1358 after other type specifiers, but it might be cleaner to count them as
1359 _reserved.
1360
1361 _attr means: specifiers that either end with attributes,
1362 or are such that any following attributes would
1363 be parsed as part of the specifier.
1364
1365 _nonattr: specifiers. */
1366
1367 typespec_nonattr:
1368 typespec_reserved_nonattr
1369 | typespec_nonreserved_nonattr
1370 ;
1371
1372 typespec_attr:
1373 typespec_reserved_attr
1374 ;
1375
1376 typespec_reserved_nonattr:
1377 TYPESPEC
1378 { OBJC_NEED_RAW_IDENTIFIER (1); }
1379 | structsp_nonattr
1380 ;
1381
1382 typespec_reserved_attr:
1383 structsp_attr
1384 ;
1385
1386 typespec_nonreserved_nonattr:
1387 TYPENAME
1388 { /* For a typedef name, record the meaning, not the name.
1389 In case of `foo foo, bar;'. */
1390 $$ = lookup_name ($1); }
1391 ifobjc
1392 | CLASSNAME protocolrefs
1393 { $$ = get_static_reference ($1, $2); }
1394 | OBJECTNAME protocolrefs
1395 { $$ = get_object_reference ($2); }
1396
1397 /* Make "<SomeProtocol>" equivalent to "id <SomeProtocol>"
1398 - nisse@lysator.liu.se */
1399 | non_empty_protocolrefs
1400 { $$ = get_object_reference ($1); }
1401 end ifobjc
1402 | typeof '(' expr ')'
1403 { skip_evaluation--; $$ = TREE_TYPE ($3); }
1404 | typeof '(' typename ')'
1405 { skip_evaluation--; $$ = groktypename ($3); }
1406 ;
1407
1408 /* typespec_nonreserved_attr does not exist. */
1409
1410 initdecls:
1411 initdcl
1412 | initdecls ',' maybe_resetattrs initdcl
1413 ;
1414
1415 notype_initdecls:
1416 notype_initdcl
1417 | notype_initdecls ',' maybe_resetattrs notype_initdcl
1418 ;
1419
1420 maybeasm:
1421 /* empty */
1422 { $$ = NULL_TREE; }
1423 | ASM_KEYWORD '(' STRING ')'
1424 { $$ = $3; }
1425 ;
1426
1427 initdcl:
1428 declarator maybeasm maybe_attribute '='
1429 { $<ttype>$ = start_decl ($1, current_declspecs, 1,
1430 chainon ($3, all_prefix_attributes));
1431 start_init ($<ttype>$, $2, global_bindings_p ()); }
1432 init
1433 /* Note how the declaration of the variable is in effect while its init is parsed! */
1434 { finish_init ();
1435 finish_decl ($<ttype>5, $6, $2); }
1436 | declarator maybeasm maybe_attribute
1437 { tree d = start_decl ($1, current_declspecs, 0,
1438 chainon ($3, all_prefix_attributes));
1439 finish_decl (d, NULL_TREE, $2);
1440 }
1441 ;
1442
1443 notype_initdcl:
1444 notype_declarator maybeasm maybe_attribute '='
1445 { $<ttype>$ = start_decl ($1, current_declspecs, 1,
1446 chainon ($3, all_prefix_attributes));
1447 start_init ($<ttype>$, $2, global_bindings_p ()); }
1448 init
1449 /* Note how the declaration of the variable is in effect while its init is parsed! */
1450 { finish_init ();
1451 finish_decl ($<ttype>5, $6, $2); }
1452 | notype_declarator maybeasm maybe_attribute
1453 { tree d = start_decl ($1, current_declspecs, 0,
1454 chainon ($3, all_prefix_attributes));
1455 finish_decl (d, NULL_TREE, $2); }
1456 ;
1457 /* the * rules are dummies to accept the Apollo extended syntax
1458 so that the header files compile. */
1459 maybe_attribute:
1460 /* empty */
1461 { $$ = NULL_TREE; }
1462 | attributes
1463 { $$ = $1; }
1464 ;
1465
1466 attributes:
1467 attribute
1468 { $$ = $1; }
1469 | attributes attribute
1470 { $$ = chainon ($1, $2); }
1471 ;
1472
1473 attribute:
1474 ATTRIBUTE '(' '(' attribute_list ')' ')'
1475 { $$ = $4; }
1476 ;
1477
1478 attribute_list:
1479 attrib
1480 { $$ = $1; }
1481 | attribute_list ',' attrib
1482 { $$ = chainon ($1, $3); }
1483 ;
1484
1485 attrib:
1486 /* empty */
1487 { $$ = NULL_TREE; }
1488 | any_word
1489 { $$ = build_tree_list ($1, NULL_TREE); }
1490 | any_word '(' IDENTIFIER ')'
1491 { $$ = build_tree_list ($1, build_tree_list (NULL_TREE, $3)); }
1492 | any_word '(' IDENTIFIER ',' nonnull_exprlist ')'
1493 { $$ = build_tree_list ($1, tree_cons (NULL_TREE, $3, $5)); }
1494 | any_word '(' exprlist ')'
1495 { $$ = build_tree_list ($1, $3); }
1496 ;
1497
1498 /* This still leaves out most reserved keywords,
1499 shouldn't we include them? */
1500
1501 any_word:
1502 identifier
1503 | scspec
1504 | TYPESPEC
1505 | TYPE_QUAL
1506 ;
1507
1508 scspec:
1509 STATIC
1510 | SCSPEC
1511 ;
1512 \f
1513 /* Initializers. `init' is the entry point. */
1514
1515 init:
1516 expr_no_commas
1517 | '{'
1518 { really_start_incremental_init (NULL_TREE); }
1519 initlist_maybe_comma '}'
1520 { $$ = pop_init_level (0); }
1521 | error
1522 { $$ = error_mark_node; }
1523 ;
1524
1525 /* `initlist_maybe_comma' is the guts of an initializer in braces. */
1526 initlist_maybe_comma:
1527 /* empty */
1528 { if (pedantic)
1529 pedwarn ("ISO C forbids empty initializer braces"); }
1530 | initlist1 maybecomma
1531 ;
1532
1533 initlist1:
1534 initelt
1535 | initlist1 ',' initelt
1536 ;
1537
1538 /* `initelt' is a single element of an initializer.
1539 It may use braces. */
1540 initelt:
1541 designator_list '=' initval
1542 { if (pedantic && ! flag_isoc99)
1543 pedwarn ("ISO C89 forbids specifying subobject to initialize"); }
1544 | designator initval
1545 { if (pedantic)
1546 pedwarn ("obsolete use of designated initializer without `='"); }
1547 | identifier ':'
1548 { set_init_label ($1);
1549 if (pedantic)
1550 pedwarn ("obsolete use of designated initializer with `:'"); }
1551 initval
1552 {}
1553 | initval
1554 ;
1555
1556 initval:
1557 '{'
1558 { push_init_level (0); }
1559 initlist_maybe_comma '}'
1560 { process_init_element (pop_init_level (0)); }
1561 | expr_no_commas
1562 { process_init_element ($1); }
1563 | error
1564 ;
1565
1566 designator_list:
1567 designator
1568 | designator_list designator
1569 ;
1570
1571 designator:
1572 '.' identifier
1573 { set_init_label ($2); }
1574 | '[' expr_no_commas ELLIPSIS expr_no_commas ']'
1575 { set_init_index ($2, $4);
1576 if (pedantic)
1577 pedwarn ("ISO C forbids specifying range of elements to initialize"); }
1578 | '[' expr_no_commas ']'
1579 { set_init_index ($2, NULL_TREE); }
1580 ;
1581 \f
1582 nested_function:
1583 declarator
1584 { if (pedantic)
1585 pedwarn ("ISO C forbids nested functions");
1586
1587 push_function_context ();
1588 if (! start_function (current_declspecs, $1,
1589 all_prefix_attributes))
1590 {
1591 pop_function_context ();
1592 YYERROR1;
1593 }
1594 parsing_iso_function_signature = false; /* Don't warn about nested functions. */
1595 }
1596 old_style_parm_decls
1597 { store_parm_decls (); }
1598 /* This used to use compstmt_or_error.
1599 That caused a bug with input `f(g) int g {}',
1600 where the use of YYERROR1 above caused an error
1601 which then was handled by compstmt_or_error.
1602 There followed a repeated execution of that same rule,
1603 which called YYERROR1 again, and so on. */
1604 save_filename save_lineno compstmt
1605 { tree decl = current_function_decl;
1606 DECL_SOURCE_FILE (decl) = $5;
1607 DECL_SOURCE_LINE (decl) = $6;
1608 finish_function (1, 1);
1609 pop_function_context ();
1610 add_decl_stmt (decl); }
1611 ;
1612
1613 notype_nested_function:
1614 notype_declarator
1615 { if (pedantic)
1616 pedwarn ("ISO C forbids nested functions");
1617
1618 push_function_context ();
1619 if (! start_function (current_declspecs, $1,
1620 all_prefix_attributes))
1621 {
1622 pop_function_context ();
1623 YYERROR1;
1624 }
1625 parsing_iso_function_signature = false; /* Don't warn about nested functions. */
1626 }
1627 old_style_parm_decls
1628 { store_parm_decls (); }
1629 /* This used to use compstmt_or_error.
1630 That caused a bug with input `f(g) int g {}',
1631 where the use of YYERROR1 above caused an error
1632 which then was handled by compstmt_or_error.
1633 There followed a repeated execution of that same rule,
1634 which called YYERROR1 again, and so on. */
1635 save_filename save_lineno compstmt
1636 { tree decl = current_function_decl;
1637 DECL_SOURCE_FILE (decl) = $5;
1638 DECL_SOURCE_LINE (decl) = $6;
1639 finish_function (1, 1);
1640 pop_function_context ();
1641 add_decl_stmt (decl); }
1642 ;
1643
1644 /* Any kind of declarator (thus, all declarators allowed
1645 after an explicit typespec). */
1646
1647 declarator:
1648 after_type_declarator
1649 | notype_declarator
1650 ;
1651
1652 /* A declarator that is allowed only after an explicit typespec. */
1653
1654 after_type_declarator:
1655 '(' maybe_attribute after_type_declarator ')'
1656 { $$ = $2 ? tree_cons ($2, $3, NULL_TREE) : $3; }
1657 | after_type_declarator '(' parmlist_or_identifiers %prec '.'
1658 { $$ = build_nt (CALL_EXPR, $1, $3, NULL_TREE); }
1659 /* | after_type_declarator '(' error ')' %prec '.'
1660 { $$ = build_nt (CALL_EXPR, $1, NULL_TREE, NULL_TREE);
1661 poplevel (0, 0, 0); } */
1662 | after_type_declarator array_declarator %prec '.'
1663 { $$ = set_array_declarator_type ($2, $1, 0); }
1664 | '*' maybe_type_quals_attrs after_type_declarator %prec UNARY
1665 { $$ = make_pointer_declarator ($2, $3); }
1666 | TYPENAME
1667 ifobjc
1668 | OBJECTNAME
1669 end ifobjc
1670 ;
1671
1672 /* Kinds of declarator that can appear in a parameter list
1673 in addition to notype_declarator. This is like after_type_declarator
1674 but does not allow a typedef name in parentheses as an identifier
1675 (because it would conflict with a function with that typedef as arg). */
1676 parm_declarator:
1677 parm_declarator_starttypename
1678 | parm_declarator_nostarttypename
1679 ;
1680
1681 parm_declarator_starttypename:
1682 parm_declarator_starttypename '(' parmlist_or_identifiers %prec '.'
1683 { $$ = build_nt (CALL_EXPR, $1, $3, NULL_TREE); }
1684 /* | parm_declarator_starttypename '(' error ')' %prec '.'
1685 { $$ = build_nt (CALL_EXPR, $1, NULL_TREE, NULL_TREE);
1686 poplevel (0, 0, 0); } */
1687 | parm_declarator_starttypename array_declarator %prec '.'
1688 { $$ = set_array_declarator_type ($2, $1, 0); }
1689 | TYPENAME
1690 ifobjc
1691 | OBJECTNAME
1692 end ifobjc
1693 ;
1694
1695 parm_declarator_nostarttypename:
1696 parm_declarator_nostarttypename '(' parmlist_or_identifiers %prec '.'
1697 { $$ = build_nt (CALL_EXPR, $1, $3, NULL_TREE); }
1698 /* | parm_declarator_nostarttypename '(' error ')' %prec '.'
1699 { $$ = build_nt (CALL_EXPR, $1, NULL_TREE, NULL_TREE);
1700 poplevel (0, 0, 0); } */
1701 | parm_declarator_nostarttypename array_declarator %prec '.'
1702 { $$ = set_array_declarator_type ($2, $1, 0); }
1703 | '*' maybe_type_quals_attrs parm_declarator_starttypename %prec UNARY
1704 { $$ = make_pointer_declarator ($2, $3); }
1705 | '*' maybe_type_quals_attrs parm_declarator_nostarttypename %prec UNARY
1706 { $$ = make_pointer_declarator ($2, $3); }
1707 | '(' maybe_attribute parm_declarator_nostarttypename ')'
1708 { $$ = $2 ? tree_cons ($2, $3, NULL_TREE) : $3; }
1709 ;
1710
1711 /* A declarator allowed whether or not there has been
1712 an explicit typespec. These cannot redeclare a typedef-name. */
1713
1714 notype_declarator:
1715 notype_declarator '(' parmlist_or_identifiers %prec '.'
1716 { $$ = build_nt (CALL_EXPR, $1, $3, NULL_TREE); }
1717 /* | notype_declarator '(' error ')' %prec '.'
1718 { $$ = build_nt (CALL_EXPR, $1, NULL_TREE, NULL_TREE);
1719 poplevel (0, 0, 0); } */
1720 | '(' maybe_attribute notype_declarator ')'
1721 { $$ = $2 ? tree_cons ($2, $3, NULL_TREE) : $3; }
1722 | '*' maybe_type_quals_attrs notype_declarator %prec UNARY
1723 { $$ = make_pointer_declarator ($2, $3); }
1724 | notype_declarator array_declarator %prec '.'
1725 { $$ = set_array_declarator_type ($2, $1, 0); }
1726 | IDENTIFIER
1727 ;
1728
1729 struct_head:
1730 STRUCT
1731 { $$ = NULL_TREE; }
1732 | STRUCT attributes
1733 { $$ = $2; }
1734 ;
1735
1736 union_head:
1737 UNION
1738 { $$ = NULL_TREE; }
1739 | UNION attributes
1740 { $$ = $2; }
1741 ;
1742
1743 enum_head:
1744 ENUM
1745 { $$ = NULL_TREE; }
1746 | ENUM attributes
1747 { $$ = $2; }
1748 ;
1749
1750 /* structsp_attr: struct/union/enum specifiers that either
1751 end with attributes, or are such that any following attributes would
1752 be parsed as part of the struct/union/enum specifier.
1753
1754 structsp_nonattr: other struct/union/enum specifiers. */
1755
1756 structsp_attr:
1757 struct_head identifier '{'
1758 { $$ = start_struct (RECORD_TYPE, $2);
1759 /* Start scope of tag before parsing components. */
1760 }
1761 component_decl_list '}' maybe_attribute
1762 { $$ = finish_struct ($<ttype>4, nreverse ($5),
1763 chainon ($1, $7)); }
1764 | struct_head '{' component_decl_list '}' maybe_attribute
1765 { $$ = finish_struct (start_struct (RECORD_TYPE, NULL_TREE),
1766 nreverse ($3), chainon ($1, $5));
1767 }
1768 | union_head identifier '{'
1769 { $$ = start_struct (UNION_TYPE, $2); }
1770 component_decl_list '}' maybe_attribute
1771 { $$ = finish_struct ($<ttype>4, nreverse ($5),
1772 chainon ($1, $7)); }
1773 | union_head '{' component_decl_list '}' maybe_attribute
1774 { $$ = finish_struct (start_struct (UNION_TYPE, NULL_TREE),
1775 nreverse ($3), chainon ($1, $5));
1776 }
1777 | enum_head identifier '{'
1778 { $$ = start_enum ($2); }
1779 enumlist maybecomma_warn '}' maybe_attribute
1780 { $$ = finish_enum ($<ttype>4, nreverse ($5),
1781 chainon ($1, $8)); }
1782 | enum_head '{'
1783 { $$ = start_enum (NULL_TREE); }
1784 enumlist maybecomma_warn '}' maybe_attribute
1785 { $$ = finish_enum ($<ttype>3, nreverse ($4),
1786 chainon ($1, $7)); }
1787 ;
1788
1789 structsp_nonattr:
1790 struct_head identifier
1791 { $$ = xref_tag (RECORD_TYPE, $2); }
1792 | union_head identifier
1793 { $$ = xref_tag (UNION_TYPE, $2); }
1794 | enum_head identifier
1795 { $$ = xref_tag (ENUMERAL_TYPE, $2);
1796 /* In ISO C, enumerated types can be referred to
1797 only if already defined. */
1798 if (pedantic && !COMPLETE_TYPE_P ($$))
1799 pedwarn ("ISO C forbids forward references to `enum' types"); }
1800 ;
1801
1802 maybecomma:
1803 /* empty */
1804 | ','
1805 ;
1806
1807 maybecomma_warn:
1808 /* empty */
1809 | ','
1810 { if (pedantic && ! flag_isoc99)
1811 pedwarn ("comma at end of enumerator list"); }
1812 ;
1813
1814 /* We chain the components in reverse order. They are put in forward
1815 order in structsp_attr.
1816
1817 Note that component_declarator returns single decls, so components
1818 and components_notype can use TREE_CHAIN directly, wheras components
1819 and components_notype return lists (of comma separated decls), so
1820 component_decl_list and component_decl_list2 must use chainon.
1821
1822 The theory behind all this is that there will be more semicolon
1823 separated fields than comma separated fields, and so we'll be
1824 minimizing the number of node traversals required by chainon. */
1825
1826 component_decl_list:
1827 component_decl_list2
1828 { $$ = $1; }
1829 | component_decl_list2 component_decl
1830 { $$ = chainon ($2, $1);
1831 pedwarn ("no semicolon at end of struct or union"); }
1832 ;
1833
1834 component_decl_list2: /* empty */
1835 { $$ = NULL_TREE; }
1836 | component_decl_list2 component_decl ';'
1837 { $$ = chainon ($2, $1); }
1838 | component_decl_list2 ';'
1839 { if (pedantic)
1840 pedwarn ("extra semicolon in struct or union specified"); }
1841 ifobjc
1842 /* foo(sizeof(struct{ @defs(ClassName)})); */
1843 | DEFS '(' CLASSNAME ')'
1844 {
1845 tree interface = lookup_interface ($3);
1846
1847 if (interface)
1848 $$ = nreverse (get_class_ivars (interface));
1849 else
1850 {
1851 error ("cannot find interface declaration for `%s'",
1852 IDENTIFIER_POINTER ($3));
1853 $$ = NULL_TREE;
1854 }
1855 }
1856 end ifobjc
1857 ;
1858
1859 component_decl:
1860 declspecs_nosc_ts setspecs components
1861 { $$ = $3;
1862 POP_DECLSPEC_STACK; }
1863 | declspecs_nosc_ts setspecs save_filename save_lineno
1864 {
1865 /* Support for unnamed structs or unions as members of
1866 structs or unions (which is [a] useful and [b] supports
1867 MS P-SDK). */
1868 if (pedantic)
1869 pedwarn ("ISO C doesn't support unnamed structs/unions");
1870
1871 $$ = grokfield($3, $4, NULL, current_declspecs, NULL_TREE);
1872 POP_DECLSPEC_STACK; }
1873 | declspecs_nosc_nots setspecs components_notype
1874 { $$ = $3;
1875 POP_DECLSPEC_STACK; }
1876 | declspecs_nosc_nots
1877 { if (pedantic)
1878 pedwarn ("ISO C forbids member declarations with no members");
1879 shadow_tag($1);
1880 $$ = NULL_TREE; }
1881 | error
1882 { $$ = NULL_TREE; }
1883 | extension component_decl
1884 { $$ = $2;
1885 RESTORE_EXT_FLAGS ($1); }
1886 ;
1887
1888 components:
1889 component_declarator
1890 | components ',' maybe_resetattrs component_declarator
1891 { TREE_CHAIN ($4) = $1; $$ = $4; }
1892 ;
1893
1894 components_notype:
1895 component_notype_declarator
1896 | components_notype ',' maybe_resetattrs component_notype_declarator
1897 { TREE_CHAIN ($4) = $1; $$ = $4; }
1898 ;
1899
1900 component_declarator:
1901 save_filename save_lineno declarator maybe_attribute
1902 { $$ = grokfield ($1, $2, $3, current_declspecs, NULL_TREE);
1903 decl_attributes (&$$, chainon ($4, all_prefix_attributes), 0); }
1904 | save_filename save_lineno
1905 declarator ':' expr_no_commas maybe_attribute
1906 { $$ = grokfield ($1, $2, $3, current_declspecs, $5);
1907 decl_attributes (&$$, chainon ($6, all_prefix_attributes), 0); }
1908 | save_filename save_lineno ':' expr_no_commas maybe_attribute
1909 { $$ = grokfield ($1, $2, NULL_TREE, current_declspecs, $4);
1910 decl_attributes (&$$, chainon ($5, all_prefix_attributes), 0); }
1911 ;
1912
1913 component_notype_declarator:
1914 save_filename save_lineno notype_declarator maybe_attribute
1915 { $$ = grokfield ($1, $2, $3, current_declspecs, NULL_TREE);
1916 decl_attributes (&$$, chainon ($4, all_prefix_attributes), 0); }
1917 | save_filename save_lineno
1918 notype_declarator ':' expr_no_commas maybe_attribute
1919 { $$ = grokfield ($1, $2, $3, current_declspecs, $5);
1920 decl_attributes (&$$, chainon ($6, all_prefix_attributes), 0); }
1921 | save_filename save_lineno ':' expr_no_commas maybe_attribute
1922 { $$ = grokfield ($1, $2, NULL_TREE, current_declspecs, $4);
1923 decl_attributes (&$$, chainon ($5, all_prefix_attributes), 0); }
1924 ;
1925
1926 /* We chain the enumerators in reverse order.
1927 They are put in forward order in structsp_attr. */
1928
1929 enumlist:
1930 enumerator
1931 | enumlist ',' enumerator
1932 { if ($1 == error_mark_node)
1933 $$ = $1;
1934 else
1935 TREE_CHAIN ($3) = $1, $$ = $3; }
1936 | error
1937 { $$ = error_mark_node; }
1938 ;
1939
1940
1941 enumerator:
1942 identifier
1943 { $$ = build_enumerator ($1, NULL_TREE); }
1944 | identifier '=' expr_no_commas
1945 { $$ = build_enumerator ($1, $3); }
1946 ;
1947
1948 typename:
1949 declspecs_nosc
1950 { pending_xref_error ();
1951 $<ttype>$ = $1; }
1952 absdcl
1953 { $$ = build_tree_list ($<ttype>2, $3); }
1954 ;
1955
1956 absdcl: /* an absolute declarator */
1957 /* empty */
1958 { $$ = NULL_TREE; }
1959 | absdcl1
1960 ;
1961
1962 absdcl_maybe_attribute: /* absdcl maybe_attribute, but not just attributes */
1963 /* empty */
1964 { $$ = build_tree_list (build_tree_list (current_declspecs,
1965 NULL_TREE),
1966 all_prefix_attributes); }
1967 | absdcl1
1968 { $$ = build_tree_list (build_tree_list (current_declspecs,
1969 $1),
1970 all_prefix_attributes); }
1971 | absdcl1_noea attributes
1972 { $$ = build_tree_list (build_tree_list (current_declspecs,
1973 $1),
1974 chainon ($2, all_prefix_attributes)); }
1975 ;
1976
1977 absdcl1: /* a nonempty absolute declarator */
1978 absdcl1_ea
1979 | absdcl1_noea
1980 ;
1981
1982 absdcl1_noea:
1983 direct_absdcl1
1984 | '*' maybe_type_quals_attrs absdcl1_noea
1985 { $$ = make_pointer_declarator ($2, $3); }
1986 ;
1987
1988 absdcl1_ea:
1989 '*' maybe_type_quals_attrs
1990 { $$ = make_pointer_declarator ($2, NULL_TREE); }
1991 | '*' maybe_type_quals_attrs absdcl1_ea
1992 { $$ = make_pointer_declarator ($2, $3); }
1993 ;
1994
1995 direct_absdcl1:
1996 '(' maybe_attribute absdcl1 ')'
1997 { $$ = $2 ? tree_cons ($2, $3, NULL_TREE) : $3; }
1998 | direct_absdcl1 '(' parmlist
1999 { $$ = build_nt (CALL_EXPR, $1, $3, NULL_TREE); }
2000 | direct_absdcl1 array_declarator
2001 { $$ = set_array_declarator_type ($2, $1, 1); }
2002 | '(' parmlist
2003 { $$ = build_nt (CALL_EXPR, NULL_TREE, $2, NULL_TREE); }
2004 | array_declarator
2005 { $$ = set_array_declarator_type ($1, NULL_TREE, 1); }
2006 ;
2007
2008 /* The [...] part of a declarator for an array type. */
2009
2010 array_declarator:
2011 '[' maybe_type_quals_attrs expr ']'
2012 { $$ = build_array_declarator ($3, $2, 0, 0); }
2013 | '[' maybe_type_quals_attrs ']'
2014 { $$ = build_array_declarator (NULL_TREE, $2, 0, 0); }
2015 | '[' maybe_type_quals_attrs '*' ']'
2016 { $$ = build_array_declarator (NULL_TREE, $2, 0, 1); }
2017 | '[' STATIC maybe_type_quals_attrs expr ']'
2018 { $$ = build_array_declarator ($4, $3, 1, 0); }
2019 /* declspecs_nosc_nots is a synonym for type_quals_attrs. */
2020 | '[' declspecs_nosc_nots STATIC expr ']'
2021 { $$ = build_array_declarator ($4, $2, 1, 0); }
2022 ;
2023
2024 /* A nonempty series of declarations and statements (possibly followed by
2025 some labels) that can form the body of a compound statement.
2026 NOTE: we don't allow labels on declarations; this might seem like a
2027 natural extension, but there would be a conflict between attributes
2028 on the label and prefix attributes on the declaration. */
2029
2030 stmts_and_decls:
2031 lineno_stmt_decl_or_labels_ending_stmt
2032 | lineno_stmt_decl_or_labels_ending_decl
2033 | lineno_stmt_decl_or_labels_ending_label
2034 {
2035 pedwarn ("deprecated use of label at end of compound statement");
2036 }
2037 | lineno_stmt_decl_or_labels_ending_error
2038 ;
2039
2040 lineno_stmt_decl_or_labels_ending_stmt:
2041 lineno_stmt
2042 | lineno_stmt_decl_or_labels_ending_stmt lineno_stmt
2043 | lineno_stmt_decl_or_labels_ending_decl lineno_stmt
2044 | lineno_stmt_decl_or_labels_ending_label lineno_stmt
2045 | lineno_stmt_decl_or_labels_ending_error lineno_stmt
2046 ;
2047
2048 lineno_stmt_decl_or_labels_ending_decl:
2049 lineno_decl
2050 | lineno_stmt_decl_or_labels_ending_stmt lineno_decl
2051 { if (pedantic && !flag_isoc99)
2052 pedwarn ("ISO C89 forbids mixed declarations and code"); }
2053 | lineno_stmt_decl_or_labels_ending_decl lineno_decl
2054 | lineno_stmt_decl_or_labels_ending_error lineno_decl
2055 ;
2056
2057 lineno_stmt_decl_or_labels_ending_label:
2058 lineno_label
2059 | lineno_stmt_decl_or_labels_ending_stmt lineno_label
2060 | lineno_stmt_decl_or_labels_ending_decl lineno_label
2061 | lineno_stmt_decl_or_labels_ending_label lineno_label
2062 | lineno_stmt_decl_or_labels_ending_error lineno_label
2063 ;
2064
2065 lineno_stmt_decl_or_labels_ending_error:
2066 errstmt
2067 | lineno_stmt_decl_or_labels errstmt
2068 ;
2069
2070 lineno_stmt_decl_or_labels:
2071 lineno_stmt_decl_or_labels_ending_stmt
2072 | lineno_stmt_decl_or_labels_ending_decl
2073 | lineno_stmt_decl_or_labels_ending_label
2074 | lineno_stmt_decl_or_labels_ending_error
2075 ;
2076
2077 errstmt: error ';'
2078 ;
2079
2080 pushlevel: /* empty */
2081 { pushlevel (0);
2082 clear_last_expr ();
2083 add_scope_stmt (/*begin_p=*/1, /*partial_p=*/0);
2084 ifobjc
2085 if (objc_method_context)
2086 add_objc_decls ();
2087 end ifobjc
2088 }
2089 ;
2090
2091 poplevel: /* empty */
2092 { $$ = add_scope_stmt (/*begin_p=*/0, /*partial_p=*/0); }
2093 ;
2094
2095 /* Start and end blocks created for the new scopes of C99. */
2096 c99_block_start: /* empty */
2097 { if (flag_isoc99)
2098 {
2099 $$ = c_begin_compound_stmt ();
2100 pushlevel (0);
2101 clear_last_expr ();
2102 add_scope_stmt (/*begin_p=*/1, /*partial_p=*/0);
2103 ifobjc
2104 if (objc_method_context)
2105 add_objc_decls ();
2106 end ifobjc
2107 }
2108 else
2109 $$ = NULL_TREE;
2110 }
2111 ;
2112
2113 /* Productions using c99_block_start and c99_block_end will need to do what's
2114 in compstmt: RECHAIN_STMTS ($1, COMPOUND_BODY ($1)); $$ = $2; where
2115 $1 is the value of c99_block_start and $2 of c99_block_end. */
2116 c99_block_end: /* empty */
2117 { if (flag_isoc99)
2118 {
2119 tree scope_stmt = add_scope_stmt (/*begin_p=*/0, /*partial_p=*/0);
2120 $$ = poplevel (kept_level_p (), 0, 0);
2121 SCOPE_STMT_BLOCK (TREE_PURPOSE (scope_stmt))
2122 = SCOPE_STMT_BLOCK (TREE_VALUE (scope_stmt))
2123 = $$;
2124 }
2125 else
2126 $$ = NULL_TREE; }
2127 ;
2128
2129 /* Read zero or more forward-declarations for labels
2130 that nested functions can jump to. */
2131 maybe_label_decls:
2132 /* empty */
2133 | label_decls
2134 { if (pedantic)
2135 pedwarn ("ISO C forbids label declarations"); }
2136 ;
2137
2138 label_decls:
2139 label_decl
2140 | label_decls label_decl
2141 ;
2142
2143 label_decl:
2144 LABEL identifiers_or_typenames ';'
2145 { tree link;
2146 for (link = $2; link; link = TREE_CHAIN (link))
2147 {
2148 tree label = shadow_label (TREE_VALUE (link));
2149 C_DECLARED_LABEL_FLAG (label) = 1;
2150 add_decl_stmt (label);
2151 }
2152 }
2153 ;
2154
2155 /* This is the body of a function definition.
2156 It causes syntax errors to ignore to the next openbrace. */
2157 compstmt_or_error:
2158 compstmt
2159 {}
2160 | error compstmt
2161 ;
2162
2163 compstmt_start: '{' { compstmt_count++;
2164 $$ = c_begin_compound_stmt (); }
2165 ;
2166
2167 compstmt_nostart: '}'
2168 { $$ = convert (void_type_node, integer_zero_node); }
2169 | pushlevel maybe_label_decls compstmt_contents_nonempty '}' poplevel
2170 { $$ = poplevel (kept_level_p (), 1, 0);
2171 SCOPE_STMT_BLOCK (TREE_PURPOSE ($5))
2172 = SCOPE_STMT_BLOCK (TREE_VALUE ($5))
2173 = $$; }
2174 ;
2175
2176 compstmt_contents_nonempty:
2177 stmts_and_decls
2178 | error
2179 ;
2180
2181 compstmt_primary_start:
2182 '(' '{'
2183 { if (current_function_decl == 0)
2184 {
2185 error ("braced-group within expression allowed only inside a function");
2186 YYERROR;
2187 }
2188 /* We must force a BLOCK for this level
2189 so that, if it is not expanded later,
2190 there is a way to turn off the entire subtree of blocks
2191 that are contained in it. */
2192 keep_next_level ();
2193 push_label_level ();
2194 compstmt_count++;
2195 $$ = add_stmt (build_stmt (COMPOUND_STMT, last_tree));
2196 }
2197 ;
2198
2199 compstmt: compstmt_start compstmt_nostart
2200 { RECHAIN_STMTS ($1, COMPOUND_BODY ($1));
2201 last_expr_type = NULL_TREE;
2202 $$ = $1; }
2203 ;
2204
2205 /* Value is number of statements counted as of the closeparen. */
2206 simple_if:
2207 if_prefix c99_block_lineno_labeled_stmt
2208 { c_finish_then (); }
2209 /* Make sure c_expand_end_cond is run once
2210 for each call to c_expand_start_cond.
2211 Otherwise a crash is likely. */
2212 | if_prefix error
2213 ;
2214
2215 if_prefix:
2216 /* We must build the IF_STMT node before parsing its
2217 condition so that STMT_LINENO refers to the line
2218 containing the "if", and not the line containing
2219 the close-parenthesis.
2220
2221 c_begin_if_stmt returns the IF_STMT node, which
2222 we later pass to c_expand_start_cond to fill
2223 in the condition and other tidbits. */
2224 IF
2225 { $<ttype>$ = c_begin_if_stmt (); }
2226 '(' expr ')'
2227 { c_expand_start_cond (c_common_truthvalue_conversion ($4),
2228 compstmt_count,$<ttype>2);
2229 $<itype>$ = stmt_count;
2230 if_stmt_locus.file = $<filename>-2;
2231 if_stmt_locus.line = $<lineno>-1; }
2232 ;
2233
2234 /* This is a subroutine of stmt.
2235 It is used twice, once for valid DO statements
2236 and once for catching errors in parsing the end test. */
2237 do_stmt_start:
2238 DO
2239 { stmt_count++;
2240 compstmt_count++;
2241 $<ttype>$
2242 = add_stmt (build_stmt (DO_STMT, NULL_TREE,
2243 NULL_TREE));
2244 /* In the event that a parse error prevents
2245 parsing the complete do-statement, set the
2246 condition now. Otherwise, we can get crashes at
2247 RTL-generation time. */
2248 DO_COND ($<ttype>$) = error_mark_node; }
2249 c99_block_lineno_labeled_stmt WHILE
2250 { $$ = $<ttype>2;
2251 RECHAIN_STMTS ($$, DO_BODY ($$)); }
2252 ;
2253
2254 /* The forced readahead in here is because we might be at the end of a
2255 line, and the line and file won't be bumped until yylex absorbs the
2256 first token on the next line. */
2257 save_filename:
2258 { if (yychar == YYEMPTY)
2259 yychar = YYLEX;
2260 $$ = input_filename; }
2261 ;
2262
2263 save_lineno:
2264 { if (yychar == YYEMPTY)
2265 yychar = YYLEX;
2266 $$ = input_line; }
2267 ;
2268
2269 lineno_labeled_stmt:
2270 lineno_stmt
2271 | lineno_label lineno_labeled_stmt
2272 ;
2273
2274 /* Like lineno_labeled_stmt, but a block in C99. */
2275 c99_block_lineno_labeled_stmt:
2276 c99_block_start lineno_labeled_stmt c99_block_end
2277 { if (flag_isoc99)
2278 RECHAIN_STMTS ($1, COMPOUND_BODY ($1)); }
2279 ;
2280
2281 lineno_stmt:
2282 save_filename save_lineno stmt
2283 { if ($3)
2284 {
2285 STMT_LINENO ($3) = $2;
2286 /* ??? We currently have no way of recording
2287 the filename for a statement. This probably
2288 matters little in practice at the moment,
2289 but I suspect that problems will occur when
2290 doing inlining at the tree level. */
2291 }
2292 }
2293 ;
2294
2295 lineno_label:
2296 save_filename save_lineno label
2297 { if ($3)
2298 {
2299 STMT_LINENO ($3) = $2;
2300 }
2301 }
2302 ;
2303
2304 select_or_iter_stmt:
2305 simple_if ELSE
2306 { c_expand_start_else ();
2307 $<itype>1 = stmt_count; }
2308 c99_block_lineno_labeled_stmt
2309 { c_finish_else ();
2310 c_expand_end_cond ();
2311 if (extra_warnings && stmt_count == $<itype>1)
2312 warning ("empty body in an else-statement"); }
2313 | simple_if %prec IF
2314 { c_expand_end_cond ();
2315 /* This warning is here instead of in simple_if, because we
2316 do not want a warning if an empty if is followed by an
2317 else statement. Increment stmt_count so we don't
2318 give a second error if this is a nested `if'. */
2319 if (extra_warnings && stmt_count++ == $<itype>1)
2320 warning ("%Hempty body in an if-statement",
2321 &if_stmt_locus); }
2322 /* Make sure c_expand_end_cond is run once
2323 for each call to c_expand_start_cond.
2324 Otherwise a crash is likely. */
2325 | simple_if ELSE error
2326 { c_expand_end_cond (); }
2327 /* We must build the WHILE_STMT node before parsing its
2328 condition so that STMT_LINENO refers to the line
2329 containing the "while", and not the line containing
2330 the close-parenthesis.
2331
2332 c_begin_while_stmt returns the WHILE_STMT node, which
2333 we later pass to c_finish_while_stmt_cond to fill
2334 in the condition and other tidbits. */
2335 | WHILE
2336 { stmt_count++;
2337 $<ttype>$ = c_begin_while_stmt (); }
2338 '(' expr ')'
2339 { $4 = c_common_truthvalue_conversion ($4);
2340 c_finish_while_stmt_cond
2341 (c_common_truthvalue_conversion ($4), $<ttype>2);
2342 $<ttype>$ = add_stmt ($<ttype>2); }
2343 c99_block_lineno_labeled_stmt
2344 { RECHAIN_STMTS ($<ttype>6, WHILE_BODY ($<ttype>6)); }
2345 | do_stmt_start
2346 '(' expr ')' ';'
2347 { DO_COND ($1) = c_common_truthvalue_conversion ($3); }
2348 | do_stmt_start error
2349 { }
2350 | FOR
2351 { $<ttype>$ = build_stmt (FOR_STMT, NULL_TREE, NULL_TREE,
2352 NULL_TREE, NULL_TREE);
2353 add_stmt ($<ttype>$); }
2354 '(' for_init_stmt
2355 { stmt_count++;
2356 RECHAIN_STMTS ($<ttype>2, FOR_INIT_STMT ($<ttype>2)); }
2357 xexpr ';'
2358 { if ($6)
2359 FOR_COND ($<ttype>2)
2360 = c_common_truthvalue_conversion ($6); }
2361 xexpr ')'
2362 { FOR_EXPR ($<ttype>2) = $9; }
2363 c99_block_lineno_labeled_stmt
2364 { RECHAIN_STMTS ($<ttype>2, FOR_BODY ($<ttype>2)); }
2365 | SWITCH '(' expr ')'
2366 { stmt_count++;
2367 $<ttype>$ = c_start_case ($3); }
2368 c99_block_lineno_labeled_stmt
2369 { c_finish_case (); }
2370 ;
2371
2372 for_init_stmt:
2373 xexpr ';'
2374 { add_stmt (build_stmt (EXPR_STMT, $1)); }
2375 | decl
2376 { check_for_loop_decls (); }
2377 ;
2378
2379 /* Parse a single real statement, not including any labels. */
2380 stmt:
2381 compstmt
2382 { stmt_count++; $$ = $1; }
2383 | expr ';'
2384 { stmt_count++;
2385 $$ = c_expand_expr_stmt ($1); }
2386 | c99_block_start select_or_iter_stmt c99_block_end
2387 { if (flag_isoc99)
2388 RECHAIN_STMTS ($1, COMPOUND_BODY ($1));
2389 $$ = NULL_TREE; }
2390 | BREAK ';'
2391 { stmt_count++;
2392 $$ = add_stmt (build_break_stmt ()); }
2393 | CONTINUE ';'
2394 { stmt_count++;
2395 $$ = add_stmt (build_continue_stmt ()); }
2396 | RETURN ';'
2397 { stmt_count++;
2398 $$ = c_expand_return (NULL_TREE); }
2399 | RETURN expr ';'
2400 { stmt_count++;
2401 $$ = c_expand_return ($2); }
2402 | ASM_KEYWORD maybe_type_qual '(' expr ')' ';'
2403 { stmt_count++;
2404 $$ = simple_asm_stmt ($4); }
2405 /* This is the case with just output operands. */
2406 | ASM_KEYWORD maybe_type_qual '(' expr ':' asm_operands ')' ';'
2407 { stmt_count++;
2408 $$ = build_asm_stmt ($2, $4, $6, NULL_TREE, NULL_TREE); }
2409 /* This is the case with input operands as well. */
2410 | ASM_KEYWORD maybe_type_qual '(' expr ':' asm_operands ':'
2411 asm_operands ')' ';'
2412 { stmt_count++;
2413 $$ = build_asm_stmt ($2, $4, $6, $8, NULL_TREE); }
2414 /* This is the case with clobbered registers as well. */
2415 | ASM_KEYWORD maybe_type_qual '(' expr ':' asm_operands ':'
2416 asm_operands ':' asm_clobbers ')' ';'
2417 { stmt_count++;
2418 $$ = build_asm_stmt ($2, $4, $6, $8, $10); }
2419 | GOTO identifier ';'
2420 { tree decl;
2421 stmt_count++;
2422 decl = lookup_label ($2);
2423 if (decl != 0)
2424 {
2425 TREE_USED (decl) = 1;
2426 $$ = add_stmt (build_stmt (GOTO_STMT, decl));
2427 }
2428 else
2429 $$ = NULL_TREE;
2430 }
2431 | GOTO '*' expr ';'
2432 { if (pedantic)
2433 pedwarn ("ISO C forbids `goto *expr;'");
2434 stmt_count++;
2435 $3 = convert (ptr_type_node, $3);
2436 $$ = add_stmt (build_stmt (GOTO_STMT, $3)); }
2437 | ';'
2438 { $$ = NULL_TREE; }
2439 ;
2440
2441 /* Any kind of label, including jump labels and case labels.
2442 ANSI C accepts labels only before statements, but we allow them
2443 also at the end of a compound statement. */
2444
2445 label: CASE expr_no_commas ':'
2446 { stmt_count++;
2447 $$ = do_case ($2, NULL_TREE); }
2448 | CASE expr_no_commas ELLIPSIS expr_no_commas ':'
2449 { stmt_count++;
2450 $$ = do_case ($2, $4); }
2451 | DEFAULT ':'
2452 { stmt_count++;
2453 $$ = do_case (NULL_TREE, NULL_TREE); }
2454 | identifier save_filename save_lineno ':' maybe_attribute
2455 { tree label = define_label ($2, $3, $1);
2456 stmt_count++;
2457 if (label)
2458 {
2459 decl_attributes (&label, $5, 0);
2460 $$ = add_stmt (build_stmt (LABEL_STMT, label));
2461 }
2462 else
2463 $$ = NULL_TREE;
2464 }
2465 ;
2466
2467 /* Either a type-qualifier or nothing. First thing in an `asm' statement. */
2468
2469 maybe_type_qual:
2470 /* empty */
2471 { emit_line_note (input_filename, input_line);
2472 $$ = NULL_TREE; }
2473 | TYPE_QUAL
2474 { emit_line_note (input_filename, input_line); }
2475 ;
2476
2477 xexpr:
2478 /* empty */
2479 { $$ = NULL_TREE; }
2480 | expr
2481 ;
2482
2483 /* These are the operands other than the first string and colon
2484 in asm ("addextend %2,%1": "=dm" (x), "0" (y), "g" (*x)) */
2485 asm_operands: /* empty */
2486 { $$ = NULL_TREE; }
2487 | nonnull_asm_operands
2488 ;
2489
2490 nonnull_asm_operands:
2491 asm_operand
2492 | nonnull_asm_operands ',' asm_operand
2493 { $$ = chainon ($1, $3); }
2494 ;
2495
2496 asm_operand:
2497 STRING '(' expr ')'
2498 { $$ = build_tree_list (build_tree_list (NULL_TREE, $1), $3); }
2499 | '[' identifier ']' STRING '(' expr ')'
2500 { $2 = build_string (IDENTIFIER_LENGTH ($2),
2501 IDENTIFIER_POINTER ($2));
2502 $$ = build_tree_list (build_tree_list ($2, $4), $6); }
2503 ;
2504
2505 asm_clobbers:
2506 STRING
2507 { $$ = tree_cons (NULL_TREE, $1, NULL_TREE); }
2508 | asm_clobbers ',' STRING
2509 { $$ = tree_cons (NULL_TREE, $3, $1); }
2510 ;
2511 \f
2512 /* This is what appears inside the parens in a function declarator.
2513 Its value is a list of ..._TYPE nodes. Attributes must appear here
2514 to avoid a conflict with their appearance after an open parenthesis
2515 in an abstract declarator, as in
2516 "void bar (int (__attribute__((__mode__(SI))) int foo));". */
2517 parmlist:
2518 maybe_attribute
2519 { pushlevel (0);
2520 clear_parm_order ();
2521 declare_parm_level (0); }
2522 parmlist_1
2523 { $$ = $3;
2524 parmlist_tags_warning ();
2525 poplevel (0, 0, 0); }
2526 ;
2527
2528 parmlist_1:
2529 parmlist_2 ')'
2530 | parms ';'
2531 { tree parm;
2532 if (pedantic)
2533 pedwarn ("ISO C forbids forward parameter declarations");
2534 /* Mark the forward decls as such. */
2535 for (parm = getdecls (); parm; parm = TREE_CHAIN (parm))
2536 TREE_ASM_WRITTEN (parm) = 1;
2537 clear_parm_order (); }
2538 maybe_attribute
2539 { /* Dummy action so attributes are in known place
2540 on parser stack. */ }
2541 parmlist_1
2542 { $$ = $6; }
2543 | error ')'
2544 { $$ = tree_cons (NULL_TREE, NULL_TREE, NULL_TREE); }
2545 ;
2546
2547 /* This is what appears inside the parens in a function declarator.
2548 Is value is represented in the format that grokdeclarator expects. */
2549 parmlist_2: /* empty */
2550 { $$ = get_parm_info (0); }
2551 | ELLIPSIS
2552 { $$ = get_parm_info (0);
2553 /* Gcc used to allow this as an extension. However, it does
2554 not work for all targets, and thus has been disabled.
2555 Also, since func (...) and func () are indistinguishable,
2556 it caused problems with the code in expand_builtin which
2557 tries to verify that BUILT_IN_NEXT_ARG is being used
2558 correctly. */
2559 error ("ISO C requires a named argument before `...'");
2560 }
2561 | parms
2562 { $$ = get_parm_info (1);
2563 parsing_iso_function_signature = true;
2564 }
2565 | parms ',' ELLIPSIS
2566 { $$ = get_parm_info (0); }
2567 ;
2568
2569 parms:
2570 firstparm
2571 { push_parm_decl ($1); }
2572 | parms ',' parm
2573 { push_parm_decl ($3); }
2574 ;
2575
2576 /* A single parameter declaration or parameter type name,
2577 as found in a parmlist. */
2578 parm:
2579 declspecs_ts setspecs parm_declarator maybe_attribute
2580 { $$ = build_tree_list (build_tree_list (current_declspecs,
2581 $3),
2582 chainon ($4, all_prefix_attributes));
2583 POP_DECLSPEC_STACK; }
2584 | declspecs_ts setspecs notype_declarator maybe_attribute
2585 { $$ = build_tree_list (build_tree_list (current_declspecs,
2586 $3),
2587 chainon ($4, all_prefix_attributes));
2588 POP_DECLSPEC_STACK; }
2589 | declspecs_ts setspecs absdcl_maybe_attribute
2590 { $$ = $3;
2591 POP_DECLSPEC_STACK; }
2592 | declspecs_nots setspecs notype_declarator maybe_attribute
2593 { $$ = build_tree_list (build_tree_list (current_declspecs,
2594 $3),
2595 chainon ($4, all_prefix_attributes));
2596 POP_DECLSPEC_STACK; }
2597
2598 | declspecs_nots setspecs absdcl_maybe_attribute
2599 { $$ = $3;
2600 POP_DECLSPEC_STACK; }
2601 ;
2602
2603 /* The first parm, which must suck attributes from off the top of the parser
2604 stack. */
2605 firstparm:
2606 declspecs_ts_nosa setspecs_fp parm_declarator maybe_attribute
2607 { $$ = build_tree_list (build_tree_list (current_declspecs,
2608 $3),
2609 chainon ($4, all_prefix_attributes));
2610 POP_DECLSPEC_STACK; }
2611 | declspecs_ts_nosa setspecs_fp notype_declarator maybe_attribute
2612 { $$ = build_tree_list (build_tree_list (current_declspecs,
2613 $3),
2614 chainon ($4, all_prefix_attributes));
2615 POP_DECLSPEC_STACK; }
2616 | declspecs_ts_nosa setspecs_fp absdcl_maybe_attribute
2617 { $$ = $3;
2618 POP_DECLSPEC_STACK; }
2619 | declspecs_nots_nosa setspecs_fp notype_declarator maybe_attribute
2620 { $$ = build_tree_list (build_tree_list (current_declspecs,
2621 $3),
2622 chainon ($4, all_prefix_attributes));
2623 POP_DECLSPEC_STACK; }
2624
2625 | declspecs_nots_nosa setspecs_fp absdcl_maybe_attribute
2626 { $$ = $3;
2627 POP_DECLSPEC_STACK; }
2628 ;
2629
2630 setspecs_fp:
2631 setspecs
2632 { prefix_attributes = chainon (prefix_attributes, $<ttype>-2);
2633 all_prefix_attributes = prefix_attributes; }
2634 ;
2635
2636 /* This is used in a function definition
2637 where either a parmlist or an identifier list is ok.
2638 Its value is a list of ..._TYPE nodes or a list of identifiers. */
2639 parmlist_or_identifiers:
2640 maybe_attribute
2641 { pushlevel (0);
2642 clear_parm_order ();
2643 declare_parm_level (1); }
2644 parmlist_or_identifiers_1
2645 { $$ = $3;
2646 parmlist_tags_warning ();
2647 poplevel (0, 0, 0); }
2648 ;
2649
2650 parmlist_or_identifiers_1:
2651 parmlist_1
2652 | identifiers ')'
2653 { tree t;
2654 for (t = $1; t; t = TREE_CHAIN (t))
2655 if (TREE_VALUE (t) == NULL_TREE)
2656 error ("`...' in old-style identifier list");
2657 $$ = tree_cons (NULL_TREE, NULL_TREE, $1);
2658
2659 /* Make sure we have a parmlist after attributes. */
2660 if ($<ttype>-1 != 0
2661 && (TREE_CODE ($$) != TREE_LIST
2662 || TREE_PURPOSE ($$) == 0
2663 || TREE_CODE (TREE_PURPOSE ($$)) != PARM_DECL))
2664 YYERROR1;
2665 }
2666 ;
2667
2668 /* A nonempty list of identifiers. */
2669 identifiers:
2670 IDENTIFIER
2671 { $$ = build_tree_list (NULL_TREE, $1); }
2672 | identifiers ',' IDENTIFIER
2673 { $$ = chainon ($1, build_tree_list (NULL_TREE, $3)); }
2674 ;
2675
2676 /* A nonempty list of identifiers, including typenames. */
2677 identifiers_or_typenames:
2678 identifier
2679 { $$ = build_tree_list (NULL_TREE, $1); }
2680 | identifiers_or_typenames ',' identifier
2681 { $$ = chainon ($1, build_tree_list (NULL_TREE, $3)); }
2682 ;
2683
2684 extension:
2685 EXTENSION
2686 { $$ = SAVE_EXT_FLAGS();
2687 pedantic = 0;
2688 warn_pointer_arith = 0;
2689 warn_traditional = 0;
2690 flag_iso = 0; }
2691 ;
2692 \f
2693 ifobjc
2694 /* Objective-C productions. */
2695
2696 objcdef:
2697 classdef
2698 | classdecl
2699 | aliasdecl
2700 | protocoldef
2701 | methoddef
2702 | END
2703 {
2704 if (objc_implementation_context)
2705 {
2706 finish_class (objc_implementation_context);
2707 objc_ivar_chain = NULL_TREE;
2708 objc_implementation_context = NULL_TREE;
2709 }
2710 else
2711 warning ("`@end' must appear in an implementation context");
2712 }
2713 ;
2714
2715 /* A nonempty list of identifiers. */
2716 identifier_list:
2717 identifier
2718 { $$ = build_tree_list (NULL_TREE, $1); }
2719 | identifier_list ',' identifier
2720 { $$ = chainon ($1, build_tree_list (NULL_TREE, $3)); }
2721 ;
2722
2723 classdecl:
2724 CLASS identifier_list ';'
2725 {
2726 objc_declare_class ($2);
2727 }
2728 ;
2729
2730 aliasdecl:
2731 ALIAS identifier identifier ';'
2732 {
2733 objc_declare_alias ($2, $3);
2734 }
2735 ;
2736
2737 classdef:
2738 INTERFACE identifier protocolrefs '{'
2739 {
2740 objc_interface_context = objc_ivar_context
2741 = start_class (CLASS_INTERFACE_TYPE, $2, NULL_TREE, $3);
2742 objc_public_flag = 0;
2743 }
2744 ivar_decl_list '}'
2745 {
2746 continue_class (objc_interface_context);
2747 }
2748 methodprotolist
2749 END
2750 {
2751 finish_class (objc_interface_context);
2752 objc_interface_context = NULL_TREE;
2753 }
2754
2755 | INTERFACE identifier protocolrefs
2756 {
2757 objc_interface_context
2758 = start_class (CLASS_INTERFACE_TYPE, $2, NULL_TREE, $3);
2759 continue_class (objc_interface_context);
2760 }
2761 methodprotolist
2762 END
2763 {
2764 finish_class (objc_interface_context);
2765 objc_interface_context = NULL_TREE;
2766 }
2767
2768 | INTERFACE identifier ':' identifier protocolrefs '{'
2769 {
2770 objc_interface_context = objc_ivar_context
2771 = start_class (CLASS_INTERFACE_TYPE, $2, $4, $5);
2772 objc_public_flag = 0;
2773 }
2774 ivar_decl_list '}'
2775 {
2776 continue_class (objc_interface_context);
2777 }
2778 methodprotolist
2779 END
2780 {
2781 finish_class (objc_interface_context);
2782 objc_interface_context = NULL_TREE;
2783 }
2784
2785 | INTERFACE identifier ':' identifier protocolrefs
2786 {
2787 objc_interface_context
2788 = start_class (CLASS_INTERFACE_TYPE, $2, $4, $5);
2789 continue_class (objc_interface_context);
2790 }
2791 methodprotolist
2792 END
2793 {
2794 finish_class (objc_interface_context);
2795 objc_interface_context = NULL_TREE;
2796 }
2797
2798 | IMPLEMENTATION identifier '{'
2799 {
2800 objc_implementation_context = objc_ivar_context
2801 = start_class (CLASS_IMPLEMENTATION_TYPE, $2, NULL_TREE, NULL_TREE);
2802 objc_public_flag = 0;
2803 }
2804 ivar_decl_list '}'
2805 {
2806 objc_ivar_chain
2807 = continue_class (objc_implementation_context);
2808 }
2809
2810 | IMPLEMENTATION identifier
2811 {
2812 objc_implementation_context
2813 = start_class (CLASS_IMPLEMENTATION_TYPE, $2, NULL_TREE, NULL_TREE);
2814 objc_ivar_chain
2815 = continue_class (objc_implementation_context);
2816 }
2817
2818 | IMPLEMENTATION identifier ':' identifier '{'
2819 {
2820 objc_implementation_context = objc_ivar_context
2821 = start_class (CLASS_IMPLEMENTATION_TYPE, $2, $4, NULL_TREE);
2822 objc_public_flag = 0;
2823 }
2824 ivar_decl_list '}'
2825 {
2826 objc_ivar_chain
2827 = continue_class (objc_implementation_context);
2828 }
2829
2830 | IMPLEMENTATION identifier ':' identifier
2831 {
2832 objc_implementation_context
2833 = start_class (CLASS_IMPLEMENTATION_TYPE, $2, $4, NULL_TREE);
2834 objc_ivar_chain
2835 = continue_class (objc_implementation_context);
2836 }
2837
2838 | INTERFACE identifier '(' identifier ')' protocolrefs
2839 {
2840 objc_interface_context
2841 = start_class (CATEGORY_INTERFACE_TYPE, $2, $4, $6);
2842 continue_class (objc_interface_context);
2843 }
2844 methodprotolist
2845 END
2846 {
2847 finish_class (objc_interface_context);
2848 objc_interface_context = NULL_TREE;
2849 }
2850
2851 | IMPLEMENTATION identifier '(' identifier ')'
2852 {
2853 objc_implementation_context
2854 = start_class (CATEGORY_IMPLEMENTATION_TYPE, $2, $4, NULL_TREE);
2855 objc_ivar_chain
2856 = continue_class (objc_implementation_context);
2857 }
2858 ;
2859
2860 protocoldef:
2861 PROTOCOL identifier protocolrefs
2862 {
2863 objc_pq_context = 1;
2864 objc_interface_context
2865 = start_protocol(PROTOCOL_INTERFACE_TYPE, $2, $3);
2866 }
2867 methodprotolist END
2868 {
2869 objc_pq_context = 0;
2870 finish_protocol(objc_interface_context);
2871 objc_interface_context = NULL_TREE;
2872 }
2873 /* The @protocol forward-declaration production introduces a
2874 reduce/reduce conflict on ';', which should be resolved in
2875 favor of the production 'identifier_list -> identifier'. */
2876 | PROTOCOL identifier_list ';'
2877 {
2878 objc_declare_protocols ($2);
2879 }
2880 ;
2881
2882 protocolrefs:
2883 /* empty */
2884 {
2885 $$ = NULL_TREE;
2886 }
2887 | non_empty_protocolrefs
2888 ;
2889
2890 non_empty_protocolrefs:
2891 ARITHCOMPARE identifier_list ARITHCOMPARE
2892 {
2893 if ($1 == LT_EXPR && $3 == GT_EXPR)
2894 $$ = $2;
2895 else
2896 YYERROR1;
2897 }
2898 ;
2899
2900 ivar_decl_list:
2901 ivar_decl_list visibility_spec ivar_decls
2902 | ivar_decls
2903 ;
2904
2905 visibility_spec:
2906 PRIVATE { objc_public_flag = 2; }
2907 | PROTECTED { objc_public_flag = 0; }
2908 | PUBLIC { objc_public_flag = 1; }
2909 ;
2910
2911 ivar_decls:
2912 /* empty */
2913 {
2914 $$ = NULL_TREE;
2915 }
2916 | ivar_decls ivar_decl ';'
2917 | ivar_decls ';'
2918 {
2919 if (pedantic)
2920 pedwarn ("extra semicolon in struct or union specified");
2921 }
2922 ;
2923
2924
2925 /* There is a shift-reduce conflict here, because `components' may
2926 start with a `typename'. It happens that shifting (the default resolution)
2927 does the right thing, because it treats the `typename' as part of
2928 a `typed_typespecs'.
2929
2930 It is possible that this same technique would allow the distinction
2931 between `notype_initdecls' and `initdecls' to be eliminated.
2932 But I am being cautious and not trying it. */
2933
2934 ivar_decl:
2935 declspecs_nosc_ts setspecs ivars
2936 { $$ = $3;
2937 POP_DECLSPEC_STACK; }
2938 | declspecs_nosc_nots setspecs ivars
2939 { $$ = $3;
2940 POP_DECLSPEC_STACK; }
2941 | error
2942 { $$ = NULL_TREE; }
2943 ;
2944
2945 ivars:
2946 /* empty */
2947 { $$ = NULL_TREE; }
2948 | ivar_declarator
2949 | ivars ',' maybe_resetattrs ivar_declarator
2950 ;
2951
2952 ivar_declarator:
2953 declarator
2954 {
2955 $$ = add_instance_variable (objc_ivar_context,
2956 objc_public_flag,
2957 $1, current_declspecs,
2958 NULL_TREE);
2959 }
2960 | declarator ':' expr_no_commas
2961 {
2962 $$ = add_instance_variable (objc_ivar_context,
2963 objc_public_flag,
2964 $1, current_declspecs, $3);
2965 }
2966 | ':' expr_no_commas
2967 {
2968 $$ = add_instance_variable (objc_ivar_context,
2969 objc_public_flag,
2970 NULL_TREE,
2971 current_declspecs, $2);
2972 }
2973 ;
2974
2975 methodtype:
2976 '+'
2977 { objc_inherit_code = CLASS_METHOD_DECL; }
2978 | '-'
2979 { objc_inherit_code = INSTANCE_METHOD_DECL; }
2980 ;
2981
2982 methoddef:
2983 methodtype
2984 {
2985 objc_pq_context = 1;
2986 if (!objc_implementation_context)
2987 fatal_error ("method definition not in class context");
2988 }
2989 methoddecl
2990 {
2991 objc_pq_context = 0;
2992 if (objc_inherit_code == CLASS_METHOD_DECL)
2993 add_class_method (objc_implementation_context, $3);
2994 else
2995 add_instance_method (objc_implementation_context, $3);
2996 start_method_def ($3);
2997 }
2998 optarglist
2999 {
3000 continue_method_def ();
3001 }
3002 compstmt_or_error
3003 {
3004 finish_method_def ();
3005 }
3006 ;
3007
3008 /* the reason for the strange actions in this rule
3009 is so that notype_initdecls when reached via datadef
3010 can find a valid list of type and sc specs in $0. */
3011
3012 methodprotolist:
3013 /* empty */
3014 | {$<ttype>$ = NULL_TREE; } methodprotolist2
3015 ;
3016
3017 methodprotolist2: /* eliminates a shift/reduce conflict */
3018 methodproto
3019 | datadef
3020 | methodprotolist2 methodproto
3021 | methodprotolist2 {$<ttype>$ = NULL_TREE; } datadef
3022 ;
3023
3024 semi_or_error:
3025 ';'
3026 | error
3027 ;
3028
3029 methodproto:
3030 methodtype
3031 {
3032 /* Remember protocol qualifiers in prototypes. */
3033 objc_pq_context = 1;
3034 }
3035 methoddecl
3036 {
3037 /* Forget protocol qualifiers here. */
3038 objc_pq_context = 0;
3039 if (objc_inherit_code == CLASS_METHOD_DECL)
3040 add_class_method (objc_interface_context, $3);
3041 else
3042 add_instance_method (objc_interface_context, $3);
3043 }
3044 semi_or_error
3045 ;
3046
3047 methoddecl:
3048 '(' typename ')' unaryselector
3049 {
3050 $$ = build_method_decl (objc_inherit_code, $2, $4, NULL_TREE);
3051 }
3052
3053 | unaryselector
3054 {
3055 $$ = build_method_decl (objc_inherit_code, NULL_TREE, $1, NULL_TREE);
3056 }
3057
3058 | '(' typename ')' keywordselector optparmlist
3059 {
3060 $$ = build_method_decl (objc_inherit_code, $2, $4, $5);
3061 }
3062
3063 | keywordselector optparmlist
3064 {
3065 $$ = build_method_decl (objc_inherit_code, NULL_TREE, $1, $2);
3066 }
3067 ;
3068
3069 /* "optarglist" assumes that start_method_def has already been called...
3070 if it is not, the "xdecls" will not be placed in the proper scope */
3071
3072 optarglist:
3073 /* empty */
3074 | ';' myxdecls
3075 ;
3076
3077 /* to get around the following situation: "int foo (int a) int b; {}" that
3078 is synthesized when parsing "- a:a b:b; id c; id d; { ... }" */
3079
3080 myxdecls:
3081 /* empty */
3082 | mydecls
3083 ;
3084
3085 mydecls:
3086 mydecl
3087 | errstmt
3088 | mydecls mydecl
3089 | mydecl errstmt
3090 ;
3091
3092 mydecl:
3093 declspecs_ts setspecs myparms ';'
3094 { POP_DECLSPEC_STACK; }
3095 | declspecs_ts ';'
3096 { shadow_tag ($1); }
3097 | declspecs_nots ';'
3098 { pedwarn ("empty declaration"); }
3099 ;
3100
3101 myparms:
3102 myparm
3103 { push_parm_decl ($1); }
3104 | myparms ',' myparm
3105 { push_parm_decl ($3); }
3106 ;
3107
3108 /* A single parameter declaration or parameter type name,
3109 as found in a parmlist. DOES NOT ALLOW AN INITIALIZER OR ASMSPEC */
3110
3111 myparm:
3112 parm_declarator maybe_attribute
3113 { $$ = build_tree_list (build_tree_list (current_declspecs,
3114 $1),
3115 chainon ($2, all_prefix_attributes)); }
3116 | notype_declarator maybe_attribute
3117 { $$ = build_tree_list (build_tree_list (current_declspecs,
3118 $1),
3119 chainon ($2, all_prefix_attributes)); }
3120 | absdcl_maybe_attribute
3121 { $$ = $1; }
3122 ;
3123
3124 optparmlist:
3125 /* empty */
3126 {
3127 $$ = NULL_TREE;
3128 }
3129 | ',' ELLIPSIS
3130 {
3131 /* oh what a kludge! */
3132 $$ = objc_ellipsis_node;
3133 }
3134 | ','
3135 {
3136 pushlevel (0);
3137 }
3138 parmlist_2
3139 {
3140 /* returns a tree list node generated by get_parm_info */
3141 $$ = $3;
3142 poplevel (0, 0, 0);
3143 }
3144 ;
3145
3146 unaryselector:
3147 selector
3148 ;
3149
3150 keywordselector:
3151 keyworddecl
3152
3153 | keywordselector keyworddecl
3154 {
3155 $$ = chainon ($1, $2);
3156 }
3157 ;
3158
3159 selector:
3160 IDENTIFIER
3161 | TYPENAME
3162 | CLASSNAME
3163 | OBJECTNAME
3164 | reservedwords
3165 ;
3166
3167 reservedwords:
3168 ENUM | STRUCT | UNION | IF | ELSE | WHILE | DO | FOR
3169 | SWITCH | CASE | DEFAULT | BREAK | CONTINUE | RETURN
3170 | GOTO | ASM_KEYWORD | SIZEOF | TYPEOF | ALIGNOF
3171 | TYPESPEC | TYPE_QUAL
3172 ;
3173
3174 keyworddecl:
3175 selector ':' '(' typename ')' identifier
3176 {
3177 $$ = build_keyword_decl ($1, $4, $6);
3178 }
3179
3180 | selector ':' identifier
3181 {
3182 $$ = build_keyword_decl ($1, NULL_TREE, $3);
3183 }
3184
3185 | ':' '(' typename ')' identifier
3186 {
3187 $$ = build_keyword_decl (NULL_TREE, $3, $5);
3188 }
3189
3190 | ':' identifier
3191 {
3192 $$ = build_keyword_decl (NULL_TREE, NULL_TREE, $2);
3193 }
3194 ;
3195
3196 messageargs:
3197 selector
3198 | keywordarglist
3199 ;
3200
3201 keywordarglist:
3202 keywordarg
3203 | keywordarglist keywordarg
3204 {
3205 $$ = chainon ($1, $2);
3206 }
3207 ;
3208
3209
3210 keywordexpr:
3211 nonnull_exprlist
3212 {
3213 if (TREE_CHAIN ($1) == NULL_TREE)
3214 /* just return the expr., remove a level of indirection */
3215 $$ = TREE_VALUE ($1);
3216 else
3217 /* we have a comma expr., we will collapse later */
3218 $$ = $1;
3219 }
3220 ;
3221
3222 keywordarg:
3223 selector ':' keywordexpr
3224 {
3225 $$ = build_tree_list ($1, $3);
3226 }
3227 | ':' keywordexpr
3228 {
3229 $$ = build_tree_list (NULL_TREE, $2);
3230 }
3231 ;
3232
3233 receiver:
3234 expr
3235 | CLASSNAME
3236 {
3237 $$ = get_class_reference ($1);
3238 }
3239 ;
3240
3241 objcmessageexpr:
3242 '[' receiver messageargs ']'
3243 { $$ = build_tree_list ($2, $3); }
3244 ;
3245
3246 selectorarg:
3247 selector
3248 | keywordnamelist
3249 ;
3250
3251 keywordnamelist:
3252 keywordname
3253 | keywordnamelist keywordname
3254 {
3255 $$ = chainon ($1, $2);
3256 }
3257 ;
3258
3259 keywordname:
3260 selector ':'
3261 {
3262 $$ = build_tree_list ($1, NULL_TREE);
3263 }
3264 | ':'
3265 {
3266 $$ = build_tree_list (NULL_TREE, NULL_TREE);
3267 }
3268 ;
3269
3270 objcselectorexpr:
3271 SELECTOR '(' selectorarg ')'
3272 {
3273 $$ = $3;
3274 }
3275 ;
3276
3277 objcprotocolexpr:
3278 PROTOCOL '(' identifier ')'
3279 {
3280 $$ = $3;
3281 }
3282 ;
3283
3284 /* extension to support C-structures in the archiver */
3285
3286 objcencodeexpr:
3287 ENCODE '(' typename ')'
3288 {
3289 $$ = groktypename ($3);
3290 }
3291 ;
3292
3293 end ifobjc
3294 %%
3295
3296 /* yylex() is a thin wrapper around c_lex(), all it does is translate
3297 cpplib.h's token codes into yacc's token codes. */
3298
3299 static enum cpp_ttype last_token;
3300
3301 /* The reserved keyword table. */
3302 struct resword
3303 {
3304 const char *word;
3305 ENUM_BITFIELD(rid) rid : 16;
3306 unsigned int disable : 16;
3307 };
3308
3309 /* Disable mask. Keywords are disabled if (reswords[i].disable & mask) is
3310 _true_. */
3311 #define D_C89 0x01 /* not in C89 */
3312 #define D_EXT 0x02 /* GCC extension */
3313 #define D_EXT89 0x04 /* GCC extension incorporated in C99 */
3314 #define D_OBJC 0x08 /* Objective C only */
3315
3316 static const struct resword reswords[] =
3317 {
3318 { "_Bool", RID_BOOL, 0 },
3319 { "_Complex", RID_COMPLEX, 0 },
3320 { "__FUNCTION__", RID_FUNCTION_NAME, 0 },
3321 { "__PRETTY_FUNCTION__", RID_PRETTY_FUNCTION_NAME, 0 },
3322 { "__alignof", RID_ALIGNOF, 0 },
3323 { "__alignof__", RID_ALIGNOF, 0 },
3324 { "__asm", RID_ASM, 0 },
3325 { "__asm__", RID_ASM, 0 },
3326 { "__attribute", RID_ATTRIBUTE, 0 },
3327 { "__attribute__", RID_ATTRIBUTE, 0 },
3328 { "__bounded", RID_BOUNDED, 0 },
3329 { "__bounded__", RID_BOUNDED, 0 },
3330 { "__builtin_choose_expr", RID_CHOOSE_EXPR, 0 },
3331 { "__builtin_types_compatible_p", RID_TYPES_COMPATIBLE_P, 0 },
3332 { "__builtin_va_arg", RID_VA_ARG, 0 },
3333 { "__complex", RID_COMPLEX, 0 },
3334 { "__complex__", RID_COMPLEX, 0 },
3335 { "__const", RID_CONST, 0 },
3336 { "__const__", RID_CONST, 0 },
3337 { "__extension__", RID_EXTENSION, 0 },
3338 { "__func__", RID_C99_FUNCTION_NAME, 0 },
3339 { "__imag", RID_IMAGPART, 0 },
3340 { "__imag__", RID_IMAGPART, 0 },
3341 { "__inline", RID_INLINE, 0 },
3342 { "__inline__", RID_INLINE, 0 },
3343 { "__label__", RID_LABEL, 0 },
3344 { "__ptrbase", RID_PTRBASE, 0 },
3345 { "__ptrbase__", RID_PTRBASE, 0 },
3346 { "__ptrextent", RID_PTREXTENT, 0 },
3347 { "__ptrextent__", RID_PTREXTENT, 0 },
3348 { "__ptrvalue", RID_PTRVALUE, 0 },
3349 { "__ptrvalue__", RID_PTRVALUE, 0 },
3350 { "__real", RID_REALPART, 0 },
3351 { "__real__", RID_REALPART, 0 },
3352 { "__restrict", RID_RESTRICT, 0 },
3353 { "__restrict__", RID_RESTRICT, 0 },
3354 { "__signed", RID_SIGNED, 0 },
3355 { "__signed__", RID_SIGNED, 0 },
3356 { "__thread", RID_THREAD, 0 },
3357 { "__typeof", RID_TYPEOF, 0 },
3358 { "__typeof__", RID_TYPEOF, 0 },
3359 { "__unbounded", RID_UNBOUNDED, 0 },
3360 { "__unbounded__", RID_UNBOUNDED, 0 },
3361 { "__volatile", RID_VOLATILE, 0 },
3362 { "__volatile__", RID_VOLATILE, 0 },
3363 { "asm", RID_ASM, D_EXT },
3364 { "auto", RID_AUTO, 0 },
3365 { "break", RID_BREAK, 0 },
3366 { "case", RID_CASE, 0 },
3367 { "char", RID_CHAR, 0 },
3368 { "const", RID_CONST, 0 },
3369 { "continue", RID_CONTINUE, 0 },
3370 { "default", RID_DEFAULT, 0 },
3371 { "do", RID_DO, 0 },
3372 { "double", RID_DOUBLE, 0 },
3373 { "else", RID_ELSE, 0 },
3374 { "enum", RID_ENUM, 0 },
3375 { "extern", RID_EXTERN, 0 },
3376 { "float", RID_FLOAT, 0 },
3377 { "for", RID_FOR, 0 },
3378 { "goto", RID_GOTO, 0 },
3379 { "if", RID_IF, 0 },
3380 { "inline", RID_INLINE, D_EXT89 },
3381 { "int", RID_INT, 0 },
3382 { "long", RID_LONG, 0 },
3383 { "register", RID_REGISTER, 0 },
3384 { "restrict", RID_RESTRICT, D_C89 },
3385 { "return", RID_RETURN, 0 },
3386 { "short", RID_SHORT, 0 },
3387 { "signed", RID_SIGNED, 0 },
3388 { "sizeof", RID_SIZEOF, 0 },
3389 { "static", RID_STATIC, 0 },
3390 { "struct", RID_STRUCT, 0 },
3391 { "switch", RID_SWITCH, 0 },
3392 { "typedef", RID_TYPEDEF, 0 },
3393 { "typeof", RID_TYPEOF, D_EXT },
3394 { "union", RID_UNION, 0 },
3395 { "unsigned", RID_UNSIGNED, 0 },
3396 { "void", RID_VOID, 0 },
3397 { "volatile", RID_VOLATILE, 0 },
3398 { "while", RID_WHILE, 0 },
3399 ifobjc
3400 { "id", RID_ID, D_OBJC },
3401
3402 /* These objc keywords are recognized only immediately after
3403 an '@'. */
3404 { "class", RID_AT_CLASS, D_OBJC },
3405 { "compatibility_alias", RID_AT_ALIAS, D_OBJC },
3406 { "defs", RID_AT_DEFS, D_OBJC },
3407 { "encode", RID_AT_ENCODE, D_OBJC },
3408 { "end", RID_AT_END, D_OBJC },
3409 { "implementation", RID_AT_IMPLEMENTATION, D_OBJC },
3410 { "interface", RID_AT_INTERFACE, D_OBJC },
3411 { "private", RID_AT_PRIVATE, D_OBJC },
3412 { "protected", RID_AT_PROTECTED, D_OBJC },
3413 { "protocol", RID_AT_PROTOCOL, D_OBJC },
3414 { "public", RID_AT_PUBLIC, D_OBJC },
3415 { "selector", RID_AT_SELECTOR, D_OBJC },
3416
3417 /* These are recognized only in protocol-qualifier context
3418 (see above) */
3419 { "bycopy", RID_BYCOPY, D_OBJC },
3420 { "byref", RID_BYREF, D_OBJC },
3421 { "in", RID_IN, D_OBJC },
3422 { "inout", RID_INOUT, D_OBJC },
3423 { "oneway", RID_ONEWAY, D_OBJC },
3424 { "out", RID_OUT, D_OBJC },
3425 end ifobjc
3426 };
3427 #define N_reswords (sizeof reswords / sizeof (struct resword))
3428
3429 /* Table mapping from RID_* constants to yacc token numbers.
3430 Unfortunately we have to have entries for all the keywords in all
3431 three languages. */
3432 static const short rid_to_yy[RID_MAX] =
3433 {
3434 /* RID_STATIC */ STATIC,
3435 /* RID_UNSIGNED */ TYPESPEC,
3436 /* RID_LONG */ TYPESPEC,
3437 /* RID_CONST */ TYPE_QUAL,
3438 /* RID_EXTERN */ SCSPEC,
3439 /* RID_REGISTER */ SCSPEC,
3440 /* RID_TYPEDEF */ SCSPEC,
3441 /* RID_SHORT */ TYPESPEC,
3442 /* RID_INLINE */ SCSPEC,
3443 /* RID_VOLATILE */ TYPE_QUAL,
3444 /* RID_SIGNED */ TYPESPEC,
3445 /* RID_AUTO */ SCSPEC,
3446 /* RID_RESTRICT */ TYPE_QUAL,
3447
3448 /* C extensions */
3449 /* RID_BOUNDED */ TYPE_QUAL,
3450 /* RID_UNBOUNDED */ TYPE_QUAL,
3451 /* RID_COMPLEX */ TYPESPEC,
3452 /* RID_THREAD */ SCSPEC,
3453
3454 /* C++ */
3455 /* RID_FRIEND */ 0,
3456 /* RID_VIRTUAL */ 0,
3457 /* RID_EXPLICIT */ 0,
3458 /* RID_EXPORT */ 0,
3459 /* RID_MUTABLE */ 0,
3460
3461 /* ObjC */
3462 /* RID_IN */ TYPE_QUAL,
3463 /* RID_OUT */ TYPE_QUAL,
3464 /* RID_INOUT */ TYPE_QUAL,
3465 /* RID_BYCOPY */ TYPE_QUAL,
3466 /* RID_BYREF */ TYPE_QUAL,
3467 /* RID_ONEWAY */ TYPE_QUAL,
3468
3469 /* C */
3470 /* RID_INT */ TYPESPEC,
3471 /* RID_CHAR */ TYPESPEC,
3472 /* RID_FLOAT */ TYPESPEC,
3473 /* RID_DOUBLE */ TYPESPEC,
3474 /* RID_VOID */ TYPESPEC,
3475 /* RID_ENUM */ ENUM,
3476 /* RID_STRUCT */ STRUCT,
3477 /* RID_UNION */ UNION,
3478 /* RID_IF */ IF,
3479 /* RID_ELSE */ ELSE,
3480 /* RID_WHILE */ WHILE,
3481 /* RID_DO */ DO,
3482 /* RID_FOR */ FOR,
3483 /* RID_SWITCH */ SWITCH,
3484 /* RID_CASE */ CASE,
3485 /* RID_DEFAULT */ DEFAULT,
3486 /* RID_BREAK */ BREAK,
3487 /* RID_CONTINUE */ CONTINUE,
3488 /* RID_RETURN */ RETURN,
3489 /* RID_GOTO */ GOTO,
3490 /* RID_SIZEOF */ SIZEOF,
3491
3492 /* C extensions */
3493 /* RID_ASM */ ASM_KEYWORD,
3494 /* RID_TYPEOF */ TYPEOF,
3495 /* RID_ALIGNOF */ ALIGNOF,
3496 /* RID_ATTRIBUTE */ ATTRIBUTE,
3497 /* RID_VA_ARG */ VA_ARG,
3498 /* RID_EXTENSION */ EXTENSION,
3499 /* RID_IMAGPART */ IMAGPART,
3500 /* RID_REALPART */ REALPART,
3501 /* RID_LABEL */ LABEL,
3502 /* RID_PTRBASE */ PTR_BASE,
3503 /* RID_PTREXTENT */ PTR_EXTENT,
3504 /* RID_PTRVALUE */ PTR_VALUE,
3505
3506 /* RID_CHOOSE_EXPR */ CHOOSE_EXPR,
3507 /* RID_TYPES_COMPATIBLE_P */ TYPES_COMPATIBLE_P,
3508
3509 /* RID_FUNCTION_NAME */ STRING_FUNC_NAME,
3510 /* RID_PRETTY_FUNCTION_NAME */ STRING_FUNC_NAME,
3511 /* RID_C99_FUNCTION_NAME */ VAR_FUNC_NAME,
3512
3513 /* C++ */
3514 /* RID_BOOL */ TYPESPEC,
3515 /* RID_WCHAR */ 0,
3516 /* RID_CLASS */ 0,
3517 /* RID_PUBLIC */ 0,
3518 /* RID_PRIVATE */ 0,
3519 /* RID_PROTECTED */ 0,
3520 /* RID_TEMPLATE */ 0,
3521 /* RID_NULL */ 0,
3522 /* RID_CATCH */ 0,
3523 /* RID_DELETE */ 0,
3524 /* RID_FALSE */ 0,
3525 /* RID_NAMESPACE */ 0,
3526 /* RID_NEW */ 0,
3527 /* RID_OPERATOR */ 0,
3528 /* RID_THIS */ 0,
3529 /* RID_THROW */ 0,
3530 /* RID_TRUE */ 0,
3531 /* RID_TRY */ 0,
3532 /* RID_TYPENAME */ 0,
3533 /* RID_TYPEID */ 0,
3534 /* RID_USING */ 0,
3535
3536 /* casts */
3537 /* RID_CONSTCAST */ 0,
3538 /* RID_DYNCAST */ 0,
3539 /* RID_REINTCAST */ 0,
3540 /* RID_STATCAST */ 0,
3541
3542 /* Objective C */
3543 /* RID_ID */ OBJECTNAME,
3544 /* RID_AT_ENCODE */ ENCODE,
3545 /* RID_AT_END */ END,
3546 /* RID_AT_CLASS */ CLASS,
3547 /* RID_AT_ALIAS */ ALIAS,
3548 /* RID_AT_DEFS */ DEFS,
3549 /* RID_AT_PRIVATE */ PRIVATE,
3550 /* RID_AT_PROTECTED */ PROTECTED,
3551 /* RID_AT_PUBLIC */ PUBLIC,
3552 /* RID_AT_PROTOCOL */ PROTOCOL,
3553 /* RID_AT_SELECTOR */ SELECTOR,
3554 /* RID_AT_INTERFACE */ INTERFACE,
3555 /* RID_AT_IMPLEMENTATION */ IMPLEMENTATION
3556 };
3557
3558 static void
3559 init_reswords ()
3560 {
3561 unsigned int i;
3562 tree id;
3563 int mask = (flag_isoc99 ? 0 : D_C89)
3564 | (flag_no_asm ? (flag_isoc99 ? D_EXT : D_EXT|D_EXT89) : 0);
3565
3566 if (!flag_objc)
3567 mask |= D_OBJC;
3568
3569 ridpointers = (tree *) ggc_calloc ((int) RID_MAX, sizeof (tree));
3570 for (i = 0; i < N_reswords; i++)
3571 {
3572 /* If a keyword is disabled, do not enter it into the table
3573 and so create a canonical spelling that isn't a keyword. */
3574 if (reswords[i].disable & mask)
3575 continue;
3576
3577 id = get_identifier (reswords[i].word);
3578 C_RID_CODE (id) = reswords[i].rid;
3579 C_IS_RESERVED_WORD (id) = 1;
3580 ridpointers [(int) reswords[i].rid] = id;
3581 }
3582 }
3583
3584 #define NAME(type) cpp_type2name (type)
3585
3586 static void
3587 yyerror (msgid)
3588 const char *msgid;
3589 {
3590 const char *string = _(msgid);
3591
3592 if (last_token == CPP_EOF)
3593 error ("%s at end of input", string);
3594 else if (last_token == CPP_CHAR || last_token == CPP_WCHAR)
3595 {
3596 unsigned int val = TREE_INT_CST_LOW (yylval.ttype);
3597 const char *const ell = (last_token == CPP_CHAR) ? "" : "L";
3598 if (val <= UCHAR_MAX && ISGRAPH (val))
3599 error ("%s before %s'%c'", string, ell, val);
3600 else
3601 error ("%s before %s'\\x%x'", string, ell, val);
3602 }
3603 else if (last_token == CPP_STRING
3604 || last_token == CPP_WSTRING)
3605 error ("%s before string constant", string);
3606 else if (last_token == CPP_NUMBER)
3607 error ("%s before numeric constant", string);
3608 else if (last_token == CPP_NAME)
3609 error ("%s before \"%s\"", string, IDENTIFIER_POINTER (yylval.ttype));
3610 else
3611 error ("%s before '%s' token", string, NAME(last_token));
3612 }
3613
3614 static int
3615 yylexname ()
3616 {
3617 tree decl;
3618
3619 ifobjc
3620 int objc_force_identifier = objc_need_raw_identifier;
3621 OBJC_NEED_RAW_IDENTIFIER (0);
3622 end ifobjc
3623
3624 if (C_IS_RESERVED_WORD (yylval.ttype))
3625 {
3626 enum rid rid_code = C_RID_CODE (yylval.ttype);
3627
3628 ifobjc
3629 /* Turn non-typedefed refs to "id" into plain identifiers; this
3630 allows constructs like "void foo(id id);" to work. */
3631 if (rid_code == RID_ID)
3632 {
3633 decl = lookup_name (yylval.ttype);
3634 if (decl == NULL_TREE || TREE_CODE (decl) != TYPE_DECL)
3635 return IDENTIFIER;
3636 }
3637
3638 if (!OBJC_IS_AT_KEYWORD (rid_code)
3639 && (!OBJC_IS_PQ_KEYWORD (rid_code) || objc_pq_context))
3640 end ifobjc
3641 {
3642 int yycode = rid_to_yy[(int) rid_code];
3643 if (yycode == STRING_FUNC_NAME)
3644 {
3645 /* __FUNCTION__ and __PRETTY_FUNCTION__ get converted
3646 to string constants. */
3647 const char *name = fname_string (rid_code);
3648
3649 yylval.ttype = build_string (strlen (name) + 1, name);
3650 C_ARTIFICIAL_STRING_P (yylval.ttype) = 1;
3651 last_token = CPP_STRING; /* so yyerror won't choke */
3652 return STRING;
3653 }
3654
3655 /* Return the canonical spelling for this keyword. */
3656 yylval.ttype = ridpointers[(int) rid_code];
3657 return yycode;
3658 }
3659 }
3660
3661 decl = lookup_name (yylval.ttype);
3662 if (decl)
3663 {
3664 if (TREE_CODE (decl) == TYPE_DECL)
3665 return TYPENAME;
3666 }
3667 ifobjc
3668 else
3669 {
3670 tree objc_interface_decl = is_class_name (yylval.ttype);
3671 /* ObjC class names are in the same namespace as variables and
3672 typedefs, and hence are shadowed by local declarations. */
3673 if (objc_interface_decl
3674 && (global_bindings_p ()
3675 || (!objc_force_identifier && !decl)))
3676 {
3677 yylval.ttype = objc_interface_decl;
3678 return CLASSNAME;
3679 }
3680 }
3681 end ifobjc
3682
3683 return IDENTIFIER;
3684 }
3685
3686 /* Concatenate strings before returning them to the parser. This isn't quite
3687 as good as having it done in the lexer, but it's better than nothing. */
3688
3689 static int
3690 yylexstring ()
3691 {
3692 enum cpp_ttype next_type;
3693 tree orig = yylval.ttype;
3694
3695 next_type = c_lex (&yylval.ttype);
3696 if (next_type == CPP_STRING
3697 || next_type == CPP_WSTRING
3698 || (next_type == CPP_NAME && yylexname () == STRING))
3699 {
3700 varray_type strings;
3701
3702 ifc
3703 static int last_lineno = 0;
3704 static const char *last_input_filename = 0;
3705 if (warn_traditional && !in_system_header
3706 && (input_line != last_lineno || !last_input_filename ||
3707 strcmp (last_input_filename, input_filename)))
3708 {
3709 warning ("traditional C rejects string concatenation");
3710 last_lineno = input_line;
3711 last_input_filename = input_filename;
3712 }
3713 end ifc
3714
3715 VARRAY_TREE_INIT (strings, 32, "strings");
3716 VARRAY_PUSH_TREE (strings, orig);
3717
3718 do
3719 {
3720 VARRAY_PUSH_TREE (strings, yylval.ttype);
3721 next_type = c_lex (&yylval.ttype);
3722 }
3723 while (next_type == CPP_STRING
3724 || next_type == CPP_WSTRING
3725 || (next_type == CPP_NAME && yylexname () == STRING));
3726
3727 yylval.ttype = combine_strings (strings);
3728 }
3729 else
3730 yylval.ttype = orig;
3731
3732 /* We will have always read one token too many. */
3733 _cpp_backup_tokens (parse_in, 1);
3734
3735 return STRING;
3736 }
3737
3738 static inline int
3739 _yylex ()
3740 {
3741 get_next:
3742 last_token = c_lex (&yylval.ttype);
3743 switch (last_token)
3744 {
3745 case CPP_EQ: return '=';
3746 case CPP_NOT: return '!';
3747 case CPP_GREATER: yylval.code = GT_EXPR; return ARITHCOMPARE;
3748 case CPP_LESS: yylval.code = LT_EXPR; return ARITHCOMPARE;
3749 case CPP_PLUS: yylval.code = PLUS_EXPR; return '+';
3750 case CPP_MINUS: yylval.code = MINUS_EXPR; return '-';
3751 case CPP_MULT: yylval.code = MULT_EXPR; return '*';
3752 case CPP_DIV: yylval.code = TRUNC_DIV_EXPR; return '/';
3753 case CPP_MOD: yylval.code = TRUNC_MOD_EXPR; return '%';
3754 case CPP_AND: yylval.code = BIT_AND_EXPR; return '&';
3755 case CPP_OR: yylval.code = BIT_IOR_EXPR; return '|';
3756 case CPP_XOR: yylval.code = BIT_XOR_EXPR; return '^';
3757 case CPP_RSHIFT: yylval.code = RSHIFT_EXPR; return RSHIFT;
3758 case CPP_LSHIFT: yylval.code = LSHIFT_EXPR; return LSHIFT;
3759
3760 case CPP_COMPL: return '~';
3761 case CPP_AND_AND: return ANDAND;
3762 case CPP_OR_OR: return OROR;
3763 case CPP_QUERY: return '?';
3764 case CPP_OPEN_PAREN: return '(';
3765 case CPP_EQ_EQ: yylval.code = EQ_EXPR; return EQCOMPARE;
3766 case CPP_NOT_EQ: yylval.code = NE_EXPR; return EQCOMPARE;
3767 case CPP_GREATER_EQ:yylval.code = GE_EXPR; return ARITHCOMPARE;
3768 case CPP_LESS_EQ: yylval.code = LE_EXPR; return ARITHCOMPARE;
3769
3770 case CPP_PLUS_EQ: yylval.code = PLUS_EXPR; return ASSIGN;
3771 case CPP_MINUS_EQ: yylval.code = MINUS_EXPR; return ASSIGN;
3772 case CPP_MULT_EQ: yylval.code = MULT_EXPR; return ASSIGN;
3773 case CPP_DIV_EQ: yylval.code = TRUNC_DIV_EXPR; return ASSIGN;
3774 case CPP_MOD_EQ: yylval.code = TRUNC_MOD_EXPR; return ASSIGN;
3775 case CPP_AND_EQ: yylval.code = BIT_AND_EXPR; return ASSIGN;
3776 case CPP_OR_EQ: yylval.code = BIT_IOR_EXPR; return ASSIGN;
3777 case CPP_XOR_EQ: yylval.code = BIT_XOR_EXPR; return ASSIGN;
3778 case CPP_RSHIFT_EQ: yylval.code = RSHIFT_EXPR; return ASSIGN;
3779 case CPP_LSHIFT_EQ: yylval.code = LSHIFT_EXPR; return ASSIGN;
3780
3781 case CPP_OPEN_SQUARE: return '[';
3782 case CPP_CLOSE_SQUARE: return ']';
3783 case CPP_OPEN_BRACE: return '{';
3784 case CPP_CLOSE_BRACE: return '}';
3785 case CPP_ELLIPSIS: return ELLIPSIS;
3786
3787 case CPP_PLUS_PLUS: return PLUSPLUS;
3788 case CPP_MINUS_MINUS: return MINUSMINUS;
3789 case CPP_DEREF: return POINTSAT;
3790 case CPP_DOT: return '.';
3791
3792 /* The following tokens may affect the interpretation of any
3793 identifiers following, if doing Objective-C. */
3794 case CPP_COLON: OBJC_NEED_RAW_IDENTIFIER (0); return ':';
3795 case CPP_COMMA: OBJC_NEED_RAW_IDENTIFIER (0); return ',';
3796 case CPP_CLOSE_PAREN: OBJC_NEED_RAW_IDENTIFIER (0); return ')';
3797 case CPP_SEMICOLON: OBJC_NEED_RAW_IDENTIFIER (0); return ';';
3798
3799 case CPP_EOF:
3800 return 0;
3801
3802 case CPP_NAME:
3803 {
3804 int ret = yylexname ();
3805 if (ret == STRING)
3806 return yylexstring ();
3807 else
3808 return ret;
3809 }
3810
3811 case CPP_NUMBER:
3812 case CPP_CHAR:
3813 case CPP_WCHAR:
3814 return CONSTANT;
3815
3816 case CPP_STRING:
3817 case CPP_WSTRING:
3818 return yylexstring ();
3819
3820 /* This token is Objective-C specific. It gives the next token
3821 special significance. */
3822 case CPP_ATSIGN:
3823 ifobjc
3824 {
3825 tree after_at;
3826 enum cpp_ttype after_at_type;
3827
3828 after_at_type = c_lex (&after_at);
3829
3830 if (after_at_type == CPP_NAME
3831 && C_IS_RESERVED_WORD (after_at)
3832 && OBJC_IS_AT_KEYWORD (C_RID_CODE (after_at)))
3833 {
3834 yylval.ttype = after_at;
3835 last_token = after_at_type;
3836 return rid_to_yy [(int) C_RID_CODE (after_at)];
3837 }
3838 _cpp_backup_tokens (parse_in, 1);
3839 return '@';
3840 }
3841 end ifobjc
3842
3843 /* These tokens are C++ specific (and will not be generated
3844 in C mode, but let's be cautious). */
3845 case CPP_SCOPE:
3846 case CPP_DEREF_STAR:
3847 case CPP_DOT_STAR:
3848 case CPP_MIN_EQ:
3849 case CPP_MAX_EQ:
3850 case CPP_MIN:
3851 case CPP_MAX:
3852 /* These tokens should not survive translation phase 4. */
3853 case CPP_HASH:
3854 case CPP_PASTE:
3855 error ("syntax error at '%s' token", NAME(last_token));
3856 goto get_next;
3857
3858 default:
3859 abort ();
3860 }
3861 /* NOTREACHED */
3862 }
3863
3864 static int
3865 yylex()
3866 {
3867 int r;
3868 timevar_push (TV_LEX);
3869 r = _yylex();
3870 timevar_pop (TV_LEX);
3871 return r;
3872 }
3873
3874 /* Function used when yydebug is set, to print a token in more detail. */
3875
3876 static void
3877 yyprint (file, yychar, yyl)
3878 FILE *file;
3879 int yychar;
3880 YYSTYPE yyl;
3881 {
3882 tree t = yyl.ttype;
3883
3884 fprintf (file, " [%s]", NAME(last_token));
3885
3886 switch (yychar)
3887 {
3888 case IDENTIFIER:
3889 case TYPENAME:
3890 case OBJECTNAME:
3891 case TYPESPEC:
3892 case TYPE_QUAL:
3893 case SCSPEC:
3894 case STATIC:
3895 if (IDENTIFIER_POINTER (t))
3896 fprintf (file, " `%s'", IDENTIFIER_POINTER (t));
3897 break;
3898
3899 case CONSTANT:
3900 fprintf (file, " %s", GET_MODE_NAME (TYPE_MODE (TREE_TYPE (t))));
3901 if (TREE_CODE (t) == INTEGER_CST)
3902 {
3903 fputs (" ", file);
3904 fprintf (file, HOST_WIDE_INT_PRINT_DOUBLE_HEX,
3905 TREE_INT_CST_HIGH (t), TREE_INT_CST_LOW (t));
3906 }
3907 break;
3908 }
3909 }
3910 \f
3911 /* This is not the ideal place to put these, but we have to get them out
3912 of c-lex.c because cp/lex.c has its own versions. */
3913
3914 /* Free malloced parser stacks if necessary. */
3915
3916 void
3917 free_parser_stacks ()
3918 {
3919 if (malloced_yyss)
3920 {
3921 free (malloced_yyss);
3922 free (malloced_yyvs);
3923 }
3924 }
3925
3926 #include "gt-c-parse.h"