gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007
   5 # Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 2, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING.  If not, write to the Free
  21 #Software Foundation, 51 Franklin Street, Fifth Floor, Boston, MA
  22 #02110-1301, USA.
  23
  24 # --------------------------------
  25 # Initialization and sanity checks
  26 # --------------------------------
  27
  28 AC_PREREQ(2.59)
  29 AC_INIT
  30 AC_CONFIG_SRCDIR(tree.c)
  31 AC_CONFIG_HEADER(auto-host.h:config.in)
  32
  33 gcc_version=`cat $srcdir/BASE-VER`
  34
  35 # Determine the host, build, and target systems
  36 AC_CANONICAL_BUILD
  37 AC_CANONICAL_HOST
  38 AC_CANONICAL_TARGET
  39
  40 # Determine the noncanonical target name, for directory use.
  41 ACX_NONCANONICAL_TARGET
  42
  43 # Determine the target- and build-specific subdirectories
  44 GCC_TOPLEV_SUBDIRS
  45
  46 # Set program_transform_name
  47 AC_ARG_PROGRAM
  48
  49 # Check for bogus environment variables.
  50 # Test if LIBRARY_PATH contains the notation for the current directory
  51 # since this would lead to problems installing/building glibc.
  52 # LIBRARY_PATH contains the current directory if one of the following
  53 # is true:
  54 # - one of the terminals (":" and ";") is the first or last sign
  55 # - two terminals occur directly after each other
  56 # - the path contains an element with a dot in it
  57 AC_MSG_CHECKING(LIBRARY_PATH variable)
  58 changequote(,)dnl
  59 case ${LIBRARY_PATH} in
  60   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  61     library_path_setting="contains current directory"
  62     ;;
  63   *)
  64     library_path_setting="ok"
  65     ;;
  66 esac
  67 changequote([,])dnl
  68 AC_MSG_RESULT($library_path_setting)
  69 if test "$library_path_setting" != "ok"; then
  70 AC_MSG_ERROR([
  71 *** LIBRARY_PATH shouldn't contain the current directory when
  72 *** building gcc. Please change the environment variable
  73 *** and run configure again.])
  74 fi
  75
  76 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  77 # since this would lead to problems installing/building glibc.
  78 # GCC_EXEC_PREFIX contains the current directory if one of the following
  79 # is true:
  80 # - one of the terminals (":" and ";") is the first or last sign
  81 # - two terminals occur directly after each other
  82 # - the path contains an element with a dot in it
  83 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  84 changequote(,)dnl
  85 case ${GCC_EXEC_PREFIX} in
  86   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  87     gcc_exec_prefix_setting="contains current directory"
  88     ;;
  89   *)
  90     gcc_exec_prefix_setting="ok"
  91     ;;
  92 esac
  93 changequote([,])dnl
  94 AC_MSG_RESULT($gcc_exec_prefix_setting)
  95 if test "$gcc_exec_prefix_setting" != "ok"; then
  96 AC_MSG_ERROR([
  97 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  98 *** building gcc. Please change the environment variable
  99 *** and run configure again.])
 100 fi
 101
 102 # -----------
 103 # Directories
 104 # -----------
 105
 106 # Specify the local prefix
 107 local_prefix=
 108 AC_ARG_WITH(local-prefix,
 109 [  --with-local-prefix=DIR specifies directory to put local include],
 110 [case "${withval}" in
 111 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 112 no)     ;;
 113 *)      local_prefix=$with_local_prefix ;;
 114 esac])
 115
 116 # Default local prefix if it is empty
 117 if test x$local_prefix = x; then
 118         local_prefix=/usr/local
 119 fi
 120
 121 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 122 # passed in by the toplevel make and thus we'd get different behavior
 123 # depending on where we built the sources.
 124 gcc_gxx_include_dir=
 125 # Specify the g++ header file directory
 126 AC_ARG_WITH(gxx-include-dir,
 127 [  --with-gxx-include-dir=DIR
 128                           specifies directory to put g++ header files],
 129 [case "${withval}" in
 130 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 131 no)     ;;
 132 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 133 esac])
 134
 135 # This logic must match libstdc++-v3/acinclude.m4:GLIBCXX_EXPORT_INSTALL_INFO.
 136 if test x${gcc_gxx_include_dir} = x; then
 137   if test x${enable_version_specific_runtime_libs} = xyes; then
 138     gcc_gxx_include_dir='${libsubdir}/include/c++'
 139   else
 140     libstdcxx_incdir='include/c++/$(version)'
 141     if test x$host != x$target; then
 142        libstdcxx_incdir="$target_alias/$libstdcxx_incdir"
 143     fi
 144 changequote(<<, >>)dnl
 145     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/$libstdcxx_incdir"
 146 changequote([, ])dnl
 147   fi
 148 fi
 149
 150 AC_ARG_WITH(cpp_install_dir,
 151 [  --with-cpp-install-dir=DIR
 152                           install the user visible C preprocessor in DIR
 153                           (relative to PREFIX) as well as PREFIX/bin],
 154 [if test x$withval = xyes; then
 155   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 156 elif test x$withval != xno; then
 157   cpp_install_dir=$withval
 158 fi])
 159
 160 # We would like to our source tree to be readonly.  However when releases or
 161 # pre-releases are generated, the flex/bison generated files as well as the
 162 # various formats of manuals need to be included along with the rest of the
 163 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 164 # just that.
 165
 166 AC_MSG_CHECKING([whether to place generated files in the source directory])
 167   dnl generated-files-in-srcdir is disabled by default
 168   AC_ARG_ENABLE(generated-files-in-srcdir,
 169 [  --enable-generated-files-in-srcdir
 170                           put copies of generated files in source dir
 171                           intended for creating source tarballs for users
 172                           without texinfo bison or flex.],
 173       generated_files_in_srcdir=$enableval,
 174       generated_files_in_srcdir=no)
 175
 176 AC_MSG_RESULT($generated_files_in_srcdir)
 177
 178 if test "$generated_files_in_srcdir" = "yes"; then
 179   GENINSRC=''
 180 else
 181   GENINSRC='#'
 182 fi
 183 AC_SUBST(GENINSRC)
 184
 185 # -------------------
 186 # Find default linker
 187 # -------------------
 188
 189 # With GNU ld
 190 AC_ARG_WITH(gnu-ld,
 191 [  --with-gnu-ld           arrange to work with GNU ld.],
 192 gnu_ld_flag="$with_gnu_ld",
 193 gnu_ld_flag=no)
 194
 195 # With pre-defined ld
 196 AC_ARG_WITH(ld,
 197 [  --with-ld               arrange to use the specified ld (full pathname)],
 198 DEFAULT_LINKER="$with_ld")
 199 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 200   if test ! -x "$DEFAULT_LINKER"; then
 201     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 202   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 203     gnu_ld_flag=yes
 204   fi
 205   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 206         [Define to enable the use of a default linker.])
 207 fi
 208
 209 AC_MSG_CHECKING([whether a default linker was specified])
 210 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 211   if test x"$gnu_ld_flag" = x"no"; then
 212     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 213   else
 214     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 215   fi
 216 else
 217   AC_MSG_RESULT(no)
 218 fi
 219
 220 # With demangler in GNU ld
 221 AC_ARG_WITH(demangler-in-ld,
 222 [  --with-demangler-in-ld  try to use demangler in GNU ld.],
 223 demangler_in_ld="$with_demangler_in_ld",
 224 demangler_in_ld=no)
 225
 226 # ----------------------
 227 # Find default assembler
 228 # ----------------------
 229
 230 # With GNU as
 231 AC_ARG_WITH(gnu-as,
 232 [  --with-gnu-as           arrange to work with GNU as],
 233 gas_flag="$with_gnu_as",
 234 gas_flag=no)
 235
 236 AC_ARG_WITH(as,
 237 [  --with-as               arrange to use the specified as (full pathname)],
 238 DEFAULT_ASSEMBLER="$with_as")
 239 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 240   if test ! -x "$DEFAULT_ASSEMBLER"; then
 241     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 242   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 243     gas_flag=yes
 244   fi
 245   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 246         [Define to enable the use of a default assembler.])
 247 fi
 248
 249 AC_MSG_CHECKING([whether a default assembler was specified])
 250 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 251   if test x"$gas_flag" = x"no"; then
 252     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 253   else
 254     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 255   fi
 256 else
 257   AC_MSG_RESULT(no)
 258 fi
 259
 260 # ---------------
 261 # Find C compiler
 262 # ---------------
 263
 264 # If a non-executable a.out is present (e.g. created by GNU as above even if
 265 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 266 # file, even when creating an executable, so an execution test fails.
 267 # Remove possible default executable files to avoid this.
 268 #
 269 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 270 # Autoconf includes it.
 271 rm -f a.out a.exe b.out
 272
 273 # Find the native compiler
 274 AC_PROG_CC
 275 AM_PROG_CC_C_O
 276 # autoconf is lame and doesn't give us any substitution variable for this.
 277 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 278   NO_MINUS_C_MINUS_O=yes
 279 else
 280   OUTPUT_OPTION='-o $@'
 281 fi
 282 AC_SUBST(NO_MINUS_C_MINUS_O)
 283 AC_SUBST(OUTPUT_OPTION)
 284
 285 # Remove the -O2: for historical reasons, unless bootstrapping we prefer
 286 # optimizations to be activated explicitly by the toplevel.
 287 case "$CC" in
 288   */prev-gcc/xgcc*) ;;
 289   *) CFLAGS=`echo $CFLAGS | sed "s/-O[[s0-9]]* *//" ` ;;
 290 esac
 291 AC_SUBST(CFLAGS)
 292
 293 # -------------------------
 294 # Check C compiler features
 295 # -------------------------
 296
 297 AC_PROG_CPP
 298 AC_C_INLINE
 299
 300 # sizeof(char) is 1 by definition.
 301 AC_CHECK_SIZEOF(void *)
 302 AC_CHECK_SIZEOF(short)
 303 AC_CHECK_SIZEOF(int)
 304 AC_CHECK_SIZEOF(long)
 305 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
 306 AC_CHECK_TYPES([__int64], [AC_CHECK_SIZEOF(__int64)])
 307
 308 # ---------------------
 309 # Warnings and checking
 310 # ---------------------
 311
 312 # Check $CC warning features (if it's GCC).
 313 # We want to use -pedantic, but we don't want warnings about
 314 # * 'long long'
 315 # * variadic macros
 316 # * overlong strings
 317 # So, we only use -pedantic if we can disable those warnings.
 318
 319 AC_CACHE_CHECK(
 320   [whether ${CC} accepts -Wno-long-long],
 321   [ac_cv_prog_cc_w_no_long_long],
 322   [save_CFLAGS="$CFLAGS"
 323   CFLAGS="-Wno-long-long"
 324   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 325                     [ac_cv_prog_cc_w_no_long_long=yes],
 326                     [ac_cv_prog_cc_w_no_long_long=no])
 327   CFLAGS="$save_CFLAGS"
 328   ])
 329
 330 AC_CACHE_CHECK(
 331   [whether ${CC} accepts -Wno-variadic-macros],
 332   [ac_cv_prog_cc_w_no_variadic_macros],
 333   [save_CFLAGS="$CFLAGS"
 334   CFLAGS="-Wno-variadic-macros"
 335   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 336                     [ac_cv_prog_cc_w_no_variadic_macros=yes],
 337                     [ac_cv_prog_cc_w_no_variadic_macros=no])
 338   CFLAGS="$save_CFLAGS"
 339   ])
 340
 341 AC_CACHE_CHECK(
 342   [whether ${CC} accepts -Wno-overlength-strings],
 343   [ac_cv_prog_cc_w_no_overlength_strings],
 344   [save_CFLAGS="$CFLAGS"
 345   CFLAGS="-Wno-overlength-strings"
 346   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 347                     [ac_cv_prog_cc_w_no_overlength_strings=yes],
 348                     [ac_cv_prog_cc_w_no_overlength_strings=no])
 349   CFLAGS="$save_CFLAGS"
 350   ])
 351
 352 strict_warn=
 353 if test $ac_cv_prog_cc_w_no_long_long = yes \
 354    && test $ac_cv_prog_cc_w_no_variadic_macros = yes \
 355    && test $ac_cv_prog_cc_w_no_overlength_strings = yes ; then
 356   strict_warn="-pedantic -Wno-long-long -Wno-variadic-macros -Wno-overlength-strings"
 357 fi
 358
 359 # Add -Wold-style-definition if it's accepted
 360 AC_CACHE_CHECK(
 361   [whether ${CC} accepts -Wold-style-definition],
 362   [ac_cv_prog_cc_w_old_style_definition],
 363   [save_CFLAGS="$CFLAGS"
 364   CFLAGS="-Wold-style-definition"
 365   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 366                     [ac_cv_prog_cc_w_old_style_definition=yes],
 367                     [ac_cv_prog_cc_w_old_style_definition=no])
 368   CFLAGS="$save_CFLAGS"
 369   ])
 370 if test $ac_cv_prog_cc_w_old_style_definition = yes ; then
 371   strict_warn="${strict_warn} -Wold-style-definition"
 372 fi
 373
 374 # Add -Wmissing-format-attribute if it's accepted
 375 AC_CACHE_CHECK(
 376   [whether ${CC} accepts -Wmissing-format-attribute],
 377   [ac_cv_prog_cc_w_missing_format_attribute],
 378   [save_CFLAGS="$CFLAGS"
 379   CFLAGS="-Wmissing-format-attribute"
 380   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 381                     [ac_cv_prog_cc_w_missing_format_attribute=yes],
 382                     [ac_cv_prog_cc_w_missing_format_attribute=no])
 383   CFLAGS="$save_CFLAGS"
 384   ])
 385 if test $ac_cv_prog_cc_w_missing_format_attribute = yes ; then
 386   strict_warn="${strict_warn} -Wmissing-format-attribute"
 387 fi
 388
 389 # Enable -Werror, period.
 390 AC_ARG_ENABLE(werror_always,
 391 [  --enable-werror-always         enable -Werror always], [],
 392 [enable_werror_always=no])
 393 if test x${enable_werror_always} = xyes ; then
 394   strict_warn="${strict_warn} -Werror"
 395 fi
 396 AC_SUBST(strict_warn)
 397
 398 # Get C++ compatibility warning flag, if supported.
 399 AC_CACHE_CHECK(
 400   [whether ${CC} accepts -Wc++-compat],
 401   [ac_cv_prog_cc_w_cxx_compat],
 402   [save_CFLAGS="$CFLAGS"
 403   CFLAGS="-Wc++-compat"
 404   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 405                     [ac_cv_prog_cc_w_cxx_compat=yes],
 406                     [ac_cv_prog_cc_w_cxx_compat=no])
 407   CFLAGS="$save_CFLAGS"
 408   ])
 409 if test x${ac_cv_prog_cc_w_cxx_compat} = xyes; then
 410   cxx_compat_warn="-Wc++-compat"
 411 fi
 412 AC_SUBST(cxx_compat_warn)
 413
 414
 415 # If the native compiler is GCC, we can enable warnings even in stage1.
 416 # That's useful for people building cross-compilers, or just running a
 417 # quick `make'.
 418 warn_cflags=
 419 if test "x$GCC" = "xyes"; then
 420   warn_cflags='$(GCC_WARN_CFLAGS)'
 421 fi
 422 AC_SUBST(warn_cflags)
 423
 424 # Enable expensive internal checks
 425 is_release=
 426 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
 427   is_release=yes
 428 fi
 429
 430 AC_ARG_ENABLE(checking,
 431 [  --enable-checking[=LIST]
 432                           enable expensive run-time checks.  With LIST,
 433                           enable only specific categories of checks.
 434                           Categories are: yes,no,all,none,release.
 435                           Flags are: assert,fold,gc,gcac,misc,
 436                           rtlflag,rtl,runtime,tree,valgrind.],
 437 [ac_checking_flags="${enableval}"],[
 438 # Determine the default checks.
 439 if test x$is_release = x ; then
 440   ac_checking_flags=yes
 441 else
 442   ac_checking_flags=release
 443 fi])
 444 ac_assert_checking=1
 445 ac_checking=
 446 ac_fold_checking=
 447 ac_gc_checking=
 448 ac_gc_always_collect=
 449 ac_rtl_checking=
 450 ac_rtlflag_checking=
 451 ac_runtime_checking=1
 452 ac_tree_checking=
 453 ac_valgrind_checking=
 454 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 455 for check in $ac_checking_flags
 456 do
 457         case $check in
 458         # these set all the flags to specific states
 459         yes)            ac_assert_checking=1 ; ac_checking=1 ;
 460                         ac_fold_checking= ; ac_gc_checking=1 ;
 461                         ac_gc_always_collect= ; ac_rtl_checking= ;
 462                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 463                         ac_tree_checking=1 ; ac_valgrind_checking= ;;
 464         no|none)        ac_assert_checking= ; ac_checking= ;
 465                         ac_fold_checking= ; ac_gc_checking= ;
 466                         ac_gc_always_collect= ; ac_rtl_checking= ;
 467                         ac_rtlflag_checking= ; ac_runtime_checking= ;
 468                         ac_tree_checking= ; ac_valgrind_checking= ;;
 469         all)            ac_assert_checking=1 ; ac_checking=1 ;
 470                         ac_fold_checking=1 ; ac_gc_checking=1 ;
 471                         ac_gc_always_collect=1 ; ac_rtl_checking=1 ;
 472                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 473                         ac_tree_checking=1 ; ac_valgrind_checking= ;;
 474         release)        ac_assert_checking=1 ; ac_checking= ;
 475                         ac_fold_checking= ; ac_gc_checking= ;
 476                         ac_gc_always_collect= ; ac_rtl_checking= ;
 477                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
 478                         ac_tree_checking= ; ac_valgrind_checking= ;;
 479         # these enable particular checks
 480         assert)         ac_assert_checking=1 ;;
 481         fold)           ac_fold_checking=1 ;;
 482         gc)             ac_gc_checking=1 ;;
 483         gcac)           ac_gc_always_collect=1 ;;
 484         misc)           ac_checking=1 ;;
 485         rtl)            ac_rtl_checking=1 ;;
 486         rtlflag)        ac_rtlflag_checking=1 ;;
 487         runtime)        ac_runtime_checking=1 ;;
 488         tree)           ac_tree_checking=1 ;;
 489         valgrind)       ac_valgrind_checking=1 ;;
 490         *)      AC_MSG_ERROR(unknown check category $check) ;;
 491         esac
 492 done
 493 IFS="$ac_save_IFS"
 494
 495 nocommon_flag=""
 496 if test x$ac_checking != x ; then
 497   AC_DEFINE(ENABLE_CHECKING, 1,
 498 [Define if you want more run-time sanity checks.  This one gets a grab
 499    bag of miscellaneous but relatively cheap checks.])
 500   nocommon_flag=-fno-common
 501 fi
 502 AC_SUBST(nocommon_flag)
 503 if test x$ac_assert_checking != x ; then
 504   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 505 [Define if you want assertions enabled.  This is a cheap check.])
 506 fi
 507 GCC_TARGET_TEMPLATE(ENABLE_RUNTIME_CHECKING)
 508 if test x$ac_runtime_checking != x ; then
 509   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
 510 [Define if you want runtime assertions enabled.  This is a cheap check.])
 511 fi
 512 if test x$ac_tree_checking != x ; then
 513   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 514 [Define if you want all operations on trees (the basic data
 515    structure of the front ends) to be checked for dynamic type safety
 516    at runtime.  This is moderately expensive.  The tree browser debugging
 517    routines will also be enabled by this option.
 518    ])
 519   TREEBROWSER=tree-browser.o
 520 fi
 521 AC_SUBST(TREEBROWSER)
 522 if test x$ac_rtl_checking != x ; then
 523   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 524 [Define if you want all operations on RTL (the basic data structure
 525    of the optimizer and back end) to be checked for dynamic type safety
 526    at runtime.  This is quite expensive.])
 527 fi
 528 if test x$ac_rtlflag_checking != x ; then
 529   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 530 [Define if you want RTL flag accesses to be checked against the RTL
 531    codes that are supported for each access macro.  This is relatively
 532    cheap.])
 533 fi
 534 if test x$ac_gc_checking != x ; then
 535   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 536 [Define if you want the garbage collector to do object poisoning and
 537    other memory allocation checks.  This is quite expensive.])
 538 fi
 539 if test x$ac_gc_always_collect != x ; then
 540   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 541 [Define if you want the garbage collector to operate in maximally
 542    paranoid mode, validating the entire heap and collecting garbage at
 543    every opportunity.  This is extremely expensive.])
 544 fi
 545 if test x$ac_fold_checking != x ; then
 546   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 547 [Define if you want fold checked that it never destructs its argument.
 548    This is quite expensive.])
 549 fi
 550 valgrind_path_defines=
 551 valgrind_command=
 552
 553 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 554 dnl # an if statement.  This was the source of very frustrating bugs
 555 dnl # in converting to autoconf 2.5x!
 556 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 557
 558 if test x$ac_valgrind_checking != x ; then
 559   # It is certainly possible that there's valgrind but no valgrind.h.
 560   # GCC relies on making annotations so we must have both.
 561   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 562   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 563     [[#include <valgrind/memcheck.h>
 564 #ifndef VALGRIND_DISCARD
 565 #error VALGRIND_DISCARD not defined
 566 #endif]])],
 567   [gcc_cv_header_valgrind_memcheck_h=yes],
 568   [gcc_cv_header_valgrind_memcheck_h=no])
 569   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 570   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 571   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 572     [[#include <memcheck.h>
 573 #ifndef VALGRIND_DISCARD
 574 #error VALGRIND_DISCARD not defined
 575 #endif]])],
 576   [gcc_cv_header_memcheck_h=yes],
 577   [gcc_cv_header_memcheck_h=no])
 578   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 579   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 580         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 581   if test "x$valgrind_path" = "x" \
 582     || (test $have_valgrind_h = no \
 583         && test $gcc_cv_header_memcheck_h = no \
 584         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 585         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 586   fi
 587   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 588   valgrind_command="$valgrind_path -q"
 589   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 590 [Define if you want to run subprograms and generated programs
 591    through valgrind (a memory checker).  This is extremely expensive.])
 592   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 593     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 594         [Define if valgrind's valgrind/memcheck.h header is installed.])
 595   fi
 596   if test $gcc_cv_header_memcheck_h = yes; then
 597     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 598         [Define if valgrind's memcheck.h header is installed.])
 599   fi
 600 fi
 601 AC_SUBST(valgrind_path_defines)
 602 AC_SUBST(valgrind_command)
 603
 604 AC_ARG_ENABLE(mapped-location,
 605 [  --enable-mapped-location   location_t is fileline integer cookie],,
 606 enable_mapped_location=no)
 607
 608 if test "$enable_mapped_location" = yes ; then
 609   AC_DEFINE(USE_MAPPED_LOCATION, 1,
 610 [Define if location_t is fileline integer cookie.])
 611 fi
 612
 613 # Enable code coverage collection
 614 AC_ARG_ENABLE(coverage,
 615 [  --enable-coverage[=LEVEL]
 616                           enable compiler's code coverage collection.
 617                           Use to measure compiler performance and locate
 618                           unused parts of the compiler. With LEVEL, specify
 619                           optimization. Values are opt, noopt,
 620                           default is noopt],
 621 [case "${enableval}" in
 622   yes|noopt)
 623     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 624     ;;
 625   opt)
 626     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 627     ;;
 628   no)
 629     # a.k.a. --disable-coverage
 630     coverage_flags=""
 631     ;;
 632   *)
 633     AC_MSG_ERROR(unknown coverage setting $enableval)
 634     ;;
 635 esac],
 636 [coverage_flags=""])
 637 AC_SUBST(coverage_flags)
 638
 639 AC_ARG_ENABLE(gather-detailed-mem-stats,
 640 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
 641 [enable_gather_detailed_mem_stats=no])
 642 if test x$enable_gather_detailed_mem_stats = xyes ; then
 643   AC_DEFINE(GATHER_STATISTICS, 1,
 644         [Define to enable detailed memory allocation stats gathering.])
 645 fi
 646
 647 # -------------------------------
 648 # Miscenalleous configure options
 649 # -------------------------------
 650
 651 # With stabs
 652 AC_ARG_WITH(stabs,
 653 [  --with-stabs            arrange to use stabs instead of host debug format],
 654 stabs="$with_stabs",
 655 stabs=no)
 656
 657 # Determine whether or not multilibs are enabled.
 658 AC_ARG_ENABLE(multilib,
 659 [  --enable-multilib       enable library support for multiple ABIs],
 660 [], [enable_multilib=yes])
 661 AC_SUBST(enable_multilib)
 662
 663 # Enable __cxa_atexit for C++.
 664 AC_ARG_ENABLE(__cxa_atexit,
 665 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 666 [], [])
 667
 668 # Enable C extension for decimal float if target supports it.
 669 AC_ARG_ENABLE(decimal-float,
 670 [  --enable-decimal-float  enable decimal float extension to C],
 671 [
 672   if test x$enablevar = xyes ; then
 673     case $target in
 674     powerpc*-*-linux* | i?86*-*-linux*)
 675       enable_decimal_float=yes
 676       ;;
 677     *)
 678       AC_MSG_WARN(decimal float is not supported for this target, ignored)
 679       enable_decimal_float=no
 680       ;;
 681     esac
 682   fi
 683 ], [enable_decimal_float=no])
 684
 685 AC_SUBST(enable_decimal_float)
 686
 687 dfp=`if test $enable_decimal_float = yes; then echo 1; else echo 0; fi`
 688 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_FLOAT, $dfp,
 689 [Define to 1 to enable decimal float extension to C.])
 690
 691 # Enable threads
 692 # Pass with no value to take the default
 693 # Pass with a value to specify a thread package
 694 AC_ARG_ENABLE(threads,
 695 [  --enable-threads        enable thread usage for target GCC
 696   --enable-threads=LIB    use LIB thread package for target GCC],,
 697 [enable_threads=''])
 698
 699 AC_ARG_ENABLE(tls,
 700 [  --enable-tls            enable or disable generation of tls code
 701                           overriding the assembler check for tls support],
 702 [
 703   case $enable_tls in
 704     yes | no) ;;
 705     *) AC_MSG_ERROR(['$enable_tls' is an invalid value for --enable-tls.
 706 Valid choices are 'yes' and 'no'.]) ;;
 707   esac
 708 ], [enable_tls=''])
 709
 710 AC_ARG_ENABLE(objc-gc,
 711 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 712                           the GNU Objective-C runtime],
 713 if test x$enable_objc_gc = xno; then
 714         objc_boehm_gc=''
 715 else
 716         objc_boehm_gc=1
 717 fi,
 718 objc_boehm_gc='')
 719
 720 AC_ARG_WITH(dwarf2,
 721 [  --with-dwarf2           force the default debug format to be DWARF 2],
 722 dwarf2="$with_dwarf2",
 723 dwarf2=no)
 724
 725 AC_ARG_ENABLE(shared,
 726 [  --disable-shared        don't provide a shared libgcc],
 727 [
 728   case $enable_shared in
 729   yes | no) ;;
 730   *)
 731     enable_shared=no
 732     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 733     for pkg in $enableval; do
 734       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 735         enable_shared=yes
 736       fi
 737     done
 738     IFS="$ac_save_ifs"
 739     ;;
 740   esac
 741 ], [enable_shared=yes])
 742 AC_SUBST(enable_shared)
 743
 744 AC_ARG_WITH(build-sysroot,
 745   [  --with-build-sysroot=sysroot
 746                           use sysroot as the system root during the build])
 747
 748 AC_ARG_WITH(sysroot,
 749 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 750 [
 751  case ${with_sysroot} in
 752  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 753  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 754  esac
 755
 756  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 757  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
 758
 759  if test "x$exec_prefix" = xNONE; then
 760   if test "x$prefix" = xNONE; then
 761    test_prefix=/usr/local
 762   else
 763    test_prefix=$prefix
 764   fi
 765  else
 766   test_prefix=$exec_prefix
 767  fi
 768  case ${TARGET_SYSTEM_ROOT} in
 769  "${test_prefix}"|"${test_prefix}/"*|\
 770  '${exec_prefix}'|'${exec_prefix}/'*)
 771    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 772    TARGET_SYSTEM_ROOT_DEFINE="$t"
 773    ;;
 774  esac
 775 ], [
 776  TARGET_SYSTEM_ROOT=
 777  TARGET_SYSTEM_ROOT_DEFINE=
 778  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 779 ])
 780 AC_SUBST(TARGET_SYSTEM_ROOT)
 781 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 782 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 783
 784 # Build with intermodule optimisations
 785 AC_ARG_ENABLE(intermodule,
 786 [  --enable-intermodule    build the compiler in one step],
 787 [case ${enable_intermodule} in
 788   yes) onestep="-onestep";;
 789   *) onestep="";;
 790 esac],
 791 [onestep=""])
 792 AC_SUBST(onestep)
 793
 794 # Sanity check enable_languages in case someone does not run the toplevel
 795 # configure # script.
 796 AC_ARG_ENABLE(languages,
 797 [  --enable-languages=LIST specify which front-ends to build],
 798 [case ,${enable_languages}, in
 799        ,,|,yes,)
 800                 # go safe -- we cannot be much sure without the toplevel
 801                 # configure's
 802                 # analysis of which target libs are present and usable
 803                 enable_languages=c
 804                 ;;
 805          *,all,*)
 806                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 807                 ;;
 808         *,c,*)
 809                 ;;
 810         *)
 811                 enable_languages=c,${enable_languages}
 812                 ;;
 813 esac],
 814 [enable_languages=c])
 815
 816 # Used by documentation targets
 817 AC_SUBST(datarootdir)
 818 AC_SUBST(docdir)
 819 AC_SUBST(htmldir)
 820
 821 # -------------------------
 822 # Checks for other programs
 823 # -------------------------
 824
 825 AC_PROG_MAKE_SET
 826
 827 # Find some useful tools
 828 AC_PROG_AWK
 829 # We need awk to create options.c and options.h.
 830 # Bail out if it's missing.
 831 case ${AWK} in
 832   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 833 esac
 834
 835 gcc_AC_PROG_LN_S
 836 ACX_PROG_LN($LN_S)
 837 AC_PROG_RANLIB
 838 case "${host}" in
 839 *-*-darwin*)
 840   # By default, the Darwin ranlib will not treat common symbols as
 841   # definitions when  building the archive table of contents.  Other
 842   # ranlibs do that; pass an option to the Darwin ranlib that makes
 843   # it behave similarly.
 844   ranlib_flags="-c"
 845   ;;
 846 *)
 847   ranlib_flags=""
 848 esac
 849 AC_SUBST(ranlib_flags)
 850
 851 gcc_AC_PROG_INSTALL
 852
 853 # See if cmp has --ignore-initial.
 854 gcc_AC_PROG_CMP_IGNORE_INITIAL
 855
 856 # See if we have the mktemp command.
 857 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 858
 859 MISSING="${CONFIG_SHELL-/bin/sh} $srcdir/../missing"
 860
 861 # See if makeinfo has been installed and is modern enough
 862 # that we can use it.
 863 gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 864   [GNU texinfo.* \([0-9][0-9.]*\)],
 865   [4.[4-9]*])
 866 if test $gcc_cv_prog_makeinfo_modern = no; then
 867   MAKEINFO="$MISSING makeinfo"
 868   AC_MSG_WARN([
 869 *** Makeinfo is missing or too old.
 870 *** Info documentation will not be built.])
 871   BUILD_INFO=
 872 else
 873   BUILD_INFO=info
 874 fi
 875 AC_SUBST(BUILD_INFO)
 876
 877 # Is pod2man recent enough to regenerate manpages?
 878 AC_MSG_CHECKING([for recent Pod::Man])
 879 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 880   AC_MSG_RESULT(yes)
 881   GENERATED_MANPAGES=generated-manpages
 882 else
 883   AC_MSG_RESULT(no)
 884   GENERATED_MANPAGES=
 885 fi
 886 AC_SUBST(GENERATED_MANPAGES)
 887
 888 # How about lex?
 889 dnl Don't use AC_PROG_LEX; we insist on flex.
 890 dnl LEXLIB is not useful in gcc.
 891 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
 892
 893 # Bison?
 894 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
 895
 896 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
 897 # check for build == host before using them.
 898
 899 # NM
 900 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
 901   && test -d ../binutils ; then
 902   NM='$(objdir)/../binutils/nm-new'
 903 else
 904   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
 905 fi
 906
 907 # AR
 908 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
 909   && test -d ../binutils ; then
 910   AR='$(objdir)/../binutils/ar'
 911 else
 912   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
 913 fi
 914
 915
 916 # --------------------
 917 # Checks for C headers
 918 # --------------------
 919
 920 AC_MSG_CHECKING(for GNU C library)
 921 AC_CACHE_VAL(gcc_cv_glibc,
 922 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 923   [[#include <features.h>]], [[
 924 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 925 #error Not a GNU C library system
 926 #endif]])],
 927   [gcc_cv_glibc=yes],
 928   [gcc_cv_glibc=no])])
 929 AC_MSG_RESULT($gcc_cv_glibc)
 930 if test $gcc_cv_glibc = yes; then
 931   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 932 fi
 933
 934 # Need to reject headers which give warnings, so that the -Werror bootstrap
 935 # works later. *sigh*  This needs to come before all header checks.
 936 AC_PROG_CPP_WERROR
 937
 938 AC_HEADER_STDC
 939 AC_HEADER_TIME
 940 ACX_HEADER_STRING
 941 AC_HEADER_SYS_WAIT
 942 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
 943                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 944                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 945                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 946
 947 # Check for thread headers.
 948 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 949 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 950
 951 # These tests can't be done till we know if we have limits.h.
 952 gcc_AC_C_CHAR_BIT
 953 AC_C_BIGENDIAN
 954
 955 # --------
 956 # UNSORTED
 957 # --------
 958
 959
 960 # These libraries may be used by collect2.
 961 # We may need a special search path to get them linked.
 962 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 963 [save_LIBS="$LIBS"
 964 for libs in '' -lld -lmld \
 965                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 966                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 967 do
 968         LIBS="$libs"
 969         AC_TRY_LINK_FUNC(ldopen,
 970                 [gcc_cv_collect2_libs="$libs"; break])
 971 done
 972 LIBS="$save_LIBS"
 973 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 974 case $gcc_cv_collect2_libs in
 975         "none required")        ;;
 976         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 977 esac
 978 AC_SUBST(COLLECT2_LIBS)
 979
 980 # When building Ada code on Alpha, we need exc_resume which is usually in
 981 # -lexc.  So test for it.
 982 save_LIBS="$LIBS"
 983 LIBS=
 984 AC_SEARCH_LIBS(exc_resume, exc)
 985 GNAT_LIBEXC="$LIBS"
 986 LIBS="$save_LIBS"
 987 AC_SUBST(GNAT_LIBEXC)
 988
 989 # Some systems put ldexp and frexp in libm instead of libc; assume
 990 # they're both in the same place.  jcf-dump needs them.
 991 save_LIBS="$LIBS"
 992 LIBS=
 993 AC_SEARCH_LIBS(ldexp, m)
 994 LDEXP_LIB="$LIBS"
 995 LIBS="$save_LIBS"
 996 AC_SUBST(LDEXP_LIB)
 997
 998 # Use <inttypes.h> only if it exists,
 999 # doesn't clash with <sys/types.h>, and declares intmax_t.
1000 AC_MSG_CHECKING(for inttypes.h)
1001 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
1002 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1003 [[#include <sys/types.h>
1004 #include <inttypes.h>]],
1005   [[intmax_t i = -1;]])],
1006   [gcc_cv_header_inttypes_h=yes],
1007   [gcc_cv_header_inttypes_h=no])])
1008 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
1009 if test $gcc_cv_header_inttypes_h = yes; then
1010   AC_DEFINE(HAVE_INTTYPES_H, 1,
1011         [Define if you have a working <inttypes.h> header file.])
1012 fi
1013
1014 dnl Disabled until we have a complete test for buggy enum bitfields.
1015 dnl gcc_AC_C_ENUM_BF_UNSIGNED
1016
1017 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
1018   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
1019   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
1020   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
1021   putchar_unlocked putc_unlocked)
1022 AC_CHECK_FUNCS(times clock kill getrlimit setrlimit atoll atoq \
1023         sysconf strsignal getrusage nl_langinfo scandir alphasort \
1024         gettimeofday mbstowcs wcswidth mmap mincore setlocale \
1025         gcc_UNLOCKED_FUNCS)
1026
1027 if test x$ac_cv_func_mbstowcs = xyes; then
1028   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
1029 [    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1030 int main()
1031 {
1032   mbstowcs(0, "", 0);
1033   return 0;
1034 }]])],
1035     [gcc_cv_func_mbstowcs_works=yes],
1036     [gcc_cv_func_mbstowcs_works=no],
1037     [gcc_cv_func_mbstowcs_works=yes])])
1038   if test x$gcc_cv_func_mbstowcs_works = xyes; then
1039     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
1040   [Define this macro if mbstowcs does not crash when its
1041    first argument is NULL.])
1042   fi
1043 fi
1044
1045 AC_CHECK_TYPE(ssize_t, int)
1046
1047 # Try to determine the array type of the second argument of getgroups
1048 # for the target system (int or gid_t).
1049 AC_TYPE_GETGROUPS
1050 if test "${target}" = "${build}"; then
1051   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
1052 else
1053   case "${target}" in
1054         # This condition may need some tweaking.  It should include all
1055         # targets where the array type of the second argument of getgroups
1056         # is int and the type of gid_t is not equivalent to int.
1057         *-*-sunos* | *-*-ultrix*)
1058                 TARGET_GETGROUPS_T=int
1059                 ;;
1060         *)
1061                 TARGET_GETGROUPS_T=gid_t
1062                 ;;
1063   esac
1064 fi
1065 AC_SUBST(TARGET_GETGROUPS_T)
1066
1067 gcc_AC_FUNC_MMAP_BLACKLIST
1068
1069 case "${host}" in
1070 *-*-*vms*)
1071   # Under VMS, vfork works very differently than on Unix. The standard test
1072   # won't work, and it isn't easily adaptable. It makes more sense to
1073   # just force it.
1074   ac_cv_func_vfork_works=yes
1075   ;;
1076 esac
1077 AC_FUNC_FORK
1078
1079 AM_ICONV
1080 # Until we have in-tree GNU iconv:
1081 LIBICONV_DEP=
1082 AC_SUBST(LIBICONV_DEP)
1083
1084 AM_LC_MESSAGES
1085
1086 AM_LANGINFO_CODESET
1087
1088 # We will need to find libiberty.h and ansidecl.h
1089 saved_CFLAGS="$CFLAGS"
1090 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1091 gcc_AC_CHECK_DECLS(getenv atol asprintf sbrk abort atof getcwd getwd \
1092         strsignal strstr strverscmp \
1093         errno snprintf vsnprintf vasprintf malloc realloc calloc \
1094         free basename getopt clock getpagesize gcc_UNLOCKED_FUNCS, , ,[
1095 #include "ansidecl.h"
1096 #include "system.h"])
1097
1098 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1099 #include "ansidecl.h"
1100 #include "system.h"
1101 #ifdef HAVE_SYS_RESOURCE_H
1102 #include <sys/resource.h>
1103 #endif
1104 ])
1105
1106 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1107 #include "ansidecl.h"
1108 #include "system.h"
1109 #ifdef HAVE_SYS_RESOURCE_H
1110 #include <sys/resource.h>
1111 #endif
1112 ]], [[rlim_t l = 0;]])],[],[AC_DEFINE([rlim_t],[long],
1113 [Define to \`long' if <sys/resource.h> doesn't define.])])
1114
1115 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1116 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1117 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1118 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1119 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1120 #include "ansidecl.h"
1121 #include "system.h"
1122 #ifdef HAVE_LDFCN_H
1123 #undef FREAD
1124 #undef FWRITE
1125 #include <ldfcn.h>
1126 #endif
1127 ])
1128
1129 gcc_AC_CHECK_DECLS(times, , ,[
1130 #include "ansidecl.h"
1131 #include "system.h"
1132 #ifdef HAVE_SYS_TIMES_H
1133 #include <sys/times.h>
1134 #endif
1135 ])
1136
1137 gcc_AC_CHECK_DECLS(sigaltstack, , ,[
1138 #include "ansidecl.h"
1139 #include "system.h"
1140 #include <signal.h>
1141 ])
1142
1143 # More time-related stuff.
1144 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1145 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1146 #include "ansidecl.h"
1147 #include "system.h"
1148 #ifdef HAVE_SYS_TIMES_H
1149 #include <sys/times.h>
1150 #endif
1151 ]], [[struct tms tms;]])],[ac_cv_struct_tms=yes],[ac_cv_struct_tms=no])])
1152 if test $ac_cv_struct_tms = yes; then
1153   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1154   [Define if <sys/times.h> defines struct tms.])
1155 fi
1156
1157 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1158 # revisit after autoconf 2.50.
1159 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1160 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1161 #include "ansidecl.h"
1162 #include "system.h"
1163 ]], [[clock_t x;]])],[gcc_cv_type_clock_t=yes],[gcc_cv_type_clock_t=no])])
1164 if test $gcc_cv_type_clock_t = yes; then
1165   AC_DEFINE(HAVE_CLOCK_T, 1,
1166   [Define if <time.h> defines clock_t.])
1167 fi
1168
1169 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1170 CFLAGS="$saved_CFLAGS"
1171
1172 gcc_AC_INITFINI_ARRAY
1173
1174 # mkdir takes a single argument on some systems.
1175 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1176
1177 # File extensions
1178 manext='.1'
1179 objext='.o'
1180 AC_SUBST(manext)
1181 AC_SUBST(objext)
1182
1183 # With Setjmp/Longjmp based exception handling.
1184 AC_ARG_ENABLE(sjlj-exceptions,
1185 [  --enable-sjlj-exceptions
1186                           arrange to use setjmp/longjmp exception handling],
1187 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1188 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1189   [Define 0/1 to force the choice for exception handling model.])])
1190
1191 # For platforms with the unwind ABI which includes an unwind library,
1192 # libunwind, we can choose to use the system libunwind.
1193 AC_ARG_WITH(system-libunwind,
1194 [  --with-system-libunwind use installed libunwind])
1195
1196 # config.gcc also contains tests of with_system_libunwind.
1197 if test x$with_system_libunwind = xyes; then
1198         AC_DEFINE(HAVE_GETIPINFO, 1,
1199 [Define to 1 if system unwind library has _Unwind_GetIPInfo.])
1200 fi
1201
1202 # --------------------------------------------------------
1203 # Build, host, and target specific configuration fragments
1204 # --------------------------------------------------------
1205
1206 # Collect build-machine-specific information.
1207 . ${srcdir}/config.build
1208
1209 # Collect host-machine-specific information.
1210 . ${srcdir}/config.host
1211
1212 target_gtfiles=
1213
1214 # Collect target-machine-specific information.
1215 . ${srcdir}/config.gcc
1216
1217 extra_objs="${host_extra_objs} ${extra_objs}"
1218 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1219
1220 # Default the target-machine variables that were not explicitly set.
1221 if test x"$tm_file" = x
1222 then tm_file=$cpu_type/$cpu_type.h; fi
1223
1224 if test x"$extra_headers" = x
1225 then extra_headers=; fi
1226
1227 if test x$md_file = x
1228 then md_file=$cpu_type/$cpu_type.md; fi
1229
1230 if test x$out_file = x
1231 then out_file=$cpu_type/$cpu_type.c; fi
1232
1233 if test x"$tmake_file" = x
1234 then tmake_file=$cpu_type/t-$cpu_type
1235 fi
1236
1237 if test x"$dwarf2" = xyes
1238 then tm_file="$tm_file tm-dwarf2.h"
1239 fi
1240
1241 # Say what files are being used for the output code and MD file.
1242 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1243 echo "Using \`$srcdir/config/$md_file' as machine description file."
1244
1245 # If any of the xm_file variables contain nonexistent files, warn
1246 # about them and drop them.
1247
1248 bx=
1249 for x in $build_xm_file; do
1250   if    test -f $srcdir/config/$x
1251   then      bx="$bx $x"
1252   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1253   fi
1254 done
1255 build_xm_file="$bx"
1256
1257 hx=
1258 for x in $host_xm_file; do
1259   if    test -f $srcdir/config/$x
1260   then      hx="$hx $x"
1261   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1262   fi
1263 done
1264 host_xm_file="$hx"
1265
1266 tx=
1267 for x in $xm_file; do
1268   if    test -f $srcdir/config/$x
1269   then      tx="$tx $x"
1270   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1271   fi
1272 done
1273 xm_file="$tx"
1274
1275 count=a
1276 for f in $tm_file; do
1277         count=${count}x
1278 done
1279 if test $count = ax; then
1280         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1281 else
1282         echo "Using the following target machine macro files:"
1283         for f in $tm_file; do
1284                 echo "  $srcdir/config/$f"
1285         done
1286 fi
1287
1288 if test x$need_64bit_hwint = xyes; then
1289         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1290 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1291 fi
1292
1293 if test x$use_long_long_for_widest_fast_int = xyes; then
1294         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1295 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1296 efficiently supported by the host hardware.])
1297 fi
1298
1299 count=a
1300 for f in $host_xm_file; do
1301         count=${count}x
1302 done
1303 if test $count = a; then
1304         :
1305 elif test $count = ax; then
1306         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1307 else
1308         echo "Using the following host machine macro files:"
1309         for f in $host_xm_file; do
1310                 echo "  $srcdir/config/$f"
1311         done
1312 fi
1313 echo "Using ${out_host_hook_obj} for host machine hooks."
1314
1315 if test "$host_xm_file" != "$build_xm_file"; then
1316         count=a
1317         for f in $build_xm_file; do
1318                 count=${count}x
1319         done
1320         if test $count = a; then
1321                 :
1322         elif test $count = ax; then
1323                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1324         else
1325                 echo "Using the following build machine macro files:"
1326                 for f in $build_xm_file; do
1327                         echo "  $srcdir/config/$f"
1328                 done
1329         fi
1330 fi
1331
1332 case ${host} in
1333   powerpc*-*-darwin*)
1334     AC_CACHE_CHECK([whether mcontext_t fields have underscores],
1335       gcc_cv_mcontext_underscores,
1336       AC_COMPILE_IFELSE([
1337 #include <sys/cdefs.h>
1338 #include <sys/signal.h>
1339 #include <ucontext.h>
1340 int main() { mcontext_t m; if (m->ss.srr0) return 0; return 0; }
1341 ],
1342         gcc_cv_mcontext_underscores=no, gcc_cv_mcontext_underscores=yes))
1343       if test $gcc_cv_mcontext_underscores = yes; then
1344         AC_DEFINE(HAS_MCONTEXT_T_UNDERSCORES,,dnl
1345           [mcontext_t fields start with __])
1346       fi
1347     ;;
1348 esac
1349
1350 # ---------
1351 # Threading
1352 # ---------
1353
1354 # Check if a valid thread package
1355 case ${enable_threads} in
1356   "" | no)
1357     # No threads
1358     target_thread_file='single'
1359     ;;
1360   yes)
1361     # default
1362     target_thread_file='single'
1363     ;;
1364   aix | dce | gnat | irix | posix | posix95 | rtems | \
1365   single | solaris | vxworks | win32 )
1366     target_thread_file=${enable_threads}
1367     ;;
1368   *)
1369     echo "${enable_threads} is an unknown thread package" 1>&2
1370     exit 1
1371     ;;
1372 esac
1373
1374 if test x${thread_file} = x; then
1375   # No thread file set by target-specific clauses in config.gcc,
1376   # so use file chosen by default logic above
1377   thread_file=${target_thread_file}
1378 fi
1379
1380 # Make gthr-default.h if we have a thread file.
1381 gthread_flags=
1382 if test $thread_file != single; then
1383   rm -f gthr-default.h
1384   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
1385   gthread_flags=-DHAVE_GTHR_DEFAULT
1386 fi
1387 AC_SUBST(gthread_flags)
1388
1389 # --------
1390 # UNSORTED
1391 # --------
1392
1393 use_cxa_atexit=no
1394 if test x$enable___cxa_atexit = xyes || \
1395    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1396   if test x$host = x$target; then
1397     case $host in
1398       # mingw32 doesn't have __cxa_atexit but uses atexit registration
1399       # keyed to flag_use_cxa_atexit
1400       *-*-mingw32*)
1401         use_cxa_atexit=yes
1402         ;;
1403       *)
1404         AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1405           [echo "__cxa_atexit can't be enabled on this target"])
1406         ;;
1407     esac
1408   else
1409     # We can't check for __cxa_atexit when building a cross, so assume
1410     # it is available
1411     use_cxa_atexit=yes
1412   fi
1413   if test x$use_cxa_atexit = xyes; then
1414     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 2,
1415       [Define if you want to use __cxa_atexit, rather than atexit, to
1416       register C++ destructors for local statics and global objects.
1417       This is essential for fully standards-compliant handling of
1418       destructors, but requires __cxa_atexit in libc.])
1419   fi
1420 fi
1421
1422 use_getipinfo=yes
1423 if test x$with_system_libunwind = xyes; then
1424    if test x$host = x$target; then
1425      AC_SEARCH_LIBS(_Unwind_GetIPInfo, unwind,, [use_getipinfo=no])
1426    fi
1427 fi
1428 GCC_TARGET_TEMPLATE(HAVE_GETIPINFO)
1429 if test x$use_getipinfo = xyes; then
1430    AC_DEFINE(HAVE_GETIPINFO, 1,
1431         [Define to 1 if system unwind library has _Unwind_GetIPInfo.])
1432 else
1433    echo "The system unwind library does not support _Unwind_GetIPInfo."
1434 fi
1435
1436 # Look for a file containing extra machine modes.
1437 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1438   extra_modes_file='$(srcdir)'/config/${extra_modes}
1439   AC_SUBST(extra_modes_file)
1440   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1441   [Define to the name of a file containing a list of extra machine modes
1442    for this architecture.])
1443 fi
1444
1445 # Convert extra_options into a form suitable for Makefile use.
1446 extra_opt_files=
1447 for f in $extra_options; do
1448   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1449 done
1450 AC_SUBST(extra_opt_files)
1451
1452 # auto-host.h is the file containing items generated by autoconf and is
1453 # the first file included by config.h.
1454 # If host=build, it is correct to have bconfig include auto-host.h
1455 # as well.  If host!=build, we are in error and need to do more
1456 # work to find out the build config parameters.
1457 if test x$host = x$build
1458 then
1459         build_auto=auto-host.h
1460 else
1461         # We create a subdir, then run autoconf in the subdir.
1462         # To prevent recursion we set host and build for the new
1463         # invocation of configure to the build for this invocation
1464         # of configure.
1465         tempdir=build.$$
1466         rm -rf $tempdir
1467         mkdir $tempdir
1468         cd $tempdir
1469         case ${srcdir} in
1470         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1471         *) realsrcdir=../${srcdir};;
1472         esac
1473         saved_CFLAGS="${CFLAGS}"
1474         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1475         ${realsrcdir}/configure \
1476                 --enable-languages=${enable_languages-all} \
1477                 --target=$target_alias --host=$build_alias --build=$build_alias
1478         CFLAGS="${saved_CFLAGS}"
1479
1480         # We just finished tests for the build machine, so rename
1481         # the file auto-build.h in the gcc directory.
1482         mv auto-host.h ../auto-build.h
1483         cd ..
1484         rm -rf $tempdir
1485         build_auto=auto-build.h
1486 fi
1487 AC_SUBST(build_subdir)
1488
1489 tm_file="${tm_file} defaults.h"
1490 tm_p_file="${tm_p_file} tm-preds.h"
1491 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1492 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1493 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1494 # put this back in temporarily.
1495 xm_file="auto-host.h ansidecl.h ${xm_file}"
1496
1497 # --------
1498 # UNSORTED
1499 # --------
1500
1501 changequote(,)dnl
1502 # Compile in configure arguments.
1503 if test -f configargs.h ; then
1504         # Being re-configured.
1505         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1506         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1507 else
1508         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1509 fi
1510
1511 # Double all backslashes and backslash all quotes to turn
1512 # gcc_config_arguments into a C string.
1513 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1514 $gcc_config_arguments
1515 EOF
1516 gcc_config_arguments_str=`cat conftest.out`
1517 rm -f conftest.out
1518
1519 cat > configargs.h <<EOF
1520 /* Generated automatically. */
1521 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1522 static const char thread_model[] = "$thread_file";
1523
1524 static const struct {
1525   const char *name, *value;
1526 } configure_default_options[] = $configure_default_options;
1527 EOF
1528 changequote([,])dnl
1529
1530 # Internationalization
1531 ZW_GNU_GETTEXT_SISTER_DIR
1532
1533 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1534 # -liconv on the link line twice.
1535 case "$LIBINTL" in *$LIBICONV*)
1536         LIBICONV= ;;
1537 esac
1538
1539 AC_ARG_ENABLE(secureplt,
1540 [  --enable-secureplt      enable -msecure-plt by default for PowerPC],
1541 [], [])
1542
1543 # Windows32 Registry support for specifying GCC installation paths.
1544 AC_ARG_ENABLE(win32-registry,
1545 [  --disable-win32-registry
1546                           disable lookup of installation paths in the
1547                           Registry on Windows hosts
1548   --enable-win32-registry enable registry lookup (default)
1549   --enable-win32-registry=KEY
1550                           use KEY instead of GCC version as the last portion
1551                           of the registry key],,)
1552
1553 case $host_os in
1554   win32 | pe | cygwin* | mingw32* | uwin*)
1555     if test "x$enable_win32_registry" != xno; then
1556       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1557     fi
1558
1559     if test "x$enable_win32_registry" != xno; then
1560       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1561   [Define to 1 if installation paths should be looked up in the Windows
1562    Registry. Ignored on non-Windows hosts.])
1563
1564       if test "x$enable_win32_registry" != xyes \
1565          && test "x$enable_win32_registry" != x; then
1566         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1567   [Define to be the last component of the Windows registry key under which
1568    to look for installation paths.  The full key used will be
1569    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1570    The default is the GCC version number.])
1571       fi
1572     fi
1573   ;;
1574 esac
1575
1576 # Get an absolute path to the GCC top-level source directory
1577 holddir=`${PWDCMD-pwd}`
1578 cd $srcdir
1579 topdir=`${PWDCMD-pwd}`
1580 cd $holddir
1581
1582 # Conditionalize the makefile for this host machine.
1583 xmake_file=
1584 for f in ${host_xmake_file}
1585 do
1586         if test -f ${srcdir}/config/$f
1587         then
1588                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1589         fi
1590 done
1591
1592 # Conditionalize the makefile for this target machine.
1593 tmake_file_=
1594 for f in ${tmake_file}
1595 do
1596         if test -f ${srcdir}/config/$f
1597         then
1598                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1599         fi
1600 done
1601 tmake_file="${tmake_file_}"
1602
1603 # This is a terrible hack which will go away some day.
1604 host_cc_for_libada=${CC}
1605 AC_SUBST(host_cc_for_libada)
1606
1607 out_object_file=`basename $out_file .c`.o
1608
1609 tm_file_list="options.h"
1610 tm_include_list="options.h"
1611 for f in $tm_file; do
1612   case $f in
1613     ./* )
1614        f=`echo $f | sed 's/^..//'`
1615        tm_file_list="${tm_file_list} $f"
1616        tm_include_list="${tm_include_list} $f"
1617        ;;
1618     defaults.h )
1619        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1620        tm_include_list="${tm_include_list} $f"
1621        ;;
1622     * )
1623        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1624        tm_include_list="${tm_include_list} config/$f"
1625        ;;
1626   esac
1627 done
1628
1629 tm_p_file_list=
1630 tm_p_include_list=
1631 for f in $tm_p_file; do
1632   case $f in
1633     tm-preds.h )
1634        tm_p_file_list="${tm_p_file_list} $f"
1635        tm_p_include_list="${tm_p_include_list} $f"
1636        ;;
1637     * )
1638        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1639        tm_p_include_list="${tm_p_include_list} config/$f"
1640   esac
1641 done
1642
1643 xm_file_list=
1644 xm_include_list=
1645 for f in $xm_file; do
1646   case $f in
1647     ansidecl.h )
1648        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1649        xm_include_list="${xm_include_list} $f"
1650        ;;
1651     auto-host.h )
1652        xm_file_list="${xm_file_list} $f"
1653        xm_include_list="${xm_include_list} $f"
1654        ;;
1655     * )
1656        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1657        xm_include_list="${xm_include_list} config/$f"
1658        ;;
1659   esac
1660 done
1661
1662 host_xm_file_list=
1663 host_xm_include_list=
1664 for f in $host_xm_file; do
1665   case $f in
1666     ansidecl.h )
1667        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1668        host_xm_include_list="${host_xm_include_list} $f"
1669        ;;
1670     auto-host.h )
1671        host_xm_file_list="${host_xm_file_list} $f"
1672        host_xm_include_list="${host_xm_include_list} $f"
1673        ;;
1674     * )
1675        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1676        host_xm_include_list="${host_xm_include_list} config/$f"
1677        ;;
1678   esac
1679 done
1680
1681 build_xm_file_list=
1682 for f in $build_xm_file; do
1683   case $f in
1684     ansidecl.h )
1685        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1686        build_xm_include_list="${build_xm_include_list} $f"
1687        ;;
1688     auto-build.h | auto-host.h )
1689        build_xm_file_list="${build_xm_file_list} $f"
1690        build_xm_include_list="${build_xm_include_list} $f"
1691        ;;
1692     * )
1693        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1694        build_xm_include_list="${build_xm_include_list} config/$f"
1695        ;;
1696   esac
1697 done
1698
1699 # Define macro CROSS_DIRECTORY_STRUCTURE in compilation if this is a
1700 # cross-compiler which does not use the native headers and libraries.
1701 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1702 CROSS=                                          AC_SUBST(CROSS)
1703 ALL=all.internal                                AC_SUBST(ALL)
1704 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1705
1706 if test "x$with_build_sysroot" != x; then
1707   build_system_header_dir=$with_build_sysroot'$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
1708 else
1709   # This value is used, even on a native system, because
1710   # CROSS_SYSTEM_HEADER_DIR is just
1711   # $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR).
1712   build_system_header_dir='$(CROSS_SYSTEM_HEADER_DIR)'
1713 fi
1714
1715 if test x$host != x$target
1716 then
1717         CROSS="-DCROSS_DIRECTORY_STRUCTURE"
1718         ALL=all.cross
1719         SYSTEM_HEADER_DIR=$build_system_header_dir
1720         case "$host","$target" in
1721         # Darwin crosses can use the host system's libraries and headers,
1722         # because of the fat library support.  Of course, it must be the
1723         # same version of Darwin on both sides.  Allow the user to
1724         # just say --target=foo-darwin without a version number to mean
1725         # "the version on this system".
1726             *-*-darwin*,*-*-darwin*)
1727                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1728                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1729                 if test $hostos = $targetos -o $targetos = darwin ; then
1730                     CROSS=
1731                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1732                     with_headers=yes
1733                 fi
1734                 ;;
1735
1736             i?86-*-*,x86_64-*-* \
1737             | powerpc*-*-*,powerpc64*-*-*)
1738                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1739         esac
1740 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1741         SYSTEM_HEADER_DIR=$build_system_header_dir
1742 fi
1743
1744 # If this is a cross-compiler that does not
1745 # have its own set of headers then define
1746 # inhibit_libc
1747
1748 # If this is using newlib, without having the headers available now,
1749 # then define inhibit_libc in LIBGCC2_CFLAGS.
1750 # This prevents libgcc2 from containing any code which requires libc
1751 # support.
1752 inhibit_libc=false
1753 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1754        test x$with_newlib = xyes ; } &&
1755      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1756        inhibit_libc=true
1757 fi
1758 AC_SUBST(inhibit_libc)
1759
1760 # When building gcc with a cross-compiler, we need to adjust things so
1761 # that the generator programs are still built with the native compiler.
1762 # Also, we cannot run fixincludes or fix-header.
1763
1764 # These are the normal (build=host) settings:
1765 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1766 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1767 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1768
1769 # Possibly disable fixproto, on a per-target basis.
1770 case ${use_fixproto} in
1771   no)
1772     STMP_FIXPROTO=
1773     ;;
1774   yes)
1775     STMP_FIXPROTO=stmp-fixproto
1776     ;;
1777 esac
1778 AC_SUBST(STMP_FIXPROTO)
1779
1780 # And these apply if build != host, or we are generating coverage data
1781 if test x$build != x$host || test "x$coverage_flags" != x
1782 then
1783     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1784
1785     if test "x$TARGET_SYSTEM_ROOT" = x; then
1786         if test "x$STMP_FIXPROTO" != x; then
1787           STMP_FIXPROTO=stmp-install-fixproto
1788         fi
1789     fi
1790 fi
1791
1792 # Expand extra_headers to include complete path.
1793 # This substitutes for lots of t-* files.
1794 extra_headers_list=
1795 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1796 for file in ${extra_headers} ; do
1797   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1798 done
1799
1800 # Define collect2 in Makefile.
1801 case $host_can_use_collect2 in
1802   no) collect2= ;;
1803   *) collect2='collect2$(exeext)' ;;
1804 esac
1805 AC_SUBST([collect2])
1806
1807 # Add a definition of USE_COLLECT2 if system wants one.
1808 case $use_collect2 in
1809   no) use_collect2= ;;
1810   "") ;;
1811   *)
1812     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1813     xm_defines="${xm_defines} USE_COLLECT2"
1814     case $host_can_use_collect2 in
1815       no)
1816         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1817         ;;
1818     esac
1819     ;;
1820 esac
1821
1822 # ---------------------------
1823 # Assembler & linker features
1824 # ---------------------------
1825
1826 # Identify the assembler which will work hand-in-glove with the newly
1827 # built GCC, so that we can examine its features.  This is the assembler
1828 # which will be driven by the driver program.
1829 #
1830 # If build != host, and we aren't building gas in-tree, we identify a
1831 # build->target assembler and hope that it will have the same features
1832 # as the host->target assembler we'll be using.
1833 gcc_cv_gas_major_version=
1834 gcc_cv_gas_minor_version=
1835 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1836
1837 m4_pattern_allow([AS_FOR_TARGET])dnl
1838 AS_VAR_SET_IF(gcc_cv_as,, [
1839 if test -x "$DEFAULT_ASSEMBLER"; then
1840         gcc_cv_as="$DEFAULT_ASSEMBLER"
1841 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1842      && test -f ../gas/Makefile \
1843      && test x$build = x$host; then
1844         gcc_cv_as=../gas/as-new$build_exeext
1845 elif test -x as$build_exeext; then
1846         # Build using assembler in the current directory.
1847         gcc_cv_as=./as$build_exeext
1848 elif test -x $AS_FOR_TARGET; then
1849         gcc_cv_as="$AS_FOR_TARGET"
1850 else
1851         AC_PATH_PROG(gcc_cv_as, $AS_FOR_TARGET)
1852 fi])
1853
1854 ORIGINAL_AS_FOR_TARGET=$gcc_cv_as
1855 AC_SUBST(ORIGINAL_AS_FOR_TARGET)
1856
1857 AC_MSG_CHECKING(what assembler to use)
1858 if test "$gcc_cv_as" = ../gas/as-new$build_exeext; then
1859   # Single tree build which includes gas.  We want to prefer it
1860   # over whatever linker top-level may have detected, since
1861   # we'll use what we're building after installation anyway.
1862   AC_MSG_RESULT(newly built gas)
1863   in_tree_gas=yes
1864   _gcc_COMPUTE_GAS_VERSION
1865   in_tree_gas_is_elf=no
1866   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1867      || (grep 'obj_format = multi' ../gas/Makefile \
1868          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1869   then
1870     in_tree_gas_is_elf=yes
1871   fi
1872 else
1873   AC_MSG_RESULT($gcc_cv_as)
1874   in_tree_gas=no
1875 fi
1876
1877 # Identify the linker which will work hand-in-glove with the newly
1878 # built GCC, so that we can examine its features.  This is the linker
1879 # which will be driven by the driver program.
1880 #
1881 # If build != host, and we aren't building gas in-tree, we identify a
1882 # build->target linker and hope that it will have the same features
1883 # as the host->target linker we'll be using.
1884 gcc_cv_gld_major_version=
1885 gcc_cv_gld_minor_version=
1886 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1887 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1888
1889 AS_VAR_SET_IF(gcc_cv_ld,, [
1890 if test -x "$DEFAULT_LINKER"; then
1891         gcc_cv_ld="$DEFAULT_LINKER"
1892 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1893      && test -f ../ld/Makefile \
1894      && test x$build = x$host; then
1895         gcc_cv_ld=../ld/ld-new$build_exeext
1896 elif test -x collect-ld$build_exeext; then
1897         # Build using linker in the current directory.
1898         gcc_cv_ld=./collect-ld$build_exeext
1899 elif test -x $LD_FOR_TARGET; then
1900         gcc_cv_ld="$LD_FOR_TARGET"
1901 else
1902         AC_PATH_PROG(gcc_cv_ld, $LD_FOR_TARGET)
1903 fi])
1904
1905 ORIGINAL_LD_FOR_TARGET=$gcc_cv_ld
1906 AC_SUBST(ORIGINAL_LD_FOR_TARGET)
1907
1908 AC_MSG_CHECKING(what linker to use)
1909 if test "$gcc_cv_ld" = ../ld/ld-new$build_exeext; then
1910         # Single tree build which includes ld.  We want to prefer it
1911         # over whatever linker top-level may have detected, since
1912         # we'll use what we're building after installation anyway.
1913         AC_MSG_RESULT(newly built ld)
1914         in_tree_ld=yes
1915         in_tree_ld_is_elf=no
1916         if (grep 'EMUL = .*elf' ../ld/Makefile \
1917             || grep 'EMUL = .*linux' ../ld/Makefile \
1918             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
1919           in_tree_ld_is_elf=yes
1920         fi
1921         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1922         do
1923 changequote(,)dnl
1924                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
1925                 if test x$gcc_cv_gld_version != x; then
1926                         break
1927                 fi
1928         done
1929         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1930         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1931 changequote([,])dnl
1932 else
1933         AC_MSG_RESULT($gcc_cv_ld)
1934         in_tree_ld=no
1935 fi
1936
1937 # Figure out what nm we will be using.
1938 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1939 AS_VAR_SET_IF(gcc_cv_nm,, [
1940 if test -f $gcc_cv_binutils_srcdir/configure.in \
1941      && test -f ../binutils/Makefile \
1942      && test x$build = x$host; then
1943         gcc_cv_nm=../binutils/nm-new$build_exeext
1944 elif test -x nm$build_exeext; then
1945         gcc_cv_nm=./nm$build_exeext
1946 elif test -x $NM_FOR_TARGET; then
1947         gcc_cv_nm="$NM_FOR_TARGET"
1948 else
1949         AC_PATH_PROG(gcc_cv_nm, $NM_FOR_TARGET)
1950 fi])
1951
1952 AC_MSG_CHECKING(what nm to use)
1953 if test "$gcc_cv_nm" = ../binutils/nm-new$build_exeext; then
1954         # Single tree build which includes binutils.
1955         AC_MSG_RESULT(newly built nm)
1956         in_tree_nm=yes
1957 else
1958         AC_MSG_RESULT($gcc_cv_nm)
1959         in_tree_nm=no
1960 fi
1961
1962 ORIGINAL_NM_FOR_TARGET=$gcc_cv_nm
1963 AC_SUBST(ORIGINAL_NM_FOR_TARGET)
1964
1965 # Figure out what objdump we will be using.
1966 AS_VAR_SET_IF(gcc_cv_objdump,, [
1967 if test -f $gcc_cv_binutils_srcdir/configure.in \
1968      && test -f ../binutils/Makefile \
1969      && test x$build = x$host; then
1970         # Single tree build which includes binutils.
1971         gcc_cv_objdump=../binutils/objdump$build_exeext
1972 elif test -x objdump$build_exeext; then
1973         gcc_cv_objdump=./objdump$build_exeext
1974 elif test -x $OBJDUMP_FOR_TARGET; then
1975         gcc_cv_objdump="$OBJDUMP_FOR_TARGET"
1976 else
1977         AC_PATH_PROG(gcc_cv_objdump, $OBJDUMP_FOR_TARGET)
1978 fi])
1979
1980 AC_MSG_CHECKING(what objdump to use)
1981 if test "$gcc_cv_objdump" = ../binutils/objdump$build_exeext; then
1982         # Single tree build which includes binutils.
1983         AC_MSG_RESULT(newly built objdump)
1984 elif test x$gcc_cv_objdump = x; then
1985         AC_MSG_RESULT(not found)
1986 else
1987         AC_MSG_RESULT($gcc_cv_objdump)
1988 fi
1989
1990 # Figure out what assembler alignment features are present.
1991 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
1992  [2,6,0],,
1993 [.balign 4
1994 .p2align 2],,
1995 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
1996   [Define if your assembler supports .balign and .p2align.])])
1997
1998 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
1999  [2,8,0],,
2000  [.p2align 4,,7],,
2001 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2002   [Define if your assembler supports specifying the maximum number
2003    of bytes to skip when using the GAS .p2align command.])])
2004
2005 gcc_GAS_CHECK_FEATURE([.literal16], gcc_cv_as_literal16,
2006  [2,8,0],,
2007  [.literal16],,
2008 [AC_DEFINE(HAVE_GAS_LITERAL16, 1,
2009   [Define if your assembler supports .literal16.])])
2010
2011 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2012  [elf,2,9,0],,
2013  [conftest_label1: .word 0
2014 .subsection -1
2015 conftest_label2: .word 0
2016 .previous],
2017  [if test x$gcc_cv_nm != x; then
2018     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2019     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2020     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2021     then :
2022     else gcc_cv_as_subsection_m1=yes
2023     fi
2024     rm -f conftest.nm1 conftest.nm2
2025   fi],
2026  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2027   [Define if your assembler supports .subsection and .subsection -1 starts
2028    emitting at the beginning of your section.])])
2029
2030 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2031  [2,2,0],,
2032  [      .weak foobar],,
2033 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2034
2035 gcc_GAS_CHECK_FEATURE([.weakref], gcc_cv_as_weakref,
2036  [2,17,0],,
2037  [      .weakref foobar, barfnot],,
2038 [AC_DEFINE(HAVE_GAS_WEAKREF, 1, [Define if your assembler supports .weakref.])])
2039
2040 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2041  [2,15,91],,
2042  [      .SPACE $TEXT$
2043         .NSUBSPA $CODE$,COMDAT],,
2044 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2045
2046 # .hidden needs to be supported in both the assembler and the linker,
2047 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2048 # This is irritatingly difficult to feature test for; we have to check the
2049 # date string after the version number.  If we've got an in-tree
2050 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2051 # to be safe.
2052 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2053 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2054  [elf,2,13,0],,
2055 [       .hidden foobar
2056 foobar:])
2057
2058 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2059 [if test $in_tree_ld = yes ; then
2060   gcc_cv_ld_hidden=no
2061   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2062      && test $in_tree_ld_is_elf = yes; then
2063      gcc_cv_ld_hidden=yes
2064   fi
2065 else
2066   gcc_cv_ld_hidden=yes
2067   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2068   if echo "$ld_ver" | grep GNU > /dev/null; then
2069 changequote(,)dnl
2070     ld_vers=`echo $ld_ver | sed -n \
2071         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2072         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2073         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2074         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)[  ].*$,\1,p' \
2075         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[     ].*$,\1,p' \
2076         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[       ].*$,\1,p' \
2077         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[   -].*$,\1,p'`
2078     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2079     ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2080     ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2081     ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2082     if test 0"$ld_date" -lt 20020404; then
2083       if test -n "$ld_date"; then
2084         # If there was date string, but was earlier than 2002-04-04, fail
2085         gcc_cv_ld_hidden=no
2086       elif test -z "$ld_vers"; then
2087         # If there was no date string nor ld version number, something is wrong
2088         gcc_cv_ld_hidden=no
2089       else
2090         test -z "$ld_vers_patch" && ld_vers_patch=0
2091         if test "$ld_vers_major" -lt 2; then
2092           gcc_cv_ld_hidden=no
2093         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2094           gcc_cv_ld_hidden="no"
2095         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2096           gcc_cv_ld_hidden=no
2097         fi
2098       fi
2099 changequote([,])dnl
2100     fi
2101   else
2102     case "${target}" in
2103       hppa64*-*-hpux* | ia64*-*-hpux*)
2104         gcc_cv_ld_hidden=yes
2105         ;;
2106       *)
2107         gcc_cv_ld_hidden=no
2108         ;;
2109     esac
2110   fi
2111 fi])
2112 libgcc_visibility=no
2113 AC_SUBST(libgcc_visibility)
2114 GCC_TARGET_TEMPLATE([HAVE_GAS_HIDDEN])
2115 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2116   libgcc_visibility=yes
2117   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2118   [Define if your assembler and linker support .hidden.])
2119 fi
2120
2121 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2122 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2123   [elf,2,11,0],,
2124 [       .data
2125         .uleb128 L2 - L1
2126 L1:
2127         .uleb128 1280
2128         .sleb128 -1010
2129 L2:],
2130  [# GAS versions before 2.11 do not support uleb128,
2131   # despite appearing to.
2132   # ??? There exists an elf-specific test that will crash
2133   # the assembler.  Perhaps it's better to figure out whether
2134   # arbitrary sections are supported and try the test.
2135   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2136   if echo "$as_ver" | grep GNU > /dev/null; then
2137 changequote(,)dnl
2138     as_ver=`echo $as_ver | sed -e 's/GNU assembler \([0-9.][0-9.]*\).*/\1/'`
2139     as_major=`echo $as_ver | sed 's/\..*//'`
2140     as_minor=`echo $as_ver | sed 's/[^.]*\.\([0-9]*\).*/\1/'`
2141 changequote([,])dnl
2142     if test $as_major -eq 2 && test $as_minor -lt 11
2143     then :
2144     else gcc_cv_as_leb128=yes
2145     fi
2146   fi],
2147   [AC_DEFINE(HAVE_AS_LEB128, 1,
2148     [Define if your assembler supports .sleb128 and .uleb128.])])
2149
2150 # GAS versions up to and including 2.11.0 may mis-optimize
2151 # .eh_frame data.
2152 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2153   [elf,2,12,0],,
2154 [       .text
2155 .LFB1:
2156         .4byte  0
2157 .L1:
2158         .4byte  0
2159 .LFE1:
2160         .section        .eh_frame,"aw",@progbits
2161 __FRAME_BEGIN__:
2162         .4byte  .LECIE1-.LSCIE1
2163 .LSCIE1:
2164         .4byte  0x0
2165         .byte   0x1
2166         .ascii "z\0"
2167         .byte   0x1
2168         .byte   0x78
2169         .byte   0x1a
2170         .byte   0x0
2171         .byte   0x4
2172         .4byte  1
2173         .p2align 1
2174 .LECIE1:
2175 .LSFDE1:
2176         .4byte  .LEFDE1-.LASFDE1
2177 .LASFDE1:
2178         .4byte  .LASFDE1-__FRAME_BEGIN__
2179         .4byte  .LFB1
2180         .4byte  .LFE1-.LFB1
2181         .byte   0x4
2182         .4byte  .LFE1-.LFB1
2183         .byte   0x4
2184         .4byte  .L1-.LFB1
2185 .LEFDE1:],
2186 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2187 cat > conftest.lit <<EOF
2188  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2189  0010 01000000 12000000 18000000 00000000  ................
2190  0020 08000000 04080000 0044               .........D      @&t@
2191 EOF
2192 cat > conftest.big <<EOF
2193  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2194  0010 00000001 00000012 00000018 00000000  ................
2195  0020 00000008 04000000 0844               .........D      @&t@
2196 EOF
2197   # If the assembler didn't choke, and we can objdump,
2198   # and we got the correct data, then succeed.
2199   # The text in the here-document typically retains its unix-style line
2200   # endings, while the output of objdump will use host line endings.
2201   # Therefore, use diff -b for the comparisons.
2202   if test x$gcc_cv_objdump != x \
2203   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2204      | tail -3 > conftest.got \
2205   && { diff -b conftest.lit conftest.got > /dev/null 2>&1 \
2206     || diff -b conftest.big conftest.got > /dev/null 2>&1; }
2207   then
2208     gcc_cv_as_eh_frame=yes
2209   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2210     gcc_cv_as_eh_frame=buggy
2211   else
2212     # Uh oh, what do we do now?
2213     gcc_cv_as_eh_frame=no
2214   fi])
2215
2216 if test $gcc_cv_as_eh_frame = buggy; then
2217   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2218   [Define if your assembler mis-optimizes .eh_frame data.])
2219 fi
2220
2221 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2222  [elf,2,12,0], [--fatal-warnings],
2223  [.section .rodata.str, "aMS", @progbits, 1])
2224 if test $gcc_cv_as_shf_merge = no; then
2225   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2226     [elf,2,12,0], [--fatal-warnings],
2227     [.section .rodata.str, "aMS", %progbits, 1])
2228 fi
2229 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2230   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2231 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2232
2233 gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group,
2234  [elf,2,16,0], [--fatal-warnings],
2235  [.section .text,"axG",@progbits,.foo,comdat])
2236 if test $gcc_cv_as_comdat_group = yes; then
2237   gcc_cv_as_comdat_group_percent=no
2238 else
2239  gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group_percent,
2240    [elf,2,16,0], [--fatal-warnings],
2241    [.section .text,"axG",%progbits,.foo,comdat])
2242 fi
2243 if test $in_tree_ld != yes && test x"$ld_vers" != x; then
2244   comdat_group=yes
2245   if test 0"$ld_date" -lt 20050308; then
2246     if test -n "$ld_date"; then
2247       # If there was date string, but was earlier than 2005-03-08, fail
2248       comdat_group=no
2249     elif test "$ld_vers_major" -lt 2; then
2250       comdat_group=no
2251     elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
2252       comdat_group=no
2253     fi
2254   fi
2255 else
2256   # assume linkers other than GNU ld don't support COMDAT group
2257   comdat_group=no
2258 fi
2259 if test $comdat_group = no; then
2260   gcc_cv_as_comdat_group=no
2261   gcc_cv_as_comdat_group_percent=no
2262 fi
2263 AC_DEFINE_UNQUOTED(HAVE_COMDAT_GROUP,
2264   [`if test $gcc_cv_as_comdat_group = yes || test $gcc_cv_as_comdat_group_percent = yes; then echo 1; else echo 0; fi`],
2265 [Define 0/1 if your assembler and linker support COMDAT groups.])
2266
2267 # Thread-local storage - the check is heavily parametrized.
2268 conftest_s=
2269 tls_first_major=
2270 tls_first_minor=
2271 tls_as_opt=
2272 case "$target" in
2273 changequote(,)dnl
2274   alpha*-*-*)
2275     conftest_s='
2276         .section ".tdata","awT",@progbits
2277 foo:    .long   25
2278         .text
2279         ldq     $27,__tls_get_addr($29)         !literal!1
2280         lda     $16,foo($29)                    !tlsgd!1
2281         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2282         ldq     $27,__tls_get_addr($29)         !literal!2
2283         lda     $16,foo($29)                    !tlsldm!2
2284         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2285         ldq     $1,foo($29)                     !gotdtprel
2286         ldah    $2,foo($29)                     !dtprelhi
2287         lda     $3,foo($2)                      !dtprello
2288         lda     $4,foo($29)                     !dtprel
2289         ldq     $1,foo($29)                     !gottprel
2290         ldah    $2,foo($29)                     !tprelhi
2291         lda     $3,foo($2)                      !tprello
2292         lda     $4,foo($29)                     !tprel'
2293         tls_first_major=2
2294         tls_first_minor=13
2295         tls_as_opt=--fatal-warnings
2296         ;;
2297   frv*-*-*)
2298     conftest_s='
2299         .section ".tdata","awT",@progbits
2300 x:      .long   25
2301         .text
2302         call    #gettlsoff(x)'
2303         tls_first_major=2
2304         tls_first_minor=14
2305         ;;
2306   hppa*-*-linux*)
2307     conftest_s='
2308 t1:     .reg    %r20
2309 t2:     .reg    %r21
2310 gp:     .reg    %r19
2311         .section ".tdata","awT",@progbits
2312 foo:    .long   25
2313         .text
2314         .align  4
2315         addil LT%foo-$tls_gdidx$,gp
2316         ldo RT%foo-$tls_gdidx$(%r1),%arg0
2317         b __tls_get_addr
2318         nop
2319         addil LT%foo-$tls_ldidx$,gp
2320         b __tls_get_addr
2321         ldo RT%foo-$tls_ldidx$(%r1),%arg0
2322         addil LR%foo-$tls_dtpoff$,%ret0
2323         ldo RR%foo-$tls_dtpoff$(%r1),%t1
2324         mfctl %cr27,%t1
2325         addil LT%foo-$tls_ieoff$,gp
2326         ldw RT%foo-$tls_ieoff$(%r1),%t2
2327         add %t1,%t2,%t3
2328         mfctl %cr27,%t1
2329         addil LR%foo-$tls_leoff$,%t1
2330         ldo RR%foo-$tls_leoff$(%r1),%t2'
2331         tls_first_major=2
2332         tls_first_minor=15
2333         tls_as_opt=--fatal-warnings
2334         ;;
2335   arm*-*-*)
2336     conftest_s='
2337         .section ".tdata","awT",%progbits
2338 foo:    .long   25
2339         .text
2340 .word foo(gottpoff)
2341 .word foo(tpoff)
2342 .word foo(tlsgd)
2343 .word foo(tlsldm)
2344 .word foo(tlsldo)'
2345         tls_first_major=2
2346         tls_first_minor=17
2347         ;;
2348   i[34567]86-*-*)
2349     conftest_s='
2350         .section ".tdata","awT",@progbits
2351 foo:    .long   25
2352         .text
2353         movl    %gs:0, %eax
2354         leal    foo@TLSGD(,%ebx,1), %eax
2355         leal    foo@TLSLDM(%ebx), %eax
2356         leal    foo@DTPOFF(%eax), %edx
2357         movl    foo@GOTTPOFF(%ebx), %eax
2358         subl    foo@GOTTPOFF(%ebx), %eax
2359         addl    foo@GOTNTPOFF(%ebx), %eax
2360         movl    foo@INDNTPOFF, %eax
2361         movl    $foo@TPOFF, %eax
2362         subl    $foo@TPOFF, %eax
2363         leal    foo@NTPOFF(%ecx), %eax'
2364         tls_first_major=2
2365         tls_first_minor=14
2366         tls_as_opt=--fatal-warnings
2367         ;;
2368   x86_64-*-*)
2369     conftest_s='
2370         .section ".tdata","awT",@progbits
2371 foo:    .long   25
2372         .text
2373         movq    %fs:0, %rax
2374         leaq    foo@TLSGD(%rip), %rdi
2375         leaq    foo@TLSLD(%rip), %rdi
2376         leaq    foo@DTPOFF(%rax), %rdx
2377         movq    foo@GOTTPOFF(%rip), %rax
2378         movq    $foo@TPOFF, %rax'
2379         tls_first_major=2
2380         tls_first_minor=14
2381         tls_as_opt=--fatal-warnings
2382         ;;
2383   ia64-*-*)
2384     conftest_s='
2385         .section ".tdata","awT",@progbits
2386 foo:    data8   25
2387         .text
2388         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2389         addl    r17 = @ltoff(@dtprel(foo#)), gp
2390         addl    r18 = @ltoff(@tprel(foo#)), gp
2391         addl    r19 = @dtprel(foo#), gp
2392         adds    r21 = @dtprel(foo#), r13
2393         movl    r23 = @dtprel(foo#)
2394         addl    r20 = @tprel(foo#), gp
2395         adds    r22 = @tprel(foo#), r13
2396         movl    r24 = @tprel(foo#)'
2397         tls_first_major=2
2398         tls_first_minor=13
2399         tls_as_opt=--fatal-warnings
2400         ;;
2401   mips*-*-*)
2402     conftest_s='
2403         .section .tdata,"awT",@progbits
2404 x:
2405         .word 2
2406         .text
2407         addiu $4, $28, %tlsgd(x)
2408         addiu $4, $28, %tlsldm(x)
2409         lui $4, %dtprel_hi(x)
2410         addiu $4, $4, %dtprel_lo(x)
2411         lw $4, %gottprel(x)($28)
2412         lui $4, %tprel_hi(x)
2413         addiu $4, $4, %tprel_lo(x)'
2414         tls_first_major=2
2415         tls_first_minor=16
2416         tls_as_opt='-32 --fatal-warnings'
2417         ;;
2418   powerpc-*-*)
2419     conftest_s='
2420         .section ".tdata","awT",@progbits
2421         .align 2
2422 ld0:    .space 4
2423 ld1:    .space 4
2424 x1:     .space 4
2425 x2:     .space 4
2426 x3:     .space 4
2427         .text
2428         addi 3,31,ld0@got@tlsgd
2429         bl __tls_get_addr
2430         addi 3,31,x1@got@tlsld
2431         bl __tls_get_addr
2432         addi 9,3,x1@dtprel
2433         addis 9,3,x2@dtprel@ha
2434         addi 9,9,x2@dtprel@l
2435         lwz 9,x3@got@tprel(31)
2436         add 9,9,x@tls
2437         addi 9,2,x1@tprel
2438         addis 9,2,x2@tprel@ha
2439         addi 9,9,x2@tprel@l'
2440         tls_first_major=2
2441         tls_first_minor=14
2442         tls_as_opt="-a32 --fatal-warnings"
2443         ;;
2444   powerpc64-*-*)
2445     conftest_s='
2446         .section ".tdata","awT",@progbits
2447         .align 3
2448 ld0:    .space 8
2449 ld1:    .space 8
2450 x1:     .space 8
2451 x2:     .space 8
2452 x3:     .space 8
2453         .text
2454         addi 3,2,ld0@got@tlsgd
2455         bl .__tls_get_addr
2456         nop
2457         addi 3,2,ld1@toc
2458         bl .__tls_get_addr
2459         nop
2460         addi 3,2,x1@got@tlsld
2461         bl .__tls_get_addr
2462         nop
2463         addi 9,3,x1@dtprel
2464         bl .__tls_get_addr
2465         nop
2466         addis 9,3,x2@dtprel@ha
2467         addi 9,9,x2@dtprel@l
2468         bl .__tls_get_addr
2469         nop
2470         ld 9,x3@got@dtprel(2)
2471         add 9,9,3
2472         bl .__tls_get_addr
2473         nop'
2474         tls_first_major=2
2475         tls_first_minor=14
2476         tls_as_opt="-a64 --fatal-warnings"
2477         ;;
2478   s390-*-*)
2479     conftest_s='
2480         .section ".tdata","awT",@progbits
2481 foo:    .long   25
2482         .text
2483         .long   foo@TLSGD
2484         .long   foo@TLSLDM
2485         .long   foo@DTPOFF
2486         .long   foo@NTPOFF
2487         .long   foo@GOTNTPOFF
2488         .long   foo@INDNTPOFF
2489         l       %r1,foo@GOTNTPOFF(%r12)
2490         l       %r1,0(%r1):tls_load:foo
2491         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2492         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2493         tls_first_major=2
2494         tls_first_minor=14
2495         tls_as_opt="-m31 --fatal-warnings"
2496         ;;
2497   s390x-*-*)
2498     conftest_s='
2499         .section ".tdata","awT",@progbits
2500 foo:    .long   25
2501         .text
2502         .quad   foo@TLSGD
2503         .quad   foo@TLSLDM
2504         .quad   foo@DTPOFF
2505         .quad   foo@NTPOFF
2506         .quad   foo@GOTNTPOFF
2507         lg      %r1,foo@GOTNTPOFF(%r12)
2508         larl    %r1,foo@INDNTPOFF
2509         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2510         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2511         tls_first_major=2
2512         tls_first_minor=14
2513         tls_as_opt="-m64 -Aesame --fatal-warnings"
2514         ;;
2515   sh-*-* | sh[34]-*-*)
2516     conftest_s='
2517         .section ".tdata","awT",@progbits
2518 foo:    .long   25
2519         .text
2520         .long   foo@TLSGD
2521         .long   foo@TLSLDM
2522         .long   foo@DTPOFF
2523         .long   foo@GOTTPOFF
2524         .long   foo@TPOFF'
2525         tls_first_major=2
2526         tls_first_minor=13
2527         tls_as_opt=--fatal-warnings
2528         ;;
2529   sparc*-*-*)
2530     case "$target" in
2531       sparc*-sun-solaris2.[56789]*)
2532         # TLS was introduced in the Solaris 9 4/04 release but
2533         # we do not enable it by default on Solaris 9 either.
2534         if test "x$enable_tls" = xyes ; then
2535           on_solaris=yes
2536         else
2537           enable_tls=no;
2538         fi
2539         ;;
2540       sparc*-sun-solaris2.*)
2541         on_solaris=yes
2542         ;;
2543       *)
2544         on_solaris=no
2545         ;;
2546     esac
2547     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2548       conftest_s='
2549         .section ".tdata",#alloc,#write,#tls
2550 foo:    .long   25
2551         .text
2552         sethi   %tgd_hi22(foo), %o0
2553         add     %o0, %tgd_lo10(foo), %o1
2554         add     %l7, %o1, %o0, %tgd_add(foo)
2555         call    __tls_get_addr, %tgd_call(foo)
2556         sethi   %tldm_hi22(foo), %l1
2557         add     %l1, %tldm_lo10(foo), %l2
2558         add     %l7, %l2, %o0, %tldm_add(foo)
2559         call    __tls_get_addr, %tldm_call(foo)
2560         sethi   %tldo_hix22(foo), %l3
2561         xor     %l3, %tldo_lox10(foo), %l4
2562         add     %o0, %l4, %l5, %tldo_add(foo)
2563         sethi   %tie_hi22(foo), %o3
2564         add     %o3, %tie_lo10(foo), %o3
2565         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2566         add     %g7, %o2, %o4, %tie_add(foo)
2567         sethi   %tle_hix22(foo), %l1
2568         xor     %l1, %tle_lox10(foo), %o5
2569         ld      [%g7 + %o5], %o1'
2570         tls_first_major=0
2571         tls_first_minor=0
2572     else
2573       conftest_s='
2574         .section ".tdata","awT",@progbits
2575 foo:    .long   25
2576         .text
2577         sethi   %tgd_hi22(foo), %o0
2578         add     %o0, %tgd_lo10(foo), %o1
2579         add     %l7, %o1, %o0, %tgd_add(foo)
2580         call    __tls_get_addr, %tgd_call(foo)
2581         sethi   %tldm_hi22(foo), %l1
2582         add     %l1, %tldm_lo10(foo), %l2
2583         add     %l7, %l2, %o0, %tldm_add(foo)
2584         call    __tls_get_addr, %tldm_call(foo)
2585         sethi   %tldo_hix22(foo), %l3
2586         xor     %l3, %tldo_lox10(foo), %l4
2587         add     %o0, %l4, %l5, %tldo_add(foo)
2588         sethi   %tie_hi22(foo), %o3
2589         add     %o3, %tie_lo10(foo), %o3
2590         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2591         add     %g7, %o2, %o4, %tie_add(foo)
2592         sethi   %tle_hix22(foo), %l1
2593         xor     %l1, %tle_lox10(foo), %o5
2594         ld      [%g7 + %o5], %o1'
2595         tls_first_major=2
2596         tls_first_minor=14
2597         tls_as_opt="-32 --fatal-warnings"
2598       fi
2599         ;;
2600 changequote([,])dnl
2601 esac
2602 set_have_as_tls=no
2603 if test "x$enable_tls" = xno ; then
2604   : # TLS explicitly disabled.
2605 elif test "x$enable_tls" = xyes ; then
2606   set_have_as_tls=yes # TLS explicitly enabled.
2607 elif test -z "$tls_first_major"; then
2608   : # If we don't have a check, assume no support.
2609 else
2610   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2611   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2612   [set_have_as_tls=yes])
2613 fi
2614 if test $set_have_as_tls = yes ; then
2615   AC_DEFINE(HAVE_AS_TLS, 1,
2616             [Define if your assembler supports thread-local storage.])
2617 fi
2618
2619 # Target-specific assembler checks.
2620
2621 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
2622 gcc_cv_ld_static_dynamic=no
2623 if test $in_tree_ld = yes ; then
2624   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10; then
2625     gcc_cv_ld_static_dynamic=yes
2626   fi
2627 elif test x$gcc_cv_ld != x; then
2628         # Check if linker supports -Bstatic/-Bdynamic option
2629         if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
2630           && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
2631                 gcc_cv_ld_static_dynamic=yes
2632         fi
2633 fi
2634 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
2635         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
2636 [Define if your linker supports -Bstatic/-Bdynamic option.])
2637 fi
2638 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
2639
2640 if test x"$demangler_in_ld" = xyes; then
2641   AC_MSG_CHECKING(linker --demangle support)
2642   gcc_cv_ld_demangle=no
2643   if test $in_tree_ld = yes; then
2644     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
2645       gcc_cv_ld_demangle=yes
2646     fi
2647   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
2648     # Check if the GNU linker supports --demangle option
2649     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
2650       gcc_cv_ld_demangle=yes
2651     fi
2652   fi
2653   if test x"$gcc_cv_ld_demangle" = xyes; then
2654     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
2655 [Define if your linker supports --demangle option.])
2656   fi
2657   AC_MSG_RESULT($gcc_cv_ld_demangle)
2658 fi
2659
2660 case "$target" in
2661   # All TARGET_ABI_OSF targets.
2662   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2663     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2664         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2665 [       .set nomacro
2666         .text
2667         extbl   $3, $2, $3      !lituse_bytoff!1
2668         ldq     $2, a($29)      !literal!1
2669         ldq     $4, b($29)      !literal!2
2670         ldq_u   $3, 0($2)       !lituse_base!1
2671         ldq     $27, f($29)     !literal!5
2672         jsr     $26, ($27), f   !lituse_jsr!5
2673         ldah    $29, 0($26)     !gpdisp!3
2674         lda     $0, c($29)      !gprel
2675         ldah    $1, d($29)      !gprelhigh
2676         lda     $1, d($1)       !gprellow
2677         lda     $29, 0($29)     !gpdisp!3],,
2678     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2679   [Define if your assembler supports explicit relocations.])])
2680     gcc_GAS_CHECK_FEATURE([jsrdirect relocation support],
2681         gcc_cv_as_alpha_jsrdirect_relocs, [2,16,90],,
2682 [       .set nomacro
2683         .text
2684         ldq     $27, a($29)     !literal!1
2685         jsr     $26, ($27), a   !lituse_jsrdirect!1],,
2686     [AC_DEFINE(HAVE_AS_JSRDIRECT_RELOCS, 1,
2687   [Define if your assembler supports the lituse_jsrdirect relocation.])])
2688     ;;
2689
2690   cris-*-*)
2691     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
2692       gcc_cv_as_cris_no_mul_bug,[2,15,91],
2693       [-no-mul-bug-abort], [.text],,
2694       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
2695                 [Define if your assembler supports the -no-mul-bug-abort option.])])
2696     ;;
2697
2698   sparc*-*-*)
2699     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2700       [.register %g2, #scratch],,
2701       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2702                 [Define if your assembler supports .register.])])
2703
2704     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2705       [-relax], [.text],,
2706       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2707                 [Define if your assembler supports -relax option.])])
2708
2709     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2710       gcc_cv_as_sparc_ua_pcrel,,
2711       [-K PIC],
2712 [.text
2713 foo:
2714         nop
2715 .data
2716 .align 4
2717 .byte 0
2718 .uaword %r_disp32(foo)],
2719       [if test x$gcc_cv_ld != x \
2720        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2721          gcc_cv_as_sparc_ua_pcrel=yes
2722        fi
2723        rm -f conftest],
2724       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2725                 [Define if your assembler and linker support unaligned PC relative relocs.])
2726
2727       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2728         gcc_cv_as_sparc_ua_pcrel_hidden,,
2729         [-K PIC],
2730 [.data
2731 .align 4
2732 .byte 0x31
2733 .uaword %r_disp32(foo)
2734 .byte 0x32, 0x33, 0x34
2735 .global foo
2736 .hidden foo
2737 foo:
2738 .skip 4],
2739         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2740          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2741          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2742             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2743             if $gcc_cv_objdump -R conftest 2> /dev/null \
2744                | grep 'DISP32' > /dev/null 2>&1; then
2745                 :
2746             else
2747                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2748             fi
2749          fi
2750          rm -f conftest],
2751          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2752                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2753     ]) # unaligned pcrel relocs
2754
2755     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2756       gcc_cv_as_sparc_offsetable_lo10,,
2757       [-xarch=v9],
2758 [.text
2759         or %g1, %lo(ab) + 12, %g1
2760         or %g1, %lo(ab + 12), %g1],
2761       [if test x$gcc_cv_objdump != x \
2762        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2763           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2764          gcc_cv_as_sparc_offsetable_lo10=yes
2765        fi],
2766        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2767                  [Define if your assembler supports offsetable %lo().])])
2768     ;;
2769
2770 changequote(,)dnl
2771   i[34567]86-*-* | x86_64-*-*)
2772 changequote([,])dnl
2773     case $target_os in
2774       cygwin* | pe | mingw32*)
2775         # Used for DWARF 2 in PE
2776         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
2777           gcc_cv_as_ix86_pe_secrel32,
2778           [2,15,91],,
2779 [.text
2780 foo:    nop
2781 .data
2782         .secrel32 foo],
2783           [if test x$gcc_cv_ld != x \
2784            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
2785              gcc_cv_as_ix86_pe_secrel32=yes
2786            fi
2787            rm -f conftest],
2788           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
2789             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
2790         ;;
2791     esac
2792
2793     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2794        gcc_cv_as_ix86_filds_fists,
2795       [2,9,0],, [filds mem; fists mem],,
2796       [AC_DEFINE(HAVE_GAS_FILDS_FISTS, 1,
2797         [Define if your assembler uses the new HImode fild and fist notation.])])
2798
2799     gcc_GAS_CHECK_FEATURE([cmov syntax],
2800       gcc_cv_as_ix86_cmov_sun_syntax,,,
2801       [cmovl.l %edx, %eax],,
2802       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
2803         [Define if your assembler supports the Sun syntax for cmov.])])
2804
2805     gcc_GAS_CHECK_FEATURE([ffreep mnemonic],
2806       gcc_cv_as_ix86_ffreep,,,
2807       [ffreep %st(1)],,
2808       [AC_DEFINE(HAVE_AS_IX86_FFREEP, 1,
2809         [Define if your assembler supports the ffreep mnemonic.])])
2810
2811     gcc_GAS_CHECK_FEATURE([different section symbol subtraction],
2812       gcc_cv_as_ix86_diff_sect_delta,,,
2813       [.section .rodata
2814 .L1:
2815         .long .L2-.L1
2816         .long .L3-.L1
2817         .text
2818 .L3:    nop
2819 .L2:    nop],,
2820       [AC_DEFINE(HAVE_AS_IX86_DIFF_SECT_DELTA, 1,
2821         [Define if your assembler supports the subtraction of symbols in different sections.])])
2822
2823     # This one is used unconditionally by i386.[ch]; it is to be defined
2824     # to 1 if the feature is present, 0 otherwise.
2825     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
2826         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
2827 [       .text
2828 .L0:
2829         nop
2830         .data
2831         .long .L0@GOTOFF])
2832     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2833       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2834       [Define true if the assembler supports '.long foo@GOTOFF'.])
2835     ;;
2836
2837   ia64*-*-*)
2838     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
2839         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
2840 [       .text
2841         addl r15 = @ltoffx(x#), gp
2842         ;;
2843         ld8.mov r16 = [[r15]], x#],,
2844     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2845           [Define if your assembler supports ltoffx and ldxmov relocations.])])
2846
2847     ;;
2848
2849   powerpc*-*-*)
2850     case $target in
2851       *-*-aix*) conftest_s='    .machine "pwr5"
2852         .csect .text[[PR]]
2853         mfcr 3,128';;
2854       *-*-darwin*)
2855         gcc_GAS_CHECK_FEATURE([.machine directive support],
2856           gcc_cv_as_machine_directive,,,
2857           [     .machine ppc7400])
2858         if test x$gcc_cv_as_machine_directive != xyes; then
2859           echo "*** This target requires an assembler supporting \".machine\"" >&2
2860           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
2861           test x$build = x$target && exit 1
2862         fi
2863         conftest_s='    .text
2864         mfcr r3,128';;
2865       *) conftest_s='   .machine power4
2866         .text
2867         mfcr 3,128';;
2868     esac
2869
2870     gcc_GAS_CHECK_FEATURE([mfcr field support],
2871       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
2872       [$conftest_s],,
2873       [AC_DEFINE(HAVE_AS_MFCRF, 1,
2874           [Define if your assembler supports mfcr field.])])
2875
2876     case $target in
2877       *-*-aix*) conftest_s='    .machine "pwr5"
2878         .csect .text[[PR]]
2879         popcntb 3,3';;
2880       *) conftest_s='   .machine power5
2881         .text
2882         popcntb 3,3';;
2883     esac
2884
2885     gcc_GAS_CHECK_FEATURE([popcntb support],
2886       gcc_cv_as_powerpc_popcntb, [2,17,0],,
2887       [$conftest_s],,
2888       [AC_DEFINE(HAVE_AS_POPCNTB, 1,
2889           [Define if your assembler supports popcntb field.])])
2890
2891     case $target in
2892       *-*-aix*) conftest_s='    .machine "pwr5x"
2893         .csect .text[[PR]]
2894         frin 1,1';;
2895       *) conftest_s='   .machine power5
2896         .text
2897         frin 1,1';;
2898     esac
2899
2900     gcc_GAS_CHECK_FEATURE([fp round support],
2901       gcc_cv_as_powerpc_fprnd, [2,17,0],,
2902       [$conftest_s],,
2903       [AC_DEFINE(HAVE_AS_FPRND, 1,
2904           [Define if your assembler supports fprnd.])])
2905
2906     case $target in
2907       *-*-aix*) conftest_s='    .machine "pwr6"
2908         .csect .text[[PR]]
2909         mffgpr 1,3';;
2910       *) conftest_s='   .machine power6
2911         .text
2912         mffgpr 1,3';;
2913     esac
2914
2915     gcc_GAS_CHECK_FEATURE([move fp gpr support],
2916       gcc_cv_as_powerpc_mfpgpr, [9,99,0],,
2917       [$conftest_s],,
2918       [AC_DEFINE(HAVE_AS_MFPGPR, 1,
2919           [Define if your assembler supports mffgpr and mftgpr.])])
2920
2921     case $target in
2922       *-*-aix*) conftest_s='    .csect .text[[PR]]
2923 LCF..0:
2924         addis 11,30,_GLOBAL_OFFSET_TABLE_-LCF..0@ha';;
2925       *-*-darwin*)
2926         conftest_s='    .text
2927 LCF0:
2928         addis r11,r30,_GLOBAL_OFFSET_TABLE_-LCF0@ha';;
2929       *) conftest_s='   .text
2930 .LCF0:
2931         addis 11,30,_GLOBAL_OFFSET_TABLE_-.LCF0@ha';;
2932     esac
2933
2934     gcc_GAS_CHECK_FEATURE([rel16 relocs],
2935       gcc_cv_as_powerpc_rel16, [2,17,0], -a32,
2936       [$conftest_s],,
2937       [AC_DEFINE(HAVE_AS_REL16, 1,
2938           [Define if your assembler supports R_PPC_REL16 relocs.])])
2939
2940     case $target in
2941       *-*-aix*) conftest_s='    .machine "pwr6"
2942         .csect .text[[PR]]
2943         cmpb 3,4,5';;
2944       *) conftest_s='   .machine power6
2945         .text
2946         cmpb 3,4,5';;
2947     esac
2948
2949     gcc_GAS_CHECK_FEATURE([compare bytes support],
2950       gcc_cv_as_powerpc_cmpb, [9,99,0], -a32,
2951       [$conftest_s],,
2952       [AC_DEFINE(HAVE_AS_CMPB, 1,
2953           [Define if your assembler supports cmpb.])])
2954
2955     case $target in
2956       *-*-aix*) conftest_s='    .machine "pwr6"
2957         .csect .text[[PR]]
2958         dadd 1,3';;
2959       *) conftest_s='   .machine power6
2960         .text
2961         dadd 1,3';;
2962     esac
2963
2964     gcc_GAS_CHECK_FEATURE([decimal float support],
2965       gcc_cv_as_powerpc_dfp, [9,99,0], -a32,
2966       [$conftest_s],,
2967       [AC_DEFINE(HAVE_AS_DFP, 1,
2968           [Define if your assembler supports DFP instructions.])])
2969     ;;
2970
2971   mips*-*-*)
2972     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2973       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
2974 [       lw $4,%gp_rel(foo)($4)],,
2975       [if test x$target_cpu_default = x
2976        then target_cpu_default=MASK_EXPLICIT_RELOCS
2977        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
2978        fi])
2979     gcc_GAS_CHECK_FEATURE([-mno-shared support],
2980       gcc_cv_as_mips_no_shared, [2,16,0], [-mno-shared], [nop],,
2981       [AC_DEFINE(HAVE_AS_NO_SHARED, 1,
2982                  [Define if the assembler understands -mno-shared.])])
2983     ;;
2984 esac
2985
2986 # Mips and HP-UX need the GNU assembler.
2987 # Linux on IA64 might be able to use the Intel assembler.
2988
2989 case "$target" in
2990   mips*-*-* | *-*-hpux* )
2991     if test x$gas_flag = xyes \
2992        || test x"$host" != x"$build" \
2993        || test ! -x "$gcc_cv_as" \
2994        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
2995       :
2996     else
2997       echo "*** This configuration requires the GNU assembler" >&2
2998       exit 1
2999     fi
3000     ;;
3001 esac
3002
3003 # ??? Not all targets support dwarf2 debug_line, even within a version
3004 # of gas.  Moreover, we need to emit a valid instruction to trigger any
3005 # info to the output file.  So, as supported targets are added to gas 2.11,
3006 # add some instruction here to (also) show we expect this might work.
3007 # ??? Once 2.11 is released, probably need to add first known working
3008 # version to the per-target configury.
3009 case "$target" in
3010   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
3011   | x86_64*-*-* | hppa*-*-* | arm*-*-* | strongarm*-*-* | xscale*-*-* \
3012   | xstormy16*-*-* | cris-*-* | xtensa-*-* | bfin-*-* | score*-*-* | spu-*-*)
3013     insn="nop"
3014     ;;
3015   ia64*-*-* | s390*-*-*)
3016     insn="nop 0"
3017     ;;
3018   mmix-*-*)
3019     insn="swym 0"
3020     ;;
3021 esac
3022 if test x"$insn" != x; then
3023  conftest_s="\
3024         .file 1 \"conftest.s\"
3025         .loc 1 3 0
3026         $insn"
3027  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
3028   gcc_cv_as_dwarf2_debug_line,
3029   [elf,2,11,0],, [$conftest_s],
3030   [if test x$gcc_cv_objdump != x \
3031    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
3032       | grep debug_line > /dev/null 2>&1; then
3033      gcc_cv_as_dwarf2_debug_line=yes
3034    fi])
3035
3036 # The .debug_line file table must be in the exact order that
3037 # we specified the files, since these indices are also used
3038 # by DW_AT_decl_file.  Approximate this test by testing if
3039 # the assembler bitches if the same index is assigned twice.
3040  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
3041   gcc_cv_as_dwarf2_file_buggy,,,
3042 [       .file 1 "foo.s"
3043         .file 1 "bar.s"])
3044
3045  if test $gcc_cv_as_dwarf2_debug_line = yes \
3046  && test $gcc_cv_as_dwarf2_file_buggy = no; then
3047         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
3048   [Define if your assembler supports dwarf2 .file/.loc directives,
3049    and preserves file table indices exactly as given.])
3050  fi
3051
3052  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
3053   gcc_cv_as_gdwarf2_flag,
3054   [elf,2,11,0], [--gdwarf2], [$insn],,
3055   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
3056 [Define if your assembler supports the --gdwarf2 option.])])
3057
3058  gcc_GAS_CHECK_FEATURE([--gstabs option],
3059   gcc_cv_as_gstabs_flag,
3060   [elf,2,11,0], [--gstabs], [$insn],
3061   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
3062    # and warns about it, but still exits successfully.  So check for
3063    # this.
3064    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
3065    then :
3066    else gcc_cv_as_gstabs_flag=yes
3067    fi],
3068   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
3069 [Define if your assembler supports the --gstabs option.])])
3070 fi
3071
3072 AC_MSG_CHECKING(linker read-only and read-write section mixing)
3073 gcc_cv_ld_ro_rw_mix=unknown
3074 if test $in_tree_ld = yes ; then
3075   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
3076      && test $in_tree_ld_is_elf = yes; then
3077     gcc_cv_ld_ro_rw_mix=read-write
3078   fi
3079 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
3080   echo '.section myfoosect, "a"' > conftest1.s
3081   echo '.section myfoosect, "aw"' > conftest2.s
3082   echo '.byte 1' >> conftest2.s
3083   echo '.section myfoosect, "a"' > conftest3.s
3084   echo '.byte 0' >> conftest3.s
3085   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
3086      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
3087      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
3088      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
3089         conftest2.o conftest3.o > /dev/null 2>&1; then
3090     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
3091                          | sed -e '/myfoosect/!d' -e N`
3092     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
3093       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
3094         gcc_cv_ld_ro_rw_mix=read-only
3095       else
3096         gcc_cv_ld_ro_rw_mix=read-write
3097       fi
3098     fi
3099   fi
3100 changequote(,)dnl
3101   rm -f conftest.* conftest[123].*
3102 changequote([,])dnl
3103 fi
3104 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
3105         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
3106   [Define if your linker links a mix of read-only
3107    and read-write sections into a read-write section.])
3108 fi
3109 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
3110
3111 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
3112 gcc_cv_ld_eh_frame_hdr=no
3113 if test $in_tree_ld = yes ; then
3114   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
3115      && test $in_tree_ld_is_elf = yes; then
3116     gcc_cv_ld_eh_frame_hdr=yes
3117   fi
3118 elif test x$gcc_cv_ld != x; then
3119         # Check if linker supports --eh-frame-hdr option
3120         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
3121                 gcc_cv_ld_eh_frame_hdr=yes
3122         fi
3123 fi
3124 GCC_TARGET_TEMPLATE([HAVE_LD_EH_FRAME_HDR])
3125 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
3126         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
3127 [Define if your linker supports --eh-frame-hdr option.])
3128 fi
3129 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
3130
3131 AC_MSG_CHECKING(linker position independent executable support)
3132 gcc_cv_ld_pie=no
3133 if test $in_tree_ld = yes ; then
3134   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
3135      && test $in_tree_ld_is_elf = yes; then
3136     gcc_cv_ld_pie=yes
3137   fi
3138 elif test x$gcc_cv_ld != x; then
3139         # Check if linker supports -pie option
3140         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
3141                 gcc_cv_ld_pie=yes
3142         fi
3143 fi
3144 if test x"$gcc_cv_ld_pie" = xyes; then
3145         AC_DEFINE(HAVE_LD_PIE, 1,
3146 [Define if your linker supports -pie option.])
3147 fi
3148 AC_MSG_RESULT($gcc_cv_ld_pie)
3149
3150 AC_MSG_CHECKING(linker EH-compatible garbage collection of sections)
3151 gcc_cv_ld_eh_gc_sections=no
3152 if test $in_tree_ld = yes ; then
3153   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 17 -o "$gcc_cv_gld_major_version" -gt 2 \
3154      && test $in_tree_ld_is_elf = yes; then
3155     gcc_cv_ld_eh_gc_sections=yes
3156   fi
3157 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
3158   cat > conftest.s <<EOF
3159         .section        .text
3160 .globl _start
3161         .type _start, @function
3162 _start:
3163         .long foo
3164         .size _start, .-_start
3165         .section        .text.foo,"ax",@progbits
3166         .type foo, @function
3167 foo:
3168         .long 0
3169         .size foo, .-foo
3170         .section        .gcc_except_table.foo,"a",@progbits
3171 .L0:
3172         .long 0
3173         .section        .eh_frame,"a",@progbits
3174         .long .L0
3175 EOF
3176   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3177     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3178          | grep "gc-sections option ignored" > /dev/null; then
3179       gcc_cv_ld_eh_gc_sections=no
3180     elif $gcc_cv_objdump -h conftest | grep gcc_except_table > /dev/null; then
3181       gcc_cv_ld_eh_gc_sections=yes
3182       # If no COMDAT groups, the compiler will emit .gnu.linkonce.t. sections.
3183       if test x$gcc_cv_as_comdat_group != xyes; then
3184         gcc_cv_ld_eh_gc_sections=no
3185         cat > conftest.s <<EOF
3186         .section        .text
3187 .globl _start
3188         .type _start, @function
3189 _start:
3190         .long foo
3191         .size _start, .-_start
3192         .section        .gnu.linkonce.t.foo,"ax",@progbits
3193         .type foo, @function
3194 foo:
3195         .long 0
3196         .size foo, .-foo
3197         .section        .gcc_except_table.foo,"a",@progbits
3198 .L0:
3199         .long 0
3200         .section        .eh_frame,"a",@progbits
3201         .long .L0
3202 EOF
3203         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3204           if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3205                | grep "gc-sections option ignored" > /dev/null; then
3206             gcc_cv_ld_eh_gc_sections=no
3207           elif $gcc_cv_objdump -h conftest | grep gcc_except_table > /dev/null; then
3208             gcc_cv_ld_eh_gc_sections=yes
3209           fi
3210         fi
3211       fi
3212     fi
3213   fi
3214   rm -f conftest.s conftest.o conftest
3215 fi
3216 case "$target" in
3217   hppa*-*-linux*)
3218     # ??? This apparently exposes a binutils bug with PC-relative relocations.
3219     gcc_cv_ld_eh_gc_sections=no
3220     ;;
3221 esac
3222 if test x$gcc_cv_ld_eh_gc_sections = xyes; then
3223         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS, 1,
3224   [Define if your linker supports garbage collection of
3225    sections in presence of EH frames.])
3226 fi
3227 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections)
3228
3229 # --------
3230 # UNSORTED
3231 # --------
3232
3233 AC_CACHE_CHECK(linker --as-needed support,
3234 gcc_cv_ld_as_needed,
3235 [gcc_cv_ld_as_needed=no
3236 if test $in_tree_ld = yes ; then
3237   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
3238      && test $in_tree_ld_is_elf = yes; then
3239     gcc_cv_ld_as_needed=yes
3240   fi
3241 elif test x$gcc_cv_ld != x; then
3242         # Check if linker supports --as-needed and --no-as-needed options
3243         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
3244                 gcc_cv_ld_as_needed=yes
3245         fi
3246 fi
3247 ])
3248 if test x"$gcc_cv_ld_as_needed" = xyes; then
3249         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
3250 [Define if your linker supports --as-needed and --no-as-needed options.])
3251 fi
3252
3253 case "$target:$tm_file" in
3254   powerpc64*-*-linux* | powerpc*-*-linux*rs6000/biarch64.h*)
3255     AC_CACHE_CHECK(linker support for omitting dot symbols,
3256     gcc_cv_ld_no_dot_syms,
3257     [gcc_cv_ld_no_dot_syms=no
3258     if test $in_tree_ld = yes ; then
3259       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
3260         gcc_cv_ld_no_dot_syms=yes
3261       fi
3262     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
3263       cat > conftest1.s <<EOF
3264         .text
3265         bl .foo
3266 EOF
3267       cat > conftest2.s <<EOF
3268         .section ".opd","aw"
3269         .align 3
3270         .globl foo
3271         .type foo,@function
3272 foo:
3273         .quad .LEfoo,.TOC.@tocbase,0
3274         .text
3275 .LEfoo:
3276         blr
3277         .size foo,.-.LEfoo
3278 EOF
3279       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
3280          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
3281          && $gcc_cv_ld -melf64ppc -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
3282         gcc_cv_ld_no_dot_syms=yes
3283       fi
3284       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
3285     fi
3286     ])
3287     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
3288       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
3289     [Define if your PowerPC64 linker only needs function descriptor syms.])
3290     fi
3291     ;;
3292 esac
3293
3294 AC_CACHE_CHECK(linker --sysroot support,
3295   gcc_cv_ld_sysroot,
3296   [gcc_cv_ld_sysroot=no
3297   if test $in_tree_ld = yes ; then
3298       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 ; then
3299         gcc_cv_ld_sysroot=yes
3300       fi
3301   elif test x$gcc_cv_ld != x; then
3302     if $gcc_cv_ld --help 2>/dev/null | grep sysroot > /dev/null; then
3303       gcc_cv_ld_sysroot=yes
3304     fi
3305   fi])
3306 if test x"$gcc_cv_ld_sysroot" = xyes; then
3307   AC_DEFINE(HAVE_LD_SYSROOT, 1,
3308   [Define if your linker supports --sysroot.])
3309 fi
3310
3311 if test x$with_sysroot = x && test x$host = x$target \
3312    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" \
3313    && test "$prefix" != "NONE"; then
3314   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
3315 [Define to PREFIX/include if cpp should also search that directory.])
3316 fi
3317
3318 # Test for stack protector support in target C library.
3319 AC_CACHE_CHECK(__stack_chk_fail in target C library,
3320       gcc_cv_libc_provides_ssp,
3321       [gcc_cv_libc_provides_ssp=no
3322     case "$target" in
3323        *-*-linux*)
3324       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3325         if test "x$with_sysroot" = x; then
3326           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3327         elif test "x$with_sysroot" = xyes; then
3328           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3329         else
3330           glibc_header_dir="${with_sysroot}/usr/include"
3331         fi
3332       else
3333         glibc_header_dir=/usr/include
3334       fi
3335       # glibc 2.4 and later provides __stack_chk_fail and
3336       # either __stack_chk_guard, or TLS access to stack guard canary.
3337       if test -f $glibc_header_dir/features.h \
3338          && $EGREP '^@<:@       @:>@*#[         ]*define[       ]+__GNU_LIBRARY__[      ]+([1-9][0-9]|[6-9])' \
3339             $glibc_header_dir/features.h > /dev/null; then
3340         if $EGREP '^@<:@        @:>@*#[         ]*define[       ]+__GLIBC__[    ]+([1-9][0-9]|[3-9])' \
3341            $glibc_header_dir/features.h > /dev/null; then
3342           gcc_cv_libc_provides_ssp=yes
3343         elif $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__GLIBC__[    ]+2' \
3344              $glibc_header_dir/features.h > /dev/null \
3345              && $EGREP '^@<:@   @:>@*#[         ]*define[       ]+__GLIBC_MINOR__[      ]+([1-9][0-9]|[4-9])' \
3346              $glibc_header_dir/features.h > /dev/null; then
3347           gcc_cv_libc_provides_ssp=yes
3348         fi
3349         fi
3350         ;;
3351        *-*-darwin*)
3352          AC_CHECK_FUNC(__stack_chk_fail,[gcc_cv_libc_provides_ssp=yes],
3353            [echo "no __stack_chk_fail on this target"])
3354         ;;
3355   *) gcc_cv_libc_provides_ssp=no ;;
3356     esac])
3357
3358 if test x$gcc_cv_libc_provides_ssp = xyes; then
3359   AC_DEFINE(TARGET_LIBC_PROVIDES_SSP, 1,
3360             [Define if your target C library provides stack protector support])
3361 fi
3362
3363 # Check if TFmode long double should be used by default or not.
3364 # Some glibc targets used DFmode long double, but with glibc 2.4
3365 # and later they can use TFmode.
3366 case "$target" in
3367   powerpc*-*-*gnu* | \
3368   sparc*-*-linux* | \
3369   s390*-*-linux* | \
3370   alpha*-*-linux*)
3371     AC_ARG_WITH(long-double-128,
3372 [  --with-long-double-128  Use 128-bit long double by default.],
3373       gcc_cv_target_ldbl128="$with_long_double_128",
3374       [gcc_cv_target_ldbl128=no
3375       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3376         if test "x$with_sysroot" = x; then
3377           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3378         elif test "x$with_sysroot" = xyes; then
3379           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3380         else
3381           glibc_header_dir="${with_sysroot}/usr/include"
3382         fi
3383       else
3384         glibc_header_dir=/usr/include
3385       fi
3386 changequote(,)dnl
3387       grep '^[  ]*#[    ]*define[       ][      ]*__LONG_DOUBLE_MATH_OPTIONAL' \
3388         $glibc_header_dir/bits/wordsize.h > /dev/null 2>&1 \
3389       && gcc_cv_target_ldbl128=yes
3390 changequote([,])dnl
3391       ])
3392     ;;
3393 esac
3394 if test x$gcc_cv_target_ldbl128 = xyes; then
3395   AC_DEFINE(TARGET_DEFAULT_LONG_DOUBLE_128, 1,
3396             [Define if TFmode long double should be the default])
3397 fi
3398
3399 # Find out what GC implementation we want, or may, use.
3400 AC_ARG_WITH(gc,
3401 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
3402                           with the compiler],
3403 [case "$withval" in
3404   page)
3405     GGC=ggc-$withval
3406     ;;
3407   zone)
3408     GGC=ggc-$withval
3409     AC_DEFINE(GGC_ZONE, 1, [Define if the zone collector is in use])
3410     ;;
3411   *)
3412     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
3413     ;;
3414 esac],
3415 [GGC=ggc-page])
3416 AC_SUBST(GGC)
3417 echo "Using $GGC for garbage collection."
3418
3419 # Use the system's zlib library.
3420 zlibdir=-L../zlib
3421 zlibinc="-I\$(srcdir)/../zlib"
3422 AC_ARG_WITH(system-zlib,
3423 [  --with-system-zlib      use installed libz],
3424 zlibdir=
3425 zlibinc=
3426 )
3427 AC_SUBST(zlibdir)
3428 AC_SUBST(zlibinc)
3429
3430 dnl Very limited version of automake's enable-maintainer-mode
3431
3432 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3433   dnl maintainer-mode is disabled by default
3434   AC_ARG_ENABLE(maintainer-mode,
3435 [  --enable-maintainer-mode
3436                           enable make rules and dependencies not useful
3437                           (and sometimes confusing) to the casual installer],
3438       maintainer_mode=$enableval,
3439       maintainer_mode=no)
3440
3441 AC_MSG_RESULT($maintainer_mode)
3442
3443 if test "$maintainer_mode" = "yes"; then
3444   MAINT=''
3445 else
3446   MAINT='#'
3447 fi
3448 AC_SUBST(MAINT)dnl
3449
3450 # --------------
3451 # Language hooks
3452 # --------------
3453
3454 # Make empty files to contain the specs and options for each language.
3455 # Then add #include lines to for a compiler that has specs and/or options.
3456
3457 subdirs=
3458 lang_opt_files=
3459 lang_specs_files=
3460 lang_tree_files=
3461 # These (without "all_") are set in each config-lang.in.
3462 # `language' must be a single word so is spelled singularly.
3463 all_languages=
3464 all_compilers=
3465 all_outputs='Makefile gccbug libada-mk'
3466 # List of language makefile fragments.
3467 all_lang_makefrags=
3468 # List of language subdirectory makefiles.  Deprecated.
3469 all_lang_makefiles=
3470 # Files for gengtype
3471 all_gtfiles="$target_gtfiles"
3472 # Files for gengtype with language
3473 all_gtfiles_files_langs=
3474 all_gtfiles_files_files=
3475
3476 # These are the languages that are set in --enable-languages,
3477 # and are available in the GCC tree.
3478 all_selected_languages=
3479
3480 # Add the language fragments.
3481 # Languages are added via two mechanisms.  Some information must be
3482 # recorded in makefile variables, these are defined in config-lang.in.
3483 # We accumulate them and plug them into the main Makefile.
3484 # The other mechanism is a set of hooks for each of the main targets
3485 # like `clean', `install', etc.
3486
3487 language_hooks="Make-hooks"
3488
3489 for lang in ${srcdir}/*/config-lang.in
3490 do
3491 changequote(,)dnl
3492         test "$lang" = "${srcdir}/*/config-lang.in" && continue
3493
3494         lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
3495         if test "x$lang_alias" = x
3496         then
3497               echo "$lang doesn't set \$language." 1>&2
3498               exit 1
3499         fi
3500         subdir="`echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
3501         subdirs="$subdirs $subdir"
3502         case ",$enable_languages," in
3503         *,$lang_alias,*)
3504             all_selected_languages="$all_selected_languages $lang_alias"
3505             if test -f $srcdir/$subdir/lang-specs.h; then
3506                 lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
3507             fi
3508             ;;
3509         esac
3510 changequote([,])dnl
3511
3512         language=
3513         boot_language=
3514         compilers=
3515         outputs=
3516         gtfiles=
3517         subdir_requires=
3518         . ${srcdir}/$subdir/config-lang.in
3519         if test "x$language" = x
3520         then
3521                 echo "${srcdir}/$subdir/config-lang.in doesn't set \$language." 1>&2
3522                 exit 1
3523         fi
3524
3525         ok=:
3526         case ",$enable_languages," in
3527                 *,$lang_alias,*) ;;
3528                 *)
3529                         for i in $subdir_requires; do
3530                                 test -f "${srcdir}/$i/config-lang.in" && continue
3531                                 ok=false
3532                                 break
3533                         done
3534                 ;;
3535         esac
3536         $ok || continue
3537
3538         all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$subdir/Make-lang.in"
3539         if test -f $srcdir/$subdir/lang.opt; then
3540             lang_opt_files="$lang_opt_files $srcdir/$subdir/lang.opt"
3541         fi
3542         if test -f $srcdir/$subdir/$subdir-tree.def; then
3543             lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
3544         fi
3545         if test -f ${srcdir}/$subdir/Makefile.in
3546                 then all_lang_makefiles="$subdir/Makefile"
3547         fi
3548         all_languages="$all_languages $language"
3549         all_compilers="$all_compilers $compilers"
3550         all_outputs="$all_outputs $outputs"
3551         all_gtfiles="$all_gtfiles $gtfiles"
3552         for f in $gtfiles
3553         do
3554                 all_gtfiles_files_langs="$all_gtfiles_files_langs ${subdir} "
3555                 all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
3556         done
3557 done
3558
3559 # Pick up gtfiles for c
3560 gtfiles=
3561 subdir="c"
3562 . ${srcdir}/c-config-lang.in
3563 all_gtfiles="$all_gtfiles $gtfiles"
3564 for f in $gtfiles
3565 do
3566         all_gtfiles_files_langs="$all_gtfiles_files_langs ${subdir} "
3567         all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
3568 done
3569
3570 check_languages=
3571 for language in $all_selected_languages
3572 do
3573         check_languages="$check_languages check-$language"
3574 done
3575
3576 # We link each language in with a set of hooks, reached indirectly via
3577 # lang.${target}.  Only do so for selected languages.
3578
3579 rm -f Make-hooks
3580 touch Make-hooks
3581 target_list="all.cross start.encap rest.encap tags \
3582         install-common install-man install-info install-pdf dvi pdf \
3583         html uninstall info man srcextra srcman srcinfo \
3584         mostlyclean clean distclean maintainer-clean"
3585
3586 for t in $target_list
3587 do
3588         x=
3589         for lang in $all_selected_languages
3590         do
3591                 x="$x $lang.$t"
3592         done
3593         echo "lang.$t: $x" >> Make-hooks
3594 done
3595
3596 # --------
3597 # UNSORTED
3598 # --------
3599
3600 # Create .gdbinit.
3601
3602 echo "dir ." > .gdbinit
3603 echo "dir ${srcdir}" >> .gdbinit
3604 if test x$gdb_needs_out_file_path = xyes
3605 then
3606         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
3607 fi
3608 if test "x$subdirs" != x; then
3609         for s in $subdirs
3610         do
3611                 echo "dir ${srcdir}/$s" >> .gdbinit
3612         done
3613 fi
3614 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
3615
3616 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
3617 # absolute path for gcc_tooldir based on inserting the number of up-directory
3618 # movements required to get from $(exec_prefix) to $(prefix) into the basic
3619 # $(libsubdir)/@(unlibsubdir) based path.
3620 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
3621 # make and thus we'd get different behavior depending on where we built the
3622 # sources.
3623 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
3624     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_noncanonical)'
3625 else
3626 changequote(<<, >>)dnl
3627 # An explanation of the sed strings:
3628 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
3629 #  -e 's|/$||'            match a trailing forward slash and eliminates it
3630 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
3631 #  -e 's|/[^/]*|../|g'    replaces each occurrence of /<directory> with ../
3632 #
3633 # (*) Note this pattern overwrites the first character of the string
3634 # with a forward slash if one is not already present.  This is not a
3635 # problem because the exact names of the sub-directories concerned is
3636 # unimportant, just the number of them matters.
3637 #
3638 # The practical upshot of these patterns is like this:
3639 #
3640 #  prefix     exec_prefix        result
3641 #  ------     -----------        ------
3642 #   /foo        /foo/bar          ../
3643 #   /foo/       /foo/bar          ../
3644 #   /foo        /foo/bar/         ../
3645 #   /foo/       /foo/bar/         ../
3646 #   /foo        /foo/bar/ugg      ../../
3647 #
3648     dollar='$$'
3649     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_noncanonical)"
3650 changequote([, ])dnl
3651 fi
3652 AC_SUBST(gcc_tooldir)
3653 AC_SUBST(dollar)
3654
3655 # Find a directory in which to install a shared libgcc.
3656
3657 AC_ARG_ENABLE(version-specific-runtime-libs,
3658 [  --enable-version-specific-runtime-libs
3659                           specify that runtime libraries should be
3660                           installed in a compiler-specific directory])
3661
3662 AC_ARG_WITH(slibdir,
3663 [  --with-slibdir=DIR      shared libraries in DIR [[LIBDIR]]],
3664 slibdir="$with_slibdir",
3665 if test "${enable_version_specific_runtime_libs+set}" = set; then
3666   slibdir='$(libsubdir)'
3667 elif test "$host" != "$target"; then
3668   slibdir='$(build_tooldir)/lib'
3669 else
3670   slibdir='$(libdir)'
3671 fi)
3672 AC_SUBST(slibdir)
3673
3674 objdir=`${PWDCMD-pwd}`
3675 AC_SUBST(objdir)
3676
3677 AC_ARG_WITH(datarootdir,
3678 [  --with-datarootdir=DIR  Use DIR as the data root [[PREFIX/share]]],
3679 datarootdir="\${prefix}/$with_datarootdir",
3680 datarootdir='$(prefix)/share')
3681 AC_SUBST(datarootdir)
3682
3683 AC_ARG_WITH(docdir,
3684 [  --with-docdir=DIR       Install documentation in DIR [[DATAROOTDIR]]],
3685 docdir="\${prefix}/$with_docdir",
3686 docdir='$(datarootdir)')
3687 AC_SUBST(docdir)
3688
3689 AC_ARG_WITH(htmldir,
3690 [  --with-htmldir=DIR      html documentation in in DIR [[DOCDIR]]],
3691 htmldir="\${prefix}/$with_htmldir",
3692 htmldir='$(docdir)')
3693 AC_SUBST(htmldir)
3694
3695 # Substitute configuration variables
3696 AC_SUBST(subdirs)
3697 AC_SUBST(srcdir)
3698 AC_SUBST(all_compilers)
3699 AC_SUBST(all_gtfiles)
3700 AC_SUBST(all_gtfiles_files_langs)
3701 AC_SUBST(all_gtfiles_files_files)
3702 AC_SUBST(all_lang_makefrags)
3703 AC_SUBST(all_lang_makefiles)
3704 AC_SUBST(all_languages)
3705 AC_SUBST(all_selected_languages)
3706 AC_SUBST(build_exeext)
3707 AC_SUBST(build_install_headers_dir)
3708 AC_SUBST(build_xm_file_list)
3709 AC_SUBST(build_xm_include_list)
3710 AC_SUBST(build_xm_defines)
3711 AC_SUBST(check_languages)
3712 AC_SUBST(cpp_install_dir)
3713 AC_SUBST(xmake_file)
3714 AC_SUBST(tmake_file)
3715 AC_SUBST(extra_gcc_objs)
3716 AC_SUBST(extra_headers_list)
3717 AC_SUBST(extra_objs)
3718 AC_SUBST(extra_parts)
3719 AC_SUBST(extra_passes)
3720 AC_SUBST(extra_programs)
3721 AC_SUBST(float_h_file)
3722 AC_SUBST(gcc_config_arguments)
3723 AC_SUBST(gcc_gxx_include_dir)
3724 AC_SUBST(host_exeext)
3725 AC_SUBST(host_xm_file_list)
3726 AC_SUBST(host_xm_include_list)
3727 AC_SUBST(host_xm_defines)
3728 AC_SUBST(out_host_hook_obj)
3729 AC_SUBST(install)
3730 AC_SUBST(lang_opt_files)
3731 AC_SUBST(lang_specs_files)
3732 AC_SUBST(lang_tree_files)
3733 AC_SUBST(local_prefix)
3734 AC_SUBST(md_file)
3735 AC_SUBST(objc_boehm_gc)
3736 AC_SUBST(out_file)
3737 AC_SUBST(out_object_file)
3738 AC_SUBST(thread_file)
3739 AC_SUBST(tm_file_list)
3740 AC_SUBST(tm_include_list)
3741 AC_SUBST(tm_defines)
3742 AC_SUBST(tm_p_file_list)
3743 AC_SUBST(tm_p_include_list)
3744 AC_SUBST(xm_file_list)
3745 AC_SUBST(xm_include_list)
3746 AC_SUBST(xm_defines)
3747 AC_SUBST(c_target_objs)
3748 AC_SUBST(cxx_target_objs)
3749 AC_SUBST(target_cpu_default)
3750
3751 AC_SUBST_FILE(language_hooks)
3752
3753 # Echo link setup.
3754 if test x${build} = x${host} ; then
3755   if test x${host} = x${target} ; then
3756     echo "Links are now set up to build a native compiler for ${target}." 1>&2
3757   else
3758     echo "Links are now set up to build a cross-compiler" 1>&2
3759     echo " from ${host} to ${target}." 1>&2
3760   fi
3761 else
3762   if test x${host} = x${target} ; then
3763     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
3764     echo " for ${target}." 1>&2
3765   else
3766     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
3767     echo " from ${host} to ${target}." 1>&2
3768   fi
3769 fi
3770
3771 AC_ARG_VAR(GMPLIBS,[How to link GMP])
3772 AC_ARG_VAR(GMPINC,[How to find GMP include files])
3773
3774 # Configure the subdirectories
3775 # AC_CONFIG_SUBDIRS($subdirs)
3776
3777 # Create the Makefile
3778 # and configure language subdirectories
3779 AC_CONFIG_FILES($all_outputs)
3780
3781 AC_CONFIG_COMMANDS([default],
3782 [
3783 case ${CONFIG_HEADERS} in
3784   *auto-host.h:config.in*)
3785   echo > cstamp-h ;;
3786 esac
3787 # Make sure all the subdirs exist.
3788 for d in $subdirs doc build
3789 do
3790     test -d $d || mkdir $d
3791 done
3792 ],
3793 [subdirs='$subdirs'])
3794 AC_OUTPUT