gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
   5 # Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 2, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING.  If not, write to the Free
  21 #Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  22 #02111-1307, USA.
  23
  24 # --------------------------------
  25 # Initialization and sanity checks
  26 # --------------------------------
  27
  28 AC_PREREQ(2.59)
  29 AC_INIT
  30 AC_CONFIG_SRCDIR(tree.c)
  31 AC_CONFIG_HEADER(auto-host.h:config.in)
  32
  33 #Set to 1 on a release branch
  34 is_release=
  35
  36 # Determine the host, build, and target systems
  37 AC_CANONICAL_BUILD
  38 AC_CANONICAL_HOST
  39 AC_CANONICAL_TARGET
  40
  41 # Determine the noncanonical target name, for directory use.
  42 ACX_NONCANONICAL_TARGET
  43
  44 # Determine the target- and build-specific subdirectories
  45 GCC_TOPLEV_SUBDIRS
  46
  47 # Set program_transform_name
  48 AC_ARG_PROGRAM
  49
  50 # Check for bogus environment variables.
  51 # Test if LIBRARY_PATH contains the notation for the current directory
  52 # since this would lead to problems installing/building glibc.
  53 # LIBRARY_PATH contains the current directory if one of the following
  54 # is true:
  55 # - one of the terminals (":" and ";") is the first or last sign
  56 # - two terminals occur directly after each other
  57 # - the path contains an element with a dot in it
  58 AC_MSG_CHECKING(LIBRARY_PATH variable)
  59 changequote(,)dnl
  60 case ${LIBRARY_PATH} in
  61   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  62     library_path_setting="contains current directory"
  63     ;;
  64   *)
  65     library_path_setting="ok"
  66     ;;
  67 esac
  68 changequote([,])dnl
  69 AC_MSG_RESULT($library_path_setting)
  70 if test "$library_path_setting" != "ok"; then
  71 AC_MSG_ERROR([
  72 *** LIBRARY_PATH shouldn't contain the current directory when
  73 *** building gcc. Please change the environment variable
  74 *** and run configure again.])
  75 fi
  76
  77 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  78 # since this would lead to problems installing/building glibc.
  79 # GCC_EXEC_PREFIX contains the current directory if one of the following
  80 # is true:
  81 # - one of the terminals (":" and ";") is the first or last sign
  82 # - two terminals occur directly after each other
  83 # - the path contains an element with a dot in it
  84 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  85 changequote(,)dnl
  86 case ${GCC_EXEC_PREFIX} in
  87   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  88     gcc_exec_prefix_setting="contains current directory"
  89     ;;
  90   *)
  91     gcc_exec_prefix_setting="ok"
  92     ;;
  93 esac
  94 changequote([,])dnl
  95 AC_MSG_RESULT($gcc_exec_prefix_setting)
  96 if test "$gcc_exec_prefix_setting" != "ok"; then
  97 AC_MSG_ERROR([
  98 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  99 *** building gcc. Please change the environment variable
 100 *** and run configure again.])
 101 fi
 102
 103 # -----------
 104 # Directories
 105 # -----------
 106
 107 # Specify the local prefix
 108 local_prefix=
 109 AC_ARG_WITH(local-prefix,
 110 [  --with-local-prefix=DIR specifies directory to put local include],
 111 [case "${withval}" in
 112 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 113 no)     ;;
 114 *)      local_prefix=$with_local_prefix ;;
 115 esac])
 116
 117 # Default local prefix if it is empty
 118 if test x$local_prefix = x; then
 119         local_prefix=/usr/local
 120 fi
 121
 122 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 123 # passed in by the toplevel make and thus we'd get different behavior
 124 # depending on where we built the sources.
 125 gcc_gxx_include_dir=
 126 # Specify the g++ header file directory
 127 AC_ARG_WITH(gxx-include-dir,
 128 [  --with-gxx-include-dir=DIR
 129                           specifies directory to put g++ header files],
 130 [case "${withval}" in
 131 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 132 no)     ;;
 133 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 134 esac])
 135
 136 if test x${gcc_gxx_include_dir} = x; then
 137   if test x${enable_version_specific_runtime_libs} = xyes; then
 138     gcc_gxx_include_dir='${libsubdir}/include/c++'
 139   else
 140     topsrcdir=${srcdir}/.. . ${srcdir}/../config.if
 141 changequote(<<, >>)dnl
 142     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/include/"${libstdcxx_incdir}
 143 changequote([, ])dnl
 144   fi
 145 fi
 146
 147 AC_ARG_WITH(cpp_install_dir,
 148 [  --with-cpp-install-dir=DIR
 149                           install the user visible C preprocessor in DIR
 150                           (relative to PREFIX) as well as PREFIX/bin],
 151 [if test x$withval = xyes; then
 152   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 153 elif test x$withval != xno; then
 154   cpp_install_dir=$withval
 155 fi])
 156
 157 # We would like to our source tree to be readonly.  However when releases or
 158 # pre-releases are generated, the flex/bison generated files as well as the
 159 # various formats of manuals need to be included along with the rest of the
 160 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 161 # just that.
 162
 163 AC_MSG_CHECKING([whether to place generated files in the source directory])
 164   dnl generated-files-in-srcdir is disabled by default
 165   AC_ARG_ENABLE(generated-files-in-srcdir,
 166 [  --enable-generated-files-in-srcdir
 167                           put copies of generated files in source dir
 168                           intended for creating source tarballs for users
 169                           without texinfo bison or flex.],
 170       generated_files_in_srcdir=$enableval,
 171       generated_files_in_srcdir=no)
 172
 173 AC_MSG_RESULT($generated_files_in_srcdir)
 174
 175 if test "$generated_files_in_srcdir" = "yes"; then
 176   GENINSRC=''
 177 else
 178   GENINSRC='#'
 179 fi
 180 AC_SUBST(GENINSRC)
 181
 182 # -------------------
 183 # Find default linker
 184 # -------------------
 185
 186 # With GNU ld
 187 AC_ARG_WITH(gnu-ld,
 188 [  --with-gnu-ld           arrange to work with GNU ld.],
 189 gnu_ld_flag="$with_gnu_ld",
 190 gnu_ld_flag=no)
 191
 192 # With pre-defined ld
 193 AC_ARG_WITH(ld,
 194 [  --with-ld               arrange to use the specified ld (full pathname)],
 195 DEFAULT_LINKER="$with_ld")
 196 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 197   if test ! -x "$DEFAULT_LINKER"; then
 198     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 199   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 200     gnu_ld_flag=yes
 201   fi
 202   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 203         [Define to enable the use of a default linker.])
 204 fi
 205
 206 AC_MSG_CHECKING([whether a default linker was specified])
 207 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 208   if test x"$gnu_ld_flag" = x"no"; then
 209     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 210   else
 211     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 212   fi
 213 else
 214   AC_MSG_RESULT(no)
 215 fi
 216
 217 # With demangler in GNU ld
 218 AC_ARG_WITH(demangler-in-ld,
 219 [  --with-demangler-in-ld  try to use demangler in GNU ld.],
 220 demangler_in_ld="$with_demangler_in_ld",
 221 demangler_in_ld=no)
 222
 223 # ----------------------
 224 # Find default assembler
 225 # ----------------------
 226
 227 # With GNU as
 228 AC_ARG_WITH(gnu-as,
 229 [  --with-gnu-as           arrange to work with GNU as],
 230 gas_flag="$with_gnu_as",
 231 gas_flag=no)
 232
 233 AC_ARG_WITH(as,
 234 [  --with-as               arrange to use the specified as (full pathname)],
 235 DEFAULT_ASSEMBLER="$with_as")
 236 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 237   if test ! -x "$DEFAULT_ASSEMBLER"; then
 238     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 239   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 240     gas_flag=yes
 241   fi
 242   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 243         [Define to enable the use of a default assembler.])
 244 fi
 245
 246 AC_MSG_CHECKING([whether a default assembler was specified])
 247 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 248   if test x"$gas_flag" = x"no"; then
 249     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 250   else
 251     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 252   fi
 253 else
 254   AC_MSG_RESULT(no)
 255 fi
 256
 257 # ---------------
 258 # Find C compiler
 259 # ---------------
 260
 261 # If a non-executable a.out is present (e.g. created by GNU as above even if
 262 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 263 # file, even when creating an executable, so an execution test fails.
 264 # Remove possible default executable files to avoid this.
 265 #
 266 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 267 # Autoconf includes it.
 268 rm -f a.out a.exe b.out
 269
 270 # Find the native compiler
 271 AC_PROG_CC
 272 AM_PROG_CC_C_O
 273 # autoconf is lame and doesn't give us any substitution variable for this.
 274 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 275   NO_MINUS_C_MINUS_O=yes
 276 else
 277   OUTPUT_OPTION='-o $@'
 278 fi
 279 AC_SUBST(NO_MINUS_C_MINUS_O)
 280 AC_SUBST(OUTPUT_OPTION)
 281
 282 # -------------------------
 283 # Check C compiler features
 284 # -------------------------
 285
 286 AC_PROG_CPP
 287 AC_C_INLINE
 288
 289 gcc_AC_C_LONG_LONG
 290
 291 # sizeof(char) is 1 by definition.
 292 AC_CHECK_SIZEOF(void *)
 293 AC_CHECK_SIZEOF(short)
 294 AC_CHECK_SIZEOF(int)
 295 AC_CHECK_SIZEOF(long)
 296 if test $ac_cv_c_long_long = yes; then
 297   AC_CHECK_SIZEOF(long long)
 298 fi
 299 if test $ac_cv_c___int64 = yes; then
 300   AC_CHECK_SIZEOF(__int64)
 301 fi
 302
 303 # ---------------------
 304 # Warnings and checking
 305 # ---------------------
 306
 307 # Check $CC warning features (if it's GCC).
 308 # We want to use -pedantic, but we don't want warnings about
 309 # * 'long long'
 310 # * variadic macros
 311 # So, we only use -pedantic if we can disable those warnings.
 312
 313 AC_CACHE_CHECK(
 314   [whether ${CC} accepts -Wno-long-long],
 315   [ac_cv_prog_cc_w_no_long_long],
 316   [save_CFLAGS="$CFLAGS"
 317   CFLAGS="-Wno-long-long"
 318   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 319                     [ac_cv_prog_cc_w_no_long_long=yes],
 320                     [ac_cv_prog_cc_w_no_long_long=no])
 321   CFLAGS="$save_CFLAGS"
 322   ])
 323
 324 AC_CACHE_CHECK(
 325   [whether ${CC} accepts -Wno-variadic-macros],
 326   [ac_cv_prog_cc_w_no_variadic_macros],
 327   [save_CFLAGS="$CFLAGS"
 328   CFLAGS="-Wno-variadic-macros"
 329   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 330                     [ac_cv_prog_cc_w_no_variadic_macros=yes],
 331                     [ac_cv_prog_cc_w_no_variadic_macros=no])
 332   CFLAGS="$save_CFLAGS"
 333   ])
 334
 335 strict1_warn=
 336 if test $ac_cv_prog_cc_w_no_long_long = yes \
 337    && test $ac_cv_prog_cc_w_no_variadic_macros = yes ; then
 338   strict1_warn="-pedantic -Wno-long-long -Wno-variadic-macros"
 339 fi
 340 AC_SUBST(strict1_warn)
 341
 342 # Add -Wold-style-definition if it's accepted
 343 AC_CACHE_CHECK(
 344   [whether ${CC} accepts -Wold-style-definition],
 345   [ac_cv_prog_cc_w_old_style_definition],
 346   [save_CFLAGS="$CFLAGS"
 347   CFLAGS="-Wold-style-definition"
 348   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 349                     [ac_cv_prog_cc_w_old_style_definition=yes],
 350                     [ac_cv_prog_cc_w_old_style_definition=no])
 351   CFLAGS="$save_CFLAGS"
 352   ])
 353 if test $ac_cv_prog_cc_w_old_style_definition = yes ; then
 354   strict1_warn="${strict1_warn} -Wold-style-definition"
 355 fi
 356
 357 # Enable -Werror, period.
 358 AC_ARG_ENABLE(werror_always,
 359 [  --enable-werror-always         enable -Werror always], [],
 360 [enable_werror_always=no])
 361 if test x${enable_werror_always} = xyes ; then
 362   strict1_warn="${strict1_warn} -Werror"
 363   WERROR=-Werror
 364 fi
 365
 366 # If the native compiler is GCC, we can enable warnings even in stage1.
 367 # That's useful for people building cross-compilers, or just running a
 368 # quick `make'.
 369 warn_cflags=
 370 if test "x$GCC" = "xyes"; then
 371   warn_cflags='$(GCC_WARN_CFLAGS)'
 372 fi
 373 AC_SUBST(warn_cflags)
 374
 375 # Enable -Werror in bootstrap stage2 and later.
 376 AC_ARG_ENABLE(werror,
 377 [  --enable-werror         enable -Werror in bootstrap stage2 and later], [],
 378 [if test x$is_release = x ; then
 379   # Default to "yes" on development branches.
 380   enable_werror=yes
 381 else
 382   # Default to "no" on release branches.
 383   enable_werror=no
 384 fi])
 385 if test x$enable_werror = xyes ; then
 386   WERROR=-Werror
 387 fi
 388 AC_SUBST(WERROR)
 389
 390 # Enable expensive internal checks
 391 AC_ARG_ENABLE(checking,
 392 [  --enable-checking[=LIST]
 393                           enable expensive run-time checks.  With LIST,
 394                           enable only specific categories of checks.
 395                           Categories are: assert,fold,gc,gcac,misc,
 396                           rtlflag,rtl,tree,valgrind,release,yes,all;],
 397 [ac_checking_flags="${enableval}"],[
 398 # Determine the default checks.
 399 if test x$is_release = x ; then
 400   ac_checking_flags=yes
 401 else
 402   ac_checking_flags=release
 403 fi])
 404 ac_assert_checking=1
 405 ac_checking=
 406 ac_tree_checking=
 407 ac_rtl_checking=
 408 ac_rtlflag_checking=
 409 ac_gc_checking=
 410 ac_gc_always_collect=
 411 ac_fold_checking=
 412 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 413 for check in $ac_checking_flags
 414 do
 415         case $check in
 416         yes)            ac_assert_checking=1 ; ac_checking=1 ;
 417                         ac_tree_checking=1 ; ac_gc_checking=1 ;
 418                         ac_rtlflag_checking=1 ;;
 419         no)             ac_assert_checking= ; ac_checking= ;
 420                         ac_tree_checking= ; ac_rtl_checking= ;
 421                         ac_rtlflag_checking= ; ac_gc_checking= ;
 422                         ac_gc_always_collect= ; ac_fold_checking= ;;
 423         all)            ac_assert_checking=1 ; ac_checking=1 ;
 424                         ac_tree_checking=1 ; ac_rtl_checking=1 ;
 425                         ac_rtlflag_checking=1 ; ac_gc_checking=1 ;
 426                         ac_gc_always_collect=1 ; ac_fold_checking=1 ;;
 427         release)        ac_assert_checking=1 ;;
 428         assert)         ac_assert_checking=1 ;;
 429         fold)           ac_fold_checking=1 ;;
 430         gc)             ac_gc_checking=1 ;;
 431         gcac)           ac_gc_always_collect=1 ;;
 432         misc)           ac_checking=1 ;;
 433         rtlflag)        ac_rtlflag_checking=1 ;;
 434         rtl)            ac_rtl_checking=1 ;;
 435         tree)           ac_tree_checking=1 ;;
 436         valgrind)       ac_checking_valgrind=1 ;;
 437         *)      AC_MSG_ERROR(unknown check category $check) ;;
 438         esac
 439 done
 440 IFS="$ac_save_IFS"
 441
 442 nocommon_flag=""
 443 if test x$ac_checking != x ; then
 444   AC_DEFINE(ENABLE_CHECKING, 1,
 445 [Define if you want more run-time sanity checks.  This one gets a grab
 446    bag of miscellaneous but relatively cheap checks.])
 447   nocommon_flag=-fno-common
 448 fi
 449 AC_SUBST(nocommon_flag)
 450 if test x$ac_assert_checking != x ; then
 451   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 452 [Define if you want assertions enabled.  This is a cheap check.])
 453 fi
 454 if test x$ac_tree_checking != x ; then
 455   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 456 [Define if you want all operations on trees (the basic data
 457    structure of the front ends) to be checked for dynamic type safety
 458    at runtime.  This is moderately expensive.  The tree browser debugging
 459    routines will also be enabled by this option.
 460    ])
 461   TREEBROWSER=tree-browser.o
 462 fi
 463 AC_SUBST(TREEBROWSER)
 464 if test x$ac_rtl_checking != x ; then
 465   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 466 [Define if you want all operations on RTL (the basic data structure
 467    of the optimizer and back end) to be checked for dynamic type safety
 468    at runtime.  This is quite expensive.])
 469 fi
 470 if test x$ac_rtlflag_checking != x ; then
 471   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 472 [Define if you want RTL flag accesses to be checked against the RTL
 473    codes that are supported for each access macro.  This is relatively
 474    cheap.])
 475 fi
 476 if test x$ac_gc_checking != x ; then
 477   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 478 [Define if you want the garbage collector to do object poisoning and
 479    other memory allocation checks.  This is quite expensive.])
 480 fi
 481 if test x$ac_gc_always_collect != x ; then
 482   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 483 [Define if you want the garbage collector to operate in maximally
 484    paranoid mode, validating the entire heap and collecting garbage at
 485    every opportunity.  This is extremely expensive.])
 486 fi
 487 if test x$ac_fold_checking != x ; then
 488   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 489 [Define if you want fold checked that it never destructs its argument.
 490    This is quite expensive.])
 491 fi
 492 valgrind_path_defines=
 493 valgrind_command=
 494
 495 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 496 dnl # an if statement.  This was the source of very frustrating bugs
 497 dnl # in converting to autoconf 2.5x!
 498 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 499
 500 if test x$ac_checking_valgrind != x ; then
 501   # It is certainly possible that there's valgrind but no valgrind.h.
 502   # GCC relies on making annotations so we must have both.
 503   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 504   AC_TRY_CPP(
 505     [#include <valgrind/memcheck.h>
 506 #ifndef VALGRIND_DISCARD
 507 #error VALGRIND_DISCARD not defined
 508 #endif],
 509   [gcc_cv_header_valgrind_memcheck_h=yes],
 510   [gcc_cv_header_valgrind_memcheck_h=no])
 511   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 512   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 513   AC_TRY_CPP(
 514     [#include <memcheck.h>
 515 #ifndef VALGRIND_DISCARD
 516 #error VALGRIND_DISCARD not defined
 517 #endif],
 518   [gcc_cv_header_memcheck_h=yes],
 519   gcc_cv_header_memcheck_h=no)
 520   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 521   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 522         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 523   if test "x$valgrind_path" = "x" \
 524     || (test $have_valgrind_h = no \
 525         && test $gcc_cv_header_memcheck_h = no \
 526         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 527         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 528   fi
 529   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 530   valgrind_command="$valgrind_path -q"
 531   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 532 [Define if you want to run subprograms and generated programs
 533    through valgrind (a memory checker).  This is extremely expensive.])
 534   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 535     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 536         [Define if valgrind's valgrind/memcheck.h header is installed.])
 537   fi
 538   if test $gcc_cv_header_memcheck_h = yes; then
 539     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 540         [Define if valgrind's memcheck.h header is installed.])
 541   fi
 542 fi
 543 AC_SUBST(valgrind_path_defines)
 544 AC_SUBST(valgrind_command)
 545
 546 AC_ARG_ENABLE(mapped-location,
 547 [  --enable-mapped-location   location_t is fileline integer cookie],,
 548 enable_mapped_location=no)
 549
 550 if test "$enable_mapped_location" = yes ; then
 551   AC_DEFINE(USE_MAPPED_LOCATION, 1,
 552 [Define if location_t is fileline integer cookie.])
 553 fi
 554
 555 # Enable code coverage collection
 556 AC_ARG_ENABLE(coverage,
 557 [  --enable-coverage[=LEVEL]
 558                           enable compiler's code coverage collection.
 559                           Use to measure compiler performance and locate
 560                           unused parts of the compiler. With LEVEL, specify
 561                           optimization. Values are opt, noopt,
 562                           default is noopt],
 563 [case "${enableval}" in
 564   yes|noopt)
 565     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 566     ;;
 567   opt)
 568     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 569     ;;
 570   no)
 571     # a.k.a. --disable-coverage
 572     coverage_flags=""
 573     ;;
 574   *)
 575     AC_MSG_ERROR(unknown coverage setting $enableval)
 576     ;;
 577 esac],
 578 [coverage_flags=""])
 579 AC_SUBST(coverage_flags)
 580
 581 AC_ARG_ENABLE(gather-detailed-mem-stats,
 582 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
 583 [enable_gather_detailed_mem_stats=no])
 584 if test x$enable_gather_detailed_mem_stats = xyes ; then
 585   AC_DEFINE(GATHER_STATISTICS, 1,
 586         [Define to enable detailed memory allocation stats gathering.])
 587 fi
 588
 589 # -------------------------------
 590 # Miscenalleous configure options
 591 # -------------------------------
 592
 593 # With stabs
 594 AC_ARG_WITH(stabs,
 595 [  --with-stabs            arrange to use stabs instead of host debug format],
 596 stabs="$with_stabs",
 597 stabs=no)
 598
 599 # Determine whether or not multilibs are enabled.
 600 AC_ARG_ENABLE(multilib,
 601 [  --enable-multilib       enable library support for multiple ABIs],
 602 [], [enable_multilib=yes])
 603 AC_SUBST(enable_multilib)
 604
 605 # Enable __cxa_atexit for C++.
 606 AC_ARG_ENABLE(__cxa_atexit,
 607 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 608 [], [])
 609
 610 # Enable threads
 611 # Pass with no value to take the default
 612 # Pass with a value to specify a thread package
 613 AC_ARG_ENABLE(threads,
 614 [  --enable-threads        enable thread usage for target GCC
 615   --enable-threads=LIB    use LIB thread package for target GCC],,
 616 [enable_threads=''])
 617
 618 AC_ARG_ENABLE(objc-gc,
 619 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 620                           the GNU Objective-C runtime],
 621 if test x$enable_objc_gc = xno; then
 622         objc_boehm_gc=''
 623 else
 624         objc_boehm_gc=1
 625 fi,
 626 objc_boehm_gc='')
 627
 628 AC_ARG_WITH(dwarf2,
 629 [  --with-dwarf2           force the default debug format to be DWARF 2],
 630 dwarf2="$with_dwarf2",
 631 dwarf2=no)
 632
 633 AC_ARG_ENABLE(shared,
 634 [  --disable-shared        don't provide a shared libgcc],
 635 [
 636   case $enable_shared in
 637   yes | no) ;;
 638   *)
 639     enable_shared=no
 640     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 641     for pkg in $enableval; do
 642       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 643         enable_shared=yes
 644       fi
 645     done
 646     IFS="$ac_save_ifs"
 647     ;;
 648   esac
 649 ], [enable_shared=yes])
 650 AC_SUBST(enable_shared)
 651
 652 AC_ARG_WITH(sysroot,
 653 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 654 [
 655  case ${with_sysroot} in
 656  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 657  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 658  esac
 659
 660  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 661  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)'
 662
 663  if test "x$exec_prefix" = xNONE; then
 664   if test "x$prefix" = xNONE; then
 665    test_prefix=/usr/local
 666   else
 667    test_prefix=$prefix
 668   fi
 669  else
 670   test_prefix=$exec_prefix
 671  fi
 672  case ${TARGET_SYSTEM_ROOT} in
 673  "${test_prefix}"|"${test_prefix}/"*|\
 674  '${exec_prefix}'|'${exec_prefix}/'*)
 675    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 676    TARGET_SYSTEM_ROOT_DEFINE="$t"
 677    ;;
 678  esac
 679 ], [
 680  TARGET_SYSTEM_ROOT=
 681  TARGET_SYSTEM_ROOT_DEFINE=
 682  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 683 ])
 684 AC_SUBST(TARGET_SYSTEM_ROOT)
 685 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 686 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 687
 688 # Build with intermodule optimisations
 689 AC_ARG_ENABLE(intermodule,
 690 [  --enable-intermodule    build the compiler in one step],
 691 [case ${enable_intermodule} in
 692   yes) onestep="-onestep";;
 693   *) onestep="";;
 694 esac],
 695 [onestep=""])
 696 AC_SUBST(onestep)
 697
 698 # Sanity check enable_languages in case someone does not run the toplevel
 699 # configure # script.
 700 AC_ARG_ENABLE(languages,
 701 [  --enable-languages=LIST specify which front-ends to build],
 702 [case ,${enable_languages}, in
 703        ,,|,yes,)
 704                 # go safe -- we cannot be much sure without the toplevel
 705                 # configure's
 706                 # analysis of which target libs are present and usable
 707                 enable_languages=c
 708                 ;;
 709          *,all,*)
 710                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 711                 ;;
 712         *,c,*)
 713                 ;;
 714         *)
 715                 enable_languages=c,${enable_languages}
 716                 ;;
 717 esac],
 718 [enable_languages=c])
 719
 720 subdirs=
 721 for lang in ${srcdir}/*/config-lang.in
 722 do
 723         case $lang in
 724         # The odd quoting in the next line works around
 725         # an apparent bug in bash 1.12 on linux.
 726 changequote(,)dnl
 727         ${srcdir}/[*]/config-lang.in) ;;
 728         *)
 729           lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
 730           if test "x$lang_alias" = x
 731           then
 732                 echo "$lang doesn't set \$language." 1>&2
 733                 exit 1
 734           fi
 735           case ",$enable_languages," in
 736           *,$lang_alias,*)
 737             subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`" ;;
 738           esac
 739           ;;
 740 changequote([,])dnl
 741         esac
 742 done
 743
 744
 745 # -------------------------
 746 # Checks for other programs
 747 # -------------------------
 748
 749 AC_PROG_MAKE_SET
 750
 751 # Find some useful tools
 752 AC_PROG_AWK
 753 # We need awk to create options.c and options.h.
 754 # Bail out if it's missing.
 755 case ${AWK} in
 756   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 757 esac
 758
 759 gcc_AC_PROG_LN_S
 760 ACX_PROG_LN($LN_S)
 761 AC_PROG_RANLIB
 762 case "${host}" in
 763 *-*-darwin*)
 764   # By default, the Darwin ranlib will not treat common symbols as
 765   # definitions when  building the archive table of contents.  Other
 766   # ranlibs do that; pass an option to the Darwin ranlib that makes
 767   # it behave similarly.
 768   ranlib_flags="-c"
 769   ;;
 770 *)
 771   ranlib_flags=""
 772 esac
 773 AC_SUBST(ranlib_flags)
 774
 775 gcc_AC_PROG_INSTALL
 776
 777 # See if cmp has --ignore-initial.
 778 gcc_AC_PROG_CMP_IGNORE_INITIAL
 779
 780 # See if we have the mktemp command.
 781 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 782
 783 MISSING="${CONFIG_SHELL-/bin/sh} $srcdir/../missing"
 784
 785 # See if makeinfo has been installed and is modern enough
 786 # that we can use it.
 787 gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 788   [GNU texinfo.* \([0-9][0-9.]*\)],
 789   [4.[2-9]*])
 790 if test $gcc_cv_prog_makeinfo_modern = no; then
 791   MAKEINFO="$MISSING makeinfo"
 792   AC_MSG_WARN([
 793 *** Makeinfo is missing or too old.
 794 *** Info documentation will not be built.])
 795   BUILD_INFO=
 796 else
 797   BUILD_INFO=info
 798 fi
 799 AC_SUBST(BUILD_INFO)
 800
 801 # Is pod2man recent enough to regenerate manpages?
 802 AC_MSG_CHECKING([for recent Pod::Man])
 803 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 804   AC_MSG_RESULT(yes)
 805   GENERATED_MANPAGES=generated-manpages
 806 else
 807   AC_MSG_RESULT(no)
 808   GENERATED_MANPAGES=
 809 fi
 810 AC_SUBST(GENERATED_MANPAGES)
 811
 812 # How about lex?
 813 dnl Don't use AC_PROG_LEX; we insist on flex.
 814 dnl LEXLIB is not useful in gcc.
 815 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
 816
 817 # Bison?
 818 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
 819
 820 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
 821 # check for build == host before using them.
 822
 823 # NM
 824 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
 825   && test -d ../binutils ; then
 826   NM='$(objdir)/../binutils/nm-new'
 827 else
 828   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
 829 fi
 830
 831 # AR
 832 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
 833   && test -d ../binutils ; then
 834   AR='$(objdir)/../binutils/ar'
 835 else
 836   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
 837 fi
 838
 839
 840 # --------------------
 841 # Checks for C headers
 842 # --------------------
 843
 844 AC_MSG_CHECKING(for GNU C library)
 845 AC_CACHE_VAL(gcc_cv_glibc,
 846 [AC_TRY_COMPILE(
 847   [#include <features.h>],[
 848 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 849 #error Not a GNU C library system
 850 #endif],
 851   [gcc_cv_glibc=yes],
 852   gcc_cv_glibc=no)])
 853 AC_MSG_RESULT($gcc_cv_glibc)
 854 if test $gcc_cv_glibc = yes; then
 855   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 856 fi
 857
 858 # Need to reject headers which give warnings, so that the -Werror bootstrap
 859 # works later. *sigh*  This needs to come before all header checks.
 860 AC_PROG_CPP_WERROR
 861
 862 AC_HEADER_STDC
 863 AC_HEADER_TIME
 864 ACX_HEADER_STRING
 865 AC_HEADER_SYS_WAIT
 866 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
 867                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 868                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 869                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 870
 871 # Check for thread headers.
 872 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 873 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 874
 875 # These tests can't be done till we know if we have limits.h.
 876 gcc_AC_C_CHAR_BIT
 877 AC_C_BIGENDIAN_CROSS
 878
 879 # --------
 880 # UNSORTED
 881 # --------
 882
 883 # Stage specific cflags for build.
 884 stage1_cflags=
 885 case $build in
 886 vax-*-*)
 887   if test x$GCC = xyes
 888   then
 889     stage1_cflags="-Wa,-J"
 890   else
 891     stage1_cflags="-J"
 892   fi
 893   ;;
 894 powerpc-*-darwin*)
 895   # The spiffy cpp-precomp chokes on some legitimate constructs in GCC
 896   # sources; use -no-cpp-precomp to get to GNU cpp.
 897   # Apple's GCC has bugs in designated initializer handling, so disable
 898   # that too.
 899   stage1_cflags="-no-cpp-precomp -DHAVE_DESIGNATED_INITIALIZERS=0"
 900   ;;
 901 esac
 902 AC_SUBST(stage1_cflags)
 903
 904 # These libraries may be used by collect2.
 905 # We may need a special search path to get them linked.
 906 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 907 [save_LIBS="$LIBS"
 908 for libs in '' -lld -lmld \
 909                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 910                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 911 do
 912         LIBS="$libs"
 913         AC_TRY_LINK_FUNC(ldopen,
 914                 [gcc_cv_collect2_libs="$libs"; break])
 915 done
 916 LIBS="$save_LIBS"
 917 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 918 case $gcc_cv_collect2_libs in
 919         "none required")        ;;
 920         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 921 esac
 922 AC_SUBST(COLLECT2_LIBS)
 923
 924 # When building Ada code on Alpha, we need exc_resume which is usually in
 925 # -lexc.  So test for it.
 926 save_LIBS="$LIBS"
 927 LIBS=
 928 AC_SEARCH_LIBS(exc_resume, exc)
 929 GNAT_LIBEXC="$LIBS"
 930 LIBS="$save_LIBS"
 931 AC_SUBST(GNAT_LIBEXC)
 932
 933 # Some systems put ldexp and frexp in libm instead of libc; assume
 934 # they're both in the same place.  jcf-dump needs them.
 935 save_LIBS="$LIBS"
 936 LIBS=
 937 AC_SEARCH_LIBS(ldexp, m)
 938 LDEXP_LIB="$LIBS"
 939 LIBS="$save_LIBS"
 940 AC_SUBST(LDEXP_LIB)
 941
 942 # Use <inttypes.h> only if it exists,
 943 # doesn't clash with <sys/types.h>, and declares intmax_t.
 944 AC_MSG_CHECKING(for inttypes.h)
 945 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 946 [AC_TRY_COMPILE(
 947   [#include <sys/types.h>
 948 #include <inttypes.h>],
 949   [intmax_t i = -1;],
 950   [gcc_cv_header_inttypes_h=yes],
 951   gcc_cv_header_inttypes_h=no)])
 952 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 953 if test $gcc_cv_header_inttypes_h = yes; then
 954   AC_DEFINE(HAVE_INTTYPES_H, 1,
 955         [Define if you have a working <inttypes.h> header file.])
 956 fi
 957
 958 dnl Disabled until we have a complete test for buggy enum bitfields.
 959 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 960
 961 AC_CHECK_FUNCS(times clock dup2 kill getrlimit setrlimit atoll atoq \
 962         sysconf strsignal putc_unlocked fputc_unlocked fputs_unlocked \
 963         fwrite_unlocked fprintf_unlocked getrusage nl_langinfo \
 964         scandir alphasort gettimeofday mbstowcs wcswidth mmap mincore \
 965         setlocale)
 966
 967 if test x$ac_cv_func_mbstowcs = xyes; then
 968   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
 969 [    AC_TRY_RUN([#include <stdlib.h>
 970 int main()
 971 {
 972   mbstowcs(0, "", 0);
 973   return 0;
 974 }],
 975     gcc_cv_func_mbstowcs_works=yes,
 976     gcc_cv_func_mbstowcs_works=no,
 977     gcc_cv_func_mbstowcs_works=yes)])
 978   if test x$gcc_cv_func_mbstowcs_works = xyes; then
 979     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
 980   [Define this macro if mbstowcs does not crash when its
 981    first argument is NULL.])
 982   fi
 983 fi
 984
 985 AC_CHECK_TYPE(ssize_t, int)
 986
 987 # Try to determine the array type of the second argument of getgroups
 988 # for the target system (int or gid_t).
 989 AC_TYPE_GETGROUPS
 990 if test "${target}" = "${build}"; then
 991   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
 992 else
 993   case "${target}" in
 994         # This condition may need some tweaking.  It should include all
 995         # targets where the array type of the second argument of getgroups
 996         # is int and the type of gid_t is not equivalent to int.
 997         *-*-sunos* | *-*-ultrix*)
 998                 TARGET_GETGROUPS_T=int
 999                 ;;
1000         *)
1001                 TARGET_GETGROUPS_T=gid_t
1002                 ;;
1003   esac
1004 fi
1005 AC_SUBST(TARGET_GETGROUPS_T)
1006
1007 gcc_AC_FUNC_PRINTF_PTR
1008 gcc_AC_FUNC_MMAP_BLACKLIST
1009
1010 case "${host}" in
1011 *-*-*vms*)
1012   # Under VMS, vfork works very differently than on Unix. The standard test
1013   # won't work, and it isn't easily adaptable. It makes more sense to
1014   # just force it.
1015   ac_cv_func_vfork_works=yes
1016   ;;
1017 esac
1018 AC_FUNC_VFORK
1019
1020 AM_ICONV
1021 # Until we have in-tree GNU iconv:
1022 LIBICONV_DEP=
1023 AC_SUBST(LIBICONV_DEP)
1024
1025 AM_LC_MESSAGES
1026
1027 AM_LANGINFO_CODESET
1028
1029 # We will need to find libiberty.h and ansidecl.h
1030 saved_CFLAGS="$CFLAGS"
1031 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1032 gcc_AC_CHECK_DECLS(getenv atol sbrk abort atof getcwd getwd \
1033         strsignal putc_unlocked fputs_unlocked fwrite_unlocked \
1034         fprintf_unlocked strstr errno snprintf vasprintf \
1035         malloc realloc calloc free basename getopt clock getpagesize, , ,[
1036 #include "ansidecl.h"
1037 #include "system.h"])
1038
1039 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1040 #include "ansidecl.h"
1041 #include "system.h"
1042 #ifdef HAVE_SYS_RESOURCE_H
1043 #include <sys/resource.h>
1044 #endif
1045 ])
1046
1047 AC_TRY_COMPILE([
1048 #include "ansidecl.h"
1049 #include "system.h"
1050 #ifdef HAVE_SYS_RESOURCE_H
1051 #include <sys/resource.h>
1052 #endif
1053 ],[rlim_t l = 0;],,[AC_DEFINE([rlim_t],[long],
1054 [Define to \`long' if <sys/resource.h> doesn't define.])])
1055
1056 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1057 #include "ansidecl.h"
1058 #include "system.h"
1059 #ifdef HAVE_LDFCN_H
1060 #include <ldfcn.h>
1061 #endif
1062 ])
1063
1064 gcc_AC_CHECK_DECLS(times, , ,[
1065 #include "ansidecl.h"
1066 #include "system.h"
1067 #ifdef HAVE_SYS_TIMES_H
1068 #include <sys/times.h>
1069 #endif
1070 ])
1071
1072 # More time-related stuff.
1073 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1074 AC_TRY_COMPILE([
1075 #include "ansidecl.h"
1076 #include "system.h"
1077 #ifdef HAVE_SYS_TIMES_H
1078 #include <sys/times.h>
1079 #endif
1080 ], [struct tms tms;], ac_cv_struct_tms=yes, ac_cv_struct_tms=no)])
1081 if test $ac_cv_struct_tms = yes; then
1082   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1083   [Define if <sys/times.h> defines struct tms.])
1084 fi
1085
1086 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1087 # revisit after autoconf 2.50.
1088 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1089 AC_TRY_COMPILE([
1090 #include "ansidecl.h"
1091 #include "system.h"
1092 ], [clock_t x;], gcc_cv_type_clock_t=yes, gcc_cv_type_clock_t=no)])
1093 if test $gcc_cv_type_clock_t = yes; then
1094   AC_DEFINE(HAVE_CLOCK_T, 1,
1095   [Define if <time.h> defines clock_t.])
1096 fi
1097
1098 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1099 CFLAGS="$saved_CFLAGS"
1100
1101 gcc_AC_INITFINI_ARRAY
1102
1103 # mkdir takes a single argument on some systems.
1104 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1105
1106 # File extensions
1107 manext='.1'
1108 objext='.o'
1109 AC_SUBST(manext)
1110 AC_SUBST(objext)
1111
1112 # With Setjmp/Longjmp based exception handling.
1113 AC_ARG_ENABLE(sjlj-exceptions,
1114 [  --enable-sjlj-exceptions
1115                           arrange to use setjmp/longjmp exception handling],
1116 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1117 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1118   [Define 0/1 to force the choice for exception handling model.])])
1119
1120 # For platforms with the unwind ABI which includes an unwind library,
1121 # libunwind, we can choose to use the system libunwind.
1122 AC_ARG_WITH(system-libunwind,
1123 [  --with-system-libunwind use installed libunwind])
1124
1125 # --------------------------------------------------------
1126 # Build, host, and target specific configuration fragments
1127 # --------------------------------------------------------
1128
1129 # Collect build-machine-specific information.
1130 . ${srcdir}/config.build
1131
1132 # Collect host-machine-specific information.
1133 . ${srcdir}/config.host
1134
1135 target_gtfiles=
1136
1137 # Collect target-machine-specific information.
1138 . ${srcdir}/config.gcc
1139
1140 extra_objs="${host_extra_objs} ${extra_objs}"
1141 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1142
1143 # Default the target-machine variables that were not explicitly set.
1144 if test x"$tm_file" = x
1145 then tm_file=$cpu_type/$cpu_type.h; fi
1146
1147 if test x"$extra_headers" = x
1148 then extra_headers=; fi
1149
1150 if test x$md_file = x
1151 then md_file=$cpu_type/$cpu_type.md; fi
1152
1153 if test x$out_file = x
1154 then out_file=$cpu_type/$cpu_type.c; fi
1155
1156 if test x"$tmake_file" = x
1157 then tmake_file=$cpu_type/t-$cpu_type
1158 fi
1159
1160 if test x"$dwarf2" = xyes
1161 then tm_file="$tm_file tm-dwarf2.h"
1162 fi
1163
1164 # Say what files are being used for the output code and MD file.
1165 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1166 echo "Using \`$srcdir/config/$md_file' as machine description file."
1167
1168 # If any of the xm_file variables contain nonexistent files, warn
1169 # about them and drop them.
1170
1171 bx=
1172 for x in $build_xm_file; do
1173   if    test -f $srcdir/config/$x
1174   then      bx="$bx $x"
1175   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1176   fi
1177 done
1178 build_xm_file="$bx"
1179
1180 hx=
1181 for x in $host_xm_file; do
1182   if    test -f $srcdir/config/$x
1183   then      hx="$hx $x"
1184   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1185   fi
1186 done
1187 host_xm_file="$hx"
1188
1189 tx=
1190 for x in $xm_file; do
1191   if    test -f $srcdir/config/$x
1192   then      tx="$tx $x"
1193   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1194   fi
1195 done
1196 xm_file="$tx"
1197
1198 count=a
1199 for f in $tm_file; do
1200         count=${count}x
1201 done
1202 if test $count = ax; then
1203         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1204 else
1205         echo "Using the following target machine macro files:"
1206         for f in $tm_file; do
1207                 echo "  $srcdir/config/$f"
1208         done
1209 fi
1210
1211 if test x$need_64bit_hwint = xyes; then
1212         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1213 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1214 fi
1215
1216 if test x$use_long_long_for_widest_fast_int = xyes; then
1217         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1218 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1219 efficiently supported by the host hardware.])
1220 fi
1221
1222 count=a
1223 for f in $host_xm_file; do
1224         count=${count}x
1225 done
1226 if test $count = a; then
1227         :
1228 elif test $count = ax; then
1229         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1230 else
1231         echo "Using the following host machine macro files:"
1232         for f in $host_xm_file; do
1233                 echo "  $srcdir/config/$f"
1234         done
1235 fi
1236 echo "Using ${out_host_hook_obj} for host machine hooks."
1237
1238 if test "$host_xm_file" != "$build_xm_file"; then
1239         count=a
1240         for f in $build_xm_file; do
1241                 count=${count}x
1242         done
1243         if test $count = a; then
1244                 :
1245         elif test $count = ax; then
1246                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1247         else
1248                 echo "Using the following build machine macro files:"
1249                 for f in $build_xm_file; do
1250                         echo "  $srcdir/config/$f"
1251                 done
1252         fi
1253 fi
1254
1255 # ---------
1256 # Threading
1257 # ---------
1258
1259 # Check if a valid thread package
1260 case ${enable_threads} in
1261   "" | no)
1262     # No threads
1263     target_thread_file='single'
1264     ;;
1265   yes)
1266     # default
1267     target_thread_file='single'
1268     ;;
1269   aix | dce | gnat | irix | posix | rtems | \
1270   single | solaris | vxworks | win32 )
1271     target_thread_file=${enable_threads}
1272     ;;
1273   *)
1274     echo "${enable_threads} is an unknown thread package" 1>&2
1275     exit 1
1276     ;;
1277 esac
1278
1279 if test x${thread_file} = x; then
1280   # No thread file set by target-specific clauses in config.gcc,
1281   # so use file chosen by default logic above
1282   thread_file=${target_thread_file}
1283 fi
1284
1285 # Make gthr-default.h if we have a thread file.
1286 gthread_flags=
1287 if test $thread_file != single; then
1288   rm -f gthr-default.h
1289   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
1290   gthread_flags=-DHAVE_GTHR_DEFAULT
1291 fi
1292 AC_SUBST(gthread_flags)
1293
1294 # --------
1295 # UNSORTED
1296 # --------
1297
1298 if test x$enable___cxa_atexit = xyes || \
1299    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1300    AC_CHECK_FUNC(__cxa_atexit,
1301         [AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 1,
1302         [Define if you want to use __cxa_atexit, rather than atexit, to
1303         register C++ destructors for local statics and global objects.
1304         This is essential for fully standards-compliant handling of
1305         destructors, but requires __cxa_atexit in libc.])],
1306         echo "__cxa_atexit can't be enabled on this target")
1307 fi
1308
1309 # Look for a file containing extra machine modes.
1310 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1311   extra_modes_file='$(srcdir)'/config/${extra_modes}
1312   AC_SUBST(extra_modes_file)
1313   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1314   [Define to the name of a file containing a list of extra machine modes
1315    for this architecture.])
1316 fi
1317
1318 # auto-host.h is the file containing items generated by autoconf and is
1319 # the first file included by config.h.
1320 # If host=build, it is correct to have bconfig include auto-host.h
1321 # as well.  If host!=build, we are in error and need to do more
1322 # work to find out the build config parameters.
1323 if test x$host = x$build
1324 then
1325         build_auto=auto-host.h
1326 else
1327         # We create a subdir, then run autoconf in the subdir.
1328         # To prevent recursion we set host and build for the new
1329         # invocation of configure to the build for this invocation
1330         # of configure.
1331         tempdir=build.$$
1332         rm -rf $tempdir
1333         mkdir $tempdir
1334         cd $tempdir
1335         case ${srcdir} in
1336         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1337         *) realsrcdir=../${srcdir};;
1338         esac
1339         saved_CFLAGS="${CFLAGS}"
1340         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1341         ${realsrcdir}/configure \
1342                 --enable-languages=${enable_languages-all} \
1343                 --target=$target_alias --host=$build_alias --build=$build_alias
1344         CFLAGS="${saved_CFLAGS}"
1345
1346         # We just finished tests for the build machine, so rename
1347         # the file auto-build.h in the gcc directory.
1348         mv auto-host.h ../auto-build.h
1349         cd ..
1350         rm -rf $tempdir
1351         build_auto=auto-build.h
1352 fi
1353 AC_SUBST(build_subdir)
1354
1355 tm_file="${tm_file} defaults.h"
1356 tm_p_file="${tm_p_file} tm-preds.h"
1357 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1358 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1359 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1360 # put this back in temporarily.
1361 xm_file="ansidecl.h ${xm_file}"
1362
1363 # --------
1364 # UNSORTED
1365 # --------
1366
1367 # Get the version trigger filename from the toplevel
1368 if test "${with_gcc_version_trigger+set}" = set; then
1369         gcc_version_trigger=$with_gcc_version_trigger
1370 else
1371         gcc_version_trigger=${srcdir}/version.c
1372 fi
1373 changequote(,)dnl
1374 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*"\([^"]*\)".*/\1/'`
1375 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
1376
1377 # Compile in configure arguments.
1378 if test -f configargs.h ; then
1379         # Being re-configured.
1380         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1381         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1382 else
1383         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1384 fi
1385
1386 # Double all backslashes and backslash all quotes to turn
1387 # gcc_config_arguments into a C string.
1388 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1389 $gcc_config_arguments
1390 EOF
1391 gcc_config_arguments_str=`cat conftest.out`
1392 rm -f conftest.out
1393
1394 cat > configargs.h <<EOF
1395 /* Generated automatically. */
1396 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1397 static const char thread_model[] = "$thread_file";
1398
1399 static const struct {
1400   const char *name, *value;
1401 } configure_default_options[] = $configure_default_options;
1402 EOF
1403 changequote([,])dnl
1404
1405 # Internationalization
1406 PACKAGE=gcc
1407 VERSION="$gcc_version"
1408 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE",
1409   [The name of this program for internationalization purposes.])
1410 AC_SUBST(PACKAGE)
1411 AC_SUBST(VERSION)
1412
1413 ZW_GNU_GETTEXT_SISTER_DIR
1414
1415 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1416 # -liconv on the link line twice.
1417 case "$LIBINTL" in *$LIBICONV*)
1418         LIBICONV= ;;
1419 esac
1420
1421 # Windows32 Registry support for specifying GCC installation paths.
1422 AC_ARG_ENABLE(win32-registry,
1423 [  --disable-win32-registry
1424                           disable lookup of installation paths in the
1425                           Registry on Windows hosts
1426   --enable-win32-registry enable registry lookup (default)
1427   --enable-win32-registry=KEY
1428                           use KEY instead of GCC version as the last portion
1429                           of the registry key],,)
1430 case $host_os in
1431         win32 | pe | cygwin* | mingw32* | uwin*)
1432 AC_MSG_CHECKING(whether windows registry support is requested)
1433 if test "x$enable_win32_registry" != xno; then
1434   AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1435 [Define to 1 if installation paths should be looked up in Windows32
1436    Registry. Ignored on non windows32 hosts.])
1437   AC_MSG_RESULT(yes)
1438   AC_SEARCH_LIBS(RegOpenKeyExA, advapi32)
1439 else
1440   AC_MSG_RESULT(no)
1441 fi
1442
1443 # Check if user specified a different registry key.
1444 case "x${enable_win32_registry}" in
1445 x | xyes)
1446   # default.
1447   gcc_cv_win32_registry_key="$VERSION"
1448   ;;
1449 xno)
1450   # no registry lookup.
1451   gcc_cv_win32_registry_key=''
1452   ;;
1453 *)
1454   # user-specified key.
1455   gcc_cv_win32_registry_key="$enable_win32_registry"
1456   ;;
1457 esac
1458
1459 if test "x$enable_win32_registry" != xno; then
1460   AC_MSG_CHECKING(registry key on windows hosts)
1461   AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$gcc_cv_win32_registry_key",
1462         [Define to be the last portion of registry key on windows hosts.])
1463   AC_MSG_RESULT($gcc_cv_win32_registry_key)
1464 fi
1465 ;;
1466 esac
1467
1468 # Get an absolute path to the GCC top-level source directory
1469 holddir=`${PWDCMD-pwd}`
1470 cd $srcdir
1471 topdir=`${PWDCMD-pwd}`
1472 cd $holddir
1473
1474 # Conditionalize the makefile for this host machine.
1475 xmake_file=
1476 for f in ${host_xmake_file}
1477 do
1478         if test -f ${srcdir}/config/$f
1479         then
1480                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1481         fi
1482 done
1483
1484 # Conditionalize the makefile for this target machine.
1485 tmake_file_=
1486 for f in ${tmake_file}
1487 do
1488         if test -f ${srcdir}/config/$f
1489         then
1490                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1491         fi
1492 done
1493 tmake_file="${tmake_file_}"
1494
1495 # If the host doesn't support symlinks, modify CC in
1496 # FLAGS_TO_PASS so CC="stage1/xgcc -Bstage1/" works.
1497 # Otherwise, we can use "CC=$(CC)".
1498 rm -f symtest.tem
1499 case "$LN_S" in
1500         *-s*)
1501                 cc_set_by_configure="\$(CC)"
1502                 quoted_cc_set_by_configure="\$(CC)"
1503                 stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1504                 quoted_stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1505                 ;;
1506         *)
1507                 cc_set_by_configure="\`case '\$(CC)' in stage*) echo '\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\$(CC)';; esac\`"
1508                 quoted_cc_set_by_configure="\\\`case '\\\$(CC)' in stage*) echo '\\\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(CC)';; esac\\\`"
1509                 stage_prefix_set_by_configure="\`case '\$(STAGE_PREFIX)' in stage*) echo '\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\$(STAGE_PREFIX)';; esac\`"
1510                 quoted_stage_prefix_set_by_configure="\\\`case '\\\$(STAGE_PREFIX)' in stage*) echo '\\\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(STAGE_PREFIX)';; esac\\\`"
1511                 ;;
1512 esac
1513
1514 out_object_file=`basename $out_file .c`.o
1515
1516 tm_file_list=
1517 tm_include_list=
1518 for f in $tm_file; do
1519   case $f in
1520     defaults.h )
1521        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1522        tm_include_list="${tm_include_list} $f"
1523        ;;
1524     * )
1525        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1526        tm_include_list="${tm_include_list} config/$f"
1527        ;;
1528   esac
1529 done
1530
1531 tm_p_file_list=
1532 tm_p_include_list=
1533 for f in $tm_p_file; do
1534   case $f in
1535     tm-preds.h )
1536        tm_p_file_list="${tm_p_file_list} $f"
1537        tm_p_include_list="${tm_p_include_list} $f"
1538        ;;
1539     * )
1540        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1541        tm_p_include_list="${tm_p_include_list} config/$f"
1542   esac
1543 done
1544
1545 xm_file_list=
1546 xm_include_list=
1547 for f in $xm_file; do
1548   case $f in
1549     ansidecl.h )
1550        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1551        xm_include_list="${xm_include_list} $f"
1552        ;;
1553     auto-host.h )
1554        xm_file_list="${xm_file_list} $f"
1555        xm_include_list="${xm_include_list} $f"
1556        ;;
1557     * )
1558        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1559        xm_include_list="${xm_include_list} config/$f"
1560        ;;
1561   esac
1562 done
1563
1564 host_xm_file_list=
1565 host_xm_include_list=
1566 for f in $host_xm_file; do
1567   case $f in
1568     ansidecl.h )
1569        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1570        host_xm_include_list="${host_xm_include_list} $f"
1571        ;;
1572     auto-host.h )
1573        host_xm_file_list="${host_xm_file_list} $f"
1574        host_xm_include_list="${host_xm_include_list} $f"
1575        ;;
1576     * )
1577        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1578        host_xm_include_list="${host_xm_include_list} config/$f"
1579        ;;
1580   esac
1581 done
1582
1583 build_xm_file_list=
1584 for f in $build_xm_file; do
1585   case $f in
1586     ansidecl.h )
1587        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1588        build_xm_include_list="${build_xm_include_list} $f"
1589        ;;
1590     auto-build.h | auto-host.h )
1591        build_xm_file_list="${build_xm_file_list} $f"
1592        build_xm_include_list="${build_xm_include_list} $f"
1593        ;;
1594     * )
1595        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1596        build_xm_include_list="${build_xm_include_list} config/$f"
1597        ;;
1598   esac
1599 done
1600
1601 # Define macro CROSS_COMPILE in compilation if this is a cross-compiler.
1602 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1603 CROSS=                                          AC_SUBST(CROSS)
1604 ALL=all.internal                                AC_SUBST(ALL)
1605 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1606 if test x$host != x$target
1607 then
1608         CROSS="-DCROSS_COMPILE"
1609         ALL=all.cross
1610         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1611         case "$host","$target" in
1612         # Darwin crosses can use the host system's libraries and headers,
1613         # because of the fat library support.  Of course, it must be the
1614         # same version of Darwin on both sides.  Allow the user to
1615         # just say --target=foo-darwin without a version number to mean
1616         # "the version on this system".
1617             *-*-darwin*,*-*-darwin*)
1618                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1619                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1620                 if test $hostos = $targetos -o $targetos = darwin ; then
1621                     CROSS=
1622                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1623                     with_headers=yes
1624                 fi
1625                 ;;
1626
1627             i?86-*-*,x86_64-*-* \
1628             | powerpc*-*-*,powerpc64*-*-*)
1629                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1630         esac
1631 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1632         # This is just $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)
1633         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1634 fi
1635
1636 # If this is a cross-compiler that does not
1637 # have its own set of headers then define
1638 # inhibit_libc
1639
1640 # If this is using newlib, without having the headers available now,
1641 # then define inhibit_libc in LIBGCC2_CFLAGS.
1642 # This prevents libgcc2 from containing any code which requires libc
1643 # support.
1644 inhibit_libc=
1645 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1646        test x$with_newlib = xyes ; } &&
1647      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1648        inhibit_libc=-Dinhibit_libc
1649 fi
1650 AC_SUBST(inhibit_libc)
1651
1652 # When building gcc with a cross-compiler, we need to adjust things so
1653 # that the generator programs are still built with the native compiler.
1654 # Also, we cannot run fixincludes or fix-header.
1655
1656 # These are the normal (build=host) settings:
1657 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1658 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1659 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1660
1661 # Possibly disable fixproto, on a per-target basis.
1662 case ${use_fixproto} in
1663   no)
1664     STMP_FIXPROTO=
1665     ;;
1666   yes)
1667     STMP_FIXPROTO=stmp-fixproto
1668     ;;
1669 esac
1670 AC_SUBST(STMP_FIXPROTO)
1671
1672 # And these apply if build != host, or we are generating coverage data
1673 if test x$build != x$host || test "x$coverage_flags" != x
1674 then
1675     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1676
1677     if test "x$TARGET_SYSTEM_ROOT" = x; then
1678         STMP_FIXINC=
1679         STMP_FIXPROTO=
1680     fi
1681 fi
1682
1683 # When bootstrapping from the toplevel, only run fixincludes during stage1
1684 if test -d ../prev-gcc
1685 then
1686     STMP_FIXINC=
1687     cp -R ../prev-gcc/include include
1688 fi
1689
1690 # Expand extra_headers to include complete path.
1691 # This substitutes for lots of t-* files.
1692 extra_headers_list=
1693 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1694 for file in ${extra_headers} ; do
1695   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1696 done
1697
1698 # Define collect2 in Makefile.
1699 case $host_can_use_collect2 in
1700   no) collect2= ;;
1701   *) collect2='collect2$(exeext)' ;;
1702 esac
1703 AC_SUBST([collect2])
1704
1705 # Add a definition of USE_COLLECT2 if system wants one.
1706 case $use_collect2 in
1707   no) use_collect2= ;;
1708   "") ;;
1709   *)
1710     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1711     xm_defines="${xm_defines} USE_COLLECT2"
1712     case $host_can_use_collect2 in
1713       no)
1714         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1715         ;;
1716     esac
1717     ;;
1718 esac
1719
1720 # ---------------------------
1721 # Assembler & linker features
1722 # ---------------------------
1723
1724 # Identify the assembler which will work hand-in-glove with the newly
1725 # built GCC, so that we can examine its features.  This is the assembler
1726 # which will be driven by the driver program.
1727 #
1728 # If build != host, and we aren't building gas in-tree, we identify a
1729 # build->target assembler and hope that it will have the same features
1730 # as the host->target assembler we'll be using.
1731 AC_MSG_CHECKING(what assembler to use)
1732 in_tree_gas=no
1733 gcc_cv_as=
1734 gcc_cv_gas_major_version=
1735 gcc_cv_gas_minor_version=
1736 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1737 if test -x "$DEFAULT_ASSEMBLER"; then
1738         gcc_cv_as="$DEFAULT_ASSEMBLER"
1739 elif test -x as$host_exeext; then
1740         # Build using assembler in the current directory.
1741         gcc_cv_as=./as$host_exeext
1742 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1743      && test -f ../gas/Makefile \
1744      && test x$build = x$host; then
1745   # Single tree build which includes gas.  We want to prefer it
1746   # over whatever linker top-level may have detected, since
1747   # we'll use what we're building after installation anyway.
1748   in_tree_gas=yes
1749   _gcc_COMPUTE_GAS_VERSION
1750   rm -f as$host_exeext
1751   $LN_S ../gas/as-new$host_exeext as$host_exeext 2>/dev/null
1752   in_tree_gas_is_elf=no
1753   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1754      || (grep 'obj_format = multi' ../gas/Makefile \
1755          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1756   then
1757     in_tree_gas_is_elf=yes
1758   fi
1759 m4_pattern_allow([AS_FOR_TARGET])dnl
1760 elif test -x "$AS_FOR_TARGET"; then
1761         gcc_cv_as="$AS_FOR_TARGET"
1762 elif test -x "$AS" && test x$host = x$target; then
1763         gcc_cv_as="$AS"
1764 fi
1765
1766 if test "x$gcc_cv_as" = x; then
1767         # Search the same directories that the installed compiler will
1768         # search.  Else we may find the wrong assembler and lose.  If we
1769         # do not find a suitable assembler binary, then try the user's
1770         # path.
1771         #
1772         # Also note we have to check MD_EXEC_PREFIX before checking the
1773         # user's path.  Unfortunately, there is no good way to get at the
1774         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1775         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1776         # to be fixed as part of the make/configure rewrite too.
1777
1778         if test "x$exec_prefix" = xNONE; then
1779                 if test "x$prefix" = xNONE; then
1780                         test_prefix=/usr/local
1781                 else
1782                         test_prefix=$prefix
1783                 fi
1784         else
1785                 test_prefix=$exec_prefix
1786         fi
1787
1788         # If the loop below does not find an assembler, then use whatever
1789         # one we can find in the users's path.
1790         # user's path.
1791         if test "x$program_prefix" != xNONE; then
1792                 gcc_cv_as=${program_prefix}as$host_exeext
1793         else
1794                 gcc_cv_as=`echo as | sed "${program_transform_name}"`$host_exeext
1795         fi
1796
1797         if test x$host = x$build; then
1798             test_dirs="$test_prefix/libexec/gcc/$target_noncanonical/$gcc_version \
1799                        $test_prefix/libexec/gcc/$target_noncanonical \
1800                        /usr/lib/gcc/$target_noncanonical/$gcc_version \
1801                        /usr/lib/gcc/$target_noncanonical \
1802                        $test_prefix/$target_noncanonical/bin/$target_noncanonical/$gcc_version \
1803                        $test_prefix/$target_noncanonical/bin"
1804         else
1805             test_dirs=
1806         fi
1807
1808         if test x$host = x$target; then
1809             test_dirs="$test_dirs \
1810                    /usr/libexec \
1811                    /usr/ccs/gcc \
1812                    /usr/ccs/bin \
1813                    /udk/usr/ccs/bin \
1814                    /bsd43/usr/lib/cmplrs/cc \
1815                    /usr/cross64/usr/bin \
1816                    /usr/lib/cmplrs/cc \
1817                    /sysv/usr/lib/cmplrs/cc \
1818                    /svr4/usr/lib/cmplrs/cc \
1819                    /usr/bin"
1820         fi
1821
1822         for dir in $test_dirs; do
1823                 if test -x $dir/as$host_exeext; then
1824                         gcc_cv_as=$dir/as$host_exeext
1825                         break;
1826                 fi
1827         done
1828 fi
1829 case $in_tree_gas in
1830   yes)
1831     AC_MSG_RESULT("newly built gas")
1832     ;;
1833   no)
1834     AC_MSG_RESULT($gcc_cv_as)
1835     ;;
1836 esac
1837
1838 # Identify the linker which will work hand-in-glove with the newly
1839 # built GCC, so that we can examine its features.  This is the linker
1840 # which will be driven by the driver program.
1841 #
1842 # If build != host, and we aren't building gas in-tree, we identify a
1843 # build->target linker and hope that it will have the same features
1844 # as the host->target linker we'll be using.
1845 AC_MSG_CHECKING(what linker to use)
1846 in_tree_ld=no
1847 gcc_cv_ld=
1848 gcc_cv_gld_major_version=
1849 gcc_cv_gld_minor_version=
1850 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1851 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1852 if test -x "$DEFAULT_LINKER"; then
1853         gcc_cv_ld="$DEFAULT_LINKER"
1854 elif test -x collect-ld$host_exeext; then
1855         # Build using linker in the current directory.
1856         gcc_cv_ld=./collect-ld$host_exeext
1857 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1858      && test -f ../ld/Makefile \
1859      && test x$build = x$host; then
1860         # Single tree build which includes ld.  We want to prefer it
1861         # over whatever linker top-level may have detected, since
1862         # we'll use what we're building after installation anyway.
1863         in_tree_ld=yes
1864         in_tree_ld_is_elf=no
1865         if (grep 'EMUL = .*elf' ../ld/Makefile \
1866             || grep 'EMUL = .*linux' ../ld/Makefile \
1867             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
1868           in_tree_ld_is_elf=yes
1869         fi
1870         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1871         do
1872 changequote(,)dnl
1873                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
1874 changequote([,])dnl
1875                 if test x$gcc_cv_gld_version != x; then
1876                         break
1877                 fi
1878         done
1879 changequote(,)dnl
1880         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1881         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1882 changequote([,])dnl
1883         rm -f collect-ld$host_exeext
1884         $LN_S ../ld/ld-new$host_exeext collect-ld$host_exeext 2>/dev/null
1885 elif test -x "$LD_FOR_TARGET"; then
1886         gcc_cv_ld="$LD_FOR_TARGET"
1887 elif test -x "$LD" && test x$host = x$target; then
1888         gcc_cv_ld="$LD"
1889 fi
1890
1891 if test "x$gcc_cv_ld" = x; then
1892         # Search the same directories that the installed compiler will
1893         # search.  Else we may find the wrong linker and lose.  If we
1894         # do not find a suitable linker binary, then try the user's
1895         # path.
1896         #
1897         # Also note we have to check MD_EXEC_PREFIX before checking the
1898         # user's path.  Unfortunately, there is no good way to get at the
1899         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1900         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1901         # to be fixed as part of the make/configure rewrite too.
1902
1903         if test "x$exec_prefix" = xNONE; then
1904                 if test "x$prefix" = xNONE; then
1905                         test_prefix=/usr/local
1906                 else
1907                         test_prefix=$prefix
1908                 fi
1909         else
1910                 test_prefix=$exec_prefix
1911         fi
1912
1913         # If the loop below does not find an linker, then use whatever
1914         # one we can find in the users's path.
1915         # user's path.
1916         if test "x$program_prefix" != xNONE; then
1917                 gcc_cv_ld=${program_prefix}ld$host_exeext
1918         else
1919                 gcc_cv_ld=`echo ld | sed "${program_transform_name}"`$host_exeext
1920         fi
1921
1922         if test x$host = x$build; then
1923             test_dirs="$test_prefix/libexec/gcc/$target_noncanonical/$gcc_version \
1924                        $test_prefix/libexec/gcc/$target_noncanonical \
1925                        /usr/lib/gcc/$target_noncanonical/$gcc_version \
1926                        /usr/lib/gcc/$target_noncanonical \
1927                        $test_prefix/$target_noncanonical/bin/$target_noncanonical/$gcc_version \
1928                        $test_prefix/$target_noncanonical/bin"
1929         else
1930             test_dirs=
1931         fi
1932
1933         if test x$host = x$target; then
1934             test_dirs="$test_dirs \
1935                    /usr/libexec \
1936                    /usr/ccs/gcc \
1937                    /usr/ccs/bin \
1938                    /udk/usr/ccs/bin \
1939                    /bsd43/usr/lib/cmplrs/cc \
1940                    /usr/cross64/usr/bin \
1941                    /usr/lib/cmplrs/cc \
1942                    /sysv/usr/lib/cmplrs/cc \
1943                    /svr4/usr/lib/cmplrs/cc \
1944                    /usr/bin"
1945         fi
1946
1947         for dir in $test_dirs; do
1948                 if test -x $dir/ld$host_exeext; then
1949                         gcc_cv_ld=$dir/ld$host_exeext
1950                         break;
1951                 fi
1952         done
1953 fi
1954 case $in_tree_ld in
1955   yes)
1956     AC_MSG_RESULT("newly built ld")
1957     ;;
1958   no)
1959     AC_MSG_RESULT($gcc_cv_ld)
1960     ;;
1961 esac
1962
1963 # Figure out what nm we will be using.
1964 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1965 AC_MSG_CHECKING(what nm to use)
1966 in_tree_nm=no
1967 if test -x nm$host_exeext; then
1968         gcc_cv_nm=./nm$host_exeext
1969 elif test -f $gcc_cv_binutils_srcdir/configure.in \
1970      && test -f ../binutils/Makefile; then
1971         # Single tree build which includes binutils.
1972         in_tree_nm=yes
1973         gcc_cv_nm=./nm$host_exeext
1974         rm -f nm$host_exeext
1975         $LN_S ../binutils/nm-new$host_exeext nm$host_exeext 2>/dev/null
1976 elif test "x$program_prefix" != xNONE; then
1977         gcc_cv_nm=${program_prefix}nm$host_exeext
1978 else
1979         gcc_cv_nm=`echo nm | sed "${program_transform_name}"`$host_exeext
1980 fi
1981 case $in_tree_nm in
1982   yes) AC_MSG_RESULT("newly built nm") ;;
1983   no)  AC_MSG_RESULT($gcc_cv_nm) ;;
1984 esac
1985
1986 # Figure out what objdump we will be using.
1987 AC_MSG_CHECKING(what objdump to use)
1988 in_tree_objdump=no
1989 if test -x objdump$host_exeext; then
1990         gcc_cv_objdump=./objdump$host_exeext
1991 elif test -f $gcc_cv_binutils_srcdir/configure.in \
1992      && test -f ../binutils/Makefile; then
1993         # Single tree build which includes binutils.
1994         in_tree_objdump=yes
1995         gcc_cv_objdump=./objdump$host_exeext
1996         rm -f objdump$host_exeext
1997         $LN_S ../binutils/objdump$host_exeext objdump$host_exeext 2>/dev/null
1998 elif test "x$program_prefix" != xNONE; then
1999         gcc_cv_objdump=${program_prefix}objdump$host_exeext
2000 else
2001         gcc_cv_objdump=`echo objdump | \
2002                 sed "${program_transform_name}"`$host_exeext
2003 fi
2004 case $in_tree_objdump in
2005   yes) AC_MSG_RESULT("newly built objdump") ;;
2006   no)  AC_MSG_RESULT($gcc_cv_objdump) ;;
2007 esac
2008
2009 # Figure out what assembler alignment features are present.
2010 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
2011  [2,6,0],,
2012 [.balign 4
2013 .p2align 2],,
2014 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2015   [Define if your assembler supports .balign and .p2align.])])
2016
2017 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2018  [2,8,0],,
2019  [.p2align 4,,7],,
2020 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2021   [Define if your assembler supports specifying the maximum number
2022    of bytes to skip when using the GAS .p2align command.])])
2023
2024 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2025  [elf,2,9,0],,
2026  [conftest_label1: .word 0
2027 .subsection -1
2028 conftest_label2: .word 0
2029 .previous],
2030  [if test x$gcc_cv_nm != x; then
2031     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2032     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2033     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2034     then :
2035     else gcc_cv_as_subsection_m1=yes
2036     fi
2037     rm -f conftest.nm1 conftest.nm2
2038   fi],
2039  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2040   [Define if your assembler supports .subsection and .subsection -1 starts
2041    emitting at the beginning of your section.])])
2042
2043 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2044  [2,2,0],,
2045  [      .weak foobar],,
2046 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2047
2048 # .hidden needs to be supported in both the assembler and the linker,
2049 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2050 # This is irritatingly difficult to feature test for; we have to check the
2051 # date string after the version number.  If we've got an in-tree
2052 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2053 # to be safe.
2054 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2055 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2056  [elf,2,13,0],,
2057 [       .hidden foobar
2058 foobar:])
2059
2060 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2061 [if test $in_tree_ld = yes ; then
2062   gcc_cv_ld_hidden=no
2063   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2064      && test $in_tree_ld_is_elf = yes; then
2065      gcc_cv_ld_hidden=yes
2066   fi
2067 else
2068   gcc_cv_ld_hidden=yes
2069   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2070   if echo "$ld_ver" | grep GNU > /dev/null; then
2071 changequote(,)dnl
2072     ld_vers=`echo $ld_ver | sed -n \
2073         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2074         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2075         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2076         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)[  ].*$,\1,p' \
2077         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[     ].*$,\1,p' \
2078         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[        ].*$,\1,p'`
2079     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2080     if test 0"$ld_date" -lt 20020404; then
2081       if test -n "$ld_date"; then
2082         # If there was date string, but was earlier than 2002-04-04, fail
2083         gcc_cv_ld_hidden=no
2084       elif test -z "$ld_vers"; then
2085         # If there was no date string nor ld version number, something is wrong
2086         gcc_cv_ld_hidden=no
2087       else
2088         ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2089         ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2090         ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2091         test -z "$ld_vers_patch" && ld_vers_patch=0
2092         if test "$ld_vers_major" -lt 2; then
2093           gcc_cv_ld_hidden=no
2094         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2095           gcc_cv_ld_hidden="no"
2096         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2097           gcc_cv_ld_hidden=no
2098         fi
2099       fi
2100 changequote([,])dnl
2101     fi
2102   else
2103     case "${target}" in
2104       hppa64*-*-hpux* | ia64*-*-hpux*)
2105         gcc_cv_ld_hidden=yes
2106         ;;
2107       *)
2108         gcc_cv_ld_hidden=no
2109         ;;
2110     esac
2111   fi
2112 fi])
2113 libgcc_visibility=no
2114 AC_SUBST(libgcc_visibility)
2115 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2116   libgcc_visibility=yes
2117   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2118   [Define if your assembler and linker support .hidden.])
2119 fi
2120
2121 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2122 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2123   [elf,2,11,0],,
2124 [       .data
2125         .uleb128 L2 - L1
2126 L1:
2127         .uleb128 1280
2128         .sleb128 -1010
2129 L2:],
2130  [# GAS versions before 2.11 do not support uleb128,
2131   # despite appearing to.
2132   # ??? There exists an elf-specific test that will crash
2133   # the assembler.  Perhaps it's better to figure out whether
2134   # arbitrary sections are supported and try the test.
2135   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2136   if echo "$as_ver" | grep GNU > /dev/null; then
2137 changequote(,)dnl
2138     as_ver=`echo $as_ver | sed -e 's/GNU assembler \([0-9.][0-9.]*\).*/\1/'`
2139     as_major=`echo $as_ver | sed 's/\..*//'`
2140     as_minor=`echo $as_ver | sed 's/[^.]*\.\([0-9]*\).*/\1/'`
2141 changequote([,])dnl
2142     if test $as_major -eq 2 && test $as_minor -lt 11
2143     then :
2144     else gcc_cv_as_leb128=yes
2145     fi
2146   fi],
2147   [AC_DEFINE(HAVE_AS_LEB128, 1,
2148     [Define if your assembler supports .sleb128 and .uleb128.])])
2149
2150 # GAS versions up to and including 2.11.0 may mis-optimize
2151 # .eh_frame data.
2152 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2153   [elf,2,12,0],,
2154 [       .text
2155 .LFB1:
2156         .4byte  0
2157 .L1:
2158         .4byte  0
2159 .LFE1:
2160         .section        .eh_frame,"aw",@progbits
2161 __FRAME_BEGIN__:
2162         .4byte  .LECIE1-.LSCIE1
2163 .LSCIE1:
2164         .4byte  0x0
2165         .byte   0x1
2166         .ascii "z\0"
2167         .byte   0x1
2168         .byte   0x78
2169         .byte   0x1a
2170         .byte   0x0
2171         .byte   0x4
2172         .4byte  1
2173         .p2align 1
2174 .LECIE1:
2175 .LSFDE1:
2176         .4byte  .LEFDE1-.LASFDE1
2177 .LASFDE1:
2178         .4byte  .LASFDE1-__FRAME_BEGIN__
2179         .4byte  .LFB1
2180         .4byte  .LFE1-.LFB1
2181         .byte   0x4
2182         .4byte  .LFE1-.LFB1
2183         .byte   0x4
2184         .4byte  .L1-.LFB1
2185 .LEFDE1:],
2186 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2187 cat > conftest.lit <<EOF
2188  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2189  0010 01000000 12000000 18000000 00000000  ................
2190  0020 08000000 04080000 0044               .........D      @&t@
2191 EOF
2192 cat > conftest.big <<EOF
2193  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2194  0010 00000001 00000012 00000018 00000000  ................
2195  0020 00000008 04000000 0844               .........D      @&t@
2196 EOF
2197   # If the assembler didn't choke, and we can objdump,
2198   # and we got the correct data, then succeed.
2199   if test x$gcc_cv_objdump != x \
2200   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2201      | tail -3 > conftest.got \
2202   && { cmp conftest.lit conftest.got > /dev/null 2>&1 \
2203     || cmp conftest.big conftest.got > /dev/null 2>&1; }
2204   then
2205     gcc_cv_as_eh_frame=yes
2206   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2207     gcc_cv_as_eh_frame=buggy
2208   else
2209     # Uh oh, what do we do now?
2210     gcc_cv_as_eh_frame=no
2211   fi])
2212
2213 if test $gcc_cv_as_eh_frame = buggy; then
2214   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2215   [Define if your assembler mis-optimizes .eh_frame data.])
2216 fi
2217
2218 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2219  [elf,2,12,0], [--fatal-warnings],
2220  [.section .rodata.str, "aMS", @progbits, 1])
2221 if test $gcc_cv_as_shf_merge = no; then
2222   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2223     [elf,2,12,0], [--fatal-warnings],
2224     [.section .rodata.str, "aMS", %progbits, 1])
2225 fi
2226 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2227   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2228 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2229
2230 gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group,
2231  [elf,2,15,91], [--fatal-warnings],
2232  [.section .text,"axG",@progbits,.foo,comdat])
2233 if test $gcc_cv_as_comdat_group = yes; then
2234   gcc_cv_as_comdat_group_percent=no
2235 else
2236  gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group_percent,
2237    [elf,2,15,91], [--fatal-warnings],
2238    [.section .text,"axG",%progbits,.foo,comdat])
2239 fi
2240 AC_DEFINE_UNQUOTED(HAVE_GAS_COMDAT_GROUP,
2241   [`if test $gcc_cv_as_comdat_group = yes || test $gcc_cv_as_comdat_group_percent = yes; then echo 1; else echo 0; fi`],
2242 [Define 0/1 if your assembler supports COMDAT group.])
2243
2244 # Thread-local storage - the check is heavily parametrized.
2245 conftest_s=
2246 tls_first_major=
2247 tls_first_minor=
2248 tls_as_opt=
2249 case "$target" in
2250 changequote(,)dnl
2251   alpha*-*-*)
2252     conftest_s='
2253         .section ".tdata","awT",@progbits
2254 foo:    .long   25
2255         .text
2256         ldq     $27,__tls_get_addr($29)         !literal!1
2257         lda     $16,foo($29)                    !tlsgd!1
2258         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2259         ldq     $27,__tls_get_addr($29)         !literal!2
2260         lda     $16,foo($29)                    !tlsldm!2
2261         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2262         ldq     $1,foo($29)                     !gotdtprel
2263         ldah    $2,foo($29)                     !dtprelhi
2264         lda     $3,foo($2)                      !dtprello
2265         lda     $4,foo($29)                     !dtprel
2266         ldq     $1,foo($29)                     !gottprel
2267         ldah    $2,foo($29)                     !tprelhi
2268         lda     $3,foo($2)                      !tprello
2269         lda     $4,foo($29)                     !tprel'
2270         tls_first_major=2
2271         tls_first_minor=13
2272         tls_as_opt=--fatal-warnings
2273         ;;
2274   i[34567]86-*-*)
2275     conftest_s='
2276         .section ".tdata","awT",@progbits
2277 foo:    .long   25
2278         .text
2279         movl    %gs:0, %eax
2280         leal    foo@TLSGD(,%ebx,1), %eax
2281         leal    foo@TLSLDM(%ebx), %eax
2282         leal    foo@DTPOFF(%eax), %edx
2283         movl    foo@GOTTPOFF(%ebx), %eax
2284         subl    foo@GOTTPOFF(%ebx), %eax
2285         addl    foo@GOTNTPOFF(%ebx), %eax
2286         movl    foo@INDNTPOFF, %eax
2287         movl    $foo@TPOFF, %eax
2288         subl    $foo@TPOFF, %eax
2289         leal    foo@NTPOFF(%ecx), %eax'
2290         tls_first_major=2
2291         tls_first_minor=14
2292         tls_as_opt=--fatal-warnings
2293         ;;
2294   x86_64-*-*)
2295     conftest_s='
2296         .section ".tdata","awT",@progbits
2297 foo:    .long   25
2298         .text
2299         movq    %fs:0, %rax
2300         leaq    foo@TLSGD(%rip), %rdi
2301         leaq    foo@TLSLD(%rip), %rdi
2302         leaq    foo@DTPOFF(%rax), %rdx
2303         movq    foo@GOTTPOFF(%rip), %rax
2304         movq    $foo@TPOFF, %rax'
2305         tls_first_major=2
2306         tls_first_minor=14
2307         tls_as_opt=--fatal-warnings
2308         ;;
2309   ia64-*-*)
2310     conftest_s='
2311         .section ".tdata","awT",@progbits
2312 foo:    data8   25
2313         .text
2314         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2315         addl    r17 = @ltoff(@dtprel(foo#)), gp
2316         addl    r18 = @ltoff(@tprel(foo#)), gp
2317         addl    r19 = @dtprel(foo#), gp
2318         adds    r21 = @dtprel(foo#), r13
2319         movl    r23 = @dtprel(foo#)
2320         addl    r20 = @tprel(foo#), gp
2321         adds    r22 = @tprel(foo#), r13
2322         movl    r24 = @tprel(foo#)'
2323         tls_first_major=2
2324         tls_first_minor=13
2325         tls_as_opt=--fatal-warnings
2326         ;;
2327   powerpc-*-*)
2328     conftest_s='
2329         .section ".tdata","awT",@progbits
2330         .align 2
2331 ld0:    .space 4
2332 ld1:    .space 4
2333 x1:     .space 4
2334 x2:     .space 4
2335 x3:     .space 4
2336         .text
2337         addi 3,31,ld0@got@tlsgd
2338         bl __tls_get_addr
2339         addi 3,31,x1@got@tlsld
2340         bl __tls_get_addr
2341         addi 9,3,x1@dtprel
2342         addis 9,3,x2@dtprel@ha
2343         addi 9,9,x2@dtprel@l
2344         lwz 9,x3@got@tprel(31)
2345         add 9,9,x@tls
2346         addi 9,2,x1@tprel
2347         addis 9,2,x2@tprel@ha
2348         addi 9,9,x2@tprel@l'
2349         tls_first_major=2
2350         tls_first_minor=14
2351         tls_as_opt="-a32 --fatal-warnings"
2352         ;;
2353   powerpc64-*-*)
2354     conftest_s='
2355         .section ".tdata","awT",@progbits
2356         .align 3
2357 ld0:    .space 8
2358 ld1:    .space 8
2359 x1:     .space 8
2360 x2:     .space 8
2361 x3:     .space 8
2362         .text
2363         addi 3,2,ld0@got@tlsgd
2364         bl .__tls_get_addr
2365         nop
2366         addi 3,2,ld1@toc
2367         bl .__tls_get_addr
2368         nop
2369         addi 3,2,x1@got@tlsld
2370         bl .__tls_get_addr
2371         nop
2372         addi 9,3,x1@dtprel
2373         bl .__tls_get_addr
2374         nop
2375         addis 9,3,x2@dtprel@ha
2376         addi 9,9,x2@dtprel@l
2377         bl .__tls_get_addr
2378         nop
2379         ld 9,x3@got@dtprel(2)
2380         add 9,9,3
2381         bl .__tls_get_addr
2382         nop'
2383         tls_first_major=2
2384         tls_first_minor=14
2385         tls_as_opt="-a64 --fatal-warnings"
2386         ;;
2387   s390-*-*)
2388     conftest_s='
2389         .section ".tdata","awT",@progbits
2390 foo:    .long   25
2391         .text
2392         .long   foo@TLSGD
2393         .long   foo@TLSLDM
2394         .long   foo@DTPOFF
2395         .long   foo@NTPOFF
2396         .long   foo@GOTNTPOFF
2397         .long   foo@INDNTPOFF
2398         l       %r1,foo@GOTNTPOFF(%r12)
2399         l       %r1,0(%r1):tls_load:foo
2400         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2401         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2402         tls_first_major=2
2403         tls_first_minor=14
2404         tls_as_opt="-m31 --fatal-warnings"
2405         ;;
2406   s390x-*-*)
2407     conftest_s='
2408         .section ".tdata","awT",@progbits
2409 foo:    .long   25
2410         .text
2411         .quad   foo@TLSGD
2412         .quad   foo@TLSLDM
2413         .quad   foo@DTPOFF
2414         .quad   foo@NTPOFF
2415         .quad   foo@GOTNTPOFF
2416         lg      %r1,foo@GOTNTPOFF(%r12)
2417         larl    %r1,foo@INDNTPOFF
2418         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2419         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2420         tls_first_major=2
2421         tls_first_minor=14
2422         tls_as_opt="-m64 -Aesame --fatal-warnings"
2423         ;;
2424   sh-*-* | sh[34]-*-*)
2425     conftest_s='
2426         .section ".tdata","awT",@progbits
2427 foo:    .long   25
2428         .text
2429         .long   foo@TLSGD
2430         .long   foo@TLSLDM
2431         .long   foo@DTPOFF
2432         .long   foo@GOTTPOFF
2433         .long   foo@TPOFF'
2434         tls_first_major=2
2435         tls_first_minor=13
2436         tls_as_opt=--fatal-warnings
2437         ;;
2438   sparc*-*-*)
2439     case "$target" in
2440       sparc*-sun-solaris2.*)
2441         on_solaris=yes
2442         ;;
2443       *)
2444         on_solaris=no
2445         ;;
2446     esac
2447     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2448       conftest_s='
2449         .section ".tdata",#alloc,#write,#tls
2450 foo:    .long   25
2451         .text
2452         sethi   %tgd_hi22(foo), %o0
2453         add     %o0, %tgd_lo10(foo), %o1
2454         add     %l7, %o1, %o0, %tgd_add(foo)
2455         call    __tls_get_addr, %tgd_call(foo)
2456         sethi   %tldm_hi22(foo), %l1
2457         add     %l1, %tldm_lo10(foo), %l2
2458         add     %l7, %l2, %o0, %tldm_add(foo)
2459         call    __tls_get_addr, %tldm_call(foo)
2460         sethi   %tldo_hix22(foo), %l3
2461         xor     %l3, %tldo_lox10(foo), %l4
2462         add     %o0, %l4, %l5, %tldo_add(foo)
2463         sethi   %tie_hi22(foo), %o3
2464         add     %o3, %tie_lo10(foo), %o3
2465         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2466         add     %g7, %o2, %o4, %tie_add(foo)
2467         sethi   %tle_hix22(foo), %l1
2468         xor     %l1, %tle_lox10(foo), %o5
2469         ld      [%g7 + %o5], %o1'
2470         tls_first_major=0
2471         tls_first_minor=0
2472     else
2473       conftest_s='
2474         .section ".tdata","awT",@progbits
2475 foo:    .long   25
2476         .text
2477         sethi   %tgd_hi22(foo), %o0
2478         add     %o0, %tgd_lo10(foo), %o1
2479         add     %l7, %o1, %o0, %tgd_add(foo)
2480         call    __tls_get_addr, %tgd_call(foo)
2481         sethi   %tldm_hi22(foo), %l1
2482         add     %l1, %tldm_lo10(foo), %l2
2483         add     %l7, %l2, %o0, %tldm_add(foo)
2484         call    __tls_get_addr, %tldm_call(foo)
2485         sethi   %tldo_hix22(foo), %l3
2486         xor     %l3, %tldo_lox10(foo), %l4
2487         add     %o0, %l4, %l5, %tldo_add(foo)
2488         sethi   %tie_hi22(foo), %o3
2489         add     %o3, %tie_lo10(foo), %o3
2490         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2491         add     %g7, %o2, %o4, %tie_add(foo)
2492         sethi   %tle_hix22(foo), %l1
2493         xor     %l1, %tle_lox10(foo), %o5
2494         ld      [%g7 + %o5], %o1'
2495         tls_first_major=2
2496         tls_first_minor=14
2497         tls_as_opt="-32 --fatal-warnings"
2498       fi
2499         ;;
2500 changequote([,])dnl
2501 esac
2502 if test -z "$tls_first_major"; then
2503   : # If we don't have a check, assume no support.
2504 else
2505   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2506   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2507   [AC_DEFINE(HAVE_AS_TLS, 1,
2508             [Define if your assembler supports thread-local storage.])])
2509 fi
2510
2511 # Target-specific assembler checks.
2512
2513 if test x"$demangler_in_ld" = xyes; then
2514   AC_MSG_CHECKING(linker --demangle support)
2515   gcc_cv_ld_demangle=no
2516   if test $in_tree_ld = yes; then
2517     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
2518       gcc_cv_ld_demangle=yes
2519     fi
2520   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
2521     # Check if the GNU linker supports --demangle option
2522     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
2523       gcc_cv_ld_demangle=yes
2524     fi
2525   fi
2526   if test x"$gcc_cv_ld_demangle" = xyes; then
2527     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
2528 [Define if your linker supports --demangle option.])
2529   fi
2530   AC_MSG_RESULT($gcc_cv_ld_demangle)
2531 fi
2532
2533 case "$target" in
2534   # All TARGET_ABI_OSF targets.
2535   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2536     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2537         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2538 [       .set nomacro
2539         .text
2540         extbl   $3, $2, $3      !lituse_bytoff!1
2541         ldq     $2, a($29)      !literal!1
2542         ldq     $4, b($29)      !literal!2
2543         ldq_u   $3, 0($2)       !lituse_base!1
2544         ldq     $27, f($29)     !literal!5
2545         jsr     $26, ($27), f   !lituse_jsr!5
2546         ldah    $29, 0($26)     !gpdisp!3
2547         lda     $0, c($29)      !gprel
2548         ldah    $1, d($29)      !gprelhigh
2549         lda     $1, d($1)       !gprellow
2550         lda     $29, 0($29)     !gpdisp!3],,
2551     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2552   [Define if your assembler supports explicit relocations.])])
2553     ;;
2554
2555   cris-*-*)
2556     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
2557       gcc_cv_as_cris_no_mul_bug,[2,15,91],
2558       [-no-mul-bug-abort], [.text],,
2559       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
2560                 [Define if your assembler supports the -no-mul-bug-abort option.])])
2561     ;;
2562
2563   sparc*-*-*)
2564     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2565       [.register %g2, #scratch],,
2566       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2567                 [Define if your assembler supports .register.])])
2568
2569     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2570       [-relax], [.text],,
2571       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2572                 [Define if your assembler supports -relax option.])])
2573
2574     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2575       gcc_cv_as_sparc_ua_pcrel,,
2576       [-K PIC],
2577 [.text
2578 foo:
2579         nop
2580 .data
2581 .align 4
2582 .byte 0
2583 .uaword %r_disp32(foo)],
2584       [if test x$gcc_cv_ld != x \
2585        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2586          gcc_cv_as_sparc_ua_pcrel=yes
2587        fi
2588        rm -f conftest],
2589       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2590                 [Define if your assembler and linker support unaligned PC relative relocs.])
2591
2592       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2593         gcc_cv_as_sparc_ua_pcrel_hidden,,
2594         [-K PIC],
2595 [.data
2596 .align 4
2597 .byte 0x31
2598 .uaword %r_disp32(foo)
2599 .byte 0x32, 0x33, 0x34
2600 .global foo
2601 .hidden foo
2602 foo:
2603 .skip 4],
2604         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2605          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2606          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2607             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2608             if $gcc_cv_objdump -R conftest 2> /dev/null \
2609                | grep 'DISP32' > /dev/null 2>&1; then
2610                 :
2611             else
2612                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2613             fi
2614          fi
2615          rm -f conftest],
2616          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2617                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2618     ]) # unaligned pcrel relocs
2619
2620     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2621       gcc_cv_as_sparc_offsetable_lo10,,
2622       [-xarch=v9],
2623 [.text
2624         or %g1, %lo(ab) + 12, %g1
2625         or %g1, %lo(ab + 12), %g1],
2626       [if test x$gcc_cv_objdump != x \
2627        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2628           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2629          gcc_cv_as_offsetable_lo10=yes
2630        fi],
2631        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2632                  [Define if your assembler supports offsetable %lo().])])
2633     ;;
2634
2635 changequote(,)dnl
2636   i[34567]86-*-* | x86_64-*-*)
2637 changequote([,])dnl
2638     case $target_os in
2639       cygwin* | pe | mingw32*)
2640         # Used for DWARF 2 in PE
2641         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
2642           gcc_cv_as_ix86_pe_secrel32,
2643           [2,15,91],,
2644 [.text
2645 foo:    nop
2646 .data
2647         .secrel32 foo],
2648           [if test x$gcc_cv_ld != x \
2649            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
2650              gcc_cv_as_ix86_pe_secrel32=yes
2651            fi
2652            rm -f conftest],
2653           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
2654             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
2655         ;;
2656     esac
2657
2658     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2659        gcc_cv_as_ix86_filds_fists,
2660       [2,9,0],, [filds mem; fists mem],,
2661       [AC_DEFINE(HAVE_GAS_FILDS_FISTS, 1,
2662         [Define if your assembler uses the new HImode fild and fist notation.])])
2663
2664     gcc_GAS_CHECK_FEATURE([cmov syntax],
2665       gcc_cv_as_ix86_cmov_sun_syntax,,,
2666       [cmovl.l %edx, %eax],,
2667       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
2668         [Define if your assembler supports the Sun syntax for cmov.])])
2669
2670     # This one is used unconditionally by i386.[ch]; it is to be defined
2671     # to 1 if the feature is present, 0 otherwise.
2672     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
2673         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
2674 [       .text
2675 .L0:
2676         nop
2677         .data
2678         .long .L0@GOTOFF])
2679     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2680       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2681       [Define true if the assembler supports '.long foo@GOTOFF'.])
2682     ;;
2683
2684   ia64*-*-*)
2685     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
2686         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
2687 [       .text
2688         addl r15 = @ltoffx(x#), gp
2689         ;;
2690         ld8.mov r16 = [[r15]], x#],,
2691     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2692           [Define if your assembler supports ltoffx and ldxmov relocations.])])
2693
2694     ;;
2695
2696   powerpc*-*-*)
2697     case $target in
2698       *-*-aix*) conftest_s='    .csect .text[[PR]]
2699         mfcr 3,128';;
2700       *-*-darwin*) conftest_s=' .text
2701         mfcr r3,128';;
2702       *) conftest_s='   .machine power4
2703         .text
2704         mfcr 3,128';;
2705     esac
2706
2707     gcc_GAS_CHECK_FEATURE([mfcr field support],
2708       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
2709       [$conftest_s],,
2710       [AC_DEFINE(HAVE_AS_MFCRF, 1,
2711           [Define if your assembler supports mfcr field.])])
2712     ;;
2713
2714   mips*-*-*)
2715     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2716       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
2717 [       lw $4,%gp_rel(foo)($4)],,
2718       [if test x$target_cpu_default = x
2719        then target_cpu_default=MASK_EXPLICIT_RELOCS
2720        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
2721        fi])
2722
2723     if test x$gas_flag = xyes \
2724        || test x"$host" != x"$build" \
2725        || test ! -x "$gcc_cv_as" \
2726        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
2727       :
2728     else
2729       echo "*** This configuration requires the GNU assembler" >&2
2730       exit 1
2731     fi
2732     ;;
2733 esac
2734 # ??? Not all targets support dwarf2 debug_line, even within a version
2735 # of gas.  Moreover, we need to emit a valid instruction to trigger any
2736 # info to the output file.  So, as supported targets are added to gas 2.11,
2737 # add some instruction here to (also) show we expect this might work.
2738 # ??? Once 2.11 is released, probably need to add first known working
2739 # version to the per-target configury.
2740 case "$target" in
2741   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
2742   | x86_64*-*-* | hppa*-*-* | arm*-*-* | strongarm*-*-* | xscale*-*-* \
2743   | xstormy16*-*-* | cris-*-* | xtensa-*-*)
2744     insn="nop"
2745     ;;
2746   ia64*-*-* | s390*-*-*)
2747     insn="nop 0"
2748     ;;
2749   mmix-*-*)
2750     insn="swym 0"
2751     ;;
2752 esac
2753 if test x"$insn" != x; then
2754  conftest_s="\
2755         .file 1 \"conftest.s\"
2756         .loc 1 3 0
2757         $insn"
2758  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
2759   gcc_cv_as_dwarf2_debug_line,
2760   [elf,2,11,0],, [$conftest_s],
2761   [# ??? This fails with non-gnu grep.  Maybe use objdump?
2762    if grep debug_line conftest.o > /dev/null 2>&1; then
2763      gcc_cv_as_dwarf2_debug_line=yes
2764    fi])
2765
2766 # The .debug_line file table must be in the exact order that
2767 # we specified the files, since these indices are also used
2768 # by DW_AT_decl_file.  Approximate this test by testing if
2769 # the assembler bitches if the same index is assigned twice.
2770  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
2771   gcc_cv_as_dwarf2_file_buggy,,,
2772 [       .file 1 "foo.s"
2773         .file 1 "bar.s"])
2774
2775  if test $gcc_cv_as_dwarf2_debug_line = yes \
2776  && test $gcc_cv_as_dwarf2_file_buggy = no; then
2777         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
2778   [Define if your assembler supports dwarf2 .file/.loc directives,
2779    and preserves file table indices exactly as given.])
2780  fi
2781
2782  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
2783   gcc_cv_as_gdwarf2_flag,
2784   [elf,2,11,0], [--gdwarf2], [$insn],,
2785   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
2786 [Define if your assembler supports the --gdwarf2 option.])])
2787
2788  gcc_GAS_CHECK_FEATURE([--gstabs option],
2789   gcc_cv_as_gstabs_flag,
2790   [elf,2,11,0], [--gstabs], [$insn],
2791   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
2792    # and warns about it, but still exits successfully.  So check for
2793    # this.
2794    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
2795    then :
2796    else gcc_cv_as_gstabs_flag=yes
2797    fi],
2798   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
2799 [Define if your assembler supports the --gstabs option.])])
2800 fi
2801
2802 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2803 gcc_cv_ld_ro_rw_mix=unknown
2804 if test $in_tree_ld = yes ; then
2805   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2806      && test $in_tree_ld_is_elf = yes; then
2807     gcc_cv_ld_ro_rw_mix=read-write
2808   fi
2809 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2810   echo '.section myfoosect, "a"' > conftest1.s
2811   echo '.section myfoosect, "aw"' > conftest2.s
2812   echo '.byte 1' >> conftest2.s
2813   echo '.section myfoosect, "a"' > conftest3.s
2814   echo '.byte 0' >> conftest3.s
2815   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2816      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2817      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2818      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2819         conftest2.o conftest3.o > /dev/null 2>&1; then
2820     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2821                          | sed -e '/myfoosect/!d' -e N`
2822     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2823       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2824         gcc_cv_ld_ro_rw_mix=read-only
2825       else
2826         gcc_cv_ld_ro_rw_mix=read-write
2827       fi
2828     fi
2829   fi
2830 changequote(,)dnl
2831   rm -f conftest.* conftest[123].*
2832 changequote([,])dnl
2833 fi
2834 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2835         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2836   [Define if your linker links a mix of read-only
2837    and read-write sections into a read-write section.])
2838 fi
2839 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2840
2841 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
2842 gcc_cv_ld_eh_frame_hdr=no
2843 if test $in_tree_ld = yes ; then
2844   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
2845      && test $in_tree_ld_is_elf = yes; then
2846     gcc_cv_ld_eh_frame_hdr=yes
2847   fi
2848 elif test x$gcc_cv_ld != x; then
2849         # Check if linker supports --eh-frame-hdr option
2850         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
2851                 gcc_cv_ld_eh_frame_hdr=yes
2852         fi
2853 fi
2854 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
2855         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
2856 [Define if your linker supports --eh-frame-hdr option.])
2857 fi
2858 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
2859
2860 AC_MSG_CHECKING(linker position independent executable support)
2861 gcc_cv_ld_pie=no
2862 if test $in_tree_ld = yes ; then
2863   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
2864      && test $in_tree_ld_is_elf = yes; then
2865     gcc_cv_ld_pie=yes
2866   fi
2867 elif test x$gcc_cv_ld != x; then
2868         # Check if linker supports -pie option
2869         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
2870                 gcc_cv_ld_pie=yes
2871         fi
2872 fi
2873 if test x"$gcc_cv_ld_pie" = xyes; then
2874         AC_DEFINE(HAVE_LD_PIE, 1,
2875 [Define if your linker supports -pie option.])
2876 fi
2877 AC_MSG_RESULT($gcc_cv_ld_pie)
2878
2879 # --------
2880 # UNSORTED
2881 # --------
2882
2883 AC_CACHE_CHECK(linker --as-needed support,
2884 gcc_cv_ld_as_needed,
2885 [gcc_cv_ld_as_needed=no
2886 if test $in_tree_ld = yes ; then
2887   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
2888      && test $in_tree_ld_is_elf = yes; then
2889     gcc_cv_ld_as_needed=yes
2890   fi
2891 elif test x$gcc_cv_ld != x; then
2892         # Check if linker supports --as-needed and --no-as-needed options
2893         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
2894                 gcc_cv_ld_as_needed=yes
2895         fi
2896 fi
2897 ])
2898 if test x"$gcc_cv_ld_as_needed" = xyes; then
2899         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
2900 [Define if your linker supports --as-needed and --no-as-needed options.])
2901 fi
2902
2903 case "$target" in
2904   powerpc64*-*-linux*)
2905     AC_CACHE_CHECK(linker support for omitting dot symbols,
2906     gcc_cv_ld_no_dot_syms,
2907     [gcc_cv_ld_no_dot_syms=no
2908     if test $in_tree_ld = yes ; then
2909       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
2910         gcc_cv_ld_no_dot_syms=yes
2911       fi
2912     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
2913       cat > conftest1.s <<EOF
2914         .text
2915         bl .foo
2916 EOF
2917       cat > conftest2.s <<EOF
2918         .section ".opd","aw"
2919         .align 3
2920         .globl foo
2921         .type foo,@function
2922 foo:
2923         .quad .LEfoo,.TOC.@tocbase,0
2924         .text
2925 .LEfoo:
2926         blr
2927         .size foo,.-.LEfoo
2928 EOF
2929       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
2930          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
2931          && $gcc_cv_ld -melf64ppc -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
2932         gcc_cv_ld_no_dot_syms=yes
2933       fi
2934       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
2935     fi
2936     ])
2937     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
2938       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
2939     [Define if your PowerPC64 linker only needs function descriptor syms.])
2940     fi
2941     ;;
2942 esac
2943
2944 if test x$with_sysroot = x && test x$host = x$target \
2945    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" ; then
2946   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
2947 [Define to PREFIX/include if cpp should also search that directory.])
2948 fi
2949
2950 # Find out what GC implementation we want, or may, use.
2951 AC_ARG_WITH(gc,
2952 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
2953                           with the compiler],
2954 [case "$withval" in
2955   page | zone)
2956     GGC=ggc-$withval
2957     ;;
2958   *)
2959     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
2960     ;;
2961 esac],
2962 [GGC=ggc-page])
2963 AC_SUBST(GGC)
2964 echo "Using $GGC for garbage collection."
2965
2966 # Use the system's zlib library.
2967 zlibdir=-L../zlib
2968 zlibinc="-I\$(srcdir)/../zlib"
2969 AC_ARG_WITH(system-zlib,
2970 [  --with-system-zlib      use installed libz],
2971 zlibdir=
2972 zlibinc=
2973 )
2974 AC_SUBST(zlibdir)
2975 AC_SUBST(zlibinc)
2976
2977 dnl Very limited version of automake's enable-maintainer-mode
2978
2979 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
2980   dnl maintainer-mode is disabled by default
2981   AC_ARG_ENABLE(maintainer-mode,
2982 [  --enable-maintainer-mode
2983                           enable make rules and dependencies not useful
2984                           (and sometimes confusing) to the casual installer],
2985       maintainer_mode=$enableval,
2986       maintainer_mode=no)
2987
2988 AC_MSG_RESULT($maintainer_mode)
2989
2990 if test "$maintainer_mode" = "yes"; then
2991   MAINT=''
2992 else
2993   MAINT='#'
2994 fi
2995 AC_SUBST(MAINT)dnl
2996
2997 # --------------
2998 # Language hooks
2999 # --------------
3000
3001 # Make empty files to contain the specs and options for each language.
3002 # Then add #include lines to for a compiler that has specs and/or options.
3003
3004 lang_opt_files=
3005 lang_specs_files=
3006 lang_tree_files=
3007 for subdir in . $subdirs
3008 do
3009         if test -f $srcdir/$subdir/lang.opt; then
3010             lang_opt_files="$lang_opt_files $srcdir/$subdir/lang.opt"
3011         fi
3012         if test -f $srcdir/$subdir/lang-specs.h; then
3013             lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
3014         fi
3015         if test -f $srcdir/$subdir/$subdir-tree.def; then
3016             lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
3017         fi
3018 done
3019
3020 # These (without "all_") are set in each config-lang.in.
3021 # `language' must be a single word so is spelled singularly.
3022 all_languages=
3023 all_boot_languages=
3024 all_compilers=
3025 all_stagestuff=
3026 all_outputs='Makefile gccbug mklibgcc mkheaders libada-mk'
3027 # List of language makefile fragments.
3028 all_lang_makefrags=
3029 # List of language subdirectory makefiles.  Deprecated.
3030 all_lang_makefiles=
3031 # Files for gengtype
3032 all_gtfiles="$target_gtfiles"
3033 # Files for gengtype with language
3034 all_gtfiles_files_langs=
3035 all_gtfiles_files_files=
3036
3037 # Add the language fragments.
3038 # Languages are added via two mechanisms.  Some information must be
3039 # recorded in makefile variables, these are defined in config-lang.in.
3040 # We accumulate them and plug them into the main Makefile.
3041 # The other mechanism is a set of hooks for each of the main targets
3042 # like `clean', `install', etc.
3043
3044 language_hooks="Make-hooks"
3045
3046 for s in $subdirs
3047 do
3048                 language=
3049                 boot_language=
3050                 compilers=
3051                 stagestuff=
3052                 outputs=
3053                 gtfiles=
3054                 . ${srcdir}/$s/config-lang.in
3055                 if test "x$language" = x
3056                 then
3057                         echo "${srcdir}/$s/config-lang.in doesn't set \$language." 1>&2
3058                         exit 1
3059                 fi
3060                 all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$s/Make-lang.in"
3061                 if test -f ${srcdir}/$s/Makefile.in
3062                 then all_lang_makefiles="$s/Makefile"
3063                 fi
3064                 all_languages="$all_languages $language"
3065                 if test "x$boot_language" = xyes
3066                 then
3067                         all_boot_languages="$all_boot_languages $language"
3068                 fi
3069                 all_compilers="$all_compilers $compilers"
3070                 all_stagestuff="$all_stagestuff $stagestuff"
3071                 all_outputs="$all_outputs $outputs"
3072                 all_gtfiles="$all_gtfiles $gtfiles"
3073                 for f in $gtfiles
3074                 do
3075                          all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
3076                          all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
3077                 done
3078 done
3079
3080 # Pick up gtfiles for c
3081 gtfiles=
3082 s="c"
3083 . ${srcdir}/c-config-lang.in
3084 all_gtfiles="$all_gtfiles $gtfiles"
3085 for f in $gtfiles
3086 do
3087         all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
3088         all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
3089 done
3090
3091 check_languages=
3092 for language in $all_languages
3093 do
3094                 check_languages="$check_languages check-$language"
3095 done
3096
3097 # We link each language in with a set of hooks, reached indirectly via
3098 # lang.${target}.
3099
3100 rm -f Make-hooks
3101 touch Make-hooks
3102 target_list="all.build all.cross start.encap rest.encap tags \
3103         install-normal install-common install-man \
3104         uninstall info man srcextra srcman srcinfo \
3105         mostlyclean clean distclean maintainer-clean \
3106         stage1 stage2 stage3 stage4 stageprofile stagefeedback"
3107 for t in $target_list
3108 do
3109         x=
3110         for lang in $all_languages
3111         do
3112                         x="$x $lang.$t"
3113         done
3114         echo "lang.$t: $x" >> Make-hooks
3115 done
3116
3117 # --------
3118 # UNSORTED
3119 # --------
3120
3121 # Create .gdbinit.
3122
3123 echo "dir ." > .gdbinit
3124 echo "dir ${srcdir}" >> .gdbinit
3125 if test x$gdb_needs_out_file_path = xyes
3126 then
3127         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
3128 fi
3129 if test "x$subdirs" != x; then
3130         for s in $subdirs
3131         do
3132                 echo "dir ${srcdir}/$s" >> .gdbinit
3133         done
3134 fi
3135 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
3136
3137 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
3138 # absolute path for gcc_tooldir based on inserting the number of up-directory
3139 # movements required to get from $(exec_prefix) to $(prefix) into the basic
3140 # $(libsubdir)/@(unlibsubdir) based path.
3141 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
3142 # make and thus we'd get different behavior depending on where we built the
3143 # sources.
3144 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
3145     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_noncanonical)'
3146 else
3147 changequote(<<, >>)dnl
3148 # An explanation of the sed strings:
3149 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
3150 #  -e 's|/$||'            match a trailing forward slash and eliminates it
3151 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
3152 #  -e 's|/[^/]*|../|g'    replaces each occurrence of /<directory> with ../
3153 #
3154 # (*) Note this pattern overwrites the first character of the string
3155 # with a forward slash if one is not already present.  This is not a
3156 # problem because the exact names of the sub-directories concerned is
3157 # unimportant, just the number of them matters.
3158 #
3159 # The practical upshot of these patterns is like this:
3160 #
3161 #  prefix     exec_prefix        result
3162 #  ------     -----------        ------
3163 #   /foo        /foo/bar          ../
3164 #   /foo/       /foo/bar          ../
3165 #   /foo        /foo/bar/         ../
3166 #   /foo/       /foo/bar/         ../
3167 #   /foo        /foo/bar/ugg      ../../
3168 #
3169     dollar='$$'
3170     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_noncanonical)"
3171 changequote([, ])dnl
3172 fi
3173 AC_SUBST(gcc_tooldir)
3174 AC_SUBST(dollar)
3175
3176 # Find a directory in which to install a shared libgcc.
3177
3178 AC_ARG_ENABLE(version-specific-runtime-libs,
3179 [  --enable-version-specific-runtime-libs
3180                           specify that runtime libraries should be
3181                           installed in a compiler-specific directory])
3182
3183 AC_ARG_WITH(slibdir,
3184 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
3185 slibdir="$with_slibdir",
3186 if test "${enable_version_specific_runtime_libs+set}" = set; then
3187   slibdir='$(libsubdir)'
3188 elif test "$host" != "$target"; then
3189   slibdir='$(build_tooldir)/lib'
3190 else
3191   slibdir='$(libdir)'
3192 fi)
3193 AC_SUBST(slibdir)
3194
3195 objdir=`${PWDCMD-pwd}`
3196 AC_SUBST(objdir)
3197
3198 # Substitute configuration variables
3199 AC_SUBST(subdirs)
3200 AC_SUBST(srcdir)
3201 AC_SUBST(all_boot_languages)
3202 AC_SUBST(all_compilers)
3203 AC_SUBST(all_gtfiles)
3204 AC_SUBST(all_gtfiles_files_langs)
3205 AC_SUBST(all_gtfiles_files_files)
3206 AC_SUBST(all_lang_makefrags)
3207 AC_SUBST(all_lang_makefiles)
3208 AC_SUBST(all_languages)
3209 AC_SUBST(all_stagestuff)
3210 AC_SUBST(build_exeext)
3211 AC_SUBST(build_install_headers_dir)
3212 AC_SUBST(build_xm_file_list)
3213 AC_SUBST(build_xm_include_list)
3214 AC_SUBST(build_xm_defines)
3215 AC_SUBST(check_languages)
3216 AC_SUBST(cc_set_by_configure)
3217 AC_SUBST(quoted_cc_set_by_configure)
3218 AC_SUBST(cpp_install_dir)
3219 AC_SUBST(xmake_file)
3220 AC_SUBST(tmake_file)
3221 AC_SUBST(extra_gcc_objs)
3222 AC_SUBST(extra_headers_list)
3223 AC_SUBST(extra_objs)
3224 AC_SUBST(extra_parts)
3225 AC_SUBST(extra_passes)
3226 AC_SUBST(extra_programs)
3227 AC_SUBST(float_h_file)
3228 AC_SUBST(gcc_config_arguments)
3229 AC_SUBST(gcc_gxx_include_dir)
3230 AC_SUBST(libstdcxx_incdir)
3231 AC_SUBST(gcc_version)
3232 AC_SUBST(gcc_version_full)
3233 AC_SUBST(gcc_version_trigger)
3234 AC_SUBST(host_exeext)
3235 AC_SUBST(host_xm_file_list)
3236 AC_SUBST(host_xm_include_list)
3237 AC_SUBST(host_xm_defines)
3238 AC_SUBST(out_host_hook_obj)
3239 AC_SUBST(install)
3240 AC_SUBST(lang_opt_files)
3241 AC_SUBST(lang_specs_files)
3242 AC_SUBST(lang_tree_files)
3243 AC_SUBST(local_prefix)
3244 AC_SUBST(md_file)
3245 AC_SUBST(objc_boehm_gc)
3246 AC_SUBST(out_file)
3247 AC_SUBST(out_object_file)
3248 AC_SUBST(stage_prefix_set_by_configure)
3249 AC_SUBST(quoted_stage_prefix_set_by_configure)
3250 AC_SUBST(thread_file)
3251 AC_SUBST(tm_file_list)
3252 AC_SUBST(tm_include_list)
3253 AC_SUBST(tm_defines)
3254 AC_SUBST(tm_p_file_list)
3255 AC_SUBST(tm_p_include_list)
3256 AC_SUBST(xm_file_list)
3257 AC_SUBST(xm_include_list)
3258 AC_SUBST(xm_defines)
3259 AC_SUBST(c_target_objs)
3260 AC_SUBST(cxx_target_objs)
3261 AC_SUBST(target_cpu_default)
3262
3263 AC_SUBST_FILE(language_hooks)
3264
3265 TL_AC_GNU_MAKE_GCC_LIB_PATH
3266
3267 # Echo link setup.
3268 if test x${build} = x${host} ; then
3269   if test x${host} = x${target} ; then
3270     echo "Links are now set up to build a native compiler for ${target}." 1>&2
3271   else
3272     echo "Links are now set up to build a cross-compiler" 1>&2
3273     echo " from ${host} to ${target}." 1>&2
3274   fi
3275 else
3276   if test x${host} = x${target} ; then
3277     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
3278     echo " for ${target}." 1>&2
3279   else
3280     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
3281     echo " from ${host} to ${target}." 1>&2
3282   fi
3283 fi
3284
3285 AC_ARG_VAR(GMPLIBS,[How to link GMP])
3286 AC_ARG_VAR(GMPINC,[How to find GMP include files])
3287
3288 # Configure the subdirectories
3289 # AC_CONFIG_SUBDIRS($subdirs)
3290
3291 # Create the Makefile
3292 # and configure language subdirectories
3293 AC_CONFIG_FILES($all_outputs)
3294
3295 AC_CONFIG_COMMANDS([default],
3296 [
3297 case ${CONFIG_HEADERS} in
3298   *auto-host.h:config.in*)
3299   echo > cstamp-h ;;
3300 esac
3301 # Make sure all the subdirs exist.
3302 for d in $subdirs doc build
3303 do
3304     test -d $d || mkdir $d
3305 done
3306 # If the host supports symlinks, point stage[1234] at ../stage[1234] so
3307 # bootstrapping and the installation procedure can still use
3308 # CC="stage1/xgcc -Bstage1/".  If the host doesn't support symlinks,
3309 # FLAGS_TO_PASS has been modified to solve the problem there.
3310 # This is virtually a duplicate of what happens in configure.lang; we do
3311 # an extra check to make sure this only happens if ln -s can be used.
3312 case "$LN_S" in
3313   *-s*)
3314     for d in ${subdirs} ; do
3315         STARTDIR=`${PWDCMD-pwd}`
3316         cd $d
3317         for t in stage1 stage2 stage3 stage4 stageprofile stagefeedback include
3318         do
3319                 rm -f $t
3320                 $LN_S ../$t $t 2>/dev/null
3321         done
3322         cd $STARTDIR
3323     done
3324   ;;
3325 esac
3326 ],
3327 [subdirs='$subdirs'])
3328 AC_OUTPUT