gcc/configure.in

   1 # configure.in for GNU CC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright (C) 1997, 1998, 1999, 2000 Free Software Foundation, Inc.
   5
   6 #This file is part of GNU CC.
   7
   8 #GNU CC is free software; you can redistribute it and/or modify
   9 #it under the terms of the GNU General Public License as published by
  10 #the Free Software Foundation; either version 2, or (at your option)
  11 #any later version.
  12
  13 #GNU CC is distributed in the hope that it will be useful,
  14 #but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 #GNU General Public License for more details.
  17
  18 #You should have received a copy of the GNU General Public License
  19 #along with GNU CC; see the file COPYING.  If not, write to
  20 #the Free Software Foundation, 59 Temple Place - Suite 330,
  21 #Boston, MA 02111-1307, USA.
  22
  23 # Initialization and defaults
  24 AC_PREREQ(2.13)
  25 AC_INIT(tree.c)
  26 AC_CONFIG_HEADER(auto-host.h:config.in)
  27
  28 remove=rm
  29 hard_link=ln
  30 symbolic_link='ln -s'
  31 copy=cp
  32
  33 # Check for bogus environment variables.
  34 # Test if LIBRARY_PATH contains the notation for the current directory
  35 # since this would lead to problems installing/building glibc.
  36 # LIBRARY_PATH contains the current directory if one of the following
  37 # is true:
  38 # - one of the terminals (":" and ";") is the first or last sign
  39 # - two terminals occur directly after each other
  40 # - the path contains an element with a dot in it
  41 AC_MSG_CHECKING(LIBRARY_PATH variable)
  42 changequote(,)dnl
  43 case ${LIBRARY_PATH} in
  44   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  45     library_path_setting="contains current directory"
  46     ;;
  47   *)
  48     library_path_setting="ok"
  49     ;;
  50 esac
  51 changequote([,])dnl
  52 AC_MSG_RESULT($library_path_setting)
  53 if test "$library_path_setting" != "ok"; then
  54 AC_MSG_ERROR([
  55 *** LIBRARY_PATH shouldn't contain the current directory when
  56 *** building gcc. Please change the environment variable
  57 *** and run configure again.])
  58 fi
  59
  60 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  61 # since this would lead to problems installing/building glibc.
  62 # GCC_EXEC_PREFIX contains the current directory if one of the following
  63 # is true:
  64 # - one of the terminals (":" and ";") is the first or last sign
  65 # - two terminals occur directly after each other
  66 # - the path contains an element with a dot in it
  67 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  68 changequote(,)dnl
  69 case ${GCC_EXEC_PREFIX} in
  70   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  71     gcc_exec_prefix_setting="contains current directory"
  72     ;;
  73   *)
  74     gcc_exec_prefix_setting="ok"
  75     ;;
  76 esac
  77 changequote([,])dnl
  78 AC_MSG_RESULT($gcc_exec_prefix_setting)
  79 if test "$gcc_exec_prefix_setting" != "ok"; then
  80 AC_MSG_ERROR([
  81 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  82 *** building gcc. Please change the environment variable
  83 *** and run configure again.])
  84 fi
  85
  86 # Check for additional parameters
  87
  88 # With GNU ld
  89 AC_ARG_WITH(gnu-ld,
  90 [  --with-gnu-ld           arrange to work with GNU ld.],
  91 gnu_ld_flag="$with_gnu_ld",
  92 gnu_ld_flag=no)
  93
  94 # With pre-defined ld
  95 AC_ARG_WITH(ld,
  96 [  --with-ld               arrange to use the specified ld (full pathname).],
  97 DEFAULT_LINKER="$with_ld")
  98 if test x"${DEFAULT_LINKER+set}" = x"set"; then
  99   if test ! -x "$DEFAULT_LINKER"; then
 100     AC_MSG_WARN([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 101   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 102     gnu_ld_flag=yes
 103   fi
 104   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 105         [Define to enable the use of a default linker.])
 106 fi
 107
 108 # With GNU as
 109 AC_ARG_WITH(gnu-as,
 110 [  --with-gnu-as           arrange to work with GNU as.],
 111 gas_flag="$with_gnu_as",
 112 gas_flag=no)
 113
 114 AC_ARG_WITH(as,
 115 [  --with-as               arrange to use the specified as (full pathname).],
 116 DEFAULT_ASSEMBLER="$with_as")
 117 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 118   if test ! -x "$DEFAULT_ASSEMBLER"; then
 119     AC_MSG_WARN([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 120   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 121     gas_flag=yes
 122   fi
 123   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 124         [Define to enable the use of a default assembler.])
 125 fi
 126
 127 # With stabs
 128 AC_ARG_WITH(stabs,
 129 [  --with-stabs            arrange to use stabs instead of host debug format.],
 130 stabs="$with_stabs",
 131 stabs=no)
 132
 133 # With ELF
 134 AC_ARG_WITH(elf,
 135 [  --with-elf              arrange to use ELF instead of host debug format.],
 136 elf="$with_elf",
 137 elf=no)
 138
 139 # Specify the local prefix
 140 local_prefix=
 141 AC_ARG_WITH(local-prefix,
 142 [  --with-local-prefix=DIR specifies directory to put local include.],
 143 [case "${withval}" in
 144 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 145 no)     ;;
 146 *)      local_prefix=$with_local_prefix ;;
 147 esac])
 148
 149 # Default local prefix if it is empty
 150 if test x$local_prefix = x; then
 151         local_prefix=/usr/local
 152 fi
 153
 154 # Build a new-libstdc++ system (ie libstdc++-v3)
 155 AC_MSG_CHECKING([for libstdc++ to install])
 156 AC_ARG_ENABLE(libstdcxx-v3,
 157 [  --enable-libstdcxx-v3
 158                           enable libstdc++-v3 for building and installation],
 159   [enable_libstdcxx_v3="$enableval"], [enable_libstdcxx_v3=yes])
 160
 161 if test x$enable_libstdcxx_v3 = xyes; then
 162   AC_MSG_RESULT(v3)
 163   HAVE_LIBSTDCXX_V3=1
 164   ac_esn=1
 165 else
 166   AC_MSG_RESULT(v2)
 167   HAVE_LIBSTDCXX_V3=0
 168   ac_esn=0
 169 fi
 170
 171 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 172 # passed in by the toplevel make and thus we'd get different behavior
 173 # depending on where we built the sources.
 174 gcc_gxx_include_dir=
 175 # Specify the g++ header file directory
 176 AC_ARG_WITH(gxx-include-dir,
 177 [  --with-gxx-include-dir=DIR
 178                           specifies directory to put g++ header files.],
 179 [case "${withval}" in
 180 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 181 no)     ;;
 182 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 183 esac])
 184
 185 if test x${gcc_gxx_include_dir} = x; then
 186   if test x${enable_version_specific_runtime_libs} = xyes; then
 187     gcc_gxx_include_dir='${libsubdir}/include/g++'
 188   else
 189     topsrcdir=${srcdir}/.. . ${srcdir}/../config.if
 190 changequote(<<, >>)dnl
 191     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/include/g++"-${libstdcxx_interface}
 192 changequote([, ])dnl
 193   fi
 194 fi
 195
 196 # Enable expensive internal checks
 197 AC_ARG_ENABLE(checking,
 198 [  --enable-checking[=LIST]
 199                           enable expensive run-time checks.  With LIST,
 200                           enable only specific categories of checks.
 201                           Categories are: misc,tree,rtl,gc,gcac; default
 202                           is misc,tree,gc],
 203 [ac_checking=
 204 ac_tree_checking=
 205 ac_rtl_checking=
 206 ac_gc_checking=
 207 ac_gc_always_collect=
 208 case "${enableval}" in
 209 yes)    ac_checking=1 ; ac_tree_checking=1 ; ac_gc_checking=1 ;;
 210 no)     ;;
 211 *)      IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 212         set fnord $enableval; shift
 213         IFS="$ac_save_IFS"
 214         for check
 215         do
 216                 case $check in
 217                 misc)   ac_checking=1 ;;
 218                 tree)   ac_tree_checking=1 ;;
 219                 rtl)    ac_rtl_checking=1 ;;
 220                 gc)     ac_gc_checking=1 ;;
 221                 gcac)   ac_gc_always_collect=1 ;;
 222                 *)      AC_MSG_ERROR(unknown check category $check) ;;
 223                 esac
 224         done
 225         ;;
 226 esac
 227 ],
 228 # Enable some checks by default for development versions of GCC
 229 [ac_checking=1; ac_tree_checking=1; ac_gc_checking=1;])
 230 if test x$ac_checking != x ; then
 231   AC_DEFINE(ENABLE_CHECKING, 1,
 232 [Define if you want more run-time sanity checks.  This one gets a grab
 233    bag of miscellaneous but relatively cheap checks.])
 234 fi
 235 if test x$ac_tree_checking != x ; then
 236   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 237 [Define if you want all operations on trees (the basic data
 238    structure of the front ends) to be checked for dynamic type safety
 239    at runtime.  This is moderately expensive.])
 240 fi
 241 if test x$ac_rtl_checking != x ; then
 242   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 243 [Define if you want all operations on RTL (the basic data structure
 244    of the optimizer and back end) to be checked for dynamic type safety
 245    at runtime.  This is quite expensive.])
 246 fi
 247 if test x$ac_gc_checking != x ; then
 248   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 249 [Define if you want the garbage collector to do object poisoning and
 250    other memory allocation checks.  This is quite expensive.])
 251 fi
 252 if test x$ac_gc_always_collect != x ; then
 253   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 254 [Define if you want the garbage collector to operate in maximally
 255    paranoid mode, validating the entire heap and collecting garbage at
 256    every opportunity.  This is extremely expensive.])
 257 fi
 258
 259
 260 AC_ARG_ENABLE(cpp,
 261 [  --disable-cpp           don't provide a user-visible C preprocessor.],
 262 [], [enable_cpp=yes])
 263
 264 AC_ARG_WITH(cpp_install_dir,
 265 [  --with-cpp-install-dir=DIR
 266                           install the user visible C preprocessor in DIR
 267                           (relative to PREFIX) as well as PREFIX/bin.],
 268 [if test x$withval = xyes; then
 269   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 270 elif test x$withval != xno; then
 271   cpp_install_dir=$withval
 272 fi])
 273
 274 # Link cpplib into the compiler proper, for C/C++/ObjC.  Defaults to on.
 275 maybe_cpplib=libcpp.a
 276 AC_ARG_ENABLE(c-cpplib,
 277 [  --enable-c-cpplib       link cpplib directly into C and C++ compilers
 278                            (HIGHLY EXPERIMENTAL).],
 279 [if test x$enable_c_cpplib != xyes; then
 280   maybe_cpplib=
 281 fi]
 282 )
 283 if test x$maybe_cpplib != x ; then
 284   AC_DEFINE(USE_CPPLIB, 1,
 285   [Define if you want the preprocessor merged into the C and C++ compilers.])
 286 fi
 287 AC_SUBST(maybe_cpplib)
 288
 289 # Enable Multibyte Characters for C/C++
 290 AC_ARG_ENABLE(c-mbchar,
 291 [  --enable-c-mbchar       Enable multibyte characters for C and C++.],
 292 if test x$enable_c_mbchar != xno; then
 293   AC_DEFINE(MULTIBYTE_CHARS, 1,
 294   [Define if you want the C and C++ compilers to support multibyte
 295    character sets for source code.])
 296 fi)
 297
 298 # Enable threads
 299 # Pass with no value to take the default
 300 # Pass with a value to specify a thread package
 301 AC_ARG_ENABLE(threads,
 302 [  --enable-threads        enable thread usage for target GCC.
 303   --enable-threads=LIB    use LIB thread package for target GCC.],,
 304 enable_threads='')
 305
 306 enable_threads_flag=$enable_threads
 307 # Check if a valid thread package
 308 case x${enable_threads_flag} in
 309         x | xno)
 310                 # No threads
 311                 target_thread_file='single'
 312                 ;;
 313         xyes)
 314                 # default
 315                 target_thread_file=''
 316                 ;;
 317         xdecosf1 | xirix | xmach | xos2 | xposix | xpthreads | xsingle | \
 318         xsolaris | xwin32 | xdce | xvxworks | xaix)
 319                 target_thread_file=$enable_threads_flag
 320                 ;;
 321         *)
 322                 echo "$enable_threads is an unknown thread package" 1>&2
 323                 exit 1
 324                 ;;
 325 esac
 326
 327 AC_ARG_ENABLE(objc-gc,
 328 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 329                           the GNU Objective-C runtime.],
 330 if test x$enable_objc_gc = xno; then
 331         objc_boehm_gc=''
 332 else
 333         objc_boehm_gc=1
 334 fi,
 335 objc_boehm_gc='')
 336
 337 AC_ARG_WITH(dwarf2,
 338 [  --with-dwarf2          force the default debug format to be DWARF2.],
 339 dwarf2="$with_dwarf2",
 340 dwarf2=no)
 341
 342 AC_ARG_ENABLE(shared,
 343 [  --disable-shared       don't provide a shared libgcc.],
 344 [], [enable_shared=yes])
 345 AC_SUBST(enable_shared)
 346
 347 # Determine the host, build, and target systems
 348 AC_CANONICAL_SYSTEM
 349
 350 # Find the native compiler
 351 AC_PROG_CC
 352 AC_PROG_CC_C_O
 353 # autoconf is lame and doesn't give us any substitution variable for this.
 354 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 355   NO_MINUS_C_MINUS_O=yes
 356 else
 357   OUTPUT_OPTION='-o $@'
 358 fi
 359 AC_SUBST(NO_MINUS_C_MINUS_O)
 360 AC_SUBST(OUTPUT_OPTION)
 361
 362 gcc_AC_C_LONG_DOUBLE
 363
 364 AC_CACHE_CHECK(whether ${CC-cc} accepts -Wno-long-long,
 365 ac_cv_prog_cc_no_long_long,
 366 [save_CFLAGS="$CFLAGS"
 367 CFLAGS="-Wno-long-long"
 368 AC_TRY_COMPILE(,,ac_cv_prog_cc_no_long_long=yes,
 369                ac_cv_prog_cc_no_long_long=no)
 370 CFLAGS="$save_CFLAGS"])
 371 strict1_warn=
 372 if test $ac_cv_prog_cc_no_long_long = yes; then
 373   strict1_warn="-pedantic -Wno-long-long"
 374 fi
 375 AC_SUBST(strict1_warn)
 376
 377 # If the native compiler is GCC, we can enable warnings even in stage1.
 378 # That's useful for people building cross-compilers, or just running a
 379 # quick `make'.
 380 warn_cflags=
 381 if test "x$GCC" = "xyes"; then
 382   warn_cflags='$(GCC_WARN_CFLAGS)'
 383 fi
 384 AC_SUBST(warn_cflags)
 385
 386 # Stage specific cflags for build.
 387 stage1_cflags=
 388 case $build in
 389 vax-*-*)
 390   if test x$GCC = xyes
 391   then
 392     stage1_cflags="-Wa,-J"
 393   else
 394     stage1_cflags="-J"
 395   fi
 396   ;;
 397 esac
 398 AC_SUBST(stage1_cflags)
 399
 400 AC_PROG_MAKE_SET
 401
 402 AC_MSG_CHECKING([whether a default assembler was specified])
 403 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 404     if test x"$gas_flag" = x"no"; then
 405         AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 406     else
 407         AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 408     fi
 409 else
 410     AC_MSG_RESULT(no)
 411 fi
 412
 413 AC_MSG_CHECKING([whether a default linker was specified])
 414 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 415     if test x"$gnu_ld_flag" = x"no"; then
 416         AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 417     else
 418         AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 419     fi
 420 else
 421     AC_MSG_RESULT(no)
 422 fi
 423
 424 AC_MSG_CHECKING(for GNU C library)
 425 AC_CACHE_VAL(gcc_cv_glibc,
 426 [AC_TRY_COMPILE(
 427   [#include <features.h>],[
 428 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 429 #error Not a GNU C library system
 430 #endif],
 431   [gcc_cv_glibc=yes],
 432   gcc_cv_glibc=no)])
 433 AC_MSG_RESULT($gcc_cv_glibc)
 434 if test $gcc_cv_glibc = yes; then
 435   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 436 fi
 437
 438 AC_C_INLINE
 439
 440 # Find some useful tools
 441 AC_PROG_AWK
 442 gcc_AC_PROG_LN
 443 gcc_AC_PROG_LN_S
 444 gcc_AC_C_VOLATILE
 445 AC_PROG_RANLIB
 446 gcc_AC_PROG_INSTALL
 447
 448 AC_HEADER_STDC
 449 AC_HEADER_TIME
 450 gcc_AC_HEADER_STRING
 451 AC_HEADER_SYS_WAIT
 452 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h \
 453                  fcntl.h unistd.h stab.h sys/file.h sys/time.h \
 454                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 455                  direct.h malloc.h langinfo.h iconv.h)
 456
 457 # Check for thread headers.
 458 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 459 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 460
 461 # See if GNAT has been installed
 462 AC_CHECK_PROG(gnat, gnatbind, yes, no)
 463
 464 # Do we have a single-tree copy of texinfo?
 465 if test -f $srcdir/../texinfo/Makefile.in; then
 466   MAKEINFO='$(objdir)/../texinfo/makeinfo/makeinfo'
 467   gcc_cv_prog_makeinfo_modern=yes
 468   AC_MSG_RESULT([Using makeinfo from the unified source tree.])
 469 else
 470   # See if makeinfo has been installed and is modern enough
 471   # that we can use it.
 472   gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 473   [GNU texinfo.* \([0-9][0-9.]*\)],
 474   [3.1[2-9] | 3.[2-9][0-9] | 4.* | 1.6[89] | 1.7[0-9]])
 475 fi
 476
 477 if test $gcc_cv_prog_makeinfo_modern = no; then
 478   AC_MSG_WARN([
 479 *** Makeinfo is missing or too old.
 480 *** Info documentation will not be built or installed.])
 481   BUILD_INFO=
 482   INSTALL_INFO=
 483 else
 484   BUILD_INFO=info               AC_SUBST(BUILD_INFO)
 485   INSTALL_INFO=install-info     AC_SUBST(INSTALL_INFO)
 486 fi
 487
 488 # How about lex?
 489 dnl Don't use AC_PROG_LEX; we insist on flex.
 490 dnl LEXLIB is not useful in gcc.
 491 if test -f $srcdir/../flex/skel.c; then
 492   FLEX='$(objdir)/../flex/flex'
 493 else
 494   AC_CHECK_PROG(FLEX, flex, flex, false)
 495 fi
 496
 497 # Bison?
 498 # The -L switch is so bison can find its skeleton file.
 499 if test -f $srcdir/../bison/bison.simple; then
 500   BISON='$(objdir)/../bison/bison -L $(srcdir)/../bison/'
 501 else
 502   AC_CHECK_PROG(BISON, bison, bison, false)
 503 fi
 504
 505 # See if the stage1 system preprocessor understands the ANSI C
 506 # preprocessor stringification operator.
 507 AC_C_STRINGIZE
 508
 509 # Use <inttypes.h> only if it exists,
 510 # doesn't clash with <sys/types.h>, and declares intmax_t.
 511 AC_MSG_CHECKING(for inttypes.h)
 512 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 513 [AC_TRY_COMPILE(
 514   [#include <sys/types.h>
 515 #include <inttypes.h>],
 516   [intmax_t i = -1;],
 517   [gcc_cv_header_inttypes_h=yes],
 518   gcc_cv_header_inttypes_h=no)])
 519 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 520 if test $gcc_cv_header_inttypes_h = yes; then
 521   AC_DEFINE(HAVE_INTTYPES_H, 1,
 522         [Define if you have a working <inttypes.h> header file.])
 523 fi
 524
 525 #
 526 # Determine if enumerated bitfields are unsigned.   ISO C says they can
 527 # be either signed or unsigned.
 528 #
 529 AC_CACHE_CHECK(for unsigned enumerated bitfields, gcc_cv_enum_bf_unsigned,
 530 [AC_TRY_RUN(#include <stdlib.h>
 531 enum t { BLAH = 128 } ;
 532 struct s_t { enum t member : 8; } s ;
 533 int main(void)
 534 {
 535         s.member = BLAH;
 536         if (s.member < 0) exit(1);
 537         exit(0);
 538
 539 }, gcc_cv_enum_bf_unsigned=yes, gcc_cv_enum_bf_unsigned=no, gcc_cv_enum_bf_unsigned=yes)])
 540 if test $gcc_cv_enum_bf_unsigned = yes; then
 541   AC_DEFINE(ENUM_BITFIELDS_ARE_UNSIGNED, 1,
 542     [Define if enumerated bitfields are treated as unsigned values.])
 543 fi
 544
 545 AC_CHECK_FUNCS(strtoul bsearch putenv popen bcopy \
 546         strchr strrchr kill getrlimit setrlimit atoll atoq \
 547         sysconf isascii gettimeofday strsignal putc_unlocked fputc_unlocked \
 548         fputs_unlocked getrusage valloc iconv nl_langinfo)
 549
 550 AC_CHECK_TYPE(ssize_t, int)
 551
 552 # Try to determine the array type of the second argument of getgroups
 553 # for the target system (int or gid_t).
 554 AC_TYPE_GETGROUPS
 555 if test "${target}" = "${build}"; then
 556   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
 557 else
 558   case "${target}" in
 559         # This condition may need some tweaking.  It should include all
 560         # targets where the array type of the second argument of getgroups
 561         # is int and the type of gid_t is not equivalent to int.
 562         *-*-sunos* | *-*-ultrix*)
 563                 TARGET_GETGROUPS_T=int
 564                 ;;
 565         *)
 566                 TARGET_GETGROUPS_T=gid_t
 567                 ;;
 568   esac
 569 fi
 570 AC_SUBST(TARGET_GETGROUPS_T)
 571
 572 gcc_AC_FUNC_VFPRINTF_DOPRNT
 573 gcc_AC_FUNC_PRINTF_PTR
 574
 575 case "${host}" in
 576 *-*-uwin*)
 577   # Under some versions of uwin, vfork is notoriously buggy and the test
 578   # can hang configure; on other versions, vfork exists just as a stub.
 579   # FIXME: This should be removed once vfork in uwin's runtime is fixed.
 580   ac_cv_func_vfork_works=no
 581   ;;
 582 esac
 583 AC_FUNC_VFORK
 584 AC_FUNC_MMAP_ANYWHERE
 585 AC_FUNC_MMAP_FILE
 586
 587 # We will need to find libiberty.h and ansidecl.h
 588 saved_CFLAGS="$CFLAGS"
 589 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
 590 gcc_AC_CHECK_DECLS(bcopy \
 591         getenv atol sbrk abort atof getcwd getwd \
 592         strsignal putc_unlocked fputs_unlocked strstr environ \
 593         malloc realloc calloc free basename getopt, , ,[
 594 #include "gansidecl.h"
 595 #include "system.h"])
 596
 597 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
 598 #include "gansidecl.h"
 599 #include "system.h"
 600 #ifdef HAVE_SYS_RESOURCE_H
 601 #include <sys/resource.h>
 602 #endif
 603 ])
 604
 605 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
 606 CFLAGS="$saved_CFLAGS"
 607
 608 # mkdir takes a single argument on some systems.
 609 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
 610
 611 # File extensions
 612 manext='.1'
 613 objext='.o'
 614 AC_SUBST(manext)
 615 AC_SUBST(objext)
 616
 617 build_xm_file=
 618 build_xm_defines=
 619 build_install_headers_dir=install-headers-tar
 620 build_exeext=
 621 host_xm_file=
 622 host_xm_defines=
 623 host_xmake_file=
 624 host_truncate_target=
 625 host_exeext=
 626
 627 # Decode the host machine, then the target machine.
 628 # For the host machine, we save the xm_file variable as host_xm_file;
 629 # then we decode the target machine and forget everything else
 630 # that came from the host machine.
 631 for machine in $build $host $target; do
 632         . ${srcdir}/config.gcc
 633 done
 634
 635 extra_objs="${host_extra_objs} ${extra_objs}"
 636
 637 # Default the target-machine variables that were not explicitly set.
 638 if test x"$tm_file" = x
 639 then tm_file=$cpu_type/$cpu_type.h; fi
 640
 641 if test x$extra_headers = x
 642 then extra_headers=; fi
 643
 644 if test x"$xm_file" = x
 645 then xm_file=$cpu_type/xm-$cpu_type.h; fi
 646
 647 if test x$md_file = x
 648 then md_file=$cpu_type/$cpu_type.md; fi
 649
 650 if test x$out_file = x
 651 then out_file=$cpu_type/$cpu_type.c; fi
 652
 653 if test x"$tmake_file" = x
 654 then tmake_file=$cpu_type/t-$cpu_type
 655 fi
 656
 657 if test x"$dwarf2" = xyes
 658 then tm_file="$tm_file tm-dwarf2.h"
 659 fi
 660
 661 if test x$float_format = x
 662 then float_format=i64
 663 fi
 664
 665 if test $float_format = none
 666 then float_h_file=Makefile.in
 667 else float_h_file=float-$float_format.h
 668 fi
 669
 670 # Handle cpp installation.
 671 if test x$enable_cpp != xno
 672 then
 673   tmake_file="$tmake_file t-install-cpp"
 674 fi
 675
 676 # Say what files are being used for the output code and MD file.
 677 echo "Using \`$srcdir/config/$out_file' to output insns."
 678 echo "Using \`$srcdir/config/$md_file' as machine description file."
 679
 680 count=a
 681 for f in $tm_file; do
 682         count=${count}x
 683 done
 684 if test $count = ax; then
 685         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
 686 else
 687         echo "Using the following target machine macro files:"
 688         for f in $tm_file; do
 689                 echo "  $srcdir/config/$f"
 690         done
 691 fi
 692
 693 count=a
 694 for f in $host_xm_file; do
 695         count=${count}x
 696 done
 697 if test $count = ax; then
 698         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
 699 else
 700         echo "Using the following host machine macro files:"
 701         for f in $host_xm_file; do
 702                 echo "  $srcdir/config/$f"
 703         done
 704 fi
 705
 706 if test "$host_xm_file" != "$build_xm_file"; then
 707         count=a
 708         for f in $build_xm_file; do
 709                 count=${count}x
 710         done
 711         if test $count = ax; then
 712                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
 713         else
 714                 echo "Using the following build machine macro files:"
 715                 for f in $build_xm_file; do
 716                         echo "  $srcdir/config/$f"
 717                 done
 718         fi
 719 fi
 720
 721 if test x$thread_file = x; then
 722         if test x$target_thread_file != x; then
 723                 thread_file=$target_thread_file
 724         else
 725                 thread_file='single'
 726         fi
 727 fi
 728
 729 # Set up the header files.
 730 # $links is the list of header files to create.
 731 # $vars is the list of shell variables with file names to include.
 732 # auto-host.h is the file containing items generated by autoconf and is
 733 # the first file included by config.h.
 734 null_defines=
 735 host_xm_file="auto-host.h gansidecl.h ${host_xm_file} hwint.h"
 736
 737 # If host=build, it is correct to have hconfig include auto-host.h
 738 # as well.  If host!=build, we are in error and need to do more
 739 # work to find out the build config parameters.
 740 if test x$host = x$build
 741 then
 742         build_xm_file="auto-host.h gansidecl.h ${build_xm_file} hwint.h"
 743 else
 744         # We create a subdir, then run autoconf in the subdir.
 745         # To prevent recursion we set host and build for the new
 746         # invocation of configure to the build for this invocation
 747         # of configure.
 748         tempdir=build.$$
 749         rm -rf $tempdir
 750         mkdir $tempdir
 751         cd $tempdir
 752         case ${srcdir} in
 753         /*) realsrcdir=${srcdir};;
 754         *) realsrcdir=../${srcdir};;
 755         esac
 756         CC=${CC_FOR_BUILD} ${realsrcdir}/configure \
 757                 --target=$target --host=$build --build=$build
 758
 759         # We just finished tests for the build machine, so rename
 760         # the file auto-build.h in the gcc directory.
 761         mv auto-host.h ../auto-build.h
 762         cd ..
 763         rm -rf $tempdir
 764         build_xm_file="auto-build.h gansidecl.h ${build_xm_file} hwint.h"
 765 fi
 766
 767 xm_file="gansidecl.h ${xm_file}"
 768 tm_file="gansidecl.h ${tm_file}"
 769
 770 vars="host_xm_file tm_file tm_p_file xm_file build_xm_file"
 771 links="config.h tm.h tm_p.h tconfig.h hconfig.h"
 772 defines="host_xm_defines null_defines null_defines xm_defines build_xm_defines"
 773
 774 rm -f config.bak
 775 if test -f config.status; then mv -f config.status config.bak; fi
 776
 777 # Make the links.
 778 while test -n "$vars"
 779 do
 780         set $vars; var=$1; shift; vars=$*
 781         set $links; link=$1; shift; links=$*
 782         set $defines; define=$1; shift; defines=$*
 783
 784         rm -f $link
 785         # Make sure the file is created, even if it is empty.
 786         echo >$link
 787
 788         # Define TARGET_CPU_DEFAULT if the system wants one.
 789         # This substitutes for lots of *.h files.
 790         if test "$target_cpu_default" != "" -a $link = tm.h
 791         then
 792                 echo "#define TARGET_CPU_DEFAULT ($target_cpu_default)" >>$link
 793         fi
 794         if test $link = tm.h
 795         then
 796                 echo "#ifndef GENERATOR_FILE" >>$link
 797                 echo "#include \"insn-codes.h\"" >>$link
 798                 echo "#endif" >>$link
 799         fi
 800
 801         for file in `eval echo '$'$var`; do
 802                 case $file in
 803                 auto-host.h | auto-build.h )
 804                         ;;
 805                 *)
 806                         echo '#ifdef IN_GCC' >>$link
 807                         ;;
 808                 esac
 809                 echo "#include \"$file\"" >>$link
 810                 case $file in
 811                 auto-host.h | auto-build.h )
 812                         ;;
 813                 *)
 814                         echo '#endif' >>$link
 815                         ;;
 816                 esac
 817         done
 818
 819         for def in `eval echo '$'$define`; do
 820                 echo "#ifndef $def" >>$link
 821                 echo "#define $def" >>$link
 822                 echo "#endif" >>$link
 823         done
 824 done
 825
 826 # Truncate the target if necessary
 827 if test x$host_truncate_target != x; then
 828         target=`echo $target | sed -e 's/\(..............\).*/\1/'`
 829 fi
 830
 831 # Get the version trigger filename from the toplevel
 832 if test "${with_gcc_version_trigger+set}" = set; then
 833         gcc_version_trigger=$with_gcc_version_trigger
 834 else
 835         gcc_version_trigger=${srcdir}/version.c
 836 fi
 837 changequote(,)dnl
 838 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*\"\([^\"]*\)\".*/\1/'`
 839 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
 840
 841 # Compile in configure arguments.
 842 if test -f configargs.h ; then
 843         # Being re-configured.
 844         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*\"\([^\"]*\)\".*/\1/'`
 845         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
 846 else
 847         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
 848 fi
 849 cat > configargs.h <<EOF
 850 /* Generated automatically. */
 851 static const char configuration_arguments[] = "$gcc_config_arguments";
 852 EOF
 853 changequote([,])dnl
 854
 855 # Internationalization
 856 PACKAGE=gcc
 857 VERSION="$gcc_version"
 858 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE",
 859         [Define to the name of the distribution.])
 860 AC_DEFINE_UNQUOTED(VERSION, "$VERSION",
 861         [Define to the version of the distribution.])
 862 AC_SUBST(PACKAGE)
 863 AC_SUBST(VERSION)
 864
 865 ALL_LINGUAS="en_GB"
 866
 867 # Enable NLS support by default
 868 AC_ARG_ENABLE(nls,
 869   [  --enable-nls            use Native Language Support (default)],
 870   , enable_nls=yes)
 871
 872 # if cross compiling, disable NLS support.
 873 # It's not worth the trouble, at least for now.
 874
 875 if test "${build}" != "${host}" && test "x$enable_nls" = "xyes"; then
 876   AC_MSG_WARN(Disabling NLS support for canadian cross compiler.)
 877   enable_nls=no
 878 fi
 879
 880 # if NLS is enabled, also enable check in po subdir
 881 if test $enable_nls = yes; then
 882   CHECK_PO=check-po
 883 else
 884   CHECK_PO=""
 885 fi
 886
 887 AC_SUBST(CHECK_PO)
 888
 889 AM_GNU_GETTEXT
 890 XGETTEXT="AWK='$AWK' \$(SHELL) \$(top_srcdir)/exgettext $XGETTEXT"
 891
 892 # Windows32 Registry support for specifying GCC installation paths.
 893 AC_ARG_ENABLE(win32-registry,
 894 [  --disable-win32-registry
 895                           Disable lookup of installation paths in the
 896                          Registry on Windows hosts.
 897   --enable-win32-registry Enable registry lookup (default).
 898   --enable-win32-registry=KEY
 899                           Use KEY instead of GCC version as the last portion
 900                          of the registry key.],,)
 901
 902 AC_MSG_CHECKING(whether windows registry support is requested)
 903 if test x$enable_win32_registry != xno; then
 904   AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
 905 [Define to 1 if installation paths should be looked up in Windows32
 906    Registry. Ignored on non windows32 hosts.])
 907   AC_MSG_RESULT(yes)
 908 else
 909   AC_MSG_RESULT(no)
 910 fi
 911
 912 # Check if user specified a different registry key.
 913 case x${enable_win32_registry} in
 914 x | xyes)
 915   # default.
 916   gcc_cv_win32_registry_key="$VERSION"
 917   ;;
 918 xno)
 919   # no registry lookup.
 920   gcc_cv_win32_registry_key=''
 921   ;;
 922 *)
 923   # user-specified key.
 924   gcc_cv_win32_registry_key="$enable_win32_registry"
 925   ;;
 926 esac
 927
 928 if test x$enable_win32_registry != xno; then
 929   AC_MSG_CHECKING(registry key on windows hosts)
 930   AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$gcc_cv_win32_registry_key",
 931         [Define to be the last portion of registry key on windows hosts.])
 932   AC_MSG_RESULT($gcc_cv_win32_registry_key)
 933 fi
 934
 935 # Get an absolute path to the GCC top-level source directory
 936 holddir=`pwd`
 937 cd $srcdir
 938 topdir=`pwd`
 939 cd $holddir
 940
 941 # Conditionalize the makefile for this host machine.
 942 # Make-host contains the concatenation of all host makefile fragments
 943 # [there can be more than one].  This file is built by configure.frag.
 944 host_overrides=Make-host
 945 dep_host_xmake_file=
 946 for f in .. ${host_xmake_file}
 947 do
 948         if test -f ${srcdir}/config/$f
 949         then
 950                 dep_host_xmake_file="${dep_host_xmake_file} ${srcdir}/config/$f"
 951         fi
 952 done
 953
 954 # Conditionalize the makefile for this target machine.
 955 # Make-target contains the concatenation of all host makefile fragments
 956 # [there can be more than one].  This file is built by configure.frag.
 957 target_overrides=Make-target
 958 dep_tmake_file=
 959 for f in .. ${tmake_file}
 960 do
 961         if test -f ${srcdir}/config/$f
 962         then
 963                 dep_tmake_file="${dep_tmake_file} ${srcdir}/config/$f"
 964         fi
 965 done
 966
 967 # If the host doesn't support symlinks, modify CC in
 968 # FLAGS_TO_PASS so CC="stage1/xgcc -Bstage1/" works.
 969 # Otherwise, we can use "CC=$(CC)".
 970 rm -f symtest.tem
 971 if $symbolic_link $srcdir/gcc.c symtest.tem 2>/dev/null
 972 then
 973         cc_set_by_configure="\$(CC)"
 974         quoted_cc_set_by_configure="\$(CC)"
 975         stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
 976 else
 977         rm -f symtest.tem
 978         if cp -p $srcdir/gcc.c symtest.tem 2>/dev/null
 979         then
 980                 symbolic_link="cp -p"
 981         else
 982                 symbolic_link="cp"
 983         fi
 984         cc_set_by_configure="\`case '\$(CC)' in stage*) echo '\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\$(CC)';; esac\`"
 985         quoted_cc_set_by_configure="\\\`case '\\\$(CC)' in stage*) echo '\\\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(CC)';; esac\\\`"
 986         stage_prefix_set_by_configure="\`case '\$(STAGE_PREFIX)' in stage*) echo '\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\$(STAGE_PREFIX)';; esac\`"
 987 fi
 988 rm -f symtest.tem
 989
 990 out_object_file=`basename $out_file .c`.o
 991
 992 tm_file_list=
 993 for f in $tm_file; do
 994   case $f in
 995     gansidecl.h )
 996        tm_file_list="${tm_file_list} $f" ;;
 997     *) tm_file_list="${tm_file_list} \$(srcdir)/config/$f" ;;
 998   esac
 999 done
1000
1001 host_xm_file_list=
1002 for f in $host_xm_file; do
1003   case $f in
1004     auto-host.h | gansidecl.h | hwint.h )
1005        host_xm_file_list="${host_xm_file_list} $f" ;;
1006     *) host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f" ;;
1007   esac
1008 done
1009
1010 build_xm_file_list=
1011 for f in $build_xm_file; do
1012   case $f in
1013     auto-build.h | auto-host.h | gansidecl.h | hwint.h )
1014        build_xm_file_list="${build_xm_file_list} $f" ;;
1015     *) build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f" ;;
1016   esac
1017 done
1018
1019 # Define macro CROSS_COMPILE in compilation
1020 # if this is a cross-compiler.
1021 # Also use all.cross instead of all.internal
1022 # and add cross-make to Makefile.
1023 cross_overrides="/dev/null"
1024 if test x$host != x$target
1025 then
1026         cross_defines="CROSS=-DCROSS_COMPILE"
1027         cross_overrides="${topdir}/cross-make"
1028 fi
1029
1030 # If this is a cross-compiler that does not
1031 # have its own set of headers then define
1032 # inhibit_libc
1033
1034 # If this is using newlib, then define inhibit_libc in
1035 # LIBGCC2_CFLAGS.  This will cause __eprintf to be left out of
1036 # libgcc.a, but that's OK because newlib should have its own version of
1037 # assert.h.
1038 inhibit_libc=
1039 if [test x$host != x$target] && [test x$with_headers = x]; then
1040        inhibit_libc=-Dinhibit_libc
1041 else
1042        if [test x$with_newlib = xyes]; then
1043                inhibit_libc=-Dinhibit_libc
1044        fi
1045 fi
1046 AC_SUBST(inhibit_libc)
1047
1048 # When building gcc with a cross-compiler, we need to fix a few things.
1049 # This must come after cross-make as we want all.build to override
1050 # all.cross.
1051 build_overrides="/dev/null"
1052 if test x$build != x$host
1053 then
1054         build_overrides="${topdir}/build-make"
1055 fi
1056
1057 # Expand extra_headers to include complete path.
1058 # This substitutes for lots of t-* files.
1059 extra_headers_list=
1060 if test "x$extra_headers" = x
1061 then true
1062 else
1063         # Prepend ${srcdir}/ginclude/ to every entry in extra_headers.
1064         for file in $extra_headers;
1065         do
1066                 extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/${file}"
1067         done
1068 fi
1069
1070 if test x$use_collect2 = xno; then
1071         use_collect2=
1072 fi
1073
1074 # Add a definition of USE_COLLECT2 if system wants one.
1075 # Also tell toplev.c what to do.
1076 # This substitutes for lots of t-* files.
1077 if test x$use_collect2 = x
1078 then
1079         will_use_collect2=
1080         maybe_use_collect2=
1081 else
1082         will_use_collect2="collect2"
1083         maybe_use_collect2="-DUSE_COLLECT2"
1084 fi
1085
1086 # If we have gas in the build tree, make a link to it.
1087 if test -f ../gas/Makefile; then
1088         rm -f as; $symbolic_link ../gas/as-new$host_exeext as$host_exeext 2>/dev/null
1089 fi
1090
1091 # If we have nm in the build tree, make a link to it.
1092 if test -f ../binutils/Makefile; then
1093         rm -f nm; $symbolic_link ../binutils/nm-new$host_exeext nm$host_exeext 2>/dev/null
1094 fi
1095
1096 # If we have ld in the build tree, make a link to it.
1097 if test -f ../ld/Makefile; then
1098 #       if test x$use_collect2 = x; then
1099 #               rm -f ld; $symbolic_link ../ld/ld-new$host_exeext ld$host_exeext 2>/dev/null
1100 #       else
1101                 rm -f collect-ld; $symbolic_link ../ld/ld-new$host_exeext collect-ld$host_exeext 2>/dev/null
1102 #       fi
1103 fi
1104
1105 # Figure out what assembler we will be using.
1106 AC_MSG_CHECKING(what assembler to use)
1107 gcc_cv_as=
1108 gcc_cv_gas_major_version=
1109 gcc_cv_gas_minor_version=
1110 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1111 if test -x "$DEFAULT_ASSEMBLER"; then
1112         gcc_cv_as="$DEFAULT_ASSEMBLER"
1113 elif test -x "$AS"; then
1114         gcc_cv_as="$AS"
1115 elif test -x as$host_exeext; then
1116         # Build using assembler in the current directory.
1117         gcc_cv_as=./as$host_exeext
1118 elif test -f $gcc_cv_as_gas_srcdir/configure.in -a -f ../gas/Makefile; then
1119         # Single tree build which includes gas.
1120         for f in $gcc_cv_as_gas_srcdir/configure $gcc_cv_as_gas_srcdir/configure.in $gcc_cv_as_gas_srcdir/Makefile.in
1121         do
1122 changequote(,)dnl
1123                 gcc_cv_gas_version=`grep '^VERSION=[0-9]*\.[0-9]*' $f`
1124 changequote([,])dnl
1125                 if test x$gcc_cv_gas_version != x; then
1126                         break
1127                 fi
1128         done
1129 changequote(,)dnl
1130         gcc_cv_gas_major_version=`expr "$gcc_cv_gas_version" : "VERSION=\([0-9]*\)"`
1131         gcc_cv_gas_minor_version=`expr "$gcc_cv_gas_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1132 changequote([,])dnl
1133 fi
1134
1135 if test "x$gcc_cv_as" = x -a x$host = x$target; then
1136         # Native build.
1137         # Search the same directories that the installed compiler will
1138         # search.  Else we may find the wrong assembler and lose.  If we
1139         # do not find a suitable assembler binary, then try the user's
1140         # path.
1141         #
1142         # Also note we have to check MD_EXEC_PREFIX before checking the
1143         # user's path.  Unfortunately, there is no good way to get at the
1144         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1145         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1146         # to be fixed as part of the make/configure rewrite too.
1147
1148         if test "x$exec_prefix" = xNONE; then
1149                 if test "x$prefix" = xNONE; then
1150                         test_prefix=/usr/local
1151                 else
1152                         test_prefix=$prefix
1153                 fi
1154         else
1155                 test_prefix=$exec_prefix
1156         fi
1157
1158         # If the loop below does not find an assembler, then use whatever
1159         # one we can find in the users's path.
1160         # user's path.
1161         as=as$host_exeext
1162
1163         test_dirs="$test_prefix/lib/gcc-lib/$target/$gcc_version \
1164                    $test_prefix/lib/gcc-lib/$target \
1165                    /usr/lib/gcc/$target/$gcc_version \
1166                    /usr/lib/gcc/$target \
1167                    $test_prefix/$target/bin/$target/$gcc_version \
1168                    $test_prefix/$target/bin \
1169                    /usr/libexec \
1170                    /usr/ccs/gcc \
1171                    /usr/ccs/bin \
1172                    /udk/usr/ccs/bin \
1173                    /bsd43/usr/lib/cmplrs/cc \
1174                    /usr/cross64/usr/bin \
1175                    /usr/lib/cmplrs/cc \
1176                    /sysv/usr/lib/cmplrs/cc \
1177                    /svr4/usr/lib/cmplrs/cc \
1178                    /usr/bin"
1179
1180         for dir in $test_dirs; do
1181                 if test -f $dir/as$host_exeext; then
1182                         gcc_cv_as=$dir/as$host_exeext
1183                         break;
1184                 fi
1185         done
1186 fi
1187 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1188   AC_MSG_RESULT("newly built gas")
1189 else
1190   AC_MSG_RESULT($gcc_cv_as)
1191 fi
1192
1193 # Figure out what nm we will be using.
1194 AC_MSG_CHECKING(what nm to use)
1195 if test -x nm$host_exeext; then
1196         gcc_cv_nm=./nm$host_exeext
1197 elif test x$host = x$target; then
1198         # Native build.
1199         gcc_cv_nm=nm$host_exeext
1200 fi
1201 AC_MSG_RESULT($gcc_cv_nm)
1202
1203 # Figure out what assembler alignment features are present.
1204 AC_MSG_CHECKING(assembler alignment features)
1205 gcc_cv_as_alignment_features=none
1206 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1207         # Gas version 2.6 and later support for .balign and .p2align.
1208         # bytes to skip when using .p2align.
1209         if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 6 -o "$gcc_cv_gas_major_version" -gt 2; then
1210                 gcc_cv_as_alignment_features=".balign and .p2align"
1211                 AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN)
1212         fi
1213         # Gas version 2.8 and later support specifying the maximum
1214         # bytes to skip when using .p2align.
1215         if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 8 -o "$gcc_cv_gas_major_version" -gt 2; then
1216                 gcc_cv_as_alignment_features=".p2align including maximum skip"
1217                 AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN)
1218         fi
1219 elif test x$gcc_cv_as != x; then
1220         # Check if we have .balign and .p2align
1221         echo ".balign  4" > conftest.s
1222         echo ".p2align  2" >> conftest.s
1223         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1224                 gcc_cv_as_alignment_features=".balign and .p2align"
1225                 AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN)
1226         fi
1227         rm -f conftest.s conftest.o
1228         # Check if specifying the maximum bytes to skip when
1229         # using .p2align is supported.
1230         echo ".p2align 4,,7" > conftest.s
1231         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1232                 gcc_cv_as_alignment_features=".p2align including maximum skip"
1233                 AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN)
1234         fi
1235         rm -f conftest.s conftest.o
1236 fi
1237 AC_MSG_RESULT($gcc_cv_as_alignment_features)
1238
1239 AC_MSG_CHECKING(assembler subsection support)
1240 gcc_cv_as_subsections=no
1241 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1242   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 9 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1243     gcc_cv_as_subsections="working .subsection -1"
1244   fi
1245 elif test x$gcc_cv_as != x; then
1246         # Check if we have .subsection
1247         echo ".subsection 1" > conftest.s
1248         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1249                 gcc_cv_as_subsections=".subsection"
1250                 if test x$gcc_cv_nm != x; then
1251                         cat > conftest.s <<EOF
1252 conftest_label1: .word 0
1253 .subsection -1
1254 conftest_label2: .word 0
1255 .previous
1256 EOF
1257                         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1258                                 $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
1259                                 $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
1260                                 if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1; then
1261                                         :
1262                                 else
1263                                         gcc_cv_as_subsections="working .subsection -1"
1264                                 fi
1265                         fi
1266                 fi
1267         fi
1268         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1269 fi
1270 if test x"$gcc_cv_as_subsections" = x"working .subsection -1"; then
1271         AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
1272 [Define if your assembler supports .subsection and .subsection -1 starts
1273    emitting at the beginning of your section.])
1274 fi
1275 AC_MSG_RESULT($gcc_cv_as_subsections)
1276
1277 AC_MSG_CHECKING(assembler weak support)
1278 gcc_cv_as_weak=no
1279 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1280   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 2 -o "$gcc_cv_gas_major_version" -gt 2; then
1281     gcc_cv_as_weak="yes"
1282   fi
1283 elif test x$gcc_cv_as != x; then
1284         # Check if we have .weak
1285         echo "  .weak foobar" > conftest.s
1286         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1287                 gcc_cv_as_weak="yes"
1288         fi
1289         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1290 fi
1291 if test x"$gcc_cv_as_weak" = xyes; then
1292         AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])
1293 fi
1294 AC_MSG_RESULT($gcc_cv_as_weak)
1295
1296 AC_MSG_CHECKING(assembler hidden support)
1297 gcc_cv_as_hidden=no
1298 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1299   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 10 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1300     gcc_cv_as_hidden="yes"
1301   fi
1302 elif test x$gcc_cv_as != x; then
1303         # Check if we have .hidden
1304         echo "  .hidden foobar" > conftest.s
1305         echo "foobar:" >> conftest.s
1306         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1307                 gcc_cv_as_hidden="yes"
1308         fi
1309         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1310 fi
1311 if test x"$gcc_cv_as_hidden" = xyes; then
1312         AC_DEFINE(HAVE_GAS_HIDDEN, 1,
1313                 [Define if your assembler supports .hidden.])
1314 fi
1315 AC_MSG_RESULT($gcc_cv_as_hidden)
1316
1317 case "$target" in
1318   sparc*-*-*)
1319     AC_CACHE_CHECK([assembler .register pseudo-op support],
1320         gcc_cv_as_register_pseudo_op, [
1321         gcc_cv_as_register_pseudo_op=unknown
1322         if test x$gcc_cv_as != x; then
1323             # Check if we have .register
1324             echo ".register %g2, #scratch" > conftest.s
1325             if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1326                 gcc_cv_as_register_pseudo_op=yes
1327             else
1328                 gcc_cv_as_register_pseudo_op=no
1329             fi
1330             rm -f conftest.s conftest.o
1331         fi
1332     ])
1333     if test "x$gcc_cv_as_register_pseudo_op" = xyes; then
1334         AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
1335                 [Define if your assembler supports .register.])
1336     fi
1337
1338     AC_CACHE_CHECK([assembler supports -relax],
1339         gcc_cv_as_relax_opt, [
1340         gcc_cv_as_relax_opt=unknown
1341         if test x$gcc_cv_as != x; then
1342             # Check if gas supports -relax
1343             echo ".text" > conftest.s
1344             if $gcc_cv_as -relax -o conftest.o conftest.s > /dev/null 2>&1; then
1345                 gcc_cv_as_relax_opt=yes
1346             else
1347                 gcc_cv_as_relax_opt=no
1348             fi
1349             rm -f conftest.s conftest.o
1350         fi
1351     ])
1352     if test "x$gcc_cv_as_relax_opt" = xyes; then
1353         AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
1354                 [Define if your assembler supports -relax option.])
1355     fi
1356
1357     case "$tm_file" in
1358     *64*)
1359         AC_CACHE_CHECK([for 64 bit support in assembler ($gcc_cv_as)],
1360             gcc_cv_as_flags64, [
1361                 if test -n "$gcc_cv_as"; then
1362                     echo ".xword foo" > conftest.s
1363                     gcc_cv_as_flags64=no
1364                     for flag in "-xarch=v9" "-64 -Av9"; do
1365                         if $gcc_cv_as $flag -o conftest.o conftest.s \
1366                             > /dev/null 2>&1; then
1367                             gcc_cv_as_flags64=$flag
1368                             break
1369                         fi
1370                     done
1371                     rm -f conftest.s conftest.o
1372                 else
1373                     if test "$gas" = yes; then
1374                         gcc_cv_as_flags64="-64 -Av9"
1375                     else
1376                         gcc_cv_as_flags64="-xarch=v9"
1377                     fi
1378                 fi
1379         ])
1380         if test "x$gcc_cv_as_flags64" = xno; then
1381 changequote(, )
1382             tmake_file=`echo " $tmake_file " | sed -e 's, sparc/t-sol2-64 , ,' -e 's,^ ,,' -e 's, $,,'`
1383             dep_tmake_file=`echo " $dep_tmake_file " | sed -e 's, [^ ]*/config/sparc/t-sol2-64 , ,' -e 's,^ ,,' -e 's, $,,'`
1384 changequote([, ])
1385         else
1386             AC_DEFINE_UNQUOTED(AS_SPARC64_FLAG, "$gcc_cv_as_flags64",
1387                         [Define if the assembler supports 64bit sparc.])
1388         fi
1389         ;;
1390     *) gcc_cv_as_flags64=${gcc_cv_as_flags64-no}
1391         ;;
1392     esac
1393
1394     if test "x$gcc_cv_as_flags64" != xno; then
1395         AC_CACHE_CHECK([for assembler offsetable %lo() support],
1396             gcc_cv_as_offsetable_lo10, [
1397             gcc_cv_as_offsetable_lo10=unknown
1398             if test "x$gcc_cv_as" != x; then
1399                 # Check if assembler has offsetable %lo()
1400                 echo "or %g1, %lo(ab) + 12, %g1" > conftest.s
1401                 echo "or %g1, %lo(ab + 12), %g1" > conftest1.s
1402                 if $gcc_cv_as $gcc_cv_as_flags64 -o conftest.o conftest.s \
1403                         > /dev/null 2>&1 &&
1404                    $gcc_cv_as $gcc_cv_as_flags64 -o conftest1.o conftest1.s \
1405                         > /dev/null 2>&1; then
1406                     if cmp conftest.o conftest1.o > /dev/null 2>&1; then
1407                         gcc_cv_as_offsetable_lo10=no
1408                     else
1409                         gcc_cv_as_offsetable_lo10=yes
1410                     fi
1411                 else
1412                     gcc_cv_as_offsetable_lo10=no
1413                 fi
1414                 rm -f conftest.s conftest.o conftest1.s conftest1.o
1415             fi
1416         ])
1417         if test "x$gcc_cv_as_offsetable_lo10" = xyes; then
1418             AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
1419                 [Define if your assembler supports offsetable %lo().])
1420         fi
1421     fi
1422     ;;
1423
1424 changequote(,)dnl
1425   i[34567]86-*-*)
1426 changequote([,])dnl
1427     AC_MSG_CHECKING(assembler instructions)
1428     gcc_cv_as_instructions=
1429     if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1430       if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 9 -o "$gcc_cv_gas_major_version" -gt 2; then
1431         gcc_cv_as_instructions="filds fists"
1432       fi
1433     elif test x$gcc_cv_as != x; then
1434         set "filds fists" "filds mem; fists mem"
1435         while test $# -gt 0
1436         do
1437                 echo "$2" > conftest.s
1438                 if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1439                         gcc_cv_as_instructions=${gcc_cv_as_instructions}$1" "
1440                 fi
1441                 shift 2
1442         done
1443         rm -f conftest.s conftest.o
1444     fi
1445     if test x"$gcc_cv_as_instructions" != x; then
1446         AC_DEFINE_UNQUOTED(HAVE_GAS_`echo "$gcc_cv_as_instructions" | sed -e 's/ $//' | tr '[a-z ]' '[A-Z_]'`)
1447     fi
1448     AC_MSG_RESULT($gcc_cv_as_instructions)
1449     ;;
1450 esac
1451
1452 AC_MSG_CHECKING(assembler dwarf2 debug_line support)
1453 gcc_cv_as_dwarf2_debug_line=no
1454 # ??? Not all targets support dwarf2 debug_line, even within a version
1455 # of gas.  Moreover, we need to emit a valid instruction to trigger any
1456 # info to the output file.  So, as supported targets are added to gas 2.11,
1457 # add some instruction here to (also) show we expect this might work.
1458 # ??? Once 2.11 is released, probably need to add first known working
1459 # version to the per-target configury.
1460 case "$target" in
1461   i?86*-*-* | mips*-*-* | alpha*-*-* | sparc*-*-*)
1462     insn="nop"
1463     ;;
1464   ia64*-*-*)
1465     insn="nop 0"
1466     ;;
1467   esac
1468 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x;
1469 then
1470   if test "$gcc_cv_gas_major_version" -eq 2 \
1471         -a "$gcc_cv_gas_minor_version" -ge 11 \
1472         -o "$gcc_cv_gas_major_version" -gt 2 \
1473      && grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1474      && test x"$insn" != x ; then
1475     gcc_cv_as_dwarf2_debug_line="yes"
1476   fi
1477 elif test x$gcc_cv_as != x -a x"$insn" != x ; then
1478         echo '  .file 0 "conftest.s"' > conftest.s
1479         echo '  .loc 0 3 0' >> conftest.s
1480         echo "  $insn" >> conftest.s
1481         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1 \
1482            && grep debug_line conftest.o > /dev/null 2>&1 ; then
1483                 gcc_cv_as_dwarf2_debug_line="yes"
1484         fi
1485         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1486 fi
1487 if test x"$gcc_cv_as_dwarf2_debug_line" = xyes; then
1488         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
1489           [Define if your assembler supports dwarf2 .file/.loc directives.])
1490 fi
1491 AC_MSG_RESULT($gcc_cv_as_dwarf2_debug_line)
1492
1493 # Figure out what language subdirectories are present.
1494 # Look if the user specified --enable-languages="..."; if not, use
1495 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1496 # go away some day.
1497 if test x"${enable_languages+set}" != xset; then
1498         if test x"${LANGUAGES+set}" = xset; then
1499                 enable_languages="`echo ${LANGUAGES} | tr ' ' ','`"
1500         else
1501                 enable_languages=all
1502         fi
1503 else
1504         if test x"${enable_languages}" = x; then
1505                 AC_MSG_ERROR([--enable-languages needs at least one argument])
1506         fi
1507 fi
1508 subdirs=
1509 for lang in ${srcdir}/*/config-lang.in ..
1510 do
1511         case $lang in
1512         ..) ;;
1513         # The odd quoting in the next line works around
1514         # an apparent bug in bash 1.12 on linux.
1515 changequote(,)dnl
1516         ${srcdir}/[*]/config-lang.in) ;;
1517         *)
1518           lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
1519           if test "x$lang_alias" = x
1520           then
1521                 echo "$lang doesn't set \$language." 1>&2
1522                 exit 1
1523           fi
1524           if test x"${enable_languages}" = xall && test x"${lang_alias}" != xCHILL; then
1525                 add_this_lang=yes
1526           else
1527                 case "${enable_languages}" in
1528                     ${lang_alias} | "${lang_alias},"* | *",${lang_alias},"* | *",${lang_alias}" )
1529                         add_this_lang=yes
1530                         ;;
1531                     * )
1532                         add_this_lang=no
1533                         ;;
1534                 esac
1535           fi
1536           if test x"${add_this_lang}" = xyes; then
1537                 case $lang in
1538                     ${srcdir}/ada/config-lang.in)
1539                         if test x$gnat = xyes ; then
1540                                 subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
1541                         fi
1542                         ;;
1543                     *)
1544                         subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
1545                         ;;
1546                 esac
1547           fi
1548           ;;
1549 changequote([,])dnl
1550         esac
1551 done
1552
1553 # Make gthr-default.h if we have a thread file.
1554 gthread_flags=
1555 if test $thread_file != single; then
1556     rm -f gthr-default.h
1557     echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
1558     gthread_flags=-DHAVE_GTHR_DEFAULT
1559 fi
1560 AC_SUBST(gthread_flags)
1561
1562 # Find out what GC implementation we want, or may, use.
1563 AC_ARG_WITH(gc,
1564 [  --with-gc={simple,page} Choose the garbage collection mechanism to use
1565                            with the compiler.],
1566 [case "$withval" in
1567   simple | page)
1568     GGC=ggc-$withval
1569     ;;
1570   *)
1571     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
1572     ;;
1573 esac],
1574 [if test $ac_cv_func_mmap_anywhere = yes \
1575     || test $ac_cv_func_valloc = yes; then
1576   GGC=ggc-page
1577 else
1578   GGC=ggc-simple
1579 fi])
1580 AC_SUBST(GGC)
1581 echo "Using $GGC for garbage collection."
1582
1583 # Use the system's zlib library.
1584 zlibdir=-L../zlib
1585 zlibinc="-I\$(srcdir)/../zlib"
1586 AC_ARG_WITH(system-zlib,
1587 [  --with-system-zlib      use installed libz],
1588 zlibdir=
1589 zlibinc=
1590 )
1591 AC_SUBST(zlibdir)
1592 AC_SUBST(zlibinc)
1593
1594 # Build a new-abi (c++) system
1595 AC_ARG_ENABLE(new-gxx-abi,
1596 [  --enable-new-gxx-abi
1597                           select the new abi for g++. You must select an ABI
1598                           at configuration time, so that the correct runtime
1599                           support is built. You cannot mix ABIs.],
1600    ,
1601   enable_new_gxx_abi=yes)
1602
1603 if test x$enable_new_gxx_abi = xyes; then
1604   AC_DEFINE(ENABLE_NEW_GXX_ABI, 1,
1605             [Define if you want to always select the new-abi for g++.])
1606   GXX_ABI_FLAG='-fnew-abi'
1607 else
1608   GXX_ABI_FLAG=
1609 fi
1610 AC_SUBST(GXX_ABI_FLAG)
1611
1612 AC_DEFINE_UNQUOTED(ENABLE_STD_NAMESPACE, $ac_esn,
1613   [Define to 1 if you want to enable namespaces (-fhonor-std) by default.])
1614 AC_SUBST(HAVE_LIBSTDCXX_V3)
1615
1616 dnl Very limited version of automake's enable-maintainer-mode
1617
1618 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
1619   dnl maintainer-mode is disabled by default
1620   AC_ARG_ENABLE(maintainer-mode,
1621 [  --enable-maintainer-mode enable make rules and dependencies not useful
1622                           (and sometimes confusing) to the casual installer],
1623       maintainer_mode=$enableval,
1624       maintainer_mode=no)
1625
1626 AC_MSG_RESULT($maintainer_mode)
1627
1628 if test "$maintainer_mode" = "yes"; then
1629   MAINT=''
1630 else
1631   MAINT='#'
1632 fi
1633 AC_SUBST(MAINT)dnl
1634
1635 # Make empty files to contain the specs and options for each language.
1636 # Then add #include lines to for a compiler that has specs and/or options.
1637
1638 lang_specs_files=
1639 lang_options_files=
1640 lang_tree_files=
1641 rm -f specs.h options.h gencheck.h
1642 touch specs.h options.h gencheck.h
1643 for subdir in . $subdirs
1644 do
1645         if test -f $srcdir/$subdir/lang-specs.h; then
1646                 echo "#include \"$subdir/lang-specs.h\"" >>specs.h
1647                 lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
1648         fi
1649         if test -f $srcdir/$subdir/lang-options.h; then
1650                 echo "#include \"$subdir/lang-options.h\"" >>options.h
1651                 lang_options_files="$lang_options_files $srcdir/$subdir/lang-options.h"
1652         fi
1653         if test -f $srcdir/$subdir/$subdir-tree.def; then
1654                 echo "#include \"$subdir/$subdir-tree.def\"" >>gencheck.h
1655                 lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
1656         fi
1657 done
1658
1659 # These (without "all_") are set in each config-lang.in.
1660 # `language' must be a single word so is spelled singularly.
1661 all_languages=
1662 all_boot_languages=
1663 all_compilers=
1664 all_stagestuff=
1665 all_diff_excludes=
1666 all_outputs='Makefile intl/Makefile po/Makefile.in fixinc/Makefile gccbug mklibgcc'
1667 # List of language makefile fragments.
1668 all_lang_makefiles=
1669 all_headers=
1670 all_lib2funcs=
1671
1672 # Add the language fragments.
1673 # Languages are added via two mechanisms.  Some information must be
1674 # recorded in makefile variables, these are defined in config-lang.in.
1675 # We accumulate them and plug them into the main Makefile.
1676 # The other mechanism is a set of hooks for each of the main targets
1677 # like `clean', `install', etc.
1678
1679 language_fragments="Make-lang"
1680 language_hooks="Make-hooks"
1681
1682 for s in .. $subdirs
1683 do
1684         if test $s != ".."
1685         then
1686                 language=
1687                 boot_language=
1688                 compilers=
1689                 stagestuff=
1690                 diff_excludes=
1691                 headers=
1692                 outputs=
1693                 lib2funcs=
1694                 . ${srcdir}/$s/config-lang.in
1695                 if test "x$language" = x
1696                 then
1697                         echo "${srcdir}/$s/config-lang.in doesn't set \$language." 1>&2
1698                         exit 1
1699                 fi
1700                 all_lang_makefiles="$all_lang_makefiles ${srcdir}/$s/Make-lang.in"
1701                 if test -f ${srcdir}/$s/Makefile.in
1702                 then all_lang_makefiles="$all_lang_makefiles ${srcdir}/$s/Makefile.in"
1703                 fi
1704                 all_languages="$all_languages $language"
1705                 if test "x$boot_language" = xyes
1706                 then
1707                         all_boot_languages="$all_boot_languages $language"
1708                 fi
1709                 all_compilers="$all_compilers $compilers"
1710                 all_stagestuff="$all_stagestuff $stagestuff"
1711                 all_diff_excludes="$all_diff_excludes $diff_excludes"
1712                 all_headers="$all_headers $headers"
1713                 all_outputs="$all_outputs $outputs"
1714                 all_lib2funcs="$all_lib2funcs $lib2funcs"
1715         fi
1716 done
1717
1718 # Since we can't use `::' targets, we link each language in
1719 # with a set of hooks, reached indirectly via lang.${target}.
1720
1721 rm -f Make-hooks
1722 touch Make-hooks
1723 target_list="all.build all.cross start.encap rest.encap \
1724         info dvi \
1725         install-normal install-common install-info install-man \
1726         uninstall \
1727         mostlyclean clean distclean extraclean maintainer-clean \
1728         stage1 stage2 stage3 stage4"
1729 for t in $target_list
1730 do
1731         x=
1732         for lang in .. $all_languages
1733         do
1734                 if test $lang != ".."; then
1735                         x="$x $lang.$t"
1736                 fi
1737         done
1738         echo "lang.$t: $x" >> Make-hooks
1739 done
1740
1741 # If we're not building in srcdir, create .gdbinit.
1742
1743 if test ! -f Makefile.in; then
1744         echo "dir ." > .gdbinit
1745         echo "dir ${srcdir}" >> .gdbinit
1746         if test x$gdb_needs_out_file_path = xyes
1747         then
1748                 echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
1749         fi
1750         if test "x$subdirs" != x; then
1751                 for s in $subdirs
1752                 do
1753                         echo "dir ${srcdir}/$s" >> .gdbinit
1754                 done
1755         fi
1756         echo "source ${srcdir}/.gdbinit" >> .gdbinit
1757 fi
1758
1759 # Define variables host_canonical and build_canonical
1760 # because some Cygnus local changes in the Makefile depend on them.
1761 build_canonical=${build}
1762 host_canonical=${host}
1763 target_subdir=
1764 if test "${host}" != "${target}" ; then
1765     target_subdir=${target}/
1766 fi
1767 AC_SUBST(build_canonical)
1768 AC_SUBST(host_canonical)
1769 AC_SUBST(target_subdir)
1770
1771 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
1772 # absolute path for gcc_tooldir based on inserting the number of up-directory
1773 # movements required to get from $(exec_prefix) to $(prefix) into the basic
1774 # $(libsubdir)/@(unlibsubdir) based path.
1775 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
1776 # make and thus we'd get different behavior depending on where we built the
1777 # sources.
1778 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
1779     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_alias)'
1780 else
1781 changequote(<<, >>)dnl
1782 # An explanation of the sed strings:
1783 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
1784 #  -e 's|/$||'            match a trailing forward slash and eliminates it
1785 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
1786 #  -e 's|/[^/]*|../|g'    replaces each occurance of /<directory> with ../
1787 #
1788 # (*) Note this pattern overwrites the first character of the string
1789 # with a forward slash if one is not already present.  This is not a
1790 # problem because the exact names of the sub-directories concerned is
1791 # unimportant, just the number of them matters.
1792 #
1793 # The practical upshot of these patterns is like this:
1794 #
1795 #  prefix     exec_prefix        result
1796 #  ------     -----------        ------
1797 #   /foo        /foo/bar          ../
1798 #   /foo/       /foo/bar          ../
1799 #   /foo        /foo/bar/         ../
1800 #   /foo/       /foo/bar/         ../
1801 #   /foo        /foo/bar/ugg      ../../
1802 #
1803     dollar='$$'
1804     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_alias)"
1805 changequote([, ])dnl
1806 fi
1807 AC_SUBST(gcc_tooldir)
1808 AC_SUBST(dollar)
1809
1810 # Nothing to do for FLOAT_H, float_format already handled.
1811 objdir=`pwd`
1812 AC_SUBST(objdir)
1813
1814 # Process the language and host/target makefile fragments.
1815 ${CONFIG_SHELL-/bin/sh} $srcdir/configure.frag $srcdir "$subdirs" "$dep_host_xmake_file" "$dep_tmake_file"
1816
1817 # Substitute configuration variables
1818 AC_SUBST(subdirs)
1819 AC_SUBST(all_boot_languages)
1820 AC_SUBST(all_compilers)
1821 AC_SUBST(all_diff_excludes)
1822 AC_SUBST(all_headers)
1823 AC_SUBST(all_lang_makefiles)
1824 AC_SUBST(all_languages)
1825 AC_SUBST(all_lib2funcs)
1826 AC_SUBST(all_stagestuff)
1827 AC_SUBST(build_exeext)
1828 AC_SUBST(build_install_headers_dir)
1829 AC_SUBST(build_xm_file_list)
1830 AC_SUBST(cc_set_by_configure)
1831 AC_SUBST(quoted_cc_set_by_configure)
1832 AC_SUBST(cpp_install_dir)
1833 AC_SUBST(dep_host_xmake_file)
1834 AC_SUBST(dep_tmake_file)
1835 AC_SUBST(extra_c_flags)
1836 AC_SUBST(extra_headers_list)
1837 AC_SUBST(extra_objs)
1838 AC_SUBST(extra_parts)
1839 AC_SUBST(extra_passes)
1840 AC_SUBST(extra_programs)
1841 AC_SUBST(float_h_file)
1842 AC_SUBST(gcc_config_arguments)
1843 AC_SUBST(gcc_gxx_include_dir)
1844 AC_SUBST(gcc_version)
1845 AC_SUBST(gcc_version_full)
1846 AC_SUBST(gcc_version_trigger)
1847 AC_SUBST(host_exeext)
1848 AC_SUBST(host_extra_gcc_objs)
1849 AC_SUBST(host_xm_file_list)
1850 AC_SUBST(install)
1851 AC_SUBST(lang_options_files)
1852 AC_SUBST(lang_specs_files)
1853 AC_SUBST(lang_tree_files)
1854 AC_SUBST(local_prefix)
1855 AC_SUBST(maybe_use_collect2)
1856 AC_SUBST(md_file)
1857 AC_SUBST(objc_boehm_gc)
1858 AC_SUBST(out_file)
1859 AC_SUBST(out_object_file)
1860 AC_SUBST(stage_prefix_set_by_configure)
1861 AC_SUBST(symbolic_link)
1862 AC_SUBST(thread_file)
1863 AC_SUBST(tm_file_list)
1864 AC_SUBST(will_use_collect2)
1865
1866
1867 AC_SUBST_FILE(target_overrides)
1868 AC_SUBST_FILE(host_overrides)
1869 AC_SUBST(cross_defines)
1870 AC_SUBST_FILE(cross_overrides)
1871 AC_SUBST_FILE(build_overrides)
1872 AC_SUBST_FILE(language_fragments)
1873 AC_SUBST_FILE(language_hooks)
1874
1875 # Echo that links are built
1876 if test x$host = x$target
1877 then
1878         str1="native "
1879 else
1880         str1="cross-"
1881         str2=" from $host"
1882 fi
1883
1884 if test x$host != x$build
1885 then
1886         str3=" on a $build system"
1887 fi
1888
1889 if test "x$str2" != x || test "x$str3" != x
1890 then
1891         str4=
1892 fi
1893
1894 echo "Links are now set up to build a ${str1}compiler for ${target}$str4" 1>&2
1895
1896 if test "x$str2" != x || test "x$str3" != x
1897 then
1898         echo " ${str2}${str3}." 1>&2
1899 fi
1900
1901 # Truncate the target if necessary
1902 if test x$host_truncate_target != x; then
1903         target=`echo $target | sed -e 's/\(..............\).*/\1/'`
1904 fi
1905
1906 # Configure the subdirectories
1907 # AC_CONFIG_SUBDIRS($subdirs)
1908
1909 # Create the Makefile
1910 # and configure language subdirectories
1911 AC_OUTPUT($all_outputs,
1912 [
1913 case x$CONFIG_HEADERS in
1914 xauto-host.h:config.in)
1915 echo > cstamp-h ;;
1916 esac
1917 # If the host supports symlinks, point stage[1234] at ../stage[1234] so
1918 # bootstrapping and the installation procedure can still use
1919 # CC="stage1/xgcc -Bstage1/".  If the host doesn't support symlinks,
1920 # FLAGS_TO_PASS has been modified to solve the problem there.
1921 # This is virtually a duplicate of what happens in configure.lang; we do
1922 # an extra check to make sure this only happens if ln -s can be used.
1923 if test "$symbolic_link" = "ln -s"; then
1924  for d in .. ${subdirs} ; do
1925    if test $d != ..; then
1926         STARTDIR=`pwd`
1927         cd $d
1928         for t in stage1 stage2 stage3 stage4 include
1929         do
1930                 rm -f $t
1931                 $symbolic_link ../$t $t 2>/dev/null
1932         done
1933         cd $STARTDIR
1934    fi
1935  done
1936 else true ; fi
1937 # Avoid having to add intl to our include paths.
1938 if test -f intl/libintl.h; then
1939   echo creating libintl.h
1940   echo '#include "intl/libintl.h"' >libintl.h
1941 fi
1942 ],
1943 [
1944 host='${host}'
1945 build='${build}'
1946 target='${target}'
1947 target_alias='${target_alias}'
1948 srcdir='${srcdir}'
1949 subdirs='${subdirs}'
1950 symbolic_link='${symbolic_link}'
1951 program_transform_set='${program_transform_set}'
1952 program_transform_name='${program_transform_name}'
1953 dep_host_xmake_file='${dep_host_xmake_file}'
1954 host_xmake_file='${host_xmake_file}'
1955 dep_tmake_file='${dep_tmake_file}'
1956 tmake_file='${tmake_file}'
1957 thread_file='${thread_file}'
1958 gcc_config_arguments='${gcc_config_arguments}'
1959 gcc_version='${gcc_version}'
1960 gcc_version_full='${gcc_version_full}'
1961 gcc_version_trigger='${gcc_version_trigger}'
1962 local_prefix='${local_prefix}'
1963 build_install_headers_dir='${build_install_headers_dir}'
1964 build_exeext='${build_exeext}'
1965 host_exeext='${host_exeext}'
1966 out_file='${out_file}'
1967 gdb_needs_out_file_path='${gdb_needs_out_file_path}'
1968 SET_MAKE='${SET_MAKE}'
1969 target_list='${target_list}'
1970 target_overrides='${target_overrides}'
1971 host_overrides='${host_overrides}'
1972 cross_defines='${cross_defines}'
1973 cross_overrides='${cross_overrides}'
1974 build_overrides='${build_overrides}'
1975 cpp_install_dir='${cpp_install_dir}'
1976 ])