gcc/opt-functions.awk

   1 #  Copyright (C) 2003, 2004, 2007, 2008, 2009, 2010
   2 #  Free Software Foundation, Inc.
   3 #  Contributed by Kelley Cook, June 2004.
   4 #  Original code from Neil Booth, May 2003.
   5 #
   6 # This program is free software; you can redistribute it and/or modify it
   7 # under the terms of the GNU General Public License as published by the
   8 # Free Software Foundation; either version 3, or (at your option) any
   9 # later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; see the file COPYING3.  If not see
  18 # <http://www.gnu.org/licenses/>.
  19
  20 # Some common subroutines for use by opt[ch]-gen.awk.
  21
  22 # Define some helpful character classes, for portability.
  23 BEGIN {
  24         lower = "abcdefghijklmnopqrstuvwxyz"
  25         upper = "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
  26         digit = "0123456789"
  27         alnum = lower "" upper "" digit
  28 }
  29
  30 # Return nonzero if FLAGS contains a flag matching REGEX.
  31 function flag_set_p(regex, flags)
  32 {
  33         return (" " flags " ") ~ (" " regex " ")
  34 }
  35
  36 # Return STRING if FLAGS contains a flag matching regexp REGEX,
  37 # otherwise return the empty string.
  38 function test_flag(regex, flags, string)
  39 {
  40         if (flag_set_p(regex, flags))
  41                 return string
  42         return ""
  43 }
  44
  45 # If FLAGS contains a "NAME(...argument...)" flag, return the value
  46 # of the argument.  Return the empty string otherwise.
  47 function opt_args(name, flags)
  48 {
  49         flags = " " flags
  50         if (flags !~ " " name "\\(")
  51                 return ""
  52         sub(".* " name "\\(", "", flags)
  53         if (flags ~ "^{")
  54         {
  55                 sub ("^{", "", flags)
  56                 sub("}\\).*", "", flags)
  57         }
  58         else
  59                 sub("\\).*", "", flags)
  60
  61         return flags
  62 }
  63
  64 # Return the Nth comma-separated element of S.  Return the empty string
  65 # if S does not contain N elements.
  66 function nth_arg(n, s)
  67 {
  68         while (n-- > 0) {
  69                 if (s !~ ",")
  70                         return ""
  71                 sub("[^,]*, *", "", s)
  72         }
  73         sub(",.*", "", s)
  74         return s
  75 }
  76
  77 # Return a bitmask of CL_* values for option flags FLAGS.
  78 function switch_flags (flags)
  79 {
  80         result = "0"
  81         for (j = 0; j < n_langs; j++) {
  82                 regex = langs[j]
  83                 gsub ( "\\+", "\\+", regex )
  84                 result = result test_flag(regex, flags, " | " macros[j])
  85         }
  86         result = result \
  87           test_flag("Common", flags, " | CL_COMMON") \
  88           test_flag("Target", flags, " | CL_TARGET") \
  89           test_flag("Driver", flags, " | CL_DRIVER") \
  90           test_flag("RejectDriver", flags, " | CL_REJECT_DRIVER") \
  91           test_flag("NoDriverArg", flags, " | CL_NO_DRIVER_ARG") \
  92           test_flag("SeparateAlias", flags, " | CL_SEPARATE_ALIAS") \
  93           test_flag("Save", flags, " | CL_SAVE") \
  94           test_flag("Joined", flags, " | CL_JOINED") \
  95           test_flag("JoinedOrMissing", flags, " | CL_JOINED | CL_MISSING_OK") \
  96           test_flag("Separate", flags, " | CL_SEPARATE") \
  97           test_flag("RejectNegative", flags, " | CL_REJECT_NEGATIVE") \
  98           test_flag("UInteger", flags, " | CL_UINTEGER") \
  99           test_flag("Undocumented", flags,  " | CL_UNDOCUMENTED") \
 100           test_flag("Warning", flags,  " | CL_WARNING") \
 101           test_flag("Optimization", flags,  " | CL_OPTIMIZATION") \
 102           test_flag("Report", flags, " | CL_REPORT")
 103         sub( "^0 \\| ", "", result )
 104         return result
 105 }
 106
 107 # If FLAGS includes a Var flag, return the name of the variable it specifies.
 108 # Return the empty string otherwise.
 109 function var_name(flags)
 110 {
 111         return nth_arg(0, opt_args("Var", flags))
 112 }
 113
 114 # Return true if the option described by FLAGS has a globally-visible state.
 115 function global_state_p(flags)
 116 {
 117         return (var_name(flags) != "" \
 118                 || opt_args("Mask", flags) != "" \
 119                 || opt_args("InverseMask", flags) != "")
 120 }
 121
 122 # Return true if the option described by FLAGS must have some state
 123 # associated with it.
 124 function needs_state_p(flags)
 125 {
 126         return (flag_set_p("Target", flags) \
 127                 && !flag_set_p("Alias.*", flags) \
 128                 && !flag_set_p("Ignore", flags))
 129 }
 130
 131 # If FLAGS describes an option that needs state without a public
 132 # variable name, return the name of that field, minus the initial
 133 # "x_", otherwise return "".  NAME is the name of the option.
 134 function static_var(name, flags)
 135 {
 136         if (global_state_p(flags) || !needs_state_p(flags))
 137                 return ""
 138         gsub ("[^" alnum "]", "_", name)
 139         return "VAR_" name
 140 }
 141
 142 # Return the type of variable that should be associated with the given flags.
 143 function var_type(flags)
 144 {
 145         if (!flag_set_p("Joined.*", flags) && !flag_set_p("Separate", flags))
 146                 return "int "
 147         else if (flag_set_p("UInteger", flags))
 148                 return "int "
 149         else
 150                 return "const char *"
 151 }
 152
 153 # Return the type of variable that should be associated with the given flags
 154 # for use within a structure.  Simple variables are changed to signed char
 155 # type instead of int to save space.
 156 function var_type_struct(flags)
 157 {
 158         if (flag_set_p("UInteger", flags))
 159                 return "int "
 160         else if (!flag_set_p("Joined.*", flags) && !flag_set_p("Separate", flags)) {
 161                 if (flag_set_p(".*Mask.*", flags))
 162                         return "int "
 163                 else
 164                         return "signed char "
 165         }
 166         else
 167                 return "const char *"
 168 }
 169
 170 # Given that an option has flags FLAGS, return an initializer for the
 171 # "var_cond" and "var_value" fields of its cl_options[] entry.
 172 function var_set(flags)
 173 {
 174         s = nth_arg(1, opt_args("Var", flags))
 175         if (s != "")
 176                 return "CLVC_EQUAL, " s
 177         s = opt_args("Mask", flags);
 178         if (s != "") {
 179                 vn = var_name(flags);
 180                 if (vn)
 181                         return "CLVC_BIT_SET, OPTION_MASK_" s
 182                 else
 183                         return "CLVC_BIT_SET, MASK_" s
 184         }
 185         s = nth_arg(0, opt_args("InverseMask", flags));
 186         if (s != "") {
 187                 vn = var_name(flags);
 188                 if (vn)
 189                         return "CLVC_BIT_CLEAR, OPTION_MASK_" s
 190                 else
 191                         return "CLVC_BIT_CLEAR, MASK_" s
 192         }
 193         if (var_type(flags) == "const char *")
 194                 return "CLVC_STRING, 0"
 195         return "CLVC_BOOLEAN, 0"
 196 }
 197
 198 # Given that an option called NAME has flags FLAGS, return an initializer
 199 # for the "flag_var" field of its cl_options[] entry.
 200 function var_ref(name, flags)
 201 {
 202         name = var_name(flags) static_var(name, flags)
 203         if (name != "")
 204                 return "offsetof (struct gcc_options, x_" name ")"
 205         if (opt_args("Mask", flags) != "")
 206                 return "offsetof (struct gcc_options, x_target_flags)"
 207         if (opt_args("InverseMask", flags) != "")
 208                 return "offsetof (struct gcc_options, x_target_flags)"
 209         return "-1"
 210 }
 211
 212 # Given the option called NAME return a sanitized version of its name.
 213 function opt_sanitized_name(name)
 214 {
 215         gsub ("[^" alnum "]", "_", name)
 216         return name
 217 }
 218
 219 # Given the option called NAME return the appropriate enum for it.
 220 function opt_enum(name)
 221 {
 222         return "OPT_" opt_sanitized_name(name)
 223 }