gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   3 dnl 2005, 2006, 2007, 2008
   4 dnl Free Software Foundation, Inc.
   5 dnl
   6 dnl This file is part of GDB.
   7 dnl
   8 dnl This program is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 3 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.59)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_GNU_SOURCE
  30 AC_AIX
  31 AC_ISC_POSIX
  32 gl_EARLY
  33 AM_PROG_CC_STDC
  34
  35 AC_CONFIG_AUX_DIR(..)
  36 AC_CANONICAL_SYSTEM
  37
  38 # Dependency checking.
  39 ZW_CREATE_DEPDIR
  40 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  41
  42 # Check for the 'make' the user wants to use.
  43 AC_CHECK_PROGS(MAKE, make)
  44 MAKE_IS_GNU=
  45 case "`$MAKE --version 2>&1 | sed 1q`" in
  46   *GNU*)
  47     MAKE_IS_GNU=yes
  48     ;;
  49 esac
  50 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  51 AC_PROG_MAKE_SET
  52
  53 dnl List of object files and targets accumulated by configure.
  54
  55 CONFIG_OBS=
  56 CONFIG_DEPS=
  57 CONFIG_SRCS=
  58 ENABLE_CFLAGS=
  59
  60 CONFIG_ALL=
  61 CONFIG_CLEAN=
  62 CONFIG_INSTALL=
  63 CONFIG_UNINSTALL=
  64
  65 dnl Set up for gettext.
  66 ZW_GNU_GETTEXT_SISTER_DIR
  67
  68 localedir='${datadir}/locale'
  69 AC_SUBST(localedir)
  70
  71 if test x"$USE_NLS" = xyes; then
  72    CONFIG_ALL="$CONFIG_ALL all-po"
  73    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  74    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  75    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  76 fi
  77
  78 gl_INIT
  79
  80 # For Makefile dependencies.
  81 GNULIB_STDINT_H=
  82 if test x"$STDINT_H" != x; then
  83   GNULIB_STDINT_H=gnulib/$STDINT_H
  84 fi
  85 AC_SUBST(GNULIB_STDINT_H)
  86
  87 PACKAGE=gdb
  88 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  89 AC_SUBST(PACKAGE)
  90
  91 # GDB does not use automake, but gnulib does.  This line lets us
  92 # generate its Makefile.in.
  93 AM_INIT_AUTOMAKE(gdb, UNUSED-VERSION, [no-define])
  94
  95 debugdir=${libdir}/debug
  96
  97 AC_ARG_WITH(separate-debug-dir,
  98 [  --with-separate-debug-dir=path   Look for global separate debug info in this path [LIBDIR/debug]],
  99 [debugdir="${withval}"])
 100
 101 AC_DEFINE_DIR(DEBUGDIR, debugdir,
 102               [Global directory for separate debug files. ])
 103 #AC_DEFINE_UNQUOTED(DEBUGDIR, "$debugdir"),
 104
 105 if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
 106   if test "x$prefix" = xNONE; then
 107     test_prefix=/usr/local
 108   else
 109     test_prefix=$prefix
 110   fi
 111 else
 112   test_prefix=$exec_prefix
 113 fi
 114 case ${debugdir} in
 115 "${test_prefix}"|"${test_prefix}/"*|\
 116 '${exec_prefix}'|'${exec_prefix}/'*)
 117   AC_DEFINE(DEBUGDIR_RELOCATABLE, 1, [Define if the debug directory should be relocated when GDB is moved.])
 118   ;;
 119 esac
 120
 121 AC_CONFIG_SUBDIRS(doc testsuite)
 122
 123 # Check whether to support alternative target configurations
 124 AC_ARG_ENABLE(targets,
 125 [  --enable-targets        alternative target configurations],
 126 [case "${enableval}" in
 127   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 128             ;;
 129   no)       enable_targets= ;;
 130   *)        enable_targets=$enableval ;;
 131 esac])
 132
 133 # Check whether to enable 64-bit support on 32-bit hosts
 134 AC_ARG_ENABLE(64-bit-bfd,
 135 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
 136 [case "${enableval}" in
 137   yes)  want64=true  ;;
 138   no)   want64=false ;;
 139   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 140 esac],[want64=false])dnl
 141
 142 # Provide defaults for some variables set by the per-host and per-target
 143 # configuration.
 144 gdb_host_obs=posix-hdep.o
 145
 146 if test "${target}" = "${host}"; then
 147   gdb_native=yes
 148 else
 149   gdb_native=no
 150 fi
 151
 152 . $srcdir/configure.host
 153
 154 # Accumulate some settings from configure.tgt over all enabled targets
 155
 156 TARGET_OBS=
 157 all_targets=
 158
 159 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 160 do
 161   if test "$targ_alias" = "all"; then
 162     all_targets=true
 163   else
 164     # Canonicalize the secondary target names.
 165     result=`$ac_config_sub $targ_alias 2>/dev/null`
 166     if test -n "$result"; then
 167         targ=$result
 168     else
 169         targ=$targ_alias
 170     fi
 171
 172     . ${srcdir}/configure.tgt
 173
 174     # Target-specific object files
 175     for i in ${gdb_target_obs}; do
 176         case " $TARGET_OBS " in
 177         *" ${i} "*) ;;
 178         *)
 179           TARGET_OBS="$TARGET_OBS ${i}"
 180           ;;
 181         esac
 182     done
 183
 184     # Check whether this target needs 64-bit CORE_ADDR
 185     if test x${want64} = xfalse; then
 186       . ${srcdir}/../bfd/config.bfd
 187     fi
 188   fi
 189 done
 190
 191 if test x${all_targets} = xtrue; then
 192
 193   # We want all 64-bit targets if we either:
 194   #  - run on a 64-bit host  or
 195   #  - already require 64-bit support for some other target  or
 196   #  - the --enable-64-bit-bfd option was supplied
 197   # Otherwise we only support all 32-bit targets.
 198   #
 199   # NOTE: This test must be in sync with the corresponding
 200   #       tests in BFD!
 201
 202   if test x${want64} = xfalse; then
 203     AC_CHECK_SIZEOF(long)
 204     if test "x${ac_cv_sizeof_long}" = "x8"; then
 205       want64=true
 206     fi
 207   fi
 208   if test x${want64} = xtrue; then
 209     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 210   else
 211     TARGET_OBS='$(ALL_TARGET_OBS)'
 212   fi
 213 fi
 214
 215 AC_SUBST(TARGET_OBS)
 216
 217 # For other settings, only the main target counts.
 218 gdb_sim=
 219 gdb_osabi=
 220 build_gdbserver=
 221 targ=$target; . ${srcdir}/configure.tgt
 222
 223 # Fetch the default architecture and default target vector from BFD.
 224 targ=$target; . $srcdir/../bfd/config.bfd
 225
 226 # We only want the first architecture, so strip off the others if
 227 # there is more than one.
 228 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 229
 230 if test "x$targ_archs" != x; then
 231   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 232     [Define to BFD's default architecture. ])
 233 fi
 234 if test "x$targ_defvec" != x; then
 235   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 236     [Define to BFD's default target vector. ])
 237 fi
 238
 239 # The CLI cannot be disabled yet, but may be in the future.
 240
 241 # Enable CLI.
 242 AC_ARG_ENABLE(gdbcli,
 243 [  --disable-gdbcli        disable command-line interface (CLI)],
 244   [case $enableval in
 245     yes)
 246       ;;
 247     no)
 248       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 249     *)
 250       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 251   esac],
 252   [enable_gdbcli=yes])
 253 if test x"$enable_gdbcli" = xyes; then
 254   if test -d $srcdir/cli; then
 255     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 256     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 257     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 258     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 259   fi
 260 fi
 261
 262 # Enable MI.
 263 AC_ARG_ENABLE(gdbmi,
 264 [  --disable-gdbmi         disable machine-interface (MI)],
 265   [case $enableval in
 266     yes | no)
 267       ;;
 268     *)
 269       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 270   esac],
 271   [enable_gdbmi=yes])
 272 if test x"$enable_gdbmi" = xyes; then
 273   if test -d $srcdir/mi; then
 274     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 275     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 276     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 277     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 278   fi
 279 fi
 280
 281 # Enable TUI.
 282 AC_ARG_ENABLE(tui,
 283 [  --enable-tui            enable full-screen terminal user interface (TUI)],
 284   [case $enableval in
 285     yes | no | auto)
 286       ;;
 287     *)
 288       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 289   esac],enable_tui=auto)
 290
 291 # Enable gdbtk.
 292 AC_ARG_ENABLE(gdbtk,
 293 [  --enable-gdbtk          enable gdbtk graphical user interface (GUI)],
 294   [case $enableval in
 295     yes | no)
 296       ;;
 297     *)
 298       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 299   esac],
 300   [if test -d $srcdir/gdbtk; then
 301     enable_gdbtk=yes
 302   else
 303     enable_gdbtk=no
 304   fi])
 305 # We unconditionally disable gdbtk tests on selected platforms.
 306 case $host_os in
 307   go32* | windows*)
 308     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 309     enable_gdbtk=no ;;
 310 esac
 311
 312 # Libunwind support.
 313 AC_ARG_WITH(libunwind,
 314 [  --with-libunwind            Use libunwind frame unwinding support],
 315 [case "${withval}" in
 316   yes)  enable_libunwind=yes ;;
 317   no)   enable_libunwind=no ;;
 318   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 319 esac],[
 320   AC_CHECK_HEADERS(libunwind.h)
 321   AC_CHECK_HEADERS(libunwind-ia64.h)
 322   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 323     enable_libunwind=yes;
 324   fi
 325 ])
 326
 327 if test x"$enable_libunwind" = xyes; then
 328   AC_CHECK_HEADERS(libunwind.h)
 329   AC_CHECK_HEADERS(libunwind-ia64.h)
 330   AC_DEFINE(HAVE_LIBUNWIND, 1, [Define if libunwind library is being used.])
 331   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 332   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 333   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 334 fi
 335
 336 # Profiling support.
 337 AC_ARG_ENABLE(profiling,
 338 [  --enable-profiling      enable profiling of GDB],
 339   [case $enableval in
 340     yes | no)
 341       ;;
 342     *)
 343       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 344   esac],
 345  [enable_profiling=no])
 346
 347 AC_CHECK_FUNCS(monstartup _mcleanup)
 348 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 349 [AC_TRY_LINK(
 350 [#include <stdlib.h>
 351 extern char _etext;
 352 ],
 353 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 354 if test $ac_cv_var__etext = yes; then
 355   AC_DEFINE(HAVE__ETEXT, 1,
 356             [Define to 1 if your system has the _etext variable. ])
 357 fi
 358 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 359 [AC_TRY_LINK(
 360 [#include <stdlib.h>
 361 extern char etext;
 362 ],
 363 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 364 if test $ac_cv_var_etext = yes; then
 365   AC_DEFINE(HAVE_ETEXT, 1,
 366             [Define to 1 if your system has the etext variable. ])
 367 fi
 368 if test "$enable_profiling" = yes ; then
 369   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 370     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 371   fi
 372   PROFILE_CFLAGS=-pg
 373   OLD_CFLAGS="$CFLAGS"
 374   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 375
 376   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 377     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 378      ac_cv_cc_supports_pg=no)])
 379
 380   if test $ac_cv_cc_supports_pg = no; then
 381     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 382   fi
 383
 384   CFLAGS="$OLD_CFLAGS"
 385 fi
 386
 387 ACX_PKGVERSION([GDB])
 388 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 389 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 390 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 391
 392 # --------------------- #
 393 # Checks for programs.  #
 394 # --------------------- #
 395
 396 AC_PROG_AWK
 397 AC_PROG_INSTALL
 398 AC_PROG_LN_S
 399 AC_PROG_RANLIB
 400 AC_PROG_YACC
 401
 402 AC_CHECK_TOOL(AR, ar)
 403 AC_CHECK_TOOL(DLLTOOL, dlltool)
 404 AC_CHECK_TOOL(WINDRES, windres)
 405
 406 # Needed for GNU/Hurd.
 407 AC_CHECK_TOOL(MIG, mig)
 408
 409 # ---------------------- #
 410 # Checks for libraries.  #
 411 # ---------------------- #
 412
 413 # We might need to link with -lm; most simulators need it.
 414 AC_CHECK_LIB(m, main)
 415
 416 # We need to link with -lw to get `wctype' on Solaris before Solaris
 417 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 418 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 419 # is known to have this problem).  Therefore we avoid libw if we can.
 420 AC_CHECK_FUNC(wctype, [],
 421   [AC_CHECK_LIB(w, wctype)])
 422
 423 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 424 AC_SEARCH_LIBS(gethostbyname, nsl)
 425
 426 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 427 AC_SEARCH_LIBS(socketpair, socket)
 428
 429 # Link in zlib if we can.  This allows us to read compressed debug sections.
 430 AC_SEARCH_LIBS(zlibVersion, z, [AC_CHECK_HEADERS(zlib.h)])
 431
 432 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 433 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 434
 435 # On alpha-osf, it appears that libtermcap and libcurses are not compatible.
 436 # There is a very specific comment in /usr/include/curses.h explaining that
 437 # termcap routines built into libcurses must not be used.
 438 #
 439 # The symptoms we observed so far is GDB unexpectedly changing
 440 # the terminal settings when tgetent is called - this is particularly
 441 # visible as the output is missing carriage returns, and so rapidly
 442 # becomes very hard to read.
 443 #
 444 # The readline configure script has already decided that libtermcap
 445 # was enough for its purposes, and so decided to build readline using
 446 # libtermcap.  Since the TUI mode requires curses, building GDB with
 447 # TUI enabled results in both libraries to be used at the same time,
 448 # which is not allowed.  This basically means that GDB with TUI is
 449 # broken on alpha-osf.
 450
 451 case $host_os in
 452   alpha*-*-osf* )
 453     if "$enable_tui" = "yes"; then
 454       AC_MSG_ERROR([Building GDB with TUI mode is not supported on this host])
 455     fi
 456     if "$enable_tui" = "auto"; then
 457       enable_tui=no
 458     fi
 459     ;;
 460 esac
 461
 462 # Check whether we should enable the TUI, but only do so if we really
 463 # can.
 464 if test x"$enable_tui" != xno; then
 465   if test -d $srcdir/tui; then
 466     # For the TUI, we need enhanced curses functionality.
 467     #
 468     # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 469     # curses library because the latter might not provide all the
 470     # functionality we need.  However, this leads to problems on systems
 471     # where the linker searches /usr/local/lib, but the compiler doesn't
 472     # search /usr/local/include, if ncurses is installed in /usr/local.  A
 473     # default installation of ncurses on alpha*-dec-osf* will lead to such
 474     # a situation.
 475     AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 476
 477     if test "$ac_cv_search_waddstr" != no; then
 478       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 479       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 480       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 481       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 482       CONFIG_ALL="${CONFIG_ALL} all-tui"
 483       CONFIG_CLEAN="${CONFIG_CLEAN} clean-tui"
 484       CONFIG_INSTALL="${CONFIG_INSTALL} install-tui"
 485       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-tui"
 486     else
 487       if test x"$enable_tui" = xyes; then
 488         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 489       else
 490         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 491       fi
 492     fi
 493   fi
 494 fi
 495
 496 # Since GDB uses Readline, we need termcap functionality.  In many
 497 # cases this will be provided by the curses library, but some systems
 498 # have a seperate termcap library, or no curses library at all.
 499
 500 case $host_os in
 501   cygwin*)
 502     if test -d $srcdir/libtermcap; then
 503       LIBS="../libtermcap/libtermcap.a $LIBS"
 504       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 505     fi ;;
 506   go32* | *djgpp*)
 507     ac_cv_search_tgetent="none required"
 508     ;;
 509   *mingw32*)
 510     ac_cv_search_tgetent="none required"
 511     CONFIG_OBS="$CONFIG_OBS win32-termcap.o"
 512     ;;
 513 esac
 514
 515 # These are the libraries checked by Readline.
 516 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 517
 518 if test "$ac_cv_search_tgetent" = no; then
 519   AC_MSG_ERROR([no termcap library found])
 520 fi
 521
 522 AC_ARG_WITH([system-readline],
 523   [AS_HELP_STRING([--with-system-readline],
 524                   [use installed readline library])])
 525
 526 if test "$with_system_readline" = yes; then
 527   READLINE=-lreadline
 528   READLINE_DEPS=
 529   READLINE_CFLAGS=
 530 else
 531   READLINE='$(READLINE_DIR)/libreadline.a'
 532   READLINE_DEPS='$(READLINE)'
 533   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 534 fi
 535 AC_SUBST(READLINE)
 536 AC_SUBST(READLINE_DEPS)
 537 AC_SUBST(READLINE_CFLAGS)
 538
 539 AC_ARG_WITH(expat,
 540   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 541   [], [with_expat=auto])
 542 AC_MSG_CHECKING([whether to use expat])
 543 AC_MSG_RESULT([$with_expat])
 544
 545 if test "${with_expat}" = no; then
 546   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 547   HAVE_LIBEXPAT=no
 548 else
 549   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 550                         [XML_Parser p = XML_ParserCreate (0);])
 551   if test "$HAVE_LIBEXPAT" != yes; then
 552     if test "$with_expat" = yes; then
 553       AC_MSG_ERROR([expat is missing or unusable])
 554     else
 555       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 556     fi
 557   else
 558     save_LIBS=$LIBS
 559     LIBS="$LIBS $LIBEXPAT"
 560     AC_CHECK_FUNCS(XML_StopParser)
 561     LIBS=$save_LIBS
 562   fi
 563 fi
 564
 565 dnl Utility to simplify finding libpython.
 566 AC_DEFUN([AC_TRY_LIBPYTHON],
 567 [
 568   version=$1
 569   define([have_libpython_var],$2)
 570   define([VERSION],[translit([$1],[abcdefghijklmnopqrstuvwxyz./-],
 571                                   [ABCDEFGHIJKLMNOPQRSTUVWXYZ___])])
 572   [HAVE_LIB]VERSION=no
 573   AC_MSG_CHECKING([for ${version}])
 574   save_LIBS=$LIBS
 575   LIBS="$LIBS -l${version}"
 576   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "${version}/Python.h"]],
 577                                  [[Py_Initialize ();]]),
 578                  [[HAVE_LIB]VERSION=yes
 579                   have_libpython_var=yes],
 580                  [LIBS=$save_LIBS])
 581   AC_MSG_RESULT([$[HAVE_LIB]VERSION])
 582 ])
 583
 584 AC_ARG_WITH(python,
 585   AS_HELP_STRING([--with-python], [include python support (auto/yes/no/<path>)]),
 586   [], [with_python=auto])
 587 AC_MSG_CHECKING([whether to use python])
 588 AC_MSG_RESULT([$with_python])
 589
 590 if test "${with_python}" = no; then
 591   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 592   have_libpython=no
 593 else
 594   case "${with_python}" in
 595   yes | auto)
 596     # Leave as empty, use defaults.
 597     python_includes=
 598     python_libs=
 599     ;;
 600   /*)
 601     python_includes="-I${with_python}/include"
 602     python_libs="-L${with_python}/lib"
 603     ;;
 604   *)
 605     AC_ERROR(invalid value for --with-python)
 606     ;;
 607   esac
 608
 609   save_CPPFLAGS=$CPPFLAGS
 610   CPPFLAGS="$CPPFLAGS ${python_includes}"
 611   save_LIBS=$LIBS
 612   LIBS="$LIBS ${python_libs}"
 613   have_libpython=no
 614   if test "${have_libpython}" = no; then
 615     AC_TRY_LIBPYTHON(python2.6, have_libpython)
 616     if test "${HAVE_LIBPYTHON2_6}" = yes; then
 617       AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 618     fi
 619   fi
 620   if test ${have_libpython} = no; then
 621     AC_TRY_LIBPYTHON(python2.5, have_libpython)
 622     if test "${HAVE_LIBPYTHON2_5}" = yes; then
 623       AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 624     fi
 625   fi
 626   if test ${have_libpython} = no; then
 627     AC_TRY_LIBPYTHON(python2.4, have_libpython)
 628     if test "${HAVE_LIBPYTHON2_4}" = yes; then
 629       AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 630     fi
 631   fi
 632   if test ${have_libpython} = no; then
 633     case "${with_python}" in
 634     yes)
 635       AC_MSG_ERROR([python is missing or unusable])
 636       ;;
 637     auto)
 638       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 639       ;;
 640     *)
 641       AC_MSG_ERROR([no usable python found at ${with_python}])
 642       ;;
 643     esac
 644     CPPFLAGS=$save_CPPFLAGS
 645     LIBS=$save_LIBS
 646   fi
 647 fi
 648
 649 if test "${have_libpython}" = yes; then
 650   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 651   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 652   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 653   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 654   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 655
 656   # Flags needed to compile Python code (taken from python-config --cflags).
 657   # We cannot call python-config directly because it will output whatever was
 658   # used when compiling the Python interpreter itself, including flags which
 659   # would make the python-related objects be compiled differently from the
 660   # rest of GDB (e.g., -O2 and -fPIC).
 661   if test "${GCC}" = yes; then
 662     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 663   fi
 664
 665   if test "x${tentative_python_cflags}" != x; then
 666     AC_MSG_CHECKING(compiler flags for python code)
 667     for flag in ${tentative_python_cflags}; do
 668       # Check that the compiler accepts it
 669       saved_CFLAGS="$CFLAGS"
 670       CFLAGS="$CFLAGS $flag"
 671       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 672       CFLAGS="$saved_CFLAGS"
 673     done
 674     AC_MSG_RESULT(${PYTHON_CFLAGS})
 675   fi
 676 else
 677   # Even if Python support is not compiled in, we need to have these files
 678   # included in order to recognize the GDB command "python".
 679   CONFIG_OBS="$CONFIG_OBS python.o python-value.o"
 680   CONFIG_SRCS="$CONFIG_SRCS python/python.c python/python-value.c"
 681 fi
 682 AC_SUBST(PYTHON_CFLAGS)
 683
 684 # ------------------------- #
 685 # Checks for header files.  #
 686 # ------------------------- #
 687
 688 AC_HEADER_DIRENT
 689 AC_HEADER_STAT
 690 AC_HEADER_STDC
 691 AC_CHECK_HEADERS(nlist.h)
 692 AC_CHECK_HEADERS(link.h, [], [],
 693 [#if HAVE_SYS_TYPES_H
 694 # include <sys/types.h>
 695 #endif
 696 #if HAVE_NLIST_H
 697 # include <nlist.h>
 698 #endif
 699 ])
 700 AC_CHECK_HEADERS(machine/reg.h)
 701 AC_CHECK_HEADERS(poll.h sys/poll.h)
 702 AC_CHECK_HEADERS(proc_service.h thread_db.h gnu/libc-version.h)
 703 AC_CHECK_HEADERS(signal.h)
 704 AC_CHECK_HEADERS(stddef.h)
 705 AC_CHECK_HEADERS(stdlib.h)
 706 AC_CHECK_HEADERS(string.h memory.h strings.h)
 707 AC_CHECK_HEADERS(sys/fault.h)
 708 AC_CHECK_HEADERS(sys/file.h)
 709 AC_CHECK_HEADERS(sys/filio.h)
 710 AC_CHECK_HEADERS(sys/ioctl.h)
 711 AC_CHECK_HEADERS(sys/param.h)
 712 AC_CHECK_HEADERS(sys/resource.h)
 713 AC_CHECK_HEADERS(sys/proc.h, [], [],
 714 [#if HAVE_SYS_PARAM_H
 715 # include <sys/param.h>
 716 #endif
 717 ])
 718 AC_CHECK_HEADERS(sys/procfs.h)
 719 AC_CHECK_HEADERS(sys/ptrace.h ptrace.h)
 720 AC_CHECK_HEADERS(sys/reg.h sys/debugreg.h)
 721 AC_CHECK_HEADERS(sys/select.h)
 722 AC_CHECK_HEADERS(sys/syscall.h)
 723 AC_CHECK_HEADERS(sys/types.h)
 724 AC_CHECK_HEADERS(sys/user.h, [], [],
 725 [#if HAVE_SYS_PARAM_H
 726 # include <sys/param.h>
 727 #endif
 728 ])
 729 AC_CHECK_HEADERS(sys/wait.h wait.h)
 730 AC_CHECK_HEADERS(termios.h termio.h sgtty.h)
 731 AC_CHECK_HEADERS(unistd.h)
 732
 733 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
 734 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
 735 # think that we don't have <curses.h> if we're using GCC.
 736 case $host_os in
 737   solaris2.[[789]])
 738     if test "$GCC" = yes; then
 739       AC_DEFINE(_MSE_INT_H, 1,
 740         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
 741    Solaris 2.[789] when using GCC. ])
 742     fi ;;
 743 esac
 744 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h)
 745 AC_CHECK_HEADERS(ncurses/term.h)
 746 AC_CHECK_HEADERS(term.h, [], [],
 747 [#if HAVE_CURSES_H
 748 # include <curses.h>
 749 #endif
 750 ])
 751
 752 # Check for HP/UX 64-bit shared library support
 753 AC_CHECK_HEADERS(elf_hp.h)
 754
 755 # FIXME: kettenis/20030102: In most cases we include these
 756 # unconditionally, so what's the point in checking these?
 757 AC_CHECK_HEADERS(ctype.h time.h)
 758
 759 # ------------------------- #
 760 # Checks for declarations.  #
 761 # ------------------------- #
 762
 763 AC_CHECK_DECLS([free, malloc, realloc])
 764 AC_CHECK_DECLS([strerror, strstr])
 765 AC_CHECK_DECLS([getopt, snprintf, vsnprintf])
 766
 767 # ----------------------- #
 768 # Checks for structures.  #
 769 # ----------------------- #
 770
 771 AC_CHECK_MEMBERS([struct stat.st_blocks])
 772 AC_CHECK_MEMBERS([struct stat.st_blksize])
 773
 774 # ------------------ #
 775 # Checks for types.  #
 776 # ------------------ #
 777
 778 AC_TYPE_SIGNAL
 779 AC_CHECK_TYPES(socklen_t, [], [],
 780 [#include <sys/types.h>
 781 #include <sys/socket.h>
 782 ])
 783
 784 # ------------------------------------- #
 785 # Checks for compiler characteristics.  #
 786 # ------------------------------------- #
 787
 788 AC_C_CONST
 789 AC_C_INLINE
 790 AC_C_BIGENDIAN
 791
 792 # ------------------------------ #
 793 # Checks for library functions.  #
 794 # ------------------------------ #
 795
 796 AC_FUNC_ALLOCA
 797 AC_FUNC_MMAP
 798 AC_FUNC_VFORK
 799 AC_CHECK_FUNCS(canonicalize_file_name realpath)
 800 AC_CHECK_FUNCS(getrusage)
 801 AC_CHECK_FUNCS(getuid getgid)
 802 AC_CHECK_FUNCS(poll)
 803 AC_CHECK_FUNCS(pread64)
 804 AC_CHECK_FUNCS(sbrk)
 805 AC_CHECK_FUNCS(setpgid setpgrp setsid)
 806 AC_CHECK_FUNCS(sigaction sigprocmask sigsetmask)
 807 AC_CHECK_FUNCS(socketpair)
 808 AC_CHECK_FUNCS(syscall)
 809 AC_CHECK_FUNCS(ttrace)
 810 AC_CHECK_FUNCS(wborder)
 811
 812 # Check the return and argument types of ptrace.  No canned test for
 813 # this, so roll our own.
 814 gdb_ptrace_headers='
 815 #if HAVE_SYS_TYPES_H
 816 # include <sys/types.h>
 817 #endif
 818 #if HAVE_SYS_PTRACE_H
 819 # include <sys/ptrace.h>
 820 #endif
 821 #if HAVE_UNISTD_H
 822 # include <unistd.h>
 823 #endif
 824 '
 825 # There is no point in checking if we don't have a prototype.
 826 AC_CHECK_DECLS(ptrace, [], [
 827   : ${gdb_cv_func_ptrace_ret='int'}
 828   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 829 ], $gdb_ptrace_headers)
 830 # Check return type.  Varargs (used on GNU/Linux) conflict with the
 831 # empty argument list, so check for that explicitly.
 832 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
 833   AC_TRY_COMPILE($gdb_ptrace_headers,
 834     [extern long ptrace (enum __ptrace_request, ...);],
 835     gdb_cv_func_ptrace_ret='long',
 836     AC_TRY_COMPILE($gdb_ptrace_headers,
 837       [extern int ptrace ();],
 838       gdb_cv_func_ptrace_ret='int',
 839       gdb_cv_func_ptrace_ret='long')))
 840 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
 841   [Define as the return type of ptrace.])
 842 # Check argument types.
 843 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
 844   AC_TRY_COMPILE($gdb_ptrace_headers,
 845     [extern long ptrace (enum __ptrace_request, ...);],
 846     [gdb_cv_func_ptrace_args='int,int,long,long'],[
 847 for gdb_arg1 in 'int' 'long'; do
 848  for gdb_arg2 in 'pid_t' 'int' 'long'; do
 849   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
 850    for gdb_arg4 in 'int' 'long'; do
 851      AC_TRY_COMPILE($gdb_ptrace_headers, [
 852 extern $gdb_cv_func_ptrace_ret
 853   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
 854 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
 855     break 4;])
 856     for gdb_arg5 in 'int *' 'int' 'long'; do
 857      AC_TRY_COMPILE($gdb_ptrace_headers, [
 858 extern $gdb_cv_func_ptrace_ret
 859   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
 860 ], [
 861 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
 862     break 5;])
 863     done
 864    done
 865   done
 866  done
 867 done
 868 # Provide a safe default value.
 869 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 870 ])])
 871 ac_save_IFS=$IFS; IFS=','
 872 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
 873 IFS=$ac_save_IFS
 874 shift
 875 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
 876   [Define to the type of arg 3 for ptrace.])
 877 if test -n "$[5]"; then
 878   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
 879     [Define to the type of arg 5 for ptrace.])
 880 fi
 881
 882 dnl AC_FUNC_SETPGRP does not work when cross compiling
 883 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
 884 if test "$cross_compiling" = no; then
 885   AC_FUNC_SETPGRP
 886 else
 887   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
 888     [AC_TRY_COMPILE([
 889 #include <unistd.h>
 890 ], [
 891   if (setpgrp(1,1) == -1)
 892     exit (0);
 893   else
 894     exit (1);
 895 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
 896 if test $ac_cv_func_setpgrp_void = yes; then
 897   AC_DEFINE(SETPGRP_VOID, 1)
 898 fi
 899 fi
 900
 901 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
 902 # since sigsetjmp might only be defined as a macro.
 903 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
 904 [AC_TRY_COMPILE([
 905 #include <setjmp.h>
 906 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 907 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
 908 if test $gdb_cv_func_sigsetjmp = yes; then
 909   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 910 fi
 911
 912 # Assume we'll default to using the included libiberty regex.
 913 gdb_use_included_regex=yes
 914
 915 # However, if the system regex is GNU regex, then default to *not*
 916 # using the included regex.
 917 AC_CACHE_CHECK(
 918   [for GNU regex],
 919   [gdb_cv_have_gnu_regex],
 920   [AC_TRY_COMPILE(
 921     [#include <gnu-versions.h>],
 922     [#define REGEX_INTERFACE_VERSION 1
 923 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
 924 # error "Version mismatch"
 925 #endif],
 926     gdb_cv_have_gnu_regex=yes,
 927     gdb_cv_have_gnu_regex=no)])
 928 if test $gdb_cv_have_gnu_regex = yes; then
 929   gdb_use_included_regex=no
 930 fi
 931
 932 AC_ARG_WITH(included-regex,
 933   [  --without-included-regex don't use included regex; this is the default
 934                           on systems with version 2 of the GNU C library
 935                           (use with caution on other system)],
 936   gdb_with_regex=$withval,
 937   gdb_with_regex=$gdb_use_included_regex)
 938 if test "$gdb_with_regex" = yes; then
 939   AC_DEFINE(USE_INCLUDED_REGEX, 1,
 940     [Define to 1 if the regex included in libiberty should be used.])
 941 fi
 942
 943 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
 944 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
 945 [#include <sys/param.h>
 946 #include <sys/proc.h>
 947 ])
 948
 949 # See if <sys/lwp.h> defines `struct lwp`.
 950 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
 951 [AC_TRY_COMPILE([#include <sys/param.h>
 952 #include <sys/lwp.h>], [struct lwp l;],
 953 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
 954 if test $gdb_cv_struct_lwp = yes; then
 955   AC_DEFINE(HAVE_STRUCT_LWP, 1,
 956             [Define to 1 if your system has struct lwp.])
 957 fi
 958
 959 # See if <machine/reg.h> degines `struct reg'.
 960 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
 961 [AC_TRY_COMPILE([#include <sys/types.h>
 962 #include <machine/reg.h>], [struct reg r;],
 963 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
 964 if test $gdb_cv_struct_reg = yes; then
 965   AC_DEFINE(HAVE_STRUCT_REG, 1,
 966             [Define to 1 if your system has struct reg in <machine/reg.h>.])
 967 fi
 968
 969 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
 970 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
 971 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
 972                  [#include <machine/reg.h>])
 973
 974 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
 975 AC_MSG_CHECKING(for PTRACE_GETREGS)
 976 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
 977 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 978                 [PTRACE_GETREGS;],
 979                 [gdb_cv_have_ptrace_getregs=yes],
 980                 [gdb_cv_have_ptrace_getregs=no])])
 981 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
 982 if test $gdb_cv_have_ptrace_getregs = yes; then
 983   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
 984   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
 985 fi
 986
 987 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
 988 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 989 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
 990 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 991                 [PTRACE_GETFPXREGS;],
 992                 [gdb_cv_have_ptrace_getfpxregs=yes],
 993                 [gdb_cv_have_ptrace_getfpxregs=no])])
 994 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
 995 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
 996   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
 997   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
 998 fi
 999
1000 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1001 AC_MSG_CHECKING(for PT_GETDBREGS)
1002 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1003 [AC_TRY_COMPILE([#include <sys/types.h>
1004 #include <sys/ptrace.h>],
1005                 [PT_GETDBREGS;],
1006                 [gdb_cv_have_pt_getdbregs=yes],
1007                 [gdb_cv_have_pt_getdbregs=no])])
1008 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1009 if test $gdb_cv_have_pt_getdbregs = yes; then
1010   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1011   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1012 fi
1013
1014 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1015 AC_MSG_CHECKING(for PT_GETXMMREGS)
1016 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1017 [AC_TRY_COMPILE([#include <sys/types.h>
1018 #include <sys/ptrace.h>],
1019                 [PT_GETXMMREGS;],
1020                 [gdb_cv_have_pt_getxmmregs=yes],
1021                 [gdb_cv_have_pt_getxmmregs=no])])
1022 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1023 if test $gdb_cv_have_pt_getxmmregs = yes; then
1024   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1025   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1026 fi
1027
1028 # Detect which type of /proc is in use, such as for Unixware or Solaris.
1029
1030 if test "${target}" = "${host}"; then
1031   case "${host}" in
1032   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
1033       AC_DEFINE(NEW_PROC_API, 1,
1034       [Define if you want to use new multi-fd /proc interface
1035        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1036       ;;
1037   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1038       AC_DEFINE(NEW_PROC_API, 1,
1039       [Define if you want to use new multi-fd /proc interface
1040        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1041       ;;
1042   mips-sgi-irix5*)
1043       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1044       AC_DEFINE([_KMEMUSER], 1,
1045       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1046        around a <sys/proc.h> problem on IRIX 5.])
1047       ;;
1048   esac
1049 fi
1050
1051 if test "$ac_cv_header_sys_procfs_h" = yes; then
1052   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
1053   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
1054   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1055   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1056   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1057   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1058   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1059   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
1060   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1061   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1062   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1063   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1064   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1065   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1066
1067
1068   dnl Check for broken prfpregset_t type
1069
1070   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1071   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1072   dnl instead of the struct itself).  We detect this here, and work
1073   dnl around it in gdb_proc_service.h.
1074
1075   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1076     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1077     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1078       [AC_TRY_RUN([#include <sys/procfs.h>
1079        int main ()
1080        {
1081          if (sizeof (prfpregset_t) == sizeof (void *))
1082            return 1;
1083          return 0;
1084        }],
1085        gdb_cv_prfpregset_t_broken=no,
1086        gdb_cv_prfpregset_t_broken=yes,
1087        gdb_cv_prfpregset_t_broken=yes)])
1088     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1089     if test $gdb_cv_prfpregset_t_broken = yes; then
1090       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1091       [Define if the prfpregset_t type is broken.])
1092     fi
1093   fi
1094
1095   dnl Check for PIOCSET ioctl entry
1096
1097   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
1098   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
1099   [AC_TRY_COMPILE([#include <unistd.h>
1100 #include <sys/types.h>
1101 #include <sys/procfs.h>
1102 ], [
1103     int dummy;;
1104     dummy = ioctl(0, PIOCSET, &dummy);
1105   ],
1106   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
1107   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
1108   if test $gdb_cv_have_procfs_piocset = yes; then
1109     AC_DEFINE(HAVE_PROCFS_PIOCSET, 1,
1110     [Define if ioctl argument PIOCSET is available.])
1111   fi
1112 fi
1113
1114 dnl For native ports (host == target), check to see what kind of
1115 dnl legacy link.h support is needed.  (See solib-legacy.c.)
1116 if test ${host} = ${target} ; then
1117   dnl Check for struct link_map with l_ members which are indicative
1118   dnl of SVR4-like shared libraries
1119
1120   AC_MSG_CHECKING(for member l_addr in struct link_map)
1121   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
1122     [AC_TRY_COMPILE([#include <link.h>],
1123                     [struct link_map lm; (void) lm.l_addr;],
1124                     gdb_cv_have_struct_link_map_with_l_members=yes,
1125                     gdb_cv_have_struct_link_map_with_l_members=no)])
1126   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
1127   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
1128     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1,
1129     [Define if <link.h> exists and defines struct link_map which has
1130      members with an ``l_'' prefix.  (For Solaris, SVR4, and
1131      SVR4-like systems.)])
1132   fi
1133
1134   dnl Check for struct link_map with lm_ members which are indicative
1135   dnl of SunOS-like shared libraries
1136
1137   AC_MSG_CHECKING(for member lm_addr in struct link_map)
1138   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
1139     [AC_TRY_COMPILE([#include <sys/types.h>
1140 #include <link.h>],
1141                     [struct link_map lm; (void) lm.lm_addr;],
1142                     gdb_cv_have_struct_link_map_with_lm_members=yes,
1143                     gdb_cv_have_struct_link_map_with_lm_members=no)])
1144   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
1145   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
1146     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1,
1147     [Define if <link.h> exists and defines struct link_map which has
1148      members with an ``lm_'' prefix.  (For SunOS.)])
1149   fi
1150
1151   dnl Check for struct so_map with som_ members which are found on
1152   dnl some *BSD systems.
1153
1154   AC_MSG_CHECKING(for member som_addr in struct so_map)
1155   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
1156     [AC_TRY_COMPILE([#include <sys/types.h>
1157 #ifdef HAVE_NLIST_H
1158 #include <nlist.h>
1159 #endif
1160 #include <link.h>],
1161                     [struct so_map lm; (void) lm.som_addr;],
1162                     gdb_cv_have_struct_so_map_with_som_members=yes,
1163                     gdb_cv_have_struct_so_map_with_som_members=no)])
1164   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
1165   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
1166     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1,
1167     [Define if <link.h> exists and defines a struct so_map which has
1168      members with an ``som_'' prefix.  (Found on older *BSD systems.)])
1169   fi
1170
1171   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
1172   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
1173
1174   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
1175   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
1176     [AC_TRY_COMPILE([#define _SYSCALL32
1177 #include <sys/link.h>], [struct link_map32 l;],
1178      gdb_cv_have_struct_link_map32=yes,
1179      gdb_cv_have_struct_link_map32=no)])
1180   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
1181   if test $gdb_cv_have_struct_link_map32 = yes; then
1182     AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1,
1183     [Define if <sys/link.h> has struct link_map32])
1184     AC_DEFINE(_SYSCALL32, 1,
1185     [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)])
1186   fi
1187 fi
1188
1189 # Check if the compiler supports the `long long' type.
1190
1191 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1192                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1193 [[extern long long foo;]],
1194 [[switch (foo & 2) { case 0: return 1; }]])],
1195                                   gdb_cv_c_long_long=yes,
1196                                   gdb_cv_c_long_long=no)])
1197 if test $gdb_cv_c_long_long = yes; then
1198   AC_DEFINE(CC_HAS_LONG_LONG, 1,
1199             [Define to 1 if the compiler supports long long.])
1200 fi
1201
1202 # Check if the compiler and runtime support printing long longs.
1203
1204 AC_CACHE_CHECK([for long long support in printf],
1205                gdb_cv_printf_has_long_long,
1206                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1207 [[char buf[32];
1208   long long l = 0;
1209   l = (l << 16) + 0x0123;
1210   l = (l << 16) + 0x4567;
1211   l = (l << 16) + 0x89ab;
1212   l = (l << 16) + 0xcdef;
1213   sprintf (buf, "0x%016llx", l);
1214   return (strcmp ("0x0123456789abcdef", buf));]])],
1215                               gdb_cv_printf_has_long_long=yes,
1216                               gdb_cv_printf_has_long_long=no,
1217                               gdb_cv_printf_has_long_long=no)])
1218 if test $gdb_cv_printf_has_long_long = yes; then
1219   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1220             [Define to 1 if the "%ll" format works to print long longs.])
1221 fi
1222
1223 # Check if the compiler and runtime support printing decfloats.
1224
1225 AC_CACHE_CHECK([for decfloat support in printf],
1226                gdb_cv_printf_has_decfloat,
1227                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1228 [[char buf[64];
1229   _Decimal32 d32 = 1.2345df;
1230   _Decimal64 d64 = 1.2345dd;
1231   _Decimal128 d128 = 1.2345dl;
1232   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1233   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1234                               gdb_cv_printf_has_decfloat=yes,
1235                               gdb_cv_printf_has_decfloat=no,
1236                               gdb_cv_printf_has_decfloat=no)])
1237 if test $gdb_cv_printf_has_decfloat = yes; then
1238   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1239             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1240 fi
1241
1242 # Check if the compiler supports the `long double' type.  We can't use
1243 # AC_C_LONG_DOUBLE because that one does additional checks on the
1244 # constants defined in <float.h> that fail on some systems,
1245 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1246
1247 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1248                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1249                                   gdb_cv_c_long_double=yes,
1250                                   gdb_cv_c_long_double=no)])
1251 if test $gdb_cv_c_long_double = yes; then
1252   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1253            [Define to 1 if the compiler supports long double.])
1254 fi
1255
1256 # Check if the compiler and runtime support printing long doubles.
1257
1258 AC_CACHE_CHECK([for long double support in printf],
1259                gdb_cv_printf_has_long_double,
1260                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1261 [[char buf[16];
1262   long double f = 3.141592653;
1263   sprintf (buf, "%Lg", f);
1264   return (strncmp ("3.14159", buf, 7));]])],
1265                               gdb_cv_printf_has_long_double=yes,
1266                               gdb_cv_printf_has_long_double=no,
1267                               gdb_cv_printf_has_long_double=no)])
1268 if test $gdb_cv_printf_has_long_double = yes; then
1269   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1270             [Define to 1 if the "%Lg" format works to print long doubles.])
1271 fi
1272
1273 # Check if the compiler and runtime support scanning long doubles.
1274
1275 AC_CACHE_CHECK([for long double support in scanf],
1276                gdb_cv_scanf_has_long_double,
1277                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1278 [[#include <stdio.h>]],
1279 [[char *buf = "3.141592653";
1280   long double f = 0;
1281   sscanf (buf, "%Lg", &f);
1282   return !(f > 3.14159 && f < 3.14160);]])],
1283                               gdb_cv_scanf_has_long_double=yes,
1284                               gdb_cv_scanf_has_long_double=no,
1285                               gdb_cv_scanf_has_long_double=no)])
1286 if test $gdb_cv_scanf_has_long_double = yes; then
1287   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1288             [Define to 1 if the "%Lg" format works to scan long doubles.])
1289 fi
1290
1291 case ${host_os} in
1292 aix*)
1293   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1294     SAVE_LDFLAGS=$LDFLAGS
1295
1296     case $GCC in
1297     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1298     *) gdb_cv_bigtoc=-bbigtoc ;;
1299     esac
1300
1301     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1302     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1303     LDFLAGS="${SAVE_LDFLAGS}"
1304   ])
1305   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1306   ;;
1307 esac
1308
1309
1310 dnl For certain native configurations, we need to check whether thread
1311 dnl support can be built in or not.
1312 dnl
1313 dnl Note that we only want this if we are both native (host == target),
1314 dnl and not doing a canadian cross build (build == host).
1315
1316 if test ${build} = ${host} -a ${host} = ${target} ; then
1317    case ${host_os} in
1318    hpux*)
1319       AC_MSG_CHECKING(for HPUX/OSF thread support)
1320       if test -f /usr/include/dce/cma_config.h ; then
1321          if test "$GCC" = "yes" ; then
1322             AC_MSG_RESULT(yes)
1323             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT, 1,
1324             [Define if you have HPUX threads])
1325             CONFIG_OBS="${CONFIG_OBS} hpux-thread.o"
1326             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
1327          else
1328             AC_MSG_RESULT(no (suppressed because you are not using GCC))
1329          fi
1330       else
1331          AC_MSG_RESULT(no)
1332       fi
1333       ;;
1334    solaris*)
1335       # See if thread_db library is around for Solaris thread debugging.
1336       # Note that we must explicitly test for version 1 of the library
1337       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1338       # the same API.
1339       AC_MSG_CHECKING(for Solaris thread debugging library)
1340       if test -f /usr/lib/libthread_db.so.1 ; then
1341          AC_MSG_RESULT(yes)
1342          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1343          [Define if using Solaris thread debugging.])
1344          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1345          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1346          AC_CHECK_LIB(dl, dlopen)
1347          if test "$GCC" = "yes" ; then
1348             # The GNU linker requires the -export-dynamic option to make
1349             # all symbols visible in the dynamic symbol table.
1350             hold_ldflags=$LDFLAGS
1351             AC_MSG_CHECKING(for the ld -export-dynamic flag)
1352             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
1353             AC_TRY_LINK(, [int i;], found=yes, found=no)
1354             LDFLAGS=$hold_ldflags
1355             AC_MSG_RESULT($found)
1356             if test $found = yes; then
1357                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
1358             fi
1359          fi
1360          # Sun randomly tweaked the prototypes in <proc_service.h>
1361          # at one point.
1362          AC_MSG_CHECKING(if <proc_service.h> is old)
1363          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1364             AC_TRY_COMPILE([
1365                 #include <proc_service.h>
1366                 ps_err_e ps_pdwrite
1367                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1368             ],, gdb_cv_proc_service_is_old=no,
1369                 gdb_cv_proc_service_is_old=yes)
1370          ])
1371          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1372          if test $gdb_cv_proc_service_is_old = yes; then
1373             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1374             [Define if <proc_service.h> on solaris uses int instead of
1375              size_t, and assorted other type changes.])
1376          fi
1377       else
1378          AC_MSG_RESULT(no)
1379       fi
1380       ;;
1381    aix*)
1382       AC_MSG_CHECKING(for AiX thread debugging library)
1383       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1384                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1385                                    [#ifndef PTHDB_VERSION_3
1386                                     #error
1387                                     #endif],
1388                                    gdb_cv_have_aix_thread_debug=yes,
1389                                    gdb_cv_have_aix_thread_debug=no)])
1390       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1391       if test $gdb_cv_have_aix_thread_debug = yes; then
1392          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1393          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1394          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
1395       fi
1396       ;;
1397    esac
1398    AC_SUBST(CONFIG_LDFLAGS)
1399 fi
1400
1401 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1402 dnl other error codes.
1403 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1404    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1405                   gdb_cv_thread_db_h_has_td_notalloc,
1406      AC_TRY_COMPILE(
1407        [#include <thread_db.h>],
1408        [int i = TD_NOTALLOC;],
1409        gdb_cv_thread_db_h_has_td_notalloc=yes,
1410        gdb_cv_thread_db_h_has_td_notalloc=no
1411      )
1412    )
1413    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1414                   gdb_cv_thread_db_h_has_td_version,
1415      AC_TRY_COMPILE(
1416        [#include <thread_db.h>],
1417        [int i = TD_VERSION;],
1418        gdb_cv_thread_db_h_has_td_version=yes,
1419        gdb_cv_thread_db_h_has_td_version=no
1420      )
1421    )
1422    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1423                   gdb_cv_thread_db_h_has_td_notls,
1424      AC_TRY_COMPILE(
1425        [#include <thread_db.h>],
1426        [int i = TD_NOTLS;],
1427        gdb_cv_thread_db_h_has_td_notls=yes,
1428        gdb_cv_thread_db_h_has_td_notls=no
1429      )
1430    )
1431 fi
1432 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1433   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1434             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1435 fi
1436 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1437   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1438             [Define if <thread_db.h> has the TD_VERSION error code.])
1439 fi
1440 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1441   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1442             [Define if <thread_db.h> has the TD_NOTLS error code.])
1443 fi
1444
1445 dnl See if we have a sys/syscall header file that has __NR_tkill.
1446 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1447    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1448                   gdb_cv_sys_syscall_h_has_tkill,
1449      AC_TRY_COMPILE(
1450        [#include <sys/syscall.h>],
1451        [int i = __NR_tkill;],
1452        gdb_cv_sys_syscall_h_has_tkill=yes,
1453        gdb_cv_sys_syscall_h_has_tkill=no
1454      )
1455    )
1456 fi
1457 dnl See if we can issue tkill syscall.
1458 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1459   AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1460 fi
1461
1462 dnl Check if we can disable the virtual address space randomization.
1463 dnl The functionality of setarch -R.
1464 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1465 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1466 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1467 #       define ADDR_NO_RANDOMIZE 0x0040000
1468 #      endif
1469        /* Test the flag could be set and stays set.  */
1470        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1471        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1472            return 1])])
1473 AC_RUN_IFELSE([PERSONALITY_TEST],
1474               [have_personality=true],
1475               [have_personality=false],
1476               [AC_LINK_IFELSE([PERSONALITY_TEST],
1477                               [have_personality=true],
1478                               [have_personality=false])])
1479 if $have_personality
1480 then
1481     AC_DEFINE([HAVE_PERSONALITY], 1,
1482               [Define if you support the personality syscall.])
1483 fi
1484
1485 dnl Handle optional features that can be enabled.
1486
1487 AC_ARG_WITH(sysroot,
1488 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
1489 [
1490  case ${with_sysroot} in
1491  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
1492  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
1493  esac
1494
1495  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
1496
1497  if test "x$prefix" = xNONE; then
1498   test_prefix=/usr/local
1499  else
1500   test_prefix=$prefix
1501  fi
1502  if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
1503   test_exec_prefix=$test_prefix
1504  else
1505   test_exec_prefix=$exec_prefix
1506  fi
1507  case ${TARGET_SYSTEM_ROOT} in
1508  "${test_prefix}"|"${test_prefix}/"*|\
1509  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
1510  '${prefix}'|'${prefix}/'*|\
1511  '${exec_prefix}'|'${exec_prefix}/'*)
1512    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
1513    TARGET_SYSTEM_ROOT_DEFINE="$t"
1514    ;;
1515  esac
1516 ], [
1517  TARGET_SYSTEM_ROOT=
1518  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
1519 ])
1520 AC_SUBST(TARGET_SYSTEM_ROOT)
1521 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
1522
1523 AC_ARG_ENABLE(werror,
1524   [  --enable-werror    treat compile warnings as errors],
1525   [case "${enableval}" in
1526      yes | y) ERROR_ON_WARNING="yes" ;;
1527      no | n)  ERROR_ON_WARNING="no" ;;
1528      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1529    esac])
1530
1531 # Enable -Werror by default when using gcc
1532 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then
1533     ERROR_ON_WARNING=yes
1534 fi
1535
1536 WERROR_CFLAGS=""
1537 if test "${ERROR_ON_WARNING}" = yes ; then
1538     WERROR_CFLAGS="-Werror"
1539 fi
1540
1541 # The entries after -Wno-pointer-sign are disabled warnings which may
1542 # be enabled in the future, which can not currently be used to build
1543 # GDB.
1544 # NOTE: If you change this list, remember to update
1545 # gdb/doc/gdbint.texinfo.
1546 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1547 -Wformat-nonliteral -Wno-pointer-sign \
1548 -Wno-unused -Wno-switch -Wno-char-subscripts"
1549
1550 # Enable -Wno-format by default when using gcc on mingw since many
1551 # GCC versions complain about %I64.
1552 case "${host}" in
1553   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1554 esac
1555
1556 AC_ARG_ENABLE(build-warnings,
1557 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
1558 [case "${enableval}" in
1559   yes)  ;;
1560   no)   build_warnings="-w";;
1561   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1562         build_warnings="${build_warnings} ${t}";;
1563   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1564         build_warnings="${t} ${build_warnings}";;
1565   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1566 esac
1567 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1568   echo "Setting compiler warning flags = $build_warnings" 6>&1
1569 fi])dnl
1570 AC_ARG_ENABLE(gdb-build-warnings,
1571 [  --enable-gdb-build-warnings Enable GDB specific build-time compiler warnings if gcc is used],
1572 [case "${enableval}" in
1573   yes)  ;;
1574   no)   build_warnings="-w";;
1575   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1576         build_warnings="${build_warnings} ${t}";;
1577   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1578         build_warnings="${t} ${build_warnings}";;
1579   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1580 esac
1581 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1582   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1583 fi])dnl
1584 WARN_CFLAGS=""
1585 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1586 then
1587     AC_MSG_CHECKING(compiler warning flags)
1588     # Separate out the -Werror flag as some files just cannot be
1589     # compiled with it enabled.
1590     for w in ${build_warnings}; do
1591         case $w in
1592         -Werr*) WERROR_CFLAGS=-Werror ;;
1593         *) # Check that GCC accepts it
1594             saved_CFLAGS="$CFLAGS"
1595             CFLAGS="$CFLAGS $w"
1596             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1597             CFLAGS="$saved_CFLAGS"
1598         esac
1599     done
1600     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1601 fi
1602 AC_SUBST(WARN_CFLAGS)
1603 AC_SUBST(WERROR_CFLAGS)
1604
1605 # In the Cygwin environment, we need some additional flags.
1606 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1607 [AC_EGREP_CPP(lose, [
1608 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1609 lose
1610 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1611
1612
1613 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1614 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1615 case ${host} in
1616   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1617   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1618   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1619 esac
1620 AC_SUBST(SER_HARDWIRE)
1621
1622 # libreadline needs libuser32.a in a cygwin environment
1623 WIN32LIBS=
1624 if test x$gdb_cv_os_cygwin = xyes; then
1625     WIN32LIBS="-luser32"
1626     case "${target}" in
1627         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1628         ;;
1629     esac
1630 fi
1631
1632 # The ser-tcp.c module requires sockets.
1633 case ${host} in
1634   *mingw32*)
1635     AC_DEFINE(USE_WIN32API, 1,
1636               [Define if we should use the Windows API, instead of the
1637                POSIX API.  On Windows, we use the Windows API when
1638                building for MinGW, but the POSIX API when building
1639                for Cygwin.])
1640     WIN32LIBS="$WIN32LIBS -lws2_32"
1641     ;;
1642 esac
1643 AC_SUBST(WIN32LIBS)
1644
1645 # Add ELF support to GDB, but only if BFD includes ELF support.
1646 OLD_CFLAGS=$CFLAGS
1647 OLD_LDFLAGS=$LDFLAGS
1648 OLD_LIBS=$LIBS
1649 CFLAGS="$CFLAGS -I${srcdir}/../include -I../bfd -I${srcdir}/../bfd"
1650 LDFLAGS="$LDFLAGS -L../bfd -L../libiberty"
1651 intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'`
1652 LIBS="-lbfd -liberty $intl $LIBS"
1653 AC_CACHE_CHECK([for ELF support in BFD], gdb_cv_var_elf,
1654 [AC_TRY_LINK(
1655 [#include <stdlib.h>
1656 #include "bfd.h"
1657 #include "elf-bfd.h"
1658 ],
1659 [bfd *abfd = NULL; bfd_get_elf_phdr_upper_bound (abfd); ],
1660 gdb_cv_var_elf=yes, gdb_cv_var_elf=no)])
1661 if test $gdb_cv_var_elf = yes; then
1662   CONFIG_OBS="$CONFIG_OBS elfread.o"
1663   AC_DEFINE(HAVE_ELF, 1,
1664             [Define if ELF support should be included.])
1665 fi
1666 CFLAGS=$OLD_CFLAGS
1667 LDFLAGS=$OLD_LDFLAGS
1668 LIBS=$OLD_LIBS
1669
1670 # Add any host-specific objects to GDB.
1671 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1672
1673 LIBGUI="../libgui/src/libgui.a"
1674 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1675 AC_SUBST(LIBGUI)
1676 AC_SUBST(GUI_CFLAGS_X)
1677
1678 WIN32LDAPP=
1679 AC_SUBST(WIN32LIBS)
1680 AC_SUBST(WIN32LDAPP)
1681
1682 case "${host}" in
1683 *-*-cygwin* | *-*-mingw* )
1684     configdir="win"
1685     ;;
1686 *)
1687     configdir="unix"
1688     ;;
1689 esac
1690
1691 GDBTKLIBS=
1692 if test "${enable_gdbtk}" = "yes"; then
1693
1694     # Gdbtk must have an absolute path to srcdir in order to run
1695     # properly when not installed.
1696     here=`pwd`
1697     cd ${srcdir}
1698     GDBTK_SRC_DIR=`pwd`
1699     cd $here
1700
1701     SC_PATH_TCLCONFIG
1702     if test -z "${no_tcl}"; then
1703         SC_LOAD_TCLCONFIG
1704
1705         # Check for in-tree tcl
1706         here=`pwd`
1707         cd ${srcdir}/..
1708         topdir=`pwd`
1709         cd ${here}
1710
1711         intree="no"
1712         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
1713           intree="yes"
1714         fi
1715
1716         # Find Tcl private headers
1717         if test x"${intree}" = xno; then
1718           CY_AC_TCL_PRIVATE_HEADERS
1719           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
1720           TCL_LIBRARY="${TCL_LIB_SPEC}"
1721           TCL_DEPS=""
1722         else
1723           # If building tcl in the same src tree, private headers
1724           # are not needed, but we need to be sure to use the right
1725           # headers library
1726           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
1727           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
1728           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
1729         fi
1730         AC_SUBST(TCL_INCLUDE)
1731         AC_SUBST(TCL_LIBRARY)
1732         AC_SUBST(TCL_DEPS)
1733
1734         # If $no_tk is nonempty, then we can't do Tk, and there is no
1735         # point to doing Tcl.
1736         if test -z "${no_tk}"; then
1737            SC_PATH_TKCONFIG
1738            SC_LOAD_TKCONFIG
1739
1740            # Check for in-tree Tk
1741            intree="no"
1742            if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
1743              intree="yes"
1744            fi
1745
1746            # Find Tk private headers
1747            if test x"${intree}" = xno; then
1748              CY_AC_TK_PRIVATE_HEADERS
1749              TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
1750              TK_LIBRARY=${TK_LIB_SPEC}
1751              TK_DEPS=""
1752            else
1753              TK_INCLUDE="-I${TK_SRC_DIR}/generic"
1754              TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
1755              TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
1756            fi
1757            AC_SUBST(TK_INCLUDE)
1758            AC_SUBST(TK_LIBRARY)
1759            AC_SUBST(TK_DEPS)
1760            AC_SUBST(TK_XINCLUDES)
1761
1762            ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1763
1764            # Include some libraries that Tcl and Tk want.
1765            TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1766            # Yes, the ordering seems wrong here.  But it isn't.
1767            # TK_LIBS is the list of libraries that need to be linked
1768            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1769            # were in LIBS then any link tests after this point would
1770            # try to include things like `$(LIBGUI)', which wouldn't work.
1771            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1772
1773            CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1774            CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1775            CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1776            CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
1777            CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
1778            CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
1779            CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
1780
1781            if test x$gdb_cv_os_cygwin = xyes; then
1782               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1783               WIN32LDAPP="-Wl,--subsystem,console"
1784               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1785            fi
1786         fi
1787     fi
1788
1789     AC_CONFIG_SUBDIRS(gdbtk)
1790 fi
1791
1792 AC_SUBST(X_CFLAGS)
1793 AC_SUBST(X_LDFLAGS)
1794 AC_SUBST(X_LIBS)
1795 AC_SUBST(GDBTKLIBS)
1796 AC_SUBST(GDBTK_CFLAGS)
1797 AC_SUBST(GDBTK_SRC_DIR)
1798
1799 AC_PATH_X
1800
1801 # Unlike the sim directory, whether a simulator is linked is controlled by
1802 # presence of a gdb_sim definition in the target configure.tgt entry.
1803 # This code just checks for a few cases where we'd like to ignore those
1804 # definitions, even when they're present in the '.mt' file.  These cases
1805 # are when --disable-sim is specified, or if the simulator directory is
1806 # not part of the source tree.
1807 #
1808 AC_ARG_ENABLE(sim,
1809 [  --enable-sim            Link gdb with simulator],
1810 [echo "enable_sim = $enable_sim";
1811  echo "enableval = ${enableval}";
1812  case "${enableval}" in
1813   yes) ignore_sim=false ;;
1814   no)  ignore_sim=true ;;
1815   *)   ignore_sim=false ;;
1816  esac],
1817 [ignore_sim=false])
1818
1819 if test ! -d "${srcdir}/../sim"; then
1820   ignore_sim=true
1821 fi
1822
1823 SIM=
1824 SIM_OBS=
1825 if test "${ignore_sim}" = "false"; then
1826   if test x"${gdb_sim}" != x ; then
1827     SIM="${gdb_sim}"
1828     SIM_OBS="remote-sim.o"
1829     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
1830   fi
1831 fi
1832 AC_SUBST(SIM)
1833 AC_SUBST(SIM_OBS)
1834
1835 AC_SUBST(ENABLE_CFLAGS)
1836 AC_SUBST(PROFILE_CFLAGS)
1837
1838 AC_SUBST(CONFIG_OBS)
1839 AC_SUBST(CONFIG_DEPS)
1840 AC_SUBST(CONFIG_SRCS)
1841 AC_SUBST(CONFIG_ALL)
1842 AC_SUBST(CONFIG_CLEAN)
1843 AC_SUBST(CONFIG_INSTALL)
1844 AC_SUBST(CONFIG_UNINSTALL)
1845
1846 # List of host floatformats.
1847 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
1848 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
1849 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
1850
1851 # target_subdir is used by the testsuite to find the target libraries.
1852 target_subdir=
1853 if test "${host}" != "${target}"; then
1854     target_subdir="${target_alias}/"
1855 fi
1856 AC_SUBST(target_subdir)
1857
1858 frags=
1859 if test "${gdb_native}" = "yes"; then
1860   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
1861   if test ! -f ${host_makefile_frag}; then
1862     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
1863   fi
1864   frags="$frags $host_makefile_frag"
1865 else
1866   host_makefile_frag=/dev/null
1867 fi
1868
1869 AC_SUBST_FILE(host_makefile_frag)
1870 AC_SUBST(frags)
1871
1872 changequote(,)dnl
1873 if test "${gdb_native}" = "yes"; then
1874 # We pick this up from the host configuration file (.mh) because we
1875 # do not have a native configuration Makefile fragment.
1876 nativefile=`sed -n '
1877 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
1878 ' ${host_makefile_frag}`
1879 fi
1880 changequote([,])
1881
1882 if test x"${gdb_osabi}" != x ; then
1883     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
1884                        [Define to the default OS ABI for this configuration.])
1885 fi
1886
1887 # Enable multi-ice-gdb-server.
1888 AC_ARG_ENABLE(multi-ice,
1889 [  --enable-multi-ice      build the multi-ice-gdb-server],
1890   [case $enableval in
1891     yes | no)
1892       ;;
1893     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
1894   esac])
1895 if test "x$enable_multi_ice" = xyes; then
1896    AC_CONFIG_SUBDIRS(multi-ice)
1897 fi
1898
1899 # We only build gdbserver automatically in a native configuration.
1900 if test "$gdb_native" = "yes"; then
1901   AC_MSG_CHECKING(whether gdbserver is supported on this host)
1902   if test "x$build_gdbserver" = xyes; then
1903     AC_MSG_RESULT(yes)
1904     AC_CONFIG_SUBDIRS(gdbserver)
1905   else
1906     AC_MSG_RESULT(no)
1907   fi
1908 fi
1909
1910 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
1911 # to an empty version.
1912
1913 files=
1914 links=
1915
1916 rm -f nm.h
1917 nm_h=""
1918 if test "${nativefile}" != ""; then
1919     nm_h=nm.h
1920     case "${nativefile}" in
1921       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
1922       * ) GDB_NM_FILE="${nativefile}"
1923     esac
1924     files="${files} ${GDB_NM_FILE}"
1925     links="${links} nm.h"
1926     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
1927 fi
1928 AC_SUBST(nm_h)
1929
1930 AC_LINK_FILES($files, $links)
1931
1932 dnl Check for exe extension set on certain hosts (e.g. Win32)
1933 AC_EXEEXT
1934
1935 dnl  Detect the character set used by this host.
1936
1937 dnl  At the moment, we just assume it's ISO-8859-1 (which is a
1938 dnl  superset of ASCII containing the characters needed for French,
1939 dnl  German, Spanish, Italian, and possibly others), but if were
1940 dnl  *were* to support any host character sets other than ISO-8859-1,
1941 dnl  here's where we'd detect it.
1942 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "ISO-8859-1",
1943           [Define to be a string naming the default host character set.])
1944
1945 AM_ICONV
1946
1947 AC_OUTPUT(Makefile .gdbinit:gdbinit.in gnulib/Makefile,
1948 [
1949 dnl Autoconf doesn't provide a mechanism for modifying definitions
1950 dnl provided by makefile fragments.
1951 dnl
1952
1953 changequote(,)dnl
1954 sed -e '/^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
1955 mv -f Makefile.tmp Makefile
1956 changequote([,])dnl
1957
1958
1959 case x$CONFIG_HEADERS in
1960 xconfig.h:config.in)
1961 echo > stamp-h ;;
1962 esac
1963 ],
1964 [
1965 gdb_host_cpu=$gdb_host_cpu
1966 nativefile=$nativefile
1967 ])
1968
1969 exit 0