gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2021 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_INIT
  22 AC_CONFIG_MACRO_DIRS([../config])
  23 AC_CONFIG_SRCDIR([main.c])
  24 AC_CONFIG_HEADERS(config.h:config.in, [echo > stamp-h])
  25 AM_MAINTAINER_MODE
  26
  27 AC_PROG_CC
  28 AC_PROG_CXX
  29
  30 AC_USE_SYSTEM_EXTENSIONS
  31 ACX_LARGEFILE
  32 AM_PROG_INSTALL_STRIP
  33
  34 AC_CONFIG_AUX_DIR(..)
  35
  36 # Set build, build_cpu, build_vendor and build_os.
  37 AC_CANONICAL_BUILD
  38
  39 # Set host, host_cpu, host_vendor, and host_os.
  40 AC_CANONICAL_HOST
  41
  42 # Set target, target_cpu, target_vendor, and target_os.
  43 AC_CANONICAL_TARGET
  44
  45 ACX_NONCANONICAL_TARGET
  46
  47 AC_ARG_PROGRAM
  48
  49 # We require a C++11 compiler.  Check if one is available, and if
  50 # necessary, set CXX_DIALECT to some -std=xxx switch.
  51 AX_CXX_COMPILE_STDCXX(11, , mandatory)
  52
  53 # Dependency checking.
  54 ZW_CREATE_DEPDIR
  55 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  56
  57 dnl List of object files and targets accumulated by configure.
  58
  59 CONFIG_OBS=
  60 CONFIG_DEPS=
  61 CONFIG_SRCS=
  62 ENABLE_CFLAGS=
  63
  64 CONFIG_ALL=
  65 CONFIG_CLEAN=
  66 CONFIG_INSTALL=
  67 CONFIG_UNINSTALL=
  68
  69 dnl Set up for gettext.
  70 ZW_GNU_GETTEXT_SISTER_DIR
  71
  72 localedir='${datadir}/locale'
  73 AC_SUBST(localedir)
  74
  75 if test x"$USE_NLS" = xyes; then
  76    CONFIG_ALL="$CONFIG_ALL all-po"
  77    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  78    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  79    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  80 fi
  81
  82 PACKAGE=gdb
  83 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  84 AC_SUBST(PACKAGE)
  85
  86 # We never need to detect it in this sub-configure.
  87 # But preserve it for config.status --recheck.
  88 AC_ARG_VAR(MAKEINFO,
  89   [Parent configure detects if it is of sufficient version.])
  90 AC_ARG_VAR(MAKEINFOFLAGS,
  91   [Parameters for MAKEINFO.])
  92
  93 MAKEINFO_EXTRA_FLAGS=""
  94 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
  95   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
  96   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
  97     gdb_cv_have_makeinfo_click=yes
  98   else
  99     gdb_cv_have_makeinfo_click=no
 100   fi])
 101 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 102   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 103 fi
 104 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 105
 106 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 107     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 108     [${libdir}/debug])
 109
 110 # We can't pass paths as command line arguments.
 111 # Mingw32 tries to be clever and will convert the paths for us.
 112 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 113 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 114 # This breaks GDB's relocatable path conversions since paths passed in
 115 # config.h would not get so translated, the path prefixes no longer match.
 116 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 117
 118 # GDB's datadir relocation
 119
 120 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 121     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 122     [${datadir}/gdb])
 123
 124 AC_ARG_WITH(relocated-sources,
 125 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 126 [reloc_srcdir="${withval}"
 127  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 128               [Relocated directory for source files. ])
 129 ])
 130
 131 AC_MSG_CHECKING([for default auto-load directory])
 132 AC_ARG_WITH(auto-load-dir,
 133 AS_HELP_STRING([--with-auto-load-dir=PATH],
 134   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 135   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 136 escape_dir=`echo $with_auto_load_dir | sed -e 's/[[$]]datadir\>/\\\\\\\\\\\\&/g' -e 's/[[$]]debugdir\>/\\\\\\\\\\\\&/g'`
 137 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 138               [Directories from which to load auto-loaded scripts.])
 139 AC_MSG_RESULT([$with_auto_load_dir])
 140
 141 AC_MSG_CHECKING([for default auto-load safe-path])
 142 AC_ARG_WITH(auto-load-safe-path,
 143 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 144   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 145 AS_HELP_STRING([--without-auto-load-safe-path],
 146                [do not restrict auto-loaded files locations]),
 147     [if test "$with_auto_load_safe_path" = "no"; then
 148      with_auto_load_safe_path="/"
 149      fi],
 150 [with_auto_load_safe_path="$with_auto_load_dir"])
 151 escape_dir=`echo $with_auto_load_safe_path | sed -e 's/[[$]]datadir\>/\\\\\\\\\\\\&/g' -e 's/[[$]]debugdir\>/\\\\\\\\\\\\&/g'`
 152 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 153               [Directories safe to hold auto-loaded files.])
 154 AC_MSG_RESULT([$with_auto_load_safe_path])
 155
 156 AC_CONFIG_SUBDIRS(testsuite)
 157
 158 # Check whether to support alternative target configurations
 159 AC_ARG_ENABLE(targets,
 160 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 161 [case "${enableval}" in
 162   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
 163             ;;
 164   no)       enable_targets= ;;
 165   *)        enable_targets=$enableval ;;
 166 esac])
 167
 168 # Check whether to enable 64-bit support on 32-bit hosts
 169 AC_ARG_ENABLE(64-bit-bfd,
 170 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 171 [case "${enableval}" in
 172   yes)  want64=true  ;;
 173   no)   want64=false ;;
 174   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 175 esac],[want64=false])dnl
 176
 177 # Provide defaults for some variables set by the per-host and per-target
 178 # configuration.
 179 gdb_host_obs=posix-hdep.o
 180
 181 if test "${target}" = "${host}"; then
 182   gdb_native=yes
 183 else
 184   gdb_native=no
 185 fi
 186
 187 . $srcdir/configure.host
 188
 189 # Accumulate some settings from configure.tgt over all enabled targets
 190
 191 TARGET_OBS=
 192 all_targets=
 193 HAVE_NATIVE_GCORE_TARGET=
 194
 195 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 196 do
 197   if test "$targ_alias" = "all"; then
 198     all_targets=true
 199   else
 200     # Canonicalize the secondary target names.
 201     result=`$ac_config_sub $targ_alias 2>/dev/null`
 202     if test -n "$result"; then
 203         targ=$result
 204     else
 205         targ=$targ_alias
 206     fi
 207
 208     . ${srcdir}/configure.tgt
 209
 210     AS_IF([test -z "${gdb_target_obs}"],
 211       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 212
 213     # Target-specific object files
 214     for i in ${gdb_target_obs}; do
 215         case " $TARGET_OBS " in
 216         *" ${i} "*) ;;
 217         *)
 218           TARGET_OBS="$TARGET_OBS ${i}"
 219           ;;
 220         esac
 221     done
 222
 223     # Check whether this target needs 64-bit CORE_ADDR
 224     if test x${want64} = xfalse; then
 225       . ${srcdir}/../bfd/config.bfd
 226     fi
 227
 228     # Check whether this target is native and supports gcore.
 229     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 230        && $gdb_have_gcore; then
 231       HAVE_NATIVE_GCORE_TARGET=1
 232     fi
 233   fi
 234 done
 235
 236 if test x${all_targets} = xtrue; then
 237
 238   # We want all 64-bit targets if we either:
 239   #  - run on a 64-bit host  or
 240   #  - already require 64-bit support for some other target  or
 241   #  - the --enable-64-bit-bfd option was supplied
 242   # Otherwise we only support all 32-bit targets.
 243   #
 244   # NOTE: This test must be in sync with the corresponding
 245   #       tests in BFD!
 246
 247   if test x${want64} = xfalse; then
 248     AC_CHECK_SIZEOF(long)
 249     if test "x${ac_cv_sizeof_long}" = "x8"; then
 250       want64=true
 251     fi
 252   fi
 253   if test x${want64} = xtrue; then
 254     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 255   else
 256     TARGET_OBS='$(ALL_TARGET_OBS)'
 257   fi
 258 fi
 259
 260 AC_SUBST(TARGET_OBS)
 261 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 262
 263 # For other settings, only the main target counts.
 264 gdb_sim=
 265 gdb_osabi=
 266 targ=$target; . ${srcdir}/configure.tgt
 267
 268 # Fetch the default architecture and default target vector from BFD.
 269 targ=$target; . $srcdir/../bfd/config.bfd
 270
 271 # We only want the first architecture, so strip off the others if
 272 # there is more than one.
 273 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 274
 275 if test "x$targ_archs" != x; then
 276   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 277     [Define to BFD's default architecture. ])
 278 fi
 279 if test "x$targ_defvec" != x; then
 280   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 281     [Define to BFD's default target vector. ])
 282 fi
 283
 284 # Enable MI.
 285 AC_ARG_ENABLE(gdbmi,
 286 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 287   [case $enableval in
 288     yes | no)
 289       ;;
 290     *)
 291       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 292   esac],
 293   [enable_gdbmi=yes])
 294 if test x"$enable_gdbmi" = xyes; then
 295   if test -d "$srcdir/mi"; then
 296     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 297     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 298     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 299     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 300   fi
 301 fi
 302
 303 # Enable TUI.
 304 AC_ARG_ENABLE(tui,
 305 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 306   [case $enableval in
 307     yes | no | auto)
 308       ;;
 309     *)
 310       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 311   esac],enable_tui=auto)
 312
 313 # Enable gdbtk.
 314 AC_ARG_ENABLE(gdbtk,
 315 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 316   [case $enableval in
 317     yes | no)
 318       ;;
 319     *)
 320       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 321   esac],
 322   [if test -d "$srcdir/gdbtk"; then
 323     enable_gdbtk=yes
 324   else
 325     enable_gdbtk=no
 326   fi])
 327 # We unconditionally disable gdbtk tests on selected platforms.
 328 case $host_os in
 329   go32* | windows*)
 330     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 331     enable_gdbtk=no ;;
 332 esac
 333
 334 # Handle optional debuginfod support
 335 AC_DEBUGINFOD
 336
 337 # Libunwind support for ia64.
 338 AC_ARG_WITH(libunwind-ia64,
 339 AS_HELP_STRING([--with-libunwind-ia64],
 340                [use libunwind frame unwinding for ia64 targets]),,
 341             [with_libunwind_ia64=auto])
 342
 343 # Backward compatibility option.
 344 if test "${with_libunwind+set}" = set; then
 345   if test x"$with_libunwind_ia64" != xauto; then
 346     AC_MSG_ERROR(
 347       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 348   fi
 349   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 350   with_libunwind_ia64="$with_libunwind"
 351 fi
 352
 353 case "$with_libunwind_ia64" in
 354   yes | no)
 355     ;;
 356   auto)
 357     AC_CHECK_HEADERS(libunwind-ia64.h)
 358     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 359     ;;
 360   *)
 361     AC_MSG_ERROR(
 362       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 363     ;;
 364 esac
 365
 366 if test x"$with_libunwind_ia64" = xyes; then
 367   AC_CHECK_HEADERS(libunwind-ia64.h)
 368   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 369     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 370   fi
 371   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 372   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 373   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 374 fi
 375
 376 opt_curses=no
 377 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 378
 379 prefer_curses=no
 380 if test "$opt_curses" = "yes"; then
 381   prefer_curses=yes
 382 fi
 383
 384 # Profiling support.
 385 AC_ARG_ENABLE(profiling,
 386 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 387   [case $enableval in
 388     yes | no)
 389       ;;
 390     *)
 391       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 392   esac],
 393  [enable_profiling=no])
 394
 395 AC_CHECK_FUNCS(monstartup _mcleanup)
 396 AC_CACHE_CHECK(
 397   [for _etext],
 398   [ac_cv_var__etext],
 399   [AC_LINK_IFELSE(
 400      [AC_LANG_PROGRAM(
 401         [#include <stdlib.h>
 402          extern char _etext;],
 403         [free (&_etext);]
 404       )],
 405      [ac_cv_var__etext=yes],
 406      [ac_cv_var__etext=no]
 407    )]
 408 )
 409 if test "$ac_cv_var__etext" = yes; then
 410   AC_DEFINE(HAVE__ETEXT, 1,
 411             [Define to 1 if your system has the _etext variable. ])
 412 fi
 413 AC_CACHE_CHECK(
 414   [for etext],
 415   [ac_cv_var_etext],
 416   [AC_LINK_IFELSE(
 417      [AC_LANG_PROGRAM(
 418         [#include <stdlib.h>
 419          extern char etext;],
 420         [free (&etext);]
 421       )],
 422      [ac_cv_var_etext=yes],
 423      [ac_cv_var_etext=no]
 424    )]
 425 )
 426 if test "$ac_cv_var_etext" = yes; then
 427   AC_DEFINE(HAVE_ETEXT, 1,
 428             [Define to 1 if your system has the etext variable. ])
 429 fi
 430 if test "$enable_profiling" = yes ; then
 431   if test "$ac_cv_func_monstartup" = no || test "$ac_cv_func__mcleanup" = no; then
 432     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 433   fi
 434   PROFILE_CFLAGS=-pg
 435   OLD_CFLAGS="$CFLAGS"
 436   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 437
 438   AC_CACHE_CHECK(
 439     [whether $CC supports -pg],
 440     [ac_cv_cc_supports_pg],
 441     [AC_COMPILE_IFELSE(
 442        [AC_LANG_PROGRAM([], [int x;])],
 443        [ac_cv_cc_supports_pg=yes],
 444        [ac_cv_cc_supports_pg=no]
 445      )]
 446   )
 447
 448   if test "$ac_cv_cc_supports_pg" = no; then
 449     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 450   fi
 451
 452   CFLAGS="$OLD_CFLAGS"
 453 fi
 454
 455 CODESIGN_CERT=
 456 AC_ARG_ENABLE([codesign],
 457   AS_HELP_STRING([--enable-codesign=CERT],
 458                  [sign gdb with 'codesign -s CERT']),
 459   [CODESIGN_CERT=$enableval])
 460 AC_SUBST([CODESIGN_CERT])
 461
 462 ACX_PKGVERSION([GDB])
 463 ACX_BUGURL([https://www.gnu.org/software/gdb/bugs/])
 464 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 465 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 466
 467 # --------------------- #
 468 # Checks for programs.  #
 469 # --------------------- #
 470
 471 AC_PROG_AWK
 472 AC_PROG_INSTALL
 473 AC_PROG_LN_S
 474 AC_PROG_RANLIB
 475 AC_PROG_YACC
 476
 477 AC_CHECK_TOOL(AR, ar)
 478 AC_CHECK_TOOL(DLLTOOL, dlltool)
 479 AC_CHECK_TOOL(WINDRES, windres)
 480
 481 case $host_os in
 482   gnu*)
 483     # Needed for GNU Hurd hosts.
 484     AC_CHECK_TOOL(MIG, mig)
 485     if test x"$MIG" = x; then
 486       AC_MSG_ERROR([MIG not found but required for $host hosts])
 487     fi
 488     ;;
 489 esac
 490
 491 # ---------------------- #
 492 # Checks for libraries.  #
 493 # ---------------------- #
 494
 495 # We might need to link with -lm; most simulators need it.
 496 AC_CHECK_LIB(m, main)
 497
 498 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 499 AC_SEARCH_LIBS(gethostbyname, nsl)
 500
 501 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 502 AC_SEARCH_LIBS(socketpair, socket)
 503
 504 # Link in zlib if we can.  This allows us to read compressed debug sections.
 505 AM_ZLIB
 506
 507 AM_ICONV
 508
 509 # GDB may fork/exec the iconv program to get the list of supported character
 510 # sets.  Allow the user to specify where to find it.
 511 # There are several factors affecting the choice of option name:
 512 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 513 #   the build-time location of libiconv files.
 514 # - The program we need to find is iconv, which comes with glibc.  The user
 515 #   doesn't necessarily have libiconv installed.  Therefore naming this
 516 #   --with-libiconv-foo feels wrong.
 517 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 518 #   defined to work on directories not files (though it really doesn't know
 519 #   the difference).
 520 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 521 #   with --with-libiconv-prefix.
 522 # Putting these together is why the option name is --with-iconv-bin.
 523
 524 AC_ARG_WITH(iconv-bin,
 525 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 526 [iconv_bin="${withval}"
 527  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 528                     [Path of directory of iconv program.])
 529  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 530 ])
 531
 532 # For the TUI, we need enhanced curses functionality.
 533 if test x"$enable_tui" != xno; then
 534   prefer_curses=yes
 535 fi
 536
 537 curses_found=no
 538 if test x"$prefer_curses" = xyes; then
 539   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 540   # curses library because the latter might not provide all the
 541   # functionality we need.  However, this leads to problems on systems
 542   # where the linker searches /usr/local/lib, but the compiler doesn't
 543   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 544   # default installation of ncurses on alpha*-dec-osf* will lead to such
 545   # a situation.
 546   AC_SEARCH_LIBS(waddstr, [ncursesw ncurses cursesX curses])
 547
 548   if test "$ac_cv_search_waddstr" != no; then
 549     curses_found=yes
 550   fi
 551 fi
 552
 553 # Check whether we should enable the TUI, but only do so if we really
 554 # can.
 555 if test x"$enable_tui" != xno; then
 556   if test -d "$srcdir/tui"; then
 557     if test "$curses_found" != no; then
 558       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 559       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 560       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 561       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 562     else
 563       if test x"$enable_tui" = xyes; then
 564         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 565       else
 566         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 567       fi
 568     fi
 569   fi
 570 fi
 571
 572 # Since GDB uses Readline, we need termcap functionality.  In many
 573 # cases this will be provided by the curses library, but some systems
 574 # have a separate termcap library, or no curses library at all.
 575
 576 case $host_os in
 577   cygwin*)
 578     if test -d "$srcdir/libtermcap"; then
 579       LIBS="../libtermcap/libtermcap.a $LIBS"
 580       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 581     fi ;;
 582   go32* | *djgpp*)
 583     ac_cv_search_tgetent="none required"
 584     ;;
 585 esac
 586
 587 # These are the libraries checked by Readline.
 588 AC_SEARCH_LIBS(tgetent, [termcap tinfow tinfo curses ncursesw ncurses])
 589
 590 if test "$ac_cv_search_tgetent" = no; then
 591   CONFIG_OBS="$CONFIG_OBS stub-termcap.o"
 592 fi
 593
 594 AC_ARG_WITH([system-readline],
 595   [AS_HELP_STRING([--with-system-readline],
 596                   [use installed readline library])])
 597
 598 if test "$with_system_readline" = yes; then
 599   AC_CHECK_HEADERS(readline/readline.h, [readline_h=yes], [readline_h=no])
 600   if test "$readline_h" = "no"; then
 601     AC_MSG_ERROR([readline development packages are probably missing])
 602   fi
 603   AC_CACHE_CHECK(
 604     [whether system readline is new enough],
 605     [gdb_cv_readline_ok],
 606     [AC_COMPILE_IFELSE(
 607        [AC_LANG_PROGRAM(
 608           [#include <stdio.h>
 609            #include <readline/readline.h>],
 610           [#if RL_VERSION_MAJOR < 7
 611            # error "readline version 7 required"
 612            #endif]
 613         )],
 614        [gdb_cv_readline_ok=yes],
 615        [gdb_cv_readline_ok=no]
 616      )]
 617   )
 618   if test "$gdb_cv_readline_ok" != yes; then
 619     AC_MSG_ERROR([system readline is not new enough])
 620   fi
 621
 622   READLINE=-lreadline
 623   READLINE_DEPS=
 624   READLINE_CFLAGS=
 625   READLINE_TEXI_INCFLAG=
 626 else
 627   READLINE='$(READLINE_DIR)/libreadline.a'
 628   READLINE_DEPS='$(READLINE)'
 629   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 630   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 631 fi
 632 AC_SUBST(READLINE)
 633 AC_SUBST(READLINE_DEPS)
 634 AC_SUBST(READLINE_CFLAGS)
 635 AC_SUBST(READLINE_TEXI_INCFLAG)
 636
 637 # Generate jit-reader.h
 638
 639 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 640 TARGET_PTR=
 641
 642 AC_CHECK_SIZEOF(unsigned long long)
 643 AC_CHECK_SIZEOF(unsigned long)
 644 AC_CHECK_SIZEOF(unsigned __int128)
 645
 646 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 647   TARGET_PTR="unsigned long"
 648 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 649   TARGET_PTR="unsigned long long"
 650 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 651   TARGET_PTR="unsigned __int128"
 652 else
 653   TARGET_PTR="unsigned long"
 654 fi
 655
 656 AC_SUBST(TARGET_PTR)
 657 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 658
 659 AC_SEARCH_LIBS(dlopen, dl)
 660
 661 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 662                 [directory to load the JIT readers from],
 663                 [${libdir}/gdb])
 664
 665 AC_ARG_WITH(expat,
 666   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 667   [], [with_expat=auto])
 668 AC_MSG_CHECKING([whether to use expat])
 669 AC_MSG_RESULT([$with_expat])
 670
 671 if test "${with_expat}" = no; then
 672   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 673   HAVE_LIBEXPAT=no
 674 else
 675   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 676                         [XML_Parser p = XML_ParserCreate (0);])
 677   if test "$HAVE_LIBEXPAT" != yes; then
 678     if test "$with_expat" = yes; then
 679       AC_MSG_ERROR([expat is missing or unusable])
 680     else
 681       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 682     fi
 683   else
 684     save_LIBS=$LIBS
 685     LIBS="$LIBS $LIBEXPAT"
 686     AC_CHECK_FUNCS(XML_StopParser)
 687     LIBS=$save_LIBS
 688   fi
 689 fi
 690
 691 # Verify that we have a usable GMP library.
 692 AC_LIB_HAVE_LINKFLAGS([gmp], [], [#include <gmp.h>],
 693                       [mpz_t n;
 694                        mpz_init (n);])
 695 if test "$HAVE_LIBGMP" != yes; then
 696   AC_MSG_ERROR([GMP is missing or unusable])
 697 fi
 698
 699 AC_ARG_WITH(mpfr,
 700   AS_HELP_STRING([--with-mpfr], [include MPFR support (auto/yes/no)]),
 701   [], [with_mpfr=auto])
 702 AC_MSG_CHECKING([whether to use MPFR])
 703 AC_MSG_RESULT([$with_mpfr])
 704
 705 if test "${with_mpfr}" = no; then
 706   AC_MSG_WARN([MPFR support disabled; some features may be unavailable.])
 707   HAVE_LIBMPFR=no
 708 else
 709   AC_LIB_HAVE_LINKFLAGS([mpfr], [gmp], [#include <mpfr.h>],
 710                         [mpfr_exp_t exp; mpfr_t x;
 711                          mpfr_frexp (&exp, x, x, MPFR_RNDN);])
 712   if test "$HAVE_LIBMPFR" != yes; then
 713     if test "$with_mpfr" = yes; then
 714       AC_MSG_ERROR([MPFR is missing or unusable])
 715     else
 716       AC_MSG_WARN([MPFR is missing or unusable; some features may be unavailable.])
 717     fi
 718   fi
 719 fi
 720
 721 # --------------------- #
 722 # Check for libpython.  #
 723 # --------------------- #
 724
 725 dnl Utility to simplify finding libpython.
 726 dnl $1 = the shell variable to assign the result to
 727 dnl      If libpython is found we store $version here.
 728 dnl $2 = additional flags to add to CPPFLAGS
 729 dnl $3 = additional flags to add to LIBS
 730
 731 AC_DEFUN([AC_TRY_LIBPYTHON],
 732 [
 733   define([have_libpython_var],$1)
 734   new_CPPFLAGS=$2
 735   new_LIBS=$3
 736   AC_MSG_CHECKING([for python])
 737   save_CPPFLAGS=$CPPFLAGS
 738   save_LIBS=$LIBS
 739   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 740   LIBS="$new_LIBS $LIBS"
 741   found_usable_python=no
 742   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "Python.h"]],
 743                                  [[Py_Initialize ();]])],
 744                  [have_libpython_var=yes
 745                   found_usable_python=yes
 746                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 747                   PYTHON_LIBS=$new_LIBS])
 748   CPPFLAGS=$save_CPPFLAGS
 749   LIBS=$save_LIBS
 750   AC_MSG_RESULT([${found_usable_python}])
 751 ])
 752
 753 dnl There are several different values for --with-python:
 754 dnl
 755 dnl no -   Don't include python support.
 756 dnl yes -  Include python support, error if it's missing.
 757 dnl        If we find python in $PATH, use it to fetch configure options,
 758 dnl        otherwise assume the compiler can find it with no help from us.
 759 dnl        Python 2.7 and 2.6 are tried in turn.
 760 dnl auto - Same as "yes", but if python is missing from the system,
 761 dnl        fall back to "no".
 762 dnl /path/to/python/exec-prefix -
 763 dnl        Use the python located in this directory.
 764 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 765 dnl        the compilation parameters.  Otherwise use
 766 dnl        -I/path/to/python/exec-prefix/include,
 767 dnl        -L/path/to/python/exec-prefix/lib.
 768 dnl        Python 2.7 and 2.6 are tried in turn.
 769 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 770 dnl        but is deprecated.
 771 dnl /path/to/python/executable -
 772 dnl        Run python-config.py with this version of python to fetch the
 773 dnl        compilation parameters.
 774 dnl        NOTE: This needn't be the real python executable.
 775 dnl        In a cross-compilation scenario (build != host), this could be
 776 dnl        a shell script that provides what python-config.py provides for
 777 dnl        --ldflags, --includes, --exec-prefix.
 778 dnl python-executable -
 779 dnl        Find python-executable in $PATH, and then handle the same as
 780 dnl        /path/to/python/executable.
 781 dnl
 782 dnl If a python program is specified, it is used to run python-config.py and
 783 dnl is passed --ldflags, --includes, --exec-prefix.
 784
 785 AC_ARG_WITH(python,
 786   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 787   [], [with_python=auto])
 788 AC_MSG_CHECKING([whether to use python])
 789 AC_MSG_RESULT([$with_python])
 790
 791 if test "${with_python}" = no; then
 792   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 793   have_libpython=no
 794 else
 795   case "${with_python}" in
 796   [[\\/]]* | ?:[[\\/]]*)
 797     if test -d "${with_python}"; then
 798       # Assume the python binary is ${with_python}/bin/python.
 799       python_prog="${with_python}/bin/python"
 800       python_prefix=
 801       # If python does not exit ${with_python}/bin, then try in
 802       # ${with_python}.  On Windows/MinGW, this is where the Python
 803       # executable is.
 804       if test ! -x "${python_prog}"; then
 805         python_prog="${with_python}/python"
 806         python_prefix=
 807       fi
 808       if test ! -x "${python_prog}"; then
 809         # Fall back to gdb 7.0/7.1 behaviour.
 810         python_prog=missing
 811         python_prefix=${with_python}
 812       fi
 813     elif test -x "${with_python}"; then
 814       # While we can't run python compiled for $host (unless host == build),
 815       # the user could write a script that provides the needed information,
 816       # so we support that.
 817       python_prog=${with_python}
 818       python_prefix=
 819     else
 820       AC_MSG_ERROR(invalid value for --with-python)
 821     fi
 822     ;;
 823   */*)
 824     # Disallow --with-python=foo/bar.
 825     AC_MSG_ERROR(invalid value for --with-python)
 826     ;;
 827   *)
 828     # The user has either specified auto, yes, or the name of the python
 829     # program assumed to be in $PATH.
 830     python_prefix=
 831     case "${with_python}" in
 832     yes | auto)
 833       if test "${build}" = "${host}"; then
 834         AC_PATH_PROG(python_prog_path, python, missing)
 835         if test "${python_prog_path}" = missing; then
 836           python_prog=missing
 837         else
 838           python_prog=${python_prog_path}
 839         fi
 840       else
 841         # Not much we can do except assume the cross-compiler will find the
 842         # right files.
 843         python_prog=missing
 844       fi
 845       ;;
 846     *)
 847       # While we can't run python compiled for $host (unless host == build),
 848       # the user could write a script that provides the needed information,
 849       # so we support that.
 850       python_prog="${with_python}"
 851       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 852       if test "${python_prog_path}" = missing; then
 853         AC_MSG_ERROR(unable to find python program ${python_prog})
 854       fi
 855       ;;
 856     esac
 857   esac
 858
 859   if test "${python_prog}" != missing; then
 860     # We have a python program to use, but it may be too old.
 861     # Don't flag an error for --with-python=auto (the default).
 862     have_python_config=yes
 863     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 864     if test $? != 0; then
 865       have_python_config=failed
 866       if test "${with_python}" != auto; then
 867         AC_MSG_ERROR(failure running python-config --includes)
 868       fi
 869     fi
 870     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 871     if test $? != 0; then
 872       have_python_config=failed
 873       if test "${with_python}" != auto; then
 874         AC_MSG_ERROR(failure running python-config --ldflags)
 875       fi
 876     fi
 877     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 878     if test $? != 0; then
 879       have_python_config=failed
 880       if test "${with_python}" != auto; then
 881         AC_MSG_ERROR(failure running python-config --exec-prefix)
 882       fi
 883     fi
 884   else
 885     # We do not have a python executable we can use to determine where
 886     # to find the Python headers and libs.  We cannot guess the include
 887     # path from the python_prefix either, because that include path
 888     # depends on the Python version.  So, there is nothing much we can
 889     # do except assume that the compiler will be able to find those files.
 890     python_includes=
 891     python_libs=
 892     have_python_config=no
 893   fi
 894
 895   # If we have python-config, only try the configuration it provides.
 896   # Otherwise fallback on the old way of trying different versions of
 897   # python in turn.
 898
 899   have_libpython=no
 900   if test "${have_python_config}" = yes; then
 901     AC_TRY_LIBPYTHON(have_libpython,
 902                      ${python_includes}, ${python_libs})
 903   elif test "${have_python_config}" != failed; then
 904     if test "${have_libpython}" = no; then
 905       AC_TRY_LIBPYTHON(have_libpython,
 906                        ${python_includes}, "-lpython2.7 ${python_libs}")
 907     fi
 908     if test "${have_libpython}" = no; then
 909       AC_TRY_LIBPYTHON(have_libpython,
 910                        ${python_includes}, "-lpython2.6 ${python_libs}")
 911     fi
 912   fi
 913
 914   if test "${have_libpython}" = no; then
 915     case "${with_python}" in
 916     yes)
 917       AC_MSG_ERROR([python is missing or unusable])
 918       ;;
 919     auto)
 920       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 921       ;;
 922     *)
 923       AC_MSG_ERROR([no usable python found at ${with_python}])
 924       ;;
 925     esac
 926   else
 927     if test -n "${python_prefix}"; then
 928       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 929                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 930       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 931     fi
 932   fi
 933 fi
 934
 935 dnl Use --with-python-libdir to control where GDB looks for the Python
 936 dnl libraries.
 937 dnl
 938 dnl If this is not given then the default will be based on the value
 939 dnl passed to --with-python, which is in the python_prefix variable.
 940 dnl If the --with-python option wasn't given then the default value in
 941 dnl python_prefix is based on running the 'gdb/python/python-config
 942 dnl --exec-prefix' script.
 943 AC_ARG_WITH(python-libdir,
 944   AS_HELP_STRING([--with-python-libdir@<:@=DIR@:>@], [search for python's libraries in DIR]),
 945   [],[
 946     # If no python libdir is specified then select one based on
 947     # python's prefix path.
 948     if test -n "${python_prefix}"; then
 949       with_python_libdir=${python_prefix}/lib
 950     fi
 951   ])
 952
 953 if test "${have_libpython}" != no; then
 954   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 955   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 956   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 957   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 958   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 959   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 960
 961   if test -n "${with_python_libdir}"; then
 962     AC_DEFINE_UNQUOTED(WITH_PYTHON_LIBDIR, "${with_python_libdir}",
 963                        [Directory containing Python's standard libraries from --with-python-libdir.])
 964     GDB_AC_DEFINE_RELOCATABLE(PYTHON_LIBDIR, [python lib], ${with_python_libdir})
 965   fi
 966
 967   # Flags needed to compile Python code (taken from python-config --cflags).
 968   # We cannot call python-config directly because it will output whatever was
 969   # used when compiling the Python interpreter itself, including flags which
 970   # would make the python-related objects be compiled differently from the
 971   # rest of GDB (e.g., -O2 and -fPIC).
 972   if test "${GCC}" = yes; then
 973     tentative_python_cflags="-fno-strict-aliasing -fwrapv"
 974     # Python headers recommend -DNDEBUG, but it's unclear if that just
 975     # refers to building Python itself.  In release mode, though, it
 976     # doesn't hurt for the Python code in gdb to follow.
 977     $development || tentative_python_cflags="$tentative_python_cflags -DNDEBUG"
 978   fi
 979
 980   if test "x${tentative_python_cflags}" != x; then
 981     AC_MSG_CHECKING(compiler flags for python code)
 982     for flag in ${tentative_python_cflags}; do
 983       # Check that the compiler accepts it
 984       saved_CFLAGS="$CFLAGS"
 985       CFLAGS="$CFLAGS $flag"
 986       AC_COMPILE_IFELSE(
 987         [AC_LANG_PROGRAM([], [])],
 988         [PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag"],
 989         []
 990       )
 991       CFLAGS="$saved_CFLAGS"
 992     done
 993     AC_MSG_RESULT(${PYTHON_CFLAGS})
 994   fi
 995
 996   # On x64 Windows, Python's include headers, and pyconfig.h in
 997   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
 998   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
 999   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
1000   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
1001   # The issue was reported to the Python community, but still isn't
1002   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
1003
1004   case "$gdb_host" in
1005     mingw64)
1006            if test "${GCC}" = yes; then
1007              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
1008            fi
1009            ;;
1010   esac
1011 else
1012   # Even if Python support is not compiled in, we need to have this file
1013   # included so that the "python" command, et.al., still exists.
1014   CONFIG_OBS="$CONFIG_OBS python/python.o"
1015   CONFIG_SRCS="$CONFIG_SRCS python/python.c"
1016 fi
1017
1018 # Work around Python http://bugs.python.org/issue10112.  See also
1019 # http://bugs.python.org/issue11410, otherwise -Wl,--dynamic-list has
1020 # no effect.  Note that the only test after this that uses Python is
1021 # the -rdynamic/-Wl,--dynamic-list test, and we do want that one to be
1022 # run without -export-dynamic too.
1023 PYTHON_LIBS=`echo $PYTHON_LIBS | sed -e 's/-Xlinker -export-dynamic//'`
1024
1025 AC_SUBST(PYTHON_CFLAGS)
1026 AC_SUBST(PYTHON_CPPFLAGS)
1027 AC_SUBST(PYTHON_LIBS)
1028 AM_CONDITIONAL(HAVE_PYTHON, test "${have_libpython}" != no)
1029
1030 # -------------------- #
1031 # Check for libguile.  #
1032 # -------------------- #
1033
1034 dnl Utility to simplify finding libguile.
1035 dnl $1 = pkg-config-program
1036 dnl $2 = space-separate list of guile versions to try
1037 dnl $3 = yes|no, indicating whether to flag errors or ignore them
1038 dnl $4 = the shell variable to assign the result to
1039 dnl      If libguile is found we store "yes" here.
1040
1041 AC_DEFUN([AC_TRY_LIBGUILE],
1042 [
1043   pkg_config=$1
1044   guile_version_list=$2
1045   flag_errors=$3
1046   define([have_libguile_var],$4)
1047   found_usable_guile=checking
1048   AC_MSG_CHECKING([for usable guile from ${pkg_config}])
1049   for guile_version in ${guile_version_list}; do
1050     ${pkg_config} --exists ${guile_version} 2>/dev/null
1051     if test $? != 0; then
1052       continue
1053     fi
1054     dnl pkg-config says the package exists, so if we get an error now,
1055     dnl that's bad.
1056     new_CPPFLAGS=`${pkg_config} --cflags ${guile_version}`
1057     if test $? != 0; then
1058       AC_MSG_ERROR([failure running pkg-config --cflags ${guile_version}])
1059     fi
1060     new_LIBS=`${pkg_config} --libs ${guile_version}`
1061     if test $? != 0; then
1062       AC_MSG_ERROR([failure running pkg-config --libs ${guile_version}])
1063     fi
1064     dnl If we get this far, great.
1065     found_usable_guile=${guile_version}
1066     break
1067   done
1068   if test "${found_usable_guile}" = "checking"; then
1069     if test "${flag_errors}" = "yes"; then
1070       AC_MSG_ERROR([unable to find usable guile version from "${guile_version_list}"])
1071     else
1072       found_usable_guile=no
1073     fi
1074   fi
1075   dnl One final sanity check.
1076   dnl The user could have said --with-guile=python-2.7.
1077   if test "${found_usable_guile}" != no; then
1078     save_CPPFLAGS=$CPPFLAGS
1079     save_LIBS=$LIBS
1080     CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
1081     LIBS="$LIBS $new_LIBS"
1082     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "libguile.h"]],
1083                                    [[scm_init_guile ();]])],
1084                    [have_libguile_var=yes
1085                     GUILE_CPPFLAGS=$new_CPPFLAGS
1086                     GUILE_LIBS=$new_LIBS],
1087                    [found_usable_guile=no])
1088     dnl scm_set_automatic_finalization_enabled added in Guile 2.2.
1089     AC_CHECK_FUNC(scm_set_automatic_finalization_enabled,
1090       AC_DEFINE(HAVE_GUILE_MANUAL_FINALIZATION, 1,
1091                 [Define if Guile supports manual finalization.])
1092     )
1093     CPPFLAGS=$save_CPPFLAGS
1094     LIBS=$save_LIBS
1095     if test "${found_usable_guile}" = no; then
1096       if test "${flag_errors}" = yes; then
1097         AC_MSG_FAILURE([linking guile version ${guile_version} test program failed])
1098       fi
1099     fi
1100   fi
1101   AC_MSG_RESULT([${found_usable_guile}])
1102 ])
1103
1104 dnl There are several different values for --with-guile:
1105 dnl
1106 dnl no -   Don't include guile support.
1107 dnl yes -  Include guile support, error if it's missing.
1108 dnl        The pkg-config program must be in $PATH.
1109 dnl auto - Same as "yes", but if guile is missing from the system,
1110 dnl        fall back to "no".
1111 dnl guile-version [guile-version-choice-2 ...] -
1112 dnl        A space-separated list of guile package versions to try.
1113 dnl        These are passed to pkg-config as-is.
1114 dnl        E.g., guile-2.0 or guile-2.2-uninstalled
1115 dnl        This requires making sure PKG_CONFIG_PATH is set appropriately.
1116 dnl /path/to/pkg-config -
1117 dnl        Use this pkg-config program.
1118 dnl        NOTE: This needn't be the "real" pkg-config program.
1119 dnl        It could be a shell script.  It is invoked as:
1120 dnl        pkg-config --exists $version
1121 dnl        pkg-config --cflags $version
1122 dnl        pkg-config --libs $version
1123 dnl        pkg-config --variable guild $version
1124 dnl        The script will be called with $version having each value in
1125 dnl        $try_guile_versions until --exists indicates success.
1126
1127 AC_ARG_WITH(guile,
1128   AS_HELP_STRING([--with-guile@<:@=GUILE@:>@], [include guile support (auto/yes/no/<guile-version>/<pkg-config-program>)]),
1129   [], [with_guile=auto])
1130 AC_MSG_CHECKING([whether to use guile])
1131 AC_MSG_RESULT([$with_guile])
1132
1133 dnl We check guile with pkg-config.
1134 AC_PATH_PROG(pkg_config_prog_path, pkg-config, missing)
1135
1136 try_guile_versions="guile-3.0 guile-2.2 guile-2.0"
1137 have_libguile=no
1138 case "${with_guile}" in
1139 no)
1140   AC_MSG_WARN([guile support disabled; some features will be unavailable.])
1141   ;;
1142 auto)
1143   if test "${pkg_config_prog_path}" = "missing"; then
1144     AC_MSG_WARN([pkg-config not found, guile support disabled])
1145   else
1146     AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, no, have_libguile)
1147   fi
1148   ;;
1149 yes)
1150   if test "${pkg_config_prog_path}" = "missing"; then
1151     AC_MSG_ERROR([pkg-config not found])
1152   fi
1153   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, yes, have_libguile)
1154   ;;
1155 [[\\/]]* | ?:[[\\/]]*)
1156   if test -x "${with_guile}"; then
1157     AC_TRY_LIBGUILE(${with_guile}, ${try_guile_versions}, yes, have_libguile)
1158   else
1159     AC_MSG_ERROR([Guile config program not executable: ${with_guile}])
1160   fi
1161   ;;
1162 "" | */*)
1163   # Disallow --with=guile="" and --with-guile=foo/bar.
1164   AC_MSG_ERROR([invalid value for --with-guile])
1165   ;;
1166 *)
1167   # A space separate list of guile versions to try, in order.
1168   if test "${pkg_config_prog_path}" = "missing"; then
1169     AC_MSG_ERROR([pkg-config not found])
1170   fi
1171   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${with_guile}, yes, have_libguile)
1172   ;;
1173 esac
1174
1175 if test "${have_libguile}" != no; then
1176   dnl Get the name of the 'guild' program.
1177   case "${with_guile}" in
1178   [[\\/]]* | ?:[[\\/]]*)
1179     GDB_GUILE_PROGRAM_NAMES(["${with_guile}"], ["${guile_version}"])
1180     ;;
1181   *)
1182     GDB_GUILE_PROGRAM_NAMES(["${pkg_config_prog_path}"], ["${guile_version}"])
1183     ;;
1184   esac
1185
1186   dnl Make sure guild can handle this host.
1187   GDB_TRY_GUILD([$srcdir/guile/lib/gdb/support.scm])
1188   dnl If not, disable guile support.
1189   if test "$ac_cv_guild_ok" = no; then
1190     have_libguile=no
1191     AC_MSG_WARN(disabling guile support, $GUILD fails compiling for $host)
1192   fi
1193 fi
1194
1195 if test "${have_libguile}" != no; then
1196   AC_DEFINE(HAVE_GUILE, 1, [Define if Guile interpreter is being linked in.])
1197   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_GUILE_OBS)"
1198   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_GUILE_DEPS)"
1199   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_GUILE_SRCS)"
1200   CONFIG_INSTALL="$CONFIG_INSTALL install-guile"
1201   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_GUILE_CFLAGS)"
1202
1203   dnl The 'scm_new_smob' function appeared in Guile 2.0.6.
1204   save_LIBS="$LIBS"
1205   save_CPPFLAGS="$CPPFLAGS"
1206   LIBS="$GUILE_LIBS"
1207   CPPFLAGS="$GUILE_CPPFLAGS"
1208   AC_CHECK_FUNCS([scm_new_smob])
1209   LIBS="$save_LIBS"
1210   CPPFLAGS="$save_CPPFLAGS"
1211 else
1212   # Even if Guile support is not compiled in, we need to have these files
1213   # included.
1214   CONFIG_OBS="$CONFIG_OBS guile/guile.o"
1215   CONFIG_SRCS="$CONFIG_SRCS guile/guile.c"
1216 fi
1217 AC_SUBST(GUILE_CPPFLAGS)
1218 AC_SUBST(GUILE_LIBS)
1219 AM_CONDITIONAL(HAVE_GUILE, test "${have_libguile}" != no)
1220
1221 # ---------------------------- #
1222 # Check for source highlight.  #
1223 # ---------------------------- #
1224
1225 SRCHIGH_LIBS=
1226 SRCHIGH_CFLAGS=
1227
1228 AC_ARG_ENABLE(source-highlight,
1229   AS_HELP_STRING([--enable-source-highlight],
1230     [enable source-highlight for source listings]),
1231   [case "${enableval}" in
1232   yes)  enable_source_highlight=yes ;;
1233   no)   enable_source_highlight=no  ;;
1234   *)    AC_MSG_ERROR(bad value ${enableval} for source-highlight option) ;;
1235 esac],
1236 [enable_source_highlight=auto])
1237
1238 if test "${enable_source_highlight}" != "no"; then
1239   AC_MSG_CHECKING([for the source-highlight library])
1240   if test "${pkg_config_prog_path}" = "missing"; then
1241     AC_MSG_RESULT([no - pkg-config not found])
1242     if test "${enable_source_highlight}" = "yes"; then
1243       AC_MSG_ERROR([pkg-config was not found in your system])
1244     fi
1245   else
1246     if ${pkg_config_prog_path} --exists source-highlight; then
1247       case "$LDFLAGS" in
1248         *static-libstdc*)
1249           AC_MSG_ERROR([source highlight is incompatible with -static-libstdc++; dnl
1250 either use --disable-source-highlight or dnl
1251 --without-static-standard-libraries])
1252           ;;
1253       esac
1254
1255       srchigh_pkg_cflags=`${pkg_config_prog_path} --cflags source-highlight`
1256       srchigh_pkg_libs=`${pkg_config_prog_path} --libs source-highlight`
1257
1258       # Now that we have found a source-highlight library, check if we can use
1259       # it.  In particular, we're trying to detect the situation that the
1260       # library is using the new libstdc++ library abi ( see
1261       # https://gcc.gnu.org/onlinedocs/libstdc++/manual/using_dual_abi.html )
1262       # while the compiler being used to compile gdb is using the old abi.
1263       # Such a situation will result in an undefined reference to
1264       # srchilite::SourceHighlight::SourceHighlight(std::string const&).
1265       # This situation can occur for instance when using a source highlight
1266       # library compiled with g++ 7.5.0 while building gdb with g++ 4.8.5.
1267       AC_LANG_PUSH(C++)
1268       save_CFLAGS=$CFLAGS
1269       save_LDFLAGS=$LDFLAGS
1270       CFLAGS="$CFLAGS $srchigh_pkg_cflags"
1271       LDFLAGS="$LDFLAGS $srchigh_pkg_libs"
1272       AC_LINK_IFELSE(
1273         [AC_LANG_PROGRAM(
1274           [#include <srchilite/sourcehighlight.h>],
1275           [std::string outlang = "esc.outlang";
1276            new srchilite::SourceHighlight (outlang);]
1277         )],
1278         [have_usable_source_highlight=yes],
1279         [have_usable_source_highlight=no]
1280       )
1281       CFLAGS="$SAVE_CFLAGS"
1282       LDFLAGS="$SAVE_LDFLAGS"
1283       AC_LANG_POP(C++)
1284
1285       if test "${have_usable_source_highlight}" = "yes"; then
1286         AC_DEFINE([HAVE_SOURCE_HIGHLIGHT], 1,
1287                   [Define to 1 if the source-highlight library is available])
1288         AC_MSG_RESULT([yes])
1289         SRCHIGH_CFLAGS="$srchigh_pkg_cflags"
1290         SRCHIGH_LIBS="$srchigh_pkg_libs"
1291       else
1292         AC_MSG_RESULT([no])
1293         if test "${enable_source_highlight}" = "yes"; then
1294           AC_MSG_ERROR([source-highlight in your system could not be used])
1295         fi
1296       fi
1297     else
1298       AC_MSG_RESULT([no])
1299       if test "${enable_source_highlight}" = "yes"; then
1300         AC_MSG_ERROR([source-highlight was not found in your system])
1301       fi
1302     fi
1303   fi
1304 fi
1305 AC_SUBST(SRCHIGH_LIBS)
1306 AC_SUBST(SRCHIGH_CFLAGS)
1307
1308 # ------------------------- #
1309 # Checks for header files.  #
1310 # ------------------------- #
1311
1312 AC_HEADER_STDC
1313 # elf_hp.h is for HP/UX 64-bit shared library support.
1314 AC_CHECK_HEADERS([nlist.h machine/reg.h \
1315                   thread_db.h \
1316                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1317                   sys/procctl.h sys/resource.h sys/ptrace.h ptrace.h \
1318                   sys/reg.h sys/debugreg.h \
1319                   termios.h elf_hp.h])
1320 AC_CHECK_HEADERS(sys/user.h, [], [],
1321 [#if HAVE_SYS_PARAM_H
1322 # include <sys/param.h>
1323 #endif
1324 ])
1325
1326 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncursesw/ncurses.h ncurses/ncurses.h ncurses/term.h)
1327 AC_CHECK_HEADERS(term.h, [], [],
1328 [#if HAVE_CURSES_H
1329 # include <curses.h>
1330 #endif
1331 ])
1332
1333 AC_CHECK_HEADERS([sys/socket.h])
1334 AC_CHECK_HEADERS([ws2tcpip.h])
1335 AC_CHECK_HEADERS([execinfo.h])
1336
1337 # ------------------------- #
1338 # Checks for declarations.  #
1339 # ------------------------- #
1340
1341 libiberty_INIT
1342
1343 AC_CHECK_DECLS([snprintf])
1344 AM_LC_MESSAGES
1345
1346 # ------------------ #
1347 # Checks for types.  #
1348 # ------------------ #
1349
1350 AC_CHECK_TYPES(socklen_t, [], [],
1351 [#include <sys/types.h>
1352 #if HAVE_SYS_SOCKET_H
1353 # include <sys/socket.h>
1354 #elif HAVE_WS2TCPIP_H
1355 # include <ws2tcpip.h>
1356 #endif
1357 ])
1358
1359 # ------------------------------------- #
1360 # Checks for compiler characteristics.  #
1361 # ------------------------------------- #
1362
1363 AC_C_CONST
1364 AC_C_INLINE
1365 AC_C_BIGENDIAN
1366
1367 # ------------------------------ #
1368 # Checks for library functions.  #
1369 # ------------------------------ #
1370
1371 AC_CHECK_FUNCS([getuid getgid \
1372                 pipe pread pread64 pwrite resize_term \
1373                 getpgid setsid \
1374                 sigaction sigsetmask socketpair \
1375                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1376                 setrlimit getrlimit posix_madvise waitpid \
1377                 use_default_colors])
1378 AM_LANGINFO_CODESET
1379 GDB_AC_COMMON
1380
1381 # Check the return and argument types of ptrace.
1382 GDB_AC_PTRACE
1383
1384 dnl AC_FUNC_SETPGRP does not work when cross compiling
1385 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1386 if test "$cross_compiling" = no; then
1387   AC_FUNC_SETPGRP
1388 else
1389   AC_CACHE_CHECK(
1390     [whether setpgrp takes no argument],
1391     [ac_cv_func_setpgrp_void],
1392     [AC_COMPILE_IFELSE(
1393        [AC_LANG_PROGRAM(
1394           [#include <unistd.h>],
1395           [if (setpgrp(1,1) == -1)
1396              exit (0);
1397            else
1398              exit (1);]
1399         )],
1400        [ac_cv_func_setpgrp_void=no],
1401        [ac_cv_func_setpgrp_void=yes]
1402      )]
1403   )
1404 if test "$ac_cv_func_setpgrp_void" = yes; then
1405   AC_DEFINE(SETPGRP_VOID, 1)
1406 fi
1407 fi
1408
1409 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1410 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1411 [#include <sys/param.h>
1412 #include <sys/proc.h>
1413 ])
1414
1415 # See if <sys/lwp.h> defines `struct lwp`.
1416 AC_CACHE_CHECK(
1417   [for struct lwp],
1418   [gdb_cv_struct_lwp],
1419   [AC_COMPILE_IFELSE(
1420      [AC_LANG_PROGRAM(
1421         [#include <sys/param.h>
1422          #define _KMEMUSER
1423          #include <sys/lwp.h>],
1424         [struct lwp l;]
1425       )],
1426      [gdb_cv_struct_lwp=yes],
1427      [gdb_cv_struct_lwp=no]
1428    )]
1429 )
1430 if test "$gdb_cv_struct_lwp" = yes; then
1431   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1432             [Define to 1 if your system has struct lwp.])
1433 fi
1434
1435 # See if <machine/reg.h> degines `struct reg'.
1436 AC_CACHE_CHECK(
1437   [for struct reg in machine/reg.h],
1438   [gdb_cv_struct_reg],
1439   [AC_COMPILE_IFELSE(
1440      [AC_LANG_PROGRAM(
1441         [#include <sys/types.h>
1442          #include <machine/reg.h>],
1443         [struct reg r;]
1444       )],
1445      [gdb_cv_struct_reg=yes],
1446      [gdb_cv_struct_reg=no]
1447    )]
1448 )
1449 if test "$gdb_cv_struct_reg" = yes; then
1450   AC_DEFINE(HAVE_STRUCT_REG, 1,
1451             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1452 fi
1453
1454 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1455 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1456 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1457                  [#include <sys/types.h>
1458 #include <machine/reg.h>])
1459
1460 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1461 AC_MSG_CHECKING(for PTRACE_GETREGS)
1462 AC_CACHE_VAL(
1463   [gdb_cv_have_ptrace_getregs],
1464   [AC_COMPILE_IFELSE(
1465     [AC_LANG_PROGRAM([#include <sys/ptrace.h>], [PTRACE_GETREGS;])],
1466     [gdb_cv_have_ptrace_getregs=yes],
1467     [gdb_cv_have_ptrace_getregs=no]
1468    )]
1469 )
1470 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1471 if test "$gdb_cv_have_ptrace_getregs" = yes; then
1472   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1473   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1474 fi
1475
1476 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1477 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1478 AC_CACHE_VAL(
1479   [gdb_cv_have_ptrace_getfpxregs],
1480   [AC_COMPILE_IFELSE(
1481      [AC_LANG_PROGRAM([#include <sys/ptrace.h>], [PTRACE_GETFPXREGS;])],
1482      [gdb_cv_have_ptrace_getfpxregs=yes],
1483      [gdb_cv_have_ptrace_getfpxregs=no]
1484    )]
1485 )
1486 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1487 if test "$gdb_cv_have_ptrace_getfpxregs" = yes; then
1488   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1489   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1490 fi
1491
1492 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1493 AC_MSG_CHECKING(for PT_GETDBREGS)
1494 AC_CACHE_VAL(
1495   [gdb_cv_have_pt_getdbregs],
1496   [AC_COMPILE_IFELSE(
1497      [AC_LANG_PROGRAM(
1498         [#include <sys/types.h>
1499          #include <sys/ptrace.h>],
1500         [PT_GETDBREGS;]
1501       )],
1502      [gdb_cv_have_pt_getdbregs=yes],
1503      [gdb_cv_have_pt_getdbregs=no]
1504    )]
1505 )
1506 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1507 if test "$gdb_cv_have_pt_getdbregs" = yes; then
1508   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1509   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1510 fi
1511
1512 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1513 AC_MSG_CHECKING(for PT_GETXMMREGS)
1514 AC_CACHE_VAL(
1515   [gdb_cv_have_pt_getxmmregs],
1516   [AC_COMPILE_IFELSE(
1517      [AC_LANG_PROGRAM(
1518         [#include <sys/types.h>
1519          #include <sys/ptrace.h>],
1520         [PT_GETXMMREGS;]
1521       )],
1522      [gdb_cv_have_pt_getxmmregs=yes],
1523      [gdb_cv_have_pt_getxmmregs=no]
1524    )]
1525 )
1526 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1527 if test "$gdb_cv_have_pt_getxmmregs" = yes; then
1528   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1529   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1530 fi
1531
1532 # See if <sys/ptrace.h> supports LWP names on FreeBSD
1533 # Older FreeBSD versions don't have the pl_tdname member of
1534 # `struct ptrace_lwpinfo'.
1535 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_tdname], [], [],
1536                  [#include <sys/ptrace.h>])
1537
1538 # See if <sys/ptrace.h> supports syscall fields on FreeBSD.  The
1539 # pl_syscall_code member of `struct ptrace_lwpinfo' was added in
1540 # FreeBSD 10.3.
1541 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_syscall_code], [], [],
1542                  [#include <sys/ptrace.h>])
1543
1544 # Check if the compiler supports the `long long' type.
1545
1546 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1547                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1548 [[extern long long foo;]],
1549 [[switch (foo & 2) { case 0: return 1; }]])],
1550                                   gdb_cv_c_long_long=yes,
1551                                   gdb_cv_c_long_long=no)])
1552 if test "$gdb_cv_c_long_long" != yes; then
1553   # libdecnumber requires long long.
1554   AC_MSG_ERROR([Compiler must support long long for GDB.])
1555 fi
1556
1557 # Check if the compiler and runtime support printing decfloats.
1558
1559 AC_CACHE_CHECK([for decfloat support in printf],
1560                gdb_cv_printf_has_decfloat,
1561                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1562 [[char buf[64];
1563   _Decimal32 d32 = 1.2345df;
1564   _Decimal64 d64 = 1.2345dd;
1565   _Decimal128 d128 = 1.2345dl;
1566   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1567   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1568                               gdb_cv_printf_has_decfloat=yes,
1569                               gdb_cv_printf_has_decfloat=no,
1570                               gdb_cv_printf_has_decfloat=no)])
1571 if test "$gdb_cv_printf_has_decfloat" = yes; then
1572   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1573             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1574 fi
1575
1576 # Check if the compiler supports the `long double' type.  We can't use
1577 # AC_C_LONG_DOUBLE because that one does additional checks on the
1578 # constants defined in <float.h> that fail on some systems,
1579 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1580
1581 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1582                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1583                                   gdb_cv_c_long_double=yes,
1584                                   gdb_cv_c_long_double=no)])
1585 if test "$gdb_cv_c_long_double" = yes; then
1586   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1587            [Define to 1 if the compiler supports long double.])
1588 fi
1589
1590 # Check if the compiler and runtime support printing long doubles.
1591
1592 AC_CACHE_CHECK([for long double support in printf],
1593                gdb_cv_printf_has_long_double,
1594                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1595 [[char buf[16];
1596   long double f = 3.141592653;
1597   sprintf (buf, "%Lg", f);
1598   return (strncmp ("3.14159", buf, 7));]])],
1599                               gdb_cv_printf_has_long_double=yes,
1600                               gdb_cv_printf_has_long_double=no,
1601                               gdb_cv_printf_has_long_double=no)])
1602 if test "$gdb_cv_printf_has_long_double" = yes; then
1603   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1604             [Define to 1 if the "%Lg" format works to print long doubles.])
1605 fi
1606
1607 # Check if the compiler and runtime support scanning long doubles.
1608
1609 AC_CACHE_CHECK([for long double support in scanf],
1610                gdb_cv_scanf_has_long_double,
1611                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1612 [[#include <stdio.h>]],
1613 [[char *buf = "3.141592653";
1614   long double f = 0;
1615   sscanf (buf, "%Lg", &f);
1616   return !(f > 3.14159 && f < 3.14160);]])],
1617                               gdb_cv_scanf_has_long_double=yes,
1618                               gdb_cv_scanf_has_long_double=no,
1619                               gdb_cv_scanf_has_long_double=no)])
1620 if test "$gdb_cv_scanf_has_long_double" = yes; then
1621   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1622             [Define to 1 if the "%Lg" format works to scan long doubles.])
1623 fi
1624
1625 case ${host_os} in
1626 aix*)
1627   AC_CACHE_CHECK(
1628     [for -bbigtoc option], [gdb_cv_bigtoc],
1629     [SAVE_LDFLAGS=$LDFLAGS
1630
1631      case $GCC in
1632        yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1633        *) gdb_cv_bigtoc=-bbigtoc ;;
1634      esac
1635
1636      LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1637      AC_LINK_IFELSE(
1638        [AC_LANG_PROGRAM([], [int i;])],
1639        [],
1640        [gdb_cv_bigtoc=]
1641      )
1642      LDFLAGS="${SAVE_LDFLAGS}"]
1643   )
1644   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1645   ;;
1646 esac
1647
1648 AC_MSG_CHECKING(for the dynamic export flag)
1649 dynamic_list=false
1650 if test "${gdb_native}" = yes; then
1651    # The dynamically loaded libthread_db needs access to symbols in the gdb
1652    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1653    # may not be supported there.
1654    old_LDFLAGS="$LDFLAGS"
1655    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1656    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1657    LDFLAGS="$LDFLAGS $RDYNAMIC"
1658    if test "${have_libpython}" = no; then
1659      AC_LINK_IFELSE(
1660        [AC_LANG_PROGRAM([], [])],
1661        [dynamic_list=true],
1662        []
1663      )
1664    else
1665      # Workaround http://bugs.python.org/issue4434 where static
1666      # libpythonX.Y.a would get its symbols required for
1667      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1668      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1669
1670      # Note the workaround for Python
1671      # http://bugs.python.org/issue10112 earlier has removed
1672      # -export-dynamic from PYTHON_LIBS.  That's exactly what we want
1673      # here too, as otherwise it'd make this -Wl,--dynamic-list test
1674      # always pass.
1675      old_CFLAGS="$CFLAGS"
1676      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1677      old_LIBS="$LIBS"
1678      LIBS="$LIBS $PYTHON_LIBS"
1679      old_CPPFLAGS="$CPPFLAGS"
1680      CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
1681      AC_RUN_IFELSE(
1682        [AC_LANG_PROGRAM(
1683          [#include "Python.h"],
1684          [int err;
1685           Py_Initialize ();
1686           err = PyRun_SimpleString ("import ctypes\n");
1687           Py_Finalize ();
1688           return err == 0 ? 0 : 1;])],
1689        [dynamic_list=true], [], [true])
1690      LIBS="$old_LIBS"
1691      CFLAGS="$old_CFLAGS"
1692      CPPFLAGS="$old_CPPFLAGS"
1693    fi
1694    LDFLAGS="$old_LDFLAGS"
1695 fi
1696 if $dynamic_list; then
1697   found="-Wl,--dynamic-list"
1698   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1699 else
1700   found="-rdynamic"
1701   RDYNAMIC="-rdynamic"
1702 fi
1703 AC_SUBST(RDYNAMIC)
1704 AC_MSG_RESULT($found)
1705
1706 AC_CACHE_CHECK(
1707   [whether execinfo.h backtrace is available],
1708   gdb_cv_execinfo_backtrace,
1709   [AC_LINK_IFELSE(
1710      [AC_LANG_PROGRAM(
1711         [
1712          #include <execinfo.h>
1713         ],
1714         [
1715          int f;
1716          void *b[[2]];
1717          f = backtrace (b, 2);
1718          backtrace_symbols_fd (b, f, 2);
1719         ])],
1720    [gdb_cv_execinfo_backtrace=yes],
1721    [gdb_cv_execinfo_backtrace=no])])
1722 if test "$gdb_cv_execinfo_backtrace" = yes; then
1723   AC_DEFINE(HAVE_EXECINFO_BACKTRACE, 1,
1724             [Define to 1 if execinfo.h backtrace functions are available.])
1725 fi
1726
1727 dnl For certain native configurations, we need to check whether thread
1728 dnl support can be built in or not.
1729 dnl
1730 dnl Note that we only want this if we are both native (host == target),
1731 dnl and not doing a canadian cross build (build == host).
1732
1733 if test "${build}" = "${host}" -a "${host}" = "${target}" ; then
1734    case ${host_os} in
1735    aix*)
1736       AC_MSG_CHECKING(for AiX thread debugging library)
1737       AC_CACHE_VAL(
1738         [gdb_cv_have_aix_thread_debug],
1739         [AC_COMPILE_IFELSE(
1740            [AC_LANG_PROGRAM(
1741               [#include <sys/pthdebug.h>],
1742               [#ifndef PTHDB_VERSION_3
1743                #error
1744                #endif]
1745             )],
1746            [gdb_cv_have_aix_thread_debug=yes],
1747            [gdb_cv_have_aix_thread_debug=no]
1748          )]
1749       )
1750       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1751       if test "$gdb_cv_have_aix_thread_debug" = yes; then
1752          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1753          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1754          LIBS="$LIBS -lpthdebug"
1755
1756          # Older versions of AIX do not provide the declaration for
1757          # the getthrds function (it appears that it was introduced
1758          # with AIX 6.x).
1759          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1760       fi
1761       ;;
1762    esac
1763    AC_SUBST(CONFIG_LDFLAGS)
1764 fi
1765
1766 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1767 dnl other error codes.
1768 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1769   AC_CACHE_CHECK(
1770     [whether <thread_db.h> has TD_NOTALLOC],
1771     [gdb_cv_thread_db_h_has_td_notalloc],
1772     [AC_COMPILE_IFELSE(
1773        [AC_LANG_PROGRAM(
1774           [#include <thread_db.h>],
1775           [int i = TD_NOTALLOC;]
1776         )],
1777        [gdb_cv_thread_db_h_has_td_notalloc=yes],
1778        [gdb_cv_thread_db_h_has_td_notalloc=no]
1779      )]
1780   )
1781
1782   AC_CACHE_CHECK(
1783     [whether <thread_db.h> has TD_VERSION],
1784     [gdb_cv_thread_db_h_has_td_version],
1785     [AC_COMPILE_IFELSE(
1786        [AC_LANG_PROGRAM(
1787           [#include <thread_db.h>],
1788           [int i = TD_VERSION;]
1789         )],
1790        [gdb_cv_thread_db_h_has_td_version=yes],
1791        [gdb_cv_thread_db_h_has_td_version=no]
1792      )]
1793   )
1794
1795   AC_CACHE_CHECK(
1796     [whether <thread_db.h> has TD_NOTLS],
1797     [gdb_cv_thread_db_h_has_td_notls],
1798     [AC_COMPILE_IFELSE(
1799        [AC_LANG_PROGRAM(
1800           [#include <thread_db.h>],
1801           [int i = TD_NOTLS;]
1802         )],
1803        [gdb_cv_thread_db_h_has_td_notls=yes],
1804        [gdb_cv_thread_db_h_has_td_notls=no]
1805      )]
1806   )
1807 fi
1808 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1809   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1810             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1811 fi
1812 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1813   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1814             [Define if <thread_db.h> has the TD_VERSION error code.])
1815 fi
1816 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1817   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1818             [Define if <thread_db.h> has the TD_NOTLS error code.])
1819 fi
1820
1821 dnl Set the host's .gdbinit filename.
1822 case $host_os in
1823   go32* | *djgpp*)
1824     gdbinit=gdb.ini
1825     ;;
1826   *)
1827     gdbinit=.gdbinit
1828     ;;
1829 esac
1830 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1831
1832 dnl Set the host's .gdbearlyinit filename
1833 AC_DEFINE_UNQUOTED(GDBEARLYINIT,".gdbearlyinit",[The .gdbearlyinit filename.])
1834
1835 dnl Handle optional features that can be enabled.
1836
1837 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1838 # except that the argument to --with-sysroot is optional.
1839 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1840 if test "x$with_sysroot" = xyes; then
1841   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1842 fi
1843 AC_ARG_WITH(sysroot,
1844   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1845                  [search for usr/lib et al within DIR]),
1846   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1847 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1848               [search for usr/lib et al within DIR])
1849 AC_SUBST(TARGET_SYSTEM_ROOT)
1850 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1851
1852 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1853     [automatically load a system-wide gdbinit file],
1854     [])
1855 GDB_AC_WITH_DIR(SYSTEM_GDBINIT_DIR, system-gdbinit-dir,
1856     [automatically load system-wide gdbinit files from this directory],
1857     [])
1858
1859 AM_GDB_WARNINGS
1860 AM_GDB_UBSAN
1861
1862 # In the Cygwin environment, we need some additional flags.
1863 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1864 [AC_EGREP_CPP(^lose$, [
1865 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1866 lose
1867 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1868
1869
1870 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1871 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1872 case ${host} in
1873   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1874   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1875   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1876   *) SER_HARDWIRE="$SER_HARDWIRE ser-uds.o" ;;
1877 esac
1878 AC_SUBST(SER_HARDWIRE)
1879
1880 # libreadline needs libuser32.a in a cygwin environment
1881 WIN32LIBS=
1882 if test x"$gdb_cv_os_cygwin" = xyes; then
1883     WIN32LIBS="-luser32"
1884     case "${target}" in
1885         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1886         ;;
1887     esac
1888 fi
1889
1890 # The ser-tcp.c module requires sockets.
1891 # Note that WIN32APILIBS is set by GDB_AC_COMMON.
1892 WIN32LIBS="$WIN32LIBS $WIN32APILIBS"
1893
1894 # Add ELF support to GDB, but only if BFD includes ELF support.
1895 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
1896                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
1897 if test "$gdb_cv_var_elf" = yes; then
1898   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o dtrace-probe.o \
1899                 gcore-elf.o elf-none-tdep.o"
1900   AC_DEFINE(HAVE_ELF, 1,
1901             [Define if ELF support should be included.])
1902   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1903   if test "$plugins" = "yes"; then
1904     AC_SEARCH_LIBS(dlopen, dl)
1905   fi
1906 fi
1907
1908 # Add macho support to GDB, but only if BFD includes it.
1909 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
1910                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
1911 if test "$gdb_cv_var_macho" = yes; then
1912   CONFIG_OBS="$CONFIG_OBS machoread.o"
1913 fi
1914
1915 # Add any host-specific objects to GDB.
1916 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1917
1918 # If building on ELF, look for lzma support for embedded compressed debug info.
1919 if test "$gdb_cv_var_elf" = yes; then
1920   AC_ARG_WITH(lzma,
1921     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
1922     [], [with_lzma=auto])
1923   AC_MSG_CHECKING([whether to use lzma])
1924   AC_MSG_RESULT([$with_lzma])
1925
1926   if test "${with_lzma}" != no; then
1927     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
1928                           [lzma_index_iter iter;
1929                            lzma_index_iter_init (&iter, 0);
1930                            lzma_mf_is_supported (LZMA_MF_HC3);])
1931     if test "$HAVE_LIBLZMA" != yes; then
1932       if test "$with_lzma" = yes; then
1933         AC_MSG_ERROR([missing liblzma for --with-lzma])
1934       fi
1935     fi
1936   fi
1937 fi
1938
1939 LIBGUI="../libgui/src/libgui.a"
1940 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1941 AC_SUBST(LIBGUI)
1942 AC_SUBST(GUI_CFLAGS_X)
1943
1944 WIN32LDAPP=
1945 AC_SUBST(WIN32LIBS)
1946 AC_SUBST(WIN32LDAPP)
1947
1948 case "${host}" in
1949 *-*-cygwin* | *-*-mingw* )
1950     configdir="win"
1951     ;;
1952 *)
1953     configdir="unix"
1954     ;;
1955 esac
1956
1957 GDBTKLIBS=
1958 if test "${enable_gdbtk}" = "yes"; then
1959
1960     # Gdbtk must have an absolute path to srcdir in order to run
1961     # properly when not installed.
1962     here=`pwd`
1963     cd ${srcdir}
1964     GDBTK_SRC_DIR=`pwd`
1965     cd $here
1966
1967     SC_PATH_TCLCONFIG
1968
1969     # If $no_tk is nonempty, then we can't do Tk, and there is no
1970     # point to doing Tcl.
1971     SC_PATH_TKCONFIG
1972
1973     if test -z "${no_tcl}" -a -z "${no_tk}"; then
1974         SC_LOAD_TCLCONFIG
1975
1976         # Check for in-tree tcl
1977         here=`pwd`
1978         cd ${srcdir}/..
1979         topdir=`pwd`
1980         cd ${here}
1981
1982         intree="no"
1983         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
1984           intree="yes"
1985         fi
1986
1987         # Find Tcl private headers
1988         if test x"${intree}" = xno; then
1989           CY_AC_TCL_PRIVATE_HEADERS
1990           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
1991           TCL_LIBRARY="${TCL_LIB_SPEC}"
1992           TCL_DEPS=""
1993         else
1994           # If building tcl in the same src tree, private headers
1995           # are not needed, but we need to be sure to use the right
1996           # headers library
1997           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
1998           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
1999           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2000         fi
2001         AC_SUBST(TCL_INCLUDE)
2002         AC_SUBST(TCL_LIBRARY)
2003         AC_SUBST(TCL_DEPS)
2004
2005         SC_LOAD_TKCONFIG
2006
2007         # Check for in-tree Tk
2008         intree="no"
2009         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2010           intree="yes"
2011         fi
2012
2013         # Find Tk private headers
2014         if test x"${intree}" = xno; then
2015           CY_AC_TK_PRIVATE_HEADERS
2016           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2017           TK_LIBRARY=${TK_LIB_SPEC}
2018           TK_DEPS=""
2019         else
2020           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2021           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2022           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2023         fi
2024         AC_SUBST(TK_INCLUDE)
2025         AC_SUBST(TK_LIBRARY)
2026         AC_SUBST(TK_DEPS)
2027         AC_SUBST(TK_XINCLUDES)
2028
2029         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2030
2031         # Include some libraries that Tcl and Tk want.
2032         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2033         # Yes, the ordering seems wrong here.  But it isn't.
2034         # TK_LIBS is the list of libraries that need to be linked
2035         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2036         # were in LIBS then any link tests after this point would
2037         # try to include things like `$(LIBGUI)', which wouldn't work.
2038         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2039
2040         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2041         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2042         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2043         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2044         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2045         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2046         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2047
2048         if test x"$gdb_cv_os_cygwin" = xyes; then
2049           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2050           WIN32LDAPP="-Wl,--subsystem,console"
2051           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2052         fi
2053
2054         AC_CONFIG_SUBDIRS(gdbtk)
2055     fi
2056 fi
2057
2058 AC_SUBST(X_CFLAGS)
2059 AC_SUBST(X_LDFLAGS)
2060 AC_SUBST(X_LIBS)
2061 AC_SUBST(GDBTKLIBS)
2062 AC_SUBST(GDBTK_CFLAGS)
2063 AC_SUBST(GDBTK_SRC_DIR)
2064
2065 AC_PATH_X
2066
2067 # Unlike the sim directory, whether a simulator is linked is controlled by
2068 # presence of a gdb_sim definition in the target configure.tgt entry.
2069 # This code just checks for a few cases where we'd like to ignore those
2070 # definitions, even when they're present in the '.mt' file.  These cases
2071 # are when --disable-sim is specified, or if the simulator directory is
2072 # not part of the source tree.
2073 #
2074 AC_ARG_ENABLE(sim,
2075 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2076 [echo "enable_sim = $enable_sim";
2077  echo "enableval = ${enableval}";
2078  case "${enableval}" in
2079   yes) ignore_sim=false ;;
2080   no)  ignore_sim=true ;;
2081   *)   ignore_sim=false ;;
2082  esac],
2083 [ignore_sim=false])
2084
2085 if test ! -d "${srcdir}/../sim"; then
2086   ignore_sim=true
2087 fi
2088
2089 SIM=
2090 SIM_OBS=
2091 if test "${ignore_sim}" = "false"; then
2092   if test x"${gdb_sim}" != x ; then
2093     SIM="${gdb_sim}"
2094     SIM_OBS="remote-sim.o"
2095     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2096
2097     # Some tdep code should only be compiled in when the ppc sim is
2098     # built.  PR sim/13418.
2099     case $target in
2100       powerpc*-*-*)
2101         AC_DEFINE(WITH_PPC_SIM, 1, [Define if the PPC simulator is being linked in.])
2102         ;;
2103     esac
2104   fi
2105 fi
2106 AC_SUBST(SIM)
2107 AC_SUBST(SIM_OBS)
2108
2109 AC_SUBST(ENABLE_CFLAGS)
2110 AC_SUBST(PROFILE_CFLAGS)
2111
2112 AC_SUBST(CONFIG_OBS)
2113 AC_SUBST(CONFIG_DEPS)
2114 AC_SUBST(CONFIG_SRCS)
2115 AC_SUBST(CONFIG_ALL)
2116 AC_SUBST(CONFIG_CLEAN)
2117 AC_SUBST(CONFIG_INSTALL)
2118 AC_SUBST(CONFIG_UNINSTALL)
2119
2120 # List of host floatformats.
2121 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2122 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2123 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2124
2125 # target_subdir is used by the testsuite to find the target libraries.
2126 target_subdir=
2127 if test "${host}" != "${target}"; then
2128     target_subdir="${target_alias}/"
2129 fi
2130 AC_SUBST(target_subdir)
2131
2132 # Import nat definitions.
2133 nat_makefile_frag=/dev/null
2134 if test "${gdb_native}" = "yes"; then
2135   . ${srcdir}/configure.nat
2136   nativefile=$NAT_FILE
2137 fi
2138
2139 AC_SUBST(NAT_FILE)
2140 AC_SUBST(NATDEPFILES)
2141 AC_SUBST(NAT_CDEPS)
2142 AC_SUBST(LOADLIBES)
2143 AC_SUBST(MH_CFLAGS)
2144 AC_SUBST(XM_CLIBS)
2145 AC_SUBST(NAT_GENERATED_FILES)
2146 AC_SUBST(HAVE_NATIVE_GCORE_HOST)
2147 AC_SUBST_FILE(nat_makefile_frag)
2148
2149 if test x"${gdb_osabi}" != x ; then
2150     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2151                        [Define to the default OS ABI for this configuration.])
2152 fi
2153
2154 # Setup possible use of libbacktrace.
2155 AC_ARG_ENABLE([libbacktrace],
2156 [AS_HELP_STRING([--enable-libbacktrace],
2157                 [use libbacktrace to write a backtrace after a fatal signal.])],
2158 [case "${enableval}" in
2159   yes)  enable_libbacktrace=yes ;;
2160   no)   enable_libbacktrace=no  ;;
2161   *)    AC_MSG_ERROR(bad value ${enableval} for --enable-libbacktrace option) ;;
2162 esac],
2163 enable_libbacktrace=yes)
2164
2165 if test "${enable_libbacktrace}" == "yes"; then
2166   LIBBACKTRACE_INC="-I$srcdir/../libbacktrace/ -I../libbacktrace/"
2167   LIBBACKTRACE_LIB=../libbacktrace/.libs/libbacktrace.a
2168   AC_DEFINE(HAVE_LIBBACKTRACE, 1, [Define if libbacktrace is being used.])
2169 else
2170   LIBBACKTRACE_INC=
2171   LIBBACKTRACE_LIB=
2172 fi
2173
2174 AC_SUBST(LIBBACKTRACE_INC)
2175 AC_SUBST(LIBBACKTRACE_LIB)
2176
2177 # Check for babeltrace and babeltrace-ctf
2178 AC_ARG_WITH(babeltrace,
2179   AS_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2180   [], [with_babeltrace=auto])
2181 AC_MSG_CHECKING([whether to use babeltrace])
2182 AC_MSG_RESULT([$with_babeltrace])
2183
2184 if test "x$with_babeltrace" = "xno"; then
2185   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2186 else
2187   # Append -Werror to CFLAGS so that configure can catch the warning
2188   # "assignment from incompatible pointer type", which is related to
2189   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2190   # in GDB, while babeltrace 1.0.3 is broken.
2191   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2192   # safe to save and restore CFLAGS here.
2193   saved_CFLAGS=$CFLAGS
2194   CFLAGS="$CFLAGS -Werror"
2195   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2196                         [#include <babeltrace/babeltrace.h>
2197                          #include <babeltrace/ctf/events.h>
2198                          #include <babeltrace/ctf/iterator.h>],
2199                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2200                         struct bt_ctf_event *event = NULL;
2201                         const struct bt_definition *scope;
2202
2203                         pos->type = BT_SEEK_BEGIN;
2204                         bt_iter_set_pos (bt_ctf_get_iter (NULL), pos);
2205                         scope = bt_ctf_get_top_level_scope (event,
2206                                                            BT_STREAM_EVENT_HEADER);
2207                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2208                         ])
2209   CFLAGS=$saved_CFLAGS
2210
2211   if test "$HAVE_LIBBABELTRACE" != yes; then
2212      if test "$with_babeltrace" = yes; then
2213        AC_MSG_ERROR([babeltrace is missing or unusable])
2214      else
2215        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2216      fi
2217   fi
2218 fi
2219
2220 # Check for xxhash
2221 AC_ARG_WITH(xxhash,
2222   AS_HELP_STRING([--with-xxhash], [use libxxhash for hashing (faster) (auto/yes/no)]),
2223   [], [with_xxhash=auto])
2224
2225 GCC_ENABLE([libctf], [yes], [], [Handle .ctf type-info sections])
2226 if test x${enable_static} = xno; then
2227   LIBCTF="-Wl,--rpath,../libctf/.libs ../libctf/.libs/libctf.so"
2228   CTF_DEPS="../libctf/.libs/libctf.so"
2229 else
2230   LIBCTF="../libctf/.libs/libctf.a"
2231   CTF_DEPS="$LIBCTF"
2232 fi
2233 if test "${enable_libctf}" = yes; then
2234   AC_DEFINE(ENABLE_LIBCTF, 1, [Handle .ctf type-info sections])
2235 else
2236   LIBCTF=
2237   CTF_DEPS=
2238 fi
2239 AC_SUBST(LIBCTF)
2240 AC_SUBST(CTF_DEPS)
2241
2242 # If nativefile (NAT_FILE) is not set in configure.nat, we link to an
2243 # empty version.
2244
2245 if test "x$with_xxhash" != "xno"; then
2246   AC_LIB_HAVE_LINKFLAGS([xxhash], [],
2247                         [#include <xxhash.h>],
2248                         [XXH32("foo", 3, 0);
2249                         ])
2250   if test "$HAVE_LIBXXHASH" != yes; then
2251     if test "$with_xxhash" = yes; then
2252       AC_MSG_ERROR([xxhash is missing or unusable])
2253     fi
2254   fi
2255   if test "x$with_xxhash" = "xauto"; then
2256     with_xxhash="$HAVE_LIBXXHASH"
2257   fi
2258 fi
2259
2260 AC_MSG_CHECKING([whether to use xxhash])
2261 AC_MSG_RESULT([$with_xxhash])
2262
2263 NM_H=
2264 rm -f nm.h
2265 if test "${nativefile}" != ""; then
2266     case "${nativefile}" in
2267       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2268       * ) GDB_NM_FILE="${nativefile}"
2269     esac
2270     AC_CONFIG_LINKS([nm.h:$GDB_NM_FILE], [echo > stamp-nmh],
2271                     [GDB_NM_FILE=$GDB_NM_FILE])
2272     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2273     NM_H=nm.h
2274 fi
2275 AC_SUBST(GDB_NM_FILE)
2276 AC_SUBST(NM_H)
2277
2278 dnl Add dependency for xsltproc if building with maintainer-mode enabled.
2279 AC_PATH_PROGS(XSLTPROC, xsltproc, missing)
2280 if test "x$USE_MAINTAINER_MODE" = xyes; then
2281   if test "${XSLTPROC}" = missing; then
2282     AC_MSG_ERROR(unable to find xsltproc.  maintainer-mode requires xsltproc.)
2283   fi
2284 fi
2285 AC_SUBST(XSLTPROC)
2286
2287 dnl Check for exe extension set on certain hosts (e.g. Win32)
2288 AC_EXEEXT
2289
2290 dnl  Detect the character set used by this host.
2291 dnl  At the moment, we just assume it's UTF-8.
2292 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2293           [Define to be a string naming the default host character set.])
2294
2295 GDB_AC_SELFTEST([
2296   CONFIG_OBS="$CONFIG_OBS \$(SELFTESTS_OBS)"
2297   CONFIG_SRCS="$CONFIG_SRCS \$(SELFTESTS_SRCS)"
2298 ])
2299
2300 GDB_AC_TRANSFORM([gdb], [GDB_TRANSFORM_NAME])
2301 GDB_AC_TRANSFORM([gcore], [GCORE_TRANSFORM_NAME])
2302 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2303 AC_CONFIG_FILES([Makefile gdb-gdb.gdb gdb-gdb.py doc/Makefile data-directory/Makefile])
2304
2305 AC_OUTPUT