gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2021 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_INIT
  22 AC_CONFIG_MACRO_DIRS([../config])
  23 AC_CONFIG_SRCDIR([main.c])
  24 AC_CONFIG_HEADERS(config.h:config.in, [echo > stamp-h])
  25 AM_MAINTAINER_MODE
  26
  27 AC_PROG_CC
  28 AC_PROG_CXX
  29
  30 AC_USE_SYSTEM_EXTENSIONS
  31 ACX_LARGEFILE
  32 AM_PROG_INSTALL_STRIP
  33
  34 AC_CONFIG_AUX_DIR(..)
  35
  36 # Set build, build_cpu, build_vendor and build_os.
  37 AC_CANONICAL_BUILD
  38
  39 # Set host, host_cpu, host_vendor, and host_os.
  40 AC_CANONICAL_HOST
  41
  42 # Set target, target_cpu, target_vendor, and target_os.
  43 AC_CANONICAL_TARGET
  44
  45 ACX_NONCANONICAL_TARGET
  46
  47 AC_ARG_PROGRAM
  48
  49 # We require a C++11 compiler.  Check if one is available, and if
  50 # necessary, set CXX_DIALECT to some -std=xxx switch.
  51 AX_CXX_COMPILE_STDCXX(11, , mandatory)
  52
  53 # Dependency checking.
  54 ZW_CREATE_DEPDIR
  55 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  56
  57 dnl List of object files and targets accumulated by configure.
  58
  59 CONFIG_OBS=
  60 CONFIG_DEPS=
  61 CONFIG_SRCS=
  62 ENABLE_CFLAGS=
  63
  64 CONFIG_ALL=
  65 CONFIG_CLEAN=
  66 CONFIG_INSTALL=
  67 CONFIG_UNINSTALL=
  68
  69 dnl Set up for gettext.
  70 ZW_GNU_GETTEXT_SISTER_DIR
  71
  72 localedir='${datadir}/locale'
  73 AC_SUBST(localedir)
  74
  75 if test x"$USE_NLS" = xyes; then
  76    CONFIG_ALL="$CONFIG_ALL all-po"
  77    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  78    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  79    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  80 fi
  81
  82 PACKAGE=gdb
  83 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  84 AC_SUBST(PACKAGE)
  85
  86 # We never need to detect it in this sub-configure.
  87 # But preserve it for config.status --recheck.
  88 AC_ARG_VAR(MAKEINFO,
  89   [Parent configure detects if it is of sufficient version.])
  90 AC_ARG_VAR(MAKEINFOFLAGS,
  91   [Parameters for MAKEINFO.])
  92
  93 MAKEINFO_EXTRA_FLAGS=""
  94 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
  95   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
  96   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
  97     gdb_cv_have_makeinfo_click=yes
  98   else
  99     gdb_cv_have_makeinfo_click=no
 100   fi])
 101 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 102   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 103 fi
 104 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 105
 106 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 107     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 108     [${libdir}/debug])
 109
 110 # We can't pass paths as command line arguments.
 111 # Mingw32 tries to be clever and will convert the paths for us.
 112 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 113 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 114 # This breaks GDB's relocatable path conversions since paths passed in
 115 # config.h would not get so translated, the path prefixes no longer match.
 116 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 117
 118 # GDB's datadir relocation
 119
 120 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 121     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 122     [${datadir}/gdb])
 123
 124 AC_ARG_WITH(relocated-sources,
 125 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 126 [reloc_srcdir="${withval}"
 127  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 128               [Relocated directory for source files. ])
 129 ])
 130
 131 AC_MSG_CHECKING([for default auto-load directory])
 132 AC_ARG_WITH(auto-load-dir,
 133 AS_HELP_STRING([--with-auto-load-dir=PATH],
 134   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 135   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 136 escape_dir=`echo $with_auto_load_dir | sed -e 's/[[$]]datadir\>/\\\\\\\\\\\\&/g' -e 's/[[$]]debugdir\>/\\\\\\\\\\\\&/g'`
 137 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 138               [Directories from which to load auto-loaded scripts.])
 139 AC_MSG_RESULT([$with_auto_load_dir])
 140
 141 AC_MSG_CHECKING([for default auto-load safe-path])
 142 AC_ARG_WITH(auto-load-safe-path,
 143 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 144   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 145 AS_HELP_STRING([--without-auto-load-safe-path],
 146                [do not restrict auto-loaded files locations]),
 147     [if test "$with_auto_load_safe_path" = "no"; then
 148      with_auto_load_safe_path="/"
 149      fi],
 150 [with_auto_load_safe_path="$with_auto_load_dir"])
 151 escape_dir=`echo $with_auto_load_safe_path | sed -e 's/[[$]]datadir\>/\\\\\\\\\\\\&/g' -e 's/[[$]]debugdir\>/\\\\\\\\\\\\&/g'`
 152 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 153               [Directories safe to hold auto-loaded files.])
 154 AC_MSG_RESULT([$with_auto_load_safe_path])
 155
 156 AC_CONFIG_SUBDIRS(testsuite)
 157
 158 # Check whether to support alternative target configurations
 159 AC_ARG_ENABLE(targets,
 160 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 161 [case "${enableval}" in
 162   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
 163             ;;
 164   no)       enable_targets= ;;
 165   *)        enable_targets=$enableval ;;
 166 esac])
 167
 168 # Check whether to enable 64-bit support on 32-bit hosts
 169 AC_ARG_ENABLE(64-bit-bfd,
 170 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 171 [case "${enableval}" in
 172   yes)  want64=true  ;;
 173   no)   want64=false ;;
 174   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 175 esac],[want64=false])dnl
 176
 177 # Provide defaults for some variables set by the per-host and per-target
 178 # configuration.
 179 gdb_host_obs=posix-hdep.o
 180
 181 if test "${target}" = "${host}"; then
 182   gdb_native=yes
 183 else
 184   gdb_native=no
 185 fi
 186
 187 . $srcdir/configure.host
 188
 189 # Accumulate some settings from configure.tgt over all enabled targets
 190
 191 TARGET_OBS=
 192 all_targets=
 193 HAVE_NATIVE_GCORE_TARGET=
 194
 195 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 196 do
 197   if test "$targ_alias" = "all"; then
 198     all_targets=true
 199   else
 200     # Canonicalize the secondary target names.
 201     result=`$ac_config_sub $targ_alias 2>/dev/null`
 202     if test -n "$result"; then
 203         targ=$result
 204     else
 205         targ=$targ_alias
 206     fi
 207
 208     . ${srcdir}/configure.tgt
 209
 210     AS_IF([test -z "${gdb_target_obs}"],
 211       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 212
 213     # Target-specific object files
 214     for i in ${gdb_target_obs}; do
 215         case " $TARGET_OBS " in
 216         *" ${i} "*) ;;
 217         *)
 218           TARGET_OBS="$TARGET_OBS ${i}"
 219           ;;
 220         esac
 221     done
 222
 223     # Check whether this target needs 64-bit CORE_ADDR
 224     if test x${want64} = xfalse; then
 225       . ${srcdir}/../bfd/config.bfd
 226     fi
 227
 228     # Check whether this target is native and supports gcore.
 229     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 230        && $gdb_have_gcore; then
 231       HAVE_NATIVE_GCORE_TARGET=1
 232     fi
 233   fi
 234 done
 235
 236 if test x${all_targets} = xtrue; then
 237
 238   # We want all 64-bit targets if we either:
 239   #  - run on a 64-bit host  or
 240   #  - already require 64-bit support for some other target  or
 241   #  - the --enable-64-bit-bfd option was supplied
 242   # Otherwise we only support all 32-bit targets.
 243   #
 244   # NOTE: This test must be in sync with the corresponding
 245   #       tests in BFD!
 246
 247   if test x${want64} = xfalse; then
 248     AC_CHECK_SIZEOF(long)
 249     if test "x${ac_cv_sizeof_long}" = "x8"; then
 250       want64=true
 251     fi
 252   fi
 253   if test x${want64} = xtrue; then
 254     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 255   else
 256     TARGET_OBS='$(ALL_TARGET_OBS)'
 257   fi
 258 fi
 259
 260 AC_SUBST(TARGET_OBS)
 261 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 262
 263 # For other settings, only the main target counts.
 264 gdb_sim=
 265 gdb_osabi=
 266 targ=$target; . ${srcdir}/configure.tgt
 267
 268 # Fetch the default architecture and default target vector from BFD.
 269 targ=$target; . $srcdir/../bfd/config.bfd
 270
 271 # We only want the first architecture, so strip off the others if
 272 # there is more than one.
 273 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 274
 275 if test "x$targ_archs" != x; then
 276   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 277     [Define to BFD's default architecture. ])
 278 fi
 279 if test "x$targ_defvec" != x; then
 280   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 281     [Define to BFD's default target vector. ])
 282 fi
 283
 284 # Enable MI.
 285 AC_ARG_ENABLE(gdbmi,
 286 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 287   [case $enableval in
 288     yes | no)
 289       ;;
 290     *)
 291       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 292   esac],
 293   [enable_gdbmi=yes])
 294 if test x"$enable_gdbmi" = xyes; then
 295   if test -d "$srcdir/mi"; then
 296     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 297     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 298     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 299     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 300   fi
 301 fi
 302
 303 # Enable TUI.
 304 AC_ARG_ENABLE(tui,
 305 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 306   [case $enableval in
 307     yes | no | auto)
 308       ;;
 309     *)
 310       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 311   esac],enable_tui=auto)
 312
 313 # Enable gdbtk.
 314 AC_ARG_ENABLE(gdbtk,
 315 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 316   [case $enableval in
 317     yes | no)
 318       ;;
 319     *)
 320       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 321   esac],
 322   [if test -d "$srcdir/gdbtk"; then
 323     enable_gdbtk=yes
 324   else
 325     enable_gdbtk=no
 326   fi])
 327 # We unconditionally disable gdbtk tests on selected platforms.
 328 case $host_os in
 329   go32* | windows*)
 330     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 331     enable_gdbtk=no ;;
 332 esac
 333
 334 # Handle optional debuginfod support
 335 AC_DEBUGINFOD
 336
 337 # Libunwind support for ia64.
 338 AC_ARG_WITH(libunwind-ia64,
 339 AS_HELP_STRING([--with-libunwind-ia64],
 340                [use libunwind frame unwinding for ia64 targets]),,
 341             [with_libunwind_ia64=auto])
 342
 343 # Backward compatibility option.
 344 if test "${with_libunwind+set}" = set; then
 345   if test x"$with_libunwind_ia64" != xauto; then
 346     AC_MSG_ERROR(
 347       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 348   fi
 349   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 350   with_libunwind_ia64="$with_libunwind"
 351 fi
 352
 353 case "$with_libunwind_ia64" in
 354   yes | no)
 355     ;;
 356   auto)
 357     AC_CHECK_HEADERS(libunwind-ia64.h)
 358     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 359     ;;
 360   *)
 361     AC_MSG_ERROR(
 362       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 363     ;;
 364 esac
 365
 366 if test x"$with_libunwind_ia64" = xyes; then
 367   AC_CHECK_HEADERS(libunwind-ia64.h)
 368   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 369     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 370   fi
 371   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 372   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 373   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 374 fi
 375
 376 opt_curses=no
 377 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 378
 379 prefer_curses=no
 380 if test "$opt_curses" = "yes"; then
 381   prefer_curses=yes
 382 fi
 383
 384 # Profiling support.
 385 AC_ARG_ENABLE(profiling,
 386 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 387   [case $enableval in
 388     yes | no)
 389       ;;
 390     *)
 391       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 392   esac],
 393  [enable_profiling=no])
 394
 395 AC_CHECK_FUNCS(monstartup _mcleanup)
 396 AC_CACHE_CHECK(
 397   [for _etext],
 398   [ac_cv_var__etext],
 399   [AC_LINK_IFELSE(
 400      [AC_LANG_PROGRAM(
 401         [#include <stdlib.h>
 402          extern char _etext;],
 403         [free (&_etext);]
 404       )],
 405      [ac_cv_var__etext=yes],
 406      [ac_cv_var__etext=no]
 407    )]
 408 )
 409 if test "$ac_cv_var__etext" = yes; then
 410   AC_DEFINE(HAVE__ETEXT, 1,
 411             [Define to 1 if your system has the _etext variable. ])
 412 fi
 413 AC_CACHE_CHECK(
 414   [for etext],
 415   [ac_cv_var_etext],
 416   [AC_LINK_IFELSE(
 417      [AC_LANG_PROGRAM(
 418         [#include <stdlib.h>
 419          extern char etext;],
 420         [free (&etext);]
 421       )],
 422      [ac_cv_var_etext=yes],
 423      [ac_cv_var_etext=no]
 424    )]
 425 )
 426 if test "$ac_cv_var_etext" = yes; then
 427   AC_DEFINE(HAVE_ETEXT, 1,
 428             [Define to 1 if your system has the etext variable. ])
 429 fi
 430 if test "$enable_profiling" = yes ; then
 431   if test "$ac_cv_func_monstartup" = no || test "$ac_cv_func__mcleanup" = no; then
 432     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 433   fi
 434   PROFILE_CFLAGS=-pg
 435   OLD_CFLAGS="$CFLAGS"
 436   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 437
 438   AC_CACHE_CHECK(
 439     [whether $CC supports -pg],
 440     [ac_cv_cc_supports_pg],
 441     [AC_COMPILE_IFELSE(
 442        [AC_LANG_PROGRAM([], [int x;])],
 443        [ac_cv_cc_supports_pg=yes],
 444        [ac_cv_cc_supports_pg=no]
 445      )]
 446   )
 447
 448   if test "$ac_cv_cc_supports_pg" = no; then
 449     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 450   fi
 451
 452   CFLAGS="$OLD_CFLAGS"
 453 fi
 454
 455 CODESIGN_CERT=
 456 AC_ARG_ENABLE([codesign],
 457   AS_HELP_STRING([--enable-codesign=CERT],
 458                  [sign gdb with 'codesign -s CERT']),
 459   [CODESIGN_CERT=$enableval])
 460 AC_SUBST([CODESIGN_CERT])
 461
 462 ACX_PKGVERSION([GDB])
 463 ACX_BUGURL([https://www.gnu.org/software/gdb/bugs/])
 464 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 465 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 466
 467 # --------------------- #
 468 # Checks for programs.  #
 469 # --------------------- #
 470
 471 AC_PROG_AWK
 472 AC_PROG_INSTALL
 473 AC_PROG_LN_S
 474 AC_PROG_RANLIB
 475 AC_PROG_YACC
 476
 477 AC_CHECK_TOOL(AR, ar)
 478 AC_CHECK_TOOL(DLLTOOL, dlltool)
 479 AC_CHECK_TOOL(WINDRES, windres)
 480
 481 case $host_os in
 482   gnu*)
 483     # Needed for GNU Hurd hosts.
 484     AC_CHECK_TOOL(MIG, mig)
 485     if test x"$MIG" = x; then
 486       AC_MSG_ERROR([MIG not found but required for $host hosts])
 487     fi
 488     ;;
 489 esac
 490
 491 # ---------------------- #
 492 # Checks for libraries.  #
 493 # ---------------------- #
 494
 495 # We might need to link with -lm; most simulators need it.
 496 AC_CHECK_LIB(m, main)
 497
 498 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 499 AC_SEARCH_LIBS(gethostbyname, nsl)
 500
 501 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 502 AC_SEARCH_LIBS(socketpair, socket)
 503
 504 # Link in zlib if we can.  This allows us to read compressed debug sections.
 505 AM_ZLIB
 506
 507 AM_ICONV
 508
 509 # GDB may fork/exec the iconv program to get the list of supported character
 510 # sets.  Allow the user to specify where to find it.
 511 # There are several factors affecting the choice of option name:
 512 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 513 #   the build-time location of libiconv files.
 514 # - The program we need to find is iconv, which comes with glibc.  The user
 515 #   doesn't necessarily have libiconv installed.  Therefore naming this
 516 #   --with-libiconv-foo feels wrong.
 517 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 518 #   defined to work on directories not files (though it really doesn't know
 519 #   the difference).
 520 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 521 #   with --with-libiconv-prefix.
 522 # Putting these together is why the option name is --with-iconv-bin.
 523
 524 AC_ARG_WITH(iconv-bin,
 525 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 526 [iconv_bin="${withval}"
 527  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 528                     [Path of directory of iconv program.])
 529  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 530 ])
 531
 532 # For the TUI, we need enhanced curses functionality.
 533 if test x"$enable_tui" != xno; then
 534   prefer_curses=yes
 535 fi
 536
 537 curses_found=no
 538 if test x"$prefer_curses" = xyes; then
 539   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 540   # curses library because the latter might not provide all the
 541   # functionality we need.  However, this leads to problems on systems
 542   # where the linker searches /usr/local/lib, but the compiler doesn't
 543   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 544   # default installation of ncurses on alpha*-dec-osf* will lead to such
 545   # a situation.
 546   AC_SEARCH_LIBS(waddstr, [ncursesw ncurses cursesX curses])
 547
 548   if test "$ac_cv_search_waddstr" != no; then
 549     curses_found=yes
 550   fi
 551 fi
 552
 553 # Check whether we should enable the TUI, but only do so if we really
 554 # can.
 555 if test x"$enable_tui" != xno; then
 556   if test -d "$srcdir/tui"; then
 557     if test "$curses_found" != no; then
 558       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 559       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 560       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 561       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 562     else
 563       if test x"$enable_tui" = xyes; then
 564         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 565       else
 566         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 567       fi
 568     fi
 569   fi
 570 fi
 571
 572 # Since GDB uses Readline, we need termcap functionality.  In many
 573 # cases this will be provided by the curses library, but some systems
 574 # have a separate termcap library, or no curses library at all.
 575
 576 case $host_os in
 577   cygwin*)
 578     if test -d "$srcdir/libtermcap"; then
 579       LIBS="../libtermcap/libtermcap.a $LIBS"
 580       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 581     fi ;;
 582   go32* | *djgpp*)
 583     ac_cv_search_tgetent="none required"
 584     ;;
 585 esac
 586
 587 # These are the libraries checked by Readline.
 588 AC_SEARCH_LIBS(tgetent, [termcap tinfow tinfo curses ncursesw ncurses])
 589
 590 if test "$ac_cv_search_tgetent" = no; then
 591   CONFIG_OBS="$CONFIG_OBS stub-termcap.o"
 592 fi
 593
 594 AC_ARG_WITH([system-readline],
 595   [AS_HELP_STRING([--with-system-readline],
 596                   [use installed readline library])])
 597
 598 if test "$with_system_readline" = yes; then
 599   AC_CACHE_CHECK(
 600     [whether system readline is new enough],
 601     [gdb_cv_readline_ok],
 602     [AC_COMPILE_IFELSE(
 603        [AC_LANG_PROGRAM(
 604           [#include <stdio.h>
 605            #include <readline/readline.h>],
 606           [#if RL_VERSION_MAJOR < 7
 607            # error "readline version 7 required"
 608            #endif]
 609         )],
 610        [gdb_cv_readline_ok=yes],
 611        [gdb_cv_readline_ok=no]
 612      )]
 613   )
 614   if test "$gdb_cv_readline_ok" != yes; then
 615     AC_MSG_ERROR([system readline is not new enough])
 616   fi
 617
 618   READLINE=-lreadline
 619   READLINE_DEPS=
 620   READLINE_CFLAGS=
 621   READLINE_TEXI_INCFLAG=
 622 else
 623   READLINE='$(READLINE_DIR)/libreadline.a'
 624   READLINE_DEPS='$(READLINE)'
 625   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 626   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 627 fi
 628 AC_SUBST(READLINE)
 629 AC_SUBST(READLINE_DEPS)
 630 AC_SUBST(READLINE_CFLAGS)
 631 AC_SUBST(READLINE_TEXI_INCFLAG)
 632
 633 # Generate jit-reader.h
 634
 635 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 636 TARGET_PTR=
 637
 638 AC_CHECK_SIZEOF(unsigned long long)
 639 AC_CHECK_SIZEOF(unsigned long)
 640 AC_CHECK_SIZEOF(unsigned __int128)
 641
 642 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 643   TARGET_PTR="unsigned long"
 644 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 645   TARGET_PTR="unsigned long long"
 646 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 647   TARGET_PTR="unsigned __int128"
 648 else
 649   TARGET_PTR="unsigned long"
 650 fi
 651
 652 AC_SUBST(TARGET_PTR)
 653 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 654
 655 AC_SEARCH_LIBS(dlopen, dl)
 656
 657 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 658                 [directory to load the JIT readers from],
 659                 [${libdir}/gdb])
 660
 661 AC_ARG_WITH(expat,
 662   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 663   [], [with_expat=auto])
 664 AC_MSG_CHECKING([whether to use expat])
 665 AC_MSG_RESULT([$with_expat])
 666
 667 if test "${with_expat}" = no; then
 668   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 669   HAVE_LIBEXPAT=no
 670 else
 671   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 672                         [XML_Parser p = XML_ParserCreate (0);])
 673   if test "$HAVE_LIBEXPAT" != yes; then
 674     if test "$with_expat" = yes; then
 675       AC_MSG_ERROR([expat is missing or unusable])
 676     else
 677       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 678     fi
 679   else
 680     save_LIBS=$LIBS
 681     LIBS="$LIBS $LIBEXPAT"
 682     AC_CHECK_FUNCS(XML_StopParser)
 683     LIBS=$save_LIBS
 684   fi
 685 fi
 686
 687 # Verify that we have a usable GMP library.
 688 AC_LIB_HAVE_LINKFLAGS([gmp], [], [#include <gmp.h>],
 689                       [mpz_t n;
 690                        mpz_init (n);])
 691 if test "$HAVE_LIBGMP" != yes; then
 692   AC_MSG_ERROR([GMP is missing or unusable])
 693 fi
 694
 695 AC_ARG_WITH(mpfr,
 696   AS_HELP_STRING([--with-mpfr], [include MPFR support (auto/yes/no)]),
 697   [], [with_mpfr=auto])
 698 AC_MSG_CHECKING([whether to use MPFR])
 699 AC_MSG_RESULT([$with_mpfr])
 700
 701 if test "${with_mpfr}" = no; then
 702   AC_MSG_WARN([MPFR support disabled; some features may be unavailable.])
 703   HAVE_LIBMPFR=no
 704 else
 705   AC_LIB_HAVE_LINKFLAGS([mpfr], [gmp], [#include <mpfr.h>],
 706                         [mpfr_exp_t exp; mpfr_t x;
 707                          mpfr_frexp (&exp, x, x, MPFR_RNDN);])
 708   if test "$HAVE_LIBMPFR" != yes; then
 709     if test "$with_mpfr" = yes; then
 710       AC_MSG_ERROR([MPFR is missing or unusable])
 711     else
 712       AC_MSG_WARN([MPFR is missing or unusable; some features may be unavailable.])
 713     fi
 714   fi
 715 fi
 716
 717 # --------------------- #
 718 # Check for libpython.  #
 719 # --------------------- #
 720
 721 dnl Utility to simplify finding libpython.
 722 dnl $1 = the shell variable to assign the result to
 723 dnl      If libpython is found we store $version here.
 724 dnl $2 = additional flags to add to CPPFLAGS
 725 dnl $3 = additional flags to add to LIBS
 726
 727 AC_DEFUN([AC_TRY_LIBPYTHON],
 728 [
 729   define([have_libpython_var],$1)
 730   new_CPPFLAGS=$2
 731   new_LIBS=$3
 732   AC_MSG_CHECKING([for python])
 733   save_CPPFLAGS=$CPPFLAGS
 734   save_LIBS=$LIBS
 735   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 736   LIBS="$new_LIBS $LIBS"
 737   found_usable_python=no
 738   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "Python.h"]],
 739                                  [[Py_Initialize ();]])],
 740                  [have_libpython_var=yes
 741                   found_usable_python=yes
 742                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 743                   PYTHON_LIBS=$new_LIBS])
 744   CPPFLAGS=$save_CPPFLAGS
 745   LIBS=$save_LIBS
 746   AC_MSG_RESULT([${found_usable_python}])
 747 ])
 748
 749 dnl There are several different values for --with-python:
 750 dnl
 751 dnl no -   Don't include python support.
 752 dnl yes -  Include python support, error if it's missing.
 753 dnl        If we find python in $PATH, use it to fetch configure options,
 754 dnl        otherwise assume the compiler can find it with no help from us.
 755 dnl        Python 2.7 and 2.6 are tried in turn.
 756 dnl auto - Same as "yes", but if python is missing from the system,
 757 dnl        fall back to "no".
 758 dnl /path/to/python/exec-prefix -
 759 dnl        Use the python located in this directory.
 760 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 761 dnl        the compilation parameters.  Otherwise use
 762 dnl        -I/path/to/python/exec-prefix/include,
 763 dnl        -L/path/to/python/exec-prefix/lib.
 764 dnl        Python 2.7 and 2.6 are tried in turn.
 765 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 766 dnl        but is deprecated.
 767 dnl /path/to/python/executable -
 768 dnl        Run python-config.py with this version of python to fetch the
 769 dnl        compilation parameters.
 770 dnl        NOTE: This needn't be the real python executable.
 771 dnl        In a cross-compilation scenario (build != host), this could be
 772 dnl        a shell script that provides what python-config.py provides for
 773 dnl        --ldflags, --includes, --exec-prefix.
 774 dnl python-executable -
 775 dnl        Find python-executable in $PATH, and then handle the same as
 776 dnl        /path/to/python/executable.
 777 dnl
 778 dnl If a python program is specified, it is used to run python-config.py and
 779 dnl is passed --ldflags, --includes, --exec-prefix.
 780
 781 AC_ARG_WITH(python,
 782   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 783   [], [with_python=auto])
 784 AC_MSG_CHECKING([whether to use python])
 785 AC_MSG_RESULT([$with_python])
 786
 787 if test "${with_python}" = no; then
 788   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 789   have_libpython=no
 790 else
 791   case "${with_python}" in
 792   [[\\/]]* | ?:[[\\/]]*)
 793     if test -d "${with_python}"; then
 794       # Assume the python binary is ${with_python}/bin/python.
 795       python_prog="${with_python}/bin/python"
 796       python_prefix=
 797       # If python does not exit ${with_python}/bin, then try in
 798       # ${with_python}.  On Windows/MinGW, this is where the Python
 799       # executable is.
 800       if test ! -x "${python_prog}"; then
 801         python_prog="${with_python}/python"
 802         python_prefix=
 803       fi
 804       if test ! -x "${python_prog}"; then
 805         # Fall back to gdb 7.0/7.1 behaviour.
 806         python_prog=missing
 807         python_prefix=${with_python}
 808       fi
 809     elif test -x "${with_python}"; then
 810       # While we can't run python compiled for $host (unless host == build),
 811       # the user could write a script that provides the needed information,
 812       # so we support that.
 813       python_prog=${with_python}
 814       python_prefix=
 815     else
 816       AC_MSG_ERROR(invalid value for --with-python)
 817     fi
 818     ;;
 819   */*)
 820     # Disallow --with-python=foo/bar.
 821     AC_MSG_ERROR(invalid value for --with-python)
 822     ;;
 823   *)
 824     # The user has either specified auto, yes, or the name of the python
 825     # program assumed to be in $PATH.
 826     python_prefix=
 827     case "${with_python}" in
 828     yes | auto)
 829       if test "${build}" = "${host}"; then
 830         AC_PATH_PROG(python_prog_path, python, missing)
 831         if test "${python_prog_path}" = missing; then
 832           python_prog=missing
 833         else
 834           python_prog=${python_prog_path}
 835         fi
 836       else
 837         # Not much we can do except assume the cross-compiler will find the
 838         # right files.
 839         python_prog=missing
 840       fi
 841       ;;
 842     *)
 843       # While we can't run python compiled for $host (unless host == build),
 844       # the user could write a script that provides the needed information,
 845       # so we support that.
 846       python_prog="${with_python}"
 847       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 848       if test "${python_prog_path}" = missing; then
 849         AC_MSG_ERROR(unable to find python program ${python_prog})
 850       fi
 851       ;;
 852     esac
 853   esac
 854
 855   if test "${python_prog}" != missing; then
 856     # We have a python program to use, but it may be too old.
 857     # Don't flag an error for --with-python=auto (the default).
 858     have_python_config=yes
 859     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 860     if test $? != 0; then
 861       have_python_config=failed
 862       if test "${with_python}" != auto; then
 863         AC_MSG_ERROR(failure running python-config --includes)
 864       fi
 865     fi
 866     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 867     if test $? != 0; then
 868       have_python_config=failed
 869       if test "${with_python}" != auto; then
 870         AC_MSG_ERROR(failure running python-config --ldflags)
 871       fi
 872     fi
 873     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 874     if test $? != 0; then
 875       have_python_config=failed
 876       if test "${with_python}" != auto; then
 877         AC_MSG_ERROR(failure running python-config --exec-prefix)
 878       fi
 879     fi
 880   else
 881     # We do not have a python executable we can use to determine where
 882     # to find the Python headers and libs.  We cannot guess the include
 883     # path from the python_prefix either, because that include path
 884     # depends on the Python version.  So, there is nothing much we can
 885     # do except assume that the compiler will be able to find those files.
 886     python_includes=
 887     python_libs=
 888     have_python_config=no
 889   fi
 890
 891   # If we have python-config, only try the configuration it provides.
 892   # Otherwise fallback on the old way of trying different versions of
 893   # python in turn.
 894
 895   have_libpython=no
 896   if test "${have_python_config}" = yes; then
 897     AC_TRY_LIBPYTHON(have_libpython,
 898                      ${python_includes}, ${python_libs})
 899   elif test "${have_python_config}" != failed; then
 900     if test "${have_libpython}" = no; then
 901       AC_TRY_LIBPYTHON(have_libpython,
 902                        ${python_includes}, "-lpython2.7 ${python_libs}")
 903     fi
 904     if test "${have_libpython}" = no; then
 905       AC_TRY_LIBPYTHON(have_libpython,
 906                        ${python_includes}, "-lpython2.6 ${python_libs}")
 907     fi
 908   fi
 909
 910   if test "${have_libpython}" = no; then
 911     case "${with_python}" in
 912     yes)
 913       AC_MSG_ERROR([python is missing or unusable])
 914       ;;
 915     auto)
 916       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 917       ;;
 918     *)
 919       AC_MSG_ERROR([no usable python found at ${with_python}])
 920       ;;
 921     esac
 922   else
 923     if test -n "${python_prefix}"; then
 924       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 925                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 926       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 927     fi
 928   fi
 929 fi
 930
 931 dnl Use --with-python-libdir to control where GDB looks for the Python
 932 dnl libraries.
 933 dnl
 934 dnl If this is not given then the default will be based on the value
 935 dnl passed to --with-python, which is in the python_prefix variable.
 936 dnl If the --with-python option wasn't given then the default value in
 937 dnl python_prefix is based on running the 'gdb/python/python-config
 938 dnl --exec-prefix' script.
 939 AC_ARG_WITH(python-libdir,
 940   AS_HELP_STRING([--with-python-libdir@<:@=DIR@:>@], [search for python's libraries in DIR]),
 941   [],[
 942     # If no python libdir is specified then select one based on
 943     # python's prefix path.
 944     if test -n "${python_prefix}"; then
 945       with_python_libdir=${python_prefix}/lib
 946     fi
 947   ])
 948
 949 if test "${have_libpython}" != no; then
 950   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 951   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 952   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 953   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 954   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 955   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 956
 957   if test -n "${with_python_libdir}"; then
 958     AC_DEFINE_UNQUOTED(WITH_PYTHON_LIBDIR, "${with_python_libdir}",
 959                        [Directory containing Python's standard libraries from --with-python-libdir.])
 960     GDB_AC_DEFINE_RELOCATABLE(PYTHON_LIBDIR, [python lib], ${with_python_libdir})
 961   fi
 962
 963   # Flags needed to compile Python code (taken from python-config --cflags).
 964   # We cannot call python-config directly because it will output whatever was
 965   # used when compiling the Python interpreter itself, including flags which
 966   # would make the python-related objects be compiled differently from the
 967   # rest of GDB (e.g., -O2 and -fPIC).
 968   if test "${GCC}" = yes; then
 969     tentative_python_cflags="-fno-strict-aliasing -fwrapv"
 970     # Python headers recommend -DNDEBUG, but it's unclear if that just
 971     # refers to building Python itself.  In release mode, though, it
 972     # doesn't hurt for the Python code in gdb to follow.
 973     $development || tentative_python_cflags="$tentative_python_cflags -DNDEBUG"
 974   fi
 975
 976   if test "x${tentative_python_cflags}" != x; then
 977     AC_MSG_CHECKING(compiler flags for python code)
 978     for flag in ${tentative_python_cflags}; do
 979       # Check that the compiler accepts it
 980       saved_CFLAGS="$CFLAGS"
 981       CFLAGS="$CFLAGS $flag"
 982       AC_COMPILE_IFELSE(
 983         [AC_LANG_PROGRAM([], [])],
 984         [PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag"],
 985         []
 986       )
 987       CFLAGS="$saved_CFLAGS"
 988     done
 989     AC_MSG_RESULT(${PYTHON_CFLAGS})
 990   fi
 991
 992   # On x64 Windows, Python's include headers, and pyconfig.h in
 993   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
 994   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
 995   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
 996   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
 997   # The issue was reported to the Python community, but still isn't
 998   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
 999
1000   case "$gdb_host" in
1001     mingw64)
1002            if test "${GCC}" = yes; then
1003              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
1004            fi
1005            ;;
1006   esac
1007 else
1008   # Even if Python support is not compiled in, we need to have this file
1009   # included so that the "python" command, et.al., still exists.
1010   CONFIG_OBS="$CONFIG_OBS python/python.o"
1011   CONFIG_SRCS="$CONFIG_SRCS python/python.c"
1012 fi
1013
1014 # Work around Python http://bugs.python.org/issue10112.  See also
1015 # http://bugs.python.org/issue11410, otherwise -Wl,--dynamic-list has
1016 # no effect.  Note that the only test after this that uses Python is
1017 # the -rdynamic/-Wl,--dynamic-list test, and we do want that one to be
1018 # run without -export-dynamic too.
1019 PYTHON_LIBS=`echo $PYTHON_LIBS | sed -e 's/-Xlinker -export-dynamic//'`
1020
1021 AC_SUBST(PYTHON_CFLAGS)
1022 AC_SUBST(PYTHON_CPPFLAGS)
1023 AC_SUBST(PYTHON_LIBS)
1024 AM_CONDITIONAL(HAVE_PYTHON, test "${have_libpython}" != no)
1025
1026 # -------------------- #
1027 # Check for libguile.  #
1028 # -------------------- #
1029
1030 dnl Utility to simplify finding libguile.
1031 dnl $1 = pkg-config-program
1032 dnl $2 = space-separate list of guile versions to try
1033 dnl $3 = yes|no, indicating whether to flag errors or ignore them
1034 dnl $4 = the shell variable to assign the result to
1035 dnl      If libguile is found we store "yes" here.
1036
1037 AC_DEFUN([AC_TRY_LIBGUILE],
1038 [
1039   pkg_config=$1
1040   guile_version_list=$2
1041   flag_errors=$3
1042   define([have_libguile_var],$4)
1043   found_usable_guile=checking
1044   AC_MSG_CHECKING([for usable guile from ${pkg_config}])
1045   for guile_version in ${guile_version_list}; do
1046     ${pkg_config} --exists ${guile_version} 2>/dev/null
1047     if test $? != 0; then
1048       continue
1049     fi
1050     dnl pkg-config says the package exists, so if we get an error now,
1051     dnl that's bad.
1052     new_CPPFLAGS=`${pkg_config} --cflags ${guile_version}`
1053     if test $? != 0; then
1054       AC_MSG_ERROR([failure running pkg-config --cflags ${guile_version}])
1055     fi
1056     new_LIBS=`${pkg_config} --libs ${guile_version}`
1057     if test $? != 0; then
1058       AC_MSG_ERROR([failure running pkg-config --libs ${guile_version}])
1059     fi
1060     dnl If we get this far, great.
1061     found_usable_guile=${guile_version}
1062     break
1063   done
1064   if test "${found_usable_guile}" = "checking"; then
1065     if test "${flag_errors}" = "yes"; then
1066       AC_MSG_ERROR([unable to find usable guile version from "${guile_version_list}"])
1067     else
1068       found_usable_guile=no
1069     fi
1070   fi
1071   dnl One final sanity check.
1072   dnl The user could have said --with-guile=python-2.7.
1073   if test "${found_usable_guile}" != no; then
1074     save_CPPFLAGS=$CPPFLAGS
1075     save_LIBS=$LIBS
1076     CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
1077     LIBS="$LIBS $new_LIBS"
1078     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "libguile.h"]],
1079                                    [[scm_init_guile ();]])],
1080                    [have_libguile_var=yes
1081                     GUILE_CPPFLAGS=$new_CPPFLAGS
1082                     GUILE_LIBS=$new_LIBS],
1083                    [found_usable_guile=no])
1084     dnl scm_set_automatic_finalization_enabled added in Guile 2.2.
1085     AC_CHECK_FUNC(scm_set_automatic_finalization_enabled,
1086       AC_DEFINE(HAVE_GUILE_MANUAL_FINALIZATION, 1,
1087                 [Define if Guile supports manual finalization.])
1088     )
1089     CPPFLAGS=$save_CPPFLAGS
1090     LIBS=$save_LIBS
1091     if test "${found_usable_guile}" = no; then
1092       if test "${flag_errors}" = yes; then
1093         AC_MSG_FAILURE([linking guile version ${guile_version} test program failed])
1094       fi
1095     fi
1096   fi
1097   AC_MSG_RESULT([${found_usable_guile}])
1098 ])
1099
1100 dnl There are several different values for --with-guile:
1101 dnl
1102 dnl no -   Don't include guile support.
1103 dnl yes -  Include guile support, error if it's missing.
1104 dnl        The pkg-config program must be in $PATH.
1105 dnl auto - Same as "yes", but if guile is missing from the system,
1106 dnl        fall back to "no".
1107 dnl guile-version [guile-version-choice-2 ...] -
1108 dnl        A space-separated list of guile package versions to try.
1109 dnl        These are passed to pkg-config as-is.
1110 dnl        E.g., guile-2.0 or guile-2.2-uninstalled
1111 dnl        This requires making sure PKG_CONFIG_PATH is set appropriately.
1112 dnl /path/to/pkg-config -
1113 dnl        Use this pkg-config program.
1114 dnl        NOTE: This needn't be the "real" pkg-config program.
1115 dnl        It could be a shell script.  It is invoked as:
1116 dnl        pkg-config --exists $version
1117 dnl        pkg-config --cflags $version
1118 dnl        pkg-config --libs $version
1119 dnl        pkg-config --variable guild $version
1120 dnl        The script will be called with $version having each value in
1121 dnl        $try_guile_versions until --exists indicates success.
1122
1123 AC_ARG_WITH(guile,
1124   AS_HELP_STRING([--with-guile@<:@=GUILE@:>@], [include guile support (auto/yes/no/<guile-version>/<pkg-config-program>)]),
1125   [], [with_guile=auto])
1126 AC_MSG_CHECKING([whether to use guile])
1127 AC_MSG_RESULT([$with_guile])
1128
1129 dnl We check guile with pkg-config.
1130 AC_PATH_PROG(pkg_config_prog_path, pkg-config, missing)
1131
1132 try_guile_versions="guile-3.0 guile-2.2 guile-2.0"
1133 have_libguile=no
1134 case "${with_guile}" in
1135 no)
1136   AC_MSG_WARN([guile support disabled; some features will be unavailable.])
1137   ;;
1138 auto)
1139   if test "${pkg_config_prog_path}" = "missing"; then
1140     AC_MSG_WARN([pkg-config not found, guile support disabled])
1141   else
1142     AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, no, have_libguile)
1143   fi
1144   ;;
1145 yes)
1146   if test "${pkg_config_prog_path}" = "missing"; then
1147     AC_MSG_ERROR([pkg-config not found])
1148   fi
1149   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, yes, have_libguile)
1150   ;;
1151 [[\\/]]* | ?:[[\\/]]*)
1152   if test -x "${with_guile}"; then
1153     AC_TRY_LIBGUILE(${with_guile}, ${try_guile_versions}, yes, have_libguile)
1154   else
1155     AC_MSG_ERROR([Guile config program not executable: ${with_guile}])
1156   fi
1157   ;;
1158 "" | */*)
1159   # Disallow --with=guile="" and --with-guile=foo/bar.
1160   AC_MSG_ERROR([invalid value for --with-guile])
1161   ;;
1162 *)
1163   # A space separate list of guile versions to try, in order.
1164   if test "${pkg_config_prog_path}" = "missing"; then
1165     AC_MSG_ERROR([pkg-config not found])
1166   fi
1167   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${with_guile}, yes, have_libguile)
1168   ;;
1169 esac
1170
1171 if test "${have_libguile}" != no; then
1172   dnl Get the name of the 'guild' program.
1173   case "${with_guile}" in
1174   [[\\/]]* | ?:[[\\/]]*)
1175     GDB_GUILE_PROGRAM_NAMES(["${with_guile}"], ["${guile_version}"])
1176     ;;
1177   *)
1178     GDB_GUILE_PROGRAM_NAMES(["${pkg_config_prog_path}"], ["${guile_version}"])
1179     ;;
1180   esac
1181
1182   dnl Make sure guild can handle this host.
1183   GDB_TRY_GUILD([$srcdir/guile/lib/gdb/support.scm])
1184   dnl If not, disable guile support.
1185   if test "$ac_cv_guild_ok" = no; then
1186     have_libguile=no
1187     AC_MSG_WARN(disabling guile support, $GUILD fails compiling for $host)
1188   fi
1189 fi
1190
1191 if test "${have_libguile}" != no; then
1192   AC_DEFINE(HAVE_GUILE, 1, [Define if Guile interpreter is being linked in.])
1193   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_GUILE_OBS)"
1194   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_GUILE_DEPS)"
1195   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_GUILE_SRCS)"
1196   CONFIG_INSTALL="$CONFIG_INSTALL install-guile"
1197   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_GUILE_CFLAGS)"
1198
1199   dnl The 'scm_new_smob' function appeared in Guile 2.0.6.
1200   save_LIBS="$LIBS"
1201   save_CPPFLAGS="$CPPFLAGS"
1202   LIBS="$GUILE_LIBS"
1203   CPPFLAGS="$GUILE_CPPFLAGS"
1204   AC_CHECK_FUNCS([scm_new_smob])
1205   LIBS="$save_LIBS"
1206   CPPFLAGS="$save_CPPFLAGS"
1207 else
1208   # Even if Guile support is not compiled in, we need to have these files
1209   # included.
1210   CONFIG_OBS="$CONFIG_OBS guile/guile.o"
1211   CONFIG_SRCS="$CONFIG_SRCS guile/guile.c"
1212 fi
1213 AC_SUBST(GUILE_CPPFLAGS)
1214 AC_SUBST(GUILE_LIBS)
1215 AM_CONDITIONAL(HAVE_GUILE, test "${have_libguile}" != no)
1216
1217 # ---------------------------- #
1218 # Check for source highlight.  #
1219 # ---------------------------- #
1220
1221 SRCHIGH_LIBS=
1222 SRCHIGH_CFLAGS=
1223
1224 AC_ARG_ENABLE(source-highlight,
1225   AS_HELP_STRING([--enable-source-highlight],
1226     [enable source-highlight for source listings]),
1227   [case "${enableval}" in
1228   yes)  enable_source_highlight=yes ;;
1229   no)   enable_source_highlight=no  ;;
1230   *)    AC_MSG_ERROR(bad value ${enableval} for source-highlight option) ;;
1231 esac],
1232 [enable_source_highlight=auto])
1233
1234 if test "${enable_source_highlight}" != "no"; then
1235   AC_MSG_CHECKING([for the source-highlight library])
1236   if test "${pkg_config_prog_path}" = "missing"; then
1237     AC_MSG_RESULT([no - pkg-config not found])
1238     if test "${enable_source_highlight}" = "yes"; then
1239       AC_MSG_ERROR([pkg-config was not found in your system])
1240     fi
1241   else
1242     if ${pkg_config_prog_path} --exists source-highlight; then
1243       case "$LDFLAGS" in
1244         *static-libstdc*)
1245           AC_MSG_ERROR([source highlight is incompatible with -static-libstdc++; dnl
1246 either use --disable-source-highlight or dnl
1247 --without-static-standard-libraries])
1248           ;;
1249       esac
1250
1251       srchigh_pkg_cflags=`${pkg_config_prog_path} --cflags source-highlight`
1252       srchigh_pkg_libs=`${pkg_config_prog_path} --libs source-highlight`
1253
1254       # Now that we have found a source-highlight library, check if we can use
1255       # it.  In particular, we're trying to detect the situation that the
1256       # library is using the new libstdc++ library abi ( see
1257       # https://gcc.gnu.org/onlinedocs/libstdc++/manual/using_dual_abi.html )
1258       # while the compiler being used to compile gdb is using the old abi.
1259       # Such a situation will result in an undefined reference to
1260       # srchilite::SourceHighlight::SourceHighlight(std::string const&).
1261       # This situation can occur for instance when using a source highlight
1262       # library compiled with g++ 7.5.0 while building gdb with g++ 4.8.5.
1263       AC_LANG_PUSH(C++)
1264       save_CFLAGS=$CFLAGS
1265       save_LDFLAGS=$LDFLAGS
1266       CFLAGS="$CFLAGS $srchigh_pkg_cflags"
1267       LDFLAGS="$LDFLAGS $srchigh_pkg_libs"
1268       AC_LINK_IFELSE(
1269         [AC_LANG_PROGRAM(
1270           [#include <srchilite/sourcehighlight.h>],
1271           [std::string outlang = "esc.outlang";
1272            new srchilite::SourceHighlight (outlang);]
1273         )],
1274         [have_usable_source_highlight=yes],
1275         [have_usable_source_highlight=no]
1276       )
1277       CFLAGS="$SAVE_CFLAGS"
1278       LDFLAGS="$SAVE_LDFLAGS"
1279       AC_LANG_POP(C++)
1280
1281       if test "${have_usable_source_highlight}" = "yes"; then
1282         AC_DEFINE([HAVE_SOURCE_HIGHLIGHT], 1,
1283                   [Define to 1 if the source-highlight library is available])
1284         AC_MSG_RESULT([yes])
1285         SRCHIGH_CFLAGS="$srchigh_pkg_cflags"
1286         SRCHIGH_LIBS="$srchigh_pkg_libs"
1287       else
1288         AC_MSG_RESULT([no])
1289         if test "${enable_source_highlight}" = "yes"; then
1290           AC_MSG_ERROR([source-highlight in your system could not be used])
1291         fi
1292       fi
1293     else
1294       AC_MSG_RESULT([no])
1295       if test "${enable_source_highlight}" = "yes"; then
1296         AC_MSG_ERROR([source-highlight was not found in your system])
1297       fi
1298     fi
1299   fi
1300 fi
1301 AC_SUBST(SRCHIGH_LIBS)
1302 AC_SUBST(SRCHIGH_CFLAGS)
1303
1304 # ------------------------- #
1305 # Checks for header files.  #
1306 # ------------------------- #
1307
1308 AC_HEADER_STDC
1309 # elf_hp.h is for HP/UX 64-bit shared library support.
1310 AC_CHECK_HEADERS([nlist.h machine/reg.h \
1311                   thread_db.h \
1312                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1313                   sys/procctl.h sys/resource.h sys/ptrace.h ptrace.h \
1314                   sys/reg.h sys/debugreg.h \
1315                   termios.h elf_hp.h])
1316 AC_CHECK_HEADERS(sys/user.h, [], [],
1317 [#if HAVE_SYS_PARAM_H
1318 # include <sys/param.h>
1319 #endif
1320 ])
1321
1322 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncursesw/ncurses.h ncurses/ncurses.h ncurses/term.h)
1323 AC_CHECK_HEADERS(term.h, [], [],
1324 [#if HAVE_CURSES_H
1325 # include <curses.h>
1326 #endif
1327 ])
1328
1329 AC_CHECK_HEADERS([sys/socket.h])
1330 AC_CHECK_HEADERS([ws2tcpip.h])
1331 AC_CHECK_HEADERS([execinfo.h])
1332
1333 # ------------------------- #
1334 # Checks for declarations.  #
1335 # ------------------------- #
1336
1337 libiberty_INIT
1338
1339 AC_CHECK_DECLS([snprintf])
1340 AM_LC_MESSAGES
1341
1342 # ------------------ #
1343 # Checks for types.  #
1344 # ------------------ #
1345
1346 AC_CHECK_TYPES(socklen_t, [], [],
1347 [#include <sys/types.h>
1348 #if HAVE_SYS_SOCKET_H
1349 # include <sys/socket.h>
1350 #elif HAVE_WS2TCPIP_H
1351 # include <ws2tcpip.h>
1352 #endif
1353 ])
1354
1355 # ------------------------------------- #
1356 # Checks for compiler characteristics.  #
1357 # ------------------------------------- #
1358
1359 AC_C_CONST
1360 AC_C_INLINE
1361 AC_C_BIGENDIAN
1362
1363 # ------------------------------ #
1364 # Checks for library functions.  #
1365 # ------------------------------ #
1366
1367 AC_CHECK_FUNCS([getuid getgid \
1368                 pipe pread pread64 pwrite resize_term \
1369                 getpgid setsid \
1370                 sigaction sigsetmask socketpair \
1371                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1372                 setrlimit getrlimit posix_madvise waitpid \
1373                 use_default_colors])
1374 AM_LANGINFO_CODESET
1375 GDB_AC_COMMON
1376
1377 # Check the return and argument types of ptrace.
1378 GDB_AC_PTRACE
1379
1380 dnl AC_FUNC_SETPGRP does not work when cross compiling
1381 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1382 if test "$cross_compiling" = no; then
1383   AC_FUNC_SETPGRP
1384 else
1385   AC_CACHE_CHECK(
1386     [whether setpgrp takes no argument],
1387     [ac_cv_func_setpgrp_void],
1388     [AC_COMPILE_IFELSE(
1389        [AC_LANG_PROGRAM(
1390           [#include <unistd.h>],
1391           [if (setpgrp(1,1) == -1)
1392              exit (0);
1393            else
1394              exit (1);]
1395         )],
1396        [ac_cv_func_setpgrp_void=no],
1397        [ac_cv_func_setpgrp_void=yes]
1398      )]
1399   )
1400 if test "$ac_cv_func_setpgrp_void" = yes; then
1401   AC_DEFINE(SETPGRP_VOID, 1)
1402 fi
1403 fi
1404
1405 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1406 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1407 [#include <sys/param.h>
1408 #include <sys/proc.h>
1409 ])
1410
1411 # See if <sys/lwp.h> defines `struct lwp`.
1412 AC_CACHE_CHECK(
1413   [for struct lwp],
1414   [gdb_cv_struct_lwp],
1415   [AC_COMPILE_IFELSE(
1416      [AC_LANG_PROGRAM(
1417         [#include <sys/param.h>
1418          #define _KMEMUSER
1419          #include <sys/lwp.h>],
1420         [struct lwp l;]
1421       )],
1422      [gdb_cv_struct_lwp=yes],
1423      [gdb_cv_struct_lwp=no]
1424    )]
1425 )
1426 if test "$gdb_cv_struct_lwp" = yes; then
1427   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1428             [Define to 1 if your system has struct lwp.])
1429 fi
1430
1431 # See if <machine/reg.h> degines `struct reg'.
1432 AC_CACHE_CHECK(
1433   [for struct reg in machine/reg.h],
1434   [gdb_cv_struct_reg],
1435   [AC_COMPILE_IFELSE(
1436      [AC_LANG_PROGRAM(
1437         [#include <sys/types.h>
1438          #include <machine/reg.h>],
1439         [struct reg r;]
1440       )],
1441      [gdb_cv_struct_reg=yes],
1442      [gdb_cv_struct_reg=no]
1443    )]
1444 )
1445 if test "$gdb_cv_struct_reg" = yes; then
1446   AC_DEFINE(HAVE_STRUCT_REG, 1,
1447             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1448 fi
1449
1450 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1451 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1452 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1453                  [#include <sys/types.h>
1454 #include <machine/reg.h>])
1455
1456 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1457 AC_MSG_CHECKING(for PTRACE_GETREGS)
1458 AC_CACHE_VAL(
1459   [gdb_cv_have_ptrace_getregs],
1460   [AC_COMPILE_IFELSE(
1461     [AC_LANG_PROGRAM([#include <sys/ptrace.h>], [PTRACE_GETREGS;])],
1462     [gdb_cv_have_ptrace_getregs=yes],
1463     [gdb_cv_have_ptrace_getregs=no]
1464    )]
1465 )
1466 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1467 if test "$gdb_cv_have_ptrace_getregs" = yes; then
1468   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1469   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1470 fi
1471
1472 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1473 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1474 AC_CACHE_VAL(
1475   [gdb_cv_have_ptrace_getfpxregs],
1476   [AC_COMPILE_IFELSE(
1477      [AC_LANG_PROGRAM([#include <sys/ptrace.h>], [PTRACE_GETFPXREGS;])],
1478      [gdb_cv_have_ptrace_getfpxregs=yes],
1479      [gdb_cv_have_ptrace_getfpxregs=no]
1480    )]
1481 )
1482 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1483 if test "$gdb_cv_have_ptrace_getfpxregs" = yes; then
1484   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1485   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1486 fi
1487
1488 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1489 AC_MSG_CHECKING(for PT_GETDBREGS)
1490 AC_CACHE_VAL(
1491   [gdb_cv_have_pt_getdbregs],
1492   [AC_COMPILE_IFELSE(
1493      [AC_LANG_PROGRAM(
1494         [#include <sys/types.h>
1495          #include <sys/ptrace.h>],
1496         [PT_GETDBREGS;]
1497       )],
1498      [gdb_cv_have_pt_getdbregs=yes],
1499      [gdb_cv_have_pt_getdbregs=no]
1500    )]
1501 )
1502 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1503 if test "$gdb_cv_have_pt_getdbregs" = yes; then
1504   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1505   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1506 fi
1507
1508 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1509 AC_MSG_CHECKING(for PT_GETXMMREGS)
1510 AC_CACHE_VAL(
1511   [gdb_cv_have_pt_getxmmregs],
1512   [AC_COMPILE_IFELSE(
1513      [AC_LANG_PROGRAM(
1514         [#include <sys/types.h>
1515          #include <sys/ptrace.h>],
1516         [PT_GETXMMREGS;]
1517       )],
1518      [gdb_cv_have_pt_getxmmregs=yes],
1519      [gdb_cv_have_pt_getxmmregs=no]
1520    )]
1521 )
1522 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1523 if test "$gdb_cv_have_pt_getxmmregs" = yes; then
1524   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1525   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1526 fi
1527
1528 # See if <sys/ptrace.h> supports LWP names on FreeBSD
1529 # Older FreeBSD versions don't have the pl_tdname member of
1530 # `struct ptrace_lwpinfo'.
1531 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_tdname], [], [],
1532                  [#include <sys/ptrace.h>])
1533
1534 # See if <sys/ptrace.h> supports syscall fields on FreeBSD.  The
1535 # pl_syscall_code member of `struct ptrace_lwpinfo' was added in
1536 # FreeBSD 10.3.
1537 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_syscall_code], [], [],
1538                  [#include <sys/ptrace.h>])
1539
1540 # Check if the compiler supports the `long long' type.
1541
1542 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1543                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1544 [[extern long long foo;]],
1545 [[switch (foo & 2) { case 0: return 1; }]])],
1546                                   gdb_cv_c_long_long=yes,
1547                                   gdb_cv_c_long_long=no)])
1548 if test "$gdb_cv_c_long_long" != yes; then
1549   # libdecnumber requires long long.
1550   AC_MSG_ERROR([Compiler must support long long for GDB.])
1551 fi
1552
1553 # Check if the compiler and runtime support printing decfloats.
1554
1555 AC_CACHE_CHECK([for decfloat support in printf],
1556                gdb_cv_printf_has_decfloat,
1557                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1558 [[char buf[64];
1559   _Decimal32 d32 = 1.2345df;
1560   _Decimal64 d64 = 1.2345dd;
1561   _Decimal128 d128 = 1.2345dl;
1562   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1563   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1564                               gdb_cv_printf_has_decfloat=yes,
1565                               gdb_cv_printf_has_decfloat=no,
1566                               gdb_cv_printf_has_decfloat=no)])
1567 if test "$gdb_cv_printf_has_decfloat" = yes; then
1568   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1569             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1570 fi
1571
1572 # Check if the compiler supports the `long double' type.  We can't use
1573 # AC_C_LONG_DOUBLE because that one does additional checks on the
1574 # constants defined in <float.h> that fail on some systems,
1575 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1576
1577 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1578                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1579                                   gdb_cv_c_long_double=yes,
1580                                   gdb_cv_c_long_double=no)])
1581 if test "$gdb_cv_c_long_double" = yes; then
1582   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1583            [Define to 1 if the compiler supports long double.])
1584 fi
1585
1586 # Check if the compiler and runtime support printing long doubles.
1587
1588 AC_CACHE_CHECK([for long double support in printf],
1589                gdb_cv_printf_has_long_double,
1590                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1591 [[char buf[16];
1592   long double f = 3.141592653;
1593   sprintf (buf, "%Lg", f);
1594   return (strncmp ("3.14159", buf, 7));]])],
1595                               gdb_cv_printf_has_long_double=yes,
1596                               gdb_cv_printf_has_long_double=no,
1597                               gdb_cv_printf_has_long_double=no)])
1598 if test "$gdb_cv_printf_has_long_double" = yes; then
1599   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1600             [Define to 1 if the "%Lg" format works to print long doubles.])
1601 fi
1602
1603 # Check if the compiler and runtime support scanning long doubles.
1604
1605 AC_CACHE_CHECK([for long double support in scanf],
1606                gdb_cv_scanf_has_long_double,
1607                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1608 [[#include <stdio.h>]],
1609 [[char *buf = "3.141592653";
1610   long double f = 0;
1611   sscanf (buf, "%Lg", &f);
1612   return !(f > 3.14159 && f < 3.14160);]])],
1613                               gdb_cv_scanf_has_long_double=yes,
1614                               gdb_cv_scanf_has_long_double=no,
1615                               gdb_cv_scanf_has_long_double=no)])
1616 if test "$gdb_cv_scanf_has_long_double" = yes; then
1617   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1618             [Define to 1 if the "%Lg" format works to scan long doubles.])
1619 fi
1620
1621 case ${host_os} in
1622 aix*)
1623   AC_CACHE_CHECK(
1624     [for -bbigtoc option], [gdb_cv_bigtoc],
1625     [SAVE_LDFLAGS=$LDFLAGS
1626
1627      case $GCC in
1628        yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1629        *) gdb_cv_bigtoc=-bbigtoc ;;
1630      esac
1631
1632      LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1633      AC_LINK_IFELSE(
1634        [AC_LANG_PROGRAM([], [int i;])],
1635        [],
1636        [gdb_cv_bigtoc=]
1637      )
1638      LDFLAGS="${SAVE_LDFLAGS}"]
1639   )
1640   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1641   ;;
1642 esac
1643
1644 AC_MSG_CHECKING(for the dynamic export flag)
1645 dynamic_list=false
1646 if test "${gdb_native}" = yes; then
1647    # The dynamically loaded libthread_db needs access to symbols in the gdb
1648    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1649    # may not be supported there.
1650    old_LDFLAGS="$LDFLAGS"
1651    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1652    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1653    LDFLAGS="$LDFLAGS $RDYNAMIC"
1654    if test "${have_libpython}" = no; then
1655      AC_LINK_IFELSE(
1656        [AC_LANG_PROGRAM([], [])],
1657        [dynamic_list=true],
1658        []
1659      )
1660    else
1661      # Workaround http://bugs.python.org/issue4434 where static
1662      # libpythonX.Y.a would get its symbols required for
1663      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1664      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1665
1666      # Note the workaround for Python
1667      # http://bugs.python.org/issue10112 earlier has removed
1668      # -export-dynamic from PYTHON_LIBS.  That's exactly what we want
1669      # here too, as otherwise it'd make this -Wl,--dynamic-list test
1670      # always pass.
1671      old_CFLAGS="$CFLAGS"
1672      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1673      old_LIBS="$LIBS"
1674      LIBS="$LIBS $PYTHON_LIBS"
1675      old_CPPFLAGS="$CPPFLAGS"
1676      CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
1677      AC_RUN_IFELSE(
1678        [AC_LANG_PROGRAM(
1679          [#include "Python.h"],
1680          [int err;
1681           Py_Initialize ();
1682           err = PyRun_SimpleString ("import ctypes\n");
1683           Py_Finalize ();
1684           return err == 0 ? 0 : 1;])],
1685        [dynamic_list=true], [], [true])
1686      LIBS="$old_LIBS"
1687      CFLAGS="$old_CFLAGS"
1688      CPPFLAGS="$old_CPPFLAGS"
1689    fi
1690    LDFLAGS="$old_LDFLAGS"
1691 fi
1692 if $dynamic_list; then
1693   found="-Wl,--dynamic-list"
1694   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1695 else
1696   found="-rdynamic"
1697   RDYNAMIC="-rdynamic"
1698 fi
1699 AC_SUBST(RDYNAMIC)
1700 AC_MSG_RESULT($found)
1701
1702 AC_CACHE_CHECK(
1703   [whether execinfo.h backtrace is available],
1704   gdb_cv_execinfo_backtrace,
1705   [AC_LINK_IFELSE(
1706      [AC_LANG_PROGRAM(
1707         [
1708          #include <execinfo.h>
1709         ],
1710         [
1711          int f;
1712          void *b[[2]];
1713          f = backtrace (b, 2);
1714          backtrace_symbols_fd (b, f, 2);
1715         ])],
1716    [gdb_cv_execinfo_backtrace=yes],
1717    [gdb_cv_execinfo_backtrace=no])])
1718 if test "$gdb_cv_execinfo_backtrace" = yes; then
1719   AC_DEFINE(HAVE_EXECINFO_BACKTRACE, 1,
1720             [Define to 1 if execinfo.h backtrace functions are available.])
1721 fi
1722
1723 dnl For certain native configurations, we need to check whether thread
1724 dnl support can be built in or not.
1725 dnl
1726 dnl Note that we only want this if we are both native (host == target),
1727 dnl and not doing a canadian cross build (build == host).
1728
1729 if test "${build}" = "${host}" -a "${host}" = "${target}" ; then
1730    case ${host_os} in
1731    aix*)
1732       AC_MSG_CHECKING(for AiX thread debugging library)
1733       AC_CACHE_VAL(
1734         [gdb_cv_have_aix_thread_debug],
1735         [AC_COMPILE_IFELSE(
1736            [AC_LANG_PROGRAM(
1737               [#include <sys/pthdebug.h>],
1738               [#ifndef PTHDB_VERSION_3
1739                #error
1740                #endif]
1741             )],
1742            [gdb_cv_have_aix_thread_debug=yes],
1743            [gdb_cv_have_aix_thread_debug=no]
1744          )]
1745       )
1746       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1747       if test "$gdb_cv_have_aix_thread_debug" = yes; then
1748          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1749          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1750          LIBS="$LIBS -lpthdebug"
1751
1752          # Older versions of AIX do not provide the declaration for
1753          # the getthrds function (it appears that it was introduced
1754          # with AIX 6.x).
1755          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1756       fi
1757       ;;
1758    esac
1759    AC_SUBST(CONFIG_LDFLAGS)
1760 fi
1761
1762 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1763 dnl other error codes.
1764 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1765   AC_CACHE_CHECK(
1766     [whether <thread_db.h> has TD_NOTALLOC],
1767     [gdb_cv_thread_db_h_has_td_notalloc],
1768     [AC_COMPILE_IFELSE(
1769        [AC_LANG_PROGRAM(
1770           [#include <thread_db.h>],
1771           [int i = TD_NOTALLOC;]
1772         )],
1773        [gdb_cv_thread_db_h_has_td_notalloc=yes],
1774        [gdb_cv_thread_db_h_has_td_notalloc=no]
1775      )]
1776   )
1777
1778   AC_CACHE_CHECK(
1779     [whether <thread_db.h> has TD_VERSION],
1780     [gdb_cv_thread_db_h_has_td_version],
1781     [AC_COMPILE_IFELSE(
1782        [AC_LANG_PROGRAM(
1783           [#include <thread_db.h>],
1784           [int i = TD_VERSION;]
1785         )],
1786        [gdb_cv_thread_db_h_has_td_version=yes],
1787        [gdb_cv_thread_db_h_has_td_version=no]
1788      )]
1789   )
1790
1791   AC_CACHE_CHECK(
1792     [whether <thread_db.h> has TD_NOTLS],
1793     [gdb_cv_thread_db_h_has_td_notls],
1794     [AC_COMPILE_IFELSE(
1795        [AC_LANG_PROGRAM(
1796           [#include <thread_db.h>],
1797           [int i = TD_NOTLS;]
1798         )],
1799        [gdb_cv_thread_db_h_has_td_notls=yes],
1800        [gdb_cv_thread_db_h_has_td_notls=no]
1801      )]
1802   )
1803 fi
1804 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1805   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1806             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1807 fi
1808 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1809   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1810             [Define if <thread_db.h> has the TD_VERSION error code.])
1811 fi
1812 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1813   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1814             [Define if <thread_db.h> has the TD_NOTLS error code.])
1815 fi
1816
1817 dnl Set the host's .gdbinit filename.
1818 case $host_os in
1819   go32* | *djgpp*)
1820     gdbinit=gdb.ini
1821     ;;
1822   *)
1823     gdbinit=.gdbinit
1824     ;;
1825 esac
1826 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1827
1828 dnl Set the host's .gdbearlyinit filename
1829 AC_DEFINE_UNQUOTED(GDBEARLYINIT,".gdbearlyinit",[The .gdbearlyinit filename.])
1830
1831 dnl Handle optional features that can be enabled.
1832
1833 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1834 # except that the argument to --with-sysroot is optional.
1835 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1836 if test "x$with_sysroot" = xyes; then
1837   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1838 fi
1839 AC_ARG_WITH(sysroot,
1840   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1841                  [search for usr/lib et al within DIR]),
1842   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1843 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1844               [search for usr/lib et al within DIR])
1845 AC_SUBST(TARGET_SYSTEM_ROOT)
1846 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1847
1848 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1849     [automatically load a system-wide gdbinit file],
1850     [])
1851 GDB_AC_WITH_DIR(SYSTEM_GDBINIT_DIR, system-gdbinit-dir,
1852     [automatically load system-wide gdbinit files from this directory],
1853     [])
1854
1855 AM_GDB_WARNINGS
1856 AM_GDB_UBSAN
1857
1858 # In the Cygwin environment, we need some additional flags.
1859 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1860 [AC_EGREP_CPP(^lose$, [
1861 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1862 lose
1863 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1864
1865
1866 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1867 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1868 case ${host} in
1869   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1870   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1871   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1872   *) SER_HARDWIRE="$SER_HARDWIRE ser-uds.o" ;;
1873 esac
1874 AC_SUBST(SER_HARDWIRE)
1875
1876 # libreadline needs libuser32.a in a cygwin environment
1877 WIN32LIBS=
1878 if test x"$gdb_cv_os_cygwin" = xyes; then
1879     WIN32LIBS="-luser32"
1880     case "${target}" in
1881         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1882         ;;
1883     esac
1884 fi
1885
1886 # The ser-tcp.c module requires sockets.
1887 # Note that WIN32APILIBS is set by GDB_AC_COMMON.
1888 WIN32LIBS="$WIN32LIBS $WIN32APILIBS"
1889
1890 # Add ELF support to GDB, but only if BFD includes ELF support.
1891 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
1892                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
1893 if test "$gdb_cv_var_elf" = yes; then
1894   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o dtrace-probe.o \
1895                 gcore-elf.o elf-none-tdep.o"
1896   AC_DEFINE(HAVE_ELF, 1,
1897             [Define if ELF support should be included.])
1898   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1899   if test "$plugins" = "yes"; then
1900     AC_SEARCH_LIBS(dlopen, dl)
1901   fi
1902 fi
1903
1904 # Add macho support to GDB, but only if BFD includes it.
1905 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
1906                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
1907 if test "$gdb_cv_var_macho" = yes; then
1908   CONFIG_OBS="$CONFIG_OBS machoread.o"
1909 fi
1910
1911 # Add any host-specific objects to GDB.
1912 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1913
1914 # If building on ELF, look for lzma support for embedded compressed debug info.
1915 if test "$gdb_cv_var_elf" = yes; then
1916   AC_ARG_WITH(lzma,
1917     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
1918     [], [with_lzma=auto])
1919   AC_MSG_CHECKING([whether to use lzma])
1920   AC_MSG_RESULT([$with_lzma])
1921
1922   if test "${with_lzma}" != no; then
1923     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
1924                           [lzma_index_iter iter;
1925                            lzma_index_iter_init (&iter, 0);
1926                            lzma_mf_is_supported (LZMA_MF_HC3);])
1927     if test "$HAVE_LIBLZMA" != yes; then
1928       if test "$with_lzma" = yes; then
1929         AC_MSG_ERROR([missing liblzma for --with-lzma])
1930       fi
1931     fi
1932   fi
1933 fi
1934
1935 LIBGUI="../libgui/src/libgui.a"
1936 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1937 AC_SUBST(LIBGUI)
1938 AC_SUBST(GUI_CFLAGS_X)
1939
1940 WIN32LDAPP=
1941 AC_SUBST(WIN32LIBS)
1942 AC_SUBST(WIN32LDAPP)
1943
1944 case "${host}" in
1945 *-*-cygwin* | *-*-mingw* )
1946     configdir="win"
1947     ;;
1948 *)
1949     configdir="unix"
1950     ;;
1951 esac
1952
1953 GDBTKLIBS=
1954 if test "${enable_gdbtk}" = "yes"; then
1955
1956     # Gdbtk must have an absolute path to srcdir in order to run
1957     # properly when not installed.
1958     here=`pwd`
1959     cd ${srcdir}
1960     GDBTK_SRC_DIR=`pwd`
1961     cd $here
1962
1963     SC_PATH_TCLCONFIG
1964
1965     # If $no_tk is nonempty, then we can't do Tk, and there is no
1966     # point to doing Tcl.
1967     SC_PATH_TKCONFIG
1968
1969     if test -z "${no_tcl}" -a -z "${no_tk}"; then
1970         SC_LOAD_TCLCONFIG
1971
1972         # Check for in-tree tcl
1973         here=`pwd`
1974         cd ${srcdir}/..
1975         topdir=`pwd`
1976         cd ${here}
1977
1978         intree="no"
1979         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
1980           intree="yes"
1981         fi
1982
1983         # Find Tcl private headers
1984         if test x"${intree}" = xno; then
1985           CY_AC_TCL_PRIVATE_HEADERS
1986           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
1987           TCL_LIBRARY="${TCL_LIB_SPEC}"
1988           TCL_DEPS=""
1989         else
1990           # If building tcl in the same src tree, private headers
1991           # are not needed, but we need to be sure to use the right
1992           # headers library
1993           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
1994           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
1995           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
1996         fi
1997         AC_SUBST(TCL_INCLUDE)
1998         AC_SUBST(TCL_LIBRARY)
1999         AC_SUBST(TCL_DEPS)
2000
2001         SC_LOAD_TKCONFIG
2002
2003         # Check for in-tree Tk
2004         intree="no"
2005         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2006           intree="yes"
2007         fi
2008
2009         # Find Tk private headers
2010         if test x"${intree}" = xno; then
2011           CY_AC_TK_PRIVATE_HEADERS
2012           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2013           TK_LIBRARY=${TK_LIB_SPEC}
2014           TK_DEPS=""
2015         else
2016           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2017           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2018           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2019         fi
2020         AC_SUBST(TK_INCLUDE)
2021         AC_SUBST(TK_LIBRARY)
2022         AC_SUBST(TK_DEPS)
2023         AC_SUBST(TK_XINCLUDES)
2024
2025         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2026
2027         # Include some libraries that Tcl and Tk want.
2028         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2029         # Yes, the ordering seems wrong here.  But it isn't.
2030         # TK_LIBS is the list of libraries that need to be linked
2031         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2032         # were in LIBS then any link tests after this point would
2033         # try to include things like `$(LIBGUI)', which wouldn't work.
2034         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2035
2036         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2037         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2038         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2039         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2040         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2041         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2042         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2043
2044         if test x"$gdb_cv_os_cygwin" = xyes; then
2045           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2046           WIN32LDAPP="-Wl,--subsystem,console"
2047           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2048         fi
2049
2050         AC_CONFIG_SUBDIRS(gdbtk)
2051     fi
2052 fi
2053
2054 AC_SUBST(X_CFLAGS)
2055 AC_SUBST(X_LDFLAGS)
2056 AC_SUBST(X_LIBS)
2057 AC_SUBST(GDBTKLIBS)
2058 AC_SUBST(GDBTK_CFLAGS)
2059 AC_SUBST(GDBTK_SRC_DIR)
2060
2061 AC_PATH_X
2062
2063 # Unlike the sim directory, whether a simulator is linked is controlled by
2064 # presence of a gdb_sim definition in the target configure.tgt entry.
2065 # This code just checks for a few cases where we'd like to ignore those
2066 # definitions, even when they're present in the '.mt' file.  These cases
2067 # are when --disable-sim is specified, or if the simulator directory is
2068 # not part of the source tree.
2069 #
2070 AC_ARG_ENABLE(sim,
2071 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2072 [echo "enable_sim = $enable_sim";
2073  echo "enableval = ${enableval}";
2074  case "${enableval}" in
2075   yes) ignore_sim=false ;;
2076   no)  ignore_sim=true ;;
2077   *)   ignore_sim=false ;;
2078  esac],
2079 [ignore_sim=false])
2080
2081 if test ! -d "${srcdir}/../sim"; then
2082   ignore_sim=true
2083 fi
2084
2085 SIM=
2086 SIM_OBS=
2087 if test "${ignore_sim}" = "false"; then
2088   if test x"${gdb_sim}" != x ; then
2089     SIM="${gdb_sim}"
2090     SIM_OBS="remote-sim.o"
2091     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2092
2093     # Some tdep code should only be compiled in when the ppc sim is
2094     # built.  PR sim/13418.
2095     case $target in
2096       powerpc*-*-*)
2097         AC_DEFINE(WITH_PPC_SIM, 1, [Define if the PPC simulator is being linked in.])
2098         ;;
2099     esac
2100   fi
2101 fi
2102 AC_SUBST(SIM)
2103 AC_SUBST(SIM_OBS)
2104
2105 AC_SUBST(ENABLE_CFLAGS)
2106 AC_SUBST(PROFILE_CFLAGS)
2107
2108 AC_SUBST(CONFIG_OBS)
2109 AC_SUBST(CONFIG_DEPS)
2110 AC_SUBST(CONFIG_SRCS)
2111 AC_SUBST(CONFIG_ALL)
2112 AC_SUBST(CONFIG_CLEAN)
2113 AC_SUBST(CONFIG_INSTALL)
2114 AC_SUBST(CONFIG_UNINSTALL)
2115
2116 # List of host floatformats.
2117 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2118 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2119 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2120
2121 # target_subdir is used by the testsuite to find the target libraries.
2122 target_subdir=
2123 if test "${host}" != "${target}"; then
2124     target_subdir="${target_alias}/"
2125 fi
2126 AC_SUBST(target_subdir)
2127
2128 # Import nat definitions.
2129 nat_makefile_frag=/dev/null
2130 if test "${gdb_native}" = "yes"; then
2131   . ${srcdir}/configure.nat
2132   nativefile=$NAT_FILE
2133 fi
2134
2135 AC_SUBST(NAT_FILE)
2136 AC_SUBST(NATDEPFILES)
2137 AC_SUBST(NAT_CDEPS)
2138 AC_SUBST(LOADLIBES)
2139 AC_SUBST(MH_CFLAGS)
2140 AC_SUBST(XM_CLIBS)
2141 AC_SUBST(NAT_GENERATED_FILES)
2142 AC_SUBST(HAVE_NATIVE_GCORE_HOST)
2143 AC_SUBST_FILE(nat_makefile_frag)
2144
2145 if test x"${gdb_osabi}" != x ; then
2146     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2147                        [Define to the default OS ABI for this configuration.])
2148 fi
2149
2150 # Setup possible use of libbacktrace.
2151 AC_ARG_ENABLE([libbacktrace],
2152 [AS_HELP_STRING([--enable-libbacktrace],
2153                 [use libbacktrace to write a backtrace after a fatal signal.])],
2154 [case "${enableval}" in
2155   yes)  enable_libbacktrace=yes ;;
2156   no)   enable_libbacktrace=no  ;;
2157   *)    AC_MSG_ERROR(bad value ${enableval} for --enable-libbacktrace option) ;;
2158 esac],
2159 enable_libbacktrace=yes)
2160
2161 if test "${enable_libbacktrace}" == "yes"; then
2162   LIBBACKTRACE_INC="-I$srcdir/../libbacktrace/ -I../libbacktrace/"
2163   LIBBACKTRACE_LIB=../libbacktrace/.libs/libbacktrace.a
2164   AC_DEFINE(HAVE_LIBBACKTRACE, 1, [Define if libbacktrace is being used.])
2165 else
2166   LIBBACKTRACE_INC=
2167   LIBBACKTRACE_LIB=
2168 fi
2169
2170 AC_SUBST(LIBBACKTRACE_INC)
2171 AC_SUBST(LIBBACKTRACE_LIB)
2172
2173 # Check for babeltrace and babeltrace-ctf
2174 AC_ARG_WITH(babeltrace,
2175   AS_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2176   [], [with_babeltrace=auto])
2177 AC_MSG_CHECKING([whether to use babeltrace])
2178 AC_MSG_RESULT([$with_babeltrace])
2179
2180 if test "x$with_babeltrace" = "xno"; then
2181   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2182 else
2183   # Append -Werror to CFLAGS so that configure can catch the warning
2184   # "assignment from incompatible pointer type", which is related to
2185   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2186   # in GDB, while babeltrace 1.0.3 is broken.
2187   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2188   # safe to save and restore CFLAGS here.
2189   saved_CFLAGS=$CFLAGS
2190   CFLAGS="$CFLAGS -Werror"
2191   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2192                         [#include <babeltrace/babeltrace.h>
2193                          #include <babeltrace/ctf/events.h>
2194                          #include <babeltrace/ctf/iterator.h>],
2195                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2196                         struct bt_ctf_event *event = NULL;
2197                         const struct bt_definition *scope;
2198
2199                         pos->type = BT_SEEK_BEGIN;
2200                         bt_iter_set_pos (bt_ctf_get_iter (NULL), pos);
2201                         scope = bt_ctf_get_top_level_scope (event,
2202                                                            BT_STREAM_EVENT_HEADER);
2203                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2204                         ])
2205   CFLAGS=$saved_CFLAGS
2206
2207   if test "$HAVE_LIBBABELTRACE" != yes; then
2208      if test "$with_babeltrace" = yes; then
2209        AC_MSG_ERROR([babeltrace is missing or unusable])
2210      else
2211        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2212      fi
2213   fi
2214 fi
2215
2216 # Check for xxhash
2217 AC_ARG_WITH(xxhash,
2218   AS_HELP_STRING([--with-xxhash], [use libxxhash for hashing (faster) (auto/yes/no)]),
2219   [], [with_xxhash=auto])
2220
2221 GCC_ENABLE([libctf], [yes], [], [Handle .ctf type-info sections])
2222 if test x${enable_static} = xno; then
2223   LIBCTF="-Wl,--rpath,../libctf/.libs ../libctf/.libs/libctf.so"
2224   CTF_DEPS="../libctf/.libs/libctf.so"
2225 else
2226   LIBCTF="../libctf/.libs/libctf.a"
2227   CTF_DEPS="$LIBCTF"
2228 fi
2229 if test "${enable_libctf}" = yes; then
2230   AC_DEFINE(ENABLE_LIBCTF, 1, [Handle .ctf type-info sections])
2231 else
2232   LIBCTF=
2233   CTF_DEPS=
2234 fi
2235 AC_SUBST(LIBCTF)
2236 AC_SUBST(CTF_DEPS)
2237
2238 # If nativefile (NAT_FILE) is not set in configure.nat, we link to an
2239 # empty version.
2240
2241 if test "x$with_xxhash" != "xno"; then
2242   AC_LIB_HAVE_LINKFLAGS([xxhash], [],
2243                         [#include <xxhash.h>],
2244                         [XXH32("foo", 3, 0);
2245                         ])
2246   if test "$HAVE_LIBXXHASH" != yes; then
2247     if test "$with_xxhash" = yes; then
2248       AC_MSG_ERROR([xxhash is missing or unusable])
2249     fi
2250   fi
2251   if test "x$with_xxhash" = "xauto"; then
2252     with_xxhash="$HAVE_LIBXXHASH"
2253   fi
2254 fi
2255
2256 AC_MSG_CHECKING([whether to use xxhash])
2257 AC_MSG_RESULT([$with_xxhash])
2258
2259 NM_H=
2260 rm -f nm.h
2261 if test "${nativefile}" != ""; then
2262     case "${nativefile}" in
2263       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2264       * ) GDB_NM_FILE="${nativefile}"
2265     esac
2266     AC_CONFIG_LINKS([nm.h:$GDB_NM_FILE], [echo > stamp-nmh],
2267                     [GDB_NM_FILE=$GDB_NM_FILE])
2268     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2269     NM_H=nm.h
2270 fi
2271 AC_SUBST(GDB_NM_FILE)
2272 AC_SUBST(NM_H)
2273
2274 dnl Add dependency for xsltproc if building with maintainer-mode enabled.
2275 AC_PATH_PROGS(XSLTPROC, xsltproc, missing)
2276 if test "x$USE_MAINTAINER_MODE" = xyes; then
2277   if test "${XSLTPROC}" = missing; then
2278     AC_MSG_ERROR(unable to find xsltproc.  maintainer-mode requires xsltproc.)
2279   fi
2280 fi
2281 AC_SUBST(XSLTPROC)
2282
2283 dnl Check for exe extension set on certain hosts (e.g. Win32)
2284 AC_EXEEXT
2285
2286 dnl  Detect the character set used by this host.
2287 dnl  At the moment, we just assume it's UTF-8.
2288 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2289           [Define to be a string naming the default host character set.])
2290
2291 GDB_AC_SELFTEST([
2292   CONFIG_OBS="$CONFIG_OBS \$(SELFTESTS_OBS)"
2293   CONFIG_SRCS="$CONFIG_SRCS \$(SELFTESTS_SRCS)"
2294 ])
2295
2296 GDB_AC_TRANSFORM([gdb], [GDB_TRANSFORM_NAME])
2297 GDB_AC_TRANSFORM([gcore], [GCORE_TRANSFORM_NAME])
2298 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2299 AC_CONFIG_FILES([Makefile gdb-gdb.gdb gdb-gdb.py doc/Makefile data-directory/Makefile])
2300
2301 AC_OUTPUT