gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   3 dnl 2005, 2006, 2007, 2008, 2009, 2010
   4 dnl Free Software Foundation, Inc.
   5 dnl
   6 dnl This file is part of GDB.
   7 dnl
   8 dnl This program is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 3 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.59)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_USE_SYSTEM_EXTENSIONS
  30 gl_EARLY
  31 ACX_LARGEFILE
  32 AM_PROG_CC_STDC
  33
  34 AC_CONFIG_AUX_DIR(..)
  35 AC_CANONICAL_SYSTEM
  36
  37 # Dependency checking.
  38 ZW_CREATE_DEPDIR
  39 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  40
  41 # Check for the 'make' the user wants to use.
  42 AC_CHECK_PROGS(MAKE, make)
  43 MAKE_IS_GNU=
  44 case "`$MAKE --version 2>&1 | sed 1q`" in
  45   *GNU*)
  46     MAKE_IS_GNU=yes
  47     ;;
  48 esac
  49 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  50 AC_PROG_MAKE_SET
  51
  52 dnl List of object files and targets accumulated by configure.
  53
  54 CONFIG_OBS=
  55 CONFIG_DEPS=
  56 CONFIG_SRCS=
  57 ENABLE_CFLAGS=
  58
  59 CONFIG_ALL=
  60 CONFIG_CLEAN=
  61 CONFIG_INSTALL=
  62 CONFIG_UNINSTALL=
  63
  64 dnl Set up for gettext.
  65 ZW_GNU_GETTEXT_SISTER_DIR
  66
  67 localedir='${datadir}/locale'
  68 AC_SUBST(localedir)
  69
  70 if test x"$USE_NLS" = xyes; then
  71    CONFIG_ALL="$CONFIG_ALL all-po"
  72    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  73    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  74    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  75 fi
  76
  77 gl_INIT
  78
  79 # For Makefile dependencies.
  80 GNULIB_STDINT_H=
  81 if test x"$STDINT_H" != x; then
  82   GNULIB_STDINT_H=gnulib/$STDINT_H
  83 fi
  84 AC_SUBST(GNULIB_STDINT_H)
  85
  86 PACKAGE=gdb
  87 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  88 AC_SUBST(PACKAGE)
  89
  90 # GDB does not use automake, but gnulib does.  This line lets us
  91 # generate its Makefile.in.
  92 AM_INIT_AUTOMAKE(gdb, UNUSED-VERSION, [no-define])
  93
  94 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
  95     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
  96     [${libdir}/debug])
  97
  98 # GDB's datadir relocation
  99
 100 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 101     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 102     [${datadir}/gdb])
 103
 104 AC_ARG_WITH(relocated-sources,
 105 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 106 [reloc_srcdir="${withval}"
 107  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 108               [Relocated directory for source files. ])
 109 ])
 110
 111 AC_CONFIG_SUBDIRS(doc testsuite)
 112
 113 # Check whether to support alternative target configurations
 114 AC_ARG_ENABLE(targets,
 115 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 116 [case "${enableval}" in
 117   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 118             ;;
 119   no)       enable_targets= ;;
 120   *)        enable_targets=$enableval ;;
 121 esac])
 122
 123 # Check whether to enable 64-bit support on 32-bit hosts
 124 AC_ARG_ENABLE(64-bit-bfd,
 125 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 126 [case "${enableval}" in
 127   yes)  want64=true  ;;
 128   no)   want64=false ;;
 129   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 130 esac],[want64=false])dnl
 131
 132 # Provide defaults for some variables set by the per-host and per-target
 133 # configuration.
 134 gdb_host_obs=posix-hdep.o
 135
 136 if test "${target}" = "${host}"; then
 137   gdb_native=yes
 138 else
 139   gdb_native=no
 140 fi
 141
 142 . $srcdir/configure.host
 143
 144 # Accumulate some settings from configure.tgt over all enabled targets
 145
 146 TARGET_OBS=
 147 all_targets=
 148
 149 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 150 do
 151   if test "$targ_alias" = "all"; then
 152     all_targets=true
 153   else
 154     # Canonicalize the secondary target names.
 155     result=`$ac_config_sub $targ_alias 2>/dev/null`
 156     if test -n "$result"; then
 157         targ=$result
 158     else
 159         targ=$targ_alias
 160     fi
 161
 162     . ${srcdir}/configure.tgt
 163
 164     AS_IF([test -z "${gdb_target_obs}"],
 165       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 166
 167     # Target-specific object files
 168     for i in ${gdb_target_obs}; do
 169         case " $TARGET_OBS " in
 170         *" ${i} "*) ;;
 171         *)
 172           TARGET_OBS="$TARGET_OBS ${i}"
 173           ;;
 174         esac
 175     done
 176
 177     # Check whether this target needs 64-bit CORE_ADDR
 178     if test x${want64} = xfalse; then
 179       . ${srcdir}/../bfd/config.bfd
 180     fi
 181   fi
 182 done
 183
 184 if test x${all_targets} = xtrue; then
 185
 186   # We want all 64-bit targets if we either:
 187   #  - run on a 64-bit host  or
 188   #  - already require 64-bit support for some other target  or
 189   #  - the --enable-64-bit-bfd option was supplied
 190   # Otherwise we only support all 32-bit targets.
 191   #
 192   # NOTE: This test must be in sync with the corresponding
 193   #       tests in BFD!
 194
 195   if test x${want64} = xfalse; then
 196     AC_CHECK_SIZEOF(long)
 197     if test "x${ac_cv_sizeof_long}" = "x8"; then
 198       want64=true
 199     fi
 200   fi
 201   if test x${want64} = xtrue; then
 202     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 203   else
 204     TARGET_OBS='$(ALL_TARGET_OBS)'
 205   fi
 206 fi
 207
 208 AC_SUBST(TARGET_OBS)
 209
 210 # For other settings, only the main target counts.
 211 gdb_sim=
 212 gdb_osabi=
 213 build_gdbserver=
 214 targ=$target; . ${srcdir}/configure.tgt
 215
 216 # Fetch the default architecture and default target vector from BFD.
 217 targ=$target; . $srcdir/../bfd/config.bfd
 218
 219 # We only want the first architecture, so strip off the others if
 220 # there is more than one.
 221 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 222
 223 if test "x$targ_archs" != x; then
 224   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 225     [Define to BFD's default architecture. ])
 226 fi
 227 if test "x$targ_defvec" != x; then
 228   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 229     [Define to BFD's default target vector. ])
 230 fi
 231
 232 # The CLI cannot be disabled yet, but may be in the future.
 233
 234 # Enable CLI.
 235 AC_ARG_ENABLE(gdbcli,
 236 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 237   [case $enableval in
 238     yes)
 239       ;;
 240     no)
 241       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 242     *)
 243       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 244   esac],
 245   [enable_gdbcli=yes])
 246 if test x"$enable_gdbcli" = xyes; then
 247   if test -d $srcdir/cli; then
 248     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 249     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 250     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 251     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 252   fi
 253 fi
 254
 255 # Enable MI.
 256 AC_ARG_ENABLE(gdbmi,
 257 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 258   [case $enableval in
 259     yes | no)
 260       ;;
 261     *)
 262       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 263   esac],
 264   [enable_gdbmi=yes])
 265 if test x"$enable_gdbmi" = xyes; then
 266   if test -d $srcdir/mi; then
 267     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 268     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 269     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 270     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 271   fi
 272 fi
 273
 274 # Enable TUI.
 275 AC_ARG_ENABLE(tui,
 276 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 277   [case $enableval in
 278     yes | no | auto)
 279       ;;
 280     *)
 281       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 282   esac],enable_tui=auto)
 283
 284 # Enable gdbtk.
 285 AC_ARG_ENABLE(gdbtk,
 286 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 287   [case $enableval in
 288     yes | no)
 289       ;;
 290     *)
 291       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 292   esac],
 293   [if test -d $srcdir/gdbtk; then
 294     enable_gdbtk=yes
 295   else
 296     enable_gdbtk=no
 297   fi])
 298 # We unconditionally disable gdbtk tests on selected platforms.
 299 case $host_os in
 300   go32* | windows*)
 301     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 302     enable_gdbtk=no ;;
 303 esac
 304
 305 # Libunwind support.
 306 AC_ARG_WITH(libunwind,
 307 AS_HELP_STRING([--with-libunwind], [use libunwind frame unwinding support]),
 308 [case "${withval}" in
 309   yes)  enable_libunwind=yes ;;
 310   no)   enable_libunwind=no ;;
 311   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 312 esac],[
 313   AC_CHECK_HEADERS(libunwind.h libunwind-ia64.h)
 314   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 315     enable_libunwind=yes;
 316   fi
 317 ])
 318
 319 if test x"$enable_libunwind" = xyes; then
 320   AC_CHECK_HEADERS(libunwind.h libunwind-ia64.h)
 321   AC_DEFINE(HAVE_LIBUNWIND, 1, [Define if libunwind library is being used.])
 322   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 323   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 324   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 325 fi
 326
 327 opt_curses=no
 328 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 329
 330 prefer_curses=no
 331 if test "$opt_curses" = "yes"; then
 332   prefer_curses=yes
 333 fi
 334
 335 # Profiling support.
 336 AC_ARG_ENABLE(profiling,
 337 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 338   [case $enableval in
 339     yes | no)
 340       ;;
 341     *)
 342       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 343   esac],
 344  [enable_profiling=no])
 345
 346 AC_CHECK_FUNCS(monstartup _mcleanup)
 347 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 348 [AC_TRY_LINK(
 349 [#include <stdlib.h>
 350 extern char _etext;
 351 ],
 352 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 353 if test $ac_cv_var__etext = yes; then
 354   AC_DEFINE(HAVE__ETEXT, 1,
 355             [Define to 1 if your system has the _etext variable. ])
 356 fi
 357 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 358 [AC_TRY_LINK(
 359 [#include <stdlib.h>
 360 extern char etext;
 361 ],
 362 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 363 if test $ac_cv_var_etext = yes; then
 364   AC_DEFINE(HAVE_ETEXT, 1,
 365             [Define to 1 if your system has the etext variable. ])
 366 fi
 367 if test "$enable_profiling" = yes ; then
 368   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 369     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 370   fi
 371   PROFILE_CFLAGS=-pg
 372   OLD_CFLAGS="$CFLAGS"
 373   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 374
 375   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 376     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 377      ac_cv_cc_supports_pg=no)])
 378
 379   if test $ac_cv_cc_supports_pg = no; then
 380     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 381   fi
 382
 383   CFLAGS="$OLD_CFLAGS"
 384 fi
 385
 386 ACX_PKGVERSION([GDB])
 387 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 388 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 389 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 390
 391 # --------------------- #
 392 # Checks for programs.  #
 393 # --------------------- #
 394
 395 AC_PROG_AWK
 396 AC_PROG_INSTALL
 397 AC_PROG_LN_S
 398 AC_PROG_RANLIB
 399 AC_PROG_YACC
 400
 401 AC_CHECK_TOOL(AR, ar)
 402 AC_CHECK_TOOL(DLLTOOL, dlltool)
 403 AC_CHECK_TOOL(WINDRES, windres)
 404
 405 # Needed for GNU/Hurd.
 406 AC_CHECK_TOOL(MIG, mig)
 407
 408 # ---------------------- #
 409 # Checks for libraries.  #
 410 # ---------------------- #
 411
 412 # We might need to link with -lm; most simulators need it.
 413 AC_CHECK_LIB(m, main)
 414
 415 # We need to link with -lw to get `wctype' on Solaris before Solaris
 416 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 417 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 418 # is known to have this problem).  Therefore we avoid libw if we can.
 419 AC_CHECK_FUNC(wctype, [],
 420   [AC_CHECK_LIB(w, wctype)])
 421
 422 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 423 AC_SEARCH_LIBS(gethostbyname, nsl)
 424
 425 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 426 AC_SEARCH_LIBS(socketpair, socket)
 427
 428 # Link in zlib if we can.  This allows us to read compressed debug sections.
 429 AM_ZLIB
 430
 431 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 432 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 433
 434 AM_ICONV
 435
 436 # On alpha-osf, it appears that libtermcap and libcurses are not compatible.
 437 # There is a very specific comment in /usr/include/curses.h explaining that
 438 # termcap routines built into libcurses must not be used.
 439 #
 440 # The symptoms we observed so far is GDB unexpectedly changing
 441 # the terminal settings when tgetent is called - this is particularly
 442 # visible as the output is missing carriage returns, and so rapidly
 443 # becomes very hard to read.
 444 #
 445 # The readline configure script has already decided that libtermcap
 446 # was enough for its purposes, and so decided to build readline using
 447 # libtermcap.  Since the TUI mode requires curses, building GDB with
 448 # TUI enabled results in both libraries to be used at the same time,
 449 # which is not allowed.  This basically means that GDB with TUI is
 450 # broken on alpha-osf.
 451
 452 case $host_os in
 453   osf* )
 454     if test x"$enable_tui" = xyes; then
 455       AC_MSG_ERROR([Building GDB with TUI mode is not supported on this host])
 456     fi
 457     if test x"$enable_tui" = xauto; then
 458       enable_tui=no
 459     fi
 460     ;;
 461 esac
 462
 463 # For the TUI, we need enhanced curses functionality.
 464 if test x"$enable_tui" != xno; then
 465   prefer_curses=yes
 466 fi
 467
 468 curses_found=no
 469 if test x"$prefer_curses" = xyes; then
 470   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 471   # curses library because the latter might not provide all the
 472   # functionality we need.  However, this leads to problems on systems
 473   # where the linker searches /usr/local/lib, but the compiler doesn't
 474   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 475   # default installation of ncurses on alpha*-dec-osf* will lead to such
 476   # a situation.
 477   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 478
 479   if test "$ac_cv_search_waddstr" != no; then
 480     curses_found=yes
 481   fi
 482 fi
 483
 484 # Check whether we should enable the TUI, but only do so if we really
 485 # can.
 486 if test x"$enable_tui" != xno; then
 487   if test -d $srcdir/tui; then
 488     if test "$curses_found" != no; then
 489       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 490       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 491       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 492       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 493       CONFIG_ALL="${CONFIG_ALL} all-tui"
 494       CONFIG_CLEAN="${CONFIG_CLEAN} clean-tui"
 495       CONFIG_INSTALL="${CONFIG_INSTALL} install-tui"
 496       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-tui"
 497     else
 498       if test x"$enable_tui" = xyes; then
 499         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 500       else
 501         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 502       fi
 503     fi
 504   fi
 505 fi
 506
 507 # Since GDB uses Readline, we need termcap functionality.  In many
 508 # cases this will be provided by the curses library, but some systems
 509 # have a seperate termcap library, or no curses library at all.
 510
 511 case $host_os in
 512   cygwin*)
 513     if test -d $srcdir/libtermcap; then
 514       LIBS="../libtermcap/libtermcap.a $LIBS"
 515       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 516     fi ;;
 517   go32* | *djgpp*)
 518     ac_cv_search_tgetent="none required"
 519     ;;
 520   *mingw32*)
 521     ac_cv_search_tgetent="none required"
 522     CONFIG_OBS="$CONFIG_OBS windows-termcap.o"
 523     ;;
 524 esac
 525
 526 # These are the libraries checked by Readline.
 527 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 528
 529 if test "$ac_cv_search_tgetent" = no; then
 530   AC_MSG_ERROR([no termcap library found])
 531 fi
 532
 533 AC_ARG_WITH([system-readline],
 534   [AS_HELP_STRING([--with-system-readline],
 535                   [use installed readline library])])
 536
 537 if test "$with_system_readline" = yes; then
 538   READLINE=-lreadline
 539   READLINE_DEPS=
 540   READLINE_CFLAGS=
 541
 542   # readline-6.0 started to use the name `_rl_echoing_p'.
 543   # `$(READLINE_DIR)/' of bundled readline would not resolve in configure.
 544
 545   AC_MSG_CHECKING([for readline_echoing_p])
 546   save_LIBS=$LIBS
 547   LIBS="$LIBS $READLINE"
 548   AC_LINK_IFELSE(AC_LANG_PROGRAM(,[[extern int readline_echoing_p;
 549                                     return readline_echoing_p;]]),
 550                  [READLINE_ECHOING_P=yes],
 551                  [READLINE_ECHOING_P=no
 552                   AC_DEFINE([readline_echoing_p], [_rl_echoing_p],
 553                             [readline-6.0 started to use different name.])])
 554   LIBS="$save_LIBS"
 555   AC_MSG_RESULT([$READLINE_ECHOING_P])
 556 else
 557   READLINE='$(READLINE_DIR)/libreadline.a'
 558   READLINE_DEPS='$(READLINE)'
 559   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 560 fi
 561 AC_SUBST(READLINE)
 562 AC_SUBST(READLINE_DEPS)
 563 AC_SUBST(READLINE_CFLAGS)
 564
 565 AC_ARG_WITH(expat,
 566   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 567   [], [with_expat=auto])
 568 AC_MSG_CHECKING([whether to use expat])
 569 AC_MSG_RESULT([$with_expat])
 570
 571 if test "${with_expat}" = no; then
 572   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 573   HAVE_LIBEXPAT=no
 574 else
 575   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 576                         [XML_Parser p = XML_ParserCreate (0);])
 577   if test "$HAVE_LIBEXPAT" != yes; then
 578     if test "$with_expat" = yes; then
 579       AC_MSG_ERROR([expat is missing or unusable])
 580     else
 581       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 582     fi
 583   else
 584     save_LIBS=$LIBS
 585     LIBS="$LIBS $LIBEXPAT"
 586     AC_CHECK_FUNCS(XML_StopParser)
 587     LIBS=$save_LIBS
 588   fi
 589 fi
 590
 591 dnl Utility to simplify finding libpython.
 592 dnl $1 = pythonX.Y
 593 dnl $2 = the shell variable to assign the result to
 594 dnl      If libpython is found we store $version here.
 595 dnl $3 = additional flags to add to CPPFLAGS
 596 dnl $4 = additional flags to add to LIBS
 597
 598 AC_DEFUN([AC_TRY_LIBPYTHON],
 599 [
 600   version=$1
 601   define([have_libpython_var],$2)
 602   new_CPPFLAGS=$3
 603   new_LIBS=$4
 604   AC_MSG_CHECKING([for ${version}])
 605   save_CPPFLAGS=$CPPFLAGS
 606   save_LIBS=$LIBS
 607   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 608   LIBS="$LIBS $new_LIBS"
 609   found_usable_python=no
 610   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "${version}/Python.h"]],
 611                                  [[Py_Initialize ();]]),
 612                  [have_libpython_var=${version}
 613                   found_usable_python=yes],
 614                  [CPPFLAGS=$save_CPPFLAGS
 615                   LIBS=$save_LIBS])
 616   AC_MSG_RESULT([${found_usable_python}])
 617 ])
 618
 619 dnl There are several different values for --with-python:
 620 dnl
 621 dnl no -   Don't include python support.
 622 dnl yes -  Include python support, error if it's missing.
 623 dnl        If we find python in $PATH, use it to fetch configure options,
 624 dnl        otherwise assume the compiler can find it with no help from us.
 625 dnl        Python 2.6, 2.5, and then 2.4 are tried in turn.
 626 dnl auto - Same as "yes", but if python is missing from the system,
 627 dnl        fall back to "no".
 628 dnl /path/to/python/exec-prefix -
 629 dnl        Use the python located in this directory.
 630 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 631 dnl        the compilation parameters.  Otherwise use
 632 dnl        -I/path/to/python/exec-prefix/include,
 633 dnl        -L/path/to/python/exec-prefix/lib.
 634 dnl        Python 2.6, 2.5, and then 2.4 are tried in turn.
 635 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 636 dnl        but is deprecated.
 637 dnl /path/to/python/executable -
 638 dnl        Run python-config.py with this version of python to fetch the
 639 dnl        compilation parameters.
 640 dnl        NOTE: This needn't be the real python executable.
 641 dnl        In a cross-compilation scenario (build != host), this could be
 642 dnl        a shell script that provides what python-config.py provides for
 643 dnl        --ldflags, --includes, --exec-prefix.
 644 dnl python-executable -
 645 dnl        Find python-executable in $PATH, and then handle the same as
 646 dnl        /path/to/python/executable.
 647 dnl
 648 dnl If a python program is specified, it is used to run python-config.py and
 649 dnl is passed --ldflags, --includes, --exec-prefix.
 650
 651 AC_ARG_WITH(python,
 652   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 653   [], [with_python=auto])
 654 AC_MSG_CHECKING([whether to use python])
 655 AC_MSG_RESULT([$with_python])
 656
 657 if test "${with_python}" = no; then
 658   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 659   have_libpython=no
 660 else
 661   case "${with_python}" in
 662   /*)
 663     if test -d ${with_python}; then
 664       # Assume the python binary is ${with_python}/bin/python.
 665       python_prog="${with_python}/bin/python"
 666       python_prefix=
 667       if test ! -x "${python_prog}"; then
 668         # Fall back to gdb 7.0/7.1 behaviour.
 669         python_prog=missing
 670         python_prefix=${with_python}
 671       fi
 672     elif test -x "${with_python}"; then
 673       # While we can't run python compiled for $host (unless host == build),
 674       # the user could write a script that provides the needed information,
 675       # so we support that.
 676       python_prog=${with_python}
 677       python_prefix=
 678     else
 679       AC_ERROR(invalid value for --with-python)
 680     fi
 681     ;;
 682   */*)
 683     # Disallow --with-python=foo/bar.
 684     AC_ERROR(invalid value for --with-python)
 685     ;;
 686   *)
 687     # The user has either specified auto, yes, or the name of the python
 688     # program assumed to be in $PATH.
 689     python_prefix=
 690     case "${with_python}" in
 691     yes | auto)
 692       if test ${build} = ${host}; then
 693         AC_PATH_PROG(python_prog_path, python, missing)
 694         if test "${python_prog_path}" = missing; then
 695           python_prog=missing
 696         else
 697           python_prog=${python_prog_path}
 698         fi
 699       else
 700         # Not much we can do except assume the cross-compiler will find the
 701         # right files.
 702         python_prog=missing
 703       fi
 704       ;;
 705     *)
 706       # While we can't run python compiled for $host (unless host == build),
 707       # the user could write a script that provides the needed information,
 708       # so we support that.
 709       python_prog="${with_python}"
 710       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 711       if test "${python_prog_path}" = missing; then
 712         AC_ERROR(unable to find python program ${python_prog})
 713       fi
 714       ;;
 715     esac
 716   esac
 717
 718   if test "${python_prog}" != missing; then
 719     # We have a python program to use, but it may be too old.
 720     # Don't flag an error for --with-python=auto (the default).
 721     have_python_config=yes
 722     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 723     if test $? != 0; then
 724       have_python_config=failed
 725       if test "${with_python}" != auto; then
 726         AC_ERROR(failure running python-config --includes)
 727       fi
 728     fi
 729     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 730     if test $? != 0; then
 731       have_python_config=failed
 732       if test "${with_python}" != auto; then
 733         AC_ERROR(failure running python-config --ldflags)
 734       fi
 735     fi
 736     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 737     if test $? != 0; then
 738       have_python_config=failed
 739       if test "${with_python}" != auto; then
 740         AC_ERROR(failure running python-config --exec-prefix)
 741       fi
 742     fi
 743   else
 744     # Fall back to gdb 7.0/7.1 behaviour.
 745     if test -z ${python_prefix}; then
 746       python_includes=
 747       python_libs=
 748     else
 749       python_includes="-I${python_prefix}/include"
 750       python_libs="-L${python_prefix}/lib"
 751     fi
 752     have_python_config=no
 753   fi
 754
 755   # Having "/pythonX.Y" in the include path is awkward.
 756   # All those python headers get bubbled up to the top inviting lots
 757   # of random collisions.  GDB originally didn't use python-config to
 758   # find the compilation parameters and includes "pythonX.Y/" in the
 759   # path of the, umm, include file.  So strip away this part of the
 760   # output of python-config --includes.
 761   python_includes=`echo "${python_includes} " \
 762                         | sed -e 's,/python[[0-9]]*[[.]][[0-9]]* , ,g'`
 763
 764   # If we have python-config, only try the configuration it provides.
 765   # Otherwise fallback on the old way of trying different versions of
 766   # python in turn.
 767
 768   have_libpython=no
 769   if test "${have_python_config}" = yes; then
 770     python_version=`echo " ${python_libs} " \
 771                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]][[0-9]]*\) .*$,\1,'`
 772     case "${python_version}" in
 773     python*)
 774       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 775                        ${python_includes}, ${python_libs})
 776       ;;
 777     *)
 778       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 779       ;;
 780     esac
 781   elif test "${have_python_config}" != failed; then
 782     if test "${have_libpython}" = no; then
 783       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 784                        ${python_includes}, "${python_libs} -lpython2.6")
 785     fi
 786     if test ${have_libpython} = no; then
 787       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 788                        ${python_includes}, "${python_libs} -lpython2.5")
 789     fi
 790     if test ${have_libpython} = no; then
 791       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 792                        ${python_includes}, "${python_libs} -lpython2.4")
 793     fi
 794   fi
 795   if test "${have_libpython}" = python2.6; then
 796     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 797   elif test "${have_libpython}" = python2.5; then
 798     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 799   elif test "${have_libpython}" = python2.4; then
 800     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 801   fi
 802
 803   if test "${have_libpython}" = no; then
 804     case "${with_python}" in
 805     yes)
 806       AC_MSG_ERROR([python is missing or unusable])
 807       ;;
 808     auto)
 809       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 810       ;;
 811     *)
 812       AC_MSG_ERROR([no usable python found at ${with_python}])
 813       ;;
 814     esac
 815   else
 816     if test -n "${python_prefix}"; then
 817       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 818                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 819       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 820     fi
 821   fi
 822 fi
 823
 824 if test "${have_libpython}" != no; then
 825   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 826   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 827   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 828   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 829   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 830
 831   # Flags needed to compile Python code (taken from python-config --cflags).
 832   # We cannot call python-config directly because it will output whatever was
 833   # used when compiling the Python interpreter itself, including flags which
 834   # would make the python-related objects be compiled differently from the
 835   # rest of GDB (e.g., -O2 and -fPIC).
 836   if test "${GCC}" = yes; then
 837     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 838   fi
 839
 840   if test "x${tentative_python_cflags}" != x; then
 841     AC_MSG_CHECKING(compiler flags for python code)
 842     for flag in ${tentative_python_cflags}; do
 843       # Check that the compiler accepts it
 844       saved_CFLAGS="$CFLAGS"
 845       CFLAGS="$CFLAGS $flag"
 846       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 847       CFLAGS="$saved_CFLAGS"
 848     done
 849     AC_MSG_RESULT(${PYTHON_CFLAGS})
 850   fi
 851 else
 852   # Even if Python support is not compiled in, we need to have these files
 853   # included.
 854   CONFIG_OBS="$CONFIG_OBS python.o py-value.o py-prettyprint.o py-auto-load.o"
 855   CONFIG_SRCS="$CONFIG_SRCS python/python.c python/py-value.c \
 856         python/py-prettyprint.c python/py-auto-load.c"
 857 fi
 858 AC_SUBST(PYTHON_CFLAGS)
 859
 860 # ------------------------- #
 861 # Checks for header files.  #
 862 # ------------------------- #
 863
 864 AC_HEADER_DIRENT
 865 AC_HEADER_STAT
 866 AC_HEADER_STDC
 867 # elf_hp.h is for HP/UX 64-bit shared library support.
 868 # FIXME: kettenis/20030102: In most cases we include these (ctype.h, time.h)
 869 # unconditionally, so what's the point in checking these?
 870 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
 871                   thread_db.h gnu/libc-version.h signal.h stddef.h \
 872                   stdlib.h string.h memory.h strings.h sys/fault.h \
 873                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
 874                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
 875                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
 876                   sys/types.h sys/wait.h wait.h termios.h termio.h \
 877                   sgtty.h unistd.h elf_hp.h ctype.h time.h locale.h])
 878 AC_CHECK_HEADERS(link.h, [], [],
 879 [#if HAVE_SYS_TYPES_H
 880 # include <sys/types.h>
 881 #endif
 882 #if HAVE_NLIST_H
 883 # include <nlist.h>
 884 #endif
 885 ])
 886 AC_CHECK_HEADERS(sys/proc.h, [], [],
 887 [#if HAVE_SYS_PARAM_H
 888 # include <sys/param.h>
 889 #endif
 890 ])
 891 AC_CHECK_HEADERS(sys/user.h, [], [],
 892 [#if HAVE_SYS_PARAM_H
 893 # include <sys/param.h>
 894 #endif
 895 ])
 896
 897 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
 898 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
 899 # think that we don't have <curses.h> if we're using GCC.
 900 case $host_os in
 901   solaris2.[[789]])
 902     if test "$GCC" = yes; then
 903       AC_DEFINE(_MSE_INT_H, 1,
 904         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
 905    Solaris 2.[789] when using GCC. ])
 906     fi ;;
 907 esac
 908 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
 909 AC_CHECK_HEADERS(term.h, [], [],
 910 [#if HAVE_CURSES_H
 911 # include <curses.h>
 912 #endif
 913 ])
 914
 915 # ------------------------- #
 916 # Checks for declarations.  #
 917 # ------------------------- #
 918
 919 AC_CHECK_DECLS([free, malloc, realloc, strerror, strstr, getopt,
 920                 snprintf, vsnprintf])
 921 AM_LC_MESSAGES
 922
 923 # ----------------------- #
 924 # Checks for structures.  #
 925 # ----------------------- #
 926
 927 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
 928
 929 # ------------------ #
 930 # Checks for types.  #
 931 # ------------------ #
 932
 933 AC_TYPE_SIGNAL
 934 AC_CHECK_TYPES(socklen_t, [], [],
 935 [#include <sys/types.h>
 936 #include <sys/socket.h>
 937 ])
 938
 939 # ------------------------------------- #
 940 # Checks for compiler characteristics.  #
 941 # ------------------------------------- #
 942
 943 AC_C_CONST
 944 AC_C_INLINE
 945 AC_C_BIGENDIAN
 946
 947 # ------------------------------ #
 948 # Checks for library functions.  #
 949 # ------------------------------ #
 950
 951 AC_FUNC_ALLOCA
 952 AC_FUNC_MMAP
 953 AC_FUNC_VFORK
 954 AC_CHECK_FUNCS([canonicalize_file_name realpath getrusage getuid \
 955                 getgid pipe poll pread64 sbrk setpgid setpgrp setsid \
 956                 sigaction sigprocmask sigsetmask socketpair syscall \
 957                 ttrace wborder setlocale iconvlist libiconvlist btowc \
 958                 setrlimit getrlimit posix_madvise])
 959 AM_LANGINFO_CODESET
 960
 961 # Check the return and argument types of ptrace.  No canned test for
 962 # this, so roll our own.
 963 gdb_ptrace_headers='
 964 #if HAVE_SYS_TYPES_H
 965 # include <sys/types.h>
 966 #endif
 967 #if HAVE_SYS_PTRACE_H
 968 # include <sys/ptrace.h>
 969 #endif
 970 #if HAVE_UNISTD_H
 971 # include <unistd.h>
 972 #endif
 973 '
 974 # There is no point in checking if we don't have a prototype.
 975 AC_CHECK_DECLS(ptrace, [], [
 976   : ${gdb_cv_func_ptrace_ret='int'}
 977   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 978 ], $gdb_ptrace_headers)
 979 # Check return type.  Varargs (used on GNU/Linux) conflict with the
 980 # empty argument list, so check for that explicitly.
 981 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
 982   AC_TRY_COMPILE($gdb_ptrace_headers,
 983     [extern long ptrace (enum __ptrace_request, ...);],
 984     gdb_cv_func_ptrace_ret='long',
 985     AC_TRY_COMPILE($gdb_ptrace_headers,
 986       [extern int ptrace ();],
 987       gdb_cv_func_ptrace_ret='int',
 988       gdb_cv_func_ptrace_ret='long')))
 989 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
 990   [Define as the return type of ptrace.])
 991 # Check argument types.
 992 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
 993   AC_TRY_COMPILE($gdb_ptrace_headers,
 994     [extern long ptrace (enum __ptrace_request, ...);],
 995     [gdb_cv_func_ptrace_args='int,int,long,long'],[
 996 for gdb_arg1 in 'int' 'long'; do
 997  for gdb_arg2 in 'pid_t' 'int' 'long'; do
 998   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
 999    for gdb_arg4 in 'int' 'long'; do
1000      AC_TRY_COMPILE($gdb_ptrace_headers, [
1001 extern $gdb_cv_func_ptrace_ret
1002   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
1003 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
1004     break 4;])
1005     for gdb_arg5 in 'int *' 'int' 'long'; do
1006      AC_TRY_COMPILE($gdb_ptrace_headers, [
1007 extern $gdb_cv_func_ptrace_ret
1008   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
1009 ], [
1010 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
1011     break 5;])
1012     done
1013    done
1014   done
1015  done
1016 done
1017 # Provide a safe default value.
1018 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1019 ])])
1020 ac_save_IFS=$IFS; IFS=','
1021 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
1022 IFS=$ac_save_IFS
1023 shift
1024 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
1025   [Define to the type of arg 3 for ptrace.])
1026 if test -n "$[5]"; then
1027   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
1028     [Define to the type of arg 5 for ptrace.])
1029 fi
1030
1031 dnl AC_FUNC_SETPGRP does not work when cross compiling
1032 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1033 if test "$cross_compiling" = no; then
1034   AC_FUNC_SETPGRP
1035 else
1036   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1037     [AC_TRY_COMPILE([
1038 #include <unistd.h>
1039 ], [
1040   if (setpgrp(1,1) == -1)
1041     exit (0);
1042   else
1043     exit (1);
1044 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1045 if test $ac_cv_func_setpgrp_void = yes; then
1046   AC_DEFINE(SETPGRP_VOID, 1)
1047 fi
1048 fi
1049
1050 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
1051 # since sigsetjmp might only be defined as a macro.
1052 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
1053 [AC_TRY_COMPILE([
1054 #include <setjmp.h>
1055 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
1056 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
1057 if test $gdb_cv_func_sigsetjmp = yes; then
1058   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
1059 fi
1060
1061 # Assume we'll default to using the included libiberty regex.
1062 gdb_use_included_regex=yes
1063
1064 # However, if the system regex is GNU regex, then default to *not*
1065 # using the included regex.
1066 AC_CACHE_CHECK(
1067   [for GNU regex],
1068   [gdb_cv_have_gnu_regex],
1069   [AC_TRY_COMPILE(
1070     [#include <gnu-versions.h>],
1071     [#define REGEX_INTERFACE_VERSION 1
1072 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1073 # error "Version mismatch"
1074 #endif],
1075     gdb_cv_have_gnu_regex=yes,
1076     gdb_cv_have_gnu_regex=no)])
1077 if test $gdb_cv_have_gnu_regex = yes; then
1078   gdb_use_included_regex=no
1079 fi
1080
1081 AC_ARG_WITH(included-regex,
1082   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1083   gdb_with_regex=$withval,
1084   gdb_with_regex=$gdb_use_included_regex)
1085 if test "$gdb_with_regex" = yes; then
1086   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1087     [Define to 1 if the regex included in libiberty should be used.])
1088 fi
1089
1090 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1091 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1092 [#include <sys/param.h>
1093 #include <sys/proc.h>
1094 ])
1095
1096 # See if <sys/lwp.h> defines `struct lwp`.
1097 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1098 [AC_TRY_COMPILE([#include <sys/param.h>
1099 #include <sys/lwp.h>], [struct lwp l;],
1100 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1101 if test $gdb_cv_struct_lwp = yes; then
1102   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1103             [Define to 1 if your system has struct lwp.])
1104 fi
1105
1106 # See if <machine/reg.h> degines `struct reg'.
1107 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1108 [AC_TRY_COMPILE([#include <sys/types.h>
1109 #include <machine/reg.h>], [struct reg r;],
1110 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1111 if test $gdb_cv_struct_reg = yes; then
1112   AC_DEFINE(HAVE_STRUCT_REG, 1,
1113             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1114 fi
1115
1116 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1117 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1118 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1119                  [#include <machine/reg.h>])
1120
1121 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1122 AC_MSG_CHECKING(for PTRACE_GETREGS)
1123 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1124 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1125                 [PTRACE_GETREGS;],
1126                 [gdb_cv_have_ptrace_getregs=yes],
1127                 [gdb_cv_have_ptrace_getregs=no])])
1128 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1129 if test $gdb_cv_have_ptrace_getregs = yes; then
1130   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1131   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1132 fi
1133
1134 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1135 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1136 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1137 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1138                 [PTRACE_GETFPXREGS;],
1139                 [gdb_cv_have_ptrace_getfpxregs=yes],
1140                 [gdb_cv_have_ptrace_getfpxregs=no])])
1141 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1142 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1143   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1144   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1145 fi
1146
1147 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1148 AC_MSG_CHECKING(for PT_GETDBREGS)
1149 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1150 [AC_TRY_COMPILE([#include <sys/types.h>
1151 #include <sys/ptrace.h>],
1152                 [PT_GETDBREGS;],
1153                 [gdb_cv_have_pt_getdbregs=yes],
1154                 [gdb_cv_have_pt_getdbregs=no])])
1155 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1156 if test $gdb_cv_have_pt_getdbregs = yes; then
1157   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1158   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1159 fi
1160
1161 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1162 AC_MSG_CHECKING(for PT_GETXMMREGS)
1163 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1164 [AC_TRY_COMPILE([#include <sys/types.h>
1165 #include <sys/ptrace.h>],
1166                 [PT_GETXMMREGS;],
1167                 [gdb_cv_have_pt_getxmmregs=yes],
1168                 [gdb_cv_have_pt_getxmmregs=no])])
1169 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1170 if test $gdb_cv_have_pt_getxmmregs = yes; then
1171   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1172   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1173 fi
1174
1175 # Detect which type of /proc is in use, such as for Unixware or Solaris.
1176
1177 if test "${target}" = "${host}"; then
1178   case "${host}" in
1179   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
1180       AC_DEFINE(NEW_PROC_API, 1,
1181       [Define if you want to use new multi-fd /proc interface
1182        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1183       ;;
1184   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1185       AC_DEFINE(NEW_PROC_API, 1,
1186       [Define if you want to use new multi-fd /proc interface
1187        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1188       ;;
1189   mips-sgi-irix5*)
1190       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1191       AC_DEFINE([_KMEMUSER], 1,
1192       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1193        around a <sys/proc.h> problem on IRIX 5.])
1194       ;;
1195   esac
1196 fi
1197
1198 if test "$ac_cv_header_sys_procfs_h" = yes; then
1199   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
1200   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
1201   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1202   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1203   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1204   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1205   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1206   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
1207   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1208   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1209   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1210   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1211   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1212   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1213
1214
1215   dnl Check for broken prfpregset_t type
1216
1217   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1218   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1219   dnl instead of the struct itself).  We detect this here, and work
1220   dnl around it in gdb_proc_service.h.
1221
1222   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1223     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1224     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1225       [AC_TRY_RUN([#include <sys/procfs.h>
1226        int main ()
1227        {
1228          if (sizeof (prfpregset_t) == sizeof (void *))
1229            return 1;
1230          return 0;
1231        }],
1232        gdb_cv_prfpregset_t_broken=no,
1233        gdb_cv_prfpregset_t_broken=yes,
1234        gdb_cv_prfpregset_t_broken=yes)])
1235     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1236     if test $gdb_cv_prfpregset_t_broken = yes; then
1237       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1238       [Define if the prfpregset_t type is broken.])
1239     fi
1240   fi
1241
1242   dnl Check for PIOCSET ioctl entry
1243
1244   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
1245   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
1246   [AC_TRY_COMPILE([#include <unistd.h>
1247 #include <sys/types.h>
1248 #include <sys/procfs.h>
1249 ], [
1250     int dummy;;
1251     dummy = ioctl(0, PIOCSET, &dummy);
1252   ],
1253   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
1254   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
1255   if test $gdb_cv_have_procfs_piocset = yes; then
1256     AC_DEFINE(HAVE_PROCFS_PIOCSET, 1,
1257     [Define if ioctl argument PIOCSET is available.])
1258   fi
1259 fi
1260
1261 dnl For native ports (host == target), check to see what kind of
1262 dnl legacy link.h support is needed.  (See solib-legacy.c.)
1263 if test ${host} = ${target} ; then
1264   dnl Check for struct link_map with l_ members which are indicative
1265   dnl of SVR4-like shared libraries
1266
1267   AC_MSG_CHECKING(for member l_addr in struct link_map)
1268   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
1269     [AC_TRY_COMPILE([#include <link.h>],
1270                     [struct link_map lm; (void) lm.l_addr;],
1271                     gdb_cv_have_struct_link_map_with_l_members=yes,
1272                     gdb_cv_have_struct_link_map_with_l_members=no)])
1273   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
1274   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
1275     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1,
1276     [Define if <link.h> exists and defines struct link_map which has
1277      members with an ``l_'' prefix.  (For Solaris, SVR4, and
1278      SVR4-like systems.)])
1279   fi
1280
1281   dnl Check for struct link_map with lm_ members which are indicative
1282   dnl of SunOS-like shared libraries
1283
1284   AC_MSG_CHECKING(for member lm_addr in struct link_map)
1285   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
1286     [AC_TRY_COMPILE([#include <sys/types.h>
1287 #include <link.h>],
1288                     [struct link_map lm; (void) lm.lm_addr;],
1289                     gdb_cv_have_struct_link_map_with_lm_members=yes,
1290                     gdb_cv_have_struct_link_map_with_lm_members=no)])
1291   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
1292   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
1293     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1,
1294     [Define if <link.h> exists and defines struct link_map which has
1295      members with an ``lm_'' prefix.  (For SunOS.)])
1296   fi
1297
1298   dnl Check for struct so_map with som_ members which are found on
1299   dnl some *BSD systems.
1300
1301   AC_MSG_CHECKING(for member som_addr in struct so_map)
1302   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
1303     [AC_TRY_COMPILE([#include <sys/types.h>
1304 #ifdef HAVE_NLIST_H
1305 #include <nlist.h>
1306 #endif
1307 #include <link.h>],
1308                     [struct so_map lm; (void) lm.som_addr;],
1309                     gdb_cv_have_struct_so_map_with_som_members=yes,
1310                     gdb_cv_have_struct_so_map_with_som_members=no)])
1311   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
1312   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
1313     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1,
1314     [Define if <link.h> exists and defines a struct so_map which has
1315      members with an ``som_'' prefix.  (Found on older *BSD systems.)])
1316   fi
1317
1318   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
1319   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
1320
1321   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
1322   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
1323     [AC_TRY_COMPILE([#define _SYSCALL32
1324 #include <sys/link.h>], [struct link_map32 l;],
1325      gdb_cv_have_struct_link_map32=yes,
1326      gdb_cv_have_struct_link_map32=no)])
1327   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
1328   if test $gdb_cv_have_struct_link_map32 = yes; then
1329     AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1,
1330     [Define if <sys/link.h> has struct link_map32])
1331     AC_DEFINE(_SYSCALL32, 1,
1332     [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)])
1333   fi
1334 fi
1335
1336 # Check if the compiler supports the `long long' type.
1337
1338 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1339                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1340 [[extern long long foo;]],
1341 [[switch (foo & 2) { case 0: return 1; }]])],
1342                                   gdb_cv_c_long_long=yes,
1343                                   gdb_cv_c_long_long=no)])
1344 if test $gdb_cv_c_long_long = yes; then
1345   AC_DEFINE(CC_HAS_LONG_LONG, 1,
1346             [Define to 1 if the compiler supports long long.])
1347 fi
1348
1349 # Check if the compiler and runtime support printing long longs.
1350
1351 AC_CACHE_CHECK([for long long support in printf],
1352                gdb_cv_printf_has_long_long,
1353                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1354 [[char buf[32];
1355   long long l = 0;
1356   l = (l << 16) + 0x0123;
1357   l = (l << 16) + 0x4567;
1358   l = (l << 16) + 0x89ab;
1359   l = (l << 16) + 0xcdef;
1360   sprintf (buf, "0x%016llx", l);
1361   return (strcmp ("0x0123456789abcdef", buf));]])],
1362                               gdb_cv_printf_has_long_long=yes,
1363                               gdb_cv_printf_has_long_long=no,
1364                               gdb_cv_printf_has_long_long=no)])
1365 if test $gdb_cv_printf_has_long_long = yes; then
1366   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1367             [Define to 1 if the "%ll" format works to print long longs.])
1368 fi
1369
1370 # Check if the compiler and runtime support printing decfloats.
1371
1372 AC_CACHE_CHECK([for decfloat support in printf],
1373                gdb_cv_printf_has_decfloat,
1374                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1375 [[char buf[64];
1376   _Decimal32 d32 = 1.2345df;
1377   _Decimal64 d64 = 1.2345dd;
1378   _Decimal128 d128 = 1.2345dl;
1379   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1380   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1381                               gdb_cv_printf_has_decfloat=yes,
1382                               gdb_cv_printf_has_decfloat=no,
1383                               gdb_cv_printf_has_decfloat=no)])
1384 if test $gdb_cv_printf_has_decfloat = yes; then
1385   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1386             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1387 fi
1388
1389 # Check if the compiler supports the `long double' type.  We can't use
1390 # AC_C_LONG_DOUBLE because that one does additional checks on the
1391 # constants defined in <float.h> that fail on some systems,
1392 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1393
1394 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1395                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1396                                   gdb_cv_c_long_double=yes,
1397                                   gdb_cv_c_long_double=no)])
1398 if test $gdb_cv_c_long_double = yes; then
1399   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1400            [Define to 1 if the compiler supports long double.])
1401 fi
1402
1403 # Check if the compiler and runtime support printing long doubles.
1404
1405 AC_CACHE_CHECK([for long double support in printf],
1406                gdb_cv_printf_has_long_double,
1407                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1408 [[char buf[16];
1409   long double f = 3.141592653;
1410   sprintf (buf, "%Lg", f);
1411   return (strncmp ("3.14159", buf, 7));]])],
1412                               gdb_cv_printf_has_long_double=yes,
1413                               gdb_cv_printf_has_long_double=no,
1414                               gdb_cv_printf_has_long_double=no)])
1415 if test $gdb_cv_printf_has_long_double = yes; then
1416   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1417             [Define to 1 if the "%Lg" format works to print long doubles.])
1418 fi
1419
1420 # Check if the compiler and runtime support scanning long doubles.
1421
1422 AC_CACHE_CHECK([for long double support in scanf],
1423                gdb_cv_scanf_has_long_double,
1424                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1425 [[#include <stdio.h>]],
1426 [[char *buf = "3.141592653";
1427   long double f = 0;
1428   sscanf (buf, "%Lg", &f);
1429   return !(f > 3.14159 && f < 3.14160);]])],
1430                               gdb_cv_scanf_has_long_double=yes,
1431                               gdb_cv_scanf_has_long_double=no,
1432                               gdb_cv_scanf_has_long_double=no)])
1433 if test $gdb_cv_scanf_has_long_double = yes; then
1434   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1435             [Define to 1 if the "%Lg" format works to scan long doubles.])
1436 fi
1437
1438 case ${host_os} in
1439 aix*)
1440   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1441     SAVE_LDFLAGS=$LDFLAGS
1442
1443     case $GCC in
1444     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1445     *) gdb_cv_bigtoc=-bbigtoc ;;
1446     esac
1447
1448     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1449     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1450     LDFLAGS="${SAVE_LDFLAGS}"
1451   ])
1452   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1453   ;;
1454 esac
1455
1456 AC_MSG_CHECKING(for the dynamic export flag)
1457 dynamic_list=false
1458 if test "${gdb_native}" = yes; then
1459    # The dynamically loaded libthread_db needs access to symbols in the gdb
1460    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1461    # may not be supported there.
1462    old_LDFLAGS="$LDFLAGS"
1463    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1464    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1465    LDFLAGS="$LDFLAGS $RDYNAMIC"
1466    if test "${have_libpython}" = no; then
1467      AC_TRY_LINK([], [], [dynamic_list=true])
1468    else
1469      # Workaround http://bugs.python.org/issue4434 where static
1470      # libpythonX.Y.a would get its symbols required for
1471      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1472      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1473      old_CFLAGS="$CFLAGS"
1474      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1475      AC_RUN_IFELSE(
1476        AC_LANG_PROGRAM(
1477          [#include "]${have_libpython}[/Python.h"],
1478          [int err;
1479           Py_Initialize ();
1480           err = PyRun_SimpleString ("import itertools\n");
1481           Py_Finalize ();
1482           return err == 0 ? 0 : 1;]),
1483        [dynamic_list=true], [], [true])
1484      CFLAGS="$old_CFLAGS"
1485    fi
1486    LDFLAGS="$old_LDFLAGS"
1487 fi
1488 if $dynamic_list; then
1489   found="-Wl,--dynamic-list"
1490   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1491 else
1492   found="-rdynamic"
1493   RDYNAMIC="-rdynamic"
1494 fi
1495 AC_SUBST(RDYNAMIC)
1496 AC_MSG_RESULT($found)
1497
1498 dnl For certain native configurations, we need to check whether thread
1499 dnl support can be built in or not.
1500 dnl
1501 dnl Note that we only want this if we are both native (host == target),
1502 dnl and not doing a canadian cross build (build == host).
1503
1504 if test ${build} = ${host} -a ${host} = ${target} ; then
1505    case ${host_os} in
1506    hpux*)
1507       AC_MSG_CHECKING(for HPUX/OSF thread support)
1508       if test -f /usr/include/dce/cma_config.h ; then
1509          if test "$GCC" = "yes" ; then
1510             AC_MSG_RESULT(yes)
1511             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT, 1,
1512             [Define if you have HPUX threads])
1513             CONFIG_OBS="${CONFIG_OBS} hpux-thread.o"
1514             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
1515          else
1516             AC_MSG_RESULT(no (suppressed because you are not using GCC))
1517          fi
1518       else
1519          AC_MSG_RESULT(no)
1520       fi
1521       ;;
1522    solaris*)
1523       # See if thread_db library is around for Solaris thread debugging.
1524       # Note that we must explicitly test for version 1 of the library
1525       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1526       # the same API.
1527       AC_MSG_CHECKING(for Solaris thread debugging library)
1528       if test -f /usr/lib/libthread_db.so.1 ; then
1529          AC_MSG_RESULT(yes)
1530          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1531          [Define if using Solaris thread debugging.])
1532          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1533          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1534          AC_CHECK_LIB(dl, dlopen)
1535          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1536          # Sun randomly tweaked the prototypes in <proc_service.h>
1537          # at one point.
1538          AC_MSG_CHECKING(if <proc_service.h> is old)
1539          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1540             AC_TRY_COMPILE([
1541                 #include <proc_service.h>
1542                 ps_err_e ps_pdwrite
1543                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1544             ],, gdb_cv_proc_service_is_old=no,
1545                 gdb_cv_proc_service_is_old=yes)
1546          ])
1547          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1548          if test $gdb_cv_proc_service_is_old = yes; then
1549             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1550             [Define if <proc_service.h> on solaris uses int instead of
1551              size_t, and assorted other type changes.])
1552          fi
1553       else
1554          AC_MSG_RESULT(no)
1555       fi
1556       ;;
1557    aix*)
1558       AC_MSG_CHECKING(for AiX thread debugging library)
1559       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1560                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1561                                    [#ifndef PTHDB_VERSION_3
1562                                     #error
1563                                     #endif],
1564                                    gdb_cv_have_aix_thread_debug=yes,
1565                                    gdb_cv_have_aix_thread_debug=no)])
1566       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1567       if test $gdb_cv_have_aix_thread_debug = yes; then
1568          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1569          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1570          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
1571       fi
1572       ;;
1573    esac
1574    AC_SUBST(CONFIG_LDFLAGS)
1575 fi
1576
1577 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1578 dnl other error codes.
1579 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1580    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1581                   gdb_cv_thread_db_h_has_td_notalloc,
1582      AC_TRY_COMPILE(
1583        [#include <thread_db.h>],
1584        [int i = TD_NOTALLOC;],
1585        gdb_cv_thread_db_h_has_td_notalloc=yes,
1586        gdb_cv_thread_db_h_has_td_notalloc=no
1587      )
1588    )
1589    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1590                   gdb_cv_thread_db_h_has_td_version,
1591      AC_TRY_COMPILE(
1592        [#include <thread_db.h>],
1593        [int i = TD_VERSION;],
1594        gdb_cv_thread_db_h_has_td_version=yes,
1595        gdb_cv_thread_db_h_has_td_version=no
1596      )
1597    )
1598    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1599                   gdb_cv_thread_db_h_has_td_notls,
1600      AC_TRY_COMPILE(
1601        [#include <thread_db.h>],
1602        [int i = TD_NOTLS;],
1603        gdb_cv_thread_db_h_has_td_notls=yes,
1604        gdb_cv_thread_db_h_has_td_notls=no
1605      )
1606    )
1607 fi
1608 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1609   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1610             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1611 fi
1612 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1613   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1614             [Define if <thread_db.h> has the TD_VERSION error code.])
1615 fi
1616 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1617   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1618             [Define if <thread_db.h> has the TD_NOTLS error code.])
1619 fi
1620
1621 dnl See if we have a sys/syscall header file that has __NR_tkill.
1622 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1623    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1624                   gdb_cv_sys_syscall_h_has_tkill,
1625      AC_TRY_COMPILE(
1626        [#include <sys/syscall.h>],
1627        [int i = __NR_tkill;],
1628        gdb_cv_sys_syscall_h_has_tkill=yes,
1629        gdb_cv_sys_syscall_h_has_tkill=no
1630      )
1631    )
1632 fi
1633 dnl See if we can issue tkill syscall.
1634 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1635   AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1636 fi
1637
1638 dnl Check if we can disable the virtual address space randomization.
1639 dnl The functionality of setarch -R.
1640 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1641 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1642 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1643 #       define ADDR_NO_RANDOMIZE 0x0040000
1644 #      endif
1645        /* Test the flag could be set and stays set.  */
1646        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1647        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1648            return 1])])
1649 AC_RUN_IFELSE([PERSONALITY_TEST],
1650               [have_personality=true],
1651               [have_personality=false],
1652               [AC_LINK_IFELSE([PERSONALITY_TEST],
1653                               [have_personality=true],
1654                               [have_personality=false])])
1655 if $have_personality
1656 then
1657     AC_DEFINE([HAVE_PERSONALITY], 1,
1658               [Define if you support the personality syscall.])
1659 fi
1660
1661 dnl Handle optional features that can be enabled.
1662
1663 target_sysroot_reloc=0
1664 AC_ARG_WITH(sysroot,
1665 AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@], [search for usr/lib et al within DIR]),
1666 [
1667  case ${with_sysroot} in
1668  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
1669  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
1670  esac
1671
1672  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
1673
1674  if test "x$prefix" = xNONE; then
1675   test_prefix=/usr/local
1676  else
1677   test_prefix=$prefix
1678  fi
1679  if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
1680   test_exec_prefix=$test_prefix
1681  else
1682   test_exec_prefix=$exec_prefix
1683  fi
1684  case ${TARGET_SYSTEM_ROOT} in
1685  "${test_prefix}"|"${test_prefix}/"*|\
1686  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
1687  '${prefix}'|'${prefix}/'*|\
1688  '${exec_prefix}'|'${exec_prefix}/'*)
1689    target_sysroot_reloc=1
1690    ;;
1691  esac
1692 ], [
1693  TARGET_SYSTEM_ROOT=
1694  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
1695 ])
1696 TARGET_SYSTEM_ROOT_DEFINE="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE=$target_sysroot_reloc"
1697 AC_SUBST(TARGET_SYSTEM_ROOT)
1698 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
1699
1700 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1701     [automatically load a system-wide gdbinit file],
1702     [])
1703
1704 AC_ARG_ENABLE(werror,
1705   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
1706   [case "${enableval}" in
1707      yes | y) ERROR_ON_WARNING="yes" ;;
1708      no | n)  ERROR_ON_WARNING="no" ;;
1709      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1710    esac])
1711
1712 # Enable -Werror by default when using gcc
1713 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then
1714     ERROR_ON_WARNING=yes
1715 fi
1716
1717 WERROR_CFLAGS=""
1718 if test "${ERROR_ON_WARNING}" = yes ; then
1719     WERROR_CFLAGS="-Werror"
1720 fi
1721
1722 # The entries after -Wno-pointer-sign are disabled warnings which may
1723 # be enabled in the future, which can not currently be used to build
1724 # GDB.
1725 # NOTE: If you change this list, remember to update
1726 # gdb/doc/gdbint.texinfo.
1727 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1728 -Wformat-nonliteral -Wno-pointer-sign \
1729 -Wno-unused -Wunused-value -Wunused-function \
1730 -Wno-switch -Wno-char-subscripts"
1731
1732 # Enable -Wno-format by default when using gcc on mingw since many
1733 # GCC versions complain about %I64.
1734 case "${host}" in
1735   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1736 esac
1737
1738 AC_ARG_ENABLE(build-warnings,
1739 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
1740 [case "${enableval}" in
1741   yes)  ;;
1742   no)   build_warnings="-w";;
1743   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1744         build_warnings="${build_warnings} ${t}";;
1745   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1746         build_warnings="${t} ${build_warnings}";;
1747   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1748 esac
1749 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1750   echo "Setting compiler warning flags = $build_warnings" 6>&1
1751 fi])dnl
1752 AC_ARG_ENABLE(gdb-build-warnings,
1753 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
1754 [case "${enableval}" in
1755   yes)  ;;
1756   no)   build_warnings="-w";;
1757   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1758         build_warnings="${build_warnings} ${t}";;
1759   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1760         build_warnings="${t} ${build_warnings}";;
1761   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1762 esac
1763 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1764   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1765 fi])dnl
1766 WARN_CFLAGS=""
1767 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1768 then
1769     AC_MSG_CHECKING(compiler warning flags)
1770     # Separate out the -Werror flag as some files just cannot be
1771     # compiled with it enabled.
1772     for w in ${build_warnings}; do
1773         case $w in
1774         -Werr*) WERROR_CFLAGS=-Werror ;;
1775         *) # Check that GCC accepts it
1776             saved_CFLAGS="$CFLAGS"
1777             CFLAGS="$CFLAGS $w"
1778             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1779             CFLAGS="$saved_CFLAGS"
1780         esac
1781     done
1782     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1783 fi
1784 AC_SUBST(WARN_CFLAGS)
1785 AC_SUBST(WERROR_CFLAGS)
1786
1787 # In the Cygwin environment, we need some additional flags.
1788 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1789 [AC_EGREP_CPP(lose, [
1790 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1791 lose
1792 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1793
1794
1795 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1796 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1797 case ${host} in
1798   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1799   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1800   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1801 esac
1802 AC_SUBST(SER_HARDWIRE)
1803
1804 # libreadline needs libuser32.a in a cygwin environment
1805 WIN32LIBS=
1806 if test x$gdb_cv_os_cygwin = xyes; then
1807     WIN32LIBS="-luser32"
1808     case "${target}" in
1809         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1810         ;;
1811     esac
1812 fi
1813
1814 # The ser-tcp.c module requires sockets.
1815 case ${host} in
1816   *mingw32*)
1817     AC_DEFINE(USE_WIN32API, 1,
1818               [Define if we should use the Windows API, instead of the
1819                POSIX API.  On Windows, we use the Windows API when
1820                building for MinGW, but the POSIX API when building
1821                for Cygwin.])
1822     WIN32LIBS="$WIN32LIBS -lws2_32"
1823     ;;
1824 esac
1825 AC_SUBST(WIN32LIBS)
1826
1827 # Add ELF support to GDB, but only if BFD includes ELF support.
1828 OLD_CFLAGS=$CFLAGS
1829 OLD_LDFLAGS=$LDFLAGS
1830 OLD_LIBS=$LIBS
1831 CFLAGS="$CFLAGS -I${srcdir}/../include -I../bfd -I${srcdir}/../bfd"
1832 LDFLAGS="$LDFLAGS -L../bfd -L../libiberty"
1833 intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'`
1834 LIBS="-lbfd -liberty $intl $LIBS"
1835 AC_CACHE_CHECK([for ELF support in BFD], gdb_cv_var_elf,
1836 [AC_TRY_LINK(
1837 [#include <stdlib.h>
1838 #include "bfd.h"
1839 #include "elf-bfd.h"
1840 ],
1841 [bfd *abfd = NULL; bfd_get_elf_phdr_upper_bound (abfd); ],
1842 gdb_cv_var_elf=yes, gdb_cv_var_elf=no)])
1843 if test $gdb_cv_var_elf = yes; then
1844   CONFIG_OBS="$CONFIG_OBS elfread.o"
1845   AC_DEFINE(HAVE_ELF, 1,
1846             [Define if ELF support should be included.])
1847 fi
1848 CFLAGS=$OLD_CFLAGS
1849 LDFLAGS=$OLD_LDFLAGS
1850 LIBS=$OLD_LIBS
1851
1852 # Add any host-specific objects to GDB.
1853 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1854
1855 LIBGUI="../libgui/src/libgui.a"
1856 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1857 AC_SUBST(LIBGUI)
1858 AC_SUBST(GUI_CFLAGS_X)
1859
1860 WIN32LDAPP=
1861 AC_SUBST(WIN32LIBS)
1862 AC_SUBST(WIN32LDAPP)
1863
1864 case "${host}" in
1865 *-*-cygwin* | *-*-mingw* )
1866     configdir="win"
1867     ;;
1868 *)
1869     configdir="unix"
1870     ;;
1871 esac
1872
1873 GDBTKLIBS=
1874 if test "${enable_gdbtk}" = "yes"; then
1875
1876     # Gdbtk must have an absolute path to srcdir in order to run
1877     # properly when not installed.
1878     here=`pwd`
1879     cd ${srcdir}
1880     GDBTK_SRC_DIR=`pwd`
1881     cd $here
1882
1883     SC_PATH_TCLCONFIG
1884
1885     # If $no_tk is nonempty, then we can't do Tk, and there is no
1886     # point to doing Tcl.
1887     SC_PATH_TKCONFIG
1888
1889     if test -z "${no_tcl}" -a -z "${no_tk}"; then
1890         SC_LOAD_TCLCONFIG
1891
1892         # Check for in-tree tcl
1893         here=`pwd`
1894         cd ${srcdir}/..
1895         topdir=`pwd`
1896         cd ${here}
1897
1898         intree="no"
1899         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
1900           intree="yes"
1901         fi
1902
1903         # Find Tcl private headers
1904         if test x"${intree}" = xno; then
1905           CY_AC_TCL_PRIVATE_HEADERS
1906           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
1907           TCL_LIBRARY="${TCL_LIB_SPEC}"
1908           TCL_DEPS=""
1909         else
1910           # If building tcl in the same src tree, private headers
1911           # are not needed, but we need to be sure to use the right
1912           # headers library
1913           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
1914           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
1915           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
1916         fi
1917         AC_SUBST(TCL_INCLUDE)
1918         AC_SUBST(TCL_LIBRARY)
1919         AC_SUBST(TCL_DEPS)
1920
1921         SC_LOAD_TKCONFIG
1922
1923         # Check for in-tree Tk
1924         intree="no"
1925         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
1926           intree="yes"
1927         fi
1928
1929         # Find Tk private headers
1930         if test x"${intree}" = xno; then
1931           CY_AC_TK_PRIVATE_HEADERS
1932           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
1933           TK_LIBRARY=${TK_LIB_SPEC}
1934           TK_DEPS=""
1935         else
1936           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
1937           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
1938           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
1939         fi
1940         AC_SUBST(TK_INCLUDE)
1941         AC_SUBST(TK_LIBRARY)
1942         AC_SUBST(TK_DEPS)
1943         AC_SUBST(TK_XINCLUDES)
1944
1945         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1946
1947         # Include some libraries that Tcl and Tk want.
1948         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1949         # Yes, the ordering seems wrong here.  But it isn't.
1950         # TK_LIBS is the list of libraries that need to be linked
1951         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1952         # were in LIBS then any link tests after this point would
1953         # try to include things like `$(LIBGUI)', which wouldn't work.
1954         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1955
1956         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1957         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1958         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1959         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
1960         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
1961         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
1962         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
1963
1964         if test x$gdb_cv_os_cygwin = xyes; then
1965           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1966           WIN32LDAPP="-Wl,--subsystem,console"
1967           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1968         fi
1969
1970         AC_CONFIG_SUBDIRS(gdbtk)
1971     fi
1972 fi
1973
1974 AC_SUBST(X_CFLAGS)
1975 AC_SUBST(X_LDFLAGS)
1976 AC_SUBST(X_LIBS)
1977 AC_SUBST(GDBTKLIBS)
1978 AC_SUBST(GDBTK_CFLAGS)
1979 AC_SUBST(GDBTK_SRC_DIR)
1980
1981 AC_PATH_X
1982
1983 # Unlike the sim directory, whether a simulator is linked is controlled by
1984 # presence of a gdb_sim definition in the target configure.tgt entry.
1985 # This code just checks for a few cases where we'd like to ignore those
1986 # definitions, even when they're present in the '.mt' file.  These cases
1987 # are when --disable-sim is specified, or if the simulator directory is
1988 # not part of the source tree.
1989 #
1990 AC_ARG_ENABLE(sim,
1991 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
1992 [echo "enable_sim = $enable_sim";
1993  echo "enableval = ${enableval}";
1994  case "${enableval}" in
1995   yes) ignore_sim=false ;;
1996   no)  ignore_sim=true ;;
1997   *)   ignore_sim=false ;;
1998  esac],
1999 [ignore_sim=false])
2000
2001 if test ! -d "${srcdir}/../sim"; then
2002   ignore_sim=true
2003 fi
2004
2005 SIM=
2006 SIM_OBS=
2007 if test "${ignore_sim}" = "false"; then
2008   if test x"${gdb_sim}" != x ; then
2009     SIM="${gdb_sim}"
2010     SIM_OBS="remote-sim.o"
2011     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2012   fi
2013 fi
2014 AC_SUBST(SIM)
2015 AC_SUBST(SIM_OBS)
2016
2017 AC_SUBST(ENABLE_CFLAGS)
2018 AC_SUBST(PROFILE_CFLAGS)
2019
2020 AC_SUBST(CONFIG_OBS)
2021 AC_SUBST(CONFIG_DEPS)
2022 AC_SUBST(CONFIG_SRCS)
2023 AC_SUBST(CONFIG_ALL)
2024 AC_SUBST(CONFIG_CLEAN)
2025 AC_SUBST(CONFIG_INSTALL)
2026 AC_SUBST(CONFIG_UNINSTALL)
2027
2028 # List of host floatformats.
2029 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2030 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2031 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2032
2033 # target_subdir is used by the testsuite to find the target libraries.
2034 target_subdir=
2035 if test "${host}" != "${target}"; then
2036     target_subdir="${target_alias}/"
2037 fi
2038 AC_SUBST(target_subdir)
2039
2040 frags=
2041 if test "${gdb_native}" = "yes"; then
2042   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
2043   if test ! -f ${host_makefile_frag}; then
2044     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
2045   fi
2046   frags="$frags $host_makefile_frag"
2047 else
2048   host_makefile_frag=/dev/null
2049 fi
2050
2051 AC_SUBST_FILE(host_makefile_frag)
2052 AC_SUBST(frags)
2053
2054 changequote(,)dnl
2055 if test "${gdb_native}" = "yes"; then
2056 # We pick this up from the host configuration file (.mh) because we
2057 # do not have a native configuration Makefile fragment.
2058 nativefile=`sed -n '
2059 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
2060 ' ${host_makefile_frag}`
2061 fi
2062 changequote([,])
2063
2064 if test x"${gdb_osabi}" != x ; then
2065     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2066                        [Define to the default OS ABI for this configuration.])
2067 fi
2068
2069 # Enable multi-ice-gdb-server.
2070 AC_ARG_ENABLE(multi-ice,
2071 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2072   [case $enableval in
2073     yes | no)
2074       ;;
2075     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2076   esac])
2077 if test "x$enable_multi_ice" = xyes; then
2078    AC_CONFIG_SUBDIRS(multi-ice)
2079 fi
2080
2081 # We only build gdbserver automatically in a native configuration.
2082 if test "$gdb_native" = "yes"; then
2083   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2084   if test "x$build_gdbserver" = xyes; then
2085     AC_MSG_RESULT(yes)
2086     AC_CONFIG_SUBDIRS(gdbserver)
2087   else
2088     AC_MSG_RESULT(no)
2089   fi
2090 fi
2091
2092 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2093 # to an empty version.
2094
2095 files=
2096 links=
2097
2098 rm -f nm.h
2099 if test "${nativefile}" != ""; then
2100     case "${nativefile}" in
2101       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2102       * ) GDB_NM_FILE="${nativefile}"
2103     esac
2104     files="${files} ${GDB_NM_FILE}"
2105     links="${links} nm.h"
2106     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2107 fi
2108 AC_SUBST(GDB_NM_FILE)
2109
2110 AC_LINK_FILES($files, $links)
2111
2112 dnl Check for exe extension set on certain hosts (e.g. Win32)
2113 AC_EXEEXT
2114
2115 dnl  Detect the character set used by this host.
2116 dnl  At the moment, we just assume it's UTF-8.
2117 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2118           [Define to be a string naming the default host character set.])
2119
2120 AC_OUTPUT(Makefile .gdbinit:gdbinit.in gnulib/Makefile,
2121 [
2122 case x$CONFIG_HEADERS in
2123 xconfig.h:config.in)
2124 echo > stamp-h ;;
2125 esac
2126 ])
2127
2128 exit 0