gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2015 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22 AC_INIT(main.c)
  23 AC_CONFIG_HEADER(config.h:config.in)
  24 AM_MAINTAINER_MODE
  25
  26 # Set the 'development' global.
  27 . $srcdir/../bfd/development.sh
  28
  29 AC_PROG_CC
  30 AC_PROG_CXX
  31
  32 AC_USE_SYSTEM_EXTENSIONS
  33 ACX_LARGEFILE
  34 AM_PROG_CC_STDC
  35 AM_PROG_INSTALL_STRIP
  36
  37 AC_CONFIG_AUX_DIR(..)
  38 AC_CANONICAL_SYSTEM
  39 AC_ARG_PROGRAM
  40
  41 # See if we are building with C++, and substitute COMPILER.
  42 GDB_AC_BUILD_WITH_CXX
  43
  44 # Dependency checking.
  45 ZW_CREATE_DEPDIR
  46 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  47
  48 # Check for the 'make' the user wants to use.
  49 AC_CHECK_PROGS(MAKE, make)
  50 MAKE_IS_GNU=
  51 case "`$MAKE --version 2>&1 | sed 1q`" in
  52   *GNU*)
  53     MAKE_IS_GNU=yes
  54     ;;
  55 esac
  56 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  57 AC_PROG_MAKE_SET
  58
  59 gnulib_extra_configure_args=
  60 # If large-file support is disabled, make sure gnulib does the same.
  61 if test "$enable_largefile" = no; then
  62 gnulib_extra_configure_args="$gnulib_extra_configure_args --disable-largefile"
  63 fi
  64
  65 # Configure gnulib.  We need to build gnulib under some other
  66 # directory not "gnulib", to avoid the problem of both GDB and
  67 # GDBserver wanting to build it in the same directory, when building
  68 # in the source dir.
  69 ACX_CONFIGURE_DIR(["gnulib"], ["build-gnulib"],
  70                   ["$gnulib_extra_configure_args"])
  71
  72 dnl List of object files and targets accumulated by configure.
  73
  74 CONFIG_OBS=
  75 CONFIG_DEPS=
  76 CONFIG_SRCS=
  77 ENABLE_CFLAGS=
  78
  79 CONFIG_ALL=
  80 CONFIG_CLEAN=
  81 CONFIG_INSTALL=
  82 CONFIG_UNINSTALL=
  83
  84 dnl Set up for gettext.
  85 ZW_GNU_GETTEXT_SISTER_DIR
  86
  87 localedir='${datadir}/locale'
  88 AC_SUBST(localedir)
  89
  90 if test x"$USE_NLS" = xyes; then
  91    CONFIG_ALL="$CONFIG_ALL all-po"
  92    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  93    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  94    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  95 fi
  96
  97 GNULIB=build-gnulib/import
  98
  99 # For Makefile dependencies.
 100 GNULIB_STDINT_H=
 101 if test x"$STDINT_H" != x; then
 102   GNULIB_STDINT_H=$GNULIB/$STDINT_H
 103 fi
 104 AC_SUBST(GNULIB_STDINT_H)
 105
 106 PACKAGE=gdb
 107 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
 108 AC_SUBST(PACKAGE)
 109
 110 # We never need to detect it in this sub-configure.
 111 # But preserve it for config.status --recheck.
 112 AC_ARG_VAR(MAKEINFO,
 113   [Parent configure detects if it is of sufficient version.])
 114 AC_ARG_VAR(MAKEINFOFLAGS,
 115   [Parameters for MAKEINFO.])
 116
 117 MAKEINFO_EXTRA_FLAGS=""
 118 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
 119   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
 120   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
 121     gdb_cv_have_makeinfo_click=yes
 122   else
 123     gdb_cv_have_makeinfo_click=no
 124   fi])
 125 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 126   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 127 fi
 128 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 129
 130 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 131     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 132     [${libdir}/debug])
 133
 134 # We can't pass paths as command line arguments.
 135 # Mingw32 tries to be clever and will convert the paths for us.
 136 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 137 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 138 # This breaks GDB's relocatable path conversions since paths passed in
 139 # config.h would not get so translated, the path prefixes no longer match.
 140 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 141
 142 # GDB's datadir relocation
 143
 144 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 145     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 146     [${datadir}/gdb])
 147
 148 AC_ARG_WITH(relocated-sources,
 149 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 150 [reloc_srcdir="${withval}"
 151  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 152               [Relocated directory for source files. ])
 153 ])
 154
 155 AC_MSG_CHECKING([for default auto-load directory])
 156 AC_ARG_WITH(auto-load-dir,
 157 AS_HELP_STRING([--with-auto-load-dir=PATH],
 158   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 159   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 160 escape_dir=`echo $with_auto_load_dir | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 161 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 162               [Directories from which to load auto-loaded scripts.])
 163 AC_MSG_RESULT([$with_auto_load_dir])
 164
 165 AC_MSG_CHECKING([for default auto-load safe-path])
 166 AC_ARG_WITH(auto-load-safe-path,
 167 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 168   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 169 AS_HELP_STRING([--without-auto-load-safe-path],
 170                [do not restrict auto-loaded files locations]),
 171     [if test "$with_auto_load_safe_path" = "no"; then
 172      with_auto_load_safe_path="/"
 173      fi],
 174 [with_auto_load_safe_path="$with_auto_load_dir"])
 175 escape_dir=`echo $with_auto_load_safe_path | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 176 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 177               [Directories safe to hold auto-loaded files.])
 178 AC_MSG_RESULT([$with_auto_load_safe_path])
 179
 180 AC_CONFIG_SUBDIRS(testsuite)
 181
 182 # Check whether to support alternative target configurations
 183 AC_ARG_ENABLE(targets,
 184 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 185 [case "${enableval}" in
 186   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 187             ;;
 188   no)       enable_targets= ;;
 189   *)        enable_targets=$enableval ;;
 190 esac])
 191
 192 # Check whether to enable 64-bit support on 32-bit hosts
 193 AC_ARG_ENABLE(64-bit-bfd,
 194 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 195 [case "${enableval}" in
 196   yes)  want64=true  ;;
 197   no)   want64=false ;;
 198   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 199 esac],[want64=false])dnl
 200
 201 # Provide defaults for some variables set by the per-host and per-target
 202 # configuration.
 203 gdb_host_obs=posix-hdep.o
 204
 205 if test "${target}" = "${host}"; then
 206   gdb_native=yes
 207 else
 208   gdb_native=no
 209 fi
 210
 211 . $srcdir/configure.host
 212
 213 # Add in the common host objects.
 214 . $srcdir/common/common.host
 215 gdb_host_obs="$gdb_host_obs $common_host_obs"
 216
 217 # Accumulate some settings from configure.tgt over all enabled targets
 218
 219 TARGET_OBS=
 220 all_targets=
 221 HAVE_NATIVE_GCORE_TARGET=
 222
 223 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 224 do
 225   if test "$targ_alias" = "all"; then
 226     all_targets=true
 227   else
 228     # Canonicalize the secondary target names.
 229     result=`$ac_config_sub $targ_alias 2>/dev/null`
 230     if test -n "$result"; then
 231         targ=$result
 232     else
 233         targ=$targ_alias
 234     fi
 235
 236     . ${srcdir}/configure.tgt
 237
 238     AS_IF([test -z "${gdb_target_obs}"],
 239       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 240
 241     # Target-specific object files
 242     for i in ${gdb_target_obs}; do
 243         case " $TARGET_OBS " in
 244         *" ${i} "*) ;;
 245         *)
 246           TARGET_OBS="$TARGET_OBS ${i}"
 247           ;;
 248         esac
 249     done
 250
 251     # Check whether this target needs 64-bit CORE_ADDR
 252     if test x${want64} = xfalse; then
 253       . ${srcdir}/../bfd/config.bfd
 254     fi
 255
 256     # Check whether this target is native and supports gcore.
 257     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 258        && $gdb_have_gcore; then
 259       HAVE_NATIVE_GCORE_TARGET=1
 260     fi
 261   fi
 262 done
 263
 264 if test x${all_targets} = xtrue; then
 265
 266   # We want all 64-bit targets if we either:
 267   #  - run on a 64-bit host  or
 268   #  - already require 64-bit support for some other target  or
 269   #  - the --enable-64-bit-bfd option was supplied
 270   # Otherwise we only support all 32-bit targets.
 271   #
 272   # NOTE: This test must be in sync with the corresponding
 273   #       tests in BFD!
 274
 275   if test x${want64} = xfalse; then
 276     AC_CHECK_SIZEOF(long)
 277     if test "x${ac_cv_sizeof_long}" = "x8"; then
 278       want64=true
 279     fi
 280   fi
 281   if test x${want64} = xtrue; then
 282     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 283   else
 284     TARGET_OBS='$(ALL_TARGET_OBS)'
 285   fi
 286 fi
 287
 288 AC_SUBST(TARGET_OBS)
 289 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 290
 291 # For other settings, only the main target counts.
 292 gdb_sim=
 293 gdb_osabi=
 294 build_gdbserver=
 295 targ=$target; . ${srcdir}/configure.tgt
 296
 297 # Fetch the default architecture and default target vector from BFD.
 298 targ=$target; . $srcdir/../bfd/config.bfd
 299
 300 # We only want the first architecture, so strip off the others if
 301 # there is more than one.
 302 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 303
 304 if test "x$targ_archs" != x; then
 305   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 306     [Define to BFD's default architecture. ])
 307 fi
 308 if test "x$targ_defvec" != x; then
 309   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 310     [Define to BFD's default target vector. ])
 311 fi
 312
 313 # The CLI cannot be disabled yet, but may be in the future.
 314
 315 # Enable CLI.
 316 AC_ARG_ENABLE(gdbcli,
 317 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 318   [case $enableval in
 319     yes)
 320       ;;
 321     no)
 322       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 323     *)
 324       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 325   esac],
 326   [enable_gdbcli=yes])
 327 if test x"$enable_gdbcli" = xyes; then
 328   if test -d $srcdir/cli; then
 329     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 330     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 331     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 332     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 333   fi
 334 fi
 335
 336 # Enable MI.
 337 AC_ARG_ENABLE(gdbmi,
 338 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 339   [case $enableval in
 340     yes | no)
 341       ;;
 342     *)
 343       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 344   esac],
 345   [enable_gdbmi=yes])
 346 if test x"$enable_gdbmi" = xyes; then
 347   if test -d $srcdir/mi; then
 348     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 349     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 350     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 351     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 352   fi
 353 fi
 354
 355 # Enable TUI.
 356 AC_ARG_ENABLE(tui,
 357 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 358   [case $enableval in
 359     yes | no | auto)
 360       ;;
 361     *)
 362       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 363   esac],enable_tui=auto)
 364
 365 # Enable gdbtk.
 366 AC_ARG_ENABLE(gdbtk,
 367 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 368   [case $enableval in
 369     yes | no)
 370       ;;
 371     *)
 372       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 373   esac],
 374   [if test -d $srcdir/gdbtk; then
 375     enable_gdbtk=yes
 376   else
 377     enable_gdbtk=no
 378   fi])
 379 # We unconditionally disable gdbtk tests on selected platforms.
 380 case $host_os in
 381   go32* | windows*)
 382     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 383     enable_gdbtk=no ;;
 384 esac
 385
 386 # Libunwind support for ia64.
 387
 388 AC_ARG_WITH(libunwind-ia64,
 389 AS_HELP_STRING([--with-libunwind-ia64],
 390                [use libunwind frame unwinding for ia64 targets]),,
 391             [with_libunwind_ia64=auto])
 392
 393 # Backward compatibility option.
 394 if test "${with_libunwind+set}" = set; then
 395   if test x"$with_libunwind_ia64" != xauto; then
 396     AC_MSG_ERROR(
 397       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 398   fi
 399   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 400   with_libunwind_ia64="$with_libunwind"
 401 fi
 402
 403 case "$with_libunwind_ia64" in
 404   yes | no)
 405     ;;
 406   auto)
 407     AC_CHECK_HEADERS(libunwind-ia64.h)
 408     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 409     ;;
 410   *)
 411     AC_MSG_ERROR(
 412       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 413     ;;
 414 esac
 415
 416 if test x"$with_libunwind_ia64" = xyes; then
 417   AC_CHECK_HEADERS(libunwind-ia64.h)
 418   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 419     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 420   fi
 421   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 422   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 423   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 424 fi
 425
 426 opt_curses=no
 427 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 428
 429 prefer_curses=no
 430 if test "$opt_curses" = "yes"; then
 431   prefer_curses=yes
 432 fi
 433
 434 # Profiling support.
 435 AC_ARG_ENABLE(profiling,
 436 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 437   [case $enableval in
 438     yes | no)
 439       ;;
 440     *)
 441       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 442   esac],
 443  [enable_profiling=no])
 444
 445 AC_CHECK_FUNCS(monstartup _mcleanup)
 446 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 447 [AC_TRY_LINK(
 448 [#include <stdlib.h>
 449 extern char _etext;
 450 ],
 451 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 452 if test $ac_cv_var__etext = yes; then
 453   AC_DEFINE(HAVE__ETEXT, 1,
 454             [Define to 1 if your system has the _etext variable. ])
 455 fi
 456 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 457 [AC_TRY_LINK(
 458 [#include <stdlib.h>
 459 extern char etext;
 460 ],
 461 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 462 if test $ac_cv_var_etext = yes; then
 463   AC_DEFINE(HAVE_ETEXT, 1,
 464             [Define to 1 if your system has the etext variable. ])
 465 fi
 466 if test "$enable_profiling" = yes ; then
 467   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 468     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 469   fi
 470   PROFILE_CFLAGS=-pg
 471   OLD_CFLAGS="$CFLAGS"
 472   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 473
 474   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 475     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 476      ac_cv_cc_supports_pg=no)])
 477
 478   if test $ac_cv_cc_supports_pg = no; then
 479     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 480   fi
 481
 482   CFLAGS="$OLD_CFLAGS"
 483 fi
 484
 485 ACX_PKGVERSION([GDB])
 486 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 487 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 488 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 489
 490 # --------------------- #
 491 # Checks for programs.  #
 492 # --------------------- #
 493
 494 AC_PROG_AWK
 495 AC_PROG_INSTALL
 496 AC_PROG_LN_S
 497 AC_PROG_RANLIB
 498 AC_PROG_YACC
 499
 500 AC_CHECK_TOOL(AR, ar)
 501 AC_CHECK_TOOL(DLLTOOL, dlltool)
 502 AC_CHECK_TOOL(WINDRES, windres)
 503
 504 case $host_os in
 505   gnu*)
 506     # Needed for GNU Hurd hosts.
 507     AC_CHECK_TOOL(MIG, mig)
 508     if test x"$MIG" = x; then
 509       AC_MSG_ERROR([MIG not found but required for $host hosts])
 510     fi
 511     ;;
 512 esac
 513
 514 # ---------------------- #
 515 # Checks for libraries.  #
 516 # ---------------------- #
 517
 518 # We might need to link with -lm; most simulators need it.
 519 AC_CHECK_LIB(m, main)
 520
 521 # We need to link with -lw to get `wctype' on Solaris before Solaris
 522 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 523 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 524 # is known to have this problem).  Therefore we avoid libw if we can.
 525 AC_CHECK_FUNC(wctype, [],
 526   [AC_CHECK_LIB(w, wctype)])
 527
 528 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 529 AC_SEARCH_LIBS(gethostbyname, nsl)
 530
 531 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 532 AC_SEARCH_LIBS(socketpair, socket)
 533
 534 # Link in zlib if we can.  This allows us to read compressed debug sections.
 535 AM_ZLIB
 536
 537 # On FreeBSD we may need libutil for kinfo_getvmmap (used by fbsd-nat.c).
 538 AC_SEARCH_LIBS(kinfo_getvmmap, util,
 539   [AC_DEFINE(HAVE_KINFO_GETVMMAP, 1,
 540             [Define to 1 if your system has the kinfo_getvmmap function. ])])
 541
 542 AM_ICONV
 543
 544 # GDB may fork/exec the iconv program to get the list of supported character
 545 # sets.  Allow the user to specify where to find it.
 546 # There are several factors affecting the choice of option name:
 547 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 548 #   the build-time location of libiconv files.
 549 # - The program we need to find is iconv, which comes with glibc.  The user
 550 #   doesn't necessarily have libiconv installed.  Therefore naming this
 551 #   --with-libiconv-foo feels wrong.
 552 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 553 #   defined to work on directories not files (though it really doesn't know
 554 #   the difference).
 555 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 556 #   with --with-libiconv-prefix.
 557 # Putting these together is why the option name is --with-iconv-bin.
 558
 559 AC_ARG_WITH(iconv-bin,
 560 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 561 [iconv_bin="${withval}"
 562  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 563                     [Path of directory of iconv program.])
 564  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 565 ])
 566
 567 # For the TUI, we need enhanced curses functionality.
 568 if test x"$enable_tui" != xno; then
 569   prefer_curses=yes
 570 fi
 571
 572 curses_found=no
 573 if test x"$prefer_curses" = xyes; then
 574   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 575   # curses library because the latter might not provide all the
 576   # functionality we need.  However, this leads to problems on systems
 577   # where the linker searches /usr/local/lib, but the compiler doesn't
 578   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 579   # default installation of ncurses on alpha*-dec-osf* will lead to such
 580   # a situation.
 581   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 582
 583   if test "$ac_cv_search_waddstr" != no; then
 584     curses_found=yes
 585   fi
 586 fi
 587
 588 # Check whether we should enable the TUI, but only do so if we really
 589 # can.
 590 if test x"$enable_tui" != xno; then
 591   if test -d $srcdir/tui; then
 592     if test "$curses_found" != no; then
 593       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 594       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 595       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 596       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 597     else
 598       if test x"$enable_tui" = xyes; then
 599         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 600       else
 601         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 602       fi
 603     fi
 604   fi
 605 fi
 606
 607 # Since GDB uses Readline, we need termcap functionality.  In many
 608 # cases this will be provided by the curses library, but some systems
 609 # have a seperate termcap library, or no curses library at all.
 610
 611 case $host_os in
 612   cygwin*)
 613     if test -d $srcdir/libtermcap; then
 614       LIBS="../libtermcap/libtermcap.a $LIBS"
 615       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 616     fi ;;
 617   go32* | *djgpp*)
 618     ac_cv_search_tgetent="none required"
 619     ;;
 620   *mingw32*)
 621     if test x"$curses_found" != xyes; then
 622       ac_cv_search_tgetent="none required"
 623       CONFIG_OBS="$CONFIG_OBS stub-termcap.o"
 624     fi ;;
 625 esac
 626
 627 # These are the libraries checked by Readline.
 628 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 629
 630 if test "$ac_cv_search_tgetent" = no; then
 631   AC_MSG_ERROR([no termcap library found])
 632 fi
 633
 634 AC_ARG_WITH([system-readline],
 635   [AS_HELP_STRING([--with-system-readline],
 636                   [use installed readline library])])
 637
 638 if test "$with_system_readline" = yes; then
 639   READLINE=-lreadline
 640   READLINE_DEPS=
 641   READLINE_CFLAGS=
 642   READLINE_TEXI_INCFLAG=
 643 else
 644   READLINE='$(READLINE_DIR)/libreadline.a'
 645   READLINE_DEPS='$(READLINE)'
 646   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 647   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 648 fi
 649 AC_SUBST(READLINE)
 650 AC_SUBST(READLINE_DEPS)
 651 AC_SUBST(READLINE_CFLAGS)
 652 AC_SUBST(READLINE_TEXI_INCFLAG)
 653
 654 # Generate jit-reader.h
 655
 656 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 657 TARGET_PTR=
 658
 659 AC_CHECK_SIZEOF(unsigned long long)
 660 AC_CHECK_SIZEOF(unsigned long)
 661 AC_CHECK_SIZEOF(unsigned __int128)
 662
 663 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 664   TARGET_PTR="unsigned long"
 665 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 666   TARGET_PTR="unsigned long long"
 667 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 668   TARGET_PTR="unsigned __int128"
 669 else
 670   TARGET_PTR="unsigned long"
 671 fi
 672
 673 AC_SUBST(TARGET_PTR)
 674 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 675
 676 AC_SEARCH_LIBS(dlopen, dl)
 677
 678 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 679                 [directory to load the JIT readers from],
 680                 [${libdir}/gdb])
 681
 682 AC_ARG_WITH(expat,
 683   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 684   [], [with_expat=auto])
 685 AC_MSG_CHECKING([whether to use expat])
 686 AC_MSG_RESULT([$with_expat])
 687
 688 if test "${with_expat}" = no; then
 689   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 690   HAVE_LIBEXPAT=no
 691 else
 692   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 693                         [XML_Parser p = XML_ParserCreate (0);])
 694   if test "$HAVE_LIBEXPAT" != yes; then
 695     if test "$with_expat" = yes; then
 696       AC_MSG_ERROR([expat is missing or unusable])
 697     else
 698       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 699     fi
 700   else
 701     save_LIBS=$LIBS
 702     LIBS="$LIBS $LIBEXPAT"
 703     AC_CHECK_FUNCS(XML_StopParser)
 704     LIBS=$save_LIBS
 705   fi
 706 fi
 707
 708 # --------------------- #
 709 # Check for libpython.  #
 710 # --------------------- #
 711
 712 dnl Utility to simplify finding libpython.
 713 dnl $1 = pythonX.Y
 714 dnl $2 = the shell variable to assign the result to
 715 dnl      If libpython is found we store $version here.
 716 dnl $3 = additional flags to add to CPPFLAGS
 717 dnl $4 = additional flags to add to LIBS
 718
 719 AC_DEFUN([AC_TRY_LIBPYTHON],
 720 [
 721   version=$1
 722   define([have_libpython_var],$2)
 723   new_CPPFLAGS=$3
 724   new_LIBS=$4
 725   AC_MSG_CHECKING([for ${version}])
 726   save_CPPFLAGS=$CPPFLAGS
 727   save_LIBS=$LIBS
 728   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 729   LIBS="$LIBS $new_LIBS"
 730   found_usable_python=no
 731   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 732                                  [[Py_Initialize ();]]),
 733                  [have_libpython_var=${version}
 734                   found_usable_python=yes
 735                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 736                   PYTHON_LIBS=$new_LIBS])
 737   CPPFLAGS=$save_CPPFLAGS
 738   LIBS=$save_LIBS
 739   AC_MSG_RESULT([${found_usable_python}])
 740 ])
 741
 742 dnl There are several different values for --with-python:
 743 dnl
 744 dnl no -   Don't include python support.
 745 dnl yes -  Include python support, error if it's missing.
 746 dnl        If we find python in $PATH, use it to fetch configure options,
 747 dnl        otherwise assume the compiler can find it with no help from us.
 748 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 749 dnl auto - Same as "yes", but if python is missing from the system,
 750 dnl        fall back to "no".
 751 dnl /path/to/python/exec-prefix -
 752 dnl        Use the python located in this directory.
 753 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 754 dnl        the compilation parameters.  Otherwise use
 755 dnl        -I/path/to/python/exec-prefix/include,
 756 dnl        -L/path/to/python/exec-prefix/lib.
 757 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 758 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 759 dnl        but is deprecated.
 760 dnl /path/to/python/executable -
 761 dnl        Run python-config.py with this version of python to fetch the
 762 dnl        compilation parameters.
 763 dnl        NOTE: This needn't be the real python executable.
 764 dnl        In a cross-compilation scenario (build != host), this could be
 765 dnl        a shell script that provides what python-config.py provides for
 766 dnl        --ldflags, --includes, --exec-prefix.
 767 dnl python-executable -
 768 dnl        Find python-executable in $PATH, and then handle the same as
 769 dnl        /path/to/python/executable.
 770 dnl
 771 dnl If a python program is specified, it is used to run python-config.py and
 772 dnl is passed --ldflags, --includes, --exec-prefix.
 773
 774 AC_ARG_WITH(python,
 775   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 776   [], [with_python=auto])
 777 AC_MSG_CHECKING([whether to use python])
 778 AC_MSG_RESULT([$with_python])
 779
 780 if test "${with_python}" = no; then
 781   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 782   have_libpython=no
 783 else
 784   case "${with_python}" in
 785   [[\\/]]* | ?:[[\\/]]*)
 786     if test -d ${with_python}; then
 787       # Assume the python binary is ${with_python}/bin/python.
 788       python_prog="${with_python}/bin/python"
 789       python_prefix=
 790       # If python does not exit ${with_python}/bin, then try in
 791       # ${with_python}.  On Windows/MinGW, this is where the Python
 792       # executable is.
 793       if test ! -x "${python_prog}"; then
 794         python_prog="${with_python}/python"
 795         python_prefix=
 796       fi
 797       if test ! -x "${python_prog}"; then
 798         # Fall back to gdb 7.0/7.1 behaviour.
 799         python_prog=missing
 800         python_prefix=${with_python}
 801       fi
 802     elif test -x "${with_python}"; then
 803       # While we can't run python compiled for $host (unless host == build),
 804       # the user could write a script that provides the needed information,
 805       # so we support that.
 806       python_prog=${with_python}
 807       python_prefix=
 808     else
 809       AC_ERROR(invalid value for --with-python)
 810     fi
 811     ;;
 812   */*)
 813     # Disallow --with-python=foo/bar.
 814     AC_ERROR(invalid value for --with-python)
 815     ;;
 816   *)
 817     # The user has either specified auto, yes, or the name of the python
 818     # program assumed to be in $PATH.
 819     python_prefix=
 820     case "${with_python}" in
 821     yes | auto)
 822       if test ${build} = ${host}; then
 823         AC_PATH_PROG(python_prog_path, python, missing)
 824         if test "${python_prog_path}" = missing; then
 825           python_prog=missing
 826         else
 827           python_prog=${python_prog_path}
 828         fi
 829       else
 830         # Not much we can do except assume the cross-compiler will find the
 831         # right files.
 832         python_prog=missing
 833       fi
 834       ;;
 835     *)
 836       # While we can't run python compiled for $host (unless host == build),
 837       # the user could write a script that provides the needed information,
 838       # so we support that.
 839       python_prog="${with_python}"
 840       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 841       if test "${python_prog_path}" = missing; then
 842         AC_ERROR(unable to find python program ${python_prog})
 843       fi
 844       ;;
 845     esac
 846   esac
 847
 848   if test "${python_prog}" != missing; then
 849     # We have a python program to use, but it may be too old.
 850     # Don't flag an error for --with-python=auto (the default).
 851     have_python_config=yes
 852     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 853     if test $? != 0; then
 854       have_python_config=failed
 855       if test "${with_python}" != auto; then
 856         AC_ERROR(failure running python-config --includes)
 857       fi
 858     fi
 859     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 860     if test $? != 0; then
 861       have_python_config=failed
 862       if test "${with_python}" != auto; then
 863         AC_ERROR(failure running python-config --ldflags)
 864       fi
 865     fi
 866     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 867     if test $? != 0; then
 868       have_python_config=failed
 869       if test "${with_python}" != auto; then
 870         AC_ERROR(failure running python-config --exec-prefix)
 871       fi
 872     fi
 873   else
 874     # We do not have a python executable we can use to determine where
 875     # to find the Python headers and libs.  We cannot guess the include
 876     # path from the python_prefix either, because that include path
 877     # depends on the Python version.  So, there is nothing much we can
 878     # do except assume that the compiler will be able to find those files.
 879     python_includes=
 880     python_libs=
 881     have_python_config=no
 882   fi
 883
 884   # If we have python-config, only try the configuration it provides.
 885   # Otherwise fallback on the old way of trying different versions of
 886   # python in turn.
 887
 888   have_libpython=no
 889   if test "${have_python_config}" = yes; then
 890     # Determine the Python version by extracting "-lpython<version>"
 891     # part of the python_libs. <version> is usually X.Y with X and Y
 892     # being decimal numbers, but can also be XY (seen on Windows).
 893     #
 894     # The extraction is performed using sed with a regular expression.
 895     # Initially, the regexp used was using the '?' quantifier to make
 896     # the dot in the version number optional.  Unfortunately, this
 897     # does not work with non-GNU versions of sed because, because of
 898     # what looks like a limitation (the '?' quantifier does not work
 899     # with back-references).  We work around this limitation by using
 900     # the '*' quantifier instead.  It means that, in theory, we might
 901     # match unexpected version strings such as "-lpython2..7", but
 902     # this seems unlikely in practice.  And even if that happens,
 903     # an error will be triggered later on, when checking that version
 904     # number.
 905     python_version=`echo " ${python_libs} " \
 906                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 907     case "${python_version}" in
 908     python*)
 909       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 910                        ${python_includes}, ${python_libs})
 911       ;;
 912     *)
 913       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 914       ;;
 915     esac
 916   elif test "${have_python_config}" != failed; then
 917     if test "${have_libpython}" = no; then
 918       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 919                        ${python_includes}, "${python_libs} -lpython2.7")
 920     fi
 921     if test "${have_libpython}" = no; then
 922       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 923                        ${python_includes}, "${python_libs} -lpython2.6")
 924     fi
 925     if test ${have_libpython} = no; then
 926       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 927                        ${python_includes}, "${python_libs} -lpython2.5")
 928     fi
 929     if test ${have_libpython} = no; then
 930       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 931                        ${python_includes}, "${python_libs} -lpython2.4")
 932     fi
 933   fi
 934   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 935     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 936   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 937     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 938   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 939     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 940   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 941     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 942   fi
 943
 944   if test "${have_libpython}" = no; then
 945     case "${with_python}" in
 946     yes)
 947       AC_MSG_ERROR([python is missing or unusable])
 948       ;;
 949     auto)
 950       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 951       ;;
 952     *)
 953       AC_MSG_ERROR([no usable python found at ${with_python}])
 954       ;;
 955     esac
 956   else
 957     if test -n "${python_prefix}"; then
 958       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 959                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 960       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 961     fi
 962   fi
 963 fi
 964
 965 if test "${have_libpython}" != no; then
 966   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 967   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 968   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 969   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 970   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 971   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 972
 973   # Flags needed to compile Python code (taken from python-config --cflags).
 974   # We cannot call python-config directly because it will output whatever was
 975   # used when compiling the Python interpreter itself, including flags which
 976   # would make the python-related objects be compiled differently from the
 977   # rest of GDB (e.g., -O2 and -fPIC).
 978   if test "${GCC}" = yes; then
 979     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 980   fi
 981
 982   if test "x${tentative_python_cflags}" != x; then
 983     AC_MSG_CHECKING(compiler flags for python code)
 984     for flag in ${tentative_python_cflags}; do
 985       # Check that the compiler accepts it
 986       saved_CFLAGS="$CFLAGS"
 987       CFLAGS="$CFLAGS $flag"
 988       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 989       CFLAGS="$saved_CFLAGS"
 990     done
 991     AC_MSG_RESULT(${PYTHON_CFLAGS})
 992   fi
 993
 994   # On x64 Windows, Python's include headers, and pyconfig.h in
 995   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
 996   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
 997   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
 998   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
 999   # The issue was reported to the Python community, but still isn't
1000   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
1001
1002   case "$gdb_host" in
1003     mingw64)
1004            if test "${GCC}" = yes; then
1005              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
1006            fi
1007            ;;
1008   esac
1009
1010   # Note that "python -m threading" cannot be used to check for
1011   # threading support due to a bug in Python 2.7.3
1012   # (http://bugs.python.org/issue15567).
1013   AC_MSG_CHECKING(whether python supports threads)
1014   saved_CPPFLAGS="${CPPFLAGS}"
1015   CPPFLAGS="${PYTHON_CPPFLAGS}"
1016   # Note that the test is reversed so that python_has_threads=yes on
1017   # unexpected failures.
1018   AC_PREPROC_IFELSE(AC_LANG_SOURCE([[
1019 #include <Python.h>
1020 #ifdef WITH_THREAD
1021 # error
1022 #endif
1023   ]]), [python_has_threads=no], [python_has_threads=yes])
1024   AC_MSG_RESULT(${python_has_threads})
1025   CPPFLAGS="${saved_CPPFLAGS}"
1026 else
1027   # Even if Python support is not compiled in, we need to have this file
1028   # included so that the "python" command, et.al., still exists.
1029   CONFIG_OBS="$CONFIG_OBS python.o"
1030   CONFIG_SRCS="$CONFIG_SRCS python/python.c"
1031 fi
1032 AC_SUBST(PYTHON_CFLAGS)
1033 AC_SUBST(PYTHON_CPPFLAGS)
1034 AC_SUBST(PYTHON_LIBS)
1035 AM_CONDITIONAL(HAVE_PYTHON, test "${have_libpython}" != no)
1036
1037 # -------------------- #
1038 # Check for libguile.  #
1039 # -------------------- #
1040
1041 dnl Utility to simplify finding libguile.
1042 dnl $1 = pkg-config-program
1043 dnl $2 = space-separate list of guile versions to try
1044 dnl $3 = yes|no, indicating whether to flag errors or ignore them
1045 dnl $4 = the shell variable to assign the result to
1046 dnl      If libguile is found we store "yes" here.
1047
1048 AC_DEFUN([AC_TRY_LIBGUILE],
1049 [
1050   pkg_config=$1
1051   guile_version_list=$2
1052   flag_errors=$3
1053   define([have_libguile_var],$4)
1054   found_usable_guile=checking
1055   AC_MSG_CHECKING([for usable guile from ${pkg_config}])
1056   for guile_version in ${guile_version_list}; do
1057     ${pkg_config} --exists ${guile_version} 2>/dev/null
1058     if test $? != 0; then
1059       continue
1060     fi
1061     dnl pkg-config says the package exists, so if we get an error now,
1062     dnl that's bad.
1063     new_CPPFLAGS=`${pkg_config} --cflags ${guile_version}`
1064     if test $? != 0; then
1065       AC_MSG_ERROR([failure running pkg-config --cflags ${guile_version}])
1066     fi
1067     new_LIBS=`${pkg_config} --libs ${guile_version}`
1068     if test $? != 0; then
1069       AC_MSG_ERROR([failure running pkg-config --libs ${guile_version}])
1070     fi
1071     dnl If we get this far, great.
1072     found_usable_guile=${guile_version}
1073     break
1074   done
1075   if test "${found_usable_guile}" = "checking"; then
1076     if test "${flag_errors}" = "yes"; then
1077       AC_MSG_ERROR([unable to find usable guile version from "${guile_version_list}"])
1078     else
1079       found_usable_guile=no
1080     fi
1081   fi
1082   dnl One final sanity check.
1083   dnl The user could have said --with-guile=python-2.7.
1084   if test "${found_usable_guile}" != no; then
1085     save_CPPFLAGS=$CPPFLAGS
1086     save_LIBS=$LIBS
1087     CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
1088     LIBS="$LIBS $new_LIBS"
1089     AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "libguile.h"]],
1090                                    [[scm_init_guile ();]]),
1091                    [have_libguile_var=yes
1092                     GUILE_CPPFLAGS=$new_CPPFLAGS
1093                     GUILE_LIBS=$new_LIBS],
1094                    [found_usable_guile=no])
1095     dnl scm_set_automatic_finalization_enabled added in Guile 2.2.
1096     AC_CHECK_FUNC(scm_set_automatic_finalization_enabled,
1097       AC_DEFINE(HAVE_GUILE_MANUAL_FINALIZATION, 1,
1098                 [Define if Guile supports manual finalization.])
1099     )
1100     CPPFLAGS=$save_CPPFLAGS
1101     LIBS=$save_LIBS
1102     if test "${found_usable_guile}" = no; then
1103       if test "${flag_errors}" = yes; then
1104         AC_MSG_FAILURE([linking guile version ${guile_version} test program failed])
1105       fi
1106     fi
1107   fi
1108   AC_MSG_RESULT([${found_usable_guile}])
1109 ])
1110
1111 dnl There are several different values for --with-guile:
1112 dnl
1113 dnl no -   Don't include guile support.
1114 dnl yes -  Include guile support, error if it's missing.
1115 dnl        The pkg-config program must be in $PATH.
1116 dnl auto - Same as "yes", but if guile is missing from the system,
1117 dnl        fall back to "no".
1118 dnl guile-version [guile-version-choice-2 ...] -
1119 dnl        A space-separated list of guile package versions to try.
1120 dnl        These are passed to pkg-config as-is.
1121 dnl        E.g., guile-2.0 or guile-2.2-uninstalled
1122 dnl        This requires making sure PKG_CONFIG_PATH is set appropriately.
1123 dnl /path/to/pkg-config -
1124 dnl        Use this pkg-config program.
1125 dnl        NOTE: This needn't be the "real" pkg-config program.
1126 dnl        It could be a shell script.  It is invoked as:
1127 dnl        pkg-config --exists $version
1128 dnl        pkg-config --cflags $version
1129 dnl        pkg-config --libs $version
1130 dnl        pkg-config --variable guild $version
1131 dnl        The script will be called with $version having each value in
1132 dnl        $try_guile_versions until --exists indicates success.
1133
1134 AC_ARG_WITH(guile,
1135   AS_HELP_STRING([--with-guile@<:@=GUILE@:>@], [include guile support (auto/yes/no/<guile-version>/<pkg-config-program>)]),
1136   [], [with_guile=auto])
1137 AC_MSG_CHECKING([whether to use guile])
1138 AC_MSG_RESULT([$with_guile])
1139
1140 dnl We check guile with pkg-config.
1141 AC_PATH_PROG(pkg_config_prog_path, pkg-config, missing)
1142
1143 try_guile_versions="guile-2.2 guile-2.0"
1144 have_libguile=no
1145 case "${with_guile}" in
1146 no)
1147   AC_MSG_WARN([guile support disabled; some features will be unavailable.])
1148   ;;
1149 auto)
1150   if test "${pkg_config_prog_path}" = "missing"; then
1151     AC_MSG_WARN([pkg-config not found, guile support disabled])
1152   else
1153     AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, no, have_libguile)
1154   fi
1155   ;;
1156 yes)
1157   if test "${pkg_config_prog_path}" = "missing"; then
1158     AC_MSG_ERROR([pkg-config not found])
1159   fi
1160   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, yes, have_libguile)
1161   ;;
1162 [[\\/]]* | ?:[[\\/]]*)
1163   if test -x "${with_guile}"; then
1164     AC_TRY_LIBGUILE(${with_guile}, ${try_guile_versions}, yes, have_libguile)
1165   else
1166     AC_MSG_ERROR([Guile config program not executable: ${with_guile}])
1167   fi
1168   ;;
1169 "" | */*)
1170   # Disallow --with=guile="" and --with-guile=foo/bar.
1171   AC_MSG_ERROR([invalid value for --with-guile])
1172   ;;
1173 *)
1174   # A space separate list of guile versions to try, in order.
1175   if test "${pkg_config_prog_path}" = "missing"; then
1176     AC_MSG_ERROR([pkg-config not found])
1177   fi
1178   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${with_guile}, yes, have_libguile)
1179   ;;
1180 esac
1181
1182 if test "${have_libguile}" != no; then
1183   dnl Get the name of the 'guild' program.
1184   case "${with_guile}" in
1185   [[\\/]]* | ?:[[\\/]]*)
1186     GDB_GUILE_PROGRAM_NAMES(["${with_guile}"], ["${guile_version}"])
1187     ;;
1188   *)
1189     GDB_GUILE_PROGRAM_NAMES(["${pkg_config_prog_path}"], ["${guile_version}"])
1190     ;;
1191   esac
1192
1193   dnl Make sure guild can handle this host.
1194   GDB_TRY_GUILD([$srcdir/guile/lib/gdb/support.scm])
1195   dnl If not, disable guile support.
1196   if test "$ac_cv_guild_ok" = no; then
1197     have_libguile=no
1198     AC_MSG_WARN(disabling guile support, $GUILD fails compiling for $host)
1199   fi
1200 fi
1201
1202 if test "${have_libguile}" != no; then
1203   AC_DEFINE(HAVE_GUILE, 1, [Define if Guile interpreter is being linked in.])
1204   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_GUILE_OBS)"
1205   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_GUILE_DEPS)"
1206   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_GUILE_SRCS)"
1207   CONFIG_INSTALL="$CONFIG_INSTALL install-guile"
1208   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_GUILE_CFLAGS)"
1209
1210   dnl The 'scm_new_smob' function appeared in Guile 2.0.6.
1211   save_LIBS="$LIBS"
1212   save_CPPFLAGS="$CPPFLAGS"
1213   LIBS="$GUILE_LIBS"
1214   CPPFLAGS="$GUILE_CPPFLAGS"
1215   AC_CHECK_FUNCS([scm_new_smob])
1216   LIBS="$save_LIBS"
1217   CPPFLAGS="$save_CPPFLAGS"
1218 else
1219   # Even if Guile support is not compiled in, we need to have these files
1220   # included.
1221   CONFIG_OBS="$CONFIG_OBS guile.o"
1222   CONFIG_SRCS="$CONFIG_SRCS guile/guile.c"
1223 fi
1224 AC_SUBST(GUILE_CPPFLAGS)
1225 AC_SUBST(GUILE_LIBS)
1226 AM_CONDITIONAL(HAVE_GUILE, test "${have_libguile}" != no)
1227
1228 # --------------------- #
1229 # Check for libmcheck.  #
1230 # --------------------- #
1231
1232 # Enable -lmcheck by default (it provides cheap-enough memory mangling),
1233 # but turn it off if Python is enabled with threads, since -lmcheck is
1234 # not thread safe (http://sourceware.org/bugzilla/show_bug.cgi?id=9939),
1235 # and for releases.
1236 if test \( "${have_libpython}" = "no" -o "${python_has_threads}" = "no" \) \
1237    && $development; then
1238   libmcheck_default=yes
1239 else
1240   libmcheck_default=no
1241 fi
1242 GDB_AC_LIBMCHECK(${libmcheck_default})
1243
1244 if test "$ENABLE_LIBMCHECK" = "yes" \
1245         -a "${have_libpython}" != "no" \
1246         -a "${python_has_threads}" = "yes" ; then
1247   AC_MSG_WARN(--enable-libmcheck may lead to spurious crashes if threads are used in python)
1248 fi
1249
1250 # ------------------------- #
1251 # Checks for header files.  #
1252 # ------------------------- #
1253
1254 AC_HEADER_STDC
1255 # elf_hp.h is for HP/UX 64-bit shared library support.
1256 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
1257                   thread_db.h \
1258                   sys/fault.h \
1259                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1260                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1261                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
1262                   termios.h termio.h \
1263                   sgtty.h elf_hp.h \
1264                   dlfcn.h])
1265 AC_CHECK_HEADERS(sys/proc.h, [], [],
1266 [#if HAVE_SYS_PARAM_H
1267 # include <sys/param.h>
1268 #endif
1269 ])
1270 AC_CHECK_HEADERS(sys/user.h, [], [],
1271 [#if HAVE_SYS_PARAM_H
1272 # include <sys/param.h>
1273 #endif
1274 ])
1275
1276 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
1277 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
1278 # think that we don't have <curses.h> if we're using GCC.
1279 case $host_os in
1280   solaris2.[[789]])
1281     if test "$GCC" = yes; then
1282       AC_DEFINE(_MSE_INT_H, 1,
1283         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
1284    Solaris 2.[789] when using GCC. ])
1285     fi ;;
1286 esac
1287 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
1288 AC_CHECK_HEADERS(term.h, [], [],
1289 [#if HAVE_CURSES_H
1290 # include <curses.h>
1291 #endif
1292 ])
1293
1294 # ------------------------- #
1295 # Checks for declarations.  #
1296 # ------------------------- #
1297
1298 libiberty_INIT
1299
1300 AC_CHECK_DECLS([free, malloc, realloc, snprintf])
1301 AM_LC_MESSAGES
1302
1303 # ----------------------- #
1304 # Checks for structures.  #
1305 # ----------------------- #
1306
1307 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1308
1309 # ------------------ #
1310 # Checks for types.  #
1311 # ------------------ #
1312
1313 AC_TYPE_SIGNAL
1314 AC_CHECK_TYPES(socklen_t, [], [],
1315 [#include <sys/types.h>
1316 #include <sys/socket.h>
1317 ])
1318
1319 # ------------------------------------- #
1320 # Checks for compiler characteristics.  #
1321 # ------------------------------------- #
1322
1323 AC_C_CONST
1324 AC_C_INLINE
1325 AC_C_BIGENDIAN
1326
1327 # ------------------------------ #
1328 # Checks for library functions.  #
1329 # ------------------------------ #
1330
1331 AC_FUNC_MMAP
1332 AC_FUNC_VFORK
1333 AC_CHECK_FUNCS([getauxval getrusage getuid getgid \
1334                 pipe poll pread pread64 pwrite resize_term \
1335                 sbrk setpgid setpgrp setsid \
1336                 sigaction sigprocmask sigsetmask socketpair \
1337                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1338                 setrlimit getrlimit posix_madvise waitpid \
1339                 ptrace64 sigaltstack mkdtemp])
1340 AM_LANGINFO_CODESET
1341 GDB_AC_COMMON
1342
1343 # Check the return and argument types of ptrace.  No canned test for
1344 # this, so roll our own.
1345 gdb_ptrace_headers='
1346 #include <sys/types.h>
1347 #if HAVE_SYS_PTRACE_H
1348 # include <sys/ptrace.h>
1349 #endif
1350 #if HAVE_UNISTD_H
1351 # include <unistd.h>
1352 #endif
1353 '
1354 # There is no point in checking if we don't have a prototype.
1355 AC_CHECK_DECLS(ptrace, [], [
1356   : ${gdb_cv_func_ptrace_ret='int'}
1357   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1358 ], $gdb_ptrace_headers)
1359 # Check return type.  Varargs (used on GNU/Linux) conflict with the
1360 # empty argument list, so check for that explicitly.
1361 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
1362   AC_TRY_COMPILE($gdb_ptrace_headers,
1363     [extern long ptrace (enum __ptrace_request, ...);],
1364     gdb_cv_func_ptrace_ret='long',
1365     AC_TRY_COMPILE($gdb_ptrace_headers,
1366       [extern int ptrace ();],
1367       gdb_cv_func_ptrace_ret='int',
1368       gdb_cv_func_ptrace_ret='long')))
1369 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
1370   [Define as the return type of ptrace.])
1371 # Check argument types.
1372 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
1373   AC_TRY_COMPILE($gdb_ptrace_headers,
1374     [extern long ptrace (enum __ptrace_request, ...);],
1375     [gdb_cv_func_ptrace_args='int,int,long,long'],[
1376 for gdb_arg1 in 'int' 'long'; do
1377  for gdb_arg2 in 'pid_t' 'int' 'long'; do
1378   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
1379    for gdb_arg4 in 'int' 'long' 'void *'; do
1380      AC_TRY_COMPILE($gdb_ptrace_headers, [
1381 extern $gdb_cv_func_ptrace_ret
1382   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
1383 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
1384     break 4;])
1385     for gdb_arg5 in 'int *' 'int' 'long'; do
1386      AC_TRY_COMPILE($gdb_ptrace_headers, [
1387 extern $gdb_cv_func_ptrace_ret
1388   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
1389 ], [
1390 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
1391     break 5;])
1392     done
1393    done
1394   done
1395  done
1396 done
1397 # Provide a safe default value.
1398 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1399 ])])
1400 ac_save_IFS=$IFS; IFS=','
1401 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
1402 IFS=$ac_save_IFS
1403 shift
1404 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
1405   [Define to the type of arg 3 for ptrace.])
1406 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG4, $[4],
1407   [Define to the type of arg 4 for ptrace.])
1408 if test -n "$[5]"; then
1409   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
1410     [Define to the type of arg 5 for ptrace.])
1411 fi
1412
1413 dnl AC_FUNC_SETPGRP does not work when cross compiling
1414 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1415 if test "$cross_compiling" = no; then
1416   AC_FUNC_SETPGRP
1417 else
1418   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1419     [AC_TRY_COMPILE([
1420 #include <unistd.h>
1421 ], [
1422   if (setpgrp(1,1) == -1)
1423     exit (0);
1424   else
1425     exit (1);
1426 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1427 if test $ac_cv_func_setpgrp_void = yes; then
1428   AC_DEFINE(SETPGRP_VOID, 1)
1429 fi
1430 fi
1431
1432 # Assume we'll default to using the included libiberty regex.
1433 gdb_use_included_regex=yes
1434
1435 # However, if the system regex is GNU regex, then default to *not*
1436 # using the included regex.
1437 AC_CACHE_CHECK(
1438   [for GNU regex],
1439   [gdb_cv_have_gnu_regex],
1440   [AC_TRY_COMPILE(
1441     [#include <gnu-versions.h>],
1442     [#define REGEX_INTERFACE_VERSION 1
1443 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1444 # error "Version mismatch"
1445 #endif],
1446     gdb_cv_have_gnu_regex=yes,
1447     gdb_cv_have_gnu_regex=no)])
1448 if test $gdb_cv_have_gnu_regex = yes; then
1449   gdb_use_included_regex=no
1450 fi
1451
1452 AC_ARG_WITH(included-regex,
1453   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1454   gdb_with_regex=$withval,
1455   gdb_with_regex=$gdb_use_included_regex)
1456 if test "$gdb_with_regex" = yes; then
1457   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1458     [Define to 1 if the regex included in libiberty should be used.])
1459 fi
1460
1461 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1462 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1463 [#include <sys/param.h>
1464 #include <sys/proc.h>
1465 ])
1466
1467 # See if <sys/lwp.h> defines `struct lwp`.
1468 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1469 [AC_TRY_COMPILE([#include <sys/param.h>
1470 #include <sys/lwp.h>], [struct lwp l;],
1471 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1472 if test $gdb_cv_struct_lwp = yes; then
1473   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1474             [Define to 1 if your system has struct lwp.])
1475 fi
1476
1477 # See if <machine/reg.h> degines `struct reg'.
1478 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1479 [AC_TRY_COMPILE([#include <sys/types.h>
1480 #include <machine/reg.h>], [struct reg r;],
1481 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1482 if test $gdb_cv_struct_reg = yes; then
1483   AC_DEFINE(HAVE_STRUCT_REG, 1,
1484             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1485 fi
1486
1487 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1488 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1489 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1490                  [#include <machine/reg.h>])
1491
1492 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
1493 # Older amd64 Linux's don't have the fs_base and gs_base members of
1494 # `struct user_regs_struct'.
1495 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
1496                  [], [], [#include <sys/user.h>])
1497
1498 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1499 AC_MSG_CHECKING(for PTRACE_GETREGS)
1500 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1501 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1502                 [PTRACE_GETREGS;],
1503                 [gdb_cv_have_ptrace_getregs=yes],
1504                 [gdb_cv_have_ptrace_getregs=no])])
1505 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1506 if test $gdb_cv_have_ptrace_getregs = yes; then
1507   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1508   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1509 fi
1510
1511 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1512 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1513 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1514 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1515                 [PTRACE_GETFPXREGS;],
1516                 [gdb_cv_have_ptrace_getfpxregs=yes],
1517                 [gdb_cv_have_ptrace_getfpxregs=no])])
1518 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1519 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1520   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1521   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1522 fi
1523
1524 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1525 AC_MSG_CHECKING(for PT_GETDBREGS)
1526 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1527 [AC_TRY_COMPILE([#include <sys/types.h>
1528 #include <sys/ptrace.h>],
1529                 [PT_GETDBREGS;],
1530                 [gdb_cv_have_pt_getdbregs=yes],
1531                 [gdb_cv_have_pt_getdbregs=no])])
1532 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1533 if test $gdb_cv_have_pt_getdbregs = yes; then
1534   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1535   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1536 fi
1537
1538 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1539 AC_MSG_CHECKING(for PT_GETXMMREGS)
1540 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1541 [AC_TRY_COMPILE([#include <sys/types.h>
1542 #include <sys/ptrace.h>],
1543                 [PT_GETXMMREGS;],
1544                 [gdb_cv_have_pt_getxmmregs=yes],
1545                 [gdb_cv_have_pt_getxmmregs=no])])
1546 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1547 if test $gdb_cv_have_pt_getxmmregs = yes; then
1548   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1549   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1550 fi
1551
1552 # Detect which type of /proc is in use, such as for Solaris.
1553
1554 if test "${target}" = "${host}"; then
1555   case "${host}" in
1556   *-*-sysv4.2* | *-*-sysv5* )
1557       AC_DEFINE(NEW_PROC_API, 1,
1558       [Define if you want to use new multi-fd /proc interface.])
1559       ;;
1560   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1561       AC_DEFINE(NEW_PROC_API, 1,
1562       [Define if you want to use new multi-fd /proc interface.])
1563       ;;
1564   mips-sgi-irix5*)
1565       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1566       AC_DEFINE([_KMEMUSER], 1,
1567       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1568        around a <sys/proc.h> problem on IRIX 5.])
1569       ;;
1570   esac
1571 fi
1572
1573 if test "$ac_cv_header_sys_procfs_h" = yes; then
1574   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1575   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1576   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1577   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1578   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1579   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1580   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1581   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1582   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1583   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1584   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1585
1586
1587   dnl Check for broken prfpregset_t type
1588
1589   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1590   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1591   dnl instead of the struct itself).  We detect this here, and work
1592   dnl around it in gdb_proc_service.h.
1593
1594   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1595     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1596     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1597       [AC_TRY_RUN([#include <sys/procfs.h>
1598        int main ()
1599        {
1600          if (sizeof (prfpregset_t) == sizeof (void *))
1601            return 1;
1602          return 0;
1603        }],
1604        gdb_cv_prfpregset_t_broken=no,
1605        gdb_cv_prfpregset_t_broken=yes,
1606        gdb_cv_prfpregset_t_broken=yes)])
1607     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1608     if test $gdb_cv_prfpregset_t_broken = yes; then
1609       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1610       [Define if the prfpregset_t type is broken.])
1611     fi
1612   fi
1613 fi
1614
1615 # Check if the compiler supports the `long long' type.
1616
1617 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1618                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1619 [[extern long long foo;]],
1620 [[switch (foo & 2) { case 0: return 1; }]])],
1621                                   gdb_cv_c_long_long=yes,
1622                                   gdb_cv_c_long_long=no)])
1623 if test $gdb_cv_c_long_long != yes; then
1624   # libdecnumber requires long long.
1625   AC_MSG_ERROR([Compiler must support long long for GDB.])
1626 fi
1627
1628 # Check if the compiler and runtime support printing long longs.
1629
1630 AC_CACHE_CHECK([for long long support in printf],
1631                gdb_cv_printf_has_long_long,
1632                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1633 [[char buf[32];
1634   long long l = 0;
1635   l = (l << 16) + 0x0123;
1636   l = (l << 16) + 0x4567;
1637   l = (l << 16) + 0x89ab;
1638   l = (l << 16) + 0xcdef;
1639   sprintf (buf, "0x%016llx", l);
1640   return (strcmp ("0x0123456789abcdef", buf));]])],
1641                               gdb_cv_printf_has_long_long=yes,
1642                               gdb_cv_printf_has_long_long=no,
1643                               gdb_cv_printf_has_long_long=no)])
1644 if test $gdb_cv_printf_has_long_long = yes; then
1645   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1646             [Define to 1 if the "%ll" format works to print long longs.])
1647 fi
1648
1649 # Check if the compiler and runtime support printing decfloats.
1650
1651 AC_CACHE_CHECK([for decfloat support in printf],
1652                gdb_cv_printf_has_decfloat,
1653                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1654 [[char buf[64];
1655   _Decimal32 d32 = 1.2345df;
1656   _Decimal64 d64 = 1.2345dd;
1657   _Decimal128 d128 = 1.2345dl;
1658   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1659   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1660                               gdb_cv_printf_has_decfloat=yes,
1661                               gdb_cv_printf_has_decfloat=no,
1662                               gdb_cv_printf_has_decfloat=no)])
1663 if test $gdb_cv_printf_has_decfloat = yes; then
1664   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1665             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1666 fi
1667
1668 # Check if the compiler supports the `long double' type.  We can't use
1669 # AC_C_LONG_DOUBLE because that one does additional checks on the
1670 # constants defined in <float.h> that fail on some systems,
1671 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1672
1673 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1674                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1675                                   gdb_cv_c_long_double=yes,
1676                                   gdb_cv_c_long_double=no)])
1677 if test $gdb_cv_c_long_double = yes; then
1678   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1679            [Define to 1 if the compiler supports long double.])
1680 fi
1681
1682 # Check if the compiler and runtime support printing long doubles.
1683
1684 AC_CACHE_CHECK([for long double support in printf],
1685                gdb_cv_printf_has_long_double,
1686                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1687 [[char buf[16];
1688   long double f = 3.141592653;
1689   sprintf (buf, "%Lg", f);
1690   return (strncmp ("3.14159", buf, 7));]])],
1691                               gdb_cv_printf_has_long_double=yes,
1692                               gdb_cv_printf_has_long_double=no,
1693                               gdb_cv_printf_has_long_double=no)])
1694 if test $gdb_cv_printf_has_long_double = yes; then
1695   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1696             [Define to 1 if the "%Lg" format works to print long doubles.])
1697 fi
1698
1699 # Check if the compiler and runtime support scanning long doubles.
1700
1701 AC_CACHE_CHECK([for long double support in scanf],
1702                gdb_cv_scanf_has_long_double,
1703                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1704 [[#include <stdio.h>]],
1705 [[char *buf = "3.141592653";
1706   long double f = 0;
1707   sscanf (buf, "%Lg", &f);
1708   return !(f > 3.14159 && f < 3.14160);]])],
1709                               gdb_cv_scanf_has_long_double=yes,
1710                               gdb_cv_scanf_has_long_double=no,
1711                               gdb_cv_scanf_has_long_double=no)])
1712 if test $gdb_cv_scanf_has_long_double = yes; then
1713   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1714             [Define to 1 if the "%Lg" format works to scan long doubles.])
1715 fi
1716
1717 case ${host_os} in
1718 aix*)
1719   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1720     SAVE_LDFLAGS=$LDFLAGS
1721
1722     case $GCC in
1723     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1724     *) gdb_cv_bigtoc=-bbigtoc ;;
1725     esac
1726
1727     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1728     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1729     LDFLAGS="${SAVE_LDFLAGS}"
1730   ])
1731   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1732   ;;
1733 esac
1734
1735 AC_MSG_CHECKING(for the dynamic export flag)
1736 dynamic_list=false
1737 if test "${gdb_native}" = yes; then
1738    # The dynamically loaded libthread_db needs access to symbols in the gdb
1739    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1740    # may not be supported there.
1741    old_LDFLAGS="$LDFLAGS"
1742    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1743    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1744    LDFLAGS="$LDFLAGS $RDYNAMIC"
1745    if test "${have_libpython}" = no; then
1746      AC_TRY_LINK([], [], [dynamic_list=true])
1747    else
1748      # Workaround http://bugs.python.org/issue4434 where static
1749      # libpythonX.Y.a would get its symbols required for
1750      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1751      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1752      old_CFLAGS="$CFLAGS"
1753      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1754      old_LIBS="$LIBS"
1755      LIBS="$LIBS $PYTHON_LIBS"
1756      AC_RUN_IFELSE(
1757        AC_LANG_PROGRAM(
1758          [#include "]${have_libpython}[/Python.h"],
1759          [int err;
1760           Py_Initialize ();
1761           err = PyRun_SimpleString ("import itertools\n");
1762           Py_Finalize ();
1763           return err == 0 ? 0 : 1;]),
1764        [dynamic_list=true], [], [true])
1765      LIBS="$old_LIBS"
1766      CFLAGS="$old_CFLAGS"
1767    fi
1768    LDFLAGS="$old_LDFLAGS"
1769 fi
1770 if $dynamic_list; then
1771   found="-Wl,--dynamic-list"
1772   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1773 else
1774   found="-rdynamic"
1775   RDYNAMIC="-rdynamic"
1776 fi
1777 AC_SUBST(RDYNAMIC)
1778 AC_MSG_RESULT($found)
1779
1780 dnl For certain native configurations, we need to check whether thread
1781 dnl support can be built in or not.
1782 dnl
1783 dnl Note that we only want this if we are both native (host == target),
1784 dnl and not doing a canadian cross build (build == host).
1785
1786 if test ${build} = ${host} -a ${host} = ${target} ; then
1787    case ${host_os} in
1788    solaris*)
1789       # See if thread_db library is around for Solaris thread debugging.
1790       # Note that we must explicitly test for version 1 of the library
1791       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1792       # the same API.
1793       AC_MSG_CHECKING(for Solaris thread debugging library)
1794       if test -f /usr/lib/libthread_db.so.1 ; then
1795          AC_MSG_RESULT(yes)
1796          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1797          [Define if using Solaris thread debugging.])
1798          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1799          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1800          AC_CHECK_LIB(dl, dlopen)
1801          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1802          # Sun randomly tweaked the prototypes in <proc_service.h>
1803          # at one point.
1804          AC_MSG_CHECKING(if <proc_service.h> is old)
1805          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1806             AC_TRY_COMPILE([
1807                 #include <proc_service.h>
1808                 ps_err_e ps_pdwrite
1809                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1810             ],, gdb_cv_proc_service_is_old=no,
1811                 gdb_cv_proc_service_is_old=yes)
1812          ])
1813          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1814          if test $gdb_cv_proc_service_is_old = yes; then
1815             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1816             [Define if <proc_service.h> on solaris uses int instead of
1817              size_t, and assorted other type changes.])
1818          fi
1819       else
1820          AC_MSG_RESULT(no)
1821       fi
1822       ;;
1823    aix*)
1824       AC_MSG_CHECKING(for AiX thread debugging library)
1825       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1826                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1827                                    [#ifndef PTHDB_VERSION_3
1828                                     #error
1829                                     #endif],
1830                                    gdb_cv_have_aix_thread_debug=yes,
1831                                    gdb_cv_have_aix_thread_debug=no)])
1832       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1833       if test $gdb_cv_have_aix_thread_debug = yes; then
1834          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1835          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1836          LIBS="$LIBS -lpthdebug"
1837
1838          # Older versions of AIX do not provide the declaration for
1839          # the getthrds function (it appears that it was introduced
1840          # with AIX 6.x).
1841          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1842       fi
1843       ;;
1844    esac
1845    AC_SUBST(CONFIG_LDFLAGS)
1846 fi
1847
1848 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1849 dnl other error codes.
1850 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1851    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1852                   gdb_cv_thread_db_h_has_td_notalloc,
1853      AC_TRY_COMPILE(
1854        [#include <thread_db.h>],
1855        [int i = TD_NOTALLOC;],
1856        gdb_cv_thread_db_h_has_td_notalloc=yes,
1857        gdb_cv_thread_db_h_has_td_notalloc=no
1858      )
1859    )
1860    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1861                   gdb_cv_thread_db_h_has_td_version,
1862      AC_TRY_COMPILE(
1863        [#include <thread_db.h>],
1864        [int i = TD_VERSION;],
1865        gdb_cv_thread_db_h_has_td_version=yes,
1866        gdb_cv_thread_db_h_has_td_version=no
1867      )
1868    )
1869    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1870                   gdb_cv_thread_db_h_has_td_notls,
1871      AC_TRY_COMPILE(
1872        [#include <thread_db.h>],
1873        [int i = TD_NOTLS;],
1874        gdb_cv_thread_db_h_has_td_notls=yes,
1875        gdb_cv_thread_db_h_has_td_notls=no
1876      )
1877    )
1878 fi
1879 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1880   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1881             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1882 fi
1883 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1884   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1885             [Define if <thread_db.h> has the TD_VERSION error code.])
1886 fi
1887 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1888   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1889             [Define if <thread_db.h> has the TD_NOTLS error code.])
1890 fi
1891
1892 dnl See if we have a sys/syscall header file that has __NR_tkill.
1893 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1894    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1895                   gdb_cv_sys_syscall_h_has_tkill,
1896      AC_TRY_COMPILE(
1897        [#include <sys/syscall.h>],
1898        [int i = __NR_tkill;],
1899        gdb_cv_sys_syscall_h_has_tkill=yes,
1900        gdb_cv_sys_syscall_h_has_tkill=no
1901      )
1902    )
1903 fi
1904 dnl See if we can issue tkill syscall.
1905 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes"; then
1906   AC_CHECK_FUNC(syscall,
1907     AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1908   )
1909 fi
1910
1911 dnl Check if we can disable the virtual address space randomization.
1912 dnl The functionality of setarch -R.
1913 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1914 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1915 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1916 #       define ADDR_NO_RANDOMIZE 0x0040000
1917 #      endif
1918        /* Test the flag could be set and stays set.  */
1919        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1920        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1921            return 1])])
1922 AC_RUN_IFELSE([PERSONALITY_TEST],
1923               [have_personality=true],
1924               [have_personality=false],
1925               [AC_LINK_IFELSE([PERSONALITY_TEST],
1926                               [have_personality=true],
1927                               [have_personality=false])])
1928 if $have_personality
1929 then
1930     AC_DEFINE([HAVE_PERSONALITY], 1,
1931               [Define if you support the personality syscall.])
1932 fi
1933
1934 dnl Set the host's .gdbinit filename.
1935 case $host_os in
1936   go32* | *djgpp*)
1937     gdbinit=gdb.ini
1938     ;;
1939   *)
1940     gdbinit=.gdbinit
1941     ;;
1942 esac
1943 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1944
1945 dnl Handle optional features that can be enabled.
1946
1947 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1948 # except that the argument to --with-sysroot is optional.
1949 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1950 if test "x$with_sysroot" = xyes; then
1951   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1952 fi
1953 AC_ARG_WITH(sysroot,
1954   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1955                  [search for usr/lib et al within DIR]),
1956   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1957 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1958               [search for usr/lib et al within DIR])
1959 AC_SUBST(TARGET_SYSTEM_ROOT)
1960 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1961
1962 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1963     [automatically load a system-wide gdbinit file],
1964     [])
1965
1966 AC_ARG_ENABLE(werror,
1967   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
1968   [case "${enableval}" in
1969      yes | y) ERROR_ON_WARNING="yes" ;;
1970      no | n)  ERROR_ON_WARNING="no" ;;
1971      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1972    esac])
1973
1974 # Enable -Werror by default when using gcc in C mode.  Leave it off
1975 # for C++ until we're warning clean.  Turn it off for releases.
1976 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" \
1977    && test x"$enable_build_with_cxx" != x"yes" \
1978    && $development; then
1979     ERROR_ON_WARNING=yes
1980 fi
1981
1982 WERROR_CFLAGS=""
1983 if test "${ERROR_ON_WARNING}" = yes ; then
1984     WERROR_CFLAGS="-Werror"
1985 fi
1986
1987 # These options work in either C or C++ modes.
1988 build_warnings="-Wall -Wpointer-arith \
1989 -Wno-unused -Wunused-value -Wunused-function \
1990 -Wno-switch -Wno-char-subscripts \
1991 -Wempty-body"
1992
1993 # Now add in C and C++ specific options, depending on mode.
1994 if test "$enable_build_with_cxx" = "yes"; then
1995    build_warnings="$build_warnings -Wno-sign-compare -Wno-write-strings \
1996 -Wno-narrowing"
1997 else
1998    build_warnings="$build_warnings -Wpointer-sign -Wmissing-prototypes \
1999 -Wdeclaration-after-statement -Wmissing-parameter-type \
2000 -Wold-style-declaration -Wold-style-definition"
2001 fi
2002
2003 # Enable -Wno-format by default when using gcc on mingw since many
2004 # GCC versions complain about %I64.
2005 case "${host}" in
2006   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
2007   *) build_warnings="$build_warnings -Wformat-nonliteral" ;;
2008 esac
2009
2010 AC_ARG_ENABLE(build-warnings,
2011 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
2012 [case "${enableval}" in
2013   yes)  ;;
2014   no)   build_warnings="-w";;
2015   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
2016         build_warnings="${build_warnings} ${t}";;
2017   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
2018         build_warnings="${t} ${build_warnings}";;
2019   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
2020 esac
2021 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
2022   echo "Setting compiler warning flags = $build_warnings" 6>&1
2023 fi])dnl
2024 AC_ARG_ENABLE(gdb-build-warnings,
2025 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
2026 [case "${enableval}" in
2027   yes)  ;;
2028   no)   build_warnings="-w";;
2029   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
2030         build_warnings="${build_warnings} ${t}";;
2031   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
2032         build_warnings="${t} ${build_warnings}";;
2033   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
2034 esac
2035 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
2036   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
2037 fi])dnl
2038
2039 # The set of warnings supported by a C++ compiler is not the same as
2040 # of the C compiler.
2041 if test "$enable_build_with_cxx" = "yes"; then
2042     AC_LANG_PUSH([C++])
2043 fi
2044
2045 WARN_CFLAGS=""
2046 if test "x${build_warnings}" != x -a "x$GCC" = xyes
2047 then
2048     AC_MSG_CHECKING(compiler warning flags)
2049     # Separate out the -Werror flag as some files just cannot be
2050     # compiled with it enabled.
2051     for w in ${build_warnings}; do
2052         case $w in
2053         -Werr*) WERROR_CFLAGS=-Werror ;;
2054         *)
2055             # Check whether GCC accepts it.
2056             saved_CFLAGS="$CFLAGS"
2057             CFLAGS="$CFLAGS $w"
2058             saved_CXXFLAGS="$CXXFLAGS"
2059             CXXFLAGS="$CXXFLAGS $w"
2060             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
2061             CFLAGS="$saved_CFLAGS"
2062             CXXFLAGS="$saved_CXXFLAGS"
2063         esac
2064     done
2065     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
2066 fi
2067 AC_SUBST(WARN_CFLAGS)
2068 AC_SUBST(WERROR_CFLAGS)
2069
2070 if test "$enable_build_with_cxx" = "yes"; then
2071    AC_LANG_POP([C++])
2072 fi
2073
2074 # In the Cygwin environment, we need some additional flags.
2075 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
2076 [AC_EGREP_CPP(^lose$, [
2077 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
2078 lose
2079 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
2080
2081
2082 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
2083 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
2084 case ${host} in
2085   *go32* ) SER_HARDWIRE=ser-go32.o ;;
2086   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
2087   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
2088 esac
2089 AC_SUBST(SER_HARDWIRE)
2090
2091 # libreadline needs libuser32.a in a cygwin environment
2092 WIN32LIBS=
2093 if test x$gdb_cv_os_cygwin = xyes; then
2094     WIN32LIBS="-luser32"
2095     case "${target}" in
2096         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
2097         ;;
2098     esac
2099 fi
2100
2101 # The ser-tcp.c module requires sockets.
2102 case ${host} in
2103   *mingw32*)
2104     AC_DEFINE(USE_WIN32API, 1,
2105               [Define if we should use the Windows API, instead of the
2106                POSIX API.  On Windows, we use the Windows API when
2107                building for MinGW, but the POSIX API when building
2108                for Cygwin.])
2109     WIN32LIBS="$WIN32LIBS -lws2_32"
2110     ;;
2111 esac
2112 AC_SUBST(WIN32LIBS)
2113
2114 # Add ELF support to GDB, but only if BFD includes ELF support.
2115 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
2116                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
2117 if test $gdb_cv_var_elf = yes; then
2118   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o dtrace-probe.o"
2119   AC_DEFINE(HAVE_ELF, 1,
2120             [Define if ELF support should be included.])
2121   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
2122   if test "$plugins" = "yes"; then
2123     AC_SEARCH_LIBS(dlopen, dl)
2124   fi
2125 fi
2126
2127 # Add macho support to GDB, but only if BFD includes it.
2128 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
2129                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
2130 if test $gdb_cv_var_macho = yes; then
2131   CONFIG_OBS="$CONFIG_OBS machoread.o"
2132 fi
2133
2134 # Add any host-specific objects to GDB.
2135 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
2136
2137 # If building on ELF, look for lzma support for embedded compressed debug info.
2138 if test $gdb_cv_var_elf = yes; then
2139   AC_ARG_WITH(lzma,
2140     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
2141     [], [with_lzma=auto])
2142   AC_MSG_CHECKING([whether to use lzma])
2143   AC_MSG_RESULT([$with_lzma])
2144
2145   if test "${with_lzma}" != no; then
2146     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
2147                           [lzma_index_iter iter;
2148                            lzma_index_iter_init (&iter, 0);
2149                            lzma_mf_is_supported (LZMA_MF_HC3);])
2150     if test "$HAVE_LIBLZMA" != yes; then
2151       if test "$with_lzma" = yes; then
2152         AC_MSG_ERROR([missing liblzma for --with-lzma])
2153       fi
2154     fi
2155   fi
2156 fi
2157
2158 LIBGUI="../libgui/src/libgui.a"
2159 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
2160 AC_SUBST(LIBGUI)
2161 AC_SUBST(GUI_CFLAGS_X)
2162
2163 WIN32LDAPP=
2164 AC_SUBST(WIN32LIBS)
2165 AC_SUBST(WIN32LDAPP)
2166
2167 case "${host}" in
2168 *-*-cygwin* | *-*-mingw* )
2169     configdir="win"
2170     ;;
2171 *)
2172     configdir="unix"
2173     ;;
2174 esac
2175
2176 GDBTKLIBS=
2177 if test "${enable_gdbtk}" = "yes"; then
2178
2179     # Gdbtk must have an absolute path to srcdir in order to run
2180     # properly when not installed.
2181     here=`pwd`
2182     cd ${srcdir}
2183     GDBTK_SRC_DIR=`pwd`
2184     cd $here
2185
2186     SC_PATH_TCLCONFIG
2187
2188     # If $no_tk is nonempty, then we can't do Tk, and there is no
2189     # point to doing Tcl.
2190     SC_PATH_TKCONFIG
2191
2192     if test -z "${no_tcl}" -a -z "${no_tk}"; then
2193         SC_LOAD_TCLCONFIG
2194
2195         # Check for in-tree tcl
2196         here=`pwd`
2197         cd ${srcdir}/..
2198         topdir=`pwd`
2199         cd ${here}
2200
2201         intree="no"
2202         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
2203           intree="yes"
2204         fi
2205
2206         # Find Tcl private headers
2207         if test x"${intree}" = xno; then
2208           CY_AC_TCL_PRIVATE_HEADERS
2209           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
2210           TCL_LIBRARY="${TCL_LIB_SPEC}"
2211           TCL_DEPS=""
2212         else
2213           # If building tcl in the same src tree, private headers
2214           # are not needed, but we need to be sure to use the right
2215           # headers library
2216           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2217           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2218           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2219         fi
2220         AC_SUBST(TCL_INCLUDE)
2221         AC_SUBST(TCL_LIBRARY)
2222         AC_SUBST(TCL_DEPS)
2223
2224         SC_LOAD_TKCONFIG
2225
2226         # Check for in-tree Tk
2227         intree="no"
2228         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2229           intree="yes"
2230         fi
2231
2232         # Find Tk private headers
2233         if test x"${intree}" = xno; then
2234           CY_AC_TK_PRIVATE_HEADERS
2235           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2236           TK_LIBRARY=${TK_LIB_SPEC}
2237           TK_DEPS=""
2238         else
2239           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2240           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2241           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2242         fi
2243         AC_SUBST(TK_INCLUDE)
2244         AC_SUBST(TK_LIBRARY)
2245         AC_SUBST(TK_DEPS)
2246         AC_SUBST(TK_XINCLUDES)
2247
2248         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2249
2250         # Include some libraries that Tcl and Tk want.
2251         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2252         # Yes, the ordering seems wrong here.  But it isn't.
2253         # TK_LIBS is the list of libraries that need to be linked
2254         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2255         # were in LIBS then any link tests after this point would
2256         # try to include things like `$(LIBGUI)', which wouldn't work.
2257         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2258
2259         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2260         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2261         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2262         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2263         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2264         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2265         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2266
2267         if test x$gdb_cv_os_cygwin = xyes; then
2268           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2269           WIN32LDAPP="-Wl,--subsystem,console"
2270           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2271         fi
2272
2273         AC_CONFIG_SUBDIRS(gdbtk)
2274     fi
2275 fi
2276
2277 AC_SUBST(X_CFLAGS)
2278 AC_SUBST(X_LDFLAGS)
2279 AC_SUBST(X_LIBS)
2280 AC_SUBST(GDBTKLIBS)
2281 AC_SUBST(GDBTK_CFLAGS)
2282 AC_SUBST(GDBTK_SRC_DIR)
2283
2284 AC_PATH_X
2285
2286 # Unlike the sim directory, whether a simulator is linked is controlled by
2287 # presence of a gdb_sim definition in the target configure.tgt entry.
2288 # This code just checks for a few cases where we'd like to ignore those
2289 # definitions, even when they're present in the '.mt' file.  These cases
2290 # are when --disable-sim is specified, or if the simulator directory is
2291 # not part of the source tree.
2292 #
2293 AC_ARG_ENABLE(sim,
2294 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2295 [echo "enable_sim = $enable_sim";
2296  echo "enableval = ${enableval}";
2297  case "${enableval}" in
2298   yes) ignore_sim=false ;;
2299   no)  ignore_sim=true ;;
2300   *)   ignore_sim=false ;;
2301  esac],
2302 [ignore_sim=false])
2303
2304 if test ! -d "${srcdir}/../sim"; then
2305   ignore_sim=true
2306 fi
2307
2308 SIM=
2309 SIM_OBS=
2310 if test "${ignore_sim}" = "false"; then
2311   if test x"${gdb_sim}" != x ; then
2312     SIM="${gdb_sim}"
2313     SIM_OBS="remote-sim.o"
2314     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2315   fi
2316 fi
2317 AC_SUBST(SIM)
2318 AC_SUBST(SIM_OBS)
2319
2320 AC_SUBST(ENABLE_CFLAGS)
2321 AC_SUBST(PROFILE_CFLAGS)
2322
2323 AC_SUBST(CONFIG_OBS)
2324 AC_SUBST(CONFIG_DEPS)
2325 AC_SUBST(CONFIG_SRCS)
2326 AC_SUBST(CONFIG_ALL)
2327 AC_SUBST(CONFIG_CLEAN)
2328 AC_SUBST(CONFIG_INSTALL)
2329 AC_SUBST(CONFIG_UNINSTALL)
2330
2331 # List of host floatformats.
2332 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2333 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2334 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2335
2336 # target_subdir is used by the testsuite to find the target libraries.
2337 target_subdir=
2338 if test "${host}" != "${target}"; then
2339     target_subdir="${target_alias}/"
2340 fi
2341 AC_SUBST(target_subdir)
2342
2343 frags=
2344 if test "${gdb_native}" = "yes"; then
2345   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
2346   if test ! -f ${host_makefile_frag}; then
2347     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
2348   fi
2349   frags="$frags $host_makefile_frag"
2350 else
2351   host_makefile_frag=/dev/null
2352 fi
2353
2354 AC_SUBST_FILE(host_makefile_frag)
2355 AC_SUBST(frags)
2356
2357 changequote(,)dnl
2358 if test "${gdb_native}" = "yes"; then
2359 # We pick this up from the host configuration file (.mh) because we
2360 # do not have a native configuration Makefile fragment.
2361 nativefile=`sed -n '
2362 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
2363 ' ${host_makefile_frag}`
2364 fi
2365 changequote([,])
2366
2367 if test x"${gdb_osabi}" != x ; then
2368     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2369                        [Define to the default OS ABI for this configuration.])
2370 fi
2371
2372 # Enable multi-ice-gdb-server.
2373 AC_ARG_ENABLE(multi-ice,
2374 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2375   [case $enableval in
2376     yes | no)
2377       ;;
2378     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2379   esac])
2380 if test "x$enable_multi_ice" = xyes; then
2381    AC_CONFIG_SUBDIRS(multi-ice)
2382 fi
2383
2384 AC_ARG_ENABLE(gdbserver,
2385 AS_HELP_STRING([--enable-gdbserver],
2386                [automatically build gdbserver (yes/no/auto, default is auto)]),
2387 [case "${enableval}" in
2388   yes| no|auto) ;;
2389   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2390 esac],[enable_gdbserver=auto])
2391
2392 # We only build gdbserver automatically in a native configuration, and
2393 # only if the user did not explicitly disable its build.
2394 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2395   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2396   if test "x$build_gdbserver" = xyes; then
2397     AC_MSG_RESULT(yes)
2398     AC_CONFIG_SUBDIRS(gdbserver)
2399     gdbserver_build_enabled=yes
2400   else
2401     AC_MSG_RESULT(no)
2402   fi
2403 fi
2404
2405 # If the user explicitly request the gdbserver to be built, verify that
2406 # we were in fact able to enable it.
2407 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2408   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2409 fi
2410
2411 # Check for babeltrace and babeltrace-ctf
2412 AC_ARG_WITH(babeltrace,
2413   AC_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2414   [], [with_babeltrace=auto])
2415 AC_MSG_CHECKING([whether to use babeltrace])
2416 AC_MSG_RESULT([$with_babeltrace])
2417
2418 if test "x$with_babeltrace" = "xno"; then
2419   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2420 else
2421   # Append -Werror to CFLAGS so that configure can catch the warning
2422   # "assignment from incompatible pointer type", which is related to
2423   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2424   # in GDB, while babeltrace 1.0.3 is broken.
2425   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2426   # safe to save and restore CFLAGS here.
2427   saved_CFLAGS=$CFLAGS
2428   CFLAGS="$CFLAGS -Werror"
2429   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2430                         [#include <babeltrace/babeltrace.h>
2431                          #include <babeltrace/ctf/events.h>
2432                          #include <babeltrace/ctf/iterator.h>],
2433                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2434                         struct bt_ctf_event *event = NULL;
2435                         const struct bt_definition *scope;
2436
2437                         bt_iter_set_pos (bt_ctf_get_iter (NULL), pos);
2438                         scope = bt_ctf_get_top_level_scope (event,
2439                                                            BT_STREAM_EVENT_HEADER);
2440                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2441                         ])
2442   CFLAGS=$saved_CFLAGS
2443
2444   if test "$HAVE_LIBBABELTRACE" != yes; then
2445      if test "$with_babeltrace" = yes; then
2446        AC_MSG_ERROR([babeltrace is missing or unusable])
2447      else
2448        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2449      fi
2450   fi
2451 fi
2452
2453 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2454 # to an empty version.
2455
2456 files=
2457 links=
2458
2459 rm -f nm.h
2460 if test "${nativefile}" != ""; then
2461     case "${nativefile}" in
2462       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2463       * ) GDB_NM_FILE="${nativefile}"
2464     esac
2465     files="${files} ${GDB_NM_FILE}"
2466     links="${links} nm.h"
2467     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2468 fi
2469 AC_SUBST(GDB_NM_FILE)
2470
2471 AC_LINK_FILES($files, $links)
2472
2473 dnl Check for exe extension set on certain hosts (e.g. Win32)
2474 AC_EXEEXT
2475
2476 dnl  Detect the character set used by this host.
2477 dnl  At the moment, we just assume it's UTF-8.
2478 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2479           [Define to be a string naming the default host character set.])
2480
2481 GDB_AC_TRANSFORM([gdb], [GDB_TRANSFORM_NAME])
2482 GDB_AC_TRANSFORM([gcore], [GCORE_TRANSFORM_NAME])
2483 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2484
2485 AC_OUTPUT(Makefile gdb-gdb.gdb doc/Makefile data-directory/Makefile,
2486 [
2487 case x$CONFIG_HEADERS in
2488 xconfig.h:config.in)
2489 echo > stamp-h ;;
2490 esac
2491 ])
2492
2493 exit 0