gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   3 dnl 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011
   4 dnl Free Software Foundation, Inc.
   5 dnl
   6 dnl This file is part of GDB.
   7 dnl
   8 dnl This program is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 3 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.59)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_USE_SYSTEM_EXTENSIONS
  30 gl_EARLY
  31 ACX_LARGEFILE
  32 AM_PROG_CC_STDC
  33
  34 AC_CONFIG_AUX_DIR(..)
  35 AC_CANONICAL_SYSTEM
  36
  37 # Dependency checking.
  38 ZW_CREATE_DEPDIR
  39 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  40
  41 # Check for the 'make' the user wants to use.
  42 AC_CHECK_PROGS(MAKE, make)
  43 MAKE_IS_GNU=
  44 case "`$MAKE --version 2>&1 | sed 1q`" in
  45   *GNU*)
  46     MAKE_IS_GNU=yes
  47     ;;
  48 esac
  49 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  50 AC_PROG_MAKE_SET
  51
  52 dnl List of object files and targets accumulated by configure.
  53
  54 CONFIG_OBS=
  55 CONFIG_DEPS=
  56 CONFIG_SRCS=
  57 ENABLE_CFLAGS=
  58
  59 CONFIG_ALL=
  60 CONFIG_CLEAN=
  61 CONFIG_INSTALL=
  62 CONFIG_UNINSTALL=
  63
  64 dnl Set up for gettext.
  65 ZW_GNU_GETTEXT_SISTER_DIR
  66
  67 localedir='${datadir}/locale'
  68 AC_SUBST(localedir)
  69
  70 if test x"$USE_NLS" = xyes; then
  71    CONFIG_ALL="$CONFIG_ALL all-po"
  72    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  73    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  74    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  75 fi
  76
  77 gl_INIT
  78
  79 # For Makefile dependencies.
  80 GNULIB_STDINT_H=
  81 if test x"$STDINT_H" != x; then
  82   GNULIB_STDINT_H=gnulib/$STDINT_H
  83 fi
  84 AC_SUBST(GNULIB_STDINT_H)
  85
  86 PACKAGE=gdb
  87 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  88 AC_SUBST(PACKAGE)
  89
  90 # Do we have a single-tree copy of texinfo?  Even if we do, we can't
  91 # rely on it - libiberty is built before texinfo.
  92 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
  93 if test "x$MAKEINFO" = "x"; then
  94   AC_ERROR([makeinfo is required for compilation])
  95 else
  96   case "$MAKEINFO" in
  97     */missing\ makeinfo*)
  98       AC_ERROR([makeinfo is required for compilation])
  99       ;;
 100   esac
 101 fi
 102 AC_SUBST(MAKEINFO)
 103
 104 # --split-size=5000000 may be already in $MAKEINFO from parent configure.
 105 # Re-running configure in gdb/ would lose it so ensure it stays present.
 106 MAKEINFOFLAGS=${MAKEINFOFLAGS---split-size=5000000}
 107 AC_SUBST(MAKEINFOFLAGS)
 108
 109 MAKEINFO_EXTRA_FLAGS=""
 110 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
 111   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
 112   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
 113     gdb_cv_have_makeinfo_click=yes
 114   else
 115     gdb_cv_have_makeinfo_click=no
 116   fi])
 117 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 118   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 119 fi
 120 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 121
 122 # GDB does not use automake, but gnulib does.  This line lets us
 123 # generate its Makefile.in.
 124 AM_INIT_AUTOMAKE(gdb, UNUSED-VERSION, [no-define])
 125
 126 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 127     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 128     [${libdir}/debug])
 129
 130 # GDB's datadir relocation
 131
 132 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 133     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 134     [${datadir}/gdb])
 135
 136 AC_ARG_WITH(relocated-sources,
 137 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 138 [reloc_srcdir="${withval}"
 139  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 140               [Relocated directory for source files. ])
 141 ])
 142
 143 AC_CONFIG_SUBDIRS(testsuite)
 144
 145 # Check whether to support alternative target configurations
 146 AC_ARG_ENABLE(targets,
 147 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 148 [case "${enableval}" in
 149   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 150             ;;
 151   no)       enable_targets= ;;
 152   *)        enable_targets=$enableval ;;
 153 esac])
 154
 155 # Check whether to enable 64-bit support on 32-bit hosts
 156 AC_ARG_ENABLE(64-bit-bfd,
 157 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 158 [case "${enableval}" in
 159   yes)  want64=true  ;;
 160   no)   want64=false ;;
 161   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 162 esac],[want64=false])dnl
 163
 164 # Provide defaults for some variables set by the per-host and per-target
 165 # configuration.
 166 gdb_host_obs=posix-hdep.o
 167
 168 if test "${target}" = "${host}"; then
 169   gdb_native=yes
 170 else
 171   gdb_native=no
 172 fi
 173
 174 . $srcdir/configure.host
 175
 176 # Accumulate some settings from configure.tgt over all enabled targets
 177
 178 TARGET_OBS=
 179 all_targets=
 180
 181 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 182 do
 183   if test "$targ_alias" = "all"; then
 184     all_targets=true
 185   else
 186     # Canonicalize the secondary target names.
 187     result=`$ac_config_sub $targ_alias 2>/dev/null`
 188     if test -n "$result"; then
 189         targ=$result
 190     else
 191         targ=$targ_alias
 192     fi
 193
 194     . ${srcdir}/configure.tgt
 195
 196     AS_IF([test -z "${gdb_target_obs}"],
 197       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 198
 199     # Target-specific object files
 200     for i in ${gdb_target_obs}; do
 201         case " $TARGET_OBS " in
 202         *" ${i} "*) ;;
 203         *)
 204           TARGET_OBS="$TARGET_OBS ${i}"
 205           ;;
 206         esac
 207     done
 208
 209     # Check whether this target needs 64-bit CORE_ADDR
 210     if test x${want64} = xfalse; then
 211       . ${srcdir}/../bfd/config.bfd
 212     fi
 213   fi
 214 done
 215
 216 if test x${all_targets} = xtrue; then
 217
 218   # We want all 64-bit targets if we either:
 219   #  - run on a 64-bit host  or
 220   #  - already require 64-bit support for some other target  or
 221   #  - the --enable-64-bit-bfd option was supplied
 222   # Otherwise we only support all 32-bit targets.
 223   #
 224   # NOTE: This test must be in sync with the corresponding
 225   #       tests in BFD!
 226
 227   if test x${want64} = xfalse; then
 228     AC_CHECK_SIZEOF(long)
 229     if test "x${ac_cv_sizeof_long}" = "x8"; then
 230       want64=true
 231     fi
 232   fi
 233   if test x${want64} = xtrue; then
 234     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 235   else
 236     TARGET_OBS='$(ALL_TARGET_OBS)'
 237   fi
 238 fi
 239
 240 AC_SUBST(TARGET_OBS)
 241
 242 # For other settings, only the main target counts.
 243 gdb_sim=
 244 gdb_osabi=
 245 build_gdbserver=
 246 targ=$target; . ${srcdir}/configure.tgt
 247
 248 # Fetch the default architecture and default target vector from BFD.
 249 targ=$target; . $srcdir/../bfd/config.bfd
 250
 251 # We only want the first architecture, so strip off the others if
 252 # there is more than one.
 253 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 254
 255 if test "x$targ_archs" != x; then
 256   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 257     [Define to BFD's default architecture. ])
 258 fi
 259 if test "x$targ_defvec" != x; then
 260   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 261     [Define to BFD's default target vector. ])
 262 fi
 263
 264 # The CLI cannot be disabled yet, but may be in the future.
 265
 266 # Enable CLI.
 267 AC_ARG_ENABLE(gdbcli,
 268 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 269   [case $enableval in
 270     yes)
 271       ;;
 272     no)
 273       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 274     *)
 275       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 276   esac],
 277   [enable_gdbcli=yes])
 278 if test x"$enable_gdbcli" = xyes; then
 279   if test -d $srcdir/cli; then
 280     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 281     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 282     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 283     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 284   fi
 285 fi
 286
 287 # Enable MI.
 288 AC_ARG_ENABLE(gdbmi,
 289 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 290   [case $enableval in
 291     yes | no)
 292       ;;
 293     *)
 294       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 295   esac],
 296   [enable_gdbmi=yes])
 297 if test x"$enable_gdbmi" = xyes; then
 298   if test -d $srcdir/mi; then
 299     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 300     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 301     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 302     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 303   fi
 304 fi
 305
 306 # Enable TUI.
 307 AC_ARG_ENABLE(tui,
 308 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 309   [case $enableval in
 310     yes | no | auto)
 311       ;;
 312     *)
 313       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 314   esac],enable_tui=auto)
 315
 316 # Enable gdbtk.
 317 AC_ARG_ENABLE(gdbtk,
 318 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 319   [case $enableval in
 320     yes | no)
 321       ;;
 322     *)
 323       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 324   esac],
 325   [if test -d $srcdir/gdbtk; then
 326     enable_gdbtk=yes
 327   else
 328     enable_gdbtk=no
 329   fi])
 330 # We unconditionally disable gdbtk tests on selected platforms.
 331 case $host_os in
 332   go32* | windows*)
 333     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 334     enable_gdbtk=no ;;
 335 esac
 336
 337 # Libunwind support.
 338 AC_ARG_WITH(libunwind,
 339 AS_HELP_STRING([--with-libunwind], [use libunwind frame unwinding support]),
 340 [case "${withval}" in
 341   yes)  enable_libunwind=yes ;;
 342   no)   enable_libunwind=no ;;
 343   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 344 esac],[
 345   AC_CHECK_HEADERS(libunwind.h libunwind-ia64.h)
 346   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 347     enable_libunwind=yes;
 348   fi
 349 ])
 350
 351 if test x"$enable_libunwind" = xyes; then
 352   AC_CHECK_HEADERS(libunwind.h libunwind-ia64.h)
 353   AC_DEFINE(HAVE_LIBUNWIND, 1, [Define if libunwind library is being used.])
 354   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 355   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 356   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 357 fi
 358
 359 opt_curses=no
 360 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 361
 362 prefer_curses=no
 363 if test "$opt_curses" = "yes"; then
 364   prefer_curses=yes
 365 fi
 366
 367 # Profiling support.
 368 AC_ARG_ENABLE(profiling,
 369 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 370   [case $enableval in
 371     yes | no)
 372       ;;
 373     *)
 374       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 375   esac],
 376  [enable_profiling=no])
 377
 378 AC_CHECK_FUNCS(monstartup _mcleanup)
 379 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 380 [AC_TRY_LINK(
 381 [#include <stdlib.h>
 382 extern char _etext;
 383 ],
 384 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 385 if test $ac_cv_var__etext = yes; then
 386   AC_DEFINE(HAVE__ETEXT, 1,
 387             [Define to 1 if your system has the _etext variable. ])
 388 fi
 389 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 390 [AC_TRY_LINK(
 391 [#include <stdlib.h>
 392 extern char etext;
 393 ],
 394 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 395 if test $ac_cv_var_etext = yes; then
 396   AC_DEFINE(HAVE_ETEXT, 1,
 397             [Define to 1 if your system has the etext variable. ])
 398 fi
 399 if test "$enable_profiling" = yes ; then
 400   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 401     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 402   fi
 403   PROFILE_CFLAGS=-pg
 404   OLD_CFLAGS="$CFLAGS"
 405   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 406
 407   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 408     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 409      ac_cv_cc_supports_pg=no)])
 410
 411   if test $ac_cv_cc_supports_pg = no; then
 412     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 413   fi
 414
 415   CFLAGS="$OLD_CFLAGS"
 416 fi
 417
 418 ACX_PKGVERSION([GDB])
 419 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 420 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 421 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 422
 423 # --------------------- #
 424 # Checks for programs.  #
 425 # --------------------- #
 426
 427 AC_PROG_AWK
 428 AC_PROG_INSTALL
 429 AC_PROG_LN_S
 430 AC_PROG_RANLIB
 431 AC_PROG_YACC
 432
 433 AC_CHECK_TOOL(AR, ar)
 434 AC_CHECK_TOOL(DLLTOOL, dlltool)
 435 AC_CHECK_TOOL(WINDRES, windres)
 436
 437 # Needed for GNU/Hurd.
 438 AC_CHECK_TOOL(MIG, mig)
 439
 440 # ---------------------- #
 441 # Checks for libraries.  #
 442 # ---------------------- #
 443
 444 # We might need to link with -lm; most simulators need it.
 445 AC_CHECK_LIB(m, main)
 446
 447 # We need to link with -lw to get `wctype' on Solaris before Solaris
 448 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 449 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 450 # is known to have this problem).  Therefore we avoid libw if we can.
 451 AC_CHECK_FUNC(wctype, [],
 452   [AC_CHECK_LIB(w, wctype)])
 453
 454 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 455 AC_SEARCH_LIBS(gethostbyname, nsl)
 456
 457 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 458 AC_SEARCH_LIBS(socketpair, socket)
 459
 460 # Link in zlib if we can.  This allows us to read compressed debug sections.
 461 AM_ZLIB
 462
 463 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 464 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 465
 466 AM_ICONV
 467
 468 # GDB may fork/exec the iconv program to get the list of supported character
 469 # sets.  Allow the user to specify where to find it.
 470 # There are several factors affecting the choice of option name:
 471 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 472 #   the build-time location of libiconv files.
 473 # - The program we need to find is iconv, which comes with glibc.  The user
 474 #   doesn't necessarily have libiconv installed.  Therefore naming this
 475 #   --with-libiconv-foo feels wrong.
 476 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 477 #   defined to work on directories not files (though it really doesn't know
 478 #   the difference).
 479 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 480 #   with --with-libiconv-prefix.
 481 # Putting these together is why the option name is --with-iconv-bin.
 482
 483 AC_ARG_WITH(iconv-bin,
 484 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 485 [iconv_bin="${withval}"
 486  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 487                     [Path of directory of iconv program.])
 488  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 489 ])
 490
 491 # On alpha-osf, it appears that libtermcap and libcurses are not compatible.
 492 # There is a very specific comment in /usr/include/curses.h explaining that
 493 # termcap routines built into libcurses must not be used.
 494 #
 495 # The symptoms we observed so far is GDB unexpectedly changing
 496 # the terminal settings when tgetent is called - this is particularly
 497 # visible as the output is missing carriage returns, and so rapidly
 498 # becomes very hard to read.
 499 #
 500 # The readline configure script has already decided that libtermcap
 501 # was enough for its purposes, and so decided to build readline using
 502 # libtermcap.  Since the TUI mode requires curses, building GDB with
 503 # TUI enabled results in both libraries to be used at the same time,
 504 # which is not allowed.  This basically means that GDB with TUI is
 505 # broken on alpha-osf.
 506
 507 case $host_os in
 508   osf* )
 509     if test x"$enable_tui" = xyes; then
 510       AC_MSG_ERROR([Building GDB with TUI mode is not supported on this host])
 511     fi
 512     if test x"$enable_tui" = xauto; then
 513       enable_tui=no
 514     fi
 515     ;;
 516 esac
 517
 518 # For the TUI, we need enhanced curses functionality.
 519 if test x"$enable_tui" != xno; then
 520   prefer_curses=yes
 521 fi
 522
 523 curses_found=no
 524 if test x"$prefer_curses" = xyes; then
 525   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 526   # curses library because the latter might not provide all the
 527   # functionality we need.  However, this leads to problems on systems
 528   # where the linker searches /usr/local/lib, but the compiler doesn't
 529   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 530   # default installation of ncurses on alpha*-dec-osf* will lead to such
 531   # a situation.
 532   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 533
 534   if test "$ac_cv_search_waddstr" != no; then
 535     curses_found=yes
 536   fi
 537 fi
 538
 539 # Check whether we should enable the TUI, but only do so if we really
 540 # can.
 541 if test x"$enable_tui" != xno; then
 542   if test -d $srcdir/tui; then
 543     if test "$curses_found" != no; then
 544       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 545       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 546       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 547       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 548     else
 549       if test x"$enable_tui" = xyes; then
 550         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 551       else
 552         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 553       fi
 554     fi
 555   fi
 556 fi
 557
 558 # Since GDB uses Readline, we need termcap functionality.  In many
 559 # cases this will be provided by the curses library, but some systems
 560 # have a seperate termcap library, or no curses library at all.
 561
 562 case $host_os in
 563   cygwin*)
 564     if test -d $srcdir/libtermcap; then
 565       LIBS="../libtermcap/libtermcap.a $LIBS"
 566       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 567     fi ;;
 568   go32* | *djgpp*)
 569     ac_cv_search_tgetent="none required"
 570     ;;
 571   *mingw32*)
 572     ac_cv_search_tgetent="none required"
 573     CONFIG_OBS="$CONFIG_OBS windows-termcap.o"
 574     ;;
 575 esac
 576
 577 # These are the libraries checked by Readline.
 578 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 579
 580 if test "$ac_cv_search_tgetent" = no; then
 581   AC_MSG_ERROR([no termcap library found])
 582 fi
 583
 584 AC_ARG_WITH([system-readline],
 585   [AS_HELP_STRING([--with-system-readline],
 586                   [use installed readline library])])
 587
 588 if test "$with_system_readline" = yes; then
 589   READLINE=-lreadline
 590   READLINE_DEPS=
 591   READLINE_CFLAGS=
 592   READLINE_TEXI_INCFLAG=
 593 else
 594   READLINE='$(READLINE_DIR)/libreadline.a'
 595   READLINE_DEPS='$(READLINE)'
 596   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 597   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 598 fi
 599 AC_SUBST(READLINE)
 600 AC_SUBST(READLINE_DEPS)
 601 AC_SUBST(READLINE_CFLAGS)
 602 AC_SUBST(READLINE_TEXI_INCFLAG)
 603
 604 # Generate jit-reader.h
 605
 606 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 607 TARGET_PTR=
 608
 609 AC_CHECK_SIZEOF(unsigned long long)
 610 AC_CHECK_SIZEOF(unsigned long)
 611 AC_CHECK_SIZEOF(unsigned __int128)
 612
 613 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 614   TARGET_PTR="unsigned long"
 615 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 616   TARGET_PTR="unsigned long long"
 617 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 618   TARGET_PTR="unsigned __int128"
 619 else
 620   TARGET_PTR="unsigned long"
 621 fi
 622
 623 AC_SUBST(TARGET_PTR)
 624 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 625
 626 AC_SEARCH_LIBS(dlopen, dl)
 627
 628 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 629                 [directory to load the JIT readers from],
 630                 [${libdir}/gdb])
 631
 632 AC_ARG_WITH(expat,
 633   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 634   [], [with_expat=auto])
 635 AC_MSG_CHECKING([whether to use expat])
 636 AC_MSG_RESULT([$with_expat])
 637
 638 if test "${with_expat}" = no; then
 639   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 640   HAVE_LIBEXPAT=no
 641 else
 642   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 643                         [XML_Parser p = XML_ParserCreate (0);])
 644   if test "$HAVE_LIBEXPAT" != yes; then
 645     if test "$with_expat" = yes; then
 646       AC_MSG_ERROR([expat is missing or unusable])
 647     else
 648       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 649     fi
 650   else
 651     save_LIBS=$LIBS
 652     LIBS="$LIBS $LIBEXPAT"
 653     AC_CHECK_FUNCS(XML_StopParser)
 654     LIBS=$save_LIBS
 655   fi
 656 fi
 657
 658 dnl Utility to simplify finding libpython.
 659 dnl $1 = pythonX.Y
 660 dnl $2 = the shell variable to assign the result to
 661 dnl      If libpython is found we store $version here.
 662 dnl $3 = additional flags to add to CPPFLAGS
 663 dnl $4 = additional flags to add to LIBS
 664
 665 AC_DEFUN([AC_TRY_LIBPYTHON],
 666 [
 667   version=$1
 668   define([have_libpython_var],$2)
 669   new_CPPFLAGS=$3
 670   new_LIBS=$4
 671   AC_MSG_CHECKING([for ${version}])
 672   save_CPPFLAGS=$CPPFLAGS
 673   save_LIBS=$LIBS
 674   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 675   LIBS="$LIBS $new_LIBS"
 676   found_usable_python=no
 677   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 678                                  [[Py_Initialize ();]]),
 679                  [have_libpython_var=${version}
 680                   found_usable_python=yes
 681                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 682                   PYTHON_LIBS=$new_LIBS])
 683   CPPFLAGS=$save_CPPFLAGS
 684   LIBS=$save_LIBS
 685   AC_MSG_RESULT([${found_usable_python}])
 686 ])
 687
 688 dnl There are several different values for --with-python:
 689 dnl
 690 dnl no -   Don't include python support.
 691 dnl yes -  Include python support, error if it's missing.
 692 dnl        If we find python in $PATH, use it to fetch configure options,
 693 dnl        otherwise assume the compiler can find it with no help from us.
 694 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 695 dnl auto - Same as "yes", but if python is missing from the system,
 696 dnl        fall back to "no".
 697 dnl /path/to/python/exec-prefix -
 698 dnl        Use the python located in this directory.
 699 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 700 dnl        the compilation parameters.  Otherwise use
 701 dnl        -I/path/to/python/exec-prefix/include,
 702 dnl        -L/path/to/python/exec-prefix/lib.
 703 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 704 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 705 dnl        but is deprecated.
 706 dnl /path/to/python/executable -
 707 dnl        Run python-config.py with this version of python to fetch the
 708 dnl        compilation parameters.
 709 dnl        NOTE: This needn't be the real python executable.
 710 dnl        In a cross-compilation scenario (build != host), this could be
 711 dnl        a shell script that provides what python-config.py provides for
 712 dnl        --ldflags, --includes, --exec-prefix.
 713 dnl python-executable -
 714 dnl        Find python-executable in $PATH, and then handle the same as
 715 dnl        /path/to/python/executable.
 716 dnl
 717 dnl If a python program is specified, it is used to run python-config.py and
 718 dnl is passed --ldflags, --includes, --exec-prefix.
 719
 720 AC_ARG_WITH(python,
 721   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 722   [], [with_python=auto])
 723 AC_MSG_CHECKING([whether to use python])
 724 AC_MSG_RESULT([$with_python])
 725
 726 if test "${with_python}" = no; then
 727   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 728   have_libpython=no
 729 else
 730   case "${with_python}" in
 731   /*)
 732     if test -d ${with_python}; then
 733       # Assume the python binary is ${with_python}/bin/python.
 734       python_prog="${with_python}/bin/python"
 735       python_prefix=
 736       # If python does not exit ${with_python}/bin, then try in
 737       # ${with_python}.  On Windows/MinGW, this is where the Python
 738       # executable is.
 739       if test ! -x "${python_prog}"; then
 740         python_prog="${with_python}/python"
 741         python_prefix=
 742       fi
 743       if test ! -x "${python_prog}"; then
 744         # Fall back to gdb 7.0/7.1 behaviour.
 745         python_prog=missing
 746         python_prefix=${with_python}
 747       fi
 748     elif test -x "${with_python}"; then
 749       # While we can't run python compiled for $host (unless host == build),
 750       # the user could write a script that provides the needed information,
 751       # so we support that.
 752       python_prog=${with_python}
 753       python_prefix=
 754     else
 755       AC_ERROR(invalid value for --with-python)
 756     fi
 757     ;;
 758   */*)
 759     # Disallow --with-python=foo/bar.
 760     AC_ERROR(invalid value for --with-python)
 761     ;;
 762   *)
 763     # The user has either specified auto, yes, or the name of the python
 764     # program assumed to be in $PATH.
 765     python_prefix=
 766     case "${with_python}" in
 767     yes | auto)
 768       if test ${build} = ${host}; then
 769         AC_PATH_PROG(python_prog_path, python, missing)
 770         if test "${python_prog_path}" = missing; then
 771           python_prog=missing
 772         else
 773           python_prog=${python_prog_path}
 774         fi
 775       else
 776         # Not much we can do except assume the cross-compiler will find the
 777         # right files.
 778         python_prog=missing
 779       fi
 780       ;;
 781     *)
 782       # While we can't run python compiled for $host (unless host == build),
 783       # the user could write a script that provides the needed information,
 784       # so we support that.
 785       python_prog="${with_python}"
 786       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 787       if test "${python_prog_path}" = missing; then
 788         AC_ERROR(unable to find python program ${python_prog})
 789       fi
 790       ;;
 791     esac
 792   esac
 793
 794   if test "${python_prog}" != missing; then
 795     # We have a python program to use, but it may be too old.
 796     # Don't flag an error for --with-python=auto (the default).
 797     have_python_config=yes
 798     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 799     if test $? != 0; then
 800       have_python_config=failed
 801       if test "${with_python}" != auto; then
 802         AC_ERROR(failure running python-config --includes)
 803       fi
 804     fi
 805     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 806     if test $? != 0; then
 807       have_python_config=failed
 808       if test "${with_python}" != auto; then
 809         AC_ERROR(failure running python-config --ldflags)
 810       fi
 811     fi
 812     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 813     if test $? != 0; then
 814       have_python_config=failed
 815       if test "${with_python}" != auto; then
 816         AC_ERROR(failure running python-config --exec-prefix)
 817       fi
 818     fi
 819   else
 820     # We do not have a python executable we can use to determine where
 821     # to find the Python headers and libs.  We cannot guess the include
 822     # path from the python_prefix either, because that include path
 823     # depends on the Python version.  So, there is nothing much we can
 824     # do except assume that the compiler will be able to find those files.
 825     python_includes=
 826     python_libs=
 827     have_python_config=no
 828   fi
 829
 830   # If we have python-config, only try the configuration it provides.
 831   # Otherwise fallback on the old way of trying different versions of
 832   # python in turn.
 833
 834   have_libpython=no
 835   if test "${have_python_config}" = yes; then
 836     # Determine the Python version by extracting "-lpython<version>"
 837     # part of the python_libs. <version> is usually X.Y with X and Y
 838     # being decimal numbers, but can also be XY (seen on Windows).
 839     #
 840     # The extraction is performed using sed with a regular expression.
 841     # Initially, the regexp used was using the '?' quantifier to make
 842     # the dot in the version number optional.  Unfortunately, this
 843     # does not work with non-GNU versions of sed because, because of
 844     # what looks like a limitation (the '?' quantifier does not work
 845     # with back-references).  We work around this limitation by using
 846     # the '*' quantifier instead.  It means that, in theory, we might
 847     # match unexpected version strings such as "-lpython2..7", but
 848     # this seems unlikely in practice.  And even if that happens,
 849     # an error will be triggered later on, when checking that version
 850     # number.
 851     python_version=`echo " ${python_libs} " \
 852                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 853     case "${python_version}" in
 854     python*)
 855       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 856                        ${python_includes}, ${python_libs})
 857       ;;
 858     *)
 859       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 860       ;;
 861     esac
 862   elif test "${have_python_config}" != failed; then
 863     if test "${have_libpython}" = no; then
 864       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 865                        ${python_includes}, "${python_libs} -lpython2.7")
 866     fi
 867     if test "${have_libpython}" = no; then
 868       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 869                        ${python_includes}, "${python_libs} -lpython2.6")
 870     fi
 871     if test ${have_libpython} = no; then
 872       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 873                        ${python_includes}, "${python_libs} -lpython2.5")
 874     fi
 875     if test ${have_libpython} = no; then
 876       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 877                        ${python_includes}, "${python_libs} -lpython2.4")
 878     fi
 879   fi
 880   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 881     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 882   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 883     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 884   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 885     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 886   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 887     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 888   fi
 889
 890   if test "${have_libpython}" = no; then
 891     case "${with_python}" in
 892     yes)
 893       AC_MSG_ERROR([python is missing or unusable])
 894       ;;
 895     auto)
 896       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 897       ;;
 898     *)
 899       AC_MSG_ERROR([no usable python found at ${with_python}])
 900       ;;
 901     esac
 902   else
 903     if test -n "${python_prefix}"; then
 904       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 905                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 906       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 907     fi
 908   fi
 909 fi
 910
 911 if test "${have_libpython}" != no; then
 912   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 913   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 914   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 915   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 916   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 917   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 918
 919   # Flags needed to compile Python code (taken from python-config --cflags).
 920   # We cannot call python-config directly because it will output whatever was
 921   # used when compiling the Python interpreter itself, including flags which
 922   # would make the python-related objects be compiled differently from the
 923   # rest of GDB (e.g., -O2 and -fPIC).
 924   if test "${GCC}" = yes; then
 925     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 926   fi
 927
 928   if test "x${tentative_python_cflags}" != x; then
 929     AC_MSG_CHECKING(compiler flags for python code)
 930     for flag in ${tentative_python_cflags}; do
 931       # Check that the compiler accepts it
 932       saved_CFLAGS="$CFLAGS"
 933       CFLAGS="$CFLAGS $flag"
 934       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 935       CFLAGS="$saved_CFLAGS"
 936     done
 937     AC_MSG_RESULT(${PYTHON_CFLAGS})
 938   fi
 939
 940   # On IRIX, type siginfo is not defined.  Instead, sys/siginfo.h provides:
 941   #    #if _SGIAPI
 942   #    #define siginfo __siginfo
 943   #    #endif
 944   # The problem is that including Python causes some XOPEN macros to be
 945   # unilaterally defined, and that in turn causes _SGIAPI to evaluate
 946   # to false.  So, we work around this issue by defining siginfo ourself
 947   # though the command-line.
 948   case "$gdb_host" in
 949     irix*) if test "${GCC}" = yes; then
 950              CPPFLAGS="$CPPFLAGS -Dsiginfo=__siginfo"
 951            fi
 952            ;;
 953   esac
 954 else
 955   # Even if Python support is not compiled in, we need to have these files
 956   # included.
 957   CONFIG_OBS="$CONFIG_OBS python.o py-value.o py-prettyprint.o py-auto-load.o"
 958   CONFIG_SRCS="$CONFIG_SRCS python/python.c python/py-value.c \
 959         python/py-prettyprint.c python/py-auto-load.c"
 960 fi
 961 AC_SUBST(PYTHON_CFLAGS)
 962 AC_SUBST(PYTHON_CPPFLAGS)
 963 AC_SUBST(PYTHON_LIBS)
 964
 965 # ------------------------- #
 966 # Checks for header files.  #
 967 # ------------------------- #
 968
 969 AC_HEADER_DIRENT
 970 AC_HEADER_STAT
 971 AC_HEADER_STDC
 972 # elf_hp.h is for HP/UX 64-bit shared library support.
 973 # FIXME: kettenis/20030102: In most cases we include these (ctype.h, time.h)
 974 # unconditionally, so what's the point in checking these?
 975 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
 976                   thread_db.h gnu/libc-version.h signal.h stddef.h \
 977                   stdlib.h string.h memory.h strings.h sys/fault.h \
 978                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
 979                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
 980                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
 981                   sys/types.h sys/wait.h wait.h termios.h termio.h \
 982                   sgtty.h unistd.h elf_hp.h ctype.h time.h locale.h \
 983                   dlfcn.h])
 984 AC_CHECK_HEADERS(link.h, [], [],
 985 [#if HAVE_SYS_TYPES_H
 986 # include <sys/types.h>
 987 #endif
 988 #if HAVE_NLIST_H
 989 # include <nlist.h>
 990 #endif
 991 ])
 992 AC_CHECK_HEADERS(sys/proc.h, [], [],
 993 [#if HAVE_SYS_PARAM_H
 994 # include <sys/param.h>
 995 #endif
 996 ])
 997 AC_CHECK_HEADERS(sys/user.h, [], [],
 998 [#if HAVE_SYS_PARAM_H
 999 # include <sys/param.h>
1000 #endif
1001 ])
1002
1003 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
1004 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
1005 # think that we don't have <curses.h> if we're using GCC.
1006 case $host_os in
1007   solaris2.[[789]])
1008     if test "$GCC" = yes; then
1009       AC_DEFINE(_MSE_INT_H, 1,
1010         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
1011    Solaris 2.[789] when using GCC. ])
1012     fi ;;
1013 esac
1014 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
1015 AC_CHECK_HEADERS(term.h, [], [],
1016 [#if HAVE_CURSES_H
1017 # include <curses.h>
1018 #endif
1019 ])
1020
1021 # ------------------------- #
1022 # Checks for declarations.  #
1023 # ------------------------- #
1024
1025 AC_CHECK_DECLS([free, malloc, realloc, strerror, strstr, getopt,
1026                 snprintf, vsnprintf])
1027 AM_LC_MESSAGES
1028
1029 # ----------------------- #
1030 # Checks for structures.  #
1031 # ----------------------- #
1032
1033 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1034
1035 # ------------------ #
1036 # Checks for types.  #
1037 # ------------------ #
1038
1039 AC_TYPE_SIGNAL
1040 AC_CHECK_TYPES(socklen_t, [], [],
1041 [#include <sys/types.h>
1042 #include <sys/socket.h>
1043 ])
1044
1045 # ------------------------------------- #
1046 # Checks for compiler characteristics.  #
1047 # ------------------------------------- #
1048
1049 AC_C_CONST
1050 AC_C_INLINE
1051 AC_C_BIGENDIAN
1052
1053 # ------------------------------ #
1054 # Checks for library functions.  #
1055 # ------------------------------ #
1056
1057 AC_FUNC_ALLOCA
1058 AC_FUNC_MMAP
1059 AC_FUNC_VFORK
1060 AC_CHECK_FUNCS([canonicalize_file_name realpath getrusage getuid \
1061                 getgid pipe poll pread64 resize_term sbrk setpgid setpgrp setsid \
1062                 sigaction sigprocmask sigsetmask socketpair syscall \
1063                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1064                 setrlimit getrlimit posix_madvise waitpid])
1065 AM_LANGINFO_CODESET
1066
1067 # Check the return and argument types of ptrace.  No canned test for
1068 # this, so roll our own.
1069 gdb_ptrace_headers='
1070 #if HAVE_SYS_TYPES_H
1071 # include <sys/types.h>
1072 #endif
1073 #if HAVE_SYS_PTRACE_H
1074 # include <sys/ptrace.h>
1075 #endif
1076 #if HAVE_UNISTD_H
1077 # include <unistd.h>
1078 #endif
1079 '
1080 # There is no point in checking if we don't have a prototype.
1081 AC_CHECK_DECLS(ptrace, [], [
1082   : ${gdb_cv_func_ptrace_ret='int'}
1083   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1084 ], $gdb_ptrace_headers)
1085 # Check return type.  Varargs (used on GNU/Linux) conflict with the
1086 # empty argument list, so check for that explicitly.
1087 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
1088   AC_TRY_COMPILE($gdb_ptrace_headers,
1089     [extern long ptrace (enum __ptrace_request, ...);],
1090     gdb_cv_func_ptrace_ret='long',
1091     AC_TRY_COMPILE($gdb_ptrace_headers,
1092       [extern int ptrace ();],
1093       gdb_cv_func_ptrace_ret='int',
1094       gdb_cv_func_ptrace_ret='long')))
1095 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
1096   [Define as the return type of ptrace.])
1097 # Check argument types.
1098 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
1099   AC_TRY_COMPILE($gdb_ptrace_headers,
1100     [extern long ptrace (enum __ptrace_request, ...);],
1101     [gdb_cv_func_ptrace_args='int,int,long,long'],[
1102 for gdb_arg1 in 'int' 'long'; do
1103  for gdb_arg2 in 'pid_t' 'int' 'long'; do
1104   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
1105    for gdb_arg4 in 'int' 'long'; do
1106      AC_TRY_COMPILE($gdb_ptrace_headers, [
1107 extern $gdb_cv_func_ptrace_ret
1108   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
1109 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
1110     break 4;])
1111     for gdb_arg5 in 'int *' 'int' 'long'; do
1112      AC_TRY_COMPILE($gdb_ptrace_headers, [
1113 extern $gdb_cv_func_ptrace_ret
1114   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
1115 ], [
1116 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
1117     break 5;])
1118     done
1119    done
1120   done
1121  done
1122 done
1123 # Provide a safe default value.
1124 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1125 ])])
1126 ac_save_IFS=$IFS; IFS=','
1127 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
1128 IFS=$ac_save_IFS
1129 shift
1130 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
1131   [Define to the type of arg 3 for ptrace.])
1132 if test -n "$[5]"; then
1133   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
1134     [Define to the type of arg 5 for ptrace.])
1135 fi
1136
1137 dnl AC_FUNC_SETPGRP does not work when cross compiling
1138 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1139 if test "$cross_compiling" = no; then
1140   AC_FUNC_SETPGRP
1141 else
1142   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1143     [AC_TRY_COMPILE([
1144 #include <unistd.h>
1145 ], [
1146   if (setpgrp(1,1) == -1)
1147     exit (0);
1148   else
1149     exit (1);
1150 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1151 if test $ac_cv_func_setpgrp_void = yes; then
1152   AC_DEFINE(SETPGRP_VOID, 1)
1153 fi
1154 fi
1155
1156 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
1157 # since sigsetjmp might only be defined as a macro.
1158 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
1159 [AC_TRY_COMPILE([
1160 #include <setjmp.h>
1161 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
1162 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
1163 if test $gdb_cv_func_sigsetjmp = yes; then
1164   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
1165 fi
1166
1167 # Assume we'll default to using the included libiberty regex.
1168 gdb_use_included_regex=yes
1169
1170 # However, if the system regex is GNU regex, then default to *not*
1171 # using the included regex.
1172 AC_CACHE_CHECK(
1173   [for GNU regex],
1174   [gdb_cv_have_gnu_regex],
1175   [AC_TRY_COMPILE(
1176     [#include <gnu-versions.h>],
1177     [#define REGEX_INTERFACE_VERSION 1
1178 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1179 # error "Version mismatch"
1180 #endif],
1181     gdb_cv_have_gnu_regex=yes,
1182     gdb_cv_have_gnu_regex=no)])
1183 if test $gdb_cv_have_gnu_regex = yes; then
1184   gdb_use_included_regex=no
1185 fi
1186
1187 AC_ARG_WITH(included-regex,
1188   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1189   gdb_with_regex=$withval,
1190   gdb_with_regex=$gdb_use_included_regex)
1191 if test "$gdb_with_regex" = yes; then
1192   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1193     [Define to 1 if the regex included in libiberty should be used.])
1194 fi
1195
1196 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1197 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1198 [#include <sys/param.h>
1199 #include <sys/proc.h>
1200 ])
1201
1202 # See if <sys/lwp.h> defines `struct lwp`.
1203 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1204 [AC_TRY_COMPILE([#include <sys/param.h>
1205 #include <sys/lwp.h>], [struct lwp l;],
1206 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1207 if test $gdb_cv_struct_lwp = yes; then
1208   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1209             [Define to 1 if your system has struct lwp.])
1210 fi
1211
1212 # See if <machine/reg.h> degines `struct reg'.
1213 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1214 [AC_TRY_COMPILE([#include <sys/types.h>
1215 #include <machine/reg.h>], [struct reg r;],
1216 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1217 if test $gdb_cv_struct_reg = yes; then
1218   AC_DEFINE(HAVE_STRUCT_REG, 1,
1219             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1220 fi
1221
1222 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1223 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1224 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1225                  [#include <machine/reg.h>])
1226
1227 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1228 AC_MSG_CHECKING(for PTRACE_GETREGS)
1229 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1230 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1231                 [PTRACE_GETREGS;],
1232                 [gdb_cv_have_ptrace_getregs=yes],
1233                 [gdb_cv_have_ptrace_getregs=no])])
1234 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1235 if test $gdb_cv_have_ptrace_getregs = yes; then
1236   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1237   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1238 fi
1239
1240 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1241 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1242 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1243 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1244                 [PTRACE_GETFPXREGS;],
1245                 [gdb_cv_have_ptrace_getfpxregs=yes],
1246                 [gdb_cv_have_ptrace_getfpxregs=no])])
1247 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1248 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1249   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1250   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1251 fi
1252
1253 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1254 AC_MSG_CHECKING(for PT_GETDBREGS)
1255 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1256 [AC_TRY_COMPILE([#include <sys/types.h>
1257 #include <sys/ptrace.h>],
1258                 [PT_GETDBREGS;],
1259                 [gdb_cv_have_pt_getdbregs=yes],
1260                 [gdb_cv_have_pt_getdbregs=no])])
1261 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1262 if test $gdb_cv_have_pt_getdbregs = yes; then
1263   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1264   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1265 fi
1266
1267 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1268 AC_MSG_CHECKING(for PT_GETXMMREGS)
1269 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1270 [AC_TRY_COMPILE([#include <sys/types.h>
1271 #include <sys/ptrace.h>],
1272                 [PT_GETXMMREGS;],
1273                 [gdb_cv_have_pt_getxmmregs=yes],
1274                 [gdb_cv_have_pt_getxmmregs=no])])
1275 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1276 if test $gdb_cv_have_pt_getxmmregs = yes; then
1277   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1278   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1279 fi
1280
1281 # Detect which type of /proc is in use, such as for Unixware or Solaris.
1282
1283 if test "${target}" = "${host}"; then
1284   case "${host}" in
1285   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
1286       AC_DEFINE(NEW_PROC_API, 1,
1287       [Define if you want to use new multi-fd /proc interface
1288        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1289       ;;
1290   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1291       AC_DEFINE(NEW_PROC_API, 1,
1292       [Define if you want to use new multi-fd /proc interface
1293        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1294       ;;
1295   mips-sgi-irix5*)
1296       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1297       AC_DEFINE([_KMEMUSER], 1,
1298       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1299        around a <sys/proc.h> problem on IRIX 5.])
1300       ;;
1301   esac
1302 fi
1303
1304 if test "$ac_cv_header_sys_procfs_h" = yes; then
1305   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
1306   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
1307   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1308   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1309   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1310   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1311   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1312   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
1313   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1314   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1315   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1316   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1317   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1318   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1319
1320
1321   dnl Check for broken prfpregset_t type
1322
1323   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1324   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1325   dnl instead of the struct itself).  We detect this here, and work
1326   dnl around it in gdb_proc_service.h.
1327
1328   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1329     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1330     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1331       [AC_TRY_RUN([#include <sys/procfs.h>
1332        int main ()
1333        {
1334          if (sizeof (prfpregset_t) == sizeof (void *))
1335            return 1;
1336          return 0;
1337        }],
1338        gdb_cv_prfpregset_t_broken=no,
1339        gdb_cv_prfpregset_t_broken=yes,
1340        gdb_cv_prfpregset_t_broken=yes)])
1341     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1342     if test $gdb_cv_prfpregset_t_broken = yes; then
1343       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1344       [Define if the prfpregset_t type is broken.])
1345     fi
1346   fi
1347
1348   dnl Check for PIOCSET ioctl entry
1349
1350   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
1351   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
1352   [AC_TRY_COMPILE([#include <unistd.h>
1353 #include <sys/types.h>
1354 #include <sys/procfs.h>
1355 ], [
1356     int dummy;;
1357     dummy = ioctl(0, PIOCSET, &dummy);
1358   ],
1359   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
1360   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
1361   if test $gdb_cv_have_procfs_piocset = yes; then
1362     AC_DEFINE(HAVE_PROCFS_PIOCSET, 1,
1363     [Define if ioctl argument PIOCSET is available.])
1364   fi
1365 fi
1366
1367 dnl For native ports (host == target), check to see what kind of
1368 dnl legacy link.h support is needed.  (See solib-legacy.c.)
1369 if test ${host} = ${target} ; then
1370   dnl Check for struct link_map with l_ members which are indicative
1371   dnl of SVR4-like shared libraries
1372
1373   AC_MSG_CHECKING(for member l_addr in struct link_map)
1374   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
1375     [AC_TRY_COMPILE([#include <link.h>],
1376                     [struct link_map lm; (void) lm.l_addr;],
1377                     gdb_cv_have_struct_link_map_with_l_members=yes,
1378                     gdb_cv_have_struct_link_map_with_l_members=no)])
1379   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
1380   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
1381     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1,
1382     [Define if <link.h> exists and defines struct link_map which has
1383      members with an ``l_'' prefix.  (For Solaris, SVR4, and
1384      SVR4-like systems.)])
1385   fi
1386
1387   dnl Check for struct link_map with lm_ members which are indicative
1388   dnl of SunOS-like shared libraries
1389
1390   AC_MSG_CHECKING(for member lm_addr in struct link_map)
1391   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
1392     [AC_TRY_COMPILE([#include <sys/types.h>
1393 #include <link.h>],
1394                     [struct link_map lm; (void) lm.lm_addr;],
1395                     gdb_cv_have_struct_link_map_with_lm_members=yes,
1396                     gdb_cv_have_struct_link_map_with_lm_members=no)])
1397   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
1398   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
1399     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1,
1400     [Define if <link.h> exists and defines struct link_map which has
1401      members with an ``lm_'' prefix.  (For SunOS.)])
1402   fi
1403
1404   dnl Check for struct so_map with som_ members which are found on
1405   dnl some *BSD systems.
1406
1407   AC_MSG_CHECKING(for member som_addr in struct so_map)
1408   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
1409     [AC_TRY_COMPILE([#include <sys/types.h>
1410 #ifdef HAVE_NLIST_H
1411 #include <nlist.h>
1412 #endif
1413 #include <link.h>],
1414                     [struct so_map lm; (void) lm.som_addr;],
1415                     gdb_cv_have_struct_so_map_with_som_members=yes,
1416                     gdb_cv_have_struct_so_map_with_som_members=no)])
1417   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
1418   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
1419     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1,
1420     [Define if <link.h> exists and defines a struct so_map which has
1421      members with an ``som_'' prefix.  (Found on older *BSD systems.)])
1422   fi
1423
1424   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
1425   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
1426
1427   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
1428   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
1429     [AC_TRY_COMPILE([#define _SYSCALL32
1430 #include <sys/link.h>], [struct link_map32 l;],
1431      gdb_cv_have_struct_link_map32=yes,
1432      gdb_cv_have_struct_link_map32=no)])
1433   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
1434   if test $gdb_cv_have_struct_link_map32 = yes; then
1435     AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1,
1436     [Define if <sys/link.h> has struct link_map32])
1437     AC_DEFINE(_SYSCALL32, 1,
1438     [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)])
1439   fi
1440 fi
1441
1442 # Check if the compiler supports the `long long' type.
1443
1444 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1445                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1446 [[extern long long foo;]],
1447 [[switch (foo & 2) { case 0: return 1; }]])],
1448                                   gdb_cv_c_long_long=yes,
1449                                   gdb_cv_c_long_long=no)])
1450 if test $gdb_cv_c_long_long = yes; then
1451   AC_DEFINE(CC_HAS_LONG_LONG, 1,
1452             [Define to 1 if the compiler supports long long.])
1453 fi
1454
1455 # Check if the compiler and runtime support printing long longs.
1456
1457 AC_CACHE_CHECK([for long long support in printf],
1458                gdb_cv_printf_has_long_long,
1459                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1460 [[char buf[32];
1461   long long l = 0;
1462   l = (l << 16) + 0x0123;
1463   l = (l << 16) + 0x4567;
1464   l = (l << 16) + 0x89ab;
1465   l = (l << 16) + 0xcdef;
1466   sprintf (buf, "0x%016llx", l);
1467   return (strcmp ("0x0123456789abcdef", buf));]])],
1468                               gdb_cv_printf_has_long_long=yes,
1469                               gdb_cv_printf_has_long_long=no,
1470                               gdb_cv_printf_has_long_long=no)])
1471 if test $gdb_cv_printf_has_long_long = yes; then
1472   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1473             [Define to 1 if the "%ll" format works to print long longs.])
1474 fi
1475
1476 # Check if the compiler and runtime support printing decfloats.
1477
1478 AC_CACHE_CHECK([for decfloat support in printf],
1479                gdb_cv_printf_has_decfloat,
1480                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1481 [[char buf[64];
1482   _Decimal32 d32 = 1.2345df;
1483   _Decimal64 d64 = 1.2345dd;
1484   _Decimal128 d128 = 1.2345dl;
1485   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1486   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1487                               gdb_cv_printf_has_decfloat=yes,
1488                               gdb_cv_printf_has_decfloat=no,
1489                               gdb_cv_printf_has_decfloat=no)])
1490 if test $gdb_cv_printf_has_decfloat = yes; then
1491   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1492             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1493 fi
1494
1495 # Check if the compiler supports the `long double' type.  We can't use
1496 # AC_C_LONG_DOUBLE because that one does additional checks on the
1497 # constants defined in <float.h> that fail on some systems,
1498 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1499
1500 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1501                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1502                                   gdb_cv_c_long_double=yes,
1503                                   gdb_cv_c_long_double=no)])
1504 if test $gdb_cv_c_long_double = yes; then
1505   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1506            [Define to 1 if the compiler supports long double.])
1507 fi
1508
1509 # Check if the compiler and runtime support printing long doubles.
1510
1511 AC_CACHE_CHECK([for long double support in printf],
1512                gdb_cv_printf_has_long_double,
1513                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1514 [[char buf[16];
1515   long double f = 3.141592653;
1516   sprintf (buf, "%Lg", f);
1517   return (strncmp ("3.14159", buf, 7));]])],
1518                               gdb_cv_printf_has_long_double=yes,
1519                               gdb_cv_printf_has_long_double=no,
1520                               gdb_cv_printf_has_long_double=no)])
1521 if test $gdb_cv_printf_has_long_double = yes; then
1522   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1523             [Define to 1 if the "%Lg" format works to print long doubles.])
1524 fi
1525
1526 # Check if the compiler and runtime support scanning long doubles.
1527
1528 AC_CACHE_CHECK([for long double support in scanf],
1529                gdb_cv_scanf_has_long_double,
1530                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1531 [[#include <stdio.h>]],
1532 [[char *buf = "3.141592653";
1533   long double f = 0;
1534   sscanf (buf, "%Lg", &f);
1535   return !(f > 3.14159 && f < 3.14160);]])],
1536                               gdb_cv_scanf_has_long_double=yes,
1537                               gdb_cv_scanf_has_long_double=no,
1538                               gdb_cv_scanf_has_long_double=no)])
1539 if test $gdb_cv_scanf_has_long_double = yes; then
1540   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1541             [Define to 1 if the "%Lg" format works to scan long doubles.])
1542 fi
1543
1544 case ${host_os} in
1545 aix*)
1546   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1547     SAVE_LDFLAGS=$LDFLAGS
1548
1549     case $GCC in
1550     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1551     *) gdb_cv_bigtoc=-bbigtoc ;;
1552     esac
1553
1554     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1555     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1556     LDFLAGS="${SAVE_LDFLAGS}"
1557   ])
1558   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1559   ;;
1560 esac
1561
1562 AC_MSG_CHECKING(for the dynamic export flag)
1563 dynamic_list=false
1564 if test "${gdb_native}" = yes; then
1565    # The dynamically loaded libthread_db needs access to symbols in the gdb
1566    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1567    # may not be supported there.
1568    old_LDFLAGS="$LDFLAGS"
1569    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1570    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1571    LDFLAGS="$LDFLAGS $RDYNAMIC"
1572    if test "${have_libpython}" = no; then
1573      AC_TRY_LINK([], [], [dynamic_list=true])
1574    else
1575      # Workaround http://bugs.python.org/issue4434 where static
1576      # libpythonX.Y.a would get its symbols required for
1577      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1578      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1579      old_CFLAGS="$CFLAGS"
1580      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1581      AC_RUN_IFELSE(
1582        AC_LANG_PROGRAM(
1583          [#include "]${have_libpython}[/Python.h"],
1584          [int err;
1585           Py_Initialize ();
1586           err = PyRun_SimpleString ("import itertools\n");
1587           Py_Finalize ();
1588           return err == 0 ? 0 : 1;]),
1589        [dynamic_list=true], [], [true])
1590      CFLAGS="$old_CFLAGS"
1591    fi
1592    LDFLAGS="$old_LDFLAGS"
1593 fi
1594 if $dynamic_list; then
1595   found="-Wl,--dynamic-list"
1596   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1597 else
1598   found="-rdynamic"
1599   RDYNAMIC="-rdynamic"
1600 fi
1601 AC_SUBST(RDYNAMIC)
1602 AC_MSG_RESULT($found)
1603
1604 dnl For certain native configurations, we need to check whether thread
1605 dnl support can be built in or not.
1606 dnl
1607 dnl Note that we only want this if we are both native (host == target),
1608 dnl and not doing a canadian cross build (build == host).
1609
1610 if test ${build} = ${host} -a ${host} = ${target} ; then
1611    case ${host_os} in
1612    solaris*)
1613       # See if thread_db library is around for Solaris thread debugging.
1614       # Note that we must explicitly test for version 1 of the library
1615       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1616       # the same API.
1617       AC_MSG_CHECKING(for Solaris thread debugging library)
1618       if test -f /usr/lib/libthread_db.so.1 ; then
1619          AC_MSG_RESULT(yes)
1620          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1621          [Define if using Solaris thread debugging.])
1622          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1623          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1624          AC_CHECK_LIB(dl, dlopen)
1625          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1626          # Sun randomly tweaked the prototypes in <proc_service.h>
1627          # at one point.
1628          AC_MSG_CHECKING(if <proc_service.h> is old)
1629          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1630             AC_TRY_COMPILE([
1631                 #include <proc_service.h>
1632                 ps_err_e ps_pdwrite
1633                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1634             ],, gdb_cv_proc_service_is_old=no,
1635                 gdb_cv_proc_service_is_old=yes)
1636          ])
1637          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1638          if test $gdb_cv_proc_service_is_old = yes; then
1639             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1640             [Define if <proc_service.h> on solaris uses int instead of
1641              size_t, and assorted other type changes.])
1642          fi
1643       else
1644          AC_MSG_RESULT(no)
1645       fi
1646       ;;
1647    aix*)
1648       AC_MSG_CHECKING(for AiX thread debugging library)
1649       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1650                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1651                                    [#ifndef PTHDB_VERSION_3
1652                                     #error
1653                                     #endif],
1654                                    gdb_cv_have_aix_thread_debug=yes,
1655                                    gdb_cv_have_aix_thread_debug=no)])
1656       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1657       if test $gdb_cv_have_aix_thread_debug = yes; then
1658          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1659          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1660          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
1661
1662          # Older versions of AIX do not provide the declaration for
1663          # the getthrds function (it appears that it was introduced
1664          # with AIX 6.x).
1665          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1666       fi
1667       ;;
1668    esac
1669    AC_SUBST(CONFIG_LDFLAGS)
1670 fi
1671
1672 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1673 dnl other error codes.
1674 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1675    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1676                   gdb_cv_thread_db_h_has_td_notalloc,
1677      AC_TRY_COMPILE(
1678        [#include <thread_db.h>],
1679        [int i = TD_NOTALLOC;],
1680        gdb_cv_thread_db_h_has_td_notalloc=yes,
1681        gdb_cv_thread_db_h_has_td_notalloc=no
1682      )
1683    )
1684    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1685                   gdb_cv_thread_db_h_has_td_version,
1686      AC_TRY_COMPILE(
1687        [#include <thread_db.h>],
1688        [int i = TD_VERSION;],
1689        gdb_cv_thread_db_h_has_td_version=yes,
1690        gdb_cv_thread_db_h_has_td_version=no
1691      )
1692    )
1693    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1694                   gdb_cv_thread_db_h_has_td_notls,
1695      AC_TRY_COMPILE(
1696        [#include <thread_db.h>],
1697        [int i = TD_NOTLS;],
1698        gdb_cv_thread_db_h_has_td_notls=yes,
1699        gdb_cv_thread_db_h_has_td_notls=no
1700      )
1701    )
1702 fi
1703 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1704   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1705             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1706 fi
1707 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1708   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1709             [Define if <thread_db.h> has the TD_VERSION error code.])
1710 fi
1711 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1712   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1713             [Define if <thread_db.h> has the TD_NOTLS error code.])
1714 fi
1715
1716 dnl See if we have a sys/syscall header file that has __NR_tkill.
1717 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1718    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1719                   gdb_cv_sys_syscall_h_has_tkill,
1720      AC_TRY_COMPILE(
1721        [#include <sys/syscall.h>],
1722        [int i = __NR_tkill;],
1723        gdb_cv_sys_syscall_h_has_tkill=yes,
1724        gdb_cv_sys_syscall_h_has_tkill=no
1725      )
1726    )
1727 fi
1728 dnl See if we can issue tkill syscall.
1729 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1730   AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1731 fi
1732
1733 dnl Check if we can disable the virtual address space randomization.
1734 dnl The functionality of setarch -R.
1735 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1736 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1737 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1738 #       define ADDR_NO_RANDOMIZE 0x0040000
1739 #      endif
1740        /* Test the flag could be set and stays set.  */
1741        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1742        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1743            return 1])])
1744 AC_RUN_IFELSE([PERSONALITY_TEST],
1745               [have_personality=true],
1746               [have_personality=false],
1747               [AC_LINK_IFELSE([PERSONALITY_TEST],
1748                               [have_personality=true],
1749                               [have_personality=false])])
1750 if $have_personality
1751 then
1752     AC_DEFINE([HAVE_PERSONALITY], 1,
1753               [Define if you support the personality syscall.])
1754 fi
1755
1756 dnl Handle optional features that can be enabled.
1757
1758 target_sysroot_reloc=0
1759 AC_ARG_WITH(sysroot,
1760 AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@], [search for usr/lib et al within DIR]),
1761 [
1762  case ${with_sysroot} in
1763  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
1764  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
1765  esac
1766
1767  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
1768
1769  if test "x$prefix" = xNONE; then
1770   test_prefix=/usr/local
1771  else
1772   test_prefix=$prefix
1773  fi
1774  if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
1775   test_exec_prefix=$test_prefix
1776  else
1777   test_exec_prefix=$exec_prefix
1778  fi
1779  case ${TARGET_SYSTEM_ROOT} in
1780  "${test_prefix}"|"${test_prefix}/"*|\
1781  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
1782  '${prefix}'|'${prefix}/'*|\
1783  '${exec_prefix}'|'${exec_prefix}/'*)
1784    target_sysroot_reloc=1
1785    ;;
1786  esac
1787 ], [
1788  TARGET_SYSTEM_ROOT=
1789  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
1790 ])
1791 TARGET_SYSTEM_ROOT_DEFINE="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE=$target_sysroot_reloc"
1792 AC_SUBST(TARGET_SYSTEM_ROOT)
1793 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
1794
1795 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1796     [automatically load a system-wide gdbinit file],
1797     [])
1798
1799 AC_ARG_ENABLE(werror,
1800   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
1801   [case "${enableval}" in
1802      yes | y) ERROR_ON_WARNING="yes" ;;
1803      no | n)  ERROR_ON_WARNING="no" ;;
1804      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1805    esac])
1806
1807 # Enable -Werror by default when using gcc
1808 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then
1809     ERROR_ON_WARNING=yes
1810 fi
1811
1812 WERROR_CFLAGS=""
1813 if test "${ERROR_ON_WARNING}" = yes ; then
1814     WERROR_CFLAGS="-Werror"
1815 fi
1816
1817 # The entries after -Wno-pointer-sign are disabled warnings which may
1818 # be enabled in the future, which can not currently be used to build
1819 # GDB.
1820 # NOTE: If you change this list, remember to update
1821 # gdb/doc/gdbint.texinfo.
1822 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1823 -Wformat-nonliteral -Wno-pointer-sign \
1824 -Wno-unused -Wunused-value -Wunused-function \
1825 -Wno-switch -Wno-char-subscripts"
1826
1827 # Enable -Wno-format by default when using gcc on mingw since many
1828 # GCC versions complain about %I64.
1829 case "${host}" in
1830   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1831 esac
1832
1833 AC_ARG_ENABLE(build-warnings,
1834 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
1835 [case "${enableval}" in
1836   yes)  ;;
1837   no)   build_warnings="-w";;
1838   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1839         build_warnings="${build_warnings} ${t}";;
1840   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1841         build_warnings="${t} ${build_warnings}";;
1842   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1843 esac
1844 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1845   echo "Setting compiler warning flags = $build_warnings" 6>&1
1846 fi])dnl
1847 AC_ARG_ENABLE(gdb-build-warnings,
1848 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
1849 [case "${enableval}" in
1850   yes)  ;;
1851   no)   build_warnings="-w";;
1852   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1853         build_warnings="${build_warnings} ${t}";;
1854   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1855         build_warnings="${t} ${build_warnings}";;
1856   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1857 esac
1858 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1859   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1860 fi])dnl
1861 WARN_CFLAGS=""
1862 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1863 then
1864     AC_MSG_CHECKING(compiler warning flags)
1865     # Separate out the -Werror flag as some files just cannot be
1866     # compiled with it enabled.
1867     for w in ${build_warnings}; do
1868         case $w in
1869         -Werr*) WERROR_CFLAGS=-Werror ;;
1870         *) # Check that GCC accepts it
1871             saved_CFLAGS="$CFLAGS"
1872             CFLAGS="$CFLAGS $w"
1873             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1874             CFLAGS="$saved_CFLAGS"
1875         esac
1876     done
1877     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1878 fi
1879 AC_SUBST(WARN_CFLAGS)
1880 AC_SUBST(WERROR_CFLAGS)
1881
1882 # In the Cygwin environment, we need some additional flags.
1883 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1884 [AC_EGREP_CPP(lose, [
1885 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1886 lose
1887 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1888
1889
1890 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1891 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1892 case ${host} in
1893   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1894   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1895   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1896 esac
1897 AC_SUBST(SER_HARDWIRE)
1898
1899 # libreadline needs libuser32.a in a cygwin environment
1900 WIN32LIBS=
1901 if test x$gdb_cv_os_cygwin = xyes; then
1902     WIN32LIBS="-luser32"
1903     case "${target}" in
1904         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1905         ;;
1906     esac
1907 fi
1908
1909 # The ser-tcp.c module requires sockets.
1910 case ${host} in
1911   *mingw32*)
1912     AC_DEFINE(USE_WIN32API, 1,
1913               [Define if we should use the Windows API, instead of the
1914                POSIX API.  On Windows, we use the Windows API when
1915                building for MinGW, but the POSIX API when building
1916                for Cygwin.])
1917     WIN32LIBS="$WIN32LIBS -lws2_32"
1918     ;;
1919 esac
1920 AC_SUBST(WIN32LIBS)
1921
1922 # Add ELF support to GDB, but only if BFD includes ELF support.
1923 OLD_CFLAGS=$CFLAGS
1924 OLD_LDFLAGS=$LDFLAGS
1925 OLD_LIBS=$LIBS
1926 CFLAGS="$CFLAGS -I${srcdir}/../include -I../bfd -I${srcdir}/../bfd"
1927 LDFLAGS="$LDFLAGS -L../bfd -L../libiberty"
1928 intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'`
1929 # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1930 if test "$plugins" = "yes"; then
1931   LIBS="-ldl $LIBS"
1932 fi
1933 LIBS="-lbfd -liberty $intl $LIBS"
1934 AC_CACHE_CHECK([for ELF support in BFD], gdb_cv_var_elf,
1935 [AC_TRY_LINK(
1936 [#include <stdlib.h>
1937 #include "bfd.h"
1938 #include "elf-bfd.h"
1939 ],
1940 [bfd *abfd = NULL; bfd_get_elf_phdr_upper_bound (abfd); ],
1941 gdb_cv_var_elf=yes, gdb_cv_var_elf=no)])
1942 if test $gdb_cv_var_elf = yes; then
1943   CONFIG_OBS="$CONFIG_OBS elfread.o"
1944   AC_DEFINE(HAVE_ELF, 1,
1945             [Define if ELF support should be included.])
1946   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1947   if test "$plugins" = "yes"; then
1948     OLD_LIBS="-ldl $OLD_LIBS"
1949   fi
1950 fi
1951 CFLAGS=$OLD_CFLAGS
1952 LDFLAGS=$OLD_LDFLAGS
1953 LIBS=$OLD_LIBS
1954
1955 # Add any host-specific objects to GDB.
1956 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1957
1958 LIBGUI="../libgui/src/libgui.a"
1959 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1960 AC_SUBST(LIBGUI)
1961 AC_SUBST(GUI_CFLAGS_X)
1962
1963 WIN32LDAPP=
1964 AC_SUBST(WIN32LIBS)
1965 AC_SUBST(WIN32LDAPP)
1966
1967 case "${host}" in
1968 *-*-cygwin* | *-*-mingw* )
1969     configdir="win"
1970     ;;
1971 *)
1972     configdir="unix"
1973     ;;
1974 esac
1975
1976 GDBTKLIBS=
1977 if test "${enable_gdbtk}" = "yes"; then
1978
1979     # Gdbtk must have an absolute path to srcdir in order to run
1980     # properly when not installed.
1981     here=`pwd`
1982     cd ${srcdir}
1983     GDBTK_SRC_DIR=`pwd`
1984     cd $here
1985
1986     SC_PATH_TCLCONFIG
1987
1988     # If $no_tk is nonempty, then we can't do Tk, and there is no
1989     # point to doing Tcl.
1990     SC_PATH_TKCONFIG
1991
1992     if test -z "${no_tcl}" -a -z "${no_tk}"; then
1993         SC_LOAD_TCLCONFIG
1994
1995         # Check for in-tree tcl
1996         here=`pwd`
1997         cd ${srcdir}/..
1998         topdir=`pwd`
1999         cd ${here}
2000
2001         intree="no"
2002         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
2003           intree="yes"
2004         fi
2005
2006         # Find Tcl private headers
2007         if test x"${intree}" = xno; then
2008           CY_AC_TCL_PRIVATE_HEADERS
2009           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
2010           TCL_LIBRARY="${TCL_LIB_SPEC}"
2011           TCL_DEPS=""
2012         else
2013           # If building tcl in the same src tree, private headers
2014           # are not needed, but we need to be sure to use the right
2015           # headers library
2016           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2017           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2018           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2019         fi
2020         AC_SUBST(TCL_INCLUDE)
2021         AC_SUBST(TCL_LIBRARY)
2022         AC_SUBST(TCL_DEPS)
2023
2024         SC_LOAD_TKCONFIG
2025
2026         # Check for in-tree Tk
2027         intree="no"
2028         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2029           intree="yes"
2030         fi
2031
2032         # Find Tk private headers
2033         if test x"${intree}" = xno; then
2034           CY_AC_TK_PRIVATE_HEADERS
2035           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2036           TK_LIBRARY=${TK_LIB_SPEC}
2037           TK_DEPS=""
2038         else
2039           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2040           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2041           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2042         fi
2043         AC_SUBST(TK_INCLUDE)
2044         AC_SUBST(TK_LIBRARY)
2045         AC_SUBST(TK_DEPS)
2046         AC_SUBST(TK_XINCLUDES)
2047
2048         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2049
2050         # Include some libraries that Tcl and Tk want.
2051         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2052         # Yes, the ordering seems wrong here.  But it isn't.
2053         # TK_LIBS is the list of libraries that need to be linked
2054         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2055         # were in LIBS then any link tests after this point would
2056         # try to include things like `$(LIBGUI)', which wouldn't work.
2057         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2058
2059         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2060         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2061         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2062         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2063         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2064         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2065         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2066
2067         if test x$gdb_cv_os_cygwin = xyes; then
2068           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2069           WIN32LDAPP="-Wl,--subsystem,console"
2070           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2071         fi
2072
2073         AC_CONFIG_SUBDIRS(gdbtk)
2074     fi
2075 fi
2076
2077 AC_SUBST(X_CFLAGS)
2078 AC_SUBST(X_LDFLAGS)
2079 AC_SUBST(X_LIBS)
2080 AC_SUBST(GDBTKLIBS)
2081 AC_SUBST(GDBTK_CFLAGS)
2082 AC_SUBST(GDBTK_SRC_DIR)
2083
2084 AC_PATH_X
2085
2086 # Unlike the sim directory, whether a simulator is linked is controlled by
2087 # presence of a gdb_sim definition in the target configure.tgt entry.
2088 # This code just checks for a few cases where we'd like to ignore those
2089 # definitions, even when they're present in the '.mt' file.  These cases
2090 # are when --disable-sim is specified, or if the simulator directory is
2091 # not part of the source tree.
2092 #
2093 AC_ARG_ENABLE(sim,
2094 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2095 [echo "enable_sim = $enable_sim";
2096  echo "enableval = ${enableval}";
2097  case "${enableval}" in
2098   yes) ignore_sim=false ;;
2099   no)  ignore_sim=true ;;
2100   *)   ignore_sim=false ;;
2101  esac],
2102 [ignore_sim=false])
2103
2104 if test ! -d "${srcdir}/../sim"; then
2105   ignore_sim=true
2106 fi
2107
2108 SIM=
2109 SIM_OBS=
2110 if test "${ignore_sim}" = "false"; then
2111   if test x"${gdb_sim}" != x ; then
2112     SIM="${gdb_sim}"
2113     SIM_OBS="remote-sim.o"
2114     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2115   fi
2116 fi
2117 AC_SUBST(SIM)
2118 AC_SUBST(SIM_OBS)
2119
2120 AC_SUBST(ENABLE_CFLAGS)
2121 AC_SUBST(PROFILE_CFLAGS)
2122
2123 AC_SUBST(CONFIG_OBS)
2124 AC_SUBST(CONFIG_DEPS)
2125 AC_SUBST(CONFIG_SRCS)
2126 AC_SUBST(CONFIG_ALL)
2127 AC_SUBST(CONFIG_CLEAN)
2128 AC_SUBST(CONFIG_INSTALL)
2129 AC_SUBST(CONFIG_UNINSTALL)
2130
2131 # List of host floatformats.
2132 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2133 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2134 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2135
2136 # target_subdir is used by the testsuite to find the target libraries.
2137 target_subdir=
2138 if test "${host}" != "${target}"; then
2139     target_subdir="${target_alias}/"
2140 fi
2141 AC_SUBST(target_subdir)
2142
2143 frags=
2144 if test "${gdb_native}" = "yes"; then
2145   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
2146   if test ! -f ${host_makefile_frag}; then
2147     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
2148   fi
2149   frags="$frags $host_makefile_frag"
2150 else
2151   host_makefile_frag=/dev/null
2152 fi
2153
2154 AC_SUBST_FILE(host_makefile_frag)
2155 AC_SUBST(frags)
2156
2157 changequote(,)dnl
2158 if test "${gdb_native}" = "yes"; then
2159 # We pick this up from the host configuration file (.mh) because we
2160 # do not have a native configuration Makefile fragment.
2161 nativefile=`sed -n '
2162 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
2163 ' ${host_makefile_frag}`
2164 fi
2165 changequote([,])
2166
2167 if test x"${gdb_osabi}" != x ; then
2168     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2169                        [Define to the default OS ABI for this configuration.])
2170 fi
2171
2172 # Enable multi-ice-gdb-server.
2173 AC_ARG_ENABLE(multi-ice,
2174 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2175   [case $enableval in
2176     yes | no)
2177       ;;
2178     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2179   esac])
2180 if test "x$enable_multi_ice" = xyes; then
2181    AC_CONFIG_SUBDIRS(multi-ice)
2182 fi
2183
2184 AC_ARG_ENABLE(gdbserver,
2185 AS_HELP_STRING([--enable-gdbserver],
2186                [automatically build gdbserver (yes/no/auto, default is auto)]),
2187 [case "${enableval}" in
2188   yes| no|auto) ;;
2189   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2190 esac],[enable_gdbserver=auto])
2191
2192 # We only build gdbserver automatically in a native configuration, and
2193 # only if the user did not explicitly disable its build.
2194 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2195   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2196   if test "x$build_gdbserver" = xyes; then
2197     AC_MSG_RESULT(yes)
2198     AC_CONFIG_SUBDIRS(gdbserver)
2199     gdbserver_build_enabled=yes
2200   else
2201     AC_MSG_RESULT(no)
2202   fi
2203 fi
2204
2205 # If the user explicitly request the gdbserver to be built, verify that
2206 # we were in fact able to enable it.
2207 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2208   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2209 fi
2210
2211 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2212 # to an empty version.
2213
2214 files=
2215 links=
2216
2217 rm -f nm.h
2218 if test "${nativefile}" != ""; then
2219     case "${nativefile}" in
2220       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2221       * ) GDB_NM_FILE="${nativefile}"
2222     esac
2223     files="${files} ${GDB_NM_FILE}"
2224     links="${links} nm.h"
2225     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2226 fi
2227 AC_SUBST(GDB_NM_FILE)
2228
2229 AC_LINK_FILES($files, $links)
2230
2231 dnl Check for exe extension set on certain hosts (e.g. Win32)
2232 AC_EXEEXT
2233
2234 dnl  Detect the character set used by this host.
2235 dnl  At the moment, we just assume it's UTF-8.
2236 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2237           [Define to be a string naming the default host character set.])
2238
2239 AC_OUTPUT(Makefile .gdbinit:gdbinit.in doc/Makefile gnulib/Makefile data-directory/Makefile,
2240 [
2241 case x$CONFIG_HEADERS in
2242 xconfig.h:config.in)
2243 echo > stamp-h ;;
2244 esac
2245 ])
2246
2247 exit 0