gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2020 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 m4_include(../config/debuginfod.m4)
  22
  23 AC_INIT
  24 AC_CONFIG_SRCDIR([main.c])
  25 AC_CONFIG_HEADERS(config.h:config.in, [echo > stamp-h])
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_PROG_CXX
  30
  31 AC_USE_SYSTEM_EXTENSIONS
  32 ACX_LARGEFILE
  33 AM_PROG_INSTALL_STRIP
  34
  35 AC_CONFIG_AUX_DIR(..)
  36
  37 # Set build, build_cpu, build_vendor and build_os.
  38 AC_CANONICAL_BUILD
  39
  40 # Set host, host_cpu, host_vendor, and host_os.
  41 AC_CANONICAL_HOST
  42
  43 # Set target, target_cpu, target_vendor, and target_os.
  44 AC_CANONICAL_TARGET
  45
  46 AC_ARG_PROGRAM
  47
  48 # We require a C++11 compiler.  Check if one is available, and if
  49 # necessary, set CXX_DIALECT to some -std=xxx switch.
  50 AX_CXX_COMPILE_STDCXX(11, , mandatory)
  51
  52 # Dependency checking.
  53 ZW_CREATE_DEPDIR
  54 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  55
  56 dnl List of object files and targets accumulated by configure.
  57
  58 CONFIG_OBS=
  59 CONFIG_DEPS=
  60 CONFIG_SRCS=
  61 ENABLE_CFLAGS=
  62
  63 CONFIG_ALL=
  64 CONFIG_CLEAN=
  65 CONFIG_INSTALL=
  66 CONFIG_UNINSTALL=
  67
  68 dnl Set up for gettext.
  69 ZW_GNU_GETTEXT_SISTER_DIR
  70
  71 localedir='${datadir}/locale'
  72 AC_SUBST(localedir)
  73
  74 if test x"$USE_NLS" = xyes; then
  75    CONFIG_ALL="$CONFIG_ALL all-po"
  76    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  77    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  78    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  79 fi
  80
  81 PACKAGE=gdb
  82 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  83 AC_SUBST(PACKAGE)
  84
  85 # We never need to detect it in this sub-configure.
  86 # But preserve it for config.status --recheck.
  87 AC_ARG_VAR(MAKEINFO,
  88   [Parent configure detects if it is of sufficient version.])
  89 AC_ARG_VAR(MAKEINFOFLAGS,
  90   [Parameters for MAKEINFO.])
  91
  92 MAKEINFO_EXTRA_FLAGS=""
  93 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
  94   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
  95   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
  96     gdb_cv_have_makeinfo_click=yes
  97   else
  98     gdb_cv_have_makeinfo_click=no
  99   fi])
 100 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 101   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 102 fi
 103 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 104
 105 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 106     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 107     [${libdir}/debug])
 108
 109 # We can't pass paths as command line arguments.
 110 # Mingw32 tries to be clever and will convert the paths for us.
 111 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 112 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 113 # This breaks GDB's relocatable path conversions since paths passed in
 114 # config.h would not get so translated, the path prefixes no longer match.
 115 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 116
 117 # GDB's datadir relocation
 118
 119 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 120     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 121     [${datadir}/gdb])
 122
 123 AC_ARG_WITH(relocated-sources,
 124 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 125 [reloc_srcdir="${withval}"
 126  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 127               [Relocated directory for source files. ])
 128 ])
 129
 130 AC_MSG_CHECKING([for default auto-load directory])
 131 AC_ARG_WITH(auto-load-dir,
 132 AS_HELP_STRING([--with-auto-load-dir=PATH],
 133   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 134   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 135 escape_dir=`echo $with_auto_load_dir | sed -e 's/[[$]]datadir\>/\\\\\\\\\\\\&/g' -e 's/[[$]]debugdir\>/\\\\\\\\\\\\&/g'`
 136 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 137               [Directories from which to load auto-loaded scripts.])
 138 AC_MSG_RESULT([$with_auto_load_dir])
 139
 140 AC_MSG_CHECKING([for default auto-load safe-path])
 141 AC_ARG_WITH(auto-load-safe-path,
 142 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 143   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 144 AS_HELP_STRING([--without-auto-load-safe-path],
 145                [do not restrict auto-loaded files locations]),
 146     [if test "$with_auto_load_safe_path" = "no"; then
 147      with_auto_load_safe_path="/"
 148      fi],
 149 [with_auto_load_safe_path="$with_auto_load_dir"])
 150 escape_dir=`echo $with_auto_load_safe_path | sed -e 's/[[$]]datadir\>/\\\\\\\\\\\\&/g' -e 's/[[$]]debugdir\>/\\\\\\\\\\\\&/g'`
 151 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 152               [Directories safe to hold auto-loaded files.])
 153 AC_MSG_RESULT([$with_auto_load_safe_path])
 154
 155 AC_CONFIG_SUBDIRS(testsuite)
 156
 157 # Check whether to support alternative target configurations
 158 AC_ARG_ENABLE(targets,
 159 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 160 [case "${enableval}" in
 161   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
 162             ;;
 163   no)       enable_targets= ;;
 164   *)        enable_targets=$enableval ;;
 165 esac])
 166
 167 # Check whether to enable 64-bit support on 32-bit hosts
 168 AC_ARG_ENABLE(64-bit-bfd,
 169 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 170 [case "${enableval}" in
 171   yes)  want64=true  ;;
 172   no)   want64=false ;;
 173   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 174 esac],[want64=false])dnl
 175
 176 # Provide defaults for some variables set by the per-host and per-target
 177 # configuration.
 178 gdb_host_obs=posix-hdep.o
 179
 180 if test "${target}" = "${host}"; then
 181   gdb_native=yes
 182 else
 183   gdb_native=no
 184 fi
 185
 186 . $srcdir/configure.host
 187
 188 # Accumulate some settings from configure.tgt over all enabled targets
 189
 190 TARGET_OBS=
 191 all_targets=
 192 HAVE_NATIVE_GCORE_TARGET=
 193
 194 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 195 do
 196   if test "$targ_alias" = "all"; then
 197     all_targets=true
 198   else
 199     # Canonicalize the secondary target names.
 200     result=`$ac_config_sub $targ_alias 2>/dev/null`
 201     if test -n "$result"; then
 202         targ=$result
 203     else
 204         targ=$targ_alias
 205     fi
 206
 207     . ${srcdir}/configure.tgt
 208
 209     AS_IF([test -z "${gdb_target_obs}"],
 210       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 211
 212     # Target-specific object files
 213     for i in ${gdb_target_obs}; do
 214         case " $TARGET_OBS " in
 215         *" ${i} "*) ;;
 216         *)
 217           TARGET_OBS="$TARGET_OBS ${i}"
 218           ;;
 219         esac
 220     done
 221
 222     # Check whether this target needs 64-bit CORE_ADDR
 223     if test x${want64} = xfalse; then
 224       . ${srcdir}/../bfd/config.bfd
 225     fi
 226
 227     # Check whether this target is native and supports gcore.
 228     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 229        && $gdb_have_gcore; then
 230       HAVE_NATIVE_GCORE_TARGET=1
 231     fi
 232   fi
 233 done
 234
 235 if test x${all_targets} = xtrue; then
 236
 237   # We want all 64-bit targets if we either:
 238   #  - run on a 64-bit host  or
 239   #  - already require 64-bit support for some other target  or
 240   #  - the --enable-64-bit-bfd option was supplied
 241   # Otherwise we only support all 32-bit targets.
 242   #
 243   # NOTE: This test must be in sync with the corresponding
 244   #       tests in BFD!
 245
 246   if test x${want64} = xfalse; then
 247     AC_CHECK_SIZEOF(long)
 248     if test "x${ac_cv_sizeof_long}" = "x8"; then
 249       want64=true
 250     fi
 251   fi
 252   if test x${want64} = xtrue; then
 253     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 254   else
 255     TARGET_OBS='$(ALL_TARGET_OBS)'
 256   fi
 257 fi
 258
 259 AC_SUBST(TARGET_OBS)
 260 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 261
 262 # For other settings, only the main target counts.
 263 gdb_sim=
 264 gdb_osabi=
 265 targ=$target; . ${srcdir}/configure.tgt
 266
 267 # Fetch the default architecture and default target vector from BFD.
 268 targ=$target; . $srcdir/../bfd/config.bfd
 269
 270 # We only want the first architecture, so strip off the others if
 271 # there is more than one.
 272 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 273
 274 if test "x$targ_archs" != x; then
 275   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 276     [Define to BFD's default architecture. ])
 277 fi
 278 if test "x$targ_defvec" != x; then
 279   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 280     [Define to BFD's default target vector. ])
 281 fi
 282
 283 # Enable MI.
 284 AC_ARG_ENABLE(gdbmi,
 285 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 286   [case $enableval in
 287     yes | no)
 288       ;;
 289     *)
 290       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 291   esac],
 292   [enable_gdbmi=yes])
 293 if test x"$enable_gdbmi" = xyes; then
 294   if test -d "$srcdir/mi"; then
 295     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 296     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 297     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 298     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 299   fi
 300 fi
 301
 302 # Enable TUI.
 303 AC_ARG_ENABLE(tui,
 304 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 305   [case $enableval in
 306     yes | no | auto)
 307       ;;
 308     *)
 309       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 310   esac],enable_tui=auto)
 311
 312 # Enable gdbtk.
 313 AC_ARG_ENABLE(gdbtk,
 314 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 315   [case $enableval in
 316     yes | no)
 317       ;;
 318     *)
 319       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 320   esac],
 321   [if test -d "$srcdir/gdbtk"; then
 322     enable_gdbtk=yes
 323   else
 324     enable_gdbtk=no
 325   fi])
 326 # We unconditionally disable gdbtk tests on selected platforms.
 327 case $host_os in
 328   go32* | windows*)
 329     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 330     enable_gdbtk=no ;;
 331 esac
 332
 333 # Handle optional debuginfod support
 334 AC_DEBUGINFOD
 335
 336 # Libunwind support for ia64.
 337 AC_ARG_WITH(libunwind-ia64,
 338 AS_HELP_STRING([--with-libunwind-ia64],
 339                [use libunwind frame unwinding for ia64 targets]),,
 340             [with_libunwind_ia64=auto])
 341
 342 # Backward compatibility option.
 343 if test "${with_libunwind+set}" = set; then
 344   if test x"$with_libunwind_ia64" != xauto; then
 345     AC_MSG_ERROR(
 346       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 347   fi
 348   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 349   with_libunwind_ia64="$with_libunwind"
 350 fi
 351
 352 case "$with_libunwind_ia64" in
 353   yes | no)
 354     ;;
 355   auto)
 356     AC_CHECK_HEADERS(libunwind-ia64.h)
 357     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 358     ;;
 359   *)
 360     AC_MSG_ERROR(
 361       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 362     ;;
 363 esac
 364
 365 if test x"$with_libunwind_ia64" = xyes; then
 366   AC_CHECK_HEADERS(libunwind-ia64.h)
 367   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 368     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 369   fi
 370   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 371   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 372   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 373 fi
 374
 375 opt_curses=no
 376 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 377
 378 prefer_curses=no
 379 if test "$opt_curses" = "yes"; then
 380   prefer_curses=yes
 381 fi
 382
 383 # Profiling support.
 384 AC_ARG_ENABLE(profiling,
 385 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 386   [case $enableval in
 387     yes | no)
 388       ;;
 389     *)
 390       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 391   esac],
 392  [enable_profiling=no])
 393
 394 AC_CHECK_FUNCS(monstartup _mcleanup)
 395 AC_CACHE_CHECK(
 396   [for _etext],
 397   [ac_cv_var__etext],
 398   [AC_LINK_IFELSE(
 399      [AC_LANG_PROGRAM(
 400         [#include <stdlib.h>
 401          extern char _etext;],
 402         [free (&_etext);]
 403       )],
 404      [ac_cv_var__etext=yes],
 405      [ac_cv_var__etext=no]
 406    )]
 407 )
 408 if test "$ac_cv_var__etext" = yes; then
 409   AC_DEFINE(HAVE__ETEXT, 1,
 410             [Define to 1 if your system has the _etext variable. ])
 411 fi
 412 AC_CACHE_CHECK(
 413   [for etext],
 414   [ac_cv_var_etext],
 415   [AC_LINK_IFELSE(
 416      [AC_LANG_PROGRAM(
 417         [#include <stdlib.h>
 418          extern char etext;],
 419         [free (&etext);]
 420       )],
 421      [ac_cv_var_etext=yes],
 422      [ac_cv_var_etext=no]
 423    )]
 424 )
 425 if test "$ac_cv_var_etext" = yes; then
 426   AC_DEFINE(HAVE_ETEXT, 1,
 427             [Define to 1 if your system has the etext variable. ])
 428 fi
 429 if test "$enable_profiling" = yes ; then
 430   if test "$ac_cv_func_monstartup" = no || test "$ac_cv_func__mcleanup" = no; then
 431     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 432   fi
 433   PROFILE_CFLAGS=-pg
 434   OLD_CFLAGS="$CFLAGS"
 435   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 436
 437   AC_CACHE_CHECK(
 438     [whether $CC supports -pg],
 439     [ac_cv_cc_supports_pg],
 440     [AC_COMPILE_IFELSE(
 441        [AC_LANG_PROGRAM([], [int x;])],
 442        [ac_cv_cc_supports_pg=yes],
 443        [ac_cv_cc_supports_pg=no]
 444      )]
 445   )
 446
 447   if test "$ac_cv_cc_supports_pg" = no; then
 448     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 449   fi
 450
 451   CFLAGS="$OLD_CFLAGS"
 452 fi
 453
 454 CODESIGN_CERT=
 455 AC_ARG_ENABLE([codesign],
 456   AS_HELP_STRING([--enable-codesign=CERT],
 457                  [sign gdb with 'codesign -s CERT']),
 458   [CODESIGN_CERT=$enableval])
 459 AC_SUBST([CODESIGN_CERT])
 460
 461 ACX_PKGVERSION([GDB])
 462 ACX_BUGURL([https://www.gnu.org/software/gdb/bugs/])
 463 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 464 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 465
 466 # --------------------- #
 467 # Checks for programs.  #
 468 # --------------------- #
 469
 470 AC_PROG_AWK
 471 AC_PROG_INSTALL
 472 AC_PROG_LN_S
 473 AC_PROG_RANLIB
 474 AC_PROG_YACC
 475
 476 AC_CHECK_TOOL(AR, ar)
 477 AC_CHECK_TOOL(DLLTOOL, dlltool)
 478 AC_CHECK_TOOL(WINDRES, windres)
 479
 480 case $host_os in
 481   gnu*)
 482     # Needed for GNU Hurd hosts.
 483     AC_CHECK_TOOL(MIG, mig)
 484     if test x"$MIG" = x; then
 485       AC_MSG_ERROR([MIG not found but required for $host hosts])
 486     fi
 487     ;;
 488 esac
 489
 490 # ---------------------- #
 491 # Checks for libraries.  #
 492 # ---------------------- #
 493
 494 # We might need to link with -lm; most simulators need it.
 495 AC_CHECK_LIB(m, main)
 496
 497 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 498 AC_SEARCH_LIBS(gethostbyname, nsl)
 499
 500 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 501 AC_SEARCH_LIBS(socketpair, socket)
 502
 503 # Link in zlib if we can.  This allows us to read compressed debug sections.
 504 AM_ZLIB
 505
 506 AM_ICONV
 507
 508 # GDB may fork/exec the iconv program to get the list of supported character
 509 # sets.  Allow the user to specify where to find it.
 510 # There are several factors affecting the choice of option name:
 511 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 512 #   the build-time location of libiconv files.
 513 # - The program we need to find is iconv, which comes with glibc.  The user
 514 #   doesn't necessarily have libiconv installed.  Therefore naming this
 515 #   --with-libiconv-foo feels wrong.
 516 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 517 #   defined to work on directories not files (though it really doesn't know
 518 #   the difference).
 519 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 520 #   with --with-libiconv-prefix.
 521 # Putting these together is why the option name is --with-iconv-bin.
 522
 523 AC_ARG_WITH(iconv-bin,
 524 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 525 [iconv_bin="${withval}"
 526  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 527                     [Path of directory of iconv program.])
 528  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 529 ])
 530
 531 # For the TUI, we need enhanced curses functionality.
 532 if test x"$enable_tui" != xno; then
 533   prefer_curses=yes
 534 fi
 535
 536 curses_found=no
 537 if test x"$prefer_curses" = xyes; then
 538   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 539   # curses library because the latter might not provide all the
 540   # functionality we need.  However, this leads to problems on systems
 541   # where the linker searches /usr/local/lib, but the compiler doesn't
 542   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 543   # default installation of ncurses on alpha*-dec-osf* will lead to such
 544   # a situation.
 545   AC_SEARCH_LIBS(waddstr, [ncursesw ncurses cursesX curses])
 546
 547   if test "$ac_cv_search_waddstr" != no; then
 548     curses_found=yes
 549   fi
 550 fi
 551
 552 # Check whether we should enable the TUI, but only do so if we really
 553 # can.
 554 if test x"$enable_tui" != xno; then
 555   if test -d "$srcdir/tui"; then
 556     if test "$curses_found" != no; then
 557       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 558       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 559       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 560       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 561     else
 562       if test x"$enable_tui" = xyes; then
 563         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 564       else
 565         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 566       fi
 567     fi
 568   fi
 569 fi
 570
 571 # Since GDB uses Readline, we need termcap functionality.  In many
 572 # cases this will be provided by the curses library, but some systems
 573 # have a separate termcap library, or no curses library at all.
 574
 575 case $host_os in
 576   cygwin*)
 577     if test -d "$srcdir/libtermcap"; then
 578       LIBS="../libtermcap/libtermcap.a $LIBS"
 579       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 580     fi ;;
 581   go32* | *djgpp*)
 582     ac_cv_search_tgetent="none required"
 583     ;;
 584 esac
 585
 586 # These are the libraries checked by Readline.
 587 AC_SEARCH_LIBS(tgetent, [termcap tinfow tinfo curses ncursesw ncurses])
 588
 589 if test "$ac_cv_search_tgetent" = no; then
 590   CONFIG_OBS="$CONFIG_OBS stub-termcap.o"
 591 fi
 592
 593 AC_ARG_WITH([system-readline],
 594   [AS_HELP_STRING([--with-system-readline],
 595                   [use installed readline library])])
 596
 597 if test "$with_system_readline" = yes; then
 598   AC_CACHE_CHECK(
 599     [whether system readline is new enough],
 600     [gdb_cv_readline_ok],
 601     [AC_COMPILE_IFELSE(
 602        [AC_LANG_PROGRAM(
 603           [#include <stdio.h>
 604            #include <readline/readline.h>],
 605           [#if RL_VERSION_MAJOR < 7
 606            # error "readline version 7 required"
 607            #endif]
 608         )],
 609        [gdb_cv_readline_ok=yes],
 610        [gdb_cv_readline_ok=no]
 611      )]
 612   )
 613   if test "$gdb_cv_readline_ok" != yes; then
 614     AC_MSG_ERROR([system readline is not new enough])
 615   fi
 616
 617   READLINE=-lreadline
 618   READLINE_DEPS=
 619   READLINE_CFLAGS=
 620   READLINE_TEXI_INCFLAG=
 621 else
 622   READLINE='$(READLINE_DIR)/libreadline.a'
 623   READLINE_DEPS='$(READLINE)'
 624   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 625   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 626 fi
 627 AC_SUBST(READLINE)
 628 AC_SUBST(READLINE_DEPS)
 629 AC_SUBST(READLINE_CFLAGS)
 630 AC_SUBST(READLINE_TEXI_INCFLAG)
 631
 632 # Generate jit-reader.h
 633
 634 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 635 TARGET_PTR=
 636
 637 AC_CHECK_SIZEOF(unsigned long long)
 638 AC_CHECK_SIZEOF(unsigned long)
 639 AC_CHECK_SIZEOF(unsigned __int128)
 640
 641 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 642   TARGET_PTR="unsigned long"
 643 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 644   TARGET_PTR="unsigned long long"
 645 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 646   TARGET_PTR="unsigned __int128"
 647 else
 648   TARGET_PTR="unsigned long"
 649 fi
 650
 651 AC_SUBST(TARGET_PTR)
 652 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 653
 654 AC_SEARCH_LIBS(dlopen, dl)
 655
 656 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 657                 [directory to load the JIT readers from],
 658                 [${libdir}/gdb])
 659
 660 AC_ARG_WITH(expat,
 661   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 662   [], [with_expat=auto])
 663 AC_MSG_CHECKING([whether to use expat])
 664 AC_MSG_RESULT([$with_expat])
 665
 666 if test "${with_expat}" = no; then
 667   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 668   HAVE_LIBEXPAT=no
 669 else
 670   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 671                         [XML_Parser p = XML_ParserCreate (0);])
 672   if test "$HAVE_LIBEXPAT" != yes; then
 673     if test "$with_expat" = yes; then
 674       AC_MSG_ERROR([expat is missing or unusable])
 675     else
 676       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 677     fi
 678   else
 679     save_LIBS=$LIBS
 680     LIBS="$LIBS $LIBEXPAT"
 681     AC_CHECK_FUNCS(XML_StopParser)
 682     LIBS=$save_LIBS
 683   fi
 684 fi
 685
 686 # Verify that we have a usable GMP library.
 687 AC_LIB_HAVE_LINKFLAGS([gmp], [], [#include <gmp.h>],
 688                       [mpz_t n;
 689                        mpz_init (n);])
 690
 691 AC_ARG_WITH(mpfr,
 692   AS_HELP_STRING([--with-mpfr], [include MPFR support (auto/yes/no)]),
 693   [], [with_mpfr=auto])
 694 AC_MSG_CHECKING([whether to use MPFR])
 695 AC_MSG_RESULT([$with_mpfr])
 696
 697 if test "${with_mpfr}" = no; then
 698   AC_MSG_WARN([MPFR support disabled; some features may be unavailable.])
 699   HAVE_LIBMPFR=no
 700 else
 701   AC_LIB_HAVE_LINKFLAGS([mpfr], [gmp], [#include <mpfr.h>],
 702                         [mpfr_exp_t exp; mpfr_t x;
 703                          mpfr_frexp (&exp, x, x, MPFR_RNDN);])
 704   if test "$HAVE_LIBMPFR" != yes; then
 705     if test "$with_mpfr" = yes; then
 706       AC_MSG_ERROR([MPFR is missing or unusable])
 707     else
 708       AC_MSG_WARN([MPFR is missing or unusable; some features may be unavailable.])
 709     fi
 710   fi
 711 fi
 712
 713 # --------------------- #
 714 # Check for libpython.  #
 715 # --------------------- #
 716
 717 dnl Utility to simplify finding libpython.
 718 dnl $1 = the shell variable to assign the result to
 719 dnl      If libpython is found we store $version here.
 720 dnl $2 = additional flags to add to CPPFLAGS
 721 dnl $3 = additional flags to add to LIBS
 722
 723 AC_DEFUN([AC_TRY_LIBPYTHON],
 724 [
 725   define([have_libpython_var],$1)
 726   new_CPPFLAGS=$2
 727   new_LIBS=$3
 728   AC_MSG_CHECKING([for python])
 729   save_CPPFLAGS=$CPPFLAGS
 730   save_LIBS=$LIBS
 731   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 732   LIBS="$new_LIBS $LIBS"
 733   found_usable_python=no
 734   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "Python.h"]],
 735                                  [[Py_Initialize ();]])],
 736                  [have_libpython_var=yes
 737                   found_usable_python=yes
 738                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 739                   PYTHON_LIBS=$new_LIBS])
 740   CPPFLAGS=$save_CPPFLAGS
 741   LIBS=$save_LIBS
 742   AC_MSG_RESULT([${found_usable_python}])
 743 ])
 744
 745 dnl There are several different values for --with-python:
 746 dnl
 747 dnl no -   Don't include python support.
 748 dnl yes -  Include python support, error if it's missing.
 749 dnl        If we find python in $PATH, use it to fetch configure options,
 750 dnl        otherwise assume the compiler can find it with no help from us.
 751 dnl        Python 2.7 and 2.6 are tried in turn.
 752 dnl auto - Same as "yes", but if python is missing from the system,
 753 dnl        fall back to "no".
 754 dnl /path/to/python/exec-prefix -
 755 dnl        Use the python located in this directory.
 756 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 757 dnl        the compilation parameters.  Otherwise use
 758 dnl        -I/path/to/python/exec-prefix/include,
 759 dnl        -L/path/to/python/exec-prefix/lib.
 760 dnl        Python 2.7 and 2.6 are tried in turn.
 761 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 762 dnl        but is deprecated.
 763 dnl /path/to/python/executable -
 764 dnl        Run python-config.py with this version of python to fetch the
 765 dnl        compilation parameters.
 766 dnl        NOTE: This needn't be the real python executable.
 767 dnl        In a cross-compilation scenario (build != host), this could be
 768 dnl        a shell script that provides what python-config.py provides for
 769 dnl        --ldflags, --includes, --exec-prefix.
 770 dnl python-executable -
 771 dnl        Find python-executable in $PATH, and then handle the same as
 772 dnl        /path/to/python/executable.
 773 dnl
 774 dnl If a python program is specified, it is used to run python-config.py and
 775 dnl is passed --ldflags, --includes, --exec-prefix.
 776
 777 AC_ARG_WITH(python,
 778   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 779   [], [with_python=auto])
 780 AC_MSG_CHECKING([whether to use python])
 781 AC_MSG_RESULT([$with_python])
 782
 783 if test "${with_python}" = no; then
 784   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 785   have_libpython=no
 786 else
 787   case "${with_python}" in
 788   [[\\/]]* | ?:[[\\/]]*)
 789     if test -d "${with_python}"; then
 790       # Assume the python binary is ${with_python}/bin/python.
 791       python_prog="${with_python}/bin/python"
 792       python_prefix=
 793       # If python does not exit ${with_python}/bin, then try in
 794       # ${with_python}.  On Windows/MinGW, this is where the Python
 795       # executable is.
 796       if test ! -x "${python_prog}"; then
 797         python_prog="${with_python}/python"
 798         python_prefix=
 799       fi
 800       if test ! -x "${python_prog}"; then
 801         # Fall back to gdb 7.0/7.1 behaviour.
 802         python_prog=missing
 803         python_prefix=${with_python}
 804       fi
 805     elif test -x "${with_python}"; then
 806       # While we can't run python compiled for $host (unless host == build),
 807       # the user could write a script that provides the needed information,
 808       # so we support that.
 809       python_prog=${with_python}
 810       python_prefix=
 811     else
 812       AC_MSG_ERROR(invalid value for --with-python)
 813     fi
 814     ;;
 815   */*)
 816     # Disallow --with-python=foo/bar.
 817     AC_MSG_ERROR(invalid value for --with-python)
 818     ;;
 819   *)
 820     # The user has either specified auto, yes, or the name of the python
 821     # program assumed to be in $PATH.
 822     python_prefix=
 823     case "${with_python}" in
 824     yes | auto)
 825       if test "${build}" = "${host}"; then
 826         AC_PATH_PROG(python_prog_path, python, missing)
 827         if test "${python_prog_path}" = missing; then
 828           python_prog=missing
 829         else
 830           python_prog=${python_prog_path}
 831         fi
 832       else
 833         # Not much we can do except assume the cross-compiler will find the
 834         # right files.
 835         python_prog=missing
 836       fi
 837       ;;
 838     *)
 839       # While we can't run python compiled for $host (unless host == build),
 840       # the user could write a script that provides the needed information,
 841       # so we support that.
 842       python_prog="${with_python}"
 843       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 844       if test "${python_prog_path}" = missing; then
 845         AC_MSG_ERROR(unable to find python program ${python_prog})
 846       fi
 847       ;;
 848     esac
 849   esac
 850
 851   if test "${python_prog}" != missing; then
 852     # We have a python program to use, but it may be too old.
 853     # Don't flag an error for --with-python=auto (the default).
 854     have_python_config=yes
 855     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 856     if test $? != 0; then
 857       have_python_config=failed
 858       if test "${with_python}" != auto; then
 859         AC_MSG_ERROR(failure running python-config --includes)
 860       fi
 861     fi
 862     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 863     if test $? != 0; then
 864       have_python_config=failed
 865       if test "${with_python}" != auto; then
 866         AC_MSG_ERROR(failure running python-config --ldflags)
 867       fi
 868     fi
 869     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 870     if test $? != 0; then
 871       have_python_config=failed
 872       if test "${with_python}" != auto; then
 873         AC_MSG_ERROR(failure running python-config --exec-prefix)
 874       fi
 875     fi
 876   else
 877     # We do not have a python executable we can use to determine where
 878     # to find the Python headers and libs.  We cannot guess the include
 879     # path from the python_prefix either, because that include path
 880     # depends on the Python version.  So, there is nothing much we can
 881     # do except assume that the compiler will be able to find those files.
 882     python_includes=
 883     python_libs=
 884     have_python_config=no
 885   fi
 886
 887   # If we have python-config, only try the configuration it provides.
 888   # Otherwise fallback on the old way of trying different versions of
 889   # python in turn.
 890
 891   have_libpython=no
 892   if test "${have_python_config}" = yes; then
 893     AC_TRY_LIBPYTHON(have_libpython,
 894                      ${python_includes}, ${python_libs})
 895   elif test "${have_python_config}" != failed; then
 896     if test "${have_libpython}" = no; then
 897       AC_TRY_LIBPYTHON(have_libpython,
 898                        ${python_includes}, "-lpython2.7 ${python_libs}")
 899     fi
 900     if test "${have_libpython}" = no; then
 901       AC_TRY_LIBPYTHON(have_libpython,
 902                        ${python_includes}, "-lpython2.6 ${python_libs}")
 903     fi
 904   fi
 905
 906   if test "${have_libpython}" = no; then
 907     case "${with_python}" in
 908     yes)
 909       AC_MSG_ERROR([python is missing or unusable])
 910       ;;
 911     auto)
 912       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 913       ;;
 914     *)
 915       AC_MSG_ERROR([no usable python found at ${with_python}])
 916       ;;
 917     esac
 918   else
 919     if test -n "${python_prefix}"; then
 920       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 921                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 922       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 923     fi
 924   fi
 925 fi
 926
 927 dnl Use --with-python-libdir to control where GDB looks for the Python
 928 dnl libraries.
 929 dnl
 930 dnl If this is not given then the default will be based on the value
 931 dnl passed to --with-python, which is in the python_prefix variable.
 932 dnl If the --with-python option wasn't given then the default value in
 933 dnl python_prefix is based on running the 'gdb/python/python-config
 934 dnl --exec-prefix' script.
 935 AC_ARG_WITH(python-libdir,
 936   AS_HELP_STRING([--with-python-libdir@<:@=DIR@:>@], [search for python's libraries in DIR]),
 937   [],[
 938     # If no python libdir is specified then select one based on
 939     # python's prefix path.
 940     if test -n "${python_prefix}"; then
 941       with_python_libdir=${python_prefix}/lib
 942     fi
 943   ])
 944
 945 if test "${have_libpython}" != no; then
 946   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 947   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 948   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 949   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 950   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 951   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 952
 953   if test -n "${with_python_libdir}"; then
 954     AC_DEFINE_UNQUOTED(WITH_PYTHON_LIBDIR, "${with_python_libdir}",
 955                        [Directory containing Python's standard libraries from --with-python-libdir.])
 956     GDB_AC_DEFINE_RELOCATABLE(PYTHON_LIBDIR, [python lib], ${with_python_libdir})
 957   fi
 958
 959   # Flags needed to compile Python code (taken from python-config --cflags).
 960   # We cannot call python-config directly because it will output whatever was
 961   # used when compiling the Python interpreter itself, including flags which
 962   # would make the python-related objects be compiled differently from the
 963   # rest of GDB (e.g., -O2 and -fPIC).
 964   if test "${GCC}" = yes; then
 965     tentative_python_cflags="-fno-strict-aliasing -fwrapv"
 966     # Python headers recommend -DNDEBUG, but it's unclear if that just
 967     # refers to building Python itself.  In release mode, though, it
 968     # doesn't hurt for the Python code in gdb to follow.
 969     $development || tentative_python_cflags="$tentative_python_cflags -DNDEBUG"
 970   fi
 971
 972   if test "x${tentative_python_cflags}" != x; then
 973     AC_MSG_CHECKING(compiler flags for python code)
 974     for flag in ${tentative_python_cflags}; do
 975       # Check that the compiler accepts it
 976       saved_CFLAGS="$CFLAGS"
 977       CFLAGS="$CFLAGS $flag"
 978       AC_COMPILE_IFELSE(
 979         [AC_LANG_PROGRAM([], [])],
 980         [PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag"],
 981         []
 982       )
 983       CFLAGS="$saved_CFLAGS"
 984     done
 985     AC_MSG_RESULT(${PYTHON_CFLAGS})
 986   fi
 987
 988   # On x64 Windows, Python's include headers, and pyconfig.h in
 989   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
 990   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
 991   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
 992   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
 993   # The issue was reported to the Python community, but still isn't
 994   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
 995
 996   case "$gdb_host" in
 997     mingw64)
 998            if test "${GCC}" = yes; then
 999              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
1000            fi
1001            ;;
1002   esac
1003 else
1004   # Even if Python support is not compiled in, we need to have this file
1005   # included so that the "python" command, et.al., still exists.
1006   CONFIG_OBS="$CONFIG_OBS python/python.o"
1007   CONFIG_SRCS="$CONFIG_SRCS python/python.c"
1008 fi
1009
1010 # Work around Python http://bugs.python.org/issue10112.  See also
1011 # http://bugs.python.org/issue11410, otherwise -Wl,--dynamic-list has
1012 # no effect.  Note that the only test after this that uses Python is
1013 # the -rdynamic/-Wl,--dynamic-list test, and we do want that one to be
1014 # run without -export-dynamic too.
1015 PYTHON_LIBS=`echo $PYTHON_LIBS | sed -e 's/-Xlinker -export-dynamic//'`
1016
1017 AC_SUBST(PYTHON_CFLAGS)
1018 AC_SUBST(PYTHON_CPPFLAGS)
1019 AC_SUBST(PYTHON_LIBS)
1020 AM_CONDITIONAL(HAVE_PYTHON, test "${have_libpython}" != no)
1021
1022 # -------------------- #
1023 # Check for libguile.  #
1024 # -------------------- #
1025
1026 dnl Utility to simplify finding libguile.
1027 dnl $1 = pkg-config-program
1028 dnl $2 = space-separate list of guile versions to try
1029 dnl $3 = yes|no, indicating whether to flag errors or ignore them
1030 dnl $4 = the shell variable to assign the result to
1031 dnl      If libguile is found we store "yes" here.
1032
1033 AC_DEFUN([AC_TRY_LIBGUILE],
1034 [
1035   pkg_config=$1
1036   guile_version_list=$2
1037   flag_errors=$3
1038   define([have_libguile_var],$4)
1039   found_usable_guile=checking
1040   AC_MSG_CHECKING([for usable guile from ${pkg_config}])
1041   for guile_version in ${guile_version_list}; do
1042     ${pkg_config} --exists ${guile_version} 2>/dev/null
1043     if test $? != 0; then
1044       continue
1045     fi
1046     dnl pkg-config says the package exists, so if we get an error now,
1047     dnl that's bad.
1048     new_CPPFLAGS=`${pkg_config} --cflags ${guile_version}`
1049     if test $? != 0; then
1050       AC_MSG_ERROR([failure running pkg-config --cflags ${guile_version}])
1051     fi
1052     new_LIBS=`${pkg_config} --libs ${guile_version}`
1053     if test $? != 0; then
1054       AC_MSG_ERROR([failure running pkg-config --libs ${guile_version}])
1055     fi
1056     dnl If we get this far, great.
1057     found_usable_guile=${guile_version}
1058     break
1059   done
1060   if test "${found_usable_guile}" = "checking"; then
1061     if test "${flag_errors}" = "yes"; then
1062       AC_MSG_ERROR([unable to find usable guile version from "${guile_version_list}"])
1063     else
1064       found_usable_guile=no
1065     fi
1066   fi
1067   dnl One final sanity check.
1068   dnl The user could have said --with-guile=python-2.7.
1069   if test "${found_usable_guile}" != no; then
1070     save_CPPFLAGS=$CPPFLAGS
1071     save_LIBS=$LIBS
1072     CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
1073     LIBS="$LIBS $new_LIBS"
1074     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "libguile.h"]],
1075                                    [[scm_init_guile ();]])],
1076                    [have_libguile_var=yes
1077                     GUILE_CPPFLAGS=$new_CPPFLAGS
1078                     GUILE_LIBS=$new_LIBS],
1079                    [found_usable_guile=no])
1080     dnl scm_set_automatic_finalization_enabled added in Guile 2.2.
1081     AC_CHECK_FUNC(scm_set_automatic_finalization_enabled,
1082       AC_DEFINE(HAVE_GUILE_MANUAL_FINALIZATION, 1,
1083                 [Define if Guile supports manual finalization.])
1084     )
1085     CPPFLAGS=$save_CPPFLAGS
1086     LIBS=$save_LIBS
1087     if test "${found_usable_guile}" = no; then
1088       if test "${flag_errors}" = yes; then
1089         AC_MSG_FAILURE([linking guile version ${guile_version} test program failed])
1090       fi
1091     fi
1092   fi
1093   AC_MSG_RESULT([${found_usable_guile}])
1094 ])
1095
1096 dnl There are several different values for --with-guile:
1097 dnl
1098 dnl no -   Don't include guile support.
1099 dnl yes -  Include guile support, error if it's missing.
1100 dnl        The pkg-config program must be in $PATH.
1101 dnl auto - Same as "yes", but if guile is missing from the system,
1102 dnl        fall back to "no".
1103 dnl guile-version [guile-version-choice-2 ...] -
1104 dnl        A space-separated list of guile package versions to try.
1105 dnl        These are passed to pkg-config as-is.
1106 dnl        E.g., guile-2.0 or guile-2.2-uninstalled
1107 dnl        This requires making sure PKG_CONFIG_PATH is set appropriately.
1108 dnl /path/to/pkg-config -
1109 dnl        Use this pkg-config program.
1110 dnl        NOTE: This needn't be the "real" pkg-config program.
1111 dnl        It could be a shell script.  It is invoked as:
1112 dnl        pkg-config --exists $version
1113 dnl        pkg-config --cflags $version
1114 dnl        pkg-config --libs $version
1115 dnl        pkg-config --variable guild $version
1116 dnl        The script will be called with $version having each value in
1117 dnl        $try_guile_versions until --exists indicates success.
1118
1119 AC_ARG_WITH(guile,
1120   AS_HELP_STRING([--with-guile@<:@=GUILE@:>@], [include guile support (auto/yes/no/<guile-version>/<pkg-config-program>)]),
1121   [], [with_guile=auto])
1122 AC_MSG_CHECKING([whether to use guile])
1123 AC_MSG_RESULT([$with_guile])
1124
1125 dnl We check guile with pkg-config.
1126 AC_PATH_PROG(pkg_config_prog_path, pkg-config, missing)
1127
1128 try_guile_versions="guile-3.0 guile-2.2 guile-2.0"
1129 have_libguile=no
1130 case "${with_guile}" in
1131 no)
1132   AC_MSG_WARN([guile support disabled; some features will be unavailable.])
1133   ;;
1134 auto)
1135   if test "${pkg_config_prog_path}" = "missing"; then
1136     AC_MSG_WARN([pkg-config not found, guile support disabled])
1137   else
1138     AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, no, have_libguile)
1139   fi
1140   ;;
1141 yes)
1142   if test "${pkg_config_prog_path}" = "missing"; then
1143     AC_MSG_ERROR([pkg-config not found])
1144   fi
1145   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, yes, have_libguile)
1146   ;;
1147 [[\\/]]* | ?:[[\\/]]*)
1148   if test -x "${with_guile}"; then
1149     AC_TRY_LIBGUILE(${with_guile}, ${try_guile_versions}, yes, have_libguile)
1150   else
1151     AC_MSG_ERROR([Guile config program not executable: ${with_guile}])
1152   fi
1153   ;;
1154 "" | */*)
1155   # Disallow --with=guile="" and --with-guile=foo/bar.
1156   AC_MSG_ERROR([invalid value for --with-guile])
1157   ;;
1158 *)
1159   # A space separate list of guile versions to try, in order.
1160   if test "${pkg_config_prog_path}" = "missing"; then
1161     AC_MSG_ERROR([pkg-config not found])
1162   fi
1163   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${with_guile}, yes, have_libguile)
1164   ;;
1165 esac
1166
1167 if test "${have_libguile}" != no; then
1168   dnl Get the name of the 'guild' program.
1169   case "${with_guile}" in
1170   [[\\/]]* | ?:[[\\/]]*)
1171     GDB_GUILE_PROGRAM_NAMES(["${with_guile}"], ["${guile_version}"])
1172     ;;
1173   *)
1174     GDB_GUILE_PROGRAM_NAMES(["${pkg_config_prog_path}"], ["${guile_version}"])
1175     ;;
1176   esac
1177
1178   dnl Make sure guild can handle this host.
1179   GDB_TRY_GUILD([$srcdir/guile/lib/gdb/support.scm])
1180   dnl If not, disable guile support.
1181   if test "$ac_cv_guild_ok" = no; then
1182     have_libguile=no
1183     AC_MSG_WARN(disabling guile support, $GUILD fails compiling for $host)
1184   fi
1185 fi
1186
1187 if test "${have_libguile}" != no; then
1188   AC_DEFINE(HAVE_GUILE, 1, [Define if Guile interpreter is being linked in.])
1189   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_GUILE_OBS)"
1190   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_GUILE_DEPS)"
1191   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_GUILE_SRCS)"
1192   CONFIG_INSTALL="$CONFIG_INSTALL install-guile"
1193   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_GUILE_CFLAGS)"
1194
1195   dnl The 'scm_new_smob' function appeared in Guile 2.0.6.
1196   save_LIBS="$LIBS"
1197   save_CPPFLAGS="$CPPFLAGS"
1198   LIBS="$GUILE_LIBS"
1199   CPPFLAGS="$GUILE_CPPFLAGS"
1200   AC_CHECK_FUNCS([scm_new_smob])
1201   LIBS="$save_LIBS"
1202   CPPFLAGS="$save_CPPFLAGS"
1203 else
1204   # Even if Guile support is not compiled in, we need to have these files
1205   # included.
1206   CONFIG_OBS="$CONFIG_OBS guile/guile.o"
1207   CONFIG_SRCS="$CONFIG_SRCS guile/guile.c"
1208 fi
1209 AC_SUBST(GUILE_CPPFLAGS)
1210 AC_SUBST(GUILE_LIBS)
1211 AM_CONDITIONAL(HAVE_GUILE, test "${have_libguile}" != no)
1212
1213 # ---------------------------- #
1214 # Check for source highlight.  #
1215 # ---------------------------- #
1216
1217 SRCHIGH_LIBS=
1218 SRCHIGH_CFLAGS=
1219
1220 AC_ARG_ENABLE(source-highlight,
1221   AS_HELP_STRING([--enable-source-highlight],
1222     [enable source-highlight for source listings]),
1223   [case "${enableval}" in
1224   yes)  enable_source_highlight=yes ;;
1225   no)   enable_source_highlight=no  ;;
1226   *)    AC_MSG_ERROR(bad value ${enableval} for source-highlight option) ;;
1227 esac],
1228 [enable_source_highlight=auto])
1229
1230 if test "${enable_source_highlight}" != "no"; then
1231   AC_MSG_CHECKING([for the source-highlight library])
1232   if test "${pkg_config_prog_path}" = "missing"; then
1233     AC_MSG_RESULT([no - pkg-config not found])
1234     if test "${enable_source_highlight}" = "yes"; then
1235       AC_MSG_ERROR([pkg-config was not found in your system])
1236     fi
1237   else
1238     case "$LDFLAGS" in
1239       *static-libstdc*)
1240         AC_MSG_ERROR([source highlight is incompatible with -static-libstdc++; dnl
1241 either use --disable-source-highlight or dnl
1242 --without-static-standard-libraries])
1243         ;;
1244     esac
1245
1246     if ${pkg_config_prog_path} --exists source-highlight; then
1247       SRCHIGH_CFLAGS=`${pkg_config_prog_path} --cflags source-highlight`
1248       SRCHIGH_LIBS=`${pkg_config_prog_path} --libs source-highlight`
1249       AC_DEFINE([HAVE_SOURCE_HIGHLIGHT], 1,
1250                 [Define to 1 if the source-highlight library is available])
1251       AC_MSG_RESULT([yes])
1252     else
1253       AC_MSG_RESULT([no])
1254       if test "${enable_source_highlight}" = "yes"; then
1255         AC_MSG_ERROR([source-highlight was not found in your system])
1256       fi
1257     fi
1258   fi
1259 fi
1260 AC_SUBST(SRCHIGH_LIBS)
1261 AC_SUBST(SRCHIGH_CFLAGS)
1262
1263 # ------------------------- #
1264 # Checks for header files.  #
1265 # ------------------------- #
1266
1267 AC_HEADER_STDC
1268 # elf_hp.h is for HP/UX 64-bit shared library support.
1269 AC_CHECK_HEADERS([nlist.h machine/reg.h \
1270                   thread_db.h \
1271                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1272                   sys/resource.h sys/ptrace.h ptrace.h \
1273                   sys/reg.h sys/debugreg.h \
1274                   termios.h elf_hp.h])
1275 AC_CHECK_HEADERS(sys/user.h, [], [],
1276 [#if HAVE_SYS_PARAM_H
1277 # include <sys/param.h>
1278 #endif
1279 ])
1280
1281 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncursesw/ncurses.h ncurses/ncurses.h ncurses/term.h)
1282 AC_CHECK_HEADERS(term.h, [], [],
1283 [#if HAVE_CURSES_H
1284 # include <curses.h>
1285 #endif
1286 ])
1287
1288 AC_CHECK_HEADERS([sys/socket.h])
1289 AC_CHECK_HEADERS([ws2tcpip.h])
1290
1291 # ------------------------- #
1292 # Checks for declarations.  #
1293 # ------------------------- #
1294
1295 libiberty_INIT
1296
1297 AC_CHECK_DECLS([snprintf])
1298 AM_LC_MESSAGES
1299
1300 # ------------------ #
1301 # Checks for types.  #
1302 # ------------------ #
1303
1304 AC_CHECK_TYPES(socklen_t, [], [],
1305 [#include <sys/types.h>
1306 #if HAVE_SYS_SOCKET_H
1307 # include <sys/socket.h>
1308 #elif HAVE_WS2TCPIP_H
1309 # include <ws2tcpip.h>
1310 #endif
1311 ])
1312
1313 # ------------------------------------- #
1314 # Checks for compiler characteristics.  #
1315 # ------------------------------------- #
1316
1317 AC_C_CONST
1318 AC_C_INLINE
1319 AC_C_BIGENDIAN
1320
1321 # ------------------------------ #
1322 # Checks for library functions.  #
1323 # ------------------------------ #
1324
1325 AC_CHECK_FUNCS([getuid getgid \
1326                 pipe pread pread64 pwrite resize_term \
1327                 getpgid setsid \
1328                 sigaction sigsetmask socketpair \
1329                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1330                 setrlimit getrlimit posix_madvise waitpid \
1331                 use_default_colors])
1332 AM_LANGINFO_CODESET
1333 GDB_AC_COMMON
1334
1335 # Check the return and argument types of ptrace.
1336 GDB_AC_PTRACE
1337
1338 dnl AC_FUNC_SETPGRP does not work when cross compiling
1339 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1340 if test "$cross_compiling" = no; then
1341   AC_FUNC_SETPGRP
1342 else
1343   AC_CACHE_CHECK(
1344     [whether setpgrp takes no argument],
1345     [ac_cv_func_setpgrp_void],
1346     [AC_COMPILE_IFELSE(
1347        [AC_LANG_PROGRAM(
1348           [#include <unistd.h>],
1349           [if (setpgrp(1,1) == -1)
1350              exit (0);
1351            else
1352              exit (1);]
1353         )],
1354        [ac_cv_func_setpgrp_void=no],
1355        [ac_cv_func_setpgrp_void=yes]
1356      )]
1357   )
1358 if test "$ac_cv_func_setpgrp_void" = yes; then
1359   AC_DEFINE(SETPGRP_VOID, 1)
1360 fi
1361 fi
1362
1363 # Assume we'll default to using the included libiberty regex.
1364 gdb_use_included_regex=yes
1365
1366 # However, if the system regex is GNU regex, then default to *not*
1367 # using the included regex.
1368 AC_CACHE_CHECK(
1369   [for GNU regex],
1370   [gdb_cv_have_gnu_regex],
1371   [AC_COMPILE_IFELSE(
1372      [AC_LANG_PROGRAM(
1373         [#include <gnu-versions.h>],
1374         [#define REGEX_INTERFACE_VERSION 1
1375          #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1376          # error "Version mismatch"
1377          #endif]
1378       )],
1379      [gdb_cv_have_gnu_regex=yes],
1380      [gdb_cv_have_gnu_regex=no]
1381    )]
1382 )
1383 if test "$gdb_cv_have_gnu_regex" = yes; then
1384   gdb_use_included_regex=no
1385 fi
1386
1387 AC_ARG_WITH(included-regex,
1388   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1389   gdb_with_regex=$withval,
1390   gdb_with_regex=$gdb_use_included_regex)
1391 if test "$gdb_with_regex" = yes; then
1392   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1393     [Define to 1 if the regex included in libiberty should be used.])
1394 fi
1395
1396 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1397 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1398 [#include <sys/param.h>
1399 #include <sys/proc.h>
1400 ])
1401
1402 # See if <sys/lwp.h> defines `struct lwp`.
1403 AC_CACHE_CHECK(
1404   [for struct lwp],
1405   [gdb_cv_struct_lwp],
1406   [AC_COMPILE_IFELSE(
1407      [AC_LANG_PROGRAM(
1408         [#include <sys/param.h>
1409          #define _KMEMUSER
1410          #include <sys/lwp.h>],
1411         [struct lwp l;]
1412       )],
1413      [gdb_cv_struct_lwp=yes],
1414      [gdb_cv_struct_lwp=no]
1415    )]
1416 )
1417 if test "$gdb_cv_struct_lwp" = yes; then
1418   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1419             [Define to 1 if your system has struct lwp.])
1420 fi
1421
1422 # See if <machine/reg.h> degines `struct reg'.
1423 AC_CACHE_CHECK(
1424   [for struct reg in machine/reg.h],
1425   [gdb_cv_struct_reg],
1426   [AC_COMPILE_IFELSE(
1427      [AC_LANG_PROGRAM(
1428         [#include <sys/types.h>
1429          #include <machine/reg.h>],
1430         [struct reg r;]
1431       )],
1432      [gdb_cv_struct_reg=yes],
1433      [gdb_cv_struct_reg=no]
1434    )]
1435 )
1436 if test "$gdb_cv_struct_reg" = yes; then
1437   AC_DEFINE(HAVE_STRUCT_REG, 1,
1438             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1439 fi
1440
1441 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1442 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1443 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1444                  [#include <sys/types.h>
1445 #include <machine/reg.h>])
1446
1447 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1448 AC_MSG_CHECKING(for PTRACE_GETREGS)
1449 AC_CACHE_VAL(
1450   [gdb_cv_have_ptrace_getregs],
1451   [AC_COMPILE_IFELSE(
1452     [AC_LANG_PROGRAM([#include <sys/ptrace.h>], [PTRACE_GETREGS;])],
1453     [gdb_cv_have_ptrace_getregs=yes],
1454     [gdb_cv_have_ptrace_getregs=no]
1455    )]
1456 )
1457 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1458 if test "$gdb_cv_have_ptrace_getregs" = yes; then
1459   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1460   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1461 fi
1462
1463 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1464 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1465 AC_CACHE_VAL(
1466   [gdb_cv_have_ptrace_getfpxregs],
1467   [AC_COMPILE_IFELSE(
1468      [AC_LANG_PROGRAM([#include <sys/ptrace.h>], [PTRACE_GETFPXREGS;])],
1469      [gdb_cv_have_ptrace_getfpxregs=yes],
1470      [gdb_cv_have_ptrace_getfpxregs=no]
1471    )]
1472 )
1473 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1474 if test "$gdb_cv_have_ptrace_getfpxregs" = yes; then
1475   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1476   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1477 fi
1478
1479 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1480 AC_MSG_CHECKING(for PT_GETDBREGS)
1481 AC_CACHE_VAL(
1482   [gdb_cv_have_pt_getdbregs],
1483   [AC_COMPILE_IFELSE(
1484      [AC_LANG_PROGRAM(
1485         [#include <sys/types.h>
1486          #include <sys/ptrace.h>],
1487         [PT_GETDBREGS;]
1488       )],
1489      [gdb_cv_have_pt_getdbregs=yes],
1490      [gdb_cv_have_pt_getdbregs=no]
1491    )]
1492 )
1493 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1494 if test "$gdb_cv_have_pt_getdbregs" = yes; then
1495   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1496   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1497 fi
1498
1499 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1500 AC_MSG_CHECKING(for PT_GETXMMREGS)
1501 AC_CACHE_VAL(
1502   [gdb_cv_have_pt_getxmmregs],
1503   [AC_COMPILE_IFELSE(
1504      [AC_LANG_PROGRAM(
1505         [#include <sys/types.h>
1506          #include <sys/ptrace.h>],
1507         [PT_GETXMMREGS;]
1508       )],
1509      [gdb_cv_have_pt_getxmmregs=yes],
1510      [gdb_cv_have_pt_getxmmregs=no]
1511    )]
1512 )
1513 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1514 if test "$gdb_cv_have_pt_getxmmregs" = yes; then
1515   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1516   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1517 fi
1518
1519 # See if <sys/ptrace.h> supports LWP names on FreeBSD
1520 # Older FreeBSD versions don't have the pl_tdname member of
1521 # `struct ptrace_lwpinfo'.
1522 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_tdname], [], [],
1523                  [#include <sys/ptrace.h>])
1524
1525 # See if <sys/ptrace.h> supports syscall fields on FreeBSD.  The
1526 # pl_syscall_code member of `struct ptrace_lwpinfo' was added in
1527 # FreeBSD 10.3.
1528 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_syscall_code], [], [],
1529                  [#include <sys/ptrace.h>])
1530
1531 # Check if the compiler supports the `long long' type.
1532
1533 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1534                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1535 [[extern long long foo;]],
1536 [[switch (foo & 2) { case 0: return 1; }]])],
1537                                   gdb_cv_c_long_long=yes,
1538                                   gdb_cv_c_long_long=no)])
1539 if test "$gdb_cv_c_long_long" != yes; then
1540   # libdecnumber requires long long.
1541   AC_MSG_ERROR([Compiler must support long long for GDB.])
1542 fi
1543
1544 # Check if the compiler and runtime support printing long longs.
1545
1546 AC_CACHE_CHECK([for long long support in printf],
1547                gdb_cv_printf_has_long_long,
1548                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1549 [[char buf[32];
1550   long long l = 0;
1551   l = (l << 16) + 0x0123;
1552   l = (l << 16) + 0x4567;
1553   l = (l << 16) + 0x89ab;
1554   l = (l << 16) + 0xcdef;
1555   sprintf (buf, "0x%016llx", l);
1556   return (strcmp ("0x0123456789abcdef", buf));]])],
1557                               gdb_cv_printf_has_long_long=yes,
1558                               gdb_cv_printf_has_long_long=no,
1559                               gdb_cv_printf_has_long_long=no)])
1560 if test "$gdb_cv_printf_has_long_long" = yes; then
1561   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1562             [Define to 1 if the "%ll" format works to print long longs.])
1563 fi
1564
1565 # Check if the compiler and runtime support printing decfloats.
1566
1567 AC_CACHE_CHECK([for decfloat support in printf],
1568                gdb_cv_printf_has_decfloat,
1569                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1570 [[char buf[64];
1571   _Decimal32 d32 = 1.2345df;
1572   _Decimal64 d64 = 1.2345dd;
1573   _Decimal128 d128 = 1.2345dl;
1574   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1575   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1576                               gdb_cv_printf_has_decfloat=yes,
1577                               gdb_cv_printf_has_decfloat=no,
1578                               gdb_cv_printf_has_decfloat=no)])
1579 if test "$gdb_cv_printf_has_decfloat" = yes; then
1580   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1581             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1582 fi
1583
1584 # Check if the compiler supports the `long double' type.  We can't use
1585 # AC_C_LONG_DOUBLE because that one does additional checks on the
1586 # constants defined in <float.h> that fail on some systems,
1587 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1588
1589 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1590                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1591                                   gdb_cv_c_long_double=yes,
1592                                   gdb_cv_c_long_double=no)])
1593 if test "$gdb_cv_c_long_double" = yes; then
1594   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1595            [Define to 1 if the compiler supports long double.])
1596 fi
1597
1598 # Check if the compiler and runtime support printing long doubles.
1599
1600 AC_CACHE_CHECK([for long double support in printf],
1601                gdb_cv_printf_has_long_double,
1602                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1603 [[char buf[16];
1604   long double f = 3.141592653;
1605   sprintf (buf, "%Lg", f);
1606   return (strncmp ("3.14159", buf, 7));]])],
1607                               gdb_cv_printf_has_long_double=yes,
1608                               gdb_cv_printf_has_long_double=no,
1609                               gdb_cv_printf_has_long_double=no)])
1610 if test "$gdb_cv_printf_has_long_double" = yes; then
1611   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1612             [Define to 1 if the "%Lg" format works to print long doubles.])
1613 fi
1614
1615 # Check if the compiler and runtime support scanning long doubles.
1616
1617 AC_CACHE_CHECK([for long double support in scanf],
1618                gdb_cv_scanf_has_long_double,
1619                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1620 [[#include <stdio.h>]],
1621 [[char *buf = "3.141592653";
1622   long double f = 0;
1623   sscanf (buf, "%Lg", &f);
1624   return !(f > 3.14159 && f < 3.14160);]])],
1625                               gdb_cv_scanf_has_long_double=yes,
1626                               gdb_cv_scanf_has_long_double=no,
1627                               gdb_cv_scanf_has_long_double=no)])
1628 if test "$gdb_cv_scanf_has_long_double" = yes; then
1629   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1630             [Define to 1 if the "%Lg" format works to scan long doubles.])
1631 fi
1632
1633 case ${host_os} in
1634 aix*)
1635   AC_CACHE_CHECK(
1636     [for -bbigtoc option], [gdb_cv_bigtoc],
1637     [SAVE_LDFLAGS=$LDFLAGS
1638
1639      case $GCC in
1640        yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1641        *) gdb_cv_bigtoc=-bbigtoc ;;
1642      esac
1643
1644      LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1645      AC_LINK_IFELSE(
1646        [AC_LANG_PROGRAM([], [int i;])],
1647        [],
1648        [gdb_cv_bigtoc=]
1649      )
1650      LDFLAGS="${SAVE_LDFLAGS}"]
1651   )
1652   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1653   ;;
1654 esac
1655
1656 AC_MSG_CHECKING(for the dynamic export flag)
1657 dynamic_list=false
1658 if test "${gdb_native}" = yes; then
1659    # The dynamically loaded libthread_db needs access to symbols in the gdb
1660    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1661    # may not be supported there.
1662    old_LDFLAGS="$LDFLAGS"
1663    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1664    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1665    LDFLAGS="$LDFLAGS $RDYNAMIC"
1666    if test "${have_libpython}" = no; then
1667      AC_LINK_IFELSE(
1668        [AC_LANG_PROGRAM([], [])],
1669        [dynamic_list=true],
1670        []
1671      )
1672    else
1673      # Workaround http://bugs.python.org/issue4434 where static
1674      # libpythonX.Y.a would get its symbols required for
1675      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1676      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1677
1678      # Note the workaround for Python
1679      # http://bugs.python.org/issue10112 earlier has removed
1680      # -export-dynamic from PYTHON_LIBS.  That's exactly what we want
1681      # here too, as otherwise it'd make this -Wl,--dynamic-list test
1682      # always pass.
1683      old_CFLAGS="$CFLAGS"
1684      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1685      old_LIBS="$LIBS"
1686      LIBS="$LIBS $PYTHON_LIBS"
1687      old_CPPFLAGS="$CPPFLAGS"
1688      CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
1689      AC_RUN_IFELSE(
1690        [AC_LANG_PROGRAM(
1691          [#include "Python.h"],
1692          [int err;
1693           Py_Initialize ();
1694           err = PyRun_SimpleString ("import ctypes\n");
1695           Py_Finalize ();
1696           return err == 0 ? 0 : 1;])],
1697        [dynamic_list=true], [], [true])
1698      LIBS="$old_LIBS"
1699      CFLAGS="$old_CFLAGS"
1700      CPPFLAGS="$old_CPPFLAGS"
1701    fi
1702    LDFLAGS="$old_LDFLAGS"
1703 fi
1704 if $dynamic_list; then
1705   found="-Wl,--dynamic-list"
1706   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1707 else
1708   found="-rdynamic"
1709   RDYNAMIC="-rdynamic"
1710 fi
1711 AC_SUBST(RDYNAMIC)
1712 AC_MSG_RESULT($found)
1713
1714 dnl For certain native configurations, we need to check whether thread
1715 dnl support can be built in or not.
1716 dnl
1717 dnl Note that we only want this if we are both native (host == target),
1718 dnl and not doing a canadian cross build (build == host).
1719
1720 if test "${build}" = "${host}" -a "${host}" = "${target}" ; then
1721    case ${host_os} in
1722    aix*)
1723       AC_MSG_CHECKING(for AiX thread debugging library)
1724       AC_CACHE_VAL(
1725         [gdb_cv_have_aix_thread_debug],
1726         [AC_COMPILE_IFELSE(
1727            [AC_LANG_PROGRAM(
1728               [#include <sys/pthdebug.h>],
1729               [#ifndef PTHDB_VERSION_3
1730                #error
1731                #endif]
1732             )],
1733            [gdb_cv_have_aix_thread_debug=yes],
1734            [gdb_cv_have_aix_thread_debug=no]
1735          )]
1736       )
1737       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1738       if test "$gdb_cv_have_aix_thread_debug" = yes; then
1739          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1740          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1741          LIBS="$LIBS -lpthdebug"
1742
1743          # Older versions of AIX do not provide the declaration for
1744          # the getthrds function (it appears that it was introduced
1745          # with AIX 6.x).
1746          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1747       fi
1748       ;;
1749    esac
1750    AC_SUBST(CONFIG_LDFLAGS)
1751 fi
1752
1753 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1754 dnl other error codes.
1755 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1756   AC_CACHE_CHECK(
1757     [whether <thread_db.h> has TD_NOTALLOC],
1758     [gdb_cv_thread_db_h_has_td_notalloc],
1759     [AC_COMPILE_IFELSE(
1760        [AC_LANG_PROGRAM(
1761           [#include <thread_db.h>],
1762           [int i = TD_NOTALLOC;]
1763         )],
1764        [gdb_cv_thread_db_h_has_td_notalloc=yes],
1765        [gdb_cv_thread_db_h_has_td_notalloc=no]
1766      )]
1767   )
1768
1769   AC_CACHE_CHECK(
1770     [whether <thread_db.h> has TD_VERSION],
1771     [gdb_cv_thread_db_h_has_td_version],
1772     [AC_COMPILE_IFELSE(
1773        [AC_LANG_PROGRAM(
1774           [#include <thread_db.h>],
1775           [int i = TD_VERSION;]
1776         )],
1777        [gdb_cv_thread_db_h_has_td_version=yes],
1778        [gdb_cv_thread_db_h_has_td_version=no]
1779      )]
1780   )
1781
1782   AC_CACHE_CHECK(
1783     [whether <thread_db.h> has TD_NOTLS],
1784     [gdb_cv_thread_db_h_has_td_notls],
1785     [AC_COMPILE_IFELSE(
1786        [AC_LANG_PROGRAM(
1787           [#include <thread_db.h>],
1788           [int i = TD_NOTLS;]
1789         )],
1790        [gdb_cv_thread_db_h_has_td_notls=yes],
1791        [gdb_cv_thread_db_h_has_td_notls=no]
1792      )]
1793   )
1794 fi
1795 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1796   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1797             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1798 fi
1799 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1800   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1801             [Define if <thread_db.h> has the TD_VERSION error code.])
1802 fi
1803 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1804   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1805             [Define if <thread_db.h> has the TD_NOTLS error code.])
1806 fi
1807
1808 dnl Set the host's .gdbinit filename.
1809 case $host_os in
1810   go32* | *djgpp*)
1811     gdbinit=gdb.ini
1812     ;;
1813   *)
1814     gdbinit=.gdbinit
1815     ;;
1816 esac
1817 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1818
1819 dnl Handle optional features that can be enabled.
1820
1821 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1822 # except that the argument to --with-sysroot is optional.
1823 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1824 if test "x$with_sysroot" = xyes; then
1825   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1826 fi
1827 AC_ARG_WITH(sysroot,
1828   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1829                  [search for usr/lib et al within DIR]),
1830   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1831 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1832               [search for usr/lib et al within DIR])
1833 AC_SUBST(TARGET_SYSTEM_ROOT)
1834 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1835
1836 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1837     [automatically load a system-wide gdbinit file],
1838     [])
1839 GDB_AC_WITH_DIR(SYSTEM_GDBINIT_DIR, system-gdbinit-dir,
1840     [automatically load system-wide gdbinit files from this directory],
1841     [])
1842
1843 AM_GDB_WARNINGS
1844 AM_GDB_UBSAN
1845
1846 # In the Cygwin environment, we need some additional flags.
1847 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1848 [AC_EGREP_CPP(^lose$, [
1849 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1850 lose
1851 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1852
1853
1854 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1855 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1856 case ${host} in
1857   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1858   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1859   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1860   *) SER_HARDWIRE="$SER_HARDWIRE ser-uds.o" ;;
1861 esac
1862 AC_SUBST(SER_HARDWIRE)
1863
1864 # libreadline needs libuser32.a in a cygwin environment
1865 WIN32LIBS=
1866 if test x"$gdb_cv_os_cygwin" = xyes; then
1867     WIN32LIBS="-luser32"
1868     case "${target}" in
1869         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1870         ;;
1871     esac
1872 fi
1873
1874 # The ser-tcp.c module requires sockets.
1875 # Note that WIN32APILIBS is set by GDB_AC_COMMON.
1876 WIN32LIBS="$WIN32LIBS $WIN32APILIBS"
1877
1878 # Add ELF support to GDB, but only if BFD includes ELF support.
1879 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
1880                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
1881 if test "$gdb_cv_var_elf" = yes; then
1882   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o dtrace-probe.o"
1883   AC_DEFINE(HAVE_ELF, 1,
1884             [Define if ELF support should be included.])
1885   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1886   if test "$plugins" = "yes"; then
1887     AC_SEARCH_LIBS(dlopen, dl)
1888   fi
1889 fi
1890
1891 # Add macho support to GDB, but only if BFD includes it.
1892 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
1893                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
1894 if test "$gdb_cv_var_macho" = yes; then
1895   CONFIG_OBS="$CONFIG_OBS machoread.o"
1896 fi
1897
1898 # Add any host-specific objects to GDB.
1899 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1900
1901 # If building on ELF, look for lzma support for embedded compressed debug info.
1902 if test "$gdb_cv_var_elf" = yes; then
1903   AC_ARG_WITH(lzma,
1904     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
1905     [], [with_lzma=auto])
1906   AC_MSG_CHECKING([whether to use lzma])
1907   AC_MSG_RESULT([$with_lzma])
1908
1909   if test "${with_lzma}" != no; then
1910     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
1911                           [lzma_index_iter iter;
1912                            lzma_index_iter_init (&iter, 0);
1913                            lzma_mf_is_supported (LZMA_MF_HC3);])
1914     if test "$HAVE_LIBLZMA" != yes; then
1915       if test "$with_lzma" = yes; then
1916         AC_MSG_ERROR([missing liblzma for --with-lzma])
1917       fi
1918     fi
1919   fi
1920 fi
1921
1922 LIBGUI="../libgui/src/libgui.a"
1923 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1924 AC_SUBST(LIBGUI)
1925 AC_SUBST(GUI_CFLAGS_X)
1926
1927 WIN32LDAPP=
1928 AC_SUBST(WIN32LIBS)
1929 AC_SUBST(WIN32LDAPP)
1930
1931 case "${host}" in
1932 *-*-cygwin* | *-*-mingw* )
1933     configdir="win"
1934     ;;
1935 *)
1936     configdir="unix"
1937     ;;
1938 esac
1939
1940 GDBTKLIBS=
1941 if test "${enable_gdbtk}" = "yes"; then
1942
1943     # Gdbtk must have an absolute path to srcdir in order to run
1944     # properly when not installed.
1945     here=`pwd`
1946     cd ${srcdir}
1947     GDBTK_SRC_DIR=`pwd`
1948     cd $here
1949
1950     SC_PATH_TCLCONFIG
1951
1952     # If $no_tk is nonempty, then we can't do Tk, and there is no
1953     # point to doing Tcl.
1954     SC_PATH_TKCONFIG
1955
1956     if test -z "${no_tcl}" -a -z "${no_tk}"; then
1957         SC_LOAD_TCLCONFIG
1958
1959         # Check for in-tree tcl
1960         here=`pwd`
1961         cd ${srcdir}/..
1962         topdir=`pwd`
1963         cd ${here}
1964
1965         intree="no"
1966         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
1967           intree="yes"
1968         fi
1969
1970         # Find Tcl private headers
1971         if test x"${intree}" = xno; then
1972           CY_AC_TCL_PRIVATE_HEADERS
1973           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
1974           TCL_LIBRARY="${TCL_LIB_SPEC}"
1975           TCL_DEPS=""
1976         else
1977           # If building tcl in the same src tree, private headers
1978           # are not needed, but we need to be sure to use the right
1979           # headers library
1980           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
1981           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
1982           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
1983         fi
1984         AC_SUBST(TCL_INCLUDE)
1985         AC_SUBST(TCL_LIBRARY)
1986         AC_SUBST(TCL_DEPS)
1987
1988         SC_LOAD_TKCONFIG
1989
1990         # Check for in-tree Tk
1991         intree="no"
1992         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
1993           intree="yes"
1994         fi
1995
1996         # Find Tk private headers
1997         if test x"${intree}" = xno; then
1998           CY_AC_TK_PRIVATE_HEADERS
1999           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2000           TK_LIBRARY=${TK_LIB_SPEC}
2001           TK_DEPS=""
2002         else
2003           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2004           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2005           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2006         fi
2007         AC_SUBST(TK_INCLUDE)
2008         AC_SUBST(TK_LIBRARY)
2009         AC_SUBST(TK_DEPS)
2010         AC_SUBST(TK_XINCLUDES)
2011
2012         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2013
2014         # Include some libraries that Tcl and Tk want.
2015         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2016         # Yes, the ordering seems wrong here.  But it isn't.
2017         # TK_LIBS is the list of libraries that need to be linked
2018         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2019         # were in LIBS then any link tests after this point would
2020         # try to include things like `$(LIBGUI)', which wouldn't work.
2021         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2022
2023         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2024         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2025         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2026         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2027         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2028         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2029         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2030
2031         if test x"$gdb_cv_os_cygwin" = xyes; then
2032           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2033           WIN32LDAPP="-Wl,--subsystem,console"
2034           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2035         fi
2036
2037         AC_CONFIG_SUBDIRS(gdbtk)
2038     fi
2039 fi
2040
2041 AC_SUBST(X_CFLAGS)
2042 AC_SUBST(X_LDFLAGS)
2043 AC_SUBST(X_LIBS)
2044 AC_SUBST(GDBTKLIBS)
2045 AC_SUBST(GDBTK_CFLAGS)
2046 AC_SUBST(GDBTK_SRC_DIR)
2047
2048 AC_PATH_X
2049
2050 # Unlike the sim directory, whether a simulator is linked is controlled by
2051 # presence of a gdb_sim definition in the target configure.tgt entry.
2052 # This code just checks for a few cases where we'd like to ignore those
2053 # definitions, even when they're present in the '.mt' file.  These cases
2054 # are when --disable-sim is specified, or if the simulator directory is
2055 # not part of the source tree.
2056 #
2057 AC_ARG_ENABLE(sim,
2058 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2059 [echo "enable_sim = $enable_sim";
2060  echo "enableval = ${enableval}";
2061  case "${enableval}" in
2062   yes) ignore_sim=false ;;
2063   no)  ignore_sim=true ;;
2064   *)   ignore_sim=false ;;
2065  esac],
2066 [ignore_sim=false])
2067
2068 if test ! -d "${srcdir}/../sim"; then
2069   ignore_sim=true
2070 fi
2071
2072 SIM=
2073 SIM_OBS=
2074 if test "${ignore_sim}" = "false"; then
2075   if test x"${gdb_sim}" != x ; then
2076     SIM="${gdb_sim}"
2077     SIM_OBS="remote-sim.o"
2078     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2079
2080     # Some tdep code should only be compiled in when the ppc sim is
2081     # built.  PR sim/13418.
2082     case $target in
2083       powerpc*-*-*)
2084         AC_DEFINE(WITH_PPC_SIM, 1, [Define if the PPC simulator is being linked in.])
2085         ;;
2086     esac
2087   fi
2088 fi
2089 AC_SUBST(SIM)
2090 AC_SUBST(SIM_OBS)
2091
2092 AC_SUBST(ENABLE_CFLAGS)
2093 AC_SUBST(PROFILE_CFLAGS)
2094
2095 AC_SUBST(CONFIG_OBS)
2096 AC_SUBST(CONFIG_DEPS)
2097 AC_SUBST(CONFIG_SRCS)
2098 AC_SUBST(CONFIG_ALL)
2099 AC_SUBST(CONFIG_CLEAN)
2100 AC_SUBST(CONFIG_INSTALL)
2101 AC_SUBST(CONFIG_UNINSTALL)
2102
2103 # List of host floatformats.
2104 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2105 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2106 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2107
2108 # target_subdir is used by the testsuite to find the target libraries.
2109 target_subdir=
2110 if test "${host}" != "${target}"; then
2111     target_subdir="${target_alias}/"
2112 fi
2113 AC_SUBST(target_subdir)
2114
2115 # Import nat definitions.
2116 nat_makefile_frag=/dev/null
2117 if test "${gdb_native}" = "yes"; then
2118   . ${srcdir}/configure.nat
2119   nativefile=$NAT_FILE
2120 fi
2121
2122 AC_SUBST(NAT_FILE)
2123 AC_SUBST(NATDEPFILES)
2124 AC_SUBST(NAT_CDEPS)
2125 AC_SUBST(LOADLIBES)
2126 AC_SUBST(MH_CFLAGS)
2127 AC_SUBST(XM_CLIBS)
2128 AC_SUBST(NAT_GENERATED_FILES)
2129 AC_SUBST(HAVE_NATIVE_GCORE_HOST)
2130 AC_SUBST_FILE(nat_makefile_frag)
2131
2132 if test x"${gdb_osabi}" != x ; then
2133     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2134                        [Define to the default OS ABI for this configuration.])
2135 fi
2136
2137 # Check for babeltrace and babeltrace-ctf
2138 AC_ARG_WITH(babeltrace,
2139   AS_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2140   [], [with_babeltrace=auto])
2141 AC_MSG_CHECKING([whether to use babeltrace])
2142 AC_MSG_RESULT([$with_babeltrace])
2143
2144 if test "x$with_babeltrace" = "xno"; then
2145   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2146 else
2147   # Append -Werror to CFLAGS so that configure can catch the warning
2148   # "assignment from incompatible pointer type", which is related to
2149   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2150   # in GDB, while babeltrace 1.0.3 is broken.
2151   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2152   # safe to save and restore CFLAGS here.
2153   saved_CFLAGS=$CFLAGS
2154   CFLAGS="$CFLAGS -Werror"
2155   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2156                         [#include <babeltrace/babeltrace.h>
2157                          #include <babeltrace/ctf/events.h>
2158                          #include <babeltrace/ctf/iterator.h>],
2159                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2160                         struct bt_ctf_event *event = NULL;
2161                         const struct bt_definition *scope;
2162
2163                         pos->type = BT_SEEK_BEGIN;
2164                         bt_iter_set_pos (bt_ctf_get_iter (NULL), pos);
2165                         scope = bt_ctf_get_top_level_scope (event,
2166                                                            BT_STREAM_EVENT_HEADER);
2167                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2168                         ])
2169   CFLAGS=$saved_CFLAGS
2170
2171   if test "$HAVE_LIBBABELTRACE" != yes; then
2172      if test "$with_babeltrace" = yes; then
2173        AC_MSG_ERROR([babeltrace is missing or unusable])
2174      else
2175        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2176      fi
2177   fi
2178 fi
2179
2180 # Check for xxhash
2181 AC_ARG_WITH(xxhash,
2182   AS_HELP_STRING([--with-xxhash], [use libxxhash for hashing (faster) (auto/yes/no)]),
2183   [], [with_xxhash=auto])
2184
2185 GCC_ENABLE([libctf], [yes], [], [Handle .ctf type-info sections])
2186 if test x${enable_static} = xno; then
2187   LIBCTF="-Wl,--rpath,../libctf/.libs ../libctf/.libs/libctf.so"
2188   CTF_DEPS="../libctf/.libs/libctf.so"
2189 else
2190   LIBCTF="../libctf/.libs/libctf.a"
2191   CTF_DEPS="$LIBCTF"
2192 fi
2193 if test "${enable_libctf}" = yes; then
2194   AC_DEFINE(ENABLE_LIBCTF, 1, [Handle .ctf type-info sections])
2195 else
2196   LIBCTF=
2197   CTF_DEPS=
2198 fi
2199 AC_SUBST(ENABLE_LIBCTF)
2200 AC_SUBST(LIBCTF)
2201 AC_SUBST(CTF_DEPS)
2202
2203 # If nativefile (NAT_FILE) is not set in configure.nat, we link to an
2204 # empty version.
2205
2206 if test "x$with_xxhash" != "xno"; then
2207   AC_LIB_HAVE_LINKFLAGS([xxhash], [],
2208                         [#include <xxhash.h>],
2209                         [XXH32("foo", 3, 0);
2210                         ])
2211   if test "$HAVE_LIBXXHASH" != yes; then
2212     if test "$with_xxhash" = yes; then
2213       AC_MSG_ERROR([xxhash is missing or unusable])
2214     fi
2215   fi
2216   if test "x$with_xxhash" = "xauto"; then
2217     with_xxhash="$HAVE_LIBXXHASH"
2218   fi
2219 fi
2220
2221 AC_MSG_CHECKING([whether to use xxhash])
2222 AC_MSG_RESULT([$with_xxhash])
2223
2224 NM_H=
2225 rm -f nm.h
2226 if test "${nativefile}" != ""; then
2227     case "${nativefile}" in
2228       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2229       * ) GDB_NM_FILE="${nativefile}"
2230     esac
2231     AC_CONFIG_LINKS([nm.h:$GDB_NM_FILE], [echo > stamp-nmh],
2232                     [GDB_NM_FILE=$GDB_NM_FILE])
2233     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2234     NM_H=nm.h
2235 fi
2236 AC_SUBST(GDB_NM_FILE)
2237 AC_SUBST(NM_H)
2238
2239 dnl Add dependency for xsltproc if building with maintainer-mode enabled.
2240 AC_PATH_PROGS(XSLTPROC, xsltproc, missing)
2241 if test "x$USE_MAINTAINER_MODE" = xyes; then
2242   if test "${XSLTPROC}" = missing; then
2243     AC_MSG_ERROR(unable to find xsltproc.  maintainer-mode requires xsltproc.)
2244   fi
2245 fi
2246 AC_SUBST(XSLTPROC)
2247
2248 dnl Check for exe extension set on certain hosts (e.g. Win32)
2249 AC_EXEEXT
2250
2251 dnl  Detect the character set used by this host.
2252 dnl  At the moment, we just assume it's UTF-8.
2253 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2254           [Define to be a string naming the default host character set.])
2255
2256 GDB_AC_SELFTEST([
2257   CONFIG_OBS="$CONFIG_OBS \$(SELFTESTS_OBS)"
2258   CONFIG_SRCS="$CONFIG_SRCS \$(SELFTESTS_SRCS)"
2259 ])
2260
2261 GDB_AC_TRANSFORM([gdb], [GDB_TRANSFORM_NAME])
2262 GDB_AC_TRANSFORM([gcore], [GCORE_TRANSFORM_NAME])
2263 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2264 AC_CONFIG_FILES([Makefile gdb-gdb.gdb gdb-gdb.py doc/Makefile data-directory/Makefile])
2265
2266 AC_OUTPUT