gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2014 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22 AC_INIT(main.c)
  23 AC_CONFIG_HEADER(config.h:config.in)
  24 AM_MAINTAINER_MODE
  25
  26 # Set the 'development' global.
  27 . $srcdir/development.sh
  28
  29 AC_PROG_CC
  30 AC_USE_SYSTEM_EXTENSIONS
  31 ACX_LARGEFILE
  32 AM_PROG_CC_STDC
  33 AM_PROG_INSTALL_STRIP
  34
  35 AC_CONFIG_AUX_DIR(..)
  36 AC_CANONICAL_SYSTEM
  37 AC_ARG_PROGRAM
  38
  39 # Dependency checking.
  40 ZW_CREATE_DEPDIR
  41 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  42
  43 # Check for the 'make' the user wants to use.
  44 AC_CHECK_PROGS(MAKE, make)
  45 MAKE_IS_GNU=
  46 case "`$MAKE --version 2>&1 | sed 1q`" in
  47   *GNU*)
  48     MAKE_IS_GNU=yes
  49     ;;
  50 esac
  51 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  52 AC_PROG_MAKE_SET
  53
  54 # Configure gnulib.  We need to build gnulib under some other
  55 # directory not "gnulib", to avoid the problem of both GDB and
  56 # GDBserver wanting to build it in the same directory, when building
  57 # in the source dir.
  58 ACX_CONFIGURE_DIR(["gnulib"], ["build-gnulib"])
  59
  60 dnl List of object files and targets accumulated by configure.
  61
  62 CONFIG_OBS=
  63 CONFIG_DEPS=
  64 CONFIG_SRCS=
  65 ENABLE_CFLAGS=
  66
  67 CONFIG_ALL=
  68 CONFIG_CLEAN=
  69 CONFIG_INSTALL=
  70 CONFIG_UNINSTALL=
  71
  72 dnl Set up for gettext.
  73 ZW_GNU_GETTEXT_SISTER_DIR
  74
  75 localedir='${datadir}/locale'
  76 AC_SUBST(localedir)
  77
  78 if test x"$USE_NLS" = xyes; then
  79    CONFIG_ALL="$CONFIG_ALL all-po"
  80    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  81    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  82    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  83 fi
  84
  85 GNULIB=build-gnulib/import
  86
  87 # For Makefile dependencies.
  88 GNULIB_STDINT_H=
  89 if test x"$STDINT_H" != x; then
  90   GNULIB_STDINT_H=$GNULIB/$STDINT_H
  91 fi
  92 AC_SUBST(GNULIB_STDINT_H)
  93
  94 PACKAGE=gdb
  95 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  96 AC_SUBST(PACKAGE)
  97
  98 # We never need to detect it in this sub-configure.
  99 # But preserve it for config.status --recheck.
 100 AC_ARG_VAR(MAKEINFO,
 101   [Parent configure detects if it is of sufficient version.])
 102 AC_ARG_VAR(MAKEINFOFLAGS,
 103   [Parameters for MAKEINFO.])
 104
 105 MAKEINFO_EXTRA_FLAGS=""
 106 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
 107   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
 108   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
 109     gdb_cv_have_makeinfo_click=yes
 110   else
 111     gdb_cv_have_makeinfo_click=no
 112   fi])
 113 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 114   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 115 fi
 116 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 117
 118 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 119     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 120     [${libdir}/debug])
 121
 122 # We can't pass paths as command line arguments.
 123 # Mingw32 tries to be clever and will convert the paths for us.
 124 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 125 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 126 # This breaks GDB's relocatable path conversions since paths passed in
 127 # config.h would not get so translated, the path prefixes no longer match.
 128 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 129
 130 # GDB's datadir relocation
 131
 132 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 133     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 134     [${datadir}/gdb])
 135
 136 AC_ARG_WITH(relocated-sources,
 137 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 138 [reloc_srcdir="${withval}"
 139  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 140               [Relocated directory for source files. ])
 141 ])
 142
 143 AC_MSG_CHECKING([for default auto-load directory])
 144 AC_ARG_WITH(auto-load-dir,
 145 AS_HELP_STRING([--with-auto-load-dir=PATH],
 146   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 147   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 148 escape_dir=`echo $with_auto_load_dir | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 149 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 150               [Directories from which to load auto-loaded scripts.])
 151 AC_MSG_RESULT([$with_auto_load_dir])
 152
 153 AC_MSG_CHECKING([for default auto-load safe-path])
 154 AC_ARG_WITH(auto-load-safe-path,
 155 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 156   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 157 AS_HELP_STRING([--without-auto-load-safe-path],
 158                [do not restrict auto-loaded files locations]),
 159     [if test "$with_auto_load_safe_path" = "no"; then
 160      with_auto_load_safe_path="/"
 161      fi],
 162 [with_auto_load_safe_path="$with_auto_load_dir"])
 163 escape_dir=`echo $with_auto_load_safe_path | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 164 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 165               [Directories safe to hold auto-loaded files.])
 166 AC_MSG_RESULT([$with_auto_load_safe_path])
 167
 168 AC_CONFIG_SUBDIRS(testsuite)
 169
 170 # Check whether to support alternative target configurations
 171 AC_ARG_ENABLE(targets,
 172 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 173 [case "${enableval}" in
 174   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 175             ;;
 176   no)       enable_targets= ;;
 177   *)        enable_targets=$enableval ;;
 178 esac])
 179
 180 # Check whether to enable 64-bit support on 32-bit hosts
 181 AC_ARG_ENABLE(64-bit-bfd,
 182 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 183 [case "${enableval}" in
 184   yes)  want64=true  ;;
 185   no)   want64=false ;;
 186   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 187 esac],[want64=false])dnl
 188
 189 # Provide defaults for some variables set by the per-host and per-target
 190 # configuration.
 191 gdb_host_obs=posix-hdep.o
 192
 193 if test "${target}" = "${host}"; then
 194   gdb_native=yes
 195 else
 196   gdb_native=no
 197 fi
 198
 199 . $srcdir/configure.host
 200
 201 # Accumulate some settings from configure.tgt over all enabled targets
 202
 203 TARGET_OBS=
 204 all_targets=
 205 HAVE_NATIVE_GCORE_TARGET=
 206
 207 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 208 do
 209   if test "$targ_alias" = "all"; then
 210     all_targets=true
 211   else
 212     # Canonicalize the secondary target names.
 213     result=`$ac_config_sub $targ_alias 2>/dev/null`
 214     if test -n "$result"; then
 215         targ=$result
 216     else
 217         targ=$targ_alias
 218     fi
 219
 220     . ${srcdir}/configure.tgt
 221
 222     AS_IF([test -z "${gdb_target_obs}"],
 223       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 224
 225     # Target-specific object files
 226     for i in ${gdb_target_obs}; do
 227         case " $TARGET_OBS " in
 228         *" ${i} "*) ;;
 229         *)
 230           TARGET_OBS="$TARGET_OBS ${i}"
 231           ;;
 232         esac
 233     done
 234
 235     # Check whether this target needs 64-bit CORE_ADDR
 236     if test x${want64} = xfalse; then
 237       . ${srcdir}/../bfd/config.bfd
 238     fi
 239
 240     # Check whether this target is native and supports gcore.
 241     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 242        && $gdb_have_gcore; then
 243       HAVE_NATIVE_GCORE_TARGET=1
 244     fi
 245   fi
 246 done
 247
 248 if test x${all_targets} = xtrue; then
 249
 250   # We want all 64-bit targets if we either:
 251   #  - run on a 64-bit host  or
 252   #  - already require 64-bit support for some other target  or
 253   #  - the --enable-64-bit-bfd option was supplied
 254   # Otherwise we only support all 32-bit targets.
 255   #
 256   # NOTE: This test must be in sync with the corresponding
 257   #       tests in BFD!
 258
 259   if test x${want64} = xfalse; then
 260     AC_CHECK_SIZEOF(long)
 261     if test "x${ac_cv_sizeof_long}" = "x8"; then
 262       want64=true
 263     fi
 264   fi
 265   if test x${want64} = xtrue; then
 266     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 267   else
 268     TARGET_OBS='$(ALL_TARGET_OBS)'
 269   fi
 270 fi
 271
 272 AC_SUBST(TARGET_OBS)
 273 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 274
 275 # For other settings, only the main target counts.
 276 gdb_sim=
 277 gdb_osabi=
 278 build_gdbserver=
 279 targ=$target; . ${srcdir}/configure.tgt
 280
 281 # Fetch the default architecture and default target vector from BFD.
 282 targ=$target; . $srcdir/../bfd/config.bfd
 283
 284 # We only want the first architecture, so strip off the others if
 285 # there is more than one.
 286 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 287
 288 if test "x$targ_archs" != x; then
 289   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 290     [Define to BFD's default architecture. ])
 291 fi
 292 if test "x$targ_defvec" != x; then
 293   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 294     [Define to BFD's default target vector. ])
 295 fi
 296
 297 # The CLI cannot be disabled yet, but may be in the future.
 298
 299 # Enable CLI.
 300 AC_ARG_ENABLE(gdbcli,
 301 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 302   [case $enableval in
 303     yes)
 304       ;;
 305     no)
 306       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 307     *)
 308       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 309   esac],
 310   [enable_gdbcli=yes])
 311 if test x"$enable_gdbcli" = xyes; then
 312   if test -d $srcdir/cli; then
 313     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 314     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 315     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 316     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 317   fi
 318 fi
 319
 320 # Enable MI.
 321 AC_ARG_ENABLE(gdbmi,
 322 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 323   [case $enableval in
 324     yes | no)
 325       ;;
 326     *)
 327       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 328   esac],
 329   [enable_gdbmi=yes])
 330 if test x"$enable_gdbmi" = xyes; then
 331   if test -d $srcdir/mi; then
 332     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 333     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 334     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 335     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 336   fi
 337 fi
 338
 339 # Enable TUI.
 340 AC_ARG_ENABLE(tui,
 341 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 342   [case $enableval in
 343     yes | no | auto)
 344       ;;
 345     *)
 346       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 347   esac],enable_tui=auto)
 348
 349 # Enable gdbtk.
 350 AC_ARG_ENABLE(gdbtk,
 351 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 352   [case $enableval in
 353     yes | no)
 354       ;;
 355     *)
 356       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 357   esac],
 358   [if test -d $srcdir/gdbtk; then
 359     enable_gdbtk=yes
 360   else
 361     enable_gdbtk=no
 362   fi])
 363 # We unconditionally disable gdbtk tests on selected platforms.
 364 case $host_os in
 365   go32* | windows*)
 366     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 367     enable_gdbtk=no ;;
 368 esac
 369
 370 # Libunwind support for ia64.
 371
 372 AC_ARG_WITH(libunwind-ia64,
 373 AS_HELP_STRING([--with-libunwind-ia64],
 374                [use libunwind frame unwinding for ia64 targets]),,
 375             [with_libunwind_ia64=auto])
 376
 377 # Backward compatibility option.
 378 if test "${with_libunwind+set}" = set; then
 379   if test x"$with_libunwind_ia64" != xauto; then
 380     AC_MSG_ERROR(
 381       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 382   fi
 383   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 384   with_libunwind_ia64="$with_libunwind"
 385 fi
 386
 387 case "$with_libunwind_ia64" in
 388   yes | no)
 389     ;;
 390   auto)
 391     AC_CHECK_HEADERS(libunwind-ia64.h)
 392     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 393     ;;
 394   *)
 395     AC_MSG_ERROR(
 396       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 397     ;;
 398 esac
 399
 400 if test x"$with_libunwind_ia64" = xyes; then
 401   AC_CHECK_HEADERS(libunwind-ia64.h)
 402   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 403     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 404   fi
 405   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 406   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 407   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 408 fi
 409
 410 opt_curses=no
 411 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 412
 413 prefer_curses=no
 414 if test "$opt_curses" = "yes"; then
 415   prefer_curses=yes
 416 fi
 417
 418 # Profiling support.
 419 AC_ARG_ENABLE(profiling,
 420 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 421   [case $enableval in
 422     yes | no)
 423       ;;
 424     *)
 425       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 426   esac],
 427  [enable_profiling=no])
 428
 429 AC_CHECK_FUNCS(monstartup _mcleanup)
 430 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 431 [AC_TRY_LINK(
 432 [#include <stdlib.h>
 433 extern char _etext;
 434 ],
 435 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 436 if test $ac_cv_var__etext = yes; then
 437   AC_DEFINE(HAVE__ETEXT, 1,
 438             [Define to 1 if your system has the _etext variable. ])
 439 fi
 440 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 441 [AC_TRY_LINK(
 442 [#include <stdlib.h>
 443 extern char etext;
 444 ],
 445 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 446 if test $ac_cv_var_etext = yes; then
 447   AC_DEFINE(HAVE_ETEXT, 1,
 448             [Define to 1 if your system has the etext variable. ])
 449 fi
 450 if test "$enable_profiling" = yes ; then
 451   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 452     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 453   fi
 454   PROFILE_CFLAGS=-pg
 455   OLD_CFLAGS="$CFLAGS"
 456   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 457
 458   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 459     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 460      ac_cv_cc_supports_pg=no)])
 461
 462   if test $ac_cv_cc_supports_pg = no; then
 463     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 464   fi
 465
 466   CFLAGS="$OLD_CFLAGS"
 467 fi
 468
 469 ACX_PKGVERSION([GDB])
 470 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 471 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 472 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 473
 474 # --------------------- #
 475 # Checks for programs.  #
 476 # --------------------- #
 477
 478 AC_PROG_AWK
 479 AC_PROG_INSTALL
 480 AC_PROG_LN_S
 481 AC_PROG_RANLIB
 482 AC_PROG_YACC
 483
 484 AC_CHECK_TOOL(AR, ar)
 485 AC_CHECK_TOOL(DLLTOOL, dlltool)
 486 AC_CHECK_TOOL(WINDRES, windres)
 487
 488 case $host_os in
 489   gnu*)
 490     # Needed for GNU Hurd hosts.
 491     AC_CHECK_TOOL(MIG, mig)
 492     if test x"$MIG" = x; then
 493       AC_MSG_ERROR([MIG not found but required for $host hosts])
 494     fi
 495     ;;
 496 esac
 497
 498 # ---------------------- #
 499 # Checks for libraries.  #
 500 # ---------------------- #
 501
 502 # We might need to link with -lm; most simulators need it.
 503 AC_CHECK_LIB(m, main)
 504
 505 # We need to link with -lw to get `wctype' on Solaris before Solaris
 506 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 507 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 508 # is known to have this problem).  Therefore we avoid libw if we can.
 509 AC_CHECK_FUNC(wctype, [],
 510   [AC_CHECK_LIB(w, wctype)])
 511
 512 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 513 AC_SEARCH_LIBS(gethostbyname, nsl)
 514
 515 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 516 AC_SEARCH_LIBS(socketpair, socket)
 517
 518 # Link in zlib if we can.  This allows us to read compressed debug sections.
 519 AM_ZLIB
 520
 521 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 522 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 523
 524 AM_ICONV
 525
 526 # GDB may fork/exec the iconv program to get the list of supported character
 527 # sets.  Allow the user to specify where to find it.
 528 # There are several factors affecting the choice of option name:
 529 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 530 #   the build-time location of libiconv files.
 531 # - The program we need to find is iconv, which comes with glibc.  The user
 532 #   doesn't necessarily have libiconv installed.  Therefore naming this
 533 #   --with-libiconv-foo feels wrong.
 534 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 535 #   defined to work on directories not files (though it really doesn't know
 536 #   the difference).
 537 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 538 #   with --with-libiconv-prefix.
 539 # Putting these together is why the option name is --with-iconv-bin.
 540
 541 AC_ARG_WITH(iconv-bin,
 542 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 543 [iconv_bin="${withval}"
 544  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 545                     [Path of directory of iconv program.])
 546  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 547 ])
 548
 549 # On alpha-osf, it appears that libtermcap and libcurses are not compatible.
 550 # There is a very specific comment in /usr/include/curses.h explaining that
 551 # termcap routines built into libcurses must not be used.
 552 #
 553 # The symptoms we observed so far is GDB unexpectedly changing
 554 # the terminal settings when tgetent is called - this is particularly
 555 # visible as the output is missing carriage returns, and so rapidly
 556 # becomes very hard to read.
 557 #
 558 # The readline configure script has already decided that libtermcap
 559 # was enough for its purposes, and so decided to build readline using
 560 # libtermcap.  Since the TUI mode requires curses, building GDB with
 561 # TUI enabled results in both libraries to be used at the same time,
 562 # which is not allowed.  This basically means that GDB with TUI is
 563 # broken on alpha-osf.
 564
 565 case $host_os in
 566   osf* )
 567     if test x"$enable_tui" = xyes; then
 568       AC_MSG_ERROR([Building GDB with TUI mode is not supported on this host])
 569     fi
 570     if test x"$enable_tui" = xauto; then
 571       enable_tui=no
 572     fi
 573     ;;
 574 esac
 575
 576 # For the TUI, we need enhanced curses functionality.
 577 if test x"$enable_tui" != xno; then
 578   prefer_curses=yes
 579 fi
 580
 581 curses_found=no
 582 if test x"$prefer_curses" = xyes; then
 583   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 584   # curses library because the latter might not provide all the
 585   # functionality we need.  However, this leads to problems on systems
 586   # where the linker searches /usr/local/lib, but the compiler doesn't
 587   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 588   # default installation of ncurses on alpha*-dec-osf* will lead to such
 589   # a situation.
 590   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 591
 592   if test "$ac_cv_search_waddstr" != no; then
 593     curses_found=yes
 594   fi
 595 fi
 596
 597 # Check whether we should enable the TUI, but only do so if we really
 598 # can.
 599 if test x"$enable_tui" != xno; then
 600   if test -d $srcdir/tui; then
 601     if test "$curses_found" != no; then
 602       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 603       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 604       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 605       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 606     else
 607       if test x"$enable_tui" = xyes; then
 608         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 609       else
 610         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 611       fi
 612     fi
 613   fi
 614 fi
 615
 616 # Since GDB uses Readline, we need termcap functionality.  In many
 617 # cases this will be provided by the curses library, but some systems
 618 # have a seperate termcap library, or no curses library at all.
 619
 620 case $host_os in
 621   cygwin*)
 622     if test -d $srcdir/libtermcap; then
 623       LIBS="../libtermcap/libtermcap.a $LIBS"
 624       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 625     fi ;;
 626   go32* | *djgpp*)
 627     ac_cv_search_tgetent="none required"
 628     ;;
 629   *mingw32*)
 630     ac_cv_search_tgetent="none required"
 631     CONFIG_OBS="$CONFIG_OBS windows-termcap.o"
 632     ;;
 633 esac
 634
 635 # These are the libraries checked by Readline.
 636 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 637
 638 if test "$ac_cv_search_tgetent" = no; then
 639   AC_MSG_ERROR([no termcap library found])
 640 fi
 641
 642 AC_ARG_WITH([system-readline],
 643   [AS_HELP_STRING([--with-system-readline],
 644                   [use installed readline library])])
 645
 646 if test "$with_system_readline" = yes; then
 647   READLINE=-lreadline
 648   READLINE_DEPS=
 649   READLINE_CFLAGS=
 650   READLINE_TEXI_INCFLAG=
 651 else
 652   READLINE='$(READLINE_DIR)/libreadline.a'
 653   READLINE_DEPS='$(READLINE)'
 654   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 655   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 656 fi
 657 AC_SUBST(READLINE)
 658 AC_SUBST(READLINE_DEPS)
 659 AC_SUBST(READLINE_CFLAGS)
 660 AC_SUBST(READLINE_TEXI_INCFLAG)
 661
 662 # Generate jit-reader.h
 663
 664 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 665 TARGET_PTR=
 666
 667 AC_CHECK_SIZEOF(unsigned long long)
 668 AC_CHECK_SIZEOF(unsigned long)
 669 AC_CHECK_SIZEOF(unsigned __int128)
 670
 671 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 672   TARGET_PTR="unsigned long"
 673 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 674   TARGET_PTR="unsigned long long"
 675 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 676   TARGET_PTR="unsigned __int128"
 677 else
 678   TARGET_PTR="unsigned long"
 679 fi
 680
 681 AC_SUBST(TARGET_PTR)
 682 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 683
 684 AC_SEARCH_LIBS(dlopen, dl)
 685
 686 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 687                 [directory to load the JIT readers from],
 688                 [${libdir}/gdb])
 689
 690 AC_ARG_WITH(expat,
 691   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 692   [], [with_expat=auto])
 693 AC_MSG_CHECKING([whether to use expat])
 694 AC_MSG_RESULT([$with_expat])
 695
 696 if test "${with_expat}" = no; then
 697   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 698   HAVE_LIBEXPAT=no
 699 else
 700   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 701                         [XML_Parser p = XML_ParserCreate (0);])
 702   if test "$HAVE_LIBEXPAT" != yes; then
 703     if test "$with_expat" = yes; then
 704       AC_MSG_ERROR([expat is missing or unusable])
 705     else
 706       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 707     fi
 708   else
 709     save_LIBS=$LIBS
 710     LIBS="$LIBS $LIBEXPAT"
 711     AC_CHECK_FUNCS(XML_StopParser)
 712     LIBS=$save_LIBS
 713   fi
 714 fi
 715
 716 # --------------------- #
 717 # Check for libpython.  #
 718 # --------------------- #
 719
 720 dnl Utility to simplify finding libpython.
 721 dnl $1 = pythonX.Y
 722 dnl $2 = the shell variable to assign the result to
 723 dnl      If libpython is found we store $version here.
 724 dnl $3 = additional flags to add to CPPFLAGS
 725 dnl $4 = additional flags to add to LIBS
 726
 727 AC_DEFUN([AC_TRY_LIBPYTHON],
 728 [
 729   version=$1
 730   define([have_libpython_var],$2)
 731   new_CPPFLAGS=$3
 732   new_LIBS=$4
 733   AC_MSG_CHECKING([for ${version}])
 734   save_CPPFLAGS=$CPPFLAGS
 735   save_LIBS=$LIBS
 736   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 737   LIBS="$LIBS $new_LIBS"
 738   found_usable_python=no
 739   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 740                                  [[Py_Initialize ();]]),
 741                  [have_libpython_var=${version}
 742                   found_usable_python=yes
 743                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 744                   PYTHON_LIBS=$new_LIBS])
 745   CPPFLAGS=$save_CPPFLAGS
 746   LIBS=$save_LIBS
 747   AC_MSG_RESULT([${found_usable_python}])
 748 ])
 749
 750 dnl There are several different values for --with-python:
 751 dnl
 752 dnl no -   Don't include python support.
 753 dnl yes -  Include python support, error if it's missing.
 754 dnl        If we find python in $PATH, use it to fetch configure options,
 755 dnl        otherwise assume the compiler can find it with no help from us.
 756 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 757 dnl auto - Same as "yes", but if python is missing from the system,
 758 dnl        fall back to "no".
 759 dnl /path/to/python/exec-prefix -
 760 dnl        Use the python located in this directory.
 761 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 762 dnl        the compilation parameters.  Otherwise use
 763 dnl        -I/path/to/python/exec-prefix/include,
 764 dnl        -L/path/to/python/exec-prefix/lib.
 765 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 766 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 767 dnl        but is deprecated.
 768 dnl /path/to/python/executable -
 769 dnl        Run python-config.py with this version of python to fetch the
 770 dnl        compilation parameters.
 771 dnl        NOTE: This needn't be the real python executable.
 772 dnl        In a cross-compilation scenario (build != host), this could be
 773 dnl        a shell script that provides what python-config.py provides for
 774 dnl        --ldflags, --includes, --exec-prefix.
 775 dnl python-executable -
 776 dnl        Find python-executable in $PATH, and then handle the same as
 777 dnl        /path/to/python/executable.
 778 dnl
 779 dnl If a python program is specified, it is used to run python-config.py and
 780 dnl is passed --ldflags, --includes, --exec-prefix.
 781
 782 AC_ARG_WITH(python,
 783   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 784   [], [with_python=auto])
 785 AC_MSG_CHECKING([whether to use python])
 786 AC_MSG_RESULT([$with_python])
 787
 788 if test "${with_python}" = no; then
 789   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 790   have_libpython=no
 791 else
 792   case "${with_python}" in
 793   [[\\/]]* | ?:[[\\/]]*)
 794     if test -d ${with_python}; then
 795       # Assume the python binary is ${with_python}/bin/python.
 796       python_prog="${with_python}/bin/python"
 797       python_prefix=
 798       # If python does not exit ${with_python}/bin, then try in
 799       # ${with_python}.  On Windows/MinGW, this is where the Python
 800       # executable is.
 801       if test ! -x "${python_prog}"; then
 802         python_prog="${with_python}/python"
 803         python_prefix=
 804       fi
 805       if test ! -x "${python_prog}"; then
 806         # Fall back to gdb 7.0/7.1 behaviour.
 807         python_prog=missing
 808         python_prefix=${with_python}
 809       fi
 810     elif test -x "${with_python}"; then
 811       # While we can't run python compiled for $host (unless host == build),
 812       # the user could write a script that provides the needed information,
 813       # so we support that.
 814       python_prog=${with_python}
 815       python_prefix=
 816     else
 817       AC_ERROR(invalid value for --with-python)
 818     fi
 819     ;;
 820   */*)
 821     # Disallow --with-python=foo/bar.
 822     AC_ERROR(invalid value for --with-python)
 823     ;;
 824   *)
 825     # The user has either specified auto, yes, or the name of the python
 826     # program assumed to be in $PATH.
 827     python_prefix=
 828     case "${with_python}" in
 829     yes | auto)
 830       if test ${build} = ${host}; then
 831         AC_PATH_PROG(python_prog_path, python, missing)
 832         if test "${python_prog_path}" = missing; then
 833           python_prog=missing
 834         else
 835           python_prog=${python_prog_path}
 836         fi
 837       else
 838         # Not much we can do except assume the cross-compiler will find the
 839         # right files.
 840         python_prog=missing
 841       fi
 842       ;;
 843     *)
 844       # While we can't run python compiled for $host (unless host == build),
 845       # the user could write a script that provides the needed information,
 846       # so we support that.
 847       python_prog="${with_python}"
 848       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 849       if test "${python_prog_path}" = missing; then
 850         AC_ERROR(unable to find python program ${python_prog})
 851       fi
 852       ;;
 853     esac
 854   esac
 855
 856   if test "${python_prog}" != missing; then
 857     # We have a python program to use, but it may be too old.
 858     # Don't flag an error for --with-python=auto (the default).
 859     have_python_config=yes
 860     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 861     if test $? != 0; then
 862       have_python_config=failed
 863       if test "${with_python}" != auto; then
 864         AC_ERROR(failure running python-config --includes)
 865       fi
 866     fi
 867     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 868     if test $? != 0; then
 869       have_python_config=failed
 870       if test "${with_python}" != auto; then
 871         AC_ERROR(failure running python-config --ldflags)
 872       fi
 873     fi
 874     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 875     if test $? != 0; then
 876       have_python_config=failed
 877       if test "${with_python}" != auto; then
 878         AC_ERROR(failure running python-config --exec-prefix)
 879       fi
 880     fi
 881   else
 882     # We do not have a python executable we can use to determine where
 883     # to find the Python headers and libs.  We cannot guess the include
 884     # path from the python_prefix either, because that include path
 885     # depends on the Python version.  So, there is nothing much we can
 886     # do except assume that the compiler will be able to find those files.
 887     python_includes=
 888     python_libs=
 889     have_python_config=no
 890   fi
 891
 892   # If we have python-config, only try the configuration it provides.
 893   # Otherwise fallback on the old way of trying different versions of
 894   # python in turn.
 895
 896   have_libpython=no
 897   if test "${have_python_config}" = yes; then
 898     # Determine the Python version by extracting "-lpython<version>"
 899     # part of the python_libs. <version> is usually X.Y with X and Y
 900     # being decimal numbers, but can also be XY (seen on Windows).
 901     #
 902     # The extraction is performed using sed with a regular expression.
 903     # Initially, the regexp used was using the '?' quantifier to make
 904     # the dot in the version number optional.  Unfortunately, this
 905     # does not work with non-GNU versions of sed because, because of
 906     # what looks like a limitation (the '?' quantifier does not work
 907     # with back-references).  We work around this limitation by using
 908     # the '*' quantifier instead.  It means that, in theory, we might
 909     # match unexpected version strings such as "-lpython2..7", but
 910     # this seems unlikely in practice.  And even if that happens,
 911     # an error will be triggered later on, when checking that version
 912     # number.
 913     python_version=`echo " ${python_libs} " \
 914                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 915     case "${python_version}" in
 916     python*)
 917       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 918                        ${python_includes}, ${python_libs})
 919       ;;
 920     *)
 921       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 922       ;;
 923     esac
 924   elif test "${have_python_config}" != failed; then
 925     if test "${have_libpython}" = no; then
 926       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 927                        ${python_includes}, "${python_libs} -lpython2.7")
 928     fi
 929     if test "${have_libpython}" = no; then
 930       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 931                        ${python_includes}, "${python_libs} -lpython2.6")
 932     fi
 933     if test ${have_libpython} = no; then
 934       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 935                        ${python_includes}, "${python_libs} -lpython2.5")
 936     fi
 937     if test ${have_libpython} = no; then
 938       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 939                        ${python_includes}, "${python_libs} -lpython2.4")
 940     fi
 941   fi
 942   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 943     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 944   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 945     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 946   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 947     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 948   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 949     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 950   fi
 951
 952   if test "${have_libpython}" = no; then
 953     case "${with_python}" in
 954     yes)
 955       AC_MSG_ERROR([python is missing or unusable])
 956       ;;
 957     auto)
 958       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 959       ;;
 960     *)
 961       AC_MSG_ERROR([no usable python found at ${with_python}])
 962       ;;
 963     esac
 964   else
 965     if test -n "${python_prefix}"; then
 966       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 967                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 968       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 969     fi
 970   fi
 971 fi
 972
 973 if test "${have_libpython}" != no; then
 974   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 975   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 976   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 977   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 978   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 979   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 980
 981   # Flags needed to compile Python code (taken from python-config --cflags).
 982   # We cannot call python-config directly because it will output whatever was
 983   # used when compiling the Python interpreter itself, including flags which
 984   # would make the python-related objects be compiled differently from the
 985   # rest of GDB (e.g., -O2 and -fPIC).
 986   if test "${GCC}" = yes; then
 987     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 988   fi
 989
 990   if test "x${tentative_python_cflags}" != x; then
 991     AC_MSG_CHECKING(compiler flags for python code)
 992     for flag in ${tentative_python_cflags}; do
 993       # Check that the compiler accepts it
 994       saved_CFLAGS="$CFLAGS"
 995       CFLAGS="$CFLAGS $flag"
 996       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 997       CFLAGS="$saved_CFLAGS"
 998     done
 999     AC_MSG_RESULT(${PYTHON_CFLAGS})
1000   fi
1001
1002   # On IRIX, type siginfo is not defined.  Instead, sys/siginfo.h provides:
1003   #    #if _SGIAPI
1004   #    #define siginfo __siginfo
1005   #    #endif
1006   # The problem is that including Python causes some XOPEN macros to be
1007   # unilaterally defined, and that in turn causes _SGIAPI to evaluate
1008   # to false.  So, we work around this issue by defining siginfo ourself
1009   # though the command-line.
1010   #
1011   # On x64 Windows, Python's include headers, and pyconfig.h in
1012   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
1013   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
1014   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
1015   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
1016   # The issue was reported to the Python community, but still isn't
1017   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
1018
1019   case "$gdb_host" in
1020     irix*) if test "${GCC}" = yes; then
1021              CPPFLAGS="$CPPFLAGS -Dsiginfo=__siginfo"
1022            fi
1023            ;;
1024     mingw64)
1025            if test "${GCC}" = yes; then
1026              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
1027            fi
1028            ;;
1029   esac
1030
1031   # Note that "python -m threading" cannot be used to check for
1032   # threading support due to a bug in Python 2.7.3
1033   # (http://bugs.python.org/issue15567).
1034   AC_MSG_CHECKING(whether python supports threads)
1035   saved_CPPFLAGS="${CPPFLAGS}"
1036   CPPFLAGS="${PYTHON_CPPFLAGS}"
1037   # Note that the test is reversed so that python_has_threads=yes on
1038   # unexpected failures.
1039   AC_PREPROC_IFELSE(AC_LANG_SOURCE([[
1040 #include <Python.h>
1041 #ifdef WITH_THREAD
1042 # error
1043 #endif
1044   ]]), [python_has_threads=no], [python_has_threads=yes])
1045   AC_MSG_RESULT(${python_has_threads})
1046   CPPFLAGS="${saved_CPPFLAGS}"
1047 else
1048   # Even if Python support is not compiled in, we need to have these files
1049   # included.
1050   CONFIG_OBS="$CONFIG_OBS python.o py-value.o py-prettyprint.o py-auto-load.o"
1051   CONFIG_SRCS="$CONFIG_SRCS python/python.c python/py-value.c \
1052         python/py-prettyprint.c python/py-auto-load.c"
1053 fi
1054 AC_SUBST(PYTHON_CFLAGS)
1055 AC_SUBST(PYTHON_CPPFLAGS)
1056 AC_SUBST(PYTHON_LIBS)
1057
1058 # --------------------- #
1059 # Check for libmcheck.  #
1060 # --------------------- #
1061
1062 # Enable -lmcheck by default (it provides cheap-enough memory mangling),
1063 # but turn it off if Python is enabled with threads, since -lmcheck is
1064 # not thread safe (http://sourceware.org/bugzilla/show_bug.cgi?id=9939),
1065 # and for releases.
1066 if test \( "${have_libpython}" = "no" -o "${python_has_threads}" = "no" \) \
1067    && $development; then
1068   libmcheck_default=yes
1069 else
1070   libmcheck_default=no
1071 fi
1072 GDB_AC_LIBMCHECK(${libmcheck_default})
1073
1074 if test "$ENABLE_LIBMCHECK" = "yes" \
1075         -a "${have_libpython}" != "no" \
1076         -a "${python_has_threads}" = "yes" ; then
1077   AC_MSG_WARN(--enable-libmcheck may lead to spurious crashes if threads are used in python)
1078 fi
1079
1080 # ------------------------- #
1081 # Checks for header files.  #
1082 # ------------------------- #
1083
1084 AC_HEADER_STDC
1085 # elf_hp.h is for HP/UX 64-bit shared library support.
1086 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
1087                   thread_db.h \
1088                   sys/fault.h \
1089                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1090                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1091                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
1092                   termios.h termio.h \
1093                   sgtty.h elf_hp.h \
1094                   dlfcn.h])
1095 AC_CHECK_HEADERS(sys/proc.h, [], [],
1096 [#if HAVE_SYS_PARAM_H
1097 # include <sys/param.h>
1098 #endif
1099 ])
1100 AC_CHECK_HEADERS(sys/user.h, [], [],
1101 [#if HAVE_SYS_PARAM_H
1102 # include <sys/param.h>
1103 #endif
1104 ])
1105
1106 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
1107 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
1108 # think that we don't have <curses.h> if we're using GCC.
1109 case $host_os in
1110   solaris2.[[789]])
1111     if test "$GCC" = yes; then
1112       AC_DEFINE(_MSE_INT_H, 1,
1113         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
1114    Solaris 2.[789] when using GCC. ])
1115     fi ;;
1116 esac
1117 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
1118 AC_CHECK_HEADERS(term.h, [], [],
1119 [#if HAVE_CURSES_H
1120 # include <curses.h>
1121 #endif
1122 ])
1123
1124 # ------------------------- #
1125 # Checks for declarations.  #
1126 # ------------------------- #
1127
1128 AC_CHECK_DECLS([free, malloc, realloc, snprintf])
1129 AM_LC_MESSAGES
1130
1131 # ----------------------- #
1132 # Checks for structures.  #
1133 # ----------------------- #
1134
1135 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1136
1137 # ------------------ #
1138 # Checks for types.  #
1139 # ------------------ #
1140
1141 AC_TYPE_SIGNAL
1142 AC_CHECK_TYPES(socklen_t, [], [],
1143 [#include <sys/types.h>
1144 #include <sys/socket.h>
1145 ])
1146
1147 # ------------------------------------- #
1148 # Checks for compiler characteristics.  #
1149 # ------------------------------------- #
1150
1151 AC_C_CONST
1152 AC_C_INLINE
1153 AC_C_BIGENDIAN
1154
1155 # ------------------------------ #
1156 # Checks for library functions.  #
1157 # ------------------------------ #
1158
1159 AC_FUNC_ALLOCA
1160 AC_FUNC_MMAP
1161 AC_FUNC_VFORK
1162 AC_CHECK_FUNCS([canonicalize_file_name realpath getrusage getuid getgid \
1163                 pipe poll pread pread64 pwrite readlink resize_term \
1164                 sbrk setpgid setpgrp setsid \
1165                 sigaction sigprocmask sigsetmask socketpair \
1166                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1167                 setrlimit getrlimit posix_madvise waitpid lstat \
1168                 ptrace64])
1169 AM_LANGINFO_CODESET
1170 GDB_AC_COMMON
1171
1172 # Check the return and argument types of ptrace.  No canned test for
1173 # this, so roll our own.
1174 gdb_ptrace_headers='
1175 #include <sys/types.h>
1176 #if HAVE_SYS_PTRACE_H
1177 # include <sys/ptrace.h>
1178 #endif
1179 #if HAVE_UNISTD_H
1180 # include <unistd.h>
1181 #endif
1182 '
1183 # There is no point in checking if we don't have a prototype.
1184 AC_CHECK_DECLS(ptrace, [], [
1185   : ${gdb_cv_func_ptrace_ret='int'}
1186   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1187 ], $gdb_ptrace_headers)
1188 # Check return type.  Varargs (used on GNU/Linux) conflict with the
1189 # empty argument list, so check for that explicitly.
1190 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
1191   AC_TRY_COMPILE($gdb_ptrace_headers,
1192     [extern long ptrace (enum __ptrace_request, ...);],
1193     gdb_cv_func_ptrace_ret='long',
1194     AC_TRY_COMPILE($gdb_ptrace_headers,
1195       [extern int ptrace ();],
1196       gdb_cv_func_ptrace_ret='int',
1197       gdb_cv_func_ptrace_ret='long')))
1198 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
1199   [Define as the return type of ptrace.])
1200 # Check argument types.
1201 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
1202   AC_TRY_COMPILE($gdb_ptrace_headers,
1203     [extern long ptrace (enum __ptrace_request, ...);],
1204     [gdb_cv_func_ptrace_args='int,int,long,long'],[
1205 for gdb_arg1 in 'int' 'long'; do
1206  for gdb_arg2 in 'pid_t' 'int' 'long'; do
1207   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
1208    for gdb_arg4 in 'int' 'long' 'void *'; do
1209      AC_TRY_COMPILE($gdb_ptrace_headers, [
1210 extern $gdb_cv_func_ptrace_ret
1211   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
1212 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
1213     break 4;])
1214     for gdb_arg5 in 'int *' 'int' 'long'; do
1215      AC_TRY_COMPILE($gdb_ptrace_headers, [
1216 extern $gdb_cv_func_ptrace_ret
1217   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
1218 ], [
1219 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
1220     break 5;])
1221     done
1222    done
1223   done
1224  done
1225 done
1226 # Provide a safe default value.
1227 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1228 ])])
1229 ac_save_IFS=$IFS; IFS=','
1230 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
1231 IFS=$ac_save_IFS
1232 shift
1233 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
1234   [Define to the type of arg 3 for ptrace.])
1235 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG4, $[4],
1236   [Define to the type of arg 4 for ptrace.])
1237 if test -n "$[5]"; then
1238   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
1239     [Define to the type of arg 5 for ptrace.])
1240 fi
1241
1242 dnl AC_FUNC_SETPGRP does not work when cross compiling
1243 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1244 if test "$cross_compiling" = no; then
1245   AC_FUNC_SETPGRP
1246 else
1247   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1248     [AC_TRY_COMPILE([
1249 #include <unistd.h>
1250 ], [
1251   if (setpgrp(1,1) == -1)
1252     exit (0);
1253   else
1254     exit (1);
1255 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1256 if test $ac_cv_func_setpgrp_void = yes; then
1257   AC_DEFINE(SETPGRP_VOID, 1)
1258 fi
1259 fi
1260
1261 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
1262 # since sigsetjmp might only be defined as a macro.
1263 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
1264 [AC_TRY_COMPILE([
1265 #include <setjmp.h>
1266 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
1267 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
1268 if test $gdb_cv_func_sigsetjmp = yes; then
1269   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
1270 fi
1271
1272 # Assume we'll default to using the included libiberty regex.
1273 gdb_use_included_regex=yes
1274
1275 # However, if the system regex is GNU regex, then default to *not*
1276 # using the included regex.
1277 AC_CACHE_CHECK(
1278   [for GNU regex],
1279   [gdb_cv_have_gnu_regex],
1280   [AC_TRY_COMPILE(
1281     [#include <gnu-versions.h>],
1282     [#define REGEX_INTERFACE_VERSION 1
1283 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1284 # error "Version mismatch"
1285 #endif],
1286     gdb_cv_have_gnu_regex=yes,
1287     gdb_cv_have_gnu_regex=no)])
1288 if test $gdb_cv_have_gnu_regex = yes; then
1289   gdb_use_included_regex=no
1290 fi
1291
1292 AC_ARG_WITH(included-regex,
1293   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1294   gdb_with_regex=$withval,
1295   gdb_with_regex=$gdb_use_included_regex)
1296 if test "$gdb_with_regex" = yes; then
1297   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1298     [Define to 1 if the regex included in libiberty should be used.])
1299 fi
1300
1301 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1302 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1303 [#include <sys/param.h>
1304 #include <sys/proc.h>
1305 ])
1306
1307 # See if <sys/lwp.h> defines `struct lwp`.
1308 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1309 [AC_TRY_COMPILE([#include <sys/param.h>
1310 #include <sys/lwp.h>], [struct lwp l;],
1311 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1312 if test $gdb_cv_struct_lwp = yes; then
1313   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1314             [Define to 1 if your system has struct lwp.])
1315 fi
1316
1317 # See if <machine/reg.h> degines `struct reg'.
1318 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1319 [AC_TRY_COMPILE([#include <sys/types.h>
1320 #include <machine/reg.h>], [struct reg r;],
1321 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1322 if test $gdb_cv_struct_reg = yes; then
1323   AC_DEFINE(HAVE_STRUCT_REG, 1,
1324             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1325 fi
1326
1327 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1328 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1329 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1330                  [#include <machine/reg.h>])
1331
1332 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
1333 # Older amd64 Linux's don't have the fs_base and gs_base members of
1334 # `struct user_regs_struct'.
1335 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
1336                  [], [], [#include <sys/user.h>])
1337
1338 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1339 AC_MSG_CHECKING(for PTRACE_GETREGS)
1340 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1341 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1342                 [PTRACE_GETREGS;],
1343                 [gdb_cv_have_ptrace_getregs=yes],
1344                 [gdb_cv_have_ptrace_getregs=no])])
1345 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1346 if test $gdb_cv_have_ptrace_getregs = yes; then
1347   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1348   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1349 fi
1350
1351 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1352 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1353 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1354 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1355                 [PTRACE_GETFPXREGS;],
1356                 [gdb_cv_have_ptrace_getfpxregs=yes],
1357                 [gdb_cv_have_ptrace_getfpxregs=no])])
1358 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1359 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1360   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1361   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1362 fi
1363
1364 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1365 AC_MSG_CHECKING(for PT_GETDBREGS)
1366 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1367 [AC_TRY_COMPILE([#include <sys/types.h>
1368 #include <sys/ptrace.h>],
1369                 [PT_GETDBREGS;],
1370                 [gdb_cv_have_pt_getdbregs=yes],
1371                 [gdb_cv_have_pt_getdbregs=no])])
1372 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1373 if test $gdb_cv_have_pt_getdbregs = yes; then
1374   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1375   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1376 fi
1377
1378 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1379 AC_MSG_CHECKING(for PT_GETXMMREGS)
1380 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1381 [AC_TRY_COMPILE([#include <sys/types.h>
1382 #include <sys/ptrace.h>],
1383                 [PT_GETXMMREGS;],
1384                 [gdb_cv_have_pt_getxmmregs=yes],
1385                 [gdb_cv_have_pt_getxmmregs=no])])
1386 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1387 if test $gdb_cv_have_pt_getxmmregs = yes; then
1388   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1389   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1390 fi
1391
1392 # Detect which type of /proc is in use, such as for Solaris.
1393
1394 if test "${target}" = "${host}"; then
1395   case "${host}" in
1396   *-*-sysv4.2* | *-*-sysv5* )
1397       AC_DEFINE(NEW_PROC_API, 1,
1398       [Define if you want to use new multi-fd /proc interface.])
1399       ;;
1400   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1401       AC_DEFINE(NEW_PROC_API, 1,
1402       [Define if you want to use new multi-fd /proc interface.])
1403       ;;
1404   mips-sgi-irix5*)
1405       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1406       AC_DEFINE([_KMEMUSER], 1,
1407       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1408        around a <sys/proc.h> problem on IRIX 5.])
1409       ;;
1410   esac
1411 fi
1412
1413 if test "$ac_cv_header_sys_procfs_h" = yes; then
1414   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1415   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1416   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1417   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1418   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1419   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1420   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1421   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1422   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1423   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1424   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1425
1426
1427   dnl Check for broken prfpregset_t type
1428
1429   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1430   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1431   dnl instead of the struct itself).  We detect this here, and work
1432   dnl around it in gdb_proc_service.h.
1433
1434   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1435     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1436     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1437       [AC_TRY_RUN([#include <sys/procfs.h>
1438        int main ()
1439        {
1440          if (sizeof (prfpregset_t) == sizeof (void *))
1441            return 1;
1442          return 0;
1443        }],
1444        gdb_cv_prfpregset_t_broken=no,
1445        gdb_cv_prfpregset_t_broken=yes,
1446        gdb_cv_prfpregset_t_broken=yes)])
1447     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1448     if test $gdb_cv_prfpregset_t_broken = yes; then
1449       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1450       [Define if the prfpregset_t type is broken.])
1451     fi
1452   fi
1453 fi
1454
1455 # Check if the compiler supports the `long long' type.
1456
1457 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1458                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1459 [[extern long long foo;]],
1460 [[switch (foo & 2) { case 0: return 1; }]])],
1461                                   gdb_cv_c_long_long=yes,
1462                                   gdb_cv_c_long_long=no)])
1463 if test $gdb_cv_c_long_long != yes; then
1464   # libdecnumber requires long long.
1465   AC_MSG_ERROR([Compiler must support long long for GDB.])
1466 fi
1467
1468 # Check if the compiler and runtime support printing long longs.
1469
1470 AC_CACHE_CHECK([for long long support in printf],
1471                gdb_cv_printf_has_long_long,
1472                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1473 [[char buf[32];
1474   long long l = 0;
1475   l = (l << 16) + 0x0123;
1476   l = (l << 16) + 0x4567;
1477   l = (l << 16) + 0x89ab;
1478   l = (l << 16) + 0xcdef;
1479   sprintf (buf, "0x%016llx", l);
1480   return (strcmp ("0x0123456789abcdef", buf));]])],
1481                               gdb_cv_printf_has_long_long=yes,
1482                               gdb_cv_printf_has_long_long=no,
1483                               gdb_cv_printf_has_long_long=no)])
1484 if test $gdb_cv_printf_has_long_long = yes; then
1485   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1486             [Define to 1 if the "%ll" format works to print long longs.])
1487 fi
1488
1489 # Check if the compiler and runtime support printing decfloats.
1490
1491 AC_CACHE_CHECK([for decfloat support in printf],
1492                gdb_cv_printf_has_decfloat,
1493                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1494 [[char buf[64];
1495   _Decimal32 d32 = 1.2345df;
1496   _Decimal64 d64 = 1.2345dd;
1497   _Decimal128 d128 = 1.2345dl;
1498   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1499   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1500                               gdb_cv_printf_has_decfloat=yes,
1501                               gdb_cv_printf_has_decfloat=no,
1502                               gdb_cv_printf_has_decfloat=no)])
1503 if test $gdb_cv_printf_has_decfloat = yes; then
1504   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1505             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1506 fi
1507
1508 # Check if the compiler supports the `long double' type.  We can't use
1509 # AC_C_LONG_DOUBLE because that one does additional checks on the
1510 # constants defined in <float.h> that fail on some systems,
1511 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1512
1513 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1514                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1515                                   gdb_cv_c_long_double=yes,
1516                                   gdb_cv_c_long_double=no)])
1517 if test $gdb_cv_c_long_double = yes; then
1518   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1519            [Define to 1 if the compiler supports long double.])
1520 fi
1521
1522 # Check if the compiler and runtime support printing long doubles.
1523
1524 AC_CACHE_CHECK([for long double support in printf],
1525                gdb_cv_printf_has_long_double,
1526                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1527 [[char buf[16];
1528   long double f = 3.141592653;
1529   sprintf (buf, "%Lg", f);
1530   return (strncmp ("3.14159", buf, 7));]])],
1531                               gdb_cv_printf_has_long_double=yes,
1532                               gdb_cv_printf_has_long_double=no,
1533                               gdb_cv_printf_has_long_double=no)])
1534 if test $gdb_cv_printf_has_long_double = yes; then
1535   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1536             [Define to 1 if the "%Lg" format works to print long doubles.])
1537 fi
1538
1539 # Check if the compiler and runtime support scanning long doubles.
1540
1541 AC_CACHE_CHECK([for long double support in scanf],
1542                gdb_cv_scanf_has_long_double,
1543                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1544 [[#include <stdio.h>]],
1545 [[char *buf = "3.141592653";
1546   long double f = 0;
1547   sscanf (buf, "%Lg", &f);
1548   return !(f > 3.14159 && f < 3.14160);]])],
1549                               gdb_cv_scanf_has_long_double=yes,
1550                               gdb_cv_scanf_has_long_double=no,
1551                               gdb_cv_scanf_has_long_double=no)])
1552 if test $gdb_cv_scanf_has_long_double = yes; then
1553   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1554             [Define to 1 if the "%Lg" format works to scan long doubles.])
1555 fi
1556
1557 case ${host_os} in
1558 aix*)
1559   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1560     SAVE_LDFLAGS=$LDFLAGS
1561
1562     case $GCC in
1563     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1564     *) gdb_cv_bigtoc=-bbigtoc ;;
1565     esac
1566
1567     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1568     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1569     LDFLAGS="${SAVE_LDFLAGS}"
1570   ])
1571   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1572   ;;
1573 esac
1574
1575 AC_MSG_CHECKING(for the dynamic export flag)
1576 dynamic_list=false
1577 if test "${gdb_native}" = yes; then
1578    # The dynamically loaded libthread_db needs access to symbols in the gdb
1579    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1580    # may not be supported there.
1581    old_LDFLAGS="$LDFLAGS"
1582    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1583    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1584    LDFLAGS="$LDFLAGS $RDYNAMIC"
1585    if test "${have_libpython}" = no; then
1586      AC_TRY_LINK([], [], [dynamic_list=true])
1587    else
1588      # Workaround http://bugs.python.org/issue4434 where static
1589      # libpythonX.Y.a would get its symbols required for
1590      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1591      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1592      old_CFLAGS="$CFLAGS"
1593      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1594      old_LIBS="$LIBS"
1595      LIBS="$LIBS $PYTHON_LIBS"
1596      AC_RUN_IFELSE(
1597        AC_LANG_PROGRAM(
1598          [#include "]${have_libpython}[/Python.h"],
1599          [int err;
1600           Py_Initialize ();
1601           err = PyRun_SimpleString ("import itertools\n");
1602           Py_Finalize ();
1603           return err == 0 ? 0 : 1;]),
1604        [dynamic_list=true], [], [true])
1605      LIBS="$old_LIBS"
1606      CFLAGS="$old_CFLAGS"
1607    fi
1608    LDFLAGS="$old_LDFLAGS"
1609 fi
1610 if $dynamic_list; then
1611   found="-Wl,--dynamic-list"
1612   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1613 else
1614   found="-rdynamic"
1615   RDYNAMIC="-rdynamic"
1616 fi
1617 AC_SUBST(RDYNAMIC)
1618 AC_MSG_RESULT($found)
1619
1620 dnl For certain native configurations, we need to check whether thread
1621 dnl support can be built in or not.
1622 dnl
1623 dnl Note that we only want this if we are both native (host == target),
1624 dnl and not doing a canadian cross build (build == host).
1625
1626 if test ${build} = ${host} -a ${host} = ${target} ; then
1627    case ${host_os} in
1628    solaris*)
1629       # See if thread_db library is around for Solaris thread debugging.
1630       # Note that we must explicitly test for version 1 of the library
1631       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1632       # the same API.
1633       AC_MSG_CHECKING(for Solaris thread debugging library)
1634       if test -f /usr/lib/libthread_db.so.1 ; then
1635          AC_MSG_RESULT(yes)
1636          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1637          [Define if using Solaris thread debugging.])
1638          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1639          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1640          AC_CHECK_LIB(dl, dlopen)
1641          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1642          # Sun randomly tweaked the prototypes in <proc_service.h>
1643          # at one point.
1644          AC_MSG_CHECKING(if <proc_service.h> is old)
1645          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1646             AC_TRY_COMPILE([
1647                 #include <proc_service.h>
1648                 ps_err_e ps_pdwrite
1649                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1650             ],, gdb_cv_proc_service_is_old=no,
1651                 gdb_cv_proc_service_is_old=yes)
1652          ])
1653          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1654          if test $gdb_cv_proc_service_is_old = yes; then
1655             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1656             [Define if <proc_service.h> on solaris uses int instead of
1657              size_t, and assorted other type changes.])
1658          fi
1659       else
1660          AC_MSG_RESULT(no)
1661       fi
1662       ;;
1663    aix*)
1664       AC_MSG_CHECKING(for AiX thread debugging library)
1665       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1666                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1667                                    [#ifndef PTHDB_VERSION_3
1668                                     #error
1669                                     #endif],
1670                                    gdb_cv_have_aix_thread_debug=yes,
1671                                    gdb_cv_have_aix_thread_debug=no)])
1672       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1673       if test $gdb_cv_have_aix_thread_debug = yes; then
1674          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1675          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1676          LIBS="$LIBS -lpthdebug"
1677
1678          # Older versions of AIX do not provide the declaration for
1679          # the getthrds function (it appears that it was introduced
1680          # with AIX 6.x).
1681          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1682       fi
1683       ;;
1684    esac
1685    AC_SUBST(CONFIG_LDFLAGS)
1686 fi
1687
1688 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1689 dnl other error codes.
1690 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1691    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1692                   gdb_cv_thread_db_h_has_td_notalloc,
1693      AC_TRY_COMPILE(
1694        [#include <thread_db.h>],
1695        [int i = TD_NOTALLOC;],
1696        gdb_cv_thread_db_h_has_td_notalloc=yes,
1697        gdb_cv_thread_db_h_has_td_notalloc=no
1698      )
1699    )
1700    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1701                   gdb_cv_thread_db_h_has_td_version,
1702      AC_TRY_COMPILE(
1703        [#include <thread_db.h>],
1704        [int i = TD_VERSION;],
1705        gdb_cv_thread_db_h_has_td_version=yes,
1706        gdb_cv_thread_db_h_has_td_version=no
1707      )
1708    )
1709    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1710                   gdb_cv_thread_db_h_has_td_notls,
1711      AC_TRY_COMPILE(
1712        [#include <thread_db.h>],
1713        [int i = TD_NOTLS;],
1714        gdb_cv_thread_db_h_has_td_notls=yes,
1715        gdb_cv_thread_db_h_has_td_notls=no
1716      )
1717    )
1718 fi
1719 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1720   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1721             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1722 fi
1723 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1724   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1725             [Define if <thread_db.h> has the TD_VERSION error code.])
1726 fi
1727 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1728   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1729             [Define if <thread_db.h> has the TD_NOTLS error code.])
1730 fi
1731
1732 dnl See if we have a sys/syscall header file that has __NR_tkill.
1733 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1734    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1735                   gdb_cv_sys_syscall_h_has_tkill,
1736      AC_TRY_COMPILE(
1737        [#include <sys/syscall.h>],
1738        [int i = __NR_tkill;],
1739        gdb_cv_sys_syscall_h_has_tkill=yes,
1740        gdb_cv_sys_syscall_h_has_tkill=no
1741      )
1742    )
1743 fi
1744 dnl See if we can issue tkill syscall.
1745 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes"; then
1746   AC_CHECK_FUNC(syscall,
1747     AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1748   )
1749 fi
1750
1751 dnl Check if we can disable the virtual address space randomization.
1752 dnl The functionality of setarch -R.
1753 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1754 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1755 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1756 #       define ADDR_NO_RANDOMIZE 0x0040000
1757 #      endif
1758        /* Test the flag could be set and stays set.  */
1759        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1760        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1761            return 1])])
1762 AC_RUN_IFELSE([PERSONALITY_TEST],
1763               [have_personality=true],
1764               [have_personality=false],
1765               [AC_LINK_IFELSE([PERSONALITY_TEST],
1766                               [have_personality=true],
1767                               [have_personality=false])])
1768 if $have_personality
1769 then
1770     AC_DEFINE([HAVE_PERSONALITY], 1,
1771               [Define if you support the personality syscall.])
1772 fi
1773
1774 dnl Set the host's .gdbinit filename.
1775 case $host_os in
1776   go32* | *djgpp*)
1777     gdbinit=gdb.ini
1778     ;;
1779   *)
1780     gdbinit=.gdbinit
1781     ;;
1782 esac
1783 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1784
1785 dnl Handle optional features that can be enabled.
1786
1787 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1788 # except that the argument to --with-sysroot is optional.
1789 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1790 if test "x$with_sysroot" = xyes; then
1791   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1792 fi
1793 AC_ARG_WITH(sysroot,
1794   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1795                  [search for usr/lib et al within DIR]),
1796   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1797 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1798               [search for usr/lib et al within DIR])
1799 AC_SUBST(TARGET_SYSTEM_ROOT)
1800 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1801
1802 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1803     [automatically load a system-wide gdbinit file],
1804     [])
1805
1806 AC_ARG_ENABLE(werror,
1807   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
1808   [case "${enableval}" in
1809      yes | y) ERROR_ON_WARNING="yes" ;;
1810      no | n)  ERROR_ON_WARNING="no" ;;
1811      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1812    esac])
1813
1814 # Enable -Werror by default when using gcc.  Turn it off for releases.
1815 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" && $development; then
1816     ERROR_ON_WARNING=yes
1817 fi
1818
1819 WERROR_CFLAGS=""
1820 if test "${ERROR_ON_WARNING}" = yes ; then
1821     WERROR_CFLAGS="-Werror"
1822 fi
1823
1824 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1825 -Wpointer-sign \
1826 -Wno-unused -Wunused-value -Wunused-function \
1827 -Wno-switch -Wno-char-subscripts -Wmissing-prototypes \
1828 -Wdeclaration-after-statement -Wempty-body -Wmissing-parameter-type \
1829 -Wold-style-declaration -Wold-style-definition"
1830
1831 # Enable -Wno-format by default when using gcc on mingw since many
1832 # GCC versions complain about %I64.
1833 case "${host}" in
1834   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1835   *) build_warnings="$build_warnings -Wformat-nonliteral" ;;
1836 esac
1837
1838 AC_ARG_ENABLE(build-warnings,
1839 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
1840 [case "${enableval}" in
1841   yes)  ;;
1842   no)   build_warnings="-w";;
1843   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1844         build_warnings="${build_warnings} ${t}";;
1845   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1846         build_warnings="${t} ${build_warnings}";;
1847   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1848 esac
1849 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1850   echo "Setting compiler warning flags = $build_warnings" 6>&1
1851 fi])dnl
1852 AC_ARG_ENABLE(gdb-build-warnings,
1853 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
1854 [case "${enableval}" in
1855   yes)  ;;
1856   no)   build_warnings="-w";;
1857   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1858         build_warnings="${build_warnings} ${t}";;
1859   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1860         build_warnings="${t} ${build_warnings}";;
1861   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1862 esac
1863 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1864   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1865 fi])dnl
1866 WARN_CFLAGS=""
1867 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1868 then
1869     AC_MSG_CHECKING(compiler warning flags)
1870     # Separate out the -Werror flag as some files just cannot be
1871     # compiled with it enabled.
1872     for w in ${build_warnings}; do
1873         case $w in
1874         -Werr*) WERROR_CFLAGS=-Werror ;;
1875         *) # Check that GCC accepts it
1876             saved_CFLAGS="$CFLAGS"
1877             CFLAGS="$CFLAGS $w"
1878             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1879             CFLAGS="$saved_CFLAGS"
1880         esac
1881     done
1882     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1883 fi
1884 AC_SUBST(WARN_CFLAGS)
1885 AC_SUBST(WERROR_CFLAGS)
1886
1887 # In the Cygwin environment, we need some additional flags.
1888 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1889 [AC_EGREP_CPP(^lose$, [
1890 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1891 lose
1892 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1893
1894
1895 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1896 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1897 case ${host} in
1898   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1899   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1900   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1901 esac
1902 AC_SUBST(SER_HARDWIRE)
1903
1904 # libreadline needs libuser32.a in a cygwin environment
1905 WIN32LIBS=
1906 if test x$gdb_cv_os_cygwin = xyes; then
1907     WIN32LIBS="-luser32"
1908     case "${target}" in
1909         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1910         ;;
1911     esac
1912 fi
1913
1914 # The ser-tcp.c module requires sockets.
1915 case ${host} in
1916   *mingw32*)
1917     AC_DEFINE(USE_WIN32API, 1,
1918               [Define if we should use the Windows API, instead of the
1919                POSIX API.  On Windows, we use the Windows API when
1920                building for MinGW, but the POSIX API when building
1921                for Cygwin.])
1922     WIN32LIBS="$WIN32LIBS -lws2_32"
1923     ;;
1924 esac
1925 AC_SUBST(WIN32LIBS)
1926
1927 # Add ELF support to GDB, but only if BFD includes ELF support.
1928 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
1929                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
1930 if test $gdb_cv_var_elf = yes; then
1931   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o"
1932   AC_DEFINE(HAVE_ELF, 1,
1933             [Define if ELF support should be included.])
1934   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1935   if test "$plugins" = "yes"; then
1936     AC_SEARCH_LIBS(dlopen, dl)
1937   fi
1938 fi
1939
1940 # Add macho support to GDB, but only if BFD includes it.
1941 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
1942                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
1943 if test $gdb_cv_var_macho = yes; then
1944   CONFIG_OBS="$CONFIG_OBS machoread.o"
1945 fi
1946
1947 # Add SOM support to GDB, but only if BFD includes it.
1948 GDB_AC_CHECK_BFD([for SOM support in BFD], gdb_cv_var_som,
1949                  [bfd_som_attach_aux_hdr (NULL, 0, NULL)], som.h)
1950 if test $gdb_cv_var_som = yes; then
1951   CONFIG_OBS="$CONFIG_OBS somread.o"
1952 fi
1953
1954 # Add any host-specific objects to GDB.
1955 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1956
1957 # If building on ELF, look for lzma support for embedded compressed debug info.
1958 if test $gdb_cv_var_elf = yes; then
1959   AC_ARG_WITH(lzma,
1960     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
1961     [], [with_lzma=auto])
1962   AC_MSG_CHECKING([whether to use lzma])
1963   AC_MSG_RESULT([$with_lzma])
1964
1965   if test "${with_lzma}" != no; then
1966     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
1967                           [lzma_index_iter iter;
1968                            lzma_index_iter_init (&iter, 0);
1969                            lzma_mf_is_supported (LZMA_MF_HC3);])
1970     if test "$HAVE_LIBLZMA" != yes; then
1971       if test "$with_lzma" = yes; then
1972         AC_MSG_ERROR([missing liblzma for --with-lzma])
1973       fi
1974     fi
1975   fi
1976 fi
1977
1978 LIBGUI="../libgui/src/libgui.a"
1979 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1980 AC_SUBST(LIBGUI)
1981 AC_SUBST(GUI_CFLAGS_X)
1982
1983 WIN32LDAPP=
1984 AC_SUBST(WIN32LIBS)
1985 AC_SUBST(WIN32LDAPP)
1986
1987 case "${host}" in
1988 *-*-cygwin* | *-*-mingw* )
1989     configdir="win"
1990     ;;
1991 *)
1992     configdir="unix"
1993     ;;
1994 esac
1995
1996 GDBTKLIBS=
1997 if test "${enable_gdbtk}" = "yes"; then
1998
1999     # Gdbtk must have an absolute path to srcdir in order to run
2000     # properly when not installed.
2001     here=`pwd`
2002     cd ${srcdir}
2003     GDBTK_SRC_DIR=`pwd`
2004     cd $here
2005
2006     SC_PATH_TCLCONFIG
2007
2008     # If $no_tk is nonempty, then we can't do Tk, and there is no
2009     # point to doing Tcl.
2010     SC_PATH_TKCONFIG
2011
2012     if test -z "${no_tcl}" -a -z "${no_tk}"; then
2013         SC_LOAD_TCLCONFIG
2014
2015         # Check for in-tree tcl
2016         here=`pwd`
2017         cd ${srcdir}/..
2018         topdir=`pwd`
2019         cd ${here}
2020
2021         intree="no"
2022         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
2023           intree="yes"
2024         fi
2025
2026         # Find Tcl private headers
2027         if test x"${intree}" = xno; then
2028           CY_AC_TCL_PRIVATE_HEADERS
2029           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
2030           TCL_LIBRARY="${TCL_LIB_SPEC}"
2031           TCL_DEPS=""
2032         else
2033           # If building tcl in the same src tree, private headers
2034           # are not needed, but we need to be sure to use the right
2035           # headers library
2036           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2037           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2038           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2039         fi
2040         AC_SUBST(TCL_INCLUDE)
2041         AC_SUBST(TCL_LIBRARY)
2042         AC_SUBST(TCL_DEPS)
2043
2044         SC_LOAD_TKCONFIG
2045
2046         # Check for in-tree Tk
2047         intree="no"
2048         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2049           intree="yes"
2050         fi
2051
2052         # Find Tk private headers
2053         if test x"${intree}" = xno; then
2054           CY_AC_TK_PRIVATE_HEADERS
2055           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2056           TK_LIBRARY=${TK_LIB_SPEC}
2057           TK_DEPS=""
2058         else
2059           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2060           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2061           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2062         fi
2063         AC_SUBST(TK_INCLUDE)
2064         AC_SUBST(TK_LIBRARY)
2065         AC_SUBST(TK_DEPS)
2066         AC_SUBST(TK_XINCLUDES)
2067
2068         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2069
2070         # Include some libraries that Tcl and Tk want.
2071         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2072         # Yes, the ordering seems wrong here.  But it isn't.
2073         # TK_LIBS is the list of libraries that need to be linked
2074         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2075         # were in LIBS then any link tests after this point would
2076         # try to include things like `$(LIBGUI)', which wouldn't work.
2077         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2078
2079         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2080         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2081         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2082         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2083         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2084         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2085         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2086
2087         if test x$gdb_cv_os_cygwin = xyes; then
2088           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2089           WIN32LDAPP="-Wl,--subsystem,console"
2090           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2091         fi
2092
2093         AC_CONFIG_SUBDIRS(gdbtk)
2094     fi
2095 fi
2096
2097 AC_SUBST(X_CFLAGS)
2098 AC_SUBST(X_LDFLAGS)
2099 AC_SUBST(X_LIBS)
2100 AC_SUBST(GDBTKLIBS)
2101 AC_SUBST(GDBTK_CFLAGS)
2102 AC_SUBST(GDBTK_SRC_DIR)
2103
2104 AC_PATH_X
2105
2106 # Unlike the sim directory, whether a simulator is linked is controlled by
2107 # presence of a gdb_sim definition in the target configure.tgt entry.
2108 # This code just checks for a few cases where we'd like to ignore those
2109 # definitions, even when they're present in the '.mt' file.  These cases
2110 # are when --disable-sim is specified, or if the simulator directory is
2111 # not part of the source tree.
2112 #
2113 AC_ARG_ENABLE(sim,
2114 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2115 [echo "enable_sim = $enable_sim";
2116  echo "enableval = ${enableval}";
2117  case "${enableval}" in
2118   yes) ignore_sim=false ;;
2119   no)  ignore_sim=true ;;
2120   *)   ignore_sim=false ;;
2121  esac],
2122 [ignore_sim=false])
2123
2124 if test ! -d "${srcdir}/../sim"; then
2125   ignore_sim=true
2126 fi
2127
2128 SIM=
2129 SIM_OBS=
2130 if test "${ignore_sim}" = "false"; then
2131   if test x"${gdb_sim}" != x ; then
2132     SIM="${gdb_sim}"
2133     SIM_OBS="remote-sim.o"
2134     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2135   fi
2136 fi
2137 AC_SUBST(SIM)
2138 AC_SUBST(SIM_OBS)
2139
2140 AC_SUBST(ENABLE_CFLAGS)
2141 AC_SUBST(PROFILE_CFLAGS)
2142
2143 AC_SUBST(CONFIG_OBS)
2144 AC_SUBST(CONFIG_DEPS)
2145 AC_SUBST(CONFIG_SRCS)
2146 AC_SUBST(CONFIG_ALL)
2147 AC_SUBST(CONFIG_CLEAN)
2148 AC_SUBST(CONFIG_INSTALL)
2149 AC_SUBST(CONFIG_UNINSTALL)
2150
2151 # List of host floatformats.
2152 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2153 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2154 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2155
2156 # target_subdir is used by the testsuite to find the target libraries.
2157 target_subdir=
2158 if test "${host}" != "${target}"; then
2159     target_subdir="${target_alias}/"
2160 fi
2161 AC_SUBST(target_subdir)
2162
2163 frags=
2164 if test "${gdb_native}" = "yes"; then
2165   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
2166   if test ! -f ${host_makefile_frag}; then
2167     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
2168   fi
2169   frags="$frags $host_makefile_frag"
2170 else
2171   host_makefile_frag=/dev/null
2172 fi
2173
2174 AC_SUBST_FILE(host_makefile_frag)
2175 AC_SUBST(frags)
2176
2177 changequote(,)dnl
2178 if test "${gdb_native}" = "yes"; then
2179 # We pick this up from the host configuration file (.mh) because we
2180 # do not have a native configuration Makefile fragment.
2181 nativefile=`sed -n '
2182 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
2183 ' ${host_makefile_frag}`
2184 fi
2185 changequote([,])
2186
2187 if test x"${gdb_osabi}" != x ; then
2188     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2189                        [Define to the default OS ABI for this configuration.])
2190 fi
2191
2192 # Enable multi-ice-gdb-server.
2193 AC_ARG_ENABLE(multi-ice,
2194 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2195   [case $enableval in
2196     yes | no)
2197       ;;
2198     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2199   esac])
2200 if test "x$enable_multi_ice" = xyes; then
2201    AC_CONFIG_SUBDIRS(multi-ice)
2202 fi
2203
2204 AC_ARG_ENABLE(gdbserver,
2205 AS_HELP_STRING([--enable-gdbserver],
2206                [automatically build gdbserver (yes/no/auto, default is auto)]),
2207 [case "${enableval}" in
2208   yes| no|auto) ;;
2209   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2210 esac],[enable_gdbserver=auto])
2211
2212 # We only build gdbserver automatically in a native configuration, and
2213 # only if the user did not explicitly disable its build.
2214 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2215   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2216   if test "x$build_gdbserver" = xyes; then
2217     AC_MSG_RESULT(yes)
2218     AC_CONFIG_SUBDIRS(gdbserver)
2219     gdbserver_build_enabled=yes
2220   else
2221     AC_MSG_RESULT(no)
2222   fi
2223 fi
2224
2225 # If the user explicitly request the gdbserver to be built, verify that
2226 # we were in fact able to enable it.
2227 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2228   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2229 fi
2230
2231 # Check for babeltrace and babeltrace-ctf
2232 AC_ARG_WITH(babeltrace,
2233   AC_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2234   [], [with_babeltrace=auto])
2235 AC_MSG_CHECKING([whether to use babeltrace])
2236 AC_MSG_RESULT([$with_babeltrace])
2237
2238 if test "x$with_babeltrace" = "xno"; then
2239   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2240 else
2241   # Append -Werror to CFLAGS so that configure can catch the warning
2242   # "assignment from incompatible pointer type", which is related to
2243   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2244   # in GDB, while babeltrace 1.0.3 is broken.
2245   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2246   # safe to save and restore CFLAGS here.
2247   saved_CFLAGS=$CFLAGS
2248   CFLAGS="$CFLAGS -Werror"
2249   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2250                         [#include <babeltrace/babeltrace.h>
2251                          #include <babeltrace/ctf/events.h>
2252                          #include <babeltrace/ctf/iterator.h>],
2253                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2254                         struct bt_ctf_event *event = NULL;
2255                         const struct bt_definition *scope;
2256
2257                         scope = bt_ctf_get_top_level_scope (event,
2258                                                            BT_STREAM_EVENT_HEADER);
2259                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2260                         ])
2261   CFLAGS=$saved_CFLAGS
2262
2263   if test "$HAVE_LIBBABELTRACE" != yes; then
2264      if test "$with_babeltrace" = yes; then
2265        AC_MSG_ERROR([babeltrace is missing or unusable])
2266      else
2267        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2268      fi
2269   fi
2270 fi
2271
2272 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2273 # to an empty version.
2274
2275 files=
2276 links=
2277
2278 rm -f nm.h
2279 if test "${nativefile}" != ""; then
2280     case "${nativefile}" in
2281       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2282       * ) GDB_NM_FILE="${nativefile}"
2283     esac
2284     files="${files} ${GDB_NM_FILE}"
2285     links="${links} nm.h"
2286     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2287 fi
2288 AC_SUBST(GDB_NM_FILE)
2289
2290 AC_LINK_FILES($files, $links)
2291
2292 dnl Check for exe extension set on certain hosts (e.g. Win32)
2293 AC_EXEEXT
2294
2295 dnl  Detect the character set used by this host.
2296 dnl  At the moment, we just assume it's UTF-8.
2297 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2298           [Define to be a string naming the default host character set.])
2299
2300 # Undo the $ec_script escaping suitable for Makefile.
2301 transform=`echo "$program_transform_name" | sed -e 's/[\\$][\\$]/\\$/g'`
2302 GDB_TRANSFORM_NAME=`echo gdb | sed -e "$transform"`
2303 if test "x$GDB_TRANSFORM_NAME" = x; then
2304   GDB_TRANSFORM_NAME=gdb
2305 fi
2306 AC_SUBST(GDB_TRANSFORM_NAME)
2307 GCORE_TRANSFORM_NAME=`echo gcore | sed -e "$transform"`
2308 if test "x$GCORE_TRANSFORM_NAME" = x; then
2309   GCORE_TRANSFORM_NAME=gcore
2310 fi
2311 AC_SUBST(GCORE_TRANSFORM_NAME)
2312 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2313
2314 AC_OUTPUT(Makefile gdb-gdb.gdb doc/Makefile data-directory/Makefile,
2315 [
2316 case x$CONFIG_HEADERS in
2317 xconfig.h:config.in)
2318 echo > stamp-h ;;
2319 esac
2320 ])
2321
2322 exit 0