gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2020 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 m4_include(../config/debuginfod.m4)
  22
  23 AC_INIT
  24 AC_CONFIG_SRCDIR([main.c])
  25 AC_CONFIG_HEADERS(config.h:config.in, [echo > stamp-h])
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_PROG_CXX
  30
  31 AC_USE_SYSTEM_EXTENSIONS
  32 ACX_LARGEFILE
  33 AM_PROG_INSTALL_STRIP
  34
  35 AC_CONFIG_AUX_DIR(..)
  36
  37 # Set build, build_cpu, build_vendor and build_os.
  38 AC_CANONICAL_BUILD
  39
  40 # Set host, host_cpu, host_vendor, and host_os.
  41 AC_CANONICAL_HOST
  42
  43 # Set target, target_cpu, target_vendor, and target_os.
  44 AC_CANONICAL_TARGET
  45
  46 AC_ARG_PROGRAM
  47
  48 # We require a C++11 compiler.  Check if one is available, and if
  49 # necessary, set CXX_DIALECT to some -std=xxx switch.
  50 AX_CXX_COMPILE_STDCXX(11, , mandatory)
  51
  52 # Dependency checking.
  53 ZW_CREATE_DEPDIR
  54 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  55
  56 dnl List of object files and targets accumulated by configure.
  57
  58 CONFIG_OBS=
  59 CONFIG_DEPS=
  60 CONFIG_SRCS=
  61 ENABLE_CFLAGS=
  62
  63 CONFIG_ALL=
  64 CONFIG_CLEAN=
  65 CONFIG_INSTALL=
  66 CONFIG_UNINSTALL=
  67
  68 dnl Set up for gettext.
  69 ZW_GNU_GETTEXT_SISTER_DIR
  70
  71 localedir='${datadir}/locale'
  72 AC_SUBST(localedir)
  73
  74 if test x"$USE_NLS" = xyes; then
  75    CONFIG_ALL="$CONFIG_ALL all-po"
  76    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  77    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  78    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  79 fi
  80
  81 PACKAGE=gdb
  82 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  83 AC_SUBST(PACKAGE)
  84
  85 # We never need to detect it in this sub-configure.
  86 # But preserve it for config.status --recheck.
  87 AC_ARG_VAR(MAKEINFO,
  88   [Parent configure detects if it is of sufficient version.])
  89 AC_ARG_VAR(MAKEINFOFLAGS,
  90   [Parameters for MAKEINFO.])
  91
  92 MAKEINFO_EXTRA_FLAGS=""
  93 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
  94   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
  95   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
  96     gdb_cv_have_makeinfo_click=yes
  97   else
  98     gdb_cv_have_makeinfo_click=no
  99   fi])
 100 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 101   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 102 fi
 103 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 104
 105 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 106     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 107     [${libdir}/debug])
 108
 109 # We can't pass paths as command line arguments.
 110 # Mingw32 tries to be clever and will convert the paths for us.
 111 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 112 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 113 # This breaks GDB's relocatable path conversions since paths passed in
 114 # config.h would not get so translated, the path prefixes no longer match.
 115 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 116
 117 # GDB's datadir relocation
 118
 119 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 120     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 121     [${datadir}/gdb])
 122
 123 AC_ARG_WITH(relocated-sources,
 124 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 125 [reloc_srcdir="${withval}"
 126  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 127               [Relocated directory for source files. ])
 128 ])
 129
 130 AC_MSG_CHECKING([for default auto-load directory])
 131 AC_ARG_WITH(auto-load-dir,
 132 AS_HELP_STRING([--with-auto-load-dir=PATH],
 133   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 134   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 135 escape_dir=`echo $with_auto_load_dir | sed -e 's/[[$]]datadir\>/\\\\\\\\\\\\&/g' -e 's/[[$]]debugdir\>/\\\\\\\\\\\\&/g'`
 136 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 137               [Directories from which to load auto-loaded scripts.])
 138 AC_MSG_RESULT([$with_auto_load_dir])
 139
 140 AC_MSG_CHECKING([for default auto-load safe-path])
 141 AC_ARG_WITH(auto-load-safe-path,
 142 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 143   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 144 AS_HELP_STRING([--without-auto-load-safe-path],
 145                [do not restrict auto-loaded files locations]),
 146     [if test "$with_auto_load_safe_path" = "no"; then
 147      with_auto_load_safe_path="/"
 148      fi],
 149 [with_auto_load_safe_path="$with_auto_load_dir"])
 150 escape_dir=`echo $with_auto_load_safe_path | sed -e 's/[[$]]datadir\>/\\\\\\\\\\\\&/g' -e 's/[[$]]debugdir\>/\\\\\\\\\\\\&/g'`
 151 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 152               [Directories safe to hold auto-loaded files.])
 153 AC_MSG_RESULT([$with_auto_load_safe_path])
 154
 155 AC_CONFIG_SUBDIRS(testsuite)
 156
 157 # Check whether to support alternative target configurations
 158 AC_ARG_ENABLE(targets,
 159 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 160 [case "${enableval}" in
 161   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
 162             ;;
 163   no)       enable_targets= ;;
 164   *)        enable_targets=$enableval ;;
 165 esac])
 166
 167 # Check whether to enable 64-bit support on 32-bit hosts
 168 AC_ARG_ENABLE(64-bit-bfd,
 169 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 170 [case "${enableval}" in
 171   yes)  want64=true  ;;
 172   no)   want64=false ;;
 173   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 174 esac],[want64=false])dnl
 175
 176 # Provide defaults for some variables set by the per-host and per-target
 177 # configuration.
 178 gdb_host_obs=posix-hdep.o
 179
 180 if test "${target}" = "${host}"; then
 181   gdb_native=yes
 182 else
 183   gdb_native=no
 184 fi
 185
 186 . $srcdir/configure.host
 187
 188 # Accumulate some settings from configure.tgt over all enabled targets
 189
 190 TARGET_OBS=
 191 all_targets=
 192 HAVE_NATIVE_GCORE_TARGET=
 193
 194 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 195 do
 196   if test "$targ_alias" = "all"; then
 197     all_targets=true
 198   else
 199     # Canonicalize the secondary target names.
 200     result=`$ac_config_sub $targ_alias 2>/dev/null`
 201     if test -n "$result"; then
 202         targ=$result
 203     else
 204         targ=$targ_alias
 205     fi
 206
 207     . ${srcdir}/configure.tgt
 208
 209     AS_IF([test -z "${gdb_target_obs}"],
 210       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 211
 212     # Target-specific object files
 213     for i in ${gdb_target_obs}; do
 214         case " $TARGET_OBS " in
 215         *" ${i} "*) ;;
 216         *)
 217           TARGET_OBS="$TARGET_OBS ${i}"
 218           ;;
 219         esac
 220     done
 221
 222     # Check whether this target needs 64-bit CORE_ADDR
 223     if test x${want64} = xfalse; then
 224       . ${srcdir}/../bfd/config.bfd
 225     fi
 226
 227     # Check whether this target is native and supports gcore.
 228     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 229        && $gdb_have_gcore; then
 230       HAVE_NATIVE_GCORE_TARGET=1
 231     fi
 232   fi
 233 done
 234
 235 if test x${all_targets} = xtrue; then
 236
 237   # We want all 64-bit targets if we either:
 238   #  - run on a 64-bit host  or
 239   #  - already require 64-bit support for some other target  or
 240   #  - the --enable-64-bit-bfd option was supplied
 241   # Otherwise we only support all 32-bit targets.
 242   #
 243   # NOTE: This test must be in sync with the corresponding
 244   #       tests in BFD!
 245
 246   if test x${want64} = xfalse; then
 247     AC_CHECK_SIZEOF(long)
 248     if test "x${ac_cv_sizeof_long}" = "x8"; then
 249       want64=true
 250     fi
 251   fi
 252   if test x${want64} = xtrue; then
 253     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 254   else
 255     TARGET_OBS='$(ALL_TARGET_OBS)'
 256   fi
 257 fi
 258
 259 AC_SUBST(TARGET_OBS)
 260 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 261
 262 # For other settings, only the main target counts.
 263 gdb_sim=
 264 gdb_osabi=
 265 targ=$target; . ${srcdir}/configure.tgt
 266
 267 # Fetch the default architecture and default target vector from BFD.
 268 targ=$target; . $srcdir/../bfd/config.bfd
 269
 270 # We only want the first architecture, so strip off the others if
 271 # there is more than one.
 272 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 273
 274 if test "x$targ_archs" != x; then
 275   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 276     [Define to BFD's default architecture. ])
 277 fi
 278 if test "x$targ_defvec" != x; then
 279   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 280     [Define to BFD's default target vector. ])
 281 fi
 282
 283 # Enable MI.
 284 AC_ARG_ENABLE(gdbmi,
 285 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 286   [case $enableval in
 287     yes | no)
 288       ;;
 289     *)
 290       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 291   esac],
 292   [enable_gdbmi=yes])
 293 if test x"$enable_gdbmi" = xyes; then
 294   if test -d "$srcdir/mi"; then
 295     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 296     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 297     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 298     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 299   fi
 300 fi
 301
 302 # Enable TUI.
 303 AC_ARG_ENABLE(tui,
 304 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 305   [case $enableval in
 306     yes | no | auto)
 307       ;;
 308     *)
 309       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 310   esac],enable_tui=auto)
 311
 312 # Enable gdbtk.
 313 AC_ARG_ENABLE(gdbtk,
 314 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 315   [case $enableval in
 316     yes | no)
 317       ;;
 318     *)
 319       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 320   esac],
 321   [if test -d "$srcdir/gdbtk"; then
 322     enable_gdbtk=yes
 323   else
 324     enable_gdbtk=no
 325   fi])
 326 # We unconditionally disable gdbtk tests on selected platforms.
 327 case $host_os in
 328   go32* | windows*)
 329     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 330     enable_gdbtk=no ;;
 331 esac
 332
 333 # Handle optional debuginfod support
 334 AC_DEBUGINFOD
 335
 336 # Libunwind support for ia64.
 337 AC_ARG_WITH(libunwind-ia64,
 338 AS_HELP_STRING([--with-libunwind-ia64],
 339                [use libunwind frame unwinding for ia64 targets]),,
 340             [with_libunwind_ia64=auto])
 341
 342 # Backward compatibility option.
 343 if test "${with_libunwind+set}" = set; then
 344   if test x"$with_libunwind_ia64" != xauto; then
 345     AC_MSG_ERROR(
 346       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 347   fi
 348   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 349   with_libunwind_ia64="$with_libunwind"
 350 fi
 351
 352 case "$with_libunwind_ia64" in
 353   yes | no)
 354     ;;
 355   auto)
 356     AC_CHECK_HEADERS(libunwind-ia64.h)
 357     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 358     ;;
 359   *)
 360     AC_MSG_ERROR(
 361       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 362     ;;
 363 esac
 364
 365 if test x"$with_libunwind_ia64" = xyes; then
 366   AC_CHECK_HEADERS(libunwind-ia64.h)
 367   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 368     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 369   fi
 370   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 371   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 372   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 373 fi
 374
 375 opt_curses=no
 376 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 377
 378 prefer_curses=no
 379 if test "$opt_curses" = "yes"; then
 380   prefer_curses=yes
 381 fi
 382
 383 # Profiling support.
 384 AC_ARG_ENABLE(profiling,
 385 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 386   [case $enableval in
 387     yes | no)
 388       ;;
 389     *)
 390       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 391   esac],
 392  [enable_profiling=no])
 393
 394 AC_CHECK_FUNCS(monstartup _mcleanup)
 395 AC_CACHE_CHECK(
 396   [for _etext],
 397   [ac_cv_var__etext],
 398   [AC_LINK_IFELSE(
 399      [AC_LANG_PROGRAM(
 400         [#include <stdlib.h>
 401          extern char _etext;],
 402         [free (&_etext);]
 403       )],
 404      [ac_cv_var__etext=yes],
 405      [ac_cv_var__etext=no]
 406    )]
 407 )
 408 if test "$ac_cv_var__etext" = yes; then
 409   AC_DEFINE(HAVE__ETEXT, 1,
 410             [Define to 1 if your system has the _etext variable. ])
 411 fi
 412 AC_CACHE_CHECK(
 413   [for etext],
 414   [ac_cv_var_etext],
 415   [AC_LINK_IFELSE(
 416      [AC_LANG_PROGRAM(
 417         [#include <stdlib.h>
 418          extern char etext;],
 419         [free (&etext);]
 420       )],
 421      [ac_cv_var_etext=yes],
 422      [ac_cv_var_etext=no]
 423    )]
 424 )
 425 if test "$ac_cv_var_etext" = yes; then
 426   AC_DEFINE(HAVE_ETEXT, 1,
 427             [Define to 1 if your system has the etext variable. ])
 428 fi
 429 if test "$enable_profiling" = yes ; then
 430   if test "$ac_cv_func_monstartup" = no || test "$ac_cv_func__mcleanup" = no; then
 431     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 432   fi
 433   PROFILE_CFLAGS=-pg
 434   OLD_CFLAGS="$CFLAGS"
 435   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 436
 437   AC_CACHE_CHECK(
 438     [whether $CC supports -pg],
 439     [ac_cv_cc_supports_pg],
 440     [AC_COMPILE_IFELSE(
 441        [AC_LANG_PROGRAM([], [int x;])],
 442        [ac_cv_cc_supports_pg=yes],
 443        [ac_cv_cc_supports_pg=no]
 444      )]
 445   )
 446
 447   if test "$ac_cv_cc_supports_pg" = no; then
 448     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 449   fi
 450
 451   CFLAGS="$OLD_CFLAGS"
 452 fi
 453
 454 CODESIGN_CERT=
 455 AC_ARG_ENABLE([codesign],
 456   AS_HELP_STRING([--enable-codesign=CERT],
 457                  [sign gdb with 'codesign -s CERT']),
 458   [CODESIGN_CERT=$enableval])
 459 AC_SUBST([CODESIGN_CERT])
 460
 461 ACX_PKGVERSION([GDB])
 462 ACX_BUGURL([https://www.gnu.org/software/gdb/bugs/])
 463 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 464 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 465
 466 # --------------------- #
 467 # Checks for programs.  #
 468 # --------------------- #
 469
 470 AC_PROG_AWK
 471 AC_PROG_INSTALL
 472 AC_PROG_LN_S
 473 AC_PROG_RANLIB
 474 AC_PROG_YACC
 475
 476 AC_CHECK_TOOL(AR, ar)
 477 AC_CHECK_TOOL(DLLTOOL, dlltool)
 478 AC_CHECK_TOOL(WINDRES, windres)
 479
 480 case $host_os in
 481   gnu*)
 482     # Needed for GNU Hurd hosts.
 483     AC_CHECK_TOOL(MIG, mig)
 484     if test x"$MIG" = x; then
 485       AC_MSG_ERROR([MIG not found but required for $host hosts])
 486     fi
 487     ;;
 488 esac
 489
 490 # ---------------------- #
 491 # Checks for libraries.  #
 492 # ---------------------- #
 493
 494 # We might need to link with -lm; most simulators need it.
 495 AC_CHECK_LIB(m, main)
 496
 497 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 498 AC_SEARCH_LIBS(gethostbyname, nsl)
 499
 500 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 501 AC_SEARCH_LIBS(socketpair, socket)
 502
 503 # Link in zlib if we can.  This allows us to read compressed debug sections.
 504 AM_ZLIB
 505
 506 AM_ICONV
 507
 508 # GDB may fork/exec the iconv program to get the list of supported character
 509 # sets.  Allow the user to specify where to find it.
 510 # There are several factors affecting the choice of option name:
 511 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 512 #   the build-time location of libiconv files.
 513 # - The program we need to find is iconv, which comes with glibc.  The user
 514 #   doesn't necessarily have libiconv installed.  Therefore naming this
 515 #   --with-libiconv-foo feels wrong.
 516 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 517 #   defined to work on directories not files (though it really doesn't know
 518 #   the difference).
 519 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 520 #   with --with-libiconv-prefix.
 521 # Putting these together is why the option name is --with-iconv-bin.
 522
 523 AC_ARG_WITH(iconv-bin,
 524 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 525 [iconv_bin="${withval}"
 526  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 527                     [Path of directory of iconv program.])
 528  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 529 ])
 530
 531 # For the TUI, we need enhanced curses functionality.
 532 if test x"$enable_tui" != xno; then
 533   prefer_curses=yes
 534 fi
 535
 536 curses_found=no
 537 if test x"$prefer_curses" = xyes; then
 538   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 539   # curses library because the latter might not provide all the
 540   # functionality we need.  However, this leads to problems on systems
 541   # where the linker searches /usr/local/lib, but the compiler doesn't
 542   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 543   # default installation of ncurses on alpha*-dec-osf* will lead to such
 544   # a situation.
 545   AC_SEARCH_LIBS(waddstr, [ncursesw ncurses cursesX curses])
 546
 547   if test "$ac_cv_search_waddstr" != no; then
 548     curses_found=yes
 549   fi
 550 fi
 551
 552 # Check whether we should enable the TUI, but only do so if we really
 553 # can.
 554 if test x"$enable_tui" != xno; then
 555   if test -d "$srcdir/tui"; then
 556     if test "$curses_found" != no; then
 557       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 558       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 559       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 560       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 561     else
 562       if test x"$enable_tui" = xyes; then
 563         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 564       else
 565         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 566       fi
 567     fi
 568   fi
 569 fi
 570
 571 # Since GDB uses Readline, we need termcap functionality.  In many
 572 # cases this will be provided by the curses library, but some systems
 573 # have a separate termcap library, or no curses library at all.
 574
 575 case $host_os in
 576   cygwin*)
 577     if test -d "$srcdir/libtermcap"; then
 578       LIBS="../libtermcap/libtermcap.a $LIBS"
 579       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 580     fi ;;
 581   go32* | *djgpp*)
 582     ac_cv_search_tgetent="none required"
 583     ;;
 584 esac
 585
 586 # These are the libraries checked by Readline.
 587 AC_SEARCH_LIBS(tgetent, [termcap tinfow tinfo curses ncursesw ncurses])
 588
 589 if test "$ac_cv_search_tgetent" = no; then
 590   CONFIG_OBS="$CONFIG_OBS stub-termcap.o"
 591 fi
 592
 593 AC_ARG_WITH([system-readline],
 594   [AS_HELP_STRING([--with-system-readline],
 595                   [use installed readline library])])
 596
 597 if test "$with_system_readline" = yes; then
 598   AC_CACHE_CHECK(
 599     [whether system readline is new enough],
 600     [gdb_cv_readline_ok],
 601     [AC_COMPILE_IFELSE(
 602        [AC_LANG_PROGRAM(
 603           [#include <stdio.h>
 604            #include <readline/readline.h>],
 605           [#if RL_VERSION_MAJOR < 7
 606            # error "readline version 7 required"
 607            #endif]
 608         )],
 609        [gdb_cv_readline_ok=yes],
 610        [gdb_cv_readline_ok=no]
 611      )]
 612   )
 613   if test "$gdb_cv_readline_ok" != yes; then
 614     AC_MSG_ERROR([system readline is not new enough])
 615   fi
 616
 617   READLINE=-lreadline
 618   READLINE_DEPS=
 619   READLINE_CFLAGS=
 620   READLINE_TEXI_INCFLAG=
 621 else
 622   READLINE='$(READLINE_DIR)/libreadline.a'
 623   READLINE_DEPS='$(READLINE)'
 624   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 625   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 626 fi
 627 AC_SUBST(READLINE)
 628 AC_SUBST(READLINE_DEPS)
 629 AC_SUBST(READLINE_CFLAGS)
 630 AC_SUBST(READLINE_TEXI_INCFLAG)
 631
 632 # Generate jit-reader.h
 633
 634 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 635 TARGET_PTR=
 636
 637 AC_CHECK_SIZEOF(unsigned long long)
 638 AC_CHECK_SIZEOF(unsigned long)
 639 AC_CHECK_SIZEOF(unsigned __int128)
 640
 641 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 642   TARGET_PTR="unsigned long"
 643 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 644   TARGET_PTR="unsigned long long"
 645 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 646   TARGET_PTR="unsigned __int128"
 647 else
 648   TARGET_PTR="unsigned long"
 649 fi
 650
 651 AC_SUBST(TARGET_PTR)
 652 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 653
 654 AC_SEARCH_LIBS(dlopen, dl)
 655
 656 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 657                 [directory to load the JIT readers from],
 658                 [${libdir}/gdb])
 659
 660 AC_ARG_WITH(expat,
 661   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 662   [], [with_expat=auto])
 663 AC_MSG_CHECKING([whether to use expat])
 664 AC_MSG_RESULT([$with_expat])
 665
 666 if test "${with_expat}" = no; then
 667   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 668   HAVE_LIBEXPAT=no
 669 else
 670   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 671                         [XML_Parser p = XML_ParserCreate (0);])
 672   if test "$HAVE_LIBEXPAT" != yes; then
 673     if test "$with_expat" = yes; then
 674       AC_MSG_ERROR([expat is missing or unusable])
 675     else
 676       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 677     fi
 678   else
 679     save_LIBS=$LIBS
 680     LIBS="$LIBS $LIBEXPAT"
 681     AC_CHECK_FUNCS(XML_StopParser)
 682     LIBS=$save_LIBS
 683   fi
 684 fi
 685
 686 AC_ARG_WITH(mpfr,
 687   AS_HELP_STRING([--with-mpfr], [include MPFR support (auto/yes/no)]),
 688   [], [with_mpfr=auto])
 689 AC_MSG_CHECKING([whether to use MPFR])
 690 AC_MSG_RESULT([$with_mpfr])
 691
 692 if test "${with_mpfr}" = no; then
 693   AC_MSG_WARN([MPFR support disabled; some features may be unavailable.])
 694   HAVE_LIBMPFR=no
 695 else
 696   AC_LIB_HAVE_LINKFLAGS([mpfr], [gmp], [#include <mpfr.h>],
 697                         [mpfr_exp_t exp; mpfr_t x;
 698                          mpfr_frexp (&exp, x, x, MPFR_RNDN);])
 699   if test "$HAVE_LIBMPFR" != yes; then
 700     if test "$with_mpfr" = yes; then
 701       AC_MSG_ERROR([MPFR is missing or unusable])
 702     else
 703       AC_MSG_WARN([MPFR is missing or unusable; some features may be unavailable.])
 704     fi
 705   fi
 706 fi
 707
 708 # --------------------- #
 709 # Check for libpython.  #
 710 # --------------------- #
 711
 712 dnl Utility to simplify finding libpython.
 713 dnl $1 = the shell variable to assign the result to
 714 dnl      If libpython is found we store $version here.
 715 dnl $2 = additional flags to add to CPPFLAGS
 716 dnl $3 = additional flags to add to LIBS
 717
 718 AC_DEFUN([AC_TRY_LIBPYTHON],
 719 [
 720   define([have_libpython_var],$1)
 721   new_CPPFLAGS=$2
 722   new_LIBS=$3
 723   AC_MSG_CHECKING([for python])
 724   save_CPPFLAGS=$CPPFLAGS
 725   save_LIBS=$LIBS
 726   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 727   LIBS="$new_LIBS $LIBS"
 728   found_usable_python=no
 729   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "Python.h"]],
 730                                  [[Py_Initialize ();]])],
 731                  [have_libpython_var=yes
 732                   found_usable_python=yes
 733                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 734                   PYTHON_LIBS=$new_LIBS])
 735   CPPFLAGS=$save_CPPFLAGS
 736   LIBS=$save_LIBS
 737   AC_MSG_RESULT([${found_usable_python}])
 738 ])
 739
 740 dnl There are several different values for --with-python:
 741 dnl
 742 dnl no -   Don't include python support.
 743 dnl yes -  Include python support, error if it's missing.
 744 dnl        If we find python in $PATH, use it to fetch configure options,
 745 dnl        otherwise assume the compiler can find it with no help from us.
 746 dnl        Python 2.7 and 2.6 are tried in turn.
 747 dnl auto - Same as "yes", but if python is missing from the system,
 748 dnl        fall back to "no".
 749 dnl /path/to/python/exec-prefix -
 750 dnl        Use the python located in this directory.
 751 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 752 dnl        the compilation parameters.  Otherwise use
 753 dnl        -I/path/to/python/exec-prefix/include,
 754 dnl        -L/path/to/python/exec-prefix/lib.
 755 dnl        Python 2.7 and 2.6 are tried in turn.
 756 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 757 dnl        but is deprecated.
 758 dnl /path/to/python/executable -
 759 dnl        Run python-config.py with this version of python to fetch the
 760 dnl        compilation parameters.
 761 dnl        NOTE: This needn't be the real python executable.
 762 dnl        In a cross-compilation scenario (build != host), this could be
 763 dnl        a shell script that provides what python-config.py provides for
 764 dnl        --ldflags, --includes, --exec-prefix.
 765 dnl python-executable -
 766 dnl        Find python-executable in $PATH, and then handle the same as
 767 dnl        /path/to/python/executable.
 768 dnl
 769 dnl If a python program is specified, it is used to run python-config.py and
 770 dnl is passed --ldflags, --includes, --exec-prefix.
 771
 772 AC_ARG_WITH(python,
 773   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 774   [], [with_python=auto])
 775 AC_MSG_CHECKING([whether to use python])
 776 AC_MSG_RESULT([$with_python])
 777
 778 if test "${with_python}" = no; then
 779   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 780   have_libpython=no
 781 else
 782   case "${with_python}" in
 783   [[\\/]]* | ?:[[\\/]]*)
 784     if test -d "${with_python}"; then
 785       # Assume the python binary is ${with_python}/bin/python.
 786       python_prog="${with_python}/bin/python"
 787       python_prefix=
 788       # If python does not exit ${with_python}/bin, then try in
 789       # ${with_python}.  On Windows/MinGW, this is where the Python
 790       # executable is.
 791       if test ! -x "${python_prog}"; then
 792         python_prog="${with_python}/python"
 793         python_prefix=
 794       fi
 795       if test ! -x "${python_prog}"; then
 796         # Fall back to gdb 7.0/7.1 behaviour.
 797         python_prog=missing
 798         python_prefix=${with_python}
 799       fi
 800     elif test -x "${with_python}"; then
 801       # While we can't run python compiled for $host (unless host == build),
 802       # the user could write a script that provides the needed information,
 803       # so we support that.
 804       python_prog=${with_python}
 805       python_prefix=
 806     else
 807       AC_MSG_ERROR(invalid value for --with-python)
 808     fi
 809     ;;
 810   */*)
 811     # Disallow --with-python=foo/bar.
 812     AC_MSG_ERROR(invalid value for --with-python)
 813     ;;
 814   *)
 815     # The user has either specified auto, yes, or the name of the python
 816     # program assumed to be in $PATH.
 817     python_prefix=
 818     case "${with_python}" in
 819     yes | auto)
 820       if test "${build}" = "${host}"; then
 821         AC_PATH_PROG(python_prog_path, python, missing)
 822         if test "${python_prog_path}" = missing; then
 823           python_prog=missing
 824         else
 825           python_prog=${python_prog_path}
 826         fi
 827       else
 828         # Not much we can do except assume the cross-compiler will find the
 829         # right files.
 830         python_prog=missing
 831       fi
 832       ;;
 833     *)
 834       # While we can't run python compiled for $host (unless host == build),
 835       # the user could write a script that provides the needed information,
 836       # so we support that.
 837       python_prog="${with_python}"
 838       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 839       if test "${python_prog_path}" = missing; then
 840         AC_MSG_ERROR(unable to find python program ${python_prog})
 841       fi
 842       ;;
 843     esac
 844   esac
 845
 846   if test "${python_prog}" != missing; then
 847     # We have a python program to use, but it may be too old.
 848     # Don't flag an error for --with-python=auto (the default).
 849     have_python_config=yes
 850     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 851     if test $? != 0; then
 852       have_python_config=failed
 853       if test "${with_python}" != auto; then
 854         AC_MSG_ERROR(failure running python-config --includes)
 855       fi
 856     fi
 857     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 858     if test $? != 0; then
 859       have_python_config=failed
 860       if test "${with_python}" != auto; then
 861         AC_MSG_ERROR(failure running python-config --ldflags)
 862       fi
 863     fi
 864     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 865     if test $? != 0; then
 866       have_python_config=failed
 867       if test "${with_python}" != auto; then
 868         AC_MSG_ERROR(failure running python-config --exec-prefix)
 869       fi
 870     fi
 871   else
 872     # We do not have a python executable we can use to determine where
 873     # to find the Python headers and libs.  We cannot guess the include
 874     # path from the python_prefix either, because that include path
 875     # depends on the Python version.  So, there is nothing much we can
 876     # do except assume that the compiler will be able to find those files.
 877     python_includes=
 878     python_libs=
 879     have_python_config=no
 880   fi
 881
 882   # If we have python-config, only try the configuration it provides.
 883   # Otherwise fallback on the old way of trying different versions of
 884   # python in turn.
 885
 886   have_libpython=no
 887   if test "${have_python_config}" = yes; then
 888     AC_TRY_LIBPYTHON(have_libpython,
 889                      ${python_includes}, ${python_libs})
 890   elif test "${have_python_config}" != failed; then
 891     if test "${have_libpython}" = no; then
 892       AC_TRY_LIBPYTHON(have_libpython,
 893                        ${python_includes}, "-lpython2.7 ${python_libs}")
 894     fi
 895     if test "${have_libpython}" = no; then
 896       AC_TRY_LIBPYTHON(have_libpython,
 897                        ${python_includes}, "-lpython2.6 ${python_libs}")
 898     fi
 899   fi
 900
 901   if test "${have_libpython}" = no; then
 902     case "${with_python}" in
 903     yes)
 904       AC_MSG_ERROR([python is missing or unusable])
 905       ;;
 906     auto)
 907       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 908       ;;
 909     *)
 910       AC_MSG_ERROR([no usable python found at ${with_python}])
 911       ;;
 912     esac
 913   else
 914     if test -n "${python_prefix}"; then
 915       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 916                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 917       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 918     fi
 919   fi
 920 fi
 921
 922 dnl Use --with-python-libdir to control where GDB looks for the Python
 923 dnl libraries.
 924 dnl
 925 dnl If this is not given then the default will be based on the value
 926 dnl passed to --with-python, which is in the python_prefix variable.
 927 dnl If the --with-python option wasn't given then the default value in
 928 dnl python_prefix is based on running the 'gdb/python/python-config
 929 dnl --exec-prefix' script.
 930 AC_ARG_WITH(python-libdir,
 931   AS_HELP_STRING([--with-python-libdir@<:@=DIR@:>@], [search for python's libraries in DIR]),
 932   [],[
 933     # If no python libdir is specified then select one based on
 934     # python's prefix path.
 935     if test -n "${python_prefix}"; then
 936       with_python_libdir=${python_prefix}/lib
 937     fi
 938   ])
 939
 940 if test "${have_libpython}" != no; then
 941   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 942   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 943   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 944   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 945   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 946   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 947
 948   if test -n "${with_python_libdir}"; then
 949     AC_DEFINE_UNQUOTED(WITH_PYTHON_LIBDIR, "${with_python_libdir}",
 950                        [Directory containing Python's standard libraries from --with-python-libdir.])
 951     GDB_AC_DEFINE_RELOCATABLE(PYTHON_LIBDIR, [python lib], ${with_python_libdir})
 952   fi
 953
 954   # Flags needed to compile Python code (taken from python-config --cflags).
 955   # We cannot call python-config directly because it will output whatever was
 956   # used when compiling the Python interpreter itself, including flags which
 957   # would make the python-related objects be compiled differently from the
 958   # rest of GDB (e.g., -O2 and -fPIC).
 959   if test "${GCC}" = yes; then
 960     tentative_python_cflags="-fno-strict-aliasing -fwrapv"
 961     # Python headers recommend -DNDEBUG, but it's unclear if that just
 962     # refers to building Python itself.  In release mode, though, it
 963     # doesn't hurt for the Python code in gdb to follow.
 964     $development || tentative_python_cflags="$tentative_python_cflags -DNDEBUG"
 965   fi
 966
 967   if test "x${tentative_python_cflags}" != x; then
 968     AC_MSG_CHECKING(compiler flags for python code)
 969     for flag in ${tentative_python_cflags}; do
 970       # Check that the compiler accepts it
 971       saved_CFLAGS="$CFLAGS"
 972       CFLAGS="$CFLAGS $flag"
 973       AC_COMPILE_IFELSE(
 974         [AC_LANG_PROGRAM([], [])],
 975         [PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag"],
 976         []
 977       )
 978       CFLAGS="$saved_CFLAGS"
 979     done
 980     AC_MSG_RESULT(${PYTHON_CFLAGS})
 981   fi
 982
 983   # On x64 Windows, Python's include headers, and pyconfig.h in
 984   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
 985   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
 986   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
 987   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
 988   # The issue was reported to the Python community, but still isn't
 989   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
 990
 991   case "$gdb_host" in
 992     mingw64)
 993            if test "${GCC}" = yes; then
 994              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
 995            fi
 996            ;;
 997   esac
 998 else
 999   # Even if Python support is not compiled in, we need to have this file
1000   # included so that the "python" command, et.al., still exists.
1001   CONFIG_OBS="$CONFIG_OBS python/python.o"
1002   CONFIG_SRCS="$CONFIG_SRCS python/python.c"
1003 fi
1004
1005 # Work around Python http://bugs.python.org/issue10112.  See also
1006 # http://bugs.python.org/issue11410, otherwise -Wl,--dynamic-list has
1007 # no effect.  Note that the only test after this that uses Python is
1008 # the -rdynamic/-Wl,--dynamic-list test, and we do want that one to be
1009 # run without -export-dynamic too.
1010 PYTHON_LIBS=`echo $PYTHON_LIBS | sed -e 's/-Xlinker -export-dynamic//'`
1011
1012 AC_SUBST(PYTHON_CFLAGS)
1013 AC_SUBST(PYTHON_CPPFLAGS)
1014 AC_SUBST(PYTHON_LIBS)
1015 AM_CONDITIONAL(HAVE_PYTHON, test "${have_libpython}" != no)
1016
1017 # -------------------- #
1018 # Check for libguile.  #
1019 # -------------------- #
1020
1021 dnl Utility to simplify finding libguile.
1022 dnl $1 = pkg-config-program
1023 dnl $2 = space-separate list of guile versions to try
1024 dnl $3 = yes|no, indicating whether to flag errors or ignore them
1025 dnl $4 = the shell variable to assign the result to
1026 dnl      If libguile is found we store "yes" here.
1027
1028 AC_DEFUN([AC_TRY_LIBGUILE],
1029 [
1030   pkg_config=$1
1031   guile_version_list=$2
1032   flag_errors=$3
1033   define([have_libguile_var],$4)
1034   found_usable_guile=checking
1035   AC_MSG_CHECKING([for usable guile from ${pkg_config}])
1036   for guile_version in ${guile_version_list}; do
1037     ${pkg_config} --exists ${guile_version} 2>/dev/null
1038     if test $? != 0; then
1039       continue
1040     fi
1041     dnl pkg-config says the package exists, so if we get an error now,
1042     dnl that's bad.
1043     new_CPPFLAGS=`${pkg_config} --cflags ${guile_version}`
1044     if test $? != 0; then
1045       AC_MSG_ERROR([failure running pkg-config --cflags ${guile_version}])
1046     fi
1047     new_LIBS=`${pkg_config} --libs ${guile_version}`
1048     if test $? != 0; then
1049       AC_MSG_ERROR([failure running pkg-config --libs ${guile_version}])
1050     fi
1051     dnl If we get this far, great.
1052     found_usable_guile=${guile_version}
1053     break
1054   done
1055   if test "${found_usable_guile}" = "checking"; then
1056     if test "${flag_errors}" = "yes"; then
1057       AC_MSG_ERROR([unable to find usable guile version from "${guile_version_list}"])
1058     else
1059       found_usable_guile=no
1060     fi
1061   fi
1062   dnl One final sanity check.
1063   dnl The user could have said --with-guile=python-2.7.
1064   if test "${found_usable_guile}" != no; then
1065     save_CPPFLAGS=$CPPFLAGS
1066     save_LIBS=$LIBS
1067     CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
1068     LIBS="$LIBS $new_LIBS"
1069     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "libguile.h"]],
1070                                    [[scm_init_guile ();]])],
1071                    [have_libguile_var=yes
1072                     GUILE_CPPFLAGS=$new_CPPFLAGS
1073                     GUILE_LIBS=$new_LIBS],
1074                    [found_usable_guile=no])
1075     dnl scm_set_automatic_finalization_enabled added in Guile 2.2.
1076     AC_CHECK_FUNC(scm_set_automatic_finalization_enabled,
1077       AC_DEFINE(HAVE_GUILE_MANUAL_FINALIZATION, 1,
1078                 [Define if Guile supports manual finalization.])
1079     )
1080     CPPFLAGS=$save_CPPFLAGS
1081     LIBS=$save_LIBS
1082     if test "${found_usable_guile}" = no; then
1083       if test "${flag_errors}" = yes; then
1084         AC_MSG_FAILURE([linking guile version ${guile_version} test program failed])
1085       fi
1086     fi
1087   fi
1088   AC_MSG_RESULT([${found_usable_guile}])
1089 ])
1090
1091 dnl There are several different values for --with-guile:
1092 dnl
1093 dnl no -   Don't include guile support.
1094 dnl yes -  Include guile support, error if it's missing.
1095 dnl        The pkg-config program must be in $PATH.
1096 dnl auto - Same as "yes", but if guile is missing from the system,
1097 dnl        fall back to "no".
1098 dnl guile-version [guile-version-choice-2 ...] -
1099 dnl        A space-separated list of guile package versions to try.
1100 dnl        These are passed to pkg-config as-is.
1101 dnl        E.g., guile-2.0 or guile-2.2-uninstalled
1102 dnl        This requires making sure PKG_CONFIG_PATH is set appropriately.
1103 dnl /path/to/pkg-config -
1104 dnl        Use this pkg-config program.
1105 dnl        NOTE: This needn't be the "real" pkg-config program.
1106 dnl        It could be a shell script.  It is invoked as:
1107 dnl        pkg-config --exists $version
1108 dnl        pkg-config --cflags $version
1109 dnl        pkg-config --libs $version
1110 dnl        pkg-config --variable guild $version
1111 dnl        The script will be called with $version having each value in
1112 dnl        $try_guile_versions until --exists indicates success.
1113
1114 AC_ARG_WITH(guile,
1115   AS_HELP_STRING([--with-guile@<:@=GUILE@:>@], [include guile support (auto/yes/no/<guile-version>/<pkg-config-program>)]),
1116   [], [with_guile=auto])
1117 AC_MSG_CHECKING([whether to use guile])
1118 AC_MSG_RESULT([$with_guile])
1119
1120 dnl We check guile with pkg-config.
1121 AC_PATH_PROG(pkg_config_prog_path, pkg-config, missing)
1122
1123 try_guile_versions="guile-3.0 guile-2.2 guile-2.0"
1124 have_libguile=no
1125 case "${with_guile}" in
1126 no)
1127   AC_MSG_WARN([guile support disabled; some features will be unavailable.])
1128   ;;
1129 auto)
1130   if test "${pkg_config_prog_path}" = "missing"; then
1131     AC_MSG_WARN([pkg-config not found, guile support disabled])
1132   else
1133     AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, no, have_libguile)
1134   fi
1135   ;;
1136 yes)
1137   if test "${pkg_config_prog_path}" = "missing"; then
1138     AC_MSG_ERROR([pkg-config not found])
1139   fi
1140   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, yes, have_libguile)
1141   ;;
1142 [[\\/]]* | ?:[[\\/]]*)
1143   if test -x "${with_guile}"; then
1144     AC_TRY_LIBGUILE(${with_guile}, ${try_guile_versions}, yes, have_libguile)
1145   else
1146     AC_MSG_ERROR([Guile config program not executable: ${with_guile}])
1147   fi
1148   ;;
1149 "" | */*)
1150   # Disallow --with=guile="" and --with-guile=foo/bar.
1151   AC_MSG_ERROR([invalid value for --with-guile])
1152   ;;
1153 *)
1154   # A space separate list of guile versions to try, in order.
1155   if test "${pkg_config_prog_path}" = "missing"; then
1156     AC_MSG_ERROR([pkg-config not found])
1157   fi
1158   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${with_guile}, yes, have_libguile)
1159   ;;
1160 esac
1161
1162 if test "${have_libguile}" != no; then
1163   dnl Get the name of the 'guild' program.
1164   case "${with_guile}" in
1165   [[\\/]]* | ?:[[\\/]]*)
1166     GDB_GUILE_PROGRAM_NAMES(["${with_guile}"], ["${guile_version}"])
1167     ;;
1168   *)
1169     GDB_GUILE_PROGRAM_NAMES(["${pkg_config_prog_path}"], ["${guile_version}"])
1170     ;;
1171   esac
1172
1173   dnl Make sure guild can handle this host.
1174   GDB_TRY_GUILD([$srcdir/guile/lib/gdb/support.scm])
1175   dnl If not, disable guile support.
1176   if test "$ac_cv_guild_ok" = no; then
1177     have_libguile=no
1178     AC_MSG_WARN(disabling guile support, $GUILD fails compiling for $host)
1179   fi
1180 fi
1181
1182 if test "${have_libguile}" != no; then
1183   AC_DEFINE(HAVE_GUILE, 1, [Define if Guile interpreter is being linked in.])
1184   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_GUILE_OBS)"
1185   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_GUILE_DEPS)"
1186   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_GUILE_SRCS)"
1187   CONFIG_INSTALL="$CONFIG_INSTALL install-guile"
1188   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_GUILE_CFLAGS)"
1189
1190   dnl The 'scm_new_smob' function appeared in Guile 2.0.6.
1191   save_LIBS="$LIBS"
1192   save_CPPFLAGS="$CPPFLAGS"
1193   LIBS="$GUILE_LIBS"
1194   CPPFLAGS="$GUILE_CPPFLAGS"
1195   AC_CHECK_FUNCS([scm_new_smob])
1196   LIBS="$save_LIBS"
1197   CPPFLAGS="$save_CPPFLAGS"
1198 else
1199   # Even if Guile support is not compiled in, we need to have these files
1200   # included.
1201   CONFIG_OBS="$CONFIG_OBS guile/guile.o"
1202   CONFIG_SRCS="$CONFIG_SRCS guile/guile.c"
1203 fi
1204 AC_SUBST(GUILE_CPPFLAGS)
1205 AC_SUBST(GUILE_LIBS)
1206 AM_CONDITIONAL(HAVE_GUILE, test "${have_libguile}" != no)
1207
1208 # ---------------------------- #
1209 # Check for source highlight.  #
1210 # ---------------------------- #
1211
1212 SRCHIGH_LIBS=
1213 SRCHIGH_CFLAGS=
1214
1215 AC_ARG_ENABLE(source-highlight,
1216   AS_HELP_STRING([--enable-source-highlight],
1217     [enable source-highlight for source listings]),
1218   [case "${enableval}" in
1219   yes)  enable_source_highlight=yes ;;
1220   no)   enable_source_highlight=no  ;;
1221   *)    AC_MSG_ERROR(bad value ${enableval} for source-highlight option) ;;
1222 esac],
1223 [enable_source_highlight=auto])
1224
1225 if test "${enable_source_highlight}" != "no"; then
1226   AC_MSG_CHECKING([for the source-highlight library])
1227   if test "${pkg_config_prog_path}" = "missing"; then
1228     AC_MSG_RESULT([no - pkg-config not found])
1229     if test "${enable_source_highlight}" = "yes"; then
1230       AC_MSG_ERROR([pkg-config was not found in your system])
1231     fi
1232   else
1233     case "$LDFLAGS" in
1234       *static-libstdc*)
1235         AC_MSG_ERROR([source highlight is incompatible with -static-libstdc++; dnl
1236 either use --disable-source-highlight or dnl
1237 --without-static-standard-libraries])
1238         ;;
1239     esac
1240
1241     if ${pkg_config_prog_path} --exists source-highlight; then
1242       SRCHIGH_CFLAGS=`${pkg_config_prog_path} --cflags source-highlight`
1243       SRCHIGH_LIBS=`${pkg_config_prog_path} --libs source-highlight`
1244       AC_DEFINE([HAVE_SOURCE_HIGHLIGHT], 1,
1245                 [Define to 1 if the source-highlight library is available])
1246       AC_MSG_RESULT([yes])
1247     else
1248       AC_MSG_RESULT([no])
1249       if test "${enable_source_highlight}" = "yes"; then
1250         AC_MSG_ERROR([source-highlight was not found in your system])
1251       fi
1252     fi
1253   fi
1254 fi
1255 AC_SUBST(SRCHIGH_LIBS)
1256 AC_SUBST(SRCHIGH_CFLAGS)
1257
1258 # ------------------------- #
1259 # Checks for header files.  #
1260 # ------------------------- #
1261
1262 AC_HEADER_STDC
1263 # elf_hp.h is for HP/UX 64-bit shared library support.
1264 AC_CHECK_HEADERS([nlist.h machine/reg.h \
1265                   thread_db.h \
1266                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1267                   sys/resource.h sys/ptrace.h ptrace.h \
1268                   sys/reg.h sys/debugreg.h \
1269                   termios.h elf_hp.h])
1270 AC_CHECK_HEADERS(sys/user.h, [], [],
1271 [#if HAVE_SYS_PARAM_H
1272 # include <sys/param.h>
1273 #endif
1274 ])
1275
1276 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncursesw/ncurses.h ncurses/ncurses.h ncurses/term.h)
1277 AC_CHECK_HEADERS(term.h, [], [],
1278 [#if HAVE_CURSES_H
1279 # include <curses.h>
1280 #endif
1281 ])
1282
1283 AC_CHECK_HEADERS([sys/socket.h])
1284 AC_CHECK_HEADERS([ws2tcpip.h])
1285
1286 # ------------------------- #
1287 # Checks for declarations.  #
1288 # ------------------------- #
1289
1290 libiberty_INIT
1291
1292 AC_CHECK_DECLS([snprintf])
1293 AM_LC_MESSAGES
1294
1295 # ------------------ #
1296 # Checks for types.  #
1297 # ------------------ #
1298
1299 AC_CHECK_TYPES(socklen_t, [], [],
1300 [#include <sys/types.h>
1301 #if HAVE_SYS_SOCKET_H
1302 # include <sys/socket.h>
1303 #elif HAVE_WS2TCPIP_H
1304 # include <ws2tcpip.h>
1305 #endif
1306 ])
1307
1308 # ------------------------------------- #
1309 # Checks for compiler characteristics.  #
1310 # ------------------------------------- #
1311
1312 AC_C_CONST
1313 AC_C_INLINE
1314 AC_C_BIGENDIAN
1315
1316 # ------------------------------ #
1317 # Checks for library functions.  #
1318 # ------------------------------ #
1319
1320 AC_CHECK_FUNCS([getuid getgid \
1321                 pipe pread pread64 pwrite resize_term \
1322                 getpgid setsid \
1323                 sigaction sigsetmask socketpair \
1324                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1325                 setrlimit getrlimit posix_madvise waitpid \
1326                 use_default_colors])
1327 AM_LANGINFO_CODESET
1328 GDB_AC_COMMON
1329
1330 # Check the return and argument types of ptrace.
1331 GDB_AC_PTRACE
1332
1333 dnl AC_FUNC_SETPGRP does not work when cross compiling
1334 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1335 if test "$cross_compiling" = no; then
1336   AC_FUNC_SETPGRP
1337 else
1338   AC_CACHE_CHECK(
1339     [whether setpgrp takes no argument],
1340     [ac_cv_func_setpgrp_void],
1341     [AC_COMPILE_IFELSE(
1342        [AC_LANG_PROGRAM(
1343           [#include <unistd.h>],
1344           [if (setpgrp(1,1) == -1)
1345              exit (0);
1346            else
1347              exit (1);]
1348         )],
1349        [ac_cv_func_setpgrp_void=no],
1350        [ac_cv_func_setpgrp_void=yes]
1351      )]
1352   )
1353 if test "$ac_cv_func_setpgrp_void" = yes; then
1354   AC_DEFINE(SETPGRP_VOID, 1)
1355 fi
1356 fi
1357
1358 # Assume we'll default to using the included libiberty regex.
1359 gdb_use_included_regex=yes
1360
1361 # However, if the system regex is GNU regex, then default to *not*
1362 # using the included regex.
1363 AC_CACHE_CHECK(
1364   [for GNU regex],
1365   [gdb_cv_have_gnu_regex],
1366   [AC_COMPILE_IFELSE(
1367      [AC_LANG_PROGRAM(
1368         [#include <gnu-versions.h>],
1369         [#define REGEX_INTERFACE_VERSION 1
1370          #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1371          # error "Version mismatch"
1372          #endif]
1373       )],
1374      [gdb_cv_have_gnu_regex=yes],
1375      [gdb_cv_have_gnu_regex=no]
1376    )]
1377 )
1378 if test "$gdb_cv_have_gnu_regex" = yes; then
1379   gdb_use_included_regex=no
1380 fi
1381
1382 AC_ARG_WITH(included-regex,
1383   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1384   gdb_with_regex=$withval,
1385   gdb_with_regex=$gdb_use_included_regex)
1386 if test "$gdb_with_regex" = yes; then
1387   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1388     [Define to 1 if the regex included in libiberty should be used.])
1389 fi
1390
1391 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1392 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1393 [#include <sys/param.h>
1394 #include <sys/proc.h>
1395 ])
1396
1397 # See if <sys/lwp.h> defines `struct lwp`.
1398 AC_CACHE_CHECK(
1399   [for struct lwp],
1400   [gdb_cv_struct_lwp],
1401   [AC_COMPILE_IFELSE(
1402      [AC_LANG_PROGRAM(
1403         [#include <sys/param.h>
1404          #define _KMEMUSER
1405          #include <sys/lwp.h>],
1406         [struct lwp l;]
1407       )],
1408      [gdb_cv_struct_lwp=yes],
1409      [gdb_cv_struct_lwp=no]
1410    )]
1411 )
1412 if test "$gdb_cv_struct_lwp" = yes; then
1413   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1414             [Define to 1 if your system has struct lwp.])
1415 fi
1416
1417 # See if <machine/reg.h> degines `struct reg'.
1418 AC_CACHE_CHECK(
1419   [for struct reg in machine/reg.h],
1420   [gdb_cv_struct_reg],
1421   [AC_COMPILE_IFELSE(
1422      [AC_LANG_PROGRAM(
1423         [#include <sys/types.h>
1424          #include <machine/reg.h>],
1425         [struct reg r;]
1426       )],
1427      [gdb_cv_struct_reg=yes],
1428      [gdb_cv_struct_reg=no]
1429    )]
1430 )
1431 if test "$gdb_cv_struct_reg" = yes; then
1432   AC_DEFINE(HAVE_STRUCT_REG, 1,
1433             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1434 fi
1435
1436 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1437 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1438 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1439                  [#include <sys/types.h>
1440 #include <machine/reg.h>])
1441
1442 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1443 AC_MSG_CHECKING(for PTRACE_GETREGS)
1444 AC_CACHE_VAL(
1445   [gdb_cv_have_ptrace_getregs],
1446   [AC_COMPILE_IFELSE(
1447     [AC_LANG_PROGRAM([#include <sys/ptrace.h>], [PTRACE_GETREGS;])],
1448     [gdb_cv_have_ptrace_getregs=yes],
1449     [gdb_cv_have_ptrace_getregs=no]
1450    )]
1451 )
1452 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1453 if test "$gdb_cv_have_ptrace_getregs" = yes; then
1454   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1455   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1456 fi
1457
1458 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1459 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1460 AC_CACHE_VAL(
1461   [gdb_cv_have_ptrace_getfpxregs],
1462   [AC_COMPILE_IFELSE(
1463      [AC_LANG_PROGRAM([#include <sys/ptrace.h>], [PTRACE_GETFPXREGS;])],
1464      [gdb_cv_have_ptrace_getfpxregs=yes],
1465      [gdb_cv_have_ptrace_getfpxregs=no]
1466    )]
1467 )
1468 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1469 if test "$gdb_cv_have_ptrace_getfpxregs" = yes; then
1470   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1471   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1472 fi
1473
1474 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1475 AC_MSG_CHECKING(for PT_GETDBREGS)
1476 AC_CACHE_VAL(
1477   [gdb_cv_have_pt_getdbregs],
1478   [AC_COMPILE_IFELSE(
1479      [AC_LANG_PROGRAM(
1480         [#include <sys/types.h>
1481          #include <sys/ptrace.h>],
1482         [PT_GETDBREGS;]
1483       )],
1484      [gdb_cv_have_pt_getdbregs=yes],
1485      [gdb_cv_have_pt_getdbregs=no]
1486    )]
1487 )
1488 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1489 if test "$gdb_cv_have_pt_getdbregs" = yes; then
1490   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1491   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1492 fi
1493
1494 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1495 AC_MSG_CHECKING(for PT_GETXMMREGS)
1496 AC_CACHE_VAL(
1497   [gdb_cv_have_pt_getxmmregs],
1498   [AC_COMPILE_IFELSE(
1499      [AC_LANG_PROGRAM(
1500         [#include <sys/types.h>
1501          #include <sys/ptrace.h>],
1502         [PT_GETXMMREGS;]
1503       )],
1504      [gdb_cv_have_pt_getxmmregs=yes],
1505      [gdb_cv_have_pt_getxmmregs=no]
1506    )]
1507 )
1508 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1509 if test "$gdb_cv_have_pt_getxmmregs" = yes; then
1510   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1511   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1512 fi
1513
1514 # See if <sys/ptrace.h> supports LWP names on FreeBSD
1515 # Older FreeBSD versions don't have the pl_tdname member of
1516 # `struct ptrace_lwpinfo'.
1517 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_tdname], [], [],
1518                  [#include <sys/ptrace.h>])
1519
1520 # See if <sys/ptrace.h> supports syscall fields on FreeBSD.  The
1521 # pl_syscall_code member of `struct ptrace_lwpinfo' was added in
1522 # FreeBSD 10.3.
1523 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_syscall_code], [], [],
1524                  [#include <sys/ptrace.h>])
1525
1526 # Check if the compiler supports the `long long' type.
1527
1528 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1529                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1530 [[extern long long foo;]],
1531 [[switch (foo & 2) { case 0: return 1; }]])],
1532                                   gdb_cv_c_long_long=yes,
1533                                   gdb_cv_c_long_long=no)])
1534 if test "$gdb_cv_c_long_long" != yes; then
1535   # libdecnumber requires long long.
1536   AC_MSG_ERROR([Compiler must support long long for GDB.])
1537 fi
1538
1539 # Check if the compiler and runtime support printing long longs.
1540
1541 AC_CACHE_CHECK([for long long support in printf],
1542                gdb_cv_printf_has_long_long,
1543                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1544 [[char buf[32];
1545   long long l = 0;
1546   l = (l << 16) + 0x0123;
1547   l = (l << 16) + 0x4567;
1548   l = (l << 16) + 0x89ab;
1549   l = (l << 16) + 0xcdef;
1550   sprintf (buf, "0x%016llx", l);
1551   return (strcmp ("0x0123456789abcdef", buf));]])],
1552                               gdb_cv_printf_has_long_long=yes,
1553                               gdb_cv_printf_has_long_long=no,
1554                               gdb_cv_printf_has_long_long=no)])
1555 if test "$gdb_cv_printf_has_long_long" = yes; then
1556   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1557             [Define to 1 if the "%ll" format works to print long longs.])
1558 fi
1559
1560 # Check if the compiler and runtime support printing decfloats.
1561
1562 AC_CACHE_CHECK([for decfloat support in printf],
1563                gdb_cv_printf_has_decfloat,
1564                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1565 [[char buf[64];
1566   _Decimal32 d32 = 1.2345df;
1567   _Decimal64 d64 = 1.2345dd;
1568   _Decimal128 d128 = 1.2345dl;
1569   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1570   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1571                               gdb_cv_printf_has_decfloat=yes,
1572                               gdb_cv_printf_has_decfloat=no,
1573                               gdb_cv_printf_has_decfloat=no)])
1574 if test "$gdb_cv_printf_has_decfloat" = yes; then
1575   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1576             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1577 fi
1578
1579 # Check if the compiler supports the `long double' type.  We can't use
1580 # AC_C_LONG_DOUBLE because that one does additional checks on the
1581 # constants defined in <float.h> that fail on some systems,
1582 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1583
1584 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1585                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1586                                   gdb_cv_c_long_double=yes,
1587                                   gdb_cv_c_long_double=no)])
1588 if test "$gdb_cv_c_long_double" = yes; then
1589   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1590            [Define to 1 if the compiler supports long double.])
1591 fi
1592
1593 # Check if the compiler and runtime support printing long doubles.
1594
1595 AC_CACHE_CHECK([for long double support in printf],
1596                gdb_cv_printf_has_long_double,
1597                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1598 [[char buf[16];
1599   long double f = 3.141592653;
1600   sprintf (buf, "%Lg", f);
1601   return (strncmp ("3.14159", buf, 7));]])],
1602                               gdb_cv_printf_has_long_double=yes,
1603                               gdb_cv_printf_has_long_double=no,
1604                               gdb_cv_printf_has_long_double=no)])
1605 if test "$gdb_cv_printf_has_long_double" = yes; then
1606   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1607             [Define to 1 if the "%Lg" format works to print long doubles.])
1608 fi
1609
1610 # Check if the compiler and runtime support scanning long doubles.
1611
1612 AC_CACHE_CHECK([for long double support in scanf],
1613                gdb_cv_scanf_has_long_double,
1614                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1615 [[#include <stdio.h>]],
1616 [[char *buf = "3.141592653";
1617   long double f = 0;
1618   sscanf (buf, "%Lg", &f);
1619   return !(f > 3.14159 && f < 3.14160);]])],
1620                               gdb_cv_scanf_has_long_double=yes,
1621                               gdb_cv_scanf_has_long_double=no,
1622                               gdb_cv_scanf_has_long_double=no)])
1623 if test "$gdb_cv_scanf_has_long_double" = yes; then
1624   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1625             [Define to 1 if the "%Lg" format works to scan long doubles.])
1626 fi
1627
1628 case ${host_os} in
1629 aix*)
1630   AC_CACHE_CHECK(
1631     [for -bbigtoc option], [gdb_cv_bigtoc],
1632     [SAVE_LDFLAGS=$LDFLAGS
1633
1634      case $GCC in
1635        yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1636        *) gdb_cv_bigtoc=-bbigtoc ;;
1637      esac
1638
1639      LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1640      AC_LINK_IFELSE(
1641        [AC_LANG_PROGRAM([], [int i;])],
1642        [],
1643        [gdb_cv_bigtoc=]
1644      )
1645      LDFLAGS="${SAVE_LDFLAGS}"]
1646   )
1647   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1648   ;;
1649 esac
1650
1651 AC_MSG_CHECKING(for the dynamic export flag)
1652 dynamic_list=false
1653 if test "${gdb_native}" = yes; then
1654    # The dynamically loaded libthread_db needs access to symbols in the gdb
1655    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1656    # may not be supported there.
1657    old_LDFLAGS="$LDFLAGS"
1658    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1659    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1660    LDFLAGS="$LDFLAGS $RDYNAMIC"
1661    if test "${have_libpython}" = no; then
1662      AC_LINK_IFELSE(
1663        [AC_LANG_PROGRAM([], [])],
1664        [dynamic_list=true],
1665        []
1666      )
1667    else
1668      # Workaround http://bugs.python.org/issue4434 where static
1669      # libpythonX.Y.a would get its symbols required for
1670      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1671      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1672
1673      # Note the workaround for Python
1674      # http://bugs.python.org/issue10112 earlier has removed
1675      # -export-dynamic from PYTHON_LIBS.  That's exactly what we want
1676      # here too, as otherwise it'd make this -Wl,--dynamic-list test
1677      # always pass.
1678      old_CFLAGS="$CFLAGS"
1679      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1680      old_LIBS="$LIBS"
1681      LIBS="$LIBS $PYTHON_LIBS"
1682      old_CPPFLAGS="$CPPFLAGS"
1683      CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
1684      AC_RUN_IFELSE(
1685        [AC_LANG_PROGRAM(
1686          [#include "Python.h"],
1687          [int err;
1688           Py_Initialize ();
1689           err = PyRun_SimpleString ("import itertools\n");
1690           Py_Finalize ();
1691           return err == 0 ? 0 : 1;])],
1692        [dynamic_list=true], [], [true])
1693      LIBS="$old_LIBS"
1694      CFLAGS="$old_CFLAGS"
1695      CPPFLAGS="$old_CPPFLAGS"
1696    fi
1697    LDFLAGS="$old_LDFLAGS"
1698 fi
1699 if $dynamic_list; then
1700   found="-Wl,--dynamic-list"
1701   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1702 else
1703   found="-rdynamic"
1704   RDYNAMIC="-rdynamic"
1705 fi
1706 AC_SUBST(RDYNAMIC)
1707 AC_MSG_RESULT($found)
1708
1709 dnl For certain native configurations, we need to check whether thread
1710 dnl support can be built in or not.
1711 dnl
1712 dnl Note that we only want this if we are both native (host == target),
1713 dnl and not doing a canadian cross build (build == host).
1714
1715 if test "${build}" = "${host}" -a "${host}" = "${target}" ; then
1716    case ${host_os} in
1717    aix*)
1718       AC_MSG_CHECKING(for AiX thread debugging library)
1719       AC_CACHE_VAL(
1720         [gdb_cv_have_aix_thread_debug],
1721         [AC_COMPILE_IFELSE(
1722            [AC_LANG_PROGRAM(
1723               [#include <sys/pthdebug.h>],
1724               [#ifndef PTHDB_VERSION_3
1725                #error
1726                #endif]
1727             )],
1728            [gdb_cv_have_aix_thread_debug=yes],
1729            [gdb_cv_have_aix_thread_debug=no]
1730          )]
1731       )
1732       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1733       if test "$gdb_cv_have_aix_thread_debug" = yes; then
1734          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1735          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1736          LIBS="$LIBS -lpthdebug"
1737
1738          # Older versions of AIX do not provide the declaration for
1739          # the getthrds function (it appears that it was introduced
1740          # with AIX 6.x).
1741          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1742       fi
1743       ;;
1744    esac
1745    AC_SUBST(CONFIG_LDFLAGS)
1746 fi
1747
1748 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1749 dnl other error codes.
1750 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1751   AC_CACHE_CHECK(
1752     [whether <thread_db.h> has TD_NOTALLOC],
1753     [gdb_cv_thread_db_h_has_td_notalloc],
1754     [AC_COMPILE_IFELSE(
1755        [AC_LANG_PROGRAM(
1756           [#include <thread_db.h>],
1757           [int i = TD_NOTALLOC;]
1758         )],
1759        [gdb_cv_thread_db_h_has_td_notalloc=yes],
1760        [gdb_cv_thread_db_h_has_td_notalloc=no]
1761      )]
1762   )
1763
1764   AC_CACHE_CHECK(
1765     [whether <thread_db.h> has TD_VERSION],
1766     [gdb_cv_thread_db_h_has_td_version],
1767     [AC_COMPILE_IFELSE(
1768        [AC_LANG_PROGRAM(
1769           [#include <thread_db.h>],
1770           [int i = TD_VERSION;]
1771         )],
1772        [gdb_cv_thread_db_h_has_td_version=yes],
1773        [gdb_cv_thread_db_h_has_td_version=no]
1774      )]
1775   )
1776
1777   AC_CACHE_CHECK(
1778     [whether <thread_db.h> has TD_NOTLS],
1779     [gdb_cv_thread_db_h_has_td_notls],
1780     [AC_COMPILE_IFELSE(
1781        [AC_LANG_PROGRAM(
1782           [#include <thread_db.h>],
1783           [int i = TD_NOTLS;]
1784         )],
1785        [gdb_cv_thread_db_h_has_td_notls=yes],
1786        [gdb_cv_thread_db_h_has_td_notls=no]
1787      )]
1788   )
1789 fi
1790 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1791   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1792             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1793 fi
1794 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1795   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1796             [Define if <thread_db.h> has the TD_VERSION error code.])
1797 fi
1798 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1799   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1800             [Define if <thread_db.h> has the TD_NOTLS error code.])
1801 fi
1802
1803 dnl Set the host's .gdbinit filename.
1804 case $host_os in
1805   go32* | *djgpp*)
1806     gdbinit=gdb.ini
1807     ;;
1808   *)
1809     gdbinit=.gdbinit
1810     ;;
1811 esac
1812 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1813
1814 dnl Handle optional features that can be enabled.
1815
1816 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1817 # except that the argument to --with-sysroot is optional.
1818 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1819 if test "x$with_sysroot" = xyes; then
1820   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1821 fi
1822 AC_ARG_WITH(sysroot,
1823   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1824                  [search for usr/lib et al within DIR]),
1825   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1826 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1827               [search for usr/lib et al within DIR])
1828 AC_SUBST(TARGET_SYSTEM_ROOT)
1829 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1830
1831 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1832     [automatically load a system-wide gdbinit file],
1833     [])
1834 GDB_AC_WITH_DIR(SYSTEM_GDBINIT_DIR, system-gdbinit-dir,
1835     [automatically load system-wide gdbinit files from this directory],
1836     [])
1837
1838 AM_GDB_WARNINGS
1839 AM_GDB_UBSAN
1840
1841 # In the Cygwin environment, we need some additional flags.
1842 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1843 [AC_EGREP_CPP(^lose$, [
1844 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1845 lose
1846 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1847
1848
1849 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1850 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1851 case ${host} in
1852   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1853   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1854   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1855   *) SER_HARDWIRE="$SER_HARDWIRE ser-uds.o" ;;
1856 esac
1857 AC_SUBST(SER_HARDWIRE)
1858
1859 # libreadline needs libuser32.a in a cygwin environment
1860 WIN32LIBS=
1861 if test x"$gdb_cv_os_cygwin" = xyes; then
1862     WIN32LIBS="-luser32"
1863     case "${target}" in
1864         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1865         ;;
1866     esac
1867 fi
1868
1869 # The ser-tcp.c module requires sockets.
1870 # Note that WIN32APILIBS is set by GDB_AC_COMMON.
1871 WIN32LIBS="$WIN32LIBS $WIN32APILIBS"
1872
1873 # Add ELF support to GDB, but only if BFD includes ELF support.
1874 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
1875                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
1876 if test "$gdb_cv_var_elf" = yes; then
1877   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o dtrace-probe.o"
1878   AC_DEFINE(HAVE_ELF, 1,
1879             [Define if ELF support should be included.])
1880   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1881   if test "$plugins" = "yes"; then
1882     AC_SEARCH_LIBS(dlopen, dl)
1883   fi
1884 fi
1885
1886 # Add macho support to GDB, but only if BFD includes it.
1887 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
1888                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
1889 if test "$gdb_cv_var_macho" = yes; then
1890   CONFIG_OBS="$CONFIG_OBS machoread.o"
1891 fi
1892
1893 # Add any host-specific objects to GDB.
1894 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1895
1896 # If building on ELF, look for lzma support for embedded compressed debug info.
1897 if test "$gdb_cv_var_elf" = yes; then
1898   AC_ARG_WITH(lzma,
1899     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
1900     [], [with_lzma=auto])
1901   AC_MSG_CHECKING([whether to use lzma])
1902   AC_MSG_RESULT([$with_lzma])
1903
1904   if test "${with_lzma}" != no; then
1905     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
1906                           [lzma_index_iter iter;
1907                            lzma_index_iter_init (&iter, 0);
1908                            lzma_mf_is_supported (LZMA_MF_HC3);])
1909     if test "$HAVE_LIBLZMA" != yes; then
1910       if test "$with_lzma" = yes; then
1911         AC_MSG_ERROR([missing liblzma for --with-lzma])
1912       fi
1913     fi
1914   fi
1915 fi
1916
1917 LIBGUI="../libgui/src/libgui.a"
1918 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1919 AC_SUBST(LIBGUI)
1920 AC_SUBST(GUI_CFLAGS_X)
1921
1922 WIN32LDAPP=
1923 AC_SUBST(WIN32LIBS)
1924 AC_SUBST(WIN32LDAPP)
1925
1926 case "${host}" in
1927 *-*-cygwin* | *-*-mingw* )
1928     configdir="win"
1929     ;;
1930 *)
1931     configdir="unix"
1932     ;;
1933 esac
1934
1935 GDBTKLIBS=
1936 if test "${enable_gdbtk}" = "yes"; then
1937
1938     # Gdbtk must have an absolute path to srcdir in order to run
1939     # properly when not installed.
1940     here=`pwd`
1941     cd ${srcdir}
1942     GDBTK_SRC_DIR=`pwd`
1943     cd $here
1944
1945     SC_PATH_TCLCONFIG
1946
1947     # If $no_tk is nonempty, then we can't do Tk, and there is no
1948     # point to doing Tcl.
1949     SC_PATH_TKCONFIG
1950
1951     if test -z "${no_tcl}" -a -z "${no_tk}"; then
1952         SC_LOAD_TCLCONFIG
1953
1954         # Check for in-tree tcl
1955         here=`pwd`
1956         cd ${srcdir}/..
1957         topdir=`pwd`
1958         cd ${here}
1959
1960         intree="no"
1961         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
1962           intree="yes"
1963         fi
1964
1965         # Find Tcl private headers
1966         if test x"${intree}" = xno; then
1967           CY_AC_TCL_PRIVATE_HEADERS
1968           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
1969           TCL_LIBRARY="${TCL_LIB_SPEC}"
1970           TCL_DEPS=""
1971         else
1972           # If building tcl in the same src tree, private headers
1973           # are not needed, but we need to be sure to use the right
1974           # headers library
1975           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
1976           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
1977           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
1978         fi
1979         AC_SUBST(TCL_INCLUDE)
1980         AC_SUBST(TCL_LIBRARY)
1981         AC_SUBST(TCL_DEPS)
1982
1983         SC_LOAD_TKCONFIG
1984
1985         # Check for in-tree Tk
1986         intree="no"
1987         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
1988           intree="yes"
1989         fi
1990
1991         # Find Tk private headers
1992         if test x"${intree}" = xno; then
1993           CY_AC_TK_PRIVATE_HEADERS
1994           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
1995           TK_LIBRARY=${TK_LIB_SPEC}
1996           TK_DEPS=""
1997         else
1998           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
1999           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2000           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2001         fi
2002         AC_SUBST(TK_INCLUDE)
2003         AC_SUBST(TK_LIBRARY)
2004         AC_SUBST(TK_DEPS)
2005         AC_SUBST(TK_XINCLUDES)
2006
2007         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2008
2009         # Include some libraries that Tcl and Tk want.
2010         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2011         # Yes, the ordering seems wrong here.  But it isn't.
2012         # TK_LIBS is the list of libraries that need to be linked
2013         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2014         # were in LIBS then any link tests after this point would
2015         # try to include things like `$(LIBGUI)', which wouldn't work.
2016         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2017
2018         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2019         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2020         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2021         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2022         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2023         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2024         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2025
2026         if test x"$gdb_cv_os_cygwin" = xyes; then
2027           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2028           WIN32LDAPP="-Wl,--subsystem,console"
2029           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2030         fi
2031
2032         AC_CONFIG_SUBDIRS(gdbtk)
2033     fi
2034 fi
2035
2036 AC_SUBST(X_CFLAGS)
2037 AC_SUBST(X_LDFLAGS)
2038 AC_SUBST(X_LIBS)
2039 AC_SUBST(GDBTKLIBS)
2040 AC_SUBST(GDBTK_CFLAGS)
2041 AC_SUBST(GDBTK_SRC_DIR)
2042
2043 AC_PATH_X
2044
2045 # Unlike the sim directory, whether a simulator is linked is controlled by
2046 # presence of a gdb_sim definition in the target configure.tgt entry.
2047 # This code just checks for a few cases where we'd like to ignore those
2048 # definitions, even when they're present in the '.mt' file.  These cases
2049 # are when --disable-sim is specified, or if the simulator directory is
2050 # not part of the source tree.
2051 #
2052 AC_ARG_ENABLE(sim,
2053 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2054 [echo "enable_sim = $enable_sim";
2055  echo "enableval = ${enableval}";
2056  case "${enableval}" in
2057   yes) ignore_sim=false ;;
2058   no)  ignore_sim=true ;;
2059   *)   ignore_sim=false ;;
2060  esac],
2061 [ignore_sim=false])
2062
2063 if test ! -d "${srcdir}/../sim"; then
2064   ignore_sim=true
2065 fi
2066
2067 SIM=
2068 SIM_OBS=
2069 if test "${ignore_sim}" = "false"; then
2070   if test x"${gdb_sim}" != x ; then
2071     SIM="${gdb_sim}"
2072     SIM_OBS="remote-sim.o"
2073     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2074
2075     # Some tdep code should only be compiled in when the ppc sim is
2076     # built.  PR sim/13418.
2077     case $target in
2078       powerpc*-*-*)
2079         AC_DEFINE(WITH_PPC_SIM, 1, [Define if the PPC simulator is being linked in.])
2080         ;;
2081     esac
2082   fi
2083 fi
2084 AC_SUBST(SIM)
2085 AC_SUBST(SIM_OBS)
2086
2087 AC_SUBST(ENABLE_CFLAGS)
2088 AC_SUBST(PROFILE_CFLAGS)
2089
2090 AC_SUBST(CONFIG_OBS)
2091 AC_SUBST(CONFIG_DEPS)
2092 AC_SUBST(CONFIG_SRCS)
2093 AC_SUBST(CONFIG_ALL)
2094 AC_SUBST(CONFIG_CLEAN)
2095 AC_SUBST(CONFIG_INSTALL)
2096 AC_SUBST(CONFIG_UNINSTALL)
2097
2098 # List of host floatformats.
2099 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2100 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2101 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2102
2103 # target_subdir is used by the testsuite to find the target libraries.
2104 target_subdir=
2105 if test "${host}" != "${target}"; then
2106     target_subdir="${target_alias}/"
2107 fi
2108 AC_SUBST(target_subdir)
2109
2110 # Import nat definitions.
2111 nat_makefile_frag=/dev/null
2112 if test "${gdb_native}" = "yes"; then
2113   . ${srcdir}/configure.nat
2114   nativefile=$NAT_FILE
2115 fi
2116
2117 AC_SUBST(NAT_FILE)
2118 AC_SUBST(NATDEPFILES)
2119 AC_SUBST(NAT_CDEPS)
2120 AC_SUBST(LOADLIBES)
2121 AC_SUBST(MH_CFLAGS)
2122 AC_SUBST(XM_CLIBS)
2123 AC_SUBST(NAT_GENERATED_FILES)
2124 AC_SUBST(HAVE_NATIVE_GCORE_HOST)
2125 AC_SUBST_FILE(nat_makefile_frag)
2126
2127 if test x"${gdb_osabi}" != x ; then
2128     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2129                        [Define to the default OS ABI for this configuration.])
2130 fi
2131
2132 # Check for babeltrace and babeltrace-ctf
2133 AC_ARG_WITH(babeltrace,
2134   AS_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2135   [], [with_babeltrace=auto])
2136 AC_MSG_CHECKING([whether to use babeltrace])
2137 AC_MSG_RESULT([$with_babeltrace])
2138
2139 if test "x$with_babeltrace" = "xno"; then
2140   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2141 else
2142   # Append -Werror to CFLAGS so that configure can catch the warning
2143   # "assignment from incompatible pointer type", which is related to
2144   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2145   # in GDB, while babeltrace 1.0.3 is broken.
2146   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2147   # safe to save and restore CFLAGS here.
2148   saved_CFLAGS=$CFLAGS
2149   CFLAGS="$CFLAGS -Werror"
2150   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2151                         [#include <babeltrace/babeltrace.h>
2152                          #include <babeltrace/ctf/events.h>
2153                          #include <babeltrace/ctf/iterator.h>],
2154                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2155                         struct bt_ctf_event *event = NULL;
2156                         const struct bt_definition *scope;
2157
2158                         pos->type = BT_SEEK_BEGIN;
2159                         bt_iter_set_pos (bt_ctf_get_iter (NULL), pos);
2160                         scope = bt_ctf_get_top_level_scope (event,
2161                                                            BT_STREAM_EVENT_HEADER);
2162                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2163                         ])
2164   CFLAGS=$saved_CFLAGS
2165
2166   if test "$HAVE_LIBBABELTRACE" != yes; then
2167      if test "$with_babeltrace" = yes; then
2168        AC_MSG_ERROR([babeltrace is missing or unusable])
2169      else
2170        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2171      fi
2172   fi
2173 fi
2174
2175 # Check for xxhash
2176 AC_ARG_WITH(xxhash,
2177   AS_HELP_STRING([--with-xxhash], [use libxxhash for hashing (faster) (auto/yes/no)]),
2178   [], [with_xxhash=auto])
2179
2180 GCC_ENABLE([libctf], [yes], [], [Handle .ctf type-info sections])
2181 if test x${enable_static} = xno; then
2182   LIBCTF="-Wl,--rpath,../libctf/.libs ../libctf/.libs/libctf.so"
2183   CTF_DEPS="../libctf/.libs/libctf.so"
2184 else
2185   LIBCTF="../libctf/.libs/libctf.a"
2186   CTF_DEPS="$LIBCTF"
2187 fi
2188 if test "${enable_libctf}" = yes; then
2189   AC_DEFINE(ENABLE_LIBCTF, 1, [Handle .ctf type-info sections])
2190 else
2191   LIBCTF=
2192   CTF_DEPS=
2193 fi
2194 AC_SUBST(ENABLE_LIBCTF)
2195 AC_SUBST(LIBCTF)
2196 AC_SUBST(CTF_DEPS)
2197
2198 # If nativefile (NAT_FILE) is not set in configure.nat, we link to an
2199 # empty version.
2200
2201 if test "x$with_xxhash" != "xno"; then
2202   AC_LIB_HAVE_LINKFLAGS([xxhash], [],
2203                         [#include <xxhash.h>],
2204                         [XXH32("foo", 3, 0);
2205                         ])
2206   if test "$HAVE_LIBXXHASH" != yes; then
2207     if test "$with_xxhash" = yes; then
2208       AC_MSG_ERROR([xxhash is missing or unusable])
2209     fi
2210   fi
2211   if test "x$with_xxhash" = "xauto"; then
2212     with_xxhash="$HAVE_LIBXXHASH"
2213   fi
2214 fi
2215
2216 AC_MSG_CHECKING([whether to use xxhash])
2217 AC_MSG_RESULT([$with_xxhash])
2218
2219 NM_H=
2220 rm -f nm.h
2221 if test "${nativefile}" != ""; then
2222     case "${nativefile}" in
2223       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2224       * ) GDB_NM_FILE="${nativefile}"
2225     esac
2226     AC_CONFIG_LINKS([nm.h:$GDB_NM_FILE], [echo > stamp-nmh],
2227                     [GDB_NM_FILE=$GDB_NM_FILE])
2228     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2229     NM_H=nm.h
2230 fi
2231 AC_SUBST(GDB_NM_FILE)
2232 AC_SUBST(NM_H)
2233
2234 dnl Add dependency for xsltproc if building with maintainer-mode enabled.
2235 AC_PATH_PROGS(XSLTPROC, xsltproc, missing)
2236 if test "x$USE_MAINTAINER_MODE" = xyes; then
2237   if test "${XSLTPROC}" = missing; then
2238     AC_MSG_ERROR(unable to find xsltproc.  maintainer-mode requires xsltproc.)
2239   fi
2240 fi
2241 AC_SUBST(XSLTPROC)
2242
2243 dnl Check for exe extension set on certain hosts (e.g. Win32)
2244 AC_EXEEXT
2245
2246 dnl  Detect the character set used by this host.
2247 dnl  At the moment, we just assume it's UTF-8.
2248 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2249           [Define to be a string naming the default host character set.])
2250
2251 GDB_AC_SELFTEST([
2252   CONFIG_OBS="$CONFIG_OBS \$(SELFTESTS_OBS)"
2253   CONFIG_SRCS="$CONFIG_SRCS \$(SELFTESTS_SRCS)"
2254 ])
2255
2256 GDB_AC_TRANSFORM([gdb], [GDB_TRANSFORM_NAME])
2257 GDB_AC_TRANSFORM([gcore], [GCORE_TRANSFORM_NAME])
2258 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2259 AC_CONFIG_FILES([Makefile gdb-gdb.gdb gdb-gdb.py doc/Makefile data-directory/Makefile])
2260
2261 AC_OUTPUT