gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2012 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22 AC_INIT(main.c)
  23 AC_CONFIG_HEADER(config.h:config.in)
  24 AM_MAINTAINER_MODE
  25
  26 AC_PROG_CC
  27 AC_USE_SYSTEM_EXTENSIONS
  28 ACX_LARGEFILE
  29 AM_PROG_CC_STDC
  30
  31 AC_CONFIG_AUX_DIR(..)
  32 AC_CANONICAL_SYSTEM
  33 AC_ARG_PROGRAM
  34
  35 # Dependency checking.
  36 ZW_CREATE_DEPDIR
  37 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  38
  39 # Check for the 'make' the user wants to use.
  40 AC_CHECK_PROGS(MAKE, make)
  41 MAKE_IS_GNU=
  42 case "`$MAKE --version 2>&1 | sed 1q`" in
  43   *GNU*)
  44     MAKE_IS_GNU=yes
  45     ;;
  46 esac
  47 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  48 AC_PROG_MAKE_SET
  49
  50 # Configure gnulib.  We need to build gnulib under some other
  51 # directory not "gnulib", to avoid the problem of both GDB and
  52 # GDBserver wanting to build it in the same directory, when building
  53 # in the source dir.
  54 ACX_CONFIGURE_DIR(["gnulib"], ["build-gnulib"])
  55
  56 dnl List of object files and targets accumulated by configure.
  57
  58 CONFIG_OBS=
  59 CONFIG_DEPS=
  60 CONFIG_SRCS=
  61 ENABLE_CFLAGS=
  62
  63 CONFIG_ALL=
  64 CONFIG_CLEAN=
  65 CONFIG_INSTALL=
  66 CONFIG_UNINSTALL=
  67
  68 dnl Set up for gettext.
  69 ZW_GNU_GETTEXT_SISTER_DIR
  70
  71 localedir='${datadir}/locale'
  72 AC_SUBST(localedir)
  73
  74 if test x"$USE_NLS" = xyes; then
  75    CONFIG_ALL="$CONFIG_ALL all-po"
  76    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  77    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  78    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  79 fi
  80
  81 GNULIB=build-gnulib/import
  82
  83 # For Makefile dependencies.
  84 GNULIB_STDINT_H=
  85 if test x"$STDINT_H" != x; then
  86   GNULIB_STDINT_H=$GNULIB/$STDINT_H
  87 fi
  88 AC_SUBST(GNULIB_STDINT_H)
  89
  90 PACKAGE=gdb
  91 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  92 AC_SUBST(PACKAGE)
  93
  94 # We never need to detect it in this sub-configure.
  95 # But preserve it for config.status --recheck.
  96 AC_ARG_VAR(MAKEINFO,
  97   [Parent configure detects if it is of sufficient version.])
  98 AC_ARG_VAR(MAKEINFOFLAGS,
  99   [Parameters for MAKEINFO.])
 100
 101 MAKEINFO_EXTRA_FLAGS=""
 102 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
 103   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
 104   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
 105     gdb_cv_have_makeinfo_click=yes
 106   else
 107     gdb_cv_have_makeinfo_click=no
 108   fi])
 109 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 110   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 111 fi
 112 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 113
 114 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 115     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 116     [${libdir}/debug])
 117
 118 # We can't pass paths as command line arguments.
 119 # Mingw32 tries to be clever and will convert the paths for us.
 120 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 121 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 122 # This breaks GDB's relocatable path conversions since paths passed in
 123 # config.h would not get so translated, the path prefixes no longer match.
 124 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 125
 126 # GDB's datadir relocation
 127
 128 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 129     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 130     [${datadir}/gdb])
 131
 132 AC_ARG_WITH(relocated-sources,
 133 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 134 [reloc_srcdir="${withval}"
 135  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 136               [Relocated directory for source files. ])
 137 ])
 138
 139 AC_MSG_CHECKING([for default auto-load safe-path])
 140 AC_ARG_WITH(auto-load-safe-path,
 141 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 142   [directories safe to hold auto-loaded files, use $ddir for --with-gdb-datadir path @<:@$ddir/auto-load@:>@])
 143 AS_HELP_STRING([--without-auto-load-safe-path],
 144                [do not restrict auto-loaded files locations]),
 145     [if test "$with_auto_load_safe_path" = "no"; then
 146      with_auto_load_safe_path="/"
 147      fi],
 148 [with_auto_load_safe_path='$ddir/auto-load'])
 149 escape_dir=`echo $with_auto_load_safe_path | sed 's/[[$]]ddir\>/\\\\\\\\\\\\&/g'`
 150 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 151               [Directories safe to hold auto-loaded files.])
 152 AC_MSG_RESULT([$with_auto_load_safe_path])
 153
 154 AC_CONFIG_SUBDIRS(testsuite)
 155
 156 # Check whether to support alternative target configurations
 157 AC_ARG_ENABLE(targets,
 158 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 159 [case "${enableval}" in
 160   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 161             ;;
 162   no)       enable_targets= ;;
 163   *)        enable_targets=$enableval ;;
 164 esac])
 165
 166 # Check whether to enable 64-bit support on 32-bit hosts
 167 AC_ARG_ENABLE(64-bit-bfd,
 168 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 169 [case "${enableval}" in
 170   yes)  want64=true  ;;
 171   no)   want64=false ;;
 172   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 173 esac],[want64=false])dnl
 174
 175 # Provide defaults for some variables set by the per-host and per-target
 176 # configuration.
 177 gdb_host_obs=posix-hdep.o
 178
 179 if test "${target}" = "${host}"; then
 180   gdb_native=yes
 181 else
 182   gdb_native=no
 183 fi
 184
 185 . $srcdir/configure.host
 186
 187 # Accumulate some settings from configure.tgt over all enabled targets
 188
 189 TARGET_OBS=
 190 all_targets=
 191
 192 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 193 do
 194   if test "$targ_alias" = "all"; then
 195     all_targets=true
 196   else
 197     # Canonicalize the secondary target names.
 198     result=`$ac_config_sub $targ_alias 2>/dev/null`
 199     if test -n "$result"; then
 200         targ=$result
 201     else
 202         targ=$targ_alias
 203     fi
 204
 205     . ${srcdir}/configure.tgt
 206
 207     AS_IF([test -z "${gdb_target_obs}"],
 208       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 209
 210     # Target-specific object files
 211     for i in ${gdb_target_obs}; do
 212         case " $TARGET_OBS " in
 213         *" ${i} "*) ;;
 214         *)
 215           TARGET_OBS="$TARGET_OBS ${i}"
 216           ;;
 217         esac
 218     done
 219
 220     # Check whether this target needs 64-bit CORE_ADDR
 221     if test x${want64} = xfalse; then
 222       . ${srcdir}/../bfd/config.bfd
 223     fi
 224   fi
 225 done
 226
 227 if test x${all_targets} = xtrue; then
 228
 229   # We want all 64-bit targets if we either:
 230   #  - run on a 64-bit host  or
 231   #  - already require 64-bit support for some other target  or
 232   #  - the --enable-64-bit-bfd option was supplied
 233   # Otherwise we only support all 32-bit targets.
 234   #
 235   # NOTE: This test must be in sync with the corresponding
 236   #       tests in BFD!
 237
 238   if test x${want64} = xfalse; then
 239     AC_CHECK_SIZEOF(long)
 240     if test "x${ac_cv_sizeof_long}" = "x8"; then
 241       want64=true
 242     fi
 243   fi
 244   if test x${want64} = xtrue; then
 245     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 246   else
 247     TARGET_OBS='$(ALL_TARGET_OBS)'
 248   fi
 249 fi
 250
 251 AC_SUBST(TARGET_OBS)
 252
 253 # For other settings, only the main target counts.
 254 gdb_sim=
 255 gdb_osabi=
 256 build_gdbserver=
 257 targ=$target; . ${srcdir}/configure.tgt
 258
 259 # Fetch the default architecture and default target vector from BFD.
 260 targ=$target; . $srcdir/../bfd/config.bfd
 261
 262 # We only want the first architecture, so strip off the others if
 263 # there is more than one.
 264 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 265
 266 if test "x$targ_archs" != x; then
 267   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 268     [Define to BFD's default architecture. ])
 269 fi
 270 if test "x$targ_defvec" != x; then
 271   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 272     [Define to BFD's default target vector. ])
 273 fi
 274
 275 # The CLI cannot be disabled yet, but may be in the future.
 276
 277 # Enable CLI.
 278 AC_ARG_ENABLE(gdbcli,
 279 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 280   [case $enableval in
 281     yes)
 282       ;;
 283     no)
 284       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 285     *)
 286       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 287   esac],
 288   [enable_gdbcli=yes])
 289 if test x"$enable_gdbcli" = xyes; then
 290   if test -d $srcdir/cli; then
 291     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 292     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 293     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 294     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 295   fi
 296 fi
 297
 298 # Enable MI.
 299 AC_ARG_ENABLE(gdbmi,
 300 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 301   [case $enableval in
 302     yes | no)
 303       ;;
 304     *)
 305       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 306   esac],
 307   [enable_gdbmi=yes])
 308 if test x"$enable_gdbmi" = xyes; then
 309   if test -d $srcdir/mi; then
 310     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 311     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 312     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 313     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 314   fi
 315 fi
 316
 317 # Enable TUI.
 318 AC_ARG_ENABLE(tui,
 319 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 320   [case $enableval in
 321     yes | no | auto)
 322       ;;
 323     *)
 324       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 325   esac],enable_tui=auto)
 326
 327 # Enable gdbtk.
 328 AC_ARG_ENABLE(gdbtk,
 329 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 330   [case $enableval in
 331     yes | no)
 332       ;;
 333     *)
 334       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 335   esac],
 336   [if test -d $srcdir/gdbtk; then
 337     enable_gdbtk=yes
 338   else
 339     enable_gdbtk=no
 340   fi])
 341 # We unconditionally disable gdbtk tests on selected platforms.
 342 case $host_os in
 343   go32* | windows*)
 344     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 345     enable_gdbtk=no ;;
 346 esac
 347
 348 # Libunwind support for ia64.
 349
 350 AC_ARG_WITH(libunwind-ia64,
 351 AS_HELP_STRING([--with-libunwind-ia64],
 352                [use libunwind frame unwinding for ia64 targets]),,
 353             [with_libunwind_ia64=auto])
 354
 355 # Backward compatibility option.
 356 if test "${with_libunwind+set}" = set; then
 357   if test x"$with_libunwind_ia64" != xauto; then
 358     AC_MSG_ERROR(
 359       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 360   fi
 361   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 362   with_libunwind_ia64="$with_libunwind"
 363 fi
 364
 365 case "$with_libunwind_ia64" in
 366   yes | no)
 367     ;;
 368   auto)
 369     AC_CHECK_HEADERS(libunwind-ia64.h)
 370     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 371     ;;
 372   *)
 373     AC_MSG_ERROR(
 374       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 375     ;;
 376 esac
 377
 378 if test x"$with_libunwind_ia64" = xyes; then
 379   AC_CHECK_HEADERS(libunwind-ia64.h)
 380   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 381     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 382   fi
 383   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 384   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 385   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 386 fi
 387
 388 opt_curses=no
 389 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 390
 391 prefer_curses=no
 392 if test "$opt_curses" = "yes"; then
 393   prefer_curses=yes
 394 fi
 395
 396 # Profiling support.
 397 AC_ARG_ENABLE(profiling,
 398 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 399   [case $enableval in
 400     yes | no)
 401       ;;
 402     *)
 403       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 404   esac],
 405  [enable_profiling=no])
 406
 407 AC_CHECK_FUNCS(monstartup _mcleanup)
 408 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 409 [AC_TRY_LINK(
 410 [#include <stdlib.h>
 411 extern char _etext;
 412 ],
 413 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 414 if test $ac_cv_var__etext = yes; then
 415   AC_DEFINE(HAVE__ETEXT, 1,
 416             [Define to 1 if your system has the _etext variable. ])
 417 fi
 418 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 419 [AC_TRY_LINK(
 420 [#include <stdlib.h>
 421 extern char etext;
 422 ],
 423 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 424 if test $ac_cv_var_etext = yes; then
 425   AC_DEFINE(HAVE_ETEXT, 1,
 426             [Define to 1 if your system has the etext variable. ])
 427 fi
 428 if test "$enable_profiling" = yes ; then
 429   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 430     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 431   fi
 432   PROFILE_CFLAGS=-pg
 433   OLD_CFLAGS="$CFLAGS"
 434   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 435
 436   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 437     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 438      ac_cv_cc_supports_pg=no)])
 439
 440   if test $ac_cv_cc_supports_pg = no; then
 441     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 442   fi
 443
 444   CFLAGS="$OLD_CFLAGS"
 445 fi
 446
 447 ACX_PKGVERSION([GDB])
 448 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 449 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 450 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 451
 452 # --------------------- #
 453 # Checks for programs.  #
 454 # --------------------- #
 455
 456 AC_PROG_AWK
 457 AC_PROG_INSTALL
 458 AC_PROG_LN_S
 459 AC_PROG_RANLIB
 460 AC_PROG_YACC
 461
 462 AC_CHECK_TOOL(AR, ar)
 463 AC_CHECK_TOOL(DLLTOOL, dlltool)
 464 AC_CHECK_TOOL(WINDRES, windres)
 465
 466 # Needed for GNU/Hurd.
 467 AC_CHECK_TOOL(MIG, mig)
 468
 469 # ---------------------- #
 470 # Checks for libraries.  #
 471 # ---------------------- #
 472
 473 # We might need to link with -lm; most simulators need it.
 474 AC_CHECK_LIB(m, main)
 475
 476 # We need to link with -lw to get `wctype' on Solaris before Solaris
 477 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 478 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 479 # is known to have this problem).  Therefore we avoid libw if we can.
 480 AC_CHECK_FUNC(wctype, [],
 481   [AC_CHECK_LIB(w, wctype)])
 482
 483 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 484 AC_SEARCH_LIBS(gethostbyname, nsl)
 485
 486 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 487 AC_SEARCH_LIBS(socketpair, socket)
 488
 489 # Link in zlib if we can.  This allows us to read compressed debug sections.
 490 AM_ZLIB
 491
 492 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 493 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 494
 495 AM_ICONV
 496
 497 # GDB may fork/exec the iconv program to get the list of supported character
 498 # sets.  Allow the user to specify where to find it.
 499 # There are several factors affecting the choice of option name:
 500 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 501 #   the build-time location of libiconv files.
 502 # - The program we need to find is iconv, which comes with glibc.  The user
 503 #   doesn't necessarily have libiconv installed.  Therefore naming this
 504 #   --with-libiconv-foo feels wrong.
 505 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 506 #   defined to work on directories not files (though it really doesn't know
 507 #   the difference).
 508 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 509 #   with --with-libiconv-prefix.
 510 # Putting these together is why the option name is --with-iconv-bin.
 511
 512 AC_ARG_WITH(iconv-bin,
 513 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 514 [iconv_bin="${withval}"
 515  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 516                     [Path of directory of iconv program.])
 517  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 518 ])
 519
 520 # On alpha-osf, it appears that libtermcap and libcurses are not compatible.
 521 # There is a very specific comment in /usr/include/curses.h explaining that
 522 # termcap routines built into libcurses must not be used.
 523 #
 524 # The symptoms we observed so far is GDB unexpectedly changing
 525 # the terminal settings when tgetent is called - this is particularly
 526 # visible as the output is missing carriage returns, and so rapidly
 527 # becomes very hard to read.
 528 #
 529 # The readline configure script has already decided that libtermcap
 530 # was enough for its purposes, and so decided to build readline using
 531 # libtermcap.  Since the TUI mode requires curses, building GDB with
 532 # TUI enabled results in both libraries to be used at the same time,
 533 # which is not allowed.  This basically means that GDB with TUI is
 534 # broken on alpha-osf.
 535
 536 case $host_os in
 537   osf* )
 538     if test x"$enable_tui" = xyes; then
 539       AC_MSG_ERROR([Building GDB with TUI mode is not supported on this host])
 540     fi
 541     if test x"$enable_tui" = xauto; then
 542       enable_tui=no
 543     fi
 544     ;;
 545 esac
 546
 547 # For the TUI, we need enhanced curses functionality.
 548 if test x"$enable_tui" != xno; then
 549   prefer_curses=yes
 550 fi
 551
 552 curses_found=no
 553 if test x"$prefer_curses" = xyes; then
 554   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 555   # curses library because the latter might not provide all the
 556   # functionality we need.  However, this leads to problems on systems
 557   # where the linker searches /usr/local/lib, but the compiler doesn't
 558   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 559   # default installation of ncurses on alpha*-dec-osf* will lead to such
 560   # a situation.
 561   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 562
 563   if test "$ac_cv_search_waddstr" != no; then
 564     curses_found=yes
 565   fi
 566 fi
 567
 568 # Check whether we should enable the TUI, but only do so if we really
 569 # can.
 570 if test x"$enable_tui" != xno; then
 571   if test -d $srcdir/tui; then
 572     if test "$curses_found" != no; then
 573       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 574       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 575       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 576       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 577     else
 578       if test x"$enable_tui" = xyes; then
 579         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 580       else
 581         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 582       fi
 583     fi
 584   fi
 585 fi
 586
 587 # Since GDB uses Readline, we need termcap functionality.  In many
 588 # cases this will be provided by the curses library, but some systems
 589 # have a seperate termcap library, or no curses library at all.
 590
 591 case $host_os in
 592   cygwin*)
 593     if test -d $srcdir/libtermcap; then
 594       LIBS="../libtermcap/libtermcap.a $LIBS"
 595       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 596     fi ;;
 597   go32* | *djgpp*)
 598     ac_cv_search_tgetent="none required"
 599     ;;
 600   *mingw32*)
 601     ac_cv_search_tgetent="none required"
 602     CONFIG_OBS="$CONFIG_OBS windows-termcap.o"
 603     ;;
 604 esac
 605
 606 # These are the libraries checked by Readline.
 607 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 608
 609 if test "$ac_cv_search_tgetent" = no; then
 610   AC_MSG_ERROR([no termcap library found])
 611 fi
 612
 613 AC_ARG_WITH([system-readline],
 614   [AS_HELP_STRING([--with-system-readline],
 615                   [use installed readline library])])
 616
 617 if test "$with_system_readline" = yes; then
 618   READLINE=-lreadline
 619   READLINE_DEPS=
 620   READLINE_CFLAGS=
 621   READLINE_TEXI_INCFLAG=
 622 else
 623   READLINE='$(READLINE_DIR)/libreadline.a'
 624   READLINE_DEPS='$(READLINE)'
 625   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 626   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 627 fi
 628 AC_SUBST(READLINE)
 629 AC_SUBST(READLINE_DEPS)
 630 AC_SUBST(READLINE_CFLAGS)
 631 AC_SUBST(READLINE_TEXI_INCFLAG)
 632
 633 # Generate jit-reader.h
 634
 635 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 636 TARGET_PTR=
 637
 638 AC_CHECK_SIZEOF(unsigned long long)
 639 AC_CHECK_SIZEOF(unsigned long)
 640 AC_CHECK_SIZEOF(unsigned __int128)
 641
 642 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 643   TARGET_PTR="unsigned long"
 644 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 645   TARGET_PTR="unsigned long long"
 646 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 647   TARGET_PTR="unsigned __int128"
 648 else
 649   TARGET_PTR="unsigned long"
 650 fi
 651
 652 AC_SUBST(TARGET_PTR)
 653 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 654
 655 AC_SEARCH_LIBS(dlopen, dl)
 656
 657 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 658                 [directory to load the JIT readers from],
 659                 [${libdir}/gdb])
 660
 661 AC_ARG_WITH(expat,
 662   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 663   [], [with_expat=auto])
 664 AC_MSG_CHECKING([whether to use expat])
 665 AC_MSG_RESULT([$with_expat])
 666
 667 if test "${with_expat}" = no; then
 668   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 669   HAVE_LIBEXPAT=no
 670 else
 671   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 672                         [XML_Parser p = XML_ParserCreate (0);])
 673   if test "$HAVE_LIBEXPAT" != yes; then
 674     if test "$with_expat" = yes; then
 675       AC_MSG_ERROR([expat is missing or unusable])
 676     else
 677       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 678     fi
 679   else
 680     save_LIBS=$LIBS
 681     LIBS="$LIBS $LIBEXPAT"
 682     AC_CHECK_FUNCS(XML_StopParser)
 683     LIBS=$save_LIBS
 684   fi
 685 fi
 686
 687 dnl Utility to simplify finding libpython.
 688 dnl $1 = pythonX.Y
 689 dnl $2 = the shell variable to assign the result to
 690 dnl      If libpython is found we store $version here.
 691 dnl $3 = additional flags to add to CPPFLAGS
 692 dnl $4 = additional flags to add to LIBS
 693
 694 AC_DEFUN([AC_TRY_LIBPYTHON],
 695 [
 696   version=$1
 697   define([have_libpython_var],$2)
 698   new_CPPFLAGS=$3
 699   new_LIBS=$4
 700   AC_MSG_CHECKING([for ${version}])
 701   save_CPPFLAGS=$CPPFLAGS
 702   save_LIBS=$LIBS
 703   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 704   LIBS="$LIBS $new_LIBS"
 705   found_usable_python=no
 706   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 707                                  [[Py_Initialize ();]]),
 708                  [have_libpython_var=${version}
 709                   found_usable_python=yes
 710                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 711                   PYTHON_LIBS=$new_LIBS])
 712   CPPFLAGS=$save_CPPFLAGS
 713   LIBS=$save_LIBS
 714   AC_MSG_RESULT([${found_usable_python}])
 715 ])
 716
 717 dnl There are several different values for --with-python:
 718 dnl
 719 dnl no -   Don't include python support.
 720 dnl yes -  Include python support, error if it's missing.
 721 dnl        If we find python in $PATH, use it to fetch configure options,
 722 dnl        otherwise assume the compiler can find it with no help from us.
 723 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 724 dnl auto - Same as "yes", but if python is missing from the system,
 725 dnl        fall back to "no".
 726 dnl /path/to/python/exec-prefix -
 727 dnl        Use the python located in this directory.
 728 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 729 dnl        the compilation parameters.  Otherwise use
 730 dnl        -I/path/to/python/exec-prefix/include,
 731 dnl        -L/path/to/python/exec-prefix/lib.
 732 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 733 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 734 dnl        but is deprecated.
 735 dnl /path/to/python/executable -
 736 dnl        Run python-config.py with this version of python to fetch the
 737 dnl        compilation parameters.
 738 dnl        NOTE: This needn't be the real python executable.
 739 dnl        In a cross-compilation scenario (build != host), this could be
 740 dnl        a shell script that provides what python-config.py provides for
 741 dnl        --ldflags, --includes, --exec-prefix.
 742 dnl python-executable -
 743 dnl        Find python-executable in $PATH, and then handle the same as
 744 dnl        /path/to/python/executable.
 745 dnl
 746 dnl If a python program is specified, it is used to run python-config.py and
 747 dnl is passed --ldflags, --includes, --exec-prefix.
 748
 749 AC_ARG_WITH(python,
 750   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 751   [], [with_python=auto])
 752 AC_MSG_CHECKING([whether to use python])
 753 AC_MSG_RESULT([$with_python])
 754
 755 if test "${with_python}" = no; then
 756   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 757   have_libpython=no
 758 else
 759   case "${with_python}" in
 760   [[\\/]]* | ?:[[\\/]]*)
 761     if test -d ${with_python}; then
 762       # Assume the python binary is ${with_python}/bin/python.
 763       python_prog="${with_python}/bin/python"
 764       python_prefix=
 765       # If python does not exit ${with_python}/bin, then try in
 766       # ${with_python}.  On Windows/MinGW, this is where the Python
 767       # executable is.
 768       if test ! -x "${python_prog}"; then
 769         python_prog="${with_python}/python"
 770         python_prefix=
 771       fi
 772       if test ! -x "${python_prog}"; then
 773         # Fall back to gdb 7.0/7.1 behaviour.
 774         python_prog=missing
 775         python_prefix=${with_python}
 776       fi
 777     elif test -x "${with_python}"; then
 778       # While we can't run python compiled for $host (unless host == build),
 779       # the user could write a script that provides the needed information,
 780       # so we support that.
 781       python_prog=${with_python}
 782       python_prefix=
 783     else
 784       AC_ERROR(invalid value for --with-python)
 785     fi
 786     ;;
 787   */*)
 788     # Disallow --with-python=foo/bar.
 789     AC_ERROR(invalid value for --with-python)
 790     ;;
 791   *)
 792     # The user has either specified auto, yes, or the name of the python
 793     # program assumed to be in $PATH.
 794     python_prefix=
 795     case "${with_python}" in
 796     yes | auto)
 797       if test ${build} = ${host}; then
 798         AC_PATH_PROG(python_prog_path, python, missing)
 799         if test "${python_prog_path}" = missing; then
 800           python_prog=missing
 801         else
 802           python_prog=${python_prog_path}
 803         fi
 804       else
 805         # Not much we can do except assume the cross-compiler will find the
 806         # right files.
 807         python_prog=missing
 808       fi
 809       ;;
 810     *)
 811       # While we can't run python compiled for $host (unless host == build),
 812       # the user could write a script that provides the needed information,
 813       # so we support that.
 814       python_prog="${with_python}"
 815       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 816       if test "${python_prog_path}" = missing; then
 817         AC_ERROR(unable to find python program ${python_prog})
 818       fi
 819       ;;
 820     esac
 821   esac
 822
 823   if test "${python_prog}" != missing; then
 824     # We have a python program to use, but it may be too old.
 825     # Don't flag an error for --with-python=auto (the default).
 826     have_python_config=yes
 827     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 828     if test $? != 0; then
 829       have_python_config=failed
 830       if test "${with_python}" != auto; then
 831         AC_ERROR(failure running python-config --includes)
 832       fi
 833     fi
 834     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 835     if test $? != 0; then
 836       have_python_config=failed
 837       if test "${with_python}" != auto; then
 838         AC_ERROR(failure running python-config --ldflags)
 839       fi
 840     fi
 841     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 842     if test $? != 0; then
 843       have_python_config=failed
 844       if test "${with_python}" != auto; then
 845         AC_ERROR(failure running python-config --exec-prefix)
 846       fi
 847     fi
 848   else
 849     # We do not have a python executable we can use to determine where
 850     # to find the Python headers and libs.  We cannot guess the include
 851     # path from the python_prefix either, because that include path
 852     # depends on the Python version.  So, there is nothing much we can
 853     # do except assume that the compiler will be able to find those files.
 854     python_includes=
 855     python_libs=
 856     have_python_config=no
 857   fi
 858
 859   # If we have python-config, only try the configuration it provides.
 860   # Otherwise fallback on the old way of trying different versions of
 861   # python in turn.
 862
 863   have_libpython=no
 864   if test "${have_python_config}" = yes; then
 865     # Determine the Python version by extracting "-lpython<version>"
 866     # part of the python_libs. <version> is usually X.Y with X and Y
 867     # being decimal numbers, but can also be XY (seen on Windows).
 868     #
 869     # The extraction is performed using sed with a regular expression.
 870     # Initially, the regexp used was using the '?' quantifier to make
 871     # the dot in the version number optional.  Unfortunately, this
 872     # does not work with non-GNU versions of sed because, because of
 873     # what looks like a limitation (the '?' quantifier does not work
 874     # with back-references).  We work around this limitation by using
 875     # the '*' quantifier instead.  It means that, in theory, we might
 876     # match unexpected version strings such as "-lpython2..7", but
 877     # this seems unlikely in practice.  And even if that happens,
 878     # an error will be triggered later on, when checking that version
 879     # number.
 880     python_version=`echo " ${python_libs} " \
 881                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 882     case "${python_version}" in
 883     python*)
 884       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 885                        ${python_includes}, ${python_libs})
 886       ;;
 887     *)
 888       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 889       ;;
 890     esac
 891   elif test "${have_python_config}" != failed; then
 892     if test "${have_libpython}" = no; then
 893       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 894                        ${python_includes}, "${python_libs} -lpython2.7")
 895     fi
 896     if test "${have_libpython}" = no; then
 897       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 898                        ${python_includes}, "${python_libs} -lpython2.6")
 899     fi
 900     if test ${have_libpython} = no; then
 901       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 902                        ${python_includes}, "${python_libs} -lpython2.5")
 903     fi
 904     if test ${have_libpython} = no; then
 905       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 906                        ${python_includes}, "${python_libs} -lpython2.4")
 907     fi
 908   fi
 909   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 910     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 911   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 912     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 913   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 914     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 915   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 916     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 917   fi
 918
 919   if test "${have_libpython}" = no; then
 920     case "${with_python}" in
 921     yes)
 922       AC_MSG_ERROR([python is missing or unusable])
 923       ;;
 924     auto)
 925       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 926       ;;
 927     *)
 928       AC_MSG_ERROR([no usable python found at ${with_python}])
 929       ;;
 930     esac
 931   else
 932     if test -n "${python_prefix}"; then
 933       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 934                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 935       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 936     fi
 937   fi
 938 fi
 939
 940 if test "${have_libpython}" != no; then
 941   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 942   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 943   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 944   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 945   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 946   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 947
 948   # Flags needed to compile Python code (taken from python-config --cflags).
 949   # We cannot call python-config directly because it will output whatever was
 950   # used when compiling the Python interpreter itself, including flags which
 951   # would make the python-related objects be compiled differently from the
 952   # rest of GDB (e.g., -O2 and -fPIC).
 953   if test "${GCC}" = yes; then
 954     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 955   fi
 956
 957   if test "x${tentative_python_cflags}" != x; then
 958     AC_MSG_CHECKING(compiler flags for python code)
 959     for flag in ${tentative_python_cflags}; do
 960       # Check that the compiler accepts it
 961       saved_CFLAGS="$CFLAGS"
 962       CFLAGS="$CFLAGS $flag"
 963       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 964       CFLAGS="$saved_CFLAGS"
 965     done
 966     AC_MSG_RESULT(${PYTHON_CFLAGS})
 967   fi
 968
 969   # On IRIX, type siginfo is not defined.  Instead, sys/siginfo.h provides:
 970   #    #if _SGIAPI
 971   #    #define siginfo __siginfo
 972   #    #endif
 973   # The problem is that including Python causes some XOPEN macros to be
 974   # unilaterally defined, and that in turn causes _SGIAPI to evaluate
 975   # to false.  So, we work around this issue by defining siginfo ourself
 976   # though the command-line.
 977   case "$gdb_host" in
 978     irix*) if test "${GCC}" = yes; then
 979              CPPFLAGS="$CPPFLAGS -Dsiginfo=__siginfo"
 980            fi
 981            ;;
 982   esac
 983 else
 984   # Even if Python support is not compiled in, we need to have these files
 985   # included.
 986   CONFIG_OBS="$CONFIG_OBS python.o py-value.o py-prettyprint.o py-auto-load.o"
 987   CONFIG_SRCS="$CONFIG_SRCS python/python.c python/py-value.c \
 988         python/py-prettyprint.c python/py-auto-load.c"
 989 fi
 990 AC_SUBST(PYTHON_CFLAGS)
 991 AC_SUBST(PYTHON_CPPFLAGS)
 992 AC_SUBST(PYTHON_LIBS)
 993
 994 # ------------------------- #
 995 # Checks for header files.  #
 996 # ------------------------- #
 997
 998 AC_HEADER_DIRENT
 999 AC_HEADER_STAT
1000 AC_HEADER_STDC
1001 # elf_hp.h is for HP/UX 64-bit shared library support.
1002 # FIXME: kettenis/20030102: In most cases we include these (ctype.h, time.h)
1003 # unconditionally, so what's the point in checking these?
1004 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
1005                   thread_db.h gnu/libc-version.h signal.h stddef.h \
1006                   stdlib.h string.h memory.h strings.h sys/fault.h \
1007                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1008                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1009                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
1010                   sys/types.h sys/wait.h wait.h termios.h termio.h \
1011                   sgtty.h unistd.h elf_hp.h ctype.h time.h locale.h \
1012                   dlfcn.h sys/socket.h sys/un.h])
1013 AC_CHECK_HEADERS(link.h, [], [],
1014 [#if HAVE_SYS_TYPES_H
1015 # include <sys/types.h>
1016 #endif
1017 #if HAVE_NLIST_H
1018 # include <nlist.h>
1019 #endif
1020 ])
1021 AC_CHECK_HEADERS(sys/proc.h, [], [],
1022 [#if HAVE_SYS_PARAM_H
1023 # include <sys/param.h>
1024 #endif
1025 ])
1026 AC_CHECK_HEADERS(sys/user.h, [], [],
1027 [#if HAVE_SYS_PARAM_H
1028 # include <sys/param.h>
1029 #endif
1030 ])
1031
1032 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
1033 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
1034 # think that we don't have <curses.h> if we're using GCC.
1035 case $host_os in
1036   solaris2.[[789]])
1037     if test "$GCC" = yes; then
1038       AC_DEFINE(_MSE_INT_H, 1,
1039         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
1040    Solaris 2.[789] when using GCC. ])
1041     fi ;;
1042 esac
1043 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
1044 AC_CHECK_HEADERS(term.h, [], [],
1045 [#if HAVE_CURSES_H
1046 # include <curses.h>
1047 #endif
1048 ])
1049
1050 # ------------------------- #
1051 # Checks for declarations.  #
1052 # ------------------------- #
1053
1054 AC_CHECK_DECLS([free, malloc, realloc, strerror, strstr, getopt,
1055                 snprintf, vsnprintf])
1056 AM_LC_MESSAGES
1057
1058 # ----------------------- #
1059 # Checks for structures.  #
1060 # ----------------------- #
1061
1062 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1063
1064 # ------------------ #
1065 # Checks for types.  #
1066 # ------------------ #
1067
1068 AC_TYPE_SIGNAL
1069 AC_CHECK_TYPES(socklen_t, [], [],
1070 [#include <sys/types.h>
1071 #include <sys/socket.h>
1072 ])
1073
1074 # ------------------------------------- #
1075 # Checks for compiler characteristics.  #
1076 # ------------------------------------- #
1077
1078 AC_C_CONST
1079 AC_C_INLINE
1080 AC_C_BIGENDIAN
1081
1082 # ------------------------------ #
1083 # Checks for library functions.  #
1084 # ------------------------------ #
1085
1086 AC_FUNC_ALLOCA
1087 AC_FUNC_MMAP
1088 AC_FUNC_VFORK
1089 AC_CHECK_FUNCS([canonicalize_file_name realpath getrusage getuid getgid \
1090                 pipe poll pread pread64 pwrite readlink resize_term \
1091                 sbrk setpgid setpgrp setsid \
1092                 sigaction sigprocmask sigsetmask socketpair syscall \
1093                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1094                 setrlimit getrlimit posix_madvise waitpid lstat])
1095 AM_LANGINFO_CODESET
1096
1097 # Check the return and argument types of ptrace.  No canned test for
1098 # this, so roll our own.
1099 gdb_ptrace_headers='
1100 #if HAVE_SYS_TYPES_H
1101 # include <sys/types.h>
1102 #endif
1103 #if HAVE_SYS_PTRACE_H
1104 # include <sys/ptrace.h>
1105 #endif
1106 #if HAVE_UNISTD_H
1107 # include <unistd.h>
1108 #endif
1109 '
1110 # There is no point in checking if we don't have a prototype.
1111 AC_CHECK_DECLS(ptrace, [], [
1112   : ${gdb_cv_func_ptrace_ret='int'}
1113   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1114 ], $gdb_ptrace_headers)
1115 # Check return type.  Varargs (used on GNU/Linux) conflict with the
1116 # empty argument list, so check for that explicitly.
1117 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
1118   AC_TRY_COMPILE($gdb_ptrace_headers,
1119     [extern long ptrace (enum __ptrace_request, ...);],
1120     gdb_cv_func_ptrace_ret='long',
1121     AC_TRY_COMPILE($gdb_ptrace_headers,
1122       [extern int ptrace ();],
1123       gdb_cv_func_ptrace_ret='int',
1124       gdb_cv_func_ptrace_ret='long')))
1125 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
1126   [Define as the return type of ptrace.])
1127 # Check argument types.
1128 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
1129   AC_TRY_COMPILE($gdb_ptrace_headers,
1130     [extern long ptrace (enum __ptrace_request, ...);],
1131     [gdb_cv_func_ptrace_args='int,int,long,long'],[
1132 for gdb_arg1 in 'int' 'long'; do
1133  for gdb_arg2 in 'pid_t' 'int' 'long'; do
1134   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
1135    for gdb_arg4 in 'int' 'long'; do
1136      AC_TRY_COMPILE($gdb_ptrace_headers, [
1137 extern $gdb_cv_func_ptrace_ret
1138   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
1139 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
1140     break 4;])
1141     for gdb_arg5 in 'int *' 'int' 'long'; do
1142      AC_TRY_COMPILE($gdb_ptrace_headers, [
1143 extern $gdb_cv_func_ptrace_ret
1144   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
1145 ], [
1146 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
1147     break 5;])
1148     done
1149    done
1150   done
1151  done
1152 done
1153 # Provide a safe default value.
1154 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1155 ])])
1156 ac_save_IFS=$IFS; IFS=','
1157 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
1158 IFS=$ac_save_IFS
1159 shift
1160 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
1161   [Define to the type of arg 3 for ptrace.])
1162 if test -n "$[5]"; then
1163   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
1164     [Define to the type of arg 5 for ptrace.])
1165 fi
1166
1167 dnl AC_FUNC_SETPGRP does not work when cross compiling
1168 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1169 if test "$cross_compiling" = no; then
1170   AC_FUNC_SETPGRP
1171 else
1172   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1173     [AC_TRY_COMPILE([
1174 #include <unistd.h>
1175 ], [
1176   if (setpgrp(1,1) == -1)
1177     exit (0);
1178   else
1179     exit (1);
1180 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1181 if test $ac_cv_func_setpgrp_void = yes; then
1182   AC_DEFINE(SETPGRP_VOID, 1)
1183 fi
1184 fi
1185
1186 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
1187 # since sigsetjmp might only be defined as a macro.
1188 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
1189 [AC_TRY_COMPILE([
1190 #include <setjmp.h>
1191 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
1192 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
1193 if test $gdb_cv_func_sigsetjmp = yes; then
1194   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
1195 fi
1196
1197 # Assume we'll default to using the included libiberty regex.
1198 gdb_use_included_regex=yes
1199
1200 # However, if the system regex is GNU regex, then default to *not*
1201 # using the included regex.
1202 AC_CACHE_CHECK(
1203   [for GNU regex],
1204   [gdb_cv_have_gnu_regex],
1205   [AC_TRY_COMPILE(
1206     [#include <gnu-versions.h>],
1207     [#define REGEX_INTERFACE_VERSION 1
1208 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1209 # error "Version mismatch"
1210 #endif],
1211     gdb_cv_have_gnu_regex=yes,
1212     gdb_cv_have_gnu_regex=no)])
1213 if test $gdb_cv_have_gnu_regex = yes; then
1214   gdb_use_included_regex=no
1215 fi
1216
1217 AC_ARG_WITH(included-regex,
1218   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1219   gdb_with_regex=$withval,
1220   gdb_with_regex=$gdb_use_included_regex)
1221 if test "$gdb_with_regex" = yes; then
1222   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1223     [Define to 1 if the regex included in libiberty should be used.])
1224 fi
1225
1226 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1227 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1228 [#include <sys/param.h>
1229 #include <sys/proc.h>
1230 ])
1231
1232 # See if <sys/lwp.h> defines `struct lwp`.
1233 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1234 [AC_TRY_COMPILE([#include <sys/param.h>
1235 #include <sys/lwp.h>], [struct lwp l;],
1236 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1237 if test $gdb_cv_struct_lwp = yes; then
1238   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1239             [Define to 1 if your system has struct lwp.])
1240 fi
1241
1242 # See if <machine/reg.h> degines `struct reg'.
1243 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1244 [AC_TRY_COMPILE([#include <sys/types.h>
1245 #include <machine/reg.h>], [struct reg r;],
1246 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1247 if test $gdb_cv_struct_reg = yes; then
1248   AC_DEFINE(HAVE_STRUCT_REG, 1,
1249             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1250 fi
1251
1252 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1253 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1254 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1255                  [#include <machine/reg.h>])
1256
1257 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1258 AC_MSG_CHECKING(for PTRACE_GETREGS)
1259 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1260 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1261                 [PTRACE_GETREGS;],
1262                 [gdb_cv_have_ptrace_getregs=yes],
1263                 [gdb_cv_have_ptrace_getregs=no])])
1264 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1265 if test $gdb_cv_have_ptrace_getregs = yes; then
1266   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1267   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1268 fi
1269
1270 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1271 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1272 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1273 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1274                 [PTRACE_GETFPXREGS;],
1275                 [gdb_cv_have_ptrace_getfpxregs=yes],
1276                 [gdb_cv_have_ptrace_getfpxregs=no])])
1277 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1278 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1279   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1280   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1281 fi
1282
1283 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1284 AC_MSG_CHECKING(for PT_GETDBREGS)
1285 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1286 [AC_TRY_COMPILE([#include <sys/types.h>
1287 #include <sys/ptrace.h>],
1288                 [PT_GETDBREGS;],
1289                 [gdb_cv_have_pt_getdbregs=yes],
1290                 [gdb_cv_have_pt_getdbregs=no])])
1291 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1292 if test $gdb_cv_have_pt_getdbregs = yes; then
1293   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1294   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1295 fi
1296
1297 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1298 AC_MSG_CHECKING(for PT_GETXMMREGS)
1299 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1300 [AC_TRY_COMPILE([#include <sys/types.h>
1301 #include <sys/ptrace.h>],
1302                 [PT_GETXMMREGS;],
1303                 [gdb_cv_have_pt_getxmmregs=yes],
1304                 [gdb_cv_have_pt_getxmmregs=no])])
1305 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1306 if test $gdb_cv_have_pt_getxmmregs = yes; then
1307   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1308   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1309 fi
1310
1311 # Detect which type of /proc is in use, such as for Unixware or Solaris.
1312
1313 if test "${target}" = "${host}"; then
1314   case "${host}" in
1315   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
1316       AC_DEFINE(NEW_PROC_API, 1,
1317       [Define if you want to use new multi-fd /proc interface
1318        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1319       ;;
1320   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1321       AC_DEFINE(NEW_PROC_API, 1,
1322       [Define if you want to use new multi-fd /proc interface
1323        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1324       ;;
1325   mips-sgi-irix5*)
1326       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1327       AC_DEFINE([_KMEMUSER], 1,
1328       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1329        around a <sys/proc.h> problem on IRIX 5.])
1330       ;;
1331   esac
1332 fi
1333
1334 if test "$ac_cv_header_sys_procfs_h" = yes; then
1335   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
1336   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
1337   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1338   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1339   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1340   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1341   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1342   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
1343   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1344   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1345   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1346   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1347   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1348   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1349
1350
1351   dnl Check for broken prfpregset_t type
1352
1353   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1354   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1355   dnl instead of the struct itself).  We detect this here, and work
1356   dnl around it in gdb_proc_service.h.
1357
1358   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1359     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1360     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1361       [AC_TRY_RUN([#include <sys/procfs.h>
1362        int main ()
1363        {
1364          if (sizeof (prfpregset_t) == sizeof (void *))
1365            return 1;
1366          return 0;
1367        }],
1368        gdb_cv_prfpregset_t_broken=no,
1369        gdb_cv_prfpregset_t_broken=yes,
1370        gdb_cv_prfpregset_t_broken=yes)])
1371     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1372     if test $gdb_cv_prfpregset_t_broken = yes; then
1373       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1374       [Define if the prfpregset_t type is broken.])
1375     fi
1376   fi
1377
1378   dnl Check for PIOCSET ioctl entry
1379
1380   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
1381   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
1382   [AC_TRY_COMPILE([#include <unistd.h>
1383 #include <sys/types.h>
1384 #include <sys/procfs.h>
1385 ], [
1386     int dummy;;
1387     dummy = ioctl(0, PIOCSET, &dummy);
1388   ],
1389   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
1390   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
1391   if test $gdb_cv_have_procfs_piocset = yes; then
1392     AC_DEFINE(HAVE_PROCFS_PIOCSET, 1,
1393     [Define if ioctl argument PIOCSET is available.])
1394   fi
1395 fi
1396
1397 dnl For native ports (host == target), check to see what kind of
1398 dnl legacy link.h support is needed.  (See solib-legacy.c.)
1399 if test ${host} = ${target} ; then
1400   dnl Check for struct link_map with l_ members which are indicative
1401   dnl of SVR4-like shared libraries
1402
1403   AC_MSG_CHECKING(for member l_addr in struct link_map)
1404   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
1405     [AC_TRY_COMPILE([#include <link.h>],
1406                     [struct link_map lm; (void) lm.l_addr;],
1407                     gdb_cv_have_struct_link_map_with_l_members=yes,
1408                     gdb_cv_have_struct_link_map_with_l_members=no)])
1409   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
1410   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
1411     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1,
1412     [Define if <link.h> exists and defines struct link_map which has
1413      members with an ``l_'' prefix.  (For Solaris, SVR4, and
1414      SVR4-like systems.)])
1415   fi
1416
1417   dnl Check for struct link_map with lm_ members which are indicative
1418   dnl of SunOS-like shared libraries
1419
1420   AC_MSG_CHECKING(for member lm_addr in struct link_map)
1421   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
1422     [AC_TRY_COMPILE([#include <sys/types.h>
1423 #include <link.h>],
1424                     [struct link_map lm; (void) lm.lm_addr;],
1425                     gdb_cv_have_struct_link_map_with_lm_members=yes,
1426                     gdb_cv_have_struct_link_map_with_lm_members=no)])
1427   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
1428   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
1429     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1,
1430     [Define if <link.h> exists and defines struct link_map which has
1431      members with an ``lm_'' prefix.  (For SunOS.)])
1432   fi
1433
1434   dnl Check for struct so_map with som_ members which are found on
1435   dnl some *BSD systems.
1436
1437   AC_MSG_CHECKING(for member som_addr in struct so_map)
1438   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
1439     [AC_TRY_COMPILE([#include <sys/types.h>
1440 #ifdef HAVE_NLIST_H
1441 #include <nlist.h>
1442 #endif
1443 #include <link.h>],
1444                     [struct so_map lm; (void) lm.som_addr;],
1445                     gdb_cv_have_struct_so_map_with_som_members=yes,
1446                     gdb_cv_have_struct_so_map_with_som_members=no)])
1447   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
1448   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
1449     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1,
1450     [Define if <link.h> exists and defines a struct so_map which has
1451      members with an ``som_'' prefix.  (Found on older *BSD systems.)])
1452   fi
1453
1454   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
1455   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
1456
1457   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
1458   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
1459     [AC_TRY_COMPILE([#define _SYSCALL32
1460 #include <sys/link.h>], [struct link_map32 l;],
1461      gdb_cv_have_struct_link_map32=yes,
1462      gdb_cv_have_struct_link_map32=no)])
1463   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
1464   if test $gdb_cv_have_struct_link_map32 = yes; then
1465     AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1,
1466     [Define if <sys/link.h> has struct link_map32])
1467     AC_DEFINE(_SYSCALL32, 1,
1468     [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)])
1469   fi
1470 fi
1471
1472 # Check if the compiler supports the `long long' type.
1473
1474 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1475                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1476 [[extern long long foo;]],
1477 [[switch (foo & 2) { case 0: return 1; }]])],
1478                                   gdb_cv_c_long_long=yes,
1479                                   gdb_cv_c_long_long=no)])
1480 if test $gdb_cv_c_long_long = yes; then
1481   AC_DEFINE(CC_HAS_LONG_LONG, 1,
1482             [Define to 1 if the compiler supports long long.])
1483 fi
1484
1485 # Check if the compiler and runtime support printing long longs.
1486
1487 AC_CACHE_CHECK([for long long support in printf],
1488                gdb_cv_printf_has_long_long,
1489                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1490 [[char buf[32];
1491   long long l = 0;
1492   l = (l << 16) + 0x0123;
1493   l = (l << 16) + 0x4567;
1494   l = (l << 16) + 0x89ab;
1495   l = (l << 16) + 0xcdef;
1496   sprintf (buf, "0x%016llx", l);
1497   return (strcmp ("0x0123456789abcdef", buf));]])],
1498                               gdb_cv_printf_has_long_long=yes,
1499                               gdb_cv_printf_has_long_long=no,
1500                               gdb_cv_printf_has_long_long=no)])
1501 if test $gdb_cv_printf_has_long_long = yes; then
1502   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1503             [Define to 1 if the "%ll" format works to print long longs.])
1504 fi
1505
1506 # Check if the compiler and runtime support printing decfloats.
1507
1508 AC_CACHE_CHECK([for decfloat support in printf],
1509                gdb_cv_printf_has_decfloat,
1510                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1511 [[char buf[64];
1512   _Decimal32 d32 = 1.2345df;
1513   _Decimal64 d64 = 1.2345dd;
1514   _Decimal128 d128 = 1.2345dl;
1515   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1516   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1517                               gdb_cv_printf_has_decfloat=yes,
1518                               gdb_cv_printf_has_decfloat=no,
1519                               gdb_cv_printf_has_decfloat=no)])
1520 if test $gdb_cv_printf_has_decfloat = yes; then
1521   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1522             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1523 fi
1524
1525 # Check if the compiler supports the `long double' type.  We can't use
1526 # AC_C_LONG_DOUBLE because that one does additional checks on the
1527 # constants defined in <float.h> that fail on some systems,
1528 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1529
1530 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1531                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1532                                   gdb_cv_c_long_double=yes,
1533                                   gdb_cv_c_long_double=no)])
1534 if test $gdb_cv_c_long_double = yes; then
1535   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1536            [Define to 1 if the compiler supports long double.])
1537 fi
1538
1539 # Check if the compiler and runtime support printing long doubles.
1540
1541 AC_CACHE_CHECK([for long double support in printf],
1542                gdb_cv_printf_has_long_double,
1543                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1544 [[char buf[16];
1545   long double f = 3.141592653;
1546   sprintf (buf, "%Lg", f);
1547   return (strncmp ("3.14159", buf, 7));]])],
1548                               gdb_cv_printf_has_long_double=yes,
1549                               gdb_cv_printf_has_long_double=no,
1550                               gdb_cv_printf_has_long_double=no)])
1551 if test $gdb_cv_printf_has_long_double = yes; then
1552   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1553             [Define to 1 if the "%Lg" format works to print long doubles.])
1554 fi
1555
1556 # Check if the compiler and runtime support scanning long doubles.
1557
1558 AC_CACHE_CHECK([for long double support in scanf],
1559                gdb_cv_scanf_has_long_double,
1560                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1561 [[#include <stdio.h>]],
1562 [[char *buf = "3.141592653";
1563   long double f = 0;
1564   sscanf (buf, "%Lg", &f);
1565   return !(f > 3.14159 && f < 3.14160);]])],
1566                               gdb_cv_scanf_has_long_double=yes,
1567                               gdb_cv_scanf_has_long_double=no,
1568                               gdb_cv_scanf_has_long_double=no)])
1569 if test $gdb_cv_scanf_has_long_double = yes; then
1570   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1571             [Define to 1 if the "%Lg" format works to scan long doubles.])
1572 fi
1573
1574 case ${host_os} in
1575 aix*)
1576   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1577     SAVE_LDFLAGS=$LDFLAGS
1578
1579     case $GCC in
1580     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1581     *) gdb_cv_bigtoc=-bbigtoc ;;
1582     esac
1583
1584     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1585     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1586     LDFLAGS="${SAVE_LDFLAGS}"
1587   ])
1588   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1589   ;;
1590 esac
1591
1592 AC_MSG_CHECKING(for the dynamic export flag)
1593 dynamic_list=false
1594 if test "${gdb_native}" = yes; then
1595    # The dynamically loaded libthread_db needs access to symbols in the gdb
1596    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1597    # may not be supported there.
1598    old_LDFLAGS="$LDFLAGS"
1599    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1600    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1601    LDFLAGS="$LDFLAGS $RDYNAMIC"
1602    if test "${have_libpython}" = no; then
1603      AC_TRY_LINK([], [], [dynamic_list=true])
1604    else
1605      # Workaround http://bugs.python.org/issue4434 where static
1606      # libpythonX.Y.a would get its symbols required for
1607      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1608      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1609      old_CFLAGS="$CFLAGS"
1610      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1611      AC_RUN_IFELSE(
1612        AC_LANG_PROGRAM(
1613          [#include "]${have_libpython}[/Python.h"],
1614          [int err;
1615           Py_Initialize ();
1616           err = PyRun_SimpleString ("import itertools\n");
1617           Py_Finalize ();
1618           return err == 0 ? 0 : 1;]),
1619        [dynamic_list=true], [], [true])
1620      CFLAGS="$old_CFLAGS"
1621    fi
1622    LDFLAGS="$old_LDFLAGS"
1623 fi
1624 if $dynamic_list; then
1625   found="-Wl,--dynamic-list"
1626   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1627 else
1628   found="-rdynamic"
1629   RDYNAMIC="-rdynamic"
1630 fi
1631 AC_SUBST(RDYNAMIC)
1632 AC_MSG_RESULT($found)
1633
1634 dnl For certain native configurations, we need to check whether thread
1635 dnl support can be built in or not.
1636 dnl
1637 dnl Note that we only want this if we are both native (host == target),
1638 dnl and not doing a canadian cross build (build == host).
1639
1640 if test ${build} = ${host} -a ${host} = ${target} ; then
1641    case ${host_os} in
1642    solaris*)
1643       # See if thread_db library is around for Solaris thread debugging.
1644       # Note that we must explicitly test for version 1 of the library
1645       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1646       # the same API.
1647       AC_MSG_CHECKING(for Solaris thread debugging library)
1648       if test -f /usr/lib/libthread_db.so.1 ; then
1649          AC_MSG_RESULT(yes)
1650          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1651          [Define if using Solaris thread debugging.])
1652          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1653          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1654          AC_CHECK_LIB(dl, dlopen)
1655          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1656          # Sun randomly tweaked the prototypes in <proc_service.h>
1657          # at one point.
1658          AC_MSG_CHECKING(if <proc_service.h> is old)
1659          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1660             AC_TRY_COMPILE([
1661                 #include <proc_service.h>
1662                 ps_err_e ps_pdwrite
1663                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1664             ],, gdb_cv_proc_service_is_old=no,
1665                 gdb_cv_proc_service_is_old=yes)
1666          ])
1667          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1668          if test $gdb_cv_proc_service_is_old = yes; then
1669             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1670             [Define if <proc_service.h> on solaris uses int instead of
1671              size_t, and assorted other type changes.])
1672          fi
1673       else
1674          AC_MSG_RESULT(no)
1675       fi
1676       ;;
1677    aix*)
1678       AC_MSG_CHECKING(for AiX thread debugging library)
1679       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1680                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1681                                    [#ifndef PTHDB_VERSION_3
1682                                     #error
1683                                     #endif],
1684                                    gdb_cv_have_aix_thread_debug=yes,
1685                                    gdb_cv_have_aix_thread_debug=no)])
1686       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1687       if test $gdb_cv_have_aix_thread_debug = yes; then
1688          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1689          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1690          LIBS="$LIBS -lpthdebug"
1691
1692          # Older versions of AIX do not provide the declaration for
1693          # the getthrds function (it appears that it was introduced
1694          # with AIX 6.x).
1695          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1696       fi
1697       ;;
1698    esac
1699    AC_SUBST(CONFIG_LDFLAGS)
1700 fi
1701
1702 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1703 dnl other error codes.
1704 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1705    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1706                   gdb_cv_thread_db_h_has_td_notalloc,
1707      AC_TRY_COMPILE(
1708        [#include <thread_db.h>],
1709        [int i = TD_NOTALLOC;],
1710        gdb_cv_thread_db_h_has_td_notalloc=yes,
1711        gdb_cv_thread_db_h_has_td_notalloc=no
1712      )
1713    )
1714    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1715                   gdb_cv_thread_db_h_has_td_version,
1716      AC_TRY_COMPILE(
1717        [#include <thread_db.h>],
1718        [int i = TD_VERSION;],
1719        gdb_cv_thread_db_h_has_td_version=yes,
1720        gdb_cv_thread_db_h_has_td_version=no
1721      )
1722    )
1723    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1724                   gdb_cv_thread_db_h_has_td_notls,
1725      AC_TRY_COMPILE(
1726        [#include <thread_db.h>],
1727        [int i = TD_NOTLS;],
1728        gdb_cv_thread_db_h_has_td_notls=yes,
1729        gdb_cv_thread_db_h_has_td_notls=no
1730      )
1731    )
1732 fi
1733 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1734   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1735             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1736 fi
1737 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1738   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1739             [Define if <thread_db.h> has the TD_VERSION error code.])
1740 fi
1741 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1742   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1743             [Define if <thread_db.h> has the TD_NOTLS error code.])
1744 fi
1745
1746 dnl See if we have a sys/syscall header file that has __NR_tkill.
1747 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1748    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1749                   gdb_cv_sys_syscall_h_has_tkill,
1750      AC_TRY_COMPILE(
1751        [#include <sys/syscall.h>],
1752        [int i = __NR_tkill;],
1753        gdb_cv_sys_syscall_h_has_tkill=yes,
1754        gdb_cv_sys_syscall_h_has_tkill=no
1755      )
1756    )
1757 fi
1758 dnl See if we can issue tkill syscall.
1759 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1760   AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1761 fi
1762
1763 dnl Check if we can disable the virtual address space randomization.
1764 dnl The functionality of setarch -R.
1765 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1766 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1767 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1768 #       define ADDR_NO_RANDOMIZE 0x0040000
1769 #      endif
1770        /* Test the flag could be set and stays set.  */
1771        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1772        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1773            return 1])])
1774 AC_RUN_IFELSE([PERSONALITY_TEST],
1775               [have_personality=true],
1776               [have_personality=false],
1777               [AC_LINK_IFELSE([PERSONALITY_TEST],
1778                               [have_personality=true],
1779                               [have_personality=false])])
1780 if $have_personality
1781 then
1782     AC_DEFINE([HAVE_PERSONALITY], 1,
1783               [Define if you support the personality syscall.])
1784 fi
1785
1786 dnl Handle optional features that can be enabled.
1787
1788 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1789 # except that the argument to --with-sysroot is optional.
1790 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1791 if test "x$with_sysroot" = xyes; then
1792   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1793 fi
1794 AC_ARG_WITH(sysroot,
1795   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1796                  [search for usr/lib et al within DIR]),
1797   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1798 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1799               [search for usr/lib et al within DIR])
1800 AC_SUBST(TARGET_SYSTEM_ROOT)
1801 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1802
1803 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1804     [automatically load a system-wide gdbinit file],
1805     [])
1806
1807 AC_ARG_ENABLE(werror,
1808   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
1809   [case "${enableval}" in
1810      yes | y) ERROR_ON_WARNING="yes" ;;
1811      no | n)  ERROR_ON_WARNING="no" ;;
1812      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1813    esac])
1814
1815 # Enable -Werror by default when using gcc
1816 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then
1817     ERROR_ON_WARNING=yes
1818 fi
1819
1820 WERROR_CFLAGS=""
1821 if test "${ERROR_ON_WARNING}" = yes ; then
1822     WERROR_CFLAGS="-Werror"
1823 fi
1824
1825 # The entries after -Wno-pointer-sign are disabled warnings which may
1826 # be enabled in the future, which can not currently be used to build
1827 # GDB.
1828 # NOTE: If you change this list, remember to update
1829 # gdb/doc/gdbint.texinfo.
1830 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1831 -Wformat-nonliteral -Wno-pointer-sign \
1832 -Wno-unused -Wunused-value -Wunused-function \
1833 -Wno-switch -Wno-char-subscripts -Wmissing-prototypes"
1834
1835 # Enable -Wno-format by default when using gcc on mingw since many
1836 # GCC versions complain about %I64.
1837 case "${host}" in
1838   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1839 esac
1840
1841 AC_ARG_ENABLE(build-warnings,
1842 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
1843 [case "${enableval}" in
1844   yes)  ;;
1845   no)   build_warnings="-w";;
1846   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1847         build_warnings="${build_warnings} ${t}";;
1848   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1849         build_warnings="${t} ${build_warnings}";;
1850   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1851 esac
1852 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1853   echo "Setting compiler warning flags = $build_warnings" 6>&1
1854 fi])dnl
1855 AC_ARG_ENABLE(gdb-build-warnings,
1856 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
1857 [case "${enableval}" in
1858   yes)  ;;
1859   no)   build_warnings="-w";;
1860   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1861         build_warnings="${build_warnings} ${t}";;
1862   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1863         build_warnings="${t} ${build_warnings}";;
1864   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1865 esac
1866 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1867   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1868 fi])dnl
1869 WARN_CFLAGS=""
1870 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1871 then
1872     AC_MSG_CHECKING(compiler warning flags)
1873     # Separate out the -Werror flag as some files just cannot be
1874     # compiled with it enabled.
1875     for w in ${build_warnings}; do
1876         case $w in
1877         -Werr*) WERROR_CFLAGS=-Werror ;;
1878         *) # Check that GCC accepts it
1879             saved_CFLAGS="$CFLAGS"
1880             CFLAGS="$CFLAGS $w"
1881             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1882             CFLAGS="$saved_CFLAGS"
1883         esac
1884     done
1885     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1886 fi
1887 AC_SUBST(WARN_CFLAGS)
1888 AC_SUBST(WERROR_CFLAGS)
1889
1890 # In the Cygwin environment, we need some additional flags.
1891 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1892 [AC_EGREP_CPP(lose, [
1893 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1894 lose
1895 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1896
1897
1898 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1899 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1900 case ${host} in
1901   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1902   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1903   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1904 esac
1905 AC_SUBST(SER_HARDWIRE)
1906
1907 # libreadline needs libuser32.a in a cygwin environment
1908 WIN32LIBS=
1909 if test x$gdb_cv_os_cygwin = xyes; then
1910     WIN32LIBS="-luser32"
1911     case "${target}" in
1912         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1913         ;;
1914     esac
1915 fi
1916
1917 # The ser-tcp.c module requires sockets.
1918 case ${host} in
1919   *mingw32*)
1920     AC_DEFINE(USE_WIN32API, 1,
1921               [Define if we should use the Windows API, instead of the
1922                POSIX API.  On Windows, we use the Windows API when
1923                building for MinGW, but the POSIX API when building
1924                for Cygwin.])
1925     WIN32LIBS="$WIN32LIBS -lws2_32"
1926     ;;
1927 esac
1928 AC_SUBST(WIN32LIBS)
1929
1930 # Add ELF support to GDB, but only if BFD includes ELF support.
1931 OLD_CFLAGS=$CFLAGS
1932 OLD_LDFLAGS=$LDFLAGS
1933 OLD_LIBS=$LIBS
1934 # Put the old CFLAGS/LDFLAGS last, in case the user's (C|LD)FLAGS
1935 # points somewhere with bfd, with -I/foo/lib and -L/foo/lib.  We
1936 # always want our bfd.
1937 CFLAGS="-I${srcdir}/../include -I../bfd -I${srcdir}/../bfd $CFLAGS"
1938 LDFLAGS="-L../bfd -L../libiberty $LDFLAGS"
1939 intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'`
1940 # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1941 if test "$plugins" = "yes"; then
1942   LIBS="-ldl $LIBS"
1943 fi
1944 LIBS="-lbfd -liberty $intl $LIBS"
1945 AC_CACHE_CHECK([for ELF support in BFD], gdb_cv_var_elf,
1946 [AC_TRY_LINK(
1947 [#include <stdlib.h>
1948 #include "bfd.h"
1949 #include "elf-bfd.h"
1950 ],
1951 [bfd *abfd = NULL; bfd_get_elf_phdr_upper_bound (abfd); ],
1952 gdb_cv_var_elf=yes, gdb_cv_var_elf=no)])
1953 if test $gdb_cv_var_elf = yes; then
1954   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o"
1955   AC_DEFINE(HAVE_ELF, 1,
1956             [Define if ELF support should be included.])
1957   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1958   if test "$plugins" = "yes"; then
1959     OLD_LIBS="-ldl $OLD_LIBS"
1960   fi
1961 fi
1962 CFLAGS=$OLD_CFLAGS
1963 LDFLAGS=$OLD_LDFLAGS
1964 LIBS=$OLD_LIBS
1965
1966 # Add any host-specific objects to GDB.
1967 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1968
1969 LIBGUI="../libgui/src/libgui.a"
1970 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1971 AC_SUBST(LIBGUI)
1972 AC_SUBST(GUI_CFLAGS_X)
1973
1974 WIN32LDAPP=
1975 AC_SUBST(WIN32LIBS)
1976 AC_SUBST(WIN32LDAPP)
1977
1978 case "${host}" in
1979 *-*-cygwin* | *-*-mingw* )
1980     configdir="win"
1981     ;;
1982 *)
1983     configdir="unix"
1984     ;;
1985 esac
1986
1987 GDBTKLIBS=
1988 if test "${enable_gdbtk}" = "yes"; then
1989
1990     # Gdbtk must have an absolute path to srcdir in order to run
1991     # properly when not installed.
1992     here=`pwd`
1993     cd ${srcdir}
1994     GDBTK_SRC_DIR=`pwd`
1995     cd $here
1996
1997     SC_PATH_TCLCONFIG
1998
1999     # If $no_tk is nonempty, then we can't do Tk, and there is no
2000     # point to doing Tcl.
2001     SC_PATH_TKCONFIG
2002
2003     if test -z "${no_tcl}" -a -z "${no_tk}"; then
2004         SC_LOAD_TCLCONFIG
2005
2006         # Check for in-tree tcl
2007         here=`pwd`
2008         cd ${srcdir}/..
2009         topdir=`pwd`
2010         cd ${here}
2011
2012         intree="no"
2013         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
2014           intree="yes"
2015         fi
2016
2017         # Find Tcl private headers
2018         if test x"${intree}" = xno; then
2019           CY_AC_TCL_PRIVATE_HEADERS
2020           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
2021           TCL_LIBRARY="${TCL_LIB_SPEC}"
2022           TCL_DEPS=""
2023         else
2024           # If building tcl in the same src tree, private headers
2025           # are not needed, but we need to be sure to use the right
2026           # headers library
2027           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2028           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2029           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2030         fi
2031         AC_SUBST(TCL_INCLUDE)
2032         AC_SUBST(TCL_LIBRARY)
2033         AC_SUBST(TCL_DEPS)
2034
2035         SC_LOAD_TKCONFIG
2036
2037         # Check for in-tree Tk
2038         intree="no"
2039         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2040           intree="yes"
2041         fi
2042
2043         # Find Tk private headers
2044         if test x"${intree}" = xno; then
2045           CY_AC_TK_PRIVATE_HEADERS
2046           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2047           TK_LIBRARY=${TK_LIB_SPEC}
2048           TK_DEPS=""
2049         else
2050           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2051           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2052           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2053         fi
2054         AC_SUBST(TK_INCLUDE)
2055         AC_SUBST(TK_LIBRARY)
2056         AC_SUBST(TK_DEPS)
2057         AC_SUBST(TK_XINCLUDES)
2058
2059         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2060
2061         # Include some libraries that Tcl and Tk want.
2062         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2063         # Yes, the ordering seems wrong here.  But it isn't.
2064         # TK_LIBS is the list of libraries that need to be linked
2065         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2066         # were in LIBS then any link tests after this point would
2067         # try to include things like `$(LIBGUI)', which wouldn't work.
2068         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2069
2070         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2071         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2072         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2073         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2074         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2075         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2076         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2077
2078         if test x$gdb_cv_os_cygwin = xyes; then
2079           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2080           WIN32LDAPP="-Wl,--subsystem,console"
2081           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2082         fi
2083
2084         AC_CONFIG_SUBDIRS(gdbtk)
2085     fi
2086 fi
2087
2088 AC_SUBST(X_CFLAGS)
2089 AC_SUBST(X_LDFLAGS)
2090 AC_SUBST(X_LIBS)
2091 AC_SUBST(GDBTKLIBS)
2092 AC_SUBST(GDBTK_CFLAGS)
2093 AC_SUBST(GDBTK_SRC_DIR)
2094
2095 AC_PATH_X
2096
2097 # Unlike the sim directory, whether a simulator is linked is controlled by
2098 # presence of a gdb_sim definition in the target configure.tgt entry.
2099 # This code just checks for a few cases where we'd like to ignore those
2100 # definitions, even when they're present in the '.mt' file.  These cases
2101 # are when --disable-sim is specified, or if the simulator directory is
2102 # not part of the source tree.
2103 #
2104 AC_ARG_ENABLE(sim,
2105 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2106 [echo "enable_sim = $enable_sim";
2107  echo "enableval = ${enableval}";
2108  case "${enableval}" in
2109   yes) ignore_sim=false ;;
2110   no)  ignore_sim=true ;;
2111   *)   ignore_sim=false ;;
2112  esac],
2113 [ignore_sim=false])
2114
2115 if test ! -d "${srcdir}/../sim"; then
2116   ignore_sim=true
2117 fi
2118
2119 SIM=
2120 SIM_OBS=
2121 if test "${ignore_sim}" = "false"; then
2122   if test x"${gdb_sim}" != x ; then
2123     SIM="${gdb_sim}"
2124     SIM_OBS="remote-sim.o"
2125     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2126   fi
2127 fi
2128 AC_SUBST(SIM)
2129 AC_SUBST(SIM_OBS)
2130
2131 AC_SUBST(ENABLE_CFLAGS)
2132 AC_SUBST(PROFILE_CFLAGS)
2133
2134 AC_SUBST(CONFIG_OBS)
2135 AC_SUBST(CONFIG_DEPS)
2136 AC_SUBST(CONFIG_SRCS)
2137 AC_SUBST(CONFIG_ALL)
2138 AC_SUBST(CONFIG_CLEAN)
2139 AC_SUBST(CONFIG_INSTALL)
2140 AC_SUBST(CONFIG_UNINSTALL)
2141
2142 # List of host floatformats.
2143 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2144 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2145 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2146
2147 # target_subdir is used by the testsuite to find the target libraries.
2148 target_subdir=
2149 if test "${host}" != "${target}"; then
2150     target_subdir="${target_alias}/"
2151 fi
2152 AC_SUBST(target_subdir)
2153
2154 frags=
2155 if test "${gdb_native}" = "yes"; then
2156   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
2157   if test ! -f ${host_makefile_frag}; then
2158     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
2159   fi
2160   frags="$frags $host_makefile_frag"
2161 else
2162   host_makefile_frag=/dev/null
2163 fi
2164
2165 AC_SUBST_FILE(host_makefile_frag)
2166 AC_SUBST(frags)
2167
2168 changequote(,)dnl
2169 if test "${gdb_native}" = "yes"; then
2170 # We pick this up from the host configuration file (.mh) because we
2171 # do not have a native configuration Makefile fragment.
2172 nativefile=`sed -n '
2173 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
2174 ' ${host_makefile_frag}`
2175 fi
2176 changequote([,])
2177
2178 if test x"${gdb_osabi}" != x ; then
2179     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2180                        [Define to the default OS ABI for this configuration.])
2181 fi
2182
2183 # Enable multi-ice-gdb-server.
2184 AC_ARG_ENABLE(multi-ice,
2185 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2186   [case $enableval in
2187     yes | no)
2188       ;;
2189     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2190   esac])
2191 if test "x$enable_multi_ice" = xyes; then
2192    AC_CONFIG_SUBDIRS(multi-ice)
2193 fi
2194
2195 AC_ARG_ENABLE(gdbserver,
2196 AS_HELP_STRING([--enable-gdbserver],
2197                [automatically build gdbserver (yes/no/auto, default is auto)]),
2198 [case "${enableval}" in
2199   yes| no|auto) ;;
2200   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2201 esac],[enable_gdbserver=auto])
2202
2203 # We only build gdbserver automatically in a native configuration, and
2204 # only if the user did not explicitly disable its build.
2205 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2206   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2207   if test "x$build_gdbserver" = xyes; then
2208     AC_MSG_RESULT(yes)
2209     AC_CONFIG_SUBDIRS(gdbserver)
2210     gdbserver_build_enabled=yes
2211   else
2212     AC_MSG_RESULT(no)
2213   fi
2214 fi
2215
2216 # If the user explicitly request the gdbserver to be built, verify that
2217 # we were in fact able to enable it.
2218 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2219   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2220 fi
2221
2222 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2223 # to an empty version.
2224
2225 files=
2226 links=
2227
2228 rm -f nm.h
2229 if test "${nativefile}" != ""; then
2230     case "${nativefile}" in
2231       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2232       * ) GDB_NM_FILE="${nativefile}"
2233     esac
2234     files="${files} ${GDB_NM_FILE}"
2235     links="${links} nm.h"
2236     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2237 fi
2238 AC_SUBST(GDB_NM_FILE)
2239
2240 AC_LINK_FILES($files, $links)
2241
2242 dnl Check for exe extension set on certain hosts (e.g. Win32)
2243 AC_EXEEXT
2244
2245 dnl  Detect the character set used by this host.
2246 dnl  At the moment, we just assume it's UTF-8.
2247 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2248           [Define to be a string naming the default host character set.])
2249
2250 AC_OUTPUT(Makefile gdb-gdb.gdb doc/Makefile data-directory/Makefile,
2251 [
2252 case x$CONFIG_HEADERS in
2253 xconfig.h:config.in)
2254 echo > stamp-h ;;
2255 esac
2256 ])
2257
2258 exit 0