gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996, 1997, 1998, 1999 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 2 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program; if not, write to the Free Software
  18 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  19
  20 dnl Process this file with autoconf to produce a configure script.
  21
  22 AC_PREREQ(2.13)dnl
  23 AC_INIT(main.c)
  24 AC_CONFIG_HEADER(config.h:config.in)
  25
  26 AC_PROG_CC
  27 AC_AIX
  28 AC_ISC_POSIX
  29 AM_PROG_CC_STDC
  30
  31 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  32 AC_CANONICAL_SYSTEM
  33
  34 dnl gdb doesn't use gettext, but bfd does.  We call this to ensure we
  35 dnl link with the correct libraries.
  36 ALL_LINGUAS=
  37 CY_GNU_GETTEXT
  38
  39 dnl List of object files added by configure.
  40
  41 CONFIG_OBS=
  42 CONFIG_DEPS=
  43 CONFIG_SRCS=
  44
  45 configdirs="doc testsuite"
  46
  47 dnl
  48 changequote(,)dnl
  49
  50 . ${srcdir}/configure.host
  51
  52 . ${srcdir}/configure.tgt
  53
  54 dnl
  55 changequote([,])dnl
  56
  57 AC_PROG_INSTALL
  58 AC_CHECK_TOOL(AR, ar)
  59 AC_CHECK_TOOL(RANLIB, ranlib, :)
  60 AC_PROG_YACC
  61
  62 AC_ARG_PROGRAM
  63
  64 AC_TYPE_SIGNAL
  65
  66 AC_HEADER_STDC
  67
  68 AC_CHECK_HEADERS(ctype.h curses.h endian.h libintl.h link.h \
  69         memory.h objlist.h ptrace.h sgtty.h stddef.h stdlib.h \
  70         string.h sys/procfs.h sys/ptrace.h sys/reg.h \
  71         term.h termio.h termios.h unistd.h wait.h sys/wait.h \
  72         wchar.h wctype.h asm/debugreg.h)
  73 AC_HEADER_STAT
  74
  75 AC_C_CONST
  76
  77 AC_CHECK_FUNCS(setpgid sbrk sigaction isascii bzero bcopy btowc)
  78 AC_FUNC_ALLOCA
  79
  80 BFD_NEED_DECLARATION(malloc)
  81 BFD_NEED_DECLARATION(realloc)
  82 BFD_NEED_DECLARATION(free)
  83 BFD_NEED_DECLARATION(strerror)
  84 BFD_NEED_DECLARATION(strdup)
  85
  86 # If we are configured native on GNU/Linux, work around problems with sys/procfs.h
  87 if test "${target}" = "${host}"; then
  88   case "${host}" in
  89   i[[3456]]86-*-linux*)
  90         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
  91         AC_DEFINE(sys_quotactl)
  92         ;;
  93   esac
  94 fi
  95
  96 AC_MSG_CHECKING([for gregset_t type])
  97 AC_CACHE_VAL(gdb_cv_have_gregset_t,
  98 [AC_TRY_LINK([#include <sys/procfs.h>],[gregset_t *gregsetp = 0],
  99 gdb_cv_have_gregset_t=yes, gdb_cv_have_gregset_t=no)])
 100 AC_MSG_RESULT($gdb_cv_have_gregset_t)
 101 if test $gdb_cv_have_gregset_t = yes; then
 102   AC_DEFINE(HAVE_GREGSET_T)
 103 fi
 104
 105 AC_MSG_CHECKING([for fpregset_t type])
 106 AC_CACHE_VAL(gdb_cv_have_fpregset_t,
 107 [AC_TRY_LINK([#include <sys/procfs.h>],[fpregset_t *fpregsetp = 0],
 108 gdb_cv_have_fpregset_t=yes, gdb_cv_have_fpregset_t=no)])
 109 AC_MSG_RESULT($gdb_cv_have_fpregset_t)
 110 if test $gdb_cv_have_fpregset_t = yes; then
 111   AC_DEFINE(HAVE_FPREGSET_T)
 112 fi
 113
 114 dnl See if host has libm.  This is usually needed by simulators.
 115 AC_CHECK_LIB(m, main)
 116
 117 dnl Solaris puts wctype in /usr/lib/libw.a before Solaris 2.6.
 118 dnl
 119 dnl A bug in GNU ld 2.9.1 causes a problem if we link in -lw
 120 dnl under Solaris 2.6 because it is some funky empty library.
 121 dnl So only link in libw if we have to.
 122 AC_CHECK_LIB(c, wctype,: ,AC_CHECK_LIB(w, wctype))
 123
 124 AC_SUBST(TERM_LIB)
 125
 126 dnl See if compiler supports "long long" type.
 127
 128 AC_MSG_CHECKING(for long long support in compiler)
 129 AC_CACHE_VAL(gdb_cv_c_long_long,
 130 [AC_TRY_COMPILE(, [
 131   extern long long foo;
 132   switch (foo & 2) { case 0: return 1; }
 133 ],
 134 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
 135 AC_MSG_RESULT($gdb_cv_c_long_long)
 136 if test $gdb_cv_c_long_long = yes; then
 137   AC_DEFINE(CC_HAS_LONG_LONG)
 138 fi
 139
 140 dnl See if the compiler and runtime support printing long long
 141
 142 AC_MSG_CHECKING(for long long support in printf)
 143 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 144 [AC_TRY_RUN([
 145 int main () {
 146   char buf[32];
 147   long long l = 0;
 148   l = (l << 16) + 0x0123;
 149   l = (l << 16) + 0x4567;
 150   l = (l << 16) + 0x89ab;
 151   l = (l << 16) + 0xcdef;
 152   sprintf (buf, "0x%016llx", l);
 153   return (strcmp ("0x0123456789abcdef", buf));
 154 }],
 155 gdb_cv_printf_has_long_long=yes,
 156 gdb_cv_printf_has_long_long=no,
 157 gdb_cv_printf_has_long_long=no)])
 158 if test $gdb_cv_printf_has_long_long = yes; then
 159   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 160 fi
 161 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 162
 163 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 164 dnl because autoconf complains about cross-compilation issues.  However, this
 165 dnl code uses the same variables as the macro for compatibility.
 166
 167 AC_MSG_CHECKING(for long double support in compiler)
 168 AC_CACHE_VAL(ac_cv_c_long_double,
 169 [AC_TRY_COMPILE(, [long double foo;],
 170 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 171 AC_MSG_RESULT($ac_cv_c_long_double)
 172 if test $ac_cv_c_long_double = yes; then
 173   AC_DEFINE(HAVE_LONG_DOUBLE)
 174 fi
 175
 176 dnl See if the compiler and runtime support printing long doubles
 177
 178 AC_MSG_CHECKING(for long double support in printf)
 179 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 180 [AC_TRY_RUN([
 181 int main () {
 182   char buf[16];
 183   long double f = 3.141592653;
 184   sprintf (buf, "%Lg", f);
 185   return (strncmp ("3.14159", buf, 7));
 186 }],
 187 gdb_cv_printf_has_long_double=yes,
 188 gdb_cv_printf_has_long_double=no,
 189 gdb_cv_printf_has_long_double=no)])
 190 if test $gdb_cv_printf_has_long_double = yes; then
 191   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 192 fi
 193 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 194
 195 dnl See if the compiler and runtime support scanning long doubles
 196
 197 AC_MSG_CHECKING(for long double support in scanf)
 198 AC_CACHE_VAL(gdb_cv_scanf_has_long_double,
 199 [AC_TRY_RUN([
 200 int main () {
 201   char *buf = "3.141592653";
 202   long double f = 0;
 203   sscanf (buf, "%Lg", &f);
 204   return !(f > 3.14159 && f < 3.14160);
 205 }],
 206 gdb_cv_scanf_has_long_double=yes,
 207 gdb_cv_scanf_has_long_double=no,
 208 gdb_cv_scanf_has_long_double=no)])
 209 if test $gdb_cv_scanf_has_long_double = yes; then
 210   AC_DEFINE(SCANF_HAS_LONG_DOUBLE)
 211 fi
 212 AC_MSG_RESULT($gdb_cv_scanf_has_long_double)
 213
 214 AC_FUNC_MMAP
 215
 216 dnl See if thread_db library is around for Solaris thread debugging.  Note that
 217 dnl we must explicitly test for version 1 of the library because version 0
 218 dnl (present on Solaris 2.4 or earlier) doesn't have the same API.
 219
 220 dnl Note that we only want this if we are both native (host == target), and
 221 dnl not doing a canadian cross build (build == host).
 222
 223 if test ${build} = ${host} -a ${host} = ${target} ; then
 224    case ${host_os} in
 225    hpux*)
 226       AC_MSG_CHECKING(for HPUX/OSF thread support)
 227       if test -f /usr/include/dce/cma_config.h ; then
 228          if test "$GCC" = "yes" ; then
 229             AC_MSG_RESULT(yes)
 230             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 231             CONFIG_OBS="${CONFIG_OJS} hpux-thread.o"
 232             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
 233          else
 234             AC_MSG_RESULT(no (suppressed because you are not using GCC))
 235          fi
 236       else
 237          AC_MSG_RESULT(no)
 238       fi
 239       ;;
 240    solaris*)
 241       AC_MSG_CHECKING(for Solaris thread debugging library)
 242       if test -f /usr/lib/libthread_db.so.1 ; then
 243          AC_MSG_RESULT(yes)
 244          AC_DEFINE(HAVE_THREAD_DB_LIB)
 245          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
 246          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
 247          AC_CHECK_LIB(dl, dlopen)
 248          if test "$GCC" = "yes" ; then
 249             # The GNU linker requires the -export-dynamic option to make
 250             # all symbols visible in the dynamic symbol table.
 251             hold_ldflags=$LDFLAGS
 252             AC_MSG_CHECKING(for the ld -export-dynamic flag)
 253             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
 254             AC_TRY_LINK(, [int i;], found=yes, found=no)
 255             LDFLAGS=$hold_ldflags
 256             AC_MSG_RESULT($found)
 257             if test $found = yes; then
 258                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
 259             fi
 260          fi
 261          # Sun randomly tweaked the prototypes in <proc_service.h>
 262          # at one point.
 263          AC_MSG_CHECKING(if <proc_service.h> is old)
 264          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
 265             AC_TRY_COMPILE([
 266                 #include <proc_service.h>
 267                 ps_err_e ps_pdwrite
 268                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
 269             ],, gdb_cv_proc_service_is_old=no,
 270                 gdb_cv_proc_service_is_old=yes)
 271          ])
 272          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
 273          if test $gdb_cv_proc_service_is_old = yes; then
 274             AC_DEFINE(PROC_SERVICE_IS_OLD)
 275          fi
 276       else
 277          AC_MSG_RESULT(no)
 278       fi
 279       ;;
 280    esac
 281    AC_SUBST(CONFIG_LDFLAGS)
 282 fi
 283
 284 dnl Handle optional features that can be enabled.
 285 ENABLE_CFLAGS=
 286
 287 AC_ARG_ENABLE(tui,
 288 [  --enable-tui            Enable full-screen terminal user interface],
 289 [
 290   case "${enable_tui}" in
 291     yes | no) ;;
 292     "")  enable_tui=yes ;;
 293     *)
 294       AC_MSG_ERROR(Bad value for --enable-tui: ${enableval})
 295     ;;
 296   esac
 297 ])
 298 case ${enable_tui} in
 299   "yes" )
 300     AC_DEFINE(TUI)
 301     BUILD_TUI=all-tui
 302     TUI_LIBRARY=tui/libtui.a
 303   ;;
 304   * )
 305     BUILD_TUI=
 306     TUI_LIBRARY=
 307   ;;
 308 esac
 309 AC_SUBST(BUILD_TUI)
 310 AC_SUBST(TUI_LIBRARY)
 311
 312 AC_ARG_ENABLE(netrom,
 313 [  --enable-netrom         Enable NetROM support],
 314 [case "${enableval}" in
 315 yes)    enable_netrom=yes ;;
 316 no)     enable_netrom=no ;;
 317 *)      AC_MSG_ERROR(bad value ${enableval} given for netrom option) ;;
 318 esac])
 319
 320 if test "${enable_netrom}" = "yes"; then
 321         CONFIG_OBS="${CONFIG_OBS} remote-nrom.o"
 322         CONFIG_SRCS="${CONFIG_SRCS} remote-nrom.c"
 323 fi
 324
 325 AC_ARG_ENABLE(build-warnings,
 326 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
 327 [build_warnings="-Wall -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations"
 328 case "${enableval}" in
 329   yes)  ;;
 330   no)   build_warnings="-w";;
 331   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
 332         build_warnings="${build_warnings} ${t}";;
 333   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
 334         build_warnings="${t} ${build_warnings}";;
 335   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
 336 esac],[build_warnings=""])dnl
 337
 338 if test "x${build_warnings}" != x -a "x$GCC" = xyes
 339 then
 340    WARN_CFLAGS="${build_warnings}"
 341 else
 342    WARN_CFLAGS=""
 343 fi
 344 AC_SUBST(WARN_CFLAGS)
 345
 346 MMALLOC_CFLAGS=
 347 MMALLOC=
 348 AC_SUBST(MMALLOC_CFLAGS)
 349 AC_SUBST(MMALLOC)
 350
 351 AC_ARG_WITH(mmalloc,
 352 [  --with-mmalloc          Use memory mapped malloc package],
 353 [case "${withval}" in
 354   yes)  want_mmalloc=true ;;
 355   no)   want_mmalloc=false;;
 356   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-mmalloc option) ;;
 357 esac],[want_mmalloc=false])dnl
 358
 359 if test x$want_mmalloc = xtrue; then
 360    AC_DEFINE(USE_MMALLOC)
 361    AC_DEFINE(MMCHECK_FORCE)
 362    MMALLOC_CFLAGS="-I$srcdir/../mmalloc"
 363    MMALLOC='../mmalloc/libmmalloc.a'
 364 fi
 365
 366 # start-sanitize-carp
 367 # The below takes an educated guess at the targets that
 368 # should be built.  It is an interum version that provides
 369 # significant backward compatibility.
 370
 371 AC_ARG_ENABLE(carp,
 372 [  --enable-carp           Configure alternative readaptive paradigm ],
 373 [case "${enableval}" in
 374   yes) enable_carp=yes ;;
 375   no)  enable_carp=no ;;
 376   *)   AC_MSG_ERROR([bad value ${enableval} for carp option]) ;;
 377 esac],[enable_carp=no])dnl
 378
 379 AC_ARG_ENABLE(targets,
 380 [  --enable-targets        alternative target configurations],
 381 [case "${enableval}" in
 382   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 383             ;;
 384   no)       enable_targets= ;;
 385   *)        enable_targets="$enableval" ;;
 386 esac])dnl
 387
 388 # Canonicalize the secondary target names.
 389 all_targets=false
 390 if test -n "$enable_targets" ; then
 391     if test "$enable_targets" = all ; then
 392         all_targets=true
 393     else
 394         for targ in `echo $enable_targets | sed 's/,/ /g'`
 395         do
 396             result=`${CONFIG_SHELL-/bin/sh} $ac_config_sub $targ 2>/dev/null`
 397             if test -n "$result" ; then
 398                 canon_targets="$canon_targets $result"
 399             fi
 400         done
 401     fi
 402 fi
 403
 404 # Convert the target names into GDB [*]-tdep.c names
 405 changequote(,)dnl
 406 selarchs=
 407 for targ in $target $canon_targets
 408 do
 409     if test "x$targ" = "xall" ; then
 410         all_targets=true
 411     else
 412         t_cpu=`echo $targ    | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/\1/'`
 413         t_vendor=`echo $targ | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/\2/'`
 414         t_os=`echo $targ     | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/\3/'`
 415         mt=`
 416 target=$targ
 417 target_cpu=$t_cpu
 418 target_vendor=$t_vendor
 419 target_os=$t_os
 420 . ${srcdir}/configure.tgt
 421 echo ${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt`
 422         if test -r ${mt} ; then
 423             # This gets confused over .mt files that have multiple -tdep.o
 424             tdep=`sed -n '
 425 s/^.*[  =]\([^  ]*\)-tdep.o.*/\1/p
 426 ' $mt`
 427             selarchs="$selarchs $tdep"
 428         fi
 429     fi
 430 done
 431 changequote([,])dnl
 432
 433 # We don't do any links based on the target system, just makefile config.
 434
 435 if test x${all_targets} = xfalse ; then
 436
 437     # Target architecture .o files.
 438     ta=
 439
 440     for arch in $selarchs
 441     do
 442         archdefs="$archdefs -DARCH_$arch"
 443         ta="$ta ${arch}-tdep.o"
 444         # Special cases
 445         case "$arch" in
 446             dvp)  ta="$ta mips-tdep.o dvp-tdep.o" ;;
 447         esac
 448     done
 449
 450     # Weed out duplicate .o files.
 451     f=""
 452     for i in $ta ; do
 453         case " $f " in
 454             *" $i "*) ;;
 455             *) f="$f $i" ;;
 456         esac
 457     done
 458     ta="$f"
 459
 460     # And duplicate -D flags.
 461     f=""
 462     for i in $archdefs ; do
 463         case " $f " in
 464             *" $i "*) ;;
 465             *) f="$f $i" ;;
 466         esac
 467     done
 468     archdefs="$f"
 469
 470     MACHINE_OBS="$ta"
 471
 472 else    # all_targets is true
 473     archdefs=-DARCH_all
 474     MACHINE_OBS='$(ALL_MACHINES)'
 475 fi
 476
 477 dnl Don't define an archdefs list
 478 dnl AC_SUBST(archdefs)
 479 dnl XXXX this name will change several more times
 480 if test "${enable_carp}" = yes ; then
 481     gdb_target=carp
 482     gdb_target_cpu=carp
 483 else
 484     MACHINE_OBS="# $MACHINE_OBS"
 485 fi
 486 AC_SUBST(MACHINE_OBS)
 487
 488 # end-sanitize-carp
 489 # start-sanitize-gdbtk
 490 # start-sanitize-ide
 491 ENABLE_IDE=
 492 AC_ARG_ENABLE(ide, [  --enable-ide            Enable IDE support])
 493 if test "$enable_ide" = yes; then
 494    enable_ide=yes
 495    ENABLE_IDE=1
 496 else
 497    enable_ide=no
 498 fi
 499 AC_SUBST(ENABLE_IDE)
 500
 501 AC_ARG_WITH(foundry-libs,
 502 [  --with-foundry-libs=DIR Use the Foundry SDK in DIR],
 503 [FOUNDRY_LIB_BASE=${withval}])
 504 AC_SUBST(FOUNDRY_LIB_BASE)
 505
 506 #
 507 # This is the Foundry SDK
 508 #
 509 # These variables are used to determine where the Foundry libs and
 510 # header files are located.
 511 #
 512 if test "$FOUNDRY_LIB_BASE" != ""; then
 513     LIBGUI="${FOUNDRY_LIB_BASE}/lib/libgui.a"
 514     GUI_CFLAGS_X="-I${FOUNDRY_LIB_BASE}/include"
 515     if test x$enable_ide = xyes; then
 516         IDE_CFLAGS_X="-I${FOUNDRY_LIB_BASE}/include -DIDE"
 517         IDE_X="-L${FOUNDRY_LIB_BASE}/lib -lilu-Tk -lilu-c -lilu"
 518     else
 519         IDE_CFLAGS_X="-I${FOUNDRY_LIB_BASE}/include"
 520     fi
 521     LIBIDETCL="${FOUNDRY_LIB_BASE}/lib/libidetcl.a"
 522     LIBIDE="${FOUNDRY_LIB_BASE}/lib/libide.a"
 523     IDE_DEPS="${FOUNDRY_LIB_BASE}/lib/libilu-Tk.a ${FOUNDRY_LIB_BASE}/lib/libilu-c.a ${FOUNDRY_LIB_BASE}/lib/libilu.a"
 524 else
 525 # end-sanitize-ide
 526     LIBGUI="../libgui/src/libgui.a"
 527     GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
 528 # start-sanitize-ide
 529     if test x$enable_ide = xyes; then
 530         IDE_CFLAGS_X="-I${srcdir}/../libidetcl/src -I${srcdir}/../libide/src -DIDE -I${srcdir}/../ilu/runtime/mainloop"
 531         IDE_X="-L../ilu/runtime/mainloop -lilu-Tk -L../ilu/runtime/c -lilu-c -L../ilu/runtime/kernel -lilu"
 532     else
 533         IDE_CFLAGS_X="-I${srcdir}/../libidetcl/src -I${srcdir}/../libide/src"
 534     fi
 535     LIBIDETCL="../libidetcl/src/libidetcl.a"
 536     LIBIDE="../libide/src/libide.a"
 537     IDE_DEPS="../ilu/runtime/mainloop/libilu-Tk.a ../ilu/runtime/c/libilu-c.a ../ilu/runtime/kernel/libilu.a"
 538 fi
 539
 540 # end-sanitize-ide
 541 AC_SUBST(LIBGUI)
 542 AC_SUBST(GUI_CFLAGS_X)
 543 # start-sanitize-ide
 544 AC_SUBST(IDE_CFLAGS_X)
 545 AC_SUBST(IDE_X)
 546 AC_SUBST(LIBIDETCL)
 547 AC_SUBST(LIBIDE)
 548 AC_SUBST(IDE_DEPS)
 549 # end-sanitize-ide
 550
 551
 552 AC_ARG_WITH(cpu,
 553 [  --with-cpu=CPU          set the default CPU variant to debug],
 554 [case "${target}" in
 555   powerpc-* | powerpcle-* )
 556     ## It would be nice to keep this table in sync with the one in
 557     ## gcc/configure.
 558     case "${with_cpu}" in
 559       ppc-uisa | rs6000 | 403 | 403GC | 505 | 860 | 601 | 602 | 603 \
 560       | 604 | 750 )
 561         ## Those are all handled in variants in rs6000-tdep.c, so they're fine.
 562       ;;
 563       common | power | power2 | rios | rios1 | rios2 | rsc | rsc1 )
 564         ## These are all RS6000 variants, as far as GDB is concerned.
 565         with_cpu=rs6000
 566       ;;
 567       603e | ec603e )
 568         with_cpu=603
 569       ;;
 570       604e )
 571         with_cpu=604
 572       ;;
 573       * )
 574         AC_MSG_WARN(GDB: unknown --with-cpu value: \`${with_cpu}'; using \`ppc-uisa'.)
 575         with_cpu=ppc-uisa
 576       ;;
 577     esac
 578   ;;
 579   * )
 580     AC_MSG_WARN(GDB may ignore the --with-cpu flag for ${target} targets)
 581   ;;
 582 esac
 583 AC_DEFINE_UNQUOTED(TARGET_CPU_DEFAULT, "${with_cpu}")
 584 ],)
 585
 586
 587 ENABLE_GDBTK=
 588
 589 AC_ARG_ENABLE(gdbtk,
 590 [  --enable-gdbtk          Enable GDBTK GUI front end],
 591 [case "${enableval}" in
 592     yes)
 593         case "$host" in
 594         *go32*)
 595             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 596             enable_gdbtk=no ;;
 597         *windows*)
 598             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 599             enable_gdbtk=no ;;
 600         *)
 601             enable_gdbtk=yes ;;
 602         esac ;;
 603     no)
 604         enable_gdbtk=no  ;;
 605     *)
 606         AC_MSG_ERROR(bad value ${enableval} given for gdbtk option) ;;
 607 esac],
 608 [
 609 # Default is on for everything but go32 and Cygwin
 610 case "$host" in
 611     *go32* | *windows*)
 612         ;;
 613     *)
 614         enable_gdbtk=yes ;;
 615     esac
 616 ])
 617
 618 # In the Cygwin environment, we need some additional flags.
 619 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
 620 [AC_EGREP_CPP(lose, [
 621 #ifdef __CYGWIN32__
 622 lose
 623 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
 624
 625 dnl Figure out which term library to use.
 626 if test x$gdb_cv_os_cygwin = xyes; then
 627   TERM_LIB='`if test -r ../libtermcap/libtermcap.a; then echo ../libtermcap/libtermcap.a; else echo -ltermcap; fi`'
 628 else
 629   TERM_LIB=
 630   AC_CHECK_LIB(ncurses, tgetent, TERM_LIB=-lncurses,
 631     AC_CHECK_LIB(termlib, tgetent, TERM_LIB=-ltermlib,
 632       AC_CHECK_LIB(termcap, tgetent, TERM_LIB=-ltermcap,
 633         AC_CHECK_LIB(curses, tgetent, TERM_LIB=-lcurses,
 634           AC_CHECK_LIB(terminfo, tgetent, TERM_LIB=-lterminfo)))))
 635
 636   if test "x$TERM_LIB" = x
 637   then
 638     AC_MSG_ERROR(Could not find a term library, e.g. termcap or termlib!)
 639   fi
 640 fi
 641
 642 WIN32LIBS=
 643 WIN32LDAPP=
 644 AC_SUBST(WIN32LIBS)
 645 AC_SUBST(WIN32LDAPP)
 646
 647 DLLTOOL=${DLLTOOL-dlltool}
 648 WINDRES=${WINDRES-windres}
 649 AC_SUBST(DLLTOOL)
 650 AC_SUBST(WINDRES)
 651
 652 if test x$gdb_cv_os_cygwin = xyes; then
 653     WIN32LIBS="-luser32"
 654     if test x$enable_ide = xyes; then
 655         WIN32LIBS="$WIN32LIBS -ladvapi32"
 656     fi
 657 fi
 658
 659 configdir="unix"
 660
 661 GDBTKLIBS=
 662 if test "${enable_gdbtk}" = "yes"; then
 663
 664     CY_AC_PATH_TCLCONFIG
 665     if test -z "${no_tcl}"; then
 666         CY_AC_LOAD_TCLCONFIG
 667         CY_AC_PATH_TKCONFIG
 668
 669         # If $no_tk is nonempty, then we can't do Tk, and there is no
 670         # point to doing Tcl.
 671         if test -z "${no_tk}"; then
 672            CY_AC_LOAD_TKCONFIG
 673            CY_AC_PATH_TCLH
 674            CY_AC_PATH_TKH
 675            CY_AC_PATH_ITCLH
 676            CY_AC_PATH_ITKH
 677            CY_AC_PATH_TIX
 678
 679            # now look for Itcl library stuff
 680
 681            CY_AC_PATH_ITCLCONFIG
 682            if test -z "${no_itcl}"; then
 683              CY_AC_LOAD_ITCLCONFIG
 684              case "${host}" in
 685              *-*-cygwin32*)
 686                 itcldir=../itcl/itcl/win/
 687                 ;;
 688              *)
 689                 itcldir=../itcl/itcl/unix/
 690                 ;;
 691              esac
 692
 693
 694              ITCLLIB="${ITCL_BUILD_LIB_SPEC}"
 695              ITCL_DEPS="${itcldir}${ITCL_LIB_FILE}"
 696            fi
 697
 698
 699            # now look for Itk library stuff
 700            CY_AC_PATH_ITKCONFIG
 701            if test -z "${no_itcl}"; then
 702              CY_AC_LOAD_ITKCONFIG
 703
 704              case "${host}" in
 705                *-*-cygwin32*)
 706                  itkdir=../itcl/itk/win/
 707                  ;;
 708                *)
 709                  itkdir=../itcl/itk/unix/
 710                  ;;
 711                esac
 712
 713              ITKLIB="${ITK_BUILD_LIB_SPEC}"
 714              ITK_DEPS="${itkdir}${ITK_LIB_FILE}"
 715            fi
 716
 717            # now look for tix library stuff
 718            TIXVERSION=4.1.8.0
 719            . ${ac_cv_c_tclconfig}/tclConfig.sh
 720            case "${host}" in
 721            *-*-cygwin*)
 722                 tixdir=../tix/win/tcl8.0
 723                 ;;
 724            *)
 725                 tixdir=../tix/unix/tk8.0
 726                 ;;
 727            esac
 728            if test "${TCL_SHARED_BUILD}" = "1"; then
 729                 TIX_LIB_EXT="${TCL_SHLIB_SUFFIX}"
 730
 731                 # Can't win them all: SunOS 4 (others?) appends a version
 732                 # number after the ".so"
 733                 case "${host}" in
 734                 *-*-sunos4*)
 735                     TIX_LIB_EXT="${TIX_LIB_EXT}.1.0" ;;
 736                 esac
 737
 738            else
 739                 TIX_LIB_EXT=".a"
 740            fi
 741
 742            if test "${TCL_LIB_VERSIONS_OK}" = "ok"; then
 743                 TIXLIB="-L${tixdir} -ltix${TIXVERSION}"
 744                 TIX_DEPS="${tixdir}/libtix${TIXVERSION}${TIX_LIB_EXT}"
 745            else
 746                 TIXLIB="-L${tixdir} -ltix`echo ${TIXVERSION} | tr -d .`"
 747                 TIX_DEPS="${tixdir}/libtix`echo ${TIXVERSION} | tr -d .`${TIX_LIB_EXT}"
 748            fi
 749
 750            ENABLE_GDBTK=1
 751            ENABLE_CFLAGS="${ENABLE_CFLAGS} -DGDBTK"
 752
 753            # Include some libraries that Tcl and Tk want.
 754            if test "${enable_ide}" = "yes"; then
 755               TCL_LIBS='$(LIBIDETCL) $(LIBIDE) $(LIBGUI) $(IDE) $(ITCL) $(ITK) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 756               CONFIG_DEPS='$(LIBIDETCL) $(LIBIDE) $(LIBGUI) $(IDE_DEPS) $(ITCL_DEPS) $(TIX_DEPS) $(TK_DEPS) $(TCL_DEPS)'
 757            else
 758               TCL_LIBS='$(LIBGUI) $(ITCL) $(ITK) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 759               CONFIG_DEPS='$(LIBGUI) $(ITCL_DEPS) $(ITK_DEPS) $(TIX_DEPS) $(TK_DEPS) $(TCL_DEPS)'
 760            fi
 761            # Yes, the ordering seems wrong here.  But it isn't.
 762            # TK_LIBS is the list of libraries that need to be linked
 763            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
 764            # were in LIBS then any link tests after this point would
 765            # try to include things like `$(LIBGUI)', which wouldn't work.
 766            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
 767            CONFIG_OBS="${CONFIG_OBS} gdbtk.o gdbtk-cmds.o gdbtk-hooks.o gdbtk-variable.o gdbtk-wrapper.o"
 768
 769            if test x$gdb_cv_os_cygwin = xyes; then
 770               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
 771               WIN32LDAPP="-Wl,--subsystem,console"
 772               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
 773            fi
 774         fi
 775     fi
 776 fi
 777
 778 AC_SUBST(ENABLE_GDBTK)
 779 AC_SUBST(X_CFLAGS)
 780 AC_SUBST(X_LDFLAGS)
 781 AC_SUBST(X_LIBS)
 782 AC_SUBST(ITCLLIB)
 783 AC_SUBST(ITCL_DEPS)
 784 AC_SUBST(ITKLIB)
 785 AC_SUBST(ITK_DEPS)
 786 AC_SUBST(TIXLIB)
 787 AC_SUBST(TIX_DEPS)
 788 AC_SUBST(GDBTKLIBS)
 789 # end-sanitize-gdbtk
 790
 791 AC_PATH_X
 792 # start-sanitize-sky
 793 # Enable GPU2 library for MIPS simulator
 794 AC_ARG_WITH(sim-gpu2,
 795 [  --with-sim-gpu2=DIR     Use GPU2 library under given DIR],
 796 [case "${target}" in
 797   mips*-sky*-*)
 798     if test -d "${withval}"
 799     then
 800       if test x${x_libraries} != x
 801       then
 802         LIBS="${LIBS} -L${withval}/lib -lgpu2 -L${x_libraries} -lX11 -lXext -lm"
 803       else
 804         LIBS="${LIBS} -L${withval}/lib -lgpu2 -lX11 -lXext -lm"
 805       fi
 806     else
 807       AC_MSG_WARN([Directory ${withval} does not exist.])
 808     fi ;;
 809   *)  AC_MSG_WARN([--with-sim-gpu2 option invalid for target ${target}])
 810 esac])dnl
 811
 812 # Enable target accurate FP library
 813 AC_ARG_WITH(sim-funit,
 814 [  --with-sim-funit=DIR    Use target FP lib under given DIR],
 815 [case "${target}" in
 816   mips*-sky*-*)
 817     if test -d "${withval}"
 818     then
 819       LIBS="${LIBS} -L${withval}/lib -lfunit"
 820     else
 821       AC_MSG_WARN([Directory ${withval} does not exist.])
 822     fi ;;
 823   *)  AC_MSG_WARN([--with-sim-funit option invalid for target ${target}])
 824 esac])dnl
 825 # end-sanitize-sky
 826
 827 AC_SUBST(ENABLE_CFLAGS)
 828
 829 AC_SUBST(CONFIG_OBS)
 830 AC_SUBST(CONFIG_DEPS)
 831 AC_SUBST(CONFIG_SRCS)
 832
 833 # Begin stuff to support --enable-shared
 834 AC_ARG_ENABLE(shared,
 835 [  --enable-shared         Use shared libraries],
 836 [case "${enableval}" in
 837   yes) shared=true ;;
 838   no)  shared=false ;;
 839   *) shared=true ;;
 840 esac])dnl
 841
 842 HLDFLAGS=
 843 HLDENV=
 844 # If we have shared libraries, try to set rpath reasonably.
 845 if test "${shared}" = "true"; then
 846   case "${host}" in
 847   *-*-hpux*)
 848     HLDFLAGS='-Wl,+s,+b,$(libdir)'
 849     ;;
 850   *-*-irix5* | *-*-irix6*)
 851     HLDFLAGS='-Wl,-rpath,$(libdir)'
 852     ;;
 853   *-*-linux*aout*)
 854     ;;
 855   *-*-linux* | *-pc-linux-gnu)
 856     HLDFLAGS='-Wl,-rpath,$(libdir)'
 857     ;;
 858   *-*-solaris*)
 859     HLDFLAGS='-R $(libdir)'
 860     ;;
 861   *-*-sysv4*)
 862     HLDENV='if test -z "$${LD_RUN_PATH}"; then LD_RUN_PATH=$(libdir); else LD_RUN_PATH=$${LD_RUN_PATH}:$(libdir); fi; export LD_RUN_PATH;'
 863     ;;
 864   esac
 865 fi
 866
 867 # On SunOS, if the linker supports the -rpath option, use it to
 868 # prevent ../bfd and ../opcodes from being included in the run time
 869 # search path.
 870 case "${host}" in
 871   *-*-sunos*)
 872     echo 'main () { }' > conftest.c
 873     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
 874     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
 875       :
 876     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
 877       :
 878     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
 879       :
 880     elif grep 'some text already loaded' conftest.t >/dev/null 2>&1; then
 881       :
 882     elif test "${shared}" = "true"; then
 883       HLDFLAGS='-Wl,-rpath=$(libdir)'
 884     else
 885       HLDFLAGS='-Wl,-rpath='
 886     fi
 887     rm -f conftest.t conftest.c conftest
 888     ;;
 889 esac
 890 AC_SUBST(HLDFLAGS)
 891 AC_SUBST(HLDENV)
 892 # End stuff to support --enable-shared
 893
 894 # target_subdir is used by the testsuite to find the target libraries.
 895 target_subdir=
 896 if test "${host}" != "${target}"; then
 897     target_subdir="${target_alias}/"
 898 fi
 899 AC_SUBST(target_subdir)
 900
 901 frags=
 902 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
 903 if test ! -f ${host_makefile_frag}; then
 904 AC_MSG_ERROR("*** Gdb does not support host ${host}")
 905 fi
 906 frags="$frags $host_makefile_frag"
 907
 908 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
 909 if test ! -f ${target_makefile_frag}; then
 910 AC_MSG_ERROR("*** Gdb does not support target ${target}")
 911 fi
 912 frags="$frags $target_makefile_frag"
 913
 914 AC_SUBST_FILE(host_makefile_frag)
 915 AC_SUBST_FILE(target_makefile_frag)
 916 AC_SUBST(frags)
 917
 918 changequote(,)dnl
 919 hostfile=`sed -n '
 920 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 921 ' ${host_makefile_frag}`
 922
 923 targetfile=`sed -n '
 924 s/TM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 925 ' ${target_makefile_frag}`
 926
 927 # these really aren't orthogonal true/false values of the same condition,
 928 # but shells are slow enough that I like to reuse the test conditions
 929 # whenever possible
 930 if test "${target}" = "${host}"; then
 931 nativefile=`sed -n '
 932 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
 933 ' ${host_makefile_frag}`
 934 # else
 935 # GDBserver is only useful in a "native" enviroment
 936 # configdirs=`echo $configdirs | sed 's/gdbserver//'`
 937 fi
 938 changequote([,])
 939
 940 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
 941 # (NAT_FILE) is not set in config/*/*.m[ht] files, we don't make the
 942 # corresponding links.  But we have to remove the xm.h files and tm.h
 943 # files anyway, e.g. when switching from "configure host" to
 944 # "configure none".
 945
 946 files=
 947 links=
 948 rm -f xm.h
 949 if test "${hostfile}" != ""; then
 950 files="${files} config/${gdb_host_cpu}/${hostfile}"
 951 links="${links} xm.h"
 952 fi
 953 rm -f tm.h
 954 if test "${targetfile}" != ""; then
 955 files="${files} config/${gdb_target_cpu}/${targetfile}"
 956 links="${links} tm.h"
 957 fi
 958 rm -f nm.h
 959 if test "${nativefile}" != ""; then
 960 files="${files} config/${gdb_host_cpu}/${nativefile}"
 961 links="${links} nm.h"
 962 else
 963 # A cross-only configuration.
 964 files="${files} config/nm-empty.h"
 965 links="${links} nm.h"
 966 fi
 967 # start-sanitize-gdbtk
 968 AC_PROG_LN_S
 969 # Make it possible to use the GUI without doing a full install
 970 if test "${enable_gdbtk}" = "yes" -a ! -d gdbtcl2 ; then
 971   if test "$LN_S" = "ln -s" -a ! -f gdbtcl2 ; then
 972   echo linking $srcdir/gdbtcl2 to gdbtcl2
 973   $LN_S $srcdir/gdbtcl2 gdbtcl2
 974   else
 975   echo Warning: Unable to link $srcdir/gdbtcl2 to gdbtcl2.  You will need to do a
 976   echo "         " make install before you are able to run the GUI.
 977   fi
 978 fi
 979 # end-sanitize-gdbtk
 980
 981 AC_LINK_FILES($files, $links)
 982
 983 dnl Check for exe extension set on certain hosts (e.g. Win32)
 984 AC_EXEEXT
 985
 986 AC_CONFIG_SUBDIRS($configdirs)
 987 AC_OUTPUT(Makefile tui/Makefile .gdbinit:gdbinit.in,
 988 [
 989 dnl Autoconf doesn't provide a mechanism for modifying definitions
 990 dnl provided by makefile fragments.
 991 dnl
 992 if test "${nativefile}" = ""; then
 993 sed -e '/^NATDEPFILES[[         ]]*=[[  ]]*/s//# NATDEPFILES=/' \
 994         < Makefile > Makefile.tem
 995 mv -f Makefile.tem Makefile
 996 fi
 997
 998 changequote(,)dnl
 999 sed -e '/^TM_FILE[      ]*=/s,^TM_FILE[         ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
1000 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
1001 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
1002 mv -f Makefile.tmp Makefile
1003 changequote([,])dnl
1004
1005 case x$CONFIG_HEADERS in
1006 xconfig.h:config.in)
1007 echo > stamp-h ;;
1008 esac
1009 ],
1010 [
1011 gdb_host_cpu=$gdb_host_cpu
1012 gdb_target_cpu=$gdb_target_cpu
1013 nativefile=$nativefile
1014 ])
1015
1016 exit 0