gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 2 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program; if not, write to the Free Software
  18 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  19
  20 dnl Process this file with autoconf to produce a configure script.
  21
  22 AC_PREREQ(2.5)dnl
  23 AC_INIT(main.c)
  24 AC_CONFIG_HEADER(config.h:config.in)
  25
  26 AC_PROG_CC
  27 AC_AIX
  28 AC_MINIX
  29 AC_ISC_POSIX
  30
  31 AC_CANONICAL_SYSTEM
  32
  33 AC_PROG_INSTALL
  34 AC_CHECK_TOOL(AR, ar)
  35 AC_CHECK_TOOL(RANLIB, ranlib, :)
  36 AC_PROG_YACC
  37 AC_PROG_AWK
  38
  39 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  40 AC_ARG_PROGRAM
  41
  42 AC_HEADER_STDC
  43 AC_CHECK_HEADERS(limits.h memory.h string.h strings.h unistd.h termios.h termio.h sgtty.h stddef.h stdlib.h sys/procfs.h link.h endian.h objlist.h)
  44 AC_HEADER_STAT
  45
  46 AC_C_CONST
  47
  48 AC_CHECK_FUNCS(setpgid sbrk select poll)
  49
  50 dnl List of object files added by configuire.
  51
  52 CONFIG_OBS=
  53
  54 # If we are configured native on Linux, work around problems with sys/procfs.h
  55 if test "${target}" = "${host}"; then
  56   case "${host}" in
  57   i[3456]86-*-linux*)
  58         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,"2")
  59         AC_DEFINE(sys_quotactl)
  60         ;;
  61   esac
  62 fi
  63
  64 AC_MSG_CHECKING([for gregset_t type])
  65 AC_CACHE_VAL(gdb_cv_have_gregset_t,
  66 [AC_TRY_LINK([#include <sys/procfs.h>],[gregset_t *gregsetp = 0],
  67 gdb_cv_have_gregset_t=yes, gdb_cv_have_gregset_t=no)])
  68 AC_MSG_RESULT($gdb_cv_have_gregset_t)
  69 if test $gdb_cv_have_gregset_t = yes; then
  70   AC_DEFINE(HAVE_GREGSET_T)
  71 fi
  72
  73 AC_MSG_CHECKING([for fpregset_t type])
  74 AC_CACHE_VAL(gdb_cv_have_fpregset_t,
  75 [AC_TRY_LINK([#include <sys/procfs.h>],[fpregset_t *fpregsetp = 0],
  76 gdb_cv_have_fpregset_t=yes, gdb_cv_have_fpregset_t=no)])
  77 AC_MSG_RESULT($gdb_cv_have_fpregset_t)
  78 if test $gdb_cv_have_fpregset_t = yes; then
  79   AC_DEFINE(HAVE_FPREGSET_T)
  80 fi
  81
  82 dnl See if compiler supports "long long" type.
  83
  84 AC_MSG_CHECKING(for long long support in compiler)
  85 AC_CACHE_VAL(gdb_cv_c_long_long,
  86 [AC_TRY_COMPILE(, [
  87   extern long long foo;
  88   switch (foo & 2) { case 0: return 1; }
  89 ],
  90 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
  91 AC_MSG_RESULT($gdb_cv_c_long_long)
  92 if test $gdb_cv_c_long_long = yes; then
  93   AC_DEFINE(CC_HAS_LONG_LONG)
  94 fi
  95
  96 dnl See if the compiler and runtime support printing long long
  97
  98 AC_MSG_CHECKING(for long long support in printf)
  99 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 100 [AC_TRY_RUN([
 101 int main () {
 102   char buf[16];
 103   long long l = 0x12345;
 104   sprintf (buf, "%llx", l);
 105   return (strcmp ("12345", buf));
 106 }],
 107 gdb_cv_printf_has_long_long=yes,
 108 gdb_cv_printf_has_long_long=no,
 109 gdb_cv_printf_has_long_long=no)])
 110 if test $gdb_cv_printf_has_long_long = yes; then
 111   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 112 fi
 113 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 114
 115 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 116 dnl because autoconf complains about cross-compilation issues.  However, this
 117 dnl code uses the same variables as the macro for compatibility.
 118
 119 AC_MSG_CHECKING(for long double support in compiler)
 120 AC_CACHE_VAL(ac_cv_c_long_double,
 121 [AC_TRY_COMPILE(, [long double foo;],
 122 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 123 AC_MSG_RESULT($ac_cv_c_long_double)
 124 if test $ac_cv_c_long_double = yes; then
 125   AC_DEFINE(HAVE_LONG_DOUBLE)
 126 fi
 127
 128 dnl See if the compiler and runtime support printing long doubles
 129
 130 AC_MSG_CHECKING(for long double support in printf)
 131 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 132 [AC_TRY_RUN([
 133 int main () {
 134   char buf[16];
 135   long double f = 3.141592653;
 136   sprintf (buf, "%Lg", f);
 137   return (strncmp ("3.14159", buf, 7));
 138 }],
 139 gdb_cv_printf_has_long_double=yes,
 140 gdb_cv_printf_has_long_double=no,
 141 gdb_cv_printf_has_long_double=no)])
 142 if test $gdb_cv_printf_has_long_double = yes; then
 143   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 144 fi
 145 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 146
 147 AC_FUNC_MMAP
 148
 149 BFD_NEED_DECLARATION(malloc)
 150 BFD_NEED_DECLARATION(realloc)
 151 BFD_NEED_DECLARATION(free)
 152
 153 dnl See if thread_db library is around for Solaris thread debugging.  Note that
 154 dnl we must explicitly test for version 1 of the library because version 0
 155 dnl (present on Solaris 2.4 or earlier) doesn't have the same API.
 156
 157 dnl Note that we only want this if we are both native (host == target), and
 158 dnl not doing a canadian cross build (build == host).
 159
 160 if test ${build} = ${host} -a ${host} = ${target} ; then
 161         case ${host_os} in
 162         hpux*)
 163                 AC_MSG_CHECKING(for HPUX/OSF thread support)
 164                 if test -f /usr/include/dce/cma_config.h ; then
 165                         AC_MSG_RESULT(yes)
 166                         AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 167                         CONFIG_OBS="${CONFIG_OJS} hpux-thread.o"
 168                 else
 169                         AC_MSG_RESULT(no)
 170                 fi
 171                 ;;
 172         solaris*)
 173                 AC_MSG_CHECKING(for Solaris thread debugging library)
 174                 if test -f /usr/lib/libthread_db.so.1 ; then
 175                         AC_MSG_RESULT(yes)
 176                         AC_DEFINE(HAVE_THREAD_DB_LIB)
 177                         CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
 178                         CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Xlinker -export-dynamic"
 179                 else
 180                         AC_MSG_RESULT(no)
 181                 fi
 182                 ;;
 183         esac
 184         AC_SUBST(CONFIG_LDFLAGS)
 185 fi
 186
 187 dnl Handle optional features that can be enabled.
 188 ENABLE_CFLAGS=
 189
 190 AC_ARG_ENABLE(netrom,
 191 [  --enable-netrom ],
 192 [case "${enableval}" in
 193 yes)    enable_netrom=yes ;;
 194 no)     enable_netrom=no ;;
 195 *)      AC_MSG_ERROR(bad value ${enableval} given for netrom option) ;;
 196 esac])
 197
 198 if test "${enable_netrom}" = "yes"; then
 199         CONFIG_OBS="${CONFIG_OBS} remote-nrom.o"
 200 fi
 201
 202 # start-sanitize-gm
 203 ENABLE_GM=
 204
 205 AC_ARG_ENABLE(gm,
 206 [  --enable-gm ],
 207 [case "${enableval}" in
 208 yes)    CONFIG_OBS="${CONFIG_OBS} gmagic.o"
 209         ENABLE_CFLAGS=-DGENERAL_MAGIC
 210         ;;
 211 no)     ;;
 212 *)      AC_MSG_ERROR(bad value ${enableval} given for gm option) ;;
 213 esac])
 214
 215 # end-sanitize-gm
 216
 217 AC_ARG_ENABLE(sim-powerpc,
 218 [  --enable-sim-powerpc ],
 219 [case "${enableval}" in
 220 yes)    powerpc_sim=yes ;;
 221 no)     powerpc_sim=no ;;
 222 *)      AC_MSG_ERROR(bad value ${enableval} given for sim-powerpc option) ;;
 223 esac],[if test x"$GCC" != x""; then powerpc_sim=yes; else powerpc_sim=no; fi])
 224
 225 # start-sanitize-gdbtk
 226 ENABLE_GDBTK=
 227
 228 AC_ARG_ENABLE(gdbtk,
 229 [  --enable-gdbtk ],
 230 [case "${enableval}" in
 231     yes)
 232         case "$host" in
 233         *go32*)
 234             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 235             enable_gdbtk=no ;;
 236         *cygwin32* | *windows*)
 237             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 238             enable_gdbtk=no ;;
 239         *)
 240             enable_gdbtk=yes ;;
 241         esac ;;
 242     no)
 243         enable_gdbtk=no  ;;
 244     *)
 245         AC_MSG_ERROR(bad value ${enableval} given for gdbtk option) ;;
 246 esac],
 247 [
 248 # Default is on for everything but go32 and cygwin32
 249 case "$host" in
 250     *go32* | *cygwin32* | *windows*)
 251         ;;
 252     *)
 253         enable_gdbtk=yes ;;
 254     esac
 255 ])
 256
 257 if test "${enable_gdbtk}" = "yes"; then
 258
 259     CY_AC_PATH_TCLCONFIG
 260     if test -z "${no_tcl}"; then
 261         CY_AC_LOAD_TCLCONFIG
 262         CY_AC_PATH_TKCONFIG
 263
 264         # If $no_tk is nonempty, then we can't do Tk, and there is no
 265         # point to doing Tcl.
 266         if test -z "${no_tk}"; then
 267            CY_AC_LOAD_TKCONFIG
 268            CY_AC_PATH_TCLH
 269            CY_AC_PATH_TKH
 270
 271            ENABLE_GDBTK=1
 272
 273            # Include some libraries that Tcl and Tk want.
 274            TCL_LIBS='$(TCL) $(TK) $(X11_LDFLAGS) $(X11_LIBS)'
 275            LIBS="${LIBS} ${TCL_LIBS} ${TK_LIBS}"
 276            CONFIG_OBS="${CONFIG_OBS} gdbtk.o"
 277         fi
 278     fi
 279 fi
 280
 281 AC_SUBST(ENABLE_GDBTK)
 282 AC_SUBST(X_CFLAGS)
 283 AC_SUBST(X_LDFLAGS)
 284 AC_SUBST(X_LIBS)
 285 # end-sanitize-gdbtk
 286
 287 AC_SUBST(ENABLE_CFLAGS)
 288
 289 AC_SUBST(CONFIG_OBS)
 290
 291 # Begin stuff to support --enable-shared
 292 AC_ARG_ENABLE(shared,
 293 [  --enable-shared         use shared libraries],
 294 [case "${enableval}" in
 295   yes) shared=true ;;
 296   no)  shared=false ;;
 297   *) shared=true ;;
 298 esac])dnl
 299
 300 HLDFLAGS=
 301 HLDENV=
 302 # If we have shared libraries, try to set rpath reasonably.
 303 if test "${shared}" = "true"; then
 304   case "${host}" in
 305   *-*-hpux*)
 306     HLDFLAGS='-Wl,+s,+b,$(libdir)'
 307     ;;
 308   *-*-irix5* | *-*-irix6*)
 309     HLDFLAGS='-Wl,-rpath,$(libdir)'
 310     ;;
 311   *-*-linux*aout*)
 312     ;;
 313   *-*-linux* | *-pc-linux-gnu)
 314     HLDFLAGS='-Wl,-rpath,$(libdir)'
 315     ;;
 316   *-*-solaris*)
 317     HLDFLAGS='-R $(libdir)'
 318     ;;
 319   *-*-sysv4*)
 320     HLDENV='if test -z "$${LD_RUN_PATH}"; then LD_RUN_PATH=$(libdir); else LD_RUN_PATH=$${LD_RUN_PATH}:$(libdir); fi; export LD_RUN_PATH;'
 321     ;;
 322   esac
 323 fi
 324
 325 # On SunOS, if the linker supports the -rpath option, use it to
 326 # prevent ../bfd and ../opcodes from being included in the run time
 327 # search path.
 328 case "${host}" in
 329   *-*-sunos*)
 330     echo 'main () { }' > conftest.c
 331     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
 332     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
 333       :
 334     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
 335       :
 336     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
 337       :
 338     elif grep 'some text already loaded' conftest.t >/dev/null 2>&1; then
 339       :
 340     elif test "${shared}" = "true"; then
 341       HLDFLAGS='-Wl,-rpath=$(libdir)'
 342     else
 343       HLDFLAGS='-Wl,-rpath='
 344     fi
 345     rm -f conftest.t conftest.c conftest
 346     ;;
 347 esac
 348 AC_SUBST(HLDFLAGS)
 349 AC_SUBST(HLDENV)
 350 # End stuff to support --enable-shared
 351
 352 # target_subdir is used by the testsuite to find the target libraries.
 353 target_subdir=
 354 if test "${host}" != "${target}"; then
 355     target_subdir="${target_alias}/"
 356 fi
 357 AC_SUBST(target_subdir)
 358
 359 configdirs="doc testsuite"
 360
 361 dnl
 362 changequote(,)dnl
 363
 364 . ${srcdir}/configure.host
 365
 366 . ${srcdir}/configure.tgt
 367
 368 dnl
 369 changequote([,])dnl
 370
 371 frags=
 372 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
 373 if test ! -f ${host_makefile_frag}; then
 374 AC_MSG_ERROR("*** Gdb does not support host ${host}")
 375 fi
 376 frags="$frags $host_makefile_frag"
 377
 378 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
 379 if test ! -f ${target_makefile_frag}; then
 380 AC_MSG_ERROR("*** Gdb does not support target ${target}")
 381 fi
 382 frags="$frags $target_makefile_frag"
 383
 384 AC_SUBST_FILE(host_makefile_frag)
 385 AC_SUBST_FILE(target_makefile_frag)
 386 AC_SUBST(frags)
 387
 388 changequote(,)dnl
 389 hostfile=`sed -n '
 390 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 391 ' ${host_makefile_frag}`
 392
 393 targetfile=`sed -n '
 394 s/TM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 395 ' ${target_makefile_frag}`
 396
 397 # these really aren't orthogonal true/false values of the same condition,
 398 # but shells are slow enough that I like to reuse the test conditions
 399 # whenever possible
 400 if test "${target}" = "${host}"; then
 401 nativefile=`sed -n '
 402 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
 403 ' ${host_makefile_frag}`
 404 else
 405 # GDBserver is only useful in a "native" enviroment
 406 configdirs=`echo $configdirs | sed 's/gdbserver//'`
 407 fi
 408 changequote([,])
 409
 410 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
 411 # (NAT_FILE) is not set in config/*/*.m[ht] files, we don't make the
 412 # corresponding links.  But we have to remove the xm.h files and tm.h
 413 # files anyway, e.g. when switching from "configure host" to
 414 # "configure none".
 415
 416 files=
 417 links=
 418 rm -f xm.h
 419 if test "${hostfile}" != ""; then
 420 files="${files} config/${gdb_host_cpu}/${hostfile}"
 421 links="${links} xm.h"
 422 fi
 423 rm -f tm.h
 424 if test "${targetfile}" != ""; then
 425 files="${files} config/${gdb_target_cpu}/${targetfile}"
 426 links="${links} tm.h"
 427 fi
 428 rm -f nm.h
 429 if test "${nativefile}" != ""; then
 430 files="${files} config/${gdb_host_cpu}/${nativefile}"
 431 links="${links} nm.h"
 432 else
 433 # A cross-only configuration.
 434 files="${files} config/nm-empty.h"
 435 links="${links} nm.h"
 436 fi
 437 # start-sanitize-gdbtk
 438
 439 # Make it possible to use the GUI without doing a full install
 440 if test "${enable_gdbtk}" = "yes" -a ! -f gdbtk.tcl ; then
 441 files="${files} gdbtk.tcl"
 442 links="${links} gdbtk.tcl"
 443 fi
 444 # end-sanitize-gdbtk
 445
 446 AC_LINK_FILES($files, $links)
 447
 448 AC_CONFIG_SUBDIRS($configdirs)
 449 AC_OUTPUT(Makefile,
 450 [
 451 dnl Autoconf doesn't provide a mechanism for modifying definitions
 452 dnl provided by makefile fragments.
 453 dnl
 454 if test "${nativefile}" = ""; then
 455 sed -e '/^NATDEPFILES[[         ]]*=[[  ]]*/s//# NATDEPFILES=/' \
 456         < Makefile > Makefile.tem
 457 mv -f Makefile.tem Makefile
 458 fi
 459
 460 changequote(,)dnl
 461 sed -e '/^TM_FILE[      ]*=/s,^TM_FILE[         ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
 462 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
 463 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
 464 mv -f Makefile.tmp Makefile
 465 changequote([,])dnl
 466
 467 case ${srcdir} in
 468 .)
 469 ;;
 470 *)
 471 grep "source ${srcdir}/.gdbinit" .gdbinit >/dev/null 2>/dev/null || \
 472 echo "source ${srcdir}/.gdbinit" >> .gdbinit
 473 esac
 474
 475 case x$CONFIG_HEADERS in
 476 xconfig.h:config.in)
 477 echo > stamp-h ;;
 478 esac
 479 ],
 480 [
 481 gdb_host_cpu=$gdb_host_cpu
 482 gdb_target_cpu=$gdb_target_cpu
 483 nativefile=$nativefile
 484 ])
 485
 486 exit 0
 487