gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003
   3 dnl Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is part of GDB.
   6 dnl
   7 dnl This program is free software; you can redistribute it and/or modify
   8 dnl it under the terms of the GNU General Public License as published by
   9 dnl the Free Software Foundation; either version 2 of the License, or
  10 dnl (at your option) any later version.
  11 dnl
  12 dnl This program is distributed in the hope that it will be useful,
  13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 dnl GNU General Public License for more details.
  16 dnl
  17 dnl You should have received a copy of the GNU General Public License
  18 dnl along with this program; if not, write to the Free Software
  19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.13)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_AIX
  30 AC_ISC_POSIX
  31 AM_PROG_CC_STDC
  32
  33 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  34 AC_CANONICAL_SYSTEM
  35
  36 dnl Set up for gettext.  PACKAGE is used when we call bindtextdomain.
  37 ALL_LINGUAS=
  38 CY_GNU_GETTEXT
  39 AC_DEFINE(PACKAGE, "gdb", [Name of this package. ])
  40
  41
  42 dnl List of object files added by configure.
  43
  44 CONFIG_OBS=
  45 CONFIG_LIB_OBS=
  46 CONFIG_DEPS=
  47 CONFIG_SRCS=
  48 CONFIG_INITS=
  49 ENABLE_CFLAGS=
  50 CONFIG_ALL=
  51 CONFIG_CLEAN=
  52 CONFIG_INSTALL=
  53 CONFIG_UNINSTALL=
  54
  55 SUBDIRS="doc testsuite nlm"
  56 configdirs="doc testsuite"
  57
  58 AC_ARG_ENABLE(multi-ice,
  59 [  --enable-multi-ice            Build the multi-ice-gdb-server],
  60 [case "${enableval}" in
  61     yes ) enable_multi_ice="yes" ;;
  62     no)  enable_multi_ice="no" ;;
  63     *) AC_MSG_ERROR(Bad value for --enable-multi-ice: ${enableval}) ;;
  64   esac
  65 ])
  66
  67 if test "${enable_multi_ice}" = "yes"; then
  68   configdirs="${configdirs} multi-ice"
  69 fi
  70
  71 dnl
  72 changequote(,)dnl
  73
  74 . ${srcdir}/configure.host
  75
  76 . ${srcdir}/configure.tgt
  77
  78 targ=${target} ; . ${srcdir}/../bfd/config.bfd
  79
  80 dnl
  81 changequote([,])dnl
  82
  83 dnl use BFD to determine the default architecture and byte order
  84 dnl (bfd_vec->byteorder provides the latter).
  85 targ=${target}
  86 . ${srcdir}/../bfd/config.bfd
  87
  88 dnl We only want the first arch, if there is more than one.
  89 targ_archs=`echo ${targ_archs} | sed -e 's/ .*//;'`
  90
  91 if test x"${targ_archs}" != x ; then
  92     AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, ${targ_archs})
  93 fi
  94 if test x"${targ_defvec}" != x ; then
  95     AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, ${targ_defvec})
  96 fi
  97
  98 AC_PROG_AWK
  99 AC_PROG_INSTALL
 100 AC_CHECK_TOOL(AR, ar)
 101 AC_CHECK_TOOL(RANLIB, ranlib, :)
 102 AC_CHECK_TOOL(DLLTOOL, dlltool)
 103 AC_CHECK_TOOL(WINDRES, windres)
 104 AC_PROG_YACC
 105
 106 dnl MiG is needed for the Hurd.
 107 AC_CHECK_TOOL(MIG, mig)
 108
 109 AC_ARG_PROGRAM
 110
 111 # ---------------------- #
 112 # Checks for libraries.  #
 113 # ---------------------- #
 114
 115 # We might need to link with -lm; most simulators need it.
 116 AC_CHECK_LIB(m, main)
 117
 118 # We need to link with -lw to get `wctype' on Solaris before Solaris
 119 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 120 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 121 # is known to have this problem).  Therefore we avoid libw if we can.
 122 AC_CHECK_FUNC(wctype, [],
 123   [AC_CHECK_LIB(w, wctype)])
 124
 125 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 126 AC_SEARCH_LIBS(socketpair, socket)
 127
 128 AC_TYPE_SIGNAL
 129
 130 AC_HEADER_DIRENT
 131 AC_HEADER_STDC
 132
 133 dnl Solaris 7 needs _MSE_INT_H defined to avoid a clash between <widec.h>
 134 dnl and <wchar.h> that causes AC_CHECK_HEADERS to think <curses.h> doesn't
 135 dnl exist.
 136
 137 case $host_os in solaris2.7 | solaris2.8) case "$GCC" in yes)
 138     AC_DEFINE(_MSE_INT_H)
 139 esac; esac
 140
 141 AC_CHECK_HEADERS(ctype.h nlist.h link.h thread_db.h proc_service.h \
 142         memory.h objlist.h ptrace.h sgtty.h stddef.h stdlib.h \
 143         string.h sys/procfs.h sys/proc.h sys/ptrace.h sys/reg.h stdint.h \
 144         term.h termio.h termios.h unistd.h wait.h sys/wait.h \
 145         wchar.h wctype.h asm/debugreg.h sys/debugreg.h sys/select.h \
 146         time.h sys/file.h sys/ioctl.h sys/user.h sys/fault.h sys/syscall.h \
 147         sys/filio.h \
 148         curses.h ncurses.h \
 149         poll.h sys/poll.h)
 150 AC_HEADER_STAT
 151
 152 AC_C_CONST
 153 AC_C_INLINE
 154
 155 AC_CHECK_FUNCS(btowc canonicalize_file_name isascii poll \
 156         realpath sbrk setpgid setpgrp sigaction sigprocmask sigsetmask )
 157 AC_FUNC_ALLOCA
 158 AC_FUNC_VFORK
 159 dnl AC_FUNC_SETPGRP does not work when cross compiling
 160 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
 161 if test "$cross_compiling" = no; then
 162   AC_FUNC_SETPGRP
 163 else
 164   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
 165     [AC_TRY_COMPILE([
 166 #include <unistd.h>
 167 ], [
 168   if (setpgrp(1,1) == -1)
 169     exit (0);
 170   else
 171     exit (1);
 172 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
 173 if test $ac_cv_func_setpgrp_void = yes; then
 174   AC_DEFINE(SETPGRP_VOID, 1)
 175 fi
 176 fi
 177
 178 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
 179 # since sigsetjmp might only be defined as a macro.
 180 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
 181 [AC_TRY_COMPILE([
 182 #include <setjmp.h>
 183 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 184 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
 185 if test $gdb_cv_func_sigsetjmp = yes; then
 186   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 187 fi
 188
 189 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
 190 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
 191 AC_CACHE_CHECK([for r_fs in struct reg], gdb_cv_struct_reg_r_fs,
 192 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_fs;],
 193 gdb_cv_struct_reg_r_fs=yes, gdb_cv_struct_reg_r_fs=no)])
 194 if test $gdb_cv_struct_reg_r_fs = yes; then
 195   AC_DEFINE(HAVE_STRUCT_REG_R_FS)
 196 fi
 197 AC_CACHE_CHECK([for r_gs in struct reg], gdb_cv_struct_reg_r_gs,
 198 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_gs;],
 199 gdb_cv_struct_reg_r_gs=yes, gdb_cv_struct_reg_r_gs=no)])
 200 if test $gdb_cv_struct_reg_r_gs = yes; then
 201   AC_DEFINE(HAVE_STRUCT_REG_R_GS)
 202 fi
 203
 204 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
 205 AC_MSG_CHECKING(for PTRACE_GETREGS)
 206 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
 207 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 208                 [PTRACE_GETREGS;],
 209                 [gdb_cv_have_ptrace_getregs=yes],
 210                 [gdb_cv_have_ptrace_getregs=no])])
 211 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
 212 if test $gdb_cv_have_ptrace_getregs = yes; then
 213   AC_DEFINE(HAVE_PTRACE_GETREGS)
 214 fi
 215
 216 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
 217 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 218 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
 219 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 220                 [PTRACE_GETFPXREGS;],
 221                 [gdb_cv_have_ptrace_getfpxregs=yes],
 222                 [gdb_cv_have_ptrace_getfpxregs=no])])
 223 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
 224 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
 225   AC_DEFINE(HAVE_PTRACE_GETFPXREGS)
 226 fi
 227
 228 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
 229 AC_MSG_CHECKING(for PT_GETDBREGS)
 230 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
 231 [AC_TRY_COMPILE([#include <sys/types.h>
 232 #include <sys/ptrace.h>],
 233                 [PT_GETDBREGS;],
 234                 [gdb_cv_have_pt_getdbregs=yes],
 235                 [gdb_cv_have_pt_getdbregs=no])])
 236 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
 237 if test $gdb_cv_have_pt_getdbregs = yes; then
 238   AC_DEFINE(HAVE_PT_GETDBREGS)
 239 fi
 240
 241 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
 242 AC_MSG_CHECKING(for PT_GETXMMREGS)
 243 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
 244 [AC_TRY_COMPILE([#include <sys/types.h>
 245 #include <sys/ptrace.h>],
 246                 [PT_GETXMMREGS;],
 247                 [gdb_cv_have_pt_getxmmregs=yes],
 248                 [gdb_cv_have_pt_getxmmregs=no])])
 249 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
 250 if test $gdb_cv_have_pt_getxmmregs = yes; then
 251   AC_DEFINE(HAVE_PT_GETXMMREGS)
 252 fi
 253
 254
 255 AC_CHECK_FUNCS(socketpair)
 256
 257
 258 BFD_NEED_DECLARATION(malloc)
 259 BFD_NEED_DECLARATION(realloc)
 260 BFD_NEED_DECLARATION(free)
 261 BFD_NEED_DECLARATION(strerror)
 262 BFD_NEED_DECLARATION(strdup)
 263 BFD_NEED_DECLARATION(strstr)
 264 BFD_NEED_DECLARATION(canonicalize_file_name)
 265
 266 # The following save_state_t checkery is only necessary for HPUX
 267 # versions earlier than 10.20.  When those fade from memory, this
 268 # could be expunged. --jsm 1999-03-22
 269
 270 AC_MSG_CHECKING(for HPUX save_state structure)
 271 AC_EGREP_HEADER(save_state_t, machine/save_state.h,
 272                 gdb_cv_hpux_savestate=yes, gdb_cv_hpux_savestate=no)
 273 AC_EGREP_HEADER(ss_wide, machine/save_state.h, gdb_cv_hpux_sswide=yes,
 274                 gdb_cv_hpux_sswide=no)
 275 if test $gdb_cv_hpux_savestate = yes
 276 then
 277   AC_DEFINE(HAVE_STRUCT_SAVE_STATE_T, 1)
 278 fi
 279 if test $gdb_cv_hpux_sswide = yes
 280 then
 281   AC_DEFINE(HAVE_STRUCT_MEMBER_SS_WIDE, 1)
 282 fi
 283 AC_MSG_RESULT($gdb_cv_hpux_sswide)
 284
 285
 286 # If we are configured native on GNU/Linux, work around problems with
 287 # sys/procfs.h
 288 # Also detect which type of /proc is in use, such as for Unixware or Solaris.
 289
 290 if test "${target}" = "${host}"; then
 291   case "${host}" in
 292   i[[3456]]86-*-linux*)
 293         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
 294         AC_DEFINE(sys_quotactl)
 295         ;;
 296   ia64-*-aix*)
 297       AC_DEFINE(NEW_PROC_API)
 298       ;;
 299   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
 300       AC_DEFINE(NEW_PROC_API)
 301       ;;
 302   *-*-solaris2.[[678]])
 303       AC_DEFINE(NEW_PROC_API)
 304       ;;
 305   esac
 306 fi
 307
 308 if test "$ac_cv_header_sys_procfs_h" = yes; then
 309   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 310   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
 311   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
 312   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
 313   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 314   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
 315   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
 316   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
 317   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 318   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 319   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
 320   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
 321   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
 322   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
 323
 324
 325   dnl Check for broken prfpregset_t type
 326
 327   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
 328   dnl prfpregset_t type (it's a typedef for the pointer to a struct
 329   dnl instead of the struct itself).  We detect this here, and work
 330   dnl around it in gdb_proc_service.h.
 331
 332   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
 333     AC_MSG_CHECKING(whether prfpregset_t type is broken)
 334     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
 335       [AC_TRY_RUN([#include <sys/procfs.h>
 336        int main ()
 337        {
 338          if (sizeof (prfpregset_t) == sizeof (void *))
 339            return 1;
 340          return 0;
 341        }],
 342        gdb_cv_prfpregset_t_broken=no,
 343        gdb_cv_prfpregset_t_broken=yes,
 344        gdb_cv_prfpregset_t_broken=yes)])
 345     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
 346     if test $gdb_cv_prfpregset_t_broken = yes; then
 347       AC_DEFINE(PRFPREGSET_T_BROKEN)
 348     fi
 349   fi
 350
 351   dnl Check for PIOCSET ioctl entry
 352
 353   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
 354   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
 355   [AC_TRY_COMPILE([#include <unistd.h>
 356 #include <sys/types.h>
 357 #include <sys/procfs.h>
 358 ], [
 359     int dummy;;
 360     dummy = ioctl(0, PIOCSET, &dummy);
 361   ],
 362   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
 363   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
 364   if test $gdb_cv_have_procfs_piocset = yes; then
 365     AC_DEFINE(HAVE_PROCFS_PIOCSET)
 366   fi
 367 fi
 368
 369 dnl For native ports (host == target), check to see what kind of
 370 dnl legacy link.h support is needed.  (See solib-legacy.c.)
 371 if test ${host} = ${target} ; then
 372   dnl Check for struct link_map with l_ members which are indicative
 373   dnl of SVR4-like shared libraries
 374
 375   AC_MSG_CHECKING(for member l_addr in struct link_map)
 376   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
 377     [AC_TRY_COMPILE([#include <link.h>],
 378                     [struct link_map lm; (void) lm.l_addr;],
 379                     gdb_cv_have_struct_link_map_with_l_members=yes,
 380                     gdb_cv_have_struct_link_map_with_l_members=no)])
 381   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
 382   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
 383     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS)
 384   fi
 385
 386   dnl Check for struct link_map with lm_ members which are indicative
 387   dnl of SunOS-like shared libraries
 388
 389   AC_MSG_CHECKING(for member lm_addr in struct link_map)
 390   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
 391     [AC_TRY_COMPILE([#include <sys/types.h>
 392 #include <link.h>],
 393                     [struct link_map lm; (void) lm.lm_addr;],
 394                     gdb_cv_have_struct_link_map_with_lm_members=yes,
 395                     gdb_cv_have_struct_link_map_with_lm_members=no)])
 396   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
 397   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
 398     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS)
 399   fi
 400
 401   dnl Check for struct so_map with som_ members which are found on
 402   dnl some *BSD systems.
 403
 404   AC_MSG_CHECKING(for member som_addr in struct so_map)
 405   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
 406     [AC_TRY_COMPILE([#include <sys/types.h>
 407 #ifdef HAVE_NLIST_H
 408 #include <nlist.h>
 409 #endif
 410 #include <link.h>],
 411                     [struct so_map lm; (void) lm.som_addr;],
 412                     gdb_cv_have_struct_so_map_with_som_members=yes,
 413                     gdb_cv_have_struct_so_map_with_som_members=no)])
 414   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
 415   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
 416     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS)
 417   fi
 418
 419   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
 420   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
 421
 422   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
 423   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
 424     [AC_TRY_COMPILE([#define _SYSCALL32
 425 #include <sys/link.h>], [struct link_map32 l;],
 426      gdb_cv_have_struct_link_map32=yes,
 427      gdb_cv_have_struct_link_map32=no)])
 428   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
 429   if test $gdb_cv_have_struct_link_map32 = yes; then
 430     AC_DEFINE(HAVE_STRUCT_LINK_MAP32)
 431     AC_DEFINE(_SYSCALL32)
 432   fi
 433 fi
 434
 435 dnl See if compiler supports "long long" type.
 436
 437 AC_MSG_CHECKING(for long long support in compiler)
 438 AC_CACHE_VAL(gdb_cv_c_long_long,
 439 [AC_TRY_COMPILE(, [
 440   extern long long foo;
 441   switch (foo & 2) { case 0: return 1; }
 442 ],
 443 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
 444 AC_MSG_RESULT($gdb_cv_c_long_long)
 445 if test $gdb_cv_c_long_long = yes; then
 446   AC_DEFINE(CC_HAS_LONG_LONG)
 447 fi
 448
 449 dnl See if the compiler and runtime support printing long long
 450
 451 AC_MSG_CHECKING(for long long support in printf)
 452 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 453 [AC_TRY_RUN([
 454 int main () {
 455   char buf[32];
 456   long long l = 0;
 457   l = (l << 16) + 0x0123;
 458   l = (l << 16) + 0x4567;
 459   l = (l << 16) + 0x89ab;
 460   l = (l << 16) + 0xcdef;
 461   sprintf (buf, "0x%016llx", l);
 462   return (strcmp ("0x0123456789abcdef", buf));
 463 }],
 464 gdb_cv_printf_has_long_long=yes,
 465 gdb_cv_printf_has_long_long=no,
 466 gdb_cv_printf_has_long_long=no)])
 467 if test $gdb_cv_printf_has_long_long = yes; then
 468   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 469 fi
 470 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 471
 472 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 473 dnl because autoconf complains about cross-compilation issues.  However, this
 474 dnl code uses the same variables as the macro for compatibility.
 475
 476 AC_MSG_CHECKING(for long double support in compiler)
 477 AC_CACHE_VAL(ac_cv_c_long_double,
 478 [AC_TRY_COMPILE(, [long double foo;],
 479 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 480 AC_MSG_RESULT($ac_cv_c_long_double)
 481 if test $ac_cv_c_long_double = yes; then
 482   AC_DEFINE(HAVE_LONG_DOUBLE)
 483 fi
 484
 485 dnl See if the compiler and runtime support printing long doubles
 486
 487 AC_MSG_CHECKING(for long double support in printf)
 488 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 489 [AC_TRY_RUN([
 490 int main () {
 491   char buf[16];
 492   long double f = 3.141592653;
 493   sprintf (buf, "%Lg", f);
 494   return (strncmp ("3.14159", buf, 7));
 495 }],
 496 gdb_cv_printf_has_long_double=yes,
 497 gdb_cv_printf_has_long_double=no,
 498 gdb_cv_printf_has_long_double=no)])
 499 if test $gdb_cv_printf_has_long_double = yes; then
 500   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 501 fi
 502 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 503
 504 dnl See if the compiler and runtime support scanning long doubles
 505
 506 AC_MSG_CHECKING(for long double support in scanf)
 507 AC_CACHE_VAL(gdb_cv_scanf_has_long_double,
 508 [AC_TRY_RUN([
 509 int main () {
 510   char *buf = "3.141592653";
 511   long double f = 0;
 512   sscanf (buf, "%Lg", &f);
 513   return !(f > 3.14159 && f < 3.14160);
 514 }],
 515 gdb_cv_scanf_has_long_double=yes,
 516 gdb_cv_scanf_has_long_double=no,
 517 gdb_cv_scanf_has_long_double=no)])
 518 if test $gdb_cv_scanf_has_long_double = yes; then
 519   AC_DEFINE(SCANF_HAS_LONG_DOUBLE)
 520 fi
 521 AC_MSG_RESULT($gdb_cv_scanf_has_long_double)
 522
 523 AC_FUNC_MMAP
 524
 525 case ${host_os} in
 526 aix*)
 527   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
 528     SAVE_LDFLAGS=$LDFLAGS
 529
 530     case $GCC in
 531     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
 532     *) gdb_cv_bigtoc=-bbigtoc ;;
 533     esac
 534
 535     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
 536     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
 537   ])
 538   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
 539   ;;
 540 esac
 541
 542
 543 dnl For certain native configurations, we need to check whether thread
 544 dnl support can be built in or not.
 545 dnl
 546 dnl Note that we only want this if we are both native (host == target),
 547 dnl and not doing a canadian cross build (build == host).
 548
 549 if test ${build} = ${host} -a ${host} = ${target} ; then
 550    case ${host_os} in
 551    hpux*)
 552       AC_MSG_CHECKING(for HPUX/OSF thread support)
 553       if test -f /usr/include/dce/cma_config.h ; then
 554          if test "$GCC" = "yes" ; then
 555             AC_MSG_RESULT(yes)
 556             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 557             CONFIG_LIB_OBS="${CONFIG_LIB_OBS} hpux-thread.o"
 558             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
 559          else
 560             AC_MSG_RESULT(no (suppressed because you are not using GCC))
 561          fi
 562       else
 563          AC_MSG_RESULT(no)
 564       fi
 565       ;;
 566    solaris*)
 567       # See if thread_db library is around for Solaris thread debugging.
 568       # Note that we must explicitly test for version 1 of the library
 569       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
 570       # the same API.
 571       AC_MSG_CHECKING(for Solaris thread debugging library)
 572       if test -f /usr/lib/libthread_db.so.1 ; then
 573          AC_MSG_RESULT(yes)
 574          AC_DEFINE(HAVE_THREAD_DB_LIB)
 575          CONFIG_LIB_OBS="${CONFIG_LIB_OBS} sol-thread.o"
 576          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
 577          AC_CHECK_LIB(dl, dlopen)
 578          if test "$GCC" = "yes" ; then
 579             # The GNU linker requires the -export-dynamic option to make
 580             # all symbols visible in the dynamic symbol table.
 581             hold_ldflags=$LDFLAGS
 582             AC_MSG_CHECKING(for the ld -export-dynamic flag)
 583             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
 584             AC_TRY_LINK(, [int i;], found=yes, found=no)
 585             LDFLAGS=$hold_ldflags
 586             AC_MSG_RESULT($found)
 587             if test $found = yes; then
 588                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
 589             fi
 590          fi
 591          # Sun randomly tweaked the prototypes in <proc_service.h>
 592          # at one point.
 593          AC_MSG_CHECKING(if <proc_service.h> is old)
 594          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
 595             AC_TRY_COMPILE([
 596                 #include <proc_service.h>
 597                 ps_err_e ps_pdwrite
 598                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
 599             ],, gdb_cv_proc_service_is_old=no,
 600                 gdb_cv_proc_service_is_old=yes)
 601          ])
 602          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
 603          if test $gdb_cv_proc_service_is_old = yes; then
 604             AC_DEFINE(PROC_SERVICE_IS_OLD)
 605          fi
 606       else
 607          AC_MSG_RESULT(no)
 608       fi
 609       ;;
 610    aix*)
 611       AC_MSG_CHECKING(for AiX thread debugging library)
 612       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
 613                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
 614                                    [#ifndef PTHDB_VERSION_3
 615                                     #error
 616                                     #endif],
 617                                    gdb_cv_have_aix_thread_debug=yes,
 618                                    gdb_cv_have_aix_thread_debug=no)])
 619       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
 620       if test $gdb_cv_have_aix_thread_debug = yes; then
 621          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
 622          CONFIG_LIB_OBS="${CONFIG_LIB_OBS} aix-thread.o"
 623          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
 624       fi
 625       ;;
 626    esac
 627    AC_SUBST(CONFIG_LDFLAGS)
 628 fi
 629
 630 dnl See if we have a thread_db header file that has TD_NOTALLOC.
 631 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
 632    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
 633                   gdb_cv_thread_db_h_has_td_notalloc,
 634      AC_TRY_COMPILE(
 635        [#include <thread_db.h>],
 636        [int i = TD_NOTALLOC;],
 637        gdb_cv_thread_db_h_has_td_notalloc=yes,
 638        gdb_cv_thread_db_h_has_td_notalloc=no
 639      )
 640    )
 641 fi
 642 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
 643   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
 644             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
 645 fi
 646
 647 dnl linux-proc.c wants to use pread64, which may require special CFLAGS
 648 dnl -D_BSD_SOURCE is normally assumed but we have to specify it because of
 649 dnl -D_XOPEN_SOURCE=500.
 650 if test $host = $target; then
 651   case $target in
 652     *-linux*)
 653       save_CFLAGS=$CFLAGS
 654       CFLAGS="$CFLAGS -D_BSD_SOURCE -D_XOPEN_SOURCE=500 -D_LARGEFILE64_SOURCE"
 655       AC_TRY_LINK([#include <unistd.h>],
 656                   [pread64 (0, NULL, 0, 0);],
 657                   [ENABLE_CFLAGS="$ENABLE_CFLAGS -D_BSD_SOURCE -D_XOPEN_SOURCE=500 -D_LARGEFILE64_SOURCE"
 658                    AC_DEFINE(HAVE_PREAD64)], [])
 659       CFLAGS=$save_CFLAGS
 660       ;;
 661   esac
 662 fi
 663
 664 dnl The CLI cannot be disabled yet, but may be in the future
 665
 666 dnl Handle CLI sub-directory configury.
 667 AC_ARG_ENABLE(gdbcli,
 668 [  --enable-gdbcli            Enable GDB-CLI interface],
 669 [
 670   case "${enableval}" in
 671     yes) enable_gdbcli=yes ;;
 672     "") enable_gdbcli=yes ;;
 673     no)
 674       AC_MSG_ERROR(The CLI cannot be disabled yet)
 675     ;;
 676     *)
 677       AC_MSG_ERROR(Bad value for --enable-gdbcli: ${enableval})
 678     ;;
 679   esac
 680 ],
 681 [enable_gdbcli=yes])
 682 case ${enable_gdbcli} in
 683   "yes" )
 684     if test -d "${srcdir}/cli" ; then
 685       CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_CLI_OBS)"
 686       CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_CLI_DEPS)"
 687       CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_CLI_SRCS)"
 688       CONFIG_INITS="${CONFIG_INITS} \$(SUBDIR_CLI_INITS)"
 689       ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_CLI_CFLAGS)"
 690       CONFIG_ALL="${CONFIG_ALL} \$(SUBDIR_CLI_ALL)"
 691       CONFIG_CLEAN="${CONFIG_CLEAN} \$(SUBDIR_CLI_CLEAN)"
 692       CONFIG_INSTALL="${CONFIG_INSTALL} \$(SUBDIR_CLI_INSTALL)"
 693       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} \$(SUBDIR_CLI_UNINSTALL)"
 694     fi
 695     ;;
 696 esac
 697
 698 dnl Handle optional features that can be enabled.
 699
 700 dnl Handle MI sub-directory configury.
 701 AC_ARG_ENABLE(gdbmi,
 702 [  --enable-gdbmi            Enable GDB-MI interface],
 703 [
 704   case "${enable_gdbmi}" in
 705     yes | no) ;;
 706     "")  enable_gdbmi=yes ;;
 707     *)
 708       AC_MSG_ERROR(Bad value for --enable-gdbmi: ${enableval})
 709     ;;
 710   esac
 711 ],
 712 [enable_gdbmi=yes])
 713 case ${enable_gdbmi} in
 714   "yes" )
 715     if test -d "${srcdir}/mi" ; then
 716       CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_MI_OBS)"
 717       CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_MI_DEPS)"
 718       CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_MI_SRCS)"
 719       CONFIG_INITS="${CONFIG_INITS} \$(SUBDIR_MI_INITS)"
 720       ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_MI_CFLAGS)"
 721       CONFIG_ALL="${CONFIG_ALL} \$(SUBDIR_MI_ALL)"
 722       CONFIG_CLEAN="${CONFIG_CLEAN} \$(SUBDIR_MI_CLEAN)"
 723       CONFIG_INSTALL="${CONFIG_INSTALL} \$(SUBDIR_MI_INSTALL)"
 724       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} \$(SUBDIR_MI_UNINSTALL)"
 725     fi
 726     ;;
 727 esac
 728
 729 # Configure UI_OUT by default (before 5.2 it can be disabled)
 730 # It must be configured if gdbmi is configured
 731
 732 UIOUT_CFLAGS=
 733 AC_SUBST(UIOUT_CFLAGS)
 734
 735 AC_ARG_WITH(uiout,
 736 [  --with-uiout          Use new uiout functions instead of *printf's],
 737 [case "${withval}" in
 738   yes)  want_uiout=true ;;
 739   no)   if test $enable_gdbmi = yes; then
 740           AC_MSG_ERROR(uiout is needed for MI and cannot be disabled)
 741         else
 742            want_uiout=false
 743         fi ;;
 744   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-uiout option) ;;
 745 esac],
 746 [want_uiout=true])dnl
 747
 748 if test $want_uiout = true; then
 749    UIOUT_CFLAGS="-DUI_OUT=1"
 750 fi
 751
 752 AC_ARG_ENABLE(tui,
 753 [  --enable-tui            Enable full-screen terminal user interface],
 754 [
 755   case "${enable_tui}" in
 756     yes | no) ;;
 757     "")  enable_tui=yes ;;
 758     *)
 759       AC_MSG_ERROR(Bad value for --enable-tui: ${enableval})
 760     ;;
 761   esac
 762 ])
 763 case ${enable_tui} in
 764   "yes" )
 765     if test -d "${srcdir}/tui" ; then
 766       CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_TUI_OBS)"
 767       CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_TUI_DEPS)"
 768       CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_TUI_SRCS)"
 769       CONFIG_INITS="${CONFIG_INITS} \$(SUBDIR_TUI_INITS)"
 770       ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_TUI_CFLAGS)"
 771       CONFIG_ALL="${CONFIG_ALL} \$(SUBDIR_TUI_ALL)"
 772       CONFIG_CLEAN="${CONFIG_CLEAN} \$(SUBDIR_TUI_CLEAN)"
 773       CONFIG_INSTALL="${CONFIG_INSTALL} \$(SUBDIR_TUI_INSTALL)"
 774       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} \$(SUBDIR_TUI_UNINSTALL)"
 775     fi
 776     ;;
 777 esac
 778
 779 AC_ARG_ENABLE(netrom,
 780 [  --enable-netrom         Enable NetROM support],
 781 [case "${enableval}" in
 782 yes)    enable_netrom=yes ;;
 783 no)     enable_netrom=no ;;
 784 *)      AC_MSG_ERROR(bad value ${enableval} given for netrom option) ;;
 785 esac])
 786
 787 if test "${enable_netrom}" = "yes"; then
 788         CONFIG_LIB_OBS="${CONFIG_LIB_OBS} remote-nrom.o"
 789         CONFIG_SRCS="${CONFIG_SRCS} remote-nrom.c"
 790 fi
 791
 792
 793 # NOTE: Don't add -Wall or -Wunused, they both include
 794 # -Wunused-parameter which reports bogus warnings.
 795 # NOTE: If you add to this list, remember to update
 796 # gdb/doc/gdbint.texinfo.
 797 build_warnings="-Wimplicit -Wreturn-type -Wcomment -Wtrigraphs \
 798 -Wformat -Wparentheses -Wpointer-arith -Wuninitialized"
 799 # Up for debate: -Wswitch -Wcomment -trigraphs -Wtrigraphs
 800 # -Wunused-function -Wunused-label -Wunused-variable -Wunused-value
 801 # -Wchar-subscripts -Wtraditional -Wshadow -Wcast-qual
 802 # -Wcast-align -Wwrite-strings -Wconversion -Wstrict-prototypes
 803 # -Wmissing-prototypes -Wmissing-declarations -Wredundant-decls
 804 # -Woverloaded-virtual -Winline -Werror"
 805 AC_ARG_ENABLE(build-warnings,
 806 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
 807 [case "${enableval}" in
 808   yes)  ;;
 809   no)   build_warnings="-w";;
 810   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
 811         build_warnings="${build_warnings} ${t}";;
 812   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
 813         build_warnings="${t} ${build_warnings}";;
 814   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
 815 esac
 816 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
 817   echo "Setting compiler warning flags = $build_warnings" 6>&1
 818 fi])dnl
 819 AC_ARG_ENABLE(gdb-build-warnings,
 820 [  --enable-gdb-build-warnings Enable GDB specific build-time compiler warnings if gcc is used],
 821 [case "${enableval}" in
 822   yes)  ;;
 823   no)   build_warnings="-w";;
 824   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
 825         build_warnings="${build_warnings} ${t}";;
 826   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
 827         build_warnings="${t} ${build_warnings}";;
 828   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
 829 esac
 830 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
 831   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
 832 fi])dnl
 833 WARN_CFLAGS=""
 834 WERROR_CFLAGS=""
 835 if test "x${build_warnings}" != x -a "x$GCC" = xyes
 836 then
 837     AC_MSG_CHECKING(compiler warning flags)
 838     # Separate out the -Werror flag as some files just cannot be
 839     # compiled with it enabled.
 840     for w in ${build_warnings}; do
 841         case $w in
 842         -Werr*) WERROR_CFLAGS=-Werror ;;
 843         *) # Check that GCC accepts it
 844             saved_CFLAGS="$CFLAGS"
 845             CFLAGS="$CFLAGS $w"
 846             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
 847             CFLAGS="$saved_CFLAGS"
 848         esac
 849     done
 850     AC_MSG_RESULT(${WARN_CFLAGS}${WERROR_CFLAGS})
 851 fi
 852 AC_SUBST(WARN_CFLAGS)
 853 AC_SUBST(WERROR_CFLAGS)
 854
 855 MMALLOC_CFLAGS=
 856 MMALLOC=
 857 AC_SUBST(MMALLOC_CFLAGS)
 858 AC_SUBST(MMALLOC)
 859
 860 AC_ARG_WITH(mmalloc,
 861 [  --with-mmalloc          Use memory mapped malloc package],
 862 [case "${withval}" in
 863   yes)  want_mmalloc=true ;;
 864   no)   want_mmalloc=false;;
 865   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-mmalloc option) ;;
 866 esac],[want_mmalloc=false])dnl
 867
 868 if test x$want_mmalloc = xtrue; then
 869    AC_DEFINE(USE_MMALLOC)
 870    AC_DEFINE(MMCHECK_FORCE)
 871    MMALLOC_CFLAGS="-I$srcdir/../mmalloc"
 872    MMALLOC='../mmalloc/libmmalloc.a'
 873 fi
 874
 875 AC_ARG_WITH(included-regex,
 876 [  --with-included-regex          Use included regex],
 877 [case "${withval}" in
 878   yes)  want_included_regex=true ;;
 879   no)   want_included_regex=false;;
 880   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-included-regex option) ;;
 881 esac],[want_included_regex=true])dnl
 882
 883 if test $want_included_regex = false; then
 884   AC_MSG_CHECKING(for GNU regex)
 885   AC_CACHE_VAL(gdb_cv_have_gnu_regex,
 886 [AC_TRY_COMPILE([#include <gnu-versions.h>
 887 #include <sys/types.h>
 888 #include <regex.h>],
 889 [#if !defined _GNU_REGEX_INTERFACE_VERSION || !defined __GLIBC__ || __GLIBC__ < 2
 890 #error No valid GNU regex.
 891 #endif
 892 ],
 893                 [gdb_cv_have_gnu_regex=yes],
 894                 [gdb_cv_have_gnu_regex=no])])
 895   AC_MSG_RESULT($gdb_cv_have_gnu_regex)
 896   if test $gdb_cv_have_gnu_regex = no; then
 897         want_included_regex=true
 898   fi
 899 fi
 900
 901 if test x${want_included_regex} = xtrue; then
 902     REGEX="gnu-regex.o"
 903     AC_DEFINE(USE_INCLUDED_REGEX)
 904 fi
 905 AC_SUBST(REGEX)
 906
 907 # In the Cygwin environment, we need some additional flags.
 908 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
 909 [AC_EGREP_CPP(lose, [
 910 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
 911 lose
 912 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
 913
 914
 915 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
 916 SER_HARDWIRE="ser-unix.o ser-pipe.o ser-tcp.o"
 917 case ${host} in
 918   *go32* ) SER_HARDWIRE=ser-go32.o ;;
 919   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
 920 esac
 921 AC_SUBST(SER_HARDWIRE)
 922
 923
 924 dnl Figure out which term library to use.
 925 if test x$gdb_host = xgo32; then
 926   TERM_LIB=
 927 else
 928 if test x$gdb_cv_os_cygwin = xyes; then
 929   TERM_LIB='`if test -r ../libtermcap/libtermcap.a; then echo ../libtermcap/libtermcap.a; else echo -ltermcap; fi`'
 930 else
 931   TERM_LIB=
 932   AC_CHECK_LIB(ncurses, tgetent, TERM_LIB=-lncurses,
 933     AC_CHECK_LIB(Hcurses, tgetent, TERM_LIB=-lHcurses,
 934       AC_CHECK_LIB(termlib, tgetent, TERM_LIB=-ltermlib,
 935         AC_CHECK_LIB(termcap, tgetent, TERM_LIB=-ltermcap,
 936           AC_CHECK_LIB(curses, tgetent, TERM_LIB=-lcurses,
 937             AC_CHECK_LIB(terminfo, tgetent, TERM_LIB=-lterminfo))))))
 938
 939   if test "x$TERM_LIB" = x
 940   then
 941     AC_MSG_ERROR(Could not find a term library, e.g. termcap or termlib!)
 942   fi
 943 fi
 944 fi
 945 AC_SUBST(TERM_LIB)
 946
 947 # libreadline needs libuser32.a in a cygwin environment
 948 WIN32LIBS=
 949 if test x$gdb_cv_os_cygwin = xyes; then
 950     WIN32LIBS="-luser32"
 951     case "${target}" in
 952         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
 953         ;;
 954     esac
 955 fi
 956 AC_SUBST(WIN32LIBS)
 957
 958 LIBGUI="../libgui/src/libgui.a"
 959 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
 960 AC_SUBST(LIBGUI)
 961 AC_SUBST(GUI_CFLAGS_X)
 962
 963 AC_ARG_WITH(cpu,
 964 [  --with-cpu=CPU          Set the default CPU variant to debug],
 965 [case "${target}" in
 966   powerpc-* | powerpcle-* )
 967     ## It would be nice to keep this table in sync with the one in
 968     ## gcc/configure.
 969     case "${with_cpu}" in
 970       ppc-uisa | rs6000 | 403 | 403GC | 505 | 860 | 601 | 602 | 603 \
 971       | 604 | 750 )
 972         ## Those are all handled in variants in rs6000-tdep.c, so they're fine.
 973       ;;
 974       common | power | power2 | rios | rios1 | rios2 | rsc | rsc1 )
 975         ## These are all RS6000 variants, as far as GDB is concerned.
 976         with_cpu=rs6000
 977       ;;
 978       603e | ec603e )
 979         with_cpu=603
 980       ;;
 981       604e )
 982         with_cpu=604
 983       ;;
 984       * )
 985         AC_MSG_WARN(GDB: unknown --with-cpu value: \`${with_cpu}'; using \`ppc-uisa'.)
 986         with_cpu=ppc-uisa
 987       ;;
 988     esac
 989   ;;
 990   * )
 991     AC_MSG_WARN(GDB may ignore the --with-cpu flag for ${target} targets)
 992   ;;
 993 esac
 994 AC_DEFINE_UNQUOTED(TARGET_CPU_DEFAULT, "${with_cpu}")
 995 ],)
 996
 997
 998 AC_ARG_ENABLE(gdbtk,
 999 [  --enable-gdbtk          Enable GDBTK GUI front end],
1000 [case "${enableval}" in
1001     yes)
1002         case "$host" in
1003         *go32*)
1004             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
1005             enable_gdbtk=no ;;
1006         *windows*)
1007             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
1008             enable_gdbtk=no ;;
1009         *)
1010             enable_gdbtk=yes ;;
1011         esac ;;
1012     no)
1013         enable_gdbtk=no  ;;
1014     *)
1015         AC_MSG_ERROR(bad value ${enableval} given for gdbtk option) ;;
1016 esac],
1017 [
1018 # Default is on for everything but go32 and Cygwin
1019 case "$host" in
1020     *go32* | *windows*)
1021         ;;
1022     *)
1023         if test -d "${srcdir}/gdbtk" ; then
1024             enable_gdbtk=yes
1025         fi
1026         ;;
1027 esac
1028 ])
1029
1030 WIN32LDAPP=
1031 AC_SUBST(WIN32LIBS)
1032 AC_SUBST(WIN32LDAPP)
1033
1034 configdir="unix"
1035
1036 GDBTKLIBS=
1037 if test "${enable_gdbtk}" = "yes"; then
1038
1039     # Gdbtk must have an absolute path to srcdir in order to run
1040     # properly when not installed.
1041     here=`pwd`
1042     cd ${srcdir}
1043     GDBTK_SRC_DIR=`pwd`
1044     cd $here
1045
1046     CY_AC_PATH_TCLCONFIG
1047     if test -z "${no_tcl}"; then
1048         CY_AC_LOAD_TCLCONFIG
1049         CY_AC_PATH_TKCONFIG
1050
1051         # now look for Tcl library stuff
1052
1053         case "${host}" in
1054         *-*-cygwin*)
1055             tcldir=../tcl/win/
1056             ;;
1057         *)
1058             tcldir=../tcl/unix/
1059             ;;
1060         esac
1061
1062         TCL_DEPS="${tcldir}${TCL_LIB_FILE}"
1063
1064         # If $no_tk is nonempty, then we can't do Tk, and there is no
1065         # point to doing Tcl.
1066         if test -z "${no_tk}"; then
1067            CY_AC_LOAD_TKCONFIG
1068            CY_AC_PATH_TCLH
1069            CY_AC_PATH_TKH
1070            CY_AC_PATH_ITCLH
1071            CY_AC_PATH_ITKH
1072
1073
1074            # now look for Tk library stuff
1075
1076            case "${host}" in
1077            *-*-cygwin*)
1078                tkdir=../tk/win/
1079                ;;
1080            *)
1081                tkdir=../tk/unix/
1082                ;;
1083            esac
1084
1085            TK_DEPS="${tkdir}${TK_LIB_FILE}"
1086
1087            # now look for Itcl library stuff
1088
1089            CY_AC_PATH_ITCLCONFIG
1090            if test -z "${no_itcl}"; then
1091              CY_AC_LOAD_ITCLCONFIG
1092
1093              ITCLLIB="${ITCL_BUILD_LIB_SPEC}"
1094              ITCL_DEPS="${ITCL_LIB_FULL_PATH}"
1095            fi
1096
1097
1098            # now look for Itk library stuff
1099            CY_AC_PATH_ITKCONFIG
1100            if test -z "${no_itcl}"; then
1101              CY_AC_LOAD_ITKCONFIG
1102
1103              ITKLIB="${ITK_BUILD_LIB_SPEC}"
1104              ITK_DEPS="${ITK_LIB_FULL_PATH}"
1105            fi
1106
1107            ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1108            # Tcl/Tk 8.1 require -fwritable strings.  I don't
1109            # know whether 8.2 will or not, but I bet it will.
1110            # I don't have to worry about 7.x since we don't support it.
1111            GDBTK_CFLAGS=""
1112            if test "$GCC" = "yes"; then
1113                if test "$TCL_VERSION" != "8.0" ; then
1114                    GDBTK_CFLAGS="-fwritable-strings"
1115                fi
1116            fi
1117
1118            # Include some libraries that Tcl and Tk want.
1119            TCL_LIBS='$(LIBGUI) $(ITCL) $(ITK) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1120            # Yes, the ordering seems wrong here.  But it isn't.
1121            # TK_LIBS is the list of libraries that need to be linked
1122            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1123            # were in LIBS then any link tests after this point would
1124            # try to include things like `$(LIBGUI)', which wouldn't work.
1125            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1126
1127            CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1128            CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1129            CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1130            CONFIG_INITS="${CONFIG_INITS} \$(SUBDIR_GDBTK_INITS)"
1131            CONFIG_ALL="${CONFIG_ALL} \$(SUBDIR_GDBTK_ALL)"
1132            CONFIG_CLEAN="${CONFIG_CLEAN} \$(SUBDIR_GDBTK_CLEAN)"
1133            CONFIG_INSTALL="${CONFIG_INSTALL} \$(SUBDIR_GDBTK_INSTALL)"
1134            CONFIG_UNINSTALL="${CONFIG_UNINSTALL} \$(SUBDIR_GDBTK_UNINSTALL)"
1135
1136            if test x$gdb_cv_os_cygwin = xyes; then
1137               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1138               WIN32LDAPP="-Wl,--subsystem,console"
1139               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1140            fi
1141         fi
1142     fi
1143
1144     SUBDIRS="${SUBDIRS} gdbtk"
1145     configdirs="${configdirs} gdbtk"
1146 fi
1147
1148 AC_SUBST(X_CFLAGS)
1149 AC_SUBST(X_LDFLAGS)
1150 AC_SUBST(X_LIBS)
1151 AC_SUBST(TCL_DEPS)
1152 AC_SUBST(TK_DEPS)
1153 AC_SUBST(ITCLLIB)
1154 AC_SUBST(ITCL_DEPS)
1155 AC_SUBST(ITKLIB)
1156 AC_SUBST(ITK_DEPS)
1157 AC_SUBST(GDBTKLIBS)
1158 AC_SUBST(GDBTK_CFLAGS)
1159 AC_SUBST(GDBTK_SRC_DIR)
1160
1161 AC_PATH_X
1162
1163
1164 # Unlike the sim directory, whether a simulator is linked is controlled by
1165 # presence of a SIM= and a SIM_OBS= definition in the target '.mt' file.
1166 # This code just checks for a few cases where we'd like to ignore those
1167 # definitions, even when they're present in the '.mt' file.  These cases
1168 # are when --disable-sim is specified, or if the simulator directory is
1169 # not part of the source tree.
1170 #
1171 AC_ARG_ENABLE(sim,
1172 [  --enable-sim            Link gdb with simulator],
1173 [echo "enable_sim = $enable_sim";
1174  echo "enableval = ${enableval}";
1175  case "${enableval}" in
1176   yes) ignore_sim=false ;;
1177   no)  ignore_sim=true ;;
1178   *)   ignore_sim=false ;;
1179  esac],
1180 [ignore_sim=false])
1181
1182 if test ! -d "${srcdir}/../sim"; then
1183   ignore_sim=true
1184 fi
1185
1186 if test "${ignore_sim}" = "true"; then
1187     IGNORE_SIM="SIM="
1188     IGNORE_SIM_OBS="SIM_OBS="
1189 else
1190     IGNORE_SIM=""
1191     IGNORE_SIM_OBS=""
1192     AC_DEFINE(WITH_SIM)
1193 fi
1194 AC_SUBST(IGNORE_SIM)
1195 AC_SUBST(IGNORE_SIM_OBS)
1196
1197 AC_SUBST(ENABLE_CFLAGS)
1198
1199 AC_SUBST(CONFIG_OBS)
1200 AC_SUBST(CONFIG_LIB_OBS)
1201 AC_SUBST(CONFIG_DEPS)
1202 AC_SUBST(CONFIG_SRCS)
1203 AC_SUBST(CONFIG_INITS)
1204 AC_SUBST(CONFIG_ALL)
1205 AC_SUBST(CONFIG_CLEAN)
1206 AC_SUBST(CONFIG_INSTALL)
1207 AC_SUBST(CONFIG_UNINSTALL)
1208
1209 # Begin stuff to support --enable-shared
1210 AC_ARG_ENABLE(shared,
1211 [  --enable-shared         Use shared libraries],
1212 [case "${enableval}" in
1213   yes) shared=true ;;
1214   no)  shared=false ;;
1215   *) shared=true ;;
1216 esac])dnl
1217
1218 HLDFLAGS=
1219 HLDENV=
1220 # If we have shared libraries, try to set rpath reasonably.
1221 if test "${shared}" = "true"; then
1222   case "${host}" in
1223   *-*-hpux*)
1224     HLDFLAGS='-Wl,+s,+b,$(libdir)'
1225     ;;
1226   *-*-irix5* | *-*-irix6*)
1227     HLDFLAGS='-Wl,-rpath,$(libdir)'
1228     ;;
1229   *-*-linux*aout*)
1230     ;;
1231   *-*-linux* | *-pc-linux-gnu*)
1232     HLDFLAGS='-Wl,-rpath,$(libdir)'
1233     ;;
1234   *-*-solaris*)
1235     HLDFLAGS='-R $(libdir)'
1236     ;;
1237   *-*-sysv4*)
1238     HLDENV='if test -z "$${LD_RUN_PATH}"; then LD_RUN_PATH=$(libdir); else LD_RUN_PATH=$${LD_RUN_PATH}:$(libdir); fi; export LD_RUN_PATH;'
1239     ;;
1240   esac
1241 fi
1242
1243 # On SunOS, if the linker supports the -rpath option, use it to
1244 # prevent ../bfd and ../opcodes from being included in the run time
1245 # search path.
1246 case "${host}" in
1247   *-*-sunos*)
1248     echo 'main () { }' > conftest.c
1249     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
1250     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
1251       :
1252     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
1253       :
1254     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
1255       :
1256     elif grep 'some text already loaded' conftest.t >/dev/null 2>&1; then
1257       :
1258     elif test "${shared}" = "true"; then
1259       HLDFLAGS='-Wl,-rpath=$(libdir)'
1260     else
1261       HLDFLAGS='-Wl,-rpath='
1262     fi
1263     rm -f conftest.t conftest.c conftest
1264     ;;
1265 esac
1266 AC_SUBST(HLDFLAGS)
1267 AC_SUBST(HLDENV)
1268 # End stuff to support --enable-shared
1269
1270 # target_subdir is used by the testsuite to find the target libraries.
1271 target_subdir=
1272 if test "${host}" != "${target}"; then
1273     target_subdir="${target_alias}/"
1274 fi
1275 AC_SUBST(target_subdir)
1276
1277 frags=
1278 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
1279 if test ! -f ${host_makefile_frag}; then
1280     # When building a native debuger the .mh file containing things
1281     # like NATDEPFILES is needed.  Cross debuggers don't need .mh
1282     # since it no longer contains anything useful.
1283     if test "${target}" = "${host}"; then
1284         AC_MSG_ERROR("*** Gdb does not support native target ${host}")
1285     else
1286         host_makefile_frag=/dev/null
1287     fi
1288 fi
1289 frags="$frags $host_makefile_frag"
1290
1291 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
1292 if test ! -f ${target_makefile_frag}; then
1293 AC_MSG_ERROR("*** Gdb does not support target ${target}")
1294 fi
1295 frags="$frags $target_makefile_frag"
1296
1297 AC_SUBST_FILE(host_makefile_frag)
1298 AC_SUBST_FILE(target_makefile_frag)
1299 AC_SUBST(frags)
1300
1301 changequote(,)dnl
1302 hostfile=`sed -n '
1303 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1304 ' ${host_makefile_frag}`
1305
1306 targetfile=`sed -n '
1307 s/TM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1308 ' ${target_makefile_frag}`
1309
1310 GDB_MULTI_ARCH=`sed -n '
1311 s/GDB_MULTI_ARCH[       ]*=[    ]*\([^  ]*\)[   ]*/\1/p
1312 ' ${target_makefile_frag}`
1313
1314 if test "${target}" = "${host}"; then
1315 # We pick this up from the host configuration file (.mh) because we
1316 # do not have a native configuration Makefile fragment.
1317 nativefile=`sed -n '
1318 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
1319 ' ${host_makefile_frag}`
1320 fi
1321 changequote([,])
1322
1323 # New targets should just set gdb_multi_arch=yes in configure.tgt.
1324 # Old targets being converted can either do that or set GDB_MULTI_ARCH
1325 # in the target specific makefile frag.  Eventually gdb_multi_arch=yes
1326 # will be the default.
1327 if test x"${GDB_MULTI_ARCH}" = x ; then
1328     case "${gdb_multi_arch}" in
1329     yes ) GDB_MULTI_ARCH=GDB_MULTI_ARCH_PURE ;;
1330     no ) GDB_MULTI_ARCH=0 ;;
1331     0|1|2 ) GDB_MULTI_ARCH=${gdb_multi_arch} ;;
1332     esac
1333 fi
1334 if test x"${GDB_MULTI_ARCH}" != x ; then
1335     AC_DEFINE_UNQUOTED(GDB_MULTI_ARCH, ${GDB_MULTI_ARCH})
1336 fi
1337 # Warn the user when they use an old practice
1338 case "${GDB_MULTI_ARCH}" in
1339     "" ) ;;
1340     0 | GDB_MULTI_ARCH_PARTIAL | 1 | GDB_MULTI_ARCH_TM | 2 )
1341         AC_MSG_WARN("GDB: Target is not pure multi-arch") ;;
1342     GDB_MULTI_ARCH_PURE )
1343         if test x"${targetfile}" != x ; then
1344             AC_MSG_WARN("GDB: Ignoring TM_FILE in ${target_makefile_frag}")
1345             targetfile=""
1346         fi ;;
1347     *)  AC_MSG_ERROR("GDB: Unknown GDB_MULTI_ARCH value ${GDB_MULTI_ARCH}");;
1348 esac
1349
1350 if test "${enable_multi_ice}" = "yes"; then
1351   SUBDIRS="${SUBDIRS} multi-ice"
1352 fi
1353
1354 # ``gdbserver'' can only be built in a native configuration.
1355 if test x"${target}" = x"${host}"; then
1356     AC_MSG_CHECKING(whether gdbserver is supported on this host)
1357     if test x"${build_gdbserver}" = xyes ; then
1358         configdirs="${configdirs} gdbserver"
1359         SUBDIRS="${SUBDIRS} gdbserver"
1360         AC_MSG_RESULT(yes)
1361     else
1362         AC_MSG_RESULT(no)
1363     fi
1364 fi
1365
1366 AC_SUBST(SUBDIRS)
1367
1368 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
1369 # (NAT_FILE) is not set in config/*/*.m[ht] files, we link to an empty
1370 # version.
1371
1372 files=
1373 links=
1374
1375 rm -f xm.h
1376 xm_h=""
1377 if test "${hostfile}" != ""; then
1378     xm_h=xm.h
1379     GDB_XM_FILE="config/${gdb_host_cpu}/${hostfile}"
1380     files="${files} ${GDB_XM_FILE}"
1381     links="${links} xm.h"
1382     AC_DEFINE_UNQUOTED(GDB_XM_FILE, ${GDB_XM_FILE})
1383 fi
1384 AC_SUBST(xm_h)
1385
1386 rm -f tm.h
1387 tm_h=""
1388 if test "${targetfile}" != ""; then
1389     tm_h=tm.h
1390     GDB_TM_FILE="config/${gdb_target_cpu}/${targetfile}"
1391     files="${files} ${GDB_TM_FILE}"
1392     links="${links} tm.h"
1393     AC_DEFINE_UNQUOTED(GDB_TM_FILE, ${GDB_TM_FILE})
1394 fi
1395 AC_SUBST(tm_h)
1396
1397 rm -f nm.h
1398 nm_h=""
1399 if test "${nativefile}" != ""; then
1400     nm_h=nm.h
1401     GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}"
1402     files="${files} ${GDB_NM_FILE}"
1403     links="${links} nm.h"
1404     AC_DEFINE_UNQUOTED(GDB_NM_FILE, ${GDB_NM_FILE})
1405 fi
1406 AC_SUBST(nm_h)
1407
1408 AC_PROG_LN_S
1409
1410 AC_LINK_FILES($files, $links)
1411
1412 dnl Check for exe extension set on certain hosts (e.g. Win32)
1413 AC_EXEEXT
1414
1415 dnl  Detect the character set used by this host.
1416
1417 dnl  At the moment, we just assume it's ISO-8859-1 (which is a
1418 dnl  superset of ASCII containing the characters needed for French,
1419 dnl  German, Spanish, Italian, and possibly others), but if were
1420 dnl  *were* to support any host character sets other than ISO-8859-1,
1421 dnl  here's where we'd detect it.
1422 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "ISO-8859-1",
1423           [Define to be a string naming the default host character set.])
1424
1425 AM_ICONV
1426
1427 AC_CONFIG_SUBDIRS($configdirs)
1428 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
1429 [
1430 dnl Autoconf doesn't provide a mechanism for modifying definitions
1431 dnl provided by makefile fragments.
1432 dnl
1433 if test "${nativefile}" = ""; then
1434         < Makefile \
1435         sed -e '/^NATDEPFILES[[         ]]*=.*\\$/,/[[^\\]]$/s/^/# /' \
1436             -e '/^NATDEPFILES[[         ]]*=/s/^/# /' \
1437         | sed -e '/^\(NATDEPFILES[[     ]]*[[+]]=[[     ]]*\)/s//# \1/' \
1438         > Makefile.tem
1439 mv -f Makefile.tem Makefile
1440 fi
1441
1442 changequote(,)dnl
1443 sed -e '/^TM_FILE[      ]*=/s,^TM_FILE[         ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
1444 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
1445 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
1446 mv -f Makefile.tmp Makefile
1447 changequote([,])dnl
1448
1449
1450 case x$CONFIG_HEADERS in
1451 xconfig.h:config.in)
1452 echo > stamp-h ;;
1453 esac
1454 ],
1455 [
1456 gdb_host_cpu=$gdb_host_cpu
1457 gdb_target_cpu=$gdb_target_cpu
1458 nativefile=$nativefile
1459 ])
1460
1461 exit 0