gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996, 1997, 1998, 1999 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 2 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program; if not, write to the Free Software
  18 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  19
  20 dnl Process this file with autoconf to produce a configure script.
  21
  22 AC_PREREQ(2.13)dnl
  23 AC_INIT(main.c)
  24 AC_CONFIG_HEADER(config.h:config.in)
  25
  26 AC_PROG_CC
  27 AC_AIX
  28 AC_ISC_POSIX
  29 AM_PROG_CC_STDC
  30
  31 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  32 AC_CANONICAL_SYSTEM
  33
  34 dnl gdb doesn't use gettext, but bfd does.  We call this to ensure we
  35 dnl link with the correct libraries.
  36 ALL_LINGUAS=
  37 CY_GNU_GETTEXT
  38
  39 dnl List of object files added by configure.
  40
  41 CONFIG_OBS=
  42 CONFIG_DEPS=
  43 CONFIG_SRCS=
  44
  45 configdirs="doc testsuite"
  46
  47 dnl
  48 changequote(,)dnl
  49
  50 . ${srcdir}/configure.host
  51
  52 . ${srcdir}/configure.tgt
  53
  54 dnl
  55 changequote([,])dnl
  56
  57 AC_PROG_AWK
  58 AC_PROG_INSTALL
  59 AC_CHECK_TOOL(AR, ar)
  60 AC_CHECK_TOOL(RANLIB, ranlib, :)
  61 AC_PROG_YACC
  62
  63 AC_ARG_PROGRAM
  64
  65 AC_TYPE_SIGNAL
  66
  67 AC_HEADER_STDC
  68
  69 AC_CHECK_HEADERS(ctype.h curses.h endian.h link.h \
  70         memory.h objlist.h ptrace.h sgtty.h stddef.h stdlib.h \
  71         string.h sys/procfs.h sys/ptrace.h sys/reg.h \
  72         term.h termio.h termios.h unistd.h wait.h sys/wait.h \
  73         wchar.h wctype.h asm/debugreg.h sys/debugreg.h sys/select.h)
  74 AC_HEADER_STAT
  75
  76 AC_C_CONST
  77
  78 AC_CHECK_FUNCS(setpgid sbrk sigaction isascii bzero bcopy btowc poll)
  79 AC_FUNC_ALLOCA
  80
  81 BFD_NEED_DECLARATION(malloc)
  82 BFD_NEED_DECLARATION(realloc)
  83 BFD_NEED_DECLARATION(free)
  84 BFD_NEED_DECLARATION(strerror)
  85 BFD_NEED_DECLARATION(strdup)
  86 BFD_NEED_DECLARATION(strstr)
  87
  88
  89 # The following save_state_t checkery is only necessary for HPUX
  90 # versions earlier than 10.20.  When those fade from memory, this
  91 # could be expunged. --jsm 1999-03-22
  92
  93 AC_MSG_CHECKING(for HPUX save_state structure)
  94 AC_EGREP_HEADER(save_state_t, machine/save_state.h,
  95                 gdb_cv_hpux_savestate=yes, gdb_cv_hpux_savestate=no)
  96 AC_EGREP_HEADER(ss_wide, machine/save_state.h, gdb_cv_hpux_sswide=yes,
  97                 gdb_cv_hpux_sswide=no)
  98 if test $gdb_cv_hpux_savestate = yes
  99 then
 100   AC_DEFINE(HAVE_STRUCT_SAVE_STATE_T, 1)
 101 fi
 102 if test $gdb_cv_hpux_sswide = yes
 103 then
 104   AC_DEFINE(HAVE_STRUCT_MEMBER_SS_WIDE, 1)
 105 fi
 106 AC_MSG_RESULT($gdb_cv_hpux_sswide)
 107
 108
 109 # If we are configured native on GNU/Linux, work around problems with
 110 # sys/procfs.h
 111 # Also detect which type of /proc is in use, such as for Unixware.
 112
 113 if test "${target}" = "${host}"; then
 114   gdb_cv_hostos_is_solaris=no
 115   case "${host}" in
 116   i[[3456]]86-*-linux*)
 117         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
 118         AC_DEFINE(sys_quotactl)
 119         ;;
 120   *-*-solaris*)
 121         gdb_cv_hostos_is_solaris=yes ;;
 122   esac
 123   AC_MSG_CHECKING(for directory proc entries)
 124 # The [gdb_host != sun4sol2] hack is because Solaris does provide the
 125 # multiple procfs files as of Solaris 2.6, but GDB can't use it right now.
 126   if test "$ac_cv_header_sys_procfs_h" = yes -a \
 127           "$gdb_cv_hostos_is_solaris" = no \
 128   -a -d /proc/$$ \
 129   -a -f /proc/$$/ctl \
 130   -a -f /proc/$$/as \
 131   -a -f /proc/$$/map \
 132   -a -f /proc/$$/status; then
 133     AC_MSG_RESULT(yes)
 134     AC_DEFINE(HAVE_MULTIPLE_PROC_FDS)
 135   else
 136     AC_MSG_RESULT(no)
 137   fi
 138 fi
 139
 140 if test "$ac_cv_header_sys_procfs_h" = yes; then
 141   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 142   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
 143   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
 144   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
 145
 146   dnl Check for PIOCSET ioctl entry
 147
 148   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
 149   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
 150   [AC_TRY_COMPILE([#include <unistd.h>
 151 #include <sys/types.h>
 152 #include <sys/procfs.h>
 153 ], [
 154     int dummy;;
 155     dummy = ioctl(0, PIOCSET, &dummy);
 156   ],
 157   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
 158   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
 159   if test $gdb_cv_have_procfs_piocset = yes; then
 160     AC_DEFINE(HAVE_PROCFS_PIOCSET)
 161   fi
 162 fi
 163
 164 dnl See if host has libm.  This is usually needed by simulators.
 165 AC_CHECK_LIB(m, main)
 166
 167 dnl Solaris puts wctype in /usr/lib/libw.a before Solaris 2.6.
 168 dnl
 169 dnl A bug in GNU ld 2.9.1 causes a problem if we link in -lw
 170 dnl under Solaris 2.6 because it is some funky empty library.
 171 dnl So only link in libw if we have to.
 172 AC_CHECK_LIB(c, wctype,: ,AC_CHECK_LIB(w, wctype))
 173
 174 dnl See if compiler supports "long long" type.
 175
 176 AC_MSG_CHECKING(for long long support in compiler)
 177 AC_CACHE_VAL(gdb_cv_c_long_long,
 178 [AC_TRY_COMPILE(, [
 179   extern long long foo;
 180   switch (foo & 2) { case 0: return 1; }
 181 ],
 182 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
 183 AC_MSG_RESULT($gdb_cv_c_long_long)
 184 if test $gdb_cv_c_long_long = yes; then
 185   AC_DEFINE(CC_HAS_LONG_LONG)
 186 fi
 187
 188 dnl See if the compiler and runtime support printing long long
 189
 190 AC_MSG_CHECKING(for long long support in printf)
 191 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 192 [AC_TRY_RUN([
 193 int main () {
 194   char buf[32];
 195   long long l = 0;
 196   l = (l << 16) + 0x0123;
 197   l = (l << 16) + 0x4567;
 198   l = (l << 16) + 0x89ab;
 199   l = (l << 16) + 0xcdef;
 200   sprintf (buf, "0x%016llx", l);
 201   return (strcmp ("0x0123456789abcdef", buf));
 202 }],
 203 gdb_cv_printf_has_long_long=yes,
 204 gdb_cv_printf_has_long_long=no,
 205 gdb_cv_printf_has_long_long=no)])
 206 if test $gdb_cv_printf_has_long_long = yes; then
 207   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 208 fi
 209 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 210
 211 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 212 dnl because autoconf complains about cross-compilation issues.  However, this
 213 dnl code uses the same variables as the macro for compatibility.
 214
 215 AC_MSG_CHECKING(for long double support in compiler)
 216 AC_CACHE_VAL(ac_cv_c_long_double,
 217 [AC_TRY_COMPILE(, [long double foo;],
 218 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 219 AC_MSG_RESULT($ac_cv_c_long_double)
 220 if test $ac_cv_c_long_double = yes; then
 221   AC_DEFINE(HAVE_LONG_DOUBLE)
 222 fi
 223
 224 dnl See if the compiler and runtime support printing long doubles
 225
 226 AC_MSG_CHECKING(for long double support in printf)
 227 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 228 [AC_TRY_RUN([
 229 int main () {
 230   char buf[16];
 231   long double f = 3.141592653;
 232   sprintf (buf, "%Lg", f);
 233   return (strncmp ("3.14159", buf, 7));
 234 }],
 235 gdb_cv_printf_has_long_double=yes,
 236 gdb_cv_printf_has_long_double=no,
 237 gdb_cv_printf_has_long_double=no)])
 238 if test $gdb_cv_printf_has_long_double = yes; then
 239   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 240 fi
 241 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 242
 243 dnl See if the compiler and runtime support scanning long doubles
 244
 245 AC_MSG_CHECKING(for long double support in scanf)
 246 AC_CACHE_VAL(gdb_cv_scanf_has_long_double,
 247 [AC_TRY_RUN([
 248 int main () {
 249   char *buf = "3.141592653";
 250   long double f = 0;
 251   sscanf (buf, "%Lg", &f);
 252   return !(f > 3.14159 && f < 3.14160);
 253 }],
 254 gdb_cv_scanf_has_long_double=yes,
 255 gdb_cv_scanf_has_long_double=no,
 256 gdb_cv_scanf_has_long_double=no)])
 257 if test $gdb_cv_scanf_has_long_double = yes; then
 258   AC_DEFINE(SCANF_HAS_LONG_DOUBLE)
 259 fi
 260 AC_MSG_RESULT($gdb_cv_scanf_has_long_double)
 261
 262 AC_FUNC_MMAP
 263
 264 dnl See if thread_db library is around for Solaris thread debugging.  Note that
 265 dnl we must explicitly test for version 1 of the library because version 0
 266 dnl (present on Solaris 2.4 or earlier) doesn't have the same API.
 267
 268 dnl Note that we only want this if we are both native (host == target), and
 269 dnl not doing a canadian cross build (build == host).
 270
 271 if test ${build} = ${host} -a ${host} = ${target} ; then
 272    case ${host_os} in
 273    hpux*)
 274       AC_MSG_CHECKING(for HPUX/OSF thread support)
 275       if test -f /usr/include/dce/cma_config.h ; then
 276          if test "$GCC" = "yes" ; then
 277             AC_MSG_RESULT(yes)
 278             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 279             CONFIG_OBS="${CONFIG_OJS} hpux-thread.o"
 280             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
 281          else
 282             AC_MSG_RESULT(no (suppressed because you are not using GCC))
 283          fi
 284       else
 285          AC_MSG_RESULT(no)
 286       fi
 287       ;;
 288    solaris*)
 289       AC_MSG_CHECKING(for Solaris thread debugging library)
 290       if test -f /usr/lib/libthread_db.so.1 ; then
 291          AC_MSG_RESULT(yes)
 292          AC_DEFINE(HAVE_THREAD_DB_LIB)
 293          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
 294          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
 295          AC_CHECK_LIB(dl, dlopen)
 296          if test "$GCC" = "yes" ; then
 297             # The GNU linker requires the -export-dynamic option to make
 298             # all symbols visible in the dynamic symbol table.
 299             hold_ldflags=$LDFLAGS
 300             AC_MSG_CHECKING(for the ld -export-dynamic flag)
 301             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
 302             AC_TRY_LINK(, [int i;], found=yes, found=no)
 303             LDFLAGS=$hold_ldflags
 304             AC_MSG_RESULT($found)
 305             if test $found = yes; then
 306                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
 307             fi
 308          fi
 309          # Sun randomly tweaked the prototypes in <proc_service.h>
 310          # at one point.
 311          AC_MSG_CHECKING(if <proc_service.h> is old)
 312          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
 313             AC_TRY_COMPILE([
 314                 #include <proc_service.h>
 315                 ps_err_e ps_pdwrite
 316                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
 317             ],, gdb_cv_proc_service_is_old=no,
 318                 gdb_cv_proc_service_is_old=yes)
 319          ])
 320          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
 321          if test $gdb_cv_proc_service_is_old = yes; then
 322             AC_DEFINE(PROC_SERVICE_IS_OLD)
 323          fi
 324       else
 325          AC_MSG_RESULT(no)
 326       fi
 327       ;;
 328    esac
 329    AC_SUBST(CONFIG_LDFLAGS)
 330 fi
 331
 332 dnl Handle optional features that can be enabled.
 333 ENABLE_CFLAGS=
 334
 335 AC_ARG_ENABLE(tui,
 336 [  --enable-tui            Enable full-screen terminal user interface],
 337 [
 338   case "${enable_tui}" in
 339     yes | no) ;;
 340     "")  enable_tui=yes ;;
 341     *)
 342       AC_MSG_ERROR(Bad value for --enable-tui: ${enableval})
 343     ;;
 344   esac
 345 ])
 346 case ${enable_tui} in
 347   "yes" )
 348     AC_DEFINE(TUI)
 349     BUILD_TUI=all-tui
 350     TUI_LIBRARY=tui/libtui.a
 351   ;;
 352   * )
 353     BUILD_TUI=
 354     TUI_LIBRARY=
 355   ;;
 356 esac
 357 AC_SUBST(BUILD_TUI)
 358 AC_SUBST(TUI_LIBRARY)
 359
 360 AC_ARG_ENABLE(netrom,
 361 [  --enable-netrom         Enable NetROM support],
 362 [case "${enableval}" in
 363 yes)    enable_netrom=yes ;;
 364 no)     enable_netrom=no ;;
 365 *)      AC_MSG_ERROR(bad value ${enableval} given for netrom option) ;;
 366 esac])
 367
 368 if test "${enable_netrom}" = "yes"; then
 369         CONFIG_OBS="${CONFIG_OBS} remote-nrom.o"
 370         CONFIG_SRCS="${CONFIG_SRCS} remote-nrom.c"
 371 fi
 372
 373 AC_ARG_ENABLE(build-warnings,
 374 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
 375 [build_warnings="-Wall -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations"
 376 case "${enableval}" in
 377   yes)  ;;
 378   no)   build_warnings="-w";;
 379   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
 380         build_warnings="${build_warnings} ${t}";;
 381   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
 382         build_warnings="${t} ${build_warnings}";;
 383   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
 384 esac],[build_warnings=""])dnl
 385
 386 if test "x${build_warnings}" != x -a "x$GCC" = xyes
 387 then
 388    WARN_CFLAGS="${build_warnings}"
 389 else
 390    WARN_CFLAGS=""
 391 fi
 392 AC_SUBST(WARN_CFLAGS)
 393
 394 MMALLOC_CFLAGS=
 395 MMALLOC=
 396 AC_SUBST(MMALLOC_CFLAGS)
 397 AC_SUBST(MMALLOC)
 398
 399 AC_ARG_WITH(mmalloc,
 400 [  --with-mmalloc          Use memory mapped malloc package],
 401 [case "${withval}" in
 402   yes)  want_mmalloc=true ;;
 403   no)   want_mmalloc=false;;
 404   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-mmalloc option) ;;
 405 esac],[want_mmalloc=false])dnl
 406
 407 if test x$want_mmalloc = xtrue; then
 408    AC_DEFINE(USE_MMALLOC)
 409    AC_DEFINE(MMCHECK_FORCE)
 410    MMALLOC_CFLAGS="-I$srcdir/../mmalloc"
 411    MMALLOC='../mmalloc/libmmalloc.a'
 412 fi
 413
 414
 415 # In the Cygwin environment, we need some additional flags.
 416 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
 417 [AC_EGREP_CPP(lose, [
 418 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
 419 lose
 420 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
 421
 422 DLLTOOL=${DLLTOOL-dlltool}
 423 WINDRES=${WINDRES-windres}
 424 AC_SUBST(DLLTOOL)
 425 AC_SUBST(WINDRES)
 426
 427 dnl Figure out which term library to use.
 428 if test x$gdb_host = xgo32; then
 429   TERM_LIB=
 430 else
 431 if test x$gdb_cv_os_cygwin = xyes; then
 432   TERM_LIB='`if test -r ../libtermcap/libtermcap.a; then echo ../libtermcap/libtermcap.a; else echo -ltermcap; fi`'
 433 else
 434   TERM_LIB=
 435   AC_CHECK_LIB(ncurses, tgetent, TERM_LIB=-lncurses,
 436     AC_CHECK_LIB(Hcurses, tgetent, TERM_LIB=-lHcurses,
 437       AC_CHECK_LIB(termlib, tgetent, TERM_LIB=-ltermlib,
 438         AC_CHECK_LIB(termcap, tgetent, TERM_LIB=-ltermcap,
 439           AC_CHECK_LIB(curses, tgetent, TERM_LIB=-lcurses,
 440             AC_CHECK_LIB(terminfo, tgetent, TERM_LIB=-lterminfo))))))
 441
 442   if test "x$TERM_LIB" = x
 443   then
 444     AC_MSG_ERROR(Could not find a term library, e.g. termcap or termlib!)
 445   fi
 446 fi
 447 fi
 448 AC_SUBST(TERM_LIB)
 449
 450 # libreadline needs libuser32.a in a cygwin environment
 451 WIN32LIBS=
 452 if test x$gdb_cv_os_cygwin = xyes; then
 453     WIN32LIBS="-luser32"
 454 fi
 455 AC_SUBST(WIN32LIBS)
 456
 457
 458 AC_PATH_X
 459
 460
 461 # Unlike the sim directory, whether a simulator is linked is controlled by
 462 # presence of a SIM= and a SIM_OBS= definition in the target '.mt' file.
 463 # This code just checks for a few cases where we'd like to ignore those
 464 # definitions, even when they're present in the '.mt' file.  These cases
 465 # are when --disable-sim is specified, or if the simulator directory is
 466 # not part of the soruce tree.
 467 #
 468 AC_ARG_ENABLE(sim,
 469 [  --enable-sim            Link gdb with simulator],
 470 [echo "enable_sim = $enable_sim";
 471  echo "enableval = ${enableval}";
 472  case "${enableval}" in
 473   yes) ignore_sim=false ;;
 474   no)  ignore_sim=true ;;
 475   *)   ignore_sim=false ;;
 476  esac],
 477 [ignore_sim=false])
 478
 479 if test ! -d "${srcdir}/../sim"; then
 480   ignore_sim=true
 481 fi
 482
 483 if test "${ignore_sim}" = "true"; then
 484     IGNORE_SIM="SIM="
 485     IGNORE_SIM_OBS="SIM_OBS="
 486 else
 487     IGNORE_SIM=""
 488     IGNORE_SIM_OBS=""
 489     AC_DEFINE(WITH_SIM)
 490 fi
 491 AC_SUBST(IGNORE_SIM)
 492 AC_SUBST(IGNORE_SIM_OBS)
 493
 494 AC_SUBST(ENABLE_CFLAGS)
 495
 496 AC_SUBST(CONFIG_OBS)
 497 AC_SUBST(CONFIG_DEPS)
 498 AC_SUBST(CONFIG_SRCS)
 499
 500 # Begin stuff to support --enable-shared
 501 AC_ARG_ENABLE(shared,
 502 [  --enable-shared         Use shared libraries],
 503 [case "${enableval}" in
 504   yes) shared=true ;;
 505   no)  shared=false ;;
 506   *) shared=true ;;
 507 esac])dnl
 508
 509 HLDFLAGS=
 510 HLDENV=
 511 # If we have shared libraries, try to set rpath reasonably.
 512 if test "${shared}" = "true"; then
 513   case "${host}" in
 514   *-*-hpux*)
 515     HLDFLAGS='-Wl,+s,+b,$(libdir)'
 516     ;;
 517   *-*-irix5* | *-*-irix6*)
 518     HLDFLAGS='-Wl,-rpath,$(libdir)'
 519     ;;
 520   *-*-linux*aout*)
 521     ;;
 522   *-*-linux* | *-pc-linux-gnu)
 523     HLDFLAGS='-Wl,-rpath,$(libdir)'
 524     ;;
 525   *-*-solaris*)
 526     HLDFLAGS='-R $(libdir)'
 527     ;;
 528   *-*-sysv4*)
 529     HLDENV='if test -z "$${LD_RUN_PATH}"; then LD_RUN_PATH=$(libdir); else LD_RUN_PATH=$${LD_RUN_PATH}:$(libdir); fi; export LD_RUN_PATH;'
 530     ;;
 531   esac
 532 fi
 533
 534 # On SunOS, if the linker supports the -rpath option, use it to
 535 # prevent ../bfd and ../opcodes from being included in the run time
 536 # search path.
 537 case "${host}" in
 538   *-*-sunos*)
 539     echo 'main () { }' > conftest.c
 540     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
 541     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
 542       :
 543     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
 544       :
 545     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
 546       :
 547     elif grep 'some text already loaded' conftest.t >/dev/null 2>&1; then
 548       :
 549     elif test "${shared}" = "true"; then
 550       HLDFLAGS='-Wl,-rpath=$(libdir)'
 551     else
 552       HLDFLAGS='-Wl,-rpath='
 553     fi
 554     rm -f conftest.t conftest.c conftest
 555     ;;
 556 esac
 557 AC_SUBST(HLDFLAGS)
 558 AC_SUBST(HLDENV)
 559 # End stuff to support --enable-shared
 560
 561 # target_subdir is used by the testsuite to find the target libraries.
 562 target_subdir=
 563 if test "${host}" != "${target}"; then
 564     target_subdir="${target_alias}/"
 565 fi
 566 AC_SUBST(target_subdir)
 567
 568 frags=
 569 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
 570 if test ! -f ${host_makefile_frag}; then
 571 AC_MSG_ERROR("*** Gdb does not support host ${host}")
 572 fi
 573 frags="$frags $host_makefile_frag"
 574
 575 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
 576 if test ! -f ${target_makefile_frag}; then
 577 AC_MSG_ERROR("*** Gdb does not support target ${target}")
 578 fi
 579 frags="$frags $target_makefile_frag"
 580
 581 AC_SUBST_FILE(host_makefile_frag)
 582 AC_SUBST_FILE(target_makefile_frag)
 583 AC_SUBST(frags)
 584
 585 changequote(,)dnl
 586 hostfile=`sed -n '
 587 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 588 ' ${host_makefile_frag}`
 589
 590 targetfile=`sed -n '
 591 s/TM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 592 ' ${target_makefile_frag}`
 593
 594 # these really aren't orthogonal true/false values of the same condition,
 595 # but shells are slow enough that I like to reuse the test conditions
 596 # whenever possible
 597 if test "${target}" = "${host}"; then
 598 nativefile=`sed -n '
 599 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
 600 ' ${host_makefile_frag}`
 601 # else
 602 # GDBserver is only useful in a "native" enviroment
 603 # configdirs=`echo $configdirs | sed 's/gdbserver//'`
 604 fi
 605 changequote([,])
 606
 607 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
 608 # (NAT_FILE) is not set in config/*/*.m[ht] files, we don't make the
 609 # corresponding links.  But we have to remove the xm.h files and tm.h
 610 # files anyway, e.g. when switching from "configure host" to
 611 # "configure none".
 612
 613 files=
 614 links=
 615 rm -f xm.h
 616 if test "${hostfile}" != ""; then
 617 files="${files} config/${gdb_host_cpu}/${hostfile}"
 618 links="${links} xm.h"
 619 fi
 620 rm -f tm.h
 621 if test "${targetfile}" != ""; then
 622 files="${files} config/${gdb_target_cpu}/${targetfile}"
 623 links="${links} tm.h"
 624 fi
 625 rm -f nm.h
 626 if test "${nativefile}" != ""; then
 627 files="${files} config/${gdb_host_cpu}/${nativefile}"
 628 links="${links} nm.h"
 629 else
 630 # A cross-only configuration.
 631 files="${files} config/nm-empty.h"
 632 links="${links} nm.h"
 633 fi
 634
 635 AC_LINK_FILES($files, $links)
 636
 637 dnl Check for exe extension set on certain hosts (e.g. Win32)
 638 AC_EXEEXT
 639
 640 AC_CONFIG_SUBDIRS($configdirs)
 641 AC_OUTPUT(Makefile tui/Makefile .gdbinit:gdbinit.in,
 642 [
 643 dnl Autoconf doesn't provide a mechanism for modifying definitions
 644 dnl provided by makefile fragments.
 645 dnl
 646 if test "${nativefile}" = ""; then
 647 sed -e '/^NATDEPFILES[[         ]]*=[[  ]]*/s//# NATDEPFILES=/' \
 648         < Makefile > Makefile.tem
 649 mv -f Makefile.tem Makefile
 650 fi
 651
 652 changequote(,)dnl
 653 sed -e '/^TM_FILE[      ]*=/s,^TM_FILE[         ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
 654 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
 655 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
 656 mv -f Makefile.tmp Makefile
 657 changequote([,])dnl
 658
 659 case x$CONFIG_HEADERS in
 660 xconfig.h:config.in)
 661 echo > stamp-h ;;
 662 esac
 663 ],
 664 [
 665 gdb_host_cpu=$gdb_host_cpu
 666 gdb_target_cpu=$gdb_target_cpu
 667 nativefile=$nativefile
 668 ])
 669
 670 exit 0