1 dnl Autoconf configure script for GDB, the GNU debugger.
2 dnl Copyright 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003
3 dnl Free Software Foundation, Inc.
5 dnl This file is part of GDB.
7 dnl This program is free software; you can redistribute it and/or modify
8 dnl it under the terms of the GNU General Public License as published by
9 dnl the Free Software Foundation; either version 2 of the License, or
10 dnl (at your option) any later version.
12 dnl This program is distributed in the hope that it will be useful,
13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15 dnl GNU General Public License for more details.
17 dnl You should have received a copy of the GNU General Public License
18 dnl along with this program; if not, write to the Free Software
19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
21 dnl Process this file with autoconf to produce a configure script.
25 AC_CONFIG_HEADER(config.h:config.in)
34 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
37 # FIXME: kettenis/20030102: The AC_PROG_RANLIB from Autoconf 2.13
38 # doesn't support cross-compilation, but the one from Autoconf 2.5x
39 # does. Override RANLIB here (i.e. before running AC_PROG_RANLIB) to
40 # deal with the lossage. Note that CY_GNU_GETTEXT currently calls
41 # AC_PROG_RANLIB. This can be removed when we switch to # Autoconf
43 AC_CHECK_TOOL(RANLIB, ranlib, :)
45 dnl Set up for gettext. PACKAGE is used when we call bindtextdomain.
48 AC_DEFINE(PACKAGE, "gdb", [Name of this package. ])
51 dnl List of object files added by configure.
64 AC_CONFIG_SUBDIRS(doc testsuite)
67 . $srcdir/configure.host
69 . $srcdir/configure.tgt
71 # Fetch the default architecture and default target vector from BFD.
72 targ=$target; . $srcdir/../bfd/config.bfd
74 # We only want the first architecture, so strip off the others if
75 # there is more than one.
76 targ_archs=`echo $targ_archs | sed 's/ .*//'`
78 if test "x$targ_archs" != x; then
79 AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
80 [Define to BFD's default architecture. ])
82 if test "x$targ_defvec" != x; then
83 AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
84 [Define to BFD's default target vector. ])
89 # The CLI cannot be disabled yet, but may be in the future.
93 [ --disable-gdbcli disable command-line interface (CLI)],
98 AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
100 AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
103 if test x"$enable_gdbcli" = xyes; then
104 if test -d $srcdir/cli; then
105 CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
106 CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
107 CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
108 CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_CLI_INITS)"
109 ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
110 CONFIG_ALL="$CONFIG_ALL \$(SUBDIR_CLI_ALL)"
111 CONFIG_CLEAN="$CONFIG_CLEAN \$(SUBDIR_CLI_CLEAN)"
112 CONFIG_INSTALL="$CONFIG_INSTALL \$(SUBDIR_CLI_INSTALL)"
113 CONFIG_UNINSTALL="$CONFIG_UNINSTALL \$(SUBDIR_CLI_UNINSTALL)"
119 [ --disable-gdbmi disable machine-interface (MI)],
124 AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
127 if test x"$enable_gdbmi" = xyes; then
128 if test -d $srcdir/mi; then
129 CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
130 CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
131 CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
132 CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_MI_INITS)"
133 ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
134 CONFIG_ALL="$CONFIG_ALL \$(SUBDIR_MI_ALL)"
135 CONFIG_CLEAN="$CONFIG_CLEAN \$(SUBDIR_MI_CLEAN)"
136 CONFIG_INSTALL="$CONFIG_INSTALL \$(SUBDIR_MI_INSTALL)"
137 CONFIG_UNINSTALL="$CONFIG_UNINSTALL \$(SUBDIR_MI_UNINSTALL)"
143 [ --enable-tui enable full-screen terminal user interface (TUI)],
148 AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
150 if test x"$enable_tui" = xyes; then
151 if test -d $srcdir/tui; then
152 CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
153 CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
154 CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
155 CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_TUI_INITS)"
156 ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
157 CONFIG_ALL="$CONFIG_ALL \$(SUBDIR_TUI_ALL)"
158 CONFIG_CLEAN="$CONFIG_CLEAN \$(SUBDIR_TUI_CLEAN)"
159 CONFIG_INSTALL="$CONFIG_INSTALL \$(SUBDIR_TUI_INSTALL)"
160 CONFIG_UNINSTALL="$CONFIG_UNINSTALL \$(SUBDIR_TUI_UNINSTALL)"
167 [ --enable-gtk enable gdbtk graphical user interface (GUI)],
172 AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
174 [if test -d $srcdir/gdbtk; then
179 # We unconditionally disable gdbtk tests on selected platforms.
182 AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
186 # --------------------- #
187 # Checks for programs. #
188 # --------------------- #
196 AC_CHECK_TOOL(AR, ar)
197 AC_CHECK_TOOL(DLLTOOL, dlltool)
198 AC_CHECK_TOOL(WINDRES, windres)
200 # Needed for GNU/Hurd.
201 AC_CHECK_TOOL(MIG, mig)
203 # ---------------------- #
204 # Checks for libraries. #
205 # ---------------------- #
207 # We might need to link with -lm; most simulators need it.
208 AC_CHECK_LIB(m, main)
210 # We need to link with -lw to get `wctype' on Solaris before Solaris
211 # 2.6. Solaris 2.6 and beyond have this function in libc, and have a
212 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
213 # is known to have this problem). Therefore we avoid libw if we can.
214 AC_CHECK_FUNC(wctype, [],
215 [AC_CHECK_LIB(w, wctype)])
217 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
218 AC_SEARCH_LIBS(socketpair, socket)
220 # Since GDB uses Readline, we need termcap functionality, so we need
221 # to find a library that provides that. When GDB is configured with
222 # --enable-tui, we need full curses functionality.
224 # FIXME: kettenis/20030102: We seem to prefer HP curses (Hcurses) over
225 # Xcurses on HP-UX; see the `-D__HP_CURSES' in the relevant host
226 # Makefile fragments. That's why we need to have `Hcurses' before
227 # `curses'. I don't see why we should use HP curses if a more
228 # standard curses is available, except that according to HP's
229 # documentation one needs to compile `-D_XOPEN_SOURCE_EXTENDED' on
230 # HP-UX 10.10 and 10.20.
232 if test "$need_curses" = yes; then
233 AC_SEARCH_LIBS(initscr, [ncurses Hcurses curses], [],
234 [AC_MSG_ERROR([no curses library found])])
239 if test -d $srcdir/libtermcap; then
240 LIBS="../libtermcap/libtermcap.a $LIBS"
241 ac_cv_search_tgetent="../libtermcap/libtermcap.a"
244 # ??? Is this really true?
245 ac_cv_search_tgetent="none required"
248 # Readline prefers curses over termcap on AIX.
250 AC_SEARCH_LIBS(tgetent, [tinfo ncurses curses termcap])
254 # Note: We used to check for libtermlib and libterminfo too, but
255 # Readline doesn't, so I think we're safe with leaving them out.
256 AC_SEARCH_LIBS(tgetent, [termcap tinfo ncurses Hcurses curses])
258 if test "$ac_cv_search_tgetent" = no; then
259 AC_MSG_ERROR([no termcap library found])
262 # ------------------------- #
263 # Checks for header files. #
264 # ------------------------- #
269 AC_CHECK_HEADERS(link.h)
270 AC_CHECK_HEADERS(nlist.h)
271 AC_CHECK_HEADERS(poll.h sys/poll.h)
272 AC_CHECK_HEADERS(proc_service.h thread_db.h)
273 AC_CHECK_HEADERS(stddef.h)
274 AC_CHECK_HEADERS(stdlib.h)
275 AC_CHECK_HEADERS(stdint.h)
276 AC_CHECK_HEADERS(string.h memory.h strings.h)
277 AC_CHECK_HEADERS(sys/fault.h)
278 AC_CHECK_HEADERS(sys/file.h)
279 AC_CHECK_HEADERS(sys/filio.h)
280 AC_CHECK_HEADERS(sys/ioctl.h)
281 AC_CHECK_HEADERS(sys/param.h)
282 AC_CHECK_HEADERS(sys/proc.h)
283 AC_CHECK_HEADERS(sys/procfs.h)
284 AC_CHECK_HEADERS(sys/ptrace.h ptrace.h)
285 AC_CHECK_HEADERS(sys/reg.h sys/debugreg.h)
286 AC_CHECK_HEADERS(sys/select.h)
287 AC_CHECK_HEADERS(sys/syscall.h)
288 AC_CHECK_HEADERS(sys/user.h)
289 AC_CHECK_HEADERS(sys/wait.h wait.h)
290 AC_CHECK_HEADERS(termios.h termio.h sgtty.h)
291 AC_CHECK_HEADERS(unistd.h)
293 # On Solaris 2.[78], we need to define _MSE_INT_H to avoid a clash
294 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
295 # think that we don't have <curses.h> if we're using GCC.
298 if test "$GCC" = yes; then
299 AC_DEFINE(_MSE_INT_H, 1,
300 [[Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
301 Solaris 2.[78] when using GCC. ]])
304 AC_CHECK_HEADERS(curses.h ncurses.h term.h)
306 # FIXME: kettenis/20030102: In most cases we include these
307 # unconditionally, so what's the point in checking these?
308 AC_CHECK_HEADERS(ctype.h time.h)
310 # ------------------ #
311 # Checks for types. #
312 # ------------------ #
316 # ------------------------------------- #
317 # Checks for compiler characteristics. #
318 # ------------------------------------- #
323 # ------------------------------ #
324 # Checks for library functions. #
325 # ------------------------------ #
330 AC_CHECK_FUNCS(canonicalize_file_name realpath)
332 AC_CHECK_FUNCS(pread64)
334 AC_CHECK_FUNCS(setpgid setpgrp)
335 AC_CHECK_FUNCS(sigaction sigprocmask sigsetmask)
336 AC_CHECK_FUNCS(socketpair)
338 dnl AC_FUNC_SETPGRP does not work when cross compiling
339 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
340 if test "$cross_compiling" = no; then
343 AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
347 if (setpgrp(1,1) == -1)
351 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
352 if test $ac_cv_func_setpgrp_void = yes; then
353 AC_DEFINE(SETPGRP_VOID, 1)
357 # Check if sigsetjmp is available. Using AC_CHECK_FUNCS won't do
358 # since sigsetjmp might only be defined as a macro.
359 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
362 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
363 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
364 if test $gdb_cv_func_sigsetjmp = yes; then
365 AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
368 # Assume we'll default to using the included libiberty regex.
369 gdb_use_included_regex=yes
371 # However, if the system regex is GNU regex, then default to *not*
372 # using the included regex.
375 [gdb_cv_have_gnu_regex],
377 [#include <gnu-versions.h>],
378 [#define REGEX_INTERFACE_VERSION 1
379 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
380 # error "Version mismatch"
382 gdb_cv_have_gnu_regex=yes,
383 gdb_cv_have_gnu_regex=no)])
384 if test $gdb_cv_have_gnu_regex = yes; then
385 gdb_use_included_regex=no
388 AC_ARG_WITH(included-regex,
389 [ --without-included-regex don't use included regex; this is the default
390 on systems with version 2 of the GNU C library
391 (use with caution on other system)],
392 gdb_with_regex=$withval,
393 gdb_with_regex=$gdb_use_included_regex)
394 if test "$gdb_with_regex" = yes; then
395 AC_DEFINE(USE_INCLUDED_REGEX, 1,
396 [Define to 1 if the regex included in libiberty should be used.])
399 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
400 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
401 AC_CACHE_CHECK([for r_fs in struct reg], gdb_cv_struct_reg_r_fs,
402 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_fs;],
403 gdb_cv_struct_reg_r_fs=yes, gdb_cv_struct_reg_r_fs=no)])
404 if test $gdb_cv_struct_reg_r_fs = yes; then
405 AC_DEFINE(HAVE_STRUCT_REG_R_FS)
407 AC_CACHE_CHECK([for r_gs in struct reg], gdb_cv_struct_reg_r_gs,
408 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_gs;],
409 gdb_cv_struct_reg_r_gs=yes, gdb_cv_struct_reg_r_gs=no)])
410 if test $gdb_cv_struct_reg_r_gs = yes; then
411 AC_DEFINE(HAVE_STRUCT_REG_R_GS)
414 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
415 AC_MSG_CHECKING(for PTRACE_GETREGS)
416 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
417 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
419 [gdb_cv_have_ptrace_getregs=yes],
420 [gdb_cv_have_ptrace_getregs=no])])
421 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
422 if test $gdb_cv_have_ptrace_getregs = yes; then
423 AC_DEFINE(HAVE_PTRACE_GETREGS)
426 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
427 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
428 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
429 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
430 [PTRACE_GETFPXREGS;],
431 [gdb_cv_have_ptrace_getfpxregs=yes],
432 [gdb_cv_have_ptrace_getfpxregs=no])])
433 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
434 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
435 AC_DEFINE(HAVE_PTRACE_GETFPXREGS)
438 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
439 AC_MSG_CHECKING(for PT_GETDBREGS)
440 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
441 [AC_TRY_COMPILE([#include <sys/types.h>
442 #include <sys/ptrace.h>],
444 [gdb_cv_have_pt_getdbregs=yes],
445 [gdb_cv_have_pt_getdbregs=no])])
446 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
447 if test $gdb_cv_have_pt_getdbregs = yes; then
448 AC_DEFINE(HAVE_PT_GETDBREGS)
451 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
452 AC_MSG_CHECKING(for PT_GETXMMREGS)
453 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
454 [AC_TRY_COMPILE([#include <sys/types.h>
455 #include <sys/ptrace.h>],
457 [gdb_cv_have_pt_getxmmregs=yes],
458 [gdb_cv_have_pt_getxmmregs=no])])
459 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
460 if test $gdb_cv_have_pt_getxmmregs = yes; then
461 AC_DEFINE(HAVE_PT_GETXMMREGS)
465 BFD_NEED_DECLARATION(malloc)
466 BFD_NEED_DECLARATION(realloc)
467 BFD_NEED_DECLARATION(free)
468 BFD_NEED_DECLARATION(strerror)
469 BFD_NEED_DECLARATION(strdup)
470 BFD_NEED_DECLARATION(strstr)
471 BFD_NEED_DECLARATION(canonicalize_file_name)
473 # The following save_state_t checkery is only necessary for HPUX
474 # versions earlier than 10.20. When those fade from memory, this
475 # could be expunged. --jsm 1999-03-22
477 AC_MSG_CHECKING(for HPUX save_state structure)
478 AC_EGREP_HEADER(save_state_t, machine/save_state.h,
479 gdb_cv_hpux_savestate=yes, gdb_cv_hpux_savestate=no)
480 AC_EGREP_HEADER(ss_wide, machine/save_state.h, gdb_cv_hpux_sswide=yes,
481 gdb_cv_hpux_sswide=no)
482 if test $gdb_cv_hpux_savestate = yes
484 AC_DEFINE(HAVE_STRUCT_SAVE_STATE_T, 1)
486 if test $gdb_cv_hpux_sswide = yes
488 AC_DEFINE(HAVE_STRUCT_MEMBER_SS_WIDE, 1)
490 AC_MSG_RESULT($gdb_cv_hpux_sswide)
493 # If we are configured native on GNU/Linux, work around problems with
495 # Also detect which type of /proc is in use, such as for Unixware or Solaris.
497 if test "${target}" = "${host}"; then
499 i[[3456]]86-*-linux*)
500 AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
501 AC_DEFINE(sys_quotactl)
504 AC_DEFINE(NEW_PROC_API)
506 *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
507 AC_DEFINE(NEW_PROC_API)
509 *-*-solaris2.[[678]])
510 AC_DEFINE(NEW_PROC_API)
515 if test "$ac_cv_header_sys_procfs_h" = yes; then
516 BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
517 BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
518 BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
519 BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
520 BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
521 BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
522 BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
523 BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
524 BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
525 BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
526 BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
527 BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
528 BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
529 BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
532 dnl Check for broken prfpregset_t type
534 dnl For Linux/i386, glibc 2.1.3 was released with a bogus
535 dnl prfpregset_t type (it's a typedef for the pointer to a struct
536 dnl instead of the struct itself). We detect this here, and work
537 dnl around it in gdb_proc_service.h.
539 if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
540 AC_MSG_CHECKING(whether prfpregset_t type is broken)
541 AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
542 [AC_TRY_RUN([#include <sys/procfs.h>
545 if (sizeof (prfpregset_t) == sizeof (void *))
549 gdb_cv_prfpregset_t_broken=no,
550 gdb_cv_prfpregset_t_broken=yes,
551 gdb_cv_prfpregset_t_broken=yes)])
552 AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
553 if test $gdb_cv_prfpregset_t_broken = yes; then
554 AC_DEFINE(PRFPREGSET_T_BROKEN)
558 dnl Check for PIOCSET ioctl entry
560 AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
561 AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
562 [AC_TRY_COMPILE([#include <unistd.h>
563 #include <sys/types.h>
564 #include <sys/procfs.h>
567 dummy = ioctl(0, PIOCSET, &dummy);
569 gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
570 AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
571 if test $gdb_cv_have_procfs_piocset = yes; then
572 AC_DEFINE(HAVE_PROCFS_PIOCSET)
576 dnl For native ports (host == target), check to see what kind of
577 dnl legacy link.h support is needed. (See solib-legacy.c.)
578 if test ${host} = ${target} ; then
579 dnl Check for struct link_map with l_ members which are indicative
580 dnl of SVR4-like shared libraries
582 AC_MSG_CHECKING(for member l_addr in struct link_map)
583 AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
584 [AC_TRY_COMPILE([#include <link.h>],
585 [struct link_map lm; (void) lm.l_addr;],
586 gdb_cv_have_struct_link_map_with_l_members=yes,
587 gdb_cv_have_struct_link_map_with_l_members=no)])
588 AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
589 if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
590 AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS)
593 dnl Check for struct link_map with lm_ members which are indicative
594 dnl of SunOS-like shared libraries
596 AC_MSG_CHECKING(for member lm_addr in struct link_map)
597 AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
598 [AC_TRY_COMPILE([#include <sys/types.h>
600 [struct link_map lm; (void) lm.lm_addr;],
601 gdb_cv_have_struct_link_map_with_lm_members=yes,
602 gdb_cv_have_struct_link_map_with_lm_members=no)])
603 AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
604 if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
605 AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS)
608 dnl Check for struct so_map with som_ members which are found on
609 dnl some *BSD systems.
611 AC_MSG_CHECKING(for member som_addr in struct so_map)
612 AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
613 [AC_TRY_COMPILE([#include <sys/types.h>
618 [struct so_map lm; (void) lm.som_addr;],
619 gdb_cv_have_struct_so_map_with_som_members=yes,
620 gdb_cv_have_struct_so_map_with_som_members=no)])
621 AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
622 if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
623 AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS)
626 dnl Check for struct link_map32 type, which allows a 64-bit Solaris
627 dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
629 AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
630 AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
631 [AC_TRY_COMPILE([#define _SYSCALL32
632 #include <sys/link.h>], [struct link_map32 l;],
633 gdb_cv_have_struct_link_map32=yes,
634 gdb_cv_have_struct_link_map32=no)])
635 AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
636 if test $gdb_cv_have_struct_link_map32 = yes; then
637 AC_DEFINE(HAVE_STRUCT_LINK_MAP32)
638 AC_DEFINE(_SYSCALL32)
642 dnl See if compiler supports "long long" type.
644 AC_MSG_CHECKING(for long long support in compiler)
645 AC_CACHE_VAL(gdb_cv_c_long_long,
647 extern long long foo;
648 switch (foo & 2) { case 0: return 1; }
650 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
651 AC_MSG_RESULT($gdb_cv_c_long_long)
652 if test $gdb_cv_c_long_long = yes; then
653 AC_DEFINE(CC_HAS_LONG_LONG)
656 dnl See if the compiler and runtime support printing long long
658 AC_MSG_CHECKING(for long long support in printf)
659 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
664 l = (l << 16) + 0x0123;
665 l = (l << 16) + 0x4567;
666 l = (l << 16) + 0x89ab;
667 l = (l << 16) + 0xcdef;
668 sprintf (buf, "0x%016llx", l);
669 return (strcmp ("0x0123456789abcdef", buf));
671 gdb_cv_printf_has_long_long=yes,
672 gdb_cv_printf_has_long_long=no,
673 gdb_cv_printf_has_long_long=no)])
674 if test $gdb_cv_printf_has_long_long = yes; then
675 AC_DEFINE(PRINTF_HAS_LONG_LONG)
677 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
679 dnl See if compiler supports "long double" type. Can't use AC_C_LONG_DOUBLE
680 dnl because autoconf complains about cross-compilation issues. However, this
681 dnl code uses the same variables as the macro for compatibility.
683 AC_MSG_CHECKING(for long double support in compiler)
684 AC_CACHE_VAL(ac_cv_c_long_double,
685 [AC_TRY_COMPILE(, [long double foo;],
686 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
687 AC_MSG_RESULT($ac_cv_c_long_double)
688 if test $ac_cv_c_long_double = yes; then
689 AC_DEFINE(HAVE_LONG_DOUBLE)
692 dnl See if the compiler and runtime support printing long doubles
694 AC_MSG_CHECKING(for long double support in printf)
695 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
699 long double f = 3.141592653;
700 sprintf (buf, "%Lg", f);
701 return (strncmp ("3.14159", buf, 7));
703 gdb_cv_printf_has_long_double=yes,
704 gdb_cv_printf_has_long_double=no,
705 gdb_cv_printf_has_long_double=no)])
706 if test $gdb_cv_printf_has_long_double = yes; then
707 AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
709 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
711 dnl See if the compiler and runtime support scanning long doubles
713 AC_MSG_CHECKING(for long double support in scanf)
714 AC_CACHE_VAL(gdb_cv_scanf_has_long_double,
717 char *buf = "3.141592653";
719 sscanf (buf, "%Lg", &f);
720 return !(f > 3.14159 && f < 3.14160);
722 gdb_cv_scanf_has_long_double=yes,
723 gdb_cv_scanf_has_long_double=no,
724 gdb_cv_scanf_has_long_double=no)])
725 if test $gdb_cv_scanf_has_long_double = yes; then
726 AC_DEFINE(SCANF_HAS_LONG_DOUBLE)
728 AC_MSG_RESULT($gdb_cv_scanf_has_long_double)
732 AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
733 SAVE_LDFLAGS=$LDFLAGS
736 yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
737 *) gdb_cv_bigtoc=-bbigtoc ;;
740 LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
741 AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
743 CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
748 dnl For certain native configurations, we need to check whether thread
749 dnl support can be built in or not.
751 dnl Note that we only want this if we are both native (host == target),
752 dnl and not doing a canadian cross build (build == host).
754 if test ${build} = ${host} -a ${host} = ${target} ; then
757 AC_MSG_CHECKING(for HPUX/OSF thread support)
758 if test -f /usr/include/dce/cma_config.h ; then
759 if test "$GCC" = "yes" ; then
761 AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
762 CONFIG_LIB_OBS="${CONFIG_LIB_OBS} hpux-thread.o"
763 CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
765 AC_MSG_RESULT(no (suppressed because you are not using GCC))
772 # See if thread_db library is around for Solaris thread debugging.
773 # Note that we must explicitly test for version 1 of the library
774 # because version 0 (present on Solaris 2.4 or earlier) doesn't have
776 AC_MSG_CHECKING(for Solaris thread debugging library)
777 if test -f /usr/lib/libthread_db.so.1 ; then
779 AC_DEFINE(HAVE_THREAD_DB_LIB)
780 CONFIG_LIB_OBS="${CONFIG_LIB_OBS} sol-thread.o"
781 CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
782 AC_CHECK_LIB(dl, dlopen)
783 if test "$GCC" = "yes" ; then
784 # The GNU linker requires the -export-dynamic option to make
785 # all symbols visible in the dynamic symbol table.
786 hold_ldflags=$LDFLAGS
787 AC_MSG_CHECKING(for the ld -export-dynamic flag)
788 LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
789 AC_TRY_LINK(, [int i;], found=yes, found=no)
790 LDFLAGS=$hold_ldflags
791 AC_MSG_RESULT($found)
792 if test $found = yes; then
793 CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
796 # Sun randomly tweaked the prototypes in <proc_service.h>
798 AC_MSG_CHECKING(if <proc_service.h> is old)
799 AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
801 #include <proc_service.h>
803 (struct ps_prochandle*, psaddr_t, const void*, size_t);
804 ],, gdb_cv_proc_service_is_old=no,
805 gdb_cv_proc_service_is_old=yes)
807 AC_MSG_RESULT($gdb_cv_proc_service_is_old)
808 if test $gdb_cv_proc_service_is_old = yes; then
809 AC_DEFINE(PROC_SERVICE_IS_OLD)
816 AC_MSG_CHECKING(for AiX thread debugging library)
817 AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
818 [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
819 [#ifndef PTHDB_VERSION_3
822 gdb_cv_have_aix_thread_debug=yes,
823 gdb_cv_have_aix_thread_debug=no)])
824 AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
825 if test $gdb_cv_have_aix_thread_debug = yes; then
826 CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
827 CONFIG_LIB_OBS="${CONFIG_LIB_OBS} aix-thread.o"
828 CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
832 AC_SUBST(CONFIG_LDFLAGS)
835 dnl See if we have a thread_db header file that has TD_NOTALLOC.
836 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
837 AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
838 gdb_cv_thread_db_h_has_td_notalloc,
840 [#include <thread_db.h>],
841 [int i = TD_NOTALLOC;],
842 gdb_cv_thread_db_h_has_td_notalloc=yes,
843 gdb_cv_thread_db_h_has_td_notalloc=no
847 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
848 AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
849 [Define if <thread_db.h> has the TD_NOTALLOC error code.])
852 dnl Handle optional features that can be enabled.
855 [ --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
857 case ${with_sysroot} in
858 yes) AC_ERROR(with-sysroot must specify path) ;;
859 *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
862 TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
864 if test "x$exec_prefix" = xNONE; then
865 if test "x$prefix" = xNONE; then
866 test_prefix=/usr/local
871 test_prefix=$exec_prefix
873 case ${TARGET_SYSTEM_ROOT} in
875 t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
876 TARGET_SYSTEM_ROOT_DEFINE="$t"
881 TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
883 AC_SUBST(TARGET_SYSTEM_ROOT)
884 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
886 # NOTE: Don't add -Wall or -Wunused, they both include
887 # -Wunused-parameter which reports bogus warnings.
888 # NOTE: If you add to this list, remember to update
889 # gdb/doc/gdbint.texinfo.
890 build_warnings="-Wimplicit -Wreturn-type -Wcomment -Wtrigraphs \
891 -Wformat -Wparentheses -Wpointer-arith -Wuninitialized"
892 # Up for debate: -Wswitch -Wcomment -trigraphs -Wtrigraphs
893 # -Wunused-function -Wunused-label -Wunused-variable -Wunused-value
894 # -Wchar-subscripts -Wtraditional -Wshadow -Wcast-qual
895 # -Wcast-align -Wwrite-strings -Wconversion -Wstrict-prototypes
896 # -Wmissing-prototypes -Wmissing-declarations -Wredundant-decls
897 # -Woverloaded-virtual -Winline -Werror"
898 AC_ARG_ENABLE(build-warnings,
899 [ --enable-build-warnings Enable build-time compiler warnings if gcc is used],
900 [case "${enableval}" in
902 no) build_warnings="-w";;
903 ,*) t=`echo "${enableval}" | sed -e "s/,/ /g"`
904 build_warnings="${build_warnings} ${t}";;
905 *,) t=`echo "${enableval}" | sed -e "s/,/ /g"`
906 build_warnings="${t} ${build_warnings}";;
907 *) build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
909 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
910 echo "Setting compiler warning flags = $build_warnings" 6>&1
912 AC_ARG_ENABLE(gdb-build-warnings,
913 [ --enable-gdb-build-warnings Enable GDB specific build-time compiler warnings if gcc is used],
914 [case "${enableval}" in
916 no) build_warnings="-w";;
917 ,*) t=`echo "${enableval}" | sed -e "s/,/ /g"`
918 build_warnings="${build_warnings} ${t}";;
919 *,) t=`echo "${enableval}" | sed -e "s/,/ /g"`
920 build_warnings="${t} ${build_warnings}";;
921 *) build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
923 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
924 echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
928 if test "x${build_warnings}" != x -a "x$GCC" = xyes
930 AC_MSG_CHECKING(compiler warning flags)
931 # Separate out the -Werror flag as some files just cannot be
932 # compiled with it enabled.
933 for w in ${build_warnings}; do
935 -Werr*) WERROR_CFLAGS=-Werror ;;
936 *) # Check that GCC accepts it
937 saved_CFLAGS="$CFLAGS"
939 AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
940 CFLAGS="$saved_CFLAGS"
943 AC_MSG_RESULT(${WARN_CFLAGS}${WERROR_CFLAGS})
945 AC_SUBST(WARN_CFLAGS)
946 AC_SUBST(WERROR_CFLAGS)
950 AC_SUBST(MMALLOC_CFLAGS)
954 [ --with-mmalloc Use memory mapped malloc package],
955 [case "${withval}" in
956 yes) want_mmalloc=true ;;
957 no) want_mmalloc=false;;
958 *) AC_MSG_ERROR(bad value ${withval} for GDB with-mmalloc option) ;;
959 esac],[want_mmalloc=false])dnl
961 if test x$want_mmalloc = xtrue; then
962 AC_DEFINE(USE_MMALLOC)
963 AC_DEFINE(MMCHECK_FORCE)
964 MMALLOC_CFLAGS="-I$srcdir/../mmalloc"
965 MMALLOC='../mmalloc/libmmalloc.a'
968 # In the Cygwin environment, we need some additional flags.
969 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
970 [AC_EGREP_CPP(lose, [
971 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
973 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
976 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
977 SER_HARDWIRE="ser-unix.o ser-pipe.o ser-tcp.o"
979 *go32* ) SER_HARDWIRE=ser-go32.o ;;
980 *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
982 AC_SUBST(SER_HARDWIRE)
984 # libreadline needs libuser32.a in a cygwin environment
986 if test x$gdb_cv_os_cygwin = xyes; then
989 *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
995 LIBGUI="../libgui/src/libgui.a"
996 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
998 AC_SUBST(GUI_CFLAGS_X)
1002 AC_SUBST(WIN32LDAPP)
1007 if test "${enable_gdbtk}" = "yes"; then
1009 # Gdbtk must have an absolute path to srcdir in order to run
1010 # properly when not installed.
1016 CY_AC_PATH_TCLCONFIG
1017 if test -z "${no_tcl}"; then
1018 CY_AC_LOAD_TCLCONFIG
1021 # now look for Tcl library stuff
1032 TCL_DEPS="${tcldir}${TCL_LIB_FILE}"
1034 # If $no_tk is nonempty, then we can't do Tk, and there is no
1035 # point to doing Tcl.
1036 if test -z "${no_tk}"; then
1044 # now look for Tk library stuff
1055 TK_DEPS="${tkdir}${TK_LIB_FILE}"
1057 # now look for Itcl library stuff
1059 CY_AC_PATH_ITCLCONFIG
1060 if test -z "${no_itcl}"; then
1061 CY_AC_LOAD_ITCLCONFIG
1063 ITCLLIB="${ITCL_BUILD_LIB_SPEC}"
1064 ITCL_DEPS="${ITCL_LIB_FULL_PATH}"
1068 # now look for Itk library stuff
1069 CY_AC_PATH_ITKCONFIG
1070 if test -z "${no_itcl}"; then
1071 CY_AC_LOAD_ITKCONFIG
1073 ITKLIB="${ITK_BUILD_LIB_SPEC}"
1074 ITK_DEPS="${ITK_LIB_FULL_PATH}"
1077 ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1078 # Tcl/Tk 8.1 require -fwritable strings. I don't
1079 # know whether 8.2 will or not, but I bet it will.
1080 # I don't have to worry about 7.x since we don't support it.
1082 if test "$GCC" = "yes"; then
1083 if test "$TCL_VERSION" != "8.0" ; then
1084 GDBTK_CFLAGS="-fwritable-strings"
1088 # Include some libraries that Tcl and Tk want.
1089 TCL_LIBS='$(LIBGUI) $(ITCL) $(ITK) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1090 # Yes, the ordering seems wrong here. But it isn't.
1091 # TK_LIBS is the list of libraries that need to be linked
1092 # after Tcl/Tk. Note that this isn't put into LIBS. If it
1093 # were in LIBS then any link tests after this point would
1094 # try to include things like `$(LIBGUI)', which wouldn't work.
1095 GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1097 CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1098 CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1099 CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1100 CONFIG_INITS="${CONFIG_INITS} \$(SUBDIR_GDBTK_INITS)"
1101 CONFIG_ALL="${CONFIG_ALL} \$(SUBDIR_GDBTK_ALL)"
1102 CONFIG_CLEAN="${CONFIG_CLEAN} \$(SUBDIR_GDBTK_CLEAN)"
1103 CONFIG_INSTALL="${CONFIG_INSTALL} \$(SUBDIR_GDBTK_INSTALL)"
1104 CONFIG_UNINSTALL="${CONFIG_UNINSTALL} \$(SUBDIR_GDBTK_UNINSTALL)"
1106 if test x$gdb_cv_os_cygwin = xyes; then
1107 WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1108 WIN32LDAPP="-Wl,--subsystem,console"
1109 CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1114 configdirs="${configdirs} gdbtk"
1127 AC_SUBST(GDBTK_CFLAGS)
1128 AC_SUBST(GDBTK_SRC_DIR)
1133 # Unlike the sim directory, whether a simulator is linked is controlled by
1134 # presence of a SIM= and a SIM_OBS= definition in the target '.mt' file.
1135 # This code just checks for a few cases where we'd like to ignore those
1136 # definitions, even when they're present in the '.mt' file. These cases
1137 # are when --disable-sim is specified, or if the simulator directory is
1138 # not part of the source tree.
1141 [ --enable-sim Link gdb with simulator],
1142 [echo "enable_sim = $enable_sim";
1143 echo "enableval = ${enableval}";
1144 case "${enableval}" in
1145 yes) ignore_sim=false ;;
1146 no) ignore_sim=true ;;
1147 *) ignore_sim=false ;;
1151 if test ! -d "${srcdir}/../sim"; then
1155 if test "${ignore_sim}" = "true"; then
1157 IGNORE_SIM_OBS="SIM_OBS="
1163 AC_SUBST(IGNORE_SIM)
1164 AC_SUBST(IGNORE_SIM_OBS)
1166 AC_SUBST(ENABLE_CFLAGS)
1168 AC_SUBST(CONFIG_OBS)
1169 AC_SUBST(CONFIG_LIB_OBS)
1170 AC_SUBST(CONFIG_DEPS)
1171 AC_SUBST(CONFIG_SRCS)
1172 AC_SUBST(CONFIG_INITS)
1173 AC_SUBST(CONFIG_ALL)
1174 AC_SUBST(CONFIG_CLEAN)
1175 AC_SUBST(CONFIG_INSTALL)
1176 AC_SUBST(CONFIG_UNINSTALL)
1178 # target_subdir is used by the testsuite to find the target libraries.
1180 if test "${host}" != "${target}"; then
1181 target_subdir="${target_alias}/"
1183 AC_SUBST(target_subdir)
1186 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
1187 if test ! -f ${host_makefile_frag}; then
1188 # When building a native debuger the .mh file containing things
1189 # like NATDEPFILES is needed. Cross debuggers don't need .mh
1190 # since it no longer contains anything useful.
1191 if test "${target}" = "${host}"; then
1192 AC_MSG_ERROR("*** Gdb does not support native target ${host}")
1194 host_makefile_frag=/dev/null
1197 frags="$frags $host_makefile_frag"
1199 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
1200 if test ! -f ${target_makefile_frag}; then
1201 AC_MSG_ERROR("*** Gdb does not support target ${target}")
1203 frags="$frags $target_makefile_frag"
1205 AC_SUBST_FILE(host_makefile_frag)
1206 AC_SUBST_FILE(target_makefile_frag)
1211 s/XM_FILE[ ]*=[ ]*\([^ ]*\)/\1/p
1212 ' ${host_makefile_frag}`
1214 targetfile=`sed -n '
1215 s/TM_FILE[ ]*=[ ]*\([^ ]*\)/\1/p
1216 ' ${target_makefile_frag}`
1218 GDB_MULTI_ARCH=`sed -n '
1219 s/GDB_MULTI_ARCH[ ]*=[ ]*\([^ ]*\)[ ]*/\1/p
1220 ' ${target_makefile_frag}`
1222 if test "${target}" = "${host}"; then
1223 # We pick this up from the host configuration file (.mh) because we
1224 # do not have a native configuration Makefile fragment.
1225 nativefile=`sed -n '
1226 s/NAT_FILE[ ]*=[ ]*\([^ ]*\)/\1/p
1227 ' ${host_makefile_frag}`
1231 # New targets should just set gdb_multi_arch=yes in configure.tgt.
1232 # Old targets being converted can either do that or set GDB_MULTI_ARCH
1233 # in the target specific makefile frag. Eventually gdb_multi_arch=yes
1234 # will be the default.
1235 if test x"${GDB_MULTI_ARCH}" = x ; then
1236 case "${gdb_multi_arch}" in
1237 yes ) GDB_MULTI_ARCH=GDB_MULTI_ARCH_PURE ;;
1238 no ) GDB_MULTI_ARCH=0 ;;
1239 0|1|2 ) GDB_MULTI_ARCH=${gdb_multi_arch} ;;
1242 if test x"${GDB_MULTI_ARCH}" != x ; then
1243 AC_DEFINE_UNQUOTED(GDB_MULTI_ARCH, ${GDB_MULTI_ARCH})
1245 # Warn the user when they use an old practice
1246 case "${GDB_MULTI_ARCH}" in
1248 0 | GDB_MULTI_ARCH_PARTIAL | 1 | GDB_MULTI_ARCH_TM | 2 )
1249 AC_MSG_WARN("GDB: Target is not pure multi-arch") ;;
1250 GDB_MULTI_ARCH_PURE )
1251 if test x"${targetfile}" != x ; then
1252 AC_MSG_WARN("GDB: Ignoring TM_FILE in ${target_makefile_frag}")
1255 *) AC_MSG_ERROR("GDB: Unknown GDB_MULTI_ARCH value ${GDB_MULTI_ARCH}");;
1258 if test x"${gdb_osabi}" != x ; then
1259 AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
1260 [Define to the default OS ABI for this configuration.])
1263 # Enable multi-ice-gdb-server.
1264 AC_ARG_ENABLE(multi-ice,
1265 [ --enable-multi-ice build the multi-ice-gdb-server],
1269 *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
1271 if test "x$enable_multi_ice" = xyes; then
1272 configdirs="$configdirs multi-ice"
1275 # We only build gdbserver automatically if host and target are the same.
1276 if test "x$target" = "x$host"; then
1277 AC_MSG_CHECKING(whether gdbserver is supported on this host)
1278 if test "x$build_gdbserver" = xyes; then
1279 configdirs="$configdirs gdbserver"
1286 AC_CONFIG_SUBDIRS($configdirs)
1288 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
1289 # (NAT_FILE) is not set in config/*/*.m[ht] files, we link to an empty
1297 if test "${hostfile}" != ""; then
1299 GDB_XM_FILE="config/${gdb_host_cpu}/${hostfile}"
1300 files="${files} ${GDB_XM_FILE}"
1301 links="${links} xm.h"
1302 AC_DEFINE_UNQUOTED(GDB_XM_FILE, ${GDB_XM_FILE})
1308 if test "${targetfile}" != ""; then
1310 GDB_TM_FILE="config/${gdb_target_cpu}/${targetfile}"
1311 files="${files} ${GDB_TM_FILE}"
1312 links="${links} tm.h"
1313 AC_DEFINE_UNQUOTED(GDB_TM_FILE, ${GDB_TM_FILE})
1319 if test "${nativefile}" != ""; then
1321 GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}"
1322 files="${files} ${GDB_NM_FILE}"
1323 links="${links} nm.h"
1324 AC_DEFINE_UNQUOTED(GDB_NM_FILE, ${GDB_NM_FILE})
1328 AC_LINK_FILES($files, $links)
1330 dnl Check for exe extension set on certain hosts (e.g. Win32)
1333 dnl Detect the character set used by this host.
1335 dnl At the moment, we just assume it's ISO-8859-1 (which is a
1336 dnl superset of ASCII containing the characters needed for French,
1337 dnl German, Spanish, Italian, and possibly others), but if were
1338 dnl *were* to support any host character sets other than ISO-8859-1,
1339 dnl here's where we'd detect it.
1340 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "ISO-8859-1",
1341 [Define to be a string naming the default host character set.])
1345 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
1347 dnl Autoconf doesn't provide a mechanism for modifying definitions
1348 dnl provided by makefile fragments.
1350 if test "${nativefile}" = ""; then
1352 sed -e '/^NATDEPFILES[[ ]]*=.*\\$/,/[[^\\]]$/s/^/# /' \
1353 -e '/^NATDEPFILES[[ ]]*=/s/^/# /' \
1354 | sed -e '/^\(NATDEPFILES[[ ]]*[[+]]=[[ ]]*\)/s//# \1/' \
1356 mv -f Makefile.tem Makefile
1360 sed -e '/^TM_FILE[ ]*=/s,^TM_FILE[ ]*=[ ]*,&config/'"${gdb_target_cpu}"'/,
1361 /^XM_FILE[ ]*=/s,^XM_FILE[ ]*=[ ]*,&config/'"${gdb_host_cpu}"'/,
1362 /^NAT_FILE[ ]*=/s,^NAT_FILE[ ]*=[ ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
1363 mv -f Makefile.tmp Makefile
1367 case x$CONFIG_HEADERS in
1368 xconfig.h:config.in)
1373 gdb_host_cpu=$gdb_host_cpu
1374 gdb_target_cpu=$gdb_target_cpu
1375 nativefile=$nativefile