gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996, 1997, 1998 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 2 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program; if not, write to the Free Software
  18 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  19
  20 dnl Process this file with autoconf to produce a configure script.
  21
  22 AC_PREREQ(2.5)dnl
  23 AC_INIT(main.c)
  24 AC_CONFIG_HEADER(config.h:config.in)
  25
  26 AC_PROG_CC
  27 AC_AIX
  28 AC_ISC_POSIX
  29
  30 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  31 AC_CANONICAL_SYSTEM
  32
  33 dnl gdb doesn't use gettext, but bfd does.  We call this to ensure we
  34 dnl link with the correct libraries.
  35 ALL_LINGUAS=
  36 CY_GNU_GETTEXT
  37
  38 dnl List of object files added by configure.
  39
  40 CONFIG_OBS=
  41 CONFIG_DEPS=
  42 CONFIG_SRCS=
  43
  44 configdirs="doc testsuite"
  45
  46 dnl
  47 changequote(,)dnl
  48
  49 . ${srcdir}/configure.host
  50
  51 . ${srcdir}/configure.tgt
  52
  53 dnl
  54 changequote([,])dnl
  55
  56 AC_PROG_INSTALL
  57 AC_CHECK_TOOL(AR, ar)
  58 AC_CHECK_TOOL(RANLIB, ranlib, :)
  59 AC_PROG_YACC
  60
  61 AC_ARG_PROGRAM
  62
  63 AC_TYPE_SIGNAL
  64
  65 AC_HEADER_STDC
  66 AC_CHECK_HEADERS(ctype.h curses.h endian.h libintl.h link.h \
  67                  memory.h objlist.h ptrace.h sgtty.h stddef.h stdlib.h \
  68                  string.h sys/procfs.h sys/ptrace.h sys/reg.h \
  69                  term.h termio.h termios.h unistd.h wait.h sys/wait.h \
  70                  wchar.h wctype.h asm/debugreg.h)
  71
  72 AC_HEADER_STAT
  73
  74 AC_C_CONST
  75
  76 AC_CHECK_FUNCS(setpgid sbrk sigaction isascii bzero bcopy btowc)
  77 AC_FUNC_ALLOCA
  78
  79 BFD_NEED_DECLARATION(malloc)
  80 BFD_NEED_DECLARATION(realloc)
  81 BFD_NEED_DECLARATION(free)
  82 BFD_NEED_DECLARATION(strerror)
  83 BFD_NEED_DECLARATION(strdup)
  84
  85 # If we are configured native on GNU/Linux, work around problems with sys/procfs.h
  86 if test "${target}" = "${host}"; then
  87   case "${host}" in
  88   i[[3456]]86-*-linux*)
  89         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
  90         AC_DEFINE(sys_quotactl)
  91         ;;
  92   esac
  93 fi
  94
  95 AC_MSG_CHECKING([for gregset_t type])
  96 AC_CACHE_VAL(gdb_cv_have_gregset_t,
  97 [AC_TRY_LINK([#include <sys/procfs.h>],[gregset_t *gregsetp = 0],
  98 gdb_cv_have_gregset_t=yes, gdb_cv_have_gregset_t=no)])
  99 AC_MSG_RESULT($gdb_cv_have_gregset_t)
 100 if test $gdb_cv_have_gregset_t = yes; then
 101   AC_DEFINE(HAVE_GREGSET_T)
 102 fi
 103
 104 AC_MSG_CHECKING([for fpregset_t type])
 105 AC_CACHE_VAL(gdb_cv_have_fpregset_t,
 106 [AC_TRY_LINK([#include <sys/procfs.h>],[fpregset_t *fpregsetp = 0],
 107 gdb_cv_have_fpregset_t=yes, gdb_cv_have_fpregset_t=no)])
 108 AC_MSG_RESULT($gdb_cv_have_fpregset_t)
 109 if test $gdb_cv_have_fpregset_t = yes; then
 110   AC_DEFINE(HAVE_FPREGSET_T)
 111 fi
 112
 113 dnl See if host has libm.  This is usually needed by simulators.
 114 AC_CHECK_LIB(m, main)
 115
 116 dnl See if compiler supports "long long" type.
 117
 118 AC_MSG_CHECKING(for long long support in compiler)
 119 AC_CACHE_VAL(gdb_cv_c_long_long,
 120 [AC_TRY_COMPILE(, [
 121   extern long long foo;
 122   switch (foo & 2) { case 0: return 1; }
 123 ],
 124 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
 125 AC_MSG_RESULT($gdb_cv_c_long_long)
 126 if test $gdb_cv_c_long_long = yes; then
 127   AC_DEFINE(CC_HAS_LONG_LONG)
 128 fi
 129
 130 dnl See if the compiler and runtime support printing long long
 131
 132 AC_MSG_CHECKING(for long long support in printf)
 133 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 134 [AC_TRY_RUN([
 135 int main () {
 136   char buf[32];
 137   long long l = 0;
 138   l = (l << 16) + 0x0123;
 139   l = (l << 16) + 0x4567;
 140   l = (l << 16) + 0x89ab;
 141   l = (l << 16) + 0xcdef;
 142   sprintf (buf, "0x%016llx", l);
 143   return (strcmp ("0x0123456789abcdef", buf));
 144 }],
 145 gdb_cv_printf_has_long_long=yes,
 146 gdb_cv_printf_has_long_long=no,
 147 gdb_cv_printf_has_long_long=no)])
 148 if test $gdb_cv_printf_has_long_long = yes; then
 149   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 150 fi
 151 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 152
 153 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 154 dnl because autoconf complains about cross-compilation issues.  However, this
 155 dnl code uses the same variables as the macro for compatibility.
 156
 157 AC_MSG_CHECKING(for long double support in compiler)
 158 AC_CACHE_VAL(ac_cv_c_long_double,
 159 [AC_TRY_COMPILE(, [long double foo;],
 160 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 161 AC_MSG_RESULT($ac_cv_c_long_double)
 162 if test $ac_cv_c_long_double = yes; then
 163   AC_DEFINE(HAVE_LONG_DOUBLE)
 164 fi
 165
 166 dnl See if the compiler and runtime support printing long doubles
 167
 168 AC_MSG_CHECKING(for long double support in printf)
 169 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 170 [AC_TRY_RUN([
 171 int main () {
 172   char buf[16];
 173   long double f = 3.141592653;
 174   sprintf (buf, "%Lg", f);
 175   return (strncmp ("3.14159", buf, 7));
 176 }],
 177 gdb_cv_printf_has_long_double=yes,
 178 gdb_cv_printf_has_long_double=no,
 179 gdb_cv_printf_has_long_double=no)])
 180 if test $gdb_cv_printf_has_long_double = yes; then
 181   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 182 fi
 183 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 184
 185 dnl See if the compiler and runtime support scanning long doubles
 186
 187 AC_MSG_CHECKING(for long double support in scanf)
 188 AC_CACHE_VAL(gdb_cv_scanf_has_long_double,
 189 [AC_TRY_RUN([
 190 int main () {
 191   char *buf = "3.141592653";
 192   long double f = 0;
 193   sscanf (buf, "%Lg", &f);
 194   return !(f > 3.14159 && f < 3.14160);
 195 }],
 196 gdb_cv_scanf_has_long_double=yes,
 197 gdb_cv_scanf_has_long_double=no,
 198 gdb_cv_scanf_has_long_double=no)])
 199 if test $gdb_cv_scanf_has_long_double = yes; then
 200   AC_DEFINE(SCANF_HAS_LONG_DOUBLE)
 201 fi
 202 AC_MSG_RESULT($gdb_cv_scanf_has_long_double)
 203
 204 AC_FUNC_MMAP
 205
 206 dnl See if thread_db library is around for Solaris thread debugging.  Note that
 207 dnl we must explicitly test for version 1 of the library because version 0
 208 dnl (present on Solaris 2.4 or earlier) doesn't have the same API.
 209
 210 dnl Note that we only want this if we are both native (host == target), and
 211 dnl not doing a canadian cross build (build == host).
 212
 213 if test ${build} = ${host} -a ${host} = ${target} ; then
 214    case ${host_os} in
 215    hpux*)
 216       AC_MSG_CHECKING(for HPUX/OSF thread support)
 217       if test -f /usr/include/dce/cma_config.h ; then
 218          if test "$GCC" = "yes" ; then
 219             AC_MSG_RESULT(yes)
 220             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 221             CONFIG_OBS="${CONFIG_OJS} hpux-thread.o"
 222             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
 223          else
 224             AC_MSG_RESULT(no (suppressed because you are not using GCC))
 225          fi
 226       else
 227          AC_MSG_RESULT(no)
 228       fi
 229       ;;
 230    solaris*)
 231       AC_MSG_CHECKING(for Solaris thread debugging library)
 232       if test -f /usr/lib/libthread_db.so.1 ; then
 233          AC_MSG_RESULT(yes)
 234          AC_DEFINE(HAVE_THREAD_DB_LIB)
 235          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
 236          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
 237          AC_CHECK_LIB(dl, dlopen)
 238          if test "$GCC" = "yes" ; then
 239             # The GNU linker requires the -export-dynamic option to make
 240             # all symbols visible in the dynamic symbol table.
 241             hold_ldflags=$LDFLAGS
 242             AC_MSG_CHECKING(for the ld -export-dynamic flag)
 243             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
 244             AC_TRY_LINK(, [int i;], found=yes, found=no)
 245             LDFLAGS=$hold_ldflags
 246             AC_MSG_RESULT($found)
 247             if test $found = yes; then
 248                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
 249             fi
 250          fi
 251       else
 252          AC_MSG_RESULT(no)
 253       fi
 254       ;;
 255    esac
 256    AC_SUBST(CONFIG_LDFLAGS)
 257 fi
 258
 259 dnl Handle optional features that can be enabled.
 260 ENABLE_CFLAGS=
 261
 262 AC_ARG_ENABLE(netrom,
 263 [  --enable-netrom ],
 264 [case "${enableval}" in
 265 yes)    enable_netrom=yes ;;
 266 no)     enable_netrom=no ;;
 267 *)      AC_MSG_ERROR(bad value ${enableval} given for netrom option) ;;
 268 esac])
 269
 270 if test "${enable_netrom}" = "yes"; then
 271         CONFIG_OBS="${CONFIG_OBS} remote-nrom.o"
 272         CONFIG_SRCS="${CONFIG_SRCS} remote-nrom.c"
 273 fi
 274
 275 AC_ARG_ENABLE(warnings,
 276 [  --enable-build-warnings Enable compiler warnings if gcc is used],
 277 [case "${enableval}" in
 278 yes)    enable_build_warnings=yes ;;
 279 no)     enable_build_warnings=no ;;
 280 *)      AC_MSG_ERROR(bad value ${enableval} given for warnings options) ;;
 281 esac])
 282
 283 if test "x$enable_build_warnings" = xyes -a "x$GCC" = xyes
 284 then
 285    WARN_CFLAGS="-Wall -Wstrict-prototypes -Wmissing-prototypes"
 286 else
 287    WARN_CFLAGS=""
 288 fi
 289 AC_SUBST(WARN_CFLAGS)
 290
 291 MMALLOC_CFLAGS=
 292 MMALLOC=
 293 AC_SUBST(MMALLOC_CFLAGS)
 294 AC_SUBST(MMALLOC)
 295
 296 AC_ARG_WITH(mmalloc,
 297 [  --with-mmalloc          Use memory mapped malloc package],
 298 [case "${withval}" in
 299   yes)  want_mmalloc=true ;;
 300   no)   want_mmalloc=false;;
 301   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-mmalloc option) ;;
 302 esac],[want_mmalloc=false])dnl
 303
 304 if test x$want_mmalloc = xtrue; then
 305    AC_DEFINE(USE_MMALLOC)
 306    AC_DEFINE(MMCHECK_FORCE)
 307    MMALLOC_CFLAGS="-I$srcdir/../mmalloc"
 308    MMALLOC='../mmalloc/libmmalloc.a'
 309 fi
 310
 311 # start-sanitize-carp
 312 # The below takes an educated guess at the targets that
 313 # should be built.  It is an interum version that provides
 314 # significant backward compatibility.
 315
 316 AC_ARG_ENABLE(carp,
 317 [  --enable-carp        Configure alternative readaptive paradigm ],
 318 [case "${enableval}" in
 319   yes) enable_carp=yes ;;
 320   no)  enable_carp=no ;;
 321   *)   AC_MSG_ERROR([bad value ${enableval} for carp option]) ;;
 322 esac],[enable_carp=no])dnl
 323
 324 AC_ARG_ENABLE(targets,
 325 [  --enable-targets        alternative target configurations],
 326 [case "${enableval}" in
 327   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 328             ;;
 329   no)       enable_targets= ;;
 330   *)        enable_targets="$enableval" ;;
 331 esac])dnl
 332
 333 # Canonicalize the secondary target names.
 334 all_targets=false
 335 if test -n "$enable_targets" ; then
 336     if test "$enable_targets" = all ; then
 337         all_targets=true
 338     else
 339         for targ in `echo $enable_targets | sed 's/,/ /g'`
 340         do
 341             result=`${CONFIG_SHELL-/bin/sh} $ac_config_sub $targ 2>/dev/null`
 342             if test -n "$result" ; then
 343                 canon_targets="$canon_targets $result"
 344             fi
 345         done
 346     fi
 347 fi
 348
 349 # Convert the target names into GDB [*]-tdep.c names
 350 changequote(,)dnl
 351 selarchs=
 352 for targ in $target $canon_targets
 353 do
 354     if test "x$targ" = "xall" ; then
 355         all_targets=true
 356     else
 357         t_cpu=`echo $targ    | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/\1/'`
 358         t_vendor=`echo $targ | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/\2/'`
 359         t_os=`echo $targ     | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/\3/'`
 360         mt=`
 361 target=$targ
 362 target_cpu=$t_cpu
 363 target_vendor=$t_vendor
 364 target_os=$t_os
 365 . ${srcdir}/configure.tgt
 366 echo ${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt`
 367         if test -r ${mt} ; then
 368             # This gets confused over .mt files that have multiple -tdep.o
 369             tdep=`sed -n '
 370 s/^.*[  =]\([^  ]*\)-tdep.o.*/\1/p
 371 ' $mt`
 372             selarchs="$selarchs $tdep"
 373         fi
 374     fi
 375 done
 376 changequote([,])dnl
 377
 378 # We don't do any links based on the target system, just makefile config.
 379
 380 if test x${all_targets} = xfalse ; then
 381
 382     # Target architecture .o files.
 383     ta=
 384
 385     for arch in $selarchs
 386     do
 387         archdefs="$archdefs -DARCH_$arch"
 388         ta="$ta ${arch}-tdep.o"
 389         # Special cases
 390         case "$arch" in
 391             dvp)  ta="$ta mips-tdep.o dvp-tdep.o" ;;
 392         esac
 393     done
 394
 395     # Weed out duplicate .o files.
 396     f=""
 397     for i in $ta ; do
 398         case " $f " in
 399             *" $i "*) ;;
 400             *) f="$f $i" ;;
 401         esac
 402     done
 403     ta="$f"
 404
 405     # And duplicate -D flags.
 406     f=""
 407     for i in $archdefs ; do
 408         case " $f " in
 409             *" $i "*) ;;
 410             *) f="$f $i" ;;
 411         esac
 412     done
 413     archdefs="$f"
 414
 415     MACHINE_OBS="$ta"
 416
 417 else    # all_targets is true
 418     archdefs=-DARCH_all
 419     MACHINE_OBS='$(ALL_MACHINES)'
 420 fi
 421
 422 dnl Don't define an archdefs list
 423 dnl AC_SUBST(archdefs)
 424 dnl XXXX this name will change several more times
 425 if test "${enable_carp}" = yes ; then
 426     gdb_target=carp
 427     gdb_target_cpu=carp
 428 else
 429     MACHINE_OBS="# $MACHINE_OBS"
 430 fi
 431 AC_SUBST(MACHINE_OBS)
 432
 433 # end-sanitize-carp
 434 # start-sanitize-gdbtk
 435 # start-sanitize-ide
 436 ENABLE_IDE=
 437 AC_ARG_ENABLE(ide, [  --enable-ide            Enable IDE support])
 438 if test "$enable_ide" = yes; then
 439    enable_ide=yes
 440    ENABLE_IDE=1
 441 else
 442    enable_ide=no
 443 fi
 444 AC_SUBST(ENABLE_IDE)
 445
 446 AC_ARG_WITH(foundry-libs,
 447 [  --with-foundry-libs=DIR Use the Foundry SDK in DIR],
 448 [FOUNDRY_LIB_BASE=${withval}])
 449 AC_SUBST(FOUNDRY_LIB_BASE)
 450
 451 #
 452 # This is the Foundry SDK
 453 #
 454 # These variables are used to determine where the Foundry libs and
 455 # header files are located.
 456 #
 457 if test "$FOUNDRY_LIB_BASE" != ""; then
 458     LIBGUI="${FOUNDRY_LIB_BASE}/lib/libgui.a"
 459     GUI_CFLAGS_X="-I${FOUNDRY_LIB_BASE}/include"
 460     if test x$enable_ide = xyes; then
 461         IDE_CFLAGS_X="-I${FOUNDRY_LIB_BASE}/include -DIDE"
 462         IDE_X="-L${FOUNDRY_LIB_BASE}/lib -lilu-Tk -lilu-c -lilu"
 463     else
 464         IDE_CFLAGS_X="-I${FOUNDRY_LIB_BASE}/include"
 465     fi
 466     LIBIDETCL="${FOUNDRY_LIB_BASE}/lib/libidetcl.a"
 467     LIBIDE="${FOUNDRY_LIB_BASE}/lib/libide.a"
 468     IDE_DEPS="${FOUNDRY_LIB_BASE}/lib/libilu-Tk.a ${FOUNDRY_LIB_BASE}/lib/libilu-c.a ${FOUNDRY_LIB_BASE}/lib/libilu.a"
 469 else
 470     LIBGUI="../libgui/src/libgui.a"
 471     GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
 472     if test x$enable_ide = xyes; then
 473         IDE_CFLAGS_X="-I${srcdir}/../libidetcl/src -I${srcdir}/../libide/src -DIDE -I${srcdir}/../ilu/runtime/mainloop"
 474         IDE_X="-L../ilu/runtime/mainloop -lilu-Tk -L../ilu/runtime/c -lilu-c -L../ilu/runtime/kernel -lilu"
 475     else
 476         IDE_CFLAGS_X="-I${srcdir}/../libidetcl/src -I${srcdir}/../libide/src"
 477     fi
 478     LIBIDETCL="../libidetcl/src/libidetcl.a"
 479     LIBIDE="../libide/src/libide.a"
 480     IDE_DEPS="../ilu/runtime/mainloop/libilu-Tk.a ../ilu/runtime/c/libilu-c.a ../ilu/runtime/kernel/libilu.a"
 481 fi
 482 AC_SUBST(LIBGUI)
 483 AC_SUBST(GUI_CFLAGS_X)
 484 AC_SUBST(IDE_CFLAGS_X)
 485 AC_SUBST(IDE_X)
 486 AC_SUBST(LIBIDETCL)
 487 AC_SUBST(LIBIDE)
 488 AC_SUBST(IDE_DEPS)
 489 # end-sanitize-ide
 490
 491 ENABLE_GDBTK=
 492
 493 AC_ARG_ENABLE(gdbtk,
 494 [  --enable-gdbtk          Enable GDBTK GUI front end],
 495 [case "${enableval}" in
 496     yes)
 497         case "$host" in
 498         *go32*)
 499             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 500             enable_gdbtk=no ;;
 501         *windows*)
 502             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 503             enable_gdbtk=no ;;
 504         *)
 505             enable_gdbtk=yes ;;
 506         esac ;;
 507     no)
 508         enable_gdbtk=no  ;;
 509     *)
 510         AC_MSG_ERROR(bad value ${enableval} given for gdbtk option) ;;
 511 esac],
 512 [
 513 # Default is on for everything but go32 and cygwin32
 514 case "$host" in
 515     *go32* | *windows*)
 516         ;;
 517     *)
 518         enable_gdbtk=yes ;;
 519     esac
 520 ])
 521
 522 # In the cygwin32 environment, we need some additional flags.
 523 AC_CACHE_CHECK([for cygwin32], gdb_cv_os_cygwin32,
 524 [AC_EGREP_CPP(lose, [
 525 #ifdef __CYGWIN32__
 526 lose
 527 #endif],[gdb_cv_os_cygwin32=yes],[gdb_cv_os_cygwin32=no])])
 528
 529 WIN32LIBS=
 530 WIN32LDAPP=
 531 AC_SUBST(WIN32LIBS)
 532 AC_SUBST(WIN32LDAPP)
 533
 534 DLLTOOL=${DLLTOOL-dlltool}
 535 WINDRES=${WINDRES-windres}
 536 AC_SUBST(DLLTOOL)
 537 AC_SUBST(WINDRES)
 538
 539 if test x$gdb_cv_os_cygwin32 = xyes; then
 540     if test x$enable_ide = xyes; then
 541         WIN32LIBS="-ladvapi32"
 542     fi
 543 fi
 544
 545 configdir="unix"
 546
 547 GDBTKLIBS=
 548 if test "${enable_gdbtk}" = "yes"; then
 549
 550     CY_AC_PATH_TCLCONFIG
 551     if test -z "${no_tcl}"; then
 552         CY_AC_LOAD_TCLCONFIG
 553         CY_AC_PATH_TKCONFIG
 554
 555         # If $no_tk is nonempty, then we can't do Tk, and there is no
 556         # point to doing Tcl.
 557         if test -z "${no_tk}"; then
 558            CY_AC_LOAD_TKCONFIG
 559            CY_AC_PATH_TCLH
 560            CY_AC_PATH_TKH
 561            CY_AC_PATH_ITCLH
 562            CY_AC_PATH_TIX
 563
 564            # now look for tix library stuff
 565            TIXVERSION=4.1.8.0
 566            . ${ac_cv_c_tclconfig}/tclConfig.sh
 567            case "${host}" in
 568            *-*-cygwin32*)
 569                 tixdir=../tix/win/tcl8.0
 570                 ;;
 571            *)
 572                 tixdir=../tix/unix/tk8.0
 573                 ;;
 574            esac
 575            if test "${TCL_SHARED_BUILD}" = "1"; then
 576                 TIX_LIB_EXT="${TCL_SHLIB_SUFFIX}"
 577
 578                 # Can't win them all: SunOS 4 (others?) appends a version
 579                 # number after the ".so"
 580                 case "${host}" in
 581                 *-*-sunos4*)
 582                     TIX_LIB_EXT="${TIX_LIB_EXT}.1.0" ;;
 583                 esac
 584
 585            else
 586                 TIX_LIB_EXT=".a"
 587            fi
 588
 589            if test "${TCL_LIB_VERSIONS_OK}" = "ok"; then
 590                 TIXLIB="-L${tixdir} -ltix${TIXVERSION}"
 591                 TIX_DEPS="${tixdir}/libtix${TIXVERSION}${TIX_LIB_EXT}"
 592            else
 593                 TIXLIB="-L${tixdir} -ltix`echo ${TIXVERSION} | tr -d .`"
 594                 TIX_DEPS="${tixdir}/libtix`echo ${TIXVERSION} | tr -d .`${TIX_LIB_EXT}"
 595            fi
 596
 597            ENABLE_GDBTK=1
 598            ENABLE_CFLAGS="${ENABLE_CFLAGS} -DGDBTK"
 599
 600            # Include some libraries that Tcl and Tk want.
 601            if test "${enable_ide}" = "yes"; then
 602               TCL_LIBS='$(LIBIDETCL) $(LIBIDE) $(LIBGUI) $(IDE) $(ITCL) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 603               CONFIG_DEPS='$(LIBIDETCL) $(LIBIDE) $(LIBGUI) $(IDE_DEPS) $(ITCL_DEPS) $(TIX_DEPS) $(TK_DEPS) $(TCL_DEPS)'
 604            else
 605               TCL_LIBS='$(LIBGUI) $(ITCL) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 606               CONFIG_DEPS='$(LIBGUI) $(ITCL_DEPS) $(TIX_DEPS) $(TK_DEPS) $(TCL_DEPS)'
 607            fi
 608            # Yes, the ordering seems wrong here.  But it isn't.
 609            # TK_LIBS is the list of libraries that need to be linked
 610            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
 611            # were in LIBS then any link tests after this point would
 612            # try to include things like `$(LIBGUI)', which wouldn't work.
 613            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
 614            CONFIG_OBS="${CONFIG_OBS} gdbtk.o gdbtk-cmds.o gdbtk-hooks.o"
 615
 616            if test x$gdb_cv_os_cygwin32 = xyes; then
 617               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32 -luser32"
 618               WIN32LDAPP="-Wl,--subsystem,console"
 619               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
 620            fi
 621         fi
 622     fi
 623 fi
 624
 625 AC_SUBST(ENABLE_GDBTK)
 626 AC_SUBST(X_CFLAGS)
 627 AC_SUBST(X_LDFLAGS)
 628 AC_SUBST(X_LIBS)
 629 AC_SUBST(TIXLIB)
 630 AC_SUBST(TIX_DEPS)
 631 AC_SUBST(GDBTKLIBS)
 632 # end-sanitize-gdbtk
 633
 634 AC_PATH_X
 635 # start-sanitize-sky
 636 # Enable GPU2 library for MIPS simulator
 637 AC_ARG_WITH(sim-gpu2,
 638 [  --with-sim-gpu2=DIR     Use GPU2 library under given DIR],
 639 [case "${target}" in
 640   mips*-sky-*)
 641     if test -d "${withval}"
 642     then
 643       LIBS="${LIBS} -L${withval}/lib -lgpu2 -L${x_libraries} -lX11 -lXext"
 644     else
 645       AC_MSG_WARN([Directory ${withval} does not exist.])
 646     fi ;;
 647   *)  AC_MSG_WARN([--with-sim-gpu2 option invalid for target ${target}])
 648 esac])dnl
 649
 650 # Enable target accurate FP library
 651 AC_ARG_WITH(sim-funit,
 652 [  --with-sim-funit=DIR    Use target FP lib under given DIR],
 653 [case "${target}" in
 654   mips*-sky-*)
 655     if test -d "${withval}"
 656     then
 657       LIBS="${LIBS} -L${withval}/lib -lfunit"
 658     else
 659       AC_MSG_WARN([Directory ${withval} does not exist.])
 660     fi ;;
 661   *)  AC_MSG_WARN([--with-sim-funit option invalid for target ${target}])
 662 esac])dnl
 663 # end-sanitize-sky
 664
 665 dnl Solaris puts wctype in /usr/lib/libw.a
 666 AC_CHECK_LIB(w, wctype, [LIBS="$LIBS -lw"])
 667
 668 AC_SUBST(ENABLE_CFLAGS)
 669
 670 AC_SUBST(CONFIG_OBS)
 671 AC_SUBST(CONFIG_DEPS)
 672 AC_SUBST(CONFIG_SRCS)
 673
 674 # Begin stuff to support --enable-shared
 675 AC_ARG_ENABLE(shared,
 676 [  --enable-shared         Use shared libraries],
 677 [case "${enableval}" in
 678   yes) shared=true ;;
 679   no)  shared=false ;;
 680   *) shared=true ;;
 681 esac])dnl
 682
 683 HLDFLAGS=
 684 HLDENV=
 685 # If we have shared libraries, try to set rpath reasonably.
 686 if test "${shared}" = "true"; then
 687   case "${host}" in
 688   *-*-hpux*)
 689     HLDFLAGS='-Wl,+s,+b,$(libdir)'
 690     ;;
 691   *-*-irix5* | *-*-irix6*)
 692     HLDFLAGS='-Wl,-rpath,$(libdir)'
 693     ;;
 694   *-*-linux*aout*)
 695     ;;
 696   *-*-linux* | *-pc-linux-gnu)
 697     HLDFLAGS='-Wl,-rpath,$(libdir)'
 698     ;;
 699   *-*-solaris*)
 700     HLDFLAGS='-R $(libdir)'
 701     ;;
 702   *-*-sysv4*)
 703     HLDENV='if test -z "$${LD_RUN_PATH}"; then LD_RUN_PATH=$(libdir); else LD_RUN_PATH=$${LD_RUN_PATH}:$(libdir); fi; export LD_RUN_PATH;'
 704     ;;
 705   esac
 706 fi
 707
 708 # On SunOS, if the linker supports the -rpath option, use it to
 709 # prevent ../bfd and ../opcodes from being included in the run time
 710 # search path.
 711 case "${host}" in
 712   *-*-sunos*)
 713     echo 'main () { }' > conftest.c
 714     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
 715     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
 716       :
 717     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
 718       :
 719     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
 720       :
 721     elif grep 'some text already loaded' conftest.t >/dev/null 2>&1; then
 722       :
 723     elif test "${shared}" = "true"; then
 724       HLDFLAGS='-Wl,-rpath=$(libdir)'
 725     else
 726       HLDFLAGS='-Wl,-rpath='
 727     fi
 728     rm -f conftest.t conftest.c conftest
 729     ;;
 730 esac
 731 AC_SUBST(HLDFLAGS)
 732 AC_SUBST(HLDENV)
 733 # End stuff to support --enable-shared
 734
 735 # target_subdir is used by the testsuite to find the target libraries.
 736 target_subdir=
 737 if test "${host}" != "${target}"; then
 738     target_subdir="${target_alias}/"
 739 fi
 740 AC_SUBST(target_subdir)
 741
 742 frags=
 743 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
 744 if test ! -f ${host_makefile_frag}; then
 745 AC_MSG_ERROR("*** Gdb does not support host ${host}")
 746 fi
 747 frags="$frags $host_makefile_frag"
 748
 749 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
 750 if test ! -f ${target_makefile_frag}; then
 751 AC_MSG_ERROR("*** Gdb does not support target ${target}")
 752 fi
 753 frags="$frags $target_makefile_frag"
 754
 755 AC_SUBST_FILE(host_makefile_frag)
 756 AC_SUBST_FILE(target_makefile_frag)
 757 AC_SUBST(frags)
 758
 759 changequote(,)dnl
 760 hostfile=`sed -n '
 761 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 762 ' ${host_makefile_frag}`
 763
 764 targetfile=`sed -n '
 765 s/TM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 766 ' ${target_makefile_frag}`
 767
 768 # these really aren't orthogonal true/false values of the same condition,
 769 # but shells are slow enough that I like to reuse the test conditions
 770 # whenever possible
 771 if test "${target}" = "${host}"; then
 772 nativefile=`sed -n '
 773 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
 774 ' ${host_makefile_frag}`
 775 # else
 776 # GDBserver is only useful in a "native" enviroment
 777 # configdirs=`echo $configdirs | sed 's/gdbserver//'`
 778 fi
 779 changequote([,])
 780
 781 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
 782 # (NAT_FILE) is not set in config/*/*.m[ht] files, we don't make the
 783 # corresponding links.  But we have to remove the xm.h files and tm.h
 784 # files anyway, e.g. when switching from "configure host" to
 785 # "configure none".
 786
 787 files=
 788 links=
 789 rm -f xm.h
 790 if test "${hostfile}" != ""; then
 791 files="${files} config/${gdb_host_cpu}/${hostfile}"
 792 links="${links} xm.h"
 793 fi
 794 rm -f tm.h
 795 if test "${targetfile}" != ""; then
 796 files="${files} config/${gdb_target_cpu}/${targetfile}"
 797 links="${links} tm.h"
 798 fi
 799 rm -f nm.h
 800 if test "${nativefile}" != ""; then
 801 files="${files} config/${gdb_host_cpu}/${nativefile}"
 802 links="${links} nm.h"
 803 else
 804 # A cross-only configuration.
 805 files="${files} config/nm-empty.h"
 806 links="${links} nm.h"
 807 fi
 808 # start-sanitize-gdbtk
 809 AC_PROG_LN_S
 810 # Make it possible to use the GUI without doing a full install
 811 if test "${enable_gdbtk}" = "yes" -a ! -d gdbtcl2 ; then
 812   if test "$LN_S" = "ln -s" -a ! -f gdbtcl2 ; then
 813   echo linking $srcdir/gdbtcl2 to gdbtcl2
 814   $LN_S $srcdir/gdbtcl2 gdbtcl2
 815   else
 816   echo Warning: Unable to link $srcdir/gdbtcl2 to gdbtcl2.  You will need to do a
 817   echo "         " make install before you are able to run the GUI.
 818   fi
 819 fi
 820 # end-sanitize-gdbtk
 821
 822 AC_LINK_FILES($files, $links)
 823
 824 dnl Check for exe extension set on certain hosts (e.g. Win32)
 825 AM_EXEEXT
 826
 827 AC_CONFIG_SUBDIRS($configdirs)
 828 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
 829 [
 830 dnl Autoconf doesn't provide a mechanism for modifying definitions
 831 dnl provided by makefile fragments.
 832 dnl
 833 if test "${nativefile}" = ""; then
 834 sed -e '/^NATDEPFILES[[         ]]*=[[  ]]*/s//# NATDEPFILES=/' \
 835         < Makefile > Makefile.tem
 836 mv -f Makefile.tem Makefile
 837 fi
 838
 839 changequote(,)dnl
 840 sed -e '/^TM_FILE[      ]*=/s,^TM_FILE[         ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
 841 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
 842 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
 843 mv -f Makefile.tmp Makefile
 844 changequote([,])dnl
 845
 846 case x$CONFIG_HEADERS in
 847 xconfig.h:config.in)
 848 echo > stamp-h ;;
 849 esac
 850 ],
 851 [
 852 gdb_host_cpu=$gdb_host_cpu
 853 gdb_target_cpu=$gdb_target_cpu
 854 nativefile=$nativefile
 855 ])
 856
 857 exit 0