gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 2 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program; if not, write to the Free Software
  18 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  19
  20 dnl Process this file with autoconf to produce a configure script.
  21
  22 AC_PREREQ(2.5)dnl
  23 AC_INIT(main.c)
  24 AC_CONFIG_HEADER(config.h:config.in)
  25
  26 AC_PROG_CC
  27 AC_AIX
  28 AC_MINIX
  29 AC_ISC_POSIX
  30
  31 DLLTOOL=${DLLTOOL-dlltool}
  32 AC_SUBST(DLLTOOL)
  33
  34 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  35 AC_CANONICAL_SYSTEM
  36
  37 dnl gdb doesn't use gettext, but bfd does.  We call this to ensure we
  38 dnl link with the correct libraries.
  39 ALL_LINGUAS=
  40 CY_GNU_GETTEXT
  41
  42 dnl List of object files added by configure.
  43
  44 CONFIG_OBS=
  45 CONFIG_DEPS=
  46 CONFIG_SRCS=
  47
  48 configdirs="doc testsuite"
  49
  50 dnl
  51 changequote(,)dnl
  52
  53 . ${srcdir}/configure.host
  54
  55 . ${srcdir}/configure.tgt
  56
  57 dnl
  58 changequote([,])dnl
  59
  60 AC_PROG_INSTALL
  61 AC_CHECK_TOOL(AR, ar)
  62 AC_CHECK_TOOL(RANLIB, ranlib, :)
  63 AC_PROG_YACC
  64 AC_PROG_AWK
  65
  66 AC_ARG_PROGRAM
  67
  68 AC_TYPE_SIGNAL
  69
  70 AC_HEADER_STDC
  71 AC_CHECK_HEADERS(ctype.h curses.h endian.h libintl.h limits.h link.h \
  72                  memory.h objlist.h ptrace.h sgtty.h stddef.h stdlib.h \
  73                  string.h strings.h sys/procfs.h sys/ptrace.h sys/reg.h \
  74                  term.h termio.h termios.h unistd.h wait.h sys/wait.h \
  75                  wchar.h wctype.h)
  76
  77 AC_HEADER_STAT
  78
  79 AC_C_CONST
  80
  81 AC_CHECK_FUNCS(setpgid sbrk select poll sigaction isascii bzero bcopy memcpy btowc)
  82 AC_FUNC_ALLOCA
  83
  84 # If we are configured native on GNU/Linux, work around problems with sys/procfs.h
  85 if test "${target}" = "${host}"; then
  86   case "${host}" in
  87   i[[3456]]86-*-linux*)
  88         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
  89         AC_DEFINE(sys_quotactl)
  90         ;;
  91   esac
  92 fi
  93
  94 AC_MSG_CHECKING([for gregset_t type])
  95 AC_CACHE_VAL(gdb_cv_have_gregset_t,
  96 [AC_TRY_LINK([#include <sys/procfs.h>],[gregset_t *gregsetp = 0],
  97 gdb_cv_have_gregset_t=yes, gdb_cv_have_gregset_t=no)])
  98 AC_MSG_RESULT($gdb_cv_have_gregset_t)
  99 if test $gdb_cv_have_gregset_t = yes; then
 100   AC_DEFINE(HAVE_GREGSET_T)
 101 fi
 102
 103 AC_MSG_CHECKING([for fpregset_t type])
 104 AC_CACHE_VAL(gdb_cv_have_fpregset_t,
 105 [AC_TRY_LINK([#include <sys/procfs.h>],[fpregset_t *fpregsetp = 0],
 106 gdb_cv_have_fpregset_t=yes, gdb_cv_have_fpregset_t=no)])
 107 AC_MSG_RESULT($gdb_cv_have_fpregset_t)
 108 if test $gdb_cv_have_fpregset_t = yes; then
 109   AC_DEFINE(HAVE_FPREGSET_T)
 110 fi
 111
 112 dnl See if host has libm.  This is usually needed by simulators.
 113 AC_CHECK_LIB(m, main)
 114
 115 dnl See if compiler supports "long long" type.
 116
 117 AC_MSG_CHECKING(for long long support in compiler)
 118 AC_CACHE_VAL(gdb_cv_c_long_long,
 119 [AC_TRY_COMPILE(, [
 120   extern long long foo;
 121   switch (foo & 2) { case 0: return 1; }
 122 ],
 123 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
 124 AC_MSG_RESULT($gdb_cv_c_long_long)
 125 if test $gdb_cv_c_long_long = yes; then
 126   AC_DEFINE(CC_HAS_LONG_LONG)
 127 fi
 128
 129 dnl See if the compiler and runtime support printing long long
 130
 131 AC_MSG_CHECKING(for long long support in printf)
 132 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 133 [AC_TRY_RUN([
 134 int main () {
 135   char buf[32];
 136   long long l = 0;
 137   l = (l << 16) + 0x0123;
 138   l = (l << 16) + 0x4567;
 139   l = (l << 16) + 0x89ab;
 140   l = (l << 16) + 0xcdef;
 141   sprintf (buf, "0x%016llx", l);
 142   return (strcmp ("0x0123456789abcdef", buf));
 143 }],
 144 gdb_cv_printf_has_long_long=yes,
 145 gdb_cv_printf_has_long_long=no,
 146 gdb_cv_printf_has_long_long=no)])
 147 if test $gdb_cv_printf_has_long_long = yes; then
 148   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 149 fi
 150 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 151
 152 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 153 dnl because autoconf complains about cross-compilation issues.  However, this
 154 dnl code uses the same variables as the macro for compatibility.
 155
 156 AC_MSG_CHECKING(for long double support in compiler)
 157 AC_CACHE_VAL(ac_cv_c_long_double,
 158 [AC_TRY_COMPILE(, [long double foo;],
 159 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 160 AC_MSG_RESULT($ac_cv_c_long_double)
 161 if test $ac_cv_c_long_double = yes; then
 162   AC_DEFINE(HAVE_LONG_DOUBLE)
 163 fi
 164
 165 dnl See if the compiler and runtime support printing long doubles
 166
 167 AC_MSG_CHECKING(for long double support in printf)
 168 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 169 [AC_TRY_RUN([
 170 int main () {
 171   char buf[16];
 172   long double f = 3.141592653;
 173   sprintf (buf, "%Lg", f);
 174   return (strncmp ("3.14159", buf, 7));
 175 }],
 176 gdb_cv_printf_has_long_double=yes,
 177 gdb_cv_printf_has_long_double=no,
 178 gdb_cv_printf_has_long_double=no)])
 179 if test $gdb_cv_printf_has_long_double = yes; then
 180   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 181 fi
 182 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 183
 184 dnl See if the compiler and runtime support scanning long doubles
 185
 186 AC_MSG_CHECKING(for long double support in scanf)
 187 AC_CACHE_VAL(gdb_cv_scanf_has_long_double,
 188 [AC_TRY_RUN([
 189 int main () {
 190   char *buf = "3.141592653";
 191   long double f = 0;
 192   sscanf (buf, "%Lg", &f);
 193   return !(f > 3.14159 && f < 3.14160);
 194 }],
 195 gdb_cv_scanf_has_long_double=yes,
 196 gdb_cv_scanf_has_long_double=no,
 197 gdb_cv_scanf_has_long_double=no)])
 198 if test $gdb_cv_scanf_has_long_double = yes; then
 199   AC_DEFINE(SCANF_HAS_LONG_DOUBLE)
 200 fi
 201 AC_MSG_RESULT($gdb_cv_scanf_has_long_double)
 202
 203 AC_FUNC_MMAP
 204
 205 BFD_NEED_DECLARATION(malloc)
 206 BFD_NEED_DECLARATION(realloc)
 207 BFD_NEED_DECLARATION(free)
 208
 209 BFD_NEED_DECLARATION(strerror)
 210
 211 dnl See if thread_db library is around for Solaris thread debugging.  Note that
 212 dnl we must explicitly test for version 1 of the library because version 0
 213 dnl (present on Solaris 2.4 or earlier) doesn't have the same API.
 214
 215 dnl Note that we only want this if we are both native (host == target), and
 216 dnl not doing a canadian cross build (build == host).
 217
 218 if test ${build} = ${host} -a ${host} = ${target} ; then
 219    case ${host_os} in
 220    hpux*)
 221       AC_MSG_CHECKING(for HPUX/OSF thread support)
 222       if test -f /usr/include/dce/cma_config.h ; then
 223          if test "$GCC" = "yes" ; then
 224             AC_MSG_RESULT(yes)
 225             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 226             CONFIG_OBS="${CONFIG_OJS} hpux-thread.o"
 227             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
 228          else
 229             AC_MSG_RESULT(no (suppressed because you are not using GCC))
 230          fi
 231       else
 232          AC_MSG_RESULT(no)
 233       fi
 234       ;;
 235    solaris*)
 236       AC_MSG_CHECKING(for Solaris thread debugging library)
 237       if test -f /usr/lib/libthread_db.so.1 ; then
 238          AC_MSG_RESULT(yes)
 239          AC_DEFINE(HAVE_THREAD_DB_LIB)
 240          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
 241          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
 242          AC_CHECK_LIB(dl, dlopen)
 243          if test "$GCC" = "yes" ; then
 244             # The GNU linker requires the -export-dynamic option to make
 245             # all symbols visible in the dynamic symbol table.
 246             hold_ldflags=$LDFLAGS
 247             AC_MSG_CHECKING(for the ld -export-dynamic flag)
 248             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
 249             AC_TRY_LINK(, [int i;], found=yes, found=no)
 250             LDFLAGS=$hold_ldflags
 251             AC_MSG_RESULT($found)
 252             if test $found = yes; then
 253                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
 254             fi
 255          fi
 256       else
 257          AC_MSG_RESULT(no)
 258       fi
 259       ;;
 260    esac
 261    AC_SUBST(CONFIG_LDFLAGS)
 262 fi
 263
 264 dnl Handle optional features that can be enabled.
 265 ENABLE_CFLAGS=
 266
 267 AC_ARG_ENABLE(netrom,
 268 [  --enable-netrom ],
 269 [case "${enableval}" in
 270 yes)    enable_netrom=yes ;;
 271 no)     enable_netrom=no ;;
 272 *)      AC_MSG_ERROR(bad value ${enableval} given for netrom option) ;;
 273 esac])
 274
 275 if test "${enable_netrom}" = "yes"; then
 276         CONFIG_OBS="${CONFIG_OBS} remote-nrom.o"
 277         CONFIG_SRCS="${CONFIG_SRCS} remote-nrom.c"
 278 fi
 279
 280 MMALLOC_CFLAGS=
 281 MMALLOC=
 282 AC_SUBST(MMALLOC_CFLAGS)
 283 AC_SUBST(MMALLOC)
 284
 285 AC_ARG_WITH(mmalloc,
 286 [  --with-mmalloc             use memory mapped malloc package],
 287 [case "${withval}" in
 288   yes)  want_mmalloc=true ;;
 289   no)   want_mmalloc=false;;
 290   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-mmalloc option) ;;
 291 esac],[want_mmalloc=false])dnl
 292
 293 if test x$want_mmalloc = xtrue; then
 294    AC_DEFINE(USE_MMALLOC)
 295    AC_DEFINE(MMCHECK_FORCE)
 296    MMALLOC_CFLAGS="-I$srcdir/../mmalloc"
 297    MMALLOC='../mmalloc/libmmalloc.a'
 298 fi
 299
 300 # start-sanitize-gdbtk
 301 # start-sanitize-ide
 302 ENABLE_IDE=
 303 AC_ARG_ENABLE(ide, [  --enable-ide            Enable IDE support])
 304 if test "$enable_ide" = yes; then
 305    enable_ide=yes
 306    ENABLE_IDE=1
 307 else
 308    enable_ide=no
 309 fi
 310 AC_SUBST(ENABLE_IDE)
 311
 312 AC_ARG_WITH(foundry-libs,
 313 [  --with-foundry-libs=directory       use the Foundry SDK in directory],
 314 [FOUNDRY_LIB_BASE=${withval}])
 315 AC_SUBST(FOUNDRY_LIB_BASE)
 316
 317 #
 318 # This is the Foundry SDK
 319 #
 320 # These variables are used to determine where the Foundry libs and
 321 # header files are located.
 322 #
 323 if test "$FOUNDRY_LIB_BASE" != ""; then
 324     LIBGUI="${FOUNDRY_LIB_BASE}/lib/libgui.a"
 325     GUI_CFLAGS_X="-I${FOUNDRY_LIB_BASE}/include"
 326     if test x$enable_ide = xyes; then
 327         IDE_CFLAGS_X="-I${FOUNDRY_LIB_BASE}/include -DIDE"
 328         IDE_X="-L${FOUNDRY_LIB_BASE}/lib -lilu-Tk -lilu-c -lilu"
 329     else
 330         IDE_CFLAGS_X="-I${FOUNDRY_LIB_BASE}/include"
 331     fi
 332     LIBIDETCL="${FOUNDRY_LIB_BASE}/lib/libidetcl.a"
 333     LIBIDE="${FOUNDRY_LIB_BASE}/lib/libide.a"
 334     IDE_DEPS="${FOUNDRY_LIB_BASE}/lib/libilu-Tk.a ${FOUNDRY_LIB_BASE}/lib/libilu-c.a ${FOUNDRY_LIB_BASE}/lib/libilu.a"
 335 else
 336     LIBGUI="../libgui/src/libgui.a"
 337     GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
 338     if test x$enable_ide = xyes; then
 339         IDE_CFLAGS_X="-I${srcdir}/../libidetcl/src -I${srcdir}/../libide/src -DIDE -I${srcdir}/../ilu/runtime/mainloop"
 340         IDE_X="-L../ilu/runtime/mainloop -lilu-Tk -L../ilu/runtime/c -lilu-c -L../ilu/runtime/kernel -lilu"
 341     else
 342         IDE_CFLAGS_X="-I${srcdir}/../libidetcl/src -I${srcdir}/../libide/src"
 343     fi
 344     LIBIDETCL="../libidetcl/src/libidetcl.a"
 345     LIBIDE="../libide/src/libide.a"
 346     IDE_DEPS="../ilu/runtime/mainloop/libilu-Tk.a ../ilu/runtime/c/libilu-c.a ../ilu/runtime/kernel/libilu.a"
 347 fi
 348 AC_SUBST(LIBGUI)
 349 AC_SUBST(GUI_CFLAGS_X)
 350 AC_SUBST(IDE_CFLAGS_X)
 351 AC_SUBST(IDE_X)
 352 AC_SUBST(LIBIDETCL)
 353 AC_SUBST(LIBIDE)
 354 AC_SUBST(IDE_DEPS)
 355 # end-sanitize-ide
 356
 357 ENABLE_GDBTK=
 358
 359 AC_ARG_ENABLE(gdbtk,
 360 [  --enable-gdbtk ],
 361 [case "${enableval}" in
 362     yes)
 363         case "$host" in
 364         *go32*)
 365             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 366             enable_gdbtk=no ;;
 367         *windows*)
 368             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 369             enable_gdbtk=no ;;
 370         *)
 371             enable_gdbtk=yes ;;
 372         esac ;;
 373     no)
 374         enable_gdbtk=no  ;;
 375     *)
 376         AC_MSG_ERROR(bad value ${enableval} given for gdbtk option) ;;
 377 esac],
 378 [
 379 # Default is on for everything but go32 and cygwin32
 380 case "$host" in
 381     *go32* | *windows*)
 382         ;;
 383     *)
 384         enable_gdbtk=yes ;;
 385     esac
 386 ])
 387
 388 # In the cygwin32 environment, we need some additional flags.
 389 AC_CACHE_CHECK([for cygwin32], gdb_cv_os_cygwin32,
 390 [AC_EGREP_CPP(lose, [
 391 #ifdef __CYGWIN32__
 392 lose
 393 #endif],[gdb_cv_os_cygwin32=yes],[gdb_cv_os_cygwin32=no])])
 394
 395 WIN32LIBS=
 396 WIN32LDAPP=
 397 AC_SUBST(WIN32LIBS)
 398 AC_SUBST(WIN32LDAPP)
 399
 400 WINDRES=${WINDRES-windres}
 401 AC_SUBST(WINDRES)
 402
 403 if test x$gdb_cv_os_cygwin32 = xyes; then
 404     if test x$enable_ide = xyes; then
 405         WIN32LIBS="-ladvapi32"
 406     fi
 407 fi
 408
 409 configdir="unix"
 410
 411 GDBTKLIBS=
 412 if test "${enable_gdbtk}" = "yes"; then
 413
 414     CY_AC_PATH_TCLCONFIG
 415     if test -z "${no_tcl}"; then
 416         CY_AC_LOAD_TCLCONFIG
 417         CY_AC_PATH_TKCONFIG
 418
 419         # If $no_tk is nonempty, then we can't do Tk, and there is no
 420         # point to doing Tcl.
 421         if test -z "${no_tk}"; then
 422            CY_AC_LOAD_TKCONFIG
 423            CY_AC_PATH_TCLH
 424            CY_AC_PATH_TKH
 425            CY_AC_PATH_ITCLH
 426            CY_AC_PATH_TIX
 427
 428            # now look for tix library stuff
 429            TIXVERSION=4.1.8.0
 430            . ${ac_cv_c_tclconfig}/tclConfig.sh
 431            case "${host}" in
 432            *-*-cygwin32*)
 433                 tixdir=../tix/win/tcl8.0
 434                 ;;
 435            *)
 436                 tixdir=../tix/unix/tk8.0
 437                 ;;
 438            esac
 439            if test "${TCL_SHARED_BUILD}" = "1"; then
 440                 TIX_LIB_EXT="${TCL_SHLIB_SUFFIX}"
 441
 442                 # Can't win them all: SunOS 4 (others?) appends a version
 443                 # number after the ".so"
 444                 case "${host}" in
 445                 *-*-sunos4*)
 446                     TIX_LIB_EXT="${TIX_LIB_EXT}.1.0" ;;
 447                 esac
 448
 449            else
 450                 TIX_LIB_EXT=".a"
 451            fi
 452
 453            if test "${TCL_LIB_VERSIONS_OK}" = "ok"; then
 454                 TIXLIB="-L${tixdir} -ltix${TIXVERSION}"
 455                 TIX_DEPS="${tixdir}/libtix${TIXVERSION}${TIX_LIB_EXT}"
 456            else
 457                 TIXLIB="-L${tixdir} -ltix`echo ${TIXVERSION} | tr -d .`"
 458                 TIX_DEPS="${tixdir}/libtix`echo ${TIXVERSION} | tr -d .`${TIX_LIB_EXT}"
 459            fi
 460
 461            ENABLE_GDBTK=1
 462            ENABLE_CFLAGS="${ENABLE_CFLAGS} -DGDBTK"
 463
 464            # Include some libraries that Tcl and Tk want.
 465            if test "${enable_ide}" = "yes"; then
 466               TCL_LIBS='$(LIBIDETCL) $(LIBIDE) $(LIBGUI) $(IDE) $(ITCL) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 467               CONFIG_DEPS='$(LIBIDETCL) $(LIBIDE) $(LIBGUI) $(IDE_DEPS) $(ITCL_DEPS) $(TIX_DEPS) $(TK_DEPS) $(TCL_DEPS)'
 468            else
 469               TCL_LIBS='$(LIBGUI) $(ITCL) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 470               CONFIG_DEPS='$(LIBGUI) $(ITCL_DEPS) $(TIX_DEPS) $(TK_DEPS) $(TCL_DEPS)'
 471            fi
 472            # Yes, the ordering seems wrong here.  But it isn't.
 473            # TK_LIBS is the list of libraries that need to be linked
 474            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
 475            # were in LIBS then any link tests after this point would
 476            # try to include things like `$(LIBGUI)', which wouldn't work.
 477            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
 478            CONFIG_OBS="${CONFIG_OBS} gdbtk.o gdbtk-cmds.o gdbtk-hooks.o"
 479
 480            if test x$gdb_cv_os_cygwin32 = xyes; then
 481               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32 -luser32"
 482               WIN32LDAPP="-Wl,--subsystem,console"
 483               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
 484            fi
 485         fi
 486     fi
 487 fi
 488
 489 AC_SUBST(ENABLE_GDBTK)
 490 AC_SUBST(X_CFLAGS)
 491 AC_SUBST(X_LDFLAGS)
 492 AC_SUBST(X_LIBS)
 493 AC_SUBST(TIXLIB)
 494 AC_SUBST(TIX_DEPS)
 495 AC_SUBST(GDBTKLIBS)
 496 # end-sanitize-gdbtk
 497
 498 AC_PATH_X
 499 # start-sanitize-sky
 500 # Enable GPU2 library for MIPS simulator
 501 AC_ARG_WITH(sim-gpu2,
 502 [  --with-sim-gpu2=path                 Use GPU2 library under given directory],
 503 [case "${target}" in
 504   mips*-sky-*)
 505     if test -d "${withval}"
 506     then
 507       LIBS="${LIBS} -L${withval}/lib -lgpu2 -L${x_libraries} -lX11 -lXext"
 508     else
 509       AC_MSG_WARN([Directory ${withval} does not exist.])
 510     fi ;;
 511   *)  AC_MSG_WARN([--with-sim-gpu2 option invalid for target ${target}])
 512 esac])dnl
 513
 514 # Enable target accurate FP library
 515 AC_ARG_WITH(sim-funit,
 516 [  --with-sim-funit=path                Use target FP lib under given directory],
 517 [case "${target}" in
 518   mips*-sky-*)
 519     if test -d "${withval}"
 520     then
 521       LIBS="${LIBS} -L${withval}/lib -lfunit"
 522     else
 523       AC_MSG_WARN([Directory ${withval} does not exist.])
 524     fi ;;
 525   *)  AC_MSG_WARN([--with-sim-funit option invalid for target ${target}])
 526 esac])dnl
 527 # end-sanitize-sky
 528
 529 dnl Solaris puts wctype in /usr/lib/libw.a
 530 AC_CHECK_LIB(w, wctype, [LIBS="$LIBS -lw"])
 531
 532 AC_SUBST(ENABLE_CFLAGS)
 533
 534 AC_SUBST(CONFIG_OBS)
 535 AC_SUBST(CONFIG_DEPS)
 536 AC_SUBST(CONFIG_SRCS)
 537
 538 # Begin stuff to support --enable-shared
 539 AC_ARG_ENABLE(shared,
 540 [  --enable-shared         use shared libraries],
 541 [case "${enableval}" in
 542   yes) shared=true ;;
 543   no)  shared=false ;;
 544   *) shared=true ;;
 545 esac])dnl
 546
 547 HLDFLAGS=
 548 HLDENV=
 549 # If we have shared libraries, try to set rpath reasonably.
 550 if test "${shared}" = "true"; then
 551   case "${host}" in
 552   *-*-hpux*)
 553     HLDFLAGS='-Wl,+s,+b,$(libdir)'
 554     ;;
 555   *-*-irix5* | *-*-irix6*)
 556     HLDFLAGS='-Wl,-rpath,$(libdir)'
 557     ;;
 558   *-*-linux*aout*)
 559     ;;
 560   *-*-linux* | *-pc-linux-gnu)
 561     HLDFLAGS='-Wl,-rpath,$(libdir)'
 562     ;;
 563   *-*-solaris*)
 564     HLDFLAGS='-R $(libdir)'
 565     ;;
 566   *-*-sysv4*)
 567     HLDENV='if test -z "$${LD_RUN_PATH}"; then LD_RUN_PATH=$(libdir); else LD_RUN_PATH=$${LD_RUN_PATH}:$(libdir); fi; export LD_RUN_PATH;'
 568     ;;
 569   esac
 570 fi
 571
 572 # On SunOS, if the linker supports the -rpath option, use it to
 573 # prevent ../bfd and ../opcodes from being included in the run time
 574 # search path.
 575 case "${host}" in
 576   *-*-sunos*)
 577     echo 'main () { }' > conftest.c
 578     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
 579     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
 580       :
 581     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
 582       :
 583     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
 584       :
 585     elif grep 'some text already loaded' conftest.t >/dev/null 2>&1; then
 586       :
 587     elif test "${shared}" = "true"; then
 588       HLDFLAGS='-Wl,-rpath=$(libdir)'
 589     else
 590       HLDFLAGS='-Wl,-rpath='
 591     fi
 592     rm -f conftest.t conftest.c conftest
 593     ;;
 594 esac
 595 AC_SUBST(HLDFLAGS)
 596 AC_SUBST(HLDENV)
 597 # End stuff to support --enable-shared
 598
 599 # target_subdir is used by the testsuite to find the target libraries.
 600 target_subdir=
 601 if test "${host}" != "${target}"; then
 602     target_subdir="${target_alias}/"
 603 fi
 604 AC_SUBST(target_subdir)
 605
 606 frags=
 607 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
 608 if test ! -f ${host_makefile_frag}; then
 609 AC_MSG_ERROR("*** Gdb does not support host ${host}")
 610 fi
 611 frags="$frags $host_makefile_frag"
 612
 613 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
 614 if test ! -f ${target_makefile_frag}; then
 615 AC_MSG_ERROR("*** Gdb does not support target ${target}")
 616 fi
 617 frags="$frags $target_makefile_frag"
 618
 619 AC_SUBST_FILE(host_makefile_frag)
 620 AC_SUBST_FILE(target_makefile_frag)
 621 AC_SUBST(frags)
 622
 623 changequote(,)dnl
 624 hostfile=`sed -n '
 625 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 626 ' ${host_makefile_frag}`
 627
 628 targetfile=`sed -n '
 629 s/TM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 630 ' ${target_makefile_frag}`
 631
 632 # these really aren't orthogonal true/false values of the same condition,
 633 # but shells are slow enough that I like to reuse the test conditions
 634 # whenever possible
 635 if test "${target}" = "${host}"; then
 636 nativefile=`sed -n '
 637 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
 638 ' ${host_makefile_frag}`
 639 # else
 640 # GDBserver is only useful in a "native" enviroment
 641 # configdirs=`echo $configdirs | sed 's/gdbserver//'`
 642 fi
 643 changequote([,])
 644
 645 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
 646 # (NAT_FILE) is not set in config/*/*.m[ht] files, we don't make the
 647 # corresponding links.  But we have to remove the xm.h files and tm.h
 648 # files anyway, e.g. when switching from "configure host" to
 649 # "configure none".
 650
 651 files=
 652 links=
 653 rm -f xm.h
 654 if test "${hostfile}" != ""; then
 655 files="${files} config/${gdb_host_cpu}/${hostfile}"
 656 links="${links} xm.h"
 657 fi
 658 rm -f tm.h
 659 if test "${targetfile}" != ""; then
 660 files="${files} config/${gdb_target_cpu}/${targetfile}"
 661 links="${links} tm.h"
 662 fi
 663 rm -f nm.h
 664 if test "${nativefile}" != ""; then
 665 files="${files} config/${gdb_host_cpu}/${nativefile}"
 666 links="${links} nm.h"
 667 else
 668 # A cross-only configuration.
 669 files="${files} config/nm-empty.h"
 670 links="${links} nm.h"
 671 fi
 672 # start-sanitize-gdbtk
 673 AC_PROG_LN_S
 674 # Make it possible to use the GUI without doing a full install
 675 if test "${enable_gdbtk}" = "yes" -a ! -d gdbtcl ; then
 676   if test "$LN_S" = "ln -s" -a ! -f gdbtcl ; then
 677   echo linking $srcdir/gdbtcl to gdbtcl
 678   $LN_S $srcdir/gdbtcl gdbtcl
 679   else
 680   echo Warning: Unable to link $srcdir/gdbtcl to gdbtcl.  You will need to do a
 681   echo "         " make install before you are able to run the GUI.
 682   fi
 683 fi
 684 # end-sanitize-gdbtk
 685
 686 AC_LINK_FILES($files, $links)
 687
 688 dnl Check for exe extension set on certain hosts (e.g. Win32)
 689 AM_EXEEXT
 690
 691 AC_CONFIG_SUBDIRS($configdirs)
 692 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
 693 [
 694 dnl Autoconf doesn't provide a mechanism for modifying definitions
 695 dnl provided by makefile fragments.
 696 dnl
 697 if test "${nativefile}" = ""; then
 698 sed -e '/^NATDEPFILES[[         ]]*=[[  ]]*/s//# NATDEPFILES=/' \
 699         < Makefile > Makefile.tem
 700 mv -f Makefile.tem Makefile
 701 fi
 702
 703 changequote(,)dnl
 704 sed -e '/^TM_FILE[      ]*=/s,^TM_FILE[         ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
 705 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
 706 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
 707 mv -f Makefile.tmp Makefile
 708 changequote([,])dnl
 709
 710 case x$CONFIG_HEADERS in
 711 xconfig.h:config.in)
 712 echo > stamp-h ;;
 713 esac
 714 ],
 715 [
 716 gdb_host_cpu=$gdb_host_cpu
 717 gdb_target_cpu=$gdb_target_cpu
 718 nativefile=$nativefile
 719 ])
 720
 721 exit 0
 722