gdb/testsuite/gdb.base/bigcore.exp

   1 # Copyright 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2004, 2005,
   2 # 2007, 2008, 2009 Free Software Foundation, Inc.
   3
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 3 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16
  17 # This file is based on corefile.exp which was written by Fred
  18 # Fish. (fnf@cygnus.com)
  19
  20 if $tracelevel then {
  21         strace $tracelevel
  22 }
  23
  24 set prms_id 0
  25 set bug_id 0
  26
  27 # Are we on a target board?  As of 2004-02-12, GDB didn't have a
  28 # mechanism that would let it efficiently access a remote corefile.
  29
  30 if ![isnative] then {
  31     untested "Remote system"
  32     return
  33 }
  34
  35 # Can the system run this test (in particular support sparse
  36 # corefiles)?  On systems that lack sparse corefile support this test
  37 # consumes too many resources - gigabytes worth of disk space and and
  38 # I/O bandwith.
  39
  40 if { [istarget "*-*-*bsd*"]
  41      || [istarget "*-*-hpux*"]
  42      || [istarget "*-*-solaris*"]
  43      || [istarget "*-*-darwin*"]
  44      || [istarget "*-*-cygwin*"] } {
  45     untested "Kernel lacks sparse corefile support (PR gdb/1551)"
  46     return
  47 }
  48
  49 # This testcase causes too much stress (in terms of memory usage)
  50 # on certain systems...
  51 if { [istarget "*-*-*irix*"] } {
  52     untested "Testcase too stressful for this system"
  53     return
  54 }
  55
  56 set testfile "bigcore"
  57 set srcfile ${testfile}.c
  58 set binfile ${objdir}/${subdir}/${testfile}
  59 set corefile ${objdir}/${subdir}/${testfile}.corefile
  60
  61 if  { [gdb_compile "${srcdir}/${subdir}/${srcfile}" "${binfile}" executable {debug}] != "" } {
  62      untested bigcore.exp
  63      return -1
  64 }
  65
  66 # Run GDB on the bigcore program up-to where it will dump core.
  67
  68 gdb_exit
  69 gdb_start
  70 gdb_reinitialize_dir $srcdir/$subdir
  71 gdb_load ${binfile}
  72 gdb_test "set print sevenbit-strings" "" \
  73         "set print sevenbit-strings; ${testfile}"
  74 gdb_test "set width 0" "" \
  75         "set width 0; ${testfile}"
  76 if { ![runto_main] } then {
  77     gdb_suppress_tests;
  78 }
  79 set print_core_line [gdb_get_line_number "Dump core"]
  80 gdb_test "tbreak $print_core_line"
  81 gdb_test continue ".*print_string.*"
  82 gdb_test next ".*0 = 0.*"
  83
  84 # Traverse part of bigcore's linked list of memory chunks (forward or
  85 # backward), saving each chunk's address.
  86
  87 proc extract_heap { dir } {
  88     global gdb_prompt
  89     global expect_out
  90     set heap ""
  91     set test "extract ${dir} heap"
  92     set lim 0
  93     gdb_test_multiple "print heap.${dir}" "$test" {
  94         -re " = \\(struct list \\*\\) 0x0.*$gdb_prompt $" {
  95             pass "$test"
  96         }
  97         -re " = \\(struct list \\*\\) (0x\[0-9a-f\]*).*$gdb_prompt $" {
  98             set heap [concat $heap $expect_out(1,string)]
  99             if { $lim >= 50 } {
 100                 pass "$test (stop at $lim)"
 101             } else {
 102                 incr lim
 103                 send_gdb "print \$.${dir}\n"
 104                 exp_continue
 105             }
 106         }
 107         -re ".*$gdb_prompt $" {
 108             fail "$test (entry $lim)"
 109         }
 110         timeout {
 111             fail "$test (timeout)"
 112         }
 113     }
 114     return $heap;
 115 }
 116 set next_heap [extract_heap next]
 117 set prev_heap [extract_heap prev]
 118
 119 # Save the total allocated size within GDB so that we can check
 120 # the core size later.
 121 gdb_test "set \$bytes_allocated = bytes_allocated" "" "save heap size"
 122
 123 # Now create a core dump
 124
 125 # Rename the core file to "TESTFILE.corefile" rather than just "core",
 126 # to avoid problems with sys admin types that like to regularly prune
 127 # all files named "core" from the system.
 128
 129 # Some systems append "core" to the name of the program; others append
 130 # the name of the program to "core"; still others (like Linux, as of
 131 # May 2003) create cores named "core.PID".
 132
 133 # Save the process ID.  Some systems dump the core into core.PID.
 134 set test "grab pid"
 135 gdb_test_multiple "info program" $test {
 136     -re "child process (\[0-9\]+).*$gdb_prompt $" {
 137         set inferior_pid $expect_out(1,string)
 138         pass $test
 139     }
 140     -re "$gdb_prompt $" {
 141         set inferior_pid unknown
 142         pass $test
 143     }
 144 }
 145
 146 # Dump core using SIGABRT
 147 set oldtimeout $timeout
 148 set timeout 600
 149 gdb_test "signal SIGABRT" "Program terminated with signal SIGABRT, .*"
 150
 151 # Find the corefile
 152 set file ""
 153 foreach pat [list core.${inferior_pid} ${testfile}.core core] {
 154     set names [glob -nocomplain $pat]
 155     if {[llength $names] == 1} {
 156         set file [lindex $names 0]
 157         remote_exec build "mv $file $corefile"
 158         break
 159     }
 160 }
 161
 162 if { $file == "" } {
 163     untested "Can't generate a core file"
 164     return 0
 165 }
 166
 167 # Check that the corefile is plausibly large enough.  We're trying to
 168 # detect the case where the operating system has truncated the file
 169 # just before signed wraparound.  TCL, unfortunately, has a similar
 170 # problem - so use catch.  It can handle the "bad" size but not
 171 # necessarily the "good" one.  And we must use GDB for the comparison,
 172 # similarly.
 173
 174 if {[catch {file size $corefile} core_size] == 0} {
 175     set core_ok 0
 176     gdb_test_multiple "print \$bytes_allocated < $core_size" "check core size" {
 177         -re " = 1\r\n$gdb_prompt $" {
 178             pass "check core size"
 179             set core_ok 1
 180         }
 181         -re " = 0\r\n$gdb_prompt $" {
 182             pass "check core size"
 183             set core_ok 0
 184         }
 185     }
 186 } {
 187     # Probably failed due to the TCL build having problems with very
 188     # large values.  Since GDB uses a 64-bit off_t (when possible) it
 189     # shouldn't have this problem.  Assume that things are going to
 190     # work.  Without this assumption the test is skiped on systems
 191     # (such as i386 GNU/Linux with patched kernel) which do pass.
 192     pass "check core size"
 193     set core_ok 1
 194 }
 195 if {! $core_ok} {
 196     untested "check core size (system does not support large corefiles)"
 197     return 0
 198 }
 199
 200 # Now load up that core file
 201
 202 set test "load corefile"
 203 gdb_test_multiple "core $corefile" "$test" {
 204     -re "A program is being debugged already.  Kill it. .y or n. " {
 205         send_gdb "y\n"
 206         exp_continue
 207     }
 208     -re "Core was generated by.*$gdb_prompt $" {
 209         pass "$test"
 210     }
 211 }
 212
 213 # Finally, re-traverse bigcore's linked list, checking each chunk's
 214 # address against the executable.  Don't use gdb_test_multiple as want
 215 # only one pass/fail.  Don't use exp_continue as the regular
 216 # expression involving $heap needs to be re-evaluated for each new
 217 # response.
 218
 219 proc check_heap { dir heap } {
 220     global gdb_prompt
 221     set test "check ${dir} heap"
 222     set ok 1
 223     set lim 0
 224     send_gdb "print heap.${dir}\n"
 225     while { $ok } {
 226         gdb_expect {
 227             -re " = \\(struct list \\*\\) [lindex $heap $lim].*$gdb_prompt $" {
 228                 if { $lim >= [llength $heap] } {
 229                     pass "$test"
 230                     set ok 0
 231                 } else {
 232                     incr lim
 233                     send_gdb "print \$.${dir}\n"
 234                 }
 235             }
 236             -re ".*$gdb_prompt $" {
 237                 fail "$test (address [lindex $heap $lim])"
 238                 set ok 0
 239             }
 240             timeout {
 241                 fail "$test (timeout)"
 242                 set ok 0
 243             }
 244         }
 245     }
 246 }
 247
 248 check_heap next $next_heap
 249 check_heap prev $prev_heap