gdb/testsuite/gdb.fortran/function-calls.exp

   1 # Copyright 2019-2023 Free Software Foundation, Inc.
   2
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 3 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program.  If not, see <http://www.gnu.org/licenses/> .
  15
  16 # Exercise passing and returning arguments in Fortran. This test case
  17 # is based on the GNU Fortran Argument passing conventions.
  18
  19 require allow_fortran_tests
  20
  21 standard_testfile ".f90"
  22
  23 if {[prepare_for_testing ${testfile}.exp ${testfile} ${srcfile} {debug f90}]} {
  24     return -1
  25 }
  26
  27 with_complaints 5 {
  28     set cmd "maint expand-symtabs $srcfile"
  29     set cmd_regexp [string_to_regexp $cmd]
  30     set re_kfail [concat "During symbol reading:" \
  31                       " unable to find array range"]
  32     gdb_test_multiple $cmd "no complaints in srcfile" {
  33         -re -wrap "$re_kfail.*" {
  34             kfail symtab/27388 $gdb_test_name
  35         }
  36         -re "^$cmd_regexp\r\n$gdb_prompt $" {
  37             pass $gdb_test_name
  38         }
  39     }
  40 }
  41
  42 if {![runto [gdb_get_line_number "post_init"]]} {
  43     return
  44 }
  45
  46 # Use inspired by gdb.base/callfuncs.exp.
  47 gdb_test_no_output "set unwindonsignal on"
  48
  49 # Baseline: function and subroutine call with no arguments.
  50 gdb_test "p no_arg()" " = .TRUE."
  51 gdb_test_no_output "call no_arg_subroutine()"
  52
  53 # Argument class: literal, inferior variable, convenience variable,
  54 # function call return value, function.
  55 # Paragraph 3: Variables are passed by reference.
  56 gdb_test "p one_arg(.TRUE.)" " = .TRUE."
  57 gdb_test "p one_arg(untrue)" " = .FALSE."
  58 gdb_test_no_output "set \$var = .FALSE."
  59 gdb_test "p one_arg(\$var)" " = .FALSE."
  60 gdb_test "p one_arg(one_arg(.TRUE.))" " = .TRUE."
  61 gdb_test "p one_arg(one_arg(.FALSE.))" " = .FALSE."
  62 gdb_test_no_output "call run(no_arg_subroutine)"
  63
  64 # Return: constant.
  65 gdb_test "p return_constant()" " = 17"
  66 # Return derived type and call a function in a module.
  67 gdb_test "p derived_types_and_module_calls::build_cart(7,8)" \
  68          " = \\\( x = 7, y = 8 \\\)"
  69
  70 # Two hidden arguments. 1. returned string and 2. string length.
  71 # Paragraph 1.
  72 gdb_test "p return_string(returned_string_debugger, 40)" ""
  73 gdb_test "p returned_string_debugger" "'returned in hidden first argument       '"
  74
  75 # Argument type: real(kind=4), complex, array, pointer, derived type,
  76 # derived type with allocatable, nested derived type.
  77 # Paragraph 4: pointer.
  78 gdb_test "p pointer_function(int_pointer)" " = 87"
  79 # Paragraph 4: array.
  80 gdb_test "call array_function(integer_array)" " = 17"
  81 gdb_test "p derived_types_and_module_calls::pass_cart(c)" \
  82          " = \\\( x = 2, y = 4 \\\)"
  83 # Allocatable elements in a derived type. Technical report ISO/IEC 15581.
  84 gdb_test "p derived_types_and_module_calls::pass_cart_nd(c_nd)" " = 4"
  85 gdb_test "p derived_types_and_module_calls::pass_nested_cart(nested_c)" \
  86           "= \\\( d = \\\( x = 1, y = 2 \\\), z = 3 \\\)"
  87 # Result within some tolerance.
  88 gdb_test "p real4_argument(real4)" " = 3.${decimal}"
  89
  90 # Paragraph 2. Complex argument and return.
  91 gdb_test "p complex_argument(fft)" " = \\\(2.${decimal},3.${decimal}\\\)"
  92
  93 # Function with optional arguments.
  94 # Paragraph 10: Option reference arguments.
  95 gdb_test "p sum_some(1,2,3)" " = 6"
  96
  97 # There is currently no mechanism to call a function without all
  98 # optional parameters present.
  99 setup_kfail "gdb/24147" *-*-*
 100 gdb_test "p sum_some(1,2)" " = 3"
 101
 102 # Paragraph 10: optional value arguments. There is insufficient DWARF
 103 # information to reliably make this case work.
 104 if { [test_compiler_info {gfortran-*} f90] } {
 105     setup_kfail "gdb/24305" *-*-*
 106 }
 107 gdb_test "p one_arg_value(10)" " = 10"
 108
 109 # DW_AT_artificial formal parameters must be passed manually. This
 110 # assert will fail if the length of the string is wrapped in a pointer.
 111 # Paragraph 7: Character type.
 112 gdb_test "p hidden_string_length('arbitrary string', 16)" " = 16"
 113
 114 # Several arguments.
 115 gdb_test "p several_arguments(2, 3, 5)" " = 10"
 116 gdb_test "p mix_of_scalar_arguments(5, .TRUE., 3.5)" " = 9"
 117
 118 # Calling other functions: Recursive call.
 119 gdb_test "p fibonacci(6)" " = 8"